src/Pure/sign.ML
author nipkow
Mon Mar 13 09:38:10 1995 +0100 (1995-03-13)
changeset 949 83c588d6fee9
parent 926 9d1348498c36
child 952 9e10962866b0
permissions -rw-r--r--
Changed treatment of during type inference internally generated type
variables.

1. They are renamed to 'a, 'b, 'c etc away from a given set of used names.
2. They are either frozen (turned into TFrees) or left schematic (TVars)
depending on a parameter. In goals they are frozen, for instantiations they
are left schematic.
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 The abstract type "sg" of signatures.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   structure Symtab: SYMTAB
    11   structure Syntax: SYNTAX
    12   structure Type: TYPE
    13   sharing Symtab = Type.Symtab
    14   local open Type Syntax in
    15     type sg
    16     val rep_sg: sg ->
    17       {tsig: type_sig,
    18        const_tab: typ Symtab.table,
    19        syn: syntax,
    20        stamps: string ref list}
    21     val subsig: sg * sg -> bool
    22     val eq_sg: sg * sg -> bool
    23     val is_draft: sg -> bool
    24     val const_type: sg -> string -> typ option
    25     val classes: sg -> class list
    26     val subsort: sg -> sort * sort -> bool
    27     val norm_sort: sg -> sort -> sort
    28     val print_sg: sg -> unit
    29     val pretty_sg: sg -> Pretty.T
    30     val pprint_sg: sg -> pprint_args -> unit
    31     val pretty_term: sg -> term -> Pretty.T
    32     val pretty_typ: sg -> typ -> Pretty.T
    33     val pretty_sort: sort -> Pretty.T
    34     val string_of_term: sg -> term -> string
    35     val string_of_typ: sg -> typ -> string
    36     val pprint_term: sg -> term -> pprint_args -> unit
    37     val pprint_typ: sg -> typ -> pprint_args -> unit
    38     val certify_typ: sg -> typ -> typ
    39     val certify_term: sg -> term -> term * typ * int
    40     val read_typ: sg * (indexname -> sort option) -> string -> typ
    41     val infer_types: sg -> (indexname -> typ option) ->
    42       (indexname -> sort option) -> string list -> bool -> bool
    43       -> term list * typ -> int * term * (indexname * typ) list
    44     val add_classes: (class * class list) list -> sg -> sg
    45     val add_classrel: (class * class) list -> sg -> sg
    46     val add_defsort: sort -> sg -> sg
    47     val add_types: (string * int * mixfix) list -> sg -> sg
    48     val add_tyabbrs: (string * string list * string * mixfix) list -> sg -> sg
    49     val add_tyabbrs_i: (string * string list * typ * mixfix) list -> sg -> sg
    50     val add_arities: (string * sort list * sort) list -> sg -> sg
    51     val add_consts: (string * string * mixfix) list -> sg -> sg
    52     val add_consts_i: (string * typ * mixfix) list -> sg -> sg
    53     val add_syntax: (string * string * mixfix) list -> sg -> sg
    54     val add_syntax_i: (string * typ * mixfix) list -> sg -> sg
    55     val add_trfuns:
    56       (string * (ast list -> ast)) list *
    57       (string * (term list -> term)) list *
    58       (string * (term list -> term)) list *
    59       (string * (ast list -> ast)) list -> sg -> sg
    60     val add_trrules: xrule list -> sg -> sg
    61     val add_name: string -> sg -> sg
    62     val make_draft: sg -> sg
    63     val merge: sg * sg -> sg
    64     val proto_pure: sg
    65     val pure: sg
    66     val cpure: sg
    67     val const_of_class: class -> string
    68     val class_of_const: string -> class
    69   end
    70 end;
    71 
    72 functor SignFun(structure Syntax: SYNTAX and Type: TYPE): SIGN =
    73 struct
    74 
    75 structure Symtab = Type.Symtab;
    76 structure Syntax = Syntax;
    77 structure BasicSyntax: BASIC_SYNTAX = Syntax;
    78 structure Pretty = Syntax.Pretty;
    79 structure Type = Type;
    80 open BasicSyntax Type;
    81 
    82 
    83 (** datatype sg **)
    84 
    85 (*the "ref" in stamps ensures that no two signatures are identical -- it is
    86   impossible to forge a signature*)
    87 
    88 datatype sg =
    89   Sg of {
    90     tsig: type_sig,                 (*order-sorted signature of types*)
    91     const_tab: typ Symtab.table,    (*types of constants*)
    92     syn: Syntax.syntax,             (*syntax for parsing and printing*)
    93     stamps: string ref list};       (*unique theory indentifier*)
    94 
    95 fun rep_sg (Sg args) = args;
    96 val tsig_of = #tsig o rep_sg;
    97 
    98 
    99 (* stamps *)
   100 
   101 fun is_draft (Sg {stamps = ref "#" :: _, ...}) = true
   102   | is_draft _ = false;
   103 
   104 fun subsig (Sg {stamps = s1, ...}, Sg {stamps = s2, ...}) = s1 subset s2;
   105 
   106 fun eq_sg (Sg {stamps = s1, ...}, Sg {stamps = s2, ...}) = eq_set (s1, s2);
   107 
   108 
   109 (* consts *)
   110 
   111 fun const_type (Sg {const_tab, ...}) c =
   112   Symtab.lookup (const_tab, c);
   113 
   114 
   115 (* classes and sorts *)
   116 
   117 val classes = #classes o Type.rep_tsig o tsig_of;
   118 
   119 val subsort = Type.subsort o tsig_of;
   120 val norm_sort = Type.norm_sort o tsig_of;
   121 
   122 fun pretty_sort [c] = Pretty.str c
   123   | pretty_sort cs = Pretty.str_list "{" "}" cs;
   124 
   125 
   126 
   127 (** print signature **)
   128 
   129 val stamp_names = rev o map !;
   130 
   131 fun print_sg sg =
   132   let
   133     fun prt_typ syn ty = Pretty.quote (Syntax.pretty_typ syn ty);
   134 
   135     fun pretty_subclass (cl, cls) = Pretty.block
   136       [Pretty.str (cl ^ " <"), Pretty.brk 1, pretty_sort cls];
   137 
   138     fun pretty_default cls = Pretty.block
   139       [Pretty.str "default:", Pretty.brk 1, pretty_sort cls];
   140 
   141     fun pretty_arg (ty, n) = Pretty.str (ty ^ " " ^ string_of_int n);
   142 
   143     fun pretty_abbr syn (ty, (vs, rhs)) = Pretty.block
   144       [prt_typ syn (Type (ty, map (fn v => TVar ((v, 0), [])) vs)),
   145         Pretty.str " =", Pretty.brk 1, prt_typ syn rhs];
   146 
   147     fun pretty_arity ty (cl, []) = Pretty.block
   148           [Pretty.str (ty ^ " ::"), Pretty.brk 1, Pretty.str cl]
   149       | pretty_arity ty (cl, srts) = Pretty.block
   150           [Pretty.str (ty ^ " ::"), Pretty.brk 1,
   151             Pretty.list "(" ")" (map pretty_sort srts),
   152             Pretty.brk 1, Pretty.str cl];
   153 
   154     fun pretty_coreg (ty, ars) = map (pretty_arity ty) ars;
   155 
   156     fun pretty_const syn (c, ty) = Pretty.block
   157       [Pretty.str (quote c ^ " ::"), Pretty.brk 1, prt_typ syn ty];
   158 
   159 
   160     val Sg {tsig, const_tab, syn, stamps} = sg;
   161     val {classes, subclass, default, args, abbrs, coreg} = rep_tsig tsig;
   162   in
   163     Pretty.writeln (Pretty.strs ("stamps:" :: stamp_names stamps));
   164     Pretty.writeln (Pretty.strs ("classes:" :: classes));
   165     Pretty.writeln (Pretty.big_list "subclass:" (map pretty_subclass subclass));
   166     Pretty.writeln (pretty_default default);
   167     Pretty.writeln (Pretty.big_list "types:" (map pretty_arg args));
   168     Pretty.writeln (Pretty.big_list "abbrs:" (map (pretty_abbr syn) abbrs));
   169     Pretty.writeln (Pretty.big_list "coreg:" (flat (map pretty_coreg coreg)));
   170     Pretty.writeln (Pretty.big_list "consts:"
   171       (map (pretty_const syn) (Symtab.dest const_tab)))
   172   end;
   173 
   174 
   175 fun pretty_sg (Sg {stamps, ...}) =
   176   Pretty.str_list "{" "}" (stamp_names stamps);
   177 
   178 val pprint_sg = Pretty.pprint o pretty_sg;
   179 
   180 
   181 
   182 (** pretty printing of terms and types **)
   183 
   184 fun pretty_term (Sg {syn, stamps, ...}) =
   185   let val curried = "CPure" mem (map ! stamps);
   186   in Syntax.pretty_term curried syn end;
   187 
   188 fun pretty_typ (Sg {syn, ...}) = Syntax.pretty_typ syn;
   189 
   190 fun string_of_term (Sg {syn, stamps, ...}) = 
   191   let val curried = "CPure" mem (map ! stamps);
   192   in Syntax.string_of_term curried syn end;
   193 
   194 fun string_of_typ (Sg {syn, ...}) = Syntax.string_of_typ syn;
   195 
   196 fun pprint_term sg = Pretty.pprint o Pretty.quote o (pretty_term sg);
   197 fun pprint_typ sg = Pretty.pprint o Pretty.quote o (pretty_typ sg);
   198 
   199 
   200 
   201 (** read types **)  (*exception ERROR*)
   202 
   203 fun err_in_type s =
   204   error ("The error(s) above occurred in type " ^ quote s);
   205 
   206 fun read_raw_typ syn tsig sort_of str =
   207   Syntax.read_typ syn (fn x => if_none (sort_of x) (defaultS tsig)) str
   208     handle ERROR => err_in_type str;
   209 
   210 (*read and certify typ wrt a signature*)
   211 fun read_typ (Sg {tsig, syn, ...}, sort_of) str =
   212   cert_typ tsig (read_raw_typ syn tsig sort_of str)
   213     handle TYPE (msg, _, _) => (writeln msg; err_in_type str);
   214 
   215 
   216 
   217 (** certify types and terms **)   (*exception TYPE*)
   218 
   219 fun certify_typ (Sg {tsig, ...}) ty = cert_typ tsig ty;
   220 
   221 
   222 fun mapfilt_atoms f (Abs (_, _, t)) = mapfilt_atoms f t
   223   | mapfilt_atoms f (t $ u) = mapfilt_atoms f t @ mapfilt_atoms f u
   224   | mapfilt_atoms f a = (case f a of Some y => [y] | None => []);
   225 
   226 fun certify_term (sg as Sg {tsig, ...}) tm =
   227   let
   228     fun valid_const a T =
   229       (case const_type sg a of
   230         Some U => typ_instance (tsig, T, U)
   231       | _ => false);
   232 
   233     fun atom_err (Const (a, T)) =
   234           if valid_const a T then None
   235           else Some ("Illegal type for constant " ^ quote a ^ " :: " ^
   236             quote (string_of_typ sg T))
   237       | atom_err (Var ((x, i), _)) =
   238           if i < 0 then Some ("Negative index for Var " ^ quote x) else None
   239       | atom_err _ = None;
   240 
   241     val norm_tm =
   242       (case it_term_types (typ_errors tsig) (tm, []) of
   243         [] => map_term_types (norm_typ tsig) tm
   244       | errs => raise_type (cat_lines errs) [] [tm]);
   245   in
   246     (case mapfilt_atoms atom_err norm_tm of
   247       [] => (norm_tm, type_of norm_tm, maxidx_of_term norm_tm)
   248     | errs => raise_type (cat_lines errs) [] [norm_tm])
   249   end;
   250 
   251 
   252 
   253 (** infer_types **)         (*exception ERROR*)
   254 
   255 fun infer_types sg types sorts used freeze print_msg (ts, T) =
   256   let
   257     val Sg {tsig, ...} = sg;
   258     val show_typ = string_of_typ sg;
   259     val show_term = string_of_term sg;
   260 
   261     fun term_err [] = ""
   262       | term_err [t] = "\nInvolving this term:\n" ^ show_term t
   263       | term_err ts = 
   264           "\nInvolving these terms:\n" ^ cat_lines (map show_term ts);
   265 
   266     fun exn_type_msg (msg, Ts, ts) =
   267 	"\nType checking error: " ^ msg ^ "\n" ^
   268 	cat_lines (map show_typ Ts) ^ term_err ts ^ "\n";
   269 
   270     val T' = certify_typ sg T
   271              handle TYPE arg => error (exn_type_msg arg);
   272 
   273     val ct = const_type sg;
   274 
   275     fun process_terms (t::ts) (idx, infrd_t, tye) msg n =
   276          let val (infrd_t', tye', msg') = 
   277               let val (T,tye) =
   278                     Type.infer_types(tsig,ct,types,sorts,used,freeze,T',t)
   279               in (Some T, Some tye, msg) end
   280               handle TYPE arg => (None, None, exn_type_msg arg)
   281 
   282              val old_show_brackets = !show_brackets;
   283 
   284              val _ = (show_brackets := true);
   285 
   286              val msg'' = 
   287                if is_none idx then (if is_none infrd_t' then msg' else "")
   288                else if is_none infrd_t' then "" 
   289                else (if msg' = "" then 
   290                 "Error: More than one term is type correct:\n" ^
   291                 (show_term (the infrd_t)) else msg') ^ "\n" ^ 
   292                 (show_term (the infrd_t')) ^ "\n";
   293 
   294          in show_brackets := old_show_brackets;
   295             if is_none infrd_t' then
   296               process_terms ts (idx, infrd_t, tye) msg'' (n+1)
   297             else
   298               process_terms ts (Some n, infrd_t', tye') msg'' (n+1)
   299          end
   300       | process_terms [] (idx, infrd_t, tye) msg _ = 
   301           if msg = "" then (the idx, the infrd_t, the tye) 
   302           else
   303             (if length ts > 1 andalso length ts <= !Syntax.ambiguity_level then
   304                                                       (*no warning shown yet?*)
   305                writeln "Warning: Currently parsed input \
   306                        \produces more than one parse tree.\n\
   307                        \For more information lower Syntax.ambiguity_level."
   308              else ();
   309              error msg)
   310 
   311     val (idx, infrd_t, tye) = process_terms ts (None, None, None) "" 0;
   312   in if print_msg andalso length ts > !Syntax.ambiguity_level then
   313        writeln "Fortunately, only one parse tree is type correct.\n\
   314          \It helps (speed!) if you disambiguate your grammar or your input."
   315      else ();
   316      (idx, infrd_t, tye)
   317   end;
   318 
   319 
   320 
   321 (** extend signature **)    (*exception ERROR*)
   322 
   323 (** signature extension functions **)  (*exception ERROR*)
   324 
   325 fun decls_of name_of mfixs =
   326   map (fn (x, y, mx) => (name_of x mx, y)) mfixs;
   327 
   328 
   329 (* add default sort *)
   330 
   331 fun ext_defsort (syn, tsig, ctab) defsort =
   332   (syn, ext_tsig_defsort tsig defsort, ctab);
   333 
   334 
   335 (* add type constructors *)
   336 
   337 fun ext_types (syn, tsig, ctab) types =
   338   (Syntax.extend_type_gram syn types,
   339     ext_tsig_types tsig (decls_of Syntax.type_name types),
   340     ctab);
   341 
   342 
   343 (* add type abbreviations *)
   344 
   345 fun read_abbr syn tsig (t, vs, rhs_src) =
   346   (t, vs, read_raw_typ syn tsig (K None) rhs_src)
   347     handle ERROR => error ("in type abbreviation " ^ t);
   348 
   349 fun ext_abbrs rd_abbr (syn, tsig, ctab) abbrs =
   350   let
   351     fun mfix_of (t, vs, _, mx) = (t, length vs, mx);
   352     val syn1 = Syntax.extend_type_gram syn (map mfix_of abbrs);
   353 
   354     fun decl_of (t, vs, rhs, mx) =
   355       rd_abbr syn1 tsig (Syntax.type_name t mx, vs, rhs);
   356   in
   357     (syn1, ext_tsig_abbrs tsig (map decl_of abbrs), ctab)
   358   end;
   359 
   360 val ext_tyabbrs_i = ext_abbrs (K (K I));
   361 val ext_tyabbrs = ext_abbrs read_abbr;
   362 
   363 
   364 (* add type arities *)
   365 
   366 fun ext_arities (syn, tsig, ctab) arities =
   367   let
   368     val tsig1 = ext_tsig_arities tsig arities;
   369     val log_types = logical_types tsig1;
   370   in
   371     (Syntax.extend_log_types syn log_types, tsig1, ctab)
   372   end;
   373 
   374 
   375 (* add term constants and syntax *)
   376 
   377 fun err_in_const c =
   378   error ("in declaration of constant " ^ quote c);
   379 
   380 fun err_dup_consts cs =
   381   error ("Duplicate declaration of constant(s) " ^ commas_quote cs);
   382 
   383 
   384 fun read_const syn tsig (c, ty_src, mx) =
   385   (c, read_raw_typ syn tsig (K None) ty_src, mx)
   386     handle ERROR => err_in_const (Syntax.const_name c mx);
   387 
   388 fun ext_cnsts rd_const syn_only (syn, tsig, ctab) raw_consts =
   389   let
   390     fun prep_const (c, ty, mx) = (c, varifyT (cert_typ tsig (no_tvars ty)), mx)
   391       handle TYPE (msg, _, _) => (writeln msg; err_in_const (Syntax.const_name c mx));
   392 
   393     val consts = map (prep_const o rd_const syn tsig) raw_consts;
   394     val decls =
   395       if syn_only then []
   396       else filter_out (equal "" o fst) (decls_of Syntax.const_name consts);
   397   in
   398     (Syntax.extend_const_gram syn consts, tsig,
   399       Symtab.extend_new (ctab, decls)
   400         handle Symtab.DUPS cs => err_dup_consts cs)
   401   end;
   402 
   403 val ext_consts_i = ext_cnsts (K (K I)) false;
   404 val ext_consts = ext_cnsts read_const false;
   405 val ext_syntax_i = ext_cnsts (K (K I)) true;
   406 val ext_syntax = ext_cnsts read_const true;
   407 
   408 
   409 (* add type classes *)
   410 
   411 fun const_of_class c = c ^ "_class";
   412 
   413 fun class_of_const c_class =
   414   let
   415     val c = implode (take (size c_class - 6, explode c_class));
   416   in
   417     if const_of_class c = c_class then c
   418     else raise_term ("class_of_const: bad name " ^ quote c_class) []
   419   end;
   420 
   421 
   422 fun ext_classes (syn, tsig, ctab) classes =
   423   let
   424     val names = map fst classes;
   425     val consts =
   426       map (fn c => (const_of_class c, a_itselfT --> propT, NoSyn)) names;
   427   in
   428     ext_consts_i
   429       (Syntax.extend_consts syn names, ext_tsig_classes tsig classes, ctab)
   430       consts
   431   end;
   432 
   433 
   434 (* add to subclass relation *)
   435 
   436 fun ext_classrel (syn, tsig, ctab) pairs =
   437   (syn, ext_tsig_subclass tsig pairs, ctab);
   438 
   439 
   440 (* add syntactic translations *)
   441 
   442 fun ext_trfuns (syn, tsig, ctab) trfuns =
   443   (Syntax.extend_trfuns syn trfuns, tsig, ctab);
   444 
   445 fun ext_trrules (syn, tsig, ctab) xrules =
   446   (Syntax.extend_trrules syn xrules, tsig, ctab);
   447 
   448 
   449 (* build signature *)
   450 
   451 fun ext_stamps stamps name =
   452   let
   453     val stmps = (case stamps of ref "#" :: ss => ss | ss => ss);
   454   in
   455     if exists (equal name o !) stmps then
   456       error ("Theory already contains a " ^ quote name ^ " component")
   457     else ref name :: stmps
   458   end;
   459 
   460 fun make_sign (syn, tsig, ctab) stamps name =
   461   Sg {tsig = tsig, const_tab = ctab, syn = syn,
   462     stamps = ext_stamps stamps name};
   463 
   464 fun extend_sign extfun name decls (Sg {tsig, const_tab, syn, stamps}) =
   465   make_sign (extfun (syn, tsig, const_tab) decls) stamps name;
   466 
   467 
   468 (* the external interfaces *)
   469 
   470 val add_classes   = extend_sign ext_classes "#";
   471 val add_classrel  = extend_sign ext_classrel "#";
   472 val add_defsort   = extend_sign ext_defsort "#";
   473 val add_types     = extend_sign ext_types "#";
   474 val add_tyabbrs   = extend_sign ext_tyabbrs "#";
   475 val add_tyabbrs_i = extend_sign ext_tyabbrs_i "#";
   476 val add_arities   = extend_sign ext_arities "#";
   477 val add_consts    = extend_sign ext_consts "#";
   478 val add_consts_i  = extend_sign ext_consts_i "#";
   479 val add_syntax    = extend_sign ext_syntax "#";
   480 val add_syntax_i  = extend_sign ext_syntax_i "#";
   481 val add_trfuns    = extend_sign ext_trfuns "#";
   482 val add_trrules   = extend_sign ext_trrules "#";
   483 
   484 fun add_name name sg = extend_sign K name () sg;
   485 val make_draft = add_name "#";
   486 
   487 
   488 
   489 (** merge signatures **)    (*exception TERM*) (*exception ERROR (* FIXME *)*)
   490 
   491 fun merge (sg1, sg2) =
   492   if subsig (sg2, sg1) then sg1
   493   else if subsig (sg1, sg2) then sg2
   494   else if is_draft sg1 orelse is_draft sg2 then
   495     raise_term "Illegal merge of draft signatures" []
   496   else
   497     (*neither is union already; must form union*)
   498     let
   499       val Sg {tsig = tsig1, const_tab = const_tab1, syn = syn1,
   500         stamps = stamps1} = sg1;
   501       val Sg {tsig = tsig2, const_tab = const_tab2, syn = syn2,
   502         stamps = stamps2} = sg2;
   503 
   504 
   505       val stamps = merge_rev_lists stamps1 stamps2;
   506       val _ =
   507         (case duplicates (stamp_names stamps) of
   508           [] => ()
   509         | dups => raise_term ("Attempt to merge different versions of theories "
   510             ^ commas_quote dups) []);
   511 
   512       val tsig = merge_tsigs (tsig1, tsig2);
   513 
   514       val const_tab = Symtab.merge (op =) (const_tab1, const_tab2)
   515         handle Symtab.DUPS cs =>
   516           raise_term ("Incompatible types for constant(s) " ^ commas_quote cs) [];
   517 
   518       val syn = Syntax.merge_syntaxes syn1 syn2;
   519     in
   520       Sg {tsig = tsig, const_tab = const_tab, syn = syn, stamps = stamps}
   521     end;
   522 
   523 
   524 
   525 (** the Pure signature **)
   526 
   527 val proto_pure =
   528   make_sign (Syntax.pure_syn, tsig0, Symtab.null) [] "#"
   529   |> add_types
   530    (("fun", 2, NoSyn) ::
   531     ("prop", 0, NoSyn) ::
   532     ("itself", 1, NoSyn) ::
   533     Syntax.pure_types)
   534   |> add_classes [(logicC, [])]
   535   |> add_defsort logicS
   536   |> add_arities
   537    [("fun", [logicS, logicS], logicS),
   538     ("prop", [], logicS),
   539     ("itself", [logicS], logicS)]
   540   |> add_syntax Syntax.pure_syntax
   541   |> add_trfuns Syntax.pure_trfuns
   542   |> add_consts
   543    [("==", "['a::{}, 'a] => prop", Mixfix ("(_ ==/ _)", [3, 2], 2)),
   544     ("=?=", "['a::{}, 'a] => prop", Mixfix ("(_ =?=/ _)", [3, 2], 2)),
   545     ("==>", "[prop, prop] => prop", Mixfix ("(_ ==>/ _)", [2, 1], 1)),
   546     ("all", "('a => prop) => prop", Binder ("!!", 0, 0)),
   547     ("TYPE", "'a itself", NoSyn)]
   548   |> add_name "ProtoPure";
   549 
   550 val pure = proto_pure
   551   |> add_syntax
   552    [("_appl",     "[('b => 'a), args] => logic",    Mixfix ("(1_/(1'(_')))",
   553                                                     [max_pri, 0], max_pri)),
   554     ("_appl",     "[('b => 'a), args] => aprop",    Mixfix ("(1_/(1'(_')))",
   555                                                     [max_pri, 0], max_pri))]
   556   |> add_name "Pure";
   557 
   558 val cpure = proto_pure
   559   |> add_syntax
   560    [("_applC",     "[('b => 'a), 'c] => logic",     Mixfix ("(1_ (1_))",
   561                                                     [max_pri-1, max_pri],
   562                                                     max_pri-1)),
   563     ("_applC",     "[('b => 'a), 'c] => aprop",     Mixfix ("(1_ (1_))",
   564                                                     [max_pri-1, max_pri],
   565                                                     max_pri-1))]
   566   |> add_name "CPure";
   567 
   568 end;