src/HOL/Product_Type.thy
author nipkow
Tue Mar 22 12:49:07 2011 +0100 (2011-03-22)
changeset 42059 83f3dc509068
parent 41792 ff3cb0c418b7
child 42083 e1209fc7ecdc
permissions -rw-r--r--
fixed a printing problem for bounded quantifiers and bounded set operators in the case of tuples
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 uses
    11   ("Tools/split_rule.ML")
    12   ("Tools/inductive_codegen.ML")
    13   ("Tools/inductive_set.ML")
    14 begin
    15 
    16 subsection {* @{typ bool} is a datatype *}
    17 
    18 rep_datatype True False by (auto intro: bool_induct)
    19 
    20 declare case_split [cases type: bool]
    21   -- "prefer plain propositional version"
    22 
    23 lemma
    24   shows [code]: "HOL.equal False P \<longleftrightarrow> \<not> P"
    25     and [code]: "HOL.equal True P \<longleftrightarrow> P" 
    26     and [code]: "HOL.equal P False \<longleftrightarrow> \<not> P" 
    27     and [code]: "HOL.equal P True \<longleftrightarrow> P"
    28     and [code nbe]: "HOL.equal P P \<longleftrightarrow> True"
    29   by (simp_all add: equal)
    30 
    31 code_const "HOL.equal \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    32   (Haskell infix 4 "==")
    33 
    34 code_instance bool :: equal
    35   (Haskell -)
    36 
    37 
    38 subsection {* The @{text unit} type *}
    39 
    40 typedef (open) unit = "{True}"
    41 proof
    42   show "True : ?unit" ..
    43 qed
    44 
    45 definition
    46   Unity :: unit    ("'(')")
    47 where
    48   "() = Abs_unit True"
    49 
    50 lemma unit_eq [no_atp]: "u = ()"
    51   by (induct u) (simp add: Unity_def)
    52 
    53 text {*
    54   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    55   this rule directly --- it loops!
    56 *}
    57 
    58 ML {*
    59   val unit_eq_proc =
    60     let val unit_meta_eq = mk_meta_eq @{thm unit_eq} in
    61       Simplifier.simproc_global @{theory} "unit_eq" ["x::unit"]
    62       (fn _ => fn _ => fn t => if HOLogic.is_unit t then NONE else SOME unit_meta_eq)
    63     end;
    64 
    65   Addsimprocs [unit_eq_proc];
    66 *}
    67 
    68 rep_datatype "()" by simp
    69 
    70 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    71   by simp
    72 
    73 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    74   by (rule triv_forall_equality)
    75 
    76 text {*
    77   This rewrite counters the effect of @{text unit_eq_proc} on @{term
    78   [source] "%u::unit. f u"}, replacing it by @{term [source]
    79   f} rather than by @{term [source] "%u. f ()"}.
    80 *}
    81 
    82 lemma unit_abs_eta_conv [simp,no_atp]: "(%u::unit. f ()) = f"
    83   by (rule ext) simp
    84 
    85 instantiation unit :: default
    86 begin
    87 
    88 definition "default = ()"
    89 
    90 instance ..
    91 
    92 end
    93 
    94 lemma [code]:
    95   "HOL.equal (u\<Colon>unit) v \<longleftrightarrow> True" unfolding equal unit_eq [of u] unit_eq [of v] by rule+
    96 
    97 code_type unit
    98   (SML "unit")
    99   (OCaml "unit")
   100   (Haskell "()")
   101   (Scala "Unit")
   102 
   103 code_const Unity
   104   (SML "()")
   105   (OCaml "()")
   106   (Haskell "()")
   107   (Scala "()")
   108 
   109 code_instance unit :: equal
   110   (Haskell -)
   111 
   112 code_const "HOL.equal \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   113   (Haskell infix 4 "==")
   114 
   115 code_reserved SML
   116   unit
   117 
   118 code_reserved OCaml
   119   unit
   120 
   121 code_reserved Scala
   122   Unit
   123 
   124 
   125 subsection {* The product type *}
   126 
   127 subsubsection {* Type definition *}
   128 
   129 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   130   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   131 
   132 typedef ('a, 'b) prod (infixr "*" 20)
   133   = "{f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   134 proof
   135   fix a b show "Pair_Rep a b \<in> ?prod"
   136     by rule+
   137 qed
   138 
   139 type_notation (xsymbols)
   140   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   141 type_notation (HTML output)
   142   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   143 
   144 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   145   "Pair a b = Abs_prod (Pair_Rep a b)"
   146 
   147 rep_datatype Pair proof -
   148   fix P :: "'a \<times> 'b \<Rightarrow> bool" and p
   149   assume "\<And>a b. P (Pair a b)"
   150   then show "P p" by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   151 next
   152   fix a c :: 'a and b d :: 'b
   153   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   154     by (auto simp add: Pair_Rep_def fun_eq_iff)
   155   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   156     by (auto simp add: prod_def)
   157   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   158     by (simp add: Pair_def Abs_prod_inject)
   159 qed
   160 
   161 declare prod.simps(2) [nitpick_simp del]
   162 
   163 declare prod.weak_case_cong [cong del]
   164 
   165 
   166 subsubsection {* Tuple syntax *}
   167 
   168 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   169   "split \<equiv> prod_case"
   170 
   171 text {*
   172   Patterns -- extends pre-defined type @{typ pttrn} used in
   173   abstractions.
   174 *}
   175 
   176 nonterminal tuple_args and patterns
   177 
   178 syntax
   179   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   180   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   181   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   182   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   183   ""            :: "pttrn => patterns"                  ("_")
   184   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   185 
   186 translations
   187   "(x, y)" == "CONST Pair x y"
   188   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   189   "%(x, y, zs). b" == "CONST prod_case (%x (y, zs). b)"
   190   "%(x, y). b" == "CONST prod_case (%x y. b)"
   191   "_abs (CONST Pair x y) t" => "%(x, y). t"
   192   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   193      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   194 
   195 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   196   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   197 print_translation {*
   198 let
   199   fun split_tr' [Abs (x, T, t as (Abs abs))] =
   200         (* split (%x y. t) => %(x,y) t *)
   201         let
   202           val (y, t') = atomic_abs_tr' abs;
   203           val (x', t'') = atomic_abs_tr' (x, T, t');
   204         in
   205           Syntax.const @{syntax_const "_abs"} $
   206             (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   207         end
   208     | split_tr' [Abs (x, T, (s as Const (@{const_syntax prod_case}, _) $ t))] =
   209         (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   210         let
   211           val Const (@{syntax_const "_abs"}, _) $
   212             (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   213           val (x', t'') = atomic_abs_tr' (x, T, t');
   214         in
   215           Syntax.const @{syntax_const "_abs"} $
   216             (Syntax.const @{syntax_const "_pattern"} $ x' $
   217               (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   218         end
   219     | split_tr' [Const (@{const_syntax prod_case}, _) $ t] =
   220         (* split (split (%x y z. t)) => %((x, y), z). t *)
   221         split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   222     | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   223         (* split (%pttrn z. t) => %(pttrn,z). t *)
   224         let val (z, t) = atomic_abs_tr' abs in
   225           Syntax.const @{syntax_const "_abs"} $
   226             (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   227         end
   228     | split_tr' _ = raise Match;
   229 in [(@{const_syntax prod_case}, split_tr')] end
   230 *}
   231 
   232 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   233 typed_print_translation {*
   234 let
   235   fun split_guess_names_tr' _ T [Abs (x, _, Abs _)] = raise Match
   236     | split_guess_names_tr' _ T [Abs (x, xT, t)] =
   237         (case (head_of t) of
   238           Const (@{const_syntax prod_case}, _) => raise Match
   239         | _ =>
   240           let 
   241             val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   242             val (y, t') = atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   243             val (x', t'') = atomic_abs_tr' (x, xT, t');
   244           in
   245             Syntax.const @{syntax_const "_abs"} $
   246               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   247           end)
   248     | split_guess_names_tr' _ T [t] =
   249         (case head_of t of
   250           Const (@{const_syntax prod_case}, _) => raise Match
   251         | _ =>
   252           let
   253             val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   254             val (y, t') = atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   255             val (x', t'') = atomic_abs_tr' ("x", xT, t');
   256           in
   257             Syntax.const @{syntax_const "_abs"} $
   258               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   259           end)
   260     | split_guess_names_tr' _ _ _ = raise Match;
   261 in [(@{const_syntax prod_case}, split_guess_names_tr')] end
   262 *}
   263 
   264 (* Force eta-contraction for terms of the form "Q A (%p. prod_case P p)"
   265    where Q is some bounded quantifier or set operator.
   266    Reason: the above prints as "Q p : A. case p of (x,y) \<Rightarrow> P x y"
   267    whereas we want "Q (x,y):A. P x y".
   268    Otherwise prevent eta-contraction.
   269 *)
   270 print_translation {*
   271 let
   272   fun contract Q f ts =
   273     case ts of
   274       [A, Abs(_, _, (s as Const (@{const_syntax prod_case},_) $ t) $ Bound 0)]
   275       => if loose_bvar1 (t,0) then f ts else Syntax.const Q $ A $ s
   276     | _ => f ts;
   277   fun contract2 (Q,f) = (Q, contract Q f);
   278   val pairs =
   279     [Syntax.preserve_binder_abs2_tr' @{const_syntax Ball} @{syntax_const "_Ball"},
   280      Syntax.preserve_binder_abs2_tr' @{const_syntax Bex} @{syntax_const "_Bex"},
   281      Syntax.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   282      Syntax.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   283 in map contract2 pairs end
   284 *}
   285 
   286 subsubsection {* Code generator setup *}
   287 
   288 code_type prod
   289   (SML infix 2 "*")
   290   (OCaml infix 2 "*")
   291   (Haskell "!((_),/ (_))")
   292   (Scala "((_),/ (_))")
   293 
   294 code_const Pair
   295   (SML "!((_),/ (_))")
   296   (OCaml "!((_),/ (_))")
   297   (Haskell "!((_),/ (_))")
   298   (Scala "!((_),/ (_))")
   299 
   300 code_instance prod :: equal
   301   (Haskell -)
   302 
   303 code_const "HOL.equal \<Colon> 'a \<times> 'b \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
   304   (Haskell infix 4 "==")
   305 
   306 types_code
   307   "prod"     ("(_ */ _)")
   308 attach (term_of) {*
   309 fun term_of_prod aF aT bF bT (x, y) = HOLogic.pair_const aT bT $ aF x $ bF y;
   310 *}
   311 attach (test) {*
   312 fun gen_prod aG aT bG bT i =
   313   let
   314     val (x, t) = aG i;
   315     val (y, u) = bG i
   316   in ((x, y), fn () => HOLogic.pair_const aT bT $ t () $ u ()) end;
   317 *}
   318 
   319 consts_code
   320   "Pair"    ("(_,/ _)")
   321 
   322 setup {*
   323 let
   324 
   325 fun strip_abs_split 0 t = ([], t)
   326   | strip_abs_split i (Abs (s, T, t)) =
   327       let
   328         val s' = Codegen.new_name t s;
   329         val v = Free (s', T)
   330       in apfst (cons v) (strip_abs_split (i-1) (subst_bound (v, t))) end
   331   | strip_abs_split i (u as Const (@{const_name prod_case}, _) $ t) =
   332       (case strip_abs_split (i+1) t of
   333         (v :: v' :: vs, u) => (HOLogic.mk_prod (v, v') :: vs, u)
   334       | _ => ([], u))
   335   | strip_abs_split i t =
   336       strip_abs_split i (Abs ("x", hd (binder_types (fastype_of t)), t $ Bound 0));
   337 
   338 fun let_codegen thy defs dep thyname brack t gr =
   339   (case strip_comb t of
   340     (t1 as Const (@{const_name Let}, _), t2 :: t3 :: ts) =>
   341     let
   342       fun dest_let (l as Const (@{const_name Let}, _) $ t $ u) =
   343           (case strip_abs_split 1 u of
   344              ([p], u') => apfst (cons (p, t)) (dest_let u')
   345            | _ => ([], l))
   346         | dest_let t = ([], t);
   347       fun mk_code (l, r) gr =
   348         let
   349           val (pl, gr1) = Codegen.invoke_codegen thy defs dep thyname false l gr;
   350           val (pr, gr2) = Codegen.invoke_codegen thy defs dep thyname false r gr1;
   351         in ((pl, pr), gr2) end
   352     in case dest_let (t1 $ t2 $ t3) of
   353         ([], _) => NONE
   354       | (ps, u) =>
   355           let
   356             val (qs, gr1) = fold_map mk_code ps gr;
   357             val (pu, gr2) = Codegen.invoke_codegen thy defs dep thyname false u gr1;
   358             val (pargs, gr3) = fold_map
   359               (Codegen.invoke_codegen thy defs dep thyname true) ts gr2
   360           in
   361             SOME (Codegen.mk_app brack
   362               (Pretty.blk (0, [Codegen.str "let ", Pretty.blk (0, flat
   363                   (separate [Codegen.str ";", Pretty.brk 1] (map (fn (pl, pr) =>
   364                     [Pretty.block [Codegen.str "val ", pl, Codegen.str " =",
   365                        Pretty.brk 1, pr]]) qs))),
   366                 Pretty.brk 1, Codegen.str "in ", pu,
   367                 Pretty.brk 1, Codegen.str "end"])) pargs, gr3)
   368           end
   369     end
   370   | _ => NONE);
   371 
   372 fun split_codegen thy defs dep thyname brack t gr = (case strip_comb t of
   373     (t1 as Const (@{const_name prod_case}, _), t2 :: ts) =>
   374       let
   375         val ([p], u) = strip_abs_split 1 (t1 $ t2);
   376         val (q, gr1) = Codegen.invoke_codegen thy defs dep thyname false p gr;
   377         val (pu, gr2) = Codegen.invoke_codegen thy defs dep thyname false u gr1;
   378         val (pargs, gr3) = fold_map
   379           (Codegen.invoke_codegen thy defs dep thyname true) ts gr2
   380       in
   381         SOME (Codegen.mk_app brack
   382           (Pretty.block [Codegen.str "(fn ", q, Codegen.str " =>",
   383             Pretty.brk 1, pu, Codegen.str ")"]) pargs, gr2)
   384       end
   385   | _ => NONE);
   386 
   387 in
   388 
   389   Codegen.add_codegen "let_codegen" let_codegen
   390   #> Codegen.add_codegen "split_codegen" split_codegen
   391 
   392 end
   393 *}
   394 
   395 
   396 subsubsection {* Fundamental operations and properties *}
   397 
   398 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   399   by (cases p) simp
   400 
   401 definition fst :: "'a \<times> 'b \<Rightarrow> 'a" where
   402   "fst p = (case p of (a, b) \<Rightarrow> a)"
   403 
   404 definition snd :: "'a \<times> 'b \<Rightarrow> 'b" where
   405   "snd p = (case p of (a, b) \<Rightarrow> b)"
   406 
   407 lemma fst_conv [simp, code]: "fst (a, b) = a"
   408   unfolding fst_def by simp
   409 
   410 lemma snd_conv [simp, code]: "snd (a, b) = b"
   411   unfolding snd_def by simp
   412 
   413 code_const fst and snd
   414   (Haskell "fst" and "snd")
   415 
   416 lemma prod_case_unfold [nitpick_unfold]: "prod_case = (%c p. c (fst p) (snd p))"
   417   by (simp add: fun_eq_iff split: prod.split)
   418 
   419 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   420   by simp
   421 
   422 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   423   by simp
   424 
   425 lemma pair_collapse [simp]: "(fst p, snd p) = p"
   426   by (cases p) simp
   427 
   428 lemmas surjective_pairing = pair_collapse [symmetric]
   429 
   430 lemma Pair_fst_snd_eq: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   431   by (cases s, cases t) simp
   432 
   433 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   434   by (simp add: Pair_fst_snd_eq)
   435 
   436 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   437   by (fact prod.cases)
   438 
   439 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   440   by (rule split_conv [THEN iffD2])
   441 
   442 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   443   by (rule split_conv [THEN iffD1])
   444 
   445 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   446   by (simp add: fun_eq_iff split: prod.split)
   447 
   448 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   449   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   450   by (simp add: fun_eq_iff split: prod.split)
   451 
   452 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   453   by (cases x) simp
   454 
   455 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   456   by (cases p) simp
   457 
   458 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   459   by (simp add: prod_case_unfold)
   460 
   461 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   462   -- {* Prevents simplification of @{term c}: much faster *}
   463   by (fact prod.weak_case_cong)
   464 
   465 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   466   by (simp add: split_eta)
   467 
   468 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   469 proof
   470   fix a b
   471   assume "!!x. PROP P x"
   472   then show "PROP P (a, b)" .
   473 next
   474   fix x
   475   assume "!!a b. PROP P (a, b)"
   476   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   477 qed
   478 
   479 text {*
   480   The rule @{thm [source] split_paired_all} does not work with the
   481   Simplifier because it also affects premises in congrence rules,
   482   where this can lead to premises of the form @{text "!!a b. ... =
   483   ?P(a, b)"} which cannot be solved by reflexivity.
   484 *}
   485 
   486 lemmas split_tupled_all = split_paired_all unit_all_eq2
   487 
   488 ML {*
   489   (* replace parameters of product type by individual component parameters *)
   490   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   491   local (* filtering with exists_paired_all is an essential optimization *)
   492     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   493           can HOLogic.dest_prodT T orelse exists_paired_all t
   494       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   495       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   496       | exists_paired_all _ = false;
   497     val ss = HOL_basic_ss
   498       addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   499       addsimprocs [unit_eq_proc];
   500   in
   501     val split_all_tac = SUBGOAL (fn (t, i) =>
   502       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   503     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   504       if exists_paired_all t then full_simp_tac ss i else no_tac);
   505     fun split_all th =
   506    if exists_paired_all (Thm.prop_of th) then full_simplify ss th else th;
   507   end;
   508 *}
   509 
   510 declaration {* fn _ =>
   511   Classical.map_cs (fn cs => cs addSbefore ("split_all_tac", split_all_tac))
   512 *}
   513 
   514 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   515   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   516   by fast
   517 
   518 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   519   by fast
   520 
   521 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   522   -- {* Can't be added to simpset: loops! *}
   523   by (simp add: split_eta)
   524 
   525 text {*
   526   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   527   @{thm [source] split_eta} as a rewrite rule is not general enough,
   528   and using @{thm [source] cond_split_eta} directly would render some
   529   existing proofs very inefficient; similarly for @{text
   530   split_beta}.
   531 *}
   532 
   533 ML {*
   534 local
   535   val cond_split_eta_ss = HOL_basic_ss addsimps @{thms cond_split_eta};
   536   fun Pair_pat k 0 (Bound m) = (m = k)
   537     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   538         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   539     | Pair_pat _ _ _ = false;
   540   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   541     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   542     | no_args k i (Bound m) = m < k orelse m > k + i
   543     | no_args _ _ _ = true;
   544   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   545     | split_pat tp i (Const (@{const_name prod_case}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   546     | split_pat tp i _ = NONE;
   547   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   548         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   549         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   550 
   551   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   552     | beta_term_pat k i (t $ u) =
   553         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   554     | beta_term_pat k i t = no_args k i t;
   555   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   556     | eta_term_pat _ _ _ = false;
   557   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   558     | subst arg k i (t $ u) =
   559         if Pair_pat k i (t $ u) then incr_boundvars k arg
   560         else (subst arg k i t $ subst arg k i u)
   561     | subst arg k i t = t;
   562   fun beta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t) $ arg) =
   563         (case split_pat beta_term_pat 1 t of
   564           SOME (i, f) => SOME (metaeq ss s (subst arg 0 i f))
   565         | NONE => NONE)
   566     | beta_proc _ _ = NONE;
   567   fun eta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t)) =
   568         (case split_pat eta_term_pat 1 t of
   569           SOME (_, ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   570         | NONE => NONE)
   571     | eta_proc _ _ = NONE;
   572 in
   573   val split_beta_proc = Simplifier.simproc_global @{theory} "split_beta" ["split f z"] (K beta_proc);
   574   val split_eta_proc = Simplifier.simproc_global @{theory} "split_eta" ["split f"] (K eta_proc);
   575 end;
   576 
   577 Addsimprocs [split_beta_proc, split_eta_proc];
   578 *}
   579 
   580 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   581   by (subst surjective_pairing, rule split_conv)
   582 
   583 lemma split_split [no_atp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   584   -- {* For use with @{text split} and the Simplifier. *}
   585   by (insert surj_pair [of p], clarify, simp)
   586 
   587 text {*
   588   @{thm [source] split_split} could be declared as @{text "[split]"}
   589   done after the Splitter has been speeded up significantly;
   590   precompute the constants involved and don't do anything unless the
   591   current goal contains one of those constants.
   592 *}
   593 
   594 lemma split_split_asm [no_atp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   595 by (subst split_split, simp)
   596 
   597 text {*
   598   \medskip @{term split} used as a logical connective or set former.
   599 
   600   \medskip These rules are for use with @{text blast}; could instead
   601   call @{text simp} using @{thm [source] prod.split} as rewrite. *}
   602 
   603 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   604   apply (simp only: split_tupled_all)
   605   apply (simp (no_asm_simp))
   606   done
   607 
   608 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   609   apply (simp only: split_tupled_all)
   610   apply (simp (no_asm_simp))
   611   done
   612 
   613 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   614   by (induct p) auto
   615 
   616 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   617   by (induct p) auto
   618 
   619 lemma splitE2:
   620   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   621 proof -
   622   assume q: "Q (split P z)"
   623   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   624   show R
   625     apply (rule r surjective_pairing)+
   626     apply (rule split_beta [THEN subst], rule q)
   627     done
   628 qed
   629 
   630 lemma splitD': "split R (a,b) c ==> R a b c"
   631   by simp
   632 
   633 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   634   by simp
   635 
   636 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   637 by (simp only: split_tupled_all, simp)
   638 
   639 lemma mem_splitE:
   640   assumes major: "z \<in> split c p"
   641     and cases: "\<And>x y. p = (x, y) \<Longrightarrow> z \<in> c x y \<Longrightarrow> Q"
   642   shows Q
   643   by (rule major [unfolded prod_case_unfold] cases surjective_pairing)+
   644 
   645 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   646 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   647 
   648 ML {*
   649 local (* filtering with exists_p_split is an essential optimization *)
   650   fun exists_p_split (Const (@{const_name prod_case},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   651     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   652     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   653     | exists_p_split _ = false;
   654   val ss = HOL_basic_ss addsimps @{thms split_conv};
   655 in
   656 val split_conv_tac = SUBGOAL (fn (t, i) =>
   657     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   658 end;
   659 *}
   660 
   661 (* This prevents applications of splitE for already splitted arguments leading
   662    to quite time-consuming computations (in particular for nested tuples) *)
   663 declaration {* fn _ =>
   664   Classical.map_cs (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac))
   665 *}
   666 
   667 lemma split_eta_SetCompr [simp,no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   668   by (rule ext) fast
   669 
   670 lemma split_eta_SetCompr2 [simp,no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   671   by (rule ext) fast
   672 
   673 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   674   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   675   by (rule ext) blast
   676 
   677 (* Do NOT make this a simp rule as it
   678    a) only helps in special situations
   679    b) can lead to nontermination in the presence of split_def
   680 *)
   681 lemma split_comp_eq: 
   682   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   683   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   684   by (rule ext) auto
   685 
   686 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   687   apply (rule_tac x = "(a, b)" in image_eqI)
   688    apply auto
   689   done
   690 
   691 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   692   by blast
   693 
   694 (*
   695 the following  would be slightly more general,
   696 but cannot be used as rewrite rule:
   697 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   698 ### ?y = .x
   699 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   700 by (rtac some_equality 1)
   701 by ( Simp_tac 1)
   702 by (split_all_tac 1)
   703 by (Asm_full_simp_tac 1)
   704 qed "The_split_eq";
   705 *)
   706 
   707 text {*
   708   Setup of internal @{text split_rule}.
   709 *}
   710 
   711 lemmas prod_caseI = prod.cases [THEN iffD2, standard]
   712 
   713 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   714   by (fact splitI2)
   715 
   716 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   717   by (fact splitI2')
   718 
   719 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   720   by (fact splitE)
   721 
   722 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   723   by (fact splitE')
   724 
   725 declare prod_caseI [intro!]
   726 
   727 lemma prod_case_beta:
   728   "prod_case f p = f (fst p) (snd p)"
   729   by (fact split_beta)
   730 
   731 lemma prod_cases3 [cases type]:
   732   obtains (fields) a b c where "y = (a, b, c)"
   733   by (cases y, case_tac b) blast
   734 
   735 lemma prod_induct3 [case_names fields, induct type]:
   736     "(!!a b c. P (a, b, c)) ==> P x"
   737   by (cases x) blast
   738 
   739 lemma prod_cases4 [cases type]:
   740   obtains (fields) a b c d where "y = (a, b, c, d)"
   741   by (cases y, case_tac c) blast
   742 
   743 lemma prod_induct4 [case_names fields, induct type]:
   744     "(!!a b c d. P (a, b, c, d)) ==> P x"
   745   by (cases x) blast
   746 
   747 lemma prod_cases5 [cases type]:
   748   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   749   by (cases y, case_tac d) blast
   750 
   751 lemma prod_induct5 [case_names fields, induct type]:
   752     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   753   by (cases x) blast
   754 
   755 lemma prod_cases6 [cases type]:
   756   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   757   by (cases y, case_tac e) blast
   758 
   759 lemma prod_induct6 [case_names fields, induct type]:
   760     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   761   by (cases x) blast
   762 
   763 lemma prod_cases7 [cases type]:
   764   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   765   by (cases y, case_tac f) blast
   766 
   767 lemma prod_induct7 [case_names fields, induct type]:
   768     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   769   by (cases x) blast
   770 
   771 lemma split_def:
   772   "split = (\<lambda>c p. c (fst p) (snd p))"
   773   by (fact prod_case_unfold)
   774 
   775 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   776   "internal_split == split"
   777 
   778 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   779   by (simp only: internal_split_def split_conv)
   780 
   781 use "Tools/split_rule.ML"
   782 setup Split_Rule.setup
   783 
   784 hide_const internal_split
   785 
   786 
   787 subsubsection {* Derived operations *}
   788 
   789 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   790   "curry = (\<lambda>c x y. c (x, y))"
   791 
   792 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   793   by (simp add: curry_def)
   794 
   795 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   796   by (simp add: curry_def)
   797 
   798 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   799   by (simp add: curry_def)
   800 
   801 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   802   by (simp add: curry_def)
   803 
   804 lemma curry_split [simp]: "curry (split f) = f"
   805   by (simp add: curry_def split_def)
   806 
   807 lemma split_curry [simp]: "split (curry f) = f"
   808   by (simp add: curry_def split_def)
   809 
   810 text {*
   811   The composition-uncurry combinator.
   812 *}
   813 
   814 notation fcomp (infixl "\<circ>>" 60)
   815 
   816 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "\<circ>\<rightarrow>" 60) where
   817   "f \<circ>\<rightarrow> g = (\<lambda>x. prod_case g (f x))"
   818 
   819 lemma scomp_unfold: "scomp = (\<lambda>f g x. g (fst (f x)) (snd (f x)))"
   820   by (simp add: fun_eq_iff scomp_def prod_case_unfold)
   821 
   822 lemma scomp_apply [simp]: "(f \<circ>\<rightarrow> g) x = prod_case g (f x)"
   823   by (simp add: scomp_unfold prod_case_unfold)
   824 
   825 lemma Pair_scomp: "Pair x \<circ>\<rightarrow> f = f x"
   826   by (simp add: fun_eq_iff scomp_apply)
   827 
   828 lemma scomp_Pair: "x \<circ>\<rightarrow> Pair = x"
   829   by (simp add: fun_eq_iff scomp_apply)
   830 
   831 lemma scomp_scomp: "(f \<circ>\<rightarrow> g) \<circ>\<rightarrow> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>\<rightarrow> h)"
   832   by (simp add: fun_eq_iff scomp_unfold)
   833 
   834 lemma scomp_fcomp: "(f \<circ>\<rightarrow> g) \<circ>> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>> h)"
   835   by (simp add: fun_eq_iff scomp_unfold fcomp_def)
   836 
   837 lemma fcomp_scomp: "(f \<circ>> g) \<circ>\<rightarrow> h = f \<circ>> (g \<circ>\<rightarrow> h)"
   838   by (simp add: fun_eq_iff scomp_unfold fcomp_apply)
   839 
   840 code_const scomp
   841   (Eval infixl 3 "#->")
   842 
   843 no_notation fcomp (infixl "\<circ>>" 60)
   844 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   845 
   846 text {*
   847   @{term map_pair} --- action of the product functor upon
   848   functions.
   849 *}
   850 
   851 definition map_pair :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   852   "map_pair f g = (\<lambda>(x, y). (f x, g y))"
   853 
   854 lemma map_pair_simp [simp, code]:
   855   "map_pair f g (a, b) = (f a, g b)"
   856   by (simp add: map_pair_def)
   857 
   858 enriched_type map_pair: map_pair
   859   by (auto simp add: split_paired_all intro: ext)
   860 
   861 lemma fst_map_pair [simp]:
   862   "fst (map_pair f g x) = f (fst x)"
   863   by (cases x) simp_all
   864 
   865 lemma snd_prod_fun [simp]:
   866   "snd (map_pair f g x) = g (snd x)"
   867   by (cases x) simp_all
   868 
   869 lemma fst_comp_map_pair [simp]:
   870   "fst \<circ> map_pair f g = f \<circ> fst"
   871   by (rule ext) simp_all
   872 
   873 lemma snd_comp_map_pair [simp]:
   874   "snd \<circ> map_pair f g = g \<circ> snd"
   875   by (rule ext) simp_all
   876 
   877 lemma map_pair_compose:
   878   "map_pair (f1 o f2) (g1 o g2) = (map_pair f1 g1 o map_pair f2 g2)"
   879   by (rule ext) (simp add: map_pair.compositionality comp_def)
   880 
   881 lemma map_pair_ident [simp]:
   882   "map_pair (%x. x) (%y. y) = (%z. z)"
   883   by (rule ext) (simp add: map_pair.identity)
   884 
   885 lemma map_pair_imageI [intro]:
   886   "(a, b) \<in> R \<Longrightarrow> (f a, g b) \<in> map_pair f g ` R"
   887   by (rule image_eqI) simp_all
   888 
   889 lemma prod_fun_imageE [elim!]:
   890   assumes major: "c \<in> map_pair f g ` R"
   891     and cases: "\<And>x y. c = (f x, g y) \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> P"
   892   shows P
   893   apply (rule major [THEN imageE])
   894   apply (case_tac x)
   895   apply (rule cases)
   896   apply simp_all
   897   done
   898 
   899 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   900   "apfst f = map_pair f id"
   901 
   902 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   903   "apsnd f = map_pair id f"
   904 
   905 lemma apfst_conv [simp, code]:
   906   "apfst f (x, y) = (f x, y)" 
   907   by (simp add: apfst_def)
   908 
   909 lemma apsnd_conv [simp, code]:
   910   "apsnd f (x, y) = (x, f y)" 
   911   by (simp add: apsnd_def)
   912 
   913 lemma fst_apfst [simp]:
   914   "fst (apfst f x) = f (fst x)"
   915   by (cases x) simp
   916 
   917 lemma fst_apsnd [simp]:
   918   "fst (apsnd f x) = fst x"
   919   by (cases x) simp
   920 
   921 lemma snd_apfst [simp]:
   922   "snd (apfst f x) = snd x"
   923   by (cases x) simp
   924 
   925 lemma snd_apsnd [simp]:
   926   "snd (apsnd f x) = f (snd x)"
   927   by (cases x) simp
   928 
   929 lemma apfst_compose:
   930   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   931   by (cases x) simp
   932 
   933 lemma apsnd_compose:
   934   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   935   by (cases x) simp
   936 
   937 lemma apfst_apsnd [simp]:
   938   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   939   by (cases x) simp
   940 
   941 lemma apsnd_apfst [simp]:
   942   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   943   by (cases x) simp
   944 
   945 lemma apfst_id [simp] :
   946   "apfst id = id"
   947   by (simp add: fun_eq_iff)
   948 
   949 lemma apsnd_id [simp] :
   950   "apsnd id = id"
   951   by (simp add: fun_eq_iff)
   952 
   953 lemma apfst_eq_conv [simp]:
   954   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   955   by (cases x) simp
   956 
   957 lemma apsnd_eq_conv [simp]:
   958   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   959   by (cases x) simp
   960 
   961 lemma apsnd_apfst_commute:
   962   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   963   by simp
   964 
   965 text {*
   966   Disjoint union of a family of sets -- Sigma.
   967 *}
   968 
   969 definition Sigma :: "['a set, 'a => 'b set] => ('a \<times> 'b) set" where
   970   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   971 
   972 abbreviation
   973   Times :: "['a set, 'b set] => ('a * 'b) set"
   974     (infixr "<*>" 80) where
   975   "A <*> B == Sigma A (%_. B)"
   976 
   977 notation (xsymbols)
   978   Times  (infixr "\<times>" 80)
   979 
   980 notation (HTML output)
   981   Times  (infixr "\<times>" 80)
   982 
   983 syntax
   984   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   985 translations
   986   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
   987 
   988 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   989   by (unfold Sigma_def) blast
   990 
   991 lemma SigmaE [elim!]:
   992     "[| c: Sigma A B;
   993         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   994      |] ==> P"
   995   -- {* The general elimination rule. *}
   996   by (unfold Sigma_def) blast
   997 
   998 text {*
   999   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
  1000   eigenvariables.
  1001 *}
  1002 
  1003 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
  1004   by blast
  1005 
  1006 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
  1007   by blast
  1008 
  1009 lemma SigmaE2:
  1010     "[| (a, b) : Sigma A B;
  1011         [| a:A;  b:B(a) |] ==> P
  1012      |] ==> P"
  1013   by blast
  1014 
  1015 lemma Sigma_cong:
  1016      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
  1017       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
  1018   by auto
  1019 
  1020 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
  1021   by blast
  1022 
  1023 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
  1024   by blast
  1025 
  1026 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
  1027   by blast
  1028 
  1029 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
  1030   by auto
  1031 
  1032 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
  1033   by auto
  1034 
  1035 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
  1036   by auto
  1037 
  1038 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
  1039   by blast
  1040 
  1041 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
  1042   by blast
  1043 
  1044 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
  1045   by (blast elim: equalityE)
  1046 
  1047 lemma SetCompr_Sigma_eq:
  1048     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
  1049   by blast
  1050 
  1051 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
  1052   by blast
  1053 
  1054 lemma UN_Times_distrib:
  1055   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
  1056   -- {* Suggested by Pierre Chartier *}
  1057   by blast
  1058 
  1059 lemma split_paired_Ball_Sigma [simp,no_atp]:
  1060     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
  1061   by blast
  1062 
  1063 lemma split_paired_Bex_Sigma [simp,no_atp]:
  1064     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
  1065   by blast
  1066 
  1067 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
  1068   by blast
  1069 
  1070 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
  1071   by blast
  1072 
  1073 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
  1074   by blast
  1075 
  1076 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
  1077   by blast
  1078 
  1079 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
  1080   by blast
  1081 
  1082 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
  1083   by blast
  1084 
  1085 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
  1086   by blast
  1087 
  1088 text {*
  1089   Non-dependent versions are needed to avoid the need for higher-order
  1090   matching, especially when the rules are re-oriented.
  1091 *}
  1092 
  1093 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1094 by blast
  1095 
  1096 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1097 by blast
  1098 
  1099 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1100 by blast
  1101 
  1102 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1103   by auto
  1104 
  1105 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1106   by (auto intro!: image_eqI)
  1107 
  1108 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1109   by (auto intro!: image_eqI)
  1110 
  1111 lemma insert_times_insert[simp]:
  1112   "insert a A \<times> insert b B =
  1113    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1114 by blast
  1115 
  1116 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1117   by (auto, case_tac "f x", auto)
  1118 
  1119 lemma swap_inj_on:
  1120   "inj_on (\<lambda>(i, j). (j, i)) A"
  1121   by (auto intro!: inj_onI)
  1122 
  1123 lemma swap_product:
  1124   "(%(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1125   by (simp add: split_def image_def) blast
  1126 
  1127 lemma image_split_eq_Sigma:
  1128   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1129 proof (safe intro!: imageI vimageI)
  1130   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1131   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1132     using * eq[symmetric] by auto
  1133 qed simp_all
  1134 
  1135 text {* The following @{const map_pair} lemmas are due to Joachim Breitner: *}
  1136 
  1137 lemma map_pair_inj_on:
  1138   assumes "inj_on f A" and "inj_on g B"
  1139   shows "inj_on (map_pair f g) (A \<times> B)"
  1140 proof (rule inj_onI)
  1141   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1142   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1143   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1144   assume "map_pair f g x = map_pair f g y"
  1145   hence "fst (map_pair f g x) = fst (map_pair f g y)" by (auto)
  1146   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1147   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1148   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1149   moreover from `map_pair f g x = map_pair f g y`
  1150   have "snd (map_pair f g x) = snd (map_pair f g y)" by (auto)
  1151   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1152   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1153   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1154   ultimately show "x = y" by(rule prod_eqI)
  1155 qed
  1156 
  1157 lemma map_pair_surj:
  1158   fixes f :: "'a \<Rightarrow> 'b" and g :: "'c \<Rightarrow> 'd"
  1159   assumes "surj f" and "surj g"
  1160   shows "surj (map_pair f g)"
  1161 unfolding surj_def
  1162 proof
  1163   fix y :: "'b \<times> 'd"
  1164   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1165   moreover
  1166   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1167   ultimately have "(fst y, snd y) = map_pair f g (a,b)" by auto
  1168   thus "\<exists>x. y = map_pair f g x" by auto
  1169 qed
  1170 
  1171 lemma map_pair_surj_on:
  1172   assumes "f ` A = A'" and "g ` B = B'"
  1173   shows "map_pair f g ` (A \<times> B) = A' \<times> B'"
  1174 unfolding image_def
  1175 proof(rule set_eqI,rule iffI)
  1176   fix x :: "'a \<times> 'c"
  1177   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = map_pair f g x}"
  1178   then obtain y where "y \<in> A \<times> B" and "x = map_pair f g y" by blast
  1179   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1180   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1181   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1182   with `x = map_pair f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1183 next
  1184   fix x :: "'a \<times> 'c"
  1185   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1186   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1187   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1188   moreover from `image g B = B'` and `snd x \<in> B'`
  1189   obtain b where "b \<in> B" and "snd x = g b" by auto
  1190   ultimately have "(fst x, snd x) = map_pair f g (a,b)" by auto
  1191   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1192   ultimately have "\<exists>y \<in> A \<times> B. x = map_pair f g y" by auto
  1193   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = map_pair f g y}" by auto
  1194 qed
  1195 
  1196 
  1197 subsection {* Inductively defined sets *}
  1198 
  1199 use "Tools/inductive_codegen.ML"
  1200 setup Inductive_Codegen.setup
  1201 
  1202 use "Tools/inductive_set.ML"
  1203 setup Inductive_Set.setup
  1204 
  1205 
  1206 subsection {* Legacy theorem bindings and duplicates *}
  1207 
  1208 lemma PairE:
  1209   obtains x y where "p = (x, y)"
  1210   by (fact prod.exhaust)
  1211 
  1212 lemma Pair_inject:
  1213   assumes "(a, b) = (a', b')"
  1214     and "a = a' ==> b = b' ==> R"
  1215   shows R
  1216   using assms by simp
  1217 
  1218 lemmas Pair_eq = prod.inject
  1219 
  1220 lemmas split = split_conv  -- {* for backwards compatibility *}
  1221 
  1222 end