src/HOL/Tools/Meson/meson_clausify.ML
author blanchet
Fri Oct 29 12:49:05 2010 +0200 (2010-10-29)
changeset 40262 8403085384eb
parent 40261 7a02144874f3
child 40263 51ed7a5ad4c5
permissions -rw-r--r--
ensure that MESON correctly preserves the name of variables (needed by the new Skolemizer)
     1 (*  Title:      HOL/Tools/Meson/meson_clausify.ML
     2     Author:     Jia Meng, Cambridge University Computer Laboratory and NICTA
     3     Author:     Jasmin Blanchette, TU Muenchen
     4 
     5 Transformation of HOL theorems into CNF forms.
     6 *)
     7 
     8 signature MESON_CLAUSIFY =
     9 sig
    10   val new_skolem_var_prefix : string
    11   val extensionalize_theorem : thm -> thm
    12   val introduce_combinators_in_cterm : cterm -> thm
    13   val introduce_combinators_in_theorem : thm -> thm
    14   val to_definitional_cnf_with_quantifiers : theory -> thm -> thm
    15   val cluster_of_zapped_var_name : string -> (int * (int * int)) * bool
    16   val cnf_axiom :
    17     Proof.context -> bool -> int -> thm -> (thm * term) option * thm list
    18 end;
    19 
    20 structure Meson_Clausify : MESON_CLAUSIFY =
    21 struct
    22 
    23 open Meson
    24 
    25 (* the extra "?" helps prevent clashes *)
    26 val new_skolem_var_prefix = "?SK"
    27 val new_nonskolem_var_prefix = "?V"
    28 
    29 (**** Transformation of Elimination Rules into First-Order Formulas****)
    30 
    31 val cfalse = cterm_of @{theory HOL} HOLogic.false_const;
    32 val ctp_false = cterm_of @{theory HOL} (HOLogic.mk_Trueprop HOLogic.false_const);
    33 
    34 (* Converts an elim-rule into an equivalent theorem that does not have the
    35    predicate variable. Leaves other theorems unchanged. We simply instantiate
    36    the conclusion variable to False. (Cf. "transform_elim_term" in
    37    "Sledgehammer_Util".) *)
    38 fun transform_elim_theorem th =
    39   case concl_of th of    (*conclusion variable*)
    40        @{const Trueprop} $ (v as Var (_, @{typ bool})) =>
    41            Thm.instantiate ([], [(cterm_of @{theory HOL} v, cfalse)]) th
    42     | v as Var(_, @{typ prop}) =>
    43            Thm.instantiate ([], [(cterm_of @{theory HOL} v, ctp_false)]) th
    44     | _ => th
    45 
    46 
    47 (**** SKOLEMIZATION BY INFERENCE (lcp) ****)
    48 
    49 fun mk_old_skolem_term_wrapper t =
    50   let val T = fastype_of t in
    51     Const (@{const_name Meson.skolem}, T --> T) $ t
    52   end
    53 
    54 fun beta_eta_in_abs_body (Abs (s, T, t')) = Abs (s, T, beta_eta_in_abs_body t')
    55   | beta_eta_in_abs_body t = Envir.beta_eta_contract t
    56 
    57 (*Traverse a theorem, accumulating Skolem function definitions.*)
    58 fun old_skolem_defs th =
    59   let
    60     fun dec_sko (Const (@{const_name Ex}, _) $ (body as Abs (_, T, p))) rhss =
    61         (*Existential: declare a Skolem function, then insert into body and continue*)
    62         let
    63           val args = OldTerm.term_frees body
    64           (* Forms a lambda-abstraction over the formal parameters *)
    65           val rhs =
    66             list_abs_free (map dest_Free args,
    67                            HOLogic.choice_const T $ beta_eta_in_abs_body body)
    68             |> mk_old_skolem_term_wrapper
    69           val comb = list_comb (rhs, args)
    70         in dec_sko (subst_bound (comb, p)) (rhs :: rhss) end
    71       | dec_sko (Const (@{const_name All},_) $ Abs (a, T, p)) rhss =
    72         (*Universal quant: insert a free variable into body and continue*)
    73         let val fname = Name.variant (OldTerm.add_term_names (p,[])) a
    74         in dec_sko (subst_bound (Free(fname,T), p)) rhss end
    75       | dec_sko (@{const conj} $ p $ q) rhss = rhss |> dec_sko p |> dec_sko q
    76       | dec_sko (@{const disj} $ p $ q) rhss = rhss |> dec_sko p |> dec_sko q
    77       | dec_sko (@{const Trueprop} $ p) rhss = dec_sko p rhss
    78       | dec_sko _ rhss = rhss
    79   in  dec_sko (prop_of th) []  end;
    80 
    81 
    82 (**** REPLACING ABSTRACTIONS BY COMBINATORS ****)
    83 
    84 val fun_cong_all = @{thm fun_eq_iff [THEN iffD1]}
    85 
    86 (* Removes the lambdas from an equation of the form "t = (%x. u)".
    87    (Cf. "extensionalize_term" in "Sledgehammer_Translate".) *)
    88 fun extensionalize_theorem th =
    89   case prop_of th of
    90     _ $ (Const (@{const_name HOL.eq}, Type (_, [Type (@{type_name fun}, _), _]))
    91          $ _ $ Abs _) => extensionalize_theorem (th RS fun_cong_all)
    92   | _ => th
    93 
    94 fun is_quasi_lambda_free (Const (@{const_name Meson.skolem}, _) $ _) = true
    95   | is_quasi_lambda_free (t1 $ t2) =
    96     is_quasi_lambda_free t1 andalso is_quasi_lambda_free t2
    97   | is_quasi_lambda_free (Abs _) = false
    98   | is_quasi_lambda_free _ = true
    99 
   100 val [f_B,g_B] = map (cterm_of @{theory}) (OldTerm.term_vars (prop_of @{thm abs_B}));
   101 val [g_C,f_C] = map (cterm_of @{theory}) (OldTerm.term_vars (prop_of @{thm abs_C}));
   102 val [f_S,g_S] = map (cterm_of @{theory}) (OldTerm.term_vars (prop_of @{thm abs_S}));
   103 
   104 (* FIXME: Requires more use of cterm constructors. *)
   105 fun abstract ct =
   106   let
   107       val thy = theory_of_cterm ct
   108       val Abs(x,_,body) = term_of ct
   109       val Type(@{type_name fun}, [xT,bodyT]) = typ_of (ctyp_of_term ct)
   110       val cxT = ctyp_of thy xT
   111       val cbodyT = ctyp_of thy bodyT
   112       fun makeK () =
   113         instantiate' [SOME cxT, SOME cbodyT] [SOME (cterm_of thy body)]
   114                      @{thm abs_K}
   115   in
   116       case body of
   117           Const _ => makeK()
   118         | Free _ => makeK()
   119         | Var _ => makeK()  (*though Var isn't expected*)
   120         | Bound 0 => instantiate' [SOME cxT] [] @{thm abs_I} (*identity: I*)
   121         | rator$rand =>
   122             if loose_bvar1 (rator,0) then (*C or S*)
   123                if loose_bvar1 (rand,0) then (*S*)
   124                  let val crator = cterm_of thy (Abs(x,xT,rator))
   125                      val crand = cterm_of thy (Abs(x,xT,rand))
   126                      val abs_S' = cterm_instantiate [(f_S,crator),(g_S,crand)] @{thm abs_S}
   127                      val (_,rhs) = Thm.dest_equals (cprop_of abs_S')
   128                  in
   129                    Thm.transitive abs_S' (Conv.binop_conv abstract rhs)
   130                  end
   131                else (*C*)
   132                  let val crator = cterm_of thy (Abs(x,xT,rator))
   133                      val abs_C' = cterm_instantiate [(f_C,crator),(g_C,cterm_of thy rand)] @{thm abs_C}
   134                      val (_,rhs) = Thm.dest_equals (cprop_of abs_C')
   135                  in
   136                    Thm.transitive abs_C' (Conv.fun_conv (Conv.arg_conv abstract) rhs)
   137                  end
   138             else if loose_bvar1 (rand,0) then (*B or eta*)
   139                if rand = Bound 0 then Thm.eta_conversion ct
   140                else (*B*)
   141                  let val crand = cterm_of thy (Abs(x,xT,rand))
   142                      val crator = cterm_of thy rator
   143                      val abs_B' = cterm_instantiate [(f_B,crator),(g_B,crand)] @{thm abs_B}
   144                      val (_,rhs) = Thm.dest_equals (cprop_of abs_B')
   145                  in Thm.transitive abs_B' (Conv.arg_conv abstract rhs) end
   146             else makeK()
   147         | _ => raise Fail "abstract: Bad term"
   148   end;
   149 
   150 (* Traverse a theorem, remplacing lambda-abstractions with combinators. *)
   151 fun introduce_combinators_in_cterm ct =
   152   if is_quasi_lambda_free (term_of ct) then
   153     Thm.reflexive ct
   154   else case term_of ct of
   155     Abs _ =>
   156     let
   157       val (cv, cta) = Thm.dest_abs NONE ct
   158       val (v, _) = dest_Free (term_of cv)
   159       val u_th = introduce_combinators_in_cterm cta
   160       val cu = Thm.rhs_of u_th
   161       val comb_eq = abstract (Thm.cabs cv cu)
   162     in Thm.transitive (Thm.abstract_rule v cv u_th) comb_eq end
   163   | _ $ _ =>
   164     let val (ct1, ct2) = Thm.dest_comb ct in
   165         Thm.combination (introduce_combinators_in_cterm ct1)
   166                         (introduce_combinators_in_cterm ct2)
   167     end
   168 
   169 fun introduce_combinators_in_theorem th =
   170   if is_quasi_lambda_free (prop_of th) then
   171     th
   172   else
   173     let
   174       val th = Drule.eta_contraction_rule th
   175       val eqth = introduce_combinators_in_cterm (cprop_of th)
   176     in Thm.equal_elim eqth th end
   177     handle THM (msg, _, _) =>
   178            (warning ("Error in the combinator translation of " ^
   179                      Display.string_of_thm_without_context th ^
   180                      "\nException message: " ^ msg ^ ".");
   181             (* A type variable of sort "{}" will make abstraction fail. *)
   182             TrueI)
   183 
   184 (*cterms are used throughout for efficiency*)
   185 val cTrueprop = cterm_of @{theory HOL} HOLogic.Trueprop;
   186 
   187 (*Given an abstraction over n variables, replace the bound variables by free
   188   ones. Return the body, along with the list of free variables.*)
   189 fun c_variant_abs_multi (ct0, vars) =
   190       let val (cv,ct) = Thm.dest_abs NONE ct0
   191       in  c_variant_abs_multi (ct, cv::vars)  end
   192       handle CTERM _ => (ct0, rev vars);
   193 
   194 val skolem_def_raw = @{thms skolem_def_raw}
   195 
   196 (* Given the definition of a Skolem function, return a theorem to replace
   197    an existential formula by a use of that function.
   198    Example: "EX x. x : A & x ~: B ==> sko A B : A & sko A B ~: B"  [.] *)
   199 fun old_skolem_theorem_from_def thy rhs0 =
   200   let
   201     val rhs = rhs0 |> Type.legacy_freeze_thaw |> #1 |> cterm_of thy
   202     val rhs' = rhs |> Thm.dest_comb |> snd
   203     val (ch, frees) = c_variant_abs_multi (rhs', [])
   204     val (hilbert, cabs) = ch |> Thm.dest_comb |>> term_of
   205     val T =
   206       case hilbert of
   207         Const (_, Type (@{type_name fun}, [_, T])) => T
   208       | _ => raise TERM ("old_skolem_theorem_from_def: expected \"Eps\"",
   209                          [hilbert])
   210     val cex = cterm_of thy (HOLogic.exists_const T)
   211     val ex_tm = Thm.capply cTrueprop (Thm.capply cex cabs)
   212     val conc =
   213       Drule.list_comb (rhs, frees)
   214       |> Drule.beta_conv cabs |> Thm.capply cTrueprop
   215     fun tacf [prem] =
   216       rewrite_goals_tac skolem_def_raw
   217       THEN rtac ((prem |> rewrite_rule skolem_def_raw)
   218                  RS Global_Theory.get_thm thy "Hilbert_Choice.someI_ex") 1
   219   in
   220     Goal.prove_internal [ex_tm] conc tacf
   221     |> forall_intr_list frees
   222     |> Thm.forall_elim_vars 0  (*Introduce Vars, but don't discharge defs.*)
   223     |> Thm.varifyT_global
   224   end
   225 
   226 fun to_definitional_cnf_with_quantifiers thy th =
   227   let
   228     val eqth = cnf.make_cnfx_thm thy (HOLogic.dest_Trueprop (prop_of th))
   229     val eqth = eqth RS @{thm eq_reflection}
   230     val eqth = eqth RS @{thm TruepropI}
   231   in Thm.equal_elim eqth th end
   232 
   233 fun zapped_var_name ((ax_no, cluster_no), skolem) index_no s =
   234   (if skolem then new_skolem_var_prefix else new_nonskolem_var_prefix) ^
   235   "_" ^ string_of_int ax_no ^ "_" ^ string_of_int cluster_no ^ "_" ^
   236   string_of_int index_no ^ "_" ^ Name.desymbolize false s
   237 
   238 fun cluster_of_zapped_var_name s =
   239   let val get_int = the o Int.fromString o nth (space_explode "_" s) in
   240     ((get_int 1, (get_int 2, get_int 3)),
   241      String.isPrefix new_skolem_var_prefix s)
   242   end
   243 
   244 fun rename_bound_vars_to_be_zapped ax_no =
   245   let
   246     fun aux (cluster as (cluster_no, cluster_skolem)) index_no pos t =
   247       case t of
   248         (t1 as Const (s, _)) $ Abs (s', T, t') =>
   249         if s = @{const_name all} orelse s = @{const_name All} orelse
   250            s = @{const_name Ex} then
   251           let
   252             val skolem = (pos = (s = @{const_name Ex}))
   253             val (cluster, index_no) =
   254               if skolem = cluster_skolem then (cluster, index_no)
   255               else ((cluster_no ||> cluster_skolem ? Integer.add 1, skolem), 0)
   256             val s' = zapped_var_name cluster index_no s'
   257           in t1 $ Abs (s', T, aux cluster (index_no + 1) pos t') end
   258         else
   259           t
   260       | (t1 as Const (s, _)) $ t2 $ t3 =>
   261         if s = @{const_name "==>"} orelse s = @{const_name HOL.implies} then
   262           t1 $ aux cluster index_no (not pos) t2 $ aux cluster index_no pos t3
   263         else if s = @{const_name HOL.conj} orelse
   264                 s = @{const_name HOL.disj} then
   265           t1 $ aux cluster index_no pos t2 $ aux cluster index_no pos t3
   266         else
   267           t
   268       | (t1 as Const (s, _)) $ t2 =>
   269         if s = @{const_name Trueprop} then
   270           t1 $ aux cluster index_no pos t2
   271         else if s = @{const_name Not} then
   272           t1 $ aux cluster index_no (not pos) t2
   273         else
   274           t
   275       | _ => t
   276   in aux ((ax_no, 0), true) 0 true end
   277 
   278 fun zap pos ct =
   279   ct
   280   |> (case term_of ct of
   281         Const (s, _) $ Abs (s', _, _) =>
   282         if s = @{const_name all} orelse s = @{const_name All} orelse
   283            s = @{const_name Ex} then
   284           Thm.dest_comb #> snd #> Thm.dest_abs (SOME s') #> snd #> zap pos
   285         else
   286           Conv.all_conv
   287       | Const (s, _) $ _ $ _ =>
   288         if s = @{const_name "==>"} orelse s = @{const_name implies} then
   289           Conv.combination_conv (Conv.arg_conv (zap (not pos))) (zap pos)
   290         else if s = @{const_name conj} orelse s = @{const_name disj} then
   291           Conv.combination_conv (Conv.arg_conv (zap pos)) (zap pos)
   292         else
   293           Conv.all_conv
   294       | Const (s, _) $ _ =>
   295         if s = @{const_name Trueprop} then Conv.arg_conv (zap pos)
   296         else if s = @{const_name Not} then Conv.arg_conv (zap (not pos))
   297         else Conv.all_conv
   298       | _ => Conv.all_conv)
   299 
   300 fun ss_only ths = MetaSimplifier.clear_ss HOL_basic_ss addsimps ths
   301 
   302 val cheat_choice =
   303   @{prop "ALL x. EX y. Q x y ==> EX f. ALL x. Q x (f x)"}
   304   |> Logic.varify_global
   305   |> Skip_Proof.make_thm @{theory}
   306 
   307 (* Converts an Isabelle theorem into NNF. *)
   308 fun nnf_axiom choice_ths new_skolemizer ax_no th ctxt =
   309   let
   310     val thy = ProofContext.theory_of ctxt
   311     val th =
   312       th |> transform_elim_theorem
   313          |> zero_var_indexes
   314          |> new_skolemizer ? forall_intr_vars
   315     val (th, ctxt) = Variable.import true [th] ctxt |>> snd |>> the_single
   316     val th = th |> Conv.fconv_rule Object_Logic.atomize
   317                 |> extensionalize_theorem
   318                 |> make_nnf ctxt
   319   in
   320     if new_skolemizer then
   321       let
   322         fun skolemize choice_ths =
   323           skolemize_with_choice_theorems ctxt choice_ths
   324           #> simplify (ss_only @{thms all_simps[symmetric]})
   325         val pull_out =
   326           simplify (ss_only @{thms all_simps[symmetric] ex_simps[symmetric]})
   327         val no_choice = null choice_ths
   328         val discharger_th =
   329           th |> (if no_choice then pull_out else skolemize choice_ths)
   330         val fully_skolemized_t =
   331           th |> prop_of
   332              |> no_choice ? rename_bound_vars_to_be_zapped ax_no
   333              |> Skip_Proof.make_thm thy |> skolemize [cheat_choice] |> cprop_of
   334              |> not no_choice
   335                 ? (term_of #> rename_bound_vars_to_be_zapped ax_no
   336                    #> cterm_of thy)
   337              |> zap true |> Drule.export_without_context
   338              |> cprop_of |> Thm.dest_equals |> snd |> term_of
   339       in
   340         if exists_subterm (fn Var ((s, _), _) =>
   341                               String.isPrefix new_skolem_var_prefix s
   342                             | _ => false) fully_skolemized_t then
   343           let
   344             val (fully_skolemized_ct, ctxt) =
   345               Variable.import_terms true [fully_skolemized_t] ctxt
   346               |>> the_single |>> cterm_of thy
   347           in
   348             (SOME (discharger_th, fully_skolemized_ct),
   349              (Thm.assume fully_skolemized_ct, ctxt))
   350           end
   351        else
   352          (NONE, (th, ctxt))
   353       end
   354     else
   355       (NONE, (th, ctxt))
   356   end
   357 
   358 (* Convert a theorem to CNF, with additional premises due to skolemization. *)
   359 fun cnf_axiom ctxt0 new_skolemizer ax_no th =
   360   let
   361     val thy = ProofContext.theory_of ctxt0
   362     val choice_ths = choice_theorems thy
   363     val (opt, (nnf_th, ctxt)) =
   364       nnf_axiom choice_ths new_skolemizer ax_no th ctxt0
   365     fun clausify th =
   366       make_cnf (if new_skolemizer orelse null choice_ths then
   367                   []
   368                 else
   369                   map (old_skolem_theorem_from_def thy)
   370                       (old_skolem_defs th)) th ctxt
   371     val (cnf_ths, ctxt) =
   372       clausify nnf_th
   373       |> (fn ([], _) =>
   374              (* FIXME: This probably doesn't work with the new Skolemizer *)
   375              clausify (to_definitional_cnf_with_quantifiers thy nnf_th)
   376            | p => p)
   377     fun intr_imp ct th =
   378       Thm.instantiate ([], map (pairself (cterm_of thy))
   379                                [(Var (("i", 0), @{typ nat}),
   380                                  HOLogic.mk_nat ax_no)])
   381                       (zero_var_indexes @{thm skolem_COMBK_D})
   382       RS Thm.implies_intr ct th
   383   in
   384     (opt |> Option.map (I #>> singleton (Variable.export ctxt ctxt0)
   385                         ##> (term_of #> HOLogic.dest_Trueprop
   386                              #> singleton (Variable.export_terms ctxt ctxt0))),
   387      cnf_ths |> map (introduce_combinators_in_theorem
   388                      #> (case opt of SOME (_, ct) => intr_imp ct | NONE => I))
   389              |> Variable.export ctxt ctxt0
   390              |> finish_cnf
   391              |> map Thm.close_derivation)
   392   end
   393   handle THM _ => (NONE, [])
   394 
   395 end;