src/HOL/Tools/record_package.ML
author wenzelm
Mon Apr 17 13:57:55 2000 +0200 (2000-04-17)
changeset 8720 840c75ab2a7f
parent 8574 bed3b994ab26
child 9040 249c135057d7
permissions -rw-r--r--
Pretty.chunks;
     1 (*  Title:      HOL/Tools/record_package.ML
     2     ID:         $Id$
     3     Author:     Wolfgang Naraschewski and Markus Wenzel, TU Muenchen
     4 
     5 Extensible records with structural subtyping in HOL.
     6 *)
     7 
     8 signature BASIC_RECORD_PACKAGE =
     9 sig
    10   val record_simproc: simproc
    11   val record_split_tac: int -> tactic
    12   val record_split_name: string
    13   val record_split_wrapper: string * wrapper
    14 end;
    15 
    16 signature RECORD_PACKAGE =
    17 sig
    18   include BASIC_RECORD_PACKAGE
    19   val quiet_mode: bool ref
    20   val updateN: string
    21   val moreS: sort
    22   val mk_fieldT: (string * typ) * typ -> typ
    23   val dest_fieldT: typ -> (string * typ) * typ
    24   val mk_field: (string * term) * term -> term
    25   val mk_fst: term -> term
    26   val mk_snd: term -> term
    27   val mk_recordT: (string * typ) list * typ -> typ
    28   val dest_recordT: typ -> (string * typ) list * typ
    29   val mk_record: (string * term) list * term -> term
    30   val mk_sel: term -> string -> term
    31   val mk_update: term -> string * term -> term
    32   val print_records: theory -> unit
    33   val add_record: (string list * bstring) -> string option
    34     -> (bstring * string) list -> theory -> theory * {simps: thm list, iffs: thm list}
    35   val add_record_i: (string list * bstring) -> (typ list * string) option
    36     -> (bstring * typ) list -> theory -> theory * {simps: thm list, iffs: thm list}
    37   val setup: (theory -> theory) list
    38 end;
    39 
    40 
    41 structure RecordPackage: RECORD_PACKAGE =
    42 struct
    43 
    44 
    45 (*** utilities ***)
    46 
    47 (* messages *)
    48 
    49 val quiet_mode = ref false;
    50 fun message s = if ! quiet_mode then () else writeln s;
    51 
    52 
    53 (* definitions and equations *)
    54 
    55 infix 0 :== ===;
    56 
    57 val (op :==) = Logic.mk_defpair;
    58 val (op ===) = HOLogic.mk_Trueprop o HOLogic.mk_eq;
    59 
    60 
    61 (* proof by simplification *)
    62 
    63 fun prove_simp sign ss tacs simps =
    64   let
    65     val ss' = Simplifier.addsimps (ss, simps);
    66 
    67     fun prove goal =
    68       Goals.prove_goalw_cterm [] (Thm.cterm_of sign goal)
    69         (K (tacs @ [ALLGOALS (Simplifier.simp_tac ss')]))
    70       handle ERROR => error ("The error(s) above occurred while trying to prove "
    71         ^ quote (Sign.string_of_term sign goal));
    72   in prove end;
    73 
    74 
    75 
    76 (*** syntax operations ***)
    77 
    78 (** name components **)
    79 
    80 val recordN = "record";
    81 val moreN = "more";
    82 val schemeN = "_scheme";
    83 val fieldN = "_field";
    84 val raw_fieldN = "_raw_field";
    85 val field_typeN = "_field_type";
    86 val fstN = "_val";
    87 val sndN = "_more";
    88 val updateN = "_update";
    89 val makeN = "make";
    90 val make_schemeN = "make_scheme";
    91 
    92 (*see datatype package*)
    93 val caseN = "_case";
    94 
    95 
    96 
    97 (** generic operations **)
    98 
    99 (* adhoc priming of vars *)
   100 
   101 fun prime (Free (x, T)) = Free (x ^ "'", T)
   102   | prime t = raise TERM ("prime: no free variable", [t]);
   103 
   104 
   105 (* product case *)
   106 
   107 fun fst_fn T U = Abs ("x", T, Abs ("y", U, Bound 1));
   108 fun snd_fn T U = Abs ("x", T, Abs ("y", U, Bound 0));
   109 
   110 fun mk_prod_case name f p =
   111   let
   112     val fT as Type ("fun", [A, Type ("fun", [B, C])]) = fastype_of f;
   113     val pT = fastype_of p;
   114   in Const (suffix caseN name, fT --> pT --> C) $ f $ p end;
   115 
   116 
   117 
   118 (** tuple operations **)
   119 
   120 (* more type class *)
   121 
   122 val moreS = ["Record.more"];
   123 
   124 
   125 (* types *)
   126 
   127 fun mk_fieldT ((c, T), U) = Type (suffix field_typeN c, [T, U]);
   128 
   129 fun dest_fieldT (typ as Type (c_field_type, [T, U])) =
   130       (case try (unsuffix field_typeN) c_field_type of
   131         None => raise TYPE ("dest_fieldT", [typ], [])
   132       | Some c => ((c, T), U))
   133   | dest_fieldT typ = raise TYPE ("dest_fieldT", [typ], []);
   134 
   135 
   136 (* constructors *)
   137 
   138 fun mk_fieldC U (c, T) = (suffix fieldN c, T --> U --> mk_fieldT ((c, T), U));
   139 
   140 fun gen_mk_field sfx ((c, t), u) =
   141   let val T = fastype_of t and U = fastype_of u
   142   in Const (suffix sfx c, [T, U] ---> mk_fieldT ((c, T), U)) $ t $ u end;
   143 
   144 val mk_field = gen_mk_field fieldN;
   145 val mk_raw_field = gen_mk_field raw_fieldN;
   146 
   147 
   148 (* destructors *)
   149 
   150 fun mk_fstC U (c, T) = (suffix fstN c, mk_fieldT ((c, T), U) --> T);
   151 fun mk_sndC U (c, T) = (suffix sndN c, mk_fieldT ((c, T), U) --> U);
   152 
   153 fun dest_field fst_or_snd p =
   154   let
   155     val pT = fastype_of p;
   156     val ((c, T), U) = dest_fieldT pT;
   157     val (destN, destT) = if fst_or_snd then (fstN, T) else (sndN, U);
   158   in Const (suffix destN c, pT --> destT) $ p end;
   159 
   160 val mk_fst = dest_field true;
   161 val mk_snd = dest_field false;
   162 
   163 
   164 
   165 (** record operations **)
   166 
   167 (* types *)
   168 
   169 val mk_recordT = foldr mk_fieldT;
   170 
   171 fun dest_recordT T =
   172   (case try dest_fieldT T of
   173     None => ([], T)
   174   | Some (c_T, U) => apfst (cons c_T) (dest_recordT U));
   175 
   176 fun find_fieldT c rT =
   177   (case assoc (fst (dest_recordT rT), c) of
   178     None => raise TYPE ("find_field: " ^ c, [rT], [])
   179   | Some T => T);
   180 
   181 
   182 (* constructors *)
   183 
   184 val mk_record = foldr mk_field;
   185 
   186 
   187 (* selectors *)
   188 
   189 fun mk_selC rT (c, T) = (c, rT --> T);
   190 
   191 fun mk_sel r c =
   192   let val rT = fastype_of r
   193   in Const (mk_selC rT (c, find_fieldT c rT)) $ r end;
   194 
   195 val mk_moreC = mk_selC;
   196 
   197 fun mk_more r c =
   198   let val rT = fastype_of r
   199   in Const (mk_moreC rT (c, snd (dest_recordT rT))) $ r end;
   200 
   201 
   202 (* updates *)
   203 
   204 fun mk_updateC rT (c, T) = (suffix updateN c, T --> rT --> rT);
   205 
   206 fun mk_update r (c, x) =
   207   let val rT = fastype_of r
   208   in Const (mk_updateC rT (c, find_fieldT c rT)) $ x $ r end;
   209 
   210 val mk_more_updateC = mk_updateC;
   211 
   212 fun mk_more_update r (c, x) =
   213   let val rT = fastype_of r
   214   in Const (mk_more_updateC rT (c, snd (dest_recordT rT))) $ x $ r end;
   215 
   216 
   217 (* make *)
   218 
   219 fun mk_makeC rT (c, Ts) = (c, Ts ---> rT);
   220 
   221 
   222 
   223 (** concrete syntax for records **)
   224 
   225 (* parse translations *)
   226 
   227 fun gen_field_tr mark sfx (t as Const (c, _) $ Free (name, _) $ arg) =
   228       if c = mark then Syntax.const (suffix sfx name) $ arg
   229       else raise TERM ("gen_field_tr: " ^ mark, [t])
   230   | gen_field_tr mark _ t = raise TERM ("gen_field_tr: " ^ mark, [t]);
   231 
   232 fun gen_fields_tr sep mark sfx (tm as Const (c, _) $ t $ u) =
   233       if c = sep then gen_field_tr mark sfx t :: gen_fields_tr sep mark sfx u
   234       else [gen_field_tr mark sfx tm]
   235   | gen_fields_tr _ mark sfx tm = [gen_field_tr mark sfx tm];
   236 
   237 fun gen_record_tr sep mark sfx unit [t] = foldr (op $) (gen_fields_tr sep mark sfx t, unit)
   238   | gen_record_tr _ _ _ _ ts = raise TERM ("gen_record_tr", ts);
   239 
   240 fun gen_record_scheme_tr sep mark sfx [t, more] = foldr (op $) (gen_fields_tr sep mark sfx t, more)
   241   | gen_record_scheme_tr _ _ _ ts = raise TERM ("gen_record_scheme_tr", ts);
   242 
   243 
   244 val record_type_tr = gen_record_tr "_field_types" "_field_type" field_typeN (Syntax.const "unit");
   245 val record_type_scheme_tr = gen_record_scheme_tr "_field_types" "_field_type" field_typeN;
   246 
   247 val record_tr = gen_record_tr "_fields" "_field" fieldN HOLogic.unit;
   248 val record_scheme_tr = gen_record_scheme_tr "_fields" "_field" fieldN;
   249 
   250 fun record_update_tr [t, u] =
   251       foldr (op $) (rev (gen_fields_tr "_updates" "_update" updateN u), t)
   252   | record_update_tr ts = raise TERM ("record_update_tr", ts);
   253 
   254 
   255 val parse_translation =
   256  [("_record_type", record_type_tr),
   257   ("_record_type_scheme", record_type_scheme_tr),
   258   ("_record", record_tr),
   259   ("_record_scheme", record_scheme_tr),
   260   ("_record_update", record_update_tr)];
   261 
   262 
   263 (* print translations *)
   264 
   265 fun gen_fields_tr' mark sfx (tm as Const (name_field, _) $ t $ u) =
   266       (case try (unsuffix sfx) name_field of
   267         Some name =>
   268           apfst (cons (Syntax.const mark $ Syntax.free name $ t)) (gen_fields_tr' mark sfx u)
   269       | None => ([], tm))
   270   | gen_fields_tr' _ _ tm = ([], tm);
   271 
   272 fun gen_record_tr' sep mark sfx is_unit record record_scheme tm =
   273   let
   274     val (ts, u) = gen_fields_tr' mark sfx tm;
   275     val t' = foldr1 (fn (v, w) => Syntax.const sep $ v $ w) ts;
   276   in
   277     if is_unit u then Syntax.const record $ t'
   278     else Syntax.const record_scheme $ t' $ u
   279   end;
   280 
   281 
   282 val record_type_tr' =
   283   gen_record_tr' "_field_types" "_field_type" field_typeN
   284     (fn Const ("unit", _) => true | _ => false) "_record_type" "_record_type_scheme";
   285 
   286 val record_tr' =
   287   gen_record_tr' "_fields" "_field" fieldN HOLogic.is_unit "_record" "_record_scheme";
   288 
   289 fun record_update_tr' tm =
   290   let val (ts, u) = gen_fields_tr' "_update" updateN tm in
   291     Syntax.const "_record_update" $ u $
   292       foldr1 (fn (v, w) => Syntax.const "_updates" $ v $ w) (rev ts)
   293   end;
   294 
   295 
   296 fun gen_field_tr' sfx tr' name =
   297   let val name_sfx = suffix sfx name
   298   in (name_sfx, fn [t, u] => tr' (Syntax.const name_sfx $ t $ u) | _ => raise Match) end;
   299 
   300 fun print_translation names =
   301   map (gen_field_tr' field_typeN record_type_tr') names @
   302   map (gen_field_tr' fieldN record_tr') names @
   303   map (gen_field_tr' updateN record_update_tr') names;
   304 
   305 
   306 
   307 (*** extend theory by record definition ***)
   308 
   309 (** record info **)
   310 
   311 (* type record_info and parent_info *)
   312 
   313 type record_info =
   314  {args: (string * sort) list,
   315   parent: (typ list * string) option,
   316   fields: (string * typ) list,
   317   simps: thm list};
   318 
   319 type parent_info =
   320  {name: string,
   321   fields: (string * typ) list,
   322   simps: thm list};
   323 
   324 
   325 (* data kind 'HOL/records' *)
   326 
   327 type record_data =
   328  {records: record_info Symtab.table,
   329   sel_upd:
   330    {selectors: unit Symtab.table,
   331     updates: string Symtab.table,
   332     simpset: Simplifier.simpset},
   333   field_splits:
   334    {fields: unit Symtab.table,
   335     simpset: Simplifier.simpset}};
   336 
   337 fun make_record_data records sel_upd field_splits =
   338  {records = records, sel_upd = sel_upd, field_splits = field_splits}: record_data;
   339 
   340 structure RecordsArgs =
   341 struct
   342   val name = "HOL/records";
   343   type T = record_data;
   344 
   345   val empty =
   346     make_record_data Symtab.empty
   347       {selectors = Symtab.empty, updates = Symtab.empty, simpset = HOL_basic_ss}
   348       {fields = Symtab.empty, simpset = HOL_basic_ss};
   349 
   350   val copy = I;
   351   val prep_ext = I;
   352   fun merge
   353    ({records = recs1,
   354      sel_upd = {selectors = sels1, updates = upds1, simpset = ss1},
   355      field_splits = {fields = flds1, simpset = fld_ss1}},
   356     {records = recs2,
   357      sel_upd = {selectors = sels2, updates = upds2, simpset = ss2},
   358      field_splits = {fields = flds2, simpset = fld_ss2}}) =
   359     make_record_data
   360       (Symtab.merge (K true) (recs1, recs2))
   361       {selectors = Symtab.merge (K true) (sels1, sels2),
   362         updates = Symtab.merge (K true) (upds1, upds2),
   363         simpset = Simplifier.merge_ss (ss1, ss2)}
   364       {fields = Symtab.merge (K true) (flds1, flds2),
   365         simpset = Simplifier.merge_ss (fld_ss1, fld_ss2)};
   366 
   367   fun print sg ({records = recs, ...}: record_data) =
   368     let
   369       val prt_typ = Sign.pretty_typ sg;
   370       val ext_const = Sign.cond_extern sg Sign.constK;
   371 
   372       fun pretty_parent None = []
   373         | pretty_parent (Some (Ts, name)) =
   374             [Pretty.block [prt_typ (Type (name, Ts)), Pretty.str " +"]];
   375 
   376       fun pretty_field (c, T) = Pretty.block
   377         [Pretty.str (ext_const c), Pretty.str " ::", Pretty.brk 1, Pretty.quote (prt_typ T)];
   378 
   379       fun pretty_record (name, {args, parent, fields, simps = _}) = Pretty.block (Pretty.fbreaks
   380         (Pretty.block [prt_typ (Type (name, map TFree args)), Pretty.str " = "] ::
   381           pretty_parent parent @ map pretty_field fields));
   382     in
   383       map pretty_record (Sign.cond_extern_table sg Sign.typeK recs)
   384       |> Pretty.chunks |> Pretty.writeln
   385     end;
   386 end;
   387 
   388 structure RecordsData = TheoryDataFun(RecordsArgs);
   389 val print_records = RecordsData.print;
   390 
   391 
   392 (* access 'records' *)
   393 
   394 fun get_record thy name = Symtab.lookup (#records (RecordsData.get thy), name);
   395 
   396 fun put_record name info thy =
   397   let
   398     val {records, sel_upd, field_splits} = RecordsData.get thy;
   399     val data = make_record_data (Symtab.update ((name, info), records)) sel_upd field_splits;
   400   in RecordsData.put data thy end;
   401 
   402 
   403 (* access 'sel_upd' *)
   404 
   405 fun get_sel_upd sg = #sel_upd (RecordsData.get_sg sg);
   406 
   407 fun get_selectors sg name = Symtab.lookup (#selectors (get_sel_upd sg), name);
   408 fun get_updates sg name = Symtab.lookup (#updates (get_sel_upd sg), name);
   409 fun get_simpset sg = #simpset (get_sel_upd sg);
   410 
   411 
   412 fun put_sel_upd names simps thy =
   413   let
   414     val sels = map (rpair ()) names;
   415     val upds = map (suffix updateN) names ~~ names;
   416 
   417     val {records, sel_upd = {selectors, updates, simpset}, field_splits} = RecordsData.get thy;
   418     val data = make_record_data records
   419       {selectors = Symtab.extend (selectors, sels),
   420         updates = Symtab.extend (updates, upds),
   421         simpset = Simplifier.addsimps (simpset, simps)}
   422       field_splits;
   423   in RecordsData.put data thy end;
   424 
   425 
   426 (* access 'field_splits' *)
   427 
   428 fun add_record_splits splits thy =
   429   let
   430     val {records, sel_upd, field_splits = {fields, simpset}} = RecordsData.get thy;
   431     val flds = map (rpair () o fst) splits;
   432     val simps = map snd splits;
   433     val data = make_record_data records sel_upd
   434       {fields = Symtab.extend (fields, flds), simpset = Simplifier.addsimps (simpset, simps)};
   435   in RecordsData.put data thy end;
   436 
   437 
   438 (* parent records *)
   439 
   440 fun inst_record thy (types, name) =
   441   let
   442     val sign = Theory.sign_of thy;
   443     fun err msg = error (msg ^ " parent record " ^ quote name);
   444 
   445     val {args, parent, fields, simps} =
   446       (case get_record thy name of Some info => info | None => err "Unknown");
   447     val _ = if length types <> length args then err "Bad number of arguments for" else ();
   448 
   449     fun bad_inst ((x, S), T) =
   450       if Sign.of_sort sign (T, S) then None else Some x
   451     val bads = mapfilter bad_inst (args ~~ types);
   452 
   453     val inst = map fst args ~~ types;
   454     val subst = Term.map_type_tfree (fn (x, _) => the (assoc (inst, x)));
   455   in
   456     if not (null bads) then
   457       err ("Ill-sorted instantiation of " ^ commas bads ^ " in")
   458     else (apsome (apfst (map subst)) parent, map (apsnd subst) fields, simps)
   459   end;
   460 
   461 fun add_parents thy (None, parents) = parents
   462   | add_parents thy (Some (types, name), parents) =
   463       let val (pparent, pfields, psimps) = inst_record thy (types, name)
   464       in add_parents thy (pparent, {name = name, fields = pfields, simps = psimps} :: parents) end;
   465 
   466 
   467 
   468 (** record simproc **)
   469 
   470 local
   471 
   472 val sel_upd_pat = [Thm.read_cterm (Theory.sign_of HOL.thy) ("s (u k r)", HOLogic.termT)];
   473 
   474 fun proc sg _ t =
   475   (case t of (sel as Const (s, _)) $ ((upd as Const (u, _)) $ k $ r) =>
   476     (case get_selectors sg s of Some () =>
   477       (case get_updates sg u of Some u_name =>
   478         let
   479           fun atomize x t = Free (x, fastype_of t);
   480           val k' = atomize "k" k;
   481           val r' = atomize "r" r;
   482           val t' = sel $ (upd $ k' $ r');
   483           val prove = mk_meta_eq o prove_simp sg (get_simpset sg) [] [];
   484         in
   485           if u_name = s then Some (prove (t' === k'))
   486           else Some (prove (t' === sel $ r'))
   487         end
   488       | None => None)
   489     | None => None)
   490   | _ => None);
   491 
   492 in
   493 
   494 val record_simproc = Simplifier.mk_simproc "record_simp" sel_upd_pat proc;
   495 
   496 end;
   497 
   498 
   499 
   500 (** record field splitting **)
   501 
   502 (* tactic *)
   503 
   504 fun record_split_tac i st =
   505   let
   506     val {field_splits = {fields, simpset}, ...} = RecordsData.get_sg (Thm.sign_of_thm st);
   507 
   508     fun is_fieldT (_, Type (a, [_, _])) = is_some (Symtab.lookup (fields, a))
   509       | is_fieldT _ = false;
   510     val params = Logic.strip_params (Library.nth_elem (i - 1, Thm.prems_of st));
   511   in
   512     if exists is_fieldT params then Simplifier.full_simp_tac simpset i st
   513     else Seq.empty
   514   end handle Library.LIST _ => Seq.empty;
   515 
   516 
   517 (* wrapper *)
   518 
   519 val record_split_name = "record_split_tac";
   520 val record_split_wrapper = (record_split_name, fn tac => record_split_tac ORELSE' tac);
   521 
   522 
   523 (* method *)
   524 
   525 val record_split_method =
   526   ("record_split", Method.no_args (Method.METHOD0 (HEADGOAL record_split_tac)),
   527     "split record fields");
   528 
   529 
   530 
   531 (** internal theory extenders **)
   532 
   533 (* field_type_defs *)
   534 
   535 fun field_type_def ((thy, simps), (name, tname, vs, T, U)) =
   536   let
   537     val full = Sign.full_name (Theory.sign_of thy);
   538     val (thy', {simps = simps', ...}) =
   539       thy
   540       |> setmp DatatypePackage.quiet_mode true
   541         (DatatypePackage.add_datatype_i true [tname]
   542           [(vs, tname, Syntax.NoSyn, [(name, [T, U], Syntax.NoSyn)])]);
   543     val thy'' =
   544       thy'
   545       |> setmp AxClass.quiet_mode true
   546         (AxClass.add_inst_arity_i (full tname, [HOLogic.termS, moreS], moreS) [] [] None);
   547   in (thy'', simps' @ simps) end;
   548 
   549 fun field_type_defs args thy = foldl field_type_def ((thy, []), args);
   550 
   551 
   552 (* field_definitions *)
   553 
   554 fun field_definitions fields names zeta moreT more vars named_vars thy =
   555   let
   556     val sign = Theory.sign_of thy;
   557     val base = Sign.base_name;
   558     val full_path = Sign.full_name_path sign;
   559 
   560 
   561     (* prepare declarations and definitions *)
   562 
   563     (*field types*)
   564     fun mk_fieldT_spec c =
   565       (suffix raw_fieldN c, suffix field_typeN c,
   566         ["'a", zeta], TFree ("'a", HOLogic.termS), moreT);
   567     val fieldT_specs = map (mk_fieldT_spec o base) names;
   568 
   569     (*field constructors*)
   570     val field_decls = map (mk_fieldC moreT) fields;
   571 
   572     fun mk_field_spec (c, v) =
   573       mk_field ((c, v), more) :== mk_raw_field ((c, v), more);
   574     val field_specs = map mk_field_spec named_vars;
   575 
   576     (*field destructors*)
   577     val dest_decls = map (mk_fstC moreT) fields @ map (mk_sndC moreT) fields;
   578 
   579     fun mk_dest_spec dest f (c, T) =
   580       let val p = Free ("p", mk_fieldT ((c, T), moreT));
   581       in dest p :== mk_prod_case (suffix field_typeN c) (f T moreT) p end;
   582     val dest_specs =
   583       map (mk_dest_spec mk_fst fst_fn) fields @
   584       map (mk_dest_spec mk_snd snd_fn) fields;
   585 
   586 
   587     (* prepare theorems *)
   588 
   589     (*constructor injects*)
   590     fun mk_inject_prop (c, v) =
   591       HOLogic.mk_eq (mk_field ((c, v), more), mk_field ((c, prime v), prime more)) ===
   592         (HOLogic.conj $ HOLogic.mk_eq (v, prime v) $ HOLogic.mk_eq (more, prime more));
   593     val inject_props = map mk_inject_prop named_vars;
   594 
   595     (*destructor conversions*)
   596     fun mk_dest_prop dest dest' (c, v) =
   597       dest (mk_field ((c, v), more)) === dest' (v, more);
   598     val dest_props =
   599       map (mk_dest_prop mk_fst fst) named_vars @
   600       map (mk_dest_prop mk_snd snd) named_vars;
   601 
   602     (*surjective pairing*)
   603     fun mk_surj_prop (c, T) =
   604       let val p = Free ("p", mk_fieldT ((c, T), moreT));
   605       in p === mk_field ((c, mk_fst p), mk_snd p) end;
   606     val surj_props = map mk_surj_prop fields;
   607 
   608 
   609     (* 1st stage: types_thy *)
   610 
   611     val (types_thy, datatype_simps) =
   612       thy
   613       |> field_type_defs fieldT_specs;
   614 
   615 
   616     (* 2nd stage: defs_thy *)
   617 
   618     val (defs_thy, (field_defs, dest_defs)) =
   619       types_thy
   620        |> (Theory.add_consts_i o map (Syntax.no_syn o apfst base)) (field_decls @ dest_decls)
   621        |> (PureThy.add_defs_i o map (fn x => (x, [Drule.tag_internal]))) field_specs
   622        |>>> (PureThy.add_defs_i o map (fn x => (x, [Drule.tag_internal]))) dest_specs;
   623 
   624 
   625     (* 3rd stage: thms_thy *)
   626 
   627     val prove = prove_simp (Theory.sign_of defs_thy) HOL_basic_ss;
   628     val prove_std = prove [] (field_defs @ dest_defs @ datatype_simps);
   629 
   630     val field_injects = map prove_std inject_props;
   631     val dest_convs = map prove_std dest_props;
   632     val surj_pairs = map (prove [DatatypePackage.induct_tac "p" 1]
   633       (map Thm.symmetric field_defs @ dest_convs)) surj_props;
   634 
   635     fun mk_split th = SplitPairedAll.rule (th RS eq_reflection);
   636     val field_splits = map mk_split surj_pairs;
   637 
   638     val thms_thy =
   639       defs_thy
   640       |> (#1 oo (PureThy.add_thmss o map Thm.no_attributes))
   641         [("field_defs", field_defs),
   642           ("dest_defs", dest_defs),
   643           ("dest_convs", dest_convs),
   644           ("surj_pairs", surj_pairs),
   645           ("field_splits", field_splits)];
   646 
   647   in (thms_thy, dest_convs, field_injects, field_splits) end;
   648 
   649 
   650 (* record_definition *)
   651 
   652 fun record_definition (args, bname) parent (parents: parent_info list) bfields thy =
   653   let
   654     val sign = Theory.sign_of thy;
   655     val full = Sign.full_name_path sign bname;
   656     val base = Sign.base_name;
   657 
   658 
   659     (* basic components *)
   660 
   661     val alphas = map fst args;
   662     val name = Sign.full_name sign bname;       (*not made part of record name space!*)
   663 
   664     val parent_fields = flat (map #fields parents);
   665     val parent_names = map fst parent_fields;
   666     val parent_types = map snd parent_fields;
   667     val parent_len = length parent_fields;
   668     val parent_xs = variantlist (map (base o fst) parent_fields, [moreN, recordN]);
   669     val parent_vars = ListPair.map Free (parent_xs, parent_types);
   670     val parent_named_vars = parent_names ~~ parent_vars;
   671 
   672     val fields = map (apfst full) bfields;
   673     val names = map fst fields;
   674     val types = map snd fields;
   675     val len = length fields;
   676     val xs = variantlist (map fst bfields, moreN :: recordN :: parent_xs);
   677     val vars = ListPair.map Free (xs, types);
   678     val named_vars = names ~~ vars;
   679 
   680     val all_fields = parent_fields @ fields;
   681     val all_names = parent_names @ names;
   682     val all_types = parent_types @ types;
   683     val all_len = parent_len + len;
   684     val all_xs = parent_xs @ xs;
   685     val all_vars = parent_vars @ vars;
   686     val all_named_vars = parent_named_vars @ named_vars;
   687 
   688     val zeta = variant alphas "'z";
   689     val moreT = TFree (zeta, moreS);
   690     val more = Free (moreN, moreT);
   691     val full_moreN = full moreN;
   692     fun more_part t = mk_more t full_moreN;
   693     fun more_part_update t x = mk_more_update t (full_moreN, x);
   694 
   695     val parent_more = funpow parent_len mk_snd;
   696     val idxs = 0 upto (len - 1);
   697 
   698     val rec_schemeT = mk_recordT (all_fields, moreT);
   699     val rec_scheme = mk_record (all_named_vars, more);
   700     val r = Free (recordN, rec_schemeT);
   701     val recT = mk_recordT (all_fields, HOLogic.unitT);
   702 
   703 
   704     (* prepare print translation functions *)
   705 
   706     val field_tr's =
   707       print_translation (distinct (flat (map NameSpace.accesses (full_moreN :: names))));
   708 
   709 
   710     (* prepare declarations *)
   711 
   712     val sel_decls = map (mk_selC rec_schemeT) bfields @
   713       [mk_moreC rec_schemeT (moreN, moreT)];
   714     val update_decls = map (mk_updateC rec_schemeT) bfields @
   715       [mk_more_updateC rec_schemeT (moreN, moreT)];
   716     val make_decls =
   717       [(mk_makeC rec_schemeT (make_schemeN, all_types @ [moreT])),
   718        (mk_makeC recT (makeN, all_types))];
   719 
   720 
   721     (* prepare definitions *)
   722 
   723     (*record (scheme) type abbreviation*)
   724     val recordT_specs =
   725       [(suffix schemeN bname, alphas @ [zeta], rec_schemeT, Syntax.NoSyn),
   726         (bname, alphas, recT, Syntax.NoSyn)];
   727 
   728     (*selectors*)
   729     fun mk_sel_spec (i, c) =
   730       mk_sel r c :== mk_fst (funpow i mk_snd (parent_more r));
   731     val sel_specs =
   732       ListPair.map mk_sel_spec (idxs, names) @
   733         [more_part r :== funpow len mk_snd (parent_more r)];
   734 
   735     (*updates*)
   736     val all_sels = all_names ~~ map (mk_sel r) all_names;
   737     fun mk_upd_spec (i, (c, x)) =
   738       mk_update r (c, x) :==
   739         mk_record (nth_update (c, x) (parent_len + i, all_sels), more_part r)
   740     val update_specs =
   741       ListPair.map mk_upd_spec (idxs, named_vars) @
   742         [more_part_update r more :== mk_record (all_sels, more)];
   743 
   744     (*makes*)
   745     val make_scheme = Const (mk_makeC rec_schemeT (full make_schemeN, all_types @ [moreT]));
   746     val make = Const (mk_makeC recT (full makeN, all_types));
   747     val make_specs =
   748       [list_comb (make_scheme, all_vars) $ more :== rec_scheme,
   749         list_comb (make, all_vars) :== mk_record (all_named_vars, HOLogic.unit)];
   750 
   751 
   752     (* prepare propositions *)
   753 
   754     (*selectors*)
   755     val sel_props =
   756       map (fn (c, x) => mk_sel rec_scheme c === x) named_vars @
   757         [more_part rec_scheme === more];
   758 
   759     (*updates*)
   760     fun mk_upd_prop (i, (c, T)) =
   761       let val x' = Free (variant all_xs (base c ^ "'"), T) in
   762         mk_update rec_scheme (c, x') ===
   763           mk_record (nth_update (c, x') (parent_len + i, all_named_vars), more)
   764       end;
   765     val update_props =
   766       ListPair.map mk_upd_prop (idxs, fields) @
   767         let val more' = Free (variant all_xs (moreN ^ "'"), moreT)
   768         in [more_part_update rec_scheme more' === mk_record (all_named_vars, more')] end;
   769 
   770 
   771     (* 1st stage: fields_thy *)
   772 
   773     val (fields_thy, field_simps, field_injects, field_splits) =
   774       thy
   775       |> Theory.add_path bname
   776       |> field_definitions fields names zeta moreT more vars named_vars;
   777 
   778     val named_splits = map2 (fn (c, th) => (suffix field_typeN c, th)) (names, field_splits);
   779 
   780 
   781     (* 2nd stage: defs_thy *)
   782 
   783     val (defs_thy, ((sel_defs, update_defs), make_defs)) =
   784       fields_thy
   785       |> Theory.parent_path
   786       |> Theory.add_tyabbrs_i recordT_specs     (*not made part of record name space!*)
   787       |> Theory.add_path bname
   788       |> Theory.add_trfuns ([], [], field_tr's, [])
   789       |> (Theory.add_consts_i o map Syntax.no_syn)
   790         (sel_decls @ update_decls @ make_decls)
   791       |> (PureThy.add_defs_i o map (fn x => (x, [Drule.tag_internal]))) sel_specs
   792       |>>> (PureThy.add_defs_i o map (fn x => (x, [Drule.tag_internal]))) update_specs
   793       |>>> (PureThy.add_defs_i o map Thm.no_attributes) make_specs;
   794 
   795 
   796     (* 3rd stage: thms_thy *)
   797 
   798     val parent_simps = flat (map #simps parents);
   799     val prove = prove_simp (Theory.sign_of defs_thy) HOL_basic_ss [];
   800 
   801     val sel_convs = map (prove (parent_simps @ sel_defs @ field_simps)) sel_props;
   802     val update_convs = map (prove (parent_simps @ update_defs @ sel_convs)) update_props;
   803 
   804     val simps = field_simps @ sel_convs @ update_convs @ make_defs;
   805     val iffs = field_injects;
   806 
   807     val thms_thy =
   808       defs_thy
   809       |> (#1 oo (PureThy.add_thmss o map Thm.no_attributes))
   810         [("select_defs", sel_defs),
   811           ("update_defs", update_defs),
   812           ("make_defs", make_defs),
   813           ("select_convs", sel_convs),
   814           ("update_convs", update_convs)]
   815       |> (#1 oo PureThy.add_thmss)
   816         [(("simps", simps), [Simplifier.simp_add_global]),
   817          (("iffs", iffs), [iff_add_global])];
   818 
   819 
   820     (* 4th stage: final_thy *)
   821 
   822     val final_thy =
   823       thms_thy
   824       |> put_record name {args = args, parent = parent, fields = fields, simps = simps}
   825       |> put_sel_upd names (field_simps @ sel_defs @ update_defs)
   826       |> add_record_splits named_splits
   827       |> Theory.parent_path;
   828 
   829   in (final_thy, {simps = simps, iffs = iffs}) end;
   830 
   831 
   832 
   833 (** theory extender interface **)
   834 
   835 (* prepare arguments *)
   836 
   837 (*note: read_raw_typ avoids expanding type abbreviations*)
   838 fun read_raw_parent sign s =
   839   (case Sign.read_raw_typ (sign, K None) s handle TYPE (msg, _, _) => error msg of
   840     Type (name, Ts) => (Ts, name)
   841   | _ => error ("Bad parent record specification: " ^ quote s));
   842 
   843 fun read_typ sign (env, s) =
   844   let
   845     fun def_sort (x, ~1) = assoc (env, x)
   846       | def_sort _ = None;
   847     val T = Type.no_tvars (Sign.read_typ (sign, def_sort) s) handle TYPE (msg, _, _) => error msg;
   848   in (Term.add_typ_tfrees (T, env), T) end;
   849 
   850 fun cert_typ sign (env, raw_T) =
   851   let val T = Type.no_tvars (Sign.certify_typ sign raw_T) handle TYPE (msg, _, _) => error msg
   852   in (Term.add_typ_tfrees (T, env), T) end;
   853 
   854 
   855 (* add_record *)
   856 
   857 (*we do all preparations and error checks here, deferring the real
   858   work to record_definition*)
   859 
   860 fun gen_add_record prep_typ prep_raw_parent (params, bname) raw_parent raw_fields thy =
   861   let
   862     val _ = Theory.requires thy "Record" "record definitions";
   863     val sign = Theory.sign_of thy;
   864     val _ = message ("Defining record " ^ quote bname ^ " ...");
   865 
   866 
   867     (* parents *)
   868 
   869     fun prep_inst T = snd (cert_typ sign ([], T));
   870 
   871     val parent = apsome (apfst (map prep_inst) o prep_raw_parent sign) raw_parent
   872       handle ERROR => error ("The error(s) above in parent record specification");
   873     val parents = add_parents thy (parent, []);
   874 
   875     val init_env =
   876       (case parent of
   877         None => []
   878       | Some (types, _) => foldr Term.add_typ_tfrees (types, []));
   879 
   880 
   881     (* fields *)
   882 
   883     fun prep_field (env, (c, raw_T)) =
   884       let val (env', T) = prep_typ sign (env, raw_T) handle ERROR =>
   885         error ("The error(s) above occured in field " ^ quote c)
   886       in (env', (c, T)) end;
   887 
   888     val (envir, bfields) = foldl_map prep_field (init_env, raw_fields);
   889     val envir_names = map fst envir;
   890 
   891 
   892     (* args *)
   893 
   894     val defaultS = Sign.defaultS sign;
   895     val args = map (fn x => (x, if_none (assoc (envir, x)) defaultS)) params;
   896 
   897 
   898     (* errors *)
   899 
   900     val name = Sign.full_name sign bname;
   901     val err_dup_record =
   902       if is_none (get_record thy name) then []
   903       else ["Duplicate definition of record " ^ quote name];
   904 
   905     val err_dup_parms =
   906       (case duplicates params of
   907         [] => []
   908       | dups => ["Duplicate parameter(s) " ^ commas dups]);
   909 
   910     val err_extra_frees =
   911       (case gen_rems (op =) (envir_names, params) of
   912         [] => []
   913       | extras => ["Extra free type variable(s) " ^ commas extras]);
   914 
   915     val err_no_fields = if null bfields then ["No fields present"] else [];
   916 
   917     val err_dup_fields =
   918       (case duplicates (map fst bfields) of
   919         [] => []
   920       | dups => ["Duplicate field(s) " ^ commas_quote dups]);
   921 
   922     val err_bad_fields =
   923       if forall (not_equal moreN o fst) bfields then []
   924       else ["Illegal field name " ^ quote moreN];
   925 
   926     val err_dup_sorts =
   927       (case duplicates envir_names of
   928         [] => []
   929       | dups => ["Inconsistent sort constraints for " ^ commas dups]);
   930 
   931     val errs =
   932       err_dup_record @ err_dup_parms @ err_extra_frees @ err_no_fields @
   933       err_dup_fields @ err_bad_fields @ err_dup_sorts;
   934   in
   935     if null errs then () else error (cat_lines errs);
   936     thy |> record_definition (args, bname) parent parents bfields
   937   end
   938   handle ERROR => error ("Failed to define record " ^ quote bname);
   939 
   940 val add_record = gen_add_record read_typ read_raw_parent;
   941 val add_record_i = gen_add_record cert_typ (K I);
   942 
   943 
   944 
   945 (** package setup **)
   946 
   947 (* setup theory *)
   948 
   949 val setup =
   950  [RecordsData.init,
   951   Theory.add_trfuns ([], parse_translation, [], []),
   952   Method.add_methods [record_split_method],
   953   Simplifier.change_simpset_of Simplifier.addsimprocs [record_simproc]];
   954 
   955 
   956 (* outer syntax *)
   957 
   958 local structure P = OuterParse and K = OuterSyntax.Keyword in
   959 
   960 val record_decl =
   961   P.type_args -- P.name -- (P.$$$ "=" |-- Scan.option (P.typ --| P.$$$ "+")
   962     -- Scan.repeat1 (P.name -- (P.$$$ "::" |-- P.typ) --| P.marg_comment));
   963 
   964 val recordP =
   965   OuterSyntax.command "record" "define extensible record" K.thy_decl
   966     (record_decl >> (fn (x, (y, z)) => Toplevel.theory (#1 o add_record x y z)));
   967 
   968 val _ = OuterSyntax.add_parsers [recordP];
   969 
   970 end;
   971 
   972 
   973 end;
   974 
   975 structure BasicRecordPackage: BASIC_RECORD_PACKAGE = RecordPackage;
   976 open BasicRecordPackage;