src/Pure/library.ML
author wenzelm
Thu Jun 02 18:29:48 2005 +0200 (2005-06-02)
changeset 16188 841342a7c41c
parent 16129 6fa9ace50240
child 16439 0509ef1b1ec3
permissions -rw-r--r--
replaced foldl_string by fold_string;
added forall_string;
improved unsuffix/unprefix: no explode;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 rational numbers, strings, lists as sets, association lists, generic
     8 tables, balanced trees, orders, current directory, misc.
     9 *)
    10 
    11 infix |> |>> |>>> ~~ \ \\ ins ins_string ins_int orf andf prefix upto downto
    12   mem mem_int mem_string union union_int union_string inter inter_int
    13   inter_string subset subset_int subset_string;
    14 
    15 infix 3 oo ooo oooo;
    16 
    17 signature BASIC_LIBRARY =
    18 sig
    19   (*functions*)
    20   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    21   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val |> : 'a * ('a -> 'b) -> 'b
    25   val |>> : ('a * 'b) * ('a -> 'c) -> 'c * 'b
    26   val |>>> : ('a * 'b) * ('a -> 'c * 'd) -> 'c * ('b * 'd)
    27   val apl: 'a * ('a * 'b -> 'c) -> 'b -> 'c
    28   val apr: ('a * 'b -> 'c) * 'b -> 'a -> 'c
    29   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    30   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    31   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    32   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    33 
    34   (*stamps*)
    35   type stamp
    36   val stamp: unit -> stamp
    37 
    38   (*old options -- invalidated*)
    39   datatype invalid = None of invalid
    40   exception OPTION of invalid
    41 
    42   (*options*)
    43   val the: 'a option -> 'a
    44   val if_none: 'a option -> 'a -> 'a
    45   val is_some: 'a option -> bool
    46   val is_none: 'a option -> bool
    47 
    48   exception ERROR
    49   val try: ('a -> 'b) -> 'a -> 'b option
    50   val can: ('a -> 'b) -> 'a -> bool
    51   datatype 'a result = Result of 'a | Exn of exn
    52   val capture: ('a -> 'b) -> 'a -> 'b result
    53   val release: 'a result -> 'a
    54   val get_result: 'a result -> 'a option
    55   val get_exn: 'a result -> exn option
    56 
    57   (*pairs*)
    58   val pair: 'a -> 'b -> 'a * 'b
    59   val rpair: 'a -> 'b -> 'b * 'a
    60   val fst: 'a * 'b -> 'a
    61   val snd: 'a * 'b -> 'b
    62   val eq_fst: (''a * 'b) * (''a * 'c) -> bool
    63   val eq_snd: ('a * ''b) * ('c * ''b) -> bool
    64   val swap: 'a * 'b -> 'b * 'a
    65   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    66   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    67   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    68 
    69   (*booleans*)
    70   val equal: ''a -> ''a -> bool
    71   val not_equal: ''a -> ''a -> bool
    72   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    73   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    74   val exists: ('a -> bool) -> 'a list -> bool
    75   val forall: ('a -> bool) -> 'a list -> bool
    76   val set: bool ref -> bool
    77   val reset: bool ref -> bool
    78   val toggle: bool ref -> bool
    79   val change: 'a ref -> ('a -> 'a) -> unit
    80   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    81   val conditional: bool -> (unit -> unit) -> unit
    82 
    83   (*lists*)
    84   exception UnequalLengths
    85   val cons: 'a -> 'a list -> 'a list
    86   val single: 'a -> 'a list
    87   val append: 'a list -> 'a list -> 'a list
    88   val apply: ('a -> 'a) list -> 'a -> 'a
    89   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    90   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    91   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    92   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    93   val foldln: ('a * int -> 'b -> 'b) -> 'a list -> 'b -> 'b
    94   val unflat: 'a list list -> 'b list -> 'b list list
    95   val splitAt: int * 'a list -> 'a list * 'a list
    96   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    97   val map_nth_elem: int -> ('a -> 'a) -> 'a list -> 'a list
    98   val split_last: 'a list -> 'a list * 'a
    99   val nth_update: 'a -> int * 'a list -> 'a list
   100   val find_index: ('a -> bool) -> 'a list -> int
   101   val find_index_eq: ''a -> ''a list -> int
   102   val find_first: ('a -> bool) -> 'a list -> 'a option
   103   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   104   val separate: 'a -> 'a list -> 'a list
   105   val replicate: int -> 'a -> 'a list
   106   val multiply: 'a list * 'a list list -> 'a list list
   107   val product: 'a list -> 'b list -> ('a * 'b) list
   108   val filter: ('a -> bool) -> 'a list -> 'a list
   109   val filter_out: ('a -> bool) -> 'a list -> 'a list
   110   val map2: ('a * 'b -> 'c) -> 'a list * 'b list -> 'c list
   111   val exists2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   112   val forall2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   113   val seq2: ('a * 'b -> unit) -> 'a list * 'b list -> unit
   114   val ~~ : 'a list * 'b list -> ('a * 'b) list
   115   val split_list: ('a * 'b) list -> 'a list * 'b list
   116   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   117   val prefix: ''a list * ''a list -> bool
   118   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   119   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   120   val prefixes1: 'a list -> 'a list list
   121   val suffixes1: 'a list -> 'a list list
   122 
   123   (*integers*)
   124   val gcd: IntInf.int * IntInf.int -> IntInf.int
   125   val lcm: IntInf.int * IntInf.int -> IntInf.int
   126   val inc: int ref -> int
   127   val dec: int ref -> int
   128   val upto: int * int -> int list
   129   val downto: int * int -> int list
   130   val downto0: int list * int -> bool
   131   val radixpand: int * int -> int list
   132   val radixstring: int * string * int -> string
   133   val string_of_int: int -> string
   134   val string_of_indexname: string * int -> string
   135   val read_radixint: int * string list -> int * string list
   136   val read_int: string list -> int * string list
   137   val oct_char: string -> string
   138 
   139   (*rational numbers*)
   140   type rat
   141   exception RAT of string
   142   val rep_rat: rat -> IntInf.int * IntInf.int
   143   val ratadd: rat * rat -> rat
   144   val ratmul: rat * rat -> rat
   145   val ratinv: rat -> rat
   146   val int_ratdiv: IntInf.int * IntInf.int -> rat
   147   val ratneg: rat -> rat
   148   val rat_of_int: int -> rat
   149   val rat_of_intinf: IntInf.int -> rat
   150 
   151   (*strings*)
   152   val nth_elem_string: int * string -> string
   153   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   154   val exists_string: (string -> bool) -> string -> bool
   155   val forall_string: (string -> bool) -> string -> bool
   156   val enclose: string -> string -> string -> string
   157   val unenclose: string -> string
   158   val quote: string -> string
   159   val space_implode: string -> string list -> string
   160   val commas: string list -> string
   161   val commas_quote: string list -> string
   162   val cat_lines: string list -> string
   163   val space_explode: string -> string -> string list
   164   val split_lines: string -> string list
   165   val prefix_lines: string -> string -> string
   166   val untabify: string list -> string list
   167   val suffix: string -> string -> string
   168   val unsuffix: string -> string -> string
   169   val unprefix: string -> string -> string
   170   val replicate_string: int -> string -> string
   171   val translate_string: (string -> string) -> string -> string
   172 
   173   (*lists as sets*)
   174   val mem: ''a * ''a list -> bool
   175   val mem_int: int * int list -> bool
   176   val mem_string: string * string list -> bool
   177   val gen_mem: ('a * 'b -> bool) -> 'a * 'b list -> bool
   178   val ins: ''a * ''a list -> ''a list
   179   val ins_int: int * int list -> int list
   180   val ins_string: string * string list -> string list
   181   val gen_ins: ('a * 'a -> bool) -> 'a * 'a list -> 'a list
   182   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   183   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   184   val union: ''a list * ''a list -> ''a list
   185   val union_int: int list * int list -> int list
   186   val union_string: string list * string list -> string list
   187   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   188   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   189   val inter: ''a list * ''a list -> ''a list
   190   val inter_int: int list * int list -> int list
   191   val inter_string: string list * string list -> string list
   192   val subset: ''a list * ''a list -> bool
   193   val subset_int: int list * int list -> bool
   194   val subset_string: string list * string list -> bool
   195   val eq_set: ''a list * ''a list -> bool
   196   val eq_set_string: string list * string list -> bool
   197   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   198   val \ : ''a list * ''a -> ''a list
   199   val \\ : ''a list * ''a list -> ''a list
   200   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   201   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   202   val gen_distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   203   val distinct: ''a list -> ''a list
   204   val findrep: ''a list -> ''a list
   205   val gen_duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   206   val duplicates: ''a list -> ''a list
   207 
   208   (*association lists*)
   209   val assoc: (''a * 'b) list * ''a -> 'b option
   210   val assoc_int: (int * 'a) list * int -> 'a option
   211   val assoc_string: (string * 'a) list * string -> 'a option
   212   val assoc_string_int: ((string * int) * 'a) list * (string * int) -> 'a option
   213   val assocs: (''a * 'b list) list -> ''a -> 'b list
   214   val assoc2: (''a * (''b * 'c) list) list * (''a * ''b) -> 'c option
   215   val gen_assoc: ('a * 'b -> bool) -> ('b * 'c) list * 'a -> 'c option
   216   val overwrite: (''a * 'b) list * (''a * 'b) -> (''a * 'b) list
   217   val gen_overwrite: ('a * 'a -> bool) -> ('a * 'b) list * ('a * 'b) -> ('a * 'b) list
   218 
   219   (*lists as tables*)
   220   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   221   val gen_merge_lists': ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   222   val merge_lists: ''a list -> ''a list -> ''a list
   223   val merge_lists': ''a list -> ''a list -> ''a list
   224   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   225   val merge_alists': (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   226 
   227   (*balanced trees*)
   228   exception Balance
   229   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   230   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   231   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   232 
   233   (*orders*)
   234   val rev_order: order -> order
   235   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   236   val int_ord: int * int -> order
   237   val string_ord: string * string -> order
   238   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   239   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   240   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   241   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   242   val sort_strings: string list -> string list
   243   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   244   val unique_strings: string list -> string list
   245 
   246   (*random numbers*)
   247   exception RANDOM
   248   val random: unit -> real
   249   val random_range: int -> int -> int
   250   val one_of: 'a list -> 'a
   251   val frequency: (int * 'a) list -> 'a
   252 
   253   (*current directory*)
   254   val cd: string -> unit
   255   val pwd: unit -> string
   256 
   257   (*misc*)
   258   val make_keylist: ('a -> 'b) -> 'a list -> ('a * 'b) list
   259   val keyfilter: ('a * ''b) list -> ''b -> 'a list
   260   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   261   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   262   val gensym: string -> string
   263   val scanwords: (string -> bool) -> string list -> string list
   264 end;
   265 
   266 signature LIBRARY =
   267 sig
   268   include BASIC_LIBRARY
   269   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   270   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   271   val take: int * 'a list -> 'a list
   272   val drop: int * 'a list -> 'a list
   273   val nth_elem: int * 'a list -> 'a
   274   val last_elem: 'a list -> 'a
   275   val flat: 'a list list -> 'a list
   276   val seq: ('a -> unit) -> 'a list -> unit
   277   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   278   val mapfilter: ('a -> 'b option) -> 'a list -> 'b list
   279 end;
   280 
   281 structure Library: LIBRARY =
   282 struct
   283 
   284 
   285 (** functions **)
   286 
   287 (*handy combinators*)
   288 fun curry f x y = f (x, y);
   289 fun uncurry f (x, y) = f x y;
   290 fun I x = x;
   291 fun K x y = x;
   292 
   293 (*reverse apply*)
   294 fun (x |> f) = f x;
   295 fun ((x, y) |>> f) = (f x, y);
   296 fun ((x, y) |>>> f) = let val (x', z) = f x in (x', (y, z)) end;
   297 
   298 (*application of (infix) operator to its left or right argument*)
   299 fun apl (x, f) y = f (x, y);
   300 fun apr (f, y) x = f (x, y);
   301 
   302 (*function exponentiation: f(...(f x)...) with n applications of f*)
   303 fun funpow n f x =
   304   let fun rep (0, x) = x
   305         | rep (n, x) = rep (n - 1, f x)
   306   in rep (n, x) end;
   307 
   308 (*concatenation: 2 and 3 args*)
   309 fun (f oo g) x y = f (g x y);
   310 fun (f ooo g) x y z = f (g x y z);
   311 fun (f oooo g) x y z w = f (g x y z w);
   312 
   313 
   314 
   315 (** stamps **)
   316 
   317 type stamp = unit ref;
   318 val stamp: unit -> stamp = ref;
   319 
   320 
   321 
   322 (** options **)
   323 
   324 (*invalidate former constructors to prevent accidental use as match-all patterns!*)
   325 datatype invalid = None of invalid;
   326 exception OPTION of invalid;
   327 
   328 val the = Option.valOf;
   329 
   330 (*strict!*)
   331 fun if_none NONE y = y
   332   | if_none (SOME x) _ = x;
   333 
   334 fun is_some (SOME _) = true
   335   | is_some NONE = false;
   336 
   337 fun is_none (SOME _) = false
   338   | is_none NONE = true;
   339 
   340 
   341 (* exception handling *)
   342 
   343 exception ERROR;
   344 
   345 fun try f x = SOME (f x)
   346   handle Interrupt => raise Interrupt | ERROR => raise ERROR | _ => NONE;
   347 
   348 fun can f x = is_some (try f x);
   349 
   350 
   351 datatype 'a result =
   352   Result of 'a |
   353   Exn of exn;
   354 
   355 fun capture f x = Result (f x) handle e => Exn e;
   356 
   357 fun release (Result y) = y
   358   | release (Exn e) = raise e;
   359 
   360 fun get_result (Result x) = SOME x
   361   | get_result _ = NONE;
   362 
   363 fun get_exn (Exn exn) = SOME exn
   364   | get_exn _ = NONE;
   365 
   366 
   367 
   368 (** pairs **)
   369 
   370 fun pair x y = (x, y);
   371 fun rpair x y = (y, x);
   372 
   373 fun fst (x, y) = x;
   374 fun snd (x, y) = y;
   375 
   376 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
   377 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
   378 
   379 fun swap (x, y) = (y, x);
   380 
   381 (*apply function to components*)
   382 fun apfst f (x, y) = (f x, y);
   383 fun apsnd f (x, y) = (x, f y);
   384 fun pairself f (x, y) = (f x, f y);
   385 
   386 
   387 
   388 (** booleans **)
   389 
   390 (* equality *)
   391 
   392 fun equal x y = x = y;
   393 fun not_equal x y = x <> y;
   394 
   395 
   396 (* operators for combining predicates *)
   397 
   398 fun (p orf q) = fn x => p x orelse q x;
   399 fun (p andf q) = fn x => p x andalso q x;
   400 
   401 
   402 (* predicates on lists *)
   403 
   404 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   405 fun exists (pred: 'a -> bool) : 'a list -> bool =
   406   let fun boolf [] = false
   407         | boolf (x :: xs) = pred x orelse boolf xs
   408   in boolf end;
   409 
   410 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   411 fun forall (pred: 'a -> bool) : 'a list -> bool =
   412   let fun boolf [] = true
   413         | boolf (x :: xs) = pred x andalso boolf xs
   414   in boolf end;
   415 
   416 
   417 (* flags *)
   418 
   419 fun set flag = (flag := true; true);
   420 fun reset flag = (flag := false; false);
   421 fun toggle flag = (flag := not (! flag); ! flag);
   422 
   423 fun change r f = r := f (! r);
   424 
   425 (*temporarily set flag, handling exceptions*)
   426 fun setmp flag value f x =
   427   let
   428     val orig_value = ! flag;
   429     fun return y = (flag := orig_value; y);
   430   in
   431     flag := value;
   432     return (f x handle exn => (return (); raise exn))
   433   end;
   434 
   435 
   436 (* conditional execution *)
   437 
   438 fun conditional b f = if b then f () else ();
   439 
   440 
   441 
   442 (** lists **)
   443 
   444 exception UnequalLengths;
   445 
   446 fun cons x xs = x :: xs;
   447 fun single x = [x];
   448 
   449 fun append xs ys = xs @ ys;
   450 
   451 fun apply [] x = x
   452   | apply (f :: fs) x = apply fs (f x);
   453 
   454 
   455 (* fold *)
   456 
   457 fun fold _ [] y = y
   458   | fold f (x :: xs) y = fold f xs (f x y);
   459 
   460 fun fold_rev _ [] y = y
   461   | fold_rev f (x :: xs) y = f x (fold_rev f xs y);
   462 
   463 fun foldl_map _ (x, []) = (x, [])
   464   | foldl_map f (x, y :: ys) =
   465       let
   466         val (x', y') = f (x, y);
   467         val (x'', ys') = foldl_map f (x', ys);
   468       in (x'', y' :: ys') end;
   469 
   470 (*the following versions of fold are designed to fit nicely with infixes*)
   471 
   472 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   473     for operators that associate to the left (TAIL RECURSIVE)*)
   474 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   475   let fun itl (e, [])  = e
   476         | itl (e, a::l) = itl (f(e, a), l)
   477   in  itl end;
   478 
   479 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   480     for operators that associate to the right (not tail recursive)*)
   481 fun foldr f (l, e) =
   482   let fun itr [] = e
   483         | itr (a::l) = f(a, itr l)
   484   in  itr l  end;
   485 
   486 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   487     for n > 0, operators that associate to the right (not tail recursive)*)
   488 fun foldr1 f l =
   489   let fun itr [x] = x
   490         | itr (x::l) = f(x, itr l)
   491   in  itr l  end;
   492 
   493 fun foldln f xs e = fst (foldl (fn ((e,i), x) => (f (x,i) e, i+1)) ((e,1),xs));
   494 
   495 
   496 (* basic list functions *)
   497 
   498 (*take the first n elements from a list*)
   499 fun take (n, []) = []
   500   | take (n, x :: xs) =
   501       if n > 0 then x :: take (n - 1, xs) else [];
   502 
   503 (*drop the first n elements from a list*)
   504 fun drop (n, []) = []
   505   | drop (n, x :: xs) =
   506       if n > 0 then drop (n - 1, xs) else x :: xs;
   507 
   508 fun splitAt(n,[]) = ([],[])
   509   | splitAt(n,xs as x::ys) =
   510       if n>0 then let val (ps,qs) = splitAt(n-1,ys) in (x::ps,qs) end
   511       else ([],xs)
   512 
   513 fun dropwhile P [] = []
   514   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   515 
   516 (*return nth element of a list, where 0 designates the first element;
   517   raise EXCEPTION if list too short*)
   518 fun nth_elem (i,xs) = List.nth(xs,i);
   519 
   520 fun map_nth_elem 0 f (x :: xs) = f x :: xs
   521   | map_nth_elem n f (x :: xs) = x :: map_nth_elem (n - 1) f xs
   522   | map_nth_elem _ _ [] = raise Subscript;
   523 
   524 (*last element of a list*)
   525 val last_elem = List.last;
   526 
   527 (*rear decomposition*)
   528 fun split_last [] = raise Empty
   529   | split_last [x] = ([], x)
   530   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   531 
   532 (*update nth element*)
   533 fun nth_update x n_xs =
   534     (case splitAt n_xs of
   535       (_,[]) => raise Subscript
   536     | (prfx, _ :: sffx') => prfx @ (x :: sffx'))
   537 
   538 (*find the position of an element in a list*)
   539 fun find_index pred =
   540   let fun find _ [] = ~1
   541         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   542   in find 0 end;
   543 
   544 fun find_index_eq x = find_index (equal x);
   545 
   546 (*find first element satisfying predicate*)
   547 fun find_first _ [] = NONE
   548   | find_first pred (x :: xs) =
   549       if pred x then SOME x else find_first pred xs;
   550 
   551 (*get first element by lookup function*)
   552 fun get_first _ [] = NONE
   553   | get_first f (x :: xs) =
   554       (case f x of
   555         NONE => get_first f xs
   556       | some => some);
   557 
   558 (*flatten a list of lists to a list*)
   559 val flat = List.concat;
   560 
   561 fun unflat (xs :: xss) ys =
   562       let val (ps,qs) = splitAt(length xs,ys)
   563       in ps :: unflat xss qs end
   564   | unflat [] [] = []
   565   | unflat _ _ = raise UnequalLengths;
   566 
   567 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   568   (proc x1; ...; proc xn) for side effects*)
   569 val seq = List.app;
   570 
   571 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   572 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   573   | separate _ xs = xs;
   574 
   575 (*make the list [x, x, ..., x] of length n*)
   576 fun replicate n (x: 'a) : 'a list =
   577   let fun rep (0, xs) = xs
   578         | rep (n, xs) = rep (n - 1, x :: xs)
   579   in
   580     if n < 0 then raise Subscript
   581     else rep (n, [])
   582   end;
   583 
   584 fun translate_string f = String.translate (f o String.str);
   585 
   586 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   587 fun multiply ([], _) = []
   588   | multiply (x :: xs, yss) = map (cons x) yss @ multiply (xs, yss);
   589 
   590 (*direct product*)
   591 fun product _ [] = []
   592   | product [] _ = []
   593   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   594 
   595 
   596 (* filter *)
   597 
   598 (*copy the list preserving elements that satisfy the predicate*)
   599 val filter = List.filter;
   600 fun filter_out f = filter (not o f);
   601 val mapfilter = List.mapPartial;
   602 
   603 
   604 (* lists of pairs *)
   605 
   606 exception UnequalLengths;
   607 
   608 fun map2 _ ([], []) = []
   609   | map2 f (x :: xs, y :: ys) = (f (x, y) :: map2 f (xs, ys))
   610   | map2 _ _ = raise UnequalLengths;
   611 
   612 fun exists2 _ ([], []) = false
   613   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   614   | exists2 _ _ = raise UnequalLengths;
   615 
   616 fun forall2 _ ([], []) = true
   617   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   618   | forall2 _ _ = raise UnequalLengths;
   619 
   620 fun seq2 _ ([], []) = ()
   621   | seq2 f (x :: xs, y :: ys) = (f (x, y); seq2 f (xs, ys))
   622   | seq2 _ _ = raise UnequalLengths;
   623 
   624 (*combine two lists forming a list of pairs:
   625   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   626 fun [] ~~ [] = []
   627   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   628   | _ ~~ _ = raise UnequalLengths;
   629 
   630 (*inverse of ~~; the old 'split':
   631   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   632 val split_list = ListPair.unzip;
   633 
   634 fun equal_lists eq (xs, ys) = length xs = length ys andalso forall2 eq (xs, ys);
   635 
   636 
   637 (* prefixes, suffixes *)
   638 
   639 fun [] prefix _ = true
   640   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   641   | _ prefix _ = false;
   642 
   643 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   644    where xi is the first element that does not satisfy the predicate*)
   645 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   646   let fun take (rxs, []) = (rev rxs, [])
   647         | take (rxs, x :: xs) =
   648             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   649   in  take([], xs)  end;
   650 
   651 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   652    where xi is the last element that does not satisfy the predicate*)
   653 fun take_suffix _ [] = ([], [])
   654   | take_suffix pred (x :: xs) =
   655       (case take_suffix pred xs of
   656         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   657       | (prfx, sffx) => (x :: prfx, sffx));
   658 
   659 fun prefixes1 [] = []
   660   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   661 
   662 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   663 
   664 
   665 
   666 (** integers **)
   667 
   668 fun gcd(x,y) =
   669   let fun gxd x y : IntInf.int =
   670     if y = 0 then x else gxd y (x mod y)
   671   in if x < y then gxd y x else gxd x y end;
   672 
   673 fun lcm(x,y) = (x * y) div gcd(x,y);
   674 
   675 fun inc i = (i := ! i + 1; ! i);
   676 fun dec i = (i := ! i - 1; ! i);
   677 
   678 
   679 (* lists of integers *)
   680 
   681 (*make the list [from, from + 1, ..., to]*)
   682 fun (from upto to) =
   683   if from > to then [] else from :: ((from + 1) upto to);
   684 
   685 (*make the list [from, from - 1, ..., to]*)
   686 fun (from downto to) =
   687   if from < to then [] else from :: ((from - 1) downto to);
   688 
   689 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   690 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   691   | downto0 ([], n) = n = ~1;
   692 
   693 
   694 (* convert integers to strings *)
   695 
   696 (*expand the number in the given base;
   697   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   698 fun radixpand (base, num) : int list =
   699   let
   700     fun radix (n, tail) =
   701       if n < base then n :: tail
   702       else radix (n div base, (n mod base) :: tail)
   703   in radix (num, []) end;
   704 
   705 (*expands a number into a string of characters starting from "zerochar";
   706   example: radixstring (2, "0", 8) gives "1000"*)
   707 fun radixstring (base, zerochar, num) =
   708   let val offset = ord zerochar;
   709       fun chrof n = chr (offset + n)
   710   in implode (map chrof (radixpand (base, num))) end;
   711 
   712 
   713 val string_of_int = Int.toString;
   714 
   715 fun string_of_indexname (a,0) = a
   716   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   717 
   718 
   719 (* read integers *)
   720 
   721 fun read_radixint (radix: int, cs) : int * string list =
   722   let val zero = ord"0"
   723       val limit = zero+radix
   724       fun scan (num,[]) = (num,[])
   725         | scan (num, c::cs) =
   726               if  zero <= ord c  andalso  ord c < limit
   727               then scan(radix*num + ord c - zero, cs)
   728               else (num, c::cs)
   729   in  scan(0,cs)  end;
   730 
   731 fun read_int cs = read_radixint (10, cs);
   732 
   733 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   734 
   735 
   736 
   737 (** strings **)
   738 
   739 (* functions tuned for strings, avoiding explode *)
   740 
   741 fun nth_elem_string (i, str) =
   742   (case try String.substring (str, i, 1) of
   743     SOME s => s
   744   | NONE => raise Subscript);
   745 
   746 fun fold_string f str x0 =
   747   let
   748     val n = size str;
   749     fun iter (x, i) =
   750       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   751   in iter (x0, 0) end;
   752 
   753 fun exists_string pred str =
   754   let
   755     val n = size str;
   756     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   757   in ex 0 end;
   758 
   759 fun forall_string pred = not o exists_string (not o pred);
   760 
   761 (*enclose in brackets*)
   762 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   763 fun unenclose str = String.substring (str, 1, size str - 2);
   764 
   765 (*simple quoting (does not escape special chars)*)
   766 val quote = enclose "\"" "\"";
   767 
   768 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   769 fun space_implode a bs = implode (separate a bs);
   770 
   771 val commas = space_implode ", ";
   772 val commas_quote = commas o map quote;
   773 
   774 (*concatenate messages, one per line, into a string*)
   775 val cat_lines = space_implode "\n";
   776 
   777 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   778 fun space_explode _ "" = []
   779   | space_explode sep str =
   780       let
   781         fun expl chs =
   782           (case take_prefix (not_equal sep) chs of
   783             (cs, []) => [implode cs]
   784           | (cs, _ :: cs') => implode cs :: expl cs');
   785       in expl (explode str) end;
   786 
   787 val split_lines = space_explode "\n";
   788 
   789 fun prefix_lines "" txt = txt
   790   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   791 
   792 fun untabify chs =
   793   let
   794     val tab_width = 8;
   795 
   796     fun untab (_, "\n") = (0, ["\n"])
   797       | untab (pos, "\t") =
   798           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   799       | untab (pos, c) = (pos + 1, [c]);
   800   in
   801     if not (exists (equal "\t") chs) then chs
   802     else flat (#2 (foldl_map untab (0, chs)))
   803   end;
   804 
   805 fun suffix sffx s = s ^ sffx;
   806 
   807 fun unsuffix sffx s =
   808   let val m = size sffx; val n = size s - m in
   809     if n >= 0 andalso String.substring (s, n, m) = sffx then String.substring (s, 0, n)
   810     else raise Fail "unsuffix"
   811   end;
   812 
   813 fun unprefix prfx s =
   814   let val m = size prfx; val n = size s - m in
   815     if String.isPrefix prfx s then String.substring (s, m, n)
   816     else raise Fail "unprefix"
   817   end;
   818 
   819 fun replicate_string 0 _ = ""
   820   | replicate_string 1 a = a
   821   | replicate_string k a =
   822       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   823       else replicate_string (k div 2) (a ^ a) ^ a;
   824 
   825 
   826 
   827 (** lists as sets **)
   828 
   829 (*membership in a list*)
   830 fun x mem [] = false
   831   | x mem (y :: ys) = x = y orelse x mem ys;
   832 
   833 (*membership in a list, optimized version for ints*)
   834 fun (x:int) mem_int [] = false
   835   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   836 
   837 (*membership in a list, optimized version for strings*)
   838 fun (x:string) mem_string [] = false
   839   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   840 
   841 (*generalized membership test*)
   842 fun gen_mem eq (x, []) = false
   843   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   844 
   845 (*insert and remove*)
   846 fun insert eq x xs = if gen_mem eq (x, xs) then xs else x :: xs;
   847 fun remove eq x xs = if gen_mem eq (x, xs) then filter_out (fn y => eq (x, y)) xs else xs;
   848 
   849 (*insertion into list if not already there*)
   850 fun (x ins xs) = if x mem xs then xs else x :: xs;
   851 
   852 (*insertion into list, optimized version for ints*)
   853 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   854 
   855 (*insertion into list, optimized version for strings*)
   856 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   857 
   858 (*generalized insertion*)
   859 fun gen_ins eq (x, xs) = insert eq x xs;
   860 
   861 (*union of sets represented as lists: no repetitions*)
   862 fun xs union [] = xs
   863   | [] union ys = ys
   864   | (x :: xs) union ys = xs union (x ins ys);
   865 
   866 (*union of sets, optimized version for ints*)
   867 fun (xs:int list) union_int [] = xs
   868   | [] union_int ys = ys
   869   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   870 
   871 (*union of sets, optimized version for strings*)
   872 fun (xs:string list) union_string [] = xs
   873   | [] union_string ys = ys
   874   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   875 
   876 (*generalized union*)
   877 fun gen_union eq (xs, []) = xs
   878   | gen_union eq ([], ys) = ys
   879   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   880 
   881 
   882 (*intersection*)
   883 fun [] inter ys = []
   884   | (x :: xs) inter ys =
   885       if x mem ys then x :: (xs inter ys) else xs inter ys;
   886 
   887 (*intersection, optimized version for ints*)
   888 fun ([]:int list) inter_int ys = []
   889   | (x :: xs) inter_int ys =
   890       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   891 
   892 (*intersection, optimized version for strings *)
   893 fun ([]:string list) inter_string ys = []
   894   | (x :: xs) inter_string ys =
   895       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   896 
   897 (*generalized intersection*)
   898 fun gen_inter eq ([], ys) = []
   899   | gen_inter eq (x::xs, ys) =
   900       if gen_mem eq (x,ys) then x :: gen_inter eq (xs, ys)
   901                            else      gen_inter eq (xs, ys);
   902 
   903 
   904 (*subset*)
   905 fun [] subset ys = true
   906   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   907 
   908 (*subset, optimized version for ints*)
   909 fun ([]:int list) subset_int ys = true
   910   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   911 
   912 (*subset, optimized version for strings*)
   913 fun ([]:string list) subset_string ys = true
   914   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   915 
   916 (*set equality*)
   917 fun eq_set (xs, ys) =
   918   xs = ys orelse (xs subset ys andalso ys subset xs);
   919 
   920 (*set equality for strings*)
   921 fun eq_set_string ((xs:string list), ys) =
   922   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   923 
   924 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   925 
   926 
   927 (*removing an element from a list WITHOUT duplicates*)
   928 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   929   | [] \ x = [];
   930 
   931 fun ys \\ xs = foldl (op \) (ys,xs);
   932 
   933 (*removing an element from a list -- possibly WITH duplicates*)
   934 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   935 fun gen_rems eq (xs, ys) = filter_out (fn x => gen_mem eq (x, ys)) xs;
   936 
   937 (*makes a list of the distinct members of the input; preserves order, takes
   938   first of equal elements*)
   939 fun gen_distinct eq lst =
   940   let
   941     val memb = gen_mem eq;
   942 
   943     fun dist (rev_seen, []) = rev rev_seen
   944       | dist (rev_seen, x :: xs) =
   945           if memb (x, rev_seen) then dist (rev_seen, xs)
   946           else dist (x :: rev_seen, xs);
   947   in
   948     dist ([], lst)
   949   end;
   950 
   951 fun distinct l = gen_distinct (op =) l;
   952 
   953 
   954 (*returns the tail beginning with the first repeated element, or []*)
   955 fun findrep [] = []
   956   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   957 
   958 
   959 (*returns a list containing all repeated elements exactly once; preserves
   960   order, takes first of equal elements*)
   961 fun gen_duplicates eq lst =
   962   let
   963     val memb = gen_mem eq;
   964 
   965     fun dups (rev_dups, []) = rev rev_dups
   966       | dups (rev_dups, x :: xs) =
   967           if memb (x, rev_dups) orelse not (memb (x, xs)) then
   968             dups (rev_dups, xs)
   969           else dups (x :: rev_dups, xs);
   970   in
   971     dups ([], lst)
   972   end;
   973 
   974 fun duplicates l = gen_duplicates (op =) l;
   975 
   976 
   977 
   978 (** association lists **)
   979 
   980 (*association list lookup*)
   981 fun assoc ([], key) = NONE
   982   | assoc ((keyi, xi) :: pairs, key) =
   983       if key = keyi then SOME xi else assoc (pairs, key);
   984 
   985 (*association list lookup, optimized version for ints*)
   986 fun assoc_int ([], (key:int)) = NONE
   987   | assoc_int ((keyi, xi) :: pairs, key) =
   988       if key = keyi then SOME xi else assoc_int (pairs, key);
   989 
   990 (*association list lookup, optimized version for strings*)
   991 fun assoc_string ([], (key:string)) = NONE
   992   | assoc_string ((keyi, xi) :: pairs, key) =
   993       if key = keyi then SOME xi else assoc_string (pairs, key);
   994 
   995 (*association list lookup, optimized version for string*ints*)
   996 fun assoc_string_int ([], (key:string*int)) = NONE
   997   | assoc_string_int ((keyi, xi) :: pairs, key) =
   998       if key = keyi then SOME xi else assoc_string_int (pairs, key);
   999 
  1000 fun assocs ps x =
  1001   (case assoc (ps, x) of
  1002     NONE => []
  1003   | SOME ys => ys);
  1004 
  1005 (*two-fold association list lookup*)
  1006 fun assoc2 (aal, (key1, key2)) =
  1007   (case assoc (aal, key1) of
  1008     SOME al => assoc (al, key2)
  1009   | NONE => NONE);
  1010 
  1011 (*generalized association list lookup*)
  1012 fun gen_assoc eq ([], key) = NONE
  1013   | gen_assoc eq ((keyi, xi) :: pairs, key) =
  1014       if eq (key, keyi) then SOME xi else gen_assoc eq (pairs, key);
  1015 
  1016 (*association list update*)
  1017 fun overwrite (al, p as (key, _)) =
  1018   let fun over ((q as (keyi, _)) :: pairs) =
  1019             if keyi = key then p :: pairs else q :: (over pairs)
  1020         | over [] = [p]
  1021   in over al end;
  1022 
  1023 fun gen_overwrite eq (al, p as (key, _)) =
  1024   let fun over ((q as (keyi, _)) :: pairs) =
  1025             if eq (keyi, key) then p :: pairs else q :: (over pairs)
  1026         | over [] = [p]
  1027   in over al end;
  1028 
  1029 
  1030 (* lists as tables *)
  1031 
  1032 fun gen_merge_lists _ xs [] = xs
  1033   | gen_merge_lists _ [] ys = ys
  1034   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1035 
  1036 fun gen_merge_lists' _ xs [] = xs
  1037   | gen_merge_lists' _ [] ys = ys
  1038   | gen_merge_lists' eq xs ys = gen_rems eq (ys, xs) @ xs;
  1039 
  1040 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1041 fun merge_lists' xs ys = gen_merge_lists' (op =) xs ys;
  1042 fun merge_alists al = gen_merge_lists eq_fst al;
  1043 fun merge_alists' al = gen_merge_lists' eq_fst al;
  1044 
  1045 
  1046 
  1047 (** balanced trees **)
  1048 
  1049 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1050 
  1051 (*balanced folding; avoids deep nesting*)
  1052 fun fold_bal f [x] = x
  1053   | fold_bal f [] = raise Balance
  1054   | fold_bal f xs =
  1055       let val (ps,qs) = splitAt(length xs div 2, xs)
  1056       in  f (fold_bal f ps, fold_bal f qs)  end;
  1057 
  1058 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1059 fun access_bal (f, g, x) n i =
  1060   let fun acc n i =     (*1<=i<=n*)
  1061           if n=1 then x else
  1062           let val n2 = n div 2
  1063           in  if i<=n2 then f (acc n2 i)
  1064                        else g (acc (n-n2) (i-n2))
  1065           end
  1066   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1067 
  1068 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1069 fun accesses_bal (f, g, x) n =
  1070   let fun acc n =
  1071           if n=1 then [x] else
  1072           let val n2 = n div 2
  1073               val acc2 = acc n2
  1074           in  if n-n2=n2 then map f acc2 @ map g acc2
  1075                          else map f acc2 @ map g (acc (n-n2)) end
  1076   in  if 1<=n then acc n else raise Balance  end;
  1077 
  1078 
  1079 
  1080 (** orders **)
  1081 
  1082 fun rev_order LESS = GREATER
  1083   | rev_order EQUAL = EQUAL
  1084   | rev_order GREATER = LESS;
  1085 
  1086 (*assume rel is a linear strict order*)
  1087 fun make_ord rel (x, y) =
  1088   if rel (x, y) then LESS
  1089   else if rel (y, x) then GREATER
  1090   else EQUAL;
  1091 
  1092 val int_ord = Int.compare;
  1093 val string_ord = String.compare;
  1094 
  1095 (*lexicographic product*)
  1096 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1097   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1098 
  1099 (*dictionary order -- in general NOT well-founded!*)
  1100 fun dict_ord _ ([], []) = EQUAL
  1101   | dict_ord _ ([], _ :: _) = LESS
  1102   | dict_ord _ (_ :: _, []) = GREATER
  1103   | dict_ord elem_ord (x :: xs, y :: ys) =
  1104       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1105 
  1106 (*lexicographic product of lists*)
  1107 fun list_ord elem_ord (xs, ys) =
  1108   prod_ord int_ord (dict_ord elem_ord) ((length xs, xs), (length ys, ys));
  1109 
  1110 
  1111 (* sorting *)
  1112 
  1113 (*quicksort (stable, i.e. does not reorder equal elements)*)
  1114 fun sort ord =
  1115   let
  1116     fun qsort xs =
  1117       let val len = length xs in
  1118         if len <= 1 then xs
  1119         else
  1120           let val (lts, eqs, gts) = part (nth_elem (len div 2, xs)) xs in
  1121             qsort lts @ eqs @ qsort gts
  1122           end
  1123       end
  1124     and part _ [] = ([], [], [])
  1125       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1126     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1127       | add EQUAL x (lts, eqs, gts) = (lts, x :: eqs, gts)
  1128       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1129   in qsort end;
  1130 
  1131 (*sort strings*)
  1132 val sort_strings = sort string_ord;
  1133 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1134 
  1135 fun unique_strings ([]: string list) = []
  1136   | unique_strings [x] = [x]
  1137   | unique_strings (x :: y :: ys) =
  1138       if x = y then unique_strings (y :: ys)
  1139       else x :: unique_strings (y :: ys);
  1140 
  1141 
  1142 (** random numbers **)
  1143 
  1144 exception RANDOM;
  1145 
  1146 fun rmod x y = x - y * Real.realFloor (x / y);
  1147 
  1148 local
  1149   val a = 16807.0;
  1150   val m = 2147483647.0;
  1151   val random_seed = ref 1.0;
  1152 in
  1153 
  1154 fun random () =
  1155   let val r = rmod (a * !random_seed) m
  1156   in (random_seed := r; r) end;
  1157 
  1158 end;
  1159 
  1160 fun random_range l h =
  1161   if h < l orelse l < 0 then raise RANDOM
  1162   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1163 
  1164 fun one_of xs = nth_elem (random_range 0 (length xs - 1), xs);
  1165 
  1166 fun frequency xs =
  1167   let
  1168     val sum = foldl op + (0, map fst xs);
  1169     fun pick n ((k, x) :: xs) =
  1170       if n <= k then x else pick (n - k) xs
  1171   in pick (random_range 1 sum) xs end;
  1172 
  1173 
  1174 (** current directory **)
  1175 
  1176 val cd = OS.FileSys.chDir;
  1177 val pwd = OS.FileSys.getDir;
  1178 
  1179 
  1180 
  1181 (** rational numbers **)
  1182 
  1183 datatype rat = Rat of bool * IntInf.int * IntInf.int
  1184 
  1185 exception RAT of string;
  1186 
  1187 fun rep_rat(Rat(a,p,q)) = (if a then p else ~p,q)
  1188 
  1189 fun ratnorm(a,p,q) = if p=0 then Rat(a,0,1) else
  1190   let val absp = abs p
  1191       val m = gcd(absp,q)
  1192   in Rat(a = (0 <= p), absp div m, q div m) end;
  1193 
  1194 fun ratadd(Rat(a,p,q),Rat(b,r,s)) =
  1195   let val den = lcm(q,s)
  1196       val p = p*(den div q) and r = r*(den div s)
  1197       val num = (if a then p else ~p) + (if b then r else ~r)
  1198   in ratnorm(true,num,den) end;
  1199 
  1200 fun ratmul(Rat(a,p,q),Rat(b,r,s)) = ratnorm(a=b,p*r,q*s)
  1201 
  1202 fun ratinv(Rat(a,p,q)) = if p=0 then raise RAT "ratinv" else Rat(a,q,p)
  1203 
  1204 fun int_ratdiv(p,q) =
  1205   if q=0 then raise RAT "int_ratdiv" else ratnorm(0<=q, p, abs q)
  1206 
  1207 fun ratneg(Rat(b,p,q)) = Rat(not b,p,q);
  1208 
  1209 fun rat_of_intinf i = if i < 0 then Rat(false,abs i,1) else Rat(true,i,1);
  1210 
  1211 fun rat_of_int i = rat_of_intinf (IntInf.fromInt i);
  1212 
  1213 
  1214 (** misc **)
  1215 
  1216 (*use the keyfun to make a list of (x, key) pairs*)
  1217 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
  1218   let fun keypair x = (x, keyfun x)
  1219   in map keypair end;
  1220 
  1221 (*given a list of (x, key) pairs and a searchkey
  1222   return the list of xs from each pair whose key equals searchkey*)
  1223 fun keyfilter [] searchkey = []
  1224   | keyfilter ((x, key) :: pairs) searchkey =
  1225       if key = searchkey then x :: keyfilter pairs searchkey
  1226       else keyfilter pairs searchkey;
  1227 
  1228 
  1229 (*Partition list into elements that satisfy predicate and those that don't.
  1230   Preserves order of elements in both lists.*)
  1231 val partition = List.partition;
  1232 
  1233 
  1234 fun partition_eq (eq:'a * 'a -> bool) =
  1235     let fun part [] = []
  1236           | part (x::ys) = let val (xs, xs') = partition (apl(x, eq)) ys
  1237                            in (x::xs)::(part xs') end
  1238     in part end;
  1239 
  1240 
  1241 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1242    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1243 fun partition_list p i j =
  1244   let fun part k xs =
  1245             if k>j then
  1246               (case xs of [] => []
  1247                          | _ => raise Fail "partition_list")
  1248             else
  1249             let val (ns, rest) = partition (p k) xs;
  1250             in  ns :: part(k+1)rest  end
  1251   in  part i end;
  1252 
  1253 
  1254 (* generating identifiers *)
  1255 
  1256 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1257 local
  1258 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1259 fun char i =      if i<26 then chr (ord "A" + i)
  1260              else if i<52 then chr (ord "a" + i - 26)
  1261              else if i<62 then chr (ord"0" + i - 52)
  1262              else if i=62 then "_"
  1263              else  (*i=63*)    "'";
  1264 
  1265 val charVec = Vector.tabulate (64, char);
  1266 
  1267 fun newid n =
  1268   let
  1269   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1270 
  1271 val seedr = ref 0;
  1272 
  1273 in
  1274 
  1275 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1276 
  1277 end;
  1278 
  1279 
  1280 (* lexical scanning *)
  1281 
  1282 (*scan a list of characters into "words" composed of "letters" (recognized by
  1283   is_let) and separated by any number of non-"letters"*)
  1284 fun scanwords is_let cs =
  1285   let fun scan1 [] = []
  1286         | scan1 cs =
  1287             let val (lets, rest) = take_prefix is_let cs
  1288             in implode lets :: scanwords is_let rest end;
  1289   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1290 
  1291 
  1292 end;
  1293 
  1294 structure BasicLibrary: BASIC_LIBRARY = Library;
  1295 open BasicLibrary;