src/HOL/Imperative_HOL/Heap_Monad.thy
author haftmann
Fri Jul 23 10:58:13 2010 +0200 (2010-07-23)
changeset 37947 844977c7abeb
parent 37878 d016aaead7a2
child 37964 0a1ae22df1f1
permissions -rw-r--r--
avoid unreliable Haskell Int type
     1 (*  Title:      HOL/Imperative_HOL/Heap_Monad.thy
     2     Author:     John Matthews, Galois Connections; Alexander Krauss, Lukas Bulwahn & Florian Haftmann, TU Muenchen
     3 *)
     4 
     5 header {* A monad with a polymorphic heap and primitive reasoning infrastructure *}
     6 
     7 theory Heap_Monad
     8 imports Heap Monad_Syntax
     9 begin
    10 
    11 subsection {* The monad *}
    12 
    13 subsubsection {* Monad construction *}
    14 
    15 text {* Monadic heap actions either produce values
    16   and transform the heap, or fail *}
    17 datatype 'a Heap = Heap "heap \<Rightarrow> ('a \<times> heap) option"
    18 
    19 primrec execute :: "'a Heap \<Rightarrow> heap \<Rightarrow> ('a \<times> heap) option" where
    20   [code del]: "execute (Heap f) = f"
    21 
    22 lemma Heap_cases [case_names succeed fail]:
    23   fixes f and h
    24   assumes succeed: "\<And>x h'. execute f h = Some (x, h') \<Longrightarrow> P"
    25   assumes fail: "execute f h = None \<Longrightarrow> P"
    26   shows P
    27   using assms by (cases "execute f h") auto
    28 
    29 lemma Heap_execute [simp]:
    30   "Heap (execute f) = f" by (cases f) simp_all
    31 
    32 lemma Heap_eqI:
    33   "(\<And>h. execute f h = execute g h) \<Longrightarrow> f = g"
    34     by (cases f, cases g) (auto simp: expand_fun_eq)
    35 
    36 ML {* structure Execute_Simps = Named_Thms(
    37   val name = "execute_simps"
    38   val description = "simplification rules for execute"
    39 ) *}
    40 
    41 setup Execute_Simps.setup
    42 
    43 lemma execute_Let [execute_simps]:
    44   "execute (let x = t in f x) = (let x = t in execute (f x))"
    45   by (simp add: Let_def)
    46 
    47 
    48 subsubsection {* Specialised lifters *}
    49 
    50 definition tap :: "(heap \<Rightarrow> 'a) \<Rightarrow> 'a Heap" where
    51   [code del]: "tap f = Heap (\<lambda>h. Some (f h, h))"
    52 
    53 lemma execute_tap [execute_simps]:
    54   "execute (tap f) h = Some (f h, h)"
    55   by (simp add: tap_def)
    56 
    57 definition heap :: "(heap \<Rightarrow> 'a \<times> heap) \<Rightarrow> 'a Heap" where
    58   [code del]: "heap f = Heap (Some \<circ> f)"
    59 
    60 lemma execute_heap [execute_simps]:
    61   "execute (heap f) = Some \<circ> f"
    62   by (simp add: heap_def)
    63 
    64 definition guard :: "(heap \<Rightarrow> bool) \<Rightarrow> (heap \<Rightarrow> 'a \<times> heap) \<Rightarrow> 'a Heap" where
    65   [code del]: "guard P f = Heap (\<lambda>h. if P h then Some (f h) else None)"
    66 
    67 lemma execute_guard [execute_simps]:
    68   "\<not> P h \<Longrightarrow> execute (guard P f) h = None"
    69   "P h \<Longrightarrow> execute (guard P f) h = Some (f h)"
    70   by (simp_all add: guard_def)
    71 
    72 
    73 subsubsection {* Predicate classifying successful computations *}
    74 
    75 definition success :: "'a Heap \<Rightarrow> heap \<Rightarrow> bool" where
    76   "success f h \<longleftrightarrow> execute f h \<noteq> None"
    77 
    78 lemma successI:
    79   "execute f h \<noteq> None \<Longrightarrow> success f h"
    80   by (simp add: success_def)
    81 
    82 lemma successE:
    83   assumes "success f h"
    84   obtains r h' where "r = fst (the (execute c h))"
    85     and "h' = snd (the (execute c h))"
    86     and "execute f h \<noteq> None"
    87   using assms by (simp add: success_def)
    88 
    89 ML {* structure Success_Intros = Named_Thms(
    90   val name = "success_intros"
    91   val description = "introduction rules for success"
    92 ) *}
    93 
    94 setup Success_Intros.setup
    95 
    96 lemma success_tapI [success_intros]:
    97   "success (tap f) h"
    98   by (rule successI) (simp add: execute_simps)
    99 
   100 lemma success_heapI [success_intros]:
   101   "success (heap f) h"
   102   by (rule successI) (simp add: execute_simps)
   103 
   104 lemma success_guardI [success_intros]:
   105   "P h \<Longrightarrow> success (guard P f) h"
   106   by (rule successI) (simp add: execute_guard)
   107 
   108 lemma success_LetI [success_intros]:
   109   "x = t \<Longrightarrow> success (f x) h \<Longrightarrow> success (let x = t in f x) h"
   110   by (simp add: Let_def)
   111 
   112 lemma success_ifI:
   113   "(c \<Longrightarrow> success t h) \<Longrightarrow> (\<not> c \<Longrightarrow> success e h) \<Longrightarrow>
   114     success (if c then t else e) h"
   115   by (simp add: success_def)
   116 
   117 
   118 subsubsection {* Predicate for a simple relational calculus *}
   119 
   120 text {*
   121   The @{text crel} predicate states that when a computation @{text c}
   122   runs with the heap @{text h} will result in return value @{text r}
   123   and a heap @{text "h'"}, i.e.~no exception occurs.
   124 *}  
   125 
   126 definition crel :: "'a Heap \<Rightarrow> heap \<Rightarrow> heap \<Rightarrow> 'a \<Rightarrow> bool" where
   127   crel_def: "crel c h h' r \<longleftrightarrow> execute c h = Some (r, h')"
   128 
   129 lemma crelI:
   130   "execute c h = Some (r, h') \<Longrightarrow> crel c h h' r"
   131   by (simp add: crel_def)
   132 
   133 lemma crelE:
   134   assumes "crel c h h' r"
   135   obtains "r = fst (the (execute c h))"
   136     and "h' = snd (the (execute c h))"
   137     and "success c h"
   138 proof (rule that)
   139   from assms have *: "execute c h = Some (r, h')" by (simp add: crel_def)
   140   then show "success c h" by (simp add: success_def)
   141   from * have "fst (the (execute c h)) = r" and "snd (the (execute c h)) = h'"
   142     by simp_all
   143   then show "r = fst (the (execute c h))"
   144     and "h' = snd (the (execute c h))" by simp_all
   145 qed
   146 
   147 lemma crel_success:
   148   "crel c h h' r \<Longrightarrow> success c h"
   149   by (simp add: crel_def success_def)
   150 
   151 lemma success_crelE:
   152   assumes "success c h"
   153   obtains r h' where "crel c h h' r"
   154   using assms by (auto simp add: crel_def success_def)
   155 
   156 lemma crel_deterministic:
   157   assumes "crel f h h' a"
   158     and "crel f h h'' b"
   159   shows "a = b" and "h' = h''"
   160   using assms unfolding crel_def by auto
   161 
   162 ML {* structure Crel_Intros = Named_Thms(
   163   val name = "crel_intros"
   164   val description = "introduction rules for crel"
   165 ) *}
   166 
   167 ML {* structure Crel_Elims = Named_Thms(
   168   val name = "crel_elims"
   169   val description = "elimination rules for crel"
   170 ) *}
   171 
   172 setup "Crel_Intros.setup #> Crel_Elims.setup"
   173 
   174 lemma crel_LetI [crel_intros]:
   175   assumes "x = t" "crel (f x) h h' r"
   176   shows "crel (let x = t in f x) h h' r"
   177   using assms by simp
   178 
   179 lemma crel_LetE [crel_elims]:
   180   assumes "crel (let x = t in f x) h h' r"
   181   obtains "crel (f t) h h' r"
   182   using assms by simp
   183 
   184 lemma crel_ifI:
   185   assumes "c \<Longrightarrow> crel t h h' r"
   186     and "\<not> c \<Longrightarrow> crel e h h' r"
   187   shows "crel (if c then t else e) h h' r"
   188   by (cases c) (simp_all add: assms)
   189 
   190 lemma crel_ifE:
   191   assumes "crel (if c then t else e) h h' r"
   192   obtains "c" "crel t h h' r"
   193     | "\<not> c" "crel e h h' r"
   194   using assms by (cases c) simp_all
   195 
   196 lemma crel_tapI [crel_intros]:
   197   assumes "h' = h" "r = f h"
   198   shows "crel (tap f) h h' r"
   199   by (rule crelI) (simp add: assms execute_simps)
   200 
   201 lemma crel_tapE [crel_elims]:
   202   assumes "crel (tap f) h h' r"
   203   obtains "h' = h" and "r = f h"
   204   using assms by (rule crelE) (auto simp add: execute_simps)
   205 
   206 lemma crel_heapI [crel_intros]:
   207   assumes "h' = snd (f h)" "r = fst (f h)"
   208   shows "crel (heap f) h h' r"
   209   by (rule crelI) (simp add: assms execute_simps)
   210 
   211 lemma crel_heapE [crel_elims]:
   212   assumes "crel (heap f) h h' r"
   213   obtains "h' = snd (f h)" and "r = fst (f h)"
   214   using assms by (rule crelE) (simp add: execute_simps)
   215 
   216 lemma crel_guardI [crel_intros]:
   217   assumes "P h" "h' = snd (f h)" "r = fst (f h)"
   218   shows "crel (guard P f) h h' r"
   219   by (rule crelI) (simp add: assms execute_simps)
   220 
   221 lemma crel_guardE [crel_elims]:
   222   assumes "crel (guard P f) h h' r"
   223   obtains "h' = snd (f h)" "r = fst (f h)" "P h"
   224   using assms by (rule crelE)
   225     (auto simp add: execute_simps elim!: successE, cases "P h", auto simp add: execute_simps)
   226 
   227 
   228 subsubsection {* Monad combinators *}
   229 
   230 definition return :: "'a \<Rightarrow> 'a Heap" where
   231   [code del]: "return x = heap (Pair x)"
   232 
   233 lemma execute_return [execute_simps]:
   234   "execute (return x) = Some \<circ> Pair x"
   235   by (simp add: return_def execute_simps)
   236 
   237 lemma success_returnI [success_intros]:
   238   "success (return x) h"
   239   by (rule successI) (simp add: execute_simps)
   240 
   241 lemma crel_returnI [crel_intros]:
   242   "h = h' \<Longrightarrow> crel (return x) h h' x"
   243   by (rule crelI) (simp add: execute_simps)
   244 
   245 lemma crel_returnE [crel_elims]:
   246   assumes "crel (return x) h h' r"
   247   obtains "r = x" "h' = h"
   248   using assms by (rule crelE) (simp add: execute_simps)
   249 
   250 definition raise :: "string \<Rightarrow> 'a Heap" where -- {* the string is just decoration *}
   251   [code del]: "raise s = Heap (\<lambda>_. None)"
   252 
   253 lemma execute_raise [execute_simps]:
   254   "execute (raise s) = (\<lambda>_. None)"
   255   by (simp add: raise_def)
   256 
   257 lemma crel_raiseE [crel_elims]:
   258   assumes "crel (raise x) h h' r"
   259   obtains "False"
   260   using assms by (rule crelE) (simp add: success_def execute_simps)
   261 
   262 definition bind :: "'a Heap \<Rightarrow> ('a \<Rightarrow> 'b Heap) \<Rightarrow> 'b Heap" where
   263   [code del]: "bind f g = Heap (\<lambda>h. case execute f h of
   264                   Some (x, h') \<Rightarrow> execute (g x) h'
   265                 | None \<Rightarrow> None)"
   266 
   267 setup {*
   268   Adhoc_Overloading.add_variant 
   269     @{const_name Monad_Syntax.bind} @{const_name Heap_Monad.bind}
   270 *}
   271 
   272 lemma execute_bind [execute_simps]:
   273   "execute f h = Some (x, h') \<Longrightarrow> execute (f \<guillemotright>= g) h = execute (g x) h'"
   274   "execute f h = None \<Longrightarrow> execute (f \<guillemotright>= g) h = None"
   275   by (simp_all add: bind_def)
   276 
   277 lemma execute_bind_success:
   278   "success f h \<Longrightarrow> execute (f \<guillemotright>= g) h = execute (g (fst (the (execute f h)))) (snd (the (execute f h)))"
   279   by (cases f h rule: Heap_cases) (auto elim!: successE simp add: bind_def)
   280 
   281 lemma success_bind_executeI:
   282   "execute f h = Some (x, h') \<Longrightarrow> success (g x) h' \<Longrightarrow> success (f \<guillemotright>= g) h"
   283   by (auto intro!: successI elim!: successE simp add: bind_def)
   284 
   285 lemma success_bind_crelI [success_intros]:
   286   "crel f h h' x \<Longrightarrow> success (g x) h' \<Longrightarrow> success (f \<guillemotright>= g) h"
   287   by (auto simp add: crel_def success_def bind_def)
   288 
   289 lemma crel_bindI [crel_intros]:
   290   assumes "crel f h h' r" "crel (g r) h' h'' r'"
   291   shows "crel (f \<guillemotright>= g) h h'' r'"
   292   using assms
   293   apply (auto intro!: crelI elim!: crelE successE)
   294   apply (subst execute_bind, simp_all)
   295   done
   296 
   297 lemma crel_bindE [crel_elims]:
   298   assumes "crel (f \<guillemotright>= g) h h'' r'"
   299   obtains h' r where "crel f h h' r" "crel (g r) h' h'' r'"
   300   using assms by (auto simp add: crel_def bind_def split: option.split_asm)
   301 
   302 lemma execute_bind_eq_SomeI:
   303   assumes "execute f h = Some (x, h')"
   304     and "execute (g x) h' = Some (y, h'')"
   305   shows "execute (f \<guillemotright>= g) h = Some (y, h'')"
   306   using assms by (simp add: bind_def)
   307 
   308 lemma return_bind [simp]: "return x \<guillemotright>= f = f x"
   309   by (rule Heap_eqI) (simp add: execute_bind execute_simps)
   310 
   311 lemma bind_return [simp]: "f \<guillemotright>= return = f"
   312   by (rule Heap_eqI) (simp add: bind_def execute_simps split: option.splits)
   313 
   314 lemma bind_bind [simp]: "(f \<guillemotright>= g) \<guillemotright>= k = (f :: 'a Heap) \<guillemotright>= (\<lambda>x. g x \<guillemotright>= k)"
   315   by (rule Heap_eqI) (simp add: bind_def execute_simps split: option.splits)
   316 
   317 lemma raise_bind [simp]: "raise e \<guillemotright>= f = raise e"
   318   by (rule Heap_eqI) (simp add: execute_simps)
   319 
   320 
   321 subsection {* Generic combinators *}
   322 
   323 subsubsection {* Assertions *}
   324 
   325 definition assert :: "('a \<Rightarrow> bool) \<Rightarrow> 'a \<Rightarrow> 'a Heap" where
   326   "assert P x = (if P x then return x else raise ''assert'')"
   327 
   328 lemma execute_assert [execute_simps]:
   329   "P x \<Longrightarrow> execute (assert P x) h = Some (x, h)"
   330   "\<not> P x \<Longrightarrow> execute (assert P x) h = None"
   331   by (simp_all add: assert_def execute_simps)
   332 
   333 lemma success_assertI [success_intros]:
   334   "P x \<Longrightarrow> success (assert P x) h"
   335   by (rule successI) (simp add: execute_assert)
   336 
   337 lemma crel_assertI [crel_intros]:
   338   "P x \<Longrightarrow> h' = h \<Longrightarrow> r = x \<Longrightarrow> crel (assert P x) h h' r"
   339   by (rule crelI) (simp add: execute_assert)
   340  
   341 lemma crel_assertE [crel_elims]:
   342   assumes "crel (assert P x) h h' r"
   343   obtains "P x" "r = x" "h' = h"
   344   using assms by (rule crelE) (cases "P x", simp_all add: execute_assert success_def)
   345 
   346 lemma assert_cong [fundef_cong]:
   347   assumes "P = P'"
   348   assumes "\<And>x. P' x \<Longrightarrow> f x = f' x"
   349   shows "(assert P x >>= f) = (assert P' x >>= f')"
   350   by (rule Heap_eqI) (insert assms, simp add: assert_def)
   351 
   352 
   353 subsubsection {* Plain lifting *}
   354 
   355 definition lift :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b Heap" where
   356   "lift f = return o f"
   357 
   358 lemma lift_collapse [simp]:
   359   "lift f x = return (f x)"
   360   by (simp add: lift_def)
   361 
   362 lemma bind_lift:
   363   "(f \<guillemotright>= lift g) = (f \<guillemotright>= (\<lambda>x. return (g x)))"
   364   by (simp add: lift_def comp_def)
   365 
   366 
   367 subsubsection {* Iteration -- warning: this is rarely useful! *}
   368 
   369 primrec fold_map :: "('a \<Rightarrow> 'b Heap) \<Rightarrow> 'a list \<Rightarrow> 'b list Heap" where
   370   "fold_map f [] = return []"
   371 | "fold_map f (x # xs) = do {
   372      y \<leftarrow> f x;
   373      ys \<leftarrow> fold_map f xs;
   374      return (y # ys)
   375    }"
   376 
   377 lemma fold_map_append:
   378   "fold_map f (xs @ ys) = fold_map f xs \<guillemotright>= (\<lambda>xs. fold_map f ys \<guillemotright>= (\<lambda>ys. return (xs @ ys)))"
   379   by (induct xs) simp_all
   380 
   381 lemma execute_fold_map_unchanged_heap [execute_simps]:
   382   assumes "\<And>x. x \<in> set xs \<Longrightarrow> \<exists>y. execute (f x) h = Some (y, h)"
   383   shows "execute (fold_map f xs) h =
   384     Some (List.map (\<lambda>x. fst (the (execute (f x) h))) xs, h)"
   385 using assms proof (induct xs)
   386   case Nil show ?case by (simp add: execute_simps)
   387 next
   388   case (Cons x xs)
   389   from Cons.prems obtain y
   390     where y: "execute (f x) h = Some (y, h)" by auto
   391   moreover from Cons.prems Cons.hyps have "execute (fold_map f xs) h =
   392     Some (map (\<lambda>x. fst (the (execute (f x) h))) xs, h)" by auto
   393   ultimately show ?case by (simp, simp only: execute_bind(1), simp add: execute_simps)
   394 qed
   395 
   396 subsection {* Code generator setup *}
   397 
   398 subsubsection {* Logical intermediate layer *}
   399 
   400 primrec raise' :: "String.literal \<Rightarrow> 'a Heap" where
   401   [code del, code_post]: "raise' (STR s) = raise s"
   402 
   403 lemma raise_raise' [code_inline]:
   404   "raise s = raise' (STR s)"
   405   by simp
   406 
   407 code_datatype raise' -- {* avoid @{const "Heap"} formally *}
   408 
   409 
   410 subsubsection {* SML and OCaml *}
   411 
   412 code_type Heap (SML "unit/ ->/ _")
   413 code_const bind (SML "!(fn/ f'_/ =>/ fn/ ()/ =>/ f'_/ (_/ ())/ ())")
   414 code_const return (SML "!(fn/ ()/ =>/ _)")
   415 code_const Heap_Monad.raise' (SML "!(raise/ Fail/ _)")
   416 
   417 code_type Heap (OCaml "unit/ ->/ _")
   418 code_const bind (OCaml "!(fun/ f'_/ ()/ ->/ f'_/ (_/ ())/ ())")
   419 code_const return (OCaml "!(fun/ ()/ ->/ _)")
   420 code_const Heap_Monad.raise' (OCaml "failwith")
   421 
   422 
   423 subsubsection {* Haskell *}
   424 
   425 text {* Adaption layer *}
   426 
   427 code_include Haskell "Heap"
   428 {*import qualified Control.Monad;
   429 import qualified Control.Monad.ST;
   430 import qualified Data.STRef;
   431 import qualified Data.Array.ST;
   432 
   433 type RealWorld = Control.Monad.ST.RealWorld;
   434 type ST s a = Control.Monad.ST.ST s a;
   435 type STRef s a = Data.STRef.STRef s a;
   436 type STArray s a = Data.Array.ST.STArray s Integer a;
   437 
   438 newSTRef = Data.STRef.newSTRef;
   439 readSTRef = Data.STRef.readSTRef;
   440 writeSTRef = Data.STRef.writeSTRef;
   441 
   442 newArray :: Integer -> a -> ST s (STArray s a);
   443 newArray k = Data.Array.ST.newArray (0, k);
   444 
   445 newListArray :: [a] -> ST s (STArray s a);
   446 newListArray xs = Data.Array.ST.newListArray (0, toInteger (length xs)) xs;
   447 
   448 newFunArray :: Integer -> (Integer -> a) -> ST s (STArray s a);
   449 newFunArray k f = Data.Array.ST.newListArray (0, k) (map f [0..k-1]);
   450 
   451 lengthArray :: STArray s a -> ST s Integer;
   452 lengthArray a = Control.Monad.liftM snd (Data.Array.ST.getBounds a);
   453 
   454 readArray :: STArray s a -> Integer -> ST s a;
   455 readArray = Data.Array.ST.readArray;
   456 
   457 writeArray :: STArray s a -> Integer -> a -> ST s ();
   458 writeArray = Data.Array.ST.writeArray;*}
   459 
   460 code_reserved Haskell Heap
   461 
   462 text {* Monad *}
   463 
   464 code_type Heap (Haskell "Heap.ST/ Heap.RealWorld/ _")
   465 code_monad bind Haskell
   466 code_const return (Haskell "return")
   467 code_const Heap_Monad.raise' (Haskell "error")
   468 
   469 
   470 subsubsection {* Scala *}
   471 
   472 code_include Scala "Heap"
   473 {*def bind[A, B](f: Unit => A, g: A => Unit => B): Unit => B = (_: Unit) => g (f ()) ()
   474 
   475 class Ref[A](x: A) {
   476   var value = x
   477 }
   478 
   479 object Ref {
   480   def apply[A](x: A): Ref[A] = new Ref[A](x)
   481 }
   482 
   483 def lookup[A](r: Ref[A]): A = r.value
   484 
   485 def update[A](r: Ref[A], x: A): Unit = { r.value = x }*}
   486 
   487 code_reserved Scala Heap
   488 
   489 code_type Heap (Scala "Unit/ =>/ _")
   490 code_const bind (Scala "bind")
   491 code_const return (Scala "('_: Unit)/ =>/ _")
   492 code_const Heap_Monad.raise' (Scala "!error((_))")
   493 
   494 
   495 subsubsection {* Target variants with less units *}
   496 
   497 setup {*
   498 
   499 let
   500 
   501 open Code_Thingol;
   502 
   503 fun imp_program naming =
   504 
   505   let
   506     fun is_const c = case lookup_const naming c
   507      of SOME c' => (fn c'' => c' = c'')
   508       | NONE => K false;
   509     val is_bind = is_const @{const_name bind};
   510     val is_return = is_const @{const_name return};
   511     val dummy_name = "";
   512     val dummy_type = ITyVar dummy_name;
   513     val dummy_case_term = IVar NONE;
   514     (*assumption: dummy values are not relevant for serialization*)
   515     val unitt = case lookup_const naming @{const_name Unity}
   516      of SOME unit' => IConst (unit', (([], []), []))
   517       | NONE => error ("Must include " ^ @{const_name Unity} ^ " in generated constants.");
   518     fun dest_abs ((v, ty) `|=> t, _) = ((v, ty), t)
   519       | dest_abs (t, ty) =
   520           let
   521             val vs = fold_varnames cons t [];
   522             val v = Name.variant vs "x";
   523             val ty' = (hd o fst o unfold_fun) ty;
   524           in ((SOME v, ty'), t `$ IVar (SOME v)) end;
   525     fun force (t as IConst (c, _) `$ t') = if is_return c
   526           then t' else t `$ unitt
   527       | force t = t `$ unitt;
   528     fun tr_bind' [(t1, _), (t2, ty2)] =
   529       let
   530         val ((v, ty), t) = dest_abs (t2, ty2);
   531       in ICase (((force t1, ty), [(IVar v, tr_bind'' t)]), dummy_case_term) end
   532     and tr_bind'' t = case unfold_app t
   533          of (IConst (c, (_, ty1 :: ty2 :: _)), [x1, x2]) => if is_bind c
   534               then tr_bind' [(x1, ty1), (x2, ty2)]
   535               else force t
   536           | _ => force t;
   537     fun imp_monad_bind'' ts = (SOME dummy_name, dummy_type) `|=> ICase (((IVar (SOME dummy_name), dummy_type),
   538       [(unitt, tr_bind' ts)]), dummy_case_term)
   539     and imp_monad_bind' (const as (c, (_, tys))) ts = if is_bind c then case (ts, tys)
   540        of ([t1, t2], ty1 :: ty2 :: _) => imp_monad_bind'' [(t1, ty1), (t2, ty2)]
   541         | ([t1, t2, t3], ty1 :: ty2 :: _) => imp_monad_bind'' [(t1, ty1), (t2, ty2)] `$ t3
   542         | (ts, _) => imp_monad_bind (eta_expand 2 (const, ts))
   543       else IConst const `$$ map imp_monad_bind ts
   544     and imp_monad_bind (IConst const) = imp_monad_bind' const []
   545       | imp_monad_bind (t as IVar _) = t
   546       | imp_monad_bind (t as _ `$ _) = (case unfold_app t
   547          of (IConst const, ts) => imp_monad_bind' const ts
   548           | (t, ts) => imp_monad_bind t `$$ map imp_monad_bind ts)
   549       | imp_monad_bind (v_ty `|=> t) = v_ty `|=> imp_monad_bind t
   550       | imp_monad_bind (ICase (((t, ty), pats), t0)) = ICase
   551           (((imp_monad_bind t, ty),
   552             (map o pairself) imp_monad_bind pats),
   553               imp_monad_bind t0);
   554 
   555   in (Graph.map_nodes o map_terms_stmt) imp_monad_bind end;
   556 
   557 in
   558 
   559 Code_Target.extend_target ("SML_imp", ("SML", imp_program))
   560 #> Code_Target.extend_target ("OCaml_imp", ("OCaml", imp_program))
   561 #> Code_Target.extend_target ("Scala_imp", ("Scala", imp_program))
   562 
   563 end
   564 
   565 *}
   566 
   567 
   568 hide_const (open) Heap heap guard raise' fold_map
   569 
   570 end