src/Pure/proofterm.ML
author wenzelm
Fri Mar 21 20:33:56 2014 +0100 (2014-03-21)
changeset 56245 84fc7dfa3cd4
parent 52696 38466f4f3483
child 59058 a78612c67ec0
permissions -rw-r--r--
more qualified names;
     1 (*  Title:      Pure/proofterm.ML
     2     Author:     Stefan Berghofer, TU Muenchen
     3 
     4 LF style proof terms.
     5 *)
     6 
     7 infix 8 % %% %>;
     8 
     9 signature BASIC_PROOFTERM =
    10 sig
    11   val proofs: int Unsynchronized.ref
    12 
    13   datatype proof =
    14      MinProof
    15    | PBound of int
    16    | Abst of string * typ option * proof
    17    | AbsP of string * term option * proof
    18    | op % of proof * term option
    19    | op %% of proof * proof
    20    | Hyp of term
    21    | PAxm of string * term * typ list option
    22    | OfClass of typ * class
    23    | Oracle of string * term * typ list option
    24    | Promise of serial * term * typ list
    25    | PThm of serial * ((string * term * typ list option) * proof_body future)
    26   and proof_body = PBody of
    27     {oracles: (string * term) Ord_List.T,
    28      thms: (serial * (string * term * proof_body future)) Ord_List.T,
    29      proof: proof}
    30 
    31   val %> : proof * term -> proof
    32 end;
    33 
    34 signature PROOFTERM =
    35 sig
    36   include BASIC_PROOFTERM
    37 
    38   type oracle = string * term
    39   type pthm = serial * (string * term * proof_body future)
    40   val proof_of: proof_body -> proof
    41   val join_proof: proof_body future -> proof
    42   val fold_proof_atoms: bool -> (proof -> 'a -> 'a) -> proof list -> 'a -> 'a
    43   val fold_body_thms: (string * term * proof_body -> 'a -> 'a) -> proof_body list -> 'a -> 'a
    44   val join_bodies: proof_body list -> unit
    45   val peek_status: proof_body list -> {failed: bool, oracle: bool, unfinished: bool}
    46 
    47   val oracle_ord: oracle * oracle -> order
    48   val thm_ord: pthm * pthm -> order
    49   val unions_oracles: oracle Ord_List.T list -> oracle Ord_List.T
    50   val unions_thms: pthm Ord_List.T list -> pthm Ord_List.T
    51   val all_oracles_of: proof_body -> oracle Ord_List.T
    52   val approximate_proof_body: proof -> proof_body
    53   val no_proof_body: proof_body
    54   val no_thm_proofs: proof -> proof
    55 
    56   val encode: proof XML.Encode.T
    57   val encode_body: proof_body XML.Encode.T
    58   val decode: proof XML.Decode.T
    59   val decode_body: proof_body XML.Decode.T
    60 
    61   (** primitive operations **)
    62   val proofs_enabled: unit -> bool
    63   val proof_combt: proof * term list -> proof
    64   val proof_combt': proof * term option list -> proof
    65   val proof_combP: proof * proof list -> proof
    66   val strip_combt: proof -> proof * term option list
    67   val strip_combP: proof -> proof * proof list
    68   val strip_thm: proof_body -> proof_body
    69   val map_proof_same: term Same.operation -> typ Same.operation
    70     -> (typ * class -> proof) -> proof Same.operation
    71   val map_proof_terms_same: term Same.operation -> typ Same.operation -> proof Same.operation
    72   val map_proof_types_same: typ Same.operation -> proof Same.operation
    73   val map_proof_terms: (term -> term) -> (typ -> typ) -> proof -> proof
    74   val map_proof_types: (typ -> typ) -> proof -> proof
    75   val fold_proof_terms: (term -> 'a -> 'a) -> (typ -> 'a -> 'a) -> proof -> 'a -> 'a
    76   val maxidx_proof: proof -> int -> int
    77   val size_of_proof: proof -> int
    78   val change_type: typ list option -> proof -> proof
    79   val prf_abstract_over: term -> proof -> proof
    80   val prf_incr_bv: int -> int -> int -> int -> proof -> proof
    81   val incr_pboundvars: int -> int -> proof -> proof
    82   val prf_loose_bvar1: proof -> int -> bool
    83   val prf_loose_Pbvar1: proof -> int -> bool
    84   val prf_add_loose_bnos: int -> int -> proof -> int list * int list -> int list * int list
    85   val norm_proof: Envir.env -> proof -> proof
    86   val norm_proof': Envir.env -> proof -> proof
    87   val prf_subst_bounds: term list -> proof -> proof
    88   val prf_subst_pbounds: proof list -> proof -> proof
    89   val freeze_thaw_prf: proof -> proof * (proof -> proof)
    90 
    91   (** proof terms for specific inference rules **)
    92   val implies_intr_proof: term -> proof -> proof
    93   val implies_intr_proof': term -> proof -> proof
    94   val forall_intr_proof: term -> string -> proof -> proof
    95   val forall_intr_proof': term -> proof -> proof
    96   val varify_proof: term -> (string * sort) list -> proof -> proof
    97   val legacy_freezeT: term -> proof -> proof
    98   val rotate_proof: term list -> term -> int -> proof -> proof
    99   val permute_prems_proof: term list -> int -> int -> proof -> proof
   100   val generalize: string list * string list -> int -> proof -> proof
   101   val instantiate: ((indexname * sort) * typ) list * ((indexname * typ) * term) list
   102     -> proof -> proof
   103   val lift_proof: term -> int -> term -> proof -> proof
   104   val incr_indexes: int -> proof -> proof
   105   val assumption_proof: term list -> term -> int -> proof -> proof
   106   val bicompose_proof: bool -> term list -> term list -> term list -> term option ->
   107     int -> int -> proof -> proof -> proof
   108   val equality_axms: (string * term) list
   109   val reflexive_axm: proof
   110   val symmetric_axm: proof
   111   val transitive_axm: proof
   112   val equal_intr_axm: proof
   113   val equal_elim_axm: proof
   114   val abstract_rule_axm: proof
   115   val combination_axm: proof
   116   val reflexive: proof
   117   val symmetric: proof -> proof
   118   val transitive: term -> typ -> proof -> proof -> proof
   119   val abstract_rule: term -> string -> proof -> proof
   120   val combination: term -> term -> term -> term -> typ -> proof -> proof -> proof
   121   val equal_intr: term -> term -> proof -> proof -> proof
   122   val equal_elim: term -> term -> proof -> proof -> proof
   123   val strip_shyps_proof: Sorts.algebra -> (typ * sort) list -> (typ * sort) list ->
   124     sort list -> proof -> proof
   125   val classrel_proof: theory -> class * class -> proof
   126   val arity_proof: theory -> string * sort list * class -> proof
   127   val of_sort_proof: theory -> (typ * class -> proof) -> typ * sort -> proof list
   128   val install_axclass_proofs:
   129    {classrel_proof: theory -> class * class -> proof,
   130     arity_proof: theory -> string * sort list * class -> proof} -> unit
   131   val axm_proof: string -> term -> proof
   132   val oracle_proof: string -> term -> oracle * proof
   133 
   134   (** rewriting on proof terms **)
   135   val add_prf_rrule: proof * proof -> theory -> theory
   136   val add_prf_rproc: (typ list -> term option list -> proof -> (proof * proof) option) -> theory -> theory
   137   val no_skel: proof
   138   val normal_skel: proof
   139   val rewrite_proof: theory -> (proof * proof) list *
   140     (typ list -> term option list -> proof -> (proof * proof) option) list -> proof -> proof
   141   val rewrite_proof_notypes: (proof * proof) list *
   142     (typ list -> term option list -> proof -> (proof * proof) option) list -> proof -> proof
   143   val rew_proof: theory -> proof -> proof
   144 
   145   val promise_proof: theory -> serial -> term -> proof
   146   val fulfill_norm_proof: theory -> (serial * proof_body) list -> proof_body -> proof_body
   147   val thm_proof: theory -> string -> sort list -> term list -> term ->
   148     (serial * proof_body future) list -> proof_body -> pthm * proof
   149   val unconstrain_thm_proof: theory -> sort list -> term ->
   150     (serial * proof_body future) list -> proof_body -> pthm * proof
   151   val get_name: sort list -> term list -> term -> proof -> string
   152   val guess_name: proof -> string
   153 end
   154 
   155 structure Proofterm : PROOFTERM =
   156 struct
   157 
   158 (***** datatype proof *****)
   159 
   160 datatype proof =
   161    MinProof
   162  | PBound of int
   163  | Abst of string * typ option * proof
   164  | AbsP of string * term option * proof
   165  | op % of proof * term option
   166  | op %% of proof * proof
   167  | Hyp of term
   168  | PAxm of string * term * typ list option
   169  | OfClass of typ * class
   170  | Oracle of string * term * typ list option
   171  | Promise of serial * term * typ list
   172  | PThm of serial * ((string * term * typ list option) * proof_body future)
   173 and proof_body = PBody of
   174   {oracles: (string * term) Ord_List.T,
   175    thms: (serial * (string * term * proof_body future)) Ord_List.T,
   176    proof: proof};
   177 
   178 type oracle = string * term;
   179 type pthm = serial * (string * term * proof_body future);
   180 
   181 fun proof_of (PBody {proof, ...}) = proof;
   182 val join_proof = Future.join #> proof_of;
   183 
   184 fun join_thms (thms: pthm list) = ignore (Future.joins (map (#3 o #2) thms));
   185 
   186 
   187 (***** proof atoms *****)
   188 
   189 fun fold_proof_atoms all f =
   190   let
   191     fun app (Abst (_, _, prf)) = app prf
   192       | app (AbsP (_, _, prf)) = app prf
   193       | app (prf % _) = app prf
   194       | app (prf1 %% prf2) = app prf1 #> app prf2
   195       | app (prf as PThm (i, (_, body))) = (fn (x, seen) =>
   196           if Inttab.defined seen i then (x, seen)
   197           else
   198             let val (x', seen') =
   199               (if all then app (join_proof body) else I) (x, Inttab.update (i, ()) seen)
   200             in (f prf x', seen') end)
   201       | app prf = (fn (x, seen) => (f prf x, seen));
   202   in fn prfs => fn x => #1 (fold app prfs (x, Inttab.empty)) end;
   203 
   204 fun fold_body_thms f =
   205   let
   206     fun app (PBody {thms, ...}) =
   207       tap join_thms thms |> fold (fn (i, (name, prop, body)) => fn (x, seen) =>
   208         if Inttab.defined seen i then (x, seen)
   209         else
   210           let
   211             val body' = Future.join body;
   212             val (x', seen') = app body' (x, Inttab.update (i, ()) seen);
   213           in (f (name, prop, body') x', seen') end);
   214   in fn bodies => fn x => #1 (fold app bodies (x, Inttab.empty)) end;
   215 
   216 fun join_bodies bodies = fold_body_thms (fn _ => fn () => ()) bodies ();
   217 
   218 fun peek_status bodies =
   219   let
   220     fun status (PBody {oracles, thms, ...}) x =
   221       let
   222         val ((oracle, unfinished, failed), seen) =
   223           (thms, x) |-> fold (fn (i, (_, _, body)) => fn (st, seen) =>
   224             if Inttab.defined seen i then (st, seen)
   225             else
   226               let val seen' = Inttab.update (i, ()) seen in
   227                 (case Future.peek body of
   228                   SOME (Exn.Res body') => status body' (st, seen')
   229                 | SOME (Exn.Exn _) =>
   230                     let val (oracle, unfinished, _) = st
   231                     in ((oracle, unfinished, true), seen') end
   232                 | NONE =>
   233                     let val (oracle, _, failed) = st
   234                     in ((oracle, true, failed), seen') end)
   235               end);
   236       in ((oracle orelse not (null oracles), unfinished, failed), seen) end;
   237     val (oracle, unfinished, failed) =
   238       #1 (fold status bodies ((false, false, false), Inttab.empty));
   239   in {oracle = oracle, unfinished = unfinished, failed = failed} end;
   240 
   241 
   242 (* proof body *)
   243 
   244 val oracle_ord = prod_ord fast_string_ord Term_Ord.fast_term_ord;
   245 fun thm_ord ((i, _): pthm, (j, _)) = int_ord (j, i);
   246 
   247 val unions_oracles = Ord_List.unions oracle_ord;
   248 val unions_thms = Ord_List.unions thm_ord;
   249 
   250 val all_oracles_of =
   251   let
   252     fun collect (PBody {oracles, thms, ...}) =
   253       tap join_thms thms |> fold (fn (i, (_, _, body)) => fn (x, seen) =>
   254         if Inttab.defined seen i then (x, seen)
   255         else
   256           let
   257             val body' = Future.join body;
   258             val (x', seen') = collect body' (x, Inttab.update (i, ()) seen);
   259           in (if null oracles then x' else oracles :: x', seen') end);
   260   in fn body => unions_oracles (#1 (collect body ([], Inttab.empty))) end;
   261 
   262 fun approximate_proof_body prf =
   263   let
   264     val (oracles, thms) = fold_proof_atoms false
   265       (fn Oracle (s, prop, _) => apfst (cons (s, prop))
   266         | PThm (i, ((name, prop, _), body)) => apsnd (cons (i, (name, prop, body)))
   267         | _ => I) [prf] ([], []);
   268   in
   269     PBody
   270      {oracles = Ord_List.make oracle_ord oracles,
   271       thms = Ord_List.make thm_ord thms,
   272       proof = prf}
   273   end;
   274 
   275 val no_proof_body = PBody {oracles = [], thms = [], proof = MinProof};
   276 val no_body = Future.value no_proof_body;
   277 
   278 fun no_thm_proofs (PThm (i, (a, _))) = PThm (i, (a, no_body))
   279   | no_thm_proofs (Abst (x, T, prf)) = Abst (x, T, no_thm_proofs prf)
   280   | no_thm_proofs (AbsP (x, t, prf)) = AbsP (x, t, no_thm_proofs prf)
   281   | no_thm_proofs (prf % t) = no_thm_proofs prf % t
   282   | no_thm_proofs (prf1 %% prf2) = no_thm_proofs prf1 %% no_thm_proofs prf2
   283   | no_thm_proofs a = a;
   284 
   285 
   286 (***** XML data representation *****)
   287 
   288 (* encode *)
   289 
   290 local
   291 
   292 open XML.Encode Term_XML.Encode;
   293 
   294 fun proof prf = prf |> variant
   295  [fn MinProof => ([], []),
   296   fn PBound a => ([int_atom a], []),
   297   fn Abst (a, b, c) => ([a], pair (option typ) proof (b, c)),
   298   fn AbsP (a, b, c) => ([a], pair (option term) proof (b, c)),
   299   fn a % b => ([], pair proof (option term) (a, b)),
   300   fn a %% b => ([], pair proof proof (a, b)),
   301   fn Hyp a => ([], term a),
   302   fn PAxm (a, b, c) => ([a], pair term (option (list typ)) (b, c)),
   303   fn OfClass (a, b) => ([b], typ a),
   304   fn Oracle (a, b, c) => ([a], pair term (option (list typ)) (b, c)),
   305   fn Promise (a, b, c) => ([int_atom a], pair term (list typ) (b, c)),
   306   fn PThm (a, ((b, c, d), body)) =>
   307     ([int_atom a, b], triple term (option (list typ)) proof_body (c, d, Future.join body))]
   308 and proof_body (PBody {oracles, thms, proof = prf}) =
   309   triple (list (pair string term)) (list pthm) proof (oracles, thms, prf)
   310 and pthm (a, (b, c, body)) =
   311   pair int (triple string term proof_body) (a, (b, c, Future.join body));
   312 
   313 in
   314 
   315 val encode = proof;
   316 val encode_body = proof_body;
   317 
   318 end;
   319 
   320 
   321 (* decode *)
   322 
   323 local
   324 
   325 open XML.Decode Term_XML.Decode;
   326 
   327 fun proof prf = prf |> variant
   328  [fn ([], []) => MinProof,
   329   fn ([a], []) => PBound (int_atom a),
   330   fn ([a], b) => let val (c, d) = pair (option typ) proof b in Abst (a, c, d) end,
   331   fn ([a], b) => let val (c, d) = pair (option term) proof b in AbsP (a, c, d) end,
   332   fn ([], a) => op % (pair proof (option term) a),
   333   fn ([], a) => op %% (pair proof proof a),
   334   fn ([], a) => Hyp (term a),
   335   fn ([a], b) => let val (c, d) = pair term (option (list typ)) b in PAxm (a, c, d) end,
   336   fn ([b], a) => OfClass (typ a, b),
   337   fn ([a], b) => let val (c, d) = pair term (option (list typ)) b in Oracle (a, c, d) end,
   338   fn ([a], b) => let val (c, d) = pair term (list typ) b in Promise (int_atom a, c, d) end,
   339   fn ([a, b], c) =>
   340     let val (d, e, f) = triple term (option (list typ)) proof_body c
   341     in PThm (int_atom a, ((b, d, e), Future.value f)) end]
   342 and proof_body x =
   343   let val (a, b, c) = triple (list (pair string term)) (list pthm) proof x
   344   in PBody {oracles = a, thms = b, proof = c} end
   345 and pthm x =
   346   let val (a, (b, c, d)) = pair int (triple string term proof_body) x
   347   in (a, (b, c, Future.value d)) end;
   348 
   349 in
   350 
   351 val decode = proof;
   352 val decode_body = proof_body;
   353 
   354 end;
   355 
   356 
   357 (***** proof objects with different levels of detail *****)
   358 
   359 fun (prf %> t) = prf % SOME t;
   360 
   361 val proof_combt = Library.foldl (op %>);
   362 val proof_combt' = Library.foldl (op %);
   363 val proof_combP = Library.foldl (op %%);
   364 
   365 fun strip_combt prf =
   366     let fun stripc (prf % t, ts) = stripc (prf, t::ts)
   367           | stripc  x =  x
   368     in  stripc (prf, [])  end;
   369 
   370 fun strip_combP prf =
   371     let fun stripc (prf %% prf', prfs) = stripc (prf, prf'::prfs)
   372           | stripc  x =  x
   373     in  stripc (prf, [])  end;
   374 
   375 fun strip_thm (body as PBody {proof, ...}) =
   376   (case strip_combt (fst (strip_combP proof)) of
   377     (PThm (_, (_, body')), _) => Future.join body'
   378   | _ => body);
   379 
   380 val mk_Abst = fold_rev (fn (s, T:typ) => fn prf => Abst (s, NONE, prf));
   381 fun mk_AbsP (i, prf) = funpow i (fn prf => AbsP ("H", NONE, prf)) prf;
   382 
   383 fun map_proof_same term typ ofclass =
   384   let
   385     val typs = Same.map typ;
   386 
   387     fun proof (Abst (s, T, prf)) =
   388           (Abst (s, Same.map_option typ T, Same.commit proof prf)
   389             handle Same.SAME => Abst (s, T, proof prf))
   390       | proof (AbsP (s, t, prf)) =
   391           (AbsP (s, Same.map_option term t, Same.commit proof prf)
   392             handle Same.SAME => AbsP (s, t, proof prf))
   393       | proof (prf % t) =
   394           (proof prf % Same.commit (Same.map_option term) t
   395             handle Same.SAME => prf % Same.map_option term t)
   396       | proof (prf1 %% prf2) =
   397           (proof prf1 %% Same.commit proof prf2
   398             handle Same.SAME => prf1 %% proof prf2)
   399       | proof (PAxm (a, prop, SOME Ts)) = PAxm (a, prop, SOME (typs Ts))
   400       | proof (OfClass T_c) = ofclass T_c
   401       | proof (Oracle (a, prop, SOME Ts)) = Oracle (a, prop, SOME (typs Ts))
   402       | proof (Promise (i, prop, Ts)) = Promise (i, prop, typs Ts)
   403       | proof (PThm (i, ((a, prop, SOME Ts), body))) =
   404           PThm (i, ((a, prop, SOME (typs Ts)), body))
   405       | proof _ = raise Same.SAME;
   406   in proof end;
   407 
   408 fun map_proof_terms_same term typ = map_proof_same term typ (fn (T, c) => OfClass (typ T, c));
   409 fun map_proof_types_same typ = map_proof_terms_same (Term_Subst.map_types_same typ) typ;
   410 
   411 fun same eq f x =
   412   let val x' = f x
   413   in if eq (x, x') then raise Same.SAME else x' end;
   414 
   415 fun map_proof_terms f g = Same.commit (map_proof_terms_same (same (op =) f) (same (op =) g));
   416 fun map_proof_types f = Same.commit (map_proof_types_same (same (op =) f));
   417 
   418 fun fold_proof_terms f g (Abst (_, SOME T, prf)) = g T #> fold_proof_terms f g prf
   419   | fold_proof_terms f g (Abst (_, NONE, prf)) = fold_proof_terms f g prf
   420   | fold_proof_terms f g (AbsP (_, SOME t, prf)) = f t #> fold_proof_terms f g prf
   421   | fold_proof_terms f g (AbsP (_, NONE, prf)) = fold_proof_terms f g prf
   422   | fold_proof_terms f g (prf % SOME t) = fold_proof_terms f g prf #> f t
   423   | fold_proof_terms f g (prf % NONE) = fold_proof_terms f g prf
   424   | fold_proof_terms f g (prf1 %% prf2) =
   425       fold_proof_terms f g prf1 #> fold_proof_terms f g prf2
   426   | fold_proof_terms _ g (PAxm (_, _, SOME Ts)) = fold g Ts
   427   | fold_proof_terms _ g (OfClass (T, _)) = g T
   428   | fold_proof_terms _ g (Oracle (_, _, SOME Ts)) = fold g Ts
   429   | fold_proof_terms _ g (Promise (_, _, Ts)) = fold g Ts
   430   | fold_proof_terms _ g (PThm (_, ((_, _, SOME Ts), _))) = fold g Ts
   431   | fold_proof_terms _ _ _ = I;
   432 
   433 fun maxidx_proof prf = fold_proof_terms Term.maxidx_term Term.maxidx_typ prf;
   434 
   435 fun size_of_proof (Abst (_, _, prf)) = 1 + size_of_proof prf
   436   | size_of_proof (AbsP (_, t, prf)) = 1 + size_of_proof prf
   437   | size_of_proof (prf % _) = 1 + size_of_proof prf
   438   | size_of_proof (prf1 %% prf2) = size_of_proof prf1 + size_of_proof prf2
   439   | size_of_proof _ = 1;
   440 
   441 fun change_type opTs (PAxm (name, prop, _)) = PAxm (name, prop, opTs)
   442   | change_type (SOME [T]) (OfClass (_, c)) = OfClass (T, c)
   443   | change_type opTs (Oracle (name, prop, _)) = Oracle (name, prop, opTs)
   444   | change_type opTs (Promise _) = raise Fail "change_type: unexpected promise"
   445   | change_type opTs (PThm (i, ((name, prop, _), body))) =
   446       PThm (i, ((name, prop, opTs), body))
   447   | change_type _ prf = prf;
   448 
   449 
   450 (***** utilities *****)
   451 
   452 fun strip_abs (_::Ts) (Abs (_, _, t)) = strip_abs Ts t
   453   | strip_abs _ t = t;
   454 
   455 fun mk_abs Ts t = Library.foldl (fn (t', T) => Abs ("", T, t')) (t, Ts);
   456 
   457 
   458 (*Abstraction of a proof term over its occurrences of v,
   459     which must contain no loose bound variables.
   460   The resulting proof term is ready to become the body of an Abst.*)
   461 
   462 fun prf_abstract_over v =
   463   let
   464     fun abst' lev u = if v aconv u then Bound lev else
   465       (case u of
   466          Abs (a, T, t) => Abs (a, T, abst' (lev + 1) t)
   467        | f $ t => (abst' lev f $ absth' lev t handle Same.SAME => f $ abst' lev t)
   468        | _ => raise Same.SAME)
   469     and absth' lev t = (abst' lev t handle Same.SAME => t);
   470 
   471     fun abst lev (AbsP (a, t, prf)) =
   472           (AbsP (a, Same.map_option (abst' lev) t, absth lev prf)
   473            handle Same.SAME => AbsP (a, t, abst lev prf))
   474       | abst lev (Abst (a, T, prf)) = Abst (a, T, abst (lev + 1) prf)
   475       | abst lev (prf1 %% prf2) = (abst lev prf1 %% absth lev prf2
   476           handle Same.SAME => prf1 %% abst lev prf2)
   477       | abst lev (prf % t) = (abst lev prf % Option.map (absth' lev) t
   478           handle Same.SAME => prf % Same.map_option (abst' lev) t)
   479       | abst _ _ = raise Same.SAME
   480     and absth lev prf = (abst lev prf handle Same.SAME => prf);
   481 
   482   in absth 0 end;
   483 
   484 
   485 (*increments a proof term's non-local bound variables
   486   required when moving a proof term within abstractions
   487      inc is  increment for bound variables
   488      lev is  level at which a bound variable is considered 'loose'*)
   489 
   490 fun incr_bv' inct tlev t = incr_bv (inct, tlev, t);
   491 
   492 fun prf_incr_bv' incP inct Plev tlev (PBound i) =
   493       if i >= Plev then PBound (i+incP) else raise Same.SAME
   494   | prf_incr_bv' incP inct Plev tlev (AbsP (a, t, body)) =
   495       (AbsP (a, Same.map_option (same (op =) (incr_bv' inct tlev)) t,
   496          prf_incr_bv incP inct (Plev+1) tlev body) handle Same.SAME =>
   497            AbsP (a, t, prf_incr_bv' incP inct (Plev+1) tlev body))
   498   | prf_incr_bv' incP inct Plev tlev (Abst (a, T, body)) =
   499       Abst (a, T, prf_incr_bv' incP inct Plev (tlev+1) body)
   500   | prf_incr_bv' incP inct Plev tlev (prf %% prf') =
   501       (prf_incr_bv' incP inct Plev tlev prf %% prf_incr_bv incP inct Plev tlev prf'
   502        handle Same.SAME => prf %% prf_incr_bv' incP inct Plev tlev prf')
   503   | prf_incr_bv' incP inct Plev tlev (prf % t) =
   504       (prf_incr_bv' incP inct Plev tlev prf % Option.map (incr_bv' inct tlev) t
   505        handle Same.SAME => prf % Same.map_option (same (op =) (incr_bv' inct tlev)) t)
   506   | prf_incr_bv' _ _ _ _ _ = raise Same.SAME
   507 and prf_incr_bv incP inct Plev tlev prf =
   508       (prf_incr_bv' incP inct Plev tlev prf handle Same.SAME => prf);
   509 
   510 fun incr_pboundvars  0 0 prf = prf
   511   | incr_pboundvars incP inct prf = prf_incr_bv incP inct 0 0 prf;
   512 
   513 
   514 fun prf_loose_bvar1 (prf1 %% prf2) k = prf_loose_bvar1 prf1 k orelse prf_loose_bvar1 prf2 k
   515   | prf_loose_bvar1 (prf % SOME t) k = prf_loose_bvar1 prf k orelse loose_bvar1 (t, k)
   516   | prf_loose_bvar1 (_ % NONE) _ = true
   517   | prf_loose_bvar1 (AbsP (_, SOME t, prf)) k = loose_bvar1 (t, k) orelse prf_loose_bvar1 prf k
   518   | prf_loose_bvar1 (AbsP (_, NONE, _)) k = true
   519   | prf_loose_bvar1 (Abst (_, _, prf)) k = prf_loose_bvar1 prf (k+1)
   520   | prf_loose_bvar1 _ _ = false;
   521 
   522 fun prf_loose_Pbvar1 (PBound i) k = i = k
   523   | prf_loose_Pbvar1 (prf1 %% prf2) k = prf_loose_Pbvar1 prf1 k orelse prf_loose_Pbvar1 prf2 k
   524   | prf_loose_Pbvar1 (prf % _) k = prf_loose_Pbvar1 prf k
   525   | prf_loose_Pbvar1 (AbsP (_, _, prf)) k = prf_loose_Pbvar1 prf (k+1)
   526   | prf_loose_Pbvar1 (Abst (_, _, prf)) k = prf_loose_Pbvar1 prf k
   527   | prf_loose_Pbvar1 _ _ = false;
   528 
   529 fun prf_add_loose_bnos plev tlev (PBound i) (is, js) =
   530       if i < plev then (is, js) else (insert (op =) (i-plev) is, js)
   531   | prf_add_loose_bnos plev tlev (prf1 %% prf2) p =
   532       prf_add_loose_bnos plev tlev prf2
   533         (prf_add_loose_bnos plev tlev prf1 p)
   534   | prf_add_loose_bnos plev tlev (prf % opt) (is, js) =
   535       prf_add_loose_bnos plev tlev prf (case opt of
   536           NONE => (is, insert (op =) ~1 js)
   537         | SOME t => (is, add_loose_bnos (t, tlev, js)))
   538   | prf_add_loose_bnos plev tlev (AbsP (_, opt, prf)) (is, js) =
   539       prf_add_loose_bnos (plev+1) tlev prf (case opt of
   540           NONE => (is, insert (op =) ~1 js)
   541         | SOME t => (is, add_loose_bnos (t, tlev, js)))
   542   | prf_add_loose_bnos plev tlev (Abst (_, _, prf)) p =
   543       prf_add_loose_bnos plev (tlev+1) prf p
   544   | prf_add_loose_bnos _ _ _ _ = ([], []);
   545 
   546 
   547 (**** substitutions ****)
   548 
   549 fun del_conflicting_tvars envT T = Term_Subst.instantiateT
   550   (map_filter (fn ixnS as (_, S) =>
   551      (Type.lookup envT ixnS; NONE) handle TYPE _ =>
   552         SOME (ixnS, TFree ("'dummy", S))) (Term.add_tvarsT T [])) T;
   553 
   554 fun del_conflicting_vars env t = Term_Subst.instantiate
   555   (map_filter (fn ixnS as (_, S) =>
   556      (Type.lookup (Envir.type_env env) ixnS; NONE) handle TYPE _ =>
   557         SOME (ixnS, TFree ("'dummy", S))) (Term.add_tvars t []),
   558    map_filter (fn (ixnT as (_, T)) =>
   559      (Envir.lookup env ixnT; NONE) handle TYPE _ =>
   560         SOME (ixnT, Free ("dummy", T))) (Term.add_vars t [])) t;
   561 
   562 fun norm_proof env =
   563   let
   564     val envT = Envir.type_env env;
   565     fun msg s = warning ("type conflict in norm_proof:\n" ^ s);
   566     fun htype f t = f env t handle TYPE (s, _, _) =>
   567       (msg s; f env (del_conflicting_vars env t));
   568     fun htypeT f T = f envT T handle TYPE (s, _, _) =>
   569       (msg s; f envT (del_conflicting_tvars envT T));
   570     fun htypeTs f Ts = f envT Ts handle TYPE (s, _, _) =>
   571       (msg s; f envT (map (del_conflicting_tvars envT) Ts));
   572 
   573     fun norm (Abst (s, T, prf)) =
   574           (Abst (s, Same.map_option (htypeT Envir.norm_type_same) T, Same.commit norm prf)
   575             handle Same.SAME => Abst (s, T, norm prf))
   576       | norm (AbsP (s, t, prf)) =
   577           (AbsP (s, Same.map_option (htype Envir.norm_term_same) t, Same.commit norm prf)
   578             handle Same.SAME => AbsP (s, t, norm prf))
   579       | norm (prf % t) =
   580           (norm prf % Option.map (htype Envir.norm_term) t
   581             handle Same.SAME => prf % Same.map_option (htype Envir.norm_term_same) t)
   582       | norm (prf1 %% prf2) =
   583           (norm prf1 %% Same.commit norm prf2
   584             handle Same.SAME => prf1 %% norm prf2)
   585       | norm (PAxm (s, prop, Ts)) =
   586           PAxm (s, prop, Same.map_option (htypeTs Envir.norm_types_same) Ts)
   587       | norm (OfClass (T, c)) =
   588           OfClass (htypeT Envir.norm_type_same T, c)
   589       | norm (Oracle (s, prop, Ts)) =
   590           Oracle (s, prop, Same.map_option (htypeTs Envir.norm_types_same) Ts)
   591       | norm (Promise (i, prop, Ts)) =
   592           Promise (i, prop, htypeTs Envir.norm_types_same Ts)
   593       | norm (PThm (i, ((s, t, Ts), body))) =
   594           PThm (i, ((s, t, Same.map_option (htypeTs Envir.norm_types_same) Ts), body))
   595       | norm _ = raise Same.SAME;
   596   in Same.commit norm end;
   597 
   598 
   599 (***** Remove some types in proof term (to save space) *****)
   600 
   601 fun remove_types (Abs (s, _, t)) = Abs (s, dummyT, remove_types t)
   602   | remove_types (t $ u) = remove_types t $ remove_types u
   603   | remove_types (Const (s, _)) = Const (s, dummyT)
   604   | remove_types t = t;
   605 
   606 fun remove_types_env (Envir.Envir {maxidx, tenv, tyenv}) =
   607   Envir.Envir {maxidx = maxidx, tenv = Vartab.map (K (apsnd remove_types)) tenv, tyenv = tyenv};
   608 
   609 fun norm_proof' env prf = norm_proof (remove_types_env env) prf;
   610 
   611 
   612 (**** substitution of bound variables ****)
   613 
   614 fun prf_subst_bounds args prf =
   615   let
   616     val n = length args;
   617     fun subst' lev (Bound i) =
   618          (if i<lev then raise Same.SAME    (*var is locally bound*)
   619           else  incr_boundvars lev (nth args (i-lev))
   620                   handle General.Subscript => Bound (i-n))  (*loose: change it*)
   621       | subst' lev (Abs (a, T, body)) = Abs (a, T,  subst' (lev+1) body)
   622       | subst' lev (f $ t) = (subst' lev f $ substh' lev t
   623           handle Same.SAME => f $ subst' lev t)
   624       | subst' _ _ = raise Same.SAME
   625     and substh' lev t = (subst' lev t handle Same.SAME => t);
   626 
   627     fun subst lev (AbsP (a, t, body)) =
   628         (AbsP (a, Same.map_option (subst' lev) t, substh lev body)
   629           handle Same.SAME => AbsP (a, t, subst lev body))
   630       | subst lev (Abst (a, T, body)) = Abst (a, T, subst (lev+1) body)
   631       | subst lev (prf %% prf') = (subst lev prf %% substh lev prf'
   632           handle Same.SAME => prf %% subst lev prf')
   633       | subst lev (prf % t) = (subst lev prf % Option.map (substh' lev) t
   634           handle Same.SAME => prf % Same.map_option (subst' lev) t)
   635       | subst _ _ = raise Same.SAME
   636     and substh lev prf = (subst lev prf handle Same.SAME => prf);
   637   in case args of [] => prf | _ => substh 0 prf end;
   638 
   639 fun prf_subst_pbounds args prf =
   640   let
   641     val n = length args;
   642     fun subst (PBound i) Plev tlev =
   643          (if i < Plev then raise Same.SAME    (*var is locally bound*)
   644           else incr_pboundvars Plev tlev (nth args (i-Plev))
   645                  handle General.Subscript => PBound (i-n)  (*loose: change it*))
   646       | subst (AbsP (a, t, body)) Plev tlev = AbsP (a, t, subst body (Plev+1) tlev)
   647       | subst (Abst (a, T, body)) Plev tlev = Abst (a, T, subst body Plev (tlev+1))
   648       | subst (prf %% prf') Plev tlev = (subst prf Plev tlev %% substh prf' Plev tlev
   649           handle Same.SAME => prf %% subst prf' Plev tlev)
   650       | subst (prf % t) Plev tlev = subst prf Plev tlev % t
   651       | subst  prf _ _ = raise Same.SAME
   652     and substh prf Plev tlev = (subst prf Plev tlev handle Same.SAME => prf)
   653   in case args of [] => prf | _ => substh prf 0 0 end;
   654 
   655 
   656 (**** Freezing and thawing of variables in proof terms ****)
   657 
   658 local
   659 
   660 fun frzT names =
   661   map_type_tvar (fn (ixn, S) => TFree (the (AList.lookup (op =) names ixn), S));
   662 
   663 fun thawT names =
   664   map_type_tfree (fn (a, S) =>
   665     (case AList.lookup (op =) names a of
   666       NONE => TFree (a, S)
   667     | SOME ixn => TVar (ixn, S)));
   668 
   669 fun freeze names names' (t $ u) =
   670       freeze names names' t $ freeze names names' u
   671   | freeze names names' (Abs (s, T, t)) =
   672       Abs (s, frzT names' T, freeze names names' t)
   673   | freeze names names' (Const (s, T)) = Const (s, frzT names' T)
   674   | freeze names names' (Free (s, T)) = Free (s, frzT names' T)
   675   | freeze names names' (Var (ixn, T)) =
   676       Free (the (AList.lookup (op =) names ixn), frzT names' T)
   677   | freeze names names' t = t;
   678 
   679 fun thaw names names' (t $ u) =
   680       thaw names names' t $ thaw names names' u
   681   | thaw names names' (Abs (s, T, t)) =
   682       Abs (s, thawT names' T, thaw names names' t)
   683   | thaw names names' (Const (s, T)) = Const (s, thawT names' T)
   684   | thaw names names' (Free (s, T)) =
   685       let val T' = thawT names' T in
   686         (case AList.lookup (op =) names s of
   687           NONE => Free (s, T')
   688         | SOME ixn => Var (ixn, T'))
   689       end
   690   | thaw names names' (Var (ixn, T)) = Var (ixn, thawT names' T)
   691   | thaw names names' t = t;
   692 
   693 in
   694 
   695 fun freeze_thaw_prf prf =
   696   let
   697     val (fs, Tfs, vs, Tvs) = fold_proof_terms
   698       (fn t => fn (fs, Tfs, vs, Tvs) =>
   699          (Term.add_free_names t fs, Term.add_tfree_names t Tfs,
   700           Term.add_var_names t vs, Term.add_tvar_names t Tvs))
   701       (fn T => fn (fs, Tfs, vs, Tvs) =>
   702          (fs, Term.add_tfree_namesT T Tfs,
   703           vs, Term.add_tvar_namesT T Tvs))
   704       prf ([], [], [], []);
   705     val names = vs ~~ Name.variant_list fs (map fst vs);
   706     val names' = Tvs ~~ Name.variant_list Tfs (map fst Tvs);
   707     val rnames = map swap names;
   708     val rnames' = map swap names';
   709   in
   710     (map_proof_terms (freeze names names') (frzT names') prf,
   711      map_proof_terms (thaw rnames rnames') (thawT rnames'))
   712   end;
   713 
   714 end;
   715 
   716 
   717 (***** implication introduction *****)
   718 
   719 fun gen_implies_intr_proof f h prf =
   720   let
   721     fun abshyp i (Hyp t) = if h aconv t then PBound i else raise Same.SAME
   722       | abshyp i (Abst (s, T, prf)) = Abst (s, T, abshyp i prf)
   723       | abshyp i (AbsP (s, t, prf)) = AbsP (s, t, abshyp (i + 1) prf)
   724       | abshyp i (prf % t) = abshyp i prf % t
   725       | abshyp i (prf1 %% prf2) =
   726           (abshyp i prf1 %% abshyph i prf2
   727             handle Same.SAME => prf1 %% abshyp i prf2)
   728       | abshyp _ _ = raise Same.SAME
   729     and abshyph i prf = (abshyp i prf handle Same.SAME => prf);
   730   in
   731     AbsP ("H", f h, abshyph 0 prf)
   732   end;
   733 
   734 val implies_intr_proof = gen_implies_intr_proof (K NONE);
   735 val implies_intr_proof' = gen_implies_intr_proof SOME;
   736 
   737 
   738 (***** forall introduction *****)
   739 
   740 fun forall_intr_proof x a prf = Abst (a, NONE, prf_abstract_over x prf);
   741 
   742 fun forall_intr_proof' t prf =
   743   let val (a, T) = (case t of Var ((a, _), T) => (a, T) | Free p => p)
   744   in Abst (a, SOME T, prf_abstract_over t prf) end;
   745 
   746 
   747 (***** varify *****)
   748 
   749 fun varify_proof t fixed prf =
   750   let
   751     val fs = Term.fold_types (Term.fold_atyps
   752       (fn TFree v => if member (op =) fixed v then I else insert (op =) v | _ => I)) t [];
   753     val used = Name.context
   754       |> fold_types (fold_atyps (fn TVar ((a, _), _) => Name.declare a | _ => I)) t;
   755     val fmap = fs ~~ #1 (fold_map Name.variant (map fst fs) used);
   756     fun thaw (f as (a, S)) =
   757       (case AList.lookup (op =) fmap f of
   758         NONE => TFree f
   759       | SOME b => TVar ((b, 0), S));
   760   in map_proof_terms (map_types (map_type_tfree thaw)) (map_type_tfree thaw) prf end;
   761 
   762 
   763 local
   764 
   765 fun new_name ix (pairs, used) =
   766   let val v = singleton (Name.variant_list used) (string_of_indexname ix)
   767   in ((ix, v) :: pairs, v :: used) end;
   768 
   769 fun freeze_one alist (ix, sort) =
   770   (case AList.lookup (op =) alist ix of
   771     NONE => TVar (ix, sort)
   772   | SOME name => TFree (name, sort));
   773 
   774 in
   775 
   776 fun legacy_freezeT t prf =
   777   let
   778     val used = Term.add_tfree_names t [];
   779     val (alist, _) = fold_rev new_name (map #1 (Term.add_tvars t [])) ([], used);
   780   in
   781     (case alist of
   782       [] => prf (*nothing to do!*)
   783     | _ =>
   784         let val frzT = map_type_tvar (freeze_one alist)
   785         in map_proof_terms (map_types frzT) frzT prf end)
   786   end;
   787 
   788 end;
   789 
   790 
   791 (***** rotate assumptions *****)
   792 
   793 fun rotate_proof Bs Bi m prf =
   794   let
   795     val params = Term.strip_all_vars Bi;
   796     val asms = Logic.strip_imp_prems (Term.strip_all_body Bi);
   797     val i = length asms;
   798     val j = length Bs;
   799   in
   800     mk_AbsP (j+1, proof_combP (prf, map PBound
   801       (j downto 1) @ [mk_Abst params (mk_AbsP (i,
   802         proof_combP (proof_combt (PBound i, map Bound ((length params - 1) downto 0)),
   803           map PBound (((i-m-1) downto 0) @ ((i-1) downto (i-m))))))]))
   804   end;
   805 
   806 
   807 (***** permute premises *****)
   808 
   809 fun permute_prems_proof prems j k prf =
   810   let val n = length prems
   811   in mk_AbsP (n, proof_combP (prf,
   812     map PBound ((n-1 downto n-j) @ (k-1 downto 0) @ (n-j-1 downto k))))
   813   end;
   814 
   815 
   816 (***** generalization *****)
   817 
   818 fun generalize (tfrees, frees) idx =
   819   Same.commit (map_proof_terms_same
   820     (Term_Subst.generalize_same (tfrees, frees) idx)
   821     (Term_Subst.generalizeT_same tfrees idx));
   822 
   823 
   824 (***** instantiation *****)
   825 
   826 fun instantiate (instT, inst) =
   827   Same.commit (map_proof_terms_same
   828     (Term_Subst.instantiate_same (instT, map (apsnd remove_types) inst))
   829     (Term_Subst.instantiateT_same instT));
   830 
   831 
   832 (***** lifting *****)
   833 
   834 fun lift_proof Bi inc prop prf =
   835   let
   836     fun lift'' Us Ts t =
   837       strip_abs Ts (Logic.incr_indexes (Us, inc) (mk_abs Ts t));
   838 
   839     fun lift' Us Ts (Abst (s, T, prf)) =
   840           (Abst (s, Same.map_option (Logic.incr_tvar_same inc) T, lifth' Us (dummyT::Ts) prf)
   841            handle Same.SAME => Abst (s, T, lift' Us (dummyT::Ts) prf))
   842       | lift' Us Ts (AbsP (s, t, prf)) =
   843           (AbsP (s, Same.map_option (same (op =) (lift'' Us Ts)) t, lifth' Us Ts prf)
   844            handle Same.SAME => AbsP (s, t, lift' Us Ts prf))
   845       | lift' Us Ts (prf % t) = (lift' Us Ts prf % Option.map (lift'' Us Ts) t
   846           handle Same.SAME => prf % Same.map_option (same (op =) (lift'' Us Ts)) t)
   847       | lift' Us Ts (prf1 %% prf2) = (lift' Us Ts prf1 %% lifth' Us Ts prf2
   848           handle Same.SAME => prf1 %% lift' Us Ts prf2)
   849       | lift' _ _ (PAxm (s, prop, Ts)) =
   850           PAxm (s, prop, (Same.map_option o Same.map) (Logic.incr_tvar_same inc) Ts)
   851       | lift' _ _ (OfClass (T, c)) =
   852           OfClass (Logic.incr_tvar_same inc T, c)
   853       | lift' _ _ (Oracle (s, prop, Ts)) =
   854           Oracle (s, prop, (Same.map_option o Same.map) (Logic.incr_tvar_same inc) Ts)
   855       | lift' _ _ (Promise (i, prop, Ts)) =
   856           Promise (i, prop, Same.map (Logic.incr_tvar_same inc) Ts)
   857       | lift' _ _ (PThm (i, ((s, prop, Ts), body))) =
   858           PThm (i, ((s, prop, (Same.map_option o Same.map) (Logic.incr_tvar inc) Ts), body))
   859       | lift' _ _ _ = raise Same.SAME
   860     and lifth' Us Ts prf = (lift' Us Ts prf handle Same.SAME => prf);
   861 
   862     val ps = map (Logic.lift_all inc Bi) (Logic.strip_imp_prems prop);
   863     val k = length ps;
   864 
   865     fun mk_app b (i, j, prf) =
   866           if b then (i-1, j, prf %% PBound i) else (i, j-1, prf %> Bound j);
   867 
   868     fun lift Us bs i j (Const ("Pure.imp", _) $ A $ B) =
   869             AbsP ("H", NONE (*A*), lift Us (true::bs) (i+1) j B)
   870       | lift Us bs i j (Const ("Pure.all", _) $ Abs (a, T, t)) =
   871             Abst (a, NONE (*T*), lift (T::Us) (false::bs) i (j+1) t)
   872       | lift Us bs i j _ = proof_combP (lifth' (rev Us) [] prf,
   873             map (fn k => (#3 (fold_rev mk_app bs (i-1, j-1, PBound k))))
   874               (i + k - 1 downto i));
   875   in
   876     mk_AbsP (k, lift [] [] 0 0 Bi)
   877   end;
   878 
   879 fun incr_indexes i =
   880   Same.commit (map_proof_terms_same
   881     (Logic.incr_indexes_same ([], i)) (Logic.incr_tvar_same i));
   882 
   883 
   884 (***** proof by assumption *****)
   885 
   886 fun mk_asm_prf t i m =
   887   let
   888     fun imp_prf _ i 0 = PBound i
   889       | imp_prf (Const ("Pure.imp", _) $ A $ B) i m = AbsP ("H", NONE (*A*), imp_prf B (i+1) (m-1))
   890       | imp_prf _ i _ = PBound i;
   891     fun all_prf (Const ("Pure.all", _) $ Abs (a, T, t)) = Abst (a, NONE (*T*), all_prf t)
   892       | all_prf t = imp_prf t (~i) m
   893   in all_prf t end;
   894 
   895 fun assumption_proof Bs Bi n prf =
   896   mk_AbsP (length Bs, proof_combP (prf,
   897     map PBound (length Bs - 1 downto 0) @ [mk_asm_prf Bi n ~1]));
   898 
   899 
   900 (***** Composition of object rule with proof state *****)
   901 
   902 fun flatten_params_proof i j n (Const ("Pure.imp", _) $ A $ B, k) =
   903       AbsP ("H", NONE (*A*), flatten_params_proof (i+1) j n (B, k))
   904   | flatten_params_proof i j n (Const ("Pure.all", _) $ Abs (a, T, t), k) =
   905       Abst (a, NONE (*T*), flatten_params_proof i (j+1) n (t, k))
   906   | flatten_params_proof i j n (_, k) = proof_combP (proof_combt (PBound (k+i),
   907       map Bound (j-1 downto 0)), map PBound (remove (op =) (i-n) (i-1 downto 0)));
   908 
   909 fun bicompose_proof flatten Bs oldAs newAs A n m rprf sprf =
   910   let
   911     val la = length newAs;
   912     val lb = length Bs;
   913   in
   914     mk_AbsP (lb+la, proof_combP (sprf,
   915       map PBound (lb + la - 1 downto la)) %%
   916         proof_combP (rprf, (if n>0 then [mk_asm_prf (the A) n m] else []) @
   917           map (if flatten then flatten_params_proof 0 0 n else PBound o snd)
   918             (oldAs ~~ (la - 1 downto 0))))
   919   end;
   920 
   921 
   922 (***** axioms for equality *****)
   923 
   924 val aT = TFree ("'a", []);
   925 val bT = TFree ("'b", []);
   926 val x = Free ("x", aT);
   927 val y = Free ("y", aT);
   928 val z = Free ("z", aT);
   929 val A = Free ("A", propT);
   930 val B = Free ("B", propT);
   931 val f = Free ("f", aT --> bT);
   932 val g = Free ("g", aT --> bT);
   933 
   934 val equality_axms =
   935  [("reflexive", Logic.mk_equals (x, x)),
   936   ("symmetric", Logic.mk_implies (Logic.mk_equals (x, y), Logic.mk_equals (y, x))),
   937   ("transitive",
   938     Logic.list_implies ([Logic.mk_equals (x, y), Logic.mk_equals (y, z)], Logic.mk_equals (x, z))),
   939   ("equal_intr",
   940     Logic.list_implies ([Logic.mk_implies (A, B), Logic.mk_implies (B, A)], Logic.mk_equals (A, B))),
   941   ("equal_elim", Logic.list_implies ([Logic.mk_equals (A, B), A], B)),
   942   ("abstract_rule",
   943     Logic.mk_implies
   944       (Logic.all x
   945         (Logic.mk_equals (f $ x, g $ x)), Logic.mk_equals (lambda x (f $ x), lambda x (g $ x)))),
   946   ("combination", Logic.list_implies
   947     ([Logic.mk_equals (f, g), Logic.mk_equals (x, y)], Logic.mk_equals (f $ x, g $ y)))];
   948 
   949 val [reflexive_axm, symmetric_axm, transitive_axm, equal_intr_axm,
   950   equal_elim_axm, abstract_rule_axm, combination_axm] =
   951     map (fn (s, t) => PAxm ("Pure." ^ s, Logic.varify_global t, NONE)) equality_axms;
   952 
   953 val reflexive = reflexive_axm % NONE;
   954 
   955 fun symmetric (prf as PAxm ("Pure.reflexive", _, _) % _) = prf
   956   | symmetric prf = symmetric_axm % NONE % NONE %% prf;
   957 
   958 fun transitive _ _ (PAxm ("Pure.reflexive", _, _) % _) prf2 = prf2
   959   | transitive _ _ prf1 (PAxm ("Pure.reflexive", _, _) % _) = prf1
   960   | transitive u (Type ("prop", [])) prf1 prf2 =
   961       transitive_axm % NONE % SOME (remove_types u) % NONE %% prf1 %% prf2
   962   | transitive u T prf1 prf2 =
   963       transitive_axm % NONE % NONE % NONE %% prf1 %% prf2;
   964 
   965 fun abstract_rule x a prf =
   966   abstract_rule_axm % NONE % NONE %% forall_intr_proof x a prf;
   967 
   968 fun check_comb (PAxm ("Pure.combination", _, _) % f % g % _ % _ %% prf %% _) =
   969       is_some f orelse check_comb prf
   970   | check_comb (PAxm ("Pure.transitive", _, _) % _ % _ % _ %% prf1 %% prf2) =
   971       check_comb prf1 andalso check_comb prf2
   972   | check_comb (PAxm ("Pure.symmetric", _, _) % _ % _ %% prf) = check_comb prf
   973   | check_comb _ = false;
   974 
   975 fun combination f g t u (Type (_, [T, U])) prf1 prf2 =
   976   let
   977     val f = Envir.beta_norm f;
   978     val g = Envir.beta_norm g;
   979     val prf =
   980       if check_comb prf1 then
   981         combination_axm % NONE % NONE
   982       else
   983         (case prf1 of
   984           PAxm ("Pure.reflexive", _, _) % _ =>
   985             combination_axm %> remove_types f % NONE
   986         | _ => combination_axm %> remove_types f %> remove_types g)
   987   in
   988     (case T of
   989       Type ("fun", _) => prf %
   990         (case head_of f of
   991           Abs _ => SOME (remove_types t)
   992         | Var _ => SOME (remove_types t)
   993         | _ => NONE) %
   994         (case head_of g of
   995            Abs _ => SOME (remove_types u)
   996         | Var _ => SOME (remove_types u)
   997         | _ => NONE) %% prf1 %% prf2
   998      | _ => prf % NONE % NONE %% prf1 %% prf2)
   999   end;
  1000 
  1001 fun equal_intr A B prf1 prf2 =
  1002   equal_intr_axm %> remove_types A %> remove_types B %% prf1 %% prf2;
  1003 
  1004 fun equal_elim A B prf1 prf2 =
  1005   equal_elim_axm %> remove_types A %> remove_types B %% prf1 %% prf2;
  1006 
  1007 
  1008 (**** type classes ****)
  1009 
  1010 fun strip_shyps_proof algebra present witnessed extra_sorts prf =
  1011   let
  1012     fun get S2 (T, S1) = if Sorts.sort_le algebra (S1, S2) then SOME T else NONE;
  1013     val extra = map (fn S => (TFree ("'dummy", S), S)) extra_sorts;
  1014     val replacements = present @ extra @ witnessed;
  1015     fun replace T =
  1016       if exists (fn (T', _) => T' = T) present then raise Same.SAME
  1017       else
  1018         (case get_first (get (Type.sort_of_atyp T)) replacements of
  1019           SOME T' => T'
  1020         | NONE => raise Fail "strip_shyps_proof: bad type variable in proof term");
  1021   in Same.commit (map_proof_types_same (Term_Subst.map_atypsT_same replace)) prf end;
  1022 
  1023 
  1024 local
  1025 
  1026 type axclass_proofs =
  1027  {classrel_proof: theory -> class * class -> proof,
  1028   arity_proof: theory -> string * sort list * class -> proof};
  1029 
  1030 val axclass_proofs: axclass_proofs Single_Assignment.var =
  1031   Single_Assignment.var "Proofterm.axclass_proofs";
  1032 
  1033 fun axclass_proof which thy x =
  1034   (case Single_Assignment.peek axclass_proofs of
  1035     NONE => raise Fail "Axclass proof operations not installed"
  1036   | SOME prfs => which prfs thy x);
  1037 
  1038 in
  1039 
  1040 val classrel_proof = axclass_proof #classrel_proof;
  1041 val arity_proof = axclass_proof #arity_proof;
  1042 
  1043 fun install_axclass_proofs prfs = Single_Assignment.assign axclass_proofs prfs;
  1044 
  1045 end;
  1046 
  1047 
  1048 local
  1049 
  1050 fun canonical_instance typs =
  1051   let
  1052     val names = Name.invent Name.context Name.aT (length typs);
  1053     val instT = map2 (fn a => fn T => (((a, 0), []), Type.strip_sorts T)) names typs;
  1054   in instantiate (instT, []) end;
  1055 
  1056 in
  1057 
  1058 fun of_sort_proof thy hyps =
  1059   Sorts.of_sort_derivation (Sign.classes_of thy)
  1060    {class_relation = fn typ => fn (prf, c1) => fn c2 =>
  1061       if c1 = c2 then prf
  1062       else canonical_instance [typ] (classrel_proof thy (c1, c2)) %% prf,
  1063     type_constructor = fn (a, typs) => fn dom => fn c =>
  1064       let val Ss = map (map snd) dom and prfs = maps (map fst) dom
  1065       in proof_combP (canonical_instance typs (arity_proof thy (a, Ss, c)), prfs) end,
  1066     type_variable = fn typ => map (fn c => (hyps (typ, c), c)) (Type.sort_of_atyp typ)};
  1067 
  1068 end;
  1069 
  1070 
  1071 (***** axioms and theorems *****)
  1072 
  1073 val proofs = Unsynchronized.ref 2;
  1074 fun proofs_enabled () = ! proofs >= 2;
  1075 
  1076 fun vars_of t = map Var (rev (Term.add_vars t []));
  1077 fun frees_of t = map Free (rev (Term.add_frees t []));
  1078 
  1079 fun test_args _ [] = true
  1080   | test_args is (Bound i :: ts) =
  1081       not (member (op =) is i) andalso test_args (i :: is) ts
  1082   | test_args _ _ = false;
  1083 
  1084 fun is_fun (Type ("fun", _)) = true
  1085   | is_fun (TVar _) = true
  1086   | is_fun _ = false;
  1087 
  1088 fun add_funvars Ts (vs, t) =
  1089   if is_fun (fastype_of1 (Ts, t)) then
  1090     union (op =) vs (map_filter (fn Var (ixn, T) =>
  1091       if is_fun T then SOME ixn else NONE | _ => NONE) (vars_of t))
  1092   else vs;
  1093 
  1094 fun add_npvars q p Ts (vs, Const ("Pure.imp", _) $ t $ u) =
  1095       add_npvars q p Ts (add_npvars q (not p) Ts (vs, t), u)
  1096   | add_npvars q p Ts (vs, Const ("Pure.all", Type (_, [Type (_, [T, _]), _])) $ t) =
  1097       add_npvars q p Ts (vs, if p andalso q then betapply (t, Var (("",0), T)) else t)
  1098   | add_npvars q p Ts (vs, Abs (_, T, t)) = add_npvars q p (T::Ts) (vs, t)
  1099   | add_npvars _ _ Ts (vs, t) = add_npvars' Ts (vs, t)
  1100 and add_npvars' Ts (vs, t) = (case strip_comb t of
  1101     (Var (ixn, _), ts) => if test_args [] ts then vs
  1102       else Library.foldl (add_npvars' Ts)
  1103         (AList.update (op =) (ixn,
  1104           Library.foldl (add_funvars Ts) ((these ooo AList.lookup) (op =) vs ixn, ts)) vs, ts)
  1105   | (Abs (_, T, u), ts) => Library.foldl (add_npvars' (T::Ts)) (vs, u :: ts)
  1106   | (_, ts) => Library.foldl (add_npvars' Ts) (vs, ts));
  1107 
  1108 fun prop_vars (Const ("Pure.imp", _) $ P $ Q) = union (op =) (prop_vars P) (prop_vars Q)
  1109   | prop_vars (Const ("Pure.all", _) $ Abs (_, _, t)) = prop_vars t
  1110   | prop_vars t = (case strip_comb t of
  1111       (Var (ixn, _), _) => [ixn] | _ => []);
  1112 
  1113 fun is_proj t =
  1114   let
  1115     fun is_p i t = (case strip_comb t of
  1116         (Bound j, []) => false
  1117       | (Bound j, ts) => j >= i orelse exists (is_p i) ts
  1118       | (Abs (_, _, u), _) => is_p (i+1) u
  1119       | (_, ts) => exists (is_p i) ts)
  1120   in (case strip_abs_body t of
  1121         Bound _ => true
  1122       | t' => is_p 0 t')
  1123   end;
  1124 
  1125 fun needed_vars prop =
  1126   union (op =) (Library.foldl (uncurry (union (op =)))
  1127     ([], map (uncurry (insert (op =))) (add_npvars true true [] ([], prop))))
  1128   (prop_vars prop);
  1129 
  1130 fun gen_axm_proof c name prop =
  1131   let
  1132     val nvs = needed_vars prop;
  1133     val args = map (fn (v as Var (ixn, _)) =>
  1134         if member (op =) nvs ixn then SOME v else NONE) (vars_of prop) @
  1135       map SOME (frees_of prop);
  1136   in
  1137     proof_combt' (c (name, prop, NONE), args)
  1138   end;
  1139 
  1140 val axm_proof = gen_axm_proof PAxm;
  1141 
  1142 fun oracle_proof name prop =
  1143   if ! proofs = 0 then ((name, Term.dummy), Oracle (name, Term.dummy, NONE))
  1144   else ((name, prop), gen_axm_proof Oracle name prop);
  1145 
  1146 fun shrink_proof thy =
  1147   let
  1148     fun shrink ls lev (prf as Abst (a, T, body)) =
  1149           let val (b, is, ch, body') = shrink ls (lev+1) body
  1150           in (b, is, ch, if ch then Abst (a, T, body') else prf) end
  1151       | shrink ls lev (prf as AbsP (a, t, body)) =
  1152           let val (b, is, ch, body') = shrink (lev::ls) lev body
  1153           in (b orelse member (op =) is 0, map_filter (fn 0 => NONE | i => SOME (i-1)) is,
  1154             ch, if ch then AbsP (a, t, body') else prf)
  1155           end
  1156       | shrink ls lev prf =
  1157           let val (is, ch, _, prf') = shrink' ls lev [] [] prf
  1158           in (false, is, ch, prf') end
  1159     and shrink' ls lev ts prfs (prf as prf1 %% prf2) =
  1160           let
  1161             val p as (_, is', ch', prf') = shrink ls lev prf2;
  1162             val (is, ch, ts', prf'') = shrink' ls lev ts (p::prfs) prf1
  1163           in (union (op =) is is', ch orelse ch', ts',
  1164               if ch orelse ch' then prf'' %% prf' else prf)
  1165           end
  1166       | shrink' ls lev ts prfs (prf as prf1 % t) =
  1167           let val (is, ch, (ch', t')::ts', prf') = shrink' ls lev (t::ts) prfs prf1
  1168           in (is, ch orelse ch', ts',
  1169               if ch orelse ch' then prf' % t' else prf) end
  1170       | shrink' ls lev ts prfs (prf as PBound i) =
  1171           (if exists (fn SOME (Bound j) => lev-j <= nth ls i | _ => true) ts
  1172              orelse has_duplicates (op =)
  1173                (Library.foldl (fn (js, SOME (Bound j)) => j :: js | (js, _) => js) ([], ts))
  1174              orelse exists #1 prfs then [i] else [], false, map (pair false) ts, prf)
  1175       | shrink' ls lev ts prfs (Hyp t) = ([], false, map (pair false) ts, Hyp t)
  1176       | shrink' ls lev ts prfs (prf as MinProof) = ([], false, map (pair false) ts, prf)
  1177       | shrink' ls lev ts prfs (prf as OfClass _) = ([], false, map (pair false) ts, prf)
  1178       | shrink' ls lev ts prfs prf =
  1179           let
  1180             val prop =
  1181               (case prf of
  1182                 PAxm (_, prop, _) => prop
  1183               | Oracle (_, prop, _) => prop
  1184               | Promise (_, prop, _) => prop
  1185               | PThm (_, ((_, prop, _), _)) => prop
  1186               | _ => raise Fail "shrink: proof not in normal form");
  1187             val vs = vars_of prop;
  1188             val (ts', ts'') = chop (length vs) ts;
  1189             val insts = take (length ts') (map (fst o dest_Var) vs) ~~ ts';
  1190             val nvs = Library.foldl (fn (ixns', (ixn, ixns)) =>
  1191               insert (op =) ixn (case AList.lookup (op =) insts ixn of
  1192                   SOME (SOME t) => if is_proj t then union (op =) ixns ixns' else ixns'
  1193                 | _ => union (op =) ixns ixns'))
  1194                   (needed prop ts'' prfs, add_npvars false true [] ([], prop));
  1195             val insts' = map
  1196               (fn (ixn, x as SOME _) => if member (op =) nvs ixn then (false, x) else (true, NONE)
  1197                 | (_, x) => (false, x)) insts
  1198           in ([], false, insts' @ map (pair false) ts'', prf) end
  1199     and needed (Const ("Pure.imp", _) $ t $ u) ts ((b, _, _, _)::prfs) =
  1200           union (op =) (if b then map (fst o dest_Var) (vars_of t) else []) (needed u ts prfs)
  1201       | needed (Var (ixn, _)) (_::_) _ = [ixn]
  1202       | needed _ _ _ = [];
  1203   in shrink end;
  1204 
  1205 
  1206 (**** Simple first order matching functions for terms and proofs ****)
  1207 
  1208 exception PMatch;
  1209 
  1210 (** see pattern.ML **)
  1211 
  1212 fun flt (i: int) = filter (fn n => n < i);
  1213 
  1214 fun fomatch Ts tymatch j instsp p =
  1215   let
  1216     fun mtch (instsp as (tyinsts, insts)) = fn
  1217         (Var (ixn, T), t)  =>
  1218           if j>0 andalso not (null (flt j (loose_bnos t)))
  1219           then raise PMatch
  1220           else (tymatch (tyinsts, fn () => (T, fastype_of1 (Ts, t))),
  1221             (ixn, t) :: insts)
  1222       | (Free (a, T), Free (b, U)) =>
  1223           if a=b then (tymatch (tyinsts, K (T, U)), insts) else raise PMatch
  1224       | (Const (a, T), Const (b, U))  =>
  1225           if a=b then (tymatch (tyinsts, K (T, U)), insts) else raise PMatch
  1226       | (f $ t, g $ u) => mtch (mtch instsp (f, g)) (t, u)
  1227       | (Bound i, Bound j) => if i=j then instsp else raise PMatch
  1228       | _ => raise PMatch
  1229   in mtch instsp (pairself Envir.beta_eta_contract p) end;
  1230 
  1231 fun match_proof Ts tymatch =
  1232   let
  1233     fun optmatch _ inst (NONE, _) = inst
  1234       | optmatch _ _ (SOME _, NONE) = raise PMatch
  1235       | optmatch mtch inst (SOME x, SOME y) = mtch inst (x, y)
  1236 
  1237     fun matcht Ts j (pinst, tinst) (t, u) =
  1238       (pinst, fomatch Ts tymatch j tinst (t, Envir.beta_norm u));
  1239     fun matchT (pinst, (tyinsts, insts)) p =
  1240       (pinst, (tymatch (tyinsts, K p), insts));
  1241     fun matchTs inst (Ts, Us) = Library.foldl (uncurry matchT) (inst, Ts ~~ Us);
  1242 
  1243     fun mtch Ts i j (pinst, tinst) (Hyp (Var (ixn, _)), prf) =
  1244           if i = 0 andalso j = 0 then ((ixn, prf) :: pinst, tinst)
  1245           else (case apfst (flt i) (apsnd (flt j)
  1246                   (prf_add_loose_bnos 0 0 prf ([], []))) of
  1247               ([], []) => ((ixn, incr_pboundvars (~i) (~j) prf) :: pinst, tinst)
  1248             | ([], _) => if j = 0 then
  1249                    ((ixn, incr_pboundvars (~i) (~j) prf) :: pinst, tinst)
  1250                  else raise PMatch
  1251             | _ => raise PMatch)
  1252       | mtch Ts i j inst (prf1 % opt1, prf2 % opt2) =
  1253           optmatch (matcht Ts j) (mtch Ts i j inst (prf1, prf2)) (opt1, opt2)
  1254       | mtch Ts i j inst (prf1 %% prf2, prf1' %% prf2') =
  1255           mtch Ts i j (mtch Ts i j inst (prf1, prf1')) (prf2, prf2')
  1256       | mtch Ts i j inst (Abst (_, opT, prf1), Abst (_, opU, prf2)) =
  1257           mtch (the_default dummyT opU :: Ts) i (j+1)
  1258             (optmatch matchT inst (opT, opU)) (prf1, prf2)
  1259       | mtch Ts i j inst (prf1, Abst (_, opU, prf2)) =
  1260           mtch (the_default dummyT opU :: Ts) i (j+1) inst
  1261             (incr_pboundvars 0 1 prf1 %> Bound 0, prf2)
  1262       | mtch Ts i j inst (AbsP (_, opt, prf1), AbsP (_, opu, prf2)) =
  1263           mtch Ts (i+1) j (optmatch (matcht Ts j) inst (opt, opu)) (prf1, prf2)
  1264       | mtch Ts i j inst (prf1, AbsP (_, _, prf2)) =
  1265           mtch Ts (i+1) j inst (incr_pboundvars 1 0 prf1 %% PBound 0, prf2)
  1266       | mtch Ts i j inst (PAxm (s1, _, opTs), PAxm (s2, _, opUs)) =
  1267           if s1 = s2 then optmatch matchTs inst (opTs, opUs)
  1268           else raise PMatch
  1269       | mtch Ts i j inst (OfClass (T1, c1), OfClass (T2, c2)) =
  1270           if c1 = c2 then matchT inst (T1, T2)
  1271           else raise PMatch
  1272       | mtch Ts i j inst (PThm (_, ((name1, prop1, opTs), _)), PThm (_, ((name2, prop2, opUs), _))) =
  1273           if name1 = name2 andalso prop1 = prop2 then
  1274             optmatch matchTs inst (opTs, opUs)
  1275           else raise PMatch
  1276       | mtch _ _ _ inst (PBound i, PBound j) = if i = j then inst else raise PMatch
  1277       | mtch _ _ _ _ _ = raise PMatch
  1278   in mtch Ts 0 0 end;
  1279 
  1280 fun prf_subst (pinst, (tyinsts, insts)) =
  1281   let
  1282     val substT = Envir.subst_type_same tyinsts;
  1283     val substTs = Same.map substT;
  1284 
  1285     fun subst' lev (Var (xi, _)) =
  1286         (case AList.lookup (op =) insts xi of
  1287           NONE => raise Same.SAME
  1288         | SOME u => incr_boundvars lev u)
  1289       | subst' _ (Const (s, T)) = Const (s, substT T)
  1290       | subst' _ (Free (s, T)) = Free (s, substT T)
  1291       | subst' lev (Abs (a, T, body)) =
  1292           (Abs (a, substT T, Same.commit (subst' (lev + 1)) body)
  1293             handle Same.SAME => Abs (a, T, subst' (lev + 1) body))
  1294       | subst' lev (f $ t) =
  1295           (subst' lev f $ Same.commit (subst' lev) t
  1296             handle Same.SAME => f $ subst' lev t)
  1297       | subst' _ _ = raise Same.SAME;
  1298 
  1299     fun subst plev tlev (AbsP (a, t, body)) =
  1300           (AbsP (a, Same.map_option (subst' tlev) t, Same.commit (subst (plev + 1) tlev) body)
  1301             handle Same.SAME => AbsP (a, t, subst (plev + 1) tlev body))
  1302       | subst plev tlev (Abst (a, T, body)) =
  1303           (Abst (a, Same.map_option substT T, Same.commit (subst plev (tlev + 1)) body)
  1304             handle Same.SAME => Abst (a, T, subst plev (tlev + 1) body))
  1305       | subst plev tlev (prf %% prf') =
  1306           (subst plev tlev prf %% Same.commit (subst plev tlev) prf'
  1307             handle Same.SAME => prf %% subst plev tlev prf')
  1308       | subst plev tlev (prf % t) =
  1309           (subst plev tlev prf % Same.commit (Same.map_option (subst' tlev)) t
  1310             handle Same.SAME => prf % Same.map_option (subst' tlev) t)
  1311       | subst plev tlev (Hyp (Var (xi, _))) =
  1312           (case AList.lookup (op =) pinst xi of
  1313             NONE => raise Same.SAME
  1314           | SOME prf' => incr_pboundvars plev tlev prf')
  1315       | subst _ _ (PAxm (id, prop, Ts)) = PAxm (id, prop, Same.map_option substTs Ts)
  1316       | subst _ _ (OfClass (T, c)) = OfClass (substT T, c)
  1317       | subst _ _ (Oracle (id, prop, Ts)) = Oracle (id, prop, Same.map_option substTs Ts)
  1318       | subst _ _ (Promise (i, prop, Ts)) = Promise (i, prop, substTs Ts)
  1319       | subst _ _ (PThm (i, ((id, prop, Ts), body))) =
  1320           PThm (i, ((id, prop, Same.map_option substTs Ts), body))
  1321       | subst _ _ _ = raise Same.SAME;
  1322   in fn t => subst 0 0 t handle Same.SAME => t end;
  1323 
  1324 (*A fast unification filter: true unless the two terms cannot be unified.
  1325   Terms must be NORMAL.  Treats all Vars as distinct. *)
  1326 fun could_unify prf1 prf2 =
  1327   let
  1328     fun matchrands (prf1 %% prf2) (prf1' %% prf2') =
  1329           could_unify prf2 prf2' andalso matchrands prf1 prf1'
  1330       | matchrands (prf % SOME t) (prf' % SOME t') =
  1331           Term.could_unify (t, t') andalso matchrands prf prf'
  1332       | matchrands (prf % _) (prf' % _) = matchrands prf prf'
  1333       | matchrands _ _ = true
  1334 
  1335     fun head_of (prf %% _) = head_of prf
  1336       | head_of (prf % _) = head_of prf
  1337       | head_of prf = prf
  1338 
  1339   in case (head_of prf1, head_of prf2) of
  1340         (_, Hyp (Var _)) => true
  1341       | (Hyp (Var _), _) => true
  1342       | (PAxm (a, _, _), PAxm (b, _, _)) => a = b andalso matchrands prf1 prf2
  1343       | (OfClass (_, c), OfClass (_, d)) => c = d andalso matchrands prf1 prf2
  1344       | (PThm (_, ((a, propa, _), _)), PThm (_, ((b, propb, _), _))) =>
  1345           a = b andalso propa = propb andalso matchrands prf1 prf2
  1346       | (PBound i, PBound j) => i = j andalso matchrands prf1 prf2
  1347       | (AbsP _, _) =>  true   (*because of possible eta equality*)
  1348       | (Abst _, _) =>  true
  1349       | (_, AbsP _) =>  true
  1350       | (_, Abst _) =>  true
  1351       | _ => false
  1352   end;
  1353 
  1354 
  1355 (**** rewriting on proof terms ****)
  1356 
  1357 val no_skel = PBound 0;
  1358 val normal_skel = Hyp (Var ((Name.uu, 0), propT));
  1359 
  1360 fun rewrite_prf tymatch (rules, procs) prf =
  1361   let
  1362     fun rew _ _ (Abst (_, _, body) % SOME t) = SOME (prf_subst_bounds [t] body, no_skel)
  1363       | rew _ _ (AbsP (_, _, body) %% prf) = SOME (prf_subst_pbounds [prf] body, no_skel)
  1364       | rew Ts hs prf =
  1365           (case get_first (fn r => r Ts hs prf) procs of
  1366             NONE => get_first (fn (prf1, prf2) => SOME (prf_subst
  1367               (match_proof Ts tymatch ([], (Vartab.empty, [])) (prf1, prf)) prf2, prf2)
  1368                  handle PMatch => NONE) (filter (could_unify prf o fst) rules)
  1369           | some => some);
  1370 
  1371     fun rew0 Ts hs (prf as AbsP (_, _, prf' %% PBound 0)) =
  1372           if prf_loose_Pbvar1 prf' 0 then rew Ts hs prf
  1373           else
  1374             let val prf'' = incr_pboundvars (~1) 0 prf'
  1375             in SOME (the_default (prf'', no_skel) (rew Ts hs prf'')) end
  1376       | rew0 Ts hs (prf as Abst (_, _, prf' % SOME (Bound 0))) =
  1377           if prf_loose_bvar1 prf' 0 then rew Ts hs prf
  1378           else
  1379             let val prf'' = incr_pboundvars 0 (~1) prf'
  1380             in SOME (the_default (prf'', no_skel) (rew Ts hs prf'')) end
  1381       | rew0 Ts hs prf = rew Ts hs prf;
  1382 
  1383     fun rew1 _ _ (Hyp (Var _)) _ = NONE
  1384       | rew1 Ts hs skel prf = (case rew2 Ts hs skel prf of
  1385           SOME prf1 => (case rew0 Ts hs prf1 of
  1386               SOME (prf2, skel') => SOME (the_default prf2 (rew1 Ts hs skel' prf2))
  1387             | NONE => SOME prf1)
  1388         | NONE => (case rew0 Ts hs prf of
  1389               SOME (prf1, skel') => SOME (the_default prf1 (rew1 Ts hs skel' prf1))
  1390             | NONE => NONE))
  1391 
  1392     and rew2 Ts hs skel (prf % SOME t) = (case prf of
  1393             Abst (_, _, body) =>
  1394               let val prf' = prf_subst_bounds [t] body
  1395               in SOME (the_default prf' (rew2 Ts hs no_skel prf')) end
  1396           | _ => (case rew1 Ts hs (case skel of skel' % _ => skel' | _ => no_skel) prf of
  1397               SOME prf' => SOME (prf' % SOME t)
  1398             | NONE => NONE))
  1399       | rew2 Ts hs skel (prf % NONE) = Option.map (fn prf' => prf' % NONE)
  1400           (rew1 Ts hs (case skel of skel' % _ => skel' | _ => no_skel) prf)
  1401       | rew2 Ts hs skel (prf1 %% prf2) = (case prf1 of
  1402             AbsP (_, _, body) =>
  1403               let val prf' = prf_subst_pbounds [prf2] body
  1404               in SOME (the_default prf' (rew2 Ts hs no_skel prf')) end
  1405           | _ =>
  1406             let val (skel1, skel2) = (case skel of
  1407                 skel1 %% skel2 => (skel1, skel2)
  1408               | _ => (no_skel, no_skel))
  1409             in case rew1 Ts hs skel1 prf1 of
  1410                 SOME prf1' => (case rew1 Ts hs skel2 prf2 of
  1411                     SOME prf2' => SOME (prf1' %% prf2')
  1412                   | NONE => SOME (prf1' %% prf2))
  1413               | NONE => (case rew1 Ts hs skel2 prf2 of
  1414                     SOME prf2' => SOME (prf1 %% prf2')
  1415                   | NONE => NONE)
  1416             end)
  1417       | rew2 Ts hs skel (Abst (s, T, prf)) = (case rew1 (the_default dummyT T :: Ts) hs
  1418               (case skel of Abst (_, _, skel') => skel' | _ => no_skel) prf of
  1419             SOME prf' => SOME (Abst (s, T, prf'))
  1420           | NONE => NONE)
  1421       | rew2 Ts hs skel (AbsP (s, t, prf)) = (case rew1 Ts (t :: hs)
  1422               (case skel of AbsP (_, _, skel') => skel' | _ => no_skel) prf of
  1423             SOME prf' => SOME (AbsP (s, t, prf'))
  1424           | NONE => NONE)
  1425       | rew2 _ _ _ _ = NONE;
  1426 
  1427   in the_default prf (rew1 [] [] no_skel prf) end;
  1428 
  1429 fun rewrite_proof thy = rewrite_prf (fn (tyenv, f) =>
  1430   Sign.typ_match thy (f ()) tyenv handle Type.TYPE_MATCH => raise PMatch);
  1431 
  1432 fun rewrite_proof_notypes rews = rewrite_prf fst rews;
  1433 
  1434 
  1435 (**** theory data ****)
  1436 
  1437 structure Data = Theory_Data
  1438 (
  1439   type T =
  1440     (stamp * (proof * proof)) list *
  1441     (stamp * (typ list -> term option list -> proof -> (proof * proof) option)) list;
  1442 
  1443   val empty = ([], []);
  1444   val extend = I;
  1445   fun merge ((rules1, procs1), (rules2, procs2)) : T =
  1446     (AList.merge (op =) (K true) (rules1, rules2),
  1447       AList.merge (op =) (K true) (procs1, procs2));
  1448 );
  1449 
  1450 fun get_data thy = let val (rules, procs) = Data.get thy in (map #2 rules, map #2 procs) end;
  1451 fun rew_proof thy = rewrite_prf fst (get_data thy);
  1452 
  1453 fun add_prf_rrule r = (Data.map o apfst) (cons (stamp (), r));
  1454 fun add_prf_rproc p = (Data.map o apsnd) (cons (stamp (), p));
  1455 
  1456 
  1457 (***** promises *****)
  1458 
  1459 fun promise_proof thy i prop =
  1460   let
  1461     val _ = prop |> Term.exists_subterm (fn t =>
  1462       (Term.is_Free t orelse Term.is_Var t) andalso
  1463         raise Fail ("promise_proof: illegal variable " ^ Syntax.string_of_term_global thy t));
  1464     val _ = prop |> Term.exists_type (Term.exists_subtype
  1465       (fn TFree (a, _) => raise Fail ("promise_proof: illegal type variable " ^ quote a)
  1466         | _ => false));
  1467   in Promise (i, prop, map TVar (Term.add_tvars prop [])) end;
  1468 
  1469 fun fulfill_norm_proof thy ps body0 =
  1470   let
  1471     val PBody {oracles = oracles0, thms = thms0, proof = proof0} = body0;
  1472     val oracles =
  1473       unions_oracles
  1474         (fold (fn (_, PBody {oracles, ...}) => not (null oracles) ? cons oracles) ps [oracles0]);
  1475     val thms =
  1476       unions_thms (fold (fn (_, PBody {thms, ...}) => not (null thms) ? cons thms) ps [thms0]);
  1477     val proofs = fold (fn (i, PBody {proof, ...}) => Inttab.update (i, proof)) ps Inttab.empty;
  1478 
  1479     fun fill (Promise (i, prop, Ts)) =
  1480           (case Inttab.lookup proofs i of
  1481             NONE => NONE
  1482           | SOME prf => SOME (instantiate (Term.add_tvars prop [] ~~ Ts, []) prf, normal_skel))
  1483       | fill _ = NONE;
  1484     val (rules, procs) = get_data thy;
  1485     val proof = rewrite_prf fst (rules, K (K fill) :: procs) proof0;
  1486   in PBody {oracles = oracles, thms = thms, proof = proof} end;
  1487 
  1488 fun fulfill_proof_future thy promises postproc body =
  1489   let
  1490     fun fulfill () =
  1491       postproc (fulfill_norm_proof thy (map (apsnd Future.join) promises) (Future.join body));
  1492   in
  1493     if null promises then Future.map postproc body
  1494     else if Future.is_finished body andalso length promises = 1 then
  1495       Future.map (fn _ => fulfill ()) (snd (hd promises))
  1496     else
  1497       (singleton o Future.forks)
  1498         {name = "Proofterm.fulfill_proof_future", group = NONE,
  1499           deps = Future.task_of body :: map (Future.task_of o snd) promises, pri = 0,
  1500           interrupts = true}
  1501         fulfill
  1502   end;
  1503 
  1504 
  1505 (***** abstraction over sort constraints *****)
  1506 
  1507 fun unconstrainT_prf thy (atyp_map, constraints) =
  1508   let
  1509     fun hyp_map hyp =
  1510       (case AList.lookup (op =) constraints hyp of
  1511         SOME t => Hyp t
  1512       | NONE => raise Fail "unconstrainT_prf: missing constraint");
  1513 
  1514     val typ = Term_Subst.map_atypsT_same (Type.strip_sorts o atyp_map);
  1515     fun ofclass (ty, c) =
  1516       let val ty' = Term.map_atyps atyp_map ty;
  1517       in the_single (of_sort_proof thy hyp_map (ty', [c])) end;
  1518   in
  1519     Same.commit (map_proof_same (Term_Subst.map_types_same typ) typ ofclass)
  1520     #> fold_rev (implies_intr_proof o snd) constraints
  1521   end;
  1522 
  1523 fun unconstrainT_body thy constrs (PBody {oracles, thms, proof}) =
  1524   PBody
  1525    {oracles = oracles,  (* FIXME merge (!), unconstrain (!?!) *)
  1526     thms = thms,  (* FIXME merge (!) *)
  1527     proof = unconstrainT_prf thy constrs proof};
  1528 
  1529 
  1530 (***** theorems *****)
  1531 
  1532 fun prepare_thm_proof thy name shyps hyps concl promises body =
  1533   let
  1534     val PBody {oracles = oracles0, thms = thms0, proof = prf} = body;
  1535     val prop = Logic.list_implies (hyps, concl);
  1536     val nvs = needed_vars prop;
  1537     val args = map (fn (v as Var (ixn, _)) =>
  1538         if member (op =) nvs ixn then SOME v else NONE) (vars_of prop) @
  1539       map SOME (frees_of prop);
  1540 
  1541     val ((atyp_map, constraints, outer_constraints), prop1) = Logic.unconstrainT shyps prop;
  1542     val postproc = unconstrainT_body thy (atyp_map, constraints);
  1543     val args1 =
  1544       (map o Option.map o Term.map_types o Term.map_atyps)
  1545         (Type.strip_sorts o atyp_map) args;
  1546     val argsP = map OfClass outer_constraints @ map Hyp hyps;
  1547 
  1548     fun make_body0 proof0 = PBody {oracles = oracles0, thms = thms0, proof = proof0};
  1549     val body0 =
  1550       if not (proofs_enabled ()) then Future.value (make_body0 MinProof)
  1551       else
  1552         (singleton o Future.cond_forks)
  1553           {name = "Proofterm.prepare_thm_proof", group = NONE,
  1554             deps = [], pri = 0, interrupts = true}
  1555           (fn () =>
  1556             make_body0
  1557               (#4 (shrink_proof thy [] 0 (rew_proof thy (fold_rev implies_intr_proof hyps prf)))));
  1558 
  1559     fun new_prf () = (serial (), fulfill_proof_future thy promises postproc body0);
  1560     val (i, body') =
  1561       (*non-deterministic, depends on unknown promises*)
  1562       (case strip_combt (fst (strip_combP prf)) of
  1563         (PThm (i, ((old_name, prop', NONE), body')), args') =>
  1564           if (old_name = "" orelse old_name = name) andalso prop1 = prop' andalso args = args'
  1565           then (i, body')
  1566           else new_prf ()
  1567       | _ => new_prf ());
  1568     val head = PThm (i, ((name, prop1, NONE), body'));
  1569   in ((i, (name, prop1, body')), head, args, argsP, args1) end;
  1570 
  1571 fun thm_proof thy name shyps hyps concl promises body =
  1572   let val (pthm, head, args, argsP, _) = prepare_thm_proof thy name shyps hyps concl promises body
  1573   in (pthm, proof_combP (proof_combt' (head, args), argsP)) end;
  1574 
  1575 fun unconstrain_thm_proof thy shyps concl promises body =
  1576   let
  1577     val (pthm, head, _, _, args) = prepare_thm_proof thy "" shyps [] concl promises body
  1578   in (pthm, proof_combt' (head, args)) end;
  1579 
  1580 
  1581 fun get_name shyps hyps prop prf =
  1582   let val (_, prop) = Logic.unconstrainT shyps (Logic.list_implies (hyps, prop)) in
  1583     (case strip_combt (fst (strip_combP prf)) of
  1584       (PThm (_, ((name, prop', _), _)), _) => if prop = prop' then name else ""
  1585     | _ => "")
  1586   end;
  1587 
  1588 fun guess_name (PThm (_, ((name, _, _), _))) = name
  1589   | guess_name (prf %% Hyp _) = guess_name prf
  1590   | guess_name (prf %% OfClass _) = guess_name prf
  1591   | guess_name (prf % NONE) = guess_name prf
  1592   | guess_name (prf % SOME (Var _)) = guess_name prf
  1593   | guess_name _ = "";
  1594 
  1595 end;
  1596 
  1597 structure Basic_Proofterm : BASIC_PROOFTERM = Proofterm;
  1598 open Basic_Proofterm;