src/Pure/variable.ML
author wenzelm
Tue Dec 13 11:51:42 2016 +0100 (2016-12-13)
changeset 64556 851ae0e7b09c
parent 62987 dc8a8a7559e7
child 67721 5348bea4accd
permissions -rw-r--r--
more symbols;
     1 (*  Title:      Pure/variable.ML
     2     Author:     Makarius
     3 
     4 Fixed type/term variables and polymorphic term abbreviations.
     5 *)
     6 
     7 signature VARIABLE =
     8 sig
     9   val names_of: Proof.context -> Name.context
    10   val binds_of: Proof.context -> (typ * term) Vartab.table
    11   val maxidx_of: Proof.context -> int
    12   val constraints_of: Proof.context -> typ Vartab.table * sort Vartab.table
    13   val is_declared: Proof.context -> string -> bool
    14   val check_name: binding -> string
    15   val default_type: Proof.context -> string -> typ option
    16   val def_type: Proof.context -> bool -> indexname -> typ option
    17   val def_sort: Proof.context -> indexname -> sort option
    18   val declare_maxidx: int -> Proof.context -> Proof.context
    19   val declare_names: term -> Proof.context -> Proof.context
    20   val declare_constraints: term -> Proof.context -> Proof.context
    21   val declare_internal: term -> Proof.context -> Proof.context
    22   val declare_term: term -> Proof.context -> Proof.context
    23   val declare_typ: typ -> Proof.context -> Proof.context
    24   val declare_prf: Proofterm.proof -> Proof.context -> Proof.context
    25   val declare_thm: thm -> Proof.context -> Proof.context
    26   val variant_frees: Proof.context -> term list -> (string * 'a) list -> (string * 'a) list
    27   val bind_term: indexname * term -> Proof.context -> Proof.context
    28   val unbind_term: indexname -> Proof.context -> Proof.context
    29   val maybe_bind_term: indexname * term option -> Proof.context -> Proof.context
    30   val expand_binds: Proof.context -> term -> term
    31   val lookup_const: Proof.context -> string -> string option
    32   val is_const: Proof.context -> string -> bool
    33   val declare_const: string * string -> Proof.context -> Proof.context
    34   val next_bound: string * typ -> Proof.context -> term * Proof.context
    35   val revert_bounds: Proof.context -> term -> term
    36   val is_body: Proof.context -> bool
    37   val set_body: bool -> Proof.context -> Proof.context
    38   val restore_body: Proof.context -> Proof.context -> Proof.context
    39   val improper_fixes: Proof.context -> Proof.context
    40   val restore_proper_fixes: Proof.context -> Proof.context -> Proof.context
    41   val is_improper: Proof.context -> string -> bool
    42   val is_fixed: Proof.context -> string -> bool
    43   val is_newly_fixed: Proof.context -> Proof.context -> string -> bool
    44   val fixed_ord: Proof.context -> string * string -> order
    45   val intern_fixed: Proof.context -> string -> string
    46   val lookup_fixed: Proof.context -> string -> string option
    47   val revert_fixed: Proof.context -> string -> string
    48   val markup_fixed: Proof.context -> string -> Markup.T
    49   val markup: Proof.context -> string -> Markup.T
    50   val markup_entity_def: Proof.context -> string -> Markup.T
    51   val dest_fixes: Proof.context -> (string * string) list
    52   val add_fixed_names: Proof.context -> term -> string list -> string list
    53   val add_fixed: Proof.context -> term -> (string * typ) list -> (string * typ) list
    54   val add_newly_fixed: Proof.context -> Proof.context ->
    55     term -> (string * typ) list -> (string * typ) list
    56   val add_free_names: Proof.context -> term -> string list -> string list
    57   val add_frees: Proof.context -> term -> (string * typ) list -> (string * typ) list
    58   val add_fixes_binding: binding list -> Proof.context -> string list * Proof.context
    59   val add_fixes: string list -> Proof.context -> string list * Proof.context
    60   val add_fixes_direct: string list -> Proof.context -> Proof.context
    61   val auto_fixes: term -> Proof.context -> Proof.context
    62   val fix_dummy_patterns: term -> Proof.context -> term * Proof.context
    63   val variant_fixes: string list -> Proof.context -> string list * Proof.context
    64   val gen_all: Proof.context -> thm -> thm
    65   val export_terms: Proof.context -> Proof.context -> term list -> term list
    66   val exportT_terms: Proof.context -> Proof.context -> term list -> term list
    67   val exportT: Proof.context -> Proof.context -> thm list -> thm list
    68   val export_prf: Proof.context -> Proof.context -> Proofterm.proof -> Proofterm.proof
    69   val export: Proof.context -> Proof.context -> thm list -> thm list
    70   val export_morphism: Proof.context -> Proof.context -> morphism
    71   val invent_types: sort list -> Proof.context -> (string * sort) list * Proof.context
    72   val importT_inst: term list -> Proof.context -> ((indexname * sort) * typ) list * Proof.context
    73   val import_inst: bool -> term list -> Proof.context ->
    74     (((indexname * sort) * typ) list * ((indexname * typ) * term) list) * Proof.context
    75   val importT_terms: term list -> Proof.context -> term list * Proof.context
    76   val import_terms: bool -> term list -> Proof.context -> term list * Proof.context
    77   val importT: thm list -> Proof.context ->
    78     (((indexname * sort) * ctyp) list * thm list) * Proof.context
    79   val import_prf: bool -> Proofterm.proof -> Proof.context -> Proofterm.proof * Proof.context
    80   val import: bool -> thm list -> Proof.context ->
    81     ((((indexname * sort) * ctyp) list * ((indexname * typ) * cterm) list) * thm list) * Proof.context
    82   val tradeT: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    83   val trade: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    84   val is_bound_focus: Proof.context -> bool
    85   val set_bound_focus: bool -> Proof.context -> Proof.context
    86   val restore_bound_focus: Proof.context -> Proof.context -> Proof.context
    87   val focus_params: binding list option -> term -> Proof.context ->
    88     (string list * (string * typ) list) * Proof.context
    89   val focus: binding list option -> term -> Proof.context ->
    90     ((string * (string * typ)) list * term) * Proof.context
    91   val focus_cterm: binding list option -> cterm -> Proof.context ->
    92     ((string * cterm) list * cterm) * Proof.context
    93   val focus_subgoal: binding list option -> int -> thm -> Proof.context ->
    94     ((string * cterm) list * cterm) * Proof.context
    95   val warn_extra_tfrees: Proof.context -> Proof.context -> unit
    96   val polymorphic_types: Proof.context -> term list -> (indexname * sort) list * term list
    97   val polymorphic: Proof.context -> term list -> term list
    98 end;
    99 
   100 structure Variable: VARIABLE =
   101 struct
   102 
   103 (** local context data **)
   104 
   105 type fixes = (string * bool) Name_Space.table;
   106 val empty_fixes: fixes = Name_Space.empty_table Markup.fixedN;
   107 
   108 datatype data = Data of
   109  {names: Name.context,                  (*type/term variable names*)
   110   consts: string Symtab.table,          (*consts within the local scope*)
   111   bounds: int * ((string * typ) * string) list,  (*next index, internal name, type, external name*)
   112   fixes: fixes,                         (*term fixes -- global name space, intern ~> extern*)
   113   binds: (typ * term) Vartab.table,     (*term bindings*)
   114   type_occs: string list Symtab.table,  (*type variables -- possibly within term variables*)
   115   maxidx: int,                          (*maximum var index*)
   116   constraints:
   117     typ Vartab.table *                  (*type constraints*)
   118     sort Vartab.table};                 (*default sorts*)
   119 
   120 fun make_data (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints) =
   121   Data {names = names, consts = consts, bounds = bounds, fixes = fixes, binds = binds,
   122     type_occs = type_occs, maxidx = maxidx, constraints = constraints};
   123 
   124 val empty_data =
   125   make_data (Name.context, Symtab.empty, (0, []), empty_fixes, Vartab.empty,
   126     Symtab.empty, ~1, (Vartab.empty, Vartab.empty));
   127 
   128 structure Data = Proof_Data
   129 (
   130   type T = data;
   131   fun init _ = empty_data;
   132 );
   133 
   134 fun map_data f =
   135   Data.map (fn Data {names, consts, bounds, fixes, binds, type_occs, maxidx, constraints} =>
   136     make_data (f (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints)));
   137 
   138 fun map_names f =
   139   map_data (fn (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints) =>
   140     (f names, consts, bounds, fixes, binds, type_occs, maxidx, constraints));
   141 
   142 fun map_consts f =
   143   map_data (fn (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints) =>
   144     (names, f consts, bounds, fixes, binds, type_occs, maxidx, constraints));
   145 
   146 fun map_bounds f =
   147   map_data (fn (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints) =>
   148     (names, consts, f bounds, fixes, binds, type_occs, maxidx, constraints));
   149 
   150 fun map_fixes f =
   151   map_data (fn (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints) =>
   152     (names, consts, bounds, f fixes, binds, type_occs, maxidx, constraints));
   153 
   154 fun map_binds f =
   155   map_data (fn (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints) =>
   156     (names, consts, bounds, fixes, f binds, type_occs, maxidx, constraints));
   157 
   158 fun map_type_occs f =
   159   map_data (fn (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints) =>
   160     (names, consts, bounds, fixes, binds, f type_occs, maxidx, constraints));
   161 
   162 fun map_maxidx f =
   163   map_data (fn (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints) =>
   164     (names, consts, bounds, fixes, binds, type_occs, f maxidx, constraints));
   165 
   166 fun map_constraints f =
   167   map_data (fn (names, consts, bounds, fixes, binds, type_occs, maxidx, constraints) =>
   168     (names, consts, bounds, fixes, binds, type_occs, maxidx, f constraints));
   169 
   170 fun rep_data ctxt = Data.get ctxt |> (fn Data rep => rep);
   171 
   172 val names_of = #names o rep_data;
   173 val fixes_of = #fixes o rep_data;
   174 val fixes_space = Name_Space.space_of_table o fixes_of;
   175 val binds_of = #binds o rep_data;
   176 val type_occs_of = #type_occs o rep_data;
   177 val maxidx_of = #maxidx o rep_data;
   178 val constraints_of = #constraints o rep_data;
   179 
   180 val is_declared = Name.is_declared o names_of;
   181 
   182 val check_name = Name_Space.base_name o tap Binding.check;
   183 
   184 
   185 
   186 (** declarations **)
   187 
   188 (* default sorts and types *)
   189 
   190 fun default_type ctxt x = Vartab.lookup (#1 (constraints_of ctxt)) (x, ~1);
   191 
   192 fun def_type ctxt pattern xi =
   193   let val {binds, constraints = (types, _), ...} = rep_data ctxt in
   194     (case Vartab.lookup types xi of
   195       NONE =>
   196         if pattern then NONE
   197         else Vartab.lookup binds xi |> Option.map (Type.mark_polymorphic o #1)
   198     | some => some)
   199   end;
   200 
   201 val def_sort = Vartab.lookup o #2 o constraints_of;
   202 
   203 
   204 (* maxidx *)
   205 
   206 val declare_maxidx = map_maxidx o Integer.max;
   207 
   208 
   209 (* names *)
   210 
   211 fun declare_type_names t =
   212   map_names (fold_types (fold_atyps Term.declare_typ_names) t) #>
   213   map_maxidx (fold_types Term.maxidx_typ t);
   214 
   215 fun declare_names t =
   216   declare_type_names t #>
   217   map_names (fold_aterms Term.declare_term_frees t) #>
   218   map_maxidx (Term.maxidx_term t);
   219 
   220 
   221 (* type occurrences *)
   222 
   223 fun decl_type_occsT T = fold_atyps (fn TFree (a, _) => Symtab.default (a, []) | _ => I) T;
   224 
   225 val decl_type_occs = fold_term_types
   226   (fn Free (x, _) => fold_atyps (fn TFree (a, _) => Symtab.insert_list (op =) (a, x) | _ => I)
   227     | _ => decl_type_occsT);
   228 
   229 val declare_type_occsT = map_type_occs o fold_types decl_type_occsT;
   230 val declare_type_occs = map_type_occs o decl_type_occs;
   231 
   232 
   233 (* constraints *)
   234 
   235 fun constrain_tvar (xi, raw_S) =
   236   let val S = #2 (Term_Position.decode_positionS raw_S)
   237   in if S = dummyS then Vartab.delete_safe xi else Vartab.update (xi, S) end;
   238 
   239 fun declare_constraints t = map_constraints (fn (types, sorts) =>
   240   let
   241     val types' = fold_aterms
   242       (fn Free (x, T) => Vartab.update ((x, ~1), T)
   243         | Var v => Vartab.update v
   244         | _ => I) t types;
   245     val sorts' = (fold_types o fold_atyps)
   246       (fn TFree (x, S) => constrain_tvar ((x, ~1), S)
   247         | TVar v => constrain_tvar v
   248         | _ => I) t sorts;
   249   in (types', sorts') end)
   250   #> declare_type_occsT t
   251   #> declare_type_names t;
   252 
   253 
   254 (* common declarations *)
   255 
   256 fun declare_internal t =
   257   declare_names t #>
   258   declare_type_occs t #>
   259   Thm.declare_term_sorts t;
   260 
   261 fun declare_term t =
   262   declare_internal t #>
   263   declare_constraints t;
   264 
   265 val declare_typ = declare_term o Logic.mk_type;
   266 
   267 val declare_prf = Proofterm.fold_proof_terms declare_internal (declare_internal o Logic.mk_type);
   268 
   269 val declare_thm = Thm.fold_terms declare_internal;
   270 
   271 
   272 (* renaming term/type frees *)
   273 
   274 fun variant_frees ctxt ts frees =
   275   let
   276     val names = names_of (fold declare_names ts ctxt);
   277     val xs = fst (fold_map Name.variant (map #1 frees) names);
   278   in xs ~~ map snd frees end;
   279 
   280 
   281 
   282 (** term bindings **)
   283 
   284 fun bind_term ((x, i), t) =
   285   let
   286     val u = Term.close_schematic_term t;
   287     val U = Term.fastype_of u;
   288   in declare_term u #> map_binds (Vartab.update ((x, i), (U, u))) end;
   289 
   290 val unbind_term = map_binds o Vartab.delete_safe;
   291 
   292 fun maybe_bind_term (xi, SOME t) = bind_term (xi, t)
   293   | maybe_bind_term (xi, NONE) = unbind_term xi;
   294 
   295 fun expand_binds ctxt =
   296   let
   297     val binds = binds_of ctxt;
   298     val get = fn Var (xi, _) => Vartab.lookup binds xi | _ => NONE;
   299   in Envir.beta_norm o Envir.expand_term get end;
   300 
   301 
   302 
   303 (** consts **)
   304 
   305 val lookup_const = Symtab.lookup o #consts o rep_data;
   306 val is_const = is_some oo lookup_const;
   307 
   308 val declare_fixed = map_consts o Symtab.delete_safe;
   309 val declare_const = map_consts o Symtab.update;
   310 
   311 
   312 
   313 (** bounds **)
   314 
   315 fun next_bound (a, T) ctxt =
   316   let
   317     val b = Name.bound (#1 (#bounds (rep_data ctxt)));
   318     val ctxt' = ctxt |> map_bounds (fn (next, bounds) => (next + 1, ((b, T), a) :: bounds));
   319   in (Free (b, T), ctxt') end;
   320 
   321 fun revert_bounds ctxt t =
   322   (case #2 (#bounds (rep_data ctxt)) of
   323     [] => t
   324   | bounds =>
   325       let
   326         val names = Term.declare_term_names t (names_of ctxt);
   327         val xs = rev (#1 (fold_map Name.variant (rev (map #2 bounds)) names));
   328         fun subst ((b, T), _) x' = (Free (b, T), Syntax_Trans.mark_bound_abs (x', T));
   329       in Term.subst_atomic (map2 subst bounds xs) t end);
   330 
   331 
   332 
   333 (** fixes **)
   334 
   335 (* inner body mode *)
   336 
   337 val inner_body =
   338   Config.bool (Config.declare ("inner_body", \<^here>) (K (Config.Bool false)));
   339 
   340 fun is_body ctxt = Config.get ctxt inner_body;
   341 val set_body = Config.put inner_body;
   342 fun restore_body ctxt = set_body (is_body ctxt);
   343 
   344 
   345 (* proper mode *)
   346 
   347 val proper_fixes =
   348   Config.bool (Config.declare ("proper_fixes", \<^here>) (K (Config.Bool true)));
   349 
   350 val improper_fixes = Config.put proper_fixes false;
   351 fun restore_proper_fixes ctxt = Config.put proper_fixes (Config.get ctxt proper_fixes);
   352 
   353 fun is_improper ctxt x =
   354   (case Name_Space.lookup (fixes_of ctxt) x of
   355     SOME (_, proper) => not proper
   356   | NONE => false);
   357 
   358 
   359 (* specialized name space *)
   360 
   361 val is_fixed = Name_Space.defined o fixes_of;
   362 fun is_newly_fixed inner outer = is_fixed inner andf (not o is_fixed outer);
   363 
   364 val fixed_ord = Name_Space.entry_ord o fixes_space;
   365 val intern_fixed = Name_Space.intern o fixes_space;
   366 
   367 fun lookup_fixed ctxt x =
   368   let val x' = intern_fixed ctxt x
   369   in if is_fixed ctxt x' then SOME x' else NONE end;
   370 
   371 fun revert_fixed ctxt x =
   372   (case Name_Space.lookup (fixes_of ctxt) x of
   373     SOME (x', _) => if intern_fixed ctxt x' = x then x' else x
   374   | NONE => x);
   375 
   376 fun markup_fixed ctxt x =
   377   Name_Space.markup (fixes_space ctxt) x
   378   |> Markup.name (revert_fixed ctxt x);
   379 
   380 fun markup ctxt x =
   381   if is_improper ctxt x then Markup.improper
   382   else if Name.is_skolem x then Markup.skolem
   383   else Markup.free;
   384 
   385 val markup_entity_def = Name_Space.markup_def o fixes_space;
   386 
   387 fun dest_fixes ctxt =
   388   Name_Space.fold_table (fn (x, (y, _)) => cons (y, x)) (fixes_of ctxt) []
   389   |> sort (Name_Space.entry_ord (fixes_space ctxt) o apply2 #2);
   390 
   391 
   392 (* collect variables *)
   393 
   394 fun add_free_names ctxt =
   395   fold_aterms (fn Free (x, _) => not (is_fixed ctxt x) ? insert (op =) x | _ => I);
   396 
   397 fun add_frees ctxt =
   398   fold_aterms (fn Free (x, T) => not (is_fixed ctxt x) ? insert (op =) (x, T) | _ => I);
   399 
   400 fun add_fixed_names ctxt =
   401   fold_aterms (fn Free (x, _) => is_fixed ctxt x ? insert (op =) x | _ => I);
   402 
   403 fun add_fixed ctxt =
   404   fold_aterms (fn Free (x, T) => is_fixed ctxt x ? insert (op =) (x, T) | _ => I);
   405 
   406 fun add_newly_fixed ctxt' ctxt =
   407   fold_aterms (fn Free (x, T) => is_newly_fixed ctxt' ctxt x ? insert (op =) (x, T) | _ => I);
   408 
   409 
   410 (* declarations *)
   411 
   412 local
   413 
   414 fun err_dups dups =
   415   error ("Duplicate fixed variable(s): " ^ commas (map Binding.print dups));
   416 
   417 fun new_fixed ((x, x'), pos) ctxt =
   418   if is_some (lookup_fixed ctxt x') then err_dups [Binding.make (x, pos)]
   419   else
   420     let
   421       val proper = Config.get ctxt proper_fixes;
   422       val context = Context.Proof ctxt
   423         |> Name_Space.map_naming (K Name_Space.global_naming)
   424         |> Context_Position.set_visible_generic false;
   425     in
   426       ctxt
   427       |> map_fixes
   428         (Name_Space.define context true (Binding.make (x', pos), (x, proper)) #> snd #>
   429           Name_Space.alias_table Name_Space.global_naming (Binding.make (x, pos)) x')
   430       |> declare_fixed x
   431       |> declare_constraints (Syntax.free x')
   432   end;
   433 
   434 fun new_fixes names' xs xs' ps =
   435   map_names (K names') #>
   436   fold new_fixed ((xs ~~ xs') ~~ ps) #>
   437   pair xs';
   438 
   439 in
   440 
   441 fun add_fixes_binding bs ctxt =
   442   let
   443     val _ =
   444       (case filter (Name.is_skolem o Binding.name_of) bs of
   445         [] => ()
   446       | bads => error ("Illegal internal Skolem constant(s): " ^ commas (map Binding.print bads)));
   447     val _ =
   448       (case duplicates (op = o apply2 Binding.name_of) bs of
   449         [] => ()
   450       | dups => err_dups dups);
   451 
   452     val xs = map check_name bs;
   453     val names = names_of ctxt;
   454     val (xs', names') =
   455       if is_body ctxt then fold_map Name.variant xs names |>> map Name.skolem
   456       else (xs, fold Name.declare xs names);
   457   in ctxt |> new_fixes names' xs xs' (map Binding.pos_of bs) end;
   458 
   459 fun bound_fixes xs ctxt =
   460   let
   461     val (xs', ctxt') = fold_map next_bound xs ctxt;
   462     val no_ps = replicate (length xs) Position.none;
   463   in ctxt' |> new_fixes (names_of ctxt') (map #1 xs) (map (#1 o dest_Free) xs') no_ps end;
   464 
   465 fun variant_fixes raw_xs ctxt =
   466   let
   467     val names = names_of ctxt;
   468     val xs = map (fn x => Name.clean x |> Name.is_internal x ? Name.internal) raw_xs;
   469     val (xs', names') = fold_map Name.variant xs names |>> (is_body ctxt ? map Name.skolem);
   470     val no_ps = replicate (length xs) Position.none;
   471   in ctxt |> new_fixes names' xs xs' no_ps end;
   472 
   473 end;
   474 
   475 val add_fixes = add_fixes_binding o map Binding.name;
   476 
   477 fun add_fixes_direct xs ctxt = ctxt
   478   |> set_body false
   479   |> (snd o add_fixes xs)
   480   |> restore_body ctxt;
   481 
   482 fun auto_fixes t ctxt = ctxt
   483   |> not (is_body ctxt) ? add_fixes_direct (rev (add_free_names ctxt t []))
   484   |> declare_term t;
   485 
   486 
   487 (* dummy patterns *)
   488 
   489 fun fix_dummy_patterns (Const ("Pure.dummy_pattern", T)) ctxt =
   490       let val ([x], ctxt') = ctxt |> set_body true |> add_fixes [Name.uu_] ||> restore_body ctxt
   491       in (Free (x, T), ctxt') end
   492   | fix_dummy_patterns (Abs (x, T, b)) ctxt =
   493       let val (b', ctxt') = fix_dummy_patterns b ctxt
   494       in (Abs (x, T, b'), ctxt') end
   495   | fix_dummy_patterns (t $ u) ctxt =
   496       let
   497         val (t', ctxt') = fix_dummy_patterns t ctxt;
   498         val (u', ctxt'') = fix_dummy_patterns u ctxt';
   499       in (t' $ u', ctxt'') end
   500   | fix_dummy_patterns a ctxt = (a, ctxt);
   501 
   502 
   503 
   504 (** export -- generalize type/term variables (beware of closure sizes) **)
   505 
   506 fun gen_all ctxt th =
   507   let
   508     val i = Thm.maxidx_thm th (maxidx_of ctxt) + 1;
   509     fun gen (x, T) = Thm.forall_elim (Thm.cterm_of ctxt (Var ((x, i), T)));
   510   in fold gen (Drule.outer_params (Thm.prop_of th)) th end;
   511 
   512 fun export_inst inner outer =
   513   let
   514     val declared_outer = is_declared outer;
   515     val still_fixed = not o is_newly_fixed inner outer;
   516 
   517     val gen_fixes =
   518       Name_Space.fold_table (fn (y, _) => not (is_fixed outer y) ? cons y)
   519         (fixes_of inner) [];
   520 
   521     val type_occs_inner = type_occs_of inner;
   522     fun gen_fixesT ts =
   523       Symtab.fold (fn (a, xs) =>
   524         if declared_outer a orelse exists still_fixed xs
   525         then I else cons a) (fold decl_type_occs ts type_occs_inner) [];
   526   in (gen_fixesT, gen_fixes) end;
   527 
   528 fun exportT_inst inner outer = #1 (export_inst inner outer);
   529 
   530 fun exportT_terms inner outer =
   531   let
   532     val mk_tfrees = exportT_inst inner outer;
   533     val maxidx = maxidx_of outer;
   534   in
   535     fn ts => ts |> map
   536       (Term_Subst.generalize (mk_tfrees ts, [])
   537         (fold (Term.fold_types Term.maxidx_typ) ts maxidx + 1))
   538   end;
   539 
   540 fun export_terms inner outer =
   541   let
   542     val (mk_tfrees, tfrees) = export_inst inner outer;
   543     val maxidx = maxidx_of outer;
   544   in
   545     fn ts => ts |> map
   546       (Term_Subst.generalize (mk_tfrees ts, tfrees)
   547         (fold Term.maxidx_term ts maxidx + 1))
   548   end;
   549 
   550 fun export_prf inner outer prf =
   551   let
   552     val (mk_tfrees, frees) = export_inst (declare_prf prf inner) outer;
   553     val tfrees = mk_tfrees [];
   554     val maxidx = maxidx_of outer;
   555     val idx = Proofterm.maxidx_proof prf maxidx + 1;
   556     val gen_term = Term_Subst.generalize_same (tfrees, frees) idx;
   557     val gen_typ = Term_Subst.generalizeT_same tfrees idx;
   558   in Same.commit (Proofterm.map_proof_terms_same gen_term gen_typ) prf end;
   559 
   560 
   561 fun gen_export (mk_tfrees, frees) maxidx ths =
   562   let
   563     val tfrees = mk_tfrees (map Thm.full_prop_of ths);
   564     val idx = fold Thm.maxidx_thm ths maxidx + 1;
   565   in map (Thm.generalize (tfrees, frees) idx) ths end;
   566 
   567 fun exportT inner outer = gen_export (exportT_inst inner outer, []) (maxidx_of outer);
   568 fun export inner outer = gen_export (export_inst inner outer) (maxidx_of outer);
   569 
   570 fun export_morphism inner outer =
   571   let
   572     val fact = export inner outer;
   573     val term = singleton (export_terms inner outer);
   574     val typ = Logic.type_map term;
   575   in
   576     Morphism.morphism "Variable.export" {binding = [], typ = [typ], term = [term], fact = [fact]}
   577   end;
   578 
   579 
   580 
   581 (** import -- fix schematic type/term variables **)
   582 
   583 fun invent_types Ss ctxt =
   584   let
   585     val tfrees = Name.invent (names_of ctxt) Name.aT (length Ss) ~~ Ss;
   586     val ctxt' = fold (declare_constraints o Logic.mk_type o TFree) tfrees ctxt;
   587   in (tfrees, ctxt') end;
   588 
   589 fun importT_inst ts ctxt =
   590   let
   591     val tvars = rev (fold Term.add_tvars ts []);
   592     val (tfrees, ctxt') = invent_types (map #2 tvars) ctxt;
   593   in (tvars ~~ map TFree tfrees, ctxt') end;
   594 
   595 fun import_inst is_open ts ctxt =
   596   let
   597     val ren = Name.clean #> (if is_open then I else Name.internal);
   598     val (instT, ctxt') = importT_inst ts ctxt;
   599     val vars = map (apsnd (Term_Subst.instantiateT instT)) (rev (fold Term.add_vars ts []));
   600     val (xs, ctxt'') = variant_fixes (map (ren o #1 o #1) vars) ctxt';
   601     val inst = vars ~~ map Free (xs ~~ map #2 vars);
   602   in ((instT, inst), ctxt'') end;
   603 
   604 fun importT_terms ts ctxt =
   605   let val (instT, ctxt') = importT_inst ts ctxt
   606   in (map (Term_Subst.instantiate (instT, [])) ts, ctxt') end;
   607 
   608 fun import_terms is_open ts ctxt =
   609   let val (inst, ctxt') = import_inst is_open ts ctxt
   610   in (map (Term_Subst.instantiate inst) ts, ctxt') end;
   611 
   612 fun importT ths ctxt =
   613   let
   614     val (instT, ctxt') = importT_inst (map Thm.full_prop_of ths) ctxt;
   615     val instT' = map (apsnd (Thm.ctyp_of ctxt')) instT;
   616     val ths' = map (Thm.instantiate (instT', [])) ths;
   617   in ((instT', ths'), ctxt') end;
   618 
   619 fun import_prf is_open prf ctxt =
   620   let
   621     val ts = rev (Proofterm.fold_proof_terms cons (cons o Logic.mk_type) prf []);
   622     val (insts, ctxt') = import_inst is_open ts ctxt;
   623   in (Proofterm.instantiate insts prf, ctxt') end;
   624 
   625 fun import is_open ths ctxt =
   626   let
   627     val ((instT, inst), ctxt') = import_inst is_open (map Thm.full_prop_of ths) ctxt;
   628     val insts' =
   629      (map (apsnd (Thm.ctyp_of ctxt')) instT,
   630       map (apsnd (Thm.cterm_of ctxt')) inst);
   631     val ths' = map (Thm.instantiate insts') ths;
   632   in ((insts', ths'), ctxt') end;
   633 
   634 
   635 (* import/export *)
   636 
   637 fun gen_trade imp exp f ctxt ths =
   638   let val ((_, ths'), ctxt') = imp ths ctxt
   639   in exp ctxt' ctxt (f ctxt' ths') end;
   640 
   641 val tradeT = gen_trade importT exportT;
   642 val trade = gen_trade (import true) export;
   643 
   644 
   645 (* focus on outermost parameters: !!x y z. B *)
   646 
   647 val bound_focus =
   648   Config.bool (Config.declare ("bound_focus", \<^here>) (K (Config.Bool false)));
   649 
   650 fun is_bound_focus ctxt = Config.get ctxt bound_focus;
   651 val set_bound_focus = Config.put bound_focus;
   652 fun restore_bound_focus ctxt = set_bound_focus (is_bound_focus ctxt);
   653 
   654 fun focus_params bindings t ctxt =
   655   let
   656     val ps = Term.variant_frees t (Term.strip_all_vars t);  (*as they are printed :-*)
   657     val (xs, Ts) = split_list ps;
   658     val (xs', ctxt') =
   659       (case bindings of
   660         SOME bs => ctxt |> set_body true |> add_fixes_binding bs ||> restore_body ctxt
   661       | NONE => if is_bound_focus ctxt then bound_fixes ps ctxt else variant_fixes xs ctxt);
   662     val ps' = xs' ~~ Ts;
   663     val ctxt'' = ctxt' |> fold (declare_constraints o Free) ps';
   664   in ((xs, ps'), ctxt'') end;
   665 
   666 fun focus bindings t ctxt =
   667   let
   668     val ((xs, ps), ctxt') = focus_params bindings t ctxt;
   669     val t' = Term.subst_bounds (rev (map Free ps), Term.strip_all_body t);
   670   in (((xs ~~ ps), t'), ctxt') end;
   671 
   672 fun forall_elim_prop t prop =
   673   Thm.beta_conversion false (Thm.apply (Thm.dest_arg prop) t)
   674   |> Thm.cprop_of |> Thm.dest_arg;
   675 
   676 fun focus_cterm bindings goal ctxt =
   677   let
   678     val ((xs, ps), ctxt') = focus_params bindings (Thm.term_of goal) ctxt;
   679     val ps' = map (Thm.cterm_of ctxt' o Free) ps;
   680     val goal' = fold forall_elim_prop ps' goal;
   681   in ((xs ~~ ps', goal'), ctxt') end;
   682 
   683 fun focus_subgoal bindings i st =
   684   let
   685     val all_vars = Thm.fold_terms Term.add_vars st [];
   686   in
   687     fold (unbind_term o #1) all_vars #>
   688     fold (declare_constraints o Var) all_vars #>
   689     focus_cterm bindings (Thm.cprem_of st i)
   690   end;
   691 
   692 
   693 
   694 (** implicit polymorphism **)
   695 
   696 (* warn_extra_tfrees *)
   697 
   698 fun warn_extra_tfrees ctxt1 ctxt2 =
   699   let
   700     fun occs_typ a = Term.exists_subtype (fn TFree (b, _) => a = b | _ => false);
   701     fun occs_free a x =
   702       (case def_type ctxt1 false (x, ~1) of
   703         SOME T => if occs_typ a T then I else cons (a, x)
   704       | NONE => cons (a, x));
   705 
   706     val occs1 = type_occs_of ctxt1;
   707     val occs2 = type_occs_of ctxt2;
   708     val extras = Symtab.fold (fn (a, xs) =>
   709       if Symtab.defined occs1 a then I else fold (occs_free a) xs) occs2 [];
   710     val tfrees = map #1 extras |> sort_distinct string_ord;
   711     val frees = map #2 extras |> sort_distinct string_ord;
   712   in
   713     if null extras orelse not (Context_Position.is_visible ctxt2) then ()
   714     else warning ("Introduced fixed type variable(s): " ^ commas tfrees ^ " in " ^
   715       space_implode " or " (map quote frees))
   716   end;
   717 
   718 
   719 (* polymorphic terms *)
   720 
   721 fun polymorphic_types ctxt ts =
   722   let
   723     val ctxt' = fold declare_term ts ctxt;
   724     val occs = type_occs_of ctxt;
   725     val occs' = type_occs_of ctxt';
   726     val types = Symtab.fold (fn (a, _) => if Symtab.defined occs a then I else cons a) occs' [];
   727     val idx = maxidx_of ctxt' + 1;
   728     val Ts' = (fold o fold_types o fold_atyps)
   729       (fn T as TFree _ =>
   730           (case Term_Subst.generalizeT types idx T of TVar v => insert (op =) v | _ => I)
   731         | _ => I) ts [];
   732     val ts' = map (Term_Subst.generalize (types, []) idx) ts;
   733   in (rev Ts', ts') end;
   734 
   735 fun polymorphic ctxt ts = snd (polymorphic_types ctxt ts);
   736 
   737 end;