src/HOL/Orderings.thy
author haftmann
Fri Jul 20 14:28:25 2007 +0200 (2007-07-20)
changeset 23881 851c74f1bb69
parent 23417 42c1a89b45c1
child 23948 261bd4678076
permissions -rw-r--r--
moved class ord from Orderings.thy to HOL.thy
     1 (*  Title:      HOL/Orderings.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* Syntactic and abstract orders *}
     7 
     8 theory Orderings
     9 imports Set Fun
    10 uses
    11   (*"~~/src/Provers/quasi.ML"*)
    12   "~~/src/Provers/order.ML"
    13 begin
    14 
    15 subsection {* Partial orders *}
    16 
    17 class order = ord +
    18   assumes less_le: "x \<sqsubset> y \<longleftrightarrow> x \<sqsubseteq> y \<and> x \<noteq> y"
    19   and order_refl [iff]: "x \<sqsubseteq> x"
    20   and order_trans: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> z \<Longrightarrow> x \<sqsubseteq> z"
    21   assumes antisym: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> x \<Longrightarrow> x = y"
    22 
    23 begin
    24 
    25 text {* Reflexivity. *}
    26 
    27 lemma eq_refl: "x = y \<Longrightarrow> x \<^loc>\<le> y"
    28     -- {* This form is useful with the classical reasoner. *}
    29 by (erule ssubst) (rule order_refl)
    30 
    31 lemma less_irrefl [iff]: "\<not> x \<^loc>< x"
    32 by (simp add: less_le)
    33 
    34 lemma le_less: "x \<^loc>\<le> y \<longleftrightarrow> x \<^loc>< y \<or> x = y"
    35     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
    36 by (simp add: less_le) blast
    37 
    38 lemma le_imp_less_or_eq: "x \<^loc>\<le> y \<Longrightarrow> x \<^loc>< y \<or> x = y"
    39 unfolding less_le by blast
    40 
    41 lemma less_imp_le: "x \<^loc>< y \<Longrightarrow> x \<^loc>\<le> y"
    42 unfolding less_le by blast
    43 
    44 lemma less_imp_neq: "x \<^loc>< y \<Longrightarrow> x \<noteq> y"
    45 by (erule contrapos_pn, erule subst, rule less_irrefl)
    46 
    47 
    48 text {* Useful for simplification, but too risky to include by default. *}
    49 
    50 lemma less_imp_not_eq: "x \<^loc>< y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
    51 by auto
    52 
    53 lemma less_imp_not_eq2: "x \<^loc>< y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
    54 by auto
    55 
    56 
    57 text {* Transitivity rules for calculational reasoning *}
    58 
    59 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<^loc>\<le> b \<Longrightarrow> a \<^loc>< b"
    60 by (simp add: less_le)
    61 
    62 lemma le_neq_trans: "a \<^loc>\<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a \<^loc>< b"
    63 by (simp add: less_le)
    64 
    65 
    66 text {* Asymmetry. *}
    67 
    68 lemma less_not_sym: "x \<^loc>< y \<Longrightarrow> \<not> (y \<^loc>< x)"
    69 by (simp add: less_le antisym)
    70 
    71 lemma less_asym: "x \<^loc>< y \<Longrightarrow> (\<not> P \<Longrightarrow> y \<^loc>< x) \<Longrightarrow> P"
    72 by (drule less_not_sym, erule contrapos_np) simp
    73 
    74 lemma eq_iff: "x = y \<longleftrightarrow> x \<^loc>\<le> y \<and> y \<^loc>\<le> x"
    75 by (blast intro: antisym)
    76 
    77 lemma antisym_conv: "y \<^loc>\<le> x \<Longrightarrow> x \<^loc>\<le> y \<longleftrightarrow> x = y"
    78 by (blast intro: antisym)
    79 
    80 lemma less_imp_neq: "x \<^loc>< y \<Longrightarrow> x \<noteq> y"
    81 by (erule contrapos_pn, erule subst, rule less_irrefl)
    82 
    83 
    84 text {* Transitivity. *}
    85 
    86 lemma less_trans: "x \<^loc>< y \<Longrightarrow> y \<^loc>< z \<Longrightarrow> x \<^loc>< z"
    87 by (simp add: less_le) (blast intro: order_trans antisym)
    88 
    89 lemma le_less_trans: "x \<^loc>\<le> y \<Longrightarrow> y \<^loc>< z \<Longrightarrow> x \<^loc>< z"
    90 by (simp add: less_le) (blast intro: order_trans antisym)
    91 
    92 lemma less_le_trans: "x \<^loc>< y \<Longrightarrow> y \<^loc>\<le> z \<Longrightarrow> x \<^loc>< z"
    93 by (simp add: less_le) (blast intro: order_trans antisym)
    94 
    95 
    96 text {* Useful for simplification, but too risky to include by default. *}
    97 
    98 lemma less_imp_not_less: "x \<^loc>< y \<Longrightarrow> (\<not> y \<^loc>< x) \<longleftrightarrow> True"
    99 by (blast elim: less_asym)
   100 
   101 lemma less_imp_triv: "x \<^loc>< y \<Longrightarrow> (y \<^loc>< x \<longrightarrow> P) \<longleftrightarrow> True"
   102 by (blast elim: less_asym)
   103 
   104 
   105 text {* Transitivity rules for calculational reasoning *}
   106 
   107 lemma less_asym': "a \<^loc>< b \<Longrightarrow> b \<^loc>< a \<Longrightarrow> P"
   108 by (rule less_asym)
   109 
   110 
   111 text {* Reverse order *}
   112 
   113 lemma order_reverse:
   114   "order (\<lambda>x y. y \<^loc>\<le> x) (\<lambda>x y. y \<^loc>< x)"
   115 by unfold_locales
   116    (simp add: less_le, auto intro: antisym order_trans)
   117 
   118 end
   119 
   120 
   121 subsection {* Linear (total) orders *}
   122 
   123 class linorder = order +
   124   assumes linear: "x \<sqsubseteq> y \<or> y \<sqsubseteq> x"
   125 begin
   126 
   127 lemma less_linear: "x \<^loc>< y \<or> x = y \<or> y \<^loc>< x"
   128 unfolding less_le using less_le linear by blast
   129 
   130 lemma le_less_linear: "x \<^loc>\<le> y \<or> y \<^loc>< x"
   131 by (simp add: le_less less_linear)
   132 
   133 lemma le_cases [case_names le ge]:
   134   "(x \<^loc>\<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<^loc>\<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   135 using linear by blast
   136 
   137 lemma linorder_cases [case_names less equal greater]:
   138   "(x \<^loc>< y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y \<^loc>< x \<Longrightarrow> P) \<Longrightarrow> P"
   139 using less_linear by blast
   140 
   141 lemma not_less: "\<not> x \<^loc>< y \<longleftrightarrow> y \<^loc>\<le> x"
   142 apply (simp add: less_le)
   143 using linear apply (blast intro: antisym)
   144 done
   145 
   146 lemma not_less_iff_gr_or_eq:
   147  "\<not>(x \<^loc>< y) \<longleftrightarrow> (x \<^loc>> y | x = y)"
   148 apply(simp add:not_less le_less)
   149 apply blast
   150 done
   151 
   152 lemma not_le: "\<not> x \<^loc>\<le> y \<longleftrightarrow> y \<^loc>< x"
   153 apply (simp add: less_le)
   154 using linear apply (blast intro: antisym)
   155 done
   156 
   157 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x \<^loc>< y \<or> y \<^loc>< x"
   158 by (cut_tac x = x and y = y in less_linear, auto)
   159 
   160 lemma neqE: "x \<noteq> y \<Longrightarrow> (x \<^loc>< y \<Longrightarrow> R) \<Longrightarrow> (y \<^loc>< x \<Longrightarrow> R) \<Longrightarrow> R"
   161 by (simp add: neq_iff) blast
   162 
   163 lemma antisym_conv1: "\<not> x \<^loc>< y \<Longrightarrow> x \<^loc>\<le> y \<longleftrightarrow> x = y"
   164 by (blast intro: antisym dest: not_less [THEN iffD1])
   165 
   166 lemma antisym_conv2: "x \<^loc>\<le> y \<Longrightarrow> \<not> x \<^loc>< y \<longleftrightarrow> x = y"
   167 by (blast intro: antisym dest: not_less [THEN iffD1])
   168 
   169 lemma antisym_conv3: "\<not> y \<^loc>< x \<Longrightarrow> \<not> x \<^loc>< y \<longleftrightarrow> x = y"
   170 by (blast intro: antisym dest: not_less [THEN iffD1])
   171 
   172 text{*Replacing the old Nat.leI*}
   173 lemma leI: "\<not> x \<^loc>< y \<Longrightarrow> y \<^loc>\<le> x"
   174 unfolding not_less .
   175 
   176 lemma leD: "y \<^loc>\<le> x \<Longrightarrow> \<not> x \<^loc>< y"
   177 unfolding not_less .
   178 
   179 (*FIXME inappropriate name (or delete altogether)*)
   180 lemma not_leE: "\<not> y \<^loc>\<le> x \<Longrightarrow> x \<^loc>< y"
   181 unfolding not_le .
   182 
   183 
   184 text {* Reverse order *}
   185 
   186 lemma linorder_reverse:
   187   "linorder (\<lambda>x y. y \<^loc>\<le> x) (\<lambda>x y. y \<^loc>< x)"
   188 by unfold_locales
   189   (simp add: less_le, auto intro: antisym order_trans simp add: linear)
   190 
   191 
   192 text {* min/max *}
   193 
   194 text {* for historic reasons, definitions are done in context ord *}
   195 
   196 definition (in ord)
   197   min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   198   "min a b = (if a \<^loc>\<le> b then a else b)"
   199 
   200 definition (in ord)
   201   max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   202   "max a b = (if a \<^loc>\<le> b then b else a)"
   203 
   204 lemmas (in -) min_def [code func, code unfold, code inline del] = min_def [folded ord_class.min]
   205 lemmas (in -) max_def [code func, code unfold, code inline del] = max_def [folded ord_class.max]
   206 
   207 lemma min_le_iff_disj:
   208   "min x y \<^loc>\<le> z \<longleftrightarrow> x \<^loc>\<le> z \<or> y \<^loc>\<le> z"
   209 unfolding min_def using linear by (auto intro: order_trans)
   210 
   211 lemma le_max_iff_disj:
   212   "z \<^loc>\<le> max x y \<longleftrightarrow> z \<^loc>\<le> x \<or> z \<^loc>\<le> y"
   213 unfolding max_def using linear by (auto intro: order_trans)
   214 
   215 lemma min_less_iff_disj:
   216   "min x y \<^loc>< z \<longleftrightarrow> x \<^loc>< z \<or> y \<^loc>< z"
   217 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   218 
   219 lemma less_max_iff_disj:
   220   "z \<^loc>< max x y \<longleftrightarrow> z \<^loc>< x \<or> z \<^loc>< y"
   221 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   222 
   223 lemma min_less_iff_conj [simp]:
   224   "z \<^loc>< min x y \<longleftrightarrow> z \<^loc>< x \<and> z \<^loc>< y"
   225 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   226 
   227 lemma max_less_iff_conj [simp]:
   228   "max x y \<^loc>< z \<longleftrightarrow> x \<^loc>< z \<and> y \<^loc>< z"
   229 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   230 
   231 lemma split_min:
   232   "P (min i j) \<longleftrightarrow> (i \<^loc>\<le> j \<longrightarrow> P i) \<and> (\<not> i \<^loc>\<le> j \<longrightarrow> P j)"
   233 by (simp add: min_def)
   234 
   235 lemma split_max:
   236   "P (max i j) \<longleftrightarrow> (i \<^loc>\<le> j \<longrightarrow> P j) \<and> (\<not> i \<^loc>\<le> j \<longrightarrow> P i)"
   237 by (simp add: max_def)
   238 
   239 end
   240 
   241 subsection {* Name duplicates -- including min/max interpretation *}
   242 
   243 lemmas order_less_le = less_le
   244 lemmas order_eq_refl = order_class.eq_refl
   245 lemmas order_less_irrefl = order_class.less_irrefl
   246 lemmas order_le_less = order_class.le_less
   247 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
   248 lemmas order_less_imp_le = order_class.less_imp_le
   249 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
   250 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
   251 lemmas order_neq_le_trans = order_class.neq_le_trans
   252 lemmas order_le_neq_trans = order_class.le_neq_trans
   253 
   254 lemmas order_antisym = antisym
   255 lemmas order_less_not_sym = order_class.less_not_sym
   256 lemmas order_less_asym = order_class.less_asym
   257 lemmas order_eq_iff = order_class.eq_iff
   258 lemmas order_antisym_conv = order_class.antisym_conv
   259 lemmas order_less_trans = order_class.less_trans
   260 lemmas order_le_less_trans = order_class.le_less_trans
   261 lemmas order_less_le_trans = order_class.less_le_trans
   262 lemmas order_less_imp_not_less = order_class.less_imp_not_less
   263 lemmas order_less_imp_triv = order_class.less_imp_triv
   264 lemmas order_less_asym' = order_class.less_asym'
   265 
   266 lemmas linorder_linear = linear
   267 lemmas linorder_less_linear = linorder_class.less_linear
   268 lemmas linorder_le_less_linear = linorder_class.le_less_linear
   269 lemmas linorder_le_cases = linorder_class.le_cases
   270 lemmas linorder_not_less = linorder_class.not_less
   271 lemmas linorder_not_le = linorder_class.not_le
   272 lemmas linorder_neq_iff = linorder_class.neq_iff
   273 lemmas linorder_neqE = linorder_class.neqE
   274 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
   275 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
   276 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
   277 
   278 lemmas min_le_iff_disj = linorder_class.min_le_iff_disj [folded ord_class.min]
   279 lemmas le_max_iff_disj = linorder_class.le_max_iff_disj [folded ord_class.max]
   280 lemmas min_less_iff_disj = linorder_class.min_less_iff_disj [folded ord_class.min]
   281 lemmas less_max_iff_disj = linorder_class.less_max_iff_disj [folded ord_class.max]
   282 lemmas min_less_iff_conj [simp] = linorder_class.min_less_iff_conj [folded ord_class.min]
   283 lemmas max_less_iff_conj [simp] = linorder_class.max_less_iff_conj [folded ord_class.max]
   284 lemmas split_min = linorder_class.split_min [folded ord_class.min]
   285 lemmas split_max = linorder_class.split_max [folded ord_class.max]
   286 
   287 
   288 subsection {* Reasoning tools setup *}
   289 
   290 ML {*
   291 local
   292 
   293 fun decomp_gen sort thy (Trueprop $ t) =
   294   let
   295     fun of_sort t =
   296       let
   297         val T = type_of t
   298       in
   299         (* exclude numeric types: linear arithmetic subsumes transitivity *)
   300         T <> HOLogic.natT andalso T <> HOLogic.intT
   301           andalso T <> HOLogic.realT andalso Sign.of_sort thy (T, sort)
   302       end;
   303     fun dec (Const (@{const_name Not}, _) $ t) = (case dec t
   304           of NONE => NONE
   305            | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   306       | dec (Const (@{const_name "op ="},  _) $ t1 $ t2) =
   307           if of_sort t1
   308           then SOME (t1, "=", t2)
   309           else NONE
   310       | dec (Const (@{const_name HOL.less_eq},  _) $ t1 $ t2) =
   311           if of_sort t1
   312           then SOME (t1, "<=", t2)
   313           else NONE
   314       | dec (Const (@{const_name HOL.less},  _) $ t1 $ t2) =
   315           if of_sort t1
   316           then SOME (t1, "<", t2)
   317           else NONE
   318       | dec _ = NONE;
   319   in dec t end;
   320 
   321 in
   322 
   323 (* sorry - there is no preorder class
   324 structure Quasi_Tac = Quasi_Tac_Fun (
   325 struct
   326   val le_trans = thm "order_trans";
   327   val le_refl = thm "order_refl";
   328   val eqD1 = thm "order_eq_refl";
   329   val eqD2 = thm "sym" RS thm "order_eq_refl";
   330   val less_reflE = thm "order_less_irrefl" RS thm "notE";
   331   val less_imp_le = thm "order_less_imp_le";
   332   val le_neq_trans = thm "order_le_neq_trans";
   333   val neq_le_trans = thm "order_neq_le_trans";
   334   val less_imp_neq = thm "less_imp_neq";
   335   val decomp_trans = decomp_gen ["Orderings.preorder"];
   336   val decomp_quasi = decomp_gen ["Orderings.preorder"];
   337 end);*)
   338 
   339 structure Order_Tac = Order_Tac_Fun (
   340 struct
   341   val less_reflE = thm "order_less_irrefl" RS thm "notE";
   342   val le_refl = thm "order_refl";
   343   val less_imp_le = thm "order_less_imp_le";
   344   val not_lessI = thm "linorder_not_less" RS thm "iffD2";
   345   val not_leI = thm "linorder_not_le" RS thm "iffD2";
   346   val not_lessD = thm "linorder_not_less" RS thm "iffD1";
   347   val not_leD = thm "linorder_not_le" RS thm "iffD1";
   348   val eqI = thm "order_antisym";
   349   val eqD1 = thm "order_eq_refl";
   350   val eqD2 = thm "sym" RS thm "order_eq_refl";
   351   val less_trans = thm "order_less_trans";
   352   val less_le_trans = thm "order_less_le_trans";
   353   val le_less_trans = thm "order_le_less_trans";
   354   val le_trans = thm "order_trans";
   355   val le_neq_trans = thm "order_le_neq_trans";
   356   val neq_le_trans = thm "order_neq_le_trans";
   357   val less_imp_neq = thm "less_imp_neq";
   358   val eq_neq_eq_imp_neq = thm "eq_neq_eq_imp_neq";
   359   val not_sym = thm "not_sym";
   360   val decomp_part = decomp_gen ["Orderings.order"];
   361   val decomp_lin = decomp_gen ["Orderings.linorder"];
   362 end);
   363 
   364 end;
   365 *}
   366 
   367 setup {*
   368 let
   369 
   370 fun prp t thm = (#prop (rep_thm thm) = t);
   371 
   372 fun prove_antisym_le sg ss ((le as Const(_,T)) $ r $ s) =
   373   let val prems = prems_of_ss ss;
   374       val less = Const (@{const_name less}, T);
   375       val t = HOLogic.mk_Trueprop(le $ s $ r);
   376   in case find_first (prp t) prems of
   377        NONE =>
   378          let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s))
   379          in case find_first (prp t) prems of
   380               NONE => NONE
   381             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_antisym_conv1}))
   382          end
   383      | SOME thm => SOME(mk_meta_eq(thm RS @{thm order_antisym_conv}))
   384   end
   385   handle THM _ => NONE;
   386 
   387 fun prove_antisym_less sg ss (NotC $ ((less as Const(_,T)) $ r $ s)) =
   388   let val prems = prems_of_ss ss;
   389       val le = Const (@{const_name less_eq}, T);
   390       val t = HOLogic.mk_Trueprop(le $ r $ s);
   391   in case find_first (prp t) prems of
   392        NONE =>
   393          let val t = HOLogic.mk_Trueprop(NotC $ (less $ s $ r))
   394          in case find_first (prp t) prems of
   395               NONE => NONE
   396             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_antisym_conv3}))
   397          end
   398      | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_antisym_conv2}))
   399   end
   400   handle THM _ => NONE;
   401 
   402 fun add_simprocs procs thy =
   403   (Simplifier.change_simpset_of thy (fn ss => ss
   404     addsimprocs (map (fn (name, raw_ts, proc) =>
   405       Simplifier.simproc thy name raw_ts proc)) procs); thy);
   406 fun add_solver name tac thy =
   407   (Simplifier.change_simpset_of thy (fn ss => ss addSolver
   408     (mk_solver name (K tac))); thy);
   409 
   410 in
   411   add_simprocs [
   412        ("antisym le", ["(x::'a::order) <= y"], prove_antisym_le),
   413        ("antisym less", ["~ (x::'a::linorder) < y"], prove_antisym_less)
   414      ]
   415   #> add_solver "Trans_linear" Order_Tac.linear_tac
   416   #> add_solver "Trans_partial" Order_Tac.partial_tac
   417   (* Adding the transitivity reasoners also as safe solvers showed a slight
   418      speed up, but the reasoning strength appears to be not higher (at least
   419      no breaking of additional proofs in the entire HOL distribution, as
   420      of 5 March 2004, was observed). *)
   421 end
   422 *}
   423 
   424 
   425 subsection {* Bounded quantifiers *}
   426 
   427 syntax
   428   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   429   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   430   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   431   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   432 
   433   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   434   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   435   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   436   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   437 
   438 syntax (xsymbols)
   439   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   440   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   441   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   442   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   443 
   444   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   445   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   446   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   447   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   448 
   449 syntax (HOL)
   450   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   451   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   452   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   453   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   454 
   455 syntax (HTML output)
   456   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   457   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   458   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   459   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   460 
   461   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   462   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   463   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   464   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   465 
   466 translations
   467   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   468   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   469   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   470   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   471   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   472   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   473   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   474   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   475 
   476 print_translation {*
   477 let
   478   val All_binder = Syntax.binder_name @{const_syntax All};
   479   val Ex_binder = Syntax.binder_name @{const_syntax Ex};
   480   val impl = @{const_syntax "op -->"};
   481   val conj = @{const_syntax "op &"};
   482   val less = @{const_syntax less};
   483   val less_eq = @{const_syntax less_eq};
   484 
   485   val trans =
   486    [((All_binder, impl, less), ("_All_less", "_All_greater")),
   487     ((All_binder, impl, less_eq), ("_All_less_eq", "_All_greater_eq")),
   488     ((Ex_binder, conj, less), ("_Ex_less", "_Ex_greater")),
   489     ((Ex_binder, conj, less_eq), ("_Ex_less_eq", "_Ex_greater_eq"))];
   490 
   491   fun matches_bound v t = 
   492      case t of (Const ("_bound", _) $ Free (v', _)) => (v = v')
   493               | _ => false
   494   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false)
   495   fun mk v c n P = Syntax.const c $ Syntax.mark_bound v $ n $ P
   496 
   497   fun tr' q = (q,
   498     fn [Const ("_bound", _) $ Free (v, _), Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   499       (case AList.lookup (op =) trans (q, c, d) of
   500         NONE => raise Match
   501       | SOME (l, g) =>
   502           if matches_bound v t andalso not (contains_var v u) then mk v l u P
   503           else if matches_bound v u andalso not (contains_var v t) then mk v g t P
   504           else raise Match)
   505      | _ => raise Match);
   506 in [tr' All_binder, tr' Ex_binder] end
   507 *}
   508 
   509 
   510 subsection {* Transitivity reasoning *}
   511 
   512 lemma ord_le_eq_trans: "a <= b ==> b = c ==> a <= c"
   513 by (rule subst)
   514 
   515 lemma ord_eq_le_trans: "a = b ==> b <= c ==> a <= c"
   516 by (rule ssubst)
   517 
   518 lemma ord_less_eq_trans: "a < b ==> b = c ==> a < c"
   519 by (rule subst)
   520 
   521 lemma ord_eq_less_trans: "a = b ==> b < c ==> a < c"
   522 by (rule ssubst)
   523 
   524 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   525   (!!x y. x < y ==> f x < f y) ==> f a < c"
   526 proof -
   527   assume r: "!!x y. x < y ==> f x < f y"
   528   assume "a < b" hence "f a < f b" by (rule r)
   529   also assume "f b < c"
   530   finally (order_less_trans) show ?thesis .
   531 qed
   532 
   533 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   534   (!!x y. x < y ==> f x < f y) ==> a < f c"
   535 proof -
   536   assume r: "!!x y. x < y ==> f x < f y"
   537   assume "a < f b"
   538   also assume "b < c" hence "f b < f c" by (rule r)
   539   finally (order_less_trans) show ?thesis .
   540 qed
   541 
   542 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   543   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   544 proof -
   545   assume r: "!!x y. x <= y ==> f x <= f y"
   546   assume "a <= b" hence "f a <= f b" by (rule r)
   547   also assume "f b < c"
   548   finally (order_le_less_trans) show ?thesis .
   549 qed
   550 
   551 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   552   (!!x y. x < y ==> f x < f y) ==> a < f c"
   553 proof -
   554   assume r: "!!x y. x < y ==> f x < f y"
   555   assume "a <= f b"
   556   also assume "b < c" hence "f b < f c" by (rule r)
   557   finally (order_le_less_trans) show ?thesis .
   558 qed
   559 
   560 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   561   (!!x y. x < y ==> f x < f y) ==> f a < c"
   562 proof -
   563   assume r: "!!x y. x < y ==> f x < f y"
   564   assume "a < b" hence "f a < f b" by (rule r)
   565   also assume "f b <= c"
   566   finally (order_less_le_trans) show ?thesis .
   567 qed
   568 
   569 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   570   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   571 proof -
   572   assume r: "!!x y. x <= y ==> f x <= f y"
   573   assume "a < f b"
   574   also assume "b <= c" hence "f b <= f c" by (rule r)
   575   finally (order_less_le_trans) show ?thesis .
   576 qed
   577 
   578 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   579   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   580 proof -
   581   assume r: "!!x y. x <= y ==> f x <= f y"
   582   assume "a <= f b"
   583   also assume "b <= c" hence "f b <= f c" by (rule r)
   584   finally (order_trans) show ?thesis .
   585 qed
   586 
   587 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   588   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   589 proof -
   590   assume r: "!!x y. x <= y ==> f x <= f y"
   591   assume "a <= b" hence "f a <= f b" by (rule r)
   592   also assume "f b <= c"
   593   finally (order_trans) show ?thesis .
   594 qed
   595 
   596 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   597   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   598 proof -
   599   assume r: "!!x y. x <= y ==> f x <= f y"
   600   assume "a <= b" hence "f a <= f b" by (rule r)
   601   also assume "f b = c"
   602   finally (ord_le_eq_trans) show ?thesis .
   603 qed
   604 
   605 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   606   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   607 proof -
   608   assume r: "!!x y. x <= y ==> f x <= f y"
   609   assume "a = f b"
   610   also assume "b <= c" hence "f b <= f c" by (rule r)
   611   finally (ord_eq_le_trans) show ?thesis .
   612 qed
   613 
   614 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   615   (!!x y. x < y ==> f x < f y) ==> f a < c"
   616 proof -
   617   assume r: "!!x y. x < y ==> f x < f y"
   618   assume "a < b" hence "f a < f b" by (rule r)
   619   also assume "f b = c"
   620   finally (ord_less_eq_trans) show ?thesis .
   621 qed
   622 
   623 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   624   (!!x y. x < y ==> f x < f y) ==> a < f c"
   625 proof -
   626   assume r: "!!x y. x < y ==> f x < f y"
   627   assume "a = f b"
   628   also assume "b < c" hence "f b < f c" by (rule r)
   629   finally (ord_eq_less_trans) show ?thesis .
   630 qed
   631 
   632 text {*
   633   Note that this list of rules is in reverse order of priorities.
   634 *}
   635 
   636 lemmas order_trans_rules [trans] =
   637   order_less_subst2
   638   order_less_subst1
   639   order_le_less_subst2
   640   order_le_less_subst1
   641   order_less_le_subst2
   642   order_less_le_subst1
   643   order_subst2
   644   order_subst1
   645   ord_le_eq_subst
   646   ord_eq_le_subst
   647   ord_less_eq_subst
   648   ord_eq_less_subst
   649   forw_subst
   650   back_subst
   651   rev_mp
   652   mp
   653   order_neq_le_trans
   654   order_le_neq_trans
   655   order_less_trans
   656   order_less_asym'
   657   order_le_less_trans
   658   order_less_le_trans
   659   order_trans
   660   order_antisym
   661   ord_le_eq_trans
   662   ord_eq_le_trans
   663   ord_less_eq_trans
   664   ord_eq_less_trans
   665   trans
   666 
   667 
   668 (* FIXME cleanup *)
   669 
   670 text {* These support proving chains of decreasing inequalities
   671     a >= b >= c ... in Isar proofs. *}
   672 
   673 lemma xt1:
   674   "a = b ==> b > c ==> a > c"
   675   "a > b ==> b = c ==> a > c"
   676   "a = b ==> b >= c ==> a >= c"
   677   "a >= b ==> b = c ==> a >= c"
   678   "(x::'a::order) >= y ==> y >= x ==> x = y"
   679   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   680   "(x::'a::order) > y ==> y >= z ==> x > z"
   681   "(x::'a::order) >= y ==> y > z ==> x > z"
   682   "(a::'a::order) > b ==> b > a ==> P"
   683   "(x::'a::order) > y ==> y > z ==> x > z"
   684   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   685   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   686   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c" 
   687   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   688   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   689   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   690 by auto
   691 
   692 lemma xt2:
   693   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   694 by (subgoal_tac "f b >= f c", force, force)
   695 
   696 lemma xt3: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==> 
   697     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   698 by (subgoal_tac "f a >= f b", force, force)
   699 
   700 lemma xt4: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   701   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   702 by (subgoal_tac "f b >= f c", force, force)
   703 
   704 lemma xt5: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   705     (!!x y. x > y ==> f x > f y) ==> f a > c"
   706 by (subgoal_tac "f a > f b", force, force)
   707 
   708 lemma xt6: "(a::'a::order) >= f b ==> b > c ==>
   709     (!!x y. x > y ==> f x > f y) ==> a > f c"
   710 by (subgoal_tac "f b > f c", force, force)
   711 
   712 lemma xt7: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   713     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   714 by (subgoal_tac "f a >= f b", force, force)
   715 
   716 lemma xt8: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   717     (!!x y. x > y ==> f x > f y) ==> a > f c"
   718 by (subgoal_tac "f b > f c", force, force)
   719 
   720 lemma xt9: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   721     (!!x y. x > y ==> f x > f y) ==> f a > c"
   722 by (subgoal_tac "f a > f b", force, force)
   723 
   724 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9
   725 
   726 (* 
   727   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
   728   for the wrong thing in an Isar proof.
   729 
   730   The extra transitivity rules can be used as follows: 
   731 
   732 lemma "(a::'a::order) > z"
   733 proof -
   734   have "a >= b" (is "_ >= ?rhs")
   735     sorry
   736   also have "?rhs >= c" (is "_ >= ?rhs")
   737     sorry
   738   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
   739     sorry
   740   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
   741     sorry
   742   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
   743     sorry
   744   also (xtrans) have "?rhs > z"
   745     sorry
   746   finally (xtrans) show ?thesis .
   747 qed
   748 
   749   Alternatively, one can use "declare xtrans [trans]" and then
   750   leave out the "(xtrans)" above.
   751 *)
   752 
   753 subsection {* Order on bool *}
   754 
   755 instance bool :: order 
   756   le_bool_def: "P \<le> Q \<equiv> P \<longrightarrow> Q"
   757   less_bool_def: "P < Q \<equiv> P \<le> Q \<and> P \<noteq> Q"
   758   by intro_classes (auto simp add: le_bool_def less_bool_def)
   759 
   760 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
   761 by (simp add: le_bool_def)
   762 
   763 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
   764 by (simp add: le_bool_def)
   765 
   766 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
   767 by (simp add: le_bool_def)
   768 
   769 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
   770 by (simp add: le_bool_def)
   771 
   772 lemma [code func]:
   773   "False \<le> b \<longleftrightarrow> True"
   774   "True \<le> b \<longleftrightarrow> b"
   775   "False < b \<longleftrightarrow> b"
   776   "True < b \<longleftrightarrow> False"
   777   unfolding le_bool_def less_bool_def by simp_all
   778 
   779 
   780 subsection {* Order on sets *}
   781 
   782 instance set :: (type) order
   783   by (intro_classes,
   784       (assumption | rule subset_refl subset_trans subset_antisym psubset_eq)+)
   785 
   786 lemmas basic_trans_rules [trans] =
   787   order_trans_rules set_rev_mp set_mp
   788 
   789 
   790 subsection {* Order on functions *}
   791 
   792 instance "fun" :: (type, ord) ord
   793   le_fun_def: "f \<le> g \<equiv> \<forall>x. f x \<le> g x"
   794   less_fun_def: "f < g \<equiv> f \<le> g \<and> f \<noteq> g" ..
   795 
   796 lemmas [code func del] = le_fun_def less_fun_def
   797 
   798 instance "fun" :: (type, order) order
   799   by default
   800     (auto simp add: le_fun_def less_fun_def expand_fun_eq
   801        intro: order_trans order_antisym)
   802 
   803 lemma le_funI: "(\<And>x. f x \<le> g x) \<Longrightarrow> f \<le> g"
   804   unfolding le_fun_def by simp
   805 
   806 lemma le_funE: "f \<le> g \<Longrightarrow> (f x \<le> g x \<Longrightarrow> P) \<Longrightarrow> P"
   807   unfolding le_fun_def by simp
   808 
   809 lemma le_funD: "f \<le> g \<Longrightarrow> f x \<le> g x"
   810   unfolding le_fun_def by simp
   811 
   812 text {*
   813   Handy introduction and elimination rules for @{text "\<le>"}
   814   on unary and binary predicates
   815 *}
   816 
   817 lemma predicate1I [Pure.intro!, intro!]:
   818   assumes PQ: "\<And>x. P x \<Longrightarrow> Q x"
   819   shows "P \<le> Q"
   820   apply (rule le_funI)
   821   apply (rule le_boolI)
   822   apply (rule PQ)
   823   apply assumption
   824   done
   825 
   826 lemma predicate1D [Pure.dest, dest]: "P \<le> Q \<Longrightarrow> P x \<Longrightarrow> Q x"
   827   apply (erule le_funE)
   828   apply (erule le_boolE)
   829   apply assumption+
   830   done
   831 
   832 lemma predicate2I [Pure.intro!, intro!]:
   833   assumes PQ: "\<And>x y. P x y \<Longrightarrow> Q x y"
   834   shows "P \<le> Q"
   835   apply (rule le_funI)+
   836   apply (rule le_boolI)
   837   apply (rule PQ)
   838   apply assumption
   839   done
   840 
   841 lemma predicate2D [Pure.dest, dest]: "P \<le> Q \<Longrightarrow> P x y \<Longrightarrow> Q x y"
   842   apply (erule le_funE)+
   843   apply (erule le_boolE)
   844   apply assumption+
   845   done
   846 
   847 lemma rev_predicate1D: "P x ==> P <= Q ==> Q x"
   848   by (rule predicate1D)
   849 
   850 lemma rev_predicate2D: "P x y ==> P <= Q ==> Q x y"
   851   by (rule predicate2D)
   852 
   853 
   854 subsection {* Monotonicity, least value operator and min/max *}
   855 
   856 locale mono =
   857   fixes f
   858   assumes mono: "A \<le> B \<Longrightarrow> f A \<le> f B"
   859 
   860 lemmas monoI [intro?] = mono.intro
   861   and monoD [dest?] = mono.mono
   862 
   863 lemma LeastI2_order:
   864   "[| P (x::'a::order);
   865       !!y. P y ==> x <= y;
   866       !!x. [| P x; ALL y. P y --> x \<le> y |] ==> Q x |]
   867    ==> Q (Least P)"
   868 apply (unfold Least_def)
   869 apply (rule theI2)
   870   apply (blast intro: order_antisym)+
   871 done
   872 
   873 lemma Least_mono:
   874   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
   875     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
   876     -- {* Courtesy of Stephan Merz *}
   877   apply clarify
   878   apply (erule_tac P = "%x. x : S" in LeastI2_order, fast)
   879   apply (rule LeastI2_order)
   880   apply (auto elim: monoD intro!: order_antisym)
   881   done
   882 
   883 lemma Least_equality:
   884   "[| P (k::'a::order); !!x. P x ==> k <= x |] ==> (LEAST x. P x) = k"
   885 apply (simp add: Least_def)
   886 apply (rule the_equality)
   887 apply (auto intro!: order_antisym)
   888 done
   889 
   890 lemma min_leastL: "(!!x. least <= x) ==> min least x = least"
   891 by (simp add: min_def)
   892 
   893 lemma max_leastL: "(!!x. least <= x) ==> max least x = x"
   894 by (simp add: max_def)
   895 
   896 lemma min_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> min x least = least"
   897 apply (simp add: min_def)
   898 apply (blast intro: order_antisym)
   899 done
   900 
   901 lemma max_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> max x least = x"
   902 apply (simp add: max_def)
   903 apply (blast intro: order_antisym)
   904 done
   905 
   906 lemma min_of_mono:
   907   "(!!x y. (f x <= f y) = (x <= y)) ==> min (f m) (f n) = f (min m n)"
   908 by (simp add: min_def)
   909 
   910 lemma max_of_mono:
   911   "(!!x y. (f x <= f y) = (x <= y)) ==> max (f m) (f n) = f (max m n)"
   912 by (simp add: max_def)
   913 
   914 
   915 subsection {* legacy ML bindings *}
   916 
   917 ML {*
   918 val monoI = @{thm monoI};
   919 *}
   920 
   921 end