src/HOL/Set.ML
author paulson
Tue Sep 15 15:04:07 1998 +0200 (1998-09-15)
changeset 5490 85855f65d0c6
parent 5450 fe9d103464a4
child 5521 7970832271cc
permissions -rw-r--r--
From Compl(A) to -A
     1 (*  Title:      HOL/set
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 Set theory for higher-order logic.  A set is simply a predicate.
     7 *)
     8 
     9 open Set;
    10 
    11 section "Relating predicates and sets";
    12 
    13 Addsimps [Collect_mem_eq];
    14 AddIffs  [mem_Collect_eq];
    15 
    16 Goal "P(a) ==> a : {x. P(x)}";
    17 by (Asm_simp_tac 1);
    18 qed "CollectI";
    19 
    20 Goal "a : {x. P(x)} ==> P(a)";
    21 by (Asm_full_simp_tac 1);
    22 qed "CollectD";
    23 
    24 val [prem] = Goal "[| !!x. (x:A) = (x:B) |] ==> A = B";
    25 by (rtac (prem RS ext RS arg_cong RS box_equals) 1);
    26 by (rtac Collect_mem_eq 1);
    27 by (rtac Collect_mem_eq 1);
    28 qed "set_ext";
    29 
    30 val [prem] = Goal "[| !!x. P(x)=Q(x) |] ==> {x. P(x)} = {x. Q(x)}";
    31 by (rtac (prem RS ext RS arg_cong) 1);
    32 qed "Collect_cong";
    33 
    34 val CollectE = make_elim CollectD;
    35 
    36 AddSIs [CollectI];
    37 AddSEs [CollectE];
    38 
    39 
    40 section "Bounded quantifiers";
    41 
    42 val prems = Goalw [Ball_def]
    43     "[| !!x. x:A ==> P(x) |] ==> ! x:A. P(x)";
    44 by (REPEAT (ares_tac (prems @ [allI,impI]) 1));
    45 qed "ballI";
    46 
    47 Goalw [Ball_def] "[| ! x:A. P(x);  x:A |] ==> P(x)";
    48 by (Blast_tac 1);
    49 qed "bspec";
    50 
    51 val major::prems = Goalw [Ball_def]
    52     "[| ! x:A. P(x);  P(x) ==> Q;  x~:A ==> Q |] ==> Q";
    53 by (rtac (major RS spec RS impCE) 1);
    54 by (REPEAT (eresolve_tac prems 1));
    55 qed "ballE";
    56 
    57 (*Takes assumptions ! x:A.P(x) and a:A; creates assumption P(a)*)
    58 fun ball_tac i = etac ballE i THEN contr_tac (i+1);
    59 
    60 AddSIs [ballI];
    61 AddEs  [ballE];
    62 
    63 Goalw [Bex_def] "[| P(x);  x:A |] ==> ? x:A. P(x)";
    64 by (Blast_tac 1);
    65 qed "bexI";
    66 
    67 qed_goal "bexCI" Set.thy 
    68    "[| ! x:A. ~P(x) ==> P(a);  a:A |] ==> ? x:A. P(x)"
    69  (fn prems=>
    70   [ (rtac classical 1),
    71     (REPEAT (ares_tac (prems@[bexI,ballI,notI,notE]) 1))  ]);
    72 
    73 val major::prems = Goalw [Bex_def]
    74     "[| ? x:A. P(x);  !!x. [| x:A; P(x) |] ==> Q  |] ==> Q";
    75 by (rtac (major RS exE) 1);
    76 by (REPEAT (eresolve_tac (prems @ [asm_rl,conjE]) 1));
    77 qed "bexE";
    78 
    79 AddIs  [bexI];
    80 AddSEs [bexE];
    81 
    82 (*Trival rewrite rule*)
    83 Goal "(! x:A. P) = ((? x. x:A) --> P)";
    84 by (simp_tac (simpset() addsimps [Ball_def]) 1);
    85 qed "ball_triv";
    86 
    87 (*Dual form for existentials*)
    88 Goal "(? x:A. P) = ((? x. x:A) & P)";
    89 by (simp_tac (simpset() addsimps [Bex_def]) 1);
    90 qed "bex_triv";
    91 
    92 Addsimps [ball_triv, bex_triv];
    93 
    94 (** Congruence rules **)
    95 
    96 val prems = Goal
    97     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
    98 \    (! x:A. P(x)) = (! x:B. Q(x))";
    99 by (resolve_tac (prems RL [ssubst]) 1);
   100 by (REPEAT (ares_tac [ballI,iffI] 1
   101      ORELSE eresolve_tac ([make_elim bspec, mp] @ (prems RL [iffE])) 1));
   102 qed "ball_cong";
   103 
   104 val prems = Goal
   105     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   106 \    (? x:A. P(x)) = (? x:B. Q(x))";
   107 by (resolve_tac (prems RL [ssubst]) 1);
   108 by (REPEAT (etac bexE 1
   109      ORELSE ares_tac ([bexI,iffI] @ (prems RL [iffD1,iffD2])) 1));
   110 qed "bex_cong";
   111 
   112 section "Subsets";
   113 
   114 val prems = Goalw [subset_def] "(!!x. x:A ==> x:B) ==> A <= B";
   115 by (REPEAT (ares_tac (prems @ [ballI]) 1));
   116 qed "subsetI";
   117 
   118 (*While (:) is not, its type must be kept
   119   for overloading of = to work.*)
   120 Blast.overloaded ("op :", domain_type);
   121 seq (fn a => Blast.overloaded (a, HOLogic.dest_setT o domain_type))
   122     ["Ball", "Bex"];
   123 (*need UNION, INTER also?*)
   124 
   125 (*Image: retain the type of the set being expressed*)
   126 Blast.overloaded ("op ``", domain_type);
   127 
   128 (*Rule in Modus Ponens style*)
   129 Goalw [subset_def] "[| A <= B;  c:A |] ==> c:B";
   130 by (Blast_tac 1);
   131 qed "subsetD";
   132 
   133 (*The same, with reversed premises for use with etac -- cf rev_mp*)
   134 qed_goal "rev_subsetD" Set.thy "[| c:A;  A <= B |] ==> c:B"
   135  (fn prems=>  [ (REPEAT (resolve_tac (prems@[subsetD]) 1)) ]);
   136 
   137 (*Converts A<=B to x:A ==> x:B*)
   138 fun impOfSubs th = th RSN (2, rev_subsetD);
   139 
   140 qed_goal "contra_subsetD" Set.thy "!!c. [| A <= B; c ~: B |] ==> c ~: A"
   141  (fn prems=>  [ (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ]);
   142 
   143 qed_goal "rev_contra_subsetD" Set.thy "!!c. [| c ~: B;  A <= B |] ==> c ~: A"
   144  (fn prems=>  [ (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ]);
   145 
   146 (*Classical elimination rule*)
   147 val major::prems = Goalw [subset_def] 
   148     "[| A <= B;  c~:A ==> P;  c:B ==> P |] ==> P";
   149 by (rtac (major RS ballE) 1);
   150 by (REPEAT (eresolve_tac prems 1));
   151 qed "subsetCE";
   152 
   153 (*Takes assumptions A<=B; c:A and creates the assumption c:B *)
   154 fun set_mp_tac i = etac subsetCE i  THEN  mp_tac i;
   155 
   156 AddSIs [subsetI];
   157 AddEs  [subsetD, subsetCE];
   158 
   159 qed_goal "subset_refl" Set.thy "A <= (A::'a set)"
   160  (fn _=> [Fast_tac 1]);		(*Blast_tac would try order_refl and fail*)
   161 
   162 Goal "[| A<=B;  B<=C |] ==> A<=(C::'a set)";
   163 by (Blast_tac 1);
   164 qed "subset_trans";
   165 
   166 
   167 section "Equality";
   168 
   169 (*Anti-symmetry of the subset relation*)
   170 Goal "[| A <= B;  B <= A |] ==> A = (B::'a set)";
   171 by (rtac set_ext 1);
   172 by (blast_tac (claset() addIs [subsetD]) 1);
   173 qed "subset_antisym";
   174 val equalityI = subset_antisym;
   175 
   176 AddSIs [equalityI];
   177 
   178 (* Equality rules from ZF set theory -- are they appropriate here? *)
   179 Goal "A = B ==> A<=(B::'a set)";
   180 by (etac ssubst 1);
   181 by (rtac subset_refl 1);
   182 qed "equalityD1";
   183 
   184 Goal "A = B ==> B<=(A::'a set)";
   185 by (etac ssubst 1);
   186 by (rtac subset_refl 1);
   187 qed "equalityD2";
   188 
   189 val prems = Goal
   190     "[| A = B;  [| A<=B; B<=(A::'a set) |] ==> P |]  ==>  P";
   191 by (resolve_tac prems 1);
   192 by (REPEAT (resolve_tac (prems RL [equalityD1,equalityD2]) 1));
   193 qed "equalityE";
   194 
   195 val major::prems = Goal
   196     "[| A = B;  [| c:A; c:B |] ==> P;  [| c~:A; c~:B |] ==> P |]  ==>  P";
   197 by (rtac (major RS equalityE) 1);
   198 by (REPEAT (contr_tac 1 ORELSE eresolve_tac ([asm_rl,subsetCE]@prems) 1));
   199 qed "equalityCE";
   200 
   201 (*Lemma for creating induction formulae -- for "pattern matching" on p
   202   To make the induction hypotheses usable, apply "spec" or "bspec" to
   203   put universal quantifiers over the free variables in p. *)
   204 val prems = Goal 
   205     "[| p:A;  !!z. z:A ==> p=z --> R |] ==> R";
   206 by (rtac mp 1);
   207 by (REPEAT (resolve_tac (refl::prems) 1));
   208 qed "setup_induction";
   209 
   210 
   211 section "The universal set -- UNIV";
   212 
   213 qed_goalw "UNIV_I" Set.thy [UNIV_def] "x : UNIV"
   214   (fn _ => [rtac CollectI 1, rtac TrueI 1]);
   215 
   216 Addsimps [UNIV_I];
   217 AddIs    [UNIV_I];  (*unsafe makes it less likely to cause problems*)
   218 
   219 qed_goal "subset_UNIV" Set.thy "A <= UNIV"
   220   (fn _ => [rtac subsetI 1, rtac UNIV_I 1]);
   221 
   222 (** Eta-contracting these two rules (to remove P) causes them to be ignored
   223     because of their interaction with congruence rules. **)
   224 
   225 Goalw [Ball_def] "Ball UNIV P = All P";
   226 by (Simp_tac 1);
   227 qed "ball_UNIV";
   228 
   229 Goalw [Bex_def] "Bex UNIV P = Ex P";
   230 by (Simp_tac 1);
   231 qed "bex_UNIV";
   232 Addsimps [ball_UNIV, bex_UNIV];
   233 
   234 
   235 section "The empty set -- {}";
   236 
   237 qed_goalw "empty_iff" Set.thy [empty_def] "(c : {}) = False"
   238  (fn _ => [ (Blast_tac 1) ]);
   239 
   240 Addsimps [empty_iff];
   241 
   242 qed_goal "emptyE" Set.thy "!!a. a:{} ==> P"
   243  (fn _ => [Full_simp_tac 1]);
   244 
   245 AddSEs [emptyE];
   246 
   247 qed_goal "empty_subsetI" Set.thy "{} <= A"
   248  (fn _ => [ (Blast_tac 1) ]);
   249 
   250 (*One effect is to delete the ASSUMPTION {} <= A*)
   251 AddIffs [empty_subsetI];
   252 
   253 qed_goal "equals0I" Set.thy "[| !!y. y:A ==> False |] ==> A={}"
   254  (fn [prem]=>
   255   [ (blast_tac (claset() addIs [prem RS FalseE]) 1) ]);
   256 
   257 (*Use for reasoning about disjointness: A Int B = {} *)
   258 qed_goal "equals0D" Set.thy "!!a. A={} ==> a ~: A"
   259  (fn _ => [ (Blast_tac 1) ]);
   260 
   261 AddDs [equals0D, sym RS equals0D];
   262 
   263 Goalw [Ball_def] "Ball {} P = True";
   264 by (Simp_tac 1);
   265 qed "ball_empty";
   266 
   267 Goalw [Bex_def] "Bex {} P = False";
   268 by (Simp_tac 1);
   269 qed "bex_empty";
   270 Addsimps [ball_empty, bex_empty];
   271 
   272 Goal "UNIV ~= {}";
   273 by (blast_tac (claset() addEs [equalityE]) 1);
   274 qed "UNIV_not_empty";
   275 AddIffs [UNIV_not_empty];
   276 
   277 
   278 
   279 section "The Powerset operator -- Pow";
   280 
   281 qed_goalw "Pow_iff" Set.thy [Pow_def] "(A : Pow(B)) = (A <= B)"
   282  (fn _ => [ (Asm_simp_tac 1) ]);
   283 
   284 AddIffs [Pow_iff]; 
   285 
   286 qed_goalw "PowI" Set.thy [Pow_def] "!!A B. A <= B ==> A : Pow(B)"
   287  (fn _ => [ (etac CollectI 1) ]);
   288 
   289 qed_goalw "PowD" Set.thy [Pow_def] "!!A B. A : Pow(B)  ==>  A<=B"
   290  (fn _=> [ (etac CollectD 1) ]);
   291 
   292 val Pow_bottom = empty_subsetI RS PowI;        (* {}: Pow(B) *)
   293 val Pow_top = subset_refl RS PowI;             (* A : Pow(A) *)
   294 
   295 
   296 section "Set complement -- Compl";
   297 
   298 qed_goalw "Compl_iff" Set.thy [Compl_def] "(c : -A) = (c~:A)"
   299  (fn _ => [ (Blast_tac 1) ]);
   300 
   301 Addsimps [Compl_iff];
   302 
   303 val prems = Goalw [Compl_def] "[| c:A ==> False |] ==> c : -A";
   304 by (REPEAT (ares_tac (prems @ [CollectI,notI]) 1));
   305 qed "ComplI";
   306 
   307 (*This form, with negated conclusion, works well with the Classical prover.
   308   Negated assumptions behave like formulae on the right side of the notional
   309   turnstile...*)
   310 Goalw [Compl_def] "c : -A ==> c~:A";
   311 by (etac CollectD 1);
   312 qed "ComplD";
   313 
   314 val ComplE = make_elim ComplD;
   315 
   316 AddSIs [ComplI];
   317 AddSEs [ComplE];
   318 
   319 
   320 section "Binary union -- Un";
   321 
   322 qed_goalw "Un_iff" Set.thy [Un_def] "(c : A Un B) = (c:A | c:B)"
   323  (fn _ => [ Blast_tac 1 ]);
   324 
   325 Addsimps [Un_iff];
   326 
   327 Goal "c:A ==> c : A Un B";
   328 by (Asm_simp_tac 1);
   329 qed "UnI1";
   330 
   331 Goal "c:B ==> c : A Un B";
   332 by (Asm_simp_tac 1);
   333 qed "UnI2";
   334 
   335 (*Classical introduction rule: no commitment to A vs B*)
   336 qed_goal "UnCI" Set.thy "(c~:B ==> c:A) ==> c : A Un B"
   337  (fn prems=>
   338   [ (Simp_tac 1),
   339     (REPEAT (ares_tac (prems@[disjCI]) 1)) ]);
   340 
   341 val major::prems = Goalw [Un_def]
   342     "[| c : A Un B;  c:A ==> P;  c:B ==> P |] ==> P";
   343 by (rtac (major RS CollectD RS disjE) 1);
   344 by (REPEAT (eresolve_tac prems 1));
   345 qed "UnE";
   346 
   347 AddSIs [UnCI];
   348 AddSEs [UnE];
   349 
   350 
   351 section "Binary intersection -- Int";
   352 
   353 qed_goalw "Int_iff" Set.thy [Int_def] "(c : A Int B) = (c:A & c:B)"
   354  (fn _ => [ (Blast_tac 1) ]);
   355 
   356 Addsimps [Int_iff];
   357 
   358 Goal "[| c:A;  c:B |] ==> c : A Int B";
   359 by (Asm_simp_tac 1);
   360 qed "IntI";
   361 
   362 Goal "c : A Int B ==> c:A";
   363 by (Asm_full_simp_tac 1);
   364 qed "IntD1";
   365 
   366 Goal "c : A Int B ==> c:B";
   367 by (Asm_full_simp_tac 1);
   368 qed "IntD2";
   369 
   370 val [major,minor] = Goal
   371     "[| c : A Int B;  [| c:A; c:B |] ==> P |] ==> P";
   372 by (rtac minor 1);
   373 by (rtac (major RS IntD1) 1);
   374 by (rtac (major RS IntD2) 1);
   375 qed "IntE";
   376 
   377 AddSIs [IntI];
   378 AddSEs [IntE];
   379 
   380 section "Set difference";
   381 
   382 qed_goalw "Diff_iff" Set.thy [set_diff_def] "(c : A-B) = (c:A & c~:B)"
   383  (fn _ => [ (Blast_tac 1) ]);
   384 
   385 Addsimps [Diff_iff];
   386 
   387 qed_goal "DiffI" Set.thy "!!c. [| c : A;  c ~: B |] ==> c : A - B"
   388  (fn _=> [ Asm_simp_tac 1 ]);
   389 
   390 qed_goal "DiffD1" Set.thy "!!c. c : A - B ==> c : A"
   391  (fn _=> [ (Asm_full_simp_tac 1) ]);
   392 
   393 qed_goal "DiffD2" Set.thy "!!c. [| c : A - B;  c : B |] ==> P"
   394  (fn _=> [ (Asm_full_simp_tac 1) ]);
   395 
   396 qed_goal "DiffE" Set.thy "[| c : A - B;  [| c:A; c~:B |] ==> P |] ==> P"
   397  (fn prems=>
   398   [ (resolve_tac prems 1),
   399     (REPEAT (ares_tac (prems RL [DiffD1, DiffD2 RS notI]) 1)) ]);
   400 
   401 AddSIs [DiffI];
   402 AddSEs [DiffE];
   403 
   404 
   405 section "Augmenting a set -- insert";
   406 
   407 qed_goalw "insert_iff" Set.thy [insert_def] "a : insert b A = (a=b | a:A)"
   408  (fn _ => [Blast_tac 1]);
   409 
   410 Addsimps [insert_iff];
   411 
   412 qed_goal "insertI1" Set.thy "a : insert a B"
   413  (fn _ => [Simp_tac 1]);
   414 
   415 qed_goal "insertI2" Set.thy "!!a. a : B ==> a : insert b B"
   416  (fn _=> [Asm_simp_tac 1]);
   417 
   418 qed_goalw "insertE" Set.thy [insert_def]
   419     "[| a : insert b A;  a=b ==> P;  a:A ==> P |] ==> P"
   420  (fn major::prems=>
   421   [ (rtac (major RS UnE) 1),
   422     (REPEAT (eresolve_tac (prems @ [CollectE]) 1)) ]);
   423 
   424 (*Classical introduction rule*)
   425 qed_goal "insertCI" Set.thy "(a~:B ==> a=b) ==> a: insert b B"
   426  (fn prems=>
   427   [ (Simp_tac 1),
   428     (REPEAT (ares_tac (prems@[disjCI]) 1)) ]);
   429 
   430 AddSIs [insertCI]; 
   431 AddSEs [insertE];
   432 
   433 section "Singletons, using insert";
   434 
   435 qed_goal "singletonI" Set.thy "a : {a}"
   436  (fn _=> [ (rtac insertI1 1) ]);
   437 
   438 Goal "b : {a} ==> b=a";
   439 by (Blast_tac 1);
   440 qed "singletonD";
   441 
   442 bind_thm ("singletonE", make_elim singletonD);
   443 
   444 qed_goal "singleton_iff" thy "(b : {a}) = (b=a)" 
   445 (fn _ => [Blast_tac 1]);
   446 
   447 Goal "{a}={b} ==> a=b";
   448 by (blast_tac (claset() addEs [equalityE]) 1);
   449 qed "singleton_inject";
   450 
   451 (*Redundant? But unlike insertCI, it proves the subgoal immediately!*)
   452 AddSIs [singletonI];   
   453 AddSDs [singleton_inject];
   454 AddSEs [singletonE];
   455 
   456 Goal "{x. x=a} = {a}";
   457 by (Blast_tac 1);
   458 qed "singleton_conv";
   459 Addsimps [singleton_conv];
   460 
   461 
   462 section "Unions of families -- UNION x:A. B(x) is Union(B``A)";
   463 
   464 Goalw [UNION_def] "(b: (UN x:A. B(x))) = (EX x:A. b: B(x))";
   465 by (Blast_tac 1);
   466 qed "UN_iff";
   467 
   468 Addsimps [UN_iff];
   469 
   470 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   471 Goal "[| a:A;  b: B(a) |] ==> b: (UN x:A. B(x))";
   472 by Auto_tac;
   473 qed "UN_I";
   474 
   475 val major::prems = Goalw [UNION_def]
   476     "[| b : (UN x:A. B(x));  !!x.[| x:A;  b: B(x) |] ==> R |] ==> R";
   477 by (rtac (major RS CollectD RS bexE) 1);
   478 by (REPEAT (ares_tac prems 1));
   479 qed "UN_E";
   480 
   481 AddIs  [UN_I];
   482 AddSEs [UN_E];
   483 
   484 val prems = Goal
   485     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   486 \    (UN x:A. C(x)) = (UN x:B. D(x))";
   487 by (REPEAT (etac UN_E 1
   488      ORELSE ares_tac ([UN_I,equalityI,subsetI] @ 
   489                       (prems RL [equalityD1,equalityD2] RL [subsetD])) 1));
   490 qed "UN_cong";
   491 
   492 
   493 section "Intersections of families -- INTER x:A. B(x) is Inter(B``A)";
   494 
   495 Goalw [INTER_def] "(b: (INT x:A. B(x))) = (ALL x:A. b: B(x))";
   496 by Auto_tac;
   497 qed "INT_iff";
   498 
   499 Addsimps [INT_iff];
   500 
   501 val prems = Goalw [INTER_def]
   502     "(!!x. x:A ==> b: B(x)) ==> b : (INT x:A. B(x))";
   503 by (REPEAT (ares_tac ([CollectI,ballI] @ prems) 1));
   504 qed "INT_I";
   505 
   506 Goal "[| b : (INT x:A. B(x));  a:A |] ==> b: B(a)";
   507 by Auto_tac;
   508 qed "INT_D";
   509 
   510 (*"Classical" elimination -- by the Excluded Middle on a:A *)
   511 val major::prems = Goalw [INTER_def]
   512     "[| b : (INT x:A. B(x));  b: B(a) ==> R;  a~:A ==> R |] ==> R";
   513 by (rtac (major RS CollectD RS ballE) 1);
   514 by (REPEAT (eresolve_tac prems 1));
   515 qed "INT_E";
   516 
   517 AddSIs [INT_I];
   518 AddEs  [INT_D, INT_E];
   519 
   520 val prems = Goal
   521     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   522 \    (INT x:A. C(x)) = (INT x:B. D(x))";
   523 by (REPEAT_FIRST (resolve_tac [INT_I,equalityI,subsetI]));
   524 by (REPEAT (dtac INT_D 1
   525      ORELSE ares_tac (prems RL [equalityD1,equalityD2] RL [subsetD]) 1));
   526 qed "INT_cong";
   527 
   528 
   529 section "Union";
   530 
   531 Goalw [Union_def] "(A : Union(C)) = (EX X:C. A:X)";
   532 by (Blast_tac 1);
   533 qed "Union_iff";
   534 
   535 Addsimps [Union_iff];
   536 
   537 (*The order of the premises presupposes that C is rigid; A may be flexible*)
   538 Goal "[| X:C;  A:X |] ==> A : Union(C)";
   539 by Auto_tac;
   540 qed "UnionI";
   541 
   542 val major::prems = Goalw [Union_def]
   543     "[| A : Union(C);  !!X.[| A:X;  X:C |] ==> R |] ==> R";
   544 by (rtac (major RS UN_E) 1);
   545 by (REPEAT (ares_tac prems 1));
   546 qed "UnionE";
   547 
   548 AddIs  [UnionI];
   549 AddSEs [UnionE];
   550 
   551 
   552 section "Inter";
   553 
   554 Goalw [Inter_def] "(A : Inter(C)) = (ALL X:C. A:X)";
   555 by (Blast_tac 1);
   556 qed "Inter_iff";
   557 
   558 Addsimps [Inter_iff];
   559 
   560 val prems = Goalw [Inter_def]
   561     "[| !!X. X:C ==> A:X |] ==> A : Inter(C)";
   562 by (REPEAT (ares_tac ([INT_I] @ prems) 1));
   563 qed "InterI";
   564 
   565 (*A "destruct" rule -- every X in C contains A as an element, but
   566   A:X can hold when X:C does not!  This rule is analogous to "spec". *)
   567 Goal "[| A : Inter(C);  X:C |] ==> A:X";
   568 by Auto_tac;
   569 qed "InterD";
   570 
   571 (*"Classical" elimination rule -- does not require proving X:C *)
   572 val major::prems = Goalw [Inter_def]
   573     "[| A : Inter(C);  X~:C ==> R;  A:X ==> R |] ==> R";
   574 by (rtac (major RS INT_E) 1);
   575 by (REPEAT (eresolve_tac prems 1));
   576 qed "InterE";
   577 
   578 AddSIs [InterI];
   579 AddEs  [InterD, InterE];
   580 
   581 
   582 (*** Image of a set under a function ***)
   583 
   584 (*Frequently b does not have the syntactic form of f(x).*)
   585 Goalw [image_def] "[| b=f(x);  x:A |] ==> b : f``A";
   586 by (Blast_tac 1);
   587 qed "image_eqI";
   588 Addsimps [image_eqI];
   589 
   590 bind_thm ("imageI", refl RS image_eqI);
   591 
   592 (*The eta-expansion gives variable-name preservation.*)
   593 val major::prems = Goalw [image_def]
   594     "[| b : (%x. f(x))``A;  !!x.[| b=f(x);  x:A |] ==> P |] ==> P"; 
   595 by (rtac (major RS CollectD RS bexE) 1);
   596 by (REPEAT (ares_tac prems 1));
   597 qed "imageE";
   598 
   599 AddIs  [image_eqI];
   600 AddSEs [imageE]; 
   601 
   602 Goal "f``(A Un B) = f``A Un f``B";
   603 by (Blast_tac 1);
   604 qed "image_Un";
   605 
   606 Goal "(z : f``A) = (EX x:A. z = f x)";
   607 by (Blast_tac 1);
   608 qed "image_iff";
   609 
   610 (*This rewrite rule would confuse users if made default.*)
   611 Goal "(f``A <= B) = (ALL x:A. f(x): B)";
   612 by (Blast_tac 1);
   613 qed "image_subset_iff";
   614 
   615 (*Replaces the three steps subsetI, imageE, hyp_subst_tac, but breaks too
   616   many existing proofs.*)
   617 val prems = Goal "(!!x. x:A ==> f(x) : B) ==> f``A <= B";
   618 by (blast_tac (claset() addIs prems) 1);
   619 qed "image_subsetI";
   620 
   621 
   622 (*** Range of a function -- just a translation for image! ***)
   623 
   624 Goal "b=f(x) ==> b : range(f)";
   625 by (EVERY1 [etac image_eqI, rtac UNIV_I]);
   626 bind_thm ("range_eqI", UNIV_I RSN (2,image_eqI));
   627 
   628 bind_thm ("rangeI", UNIV_I RS imageI);
   629 
   630 val [major,minor] = Goal 
   631     "[| b : range(%x. f(x));  !!x. b=f(x) ==> P |] ==> P"; 
   632 by (rtac (major RS imageE) 1);
   633 by (etac minor 1);
   634 qed "rangeE";
   635 
   636 
   637 (*** Set reasoning tools ***)
   638 
   639 
   640 (** Rewrite rules for boolean case-splitting: faster than 
   641 	addsplits[split_if]
   642 **)
   643 
   644 bind_thm ("split_if_eq1", read_instantiate [("P", "%x. x = ?b")] split_if);
   645 bind_thm ("split_if_eq2", read_instantiate [("P", "%x. ?a = x")] split_if);
   646 
   647 (*Split ifs on either side of the membership relation.
   648 	Not for Addsimps -- can cause goals to blow up!*)
   649 bind_thm ("split_if_mem1", 
   650     read_instantiate_sg (sign_of Set.thy) [("P", "%x. x : ?b")] split_if);
   651 bind_thm ("split_if_mem2", 
   652     read_instantiate_sg (sign_of Set.thy) [("P", "%x. ?a : x")] split_if);
   653 
   654 val split_ifs = [if_bool_eq_conj, split_if_eq1, split_if_eq2,
   655 		  split_if_mem1, split_if_mem2];
   656 
   657 
   658 (*Each of these has ALREADY been added to simpset() above.*)
   659 val mem_simps = [insert_iff, empty_iff, Un_iff, Int_iff, Compl_iff, Diff_iff, 
   660                  mem_Collect_eq, UN_iff, Union_iff, INT_iff, Inter_iff];
   661 
   662 val mksimps_pairs = ("Ball",[bspec]) :: mksimps_pairs;
   663 
   664 simpset_ref() := simpset() addcongs [ball_cong,bex_cong]
   665                     setmksimps (mksimps mksimps_pairs);
   666 
   667 Addsimps[subset_UNIV, subset_refl];
   668 
   669 
   670 (*** < ***)
   671 
   672 Goalw [psubset_def] "!!A::'a set. [| A <= B; A ~= B |] ==> A<B";
   673 by (Blast_tac 1);
   674 qed "psubsetI";
   675 
   676 Goalw [psubset_def] "A < insert x B ==> (x ~: A) & A<=B | x:A & A-{x}<B";
   677 by Auto_tac;
   678 qed "psubset_insertD";
   679 
   680 bind_thm ("psubset_eq", psubset_def RS meta_eq_to_obj_eq);