src/Pure/drule.ML
author wenzelm
Mon Dec 04 22:54:31 2017 +0100 (20 months ago)
changeset 67131 85d10959c2e4
parent 64556 851ae0e7b09c
child 67721 5348bea4accd
permissions -rw-r--r--
tuned signature;
     1 (*  Title:      Pure/drule.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3 
     4 Derived rules and other operations on theorems.
     5 *)
     6 
     7 infix 0 RS RSN RL RLN MRS OF COMP INCR_COMP COMP_INCR;
     8 
     9 signature BASIC_DRULE =
    10 sig
    11   val mk_implies: cterm * cterm -> cterm
    12   val list_implies: cterm list * cterm -> cterm
    13   val strip_imp_prems: cterm -> cterm list
    14   val strip_imp_concl: cterm -> cterm
    15   val cprems_of: thm -> cterm list
    16   val forall_intr_list: cterm list -> thm -> thm
    17   val forall_intr_vars: thm -> thm
    18   val forall_elim_list: cterm list -> thm -> thm
    19   val lift_all: Proof.context -> cterm -> thm -> thm
    20   val implies_elim_list: thm -> thm list -> thm
    21   val implies_intr_list: cterm list -> thm -> thm
    22   val instantiate_normalize: ((indexname * sort) * ctyp) list * ((indexname * typ) * cterm) list ->
    23     thm -> thm
    24   val infer_instantiate_types: Proof.context -> ((indexname * typ) * cterm) list -> thm -> thm
    25   val infer_instantiate: Proof.context -> (indexname * cterm) list -> thm -> thm
    26   val infer_instantiate': Proof.context -> cterm option list -> thm -> thm
    27   val zero_var_indexes_list: thm list -> thm list
    28   val zero_var_indexes: thm -> thm
    29   val implies_intr_hyps: thm -> thm
    30   val rotate_prems: int -> thm -> thm
    31   val rearrange_prems: int list -> thm -> thm
    32   val RSN: thm * (int * thm) -> thm
    33   val RS: thm * thm -> thm
    34   val RLN: thm list * (int * thm list) -> thm list
    35   val RL: thm list * thm list -> thm list
    36   val MRS: thm list * thm -> thm
    37   val OF: thm * thm list -> thm
    38   val COMP: thm * thm -> thm
    39   val INCR_COMP: thm * thm -> thm
    40   val COMP_INCR: thm * thm -> thm
    41   val size_of_thm: thm -> int
    42   val reflexive_thm: thm
    43   val symmetric_thm: thm
    44   val transitive_thm: thm
    45   val extensional: thm -> thm
    46   val asm_rl: thm
    47   val cut_rl: thm
    48   val revcut_rl: thm
    49   val thin_rl: thm
    50 end;
    51 
    52 signature DRULE =
    53 sig
    54   include BASIC_DRULE
    55   val outer_params: term -> (string * typ) list
    56   val generalize: string list * string list -> thm -> thm
    57   val list_comb: cterm * cterm list -> cterm
    58   val strip_comb: cterm -> cterm * cterm list
    59   val strip_type: ctyp -> ctyp list * ctyp
    60   val beta_conv: cterm -> cterm -> cterm
    61   val flexflex_unique: Proof.context option -> thm -> thm
    62   val export_without_context: thm -> thm
    63   val export_without_context_open: thm -> thm
    64   val store_thm: binding -> thm -> thm
    65   val store_standard_thm: binding -> thm -> thm
    66   val store_thm_open: binding -> thm -> thm
    67   val store_standard_thm_open: binding -> thm -> thm
    68   val multi_resolve: Proof.context option -> thm list -> thm -> thm Seq.seq
    69   val multi_resolves: Proof.context option -> thm list -> thm list -> thm Seq.seq
    70   val compose: thm * int * thm -> thm
    71   val equals_cong: thm
    72   val imp_cong: thm
    73   val swap_prems_eq: thm
    74   val imp_cong_rule: thm -> thm -> thm
    75   val arg_cong_rule: cterm -> thm -> thm
    76   val binop_cong_rule: cterm -> thm -> thm -> thm
    77   val fun_cong_rule: thm -> cterm -> thm
    78   val beta_eta_conversion: cterm -> thm
    79   val eta_contraction_rule: thm -> thm
    80   val norm_hhf_eq: thm
    81   val norm_hhf_eqs: thm list
    82   val is_norm_hhf: term -> bool
    83   val norm_hhf: theory -> term -> term
    84   val norm_hhf_cterm: Proof.context -> cterm -> cterm
    85   val protect: cterm -> cterm
    86   val protectI: thm
    87   val protectD: thm
    88   val protect_cong: thm
    89   val implies_intr_protected: cterm list -> thm -> thm
    90   val termI: thm
    91   val mk_term: cterm -> thm
    92   val dest_term: thm -> cterm
    93   val cterm_rule: (thm -> thm) -> cterm -> cterm
    94   val cterm_add_frees: cterm -> cterm list -> cterm list
    95   val cterm_add_vars: cterm -> cterm list -> cterm list
    96   val dummy_thm: thm
    97   val free_dummy_thm: thm
    98   val is_sort_constraint: term -> bool
    99   val sort_constraintI: thm
   100   val sort_constraint_eq: thm
   101   val with_subgoal: int -> (thm -> thm) -> thm -> thm
   102   val comp_no_flatten: thm * int -> int -> thm -> thm
   103   val rename_bvars: (string * string) list -> thm -> thm
   104   val rename_bvars': string option list -> thm -> thm
   105   val incr_indexes: thm -> thm -> thm
   106   val incr_indexes2: thm -> thm -> thm -> thm
   107   val triv_forall_equality: thm
   108   val distinct_prems_rl: thm
   109   val equal_intr_rule: thm
   110   val equal_elim_rule1: thm
   111   val equal_elim_rule2: thm
   112   val remdups_rl: thm
   113   val abs_def: thm -> thm
   114 end;
   115 
   116 structure Drule: DRULE =
   117 struct
   118 
   119 
   120 (** some cterm->cterm operations: faster than calling cterm_of! **)
   121 
   122 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   123 fun strip_imp_prems ct =
   124   let val (cA, cB) = Thm.dest_implies ct
   125   in cA :: strip_imp_prems cB end
   126   handle TERM _ => [];
   127 
   128 (* A1==>...An==>B  goes to B, where B is not an implication *)
   129 fun strip_imp_concl ct =
   130   (case Thm.term_of ct of
   131     Const ("Pure.imp", _) $ _ $ _ => strip_imp_concl (Thm.dest_arg ct)
   132   | _ => ct);
   133 
   134 (*The premises of a theorem, as a cterm list*)
   135 val cprems_of = strip_imp_prems o Thm.cprop_of;
   136 
   137 fun certify t = Thm.global_cterm_of (Context.the_global_context ()) t;
   138 
   139 val implies = certify Logic.implies;
   140 fun mk_implies (A, B) = Thm.apply (Thm.apply implies A) B;
   141 
   142 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   143 fun list_implies([], B) = B
   144   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   145 
   146 (*cterm version of list_comb: maps  (f, [t1,...,tn])  to  f(t1,...,tn) *)
   147 fun list_comb (f, []) = f
   148   | list_comb (f, t::ts) = list_comb (Thm.apply f t, ts);
   149 
   150 (*cterm version of strip_comb: maps  f(t1,...,tn)  to  (f, [t1,...,tn]) *)
   151 fun strip_comb ct =
   152   let
   153     fun stripc (p as (ct, cts)) =
   154       let val (ct1, ct2) = Thm.dest_comb ct
   155       in stripc (ct1, ct2 :: cts) end handle CTERM _ => p
   156   in stripc (ct, []) end;
   157 
   158 (* cterm version of strip_type: maps  [T1,...,Tn]--->T  to   ([T1,T2,...,Tn], T) *)
   159 fun strip_type cT = (case Thm.typ_of cT of
   160     Type ("fun", _) =>
   161       let
   162         val [cT1, cT2] = Thm.dest_ctyp cT;
   163         val (cTs, cT') = strip_type cT2
   164       in (cT1 :: cTs, cT') end
   165   | _ => ([], cT));
   166 
   167 (*Beta-conversion for cterms, where x is an abstraction. Simply returns the rhs
   168   of the meta-equality returned by the beta_conversion rule.*)
   169 fun beta_conv x y =
   170   Thm.dest_arg (Thm.cprop_of (Thm.beta_conversion false (Thm.apply x y)));
   171 
   172 
   173 
   174 (** Standardization of rules **)
   175 
   176 (*Generalization over a list of variables*)
   177 val forall_intr_list = fold_rev Thm.forall_intr;
   178 
   179 (*Generalization over Vars -- canonical order*)
   180 fun forall_intr_vars th = fold Thm.forall_intr (Thm.add_vars th []) th;
   181 
   182 fun outer_params t =
   183   let val vs = Term.strip_all_vars t
   184   in Name.variant_list [] (map (Name.clean o #1) vs) ~~ map #2 vs end;
   185 
   186 (*lift vars wrt. outermost goal parameters
   187   -- reverses the effect of gen_all modulo higher-order unification*)
   188 fun lift_all ctxt raw_goal raw_th =
   189   let
   190     val thy = Proof_Context.theory_of ctxt;
   191     val goal = Thm.transfer_cterm thy raw_goal;
   192     val th = Thm.transfer thy raw_th;
   193 
   194     val maxidx = Thm.maxidx_of th;
   195     val ps = outer_params (Thm.term_of goal)
   196       |> map (fn (x, T) => Var ((x, maxidx + 1), Logic.incr_tvar (maxidx + 1) T));
   197     val Ts = map Term.fastype_of ps;
   198     val inst =
   199       Thm.fold_terms Term.add_vars th []
   200       |> map (fn (xi, T) => ((xi, T), Thm.cterm_of ctxt (Term.list_comb (Var (xi, Ts ---> T), ps))));
   201   in
   202     th
   203     |> Thm.instantiate ([], inst)
   204     |> fold_rev (Thm.forall_intr o Thm.cterm_of ctxt) ps
   205   end;
   206 
   207 (*direct generalization*)
   208 fun generalize names th = Thm.generalize names (Thm.maxidx_of th + 1) th;
   209 
   210 (*specialization over a list of cterms*)
   211 val forall_elim_list = fold Thm.forall_elim;
   212 
   213 (*maps A1,...,An |- B  to  [| A1;...;An |] ==> B*)
   214 val implies_intr_list = fold_rev Thm.implies_intr;
   215 
   216 (*maps [| A1;...;An |] ==> B and [A1,...,An]  to  B*)
   217 fun implies_elim_list impth ths = fold Thm.elim_implies ths impth;
   218 
   219 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   220 fun zero_var_indexes_list [] = []
   221   | zero_var_indexes_list ths =
   222       let
   223         val (instT, inst) = Term_Subst.zero_var_indexes_inst (map Thm.full_prop_of ths);
   224 
   225         val tvars = fold Thm.add_tvars ths [];
   226         fun the_tvar v = the (find_first (fn cT => v = dest_TVar (Thm.typ_of cT)) tvars);
   227         val instT' = map (fn (v, TVar (b, _)) => (v, Thm.rename_tvar b (the_tvar v))) instT;
   228 
   229         val vars = fold (Thm.add_vars o Thm.instantiate (instT', [])) ths [];
   230         fun the_var v = the (find_first (fn ct => v = dest_Var (Thm.term_of ct)) vars);
   231         val inst' = map (fn (v, Var (b, _)) => (v, Thm.var (b, Thm.ctyp_of_cterm (the_var v)))) inst;
   232       in map (Thm.adjust_maxidx_thm ~1 o Thm.instantiate (instT', inst')) ths end;
   233 
   234 val zero_var_indexes = singleton zero_var_indexes_list;
   235 
   236 
   237 (** Standard form of object-rule: no hypotheses, flexflex constraints,
   238     Frees, or outer quantifiers; all generality expressed by Vars of index 0.**)
   239 
   240 (*Discharge all hypotheses.*)
   241 fun implies_intr_hyps th = fold Thm.implies_intr (Thm.chyps_of th) th;
   242 
   243 (*Squash a theorem's flexflex constraints provided it can be done uniquely.
   244   This step can lose information.*)
   245 fun flexflex_unique opt_ctxt th =
   246   if null (Thm.tpairs_of th) then th
   247   else
   248     (case distinct Thm.eq_thm (Seq.list_of (Thm.flexflex_rule opt_ctxt th)) of
   249       [th] => th
   250     | [] => raise THM ("flexflex_unique: impossible constraints", 0, [th])
   251     | _ => raise THM ("flexflex_unique: multiple unifiers", 0, [th]));
   252 
   253 
   254 (* old-style export without context *)
   255 
   256 val export_without_context_open =
   257   implies_intr_hyps
   258   #> Thm.forall_intr_frees
   259   #> `Thm.maxidx_of
   260   #-> (fn maxidx =>
   261     Thm.forall_elim_vars (maxidx + 1)
   262     #> Thm.strip_shyps
   263     #> zero_var_indexes
   264     #> Thm.varifyT_global);
   265 
   266 val export_without_context =
   267   flexflex_unique NONE
   268   #> export_without_context_open
   269   #> Thm.close_derivation;
   270 
   271 
   272 (*Rotates a rule's premises to the left by k*)
   273 fun rotate_prems 0 = I
   274   | rotate_prems k = Thm.permute_prems 0 k;
   275 
   276 fun with_subgoal i f = rotate_prems (i - 1) #> f #> rotate_prems (1 - i);
   277 
   278 (*Permute prems, where the i-th position in the argument list (counting from 0)
   279   gives the position within the original thm to be transferred to position i.
   280   Any remaining trailing positions are left unchanged.*)
   281 val rearrange_prems =
   282   let
   283     fun rearr new [] thm = thm
   284       | rearr new (p :: ps) thm =
   285           rearr (new + 1)
   286             (map (fn q => if new <= q andalso q < p then q + 1 else q) ps)
   287             (Thm.permute_prems (new + 1) (new - p) (Thm.permute_prems new (p - new) thm))
   288   in rearr 0 end;
   289 
   290 
   291 (*Resolution: multiple arguments, multiple results*)
   292 local
   293   fun res opt_ctxt th i rule =
   294     Thm.biresolution opt_ctxt false [(false, th)] i rule handle THM _ => Seq.empty;
   295 
   296   fun multi_res _ _ [] rule = Seq.single rule
   297     | multi_res opt_ctxt i (th :: ths) rule =
   298         Seq.maps (res opt_ctxt th i) (multi_res opt_ctxt (i + 1) ths rule);
   299 in
   300   fun multi_resolve opt_ctxt = multi_res opt_ctxt 1;
   301   fun multi_resolves opt_ctxt facts rules =
   302     Seq.maps (multi_resolve opt_ctxt facts) (Seq.of_list rules);
   303 end;
   304 
   305 (*Resolution: exactly one resolvent must be produced*)
   306 fun tha RSN (i, thb) =
   307   (case Seq.chop 2 (Thm.biresolution NONE false [(false, tha)] i thb) of
   308     ([th], _) => th
   309   | ([], _) => raise THM ("RSN: no unifiers", i, [tha, thb])
   310   | _ => raise THM ("RSN: multiple unifiers", i, [tha, thb]));
   311 
   312 (*Resolution: P==>Q, Q==>R gives P==>R*)
   313 fun tha RS thb = tha RSN (1,thb);
   314 
   315 (*For joining lists of rules*)
   316 fun thas RLN (i, thbs) =
   317   let
   318     val resolve = Thm.biresolution NONE false (map (pair false) thas) i
   319     fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   320   in maps resb thbs end;
   321 
   322 fun thas RL thbs = thas RLN (1, thbs);
   323 
   324 (*Isar-style multi-resolution*)
   325 fun bottom_rl OF rls =
   326   (case Seq.chop 2 (multi_resolve NONE rls bottom_rl) of
   327     ([th], _) => th
   328   | ([], _) => raise THM ("OF: no unifiers", 0, bottom_rl :: rls)
   329   | _ => raise THM ("OF: multiple unifiers", 0, bottom_rl :: rls));
   330 
   331 (*Resolve a list of rules against bottom_rl from right to left;
   332   makes proof trees*)
   333 fun rls MRS bottom_rl = bottom_rl OF rls;
   334 
   335 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   336   with no lifting or renaming!  Q may contain ==> or meta-quants
   337   ALWAYS deletes premise i *)
   338 fun compose (tha, i, thb) =
   339   Thm.bicompose NONE {flatten = true, match = false, incremented = false} (false, tha, 0) i thb
   340   |> Seq.list_of |> distinct Thm.eq_thm
   341   |> (fn [th] => th | _ => raise THM ("compose: unique result expected", i, [tha, thb]));
   342 
   343 
   344 (** theorem equality **)
   345 
   346 (*Useful "distance" function for BEST_FIRST*)
   347 val size_of_thm = size_of_term o Thm.full_prop_of;
   348 
   349 
   350 
   351 (*** Meta-Rewriting Rules ***)
   352 
   353 val read_prop = certify o Simple_Syntax.read_prop;
   354 
   355 fun store_thm name th =
   356   Context.>>> (Context.map_theory_result (Global_Theory.store_thm (name, th)));
   357 
   358 fun store_thm_open name th =
   359   Context.>>> (Context.map_theory_result (Global_Theory.store_thm_open (name, th)));
   360 
   361 fun store_standard_thm name th = store_thm name (export_without_context th);
   362 fun store_standard_thm_open name th = store_thm_open name (export_without_context_open th);
   363 
   364 val reflexive_thm =
   365   let val cx = certify (Var(("x",0),TVar(("'a",0),[])))
   366   in store_standard_thm_open (Binding.make ("reflexive", \<^here>)) (Thm.reflexive cx) end;
   367 
   368 val symmetric_thm =
   369   let
   370     val xy = read_prop "x::'a == y::'a";
   371     val thm = Thm.implies_intr xy (Thm.symmetric (Thm.assume xy));
   372   in store_standard_thm_open (Binding.make ("symmetric", \<^here>)) thm end;
   373 
   374 val transitive_thm =
   375   let
   376     val xy = read_prop "x::'a == y::'a";
   377     val yz = read_prop "y::'a == z::'a";
   378     val xythm = Thm.assume xy;
   379     val yzthm = Thm.assume yz;
   380     val thm = Thm.implies_intr yz (Thm.transitive xythm yzthm);
   381   in store_standard_thm_open (Binding.make ("transitive", \<^here>)) thm end;
   382 
   383 fun extensional eq =
   384   let val eq' =
   385     Thm.abstract_rule "x" (Thm.dest_arg (fst (Thm.dest_equals (Thm.cprop_of eq)))) eq
   386   in Thm.equal_elim (Thm.eta_conversion (Thm.cprop_of eq')) eq' end;
   387 
   388 val equals_cong =
   389   store_standard_thm_open (Binding.make ("equals_cong", \<^here>))
   390     (Thm.reflexive (read_prop "x::'a == y::'a"));
   391 
   392 val imp_cong =
   393   let
   394     val ABC = read_prop "A ==> B::prop == C::prop"
   395     val AB = read_prop "A ==> B"
   396     val AC = read_prop "A ==> C"
   397     val A = read_prop "A"
   398   in
   399     store_standard_thm_open (Binding.make ("imp_cong", \<^here>))
   400       (Thm.implies_intr ABC (Thm.equal_intr
   401         (Thm.implies_intr AB (Thm.implies_intr A
   402           (Thm.equal_elim (Thm.implies_elim (Thm.assume ABC) (Thm.assume A))
   403             (Thm.implies_elim (Thm.assume AB) (Thm.assume A)))))
   404         (Thm.implies_intr AC (Thm.implies_intr A
   405           (Thm.equal_elim (Thm.symmetric (Thm.implies_elim (Thm.assume ABC) (Thm.assume A)))
   406             (Thm.implies_elim (Thm.assume AC) (Thm.assume A)))))))
   407   end;
   408 
   409 val swap_prems_eq =
   410   let
   411     val ABC = read_prop "A ==> B ==> C"
   412     val BAC = read_prop "B ==> A ==> C"
   413     val A = read_prop "A"
   414     val B = read_prop "B"
   415   in
   416     store_standard_thm_open (Binding.make ("swap_prems_eq", \<^here>))
   417       (Thm.equal_intr
   418         (Thm.implies_intr ABC (Thm.implies_intr B (Thm.implies_intr A
   419           (Thm.implies_elim (Thm.implies_elim (Thm.assume ABC) (Thm.assume A)) (Thm.assume B)))))
   420         (Thm.implies_intr BAC (Thm.implies_intr A (Thm.implies_intr B
   421           (Thm.implies_elim (Thm.implies_elim (Thm.assume BAC) (Thm.assume B)) (Thm.assume A))))))
   422   end;
   423 
   424 val imp_cong_rule = Thm.combination o Thm.combination (Thm.reflexive implies);
   425 
   426 fun arg_cong_rule ct th = Thm.combination (Thm.reflexive ct) th;    (*AP_TERM in LCF/HOL*)
   427 fun fun_cong_rule th ct = Thm.combination th (Thm.reflexive ct);    (*AP_THM in LCF/HOL*)
   428 fun binop_cong_rule ct th1 th2 = Thm.combination (arg_cong_rule ct th1) th2;
   429 
   430 fun beta_eta_conversion ct =
   431   let val thm = Thm.beta_conversion true ct
   432   in Thm.transitive thm (Thm.eta_conversion (Thm.rhs_of thm)) end;
   433 
   434 (*Contract all eta-redexes in the theorem, lest they give rise to needless abstractions*)
   435 fun eta_contraction_rule th =
   436   Thm.equal_elim (Thm.eta_conversion (Thm.cprop_of th)) th;
   437 
   438 
   439 (* abs_def *)
   440 
   441 (*
   442    f ?x1 ... ?xn == u
   443   --------------------
   444    f == %x1 ... xn. u
   445 *)
   446 
   447 local
   448 
   449 fun contract_lhs th =
   450   Thm.transitive (Thm.symmetric (beta_eta_conversion (#1 (Thm.dest_equals (Thm.cprop_of th))))) th;
   451 
   452 fun var_args ct =
   453   (case try Thm.dest_comb ct of
   454     SOME (f, arg) =>
   455       (case Thm.term_of arg of
   456         Var ((x, _), _) => update (eq_snd (op aconvc)) (x, arg) (var_args f)
   457       | _ => [])
   458   | NONE => []);
   459 
   460 in
   461 
   462 fun abs_def th =
   463   let
   464     val th' = contract_lhs th;
   465     val args = var_args (Thm.lhs_of th');
   466   in contract_lhs (fold (uncurry Thm.abstract_rule) args th') end;
   467 
   468 end;
   469 
   470 
   471 
   472 (*** Some useful meta-theorems ***)
   473 
   474 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   475 val asm_rl =
   476   store_standard_thm_open (Binding.make ("asm_rl", \<^here>))
   477     (Thm.trivial (read_prop "?psi"));
   478 
   479 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   480 val cut_rl =
   481   store_standard_thm_open (Binding.make ("cut_rl", \<^here>))
   482     (Thm.trivial (read_prop "?psi ==> ?theta"));
   483 
   484 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   485      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   486 val revcut_rl =
   487   let
   488     val V = read_prop "V";
   489     val VW = read_prop "V ==> W";
   490   in
   491     store_standard_thm_open (Binding.make ("revcut_rl", \<^here>))
   492       (Thm.implies_intr V
   493         (Thm.implies_intr VW (Thm.implies_elim (Thm.assume VW) (Thm.assume V))))
   494   end;
   495 
   496 (*for deleting an unwanted assumption*)
   497 val thin_rl =
   498   let
   499     val V = read_prop "V";
   500     val W = read_prop "W";
   501     val thm = Thm.implies_intr V (Thm.implies_intr W (Thm.assume W));
   502   in store_standard_thm_open (Binding.make ("thin_rl", \<^here>)) thm end;
   503 
   504 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   505 val triv_forall_equality =
   506   let
   507     val V = read_prop "V";
   508     val QV = read_prop "!!x::'a. V";
   509     val x = certify (Free ("x", Term.aT []));
   510   in
   511     store_standard_thm_open (Binding.make ("triv_forall_equality", \<^here>))
   512       (Thm.equal_intr (Thm.implies_intr QV (Thm.forall_elim x (Thm.assume QV)))
   513         (Thm.implies_intr V (Thm.forall_intr x (Thm.assume V))))
   514   end;
   515 
   516 (* (PROP ?Phi ==> PROP ?Phi ==> PROP ?Psi) ==>
   517    (PROP ?Phi ==> PROP ?Psi)
   518 *)
   519 val distinct_prems_rl =
   520   let
   521     val AAB = read_prop "Phi ==> Phi ==> Psi";
   522     val A = read_prop "Phi";
   523   in
   524     store_standard_thm_open (Binding.make ("distinct_prems_rl", \<^here>))
   525       (implies_intr_list [AAB, A]
   526         (implies_elim_list (Thm.assume AAB) [Thm.assume A, Thm.assume A]))
   527   end;
   528 
   529 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   530    ==> PROP ?phi == PROP ?psi
   531    Introduction rule for == as a meta-theorem.
   532 *)
   533 val equal_intr_rule =
   534   let
   535     val PQ = read_prop "phi ==> psi";
   536     val QP = read_prop "psi ==> phi";
   537   in
   538     store_standard_thm_open (Binding.make ("equal_intr_rule", \<^here>))
   539       (Thm.implies_intr PQ
   540         (Thm.implies_intr QP (Thm.equal_intr (Thm.assume PQ) (Thm.assume QP))))
   541   end;
   542 
   543 (* PROP ?phi == PROP ?psi ==> PROP ?phi ==> PROP ?psi *)
   544 val equal_elim_rule1 =
   545   let
   546     val eq = read_prop "phi::prop == psi::prop";
   547     val P = read_prop "phi";
   548   in
   549     store_standard_thm_open (Binding.make ("equal_elim_rule1", \<^here>))
   550       (Thm.equal_elim (Thm.assume eq) (Thm.assume P) |> implies_intr_list [eq, P])
   551   end;
   552 
   553 (* PROP ?psi == PROP ?phi ==> PROP ?phi ==> PROP ?psi *)
   554 val equal_elim_rule2 =
   555   store_standard_thm_open (Binding.make ("equal_elim_rule2", \<^here>))
   556     (symmetric_thm RS equal_elim_rule1);
   557 
   558 (* PROP ?phi ==> PROP ?phi ==> PROP ?psi ==> PROP ?psi *)
   559 val remdups_rl =
   560   let
   561     val P = read_prop "phi";
   562     val Q = read_prop "psi";
   563     val thm = implies_intr_list [P, P, Q] (Thm.assume Q);
   564   in store_standard_thm_open (Binding.make ("remdups_rl", \<^here>)) thm end;
   565 
   566 
   567 
   568 (** embedded terms and types **)
   569 
   570 local
   571   val A = certify (Free ("A", propT));
   572   val axiom = Thm.unvarify_axiom (Context.the_global_context ());
   573   val prop_def = axiom "Pure.prop_def";
   574   val term_def = axiom "Pure.term_def";
   575   val sort_constraint_def = axiom "Pure.sort_constraint_def";
   576   val C = Thm.lhs_of sort_constraint_def;
   577   val T = Thm.dest_arg C;
   578   val CA = mk_implies (C, A);
   579 in
   580 
   581 (* protect *)
   582 
   583 val protect = Thm.apply (certify Logic.protectC);
   584 
   585 val protectI =
   586   store_standard_thm (Binding.concealed (Binding.make ("protectI", \<^here>)))
   587     (Thm.equal_elim (Thm.symmetric prop_def) (Thm.assume A));
   588 
   589 val protectD =
   590   store_standard_thm (Binding.concealed (Binding.make ("protectD", \<^here>)))
   591     (Thm.equal_elim prop_def (Thm.assume (protect A)));
   592 
   593 val protect_cong =
   594   store_standard_thm_open (Binding.make ("protect_cong", \<^here>))
   595     (Thm.reflexive (protect A));
   596 
   597 fun implies_intr_protected asms th =
   598   let val asms' = map protect asms in
   599     implies_elim_list
   600       (implies_intr_list asms th)
   601       (map (fn asm' => Thm.assume asm' RS protectD) asms')
   602     |> implies_intr_list asms'
   603   end;
   604 
   605 
   606 (* term *)
   607 
   608 val termI =
   609   store_standard_thm (Binding.concealed (Binding.make ("termI", \<^here>)))
   610     (Thm.equal_elim (Thm.symmetric term_def) (Thm.forall_intr A (Thm.trivial A)));
   611 
   612 fun mk_term ct =
   613   let
   614     val cT = Thm.ctyp_of_cterm ct;
   615     val T = Thm.typ_of cT;
   616   in Thm.instantiate ([((("'a", 0), []), cT)], [((("x", 0), T), ct)]) termI end;
   617 
   618 fun dest_term th =
   619   let val cprop = strip_imp_concl (Thm.cprop_of th) in
   620     if can Logic.dest_term (Thm.term_of cprop) then
   621       Thm.dest_arg cprop
   622     else raise THM ("dest_term", 0, [th])
   623   end;
   624 
   625 fun cterm_rule f = dest_term o f o mk_term;
   626 
   627 val cterm_add_frees = Thm.add_frees o mk_term;
   628 val cterm_add_vars = Thm.add_vars o mk_term;
   629 
   630 val dummy_thm = mk_term (certify Term.dummy_prop);
   631 val free_dummy_thm = Thm.tag_free_dummy dummy_thm;
   632 
   633 
   634 (* sort_constraint *)
   635 
   636 fun is_sort_constraint (Const ("Pure.sort_constraint", _) $ Const ("Pure.type", _)) = true
   637   | is_sort_constraint _ = false;
   638 
   639 val sort_constraintI =
   640   store_standard_thm (Binding.concealed (Binding.make ("sort_constraintI", \<^here>)))
   641     (Thm.equal_elim (Thm.symmetric sort_constraint_def) (mk_term T));
   642 
   643 val sort_constraint_eq =
   644   store_standard_thm (Binding.concealed (Binding.make ("sort_constraint_eq", \<^here>)))
   645     (Thm.equal_intr
   646       (Thm.implies_intr CA (Thm.implies_elim (Thm.assume CA)
   647         (Thm.unvarify_global (Context.the_global_context ()) sort_constraintI)))
   648       (implies_intr_list [A, C] (Thm.assume A)));
   649 
   650 end;
   651 
   652 
   653 (* HHF normalization *)
   654 
   655 (* (PROP ?phi ==> (!!x. PROP ?psi x)) == (!!x. PROP ?phi ==> PROP ?psi x) *)
   656 val norm_hhf_eq =
   657   let
   658     val aT = TFree ("'a", []);
   659     val x = Free ("x", aT);
   660     val phi = Free ("phi", propT);
   661     val psi = Free ("psi", aT --> propT);
   662 
   663     val cx = certify x;
   664     val cphi = certify phi;
   665     val lhs = certify (Logic.mk_implies (phi, Logic.all x (psi $ x)));
   666     val rhs = certify (Logic.all x (Logic.mk_implies (phi, psi $ x)));
   667   in
   668     Thm.equal_intr
   669       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   670         |> Thm.forall_elim cx
   671         |> Thm.implies_intr cphi
   672         |> Thm.forall_intr cx
   673         |> Thm.implies_intr lhs)
   674       (Thm.implies_elim
   675           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   676         |> Thm.forall_intr cx
   677         |> Thm.implies_intr cphi
   678         |> Thm.implies_intr rhs)
   679     |> store_standard_thm_open (Binding.make ("norm_hhf_eq", \<^here>))
   680   end;
   681 
   682 val norm_hhf_prop = Logic.dest_equals (Thm.prop_of norm_hhf_eq);
   683 val norm_hhf_eqs = [norm_hhf_eq, sort_constraint_eq];
   684 
   685 fun is_norm_hhf (Const ("Pure.sort_constraint", _)) = false
   686   | is_norm_hhf (Const ("Pure.imp", _) $ _ $ (Const ("Pure.all", _) $ _)) = false
   687   | is_norm_hhf (Abs _ $ _) = false
   688   | is_norm_hhf (t $ u) = is_norm_hhf t andalso is_norm_hhf u
   689   | is_norm_hhf (Abs (_, _, t)) = is_norm_hhf t
   690   | is_norm_hhf _ = true;
   691 
   692 fun norm_hhf thy t =
   693   if is_norm_hhf t then t
   694   else Pattern.rewrite_term thy [norm_hhf_prop] [] t;
   695 
   696 fun norm_hhf_cterm ctxt raw_ct =
   697   let
   698     val thy = Proof_Context.theory_of ctxt;
   699     val ct = Thm.transfer_cterm thy raw_ct;
   700     val t = Thm.term_of ct;
   701   in if is_norm_hhf t then ct else Thm.cterm_of ctxt (norm_hhf thy t) end;
   702 
   703 
   704 (* var indexes *)
   705 
   706 fun incr_indexes th = Thm.incr_indexes (Thm.maxidx_of th + 1);
   707 
   708 fun incr_indexes2 th1 th2 =
   709   Thm.incr_indexes (Int.max (Thm.maxidx_of th1, Thm.maxidx_of th2) + 1);
   710 
   711 local
   712 
   713 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   714 fun comp incremented th1 th2 =
   715   Thm.bicompose NONE {flatten = true, match = false, incremented = incremented}
   716     (false, th1, 0) 1 th2
   717   |> Seq.list_of |> distinct Thm.eq_thm
   718   |> (fn [th] => th | _ => raise THM ("COMP", 1, [th1, th2]));
   719 
   720 in
   721 
   722 fun th1 COMP th2 = comp false th1 th2;
   723 fun th1 INCR_COMP th2 = comp true (incr_indexes th2 th1) th2;
   724 fun th1 COMP_INCR th2 = comp true th1 (incr_indexes th1 th2);
   725 
   726 end;
   727 
   728 fun comp_no_flatten (th, n) i rule =
   729   (case distinct Thm.eq_thm (Seq.list_of
   730       (Thm.bicompose NONE {flatten = false, match = false, incremented = true}
   731         (false, th, n) i (incr_indexes th rule))) of
   732     [th'] => th'
   733   | [] => raise THM ("comp_no_flatten", i, [th, rule])
   734   | _ => raise THM ("comp_no_flatten: unique result expected", i, [th, rule]));
   735 
   736 
   737 
   738 (** variations on Thm.instantiate **)
   739 
   740 fun instantiate_normalize instpair th =
   741   Thm.adjust_maxidx_thm ~1 (Thm.instantiate instpair th COMP_INCR asm_rl);
   742 
   743 (*instantiation with type-inference for variables*)
   744 fun infer_instantiate_types _ [] th = th
   745   | infer_instantiate_types ctxt args raw_th =
   746       let
   747         val thy = Proof_Context.theory_of ctxt;
   748         val th = Thm.transfer thy raw_th;
   749 
   750         fun infer ((xi, T), cu) (tyenv, maxidx) =
   751           let
   752             val _ = Thm.ctyp_of ctxt T;
   753             val _ = Thm.transfer_cterm thy cu;
   754             val U = Thm.typ_of_cterm cu;
   755             val maxidx' = maxidx
   756               |> Integer.max (#2 xi)
   757               |> Term.maxidx_typ T
   758               |> Integer.max (Thm.maxidx_of_cterm cu);
   759             val (tyenv', maxidx'') = Sign.typ_unify thy (T, U) (tyenv, maxidx')
   760               handle Type.TUNIFY =>
   761                 let
   762                   val t = Var (xi, T);
   763                   val u = Thm.term_of cu;
   764                 in
   765                   raise THM ("infer_instantiate_types: type " ^
   766                     Syntax.string_of_typ ctxt (Envir.norm_type tyenv T) ^ " of variable " ^
   767                     Syntax.string_of_term ctxt (Term.map_types (Envir.norm_type tyenv) t) ^
   768                     "\ncannot be unified with type " ^
   769                     Syntax.string_of_typ ctxt (Envir.norm_type tyenv U) ^ " of term " ^
   770                     Syntax.string_of_term ctxt (Term.map_types (Envir.norm_type tyenv) u),
   771                     0, [th])
   772                 end;
   773           in (tyenv', maxidx'') end;
   774 
   775         val (tyenv, _) = fold infer args (Vartab.empty, 0);
   776         val instT =
   777           Vartab.fold (fn (xi, (S, T)) =>
   778             cons ((xi, S), Thm.ctyp_of ctxt (Envir.norm_type tyenv T))) tyenv [];
   779         val inst = args |> map (fn ((xi, T), cu) =>
   780           ((xi, Envir.norm_type tyenv T),
   781             Thm.instantiate_cterm (instT, []) (Thm.transfer_cterm thy cu)));
   782       in instantiate_normalize (instT, inst) th end
   783       handle CTERM (msg, _) => raise THM (msg, 0, [raw_th])
   784         | TERM (msg, _) => raise THM (msg, 0, [raw_th])
   785         | TYPE (msg, _, _) => raise THM (msg, 0, [raw_th]);
   786 
   787 fun infer_instantiate _ [] th = th
   788   | infer_instantiate ctxt args th =
   789       let
   790         val vars = Term.add_vars (Thm.full_prop_of th) [];
   791         val dups = duplicates (eq_fst op =) vars;
   792         val _ = null dups orelse
   793           raise THM ("infer_instantiate: inconsistent types for variables " ^
   794             commas_quote (map (Syntax.string_of_term (Config.put show_types true ctxt) o Var) dups),
   795             0, [th]);
   796         val args' = args |> map_filter (fn (xi, cu) =>
   797           AList.lookup (op =) vars xi |> Option.map (fn T => ((xi, T), cu)));
   798       in infer_instantiate_types ctxt args' th end;
   799 
   800 fun infer_instantiate' ctxt args th =
   801   let
   802     val vars = rev (Term.add_vars (Thm.full_prop_of th) []);
   803     val args' = zip_options vars args
   804       handle ListPair.UnequalLengths =>
   805         raise THM ("infer_instantiate': more instantiations than variables in thm", 0, [th]);
   806   in infer_instantiate_types ctxt args' th end;
   807 
   808 
   809 
   810 (** renaming of bound variables **)
   811 
   812 (* replace bound variables x_i in thm by y_i *)
   813 (* where vs = [(x_1, y_1), ..., (x_n, y_n)]  *)
   814 
   815 fun rename_bvars [] thm = thm
   816   | rename_bvars vs thm =
   817       let
   818         fun rename (Abs (x, T, t)) = Abs (AList.lookup (op =) vs x |> the_default x, T, rename t)
   819           | rename (t $ u) = rename t $ rename u
   820           | rename a = a;
   821       in Thm.renamed_prop (rename (Thm.prop_of thm)) thm end;
   822 
   823 
   824 (* renaming in left-to-right order *)
   825 
   826 fun rename_bvars' xs thm =
   827   let
   828     fun rename [] t = ([], t)
   829       | rename (x' :: xs) (Abs (x, T, t)) =
   830           let val (xs', t') = rename xs t
   831           in (xs', Abs (the_default x x', T, t')) end
   832       | rename xs (t $ u) =
   833           let
   834             val (xs', t') = rename xs t;
   835             val (xs'', u') = rename xs' u;
   836           in (xs'', t' $ u') end
   837       | rename xs a = (xs, a);
   838   in
   839     (case rename xs (Thm.prop_of thm) of
   840       ([], prop') => Thm.renamed_prop prop' thm
   841     | _ => error "More names than abstractions in theorem")
   842   end;
   843 
   844 end;
   845 
   846 structure Basic_Drule: BASIC_DRULE = Drule;
   847 open Basic_Drule;