src/ZF/Constructible/Wellorderings.thy
author wenzelm
Mon Dec 04 22:54:31 2017 +0100 (21 months ago)
changeset 67131 85d10959c2e4
parent 61798 27f3c10b0b50
child 67443 3abf6a722518
permissions -rw-r--r--
tuned signature;
     1 (*  Title:      ZF/Constructible/Wellorderings.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3 *)
     4 
     5 section \<open>Relativized Wellorderings\<close>
     6 
     7 theory Wellorderings imports Relative begin
     8 
     9 text\<open>We define functions analogous to @{term ordermap} @{term ordertype} 
    10       but without using recursion.  Instead, there is a direct appeal
    11       to Replacement.  This will be the basis for a version relativized
    12       to some class \<open>M\<close>.  The main result is Theorem I 7.6 in Kunen,
    13       page 17.\<close>
    14 
    15 
    16 subsection\<open>Wellorderings\<close>
    17 
    18 definition
    19   irreflexive :: "[i=>o,i,i]=>o" where
    20     "irreflexive(M,A,r) == \<forall>x[M]. x\<in>A \<longrightarrow> <x,x> \<notin> r"
    21   
    22 definition
    23   transitive_rel :: "[i=>o,i,i]=>o" where
    24     "transitive_rel(M,A,r) == 
    25         \<forall>x[M]. x\<in>A \<longrightarrow> (\<forall>y[M]. y\<in>A \<longrightarrow> (\<forall>z[M]. z\<in>A \<longrightarrow> 
    26                           <x,y>\<in>r \<longrightarrow> <y,z>\<in>r \<longrightarrow> <x,z>\<in>r))"
    27 
    28 definition
    29   linear_rel :: "[i=>o,i,i]=>o" where
    30     "linear_rel(M,A,r) == 
    31         \<forall>x[M]. x\<in>A \<longrightarrow> (\<forall>y[M]. y\<in>A \<longrightarrow> <x,y>\<in>r | x=y | <y,x>\<in>r)"
    32 
    33 definition
    34   wellfounded :: "[i=>o,i]=>o" where
    35     \<comment>\<open>EVERY non-empty set has an \<open>r\<close>-minimal element\<close>
    36     "wellfounded(M,r) == 
    37         \<forall>x[M]. x\<noteq>0 \<longrightarrow> (\<exists>y[M]. y\<in>x & ~(\<exists>z[M]. z\<in>x & <z,y> \<in> r))"
    38 definition
    39   wellfounded_on :: "[i=>o,i,i]=>o" where
    40     \<comment>\<open>every non-empty SUBSET OF \<open>A\<close> has an \<open>r\<close>-minimal element\<close>
    41     "wellfounded_on(M,A,r) == 
    42         \<forall>x[M]. x\<noteq>0 \<longrightarrow> x\<subseteq>A \<longrightarrow> (\<exists>y[M]. y\<in>x & ~(\<exists>z[M]. z\<in>x & <z,y> \<in> r))"
    43 
    44 definition
    45   wellordered :: "[i=>o,i,i]=>o" where
    46     \<comment>\<open>linear and wellfounded on \<open>A\<close>\<close>
    47     "wellordered(M,A,r) == 
    48         transitive_rel(M,A,r) & linear_rel(M,A,r) & wellfounded_on(M,A,r)"
    49 
    50 
    51 subsubsection \<open>Trivial absoluteness proofs\<close>
    52 
    53 lemma (in M_basic) irreflexive_abs [simp]: 
    54      "M(A) ==> irreflexive(M,A,r) \<longleftrightarrow> irrefl(A,r)"
    55 by (simp add: irreflexive_def irrefl_def)
    56 
    57 lemma (in M_basic) transitive_rel_abs [simp]: 
    58      "M(A) ==> transitive_rel(M,A,r) \<longleftrightarrow> trans[A](r)"
    59 by (simp add: transitive_rel_def trans_on_def)
    60 
    61 lemma (in M_basic) linear_rel_abs [simp]: 
    62      "M(A) ==> linear_rel(M,A,r) \<longleftrightarrow> linear(A,r)"
    63 by (simp add: linear_rel_def linear_def)
    64 
    65 lemma (in M_basic) wellordered_is_trans_on: 
    66     "[| wellordered(M,A,r); M(A) |] ==> trans[A](r)"
    67 by (auto simp add: wellordered_def)
    68 
    69 lemma (in M_basic) wellordered_is_linear: 
    70     "[| wellordered(M,A,r); M(A) |] ==> linear(A,r)"
    71 by (auto simp add: wellordered_def)
    72 
    73 lemma (in M_basic) wellordered_is_wellfounded_on: 
    74     "[| wellordered(M,A,r); M(A) |] ==> wellfounded_on(M,A,r)"
    75 by (auto simp add: wellordered_def)
    76 
    77 lemma (in M_basic) wellfounded_imp_wellfounded_on: 
    78     "[| wellfounded(M,r); M(A) |] ==> wellfounded_on(M,A,r)"
    79 by (auto simp add: wellfounded_def wellfounded_on_def)
    80 
    81 lemma (in M_basic) wellfounded_on_subset_A:
    82      "[| wellfounded_on(M,A,r);  B<=A |] ==> wellfounded_on(M,B,r)"
    83 by (simp add: wellfounded_on_def, blast)
    84 
    85 
    86 subsubsection \<open>Well-founded relations\<close>
    87 
    88 lemma  (in M_basic) wellfounded_on_iff_wellfounded:
    89      "wellfounded_on(M,A,r) \<longleftrightarrow> wellfounded(M, r \<inter> A*A)"
    90 apply (simp add: wellfounded_on_def wellfounded_def, safe)
    91  apply force
    92 apply (drule_tac x=x in rspec, assumption, blast) 
    93 done
    94 
    95 lemma (in M_basic) wellfounded_on_imp_wellfounded:
    96      "[|wellfounded_on(M,A,r); r \<subseteq> A*A|] ==> wellfounded(M,r)"
    97 by (simp add: wellfounded_on_iff_wellfounded subset_Int_iff)
    98 
    99 lemma (in M_basic) wellfounded_on_field_imp_wellfounded:
   100      "wellfounded_on(M, field(r), r) ==> wellfounded(M,r)"
   101 by (simp add: wellfounded_def wellfounded_on_iff_wellfounded, fast)
   102 
   103 lemma (in M_basic) wellfounded_iff_wellfounded_on_field:
   104      "M(r) ==> wellfounded(M,r) \<longleftrightarrow> wellfounded_on(M, field(r), r)"
   105 by (blast intro: wellfounded_imp_wellfounded_on
   106                  wellfounded_on_field_imp_wellfounded)
   107 
   108 (*Consider the least z in domain(r) such that P(z) does not hold...*)
   109 lemma (in M_basic) wellfounded_induct: 
   110      "[| wellfounded(M,r); M(a); M(r); separation(M, \<lambda>x. ~P(x));  
   111          \<forall>x. M(x) & (\<forall>y. <y,x> \<in> r \<longrightarrow> P(y)) \<longrightarrow> P(x) |]
   112       ==> P(a)"
   113 apply (simp (no_asm_use) add: wellfounded_def)
   114 apply (drule_tac x="{z \<in> domain(r). ~P(z)}" in rspec)
   115 apply (blast dest: transM)+
   116 done
   117 
   118 lemma (in M_basic) wellfounded_on_induct: 
   119      "[| a\<in>A;  wellfounded_on(M,A,r);  M(A);  
   120        separation(M, \<lambda>x. x\<in>A \<longrightarrow> ~P(x));  
   121        \<forall>x\<in>A. M(x) & (\<forall>y\<in>A. <y,x> \<in> r \<longrightarrow> P(y)) \<longrightarrow> P(x) |]
   122       ==> P(a)"
   123 apply (simp (no_asm_use) add: wellfounded_on_def)
   124 apply (drule_tac x="{z\<in>A. z\<in>A \<longrightarrow> ~P(z)}" in rspec)
   125 apply (blast intro: transM)+
   126 done
   127 
   128 
   129 subsubsection \<open>Kunen's lemma IV 3.14, page 123\<close>
   130 
   131 lemma (in M_basic) linear_imp_relativized: 
   132      "linear(A,r) ==> linear_rel(M,A,r)" 
   133 by (simp add: linear_def linear_rel_def) 
   134 
   135 lemma (in M_basic) trans_on_imp_relativized: 
   136      "trans[A](r) ==> transitive_rel(M,A,r)" 
   137 by (unfold transitive_rel_def trans_on_def, blast) 
   138 
   139 lemma (in M_basic) wf_on_imp_relativized: 
   140      "wf[A](r) ==> wellfounded_on(M,A,r)" 
   141 apply (simp add: wellfounded_on_def wf_def wf_on_def, clarify) 
   142 apply (drule_tac x=x in spec, blast) 
   143 done
   144 
   145 lemma (in M_basic) wf_imp_relativized: 
   146      "wf(r) ==> wellfounded(M,r)" 
   147 apply (simp add: wellfounded_def wf_def, clarify) 
   148 apply (drule_tac x=x in spec, blast) 
   149 done
   150 
   151 lemma (in M_basic) well_ord_imp_relativized: 
   152      "well_ord(A,r) ==> wellordered(M,A,r)" 
   153 by (simp add: wellordered_def well_ord_def tot_ord_def part_ord_def
   154        linear_imp_relativized trans_on_imp_relativized wf_on_imp_relativized)
   155 
   156 text\<open>The property being well founded (and hence of being well ordered) is not absolute: 
   157 the set that doesn't contain a minimal element may not exist in the class M. 
   158 However, every set that is well founded in a transitive model M is well founded (page 124).\<close>
   159 
   160 subsection\<open>Relativized versions of order-isomorphisms and order types\<close>
   161 
   162 lemma (in M_basic) order_isomorphism_abs [simp]: 
   163      "[| M(A); M(B); M(f) |] 
   164       ==> order_isomorphism(M,A,r,B,s,f) \<longleftrightarrow> f \<in> ord_iso(A,r,B,s)"
   165 by (simp add: apply_closed order_isomorphism_def ord_iso_def)
   166 
   167 lemma (in M_basic) pred_set_abs [simp]: 
   168      "[| M(r); M(B) |] ==> pred_set(M,A,x,r,B) \<longleftrightarrow> B = Order.pred(A,x,r)"
   169 apply (simp add: pred_set_def Order.pred_def)
   170 apply (blast dest: transM) 
   171 done
   172 
   173 lemma (in M_basic) pred_closed [intro,simp]: 
   174      "[| M(A); M(r); M(x) |] ==> M(Order.pred(A,x,r))"
   175 apply (simp add: Order.pred_def) 
   176 apply (insert pred_separation [of r x], simp) 
   177 done
   178 
   179 lemma (in M_basic) membership_abs [simp]: 
   180      "[| M(r); M(A) |] ==> membership(M,A,r) \<longleftrightarrow> r = Memrel(A)"
   181 apply (simp add: membership_def Memrel_def, safe)
   182   apply (rule equalityI) 
   183    apply clarify 
   184    apply (frule transM, assumption)
   185    apply blast
   186   apply clarify 
   187   apply (subgoal_tac "M(<xb,ya>)", blast) 
   188   apply (blast dest: transM) 
   189  apply auto 
   190 done
   191 
   192 lemma (in M_basic) M_Memrel_iff:
   193      "M(A) ==> 
   194       Memrel(A) = {z \<in> A*A. \<exists>x[M]. \<exists>y[M]. z = \<langle>x,y\<rangle> & x \<in> y}"
   195 apply (simp add: Memrel_def) 
   196 apply (blast dest: transM)
   197 done 
   198 
   199 lemma (in M_basic) Memrel_closed [intro,simp]: 
   200      "M(A) ==> M(Memrel(A))"
   201 apply (simp add: M_Memrel_iff) 
   202 apply (insert Memrel_separation, simp)
   203 done
   204 
   205 
   206 subsection \<open>Main results of Kunen, Chapter 1 section 6\<close>
   207 
   208 text\<open>Subset properties-- proved outside the locale\<close>
   209 
   210 lemma linear_rel_subset: 
   211     "[| linear_rel(M,A,r);  B<=A |] ==> linear_rel(M,B,r)"
   212 by (unfold linear_rel_def, blast)
   213 
   214 lemma transitive_rel_subset: 
   215     "[| transitive_rel(M,A,r);  B<=A |] ==> transitive_rel(M,B,r)"
   216 by (unfold transitive_rel_def, blast)
   217 
   218 lemma wellfounded_on_subset: 
   219     "[| wellfounded_on(M,A,r);  B<=A |] ==> wellfounded_on(M,B,r)"
   220 by (unfold wellfounded_on_def subset_def, blast)
   221 
   222 lemma wellordered_subset: 
   223     "[| wellordered(M,A,r);  B<=A |] ==> wellordered(M,B,r)"
   224 apply (unfold wellordered_def)
   225 apply (blast intro: linear_rel_subset transitive_rel_subset 
   226                     wellfounded_on_subset)
   227 done
   228 
   229 lemma (in M_basic) wellfounded_on_asym:
   230      "[| wellfounded_on(M,A,r);  <a,x>\<in>r;  a\<in>A; x\<in>A;  M(A) |] ==> <x,a>\<notin>r"
   231 apply (simp add: wellfounded_on_def) 
   232 apply (drule_tac x="{x,a}" in rspec) 
   233 apply (blast dest: transM)+
   234 done
   235 
   236 lemma (in M_basic) wellordered_asym:
   237      "[| wellordered(M,A,r);  <a,x>\<in>r;  a\<in>A; x\<in>A;  M(A) |] ==> <x,a>\<notin>r"
   238 by (simp add: wellordered_def, blast dest: wellfounded_on_asym)
   239 
   240 end