src/HOL/Lifting.thy
 author hoelzl Fri Feb 19 13:40:50 2016 +0100 (2016-02-19) changeset 62378 85ed00c1fe7c parent 61799 4cf66f21b764 child 63092 a949b2a5f51d permissions -rw-r--r--
generalize more theorems to support enat and ennreal
1 (*  Title:      HOL/Lifting.thy
2     Author:     Brian Huffman and Ondrej Kuncar
3     Author:     Cezary Kaliszyk and Christian Urban
4 *)
6 section \<open>Lifting package\<close>
8 theory Lifting
9 imports Equiv_Relations Transfer
10 keywords
11   "parametric" and
12   "print_quot_maps" "print_quotients" :: diag and
13   "lift_definition" :: thy_goal and
14   "setup_lifting" "lifting_forget" "lifting_update" :: thy_decl
15 begin
17 subsection \<open>Function map\<close>
19 context
20 begin
21 interpretation lifting_syntax .
23 lemma map_fun_id:
24   "(id ---> id) = id"
25   by (simp add: fun_eq_iff)
27 subsection \<open>Quotient Predicate\<close>
29 definition
30   "Quotient R Abs Rep T \<longleftrightarrow>
31      (\<forall>a. Abs (Rep a) = a) \<and>
32      (\<forall>a. R (Rep a) (Rep a)) \<and>
33      (\<forall>r s. R r s \<longleftrightarrow> R r r \<and> R s s \<and> Abs r = Abs s) \<and>
34      T = (\<lambda>x y. R x x \<and> Abs x = y)"
36 lemma QuotientI:
37   assumes "\<And>a. Abs (Rep a) = a"
38     and "\<And>a. R (Rep a) (Rep a)"
39     and "\<And>r s. R r s \<longleftrightarrow> R r r \<and> R s s \<and> Abs r = Abs s"
40     and "T = (\<lambda>x y. R x x \<and> Abs x = y)"
41   shows "Quotient R Abs Rep T"
42   using assms unfolding Quotient_def by blast
44 context
45   fixes R Abs Rep T
46   assumes a: "Quotient R Abs Rep T"
47 begin
49 lemma Quotient_abs_rep: "Abs (Rep a) = a"
50   using a unfolding Quotient_def
51   by simp
53 lemma Quotient_rep_reflp: "R (Rep a) (Rep a)"
54   using a unfolding Quotient_def
55   by blast
57 lemma Quotient_rel:
58   "R r r \<and> R s s \<and> Abs r = Abs s \<longleftrightarrow> R r s" \<comment> \<open>orientation does not loop on rewriting\<close>
59   using a unfolding Quotient_def
60   by blast
62 lemma Quotient_cr_rel: "T = (\<lambda>x y. R x x \<and> Abs x = y)"
63   using a unfolding Quotient_def
64   by blast
66 lemma Quotient_refl1: "R r s \<Longrightarrow> R r r"
67   using a unfolding Quotient_def
68   by fast
70 lemma Quotient_refl2: "R r s \<Longrightarrow> R s s"
71   using a unfolding Quotient_def
72   by fast
74 lemma Quotient_rel_rep: "R (Rep a) (Rep b) \<longleftrightarrow> a = b"
75   using a unfolding Quotient_def
76   by metis
78 lemma Quotient_rep_abs: "R r r \<Longrightarrow> R (Rep (Abs r)) r"
79   using a unfolding Quotient_def
80   by blast
82 lemma Quotient_rep_abs_eq: "R t t \<Longrightarrow> R \<le> op= \<Longrightarrow> Rep (Abs t) = t"
83   using a unfolding Quotient_def
84   by blast
86 lemma Quotient_rep_abs_fold_unmap:
87   assumes "x' \<equiv> Abs x" and "R x x" and "Rep x' \<equiv> Rep' x'"
88   shows "R (Rep' x') x"
89 proof -
90   have "R (Rep x') x" using assms(1-2) Quotient_rep_abs by auto
91   then show ?thesis using assms(3) by simp
92 qed
94 lemma Quotient_Rep_eq:
95   assumes "x' \<equiv> Abs x"
96   shows "Rep x' \<equiv> Rep x'"
97 by simp
99 lemma Quotient_rel_abs: "R r s \<Longrightarrow> Abs r = Abs s"
100   using a unfolding Quotient_def
101   by blast
103 lemma Quotient_rel_abs2:
104   assumes "R (Rep x) y"
105   shows "x = Abs y"
106 proof -
107   from assms have "Abs (Rep x) = Abs y" by (auto intro: Quotient_rel_abs)
108   then show ?thesis using assms(1) by (simp add: Quotient_abs_rep)
109 qed
111 lemma Quotient_symp: "symp R"
112   using a unfolding Quotient_def using sympI by (metis (full_types))
114 lemma Quotient_transp: "transp R"
115   using a unfolding Quotient_def using transpI by (metis (full_types))
117 lemma Quotient_part_equivp: "part_equivp R"
118 by (metis Quotient_rep_reflp Quotient_symp Quotient_transp part_equivpI)
120 end
122 lemma identity_quotient: "Quotient (op =) id id (op =)"
123 unfolding Quotient_def by simp
125 text \<open>TODO: Use one of these alternatives as the real definition.\<close>
127 lemma Quotient_alt_def:
128   "Quotient R Abs Rep T \<longleftrightarrow>
129     (\<forall>a b. T a b \<longrightarrow> Abs a = b) \<and>
130     (\<forall>b. T (Rep b) b) \<and>
131     (\<forall>x y. R x y \<longleftrightarrow> T x (Abs x) \<and> T y (Abs y) \<and> Abs x = Abs y)"
132 apply safe
133 apply (simp (no_asm_use) only: Quotient_def, fast)
134 apply (simp (no_asm_use) only: Quotient_def, fast)
135 apply (simp (no_asm_use) only: Quotient_def, fast)
136 apply (simp (no_asm_use) only: Quotient_def, fast)
137 apply (simp (no_asm_use) only: Quotient_def, fast)
138 apply (simp (no_asm_use) only: Quotient_def, fast)
139 apply (rule QuotientI)
140 apply simp
141 apply metis
142 apply simp
143 apply (rule ext, rule ext, metis)
144 done
146 lemma Quotient_alt_def2:
147   "Quotient R Abs Rep T \<longleftrightarrow>
148     (\<forall>a b. T a b \<longrightarrow> Abs a = b) \<and>
149     (\<forall>b. T (Rep b) b) \<and>
150     (\<forall>x y. R x y \<longleftrightarrow> T x (Abs y) \<and> T y (Abs x))"
151   unfolding Quotient_alt_def by (safe, metis+)
153 lemma Quotient_alt_def3:
154   "Quotient R Abs Rep T \<longleftrightarrow>
155     (\<forall>a b. T a b \<longrightarrow> Abs a = b) \<and> (\<forall>b. T (Rep b) b) \<and>
156     (\<forall>x y. R x y \<longleftrightarrow> (\<exists>z. T x z \<and> T y z))"
157   unfolding Quotient_alt_def2 by (safe, metis+)
159 lemma Quotient_alt_def4:
160   "Quotient R Abs Rep T \<longleftrightarrow>
161     (\<forall>a b. T a b \<longrightarrow> Abs a = b) \<and> (\<forall>b. T (Rep b) b) \<and> R = T OO conversep T"
162   unfolding Quotient_alt_def3 fun_eq_iff by auto
164 lemma Quotient_alt_def5:
165   "Quotient R Abs Rep T \<longleftrightarrow>
166     T \<le> BNF_Def.Grp UNIV Abs \<and> BNF_Def.Grp UNIV Rep \<le> T\<inverse>\<inverse> \<and> R = T OO T\<inverse>\<inverse>"
167   unfolding Quotient_alt_def4 Grp_def by blast
169 lemma fun_quotient:
170   assumes 1: "Quotient R1 abs1 rep1 T1"
171   assumes 2: "Quotient R2 abs2 rep2 T2"
172   shows "Quotient (R1 ===> R2) (rep1 ---> abs2) (abs1 ---> rep2) (T1 ===> T2)"
173   using assms unfolding Quotient_alt_def2
174   unfolding rel_fun_def fun_eq_iff map_fun_apply
175   by (safe, metis+)
177 lemma apply_rsp:
178   fixes f g::"'a \<Rightarrow> 'c"
179   assumes q: "Quotient R1 Abs1 Rep1 T1"
180   and     a: "(R1 ===> R2) f g" "R1 x y"
181   shows "R2 (f x) (g y)"
182   using a by (auto elim: rel_funE)
184 lemma apply_rsp':
185   assumes a: "(R1 ===> R2) f g" "R1 x y"
186   shows "R2 (f x) (g y)"
187   using a by (auto elim: rel_funE)
189 lemma apply_rsp'':
190   assumes "Quotient R Abs Rep T"
191   and "(R ===> S) f f"
192   shows "S (f (Rep x)) (f (Rep x))"
193 proof -
194   from assms(1) have "R (Rep x) (Rep x)" by (rule Quotient_rep_reflp)
195   then show ?thesis using assms(2) by (auto intro: apply_rsp')
196 qed
198 subsection \<open>Quotient composition\<close>
200 lemma Quotient_compose:
201   assumes 1: "Quotient R1 Abs1 Rep1 T1"
202   assumes 2: "Quotient R2 Abs2 Rep2 T2"
203   shows "Quotient (T1 OO R2 OO conversep T1) (Abs2 \<circ> Abs1) (Rep1 \<circ> Rep2) (T1 OO T2)"
204   using assms unfolding Quotient_alt_def4 by fastforce
206 lemma equivp_reflp2:
207   "equivp R \<Longrightarrow> reflp R"
208   by (erule equivpE)
210 subsection \<open>Respects predicate\<close>
212 definition Respects :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> 'a set"
213   where "Respects R = {x. R x x}"
215 lemma in_respects: "x \<in> Respects R \<longleftrightarrow> R x x"
216   unfolding Respects_def by simp
218 lemma UNIV_typedef_to_Quotient:
219   assumes "type_definition Rep Abs UNIV"
220   and T_def: "T \<equiv> (\<lambda>x y. x = Rep y)"
221   shows "Quotient (op =) Abs Rep T"
222 proof -
223   interpret type_definition Rep Abs UNIV by fact
224   from Abs_inject Rep_inverse Abs_inverse T_def show ?thesis
225     by (fastforce intro!: QuotientI fun_eq_iff)
226 qed
228 lemma UNIV_typedef_to_equivp:
229   fixes Abs :: "'a \<Rightarrow> 'b"
230   and Rep :: "'b \<Rightarrow> 'a"
231   assumes "type_definition Rep Abs (UNIV::'a set)"
232   shows "equivp (op=::'a\<Rightarrow>'a\<Rightarrow>bool)"
233 by (rule identity_equivp)
235 lemma typedef_to_Quotient:
236   assumes "type_definition Rep Abs S"
237   and T_def: "T \<equiv> (\<lambda>x y. x = Rep y)"
238   shows "Quotient (eq_onp (\<lambda>x. x \<in> S)) Abs Rep T"
239 proof -
240   interpret type_definition Rep Abs S by fact
241   from Rep Abs_inject Rep_inverse Abs_inverse T_def show ?thesis
242     by (auto intro!: QuotientI simp: eq_onp_def fun_eq_iff)
243 qed
245 lemma typedef_to_part_equivp:
246   assumes "type_definition Rep Abs S"
247   shows "part_equivp (eq_onp (\<lambda>x. x \<in> S))"
248 proof (intro part_equivpI)
249   interpret type_definition Rep Abs S by fact
250   show "\<exists>x. eq_onp (\<lambda>x. x \<in> S) x x" using Rep by (auto simp: eq_onp_def)
251 next
252   show "symp (eq_onp (\<lambda>x. x \<in> S))" by (auto intro: sympI simp: eq_onp_def)
253 next
254   show "transp (eq_onp (\<lambda>x. x \<in> S))" by (auto intro: transpI simp: eq_onp_def)
255 qed
257 lemma open_typedef_to_Quotient:
258   assumes "type_definition Rep Abs {x. P x}"
259   and T_def: "T \<equiv> (\<lambda>x y. x = Rep y)"
260   shows "Quotient (eq_onp P) Abs Rep T"
261   using typedef_to_Quotient [OF assms] by simp
263 lemma open_typedef_to_part_equivp:
264   assumes "type_definition Rep Abs {x. P x}"
265   shows "part_equivp (eq_onp P)"
266   using typedef_to_part_equivp [OF assms] by simp
268 lemma type_definition_Quotient_not_empty: "Quotient (eq_onp P) Abs Rep T \<Longrightarrow> \<exists>x. P x"
269 unfolding eq_onp_def by (drule Quotient_rep_reflp) blast
271 lemma type_definition_Quotient_not_empty_witness: "Quotient (eq_onp P) Abs Rep T \<Longrightarrow> P (Rep undefined)"
272 unfolding eq_onp_def by (drule Quotient_rep_reflp) blast
275 text \<open>Generating transfer rules for quotients.\<close>
277 context
278   fixes R Abs Rep T
279   assumes 1: "Quotient R Abs Rep T"
280 begin
282 lemma Quotient_right_unique: "right_unique T"
283   using 1 unfolding Quotient_alt_def right_unique_def by metis
285 lemma Quotient_right_total: "right_total T"
286   using 1 unfolding Quotient_alt_def right_total_def by metis
288 lemma Quotient_rel_eq_transfer: "(T ===> T ===> op =) R (op =)"
289   using 1 unfolding Quotient_alt_def rel_fun_def by simp
291 lemma Quotient_abs_induct:
292   assumes "\<And>y. R y y \<Longrightarrow> P (Abs y)" shows "P x"
293   using 1 assms unfolding Quotient_def by metis
295 end
297 text \<open>Generating transfer rules for total quotients.\<close>
299 context
300   fixes R Abs Rep T
301   assumes 1: "Quotient R Abs Rep T" and 2: "reflp R"
302 begin
304 lemma Quotient_left_total: "left_total T"
305   using 1 2 unfolding Quotient_alt_def left_total_def reflp_def by auto
307 lemma Quotient_bi_total: "bi_total T"
308   using 1 2 unfolding Quotient_alt_def bi_total_def reflp_def by auto
310 lemma Quotient_id_abs_transfer: "(op = ===> T) (\<lambda>x. x) Abs"
311   using 1 2 unfolding Quotient_alt_def reflp_def rel_fun_def by simp
313 lemma Quotient_total_abs_induct: "(\<And>y. P (Abs y)) \<Longrightarrow> P x"
314   using 1 2 assms unfolding Quotient_alt_def reflp_def by metis
316 lemma Quotient_total_abs_eq_iff: "Abs x = Abs y \<longleftrightarrow> R x y"
317   using Quotient_rel [OF 1] 2 unfolding reflp_def by simp
319 end
321 text \<open>Generating transfer rules for a type defined with \<open>typedef\<close>.\<close>
323 context
324   fixes Rep Abs A T
325   assumes type: "type_definition Rep Abs A"
326   assumes T_def: "T \<equiv> (\<lambda>(x::'a) (y::'b). x = Rep y)"
327 begin
329 lemma typedef_left_unique: "left_unique T"
330   unfolding left_unique_def T_def
331   by (simp add: type_definition.Rep_inject [OF type])
333 lemma typedef_bi_unique: "bi_unique T"
334   unfolding bi_unique_def T_def
335   by (simp add: type_definition.Rep_inject [OF type])
337 (* the following two theorems are here only for convinience *)
339 lemma typedef_right_unique: "right_unique T"
340   using T_def type Quotient_right_unique typedef_to_Quotient
341   by blast
343 lemma typedef_right_total: "right_total T"
344   using T_def type Quotient_right_total typedef_to_Quotient
345   by blast
347 lemma typedef_rep_transfer: "(T ===> op =) (\<lambda>x. x) Rep"
348   unfolding rel_fun_def T_def by simp
350 end
352 text \<open>Generating the correspondence rule for a constant defined with
353   \<open>lift_definition\<close>.\<close>
355 lemma Quotient_to_transfer:
356   assumes "Quotient R Abs Rep T" and "R c c" and "c' \<equiv> Abs c"
357   shows "T c c'"
358   using assms by (auto dest: Quotient_cr_rel)
360 text \<open>Proving reflexivity\<close>
362 lemma Quotient_to_left_total:
363   assumes q: "Quotient R Abs Rep T"
364   and r_R: "reflp R"
365   shows "left_total T"
366 using r_R Quotient_cr_rel[OF q] unfolding left_total_def by (auto elim: reflpE)
368 lemma Quotient_composition_ge_eq:
369   assumes "left_total T"
370   assumes "R \<ge> op="
371   shows "(T OO R OO T\<inverse>\<inverse>) \<ge> op="
372 using assms unfolding left_total_def by fast
374 lemma Quotient_composition_le_eq:
375   assumes "left_unique T"
376   assumes "R \<le> op="
377   shows "(T OO R OO T\<inverse>\<inverse>) \<le> op="
378 using assms unfolding left_unique_def by blast
380 lemma eq_onp_le_eq:
381   "eq_onp P \<le> op=" unfolding eq_onp_def by blast
383 lemma reflp_ge_eq:
384   "reflp R \<Longrightarrow> R \<ge> op=" unfolding reflp_def by blast
386 text \<open>Proving a parametrized correspondence relation\<close>
388 definition POS :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool" where
389 "POS A B \<equiv> A \<le> B"
391 definition  NEG :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool" where
392 "NEG A B \<equiv> B \<le> A"
394 lemma pos_OO_eq:
395   shows "POS (A OO op=) A"
396 unfolding POS_def OO_def by blast
398 lemma pos_eq_OO:
399   shows "POS (op= OO A) A"
400 unfolding POS_def OO_def by blast
402 lemma neg_OO_eq:
403   shows "NEG (A OO op=) A"
404 unfolding NEG_def OO_def by auto
406 lemma neg_eq_OO:
407   shows "NEG (op= OO A) A"
408 unfolding NEG_def OO_def by blast
410 lemma POS_trans:
411   assumes "POS A B"
412   assumes "POS B C"
413   shows "POS A C"
414 using assms unfolding POS_def by auto
416 lemma NEG_trans:
417   assumes "NEG A B"
418   assumes "NEG B C"
419   shows "NEG A C"
420 using assms unfolding NEG_def by auto
422 lemma POS_NEG:
423   "POS A B \<equiv> NEG B A"
424   unfolding POS_def NEG_def by auto
426 lemma NEG_POS:
427   "NEG A B \<equiv> POS B A"
428   unfolding POS_def NEG_def by auto
430 lemma POS_pcr_rule:
431   assumes "POS (A OO B) C"
432   shows "POS (A OO B OO X) (C OO X)"
433 using assms unfolding POS_def OO_def by blast
435 lemma NEG_pcr_rule:
436   assumes "NEG (A OO B) C"
437   shows "NEG (A OO B OO X) (C OO X)"
438 using assms unfolding NEG_def OO_def by blast
440 lemma POS_apply:
441   assumes "POS R R'"
442   assumes "R f g"
443   shows "R' f g"
444 using assms unfolding POS_def by auto
446 text \<open>Proving a parametrized correspondence relation\<close>
448 lemma fun_mono:
449   assumes "A \<ge> C"
450   assumes "B \<le> D"
451   shows   "(A ===> B) \<le> (C ===> D)"
452 using assms unfolding rel_fun_def by blast
454 lemma pos_fun_distr: "((R ===> S) OO (R' ===> S')) \<le> ((R OO R') ===> (S OO S'))"
455 unfolding OO_def rel_fun_def by blast
457 lemma functional_relation: "right_unique R \<Longrightarrow> left_total R \<Longrightarrow> \<forall>x. \<exists>!y. R x y"
458 unfolding right_unique_def left_total_def by blast
460 lemma functional_converse_relation: "left_unique R \<Longrightarrow> right_total R \<Longrightarrow> \<forall>y. \<exists>!x. R x y"
461 unfolding left_unique_def right_total_def by blast
463 lemma neg_fun_distr1:
464 assumes 1: "left_unique R" "right_total R"
465 assumes 2: "right_unique R'" "left_total R'"
466 shows "(R OO R' ===> S OO S') \<le> ((R ===> S) OO (R' ===> S')) "
467   using functional_relation[OF 2] functional_converse_relation[OF 1]
468   unfolding rel_fun_def OO_def
469   apply clarify
470   apply (subst all_comm)
471   apply (subst all_conj_distrib[symmetric])
472   apply (intro choice)
473   by metis
475 lemma neg_fun_distr2:
476 assumes 1: "right_unique R'" "left_total R'"
477 assumes 2: "left_unique S'" "right_total S'"
478 shows "(R OO R' ===> S OO S') \<le> ((R ===> S) OO (R' ===> S'))"
479   using functional_converse_relation[OF 2] functional_relation[OF 1]
480   unfolding rel_fun_def OO_def
481   apply clarify
482   apply (subst all_comm)
483   apply (subst all_conj_distrib[symmetric])
484   apply (intro choice)
485   by metis
487 subsection \<open>Domains\<close>
489 lemma composed_equiv_rel_eq_onp:
490   assumes "left_unique R"
491   assumes "(R ===> op=) P P'"
492   assumes "Domainp R = P''"
493   shows "(R OO eq_onp P' OO R\<inverse>\<inverse>) = eq_onp (inf P'' P)"
494 using assms unfolding OO_def conversep_iff Domainp_iff[abs_def] left_unique_def rel_fun_def eq_onp_def
495 fun_eq_iff by blast
497 lemma composed_equiv_rel_eq_eq_onp:
498   assumes "left_unique R"
499   assumes "Domainp R = P"
500   shows "(R OO op= OO R\<inverse>\<inverse>) = eq_onp P"
501 using assms unfolding OO_def conversep_iff Domainp_iff[abs_def] left_unique_def eq_onp_def
502 fun_eq_iff is_equality_def by metis
504 lemma pcr_Domainp_par_left_total:
505   assumes "Domainp B = P"
506   assumes "left_total A"
507   assumes "(A ===> op=) P' P"
508   shows "Domainp (A OO B) = P'"
509 using assms
510 unfolding Domainp_iff[abs_def] OO_def bi_unique_def left_total_def rel_fun_def
511 by (fast intro: fun_eq_iff)
513 lemma pcr_Domainp_par:
514 assumes "Domainp B = P2"
515 assumes "Domainp A = P1"
516 assumes "(A ===> op=) P2' P2"
517 shows "Domainp (A OO B) = (inf P1 P2')"
518 using assms unfolding rel_fun_def Domainp_iff[abs_def] OO_def
519 by (fast intro: fun_eq_iff)
521 definition rel_pred_comp :: "('a => 'b => bool) => ('b => bool) => 'a => bool"
522 where "rel_pred_comp R P \<equiv> \<lambda>x. \<exists>y. R x y \<and> P y"
524 lemma pcr_Domainp:
525 assumes "Domainp B = P"
526 shows "Domainp (A OO B) = (\<lambda>x. \<exists>y. A x y \<and> P y)"
527 using assms by blast
529 lemma pcr_Domainp_total:
530   assumes "left_total B"
531   assumes "Domainp A = P"
532   shows "Domainp (A OO B) = P"
533 using assms unfolding left_total_def
534 by fast
536 lemma Quotient_to_Domainp:
537   assumes "Quotient R Abs Rep T"
538   shows "Domainp T = (\<lambda>x. R x x)"
539 by (simp add: Domainp_iff[abs_def] Quotient_cr_rel[OF assms])
541 lemma eq_onp_to_Domainp:
542   assumes "Quotient (eq_onp P) Abs Rep T"
543   shows "Domainp T = P"
544 by (simp add: eq_onp_def Domainp_iff[abs_def] Quotient_cr_rel[OF assms])
546 end
548 (* needed for lifting_def_code_dt.ML (moved from Lifting_Set) *)
549 lemma right_total_UNIV_transfer:
550   assumes "right_total A"
551   shows "(rel_set A) (Collect (Domainp A)) UNIV"
552   using assms unfolding right_total_def rel_set_def Domainp_iff by blast
554 subsection \<open>ML setup\<close>
556 ML_file "Tools/Lifting/lifting_util.ML"
558 named_theorems relator_eq_onp
559   "theorems that a relator of an eq_onp is an eq_onp of the corresponding predicate"
560 ML_file "Tools/Lifting/lifting_info.ML"
562 (* setup for the function type *)
563 declare fun_quotient[quot_map]
564 declare fun_mono[relator_mono]
565 lemmas [relator_distr] = pos_fun_distr neg_fun_distr1 neg_fun_distr2
567 ML_file "Tools/Lifting/lifting_bnf.ML"
568 ML_file "Tools/Lifting/lifting_term.ML"
569 ML_file "Tools/Lifting/lifting_def.ML"
570 ML_file "Tools/Lifting/lifting_setup.ML"
571 ML_file "Tools/Lifting/lifting_def_code_dt.ML"
573 lemma pred_prod_beta: "pred_prod P Q xy \<longleftrightarrow> P (fst xy) \<and> Q (snd xy)"
574 by(cases xy) simp
576 lemma pred_prod_split: "P (pred_prod Q R xy) \<longleftrightarrow> (\<forall>x y. xy = (x, y) \<longrightarrow> P (Q x \<and> R y))"
577 by(cases xy) simp
579 hide_const (open) POS NEG
581 end