src/HOL/Map.thy
author hoelzl
Fri Feb 19 13:40:50 2016 +0100 (2016-02-19)
changeset 62378 85ed00c1fe7c
parent 61955 e96292f32c3c
child 62390 842917225d56
permissions -rw-r--r--
generalize more theorems to support enat and ennreal
     1 (*  Title:      HOL/Map.thy
     2     Author:     Tobias Nipkow, based on a theory by David von Oheimb
     3     Copyright   1997-2003 TU Muenchen
     4 
     5 The datatype of "maps"; strongly resembles maps in VDM.
     6 *)
     7 
     8 section \<open>Maps\<close>
     9 
    10 theory Map
    11 imports List
    12 begin
    13 
    14 type_synonym ('a, 'b) "map" = "'a \<Rightarrow> 'b option" (infixr "\<rightharpoonup>" 0)
    15 
    16 abbreviation
    17   empty :: "'a \<rightharpoonup> 'b" where
    18   "empty \<equiv> \<lambda>x. None"
    19 
    20 definition
    21   map_comp :: "('b \<rightharpoonup> 'c) \<Rightarrow> ('a \<rightharpoonup> 'b) \<Rightarrow> ('a \<rightharpoonup> 'c)"  (infixl "\<circ>\<^sub>m" 55) where
    22   "f \<circ>\<^sub>m g = (\<lambda>k. case g k of None \<Rightarrow> None | Some v \<Rightarrow> f v)"
    23 
    24 definition
    25   map_add :: "('a \<rightharpoonup> 'b) \<Rightarrow> ('a \<rightharpoonup> 'b) \<Rightarrow> ('a \<rightharpoonup> 'b)"  (infixl "++" 100) where
    26   "m1 ++ m2 = (\<lambda>x. case m2 x of None \<Rightarrow> m1 x | Some y \<Rightarrow> Some y)"
    27 
    28 definition
    29   restrict_map :: "('a \<rightharpoonup> 'b) \<Rightarrow> 'a set \<Rightarrow> ('a \<rightharpoonup> 'b)"  (infixl "|`"  110) where
    30   "m|`A = (\<lambda>x. if x \<in> A then m x else None)"
    31 
    32 notation (latex output)
    33   restrict_map  ("_\<restriction>\<^bsub>_\<^esub>" [111,110] 110)
    34 
    35 definition
    36   dom :: "('a \<rightharpoonup> 'b) \<Rightarrow> 'a set" where
    37   "dom m = {a. m a \<noteq> None}"
    38 
    39 definition
    40   ran :: "('a \<rightharpoonup> 'b) \<Rightarrow> 'b set" where
    41   "ran m = {b. \<exists>a. m a = Some b}"
    42 
    43 definition
    44   map_le :: "('a \<rightharpoonup> 'b) \<Rightarrow> ('a \<rightharpoonup> 'b) \<Rightarrow> bool"  (infix "\<subseteq>\<^sub>m" 50) where
    45   "(m\<^sub>1 \<subseteq>\<^sub>m m\<^sub>2) \<longleftrightarrow> (\<forall>a \<in> dom m\<^sub>1. m\<^sub>1 a = m\<^sub>2 a)"
    46 
    47 nonterminal maplets and maplet
    48 
    49 syntax
    50   "_maplet"  :: "['a, 'a] \<Rightarrow> maplet"             ("_ /\<mapsto>/ _")
    51   "_maplets" :: "['a, 'a] \<Rightarrow> maplet"             ("_ /[\<mapsto>]/ _")
    52   ""         :: "maplet \<Rightarrow> maplets"             ("_")
    53   "_Maplets" :: "[maplet, maplets] \<Rightarrow> maplets" ("_,/ _")
    54   "_MapUpd"  :: "['a \<rightharpoonup> 'b, maplets] \<Rightarrow> 'a \<rightharpoonup> 'b" ("_/'(_')" [900, 0] 900)
    55   "_Map"     :: "maplets \<Rightarrow> 'a \<rightharpoonup> 'b"            ("(1[_])")
    56 
    57 syntax (ASCII)
    58   "_maplet"  :: "['a, 'a] \<Rightarrow> maplet"             ("_ /|->/ _")
    59   "_maplets" :: "['a, 'a] \<Rightarrow> maplet"             ("_ /[|->]/ _")
    60 
    61 translations
    62   "_MapUpd m (_Maplets xy ms)"  \<rightleftharpoons> "_MapUpd (_MapUpd m xy) ms"
    63   "_MapUpd m (_maplet  x y)"    \<rightleftharpoons> "m(x := CONST Some y)"
    64   "_Map ms"                     \<rightleftharpoons> "_MapUpd (CONST empty) ms"
    65   "_Map (_Maplets ms1 ms2)"     \<leftharpoondown> "_MapUpd (_Map ms1) ms2"
    66   "_Maplets ms1 (_Maplets ms2 ms3)" \<leftharpoondown> "_Maplets (_Maplets ms1 ms2) ms3"
    67 
    68 primrec map_of :: "('a \<times> 'b) list \<Rightarrow> 'a \<rightharpoonup> 'b"
    69 where
    70   "map_of [] = empty"
    71 | "map_of (p # ps) = (map_of ps)(fst p \<mapsto> snd p)"
    72 
    73 definition map_upds :: "('a \<rightharpoonup> 'b) \<Rightarrow> 'a list \<Rightarrow> 'b list \<Rightarrow> 'a \<rightharpoonup> 'b"
    74   where "map_upds m xs ys = m ++ map_of (rev (zip xs ys))"
    75 translations
    76   "_MapUpd m (_maplets x y)" \<rightleftharpoons> "CONST map_upds m x y"
    77 
    78 lemma map_of_Cons_code [code]:
    79   "map_of [] k = None"
    80   "map_of ((l, v) # ps) k = (if l = k then Some v else map_of ps k)"
    81   by simp_all
    82 
    83 
    84 subsection \<open>@{term [source] empty}\<close>
    85 
    86 lemma empty_upd_none [simp]: "empty(x := None) = empty"
    87   by (rule ext) simp
    88 
    89 
    90 subsection \<open>@{term [source] map_upd}\<close>
    91 
    92 lemma map_upd_triv: "t k = Some x \<Longrightarrow> t(k\<mapsto>x) = t"
    93   by (rule ext) simp
    94 
    95 lemma map_upd_nonempty [simp]: "t(k\<mapsto>x) \<noteq> empty"
    96 proof
    97   assume "t(k \<mapsto> x) = empty"
    98   then have "(t(k \<mapsto> x)) k = None" by simp
    99   then show False by simp
   100 qed
   101 
   102 lemma map_upd_eqD1:
   103   assumes "m(a\<mapsto>x) = n(a\<mapsto>y)"
   104   shows "x = y"
   105 proof -
   106   from assms have "(m(a\<mapsto>x)) a = (n(a\<mapsto>y)) a" by simp
   107   then show ?thesis by simp
   108 qed
   109 
   110 lemma map_upd_Some_unfold:
   111   "((m(a\<mapsto>b)) x = Some y) = (x = a \<and> b = y \<or> x \<noteq> a \<and> m x = Some y)"
   112 by auto
   113 
   114 lemma image_map_upd [simp]: "x \<notin> A \<Longrightarrow> m(x \<mapsto> y) ` A = m ` A"
   115 by auto
   116 
   117 lemma finite_range_updI: "finite (range f) \<Longrightarrow> finite (range (f(a\<mapsto>b)))"
   118 unfolding image_def
   119 apply (simp (no_asm_use) add:full_SetCompr_eq)
   120 apply (rule finite_subset)
   121  prefer 2 apply assumption
   122 apply (auto)
   123 done
   124 
   125 
   126 subsection \<open>@{term [source] map_of}\<close>
   127 
   128 lemma map_of_eq_None_iff:
   129   "(map_of xys x = None) = (x \<notin> fst ` (set xys))"
   130 by (induct xys) simp_all
   131 
   132 lemma map_of_eq_Some_iff [simp]:
   133   "distinct(map fst xys) \<Longrightarrow> (map_of xys x = Some y) = ((x,y) \<in> set xys)"
   134 apply (induct xys)
   135  apply simp
   136 apply (auto simp: map_of_eq_None_iff [symmetric])
   137 done
   138 
   139 lemma Some_eq_map_of_iff [simp]:
   140   "distinct(map fst xys) \<Longrightarrow> (Some y = map_of xys x) = ((x,y) \<in> set xys)"
   141 by (auto simp del: map_of_eq_Some_iff simp: map_of_eq_Some_iff [symmetric])
   142 
   143 lemma map_of_is_SomeI [simp]: "\<lbrakk> distinct(map fst xys); (x,y) \<in> set xys \<rbrakk>
   144     \<Longrightarrow> map_of xys x = Some y"
   145 apply (induct xys)
   146  apply simp
   147 apply force
   148 done
   149 
   150 lemma map_of_zip_is_None [simp]:
   151   "length xs = length ys \<Longrightarrow> (map_of (zip xs ys) x = None) = (x \<notin> set xs)"
   152 by (induct rule: list_induct2) simp_all
   153 
   154 lemma map_of_zip_is_Some:
   155   assumes "length xs = length ys"
   156   shows "x \<in> set xs \<longleftrightarrow> (\<exists>y. map_of (zip xs ys) x = Some y)"
   157 using assms by (induct rule: list_induct2) simp_all
   158 
   159 lemma map_of_zip_upd:
   160   fixes x :: 'a and xs :: "'a list" and ys zs :: "'b list"
   161   assumes "length ys = length xs"
   162     and "length zs = length xs"
   163     and "x \<notin> set xs"
   164     and "map_of (zip xs ys)(x \<mapsto> y) = map_of (zip xs zs)(x \<mapsto> z)"
   165   shows "map_of (zip xs ys) = map_of (zip xs zs)"
   166 proof
   167   fix x' :: 'a
   168   show "map_of (zip xs ys) x' = map_of (zip xs zs) x'"
   169   proof (cases "x = x'")
   170     case True
   171     from assms True map_of_zip_is_None [of xs ys x']
   172       have "map_of (zip xs ys) x' = None" by simp
   173     moreover from assms True map_of_zip_is_None [of xs zs x']
   174       have "map_of (zip xs zs) x' = None" by simp
   175     ultimately show ?thesis by simp
   176   next
   177     case False from assms
   178       have "(map_of (zip xs ys)(x \<mapsto> y)) x' = (map_of (zip xs zs)(x \<mapsto> z)) x'" by auto
   179     with False show ?thesis by simp
   180   qed
   181 qed
   182 
   183 lemma map_of_zip_inject:
   184   assumes "length ys = length xs"
   185     and "length zs = length xs"
   186     and dist: "distinct xs"
   187     and map_of: "map_of (zip xs ys) = map_of (zip xs zs)"
   188   shows "ys = zs"
   189   using assms(1) assms(2)[symmetric]
   190   using dist map_of
   191 proof (induct ys xs zs rule: list_induct3)
   192   case Nil show ?case by simp
   193 next
   194   case (Cons y ys x xs z zs)
   195   from \<open>map_of (zip (x#xs) (y#ys)) = map_of (zip (x#xs) (z#zs))\<close>
   196     have map_of: "map_of (zip xs ys)(x \<mapsto> y) = map_of (zip xs zs)(x \<mapsto> z)" by simp
   197   from Cons have "length ys = length xs" and "length zs = length xs"
   198     and "x \<notin> set xs" by simp_all
   199   then have "map_of (zip xs ys) = map_of (zip xs zs)" using map_of by (rule map_of_zip_upd)
   200   with Cons.hyps \<open>distinct (x # xs)\<close> have "ys = zs" by simp
   201   moreover from map_of have "y = z" by (rule map_upd_eqD1)
   202   ultimately show ?case by simp
   203 qed
   204 
   205 lemma map_of_zip_map:
   206   "map_of (zip xs (map f xs)) = (\<lambda>x. if x \<in> set xs then Some (f x) else None)"
   207   by (induct xs) (simp_all add: fun_eq_iff)
   208 
   209 lemma finite_range_map_of: "finite (range (map_of xys))"
   210 apply (induct xys)
   211  apply (simp_all add: image_constant)
   212 apply (rule finite_subset)
   213  prefer 2 apply assumption
   214 apply auto
   215 done
   216 
   217 lemma map_of_SomeD: "map_of xs k = Some y \<Longrightarrow> (k, y) \<in> set xs"
   218   by (induct xs) (auto split: if_splits)
   219 
   220 lemma map_of_mapk_SomeI:
   221   "inj f \<Longrightarrow> map_of t k = Some x \<Longrightarrow>
   222    map_of (map (case_prod (\<lambda>k. Pair (f k))) t) (f k) = Some x"
   223 by (induct t) (auto simp: inj_eq)
   224 
   225 lemma weak_map_of_SomeI: "(k, x) \<in> set l \<Longrightarrow> \<exists>x. map_of l k = Some x"
   226 by (induct l) auto
   227 
   228 lemma map_of_filter_in:
   229   "map_of xs k = Some z \<Longrightarrow> P k z \<Longrightarrow> map_of (filter (case_prod P) xs) k = Some z"
   230 by (induct xs) auto
   231 
   232 lemma map_of_map:
   233   "map_of (map (\<lambda>(k, v). (k, f v)) xs) = map_option f \<circ> map_of xs"
   234   by (induct xs) (auto simp: fun_eq_iff)
   235 
   236 lemma dom_map_option:
   237   "dom (\<lambda>k. map_option (f k) (m k)) = dom m"
   238   by (simp add: dom_def)
   239 
   240 lemma dom_map_option_comp [simp]:
   241   "dom (map_option g \<circ> m) = dom m"
   242   using dom_map_option [of "\<lambda>_. g" m] by (simp add: comp_def)
   243 
   244 
   245 subsection \<open>@{const map_option} related\<close>
   246 
   247 lemma map_option_o_empty [simp]: "map_option f o empty = empty"
   248 by (rule ext) simp
   249 
   250 lemma map_option_o_map_upd [simp]:
   251   "map_option f o m(a\<mapsto>b) = (map_option f o m)(a\<mapsto>f b)"
   252 by (rule ext) simp
   253 
   254 
   255 subsection \<open>@{term [source] map_comp} related\<close>
   256 
   257 lemma map_comp_empty [simp]:
   258   "m \<circ>\<^sub>m empty = empty"
   259   "empty \<circ>\<^sub>m m = empty"
   260 by (auto simp: map_comp_def split: option.splits)
   261 
   262 lemma map_comp_simps [simp]:
   263   "m2 k = None \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = None"
   264   "m2 k = Some k' \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = m1 k'"
   265 by (auto simp: map_comp_def)
   266 
   267 lemma map_comp_Some_iff:
   268   "((m1 \<circ>\<^sub>m m2) k = Some v) = (\<exists>k'. m2 k = Some k' \<and> m1 k' = Some v)"
   269 by (auto simp: map_comp_def split: option.splits)
   270 
   271 lemma map_comp_None_iff:
   272   "((m1 \<circ>\<^sub>m m2) k = None) = (m2 k = None \<or> (\<exists>k'. m2 k = Some k' \<and> m1 k' = None)) "
   273 by (auto simp: map_comp_def split: option.splits)
   274 
   275 
   276 subsection \<open>\<open>++\<close>\<close>
   277 
   278 lemma map_add_empty[simp]: "m ++ empty = m"
   279 by(simp add: map_add_def)
   280 
   281 lemma empty_map_add[simp]: "empty ++ m = m"
   282 by (rule ext) (simp add: map_add_def split: option.split)
   283 
   284 lemma map_add_assoc[simp]: "m1 ++ (m2 ++ m3) = (m1 ++ m2) ++ m3"
   285 by (rule ext) (simp add: map_add_def split: option.split)
   286 
   287 lemma map_add_Some_iff:
   288   "((m ++ n) k = Some x) = (n k = Some x | n k = None & m k = Some x)"
   289 by (simp add: map_add_def split: option.split)
   290 
   291 lemma map_add_SomeD [dest!]:
   292   "(m ++ n) k = Some x \<Longrightarrow> n k = Some x \<or> n k = None \<and> m k = Some x"
   293 by (rule map_add_Some_iff [THEN iffD1])
   294 
   295 lemma map_add_find_right [simp]: "n k = Some xx \<Longrightarrow> (m ++ n) k = Some xx"
   296 by (subst map_add_Some_iff) fast
   297 
   298 lemma map_add_None [iff]: "((m ++ n) k = None) = (n k = None & m k = None)"
   299 by (simp add: map_add_def split: option.split)
   300 
   301 lemma map_add_upd[simp]: "f ++ g(x\<mapsto>y) = (f ++ g)(x\<mapsto>y)"
   302 by (rule ext) (simp add: map_add_def)
   303 
   304 lemma map_add_upds[simp]: "m1 ++ (m2(xs[\<mapsto>]ys)) = (m1++m2)(xs[\<mapsto>]ys)"
   305 by (simp add: map_upds_def)
   306 
   307 lemma map_add_upd_left: "m\<notin>dom e2 \<Longrightarrow> e1(m \<mapsto> u1) ++ e2 = (e1 ++ e2)(m \<mapsto> u1)"
   308 by (rule ext) (auto simp: map_add_def dom_def split: option.split)
   309 
   310 lemma map_of_append[simp]: "map_of (xs @ ys) = map_of ys ++ map_of xs"
   311 unfolding map_add_def
   312 apply (induct xs)
   313  apply simp
   314 apply (rule ext)
   315 apply (simp split add: option.split)
   316 done
   317 
   318 lemma finite_range_map_of_map_add:
   319   "finite (range f) \<Longrightarrow> finite (range (f ++ map_of l))"
   320 apply (induct l)
   321  apply (auto simp del: fun_upd_apply)
   322 apply (erule finite_range_updI)
   323 done
   324 
   325 lemma inj_on_map_add_dom [iff]:
   326   "inj_on (m ++ m') (dom m') = inj_on m' (dom m')"
   327 by (fastforce simp: map_add_def dom_def inj_on_def split: option.splits)
   328 
   329 lemma map_upds_fold_map_upd:
   330   "m(ks[\<mapsto>]vs) = foldl (\<lambda>m (k, v). m(k \<mapsto> v)) m (zip ks vs)"
   331 unfolding map_upds_def proof (rule sym, rule zip_obtain_same_length)
   332   fix ks :: "'a list" and vs :: "'b list"
   333   assume "length ks = length vs"
   334   then show "foldl (\<lambda>m (k, v). m(k\<mapsto>v)) m (zip ks vs) = m ++ map_of (rev (zip ks vs))"
   335     by(induct arbitrary: m rule: list_induct2) simp_all
   336 qed
   337 
   338 lemma map_add_map_of_foldr:
   339   "m ++ map_of ps = foldr (\<lambda>(k, v) m. m(k \<mapsto> v)) ps m"
   340   by (induct ps) (auto simp: fun_eq_iff map_add_def)
   341 
   342 
   343 subsection \<open>@{term [source] restrict_map}\<close>
   344 
   345 lemma restrict_map_to_empty [simp]: "m|`{} = empty"
   346 by (simp add: restrict_map_def)
   347 
   348 lemma restrict_map_insert: "f |` (insert a A) = (f |` A)(a := f a)"
   349 by (auto simp: restrict_map_def)
   350 
   351 lemma restrict_map_empty [simp]: "empty|`D = empty"
   352 by (simp add: restrict_map_def)
   353 
   354 lemma restrict_in [simp]: "x \<in> A \<Longrightarrow> (m|`A) x = m x"
   355 by (simp add: restrict_map_def)
   356 
   357 lemma restrict_out [simp]: "x \<notin> A \<Longrightarrow> (m|`A) x = None"
   358 by (simp add: restrict_map_def)
   359 
   360 lemma ran_restrictD: "y \<in> ran (m|`A) \<Longrightarrow> \<exists>x\<in>A. m x = Some y"
   361 by (auto simp: restrict_map_def ran_def split: split_if_asm)
   362 
   363 lemma dom_restrict [simp]: "dom (m|`A) = dom m \<inter> A"
   364 by (auto simp: restrict_map_def dom_def split: split_if_asm)
   365 
   366 lemma restrict_upd_same [simp]: "m(x\<mapsto>y)|`(-{x}) = m|`(-{x})"
   367 by (rule ext) (auto simp: restrict_map_def)
   368 
   369 lemma restrict_restrict [simp]: "m|`A|`B = m|`(A\<inter>B)"
   370 by (rule ext) (auto simp: restrict_map_def)
   371 
   372 lemma restrict_fun_upd [simp]:
   373   "m(x := y)|`D = (if x \<in> D then (m|`(D-{x}))(x := y) else m|`D)"
   374 by (simp add: restrict_map_def fun_eq_iff)
   375 
   376 lemma fun_upd_None_restrict [simp]:
   377   "(m|`D)(x := None) = (if x \<in> D then m|`(D - {x}) else m|`D)"
   378 by (simp add: restrict_map_def fun_eq_iff)
   379 
   380 lemma fun_upd_restrict: "(m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   381 by (simp add: restrict_map_def fun_eq_iff)
   382 
   383 lemma fun_upd_restrict_conv [simp]:
   384   "x \<in> D \<Longrightarrow> (m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   385 by (simp add: restrict_map_def fun_eq_iff)
   386 
   387 lemma map_of_map_restrict:
   388   "map_of (map (\<lambda>k. (k, f k)) ks) = (Some \<circ> f) |` set ks"
   389   by (induct ks) (simp_all add: fun_eq_iff restrict_map_insert)
   390 
   391 lemma restrict_complement_singleton_eq:
   392   "f |` (- {x}) = f(x := None)"
   393   by (simp add: restrict_map_def fun_eq_iff)
   394 
   395 
   396 subsection \<open>@{term [source] map_upds}\<close>
   397 
   398 lemma map_upds_Nil1 [simp]: "m([] [\<mapsto>] bs) = m"
   399 by (simp add: map_upds_def)
   400 
   401 lemma map_upds_Nil2 [simp]: "m(as [\<mapsto>] []) = m"
   402 by (simp add:map_upds_def)
   403 
   404 lemma map_upds_Cons [simp]: "m(a#as [\<mapsto>] b#bs) = (m(a\<mapsto>b))(as[\<mapsto>]bs)"
   405 by (simp add:map_upds_def)
   406 
   407 lemma map_upds_append1 [simp]: "size xs < size ys \<Longrightarrow>
   408   m(xs@[x] [\<mapsto>] ys) = m(xs [\<mapsto>] ys)(x \<mapsto> ys!size xs)"
   409 apply(induct xs arbitrary: ys m)
   410  apply (clarsimp simp add: neq_Nil_conv)
   411 apply (case_tac ys)
   412  apply simp
   413 apply simp
   414 done
   415 
   416 lemma map_upds_list_update2_drop [simp]:
   417   "size xs \<le> i \<Longrightarrow> m(xs[\<mapsto>]ys[i:=y]) = m(xs[\<mapsto>]ys)"
   418 apply (induct xs arbitrary: m ys i)
   419  apply simp
   420 apply (case_tac ys)
   421  apply simp
   422 apply (simp split: nat.split)
   423 done
   424 
   425 lemma map_upd_upds_conv_if:
   426   "(f(x\<mapsto>y))(xs [\<mapsto>] ys) =
   427    (if x \<in> set(take (length ys) xs) then f(xs [\<mapsto>] ys)
   428                                     else (f(xs [\<mapsto>] ys))(x\<mapsto>y))"
   429 apply (induct xs arbitrary: x y ys f)
   430  apply simp
   431 apply (case_tac ys)
   432  apply (auto split: split_if simp: fun_upd_twist)
   433 done
   434 
   435 lemma map_upds_twist [simp]:
   436   "a \<notin> set as \<Longrightarrow> m(a\<mapsto>b)(as[\<mapsto>]bs) = m(as[\<mapsto>]bs)(a\<mapsto>b)"
   437 using set_take_subset by (fastforce simp add: map_upd_upds_conv_if)
   438 
   439 lemma map_upds_apply_nontin [simp]:
   440   "x \<notin> set xs \<Longrightarrow> (f(xs[\<mapsto>]ys)) x = f x"
   441 apply (induct xs arbitrary: ys)
   442  apply simp
   443 apply (case_tac ys)
   444  apply (auto simp: map_upd_upds_conv_if)
   445 done
   446 
   447 lemma fun_upds_append_drop [simp]:
   448   "size xs = size ys \<Longrightarrow> m(xs@zs[\<mapsto>]ys) = m(xs[\<mapsto>]ys)"
   449 apply (induct xs arbitrary: m ys)
   450  apply simp
   451 apply (case_tac ys)
   452  apply simp_all
   453 done
   454 
   455 lemma fun_upds_append2_drop [simp]:
   456   "size xs = size ys \<Longrightarrow> m(xs[\<mapsto>]ys@zs) = m(xs[\<mapsto>]ys)"
   457 apply (induct xs arbitrary: m ys)
   458  apply simp
   459 apply (case_tac ys)
   460  apply simp_all
   461 done
   462 
   463 
   464 lemma restrict_map_upds[simp]:
   465   "\<lbrakk> length xs = length ys; set xs \<subseteq> D \<rbrakk>
   466     \<Longrightarrow> m(xs [\<mapsto>] ys)|`D = (m|`(D - set xs))(xs [\<mapsto>] ys)"
   467 apply (induct xs arbitrary: m ys)
   468  apply simp
   469 apply (case_tac ys)
   470  apply simp
   471 apply (simp add: Diff_insert [symmetric] insert_absorb)
   472 apply (simp add: map_upd_upds_conv_if)
   473 done
   474 
   475 
   476 subsection \<open>@{term [source] dom}\<close>
   477 
   478 lemma dom_eq_empty_conv [simp]: "dom f = {} \<longleftrightarrow> f = empty"
   479   by (auto simp: dom_def)
   480 
   481 lemma domI: "m a = Some b \<Longrightarrow> a \<in> dom m"
   482   by (simp add: dom_def)
   483 (* declare domI [intro]? *)
   484 
   485 lemma domD: "a \<in> dom m \<Longrightarrow> \<exists>b. m a = Some b"
   486   by (cases "m a") (auto simp add: dom_def)
   487 
   488 lemma domIff [iff, simp del]: "a \<in> dom m \<longleftrightarrow> m a \<noteq> None"
   489   by (simp add: dom_def)
   490 
   491 lemma dom_empty [simp]: "dom empty = {}"
   492   by (simp add: dom_def)
   493 
   494 lemma dom_fun_upd [simp]:
   495   "dom(f(x := y)) = (if y = None then dom f - {x} else insert x (dom f))"
   496   by (auto simp: dom_def)
   497 
   498 lemma dom_if:
   499   "dom (\<lambda>x. if P x then f x else g x) = dom f \<inter> {x. P x} \<union> dom g \<inter> {x. \<not> P x}"
   500   by (auto split: if_splits)
   501 
   502 lemma dom_map_of_conv_image_fst:
   503   "dom (map_of xys) = fst ` set xys"
   504   by (induct xys) (auto simp add: dom_if)
   505 
   506 lemma dom_map_of_zip [simp]: "length xs = length ys \<Longrightarrow> dom (map_of (zip xs ys)) = set xs"
   507   by (induct rule: list_induct2) (auto simp: dom_if)
   508 
   509 lemma finite_dom_map_of: "finite (dom (map_of l))"
   510   by (induct l) (auto simp: dom_def insert_Collect [symmetric])
   511 
   512 lemma dom_map_upds [simp]:
   513   "dom(m(xs[\<mapsto>]ys)) = set(take (length ys) xs) \<union> dom m"
   514 apply (induct xs arbitrary: m ys)
   515  apply simp
   516 apply (case_tac ys)
   517  apply auto
   518 done
   519 
   520 lemma dom_map_add [simp]: "dom (m ++ n) = dom n \<union> dom m"
   521   by (auto simp: dom_def)
   522 
   523 lemma dom_override_on [simp]:
   524   "dom (override_on f g A) =
   525     (dom f  - {a. a \<in> A - dom g}) \<union> {a. a \<in> A \<inter> dom g}"
   526   by (auto simp: dom_def override_on_def)
   527 
   528 lemma map_add_comm: "dom m1 \<inter> dom m2 = {} \<Longrightarrow> m1 ++ m2 = m2 ++ m1"
   529   by (rule ext) (force simp: map_add_def dom_def split: option.split)
   530 
   531 lemma map_add_dom_app_simps:
   532   "m \<in> dom l2 \<Longrightarrow> (l1 ++ l2) m = l2 m"
   533   "m \<notin> dom l1 \<Longrightarrow> (l1 ++ l2) m = l2 m"
   534   "m \<notin> dom l2 \<Longrightarrow> (l1 ++ l2) m = l1 m"
   535   by (auto simp add: map_add_def split: option.split_asm)
   536 
   537 lemma dom_const [simp]:
   538   "dom (\<lambda>x. Some (f x)) = UNIV"
   539   by auto
   540 
   541 (* Due to John Matthews - could be rephrased with dom *)
   542 lemma finite_map_freshness:
   543   "finite (dom (f :: 'a \<rightharpoonup> 'b)) \<Longrightarrow> \<not> finite (UNIV :: 'a set) \<Longrightarrow>
   544    \<exists>x. f x = None"
   545   by (bestsimp dest: ex_new_if_finite)
   546 
   547 lemma dom_minus:
   548   "f x = None \<Longrightarrow> dom f - insert x A = dom f - A"
   549   unfolding dom_def by simp
   550 
   551 lemma insert_dom:
   552   "f x = Some y \<Longrightarrow> insert x (dom f) = dom f"
   553   unfolding dom_def by auto
   554 
   555 lemma map_of_map_keys:
   556   "set xs = dom m \<Longrightarrow> map_of (map (\<lambda>k. (k, the (m k))) xs) = m"
   557   by (rule ext) (auto simp add: map_of_map_restrict restrict_map_def)
   558 
   559 lemma map_of_eqI:
   560   assumes set_eq: "set (map fst xs) = set (map fst ys)"
   561   assumes map_eq: "\<forall>k\<in>set (map fst xs). map_of xs k = map_of ys k"
   562   shows "map_of xs = map_of ys"
   563 proof (rule ext)
   564   fix k show "map_of xs k = map_of ys k"
   565   proof (cases "map_of xs k")
   566     case None
   567     then have "k \<notin> set (map fst xs)" by (simp add: map_of_eq_None_iff)
   568     with set_eq have "k \<notin> set (map fst ys)" by simp
   569     then have "map_of ys k = None" by (simp add: map_of_eq_None_iff)
   570     with None show ?thesis by simp
   571   next
   572     case (Some v)
   573     then have "k \<in> set (map fst xs)" by (auto simp add: dom_map_of_conv_image_fst [symmetric])
   574     with map_eq show ?thesis by auto
   575   qed
   576 qed
   577 
   578 lemma map_of_eq_dom:
   579   assumes "map_of xs = map_of ys"
   580   shows "fst ` set xs = fst ` set ys"
   581 proof -
   582   from assms have "dom (map_of xs) = dom (map_of ys)" by simp
   583   then show ?thesis by (simp add: dom_map_of_conv_image_fst)
   584 qed
   585 
   586 lemma finite_set_of_finite_maps:
   587   assumes "finite A" "finite B"
   588   shows "finite {m. dom m = A \<and> ran m \<subseteq> B}" (is "finite ?S")
   589 proof -
   590   let ?S' = "{m. \<forall>x. (x \<in> A \<longrightarrow> m x \<in> Some ` B) \<and> (x \<notin> A \<longrightarrow> m x = None)}"
   591   have "?S = ?S'"
   592   proof
   593     show "?S \<subseteq> ?S'" by (auto simp: dom_def ran_def image_def)
   594     show "?S' \<subseteq> ?S"
   595     proof
   596       fix m assume "m \<in> ?S'"
   597       hence 1: "dom m = A" by force
   598       hence 2: "ran m \<subseteq> B" using \<open>m \<in> ?S'\<close> by (auto simp: dom_def ran_def)
   599       from 1 2 show "m \<in> ?S" by blast
   600     qed
   601   qed
   602   with assms show ?thesis by(simp add: finite_set_of_finite_funs)
   603 qed
   604 
   605 
   606 subsection \<open>@{term [source] ran}\<close>
   607 
   608 lemma ranI: "m a = Some b \<Longrightarrow> b \<in> ran m"
   609   by (auto simp: ran_def)
   610 (* declare ranI [intro]? *)
   611 
   612 lemma ran_empty [simp]: "ran empty = {}"
   613   by (auto simp: ran_def)
   614 
   615 lemma ran_map_upd [simp]: "m a = None \<Longrightarrow> ran(m(a\<mapsto>b)) = insert b (ran m)"
   616   unfolding ran_def
   617 apply auto
   618 apply (subgoal_tac "aa \<noteq> a")
   619  apply auto
   620 done
   621 
   622 lemma ran_distinct:
   623   assumes dist: "distinct (map fst al)"
   624   shows "ran (map_of al) = snd ` set al"
   625   using assms
   626 proof (induct al)
   627   case Nil
   628   then show ?case by simp
   629 next
   630   case (Cons kv al)
   631   then have "ran (map_of al) = snd ` set al" by simp
   632   moreover from Cons.prems have "map_of al (fst kv) = None"
   633     by (simp add: map_of_eq_None_iff)
   634   ultimately show ?case by (simp only: map_of.simps ran_map_upd) simp
   635 qed
   636 
   637 lemma ran_map_option: "ran (\<lambda>x. map_option f (m x)) = f ` ran m"
   638   by (auto simp add: ran_def)
   639 
   640 
   641 subsection \<open>\<open>map_le\<close>\<close>
   642 
   643 lemma map_le_empty [simp]: "empty \<subseteq>\<^sub>m g"
   644   by (simp add: map_le_def)
   645 
   646 lemma upd_None_map_le [simp]: "f(x := None) \<subseteq>\<^sub>m f"
   647   by (force simp add: map_le_def)
   648 
   649 lemma map_le_upd[simp]: "f \<subseteq>\<^sub>m g ==> f(a := b) \<subseteq>\<^sub>m g(a := b)"
   650   by (fastforce simp add: map_le_def)
   651 
   652 lemma map_le_imp_upd_le [simp]: "m1 \<subseteq>\<^sub>m m2 \<Longrightarrow> m1(x := None) \<subseteq>\<^sub>m m2(x \<mapsto> y)"
   653   by (force simp add: map_le_def)
   654 
   655 lemma map_le_upds [simp]:
   656   "f \<subseteq>\<^sub>m g \<Longrightarrow> f(as [\<mapsto>] bs) \<subseteq>\<^sub>m g(as [\<mapsto>] bs)"
   657 apply (induct as arbitrary: f g bs)
   658  apply simp
   659 apply (case_tac bs)
   660  apply auto
   661 done
   662 
   663 lemma map_le_implies_dom_le: "(f \<subseteq>\<^sub>m g) \<Longrightarrow> (dom f \<subseteq> dom g)"
   664   by (fastforce simp add: map_le_def dom_def)
   665 
   666 lemma map_le_refl [simp]: "f \<subseteq>\<^sub>m f"
   667   by (simp add: map_le_def)
   668 
   669 lemma map_le_trans[trans]: "\<lbrakk> m1 \<subseteq>\<^sub>m m2; m2 \<subseteq>\<^sub>m m3\<rbrakk> \<Longrightarrow> m1 \<subseteq>\<^sub>m m3"
   670   by (auto simp add: map_le_def dom_def)
   671 
   672 lemma map_le_antisym: "\<lbrakk> f \<subseteq>\<^sub>m g; g \<subseteq>\<^sub>m f \<rbrakk> \<Longrightarrow> f = g"
   673 unfolding map_le_def
   674 apply (rule ext)
   675 apply (case_tac "x \<in> dom f", simp)
   676 apply (case_tac "x \<in> dom g", simp, fastforce)
   677 done
   678 
   679 lemma map_le_map_add [simp]: "f \<subseteq>\<^sub>m g ++ f"
   680   by (fastforce simp: map_le_def)
   681 
   682 lemma map_le_iff_map_add_commute: "f \<subseteq>\<^sub>m f ++ g \<longleftrightarrow> f ++ g = g ++ f"
   683   by (fastforce simp: map_add_def map_le_def fun_eq_iff split: option.splits)
   684 
   685 lemma map_add_le_mapE: "f ++ g \<subseteq>\<^sub>m h \<Longrightarrow> g \<subseteq>\<^sub>m h"
   686   by (fastforce simp: map_le_def map_add_def dom_def)
   687 
   688 lemma map_add_le_mapI: "\<lbrakk> f \<subseteq>\<^sub>m h; g \<subseteq>\<^sub>m h \<rbrakk> \<Longrightarrow> f ++ g \<subseteq>\<^sub>m h"
   689   by (auto simp: map_le_def map_add_def dom_def split: option.splits)
   690 
   691 lemma dom_eq_singleton_conv: "dom f = {x} \<longleftrightarrow> (\<exists>v. f = [x \<mapsto> v])"
   692 proof(rule iffI)
   693   assume "\<exists>v. f = [x \<mapsto> v]"
   694   thus "dom f = {x}" by(auto split: split_if_asm)
   695 next
   696   assume "dom f = {x}"
   697   then obtain v where "f x = Some v" by auto
   698   hence "[x \<mapsto> v] \<subseteq>\<^sub>m f" by(auto simp add: map_le_def)
   699   moreover have "f \<subseteq>\<^sub>m [x \<mapsto> v]" using \<open>dom f = {x}\<close> \<open>f x = Some v\<close>
   700     by(auto simp add: map_le_def)
   701   ultimately have "f = [x \<mapsto> v]" by-(rule map_le_antisym)
   702   thus "\<exists>v. f = [x \<mapsto> v]" by blast
   703 qed
   704 
   705 
   706 subsection \<open>Various\<close>
   707 
   708 lemma set_map_of_compr:
   709   assumes distinct: "distinct (map fst xs)"
   710   shows "set xs = {(k, v). map_of xs k = Some v}"
   711   using assms
   712 proof (induct xs)
   713   case Nil
   714   then show ?case by simp
   715 next
   716   case (Cons x xs)
   717   obtain k v where "x = (k, v)" by (cases x) blast
   718   with Cons.prems have "k \<notin> dom (map_of xs)"
   719     by (simp add: dom_map_of_conv_image_fst)
   720   then have *: "insert (k, v) {(k, v). map_of xs k = Some v} =
   721     {(k', v'). (map_of xs(k \<mapsto> v)) k' = Some v'}"
   722     by (auto split: if_splits)
   723   from Cons have "set xs = {(k, v). map_of xs k = Some v}" by simp
   724   with * \<open>x = (k, v)\<close> show ?case by simp
   725 qed
   726 
   727 lemma map_of_inject_set:
   728   assumes distinct: "distinct (map fst xs)" "distinct (map fst ys)"
   729   shows "map_of xs = map_of ys \<longleftrightarrow> set xs = set ys" (is "?lhs \<longleftrightarrow> ?rhs")
   730 proof
   731   assume ?lhs
   732   moreover from \<open>distinct (map fst xs)\<close> have "set xs = {(k, v). map_of xs k = Some v}"
   733     by (rule set_map_of_compr)
   734   moreover from \<open>distinct (map fst ys)\<close> have "set ys = {(k, v). map_of ys k = Some v}"
   735     by (rule set_map_of_compr)
   736   ultimately show ?rhs by simp
   737 next
   738   assume ?rhs show ?lhs
   739   proof
   740     fix k
   741     show "map_of xs k = map_of ys k"
   742     proof (cases "map_of xs k")
   743       case None
   744       with \<open>?rhs\<close> have "map_of ys k = None"
   745         by (simp add: map_of_eq_None_iff)
   746       with None show ?thesis by simp
   747     next
   748       case (Some v)
   749       with distinct \<open>?rhs\<close> have "map_of ys k = Some v"
   750         by simp
   751       with Some show ?thesis by simp
   752     qed
   753   qed
   754 qed
   755 
   756 end