src/HOL/Multivariate_Analysis/Complex_Analysis_Basics.thy
author hoelzl
Fri Feb 19 13:40:50 2016 +0100 (2016-02-19)
changeset 62378 85ed00c1fe7c
parent 62217 527488dc8b90
child 62397 5ae24f33d343
permissions -rw-r--r--
generalize more theorems to support enat and ennreal
     1 (*  Author: John Harrison, Marco Maggesi, Graziano Gentili, Gianni Ciolli, Valentina Bruno
     2     Ported from "hol_light/Multivariate/canal.ml" by L C Paulson (2014)
     3 *)
     4 
     5 section \<open>Complex Analysis Basics\<close>
     6 
     7 theory Complex_Analysis_Basics
     8 imports Cartesian_Euclidean_Space "~~/src/HOL/Library/Nonpos_Ints"
     9 begin
    10 
    11 
    12 subsection\<open>General lemmas\<close>
    13 
    14 lemma nonneg_Reals_cmod_eq_Re: "z \<in> \<real>\<^sub>\<ge>\<^sub>0 \<Longrightarrow> norm z = Re z"
    15   by (simp add: complex_nonneg_Reals_iff cmod_eq_Re)
    16 
    17 lemma has_derivative_mult_right:
    18   fixes c:: "'a :: real_normed_algebra"
    19   shows "((op * c) has_derivative (op * c)) F"
    20 by (rule has_derivative_mult_right [OF has_derivative_id])
    21 
    22 lemma has_derivative_of_real[derivative_intros, simp]:
    23   "(f has_derivative f') F \<Longrightarrow> ((\<lambda>x. of_real (f x)) has_derivative (\<lambda>x. of_real (f' x))) F"
    24   using bounded_linear.has_derivative[OF bounded_linear_of_real] .
    25 
    26 lemma has_vector_derivative_real_complex:
    27   "DERIV f (of_real a) :> f' \<Longrightarrow> ((\<lambda>x. f (of_real x)) has_vector_derivative f') (at a within s)"
    28   using has_derivative_compose[of of_real of_real a _ f "op * f'"]
    29   by (simp add: scaleR_conv_of_real ac_simps has_vector_derivative_def has_field_derivative_def)
    30 
    31 lemma fact_cancel:
    32   fixes c :: "'a::real_field"
    33   shows "of_nat (Suc n) * c / (fact (Suc n)) = c / (fact n)"
    34   by (simp add: of_nat_mult del: of_nat_Suc times_nat.simps)
    35 
    36 lemma bilinear_times:
    37   fixes c::"'a::real_algebra" shows "bilinear (\<lambda>x y::'a. x*y)"
    38   by (auto simp: bilinear_def distrib_left distrib_right intro!: linearI)
    39 
    40 lemma linear_cnj: "linear cnj"
    41   using bounded_linear.linear[OF bounded_linear_cnj] .
    42 
    43 lemma tendsto_Re_upper:
    44   assumes "~ (trivial_limit F)"
    45           "(f \<longlongrightarrow> l) F"
    46           "eventually (\<lambda>x. Re(f x) \<le> b) F"
    47     shows  "Re(l) \<le> b"
    48   by (metis assms tendsto_le [OF _ tendsto_const]  tendsto_Re)
    49 
    50 lemma tendsto_Re_lower:
    51   assumes "~ (trivial_limit F)"
    52           "(f \<longlongrightarrow> l) F"
    53           "eventually (\<lambda>x. b \<le> Re(f x)) F"
    54     shows  "b \<le> Re(l)"
    55   by (metis assms tendsto_le [OF _ _ tendsto_const]  tendsto_Re)
    56 
    57 lemma tendsto_Im_upper:
    58   assumes "~ (trivial_limit F)"
    59           "(f \<longlongrightarrow> l) F"
    60           "eventually (\<lambda>x. Im(f x) \<le> b) F"
    61     shows  "Im(l) \<le> b"
    62   by (metis assms tendsto_le [OF _ tendsto_const]  tendsto_Im)
    63 
    64 lemma tendsto_Im_lower:
    65   assumes "~ (trivial_limit F)"
    66           "(f \<longlongrightarrow> l) F"
    67           "eventually (\<lambda>x. b \<le> Im(f x)) F"
    68     shows  "b \<le> Im(l)"
    69   by (metis assms tendsto_le [OF _ _ tendsto_const]  tendsto_Im)
    70 
    71 lemma lambda_zero: "(\<lambda>h::'a::mult_zero. 0) = op * 0"
    72   by auto
    73 
    74 lemma lambda_one: "(\<lambda>x::'a::monoid_mult. x) = op * 1"
    75   by auto
    76 
    77 lemma continuous_mult_left:
    78   fixes c::"'a::real_normed_algebra"
    79   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. c * f x)"
    80 by (rule continuous_mult [OF continuous_const])
    81 
    82 lemma continuous_mult_right:
    83   fixes c::"'a::real_normed_algebra"
    84   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. f x * c)"
    85 by (rule continuous_mult [OF _ continuous_const])
    86 
    87 lemma continuous_on_mult_left:
    88   fixes c::"'a::real_normed_algebra"
    89   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. c * f x)"
    90 by (rule continuous_on_mult [OF continuous_on_const])
    91 
    92 lemma continuous_on_mult_right:
    93   fixes c::"'a::real_normed_algebra"
    94   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. f x * c)"
    95 by (rule continuous_on_mult [OF _ continuous_on_const])
    96 
    97 lemma uniformly_continuous_on_cmul_right [continuous_intros]:
    98   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
    99   shows "uniformly_continuous_on s f \<Longrightarrow> uniformly_continuous_on s (\<lambda>x. f x * c)"
   100   using bounded_linear.uniformly_continuous_on[OF bounded_linear_mult_left] .
   101 
   102 lemma uniformly_continuous_on_cmul_left[continuous_intros]:
   103   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
   104   assumes "uniformly_continuous_on s f"
   105     shows "uniformly_continuous_on s (\<lambda>x. c * f x)"
   106 by (metis assms bounded_linear.uniformly_continuous_on bounded_linear_mult_right)
   107 
   108 lemma continuous_within_norm_id [continuous_intros]: "continuous (at x within S) norm"
   109   by (rule continuous_norm [OF continuous_ident])
   110 
   111 lemma continuous_on_norm_id [continuous_intros]: "continuous_on S norm"
   112   by (intro continuous_on_id continuous_on_norm)
   113 
   114 subsection\<open>DERIV stuff\<close>
   115 
   116 lemma DERIV_zero_connected_constant:
   117   fixes f :: "'a::{real_normed_field,euclidean_space} \<Rightarrow> 'a"
   118   assumes "connected s"
   119       and "open s"
   120       and "finite k"
   121       and "continuous_on s f"
   122       and "\<forall>x\<in>(s - k). DERIV f x :> 0"
   123     obtains c where "\<And>x. x \<in> s \<Longrightarrow> f(x) = c"
   124 using has_derivative_zero_connected_constant [OF assms(1-4)] assms
   125 by (metis DERIV_const has_derivative_const Diff_iff at_within_open frechet_derivative_at has_field_derivative_def)
   126 
   127 lemma DERIV_zero_constant:
   128   fixes f :: "'a::{real_normed_field, real_inner} \<Rightarrow> 'a"
   129   shows    "\<lbrakk>convex s;
   130              \<And>x. x\<in>s \<Longrightarrow> (f has_field_derivative 0) (at x within s)\<rbrakk>
   131              \<Longrightarrow> \<exists>c. \<forall>x \<in> s. f(x) = c"
   132   by (auto simp: has_field_derivative_def lambda_zero intro: has_derivative_zero_constant)
   133 
   134 lemma DERIV_zero_unique:
   135   fixes f :: "'a::{real_normed_field, real_inner} \<Rightarrow> 'a"
   136   assumes "convex s"
   137       and d0: "\<And>x. x\<in>s \<Longrightarrow> (f has_field_derivative 0) (at x within s)"
   138       and "a \<in> s"
   139       and "x \<in> s"
   140     shows "f x = f a"
   141   by (rule has_derivative_zero_unique [OF assms(1) _ assms(4,3)])
   142      (metis d0 has_field_derivative_imp_has_derivative lambda_zero)
   143 
   144 lemma DERIV_zero_connected_unique:
   145   fixes f :: "'a::{real_normed_field, real_inner} \<Rightarrow> 'a"
   146   assumes "connected s"
   147       and "open s"
   148       and d0: "\<And>x. x\<in>s \<Longrightarrow> DERIV f x :> 0"
   149       and "a \<in> s"
   150       and "x \<in> s"
   151     shows "f x = f a"
   152     by (rule has_derivative_zero_unique_connected [OF assms(2,1) _ assms(5,4)])
   153        (metis has_field_derivative_def lambda_zero d0)
   154 
   155 lemma DERIV_transform_within:
   156   assumes "(f has_field_derivative f') (at a within s)"
   157       and "0 < d" "a \<in> s"
   158       and "\<And>x. x\<in>s \<Longrightarrow> dist x a < d \<Longrightarrow> f x = g x"
   159     shows "(g has_field_derivative f') (at a within s)"
   160   using assms unfolding has_field_derivative_def
   161   by (blast intro: has_derivative_transform_within)
   162 
   163 lemma DERIV_transform_within_open:
   164   assumes "DERIV f a :> f'"
   165       and "open s" "a \<in> s"
   166       and "\<And>x. x\<in>s \<Longrightarrow> f x = g x"
   167     shows "DERIV g a :> f'"
   168   using assms unfolding has_field_derivative_def
   169 by (metis has_derivative_transform_within_open)
   170 
   171 lemma DERIV_transform_at:
   172   assumes "DERIV f a :> f'"
   173       and "0 < d"
   174       and "\<And>x. dist x a < d \<Longrightarrow> f x = g x"
   175     shows "DERIV g a :> f'"
   176   by (blast intro: assms DERIV_transform_within)
   177 
   178 (*generalising DERIV_isconst_all, which requires type real (using the ordering)*)
   179 lemma DERIV_zero_UNIV_unique:
   180   fixes f :: "'a::{real_normed_field, real_inner} \<Rightarrow> 'a"
   181   shows "(\<And>x. DERIV f x :> 0) \<Longrightarrow> f x = f a"
   182 by (metis DERIV_zero_unique UNIV_I assms convex_UNIV)
   183 
   184 subsection \<open>Some limit theorems about real part of real series etc.\<close>
   185 
   186 (*MOVE? But not to Finite_Cartesian_Product*)
   187 lemma sums_vec_nth :
   188   assumes "f sums a"
   189   shows "(\<lambda>x. f x $ i) sums a $ i"
   190 using assms unfolding sums_def
   191 by (auto dest: tendsto_vec_nth [where i=i])
   192 
   193 lemma summable_vec_nth :
   194   assumes "summable f"
   195   shows "summable (\<lambda>x. f x $ i)"
   196 using assms unfolding summable_def
   197 by (blast intro: sums_vec_nth)
   198 
   199 subsection \<open>Complex number lemmas\<close>
   200 
   201 lemma
   202   shows open_halfspace_Re_lt: "open {z. Re(z) < b}"
   203     and open_halfspace_Re_gt: "open {z. Re(z) > b}"
   204     and closed_halfspace_Re_ge: "closed {z. Re(z) \<ge> b}"
   205     and closed_halfspace_Re_le: "closed {z. Re(z) \<le> b}"
   206     and closed_halfspace_Re_eq: "closed {z. Re(z) = b}"
   207     and open_halfspace_Im_lt: "open {z. Im(z) < b}"
   208     and open_halfspace_Im_gt: "open {z. Im(z) > b}"
   209     and closed_halfspace_Im_ge: "closed {z. Im(z) \<ge> b}"
   210     and closed_halfspace_Im_le: "closed {z. Im(z) \<le> b}"
   211     and closed_halfspace_Im_eq: "closed {z. Im(z) = b}"
   212   by (intro open_Collect_less closed_Collect_le closed_Collect_eq isCont_Re
   213             isCont_Im continuous_ident continuous_const)+
   214 
   215 lemma closed_complex_Reals: "closed (\<real> :: complex set)"
   216 proof -
   217   have "(\<real> :: complex set) = {z. Im z = 0}"
   218     by (auto simp: complex_is_Real_iff)
   219   then show ?thesis
   220     by (metis closed_halfspace_Im_eq)
   221 qed
   222 
   223 lemma closed_Real_halfspace_Re_le: "closed (\<real> \<inter> {w. Re w \<le> x})"
   224   by (simp add: closed_Int closed_complex_Reals closed_halfspace_Re_le)
   225 
   226 corollary closed_nonpos_Reals_complex [simp]: "closed (\<real>\<^sub>\<le>\<^sub>0 :: complex set)"
   227 proof -
   228   have "\<real>\<^sub>\<le>\<^sub>0 = \<real> \<inter> {z. Re(z) \<le> 0}"
   229     using complex_nonpos_Reals_iff complex_is_Real_iff by auto
   230   then show ?thesis
   231     by (metis closed_Real_halfspace_Re_le)
   232 qed
   233 
   234 lemma closed_Real_halfspace_Re_ge: "closed (\<real> \<inter> {w. x \<le> Re(w)})"
   235   using closed_halfspace_Re_ge
   236   by (simp add: closed_Int closed_complex_Reals)
   237 
   238 corollary closed_nonneg_Reals_complex [simp]: "closed (\<real>\<^sub>\<ge>\<^sub>0 :: complex set)"
   239 proof -
   240   have "\<real>\<^sub>\<ge>\<^sub>0 = \<real> \<inter> {z. Re(z) \<ge> 0}"
   241     using complex_nonneg_Reals_iff complex_is_Real_iff by auto
   242   then show ?thesis
   243     by (metis closed_Real_halfspace_Re_ge)
   244 qed
   245 
   246 lemma closed_real_abs_le: "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   247 proof -
   248   have "{w \<in> \<real>. \<bar>Re w\<bar> \<le> r} = (\<real> \<inter> {w. Re w \<le> r}) \<inter> (\<real> \<inter> {w. Re w \<ge> -r})"
   249     by auto
   250   then show "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   251     by (simp add: closed_Int closed_Real_halfspace_Re_ge closed_Real_halfspace_Re_le)
   252 qed
   253 
   254 lemma real_lim:
   255   fixes l::complex
   256   assumes "(f \<longlongrightarrow> l) F" and "~(trivial_limit F)" and "eventually P F" and "\<And>a. P a \<Longrightarrow> f a \<in> \<real>"
   257   shows  "l \<in> \<real>"
   258 proof (rule Lim_in_closed_set[OF closed_complex_Reals _ assms(2,1)])
   259   show "eventually (\<lambda>x. f x \<in> \<real>) F"
   260     using assms(3, 4) by (auto intro: eventually_mono)
   261 qed
   262 
   263 lemma real_lim_sequentially:
   264   fixes l::complex
   265   shows "(f \<longlongrightarrow> l) sequentially \<Longrightarrow> (\<exists>N. \<forall>n\<ge>N. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   266 by (rule real_lim [where F=sequentially]) (auto simp: eventually_sequentially)
   267 
   268 lemma real_series:
   269   fixes l::complex
   270   shows "f sums l \<Longrightarrow> (\<And>n. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   271 unfolding sums_def
   272 by (metis real_lim_sequentially setsum_in_Reals)
   273 
   274 lemma Lim_null_comparison_Re:
   275   assumes "eventually (\<lambda>x. norm(f x) \<le> Re(g x)) F" "(g \<longlongrightarrow> 0) F" shows "(f \<longlongrightarrow> 0) F"
   276   by (rule Lim_null_comparison[OF assms(1)] tendsto_eq_intros assms(2))+ simp
   277 
   278 subsection\<open>Holomorphic functions\<close>
   279 
   280 text\<open>Could be generalized to real normed fields, but in practice that would only include the reals\<close>
   281 definition complex_differentiable :: "[complex \<Rightarrow> complex, complex filter] \<Rightarrow> bool"
   282            (infixr "(complex'_differentiable)" 50)
   283   where "f complex_differentiable F \<equiv> \<exists>f'. (f has_field_derivative f') F"
   284 
   285 lemma complex_differentiable_imp_continuous_at:
   286     "f complex_differentiable (at x within s) \<Longrightarrow> continuous (at x within s) f"
   287   by (metis DERIV_continuous complex_differentiable_def)
   288 
   289 lemma complex_differentiable_within_subset:
   290     "\<lbrakk>f complex_differentiable (at x within s); t \<subseteq> s\<rbrakk>
   291      \<Longrightarrow> f complex_differentiable (at x within t)"
   292   by (metis DERIV_subset complex_differentiable_def)
   293 
   294 lemma complex_differentiable_at_within:
   295     "\<lbrakk>f complex_differentiable (at x)\<rbrakk>
   296      \<Longrightarrow> f complex_differentiable (at x within s)"
   297   unfolding complex_differentiable_def
   298   by (metis DERIV_subset top_greatest)
   299 
   300 lemma complex_differentiable_linear [derivative_intros]: "(op * c) complex_differentiable F"
   301 proof -
   302   show ?thesis
   303     unfolding complex_differentiable_def has_field_derivative_def mult_commute_abs
   304     by (force intro: has_derivative_mult_right)
   305 qed
   306 
   307 lemma complex_differentiable_const [derivative_intros]: "(\<lambda>z. c) complex_differentiable F"
   308   unfolding complex_differentiable_def has_field_derivative_def
   309   by (rule exI [where x=0])
   310      (metis has_derivative_const lambda_zero)
   311 
   312 lemma complex_differentiable_ident [derivative_intros]: "(\<lambda>z. z) complex_differentiable F"
   313   unfolding complex_differentiable_def has_field_derivative_def
   314   by (rule exI [where x=1])
   315      (simp add: lambda_one [symmetric])
   316 
   317 lemma complex_differentiable_id [derivative_intros]: "id complex_differentiable F"
   318   unfolding id_def by (rule complex_differentiable_ident)
   319 
   320 lemma complex_differentiable_minus [derivative_intros]:
   321   "f complex_differentiable F \<Longrightarrow> (\<lambda>z. - (f z)) complex_differentiable F"
   322   using assms unfolding complex_differentiable_def
   323   by (metis field_differentiable_minus)
   324 
   325 lemma complex_differentiable_add [derivative_intros]:
   326   assumes "f complex_differentiable F" "g complex_differentiable F"
   327     shows "(\<lambda>z. f z + g z) complex_differentiable F"
   328   using assms unfolding complex_differentiable_def
   329   by (metis field_differentiable_add)
   330 
   331 lemma complex_differentiable_setsum [derivative_intros]:
   332   "(\<And>i. i \<in> I \<Longrightarrow> (f i) complex_differentiable F) \<Longrightarrow> (\<lambda>z. \<Sum>i\<in>I. f i z) complex_differentiable F"
   333   by (induct I rule: infinite_finite_induct)
   334      (auto intro: complex_differentiable_add complex_differentiable_const)
   335 
   336 lemma complex_differentiable_diff [derivative_intros]:
   337   assumes "f complex_differentiable F" "g complex_differentiable F"
   338     shows "(\<lambda>z. f z - g z) complex_differentiable F"
   339   using assms unfolding complex_differentiable_def
   340   by (metis field_differentiable_diff)
   341 
   342 lemma complex_differentiable_inverse [derivative_intros]:
   343   assumes "f complex_differentiable (at a within s)" "f a \<noteq> 0"
   344   shows "(\<lambda>z. inverse (f z)) complex_differentiable (at a within s)"
   345   using assms unfolding complex_differentiable_def
   346   by (metis DERIV_inverse_fun)
   347 
   348 lemma complex_differentiable_mult [derivative_intros]:
   349   assumes "f complex_differentiable (at a within s)"
   350           "g complex_differentiable (at a within s)"
   351     shows "(\<lambda>z. f z * g z) complex_differentiable (at a within s)"
   352   using assms unfolding complex_differentiable_def
   353   by (metis DERIV_mult [of f _ a s g])
   354 
   355 lemma complex_differentiable_divide [derivative_intros]:
   356   assumes "f complex_differentiable (at a within s)"
   357           "g complex_differentiable (at a within s)"
   358           "g a \<noteq> 0"
   359     shows "(\<lambda>z. f z / g z) complex_differentiable (at a within s)"
   360   using assms unfolding complex_differentiable_def
   361   by (metis DERIV_divide [of f _ a s g])
   362 
   363 lemma complex_differentiable_power [derivative_intros]:
   364   assumes "f complex_differentiable (at a within s)"
   365     shows "(\<lambda>z. f z ^ n) complex_differentiable (at a within s)"
   366   using assms unfolding complex_differentiable_def
   367   by (metis DERIV_power)
   368 
   369 lemma complex_differentiable_transform_within:
   370   "0 < d \<Longrightarrow>
   371         x \<in> s \<Longrightarrow>
   372         (\<And>x'. x' \<in> s \<Longrightarrow> dist x' x < d \<Longrightarrow> f x' = g x') \<Longrightarrow>
   373         f complex_differentiable (at x within s)
   374         \<Longrightarrow> g complex_differentiable (at x within s)"
   375   unfolding complex_differentiable_def has_field_derivative_def
   376   by (blast intro: has_derivative_transform_within)
   377 
   378 lemma complex_differentiable_compose_within:
   379   assumes "f complex_differentiable (at a within s)"
   380           "g complex_differentiable (at (f a) within f`s)"
   381     shows "(g o f) complex_differentiable (at a within s)"
   382   using assms unfolding complex_differentiable_def
   383   by (metis DERIV_image_chain)
   384 
   385 lemma complex_differentiable_compose:
   386   "f complex_differentiable at z \<Longrightarrow> g complex_differentiable at (f z)
   387           \<Longrightarrow> (g o f) complex_differentiable at z"
   388 by (metis complex_differentiable_at_within complex_differentiable_compose_within)
   389 
   390 lemma complex_differentiable_within_open:
   391      "\<lbrakk>a \<in> s; open s\<rbrakk> \<Longrightarrow> f complex_differentiable at a within s \<longleftrightarrow>
   392                           f complex_differentiable at a"
   393   unfolding complex_differentiable_def
   394   by (metis at_within_open)
   395 
   396 subsection\<open>Caratheodory characterization.\<close>
   397 
   398 lemma complex_differentiable_caratheodory_at:
   399   "f complex_differentiable (at z) \<longleftrightarrow>
   400          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z) g)"
   401   using CARAT_DERIV [of f]
   402   by (simp add: complex_differentiable_def has_field_derivative_def)
   403 
   404 lemma complex_differentiable_caratheodory_within:
   405   "f complex_differentiable (at z within s) \<longleftrightarrow>
   406          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z within s) g)"
   407   using DERIV_caratheodory_within [of f]
   408   by (simp add: complex_differentiable_def has_field_derivative_def)
   409 
   410 subsection\<open>Holomorphic\<close>
   411 
   412 definition holomorphic_on :: "[complex \<Rightarrow> complex, complex set] \<Rightarrow> bool"
   413            (infixl "(holomorphic'_on)" 50)
   414   where "f holomorphic_on s \<equiv> \<forall>x\<in>s. f complex_differentiable (at x within s)"
   415 
   416 named_theorems holomorphic_intros "structural introduction rules for holomorphic_on"
   417 
   418 lemma holomorphic_onI [intro?]: "(\<And>x. x \<in> s \<Longrightarrow> f complex_differentiable (at x within s)) \<Longrightarrow> f holomorphic_on s"
   419   by (simp add: holomorphic_on_def)
   420 
   421 lemma holomorphic_onD [dest?]: "\<lbrakk>f holomorphic_on s; x \<in> s\<rbrakk> \<Longrightarrow> f complex_differentiable (at x within s)"
   422   by (simp add: holomorphic_on_def)
   423 
   424 lemma holomorphic_on_imp_differentiable_at:
   425    "\<lbrakk>f holomorphic_on s; open s; x \<in> s\<rbrakk> \<Longrightarrow> f complex_differentiable (at x)"
   426 using at_within_open holomorphic_on_def by fastforce
   427 
   428 lemma holomorphic_on_empty [holomorphic_intros]: "f holomorphic_on {}"
   429   by (simp add: holomorphic_on_def)
   430 
   431 lemma holomorphic_on_open:
   432     "open s \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> (\<forall>x \<in> s. \<exists>f'. DERIV f x :> f')"
   433   by (auto simp: holomorphic_on_def complex_differentiable_def has_field_derivative_def at_within_open [of _ s])
   434 
   435 lemma holomorphic_on_imp_continuous_on:
   436     "f holomorphic_on s \<Longrightarrow> continuous_on s f"
   437   by (metis complex_differentiable_imp_continuous_at continuous_on_eq_continuous_within holomorphic_on_def)
   438 
   439 lemma holomorphic_on_subset:
   440     "f holomorphic_on s \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f holomorphic_on t"
   441   unfolding holomorphic_on_def
   442   by (metis complex_differentiable_within_subset subsetD)
   443 
   444 lemma holomorphic_transform: "\<lbrakk>f holomorphic_on s; \<And>x. x \<in> s \<Longrightarrow> f x = g x\<rbrakk> \<Longrightarrow> g holomorphic_on s"
   445   by (metis complex_differentiable_transform_within linordered_field_no_ub holomorphic_on_def)
   446 
   447 lemma holomorphic_cong: "s = t ==> (\<And>x. x \<in> s \<Longrightarrow> f x = g x) \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> g holomorphic_on t"
   448   by (metis holomorphic_transform)
   449 
   450 lemma holomorphic_on_linear [simp, holomorphic_intros]: "(op * c) holomorphic_on s"
   451   unfolding holomorphic_on_def by (metis complex_differentiable_linear)
   452 
   453 lemma holomorphic_on_const [simp, holomorphic_intros]: "(\<lambda>z. c) holomorphic_on s"
   454   unfolding holomorphic_on_def by (metis complex_differentiable_const)
   455 
   456 lemma holomorphic_on_ident [simp, holomorphic_intros]: "(\<lambda>x. x) holomorphic_on s"
   457   unfolding holomorphic_on_def by (metis complex_differentiable_ident)
   458 
   459 lemma holomorphic_on_id [simp, holomorphic_intros]: "id holomorphic_on s"
   460   unfolding id_def by (rule holomorphic_on_ident)
   461 
   462 lemma holomorphic_on_compose:
   463   "f holomorphic_on s \<Longrightarrow> g holomorphic_on (f ` s) \<Longrightarrow> (g o f) holomorphic_on s"
   464   using complex_differentiable_compose_within[of f _ s g]
   465   by (auto simp: holomorphic_on_def)
   466 
   467 lemma holomorphic_on_compose_gen:
   468   "f holomorphic_on s \<Longrightarrow> g holomorphic_on t \<Longrightarrow> f ` s \<subseteq> t \<Longrightarrow> (g o f) holomorphic_on s"
   469   by (metis holomorphic_on_compose holomorphic_on_subset)
   470 
   471 lemma holomorphic_on_minus [holomorphic_intros]: "f holomorphic_on s \<Longrightarrow> (\<lambda>z. -(f z)) holomorphic_on s"
   472   by (metis complex_differentiable_minus holomorphic_on_def)
   473 
   474 lemma holomorphic_on_add [holomorphic_intros]:
   475   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z + g z) holomorphic_on s"
   476   unfolding holomorphic_on_def by (metis complex_differentiable_add)
   477 
   478 lemma holomorphic_on_diff [holomorphic_intros]:
   479   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z - g z) holomorphic_on s"
   480   unfolding holomorphic_on_def by (metis complex_differentiable_diff)
   481 
   482 lemma holomorphic_on_mult [holomorphic_intros]:
   483   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z * g z) holomorphic_on s"
   484   unfolding holomorphic_on_def by (metis complex_differentiable_mult)
   485 
   486 lemma holomorphic_on_inverse [holomorphic_intros]:
   487   "\<lbrakk>f holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> f z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. inverse (f z)) holomorphic_on s"
   488   unfolding holomorphic_on_def by (metis complex_differentiable_inverse)
   489 
   490 lemma holomorphic_on_divide [holomorphic_intros]:
   491   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> g z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. f z / g z) holomorphic_on s"
   492   unfolding holomorphic_on_def by (metis complex_differentiable_divide)
   493 
   494 lemma holomorphic_on_power [holomorphic_intros]:
   495   "f holomorphic_on s \<Longrightarrow> (\<lambda>z. (f z)^n) holomorphic_on s"
   496   unfolding holomorphic_on_def by (metis complex_differentiable_power)
   497 
   498 lemma holomorphic_on_setsum [holomorphic_intros]:
   499   "(\<And>i. i \<in> I \<Longrightarrow> (f i) holomorphic_on s) \<Longrightarrow> (\<lambda>x. setsum (\<lambda>i. f i x) I) holomorphic_on s"
   500   unfolding holomorphic_on_def by (metis complex_differentiable_setsum)
   501 
   502 lemma DERIV_deriv_iff_complex_differentiable:
   503   "DERIV f x :> deriv f x \<longleftrightarrow> f complex_differentiable at x"
   504   unfolding complex_differentiable_def by (metis DERIV_imp_deriv)
   505 
   506 lemma complex_derivative_chain:
   507   "f complex_differentiable at x \<Longrightarrow> g complex_differentiable at (f x)
   508     \<Longrightarrow> deriv (g o f) x = deriv g (f x) * deriv f x"
   509   by (metis DERIV_deriv_iff_complex_differentiable DERIV_chain DERIV_imp_deriv)
   510 
   511 lemma deriv_linear: "deriv (\<lambda>w. c * w) = (\<lambda>z. c)"
   512   by (metis DERIV_imp_deriv DERIV_cmult_Id)
   513 
   514 lemma deriv_ident: "deriv (\<lambda>w. w) = (\<lambda>z. 1)"
   515   by (metis DERIV_imp_deriv DERIV_ident)
   516 
   517 lemma deriv_const: "deriv (\<lambda>w. c) = (\<lambda>z. 0)"
   518   by (metis DERIV_imp_deriv DERIV_const)
   519 
   520 lemma complex_derivative_add:
   521   "\<lbrakk>f complex_differentiable at z; g complex_differentiable at z\<rbrakk>
   522    \<Longrightarrow> deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   523   unfolding DERIV_deriv_iff_complex_differentiable[symmetric]
   524   by (auto intro!: DERIV_imp_deriv derivative_intros)
   525 
   526 lemma complex_derivative_diff:
   527   "\<lbrakk>f complex_differentiable at z; g complex_differentiable at z\<rbrakk>
   528    \<Longrightarrow> deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   529   unfolding DERIV_deriv_iff_complex_differentiable[symmetric]
   530   by (auto intro!: DERIV_imp_deriv derivative_intros)
   531 
   532 lemma complex_derivative_mult:
   533   "\<lbrakk>f complex_differentiable at z; g complex_differentiable at z\<rbrakk>
   534    \<Longrightarrow> deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   535   unfolding DERIV_deriv_iff_complex_differentiable[symmetric]
   536   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   537 
   538 lemma complex_derivative_cmult:
   539   "f complex_differentiable at z \<Longrightarrow> deriv (\<lambda>w. c * f w) z = c * deriv f z"
   540   unfolding DERIV_deriv_iff_complex_differentiable[symmetric]
   541   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   542 
   543 lemma complex_derivative_cmult_right:
   544   "f complex_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w * c) z = deriv f z * c"
   545   unfolding DERIV_deriv_iff_complex_differentiable[symmetric]
   546   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   547 
   548 lemma complex_derivative_cdivide_right:
   549   "f complex_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w / c) z = deriv f z / c"
   550   unfolding Fields.field_class.field_divide_inverse
   551   by (blast intro: complex_derivative_cmult_right)
   552 
   553 lemma complex_derivative_transform_within_open:
   554   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; open s; z \<in> s; \<And>w. w \<in> s \<Longrightarrow> f w = g w\<rbrakk>
   555    \<Longrightarrow> deriv f z = deriv g z"
   556   unfolding holomorphic_on_def
   557   by (rule DERIV_imp_deriv)
   558      (metis DERIV_deriv_iff_complex_differentiable DERIV_transform_within_open at_within_open)
   559 
   560 lemma complex_derivative_compose_linear:
   561   "f complex_differentiable at (c * z) \<Longrightarrow> deriv (\<lambda>w. f (c * w)) z = c * deriv f (c * z)"
   562 apply (rule DERIV_imp_deriv)
   563 apply (simp add: DERIV_deriv_iff_complex_differentiable [symmetric])
   564 apply (drule DERIV_chain' [of "times c" c z UNIV f "deriv f (c * z)", OF DERIV_cmult_Id])
   565 apply (simp add: algebra_simps)
   566 done
   567 
   568 subsection\<open>Analyticity on a set\<close>
   569 
   570 definition analytic_on (infixl "(analytic'_on)" 50)
   571   where
   572    "f analytic_on s \<equiv> \<forall>x \<in> s. \<exists>e. 0 < e \<and> f holomorphic_on (ball x e)"
   573 
   574 lemma analytic_imp_holomorphic: "f analytic_on s \<Longrightarrow> f holomorphic_on s"
   575   by (simp add: at_within_open [OF _ open_ball] analytic_on_def holomorphic_on_def)
   576      (metis centre_in_ball complex_differentiable_at_within)
   577 
   578 lemma analytic_on_open: "open s \<Longrightarrow> f analytic_on s \<longleftrightarrow> f holomorphic_on s"
   579 apply (auto simp: analytic_imp_holomorphic)
   580 apply (auto simp: analytic_on_def holomorphic_on_def)
   581 by (metis holomorphic_on_def holomorphic_on_subset open_contains_ball)
   582 
   583 lemma analytic_on_imp_differentiable_at:
   584   "f analytic_on s \<Longrightarrow> x \<in> s \<Longrightarrow> f complex_differentiable (at x)"
   585  apply (auto simp: analytic_on_def holomorphic_on_def)
   586 by (metis Topology_Euclidean_Space.open_ball centre_in_ball complex_differentiable_within_open)
   587 
   588 lemma analytic_on_subset: "f analytic_on s \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f analytic_on t"
   589   by (auto simp: analytic_on_def)
   590 
   591 lemma analytic_on_Un: "f analytic_on (s \<union> t) \<longleftrightarrow> f analytic_on s \<and> f analytic_on t"
   592   by (auto simp: analytic_on_def)
   593 
   594 lemma analytic_on_Union: "f analytic_on (\<Union>s) \<longleftrightarrow> (\<forall>t \<in> s. f analytic_on t)"
   595   by (auto simp: analytic_on_def)
   596 
   597 lemma analytic_on_UN: "f analytic_on (\<Union>i\<in>I. s i) \<longleftrightarrow> (\<forall>i\<in>I. f analytic_on (s i))"
   598   by (auto simp: analytic_on_def)
   599 
   600 lemma analytic_on_holomorphic:
   601   "f analytic_on s \<longleftrightarrow> (\<exists>t. open t \<and> s \<subseteq> t \<and> f holomorphic_on t)"
   602   (is "?lhs = ?rhs")
   603 proof -
   604   have "?lhs \<longleftrightarrow> (\<exists>t. open t \<and> s \<subseteq> t \<and> f analytic_on t)"
   605   proof safe
   606     assume "f analytic_on s"
   607     then show "\<exists>t. open t \<and> s \<subseteq> t \<and> f analytic_on t"
   608       apply (simp add: analytic_on_def)
   609       apply (rule exI [where x="\<Union>{u. open u \<and> f analytic_on u}"], auto)
   610       apply (metis Topology_Euclidean_Space.open_ball analytic_on_open centre_in_ball)
   611       by (metis analytic_on_def)
   612   next
   613     fix t
   614     assume "open t" "s \<subseteq> t" "f analytic_on t"
   615     then show "f analytic_on s"
   616         by (metis analytic_on_subset)
   617   qed
   618   also have "... \<longleftrightarrow> ?rhs"
   619     by (auto simp: analytic_on_open)
   620   finally show ?thesis .
   621 qed
   622 
   623 lemma analytic_on_linear: "(op * c) analytic_on s"
   624   by (auto simp add: analytic_on_holomorphic holomorphic_on_linear)
   625 
   626 lemma analytic_on_const: "(\<lambda>z. c) analytic_on s"
   627   by (metis analytic_on_def holomorphic_on_const zero_less_one)
   628 
   629 lemma analytic_on_ident: "(\<lambda>x. x) analytic_on s"
   630   by (simp add: analytic_on_def holomorphic_on_ident gt_ex)
   631 
   632 lemma analytic_on_id: "id analytic_on s"
   633   unfolding id_def by (rule analytic_on_ident)
   634 
   635 lemma analytic_on_compose:
   636   assumes f: "f analytic_on s"
   637       and g: "g analytic_on (f ` s)"
   638     shows "(g o f) analytic_on s"
   639 unfolding analytic_on_def
   640 proof (intro ballI)
   641   fix x
   642   assume x: "x \<in> s"
   643   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball x e" using f
   644     by (metis analytic_on_def)
   645   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball (f x) e'" using g
   646     by (metis analytic_on_def g image_eqI x)
   647   have "isCont f x"
   648     by (metis analytic_on_imp_differentiable_at complex_differentiable_imp_continuous_at f x)
   649   with e' obtain d where d: "0 < d" and fd: "f ` ball x d \<subseteq> ball (f x) e'"
   650      by (auto simp: continuous_at_ball)
   651   have "g \<circ> f holomorphic_on ball x (min d e)"
   652     apply (rule holomorphic_on_compose)
   653     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   654     by (metis fd gh holomorphic_on_subset image_mono min.cobounded1 subset_ball)
   655   then show "\<exists>e>0. g \<circ> f holomorphic_on ball x e"
   656     by (metis d e min_less_iff_conj)
   657 qed
   658 
   659 lemma analytic_on_compose_gen:
   660   "f analytic_on s \<Longrightarrow> g analytic_on t \<Longrightarrow> (\<And>z. z \<in> s \<Longrightarrow> f z \<in> t)
   661              \<Longrightarrow> g o f analytic_on s"
   662 by (metis analytic_on_compose analytic_on_subset image_subset_iff)
   663 
   664 lemma analytic_on_neg:
   665   "f analytic_on s \<Longrightarrow> (\<lambda>z. -(f z)) analytic_on s"
   666 by (metis analytic_on_holomorphic holomorphic_on_minus)
   667 
   668 lemma analytic_on_add:
   669   assumes f: "f analytic_on s"
   670       and g: "g analytic_on s"
   671     shows "(\<lambda>z. f z + g z) analytic_on s"
   672 unfolding analytic_on_def
   673 proof (intro ballI)
   674   fix z
   675   assume z: "z \<in> s"
   676   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   677     by (metis analytic_on_def)
   678   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   679     by (metis analytic_on_def g z)
   680   have "(\<lambda>z. f z + g z) holomorphic_on ball z (min e e')"
   681     apply (rule holomorphic_on_add)
   682     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   683     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   684   then show "\<exists>e>0. (\<lambda>z. f z + g z) holomorphic_on ball z e"
   685     by (metis e e' min_less_iff_conj)
   686 qed
   687 
   688 lemma analytic_on_diff:
   689   assumes f: "f analytic_on s"
   690       and g: "g analytic_on s"
   691     shows "(\<lambda>z. f z - g z) analytic_on s"
   692 unfolding analytic_on_def
   693 proof (intro ballI)
   694   fix z
   695   assume z: "z \<in> s"
   696   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   697     by (metis analytic_on_def)
   698   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   699     by (metis analytic_on_def g z)
   700   have "(\<lambda>z. f z - g z) holomorphic_on ball z (min e e')"
   701     apply (rule holomorphic_on_diff)
   702     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   703     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   704   then show "\<exists>e>0. (\<lambda>z. f z - g z) holomorphic_on ball z e"
   705     by (metis e e' min_less_iff_conj)
   706 qed
   707 
   708 lemma analytic_on_mult:
   709   assumes f: "f analytic_on s"
   710       and g: "g analytic_on s"
   711     shows "(\<lambda>z. f z * g z) analytic_on s"
   712 unfolding analytic_on_def
   713 proof (intro ballI)
   714   fix z
   715   assume z: "z \<in> s"
   716   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   717     by (metis analytic_on_def)
   718   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   719     by (metis analytic_on_def g z)
   720   have "(\<lambda>z. f z * g z) holomorphic_on ball z (min e e')"
   721     apply (rule holomorphic_on_mult)
   722     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   723     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   724   then show "\<exists>e>0. (\<lambda>z. f z * g z) holomorphic_on ball z e"
   725     by (metis e e' min_less_iff_conj)
   726 qed
   727 
   728 lemma analytic_on_inverse:
   729   assumes f: "f analytic_on s"
   730       and nz: "(\<And>z. z \<in> s \<Longrightarrow> f z \<noteq> 0)"
   731     shows "(\<lambda>z. inverse (f z)) analytic_on s"
   732 unfolding analytic_on_def
   733 proof (intro ballI)
   734   fix z
   735   assume z: "z \<in> s"
   736   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   737     by (metis analytic_on_def)
   738   have "continuous_on (ball z e) f"
   739     by (metis fh holomorphic_on_imp_continuous_on)
   740   then obtain e' where e': "0 < e'" and nz': "\<And>y. dist z y < e' \<Longrightarrow> f y \<noteq> 0"
   741     by (metis Topology_Euclidean_Space.open_ball centre_in_ball continuous_on_open_avoid e z nz)
   742   have "(\<lambda>z. inverse (f z)) holomorphic_on ball z (min e e')"
   743     apply (rule holomorphic_on_inverse)
   744     apply (metis fh holomorphic_on_subset min.cobounded2 min.commute subset_ball)
   745     by (metis nz' mem_ball min_less_iff_conj)
   746   then show "\<exists>e>0. (\<lambda>z. inverse (f z)) holomorphic_on ball z e"
   747     by (metis e e' min_less_iff_conj)
   748 qed
   749 
   750 
   751 lemma analytic_on_divide:
   752   assumes f: "f analytic_on s"
   753       and g: "g analytic_on s"
   754       and nz: "(\<And>z. z \<in> s \<Longrightarrow> g z \<noteq> 0)"
   755     shows "(\<lambda>z. f z / g z) analytic_on s"
   756 unfolding divide_inverse
   757 by (metis analytic_on_inverse analytic_on_mult f g nz)
   758 
   759 lemma analytic_on_power:
   760   "f analytic_on s \<Longrightarrow> (\<lambda>z. (f z) ^ n) analytic_on s"
   761 by (induct n) (auto simp: analytic_on_const analytic_on_mult)
   762 
   763 lemma analytic_on_setsum:
   764   "(\<And>i. i \<in> I \<Longrightarrow> (f i) analytic_on s) \<Longrightarrow> (\<lambda>x. setsum (\<lambda>i. f i x) I) analytic_on s"
   765   by (induct I rule: infinite_finite_induct) (auto simp: analytic_on_const analytic_on_add)
   766 
   767 subsection\<open>analyticity at a point.\<close>
   768 
   769 lemma analytic_at_ball:
   770   "f analytic_on {z} \<longleftrightarrow> (\<exists>e. 0<e \<and> f holomorphic_on ball z e)"
   771 by (metis analytic_on_def singleton_iff)
   772 
   773 lemma analytic_at:
   774     "f analytic_on {z} \<longleftrightarrow> (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s)"
   775 by (metis analytic_on_holomorphic empty_subsetI insert_subset)
   776 
   777 lemma analytic_on_analytic_at:
   778     "f analytic_on s \<longleftrightarrow> (\<forall>z \<in> s. f analytic_on {z})"
   779 by (metis analytic_at_ball analytic_on_def)
   780 
   781 lemma analytic_at_two:
   782   "f analytic_on {z} \<and> g analytic_on {z} \<longleftrightarrow>
   783    (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s \<and> g holomorphic_on s)"
   784   (is "?lhs = ?rhs")
   785 proof
   786   assume ?lhs
   787   then obtain s t
   788     where st: "open s" "z \<in> s" "f holomorphic_on s"
   789               "open t" "z \<in> t" "g holomorphic_on t"
   790     by (auto simp: analytic_at)
   791   show ?rhs
   792     apply (rule_tac x="s \<inter> t" in exI)
   793     using st
   794     apply (auto simp: Diff_subset holomorphic_on_subset)
   795     done
   796 next
   797   assume ?rhs
   798   then show ?lhs
   799     by (force simp add: analytic_at)
   800 qed
   801 
   802 subsection\<open>Combining theorems for derivative with ``analytic at'' hypotheses\<close>
   803 
   804 lemma
   805   assumes "f analytic_on {z}" "g analytic_on {z}"
   806   shows complex_derivative_add_at: "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   807     and complex_derivative_diff_at: "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   808     and complex_derivative_mult_at: "deriv (\<lambda>w. f w * g w) z =
   809            f z * deriv g z + deriv f z * g z"
   810 proof -
   811   obtain s where s: "open s" "z \<in> s" "f holomorphic_on s" "g holomorphic_on s"
   812     using assms by (metis analytic_at_two)
   813   show "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   814     apply (rule DERIV_imp_deriv [OF DERIV_add])
   815     using s
   816     apply (auto simp: holomorphic_on_open complex_differentiable_def DERIV_deriv_iff_complex_differentiable)
   817     done
   818   show "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   819     apply (rule DERIV_imp_deriv [OF DERIV_diff])
   820     using s
   821     apply (auto simp: holomorphic_on_open complex_differentiable_def DERIV_deriv_iff_complex_differentiable)
   822     done
   823   show "deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   824     apply (rule DERIV_imp_deriv [OF DERIV_mult'])
   825     using s
   826     apply (auto simp: holomorphic_on_open complex_differentiable_def DERIV_deriv_iff_complex_differentiable)
   827     done
   828 qed
   829 
   830 lemma complex_derivative_cmult_at:
   831   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. c * f w) z = c * deriv f z"
   832 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   833 
   834 lemma complex_derivative_cmult_right_at:
   835   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. f w * c) z = deriv f z * c"
   836 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   837 
   838 subsection\<open>Complex differentiation of sequences and series\<close>
   839 
   840 (* TODO: Could probably be simplified using Uniform_Limit *)
   841 lemma has_complex_derivative_sequence:
   842   fixes s :: "complex set"
   843   assumes cvs: "convex s"
   844       and df:  "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x within s)"
   845       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> s \<longrightarrow> norm (f' n x - g' x) \<le> e"
   846       and "\<exists>x l. x \<in> s \<and> ((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   847     shows "\<exists>g. \<forall>x \<in> s. ((\<lambda>n. f n x) \<longlongrightarrow> g x) sequentially \<and>
   848                        (g has_field_derivative (g' x)) (at x within s)"
   849 proof -
   850   from assms obtain x l where x: "x \<in> s" and tf: "((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   851     by blast
   852   { fix e::real assume e: "e > 0"
   853     then obtain N where N: "\<forall>n\<ge>N. \<forall>x. x \<in> s \<longrightarrow> cmod (f' n x - g' x) \<le> e"
   854       by (metis conv)
   855     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   856     proof (rule exI [of _ N], clarify)
   857       fix n y h
   858       assume "N \<le> n" "y \<in> s"
   859       then have "cmod (f' n y - g' y) \<le> e"
   860         by (metis N)
   861       then have "cmod h * cmod (f' n y - g' y) \<le> cmod h * e"
   862         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   863       then show "cmod (f' n y * h - g' y * h) \<le> e * cmod h"
   864         by (simp add: norm_mult [symmetric] field_simps)
   865     qed
   866   } note ** = this
   867   show ?thesis
   868   unfolding has_field_derivative_def
   869   proof (rule has_derivative_sequence [OF cvs _ _ x])
   870     show "\<forall>n. \<forall>x\<in>s. (f n has_derivative (op * (f' n x))) (at x within s)"
   871       by (metis has_field_derivative_def df)
   872   next show "(\<lambda>n. f n x) \<longlonglongrightarrow> l"
   873     by (rule tf)
   874   next show "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   875     by (blast intro: **)
   876   qed
   877 qed
   878 
   879 
   880 lemma has_complex_derivative_series:
   881   fixes s :: "complex set"
   882   assumes cvs: "convex s"
   883       and df:  "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x within s)"
   884       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> s
   885                 \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   886       and "\<exists>x l. x \<in> s \<and> ((\<lambda>n. f n x) sums l)"
   887     shows "\<exists>g. \<forall>x \<in> s. ((\<lambda>n. f n x) sums g x) \<and> ((g has_field_derivative g' x) (at x within s))"
   888 proof -
   889   from assms obtain x l where x: "x \<in> s" and sf: "((\<lambda>n. f n x) sums l)"
   890     by blast
   891   { fix e::real assume e: "e > 0"
   892     then obtain N where N: "\<forall>n x. n \<ge> N \<longrightarrow> x \<in> s
   893             \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   894       by (metis conv)
   895     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   896     proof (rule exI [of _ N], clarify)
   897       fix n y h
   898       assume "N \<le> n" "y \<in> s"
   899       then have "cmod ((\<Sum>i<n. f' i y) - g' y) \<le> e"
   900         by (metis N)
   901       then have "cmod h * cmod ((\<Sum>i<n. f' i y) - g' y) \<le> cmod h * e"
   902         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   903       then show "cmod ((\<Sum>i<n. h * f' i y) - g' y * h) \<le> e * cmod h"
   904         by (simp add: norm_mult [symmetric] field_simps setsum_right_distrib)
   905     qed
   906   } note ** = this
   907   show ?thesis
   908   unfolding has_field_derivative_def
   909   proof (rule has_derivative_series [OF cvs _ _ x])
   910     fix n x
   911     assume "x \<in> s"
   912     then show "((f n) has_derivative (\<lambda>z. z * f' n x)) (at x within s)"
   913       by (metis df has_field_derivative_def mult_commute_abs)
   914   next show " ((\<lambda>n. f n x) sums l)"
   915     by (rule sf)
   916   next show "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   917     by (blast intro: **)
   918   qed
   919 qed
   920 
   921 
   922 lemma complex_differentiable_series:
   923   fixes f :: "nat \<Rightarrow> complex \<Rightarrow> complex"
   924   assumes "convex s" "open s"
   925   assumes "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x)"
   926   assumes "uniformly_convergent_on s (\<lambda>n x. \<Sum>i<n. f' i x)"
   927   assumes "x0 \<in> s" "summable (\<lambda>n. f n x0)" and x: "x \<in> s"
   928   shows   "summable (\<lambda>n. f n x)" and "(\<lambda>x. \<Sum>n. f n x) complex_differentiable (at x)"
   929 proof -
   930   from assms(4) obtain g' where A: "uniform_limit s (\<lambda>n x. \<Sum>i<n. f' i x) g' sequentially"
   931     unfolding uniformly_convergent_on_def by blast
   932   from x and \<open>open s\<close> have s: "at x within s = at x" by (rule at_within_open)
   933   have "\<exists>g. \<forall>x\<in>s. (\<lambda>n. f n x) sums g x \<and> (g has_field_derivative g' x) (at x within s)"
   934     by (intro has_field_derivative_series[of s f f' g' x0] assms A has_field_derivative_at_within)
   935   then obtain g where g: "\<And>x. x \<in> s \<Longrightarrow> (\<lambda>n. f n x) sums g x"
   936     "\<And>x. x \<in> s \<Longrightarrow> (g has_field_derivative g' x) (at x within s)" by blast
   937   from g[OF x] show "summable (\<lambda>n. f n x)" by (auto simp: summable_def)
   938   from g(2)[OF x] have g': "(g has_derivative op * (g' x)) (at x)"
   939     by (simp add: has_field_derivative_def s)
   940   have "((\<lambda>x. \<Sum>n. f n x) has_derivative op * (g' x)) (at x)"
   941     by (rule has_derivative_transform_within_open[OF g' \<open>open s\<close> x])
   942        (insert g, auto simp: sums_iff)
   943   thus "(\<lambda>x. \<Sum>n. f n x) complex_differentiable (at x)" unfolding differentiable_def
   944     by (auto simp: summable_def complex_differentiable_def has_field_derivative_def)
   945 qed
   946 
   947 lemma complex_differentiable_series':
   948   fixes f :: "nat \<Rightarrow> complex \<Rightarrow> complex"
   949   assumes "convex s" "open s"
   950   assumes "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x)"
   951   assumes "uniformly_convergent_on s (\<lambda>n x. \<Sum>i<n. f' i x)"
   952   assumes "x0 \<in> s" "summable (\<lambda>n. f n x0)"
   953   shows   "(\<lambda>x. \<Sum>n. f n x) complex_differentiable (at x0)"
   954   using complex_differentiable_series[OF assms, of x0] \<open>x0 \<in> s\<close> by blast+
   955 
   956 subsection\<open>Bound theorem\<close>
   957 
   958 lemma complex_differentiable_bound:
   959   fixes s :: "complex set"
   960   assumes cvs: "convex s"
   961       and df:  "\<And>z. z \<in> s \<Longrightarrow> (f has_field_derivative f' z) (at z within s)"
   962       and dn:  "\<And>z. z \<in> s \<Longrightarrow> norm (f' z) \<le> B"
   963       and "x \<in> s"  "y \<in> s"
   964     shows "norm(f x - f y) \<le> B * norm(x - y)"
   965   apply (rule differentiable_bound [OF cvs])
   966   apply (rule ballI, erule df [unfolded has_field_derivative_def])
   967   apply (rule ballI, rule onorm_le, simp add: norm_mult mult_right_mono dn)
   968   apply fact
   969   apply fact
   970   done
   971 
   972 subsection\<open>Inverse function theorem for complex derivatives.\<close>
   973 
   974 lemma has_complex_derivative_inverse_basic:
   975   fixes f :: "complex \<Rightarrow> complex"
   976   shows "DERIV f (g y) :> f' \<Longrightarrow>
   977         f' \<noteq> 0 \<Longrightarrow>
   978         continuous (at y) g \<Longrightarrow>
   979         open t \<Longrightarrow>
   980         y \<in> t \<Longrightarrow>
   981         (\<And>z. z \<in> t \<Longrightarrow> f (g z) = z)
   982         \<Longrightarrow> DERIV g y :> inverse (f')"
   983   unfolding has_field_derivative_def
   984   apply (rule has_derivative_inverse_basic)
   985   apply (auto simp:  bounded_linear_mult_right)
   986   done
   987 
   988 (*Used only once, in Multivariate/cauchy.ml. *)
   989 lemma has_complex_derivative_inverse_strong:
   990   fixes f :: "complex \<Rightarrow> complex"
   991   shows "DERIV f x :> f' \<Longrightarrow>
   992          f' \<noteq> 0 \<Longrightarrow>
   993          open s \<Longrightarrow>
   994          x \<in> s \<Longrightarrow>
   995          continuous_on s f \<Longrightarrow>
   996          (\<And>z. z \<in> s \<Longrightarrow> g (f z) = z)
   997          \<Longrightarrow> DERIV g (f x) :> inverse (f')"
   998   unfolding has_field_derivative_def
   999   apply (rule has_derivative_inverse_strong [of s x f g ])
  1000   using assms
  1001   by auto
  1002 
  1003 lemma has_complex_derivative_inverse_strong_x:
  1004   fixes f :: "complex \<Rightarrow> complex"
  1005   shows  "DERIV f (g y) :> f' \<Longrightarrow>
  1006           f' \<noteq> 0 \<Longrightarrow>
  1007           open s \<Longrightarrow>
  1008           continuous_on s f \<Longrightarrow>
  1009           g y \<in> s \<Longrightarrow> f(g y) = y \<Longrightarrow>
  1010           (\<And>z. z \<in> s \<Longrightarrow> g (f z) = z)
  1011           \<Longrightarrow> DERIV g y :> inverse (f')"
  1012   unfolding has_field_derivative_def
  1013   apply (rule has_derivative_inverse_strong_x [of s g y f])
  1014   using assms
  1015   by auto
  1016 
  1017 subsection \<open>Taylor on Complex Numbers\<close>
  1018 
  1019 lemma setsum_Suc_reindex:
  1020   fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
  1021     shows  "setsum f {0..n} = f 0 - f (Suc n) + setsum (\<lambda>i. f (Suc i)) {0..n}"
  1022 by (induct n) auto
  1023 
  1024 lemma complex_taylor:
  1025   assumes s: "convex s"
  1026       and f: "\<And>i x. x \<in> s \<Longrightarrow> i \<le> n \<Longrightarrow> (f i has_field_derivative f (Suc i) x) (at x within s)"
  1027       and B: "\<And>x. x \<in> s \<Longrightarrow> cmod (f (Suc n) x) \<le> B"
  1028       and w: "w \<in> s"
  1029       and z: "z \<in> s"
  1030     shows "cmod(f 0 z - (\<Sum>i\<le>n. f i w * (z-w) ^ i / (fact i)))
  1031           \<le> B * cmod(z - w)^(Suc n) / fact n"
  1032 proof -
  1033   have wzs: "closed_segment w z \<subseteq> s" using assms
  1034     by (metis convex_contains_segment)
  1035   { fix u
  1036     assume "u \<in> closed_segment w z"
  1037     then have "u \<in> s"
  1038       by (metis wzs subsetD)
  1039     have "(\<Sum>i\<le>n. f i u * (- of_nat i * (z-u)^(i - 1)) / (fact i) +
  1040                       f (Suc i) u * (z-u)^i / (fact i)) =
  1041               f (Suc n) u * (z-u) ^ n / (fact n)"
  1042     proof (induction n)
  1043       case 0 show ?case by simp
  1044     next
  1045       case (Suc n)
  1046       have "(\<Sum>i\<le>Suc n. f i u * (- of_nat i * (z-u) ^ (i - 1)) / (fact i) +
  1047                              f (Suc i) u * (z-u) ^ i / (fact i)) =
  1048            f (Suc n) u * (z-u) ^ n / (fact n) +
  1049            f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n) / (fact (Suc n)) -
  1050            f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n) / (fact (Suc n))"
  1051         using Suc by simp
  1052       also have "... = f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n))"
  1053       proof -
  1054         have "(fact(Suc n)) *
  1055              (f(Suc n) u *(z-u) ^ n / (fact n) +
  1056                f(Suc(Suc n)) u *((z-u) *(z-u) ^ n) / (fact(Suc n)) -
  1057                f(Suc n) u *((1 + of_nat n) *(z-u) ^ n) / (fact(Suc n))) =
  1058             ((fact(Suc n)) *(f(Suc n) u *(z-u) ^ n)) / (fact n) +
  1059             ((fact(Suc n)) *(f(Suc(Suc n)) u *((z-u) *(z-u) ^ n)) / (fact(Suc n))) -
  1060             ((fact(Suc n)) *(f(Suc n) u *(of_nat(Suc n) *(z-u) ^ n))) / (fact(Suc n))"
  1061           by (simp add: algebra_simps del: fact.simps)
  1062         also have "... = ((fact (Suc n)) * (f (Suc n) u * (z-u) ^ n)) / (fact n) +
  1063                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
  1064                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
  1065           by (simp del: fact.simps)
  1066         also have "... = (of_nat (Suc n) * (f (Suc n) u * (z-u) ^ n)) +
  1067                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
  1068                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
  1069           by (simp only: fact.simps of_nat_mult ac_simps) simp
  1070         also have "... = f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)"
  1071           by (simp add: algebra_simps)
  1072         finally show ?thesis
  1073         by (simp add: mult_left_cancel [where c = "(fact (Suc n))", THEN iffD1] del: fact.simps)
  1074       qed
  1075       finally show ?case .
  1076     qed
  1077     then have "((\<lambda>v. (\<Sum>i\<le>n. f i v * (z - v)^i / (fact i)))
  1078                 has_field_derivative f (Suc n) u * (z-u) ^ n / (fact n))
  1079                (at u within s)"
  1080       apply (intro derivative_eq_intros)
  1081       apply (blast intro: assms \<open>u \<in> s\<close>)
  1082       apply (rule refl)+
  1083       apply (auto simp: field_simps)
  1084       done
  1085   } note sum_deriv = this
  1086   { fix u
  1087     assume u: "u \<in> closed_segment w z"
  1088     then have us: "u \<in> s"
  1089       by (metis wzs subsetD)
  1090     have "cmod (f (Suc n) u) * cmod (z - u) ^ n \<le> cmod (f (Suc n) u) * cmod (u - z) ^ n"
  1091       by (metis norm_minus_commute order_refl)
  1092     also have "... \<le> cmod (f (Suc n) u) * cmod (z - w) ^ n"
  1093       by (metis mult_left_mono norm_ge_zero power_mono segment_bound [OF u])
  1094     also have "... \<le> B * cmod (z - w) ^ n"
  1095       by (metis norm_ge_zero zero_le_power mult_right_mono  B [OF us])
  1096     finally have "cmod (f (Suc n) u) * cmod (z - u) ^ n \<le> B * cmod (z - w) ^ n" .
  1097   } note cmod_bound = this
  1098   have "(\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)) = (\<Sum>i\<le>n. (f i z / (fact i)) * 0 ^ i)"
  1099     by simp
  1100   also have "\<dots> = f 0 z / (fact 0)"
  1101     by (subst setsum_zero_power) simp
  1102   finally have "cmod (f 0 z - (\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)))
  1103                 \<le> cmod ((\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)) -
  1104                         (\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)))"
  1105     by (simp add: norm_minus_commute)
  1106   also have "... \<le> B * cmod (z - w) ^ n / (fact n) * cmod (w - z)"
  1107     apply (rule complex_differentiable_bound
  1108       [where f' = "\<lambda>w. f (Suc n) w * (z - w)^n / (fact n)"
  1109          and s = "closed_segment w z", OF convex_closed_segment])
  1110     apply (auto simp: ends_in_segment DERIV_subset [OF sum_deriv wzs]
  1111                   norm_divide norm_mult norm_power divide_le_cancel cmod_bound)
  1112     done
  1113   also have "...  \<le> B * cmod (z - w) ^ Suc n / (fact n)"
  1114     by (simp add: algebra_simps norm_minus_commute)
  1115   finally show ?thesis .
  1116 qed
  1117 
  1118 text\<open>Something more like the traditional MVT for real components.\<close>
  1119 
  1120 lemma complex_mvt_line:
  1121   assumes "\<And>u. u \<in> closed_segment w z \<Longrightarrow> (f has_field_derivative f'(u)) (at u)"
  1122     shows "\<exists>u. u \<in> closed_segment w z \<and> Re(f z) - Re(f w) = Re(f'(u) * (z - w))"
  1123 proof -
  1124   have twz: "\<And>t. (1 - t) *\<^sub>R w + t *\<^sub>R z = w + t *\<^sub>R (z - w)"
  1125     by (simp add: real_vector.scale_left_diff_distrib real_vector.scale_right_diff_distrib)
  1126   note assms[unfolded has_field_derivative_def, derivative_intros]
  1127   show ?thesis
  1128     apply (cut_tac mvt_simple
  1129                      [of 0 1 "Re o f o (\<lambda>t. (1 - t) *\<^sub>R w +  t *\<^sub>R z)"
  1130                       "\<lambda>u. Re o (\<lambda>h. f'((1 - u) *\<^sub>R w + u *\<^sub>R z) * h) o (\<lambda>t. t *\<^sub>R (z - w))"])
  1131     apply auto
  1132     apply (rule_tac x="(1 - x) *\<^sub>R w + x *\<^sub>R z" in exI)
  1133     apply (auto simp: closed_segment_def twz) []
  1134     apply (intro derivative_eq_intros has_derivative_at_within, simp_all)
  1135     apply (simp add: fun_eq_iff real_vector.scale_right_diff_distrib)
  1136     apply (force simp: twz closed_segment_def)
  1137     done
  1138 qed
  1139 
  1140 lemma complex_taylor_mvt:
  1141   assumes "\<And>i x. \<lbrakk>x \<in> closed_segment w z; i \<le> n\<rbrakk> \<Longrightarrow> ((f i) has_field_derivative f (Suc i) x) (at x)"
  1142     shows "\<exists>u. u \<in> closed_segment w z \<and>
  1143             Re (f 0 z) =
  1144             Re ((\<Sum>i = 0..n. f i w * (z - w) ^ i / (fact i)) +
  1145                 (f (Suc n) u * (z-u)^n / (fact n)) * (z - w))"
  1146 proof -
  1147   { fix u
  1148     assume u: "u \<in> closed_segment w z"
  1149     have "(\<Sum>i = 0..n.
  1150                (f (Suc i) u * (z-u) ^ i - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) /
  1151                (fact i)) =
  1152           f (Suc 0) u -
  1153              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1154              (fact (Suc n)) +
  1155              (\<Sum>i = 0..n.
  1156                  (f (Suc (Suc i)) u * ((z-u) ^ Suc i) - of_nat (Suc i) * (f (Suc i) u * (z-u) ^ i)) /
  1157                  (fact (Suc i)))"
  1158        by (subst setsum_Suc_reindex) simp
  1159     also have "... = f (Suc 0) u -
  1160              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1161              (fact (Suc n)) +
  1162              (\<Sum>i = 0..n.
  1163                  f (Suc (Suc i)) u * ((z-u) ^ Suc i) / (fact (Suc i))  -
  1164                  f (Suc i) u * (z-u) ^ i / (fact i))"
  1165       by (simp only: diff_divide_distrib fact_cancel ac_simps)
  1166     also have "... = f (Suc 0) u -
  1167              (f (Suc (Suc n)) u * (z-u) ^ Suc n - of_nat (Suc n) * (z-u) ^ n * f (Suc n) u) /
  1168              (fact (Suc n)) +
  1169              f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n)) - f (Suc 0) u"
  1170       by (subst setsum_Suc_diff) auto
  1171     also have "... = f (Suc n) u * (z-u) ^ n / (fact n)"
  1172       by (simp only: algebra_simps diff_divide_distrib fact_cancel)
  1173     finally have "(\<Sum>i = 0..n. (f (Suc i) u * (z - u) ^ i
  1174                              - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) / (fact i)) =
  1175                   f (Suc n) u * (z - u) ^ n / (fact n)" .
  1176     then have "((\<lambda>u. \<Sum>i = 0..n. f i u * (z - u) ^ i / (fact i)) has_field_derivative
  1177                 f (Suc n) u * (z - u) ^ n / (fact n))  (at u)"
  1178       apply (intro derivative_eq_intros)+
  1179       apply (force intro: u assms)
  1180       apply (rule refl)+
  1181       apply (auto simp: ac_simps)
  1182       done
  1183   }
  1184   then show ?thesis
  1185     apply (cut_tac complex_mvt_line [of w z "\<lambda>u. \<Sum>i = 0..n. f i u * (z-u) ^ i / (fact i)"
  1186                "\<lambda>u. (f (Suc n) u * (z-u)^n / (fact n))"])
  1187     apply (auto simp add: intro: open_closed_segment)
  1188     done
  1189 qed
  1190 
  1191 
  1192 subsection \<open>Polynomal function extremal theorem, from HOL Light\<close>
  1193 
  1194 lemma polyfun_extremal_lemma: (*COMPLEX_POLYFUN_EXTREMAL_LEMMA in HOL Light*)
  1195     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1196   assumes "0 < e"
  1197     shows "\<exists>M. \<forall>z. M \<le> norm(z) \<longrightarrow> norm (\<Sum>i\<le>n. c(i) * z^i) \<le> e * norm(z) ^ (Suc n)"
  1198 proof (induct n)
  1199   case 0 with assms
  1200   show ?case
  1201     apply (rule_tac x="norm (c 0) / e" in exI)
  1202     apply (auto simp: field_simps)
  1203     done
  1204 next
  1205   case (Suc n)
  1206   obtain M where M: "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1207     using Suc assms by blast
  1208   show ?case
  1209   proof (rule exI [where x= "max M (1 + norm(c(Suc n)) / e)"], clarsimp simp del: power_Suc)
  1210     fix z::'a
  1211     assume z1: "M \<le> norm z" and "1 + norm (c (Suc n)) / e \<le> norm z"
  1212     then have z2: "e + norm (c (Suc n)) \<le> e * norm z"
  1213       using assms by (simp add: field_simps)
  1214     have "norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1215       using M [OF z1] by simp
  1216     then have "norm (\<Sum>i\<le>n. c i * z^i) + norm (c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1217       by simp
  1218     then have "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1219       by (blast intro: norm_triangle_le elim: )
  1220     also have "... \<le> (e + norm (c (Suc n))) * norm z ^ Suc n"
  1221       by (simp add: norm_power norm_mult algebra_simps)
  1222     also have "... \<le> (e * norm z) * norm z ^ Suc n"
  1223       by (metis z2 mult.commute mult_left_mono norm_ge_zero norm_power)
  1224     finally show "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc (Suc n)"
  1225       by simp
  1226   qed
  1227 qed
  1228 
  1229 lemma polyfun_extremal: (*COMPLEX_POLYFUN_EXTREMAL in HOL Light*)
  1230     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1231   assumes k: "c k \<noteq> 0" "1\<le>k" and kn: "k\<le>n"
  1232     shows "eventually (\<lambda>z. norm (\<Sum>i\<le>n. c(i) * z^i) \<ge> B) at_infinity"
  1233 using kn
  1234 proof (induction n)
  1235   case 0
  1236   then show ?case
  1237     using k  by simp
  1238 next
  1239   case (Suc m)
  1240   let ?even = ?case
  1241   show ?even
  1242   proof (cases "c (Suc m) = 0")
  1243     case True
  1244     then show ?even using Suc k
  1245       by auto (metis antisym_conv less_eq_Suc_le not_le)
  1246   next
  1247     case False
  1248     then obtain M where M:
  1249           "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>m. c i * z^i) \<le> norm (c (Suc m)) / 2 * norm z ^ Suc m"
  1250       using polyfun_extremal_lemma [of "norm(c (Suc m)) / 2" c m] Suc
  1251       by auto
  1252     have "\<exists>b. \<forall>z. b \<le> norm z \<longrightarrow> B \<le> norm (\<Sum>i\<le>Suc m. c i * z^i)"
  1253     proof (rule exI [where x="max M (max 1 (\<bar>B\<bar> / (norm(c (Suc m)) / 2)))"], clarsimp simp del: power_Suc)
  1254       fix z::'a
  1255       assume z1: "M \<le> norm z" "1 \<le> norm z"
  1256          and "\<bar>B\<bar> * 2 / norm (c (Suc m)) \<le> norm z"
  1257       then have z2: "\<bar>B\<bar> \<le> norm (c (Suc m)) * norm z / 2"
  1258         using False by (simp add: field_simps)
  1259       have nz: "norm z \<le> norm z ^ Suc m"
  1260         by (metis \<open>1 \<le> norm z\<close> One_nat_def less_eq_Suc_le power_increasing power_one_right zero_less_Suc)
  1261       have *: "\<And>y x. norm (c (Suc m)) * norm z / 2 \<le> norm y - norm x \<Longrightarrow> B \<le> norm (x + y)"
  1262         by (metis abs_le_iff add.commute norm_diff_ineq order_trans z2)
  1263       have "norm z * norm (c (Suc m)) + 2 * norm (\<Sum>i\<le>m. c i * z^i)
  1264             \<le> norm (c (Suc m)) * norm z + norm (c (Suc m)) * norm z ^ Suc m"
  1265         using M [of z] Suc z1  by auto
  1266       also have "... \<le> 2 * (norm (c (Suc m)) * norm z ^ Suc m)"
  1267         using nz by (simp add: mult_mono del: power_Suc)
  1268       finally show "B \<le> norm ((\<Sum>i\<le>m. c i * z^i) + c (Suc m) * z ^ Suc m)"
  1269         using Suc.IH
  1270         apply (auto simp: eventually_at_infinity)
  1271         apply (rule *)
  1272         apply (simp add: field_simps norm_mult norm_power)
  1273         done
  1274     qed
  1275     then show ?even
  1276       by (simp add: eventually_at_infinity)
  1277   qed
  1278 qed
  1279 
  1280 end