src/HOL/Power.thy
 author hoelzl Fri Feb 19 13:40:50 2016 +0100 (2016-02-19) changeset 62378 85ed00c1fe7c parent 62366 95c6cf433c91 child 62481 b5d8e57826df permissions -rw-r--r--
generalize more theorems to support enat and ennreal
```     1 (*  Title:      HOL/Power.thy
```
```     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
```
```     3     Copyright   1997  University of Cambridge
```
```     4 *)
```
```     5
```
```     6 section \<open>Exponentiation\<close>
```
```     7
```
```     8 theory Power
```
```     9 imports Num Equiv_Relations
```
```    10 begin
```
```    11
```
```    12 subsection \<open>Powers for Arbitrary Monoids\<close>
```
```    13
```
```    14 class power = one + times
```
```    15 begin
```
```    16
```
```    17 primrec power :: "'a \<Rightarrow> nat \<Rightarrow> 'a"  (infixr "^" 80)
```
```    18 where
```
```    19   power_0: "a ^ 0 = 1"
```
```    20 | power_Suc: "a ^ Suc n = a * a ^ n"
```
```    21
```
```    22 notation (latex output)
```
```    23   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
```
```    24
```
```    25 text \<open>Special syntax for squares.\<close>
```
```    26 abbreviation power2 :: "'a \<Rightarrow> 'a"  ("(_\<^sup>2)" [1000] 999)
```
```    27   where "x\<^sup>2 \<equiv> x ^ 2"
```
```    28
```
```    29 end
```
```    30
```
```    31 context monoid_mult
```
```    32 begin
```
```    33
```
```    34 subclass power .
```
```    35
```
```    36 lemma power_one [simp]:
```
```    37   "1 ^ n = 1"
```
```    38   by (induct n) simp_all
```
```    39
```
```    40 lemma power_one_right [simp]:
```
```    41   "a ^ 1 = a"
```
```    42   by simp
```
```    43
```
```    44 lemma power_Suc0_right [simp]:
```
```    45   "a ^ Suc 0 = a"
```
```    46   by simp
```
```    47
```
```    48 lemma power_commutes:
```
```    49   "a ^ n * a = a * a ^ n"
```
```    50   by (induct n) (simp_all add: mult.assoc)
```
```    51
```
```    52 lemma power_Suc2:
```
```    53   "a ^ Suc n = a ^ n * a"
```
```    54   by (simp add: power_commutes)
```
```    55
```
```    56 lemma power_add:
```
```    57   "a ^ (m + n) = a ^ m * a ^ n"
```
```    58   by (induct m) (simp_all add: algebra_simps)
```
```    59
```
```    60 lemma power_mult:
```
```    61   "a ^ (m * n) = (a ^ m) ^ n"
```
```    62   by (induct n) (simp_all add: power_add)
```
```    63
```
```    64 lemma power2_eq_square: "a\<^sup>2 = a * a"
```
```    65   by (simp add: numeral_2_eq_2)
```
```    66
```
```    67 lemma power3_eq_cube: "a ^ 3 = a * a * a"
```
```    68   by (simp add: numeral_3_eq_3 mult.assoc)
```
```    69
```
```    70 lemma power_even_eq:
```
```    71   "a ^ (2 * n) = (a ^ n)\<^sup>2"
```
```    72   by (subst mult.commute) (simp add: power_mult)
```
```    73
```
```    74 lemma power_odd_eq:
```
```    75   "a ^ Suc (2*n) = a * (a ^ n)\<^sup>2"
```
```    76   by (simp add: power_even_eq)
```
```    77
```
```    78 lemma power_numeral_even:
```
```    79   "z ^ numeral (Num.Bit0 w) = (let w = z ^ (numeral w) in w * w)"
```
```    80   unfolding numeral_Bit0 power_add Let_def ..
```
```    81
```
```    82 lemma power_numeral_odd:
```
```    83   "z ^ numeral (Num.Bit1 w) = (let w = z ^ (numeral w) in z * w * w)"
```
```    84   unfolding numeral_Bit1 One_nat_def add_Suc_right add_0_right
```
```    85   unfolding power_Suc power_add Let_def mult.assoc ..
```
```    86
```
```    87 lemma funpow_times_power:
```
```    88   "(times x ^^ f x) = times (x ^ f x)"
```
```    89 proof (induct "f x" arbitrary: f)
```
```    90   case 0 then show ?case by (simp add: fun_eq_iff)
```
```    91 next
```
```    92   case (Suc n)
```
```    93   def g \<equiv> "\<lambda>x. f x - 1"
```
```    94   with Suc have "n = g x" by simp
```
```    95   with Suc have "times x ^^ g x = times (x ^ g x)" by simp
```
```    96   moreover from Suc g_def have "f x = g x + 1" by simp
```
```    97   ultimately show ?case by (simp add: power_add funpow_add fun_eq_iff mult.assoc)
```
```    98 qed
```
```    99
```
```   100 lemma power_commuting_commutes:
```
```   101   assumes "x * y = y * x"
```
```   102   shows "x ^ n * y = y * x ^n"
```
```   103 proof (induct n)
```
```   104   case (Suc n)
```
```   105   have "x ^ Suc n * y = x ^ n * y * x"
```
```   106     by (subst power_Suc2) (simp add: assms ac_simps)
```
```   107   also have "\<dots> = y * x ^ Suc n"
```
```   108     unfolding Suc power_Suc2
```
```   109     by (simp add: ac_simps)
```
```   110   finally show ?case .
```
```   111 qed simp
```
```   112
```
```   113 lemma power_minus_mult:
```
```   114   "0 < n \<Longrightarrow> a ^ (n - 1) * a = a ^ n"
```
```   115   by (simp add: power_commutes split add: nat_diff_split)
```
```   116
```
```   117 end
```
```   118
```
```   119 context comm_monoid_mult
```
```   120 begin
```
```   121
```
```   122 lemma power_mult_distrib [field_simps]:
```
```   123   "(a * b) ^ n = (a ^ n) * (b ^ n)"
```
```   124   by (induct n) (simp_all add: ac_simps)
```
```   125
```
```   126 end
```
```   127
```
```   128 text\<open>Extract constant factors from powers\<close>
```
```   129 declare power_mult_distrib [where a = "numeral w" for w, simp]
```
```   130 declare power_mult_distrib [where b = "numeral w" for w, simp]
```
```   131
```
```   132 lemma power_add_numeral [simp]:
```
```   133   fixes a :: "'a :: monoid_mult"
```
```   134   shows "a^numeral m * a^numeral n = a^numeral (m + n)"
```
```   135   by (simp add: power_add [symmetric])
```
```   136
```
```   137 lemma power_add_numeral2 [simp]:
```
```   138   fixes a :: "'a :: monoid_mult"
```
```   139   shows "a^numeral m * (a^numeral n * b) = a^numeral (m + n) * b"
```
```   140   by (simp add: mult.assoc [symmetric])
```
```   141
```
```   142 lemma power_mult_numeral [simp]:
```
```   143   fixes a :: "'a :: monoid_mult"
```
```   144   shows"(a^numeral m)^numeral n = a^numeral (m * n)"
```
```   145   by (simp only: numeral_mult power_mult)
```
```   146
```
```   147 context semiring_numeral
```
```   148 begin
```
```   149
```
```   150 lemma numeral_sqr: "numeral (Num.sqr k) = numeral k * numeral k"
```
```   151   by (simp only: sqr_conv_mult numeral_mult)
```
```   152
```
```   153 lemma numeral_pow: "numeral (Num.pow k l) = numeral k ^ numeral l"
```
```   154   by (induct l, simp_all only: numeral_class.numeral.simps pow.simps
```
```   155     numeral_sqr numeral_mult power_add power_one_right)
```
```   156
```
```   157 lemma power_numeral [simp]: "numeral k ^ numeral l = numeral (Num.pow k l)"
```
```   158   by (rule numeral_pow [symmetric])
```
```   159
```
```   160 end
```
```   161
```
```   162 context semiring_1
```
```   163 begin
```
```   164
```
```   165 lemma of_nat_power [simp]:
```
```   166   "of_nat (m ^ n) = of_nat m ^ n"
```
```   167   by (induct n) (simp_all add: of_nat_mult)
```
```   168
```
```   169 lemma zero_power:
```
```   170   "0 < n \<Longrightarrow> 0 ^ n = 0"
```
```   171   by (cases n) simp_all
```
```   172
```
```   173 lemma power_zero_numeral [simp]:
```
```   174   "0 ^ numeral k = 0"
```
```   175   by (simp add: numeral_eq_Suc)
```
```   176
```
```   177 lemma zero_power2: "0\<^sup>2 = 0" (* delete? *)
```
```   178   by (rule power_zero_numeral)
```
```   179
```
```   180 lemma one_power2: "1\<^sup>2 = 1" (* delete? *)
```
```   181   by (rule power_one)
```
```   182
```
```   183 lemma power_0_Suc [simp]:
```
```   184   "0 ^ Suc n = 0"
```
```   185   by simp
```
```   186
```
```   187 text\<open>It looks plausible as a simprule, but its effect can be strange.\<close>
```
```   188 lemma power_0_left:
```
```   189   "0 ^ n = (if n = 0 then 1 else 0)"
```
```   190   by (cases n) simp_all
```
```   191
```
```   192 end
```
```   193
```
```   194 context comm_semiring_1
```
```   195 begin
```
```   196
```
```   197 text \<open>The divides relation\<close>
```
```   198
```
```   199 lemma le_imp_power_dvd:
```
```   200   assumes "m \<le> n" shows "a ^ m dvd a ^ n"
```
```   201 proof
```
```   202   have "a ^ n = a ^ (m + (n - m))"
```
```   203     using \<open>m \<le> n\<close> by simp
```
```   204   also have "\<dots> = a ^ m * a ^ (n - m)"
```
```   205     by (rule power_add)
```
```   206   finally show "a ^ n = a ^ m * a ^ (n - m)" .
```
```   207 qed
```
```   208
```
```   209 lemma power_le_dvd:
```
```   210   "a ^ n dvd b \<Longrightarrow> m \<le> n \<Longrightarrow> a ^ m dvd b"
```
```   211   by (rule dvd_trans [OF le_imp_power_dvd])
```
```   212
```
```   213 lemma dvd_power_same:
```
```   214   "x dvd y \<Longrightarrow> x ^ n dvd y ^ n"
```
```   215   by (induct n) (auto simp add: mult_dvd_mono)
```
```   216
```
```   217 lemma dvd_power_le:
```
```   218   "x dvd y \<Longrightarrow> m \<ge> n \<Longrightarrow> x ^ n dvd y ^ m"
```
```   219   by (rule power_le_dvd [OF dvd_power_same])
```
```   220
```
```   221 lemma dvd_power [simp]:
```
```   222   assumes "n > (0::nat) \<or> x = 1"
```
```   223   shows "x dvd (x ^ n)"
```
```   224 using assms proof
```
```   225   assume "0 < n"
```
```   226   then have "x ^ n = x ^ Suc (n - 1)" by simp
```
```   227   then show "x dvd (x ^ n)" by simp
```
```   228 next
```
```   229   assume "x = 1"
```
```   230   then show "x dvd (x ^ n)" by simp
```
```   231 qed
```
```   232
```
```   233 end
```
```   234
```
```   235 class semiring_1_no_zero_divisors = semiring_1 + semiring_no_zero_divisors
```
```   236 begin
```
```   237
```
```   238 subclass power .
```
```   239
```
```   240 lemma power_eq_0_iff [simp]:
```
```   241   "a ^ n = 0 \<longleftrightarrow> a = 0 \<and> n > 0"
```
```   242   by (induct n) auto
```
```   243
```
```   244 lemma power_not_zero:
```
```   245   "a \<noteq> 0 \<Longrightarrow> a ^ n \<noteq> 0"
```
```   246   by (induct n) auto
```
```   247
```
```   248 lemma zero_eq_power2 [simp]:
```
```   249   "a\<^sup>2 = 0 \<longleftrightarrow> a = 0"
```
```   250   unfolding power2_eq_square by simp
```
```   251
```
```   252 end
```
```   253
```
```   254 context semidom
```
```   255 begin
```
```   256
```
```   257 subclass semiring_1_no_zero_divisors ..
```
```   258
```
```   259 end
```
```   260
```
```   261 context ring_1
```
```   262 begin
```
```   263
```
```   264 lemma power_minus:
```
```   265   "(- a) ^ n = (- 1) ^ n * a ^ n"
```
```   266 proof (induct n)
```
```   267   case 0 show ?case by simp
```
```   268 next
```
```   269   case (Suc n) then show ?case
```
```   270     by (simp del: power_Suc add: power_Suc2 mult.assoc)
```
```   271 qed
```
```   272
```
```   273 lemma power_minus': "NO_MATCH 1 x \<Longrightarrow> (-x) ^ n = (-1)^n * x ^ n"
```
```   274   by (rule power_minus)
```
```   275
```
```   276 lemma power_minus_Bit0:
```
```   277   "(- x) ^ numeral (Num.Bit0 k) = x ^ numeral (Num.Bit0 k)"
```
```   278   by (induct k, simp_all only: numeral_class.numeral.simps power_add
```
```   279     power_one_right mult_minus_left mult_minus_right minus_minus)
```
```   280
```
```   281 lemma power_minus_Bit1:
```
```   282   "(- x) ^ numeral (Num.Bit1 k) = - (x ^ numeral (Num.Bit1 k))"
```
```   283   by (simp only: eval_nat_numeral(3) power_Suc power_minus_Bit0 mult_minus_left)
```
```   284
```
```   285 lemma power2_minus [simp]:
```
```   286   "(- a)\<^sup>2 = a\<^sup>2"
```
```   287   by (fact power_minus_Bit0)
```
```   288
```
```   289 lemma power_minus1_even [simp]:
```
```   290   "(- 1) ^ (2*n) = 1"
```
```   291 proof (induct n)
```
```   292   case 0 show ?case by simp
```
```   293 next
```
```   294   case (Suc n) then show ?case by (simp add: power_add power2_eq_square)
```
```   295 qed
```
```   296
```
```   297 lemma power_minus1_odd:
```
```   298   "(- 1) ^ Suc (2*n) = -1"
```
```   299   by simp
```
```   300
```
```   301 lemma power_minus_even [simp]:
```
```   302   "(-a) ^ (2*n) = a ^ (2*n)"
```
```   303   by (simp add: power_minus [of a])
```
```   304
```
```   305 end
```
```   306
```
```   307 context ring_1_no_zero_divisors
```
```   308 begin
```
```   309
```
```   310 subclass semiring_1_no_zero_divisors ..
```
```   311
```
```   312 lemma power2_eq_1_iff:
```
```   313   "a\<^sup>2 = 1 \<longleftrightarrow> a = 1 \<or> a = - 1"
```
```   314   using square_eq_1_iff [of a] by (simp add: power2_eq_square)
```
```   315
```
```   316 end
```
```   317
```
```   318 context idom
```
```   319 begin
```
```   320
```
```   321 lemma power2_eq_iff: "x\<^sup>2 = y\<^sup>2 \<longleftrightarrow> x = y \<or> x = - y"
```
```   322   unfolding power2_eq_square by (rule square_eq_iff)
```
```   323
```
```   324 end
```
```   325
```
```   326 context algebraic_semidom
```
```   327 begin
```
```   328
```
```   329 lemma div_power:
```
```   330   assumes "b dvd a"
```
```   331   shows "(a div b) ^ n = a ^ n div b ^ n"
```
```   332   using assms by (induct n) (simp_all add: div_mult_div_if_dvd dvd_power_same)
```
```   333
```
```   334 lemma is_unit_power_iff:
```
```   335   "is_unit (a ^ n) \<longleftrightarrow> is_unit a \<or> n = 0"
```
```   336   by (induct n) (auto simp add: is_unit_mult_iff)
```
```   337
```
```   338 end
```
```   339
```
```   340 context normalization_semidom
```
```   341 begin
```
```   342
```
```   343 lemma normalize_power:
```
```   344   "normalize (a ^ n) = normalize a ^ n"
```
```   345   by (induct n) (simp_all add: normalize_mult)
```
```   346
```
```   347 lemma unit_factor_power:
```
```   348   "unit_factor (a ^ n) = unit_factor a ^ n"
```
```   349   by (induct n) (simp_all add: unit_factor_mult)
```
```   350
```
```   351 end
```
```   352
```
```   353 context division_ring
```
```   354 begin
```
```   355
```
```   356 text\<open>Perhaps these should be simprules.\<close>
```
```   357 lemma power_inverse [field_simps, divide_simps]:
```
```   358   "inverse a ^ n = inverse (a ^ n)"
```
```   359 proof (cases "a = 0")
```
```   360   case True then show ?thesis by (simp add: power_0_left)
```
```   361 next
```
```   362   case False then have "inverse (a ^ n) = inverse a ^ n"
```
```   363     by (induct n) (simp_all add: nonzero_inverse_mult_distrib power_commutes)
```
```   364   then show ?thesis by simp
```
```   365 qed
```
```   366
```
```   367 lemma power_one_over [field_simps, divide_simps]:
```
```   368   "(1 / a) ^ n = 1 / a ^ n"
```
```   369   using power_inverse [of a] by (simp add: divide_inverse)
```
```   370
```
```   371 end
```
```   372
```
```   373 context field
```
```   374 begin
```
```   375
```
```   376 lemma power_diff:
```
```   377   assumes nz: "a \<noteq> 0"
```
```   378   shows "n \<le> m \<Longrightarrow> a ^ (m - n) = a ^ m / a ^ n"
```
```   379   by (induct m n rule: diff_induct) (simp_all add: nz power_not_zero)
```
```   380
```
```   381 lemma power_divide [field_simps, divide_simps]:
```
```   382   "(a / b) ^ n = a ^ n / b ^ n"
```
```   383   by (induct n) simp_all
```
```   384
```
```   385 end
```
```   386
```
```   387
```
```   388 subsection \<open>Exponentiation on ordered types\<close>
```
```   389
```
```   390 context linordered_semidom
```
```   391 begin
```
```   392
```
```   393 lemma zero_less_power [simp]:
```
```   394   "0 < a \<Longrightarrow> 0 < a ^ n"
```
```   395   by (induct n) simp_all
```
```   396
```
```   397 lemma zero_le_power [simp]:
```
```   398   "0 \<le> a \<Longrightarrow> 0 \<le> a ^ n"
```
```   399   by (induct n) simp_all
```
```   400
```
```   401 lemma power_mono:
```
```   402   "a \<le> b \<Longrightarrow> 0 \<le> a \<Longrightarrow> a ^ n \<le> b ^ n"
```
```   403   by (induct n) (auto intro: mult_mono order_trans [of 0 a b])
```
```   404
```
```   405 lemma one_le_power [simp]: "1 \<le> a \<Longrightarrow> 1 \<le> a ^ n"
```
```   406   using power_mono [of 1 a n] by simp
```
```   407
```
```   408 lemma power_le_one: "\<lbrakk>0 \<le> a; a \<le> 1\<rbrakk> \<Longrightarrow> a ^ n \<le> 1"
```
```   409   using power_mono [of a 1 n] by simp
```
```   410
```
```   411 lemma power_gt1_lemma:
```
```   412   assumes gt1: "1 < a"
```
```   413   shows "1 < a * a ^ n"
```
```   414 proof -
```
```   415   from gt1 have "0 \<le> a"
```
```   416     by (fact order_trans [OF zero_le_one less_imp_le])
```
```   417   have "1 * 1 < a * 1" using gt1 by simp
```
```   418   also have "\<dots> \<le> a * a ^ n" using gt1
```
```   419     by (simp only: mult_mono \<open>0 \<le> a\<close> one_le_power order_less_imp_le
```
```   420         zero_le_one order_refl)
```
```   421   finally show ?thesis by simp
```
```   422 qed
```
```   423
```
```   424 lemma power_gt1:
```
```   425   "1 < a \<Longrightarrow> 1 < a ^ Suc n"
```
```   426   by (simp add: power_gt1_lemma)
```
```   427
```
```   428 lemma one_less_power [simp]:
```
```   429   "1 < a \<Longrightarrow> 0 < n \<Longrightarrow> 1 < a ^ n"
```
```   430   by (cases n) (simp_all add: power_gt1_lemma)
```
```   431
```
```   432 lemma power_le_imp_le_exp:
```
```   433   assumes gt1: "1 < a"
```
```   434   shows "a ^ m \<le> a ^ n \<Longrightarrow> m \<le> n"
```
```   435 proof (induct m arbitrary: n)
```
```   436   case 0
```
```   437   show ?case by simp
```
```   438 next
```
```   439   case (Suc m)
```
```   440   show ?case
```
```   441   proof (cases n)
```
```   442     case 0
```
```   443     with Suc.prems Suc.hyps have "a * a ^ m \<le> 1" by simp
```
```   444     with gt1 show ?thesis
```
```   445       by (force simp only: power_gt1_lemma
```
```   446           not_less [symmetric])
```
```   447   next
```
```   448     case (Suc n)
```
```   449     with Suc.prems Suc.hyps show ?thesis
```
```   450       by (force dest: mult_left_le_imp_le
```
```   451           simp add: less_trans [OF zero_less_one gt1])
```
```   452   qed
```
```   453 qed
```
```   454
```
```   455 lemma of_nat_zero_less_power_iff [simp]:
```
```   456   "of_nat x ^ n > 0 \<longleftrightarrow> x > 0 \<or> n = 0"
```
```   457   by (induct n) auto
```
```   458
```
```   459 text\<open>Surely we can strengthen this? It holds for \<open>0<a<1\<close> too.\<close>
```
```   460 lemma power_inject_exp [simp]:
```
```   461   "1 < a \<Longrightarrow> a ^ m = a ^ n \<longleftrightarrow> m = n"
```
```   462   by (force simp add: order_antisym power_le_imp_le_exp)
```
```   463
```
```   464 text\<open>Can relax the first premise to @{term "0<a"} in the case of the
```
```   465 natural numbers.\<close>
```
```   466 lemma power_less_imp_less_exp:
```
```   467   "1 < a \<Longrightarrow> a ^ m < a ^ n \<Longrightarrow> m < n"
```
```   468   by (simp add: order_less_le [of m n] less_le [of "a^m" "a^n"]
```
```   469     power_le_imp_le_exp)
```
```   470
```
```   471 lemma power_strict_mono [rule_format]:
```
```   472   "a < b \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 < n \<longrightarrow> a ^ n < b ^ n"
```
```   473   by (induct n)
```
```   474    (auto simp add: mult_strict_mono le_less_trans [of 0 a b])
```
```   475
```
```   476 text\<open>Lemma for \<open>power_strict_decreasing\<close>\<close>
```
```   477 lemma power_Suc_less:
```
```   478   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a * a ^ n < a ^ n"
```
```   479   by (induct n)
```
```   480     (auto simp add: mult_strict_left_mono)
```
```   481
```
```   482 lemma power_strict_decreasing [rule_format]:
```
```   483   "n < N \<Longrightarrow> 0 < a \<Longrightarrow> a < 1 \<longrightarrow> a ^ N < a ^ n"
```
```   484 proof (induct N)
```
```   485   case 0 then show ?case by simp
```
```   486 next
```
```   487   case (Suc N) then show ?case
```
```   488   apply (auto simp add: power_Suc_less less_Suc_eq)
```
```   489   apply (subgoal_tac "a * a^N < 1 * a^n")
```
```   490   apply simp
```
```   491   apply (rule mult_strict_mono) apply auto
```
```   492   done
```
```   493 qed
```
```   494
```
```   495 text\<open>Proof resembles that of \<open>power_strict_decreasing\<close>\<close>
```
```   496 lemma power_decreasing [rule_format]:
```
```   497   "n \<le> N \<Longrightarrow> 0 \<le> a \<Longrightarrow> a \<le> 1 \<longrightarrow> a ^ N \<le> a ^ n"
```
```   498 proof (induct N)
```
```   499   case 0 then show ?case by simp
```
```   500 next
```
```   501   case (Suc N) then show ?case
```
```   502   apply (auto simp add: le_Suc_eq)
```
```   503   apply (subgoal_tac "a * a^N \<le> 1 * a^n", simp)
```
```   504   apply (rule mult_mono) apply auto
```
```   505   done
```
```   506 qed
```
```   507
```
```   508 lemma power_Suc_less_one:
```
```   509   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a ^ Suc n < 1"
```
```   510   using power_strict_decreasing [of 0 "Suc n" a] by simp
```
```   511
```
```   512 text\<open>Proof again resembles that of \<open>power_strict_decreasing\<close>\<close>
```
```   513 lemma power_increasing [rule_format]:
```
```   514   "n \<le> N \<Longrightarrow> 1 \<le> a \<Longrightarrow> a ^ n \<le> a ^ N"
```
```   515 proof (induct N)
```
```   516   case 0 then show ?case by simp
```
```   517 next
```
```   518   case (Suc N) then show ?case
```
```   519   apply (auto simp add: le_Suc_eq)
```
```   520   apply (subgoal_tac "1 * a^n \<le> a * a^N", simp)
```
```   521   apply (rule mult_mono) apply (auto simp add: order_trans [OF zero_le_one])
```
```   522   done
```
```   523 qed
```
```   524
```
```   525 text\<open>Lemma for \<open>power_strict_increasing\<close>\<close>
```
```   526 lemma power_less_power_Suc:
```
```   527   "1 < a \<Longrightarrow> a ^ n < a * a ^ n"
```
```   528   by (induct n) (auto simp add: mult_strict_left_mono less_trans [OF zero_less_one])
```
```   529
```
```   530 lemma power_strict_increasing [rule_format]:
```
```   531   "n < N \<Longrightarrow> 1 < a \<longrightarrow> a ^ n < a ^ N"
```
```   532 proof (induct N)
```
```   533   case 0 then show ?case by simp
```
```   534 next
```
```   535   case (Suc N) then show ?case
```
```   536   apply (auto simp add: power_less_power_Suc less_Suc_eq)
```
```   537   apply (subgoal_tac "1 * a^n < a * a^N", simp)
```
```   538   apply (rule mult_strict_mono) apply (auto simp add: less_trans [OF zero_less_one] less_imp_le)
```
```   539   done
```
```   540 qed
```
```   541
```
```   542 lemma power_increasing_iff [simp]:
```
```   543   "1 < b \<Longrightarrow> b ^ x \<le> b ^ y \<longleftrightarrow> x \<le> y"
```
```   544   by (blast intro: power_le_imp_le_exp power_increasing less_imp_le)
```
```   545
```
```   546 lemma power_strict_increasing_iff [simp]:
```
```   547   "1 < b \<Longrightarrow> b ^ x < b ^ y \<longleftrightarrow> x < y"
```
```   548 by (blast intro: power_less_imp_less_exp power_strict_increasing)
```
```   549
```
```   550 lemma power_le_imp_le_base:
```
```   551   assumes le: "a ^ Suc n \<le> b ^ Suc n"
```
```   552     and ynonneg: "0 \<le> b"
```
```   553   shows "a \<le> b"
```
```   554 proof (rule ccontr)
```
```   555   assume "~ a \<le> b"
```
```   556   then have "b < a" by (simp only: linorder_not_le)
```
```   557   then have "b ^ Suc n < a ^ Suc n"
```
```   558     by (simp only: assms power_strict_mono)
```
```   559   from le and this show False
```
```   560     by (simp add: linorder_not_less [symmetric])
```
```   561 qed
```
```   562
```
```   563 lemma power_less_imp_less_base:
```
```   564   assumes less: "a ^ n < b ^ n"
```
```   565   assumes nonneg: "0 \<le> b"
```
```   566   shows "a < b"
```
```   567 proof (rule contrapos_pp [OF less])
```
```   568   assume "~ a < b"
```
```   569   hence "b \<le> a" by (simp only: linorder_not_less)
```
```   570   hence "b ^ n \<le> a ^ n" using nonneg by (rule power_mono)
```
```   571   thus "\<not> a ^ n < b ^ n" by (simp only: linorder_not_less)
```
```   572 qed
```
```   573
```
```   574 lemma power_inject_base:
```
```   575   "a ^ Suc n = b ^ Suc n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a = b"
```
```   576 by (blast intro: power_le_imp_le_base antisym eq_refl sym)
```
```   577
```
```   578 lemma power_eq_imp_eq_base:
```
```   579   "a ^ n = b ^ n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 < n \<Longrightarrow> a = b"
```
```   580   by (cases n) (simp_all del: power_Suc, rule power_inject_base)
```
```   581
```
```   582 lemma power_eq_iff_eq_base:
```
```   583   "0 < n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a ^ n = b ^ n \<longleftrightarrow> a = b"
```
```   584   using power_eq_imp_eq_base [of a n b] by auto
```
```   585
```
```   586 lemma power2_le_imp_le:
```
```   587   "x\<^sup>2 \<le> y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x \<le> y"
```
```   588   unfolding numeral_2_eq_2 by (rule power_le_imp_le_base)
```
```   589
```
```   590 lemma power2_less_imp_less:
```
```   591   "x\<^sup>2 < y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x < y"
```
```   592   by (rule power_less_imp_less_base)
```
```   593
```
```   594 lemma power2_eq_imp_eq:
```
```   595   "x\<^sup>2 = y\<^sup>2 \<Longrightarrow> 0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> x = y"
```
```   596   unfolding numeral_2_eq_2 by (erule (2) power_eq_imp_eq_base) simp
```
```   597
```
```   598 lemma power_Suc_le_self:
```
```   599   shows "0 \<le> a \<Longrightarrow> a \<le> 1 \<Longrightarrow> a ^ Suc n \<le> a"
```
```   600   using power_decreasing [of 1 "Suc n" a] by simp
```
```   601
```
```   602 end
```
```   603
```
```   604 context linordered_ring_strict
```
```   605 begin
```
```   606
```
```   607 lemma sum_squares_eq_zero_iff:
```
```   608   "x * x + y * y = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
```
```   609   by (simp add: add_nonneg_eq_0_iff)
```
```   610
```
```   611 lemma sum_squares_le_zero_iff:
```
```   612   "x * x + y * y \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
```
```   613   by (simp add: le_less not_sum_squares_lt_zero sum_squares_eq_zero_iff)
```
```   614
```
```   615 lemma sum_squares_gt_zero_iff:
```
```   616   "0 < x * x + y * y \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
```
```   617   by (simp add: not_le [symmetric] sum_squares_le_zero_iff)
```
```   618
```
```   619 end
```
```   620
```
```   621 context linordered_idom
```
```   622 begin
```
```   623
```
```   624 lemma power_abs: "\<bar>a ^ n\<bar> = \<bar>a\<bar> ^ n"
```
```   625   by (induct n) (auto simp add: abs_mult)
```
```   626
```
```   627 lemma abs_power_minus [simp]: "\<bar>(-a) ^ n\<bar> = \<bar>a ^ n\<bar>"
```
```   628   by (simp add: power_abs)
```
```   629
```
```   630 lemma zero_less_power_abs_iff [simp]: "0 < \<bar>a\<bar> ^ n \<longleftrightarrow> a \<noteq> 0 \<or> n = 0"
```
```   631 proof (induct n)
```
```   632   case 0 show ?case by simp
```
```   633 next
```
```   634   case (Suc n) show ?case by (auto simp add: Suc zero_less_mult_iff)
```
```   635 qed
```
```   636
```
```   637 lemma zero_le_power_abs [simp]: "0 \<le> \<bar>a\<bar> ^ n"
```
```   638   by (rule zero_le_power [OF abs_ge_zero])
```
```   639
```
```   640 lemma zero_le_power2 [simp]:
```
```   641   "0 \<le> a\<^sup>2"
```
```   642   by (simp add: power2_eq_square)
```
```   643
```
```   644 lemma zero_less_power2 [simp]:
```
```   645   "0 < a\<^sup>2 \<longleftrightarrow> a \<noteq> 0"
```
```   646   by (force simp add: power2_eq_square zero_less_mult_iff linorder_neq_iff)
```
```   647
```
```   648 lemma power2_less_0 [simp]:
```
```   649   "\<not> a\<^sup>2 < 0"
```
```   650   by (force simp add: power2_eq_square mult_less_0_iff)
```
```   651
```
```   652 lemma power2_less_eq_zero_iff [simp]:
```
```   653   "a\<^sup>2 \<le> 0 \<longleftrightarrow> a = 0"
```
```   654   by (simp add: le_less)
```
```   655
```
```   656 lemma abs_power2 [simp]: "\<bar>a\<^sup>2\<bar> = a\<^sup>2"
```
```   657   by (simp add: power2_eq_square abs_mult abs_mult_self)
```
```   658
```
```   659 lemma power2_abs [simp]: "\<bar>a\<bar>\<^sup>2 = a\<^sup>2"
```
```   660   by (simp add: power2_eq_square abs_mult_self)
```
```   661
```
```   662 lemma odd_power_less_zero:
```
```   663   "a < 0 \<Longrightarrow> a ^ Suc (2*n) < 0"
```
```   664 proof (induct n)
```
```   665   case 0
```
```   666   then show ?case by simp
```
```   667 next
```
```   668   case (Suc n)
```
```   669   have "a ^ Suc (2 * Suc n) = (a*a) * a ^ Suc(2*n)"
```
```   670     by (simp add: ac_simps power_add power2_eq_square)
```
```   671   thus ?case
```
```   672     by (simp del: power_Suc add: Suc mult_less_0_iff mult_neg_neg)
```
```   673 qed
```
```   674
```
```   675 lemma odd_0_le_power_imp_0_le:
```
```   676   "0 \<le> a ^ Suc (2*n) \<Longrightarrow> 0 \<le> a"
```
```   677   using odd_power_less_zero [of a n]
```
```   678     by (force simp add: linorder_not_less [symmetric])
```
```   679
```
```   680 lemma zero_le_even_power'[simp]:
```
```   681   "0 \<le> a ^ (2*n)"
```
```   682 proof (induct n)
```
```   683   case 0
```
```   684     show ?case by simp
```
```   685 next
```
```   686   case (Suc n)
```
```   687     have "a ^ (2 * Suc n) = (a*a) * a ^ (2*n)"
```
```   688       by (simp add: ac_simps power_add power2_eq_square)
```
```   689     thus ?case
```
```   690       by (simp add: Suc zero_le_mult_iff)
```
```   691 qed
```
```   692
```
```   693 lemma sum_power2_ge_zero:
```
```   694   "0 \<le> x\<^sup>2 + y\<^sup>2"
```
```   695   by (intro add_nonneg_nonneg zero_le_power2)
```
```   696
```
```   697 lemma not_sum_power2_lt_zero:
```
```   698   "\<not> x\<^sup>2 + y\<^sup>2 < 0"
```
```   699   unfolding not_less by (rule sum_power2_ge_zero)
```
```   700
```
```   701 lemma sum_power2_eq_zero_iff:
```
```   702   "x\<^sup>2 + y\<^sup>2 = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
```
```   703   unfolding power2_eq_square by (simp add: add_nonneg_eq_0_iff)
```
```   704
```
```   705 lemma sum_power2_le_zero_iff:
```
```   706   "x\<^sup>2 + y\<^sup>2 \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
```
```   707   by (simp add: le_less sum_power2_eq_zero_iff not_sum_power2_lt_zero)
```
```   708
```
```   709 lemma sum_power2_gt_zero_iff:
```
```   710   "0 < x\<^sup>2 + y\<^sup>2 \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
```
```   711   unfolding not_le [symmetric] by (simp add: sum_power2_le_zero_iff)
```
```   712
```
```   713 lemma abs_le_square_iff:
```
```   714    "\<bar>x\<bar> \<le> \<bar>y\<bar> \<longleftrightarrow> x\<^sup>2 \<le> y\<^sup>2"
```
```   715 proof
```
```   716   assume "\<bar>x\<bar> \<le> \<bar>y\<bar>"
```
```   717   then have "\<bar>x\<bar>\<^sup>2 \<le> \<bar>y\<bar>\<^sup>2" by (rule power_mono, simp)
```
```   718   then show "x\<^sup>2 \<le> y\<^sup>2" by simp
```
```   719 next
```
```   720   assume "x\<^sup>2 \<le> y\<^sup>2"
```
```   721   then show "\<bar>x\<bar> \<le> \<bar>y\<bar>"
```
```   722     by (auto intro!: power2_le_imp_le [OF _ abs_ge_zero])
```
```   723 qed
```
```   724
```
```   725 lemma abs_square_le_1:"x\<^sup>2 \<le> 1 \<longleftrightarrow> \<bar>x\<bar> \<le> 1"
```
```   726   using abs_le_square_iff [of x 1]
```
```   727   by simp
```
```   728
```
```   729 lemma abs_square_eq_1: "x\<^sup>2 = 1 \<longleftrightarrow> \<bar>x\<bar> = 1"
```
```   730   by (auto simp add: abs_if power2_eq_1_iff)
```
```   731
```
```   732 lemma abs_square_less_1: "x\<^sup>2 < 1 \<longleftrightarrow> \<bar>x\<bar> < 1"
```
```   733   using  abs_square_eq_1 [of x] abs_square_le_1 [of x]
```
```   734   by (auto simp add: le_less)
```
```   735
```
```   736 end
```
```   737
```
```   738
```
```   739 subsection \<open>Miscellaneous rules\<close>
```
```   740
```
```   741 lemma (in linordered_semidom) self_le_power:
```
```   742   "1 \<le> a \<Longrightarrow> 0 < n \<Longrightarrow> a \<le> a ^ n"
```
```   743   using power_increasing [of 1 n a] power_one_right [of a] by auto
```
```   744
```
```   745 lemma (in power) power_eq_if:
```
```   746   "p ^ m = (if m=0 then 1 else p * (p ^ (m - 1)))"
```
```   747   unfolding One_nat_def by (cases m) simp_all
```
```   748
```
```   749 lemma (in comm_semiring_1) power2_sum:
```
```   750   "(x + y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 + 2 * x * y"
```
```   751   by (simp add: algebra_simps power2_eq_square mult_2_right)
```
```   752
```
```   753 lemma (in comm_ring_1) power2_diff:
```
```   754   "(x - y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 - 2 * x * y"
```
```   755   by (simp add: algebra_simps power2_eq_square mult_2_right)
```
```   756
```
```   757 lemma (in comm_ring_1) power2_commute:
```
```   758   "(x - y)\<^sup>2 = (y - x)\<^sup>2"
```
```   759   by (simp add: algebra_simps power2_eq_square)
```
```   760
```
```   761 text \<open>Simprules for comparisons where common factors can be cancelled.\<close>
```
```   762
```
```   763 lemmas zero_compare_simps =
```
```   764     add_strict_increasing add_strict_increasing2 add_increasing
```
```   765     zero_le_mult_iff zero_le_divide_iff
```
```   766     zero_less_mult_iff zero_less_divide_iff
```
```   767     mult_le_0_iff divide_le_0_iff
```
```   768     mult_less_0_iff divide_less_0_iff
```
```   769     zero_le_power2 power2_less_0
```
```   770
```
```   771
```
```   772 subsection \<open>Exponentiation for the Natural Numbers\<close>
```
```   773
```
```   774 lemma nat_one_le_power [simp]:
```
```   775   "Suc 0 \<le> i \<Longrightarrow> Suc 0 \<le> i ^ n"
```
```   776   by (rule one_le_power [of i n, unfolded One_nat_def])
```
```   777
```
```   778 lemma nat_zero_less_power_iff [simp]:
```
```   779   "x ^ n > 0 \<longleftrightarrow> x > (0::nat) \<or> n = 0"
```
```   780   by (induct n) auto
```
```   781
```
```   782 lemma nat_power_eq_Suc_0_iff [simp]:
```
```   783   "x ^ m = Suc 0 \<longleftrightarrow> m = 0 \<or> x = Suc 0"
```
```   784   by (induct m) auto
```
```   785
```
```   786 lemma power_Suc_0 [simp]:
```
```   787   "Suc 0 ^ n = Suc 0"
```
```   788   by simp
```
```   789
```
```   790 text\<open>Valid for the naturals, but what if \<open>0<i<1\<close>?
```
```   791 Premises cannot be weakened: consider the case where @{term "i=0"},
```
```   792 @{term "m=1"} and @{term "n=0"}.\<close>
```
```   793 lemma nat_power_less_imp_less:
```
```   794   assumes nonneg: "0 < (i::nat)"
```
```   795   assumes less: "i ^ m < i ^ n"
```
```   796   shows "m < n"
```
```   797 proof (cases "i = 1")
```
```   798   case True with less power_one [where 'a = nat] show ?thesis by simp
```
```   799 next
```
```   800   case False with nonneg have "1 < i" by auto
```
```   801   from power_strict_increasing_iff [OF this] less show ?thesis ..
```
```   802 qed
```
```   803
```
```   804 lemma power_dvd_imp_le:
```
```   805   "i ^ m dvd i ^ n \<Longrightarrow> (1::nat) < i \<Longrightarrow> m \<le> n"
```
```   806   apply (rule power_le_imp_le_exp, assumption)
```
```   807   apply (erule dvd_imp_le, simp)
```
```   808   done
```
```   809
```
```   810 lemma power2_nat_le_eq_le:
```
```   811   fixes m n :: nat
```
```   812   shows "m\<^sup>2 \<le> n\<^sup>2 \<longleftrightarrow> m \<le> n"
```
```   813   by (auto intro: power2_le_imp_le power_mono)
```
```   814
```
```   815 lemma power2_nat_le_imp_le:
```
```   816   fixes m n :: nat
```
```   817   assumes "m\<^sup>2 \<le> n"
```
```   818   shows "m \<le> n"
```
```   819 proof (cases m)
```
```   820   case 0 then show ?thesis by simp
```
```   821 next
```
```   822   case (Suc k)
```
```   823   show ?thesis
```
```   824   proof (rule ccontr)
```
```   825     assume "\<not> m \<le> n"
```
```   826     then have "n < m" by simp
```
```   827     with assms Suc show False
```
```   828       by (simp add: power2_eq_square)
```
```   829   qed
```
```   830 qed
```
```   831
```
```   832 subsubsection \<open>Cardinality of the Powerset\<close>
```
```   833
```
```   834 lemma card_UNIV_bool [simp]: "card (UNIV :: bool set) = 2"
```
```   835   unfolding UNIV_bool by simp
```
```   836
```
```   837 lemma card_Pow: "finite A \<Longrightarrow> card (Pow A) = 2 ^ card A"
```
```   838 proof (induct rule: finite_induct)
```
```   839   case empty
```
```   840     show ?case by auto
```
```   841 next
```
```   842   case (insert x A)
```
```   843   then have "inj_on (insert x) (Pow A)"
```
```   844     unfolding inj_on_def by (blast elim!: equalityE)
```
```   845   then have "card (Pow A) + card (insert x ` Pow A) = 2 * 2 ^ card A"
```
```   846     by (simp add: mult_2 card_image Pow_insert insert.hyps)
```
```   847   then show ?case using insert
```
```   848     apply (simp add: Pow_insert)
```
```   849     apply (subst card_Un_disjoint, auto)
```
```   850     done
```
```   851 qed
```
```   852
```
```   853
```
```   854 subsubsection \<open>Generalized sum over a set\<close>
```
```   855
```
```   856 lemma setsum_zero_power [simp]:
```
```   857   fixes c :: "nat \<Rightarrow> 'a::division_ring"
```
```   858   shows "(\<Sum>i\<in>A. c i * 0^i) = (if finite A \<and> 0 \<in> A then c 0 else 0)"
```
```   859 apply (cases "finite A")
```
```   860   by (induction A rule: finite_induct) auto
```
```   861
```
```   862 lemma setsum_zero_power' [simp]:
```
```   863   fixes c :: "nat \<Rightarrow> 'a::field"
```
```   864   shows "(\<Sum>i\<in>A. c i * 0^i / d i) = (if finite A \<and> 0 \<in> A then c 0 / d 0 else 0)"
```
```   865   using setsum_zero_power [of "\<lambda>i. c i / d i" A]
```
```   866   by auto
```
```   867
```
```   868
```
```   869 subsubsection \<open>Generalized product over a set\<close>
```
```   870
```
```   871 lemma setprod_constant: "finite A ==> (\<Prod>x\<in> A. (y::'a::{comm_monoid_mult})) = y^(card A)"
```
```   872 apply (erule finite_induct)
```
```   873 apply auto
```
```   874 done
```
```   875
```
```   876 lemma setprod_power_distrib:
```
```   877   fixes f :: "'a \<Rightarrow> 'b::comm_semiring_1"
```
```   878   shows "setprod f A ^ n = setprod (\<lambda>x. (f x) ^ n) A"
```
```   879 proof (cases "finite A")
```
```   880   case True then show ?thesis
```
```   881     by (induct A rule: finite_induct) (auto simp add: power_mult_distrib)
```
```   882 next
```
```   883   case False then show ?thesis
```
```   884     by simp
```
```   885 qed
```
```   886
```
```   887 lemma power_setsum:
```
```   888   "c ^ (\<Sum>a\<in>A. f a) = (\<Prod>a\<in>A. c ^ f a)"
```
```   889   by (induct A rule: infinite_finite_induct) (simp_all add: power_add)
```
```   890
```
```   891 lemma setprod_gen_delta:
```
```   892   assumes fS: "finite S"
```
```   893   shows "setprod (\<lambda>k. if k=a then b k else c) S = (if a \<in> S then (b a ::'a::comm_monoid_mult) * c^ (card S - 1) else c^ card S)"
```
```   894 proof-
```
```   895   let ?f = "(\<lambda>k. if k=a then b k else c)"
```
```   896   {assume a: "a \<notin> S"
```
```   897     hence "\<forall> k\<in> S. ?f k = c" by simp
```
```   898     hence ?thesis  using a setprod_constant[OF fS, of c] by simp }
```
```   899   moreover
```
```   900   {assume a: "a \<in> S"
```
```   901     let ?A = "S - {a}"
```
```   902     let ?B = "{a}"
```
```   903     have eq: "S = ?A \<union> ?B" using a by blast
```
```   904     have dj: "?A \<inter> ?B = {}" by simp
```
```   905     from fS have fAB: "finite ?A" "finite ?B" by auto
```
```   906     have fA0:"setprod ?f ?A = setprod (\<lambda>i. c) ?A"
```
```   907       apply (rule setprod.cong) by auto
```
```   908     have cA: "card ?A = card S - 1" using fS a by auto
```
```   909     have fA1: "setprod ?f ?A = c ^ card ?A"  unfolding fA0 apply (rule setprod_constant) using fS by auto
```
```   910     have "setprod ?f ?A * setprod ?f ?B = setprod ?f S"
```
```   911       using setprod.union_disjoint[OF fAB dj, of ?f, unfolded eq[symmetric]]
```
```   912       by simp
```
```   913     then have ?thesis using a cA
```
```   914       by (simp add: fA1 field_simps cong add: setprod.cong cong del: if_weak_cong)}
```
```   915   ultimately show ?thesis by blast
```
```   916 qed
```
```   917
```
```   918 subsection \<open>Code generator tweak\<close>
```
```   919
```
```   920 code_identifier
```
```   921   code_module Power \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
```
```   922
```
```   923 end
```