src/HOL/Predicate.thy
author hoelzl
Fri Feb 19 13:40:50 2016 +0100 (2016-02-19)
changeset 62378 85ed00c1fe7c
parent 62026 ea3b1b0413b4
child 62390 842917225d56
permissions -rw-r--r--
generalize more theorems to support enat and ennreal
     1 (*  Title:      HOL/Predicate.thy
     2     Author:     Lukas Bulwahn and Florian Haftmann, TU Muenchen
     3 *)
     4 
     5 section \<open>Predicates as enumerations\<close>
     6 
     7 theory Predicate
     8 imports String
     9 begin
    10 
    11 subsection \<open>The type of predicate enumerations (a monad)\<close>
    12 
    13 datatype (plugins only: code extraction) (dead 'a) pred = Pred "'a \<Rightarrow> bool"
    14 
    15 primrec eval :: "'a pred \<Rightarrow> 'a \<Rightarrow> bool" where
    16   eval_pred: "eval (Pred f) = f"
    17 
    18 lemma Pred_eval [simp]:
    19   "Pred (eval x) = x"
    20   by (cases x) simp
    21 
    22 lemma pred_eqI:
    23   "(\<And>w. eval P w \<longleftrightarrow> eval Q w) \<Longrightarrow> P = Q"
    24   by (cases P, cases Q) (auto simp add: fun_eq_iff)
    25 
    26 lemma pred_eq_iff:
    27   "P = Q \<Longrightarrow> (\<And>w. eval P w \<longleftrightarrow> eval Q w)"
    28   by (simp add: pred_eqI)
    29 
    30 instantiation pred :: (type) complete_lattice
    31 begin
    32 
    33 definition
    34   "P \<le> Q \<longleftrightarrow> eval P \<le> eval Q"
    35 
    36 definition
    37   "P < Q \<longleftrightarrow> eval P < eval Q"
    38 
    39 definition
    40   "\<bottom> = Pred \<bottom>"
    41 
    42 lemma eval_bot [simp]:
    43   "eval \<bottom>  = \<bottom>"
    44   by (simp add: bot_pred_def)
    45 
    46 definition
    47   "\<top> = Pred \<top>"
    48 
    49 lemma eval_top [simp]:
    50   "eval \<top>  = \<top>"
    51   by (simp add: top_pred_def)
    52 
    53 definition
    54   "P \<sqinter> Q = Pred (eval P \<sqinter> eval Q)"
    55 
    56 lemma eval_inf [simp]:
    57   "eval (P \<sqinter> Q) = eval P \<sqinter> eval Q"
    58   by (simp add: inf_pred_def)
    59 
    60 definition
    61   "P \<squnion> Q = Pred (eval P \<squnion> eval Q)"
    62 
    63 lemma eval_sup [simp]:
    64   "eval (P \<squnion> Q) = eval P \<squnion> eval Q"
    65   by (simp add: sup_pred_def)
    66 
    67 definition
    68   "\<Sqinter>A = Pred (INFIMUM A eval)"
    69 
    70 lemma eval_Inf [simp]:
    71   "eval (\<Sqinter>A) = INFIMUM A eval"
    72   by (simp add: Inf_pred_def)
    73 
    74 definition
    75   "\<Squnion>A = Pred (SUPREMUM A eval)"
    76 
    77 lemma eval_Sup [simp]:
    78   "eval (\<Squnion>A) = SUPREMUM A eval"
    79   by (simp add: Sup_pred_def)
    80 
    81 instance proof
    82 qed (auto intro!: pred_eqI simp add: less_eq_pred_def less_pred_def le_fun_def less_fun_def)
    83 
    84 end
    85 
    86 lemma eval_INF [simp]:
    87   "eval (INFIMUM A f) = INFIMUM A (eval \<circ> f)"
    88   using eval_Inf [of "f ` A"] by simp
    89 
    90 lemma eval_SUP [simp]:
    91   "eval (SUPREMUM A f) = SUPREMUM A (eval \<circ> f)"
    92   using eval_Sup [of "f ` A"] by simp
    93 
    94 instantiation pred :: (type) complete_boolean_algebra
    95 begin
    96 
    97 definition
    98   "- P = Pred (- eval P)"
    99 
   100 lemma eval_compl [simp]:
   101   "eval (- P) = - eval P"
   102   by (simp add: uminus_pred_def)
   103 
   104 definition
   105   "P - Q = Pred (eval P - eval Q)"
   106 
   107 lemma eval_minus [simp]:
   108   "eval (P - Q) = eval P - eval Q"
   109   by (simp add: minus_pred_def)
   110 
   111 instance proof
   112 qed (auto intro!: pred_eqI)
   113 
   114 end
   115 
   116 definition single :: "'a \<Rightarrow> 'a pred" where
   117   "single x = Pred ((op =) x)"
   118 
   119 lemma eval_single [simp]:
   120   "eval (single x) = (op =) x"
   121   by (simp add: single_def)
   122 
   123 definition bind :: "'a pred \<Rightarrow> ('a \<Rightarrow> 'b pred) \<Rightarrow> 'b pred" (infixl "\<bind>" 70) where
   124   "P \<bind> f = (SUPREMUM {x. eval P x} f)"
   125 
   126 lemma eval_bind [simp]:
   127   "eval (P \<bind> f) = eval (SUPREMUM {x. eval P x} f)"
   128   by (simp add: bind_def)
   129 
   130 lemma bind_bind:
   131   "(P \<bind> Q) \<bind> R = P \<bind> (\<lambda>x. Q x \<bind> R)"
   132   by (rule pred_eqI) auto
   133 
   134 lemma bind_single:
   135   "P \<bind> single = P"
   136   by (rule pred_eqI) auto
   137 
   138 lemma single_bind:
   139   "single x \<bind> P = P x"
   140   by (rule pred_eqI) auto
   141 
   142 lemma bottom_bind:
   143   "\<bottom> \<bind> P = \<bottom>"
   144   by (rule pred_eqI) auto
   145 
   146 lemma sup_bind:
   147   "(P \<squnion> Q) \<bind> R = P \<bind> R \<squnion> Q \<bind> R"
   148   by (rule pred_eqI) auto
   149 
   150 lemma Sup_bind:
   151   "(\<Squnion>A \<bind> f) = \<Squnion>((\<lambda>x. x \<bind> f) ` A)"
   152   by (rule pred_eqI) auto
   153 
   154 lemma pred_iffI:
   155   assumes "\<And>x. eval A x \<Longrightarrow> eval B x"
   156   and "\<And>x. eval B x \<Longrightarrow> eval A x"
   157   shows "A = B"
   158   using assms by (auto intro: pred_eqI)
   159   
   160 lemma singleI: "eval (single x) x"
   161   by simp
   162 
   163 lemma singleI_unit: "eval (single ()) x"
   164   by simp
   165 
   166 lemma singleE: "eval (single x) y \<Longrightarrow> (y = x \<Longrightarrow> P) \<Longrightarrow> P"
   167   by simp
   168 
   169 lemma singleE': "eval (single x) y \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> P"
   170   by simp
   171 
   172 lemma bindI: "eval P x \<Longrightarrow> eval (Q x) y \<Longrightarrow> eval (P \<bind> Q) y"
   173   by auto
   174 
   175 lemma bindE: "eval (R \<bind> Q) y \<Longrightarrow> (\<And>x. eval R x \<Longrightarrow> eval (Q x) y \<Longrightarrow> P) \<Longrightarrow> P"
   176   by auto
   177 
   178 lemma botE: "eval \<bottom> x \<Longrightarrow> P"
   179   by auto
   180 
   181 lemma supI1: "eval A x \<Longrightarrow> eval (A \<squnion> B) x"
   182   by auto
   183 
   184 lemma supI2: "eval B x \<Longrightarrow> eval (A \<squnion> B) x" 
   185   by auto
   186 
   187 lemma supE: "eval (A \<squnion> B) x \<Longrightarrow> (eval A x \<Longrightarrow> P) \<Longrightarrow> (eval B x \<Longrightarrow> P) \<Longrightarrow> P"
   188   by auto
   189 
   190 lemma single_not_bot [simp]:
   191   "single x \<noteq> \<bottom>"
   192   by (auto simp add: single_def bot_pred_def fun_eq_iff)
   193 
   194 lemma not_bot:
   195   assumes "A \<noteq> \<bottom>"
   196   obtains x where "eval A x"
   197   using assms by (cases A) (auto simp add: bot_pred_def)
   198 
   199 
   200 subsection \<open>Emptiness check and definite choice\<close>
   201 
   202 definition is_empty :: "'a pred \<Rightarrow> bool" where
   203   "is_empty A \<longleftrightarrow> A = \<bottom>"
   204 
   205 lemma is_empty_bot:
   206   "is_empty \<bottom>"
   207   by (simp add: is_empty_def)
   208 
   209 lemma not_is_empty_single:
   210   "\<not> is_empty (single x)"
   211   by (auto simp add: is_empty_def single_def bot_pred_def fun_eq_iff)
   212 
   213 lemma is_empty_sup:
   214   "is_empty (A \<squnion> B) \<longleftrightarrow> is_empty A \<and> is_empty B"
   215   by (auto simp add: is_empty_def)
   216 
   217 definition singleton :: "(unit \<Rightarrow> 'a) \<Rightarrow> 'a pred \<Rightarrow> 'a" where
   218   "\<And>default. singleton default A = (if \<exists>!x. eval A x then THE x. eval A x else default ())"
   219 
   220 lemma singleton_eqI:
   221   fixes default
   222   shows "\<exists>!x. eval A x \<Longrightarrow> eval A x \<Longrightarrow> singleton default A = x"
   223   by (auto simp add: singleton_def)
   224 
   225 lemma eval_singletonI:
   226   fixes default
   227   shows "\<exists>!x. eval A x \<Longrightarrow> eval A (singleton default A)"
   228 proof -
   229   assume assm: "\<exists>!x. eval A x"
   230   then obtain x where x: "eval A x" ..
   231   with assm have "singleton default A = x" by (rule singleton_eqI)
   232   with x show ?thesis by simp
   233 qed
   234 
   235 lemma single_singleton:
   236   fixes default
   237   shows "\<exists>!x. eval A x \<Longrightarrow> single (singleton default A) = A"
   238 proof -
   239   assume assm: "\<exists>!x. eval A x"
   240   then have "eval A (singleton default A)"
   241     by (rule eval_singletonI)
   242   moreover from assm have "\<And>x. eval A x \<Longrightarrow> singleton default A = x"
   243     by (rule singleton_eqI)
   244   ultimately have "eval (single (singleton default A)) = eval A"
   245     by (simp (no_asm_use) add: single_def fun_eq_iff) blast
   246   then have "\<And>x. eval (single (singleton default A)) x = eval A x"
   247     by simp
   248   then show ?thesis by (rule pred_eqI)
   249 qed
   250 
   251 lemma singleton_undefinedI:
   252   fixes default
   253   shows "\<not> (\<exists>!x. eval A x) \<Longrightarrow> singleton default A = default ()"
   254   by (simp add: singleton_def)
   255 
   256 lemma singleton_bot:
   257   fixes default
   258   shows "singleton default \<bottom> = default ()"
   259   by (auto simp add: bot_pred_def intro: singleton_undefinedI)
   260 
   261 lemma singleton_single:
   262   fixes default
   263   shows "singleton default (single x) = x"
   264   by (auto simp add: intro: singleton_eqI singleI elim: singleE)
   265 
   266 lemma singleton_sup_single_single:
   267   fixes default
   268   shows "singleton default (single x \<squnion> single y) = (if x = y then x else default ())"
   269 proof (cases "x = y")
   270   case True then show ?thesis by (simp add: singleton_single)
   271 next
   272   case False
   273   have "eval (single x \<squnion> single y) x"
   274     and "eval (single x \<squnion> single y) y"
   275   by (auto intro: supI1 supI2 singleI)
   276   with False have "\<not> (\<exists>!z. eval (single x \<squnion> single y) z)"
   277     by blast
   278   then have "singleton default (single x \<squnion> single y) = default ()"
   279     by (rule singleton_undefinedI)
   280   with False show ?thesis by simp
   281 qed
   282 
   283 lemma singleton_sup_aux:
   284   fixes default
   285   shows
   286   "singleton default (A \<squnion> B) = (if A = \<bottom> then singleton default B
   287     else if B = \<bottom> then singleton default A
   288     else singleton default
   289       (single (singleton default A) \<squnion> single (singleton default B)))"
   290 proof (cases "(\<exists>!x. eval A x) \<and> (\<exists>!y. eval B y)")
   291   case True then show ?thesis by (simp add: single_singleton)
   292 next
   293   case False
   294   from False have A_or_B:
   295     "singleton default A = default () \<or> singleton default B = default ()"
   296     by (auto intro!: singleton_undefinedI)
   297   then have rhs: "singleton default
   298     (single (singleton default A) \<squnion> single (singleton default B)) = default ()"
   299     by (auto simp add: singleton_sup_single_single singleton_single)
   300   from False have not_unique:
   301     "\<not> (\<exists>!x. eval A x) \<or> \<not> (\<exists>!y. eval B y)" by simp
   302   show ?thesis proof (cases "A \<noteq> \<bottom> \<and> B \<noteq> \<bottom>")
   303     case True
   304     then obtain a b where a: "eval A a" and b: "eval B b"
   305       by (blast elim: not_bot)
   306     with True not_unique have "\<not> (\<exists>!x. eval (A \<squnion> B) x)"
   307       by (auto simp add: sup_pred_def bot_pred_def)
   308     then have "singleton default (A \<squnion> B) = default ()" by (rule singleton_undefinedI)
   309     with True rhs show ?thesis by simp
   310   next
   311     case False then show ?thesis by auto
   312   qed
   313 qed
   314 
   315 lemma singleton_sup:
   316   fixes default
   317   shows
   318   "singleton default (A \<squnion> B) = (if A = \<bottom> then singleton default B
   319     else if B = \<bottom> then singleton default A
   320     else if singleton default A = singleton default B then singleton default A else default ())"
   321   using singleton_sup_aux [of default A B] by (simp only: singleton_sup_single_single)
   322 
   323 
   324 subsection \<open>Derived operations\<close>
   325 
   326 definition if_pred :: "bool \<Rightarrow> unit pred" where
   327   if_pred_eq: "if_pred b = (if b then single () else \<bottom>)"
   328 
   329 definition holds :: "unit pred \<Rightarrow> bool" where
   330   holds_eq: "holds P = eval P ()"
   331 
   332 definition not_pred :: "unit pred \<Rightarrow> unit pred" where
   333   not_pred_eq: "not_pred P = (if eval P () then \<bottom> else single ())"
   334 
   335 lemma if_predI: "P \<Longrightarrow> eval (if_pred P) ()"
   336   unfolding if_pred_eq by (auto intro: singleI)
   337 
   338 lemma if_predE: "eval (if_pred b) x \<Longrightarrow> (b \<Longrightarrow> x = () \<Longrightarrow> P) \<Longrightarrow> P"
   339   unfolding if_pred_eq by (cases b) (auto elim: botE)
   340 
   341 lemma not_predI: "\<not> P \<Longrightarrow> eval (not_pred (Pred (\<lambda>u. P))) ()"
   342   unfolding not_pred_eq eval_pred by (auto intro: singleI)
   343 
   344 lemma not_predI': "\<not> eval P () \<Longrightarrow> eval (not_pred P) ()"
   345   unfolding not_pred_eq by (auto intro: singleI)
   346 
   347 lemma not_predE: "eval (not_pred (Pred (\<lambda>u. P))) x \<Longrightarrow> (\<not> P \<Longrightarrow> thesis) \<Longrightarrow> thesis"
   348   unfolding not_pred_eq
   349   by (auto split: split_if_asm elim: botE)
   350 
   351 lemma not_predE': "eval (not_pred P) x \<Longrightarrow> (\<not> eval P x \<Longrightarrow> thesis) \<Longrightarrow> thesis"
   352   unfolding not_pred_eq
   353   by (auto split: split_if_asm elim: botE)
   354 lemma "f () = False \<or> f () = True"
   355 by simp
   356 
   357 lemma closure_of_bool_cases [no_atp]:
   358   fixes f :: "unit \<Rightarrow> bool"
   359   assumes "f = (\<lambda>u. False) \<Longrightarrow> P f"
   360   assumes "f = (\<lambda>u. True) \<Longrightarrow> P f"
   361   shows "P f"
   362 proof -
   363   have "f = (\<lambda>u. False) \<or> f = (\<lambda>u. True)"
   364     apply (cases "f ()")
   365     apply (rule disjI2)
   366     apply (rule ext)
   367     apply (simp add: unit_eq)
   368     apply (rule disjI1)
   369     apply (rule ext)
   370     apply (simp add: unit_eq)
   371     done
   372   from this assms show ?thesis by blast
   373 qed
   374 
   375 lemma unit_pred_cases:
   376   assumes "P \<bottom>"
   377   assumes "P (single ())"
   378   shows "P Q"
   379 using assms unfolding bot_pred_def bot_fun_def bot_bool_def empty_def single_def proof (cases Q)
   380   fix f
   381   assume "P (Pred (\<lambda>u. False))" "P (Pred (\<lambda>u. () = u))"
   382   then have "P (Pred f)" 
   383     by (cases _ f rule: closure_of_bool_cases) simp_all
   384   moreover assume "Q = Pred f"
   385   ultimately show "P Q" by simp
   386 qed
   387   
   388 lemma holds_if_pred:
   389   "holds (if_pred b) = b"
   390 unfolding if_pred_eq holds_eq
   391 by (cases b) (auto intro: singleI elim: botE)
   392 
   393 lemma if_pred_holds:
   394   "if_pred (holds P) = P"
   395 unfolding if_pred_eq holds_eq
   396 by (rule unit_pred_cases) (auto intro: singleI elim: botE)
   397 
   398 lemma is_empty_holds:
   399   "is_empty P \<longleftrightarrow> \<not> holds P"
   400 unfolding is_empty_def holds_eq
   401 by (rule unit_pred_cases) (auto elim: botE intro: singleI)
   402 
   403 definition map :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a pred \<Rightarrow> 'b pred" where
   404   "map f P = P \<bind> (single o f)"
   405 
   406 lemma eval_map [simp]:
   407   "eval (map f P) = (\<Squnion>x\<in>{x. eval P x}. (\<lambda>y. f x = y))"
   408   by (auto simp add: map_def comp_def)
   409 
   410 functor map: map
   411   by (rule ext, rule pred_eqI, auto)+
   412 
   413 
   414 subsection \<open>Implementation\<close>
   415 
   416 datatype (plugins only: code extraction) (dead 'a) seq =
   417   Empty
   418 | Insert "'a" "'a pred"
   419 | Join "'a pred" "'a seq"
   420 
   421 primrec pred_of_seq :: "'a seq \<Rightarrow> 'a pred" where
   422   "pred_of_seq Empty = \<bottom>"
   423 | "pred_of_seq (Insert x P) = single x \<squnion> P"
   424 | "pred_of_seq (Join P xq) = P \<squnion> pred_of_seq xq"
   425 
   426 definition Seq :: "(unit \<Rightarrow> 'a seq) \<Rightarrow> 'a pred" where
   427   "Seq f = pred_of_seq (f ())"
   428 
   429 code_datatype Seq
   430 
   431 primrec member :: "'a seq \<Rightarrow> 'a \<Rightarrow> bool"  where
   432   "member Empty x \<longleftrightarrow> False"
   433 | "member (Insert y P) x \<longleftrightarrow> x = y \<or> eval P x"
   434 | "member (Join P xq) x \<longleftrightarrow> eval P x \<or> member xq x"
   435 
   436 lemma eval_member:
   437   "member xq = eval (pred_of_seq xq)"
   438 proof (induct xq)
   439   case Empty show ?case
   440   by (auto simp add: fun_eq_iff elim: botE)
   441 next
   442   case Insert show ?case
   443   by (auto simp add: fun_eq_iff elim: supE singleE intro: supI1 supI2 singleI)
   444 next
   445   case Join then show ?case
   446   by (auto simp add: fun_eq_iff elim: supE intro: supI1 supI2)
   447 qed
   448 
   449 lemma eval_code [(* FIXME declare simp *)code]: "eval (Seq f) = member (f ())"
   450   unfolding Seq_def by (rule sym, rule eval_member)
   451 
   452 lemma single_code [code]:
   453   "single x = Seq (\<lambda>u. Insert x \<bottom>)"
   454   unfolding Seq_def by simp
   455 
   456 primrec "apply" :: "('a \<Rightarrow> 'b pred) \<Rightarrow> 'a seq \<Rightarrow> 'b seq" where
   457   "apply f Empty = Empty"
   458 | "apply f (Insert x P) = Join (f x) (Join (P \<bind> f) Empty)"
   459 | "apply f (Join P xq) = Join (P \<bind> f) (apply f xq)"
   460 
   461 lemma apply_bind:
   462   "pred_of_seq (apply f xq) = pred_of_seq xq \<bind> f"
   463 proof (induct xq)
   464   case Empty show ?case
   465     by (simp add: bottom_bind)
   466 next
   467   case Insert show ?case
   468     by (simp add: single_bind sup_bind)
   469 next
   470   case Join then show ?case
   471     by (simp add: sup_bind)
   472 qed
   473   
   474 lemma bind_code [code]:
   475   "Seq g \<bind> f = Seq (\<lambda>u. apply f (g ()))"
   476   unfolding Seq_def by (rule sym, rule apply_bind)
   477 
   478 lemma bot_set_code [code]:
   479   "\<bottom> = Seq (\<lambda>u. Empty)"
   480   unfolding Seq_def by simp
   481 
   482 primrec adjunct :: "'a pred \<Rightarrow> 'a seq \<Rightarrow> 'a seq" where
   483   "adjunct P Empty = Join P Empty"
   484 | "adjunct P (Insert x Q) = Insert x (Q \<squnion> P)"
   485 | "adjunct P (Join Q xq) = Join Q (adjunct P xq)"
   486 
   487 lemma adjunct_sup:
   488   "pred_of_seq (adjunct P xq) = P \<squnion> pred_of_seq xq"
   489   by (induct xq) (simp_all add: sup_assoc sup_commute sup_left_commute)
   490 
   491 lemma sup_code [code]:
   492   "Seq f \<squnion> Seq g = Seq (\<lambda>u. case f ()
   493     of Empty \<Rightarrow> g ()
   494      | Insert x P \<Rightarrow> Insert x (P \<squnion> Seq g)
   495      | Join P xq \<Rightarrow> adjunct (Seq g) (Join P xq))"
   496 proof (cases "f ()")
   497   case Empty
   498   thus ?thesis
   499     unfolding Seq_def by (simp add: sup_commute [of "\<bottom>"])
   500 next
   501   case Insert
   502   thus ?thesis
   503     unfolding Seq_def by (simp add: sup_assoc)
   504 next
   505   case Join
   506   thus ?thesis
   507     unfolding Seq_def
   508     by (simp add: adjunct_sup sup_assoc sup_commute sup_left_commute)
   509 qed
   510 
   511 primrec contained :: "'a seq \<Rightarrow> 'a pred \<Rightarrow> bool" where
   512   "contained Empty Q \<longleftrightarrow> True"
   513 | "contained (Insert x P) Q \<longleftrightarrow> eval Q x \<and> P \<le> Q"
   514 | "contained (Join P xq) Q \<longleftrightarrow> P \<le> Q \<and> contained xq Q"
   515 
   516 lemma single_less_eq_eval:
   517   "single x \<le> P \<longleftrightarrow> eval P x"
   518   by (auto simp add: less_eq_pred_def le_fun_def)
   519 
   520 lemma contained_less_eq:
   521   "contained xq Q \<longleftrightarrow> pred_of_seq xq \<le> Q"
   522   by (induct xq) (simp_all add: single_less_eq_eval)
   523 
   524 lemma less_eq_pred_code [code]:
   525   "Seq f \<le> Q = (case f ()
   526    of Empty \<Rightarrow> True
   527     | Insert x P \<Rightarrow> eval Q x \<and> P \<le> Q
   528     | Join P xq \<Rightarrow> P \<le> Q \<and> contained xq Q)"
   529   by (cases "f ()")
   530     (simp_all add: Seq_def single_less_eq_eval contained_less_eq)
   531 
   532 lemma eq_pred_code [code]:
   533   fixes P Q :: "'a pred"
   534   shows "HOL.equal P Q \<longleftrightarrow> P \<le> Q \<and> Q \<le> P"
   535   by (auto simp add: equal)
   536 
   537 lemma [code nbe]:
   538   "HOL.equal (x :: 'a pred) x \<longleftrightarrow> True"
   539   by (fact equal_refl)
   540 
   541 lemma [code]:
   542   "case_pred f P = f (eval P)"
   543   by (cases P) simp
   544 
   545 lemma [code]:
   546   "rec_pred f P = f (eval P)"
   547   by (cases P) simp
   548 
   549 inductive eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool" where "eq x x"
   550 
   551 lemma eq_is_eq: "eq x y \<equiv> (x = y)"
   552   by (rule eq_reflection) (auto intro: eq.intros elim: eq.cases)
   553 
   554 primrec null :: "'a seq \<Rightarrow> bool" where
   555   "null Empty \<longleftrightarrow> True"
   556 | "null (Insert x P) \<longleftrightarrow> False"
   557 | "null (Join P xq) \<longleftrightarrow> is_empty P \<and> null xq"
   558 
   559 lemma null_is_empty:
   560   "null xq \<longleftrightarrow> is_empty (pred_of_seq xq)"
   561   by (induct xq) (simp_all add: is_empty_bot not_is_empty_single is_empty_sup)
   562 
   563 lemma is_empty_code [code]:
   564   "is_empty (Seq f) \<longleftrightarrow> null (f ())"
   565   by (simp add: null_is_empty Seq_def)
   566 
   567 primrec the_only :: "(unit \<Rightarrow> 'a) \<Rightarrow> 'a seq \<Rightarrow> 'a" where
   568   [code del]: "\<And>default. the_only default Empty = default ()"
   569 | "\<And>default. the_only default (Insert x P) =
   570     (if is_empty P then x else let y = singleton default P in if x = y then x else default ())"
   571 | "\<And>default. the_only default (Join P xq) =
   572     (if is_empty P then the_only default xq else if null xq then singleton default P
   573        else let x = singleton default P; y = the_only default xq in
   574        if x = y then x else default ())"
   575 
   576 lemma the_only_singleton:
   577   fixes default
   578   shows "the_only default xq = singleton default (pred_of_seq xq)"
   579   by (induct xq)
   580     (auto simp add: singleton_bot singleton_single is_empty_def
   581     null_is_empty Let_def singleton_sup)
   582 
   583 lemma singleton_code [code]:
   584   fixes default
   585   shows
   586   "singleton default (Seq f) =
   587     (case f () of
   588       Empty \<Rightarrow> default ()
   589     | Insert x P \<Rightarrow> if is_empty P then x
   590         else let y = singleton default P in
   591           if x = y then x else default ()
   592     | Join P xq \<Rightarrow> if is_empty P then the_only default xq
   593         else if null xq then singleton default P
   594         else let x = singleton default P; y = the_only default xq in
   595           if x = y then x else default ())"
   596   by (cases "f ()")
   597    (auto simp add: Seq_def the_only_singleton is_empty_def
   598       null_is_empty singleton_bot singleton_single singleton_sup Let_def)
   599 
   600 definition the :: "'a pred \<Rightarrow> 'a" where
   601   "the A = (THE x. eval A x)"
   602 
   603 lemma the_eqI:
   604   "(THE x. eval P x) = x \<Longrightarrow> the P = x"
   605   by (simp add: the_def)
   606 
   607 lemma the_eq [code]: "the A = singleton (\<lambda>x. Code.abort (STR ''not_unique'') (\<lambda>_. the A)) A"
   608   by (rule the_eqI) (simp add: singleton_def the_def)
   609 
   610 code_reflect Predicate
   611   datatypes pred = Seq and seq = Empty | Insert | Join
   612 
   613 ML \<open>
   614 signature PREDICATE =
   615 sig
   616   val anamorph: ('a -> ('b * 'a) option) -> int -> 'a -> 'b list * 'a
   617   datatype 'a pred = Seq of (unit -> 'a seq)
   618   and 'a seq = Empty | Insert of 'a * 'a pred | Join of 'a pred * 'a seq
   619   val map: ('a -> 'b) -> 'a pred -> 'b pred
   620   val yield: 'a pred -> ('a * 'a pred) option
   621   val yieldn: int -> 'a pred -> 'a list * 'a pred
   622 end;
   623 
   624 structure Predicate : PREDICATE =
   625 struct
   626 
   627 fun anamorph f k x =
   628  (if k = 0 then ([], x)
   629   else case f x
   630    of NONE => ([], x)
   631     | SOME (v, y) => let
   632         val k' = k - 1;
   633         val (vs, z) = anamorph f k' y
   634       in (v :: vs, z) end);
   635 
   636 datatype pred = datatype Predicate.pred
   637 datatype seq = datatype Predicate.seq
   638 
   639 fun map f = @{code Predicate.map} f;
   640 
   641 fun yield (Seq f) = next (f ())
   642 and next Empty = NONE
   643   | next (Insert (x, P)) = SOME (x, P)
   644   | next (Join (P, xq)) = (case yield P
   645      of NONE => next xq
   646       | SOME (x, Q) => SOME (x, Seq (fn _ => Join (Q, xq))));
   647 
   648 fun yieldn k = anamorph yield k;
   649 
   650 end;
   651 \<close>
   652 
   653 text \<open>Conversion from and to sets\<close>
   654 
   655 definition pred_of_set :: "'a set \<Rightarrow> 'a pred" where
   656   "pred_of_set = Pred \<circ> (\<lambda>A x. x \<in> A)"
   657 
   658 lemma eval_pred_of_set [simp]:
   659   "eval (pred_of_set A) x \<longleftrightarrow> x \<in>A"
   660   by (simp add: pred_of_set_def)
   661 
   662 definition set_of_pred :: "'a pred \<Rightarrow> 'a set" where
   663   "set_of_pred = Collect \<circ> eval"
   664 
   665 lemma member_set_of_pred [simp]:
   666   "x \<in> set_of_pred P \<longleftrightarrow> Predicate.eval P x"
   667   by (simp add: set_of_pred_def)
   668 
   669 definition set_of_seq :: "'a seq \<Rightarrow> 'a set" where
   670   "set_of_seq = set_of_pred \<circ> pred_of_seq"
   671 
   672 lemma member_set_of_seq [simp]:
   673   "x \<in> set_of_seq xq = Predicate.member xq x"
   674   by (simp add: set_of_seq_def eval_member)
   675 
   676 lemma of_pred_code [code]:
   677   "set_of_pred (Predicate.Seq f) = (case f () of
   678      Predicate.Empty \<Rightarrow> {}
   679    | Predicate.Insert x P \<Rightarrow> insert x (set_of_pred P)
   680    | Predicate.Join P xq \<Rightarrow> set_of_pred P \<union> set_of_seq xq)"
   681   by (auto split: seq.split simp add: eval_code)
   682 
   683 lemma of_seq_code [code]:
   684   "set_of_seq Predicate.Empty = {}"
   685   "set_of_seq (Predicate.Insert x P) = insert x (set_of_pred P)"
   686   "set_of_seq (Predicate.Join P xq) = set_of_pred P \<union> set_of_seq xq"
   687   by auto
   688 
   689 text \<open>Lazy Evaluation of an indexed function\<close>
   690 
   691 function iterate_upto :: "(natural \<Rightarrow> 'a) \<Rightarrow> natural \<Rightarrow> natural \<Rightarrow> 'a Predicate.pred"
   692 where
   693   "iterate_upto f n m =
   694     Predicate.Seq (%u. if n > m then Predicate.Empty
   695      else Predicate.Insert (f n) (iterate_upto f (n + 1) m))"
   696 by pat_completeness auto
   697 
   698 termination by (relation "measure (%(f, n, m). nat_of_natural (m + 1 - n))")
   699   (auto simp add: less_natural_def)
   700 
   701 text \<open>Misc\<close>
   702 
   703 declare Inf_set_fold [where 'a = "'a Predicate.pred", code]
   704 declare Sup_set_fold [where 'a = "'a Predicate.pred", code]
   705 
   706 (* FIXME: better implement conversion by bisection *)
   707 
   708 lemma pred_of_set_fold_sup:
   709   assumes "finite A"
   710   shows "pred_of_set A = Finite_Set.fold sup bot (Predicate.single ` A)" (is "?lhs = ?rhs")
   711 proof (rule sym)
   712   interpret comp_fun_idem "sup :: 'a Predicate.pred \<Rightarrow> 'a Predicate.pred \<Rightarrow> 'a Predicate.pred"
   713     by (fact comp_fun_idem_sup)
   714   from \<open>finite A\<close> show "?rhs = ?lhs" by (induct A) (auto intro!: pred_eqI)
   715 qed
   716 
   717 lemma pred_of_set_set_fold_sup:
   718   "pred_of_set (set xs) = fold sup (List.map Predicate.single xs) bot"
   719 proof -
   720   interpret comp_fun_idem "sup :: 'a Predicate.pred \<Rightarrow> 'a Predicate.pred \<Rightarrow> 'a Predicate.pred"
   721     by (fact comp_fun_idem_sup)
   722   show ?thesis by (simp add: pred_of_set_fold_sup fold_set_fold [symmetric])
   723 qed
   724 
   725 lemma pred_of_set_set_foldr_sup [code]:
   726   "pred_of_set (set xs) = foldr sup (List.map Predicate.single xs) bot"
   727   by (simp add: pred_of_set_set_fold_sup ac_simps foldr_fold fun_eq_iff)
   728 
   729 no_notation
   730   bind (infixl "\<bind>" 70)
   731 
   732 hide_type (open) pred seq
   733 hide_const (open) Pred eval single bind is_empty singleton if_pred not_pred holds
   734   Empty Insert Join Seq member pred_of_seq "apply" adjunct null the_only eq map the
   735   iterate_upto
   736 hide_fact (open) null_def member_def
   737 
   738 end