src/HOL/Probability/Finite_Product_Measure.thy
author hoelzl
Fri Feb 19 13:40:50 2016 +0100 (2016-02-19)
changeset 62378 85ed00c1fe7c
parent 61988 34b51f436e92
child 62390 842917225d56
permissions -rw-r--r--
generalize more theorems to support enat and ennreal
     1 (*  Title:      HOL/Probability/Finite_Product_Measure.thy
     2     Author:     Johannes Hölzl, TU München
     3 *)
     4 
     5 section \<open>Finite product measures\<close>
     6 
     7 theory Finite_Product_Measure
     8 imports Binary_Product_Measure
     9 begin
    10 
    11 lemma PiE_choice: "(\<exists>f\<in>PiE I F. \<forall>i\<in>I. P i (f i)) \<longleftrightarrow> (\<forall>i\<in>I. \<exists>x\<in>F i. P i x)"
    12   by (auto simp: Bex_def PiE_iff Ball_def dest!: choice_iff'[THEN iffD1])
    13      (force intro: exI[of _ "restrict f I" for f])
    14 
    15 lemma case_prod_const: "(\<lambda>(i, j). c) = (\<lambda>_. c)"
    16   by auto
    17 
    18 subsubsection \<open>More about Function restricted by @{const extensional}\<close>
    19 
    20 definition
    21   "merge I J = (\<lambda>(x, y) i. if i \<in> I then x i else if i \<in> J then y i else undefined)"
    22 
    23 lemma merge_apply[simp]:
    24   "I \<inter> J = {} \<Longrightarrow> i \<in> I \<Longrightarrow> merge I J (x, y) i = x i"
    25   "I \<inter> J = {} \<Longrightarrow> i \<in> J \<Longrightarrow> merge I J (x, y) i = y i"
    26   "J \<inter> I = {} \<Longrightarrow> i \<in> I \<Longrightarrow> merge I J (x, y) i = x i"
    27   "J \<inter> I = {} \<Longrightarrow> i \<in> J \<Longrightarrow> merge I J (x, y) i = y i"
    28   "i \<notin> I \<Longrightarrow> i \<notin> J \<Longrightarrow> merge I J (x, y) i = undefined"
    29   unfolding merge_def by auto
    30 
    31 lemma merge_commute:
    32   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) = merge J I (y, x)"
    33   by (force simp: merge_def)
    34 
    35 lemma Pi_cancel_merge_range[simp]:
    36   "I \<inter> J = {} \<Longrightarrow> x \<in> Pi I (merge I J (A, B)) \<longleftrightarrow> x \<in> Pi I A"
    37   "I \<inter> J = {} \<Longrightarrow> x \<in> Pi I (merge J I (B, A)) \<longleftrightarrow> x \<in> Pi I A"
    38   "J \<inter> I = {} \<Longrightarrow> x \<in> Pi I (merge I J (A, B)) \<longleftrightarrow> x \<in> Pi I A"
    39   "J \<inter> I = {} \<Longrightarrow> x \<in> Pi I (merge J I (B, A)) \<longleftrightarrow> x \<in> Pi I A"
    40   by (auto simp: Pi_def)
    41 
    42 lemma Pi_cancel_merge[simp]:
    43   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
    44   "J \<inter> I = {} \<Longrightarrow> merge I J (x, y) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
    45   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) \<in> Pi J B \<longleftrightarrow> y \<in> Pi J B"
    46   "J \<inter> I = {} \<Longrightarrow> merge I J (x, y) \<in> Pi J B \<longleftrightarrow> y \<in> Pi J B"
    47   by (auto simp: Pi_def)
    48 
    49 lemma extensional_merge[simp]: "merge I J (x, y) \<in> extensional (I \<union> J)"
    50   by (auto simp: extensional_def)
    51 
    52 lemma restrict_merge[simp]:
    53   "I \<inter> J = {} \<Longrightarrow> restrict (merge I J (x, y)) I = restrict x I"
    54   "I \<inter> J = {} \<Longrightarrow> restrict (merge I J (x, y)) J = restrict y J"
    55   "J \<inter> I = {} \<Longrightarrow> restrict (merge I J (x, y)) I = restrict x I"
    56   "J \<inter> I = {} \<Longrightarrow> restrict (merge I J (x, y)) J = restrict y J"
    57   by (auto simp: restrict_def)
    58 
    59 lemma split_merge: "P (merge I J (x,y) i) \<longleftrightarrow> (i \<in> I \<longrightarrow> P (x i)) \<and> (i \<in> J - I \<longrightarrow> P (y i)) \<and> (i \<notin> I \<union> J \<longrightarrow> P undefined)"
    60   unfolding merge_def by auto
    61 
    62 lemma PiE_cancel_merge[simp]:
    63   "I \<inter> J = {} \<Longrightarrow>
    64     merge I J (x, y) \<in> PiE (I \<union> J) B \<longleftrightarrow> x \<in> Pi I B \<and> y \<in> Pi J B"
    65   by (auto simp: PiE_def restrict_Pi_cancel)
    66 
    67 lemma merge_singleton[simp]: "i \<notin> I \<Longrightarrow> merge I {i} (x,y) = restrict (x(i := y i)) (insert i I)"
    68   unfolding merge_def by (auto simp: fun_eq_iff)
    69 
    70 lemma extensional_merge_sub: "I \<union> J \<subseteq> K \<Longrightarrow> merge I J (x, y) \<in> extensional K"
    71   unfolding merge_def extensional_def by auto
    72 
    73 lemma merge_restrict[simp]:
    74   "merge I J (restrict x I, y) = merge I J (x, y)"
    75   "merge I J (x, restrict y J) = merge I J (x, y)"
    76   unfolding merge_def by auto
    77 
    78 lemma merge_x_x_eq_restrict[simp]:
    79   "merge I J (x, x) = restrict x (I \<union> J)"
    80   unfolding merge_def by auto
    81 
    82 lemma injective_vimage_restrict:
    83   assumes J: "J \<subseteq> I"
    84   and sets: "A \<subseteq> (\<Pi>\<^sub>E i\<in>J. S i)" "B \<subseteq> (\<Pi>\<^sub>E i\<in>J. S i)" and ne: "(\<Pi>\<^sub>E i\<in>I. S i) \<noteq> {}"
    85   and eq: "(\<lambda>x. restrict x J) -` A \<inter> (\<Pi>\<^sub>E i\<in>I. S i) = (\<lambda>x. restrict x J) -` B \<inter> (\<Pi>\<^sub>E i\<in>I. S i)"
    86   shows "A = B"
    87 proof  (intro set_eqI)
    88   fix x
    89   from ne obtain y where y: "\<And>i. i \<in> I \<Longrightarrow> y i \<in> S i" by auto
    90   have "J \<inter> (I - J) = {}" by auto
    91   show "x \<in> A \<longleftrightarrow> x \<in> B"
    92   proof cases
    93     assume x: "x \<in> (\<Pi>\<^sub>E i\<in>J. S i)"
    94     have "x \<in> A \<longleftrightarrow> merge J (I - J) (x,y) \<in> (\<lambda>x. restrict x J) -` A \<inter> (\<Pi>\<^sub>E i\<in>I. S i)"
    95       using y x \<open>J \<subseteq> I\<close> PiE_cancel_merge[of "J" "I - J" x y S]
    96       by (auto simp del: PiE_cancel_merge simp add: Un_absorb1)
    97     then show "x \<in> A \<longleftrightarrow> x \<in> B"
    98       using y x \<open>J \<subseteq> I\<close> PiE_cancel_merge[of "J" "I - J" x y S]
    99       by (auto simp del: PiE_cancel_merge simp add: Un_absorb1 eq)
   100   qed (insert sets, auto)
   101 qed
   102 
   103 lemma restrict_vimage:
   104   "I \<inter> J = {} \<Longrightarrow>
   105     (\<lambda>x. (restrict x I, restrict x J)) -` (Pi\<^sub>E I E \<times> Pi\<^sub>E J F) = Pi (I \<union> J) (merge I J (E, F))"
   106   by (auto simp: restrict_Pi_cancel PiE_def)
   107 
   108 lemma merge_vimage:
   109   "I \<inter> J = {} \<Longrightarrow> merge I J -` Pi\<^sub>E (I \<union> J) E = Pi I E \<times> Pi J E"
   110   by (auto simp: restrict_Pi_cancel PiE_def)
   111 
   112 subsection \<open>Finite product spaces\<close>
   113 
   114 subsubsection \<open>Products\<close>
   115 
   116 definition prod_emb where
   117   "prod_emb I M K X = (\<lambda>x. restrict x K) -` X \<inter> (PIE i:I. space (M i))"
   118 
   119 lemma prod_emb_iff: 
   120   "f \<in> prod_emb I M K X \<longleftrightarrow> f \<in> extensional I \<and> (restrict f K \<in> X) \<and> (\<forall>i\<in>I. f i \<in> space (M i))"
   121   unfolding prod_emb_def PiE_def by auto
   122 
   123 lemma
   124   shows prod_emb_empty[simp]: "prod_emb M L K {} = {}"
   125     and prod_emb_Un[simp]: "prod_emb M L K (A \<union> B) = prod_emb M L K A \<union> prod_emb M L K B"
   126     and prod_emb_Int: "prod_emb M L K (A \<inter> B) = prod_emb M L K A \<inter> prod_emb M L K B"
   127     and prod_emb_UN[simp]: "prod_emb M L K (\<Union>i\<in>I. F i) = (\<Union>i\<in>I. prod_emb M L K (F i))"
   128     and prod_emb_INT[simp]: "I \<noteq> {} \<Longrightarrow> prod_emb M L K (\<Inter>i\<in>I. F i) = (\<Inter>i\<in>I. prod_emb M L K (F i))"
   129     and prod_emb_Diff[simp]: "prod_emb M L K (A - B) = prod_emb M L K A - prod_emb M L K B"
   130   by (auto simp: prod_emb_def)
   131 
   132 lemma prod_emb_PiE: "J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> E i \<subseteq> space (M i)) \<Longrightarrow>
   133     prod_emb I M J (\<Pi>\<^sub>E i\<in>J. E i) = (\<Pi>\<^sub>E i\<in>I. if i \<in> J then E i else space (M i))"
   134   by (force simp: prod_emb_def PiE_iff split_if_mem2)
   135 
   136 lemma prod_emb_PiE_same_index[simp]:
   137     "(\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> space (M i)) \<Longrightarrow> prod_emb I M I (Pi\<^sub>E I E) = Pi\<^sub>E I E"
   138   by (auto simp: prod_emb_def PiE_iff)
   139 
   140 lemma prod_emb_trans[simp]:
   141   "J \<subseteq> K \<Longrightarrow> K \<subseteq> L \<Longrightarrow> prod_emb L M K (prod_emb K M J X) = prod_emb L M J X"
   142   by (auto simp add: Int_absorb1 prod_emb_def PiE_def)
   143 
   144 lemma prod_emb_Pi:
   145   assumes "X \<in> (\<Pi> j\<in>J. sets (M j))" "J \<subseteq> K"
   146   shows "prod_emb K M J (Pi\<^sub>E J X) = (\<Pi>\<^sub>E i\<in>K. if i \<in> J then X i else space (M i))"
   147   using assms sets.space_closed
   148   by (auto simp: prod_emb_def PiE_iff split: split_if_asm) blast+
   149 
   150 lemma prod_emb_id:
   151   "B \<subseteq> (\<Pi>\<^sub>E i\<in>L. space (M i)) \<Longrightarrow> prod_emb L M L B = B"
   152   by (auto simp: prod_emb_def subset_eq extensional_restrict)
   153 
   154 lemma prod_emb_mono:
   155   "F \<subseteq> G \<Longrightarrow> prod_emb A M B F \<subseteq> prod_emb A M B G"
   156   by (auto simp: prod_emb_def)
   157 
   158 definition PiM :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i \<Rightarrow> 'a) measure" where
   159   "PiM I M = extend_measure (\<Pi>\<^sub>E i\<in>I. space (M i))
   160     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}
   161     (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^sub>E j\<in>J. X j))
   162     (\<lambda>(J, X). \<Prod>j\<in>J \<union> {i\<in>I. emeasure (M i) (space (M i)) \<noteq> 1}. if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j)))"
   163 
   164 definition prod_algebra :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i \<Rightarrow> 'a) set set" where
   165   "prod_algebra I M = (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^sub>E j\<in>J. X j)) `
   166     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}"
   167 
   168 abbreviation
   169   "Pi\<^sub>M I M \<equiv> PiM I M"
   170 
   171 syntax
   172   "_PiM" :: "pttrn \<Rightarrow> 'i set \<Rightarrow> 'a measure \<Rightarrow> ('i => 'a) measure"  ("(3\<Pi>\<^sub>M _\<in>_./ _)"  10)
   173 translations
   174   "\<Pi>\<^sub>M x\<in>I. M" == "CONST PiM I (%x. M)"
   175 
   176 lemma extend_measure_cong:
   177   assumes "\<Omega> = \<Omega>'" "I = I'" "G = G'" "\<And>i. i \<in> I' \<Longrightarrow> \<mu> i = \<mu>' i"
   178   shows "extend_measure \<Omega> I G \<mu> = extend_measure \<Omega>' I' G' \<mu>'"
   179   unfolding extend_measure_def by (auto simp add: assms)
   180 
   181 lemma Pi_cong_sets:
   182     "\<lbrakk>I = J; \<And>x. x \<in> I \<Longrightarrow> M x = N x\<rbrakk> \<Longrightarrow> Pi I M = Pi J N"
   183   unfolding Pi_def by auto 
   184 
   185 lemma PiM_cong:
   186   assumes "I = J" "\<And>x. x \<in> I \<Longrightarrow> M x = N x"
   187   shows "PiM I M = PiM J N"
   188   unfolding PiM_def
   189 proof (rule extend_measure_cong, goal_cases)
   190   case 1
   191   show ?case using assms
   192     by (subst assms(1), intro PiE_cong[of J "\<lambda>i. space (M i)" "\<lambda>i. space (N i)"]) simp_all
   193 next
   194   case 2
   195   have "\<And>K. K \<subseteq> J \<Longrightarrow> (\<Pi> j\<in>K. sets (M j)) = (\<Pi> j\<in>K. sets (N j))"
   196     using assms by (intro Pi_cong_sets) auto
   197   thus ?case by (auto simp: assms)
   198 next
   199   case 3
   200   show ?case using assms 
   201     by (intro ext) (auto simp: prod_emb_def dest: PiE_mem)
   202 next
   203   case (4 x)
   204   thus ?case using assms 
   205     by (auto intro!: setprod.cong split: split_if_asm)
   206 qed
   207 
   208 
   209 lemma prod_algebra_sets_into_space:
   210   "prod_algebra I M \<subseteq> Pow (\<Pi>\<^sub>E i\<in>I. space (M i))"
   211   by (auto simp: prod_emb_def prod_algebra_def)
   212 
   213 lemma prod_algebra_eq_finite:
   214   assumes I: "finite I"
   215   shows "prod_algebra I M = {(\<Pi>\<^sub>E i\<in>I. X i) |X. X \<in> (\<Pi> j\<in>I. sets (M j))}" (is "?L = ?R")
   216 proof (intro iffI set_eqI)
   217   fix A assume "A \<in> ?L"
   218   then obtain J E where J: "J \<noteq> {} \<or> I = {}" "finite J" "J \<subseteq> I" "\<forall>i\<in>J. E i \<in> sets (M i)"
   219     and A: "A = prod_emb I M J (PIE j:J. E j)"
   220     by (auto simp: prod_algebra_def)
   221   let ?A = "\<Pi>\<^sub>E i\<in>I. if i \<in> J then E i else space (M i)"
   222   have A: "A = ?A"
   223     unfolding A using J by (intro prod_emb_PiE sets.sets_into_space) auto
   224   show "A \<in> ?R" unfolding A using J sets.top
   225     by (intro CollectI exI[of _ "\<lambda>i. if i \<in> J then E i else space (M i)"]) simp
   226 next
   227   fix A assume "A \<in> ?R"
   228   then obtain X where A: "A = (\<Pi>\<^sub>E i\<in>I. X i)" and X: "X \<in> (\<Pi> j\<in>I. sets (M j))" by auto
   229   then have A: "A = prod_emb I M I (\<Pi>\<^sub>E i\<in>I. X i)"
   230     by (simp add: prod_emb_PiE_same_index[OF sets.sets_into_space] Pi_iff)
   231   from X I show "A \<in> ?L" unfolding A
   232     by (auto simp: prod_algebra_def)
   233 qed
   234 
   235 lemma prod_algebraI:
   236   "finite J \<Longrightarrow> (J \<noteq> {} \<or> I = {}) \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> E i \<in> sets (M i))
   237     \<Longrightarrow> prod_emb I M J (PIE j:J. E j) \<in> prod_algebra I M"
   238   by (auto simp: prod_algebra_def)
   239 
   240 lemma prod_algebraI_finite:
   241   "finite I \<Longrightarrow> (\<forall>i\<in>I. E i \<in> sets (M i)) \<Longrightarrow> (Pi\<^sub>E I E) \<in> prod_algebra I M"
   242   using prod_algebraI[of I I E M] prod_emb_PiE_same_index[of I E M, OF sets.sets_into_space] by simp
   243 
   244 lemma Int_stable_PiE: "Int_stable {Pi\<^sub>E J E | E. \<forall>i\<in>I. E i \<in> sets (M i)}"
   245 proof (safe intro!: Int_stableI)
   246   fix E F assume "\<forall>i\<in>I. E i \<in> sets (M i)" "\<forall>i\<in>I. F i \<in> sets (M i)"
   247   then show "\<exists>G. Pi\<^sub>E J E \<inter> Pi\<^sub>E J F = Pi\<^sub>E J G \<and> (\<forall>i\<in>I. G i \<in> sets (M i))"
   248     by (auto intro!: exI[of _ "\<lambda>i. E i \<inter> F i"] simp: PiE_Int)
   249 qed
   250 
   251 lemma prod_algebraE:
   252   assumes A: "A \<in> prod_algebra I M"
   253   obtains J E where "A = prod_emb I M J (PIE j:J. E j)"
   254     "finite J" "J \<noteq> {} \<or> I = {}" "J \<subseteq> I" "\<And>i. i \<in> J \<Longrightarrow> E i \<in> sets (M i)" 
   255   using A by (auto simp: prod_algebra_def)
   256 
   257 lemma prod_algebraE_all:
   258   assumes A: "A \<in> prod_algebra I M"
   259   obtains E where "A = Pi\<^sub>E I E" "E \<in> (\<Pi> i\<in>I. sets (M i))"
   260 proof -
   261   from A obtain E J where A: "A = prod_emb I M J (Pi\<^sub>E J E)"
   262     and J: "J \<subseteq> I" and E: "E \<in> (\<Pi> i\<in>J. sets (M i))"
   263     by (auto simp: prod_algebra_def)
   264   from E have "\<And>i. i \<in> J \<Longrightarrow> E i \<subseteq> space (M i)"
   265     using sets.sets_into_space by auto
   266   then have "A = (\<Pi>\<^sub>E i\<in>I. if i\<in>J then E i else space (M i))"
   267     using A J by (auto simp: prod_emb_PiE)
   268   moreover have "(\<lambda>i. if i\<in>J then E i else space (M i)) \<in> (\<Pi> i\<in>I. sets (M i))"
   269     using sets.top E by auto
   270   ultimately show ?thesis using that by auto
   271 qed
   272 
   273 lemma Int_stable_prod_algebra: "Int_stable (prod_algebra I M)"
   274 proof (unfold Int_stable_def, safe)
   275   fix A assume "A \<in> prod_algebra I M"
   276   from prod_algebraE[OF this] guess J E . note A = this
   277   fix B assume "B \<in> prod_algebra I M"
   278   from prod_algebraE[OF this] guess K F . note B = this
   279   have "A \<inter> B = prod_emb I M (J \<union> K) (\<Pi>\<^sub>E i\<in>J \<union> K. (if i \<in> J then E i else space (M i)) \<inter> 
   280       (if i \<in> K then F i else space (M i)))"
   281     unfolding A B using A(2,3,4) A(5)[THEN sets.sets_into_space] B(2,3,4)
   282       B(5)[THEN sets.sets_into_space]
   283     apply (subst (1 2 3) prod_emb_PiE)
   284     apply (simp_all add: subset_eq PiE_Int)
   285     apply blast
   286     apply (intro PiE_cong)
   287     apply auto
   288     done
   289   also have "\<dots> \<in> prod_algebra I M"
   290     using A B by (auto intro!: prod_algebraI)
   291   finally show "A \<inter> B \<in> prod_algebra I M" .
   292 qed
   293 
   294 lemma prod_algebra_mono:
   295   assumes space: "\<And>i. i \<in> I \<Longrightarrow> space (E i) = space (F i)"
   296   assumes sets: "\<And>i. i \<in> I \<Longrightarrow> sets (E i) \<subseteq> sets (F i)"
   297   shows "prod_algebra I E \<subseteq> prod_algebra I F"
   298 proof
   299   fix A assume "A \<in> prod_algebra I E"
   300   then obtain J G where J: "J \<noteq> {} \<or> I = {}" "finite J" "J \<subseteq> I"
   301     and A: "A = prod_emb I E J (\<Pi>\<^sub>E i\<in>J. G i)"
   302     and G: "\<And>i. i \<in> J \<Longrightarrow> G i \<in> sets (E i)"
   303     by (auto simp: prod_algebra_def)
   304   moreover
   305   from space have "(\<Pi>\<^sub>E i\<in>I. space (E i)) = (\<Pi>\<^sub>E i\<in>I. space (F i))"
   306     by (rule PiE_cong)
   307   with A have "A = prod_emb I F J (\<Pi>\<^sub>E i\<in>J. G i)"
   308     by (simp add: prod_emb_def)
   309   moreover
   310   from sets G J have "\<And>i. i \<in> J \<Longrightarrow> G i \<in> sets (F i)"
   311     by auto
   312   ultimately show "A \<in> prod_algebra I F"
   313     apply (simp add: prod_algebra_def image_iff)
   314     apply (intro exI[of _ J] exI[of _ G] conjI)
   315     apply auto
   316     done
   317 qed
   318 
   319 lemma prod_algebra_cong:
   320   assumes "I = J" and sets: "(\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sets (N i))"
   321   shows "prod_algebra I M = prod_algebra J N"
   322 proof -
   323   have space: "\<And>i. i \<in> I \<Longrightarrow> space (M i) = space (N i)"
   324     using sets_eq_imp_space_eq[OF sets] by auto
   325   with sets show ?thesis unfolding \<open>I = J\<close>
   326     by (intro antisym prod_algebra_mono) auto
   327 qed
   328 
   329 lemma space_in_prod_algebra:
   330   "(\<Pi>\<^sub>E i\<in>I. space (M i)) \<in> prod_algebra I M"
   331 proof cases
   332   assume "I = {}" then show ?thesis
   333     by (auto simp add: prod_algebra_def image_iff prod_emb_def)
   334 next
   335   assume "I \<noteq> {}"
   336   then obtain i where "i \<in> I" by auto
   337   then have "(\<Pi>\<^sub>E i\<in>I. space (M i)) = prod_emb I M {i} (\<Pi>\<^sub>E i\<in>{i}. space (M i))"
   338     by (auto simp: prod_emb_def)
   339   also have "\<dots> \<in> prod_algebra I M"
   340     using \<open>i \<in> I\<close> by (intro prod_algebraI) auto
   341   finally show ?thesis .
   342 qed
   343 
   344 lemma space_PiM: "space (\<Pi>\<^sub>M i\<in>I. M i) = (\<Pi>\<^sub>E i\<in>I. space (M i))"
   345   using prod_algebra_sets_into_space unfolding PiM_def prod_algebra_def by (intro space_extend_measure) simp
   346 
   347 lemma prod_emb_subset_PiM[simp]: "prod_emb I M K X \<subseteq> space (PiM I M)"
   348   by (auto simp: prod_emb_def space_PiM)
   349 
   350 lemma space_PiM_empty_iff[simp]: "space (PiM I M) = {} \<longleftrightarrow>  (\<exists>i\<in>I. space (M i) = {})"
   351   by (auto simp: space_PiM PiE_eq_empty_iff)
   352 
   353 lemma undefined_in_PiM_empty[simp]: "(\<lambda>x. undefined) \<in> space (PiM {} M)"
   354   by (auto simp: space_PiM)
   355 
   356 lemma sets_PiM: "sets (\<Pi>\<^sub>M i\<in>I. M i) = sigma_sets (\<Pi>\<^sub>E i\<in>I. space (M i)) (prod_algebra I M)"
   357   using prod_algebra_sets_into_space unfolding PiM_def prod_algebra_def by (intro sets_extend_measure) simp
   358 
   359 lemma sets_PiM_single: "sets (PiM I M) =
   360     sigma_sets (\<Pi>\<^sub>E i\<in>I. space (M i)) {{f\<in>\<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> A} | i A. i \<in> I \<and> A \<in> sets (M i)}"
   361     (is "_ = sigma_sets ?\<Omega> ?R")
   362   unfolding sets_PiM
   363 proof (rule sigma_sets_eqI)
   364   interpret R: sigma_algebra ?\<Omega> "sigma_sets ?\<Omega> ?R" by (rule sigma_algebra_sigma_sets) auto
   365   fix A assume "A \<in> prod_algebra I M"
   366   from prod_algebraE[OF this] guess J X . note X = this
   367   show "A \<in> sigma_sets ?\<Omega> ?R"
   368   proof cases
   369     assume "I = {}"
   370     with X have "A = {\<lambda>x. undefined}" by (auto simp: prod_emb_def)
   371     with \<open>I = {}\<close> show ?thesis by (auto intro!: sigma_sets_top)
   372   next
   373     assume "I \<noteq> {}"
   374     with X have "A = (\<Inter>j\<in>J. {f\<in>(\<Pi>\<^sub>E i\<in>I. space (M i)). f j \<in> X j})"
   375       by (auto simp: prod_emb_def)
   376     also have "\<dots> \<in> sigma_sets ?\<Omega> ?R"
   377       using X \<open>I \<noteq> {}\<close> by (intro R.finite_INT sigma_sets.Basic) auto
   378     finally show "A \<in> sigma_sets ?\<Omega> ?R" .
   379   qed
   380 next
   381   fix A assume "A \<in> ?R"
   382   then obtain i B where A: "A = {f\<in>\<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> B}" "i \<in> I" "B \<in> sets (M i)" 
   383     by auto
   384   then have "A = prod_emb I M {i} (\<Pi>\<^sub>E i\<in>{i}. B)"
   385      by (auto simp: prod_emb_def)
   386   also have "\<dots> \<in> sigma_sets ?\<Omega> (prod_algebra I M)"
   387     using A by (intro sigma_sets.Basic prod_algebraI) auto
   388   finally show "A \<in> sigma_sets ?\<Omega> (prod_algebra I M)" .
   389 qed
   390 
   391 lemma sets_PiM_eq_proj:
   392   "I \<noteq> {} \<Longrightarrow> sets (PiM I M) = sets (\<Squnion>\<^sub>\<sigma> i\<in>I. vimage_algebra (\<Pi>\<^sub>E i\<in>I. space (M i)) (\<lambda>x. x i) (M i))"
   393   apply (simp add: sets_PiM_single sets_Sup_sigma)
   394   apply (subst SUP_cong[OF refl])
   395   apply (rule sets_vimage_algebra2)
   396   apply auto []
   397   apply (auto intro!: arg_cong2[where f=sigma_sets])
   398   done
   399 
   400 lemma
   401   shows space_PiM_empty: "space (Pi\<^sub>M {} M) = {\<lambda>k. undefined}"
   402     and sets_PiM_empty: "sets (Pi\<^sub>M {} M) = { {}, {\<lambda>k. undefined} }"
   403   by (simp_all add: space_PiM sets_PiM_single image_constant sigma_sets_empty_eq)
   404 
   405 lemma sets_PiM_sigma:
   406   assumes \<Omega>_cover: "\<And>i. i \<in> I \<Longrightarrow> \<exists>S\<subseteq>E i. countable S \<and> \<Omega> i = \<Union>S"
   407   assumes E: "\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> Pow (\<Omega> i)"
   408   assumes J: "\<And>j. j \<in> J \<Longrightarrow> finite j" "\<Union>J = I"
   409   defines "P \<equiv> {{f\<in>(\<Pi>\<^sub>E i\<in>I. \<Omega> i). \<forall>i\<in>j. f i \<in> A i} | A j. j \<in> J \<and> A \<in> Pi j E}"
   410   shows "sets (\<Pi>\<^sub>M i\<in>I. sigma (\<Omega> i) (E i)) = sets (sigma (\<Pi>\<^sub>E i\<in>I. \<Omega> i) P)"
   411 proof cases
   412   assume "I = {}" 
   413   with \<open>\<Union>J = I\<close> have "P = {{\<lambda>_. undefined}} \<or> P = {}"
   414     by (auto simp: P_def)
   415   with \<open>I = {}\<close> show ?thesis
   416     by (auto simp add: sets_PiM_empty sigma_sets_empty_eq)
   417 next
   418   let ?F = "\<lambda>i. {(\<lambda>x. x i) -` A \<inter> Pi\<^sub>E I \<Omega> |A. A \<in> E i}"
   419   assume "I \<noteq> {}"
   420   then have "sets (Pi\<^sub>M I (\<lambda>i. sigma (\<Omega> i) (E i))) = 
   421       sets (\<Squnion>\<^sub>\<sigma> i\<in>I. vimage_algebra (\<Pi>\<^sub>E i\<in>I. \<Omega> i) (\<lambda>x. x i) (sigma (\<Omega> i) (E i)))"
   422     by (subst sets_PiM_eq_proj) (auto simp: space_measure_of_conv)
   423   also have "\<dots> = sets (\<Squnion>\<^sub>\<sigma> i\<in>I. sigma (Pi\<^sub>E I \<Omega>) (?F i))"
   424     using E by (intro SUP_sigma_cong arg_cong[where f=sets] vimage_algebra_sigma) auto
   425   also have "\<dots> = sets (sigma (Pi\<^sub>E I \<Omega>) (\<Union>i\<in>I. ?F i))"
   426     using \<open>I \<noteq> {}\<close> by (intro arg_cong[where f=sets] SUP_sigma_sigma) auto
   427   also have "\<dots> = sets (sigma (Pi\<^sub>E I \<Omega>) P)"
   428   proof (intro arg_cong[where f=sets] sigma_eqI sigma_sets_eqI)
   429     show "(\<Union>i\<in>I. ?F i) \<subseteq> Pow (Pi\<^sub>E I \<Omega>)" "P \<subseteq> Pow (Pi\<^sub>E I \<Omega>)"
   430       by (auto simp: P_def)
   431   next
   432     interpret P: sigma_algebra "\<Pi>\<^sub>E i\<in>I. \<Omega> i" "sigma_sets (\<Pi>\<^sub>E i\<in>I. \<Omega> i) P"
   433       by (auto intro!: sigma_algebra_sigma_sets simp: P_def)
   434 
   435     fix Z assume "Z \<in> (\<Union>i\<in>I. ?F i)"
   436     then obtain i A where i: "i \<in> I" "A \<in> E i" and Z_def: "Z = (\<lambda>x. x i) -` A \<inter> Pi\<^sub>E I \<Omega>"
   437       by auto
   438     from \<open>i \<in> I\<close> J obtain j where j: "i \<in> j" "j \<in> J" "j \<subseteq> I" "finite j"
   439       by auto
   440     obtain S where S: "\<And>i. i \<in> j \<Longrightarrow> S i \<subseteq> E i" "\<And>i. i \<in> j \<Longrightarrow> countable (S i)"
   441       "\<And>i. i \<in> j \<Longrightarrow> \<Omega> i = \<Union>(S i)"
   442       by (metis subset_eq \<Omega>_cover \<open>j \<subseteq> I\<close>)
   443     def A' \<equiv> "\<lambda>n. n(i := A)"
   444     then have A'_i: "\<And>n. A' n i = A"
   445       by simp
   446     { fix n assume "n \<in> Pi\<^sub>E (j - {i}) S"
   447       then have "A' n \<in> Pi j E"
   448         unfolding PiE_def Pi_def using S(1) by (auto simp: A'_def \<open>A \<in> E i\<close> )
   449       with \<open>j \<in> J\<close> have "{f \<in> Pi\<^sub>E I \<Omega>. \<forall>i\<in>j. f i \<in> A' n i} \<in> P"
   450         by (auto simp: P_def) }
   451     note A'_in_P = this
   452 
   453     { fix x assume "x i \<in> A" "x \<in> Pi\<^sub>E I \<Omega>"
   454       with S(3) \<open>j \<subseteq> I\<close> have "\<forall>i\<in>j. \<exists>s\<in>S i. x i \<in> s"
   455         by (auto simp: PiE_def Pi_def)
   456       then obtain s where s: "\<And>i. i \<in> j \<Longrightarrow> s i \<in> S i" "\<And>i. i \<in> j \<Longrightarrow> x i \<in> s i"
   457         by metis
   458       with \<open>x i \<in> A\<close> have "\<exists>n\<in>PiE (j-{i}) S. \<forall>i\<in>j. x i \<in> A' n i"
   459         by (intro bexI[of _ "restrict (s(i := A)) (j-{i})"]) (auto simp: A'_def split: if_splits) }
   460     then have "Z = (\<Union>n\<in>PiE (j-{i}) S. {f\<in>(\<Pi>\<^sub>E i\<in>I. \<Omega> i). \<forall>i\<in>j. f i \<in> A' n i})"
   461       unfolding Z_def
   462       by (auto simp add: set_eq_iff ball_conj_distrib \<open>i\<in>j\<close> A'_i dest: bspec[OF _ \<open>i\<in>j\<close>]
   463                cong: conj_cong)
   464     also have "\<dots> \<in> sigma_sets (\<Pi>\<^sub>E i\<in>I. \<Omega> i) P"
   465       using \<open>finite j\<close> S(2)
   466       by (intro P.countable_UN' countable_PiE) (simp_all add: image_subset_iff A'_in_P)
   467     finally show "Z \<in> sigma_sets (\<Pi>\<^sub>E i\<in>I. \<Omega> i) P" .
   468   next
   469     interpret F: sigma_algebra "\<Pi>\<^sub>E i\<in>I. \<Omega> i" "sigma_sets (\<Pi>\<^sub>E i\<in>I. \<Omega> i) (\<Union>i\<in>I. ?F i)"
   470       by (auto intro!: sigma_algebra_sigma_sets)
   471 
   472     fix b assume "b \<in> P"
   473     then obtain A j where b: "b = {f\<in>(\<Pi>\<^sub>E i\<in>I. \<Omega> i). \<forall>i\<in>j. f i \<in> A i}" "j \<in> J" "A \<in> Pi j E"
   474       by (auto simp: P_def)
   475     show "b \<in> sigma_sets (Pi\<^sub>E I \<Omega>) (\<Union>i\<in>I. ?F i)"
   476     proof cases
   477       assume "j = {}"
   478       with b have "b = (\<Pi>\<^sub>E i\<in>I. \<Omega> i)"
   479         by auto
   480       then show ?thesis
   481         by blast
   482     next
   483       assume "j \<noteq> {}"
   484       with J b(2,3) have eq: "b = (\<Inter>i\<in>j. ((\<lambda>x. x i) -` A i \<inter> Pi\<^sub>E I \<Omega>))"
   485         unfolding b(1)
   486         by (auto simp: PiE_def Pi_def)
   487       show ?thesis
   488         unfolding eq using \<open>A \<in> Pi j E\<close> \<open>j \<in> J\<close> J(2)
   489         by (intro F.finite_INT J \<open>j \<in> J\<close> \<open>j \<noteq> {}\<close> sigma_sets.Basic) blast
   490     qed
   491   qed
   492   finally show "?thesis" .
   493 qed
   494 
   495 lemma sets_PiM_in_sets:
   496   assumes space: "space N = (\<Pi>\<^sub>E i\<in>I. space (M i))"
   497   assumes sets: "\<And>i A. i \<in> I \<Longrightarrow> A \<in> sets (M i) \<Longrightarrow> {x\<in>space N. x i \<in> A} \<in> sets N"
   498   shows "sets (\<Pi>\<^sub>M i \<in> I. M i) \<subseteq> sets N"
   499   unfolding sets_PiM_single space[symmetric]
   500   by (intro sets.sigma_sets_subset subsetI) (auto intro: sets)
   501 
   502 lemma sets_PiM_cong[measurable_cong]:
   503   assumes "I = J" "\<And>i. i \<in> J \<Longrightarrow> sets (M i) = sets (N i)" shows "sets (PiM I M) = sets (PiM J N)"
   504   using assms sets_eq_imp_space_eq[OF assms(2)] by (simp add: sets_PiM_single cong: PiE_cong conj_cong)
   505 
   506 lemma sets_PiM_I:
   507   assumes "finite J" "J \<subseteq> I" "\<forall>i\<in>J. E i \<in> sets (M i)"
   508   shows "prod_emb I M J (PIE j:J. E j) \<in> sets (\<Pi>\<^sub>M i\<in>I. M i)"
   509 proof cases
   510   assume "J = {}"
   511   then have "prod_emb I M J (PIE j:J. E j) = (PIE j:I. space (M j))"
   512     by (auto simp: prod_emb_def)
   513   then show ?thesis
   514     by (auto simp add: sets_PiM intro!: sigma_sets_top)
   515 next
   516   assume "J \<noteq> {}" with assms show ?thesis
   517     by (force simp add: sets_PiM prod_algebra_def)
   518 qed
   519 
   520 lemma measurable_PiM:
   521   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
   522   assumes sets: "\<And>X J. J \<noteq> {} \<or> I = {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)) \<Longrightarrow>
   523     f -` prod_emb I M J (Pi\<^sub>E J X) \<inter> space N \<in> sets N" 
   524   shows "f \<in> measurable N (PiM I M)"
   525   using sets_PiM prod_algebra_sets_into_space space
   526 proof (rule measurable_sigma_sets)
   527   fix A assume "A \<in> prod_algebra I M"
   528   from prod_algebraE[OF this] guess J X .
   529   with sets[of J X] show "f -` A \<inter> space N \<in> sets N" by auto
   530 qed
   531 
   532 lemma measurable_PiM_Collect:
   533   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
   534   assumes sets: "\<And>X J. J \<noteq> {} \<or> I = {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)) \<Longrightarrow>
   535     {\<omega>\<in>space N. \<forall>i\<in>J. f \<omega> i \<in> X i} \<in> sets N" 
   536   shows "f \<in> measurable N (PiM I M)"
   537   using sets_PiM prod_algebra_sets_into_space space
   538 proof (rule measurable_sigma_sets)
   539   fix A assume "A \<in> prod_algebra I M"
   540   from prod_algebraE[OF this] guess J X . note X = this
   541   then have "f -` A \<inter> space N = {\<omega> \<in> space N. \<forall>i\<in>J. f \<omega> i \<in> X i}"
   542     using space by (auto simp: prod_emb_def del: PiE_I)
   543   also have "\<dots> \<in> sets N" using X(3,2,4,5) by (rule sets)
   544   finally show "f -` A \<inter> space N \<in> sets N" .
   545 qed
   546 
   547 lemma measurable_PiM_single:
   548   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
   549   assumes sets: "\<And>A i. i \<in> I \<Longrightarrow> A \<in> sets (M i) \<Longrightarrow> {\<omega> \<in> space N. f \<omega> i \<in> A} \<in> sets N" 
   550   shows "f \<in> measurable N (PiM I M)"
   551   using sets_PiM_single
   552 proof (rule measurable_sigma_sets)
   553   fix A assume "A \<in> {{f \<in> \<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> A} |i A. i \<in> I \<and> A \<in> sets (M i)}"
   554   then obtain B i where "A = {f \<in> \<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> B}" and B: "i \<in> I" "B \<in> sets (M i)"
   555     by auto
   556   with space have "f -` A \<inter> space N = {\<omega> \<in> space N. f \<omega> i \<in> B}" by auto
   557   also have "\<dots> \<in> sets N" using B by (rule sets)
   558   finally show "f -` A \<inter> space N \<in> sets N" .
   559 qed (auto simp: space)
   560 
   561 lemma measurable_PiM_single':
   562   assumes f: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> measurable N (M i)"
   563     and "(\<lambda>\<omega> i. f i \<omega>) \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
   564   shows "(\<lambda>\<omega> i. f i \<omega>) \<in> measurable N (Pi\<^sub>M I M)"
   565 proof (rule measurable_PiM_single)
   566   fix A i assume A: "i \<in> I" "A \<in> sets (M i)"
   567   then have "{\<omega> \<in> space N. f i \<omega> \<in> A} = f i -` A \<inter> space N"
   568     by auto
   569   then show "{\<omega> \<in> space N. f i \<omega> \<in> A} \<in> sets N"
   570     using A f by (auto intro!: measurable_sets)
   571 qed fact
   572 
   573 lemma sets_PiM_I_finite[measurable]:
   574   assumes "finite I" and sets: "(\<And>i. i \<in> I \<Longrightarrow> E i \<in> sets (M i))"
   575   shows "(PIE j:I. E j) \<in> sets (\<Pi>\<^sub>M i\<in>I. M i)"
   576   using sets_PiM_I[of I I E M] sets.sets_into_space[OF sets] \<open>finite I\<close> sets by auto
   577 
   578 lemma measurable_component_singleton[measurable (raw)]:
   579   assumes "i \<in> I" shows "(\<lambda>x. x i) \<in> measurable (Pi\<^sub>M I M) (M i)"
   580 proof (unfold measurable_def, intro CollectI conjI ballI)
   581   fix A assume "A \<in> sets (M i)"
   582   then have "(\<lambda>x. x i) -` A \<inter> space (Pi\<^sub>M I M) = prod_emb I M {i} (\<Pi>\<^sub>E j\<in>{i}. A)"
   583     using sets.sets_into_space \<open>i \<in> I\<close>
   584     by (fastforce dest: Pi_mem simp: prod_emb_def space_PiM split: split_if_asm)
   585   then show "(\<lambda>x. x i) -` A \<inter> space (Pi\<^sub>M I M) \<in> sets (Pi\<^sub>M I M)"
   586     using \<open>A \<in> sets (M i)\<close> \<open>i \<in> I\<close> by (auto intro!: sets_PiM_I)
   587 qed (insert \<open>i \<in> I\<close>, auto simp: space_PiM)
   588 
   589 lemma measurable_component_singleton'[measurable_dest]:
   590   assumes f: "f \<in> measurable N (Pi\<^sub>M I M)"
   591   assumes g: "g \<in> measurable L N"
   592   assumes i: "i \<in> I"
   593   shows "(\<lambda>x. (f (g x)) i) \<in> measurable L (M i)"
   594   using measurable_compose[OF measurable_compose[OF g f] measurable_component_singleton, OF i] .
   595 
   596 lemma measurable_PiM_component_rev:
   597   "i \<in> I \<Longrightarrow> f \<in> measurable (M i) N \<Longrightarrow> (\<lambda>x. f (x i)) \<in> measurable (PiM I M) N"
   598   by simp
   599 
   600 lemma measurable_case_nat[measurable (raw)]:
   601   assumes [measurable (raw)]: "i = 0 \<Longrightarrow> f \<in> measurable M N"
   602     "\<And>j. i = Suc j \<Longrightarrow> (\<lambda>x. g x j) \<in> measurable M N"
   603   shows "(\<lambda>x. case_nat (f x) (g x) i) \<in> measurable M N"
   604   by (cases i) simp_all
   605  
   606 lemma measurable_case_nat'[measurable (raw)]:
   607   assumes fg[measurable]: "f \<in> measurable N M" "g \<in> measurable N (\<Pi>\<^sub>M i\<in>UNIV. M)"
   608   shows "(\<lambda>x. case_nat (f x) (g x)) \<in> measurable N (\<Pi>\<^sub>M i\<in>UNIV. M)"
   609   using fg[THEN measurable_space]
   610   by (auto intro!: measurable_PiM_single' simp add: space_PiM PiE_iff split: nat.split)
   611 
   612 lemma measurable_add_dim[measurable]:
   613   "(\<lambda>(f, y). f(i := y)) \<in> measurable (Pi\<^sub>M I M \<Otimes>\<^sub>M M i) (Pi\<^sub>M (insert i I) M)"
   614     (is "?f \<in> measurable ?P ?I")
   615 proof (rule measurable_PiM_single)
   616   fix j A assume j: "j \<in> insert i I" and A: "A \<in> sets (M j)"
   617   have "{\<omega> \<in> space ?P. (\<lambda>(f, x). fun_upd f i x) \<omega> j \<in> A} =
   618     (if j = i then space (Pi\<^sub>M I M) \<times> A else ((\<lambda>x. x j) \<circ> fst) -` A \<inter> space ?P)"
   619     using sets.sets_into_space[OF A] by (auto simp add: space_pair_measure space_PiM)
   620   also have "\<dots> \<in> sets ?P"
   621     using A j
   622     by (auto intro!: measurable_sets[OF measurable_comp, OF _ measurable_component_singleton])
   623   finally show "{\<omega> \<in> space ?P. case_prod (\<lambda>f. fun_upd f i) \<omega> j \<in> A} \<in> sets ?P" .
   624 qed (auto simp: space_pair_measure space_PiM PiE_def)
   625 
   626 lemma measurable_fun_upd:
   627   assumes I: "I = J \<union> {i}"
   628   assumes f[measurable]: "f \<in> measurable N (PiM J M)"
   629   assumes h[measurable]: "h \<in> measurable N (M i)"
   630   shows "(\<lambda>x. (f x) (i := h x)) \<in> measurable N (PiM I M)"
   631 proof (intro measurable_PiM_single')
   632   fix j assume "j \<in> I" then show "(\<lambda>\<omega>. ((f \<omega>)(i := h \<omega>)) j) \<in> measurable N (M j)"
   633     unfolding I by (cases "j = i") auto
   634 next
   635   show "(\<lambda>x. (f x)(i := h x)) \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
   636     using I f[THEN measurable_space] h[THEN measurable_space]
   637     by (auto simp: space_PiM PiE_iff extensional_def)
   638 qed
   639 
   640 lemma measurable_component_update:
   641   "x \<in> space (Pi\<^sub>M I M) \<Longrightarrow> i \<notin> I \<Longrightarrow> (\<lambda>v. x(i := v)) \<in> measurable (M i) (Pi\<^sub>M (insert i I) M)"
   642   by simp
   643 
   644 lemma measurable_merge[measurable]:
   645   "merge I J \<in> measurable (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M) (Pi\<^sub>M (I \<union> J) M)"
   646     (is "?f \<in> measurable ?P ?U")
   647 proof (rule measurable_PiM_single)
   648   fix i A assume A: "A \<in> sets (M i)" "i \<in> I \<union> J"
   649   then have "{\<omega> \<in> space ?P. merge I J \<omega> i \<in> A} =
   650     (if i \<in> I then ((\<lambda>x. x i) \<circ> fst) -` A \<inter> space ?P else ((\<lambda>x. x i) \<circ> snd) -` A \<inter> space ?P)"
   651     by (auto simp: merge_def)
   652   also have "\<dots> \<in> sets ?P"
   653     using A
   654     by (auto intro!: measurable_sets[OF measurable_comp, OF _ measurable_component_singleton])
   655   finally show "{\<omega> \<in> space ?P. merge I J \<omega> i \<in> A} \<in> sets ?P" .
   656 qed (auto simp: space_pair_measure space_PiM PiE_iff merge_def extensional_def)
   657 
   658 lemma measurable_restrict[measurable (raw)]:
   659   assumes X: "\<And>i. i \<in> I \<Longrightarrow> X i \<in> measurable N (M i)"
   660   shows "(\<lambda>x. \<lambda>i\<in>I. X i x) \<in> measurable N (Pi\<^sub>M I M)"
   661 proof (rule measurable_PiM_single)
   662   fix A i assume A: "i \<in> I" "A \<in> sets (M i)"
   663   then have "{\<omega> \<in> space N. (\<lambda>i\<in>I. X i \<omega>) i \<in> A} = X i -` A \<inter> space N"
   664     by auto
   665   then show "{\<omega> \<in> space N. (\<lambda>i\<in>I. X i \<omega>) i \<in> A} \<in> sets N"
   666     using A X by (auto intro!: measurable_sets)
   667 qed (insert X, auto simp add: PiE_def dest: measurable_space)
   668 
   669 lemma measurable_abs_UNIV: 
   670   "(\<And>n. (\<lambda>\<omega>. f n \<omega>) \<in> measurable M (N n)) \<Longrightarrow> (\<lambda>\<omega> n. f n \<omega>) \<in> measurable M (PiM UNIV N)"
   671   by (intro measurable_PiM_single) (auto dest: measurable_space)
   672 
   673 lemma measurable_restrict_subset: "J \<subseteq> L \<Longrightarrow> (\<lambda>f. restrict f J) \<in> measurable (Pi\<^sub>M L M) (Pi\<^sub>M J M)"
   674   by (intro measurable_restrict measurable_component_singleton) auto
   675 
   676 lemma measurable_restrict_subset':
   677   assumes "J \<subseteq> L" "\<And>x. x \<in> J \<Longrightarrow> sets (M x) = sets (N x)"
   678   shows "(\<lambda>f. restrict f J) \<in> measurable (Pi\<^sub>M L M) (Pi\<^sub>M J N)"
   679 proof-
   680   from assms(1) have "(\<lambda>f. restrict f J) \<in> measurable (Pi\<^sub>M L M) (Pi\<^sub>M J M)"
   681     by (rule measurable_restrict_subset)
   682   also from assms(2) have "measurable (Pi\<^sub>M L M) (Pi\<^sub>M J M) = measurable (Pi\<^sub>M L M) (Pi\<^sub>M J N)"
   683     by (intro sets_PiM_cong measurable_cong_sets) simp_all
   684   finally show ?thesis .
   685 qed
   686 
   687 lemma measurable_prod_emb[intro, simp]:
   688   "J \<subseteq> L \<Longrightarrow> X \<in> sets (Pi\<^sub>M J M) \<Longrightarrow> prod_emb L M J X \<in> sets (Pi\<^sub>M L M)"
   689   unfolding prod_emb_def space_PiM[symmetric]
   690   by (auto intro!: measurable_sets measurable_restrict measurable_component_singleton)
   691 
   692 lemma merge_in_prod_emb:
   693   assumes "y \<in> space (PiM I M)" "x \<in> X" and X: "X \<in> sets (Pi\<^sub>M J M)" and "J \<subseteq> I"
   694   shows "merge J I (x, y) \<in> prod_emb I M J X"
   695   using assms sets.sets_into_space[OF X]
   696   by (simp add: merge_def prod_emb_def subset_eq space_PiM PiE_def extensional_restrict Pi_iff
   697            cong: if_cong restrict_cong)
   698      (simp add: extensional_def)
   699 
   700 lemma prod_emb_eq_emptyD:
   701   assumes J: "J \<subseteq> I" and ne: "space (PiM I M) \<noteq> {}" and X: "X \<in> sets (Pi\<^sub>M J M)"
   702     and *: "prod_emb I M J X = {}"
   703   shows "X = {}"
   704 proof safe
   705   fix x assume "x \<in> X"
   706   obtain \<omega> where "\<omega> \<in> space (PiM I M)"
   707     using ne by blast
   708   from merge_in_prod_emb[OF this \<open>x\<in>X\<close> X J] * show "x \<in> {}" by auto 
   709 qed
   710 
   711 lemma sets_in_Pi_aux:
   712   "finite I \<Longrightarrow> (\<And>j. j \<in> I \<Longrightarrow> {x\<in>space (M j). x \<in> F j} \<in> sets (M j)) \<Longrightarrow>
   713   {x\<in>space (PiM I M). x \<in> Pi I F} \<in> sets (PiM I M)"
   714   by (simp add: subset_eq Pi_iff)
   715 
   716 lemma sets_in_Pi[measurable (raw)]:
   717   "finite I \<Longrightarrow> f \<in> measurable N (PiM I M) \<Longrightarrow>
   718   (\<And>j. j \<in> I \<Longrightarrow> {x\<in>space (M j). x \<in> F j} \<in> sets (M j)) \<Longrightarrow>
   719   Measurable.pred N (\<lambda>x. f x \<in> Pi I F)"
   720   unfolding pred_def
   721   by (rule measurable_sets_Collect[of f N "PiM I M", OF _ sets_in_Pi_aux]) auto
   722 
   723 lemma sets_in_extensional_aux:
   724   "{x\<in>space (PiM I M). x \<in> extensional I} \<in> sets (PiM I M)"
   725 proof -
   726   have "{x\<in>space (PiM I M). x \<in> extensional I} = space (PiM I M)"
   727     by (auto simp add: extensional_def space_PiM)
   728   then show ?thesis by simp
   729 qed
   730 
   731 lemma sets_in_extensional[measurable (raw)]:
   732   "f \<in> measurable N (PiM I M) \<Longrightarrow> Measurable.pred N (\<lambda>x. f x \<in> extensional I)"
   733   unfolding pred_def
   734   by (rule measurable_sets_Collect[of f N "PiM I M", OF _ sets_in_extensional_aux]) auto
   735 
   736 lemma sets_PiM_I_countable:
   737   assumes I: "countable I" and E: "\<And>i. i \<in> I \<Longrightarrow> E i \<in> sets (M i)" shows "Pi\<^sub>E I E \<in> sets (Pi\<^sub>M I M)"
   738 proof cases
   739   assume "I \<noteq> {}"
   740   then have "PiE I E = (\<Inter>i\<in>I. prod_emb I M {i} (PiE {i} E))"
   741     using E[THEN sets.sets_into_space] by (auto simp: PiE_iff prod_emb_def fun_eq_iff)
   742   also have "\<dots> \<in> sets (PiM I M)"
   743     using I \<open>I \<noteq> {}\<close> by (safe intro!: sets.countable_INT' measurable_prod_emb sets_PiM_I_finite E)
   744   finally show ?thesis .
   745 qed (simp add: sets_PiM_empty)
   746 
   747 lemma sets_PiM_D_countable:
   748   assumes A: "A \<in> PiM I M"
   749   shows "\<exists>J\<subseteq>I. \<exists>X\<in>PiM J M. countable J \<and> A = prod_emb I M J X"
   750   using A[unfolded sets_PiM_single]
   751 proof induction
   752   case (Basic A)
   753   then obtain i X where *: "i \<in> I" "X \<in> sets (M i)" and "A = {f \<in> \<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> X}"
   754     by auto
   755   then have A: "A = prod_emb I M {i} (\<Pi>\<^sub>E _\<in>{i}. X)"
   756     by (auto simp: prod_emb_def)
   757   then show ?case
   758     by (intro exI[of _ "{i}"] conjI bexI[of _ "\<Pi>\<^sub>E _\<in>{i}. X"])
   759        (auto intro: countable_finite * sets_PiM_I_finite)
   760 next
   761   case Empty then show ?case
   762     by (intro exI[of _ "{}"] conjI bexI[of _ "{}"]) auto
   763 next
   764   case (Compl A)
   765   then obtain J X where "J \<subseteq> I" "X \<in> sets (Pi\<^sub>M J M)" "countable J" "A = prod_emb I M J X"
   766     by auto
   767   then show ?case
   768     by (intro exI[of _ J] bexI[of _ "space (PiM J M) - X"] conjI)
   769        (auto simp add: space_PiM prod_emb_PiE intro!: sets_PiM_I_countable)
   770 next
   771   case (Union K)
   772   obtain J X where J: "\<And>i. J i \<subseteq> I" "\<And>i. countable (J i)" and X: "\<And>i. X i \<in> sets (Pi\<^sub>M (J i) M)"
   773     and K: "\<And>i. K i = prod_emb I M (J i) (X i)"
   774     by (metis Union.IH)
   775   show ?case
   776   proof (intro exI[of _ "\<Union>i. J i"] bexI[of _ "\<Union>i. prod_emb (\<Union>i. J i) M (J i) (X i)"] conjI)
   777     show "(\<Union>i. J i) \<subseteq> I" "countable (\<Union>i. J i)" using J by auto
   778     with J show "UNION UNIV K = prod_emb I M (\<Union>i. J i) (\<Union>i. prod_emb (\<Union>i. J i) M (J i) (X i))" 
   779       by (simp add: K[abs_def] SUP_upper)
   780   qed(auto intro: X)
   781 qed
   782 
   783 lemma measure_eqI_PiM_finite:
   784   assumes [simp]: "finite I" "sets P = PiM I M" "sets Q = PiM I M"
   785   assumes eq: "\<And>A. (\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> P (Pi\<^sub>E I A) = Q (Pi\<^sub>E I A)"
   786   assumes A: "range A \<subseteq> prod_algebra I M" "(\<Union>i. A i) = space (PiM I M)" "\<And>i::nat. P (A i) \<noteq> \<infinity>"
   787   shows "P = Q"
   788 proof (rule measure_eqI_generator_eq[OF Int_stable_prod_algebra prod_algebra_sets_into_space])
   789   show "range A \<subseteq> prod_algebra I M" "(\<Union>i. A i) = (\<Pi>\<^sub>E i\<in>I. space (M i))" "\<And>i. P (A i) \<noteq> \<infinity>"
   790     unfolding space_PiM[symmetric] by fact+
   791   fix X assume "X \<in> prod_algebra I M"
   792   then obtain J E where X: "X = prod_emb I M J (PIE j:J. E j)"
   793     and J: "finite J" "J \<subseteq> I" "\<And>j. j \<in> J \<Longrightarrow> E j \<in> sets (M j)"
   794     by (force elim!: prod_algebraE)
   795   then show "emeasure P X = emeasure Q X"
   796     unfolding X by (subst (1 2) prod_emb_Pi) (auto simp: eq)
   797 qed (simp_all add: sets_PiM)
   798 
   799 lemma measure_eqI_PiM_infinite:
   800   assumes [simp]: "sets P = PiM I M" "sets Q = PiM I M"
   801   assumes eq: "\<And>A J. finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow>
   802     P (prod_emb I M J (Pi\<^sub>E J A)) = Q (prod_emb I M J (Pi\<^sub>E J A))"
   803   assumes A: "finite_measure P"
   804   shows "P = Q"
   805 proof (rule measure_eqI_generator_eq[OF Int_stable_prod_algebra prod_algebra_sets_into_space])
   806   interpret finite_measure P by fact
   807   def i \<equiv> "SOME i. i \<in> I"
   808   have i: "I \<noteq> {} \<Longrightarrow> i \<in> I"
   809     unfolding i_def by (rule someI_ex) auto
   810   def A \<equiv> "\<lambda>n::nat. if I = {} then prod_emb I M {} (\<Pi>\<^sub>E i\<in>{}. {}) else prod_emb I M {i} (\<Pi>\<^sub>E i\<in>{i}. space (M i))"
   811   then show "range A \<subseteq> prod_algebra I M"
   812     using prod_algebraI[of "{}" I "\<lambda>i. space (M i)" M] by (auto intro!: prod_algebraI i)
   813   have "\<And>i. A i = space (PiM I M)"
   814     by (auto simp: prod_emb_def space_PiM PiE_iff A_def i ex_in_conv[symmetric] exI)
   815   then show "(\<Union>i. A i) = (\<Pi>\<^sub>E i\<in>I. space (M i))" "\<And>i. emeasure P (A i) \<noteq> \<infinity>"
   816     by (auto simp: space_PiM)
   817 next
   818   fix X assume X: "X \<in> prod_algebra I M"
   819   then obtain J E where X: "X = prod_emb I M J (PIE j:J. E j)"
   820     and J: "finite J" "J \<subseteq> I" "\<And>j. j \<in> J \<Longrightarrow> E j \<in> sets (M j)"
   821     by (force elim!: prod_algebraE)
   822   then show "emeasure P X = emeasure Q X"
   823     by (auto intro!: eq)
   824 qed (auto simp: sets_PiM)
   825 
   826 locale product_sigma_finite =
   827   fixes M :: "'i \<Rightarrow> 'a measure"
   828   assumes sigma_finite_measures: "\<And>i. sigma_finite_measure (M i)"
   829 
   830 sublocale product_sigma_finite \<subseteq> M?: sigma_finite_measure "M i" for i
   831   by (rule sigma_finite_measures)
   832 
   833 locale finite_product_sigma_finite = product_sigma_finite M for M :: "'i \<Rightarrow> 'a measure" +
   834   fixes I :: "'i set"
   835   assumes finite_index: "finite I"
   836 
   837 lemma (in finite_product_sigma_finite) sigma_finite_pairs:
   838   "\<exists>F::'i \<Rightarrow> nat \<Rightarrow> 'a set.
   839     (\<forall>i\<in>I. range (F i) \<subseteq> sets (M i)) \<and>
   840     (\<forall>k. \<forall>i\<in>I. emeasure (M i) (F i k) \<noteq> \<infinity>) \<and> incseq (\<lambda>k. \<Pi>\<^sub>E i\<in>I. F i k) \<and>
   841     (\<Union>k. \<Pi>\<^sub>E i\<in>I. F i k) = space (PiM I M)"
   842 proof -
   843   have "\<forall>i::'i. \<exists>F::nat \<Rightarrow> 'a set. range F \<subseteq> sets (M i) \<and> incseq F \<and> (\<Union>i. F i) = space (M i) \<and> (\<forall>k. emeasure (M i) (F k) \<noteq> \<infinity>)"
   844     using M.sigma_finite_incseq by metis
   845   from choice[OF this] guess F :: "'i \<Rightarrow> nat \<Rightarrow> 'a set" ..
   846   then have F: "\<And>i. range (F i) \<subseteq> sets (M i)" "\<And>i. incseq (F i)" "\<And>i. (\<Union>j. F i j) = space (M i)" "\<And>i k. emeasure (M i) (F i k) \<noteq> \<infinity>"
   847     by auto
   848   let ?F = "\<lambda>k. \<Pi>\<^sub>E i\<in>I. F i k"
   849   note space_PiM[simp]
   850   show ?thesis
   851   proof (intro exI[of _ F] conjI allI incseq_SucI set_eqI iffI ballI)
   852     fix i show "range (F i) \<subseteq> sets (M i)" by fact
   853   next
   854     fix i k show "emeasure (M i) (F i k) \<noteq> \<infinity>" by fact
   855   next
   856     fix x assume "x \<in> (\<Union>i. ?F i)" with F(1) show "x \<in> space (PiM I M)"
   857       by (auto simp: PiE_def dest!: sets.sets_into_space)
   858   next
   859     fix f assume "f \<in> space (PiM I M)"
   860     with Pi_UN[OF finite_index, of "\<lambda>k i. F i k"] F
   861     show "f \<in> (\<Union>i. ?F i)" by (auto simp: incseq_def PiE_def)
   862   next
   863     fix i show "?F i \<subseteq> ?F (Suc i)"
   864       using \<open>\<And>i. incseq (F i)\<close>[THEN incseq_SucD] by auto
   865   qed
   866 qed
   867 
   868 lemma emeasure_PiM_empty[simp]: "emeasure (PiM {} M) {\<lambda>_. undefined} = 1"
   869 proof -
   870   let ?\<mu> = "\<lambda>A. if A = {} then 0 else (1::ereal)"
   871   have "emeasure (Pi\<^sub>M {} M) (prod_emb {} M {} (\<Pi>\<^sub>E i\<in>{}. {})) = 1"
   872   proof (subst emeasure_extend_measure_Pair[OF PiM_def])
   873     show "positive (PiM {} M) ?\<mu>"
   874       by (auto simp: positive_def)
   875     show "countably_additive (PiM {} M) ?\<mu>"
   876       by (rule sets.countably_additiveI_finite)
   877          (auto simp: additive_def positive_def sets_PiM_empty space_PiM_empty intro!: )
   878   qed (auto simp: prod_emb_def)
   879   also have "(prod_emb {} M {} (\<Pi>\<^sub>E i\<in>{}. {})) = {\<lambda>_. undefined}"
   880     by (auto simp: prod_emb_def)
   881   finally show ?thesis
   882     by simp
   883 qed
   884 
   885 lemma PiM_empty: "PiM {} M = count_space {\<lambda>_. undefined}"
   886   by (rule measure_eqI) (auto simp add: sets_PiM_empty one_ereal_def)
   887 
   888 lemma (in product_sigma_finite) emeasure_PiM:
   889   "finite I \<Longrightarrow> (\<And>i. i\<in>I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> emeasure (PiM I M) (Pi\<^sub>E I A) = (\<Prod>i\<in>I. emeasure (M i) (A i))"
   890 proof (induct I arbitrary: A rule: finite_induct)
   891   case (insert i I)
   892   interpret finite_product_sigma_finite M I by standard fact
   893   have "finite (insert i I)" using \<open>finite I\<close> by auto
   894   interpret I': finite_product_sigma_finite M "insert i I" by standard fact
   895   let ?h = "(\<lambda>(f, y). f(i := y))"
   896 
   897   let ?P = "distr (Pi\<^sub>M I M \<Otimes>\<^sub>M M i) (Pi\<^sub>M (insert i I) M) ?h"
   898   let ?\<mu> = "emeasure ?P"
   899   let ?I = "{j \<in> insert i I. emeasure (M j) (space (M j)) \<noteq> 1}"
   900   let ?f = "\<lambda>J E j. if j \<in> J then emeasure (M j) (E j) else emeasure (M j) (space (M j))"
   901 
   902   have "emeasure (Pi\<^sub>M (insert i I) M) (prod_emb (insert i I) M (insert i I) (Pi\<^sub>E (insert i I) A)) =
   903     (\<Prod>i\<in>insert i I. emeasure (M i) (A i))"
   904   proof (subst emeasure_extend_measure_Pair[OF PiM_def])
   905     fix J E assume "(J \<noteq> {} \<or> insert i I = {}) \<and> finite J \<and> J \<subseteq> insert i I \<and> E \<in> (\<Pi> j\<in>J. sets (M j))"
   906     then have J: "J \<noteq> {}" "finite J" "J \<subseteq> insert i I" and E: "\<forall>j\<in>J. E j \<in> sets (M j)" by auto
   907     let ?p = "prod_emb (insert i I) M J (Pi\<^sub>E J E)"
   908     let ?p' = "prod_emb I M (J - {i}) (\<Pi>\<^sub>E j\<in>J-{i}. E j)"
   909     have "?\<mu> ?p =
   910       emeasure (Pi\<^sub>M I M \<Otimes>\<^sub>M (M i)) (?h -` ?p \<inter> space (Pi\<^sub>M I M \<Otimes>\<^sub>M M i))"
   911       by (intro emeasure_distr measurable_add_dim sets_PiM_I) fact+
   912     also have "?h -` ?p \<inter> space (Pi\<^sub>M I M \<Otimes>\<^sub>M M i) = ?p' \<times> (if i \<in> J then E i else space (M i))"
   913       using J E[rule_format, THEN sets.sets_into_space]
   914       by (force simp: space_pair_measure space_PiM prod_emb_iff PiE_def Pi_iff split: split_if_asm)
   915     also have "emeasure (Pi\<^sub>M I M \<Otimes>\<^sub>M (M i)) (?p' \<times> (if i \<in> J then E i else space (M i))) =
   916       emeasure (Pi\<^sub>M I M) ?p' * emeasure (M i) (if i \<in> J then (E i) else space (M i))"
   917       using J E by (intro M.emeasure_pair_measure_Times sets_PiM_I) auto
   918     also have "?p' = (\<Pi>\<^sub>E j\<in>I. if j \<in> J-{i} then E j else space (M j))"
   919       using J E[rule_format, THEN sets.sets_into_space]
   920       by (auto simp: prod_emb_iff PiE_def Pi_iff split: split_if_asm) blast+
   921     also have "emeasure (Pi\<^sub>M I M) (\<Pi>\<^sub>E j\<in>I. if j \<in> J-{i} then E j else space (M j)) =
   922       (\<Prod> j\<in>I. if j \<in> J-{i} then emeasure (M j) (E j) else emeasure (M j) (space (M j)))"
   923       using E by (subst insert) (auto intro!: setprod.cong)
   924     also have "(\<Prod>j\<in>I. if j \<in> J - {i} then emeasure (M j) (E j) else emeasure (M j) (space (M j))) *
   925        emeasure (M i) (if i \<in> J then E i else space (M i)) = (\<Prod>j\<in>insert i I. ?f J E j)"
   926       using insert by (auto simp: mult.commute intro!: arg_cong2[where f="op *"] setprod.cong)
   927     also have "\<dots> = (\<Prod>j\<in>J \<union> ?I. ?f J E j)"
   928       using insert(1,2) J E by (intro setprod.mono_neutral_right) auto
   929     finally show "?\<mu> ?p = \<dots>" .
   930 
   931     show "prod_emb (insert i I) M J (Pi\<^sub>E J E) \<in> Pow (\<Pi>\<^sub>E i\<in>insert i I. space (M i))"
   932       using J E[rule_format, THEN sets.sets_into_space] by (auto simp: prod_emb_iff PiE_def)
   933   next
   934     show "positive (sets (Pi\<^sub>M (insert i I) M)) ?\<mu>" "countably_additive (sets (Pi\<^sub>M (insert i I) M)) ?\<mu>"
   935       using emeasure_positive[of ?P] emeasure_countably_additive[of ?P] by simp_all
   936   next
   937     show "(insert i I \<noteq> {} \<or> insert i I = {}) \<and> finite (insert i I) \<and>
   938       insert i I \<subseteq> insert i I \<and> A \<in> (\<Pi> j\<in>insert i I. sets (M j))"
   939       using insert by auto
   940   qed (auto intro!: setprod.cong)
   941   with insert show ?case
   942     by (subst (asm) prod_emb_PiE_same_index) (auto intro!: sets.sets_into_space)
   943 qed simp
   944 
   945 lemma (in product_sigma_finite) PiM_eqI:
   946   assumes I[simp]: "finite I" and P: "sets P = PiM I M"
   947   assumes eq: "\<And>A. (\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> P (Pi\<^sub>E I A) = (\<Prod>i\<in>I. emeasure (M i) (A i))"
   948   shows "P = PiM I M"
   949 proof -
   950   interpret finite_product_sigma_finite M I
   951     proof qed fact
   952   from sigma_finite_pairs guess C .. note C = this
   953   show ?thesis
   954   proof (rule measure_eqI_PiM_finite[OF I refl P, symmetric])
   955     show "(\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> (Pi\<^sub>M I M) (Pi\<^sub>E I A) = P (Pi\<^sub>E I A)" for A
   956       by (simp add: eq emeasure_PiM)
   957     def A \<equiv> "\<lambda>n. \<Pi>\<^sub>E i\<in>I. C i n"
   958     with C show "range A \<subseteq> prod_algebra I M" "\<And>i. emeasure (Pi\<^sub>M I M) (A i) \<noteq> \<infinity>" "(\<Union>i. A i) = space (PiM I M)"
   959       by (auto intro!: prod_algebraI_finite simp: emeasure_PiM subset_eq setprod_PInf emeasure_nonneg)
   960   qed
   961 qed
   962 
   963 lemma (in product_sigma_finite) sigma_finite: 
   964   assumes "finite I"
   965   shows "sigma_finite_measure (PiM I M)"
   966 proof
   967   interpret finite_product_sigma_finite M I by standard fact
   968 
   969   obtain F where F: "\<And>j. countable (F j)" "\<And>j f. f \<in> F j \<Longrightarrow> f \<in> sets (M j)"
   970     "\<And>j f. f \<in> F j \<Longrightarrow> emeasure (M j) f \<noteq> \<infinity>" and
   971     in_space: "\<And>j. space (M j) = (\<Union>F j)"
   972     using sigma_finite_countable by (metis subset_eq)
   973   moreover have "(\<Union>(PiE I ` PiE I F)) = space (Pi\<^sub>M I M)"
   974     using in_space by (auto simp: space_PiM PiE_iff intro!: PiE_choice[THEN iffD2])
   975   ultimately show "\<exists>A. countable A \<and> A \<subseteq> sets (Pi\<^sub>M I M) \<and> \<Union>A = space (Pi\<^sub>M I M) \<and> (\<forall>a\<in>A. emeasure (Pi\<^sub>M I M) a \<noteq> \<infinity>)"
   976     by (intro exI[of _ "PiE I ` PiE I F"])
   977        (auto intro!: countable_PiE sets_PiM_I_finite
   978              simp: PiE_iff emeasure_PiM finite_index setprod_PInf emeasure_nonneg)
   979 qed
   980 
   981 sublocale finite_product_sigma_finite \<subseteq> sigma_finite_measure "Pi\<^sub>M I M"
   982   using sigma_finite[OF finite_index] .
   983 
   984 lemma (in finite_product_sigma_finite) measure_times:
   985   "(\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> emeasure (Pi\<^sub>M I M) (Pi\<^sub>E I A) = (\<Prod>i\<in>I. emeasure (M i) (A i))"
   986   using emeasure_PiM[OF finite_index] by auto
   987 
   988 lemma (in product_sigma_finite) nn_integral_empty:
   989   "0 \<le> f (\<lambda>k. undefined) \<Longrightarrow> integral\<^sup>N (Pi\<^sub>M {} M) f = f (\<lambda>k. undefined)"
   990   by (simp add: PiM_empty nn_integral_count_space_finite max.absorb2)
   991 
   992 lemma (in product_sigma_finite) distr_merge:
   993   assumes IJ[simp]: "I \<inter> J = {}" and fin: "finite I" "finite J"
   994   shows "distr (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M) (Pi\<^sub>M (I \<union> J) M) (merge I J) = Pi\<^sub>M (I \<union> J) M"
   995    (is "?D = ?P")
   996 proof (rule PiM_eqI)
   997   interpret I: finite_product_sigma_finite M I by standard fact
   998   interpret J: finite_product_sigma_finite M J by standard fact
   999   fix A assume A: "\<And>i. i \<in> I \<union> J \<Longrightarrow> A i \<in> sets (M i)"
  1000   have *: "(merge I J -` Pi\<^sub>E (I \<union> J) A \<inter> space (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M)) = PiE I A \<times> PiE J A"
  1001     using A[THEN sets.sets_into_space] by (auto simp: space_PiM space_pair_measure)
  1002   from A fin show "emeasure (distr (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M) (Pi\<^sub>M (I \<union> J) M) (merge I J)) (Pi\<^sub>E (I \<union> J) A) =
  1003       (\<Prod>i\<in>I \<union> J. emeasure (M i) (A i))"
  1004     by (subst emeasure_distr)
  1005        (auto simp: * J.emeasure_pair_measure_Times I.measure_times J.measure_times setprod.union_disjoint)
  1006 qed (insert fin, simp_all)
  1007 
  1008 lemma (in product_sigma_finite) product_nn_integral_fold:
  1009   assumes IJ: "I \<inter> J = {}" "finite I" "finite J"
  1010   and f: "f \<in> borel_measurable (Pi\<^sub>M (I \<union> J) M)"
  1011   shows "integral\<^sup>N (Pi\<^sub>M (I \<union> J) M) f =
  1012     (\<integral>\<^sup>+ x. (\<integral>\<^sup>+ y. f (merge I J (x, y)) \<partial>(Pi\<^sub>M J M)) \<partial>(Pi\<^sub>M I M))"
  1013 proof -
  1014   interpret I: finite_product_sigma_finite M I by standard fact
  1015   interpret J: finite_product_sigma_finite M J by standard fact
  1016   interpret P: pair_sigma_finite "Pi\<^sub>M I M" "Pi\<^sub>M J M" by standard
  1017   have P_borel: "(\<lambda>x. f (merge I J x)) \<in> borel_measurable (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M)"
  1018     using measurable_comp[OF measurable_merge f] by (simp add: comp_def)
  1019   show ?thesis
  1020     apply (subst distr_merge[OF IJ, symmetric])
  1021     apply (subst nn_integral_distr[OF measurable_merge f])
  1022     apply (subst J.nn_integral_fst[symmetric, OF P_borel])
  1023     apply simp
  1024     done
  1025 qed
  1026 
  1027 lemma (in product_sigma_finite) distr_singleton:
  1028   "distr (Pi\<^sub>M {i} M) (M i) (\<lambda>x. x i) = M i" (is "?D = _")
  1029 proof (intro measure_eqI[symmetric])
  1030   interpret I: finite_product_sigma_finite M "{i}" by standard simp
  1031   fix A assume A: "A \<in> sets (M i)"
  1032   then have "(\<lambda>x. x i) -` A \<inter> space (Pi\<^sub>M {i} M) = (\<Pi>\<^sub>E i\<in>{i}. A)"
  1033     using sets.sets_into_space by (auto simp: space_PiM)
  1034   then show "emeasure (M i) A = emeasure ?D A"
  1035     using A I.measure_times[of "\<lambda>_. A"]
  1036     by (simp add: emeasure_distr measurable_component_singleton)
  1037 qed simp
  1038 
  1039 lemma (in product_sigma_finite) product_nn_integral_singleton:
  1040   assumes f: "f \<in> borel_measurable (M i)"
  1041   shows "integral\<^sup>N (Pi\<^sub>M {i} M) (\<lambda>x. f (x i)) = integral\<^sup>N (M i) f"
  1042 proof -
  1043   interpret I: finite_product_sigma_finite M "{i}" by standard simp
  1044   from f show ?thesis
  1045     apply (subst distr_singleton[symmetric])
  1046     apply (subst nn_integral_distr[OF measurable_component_singleton])
  1047     apply simp_all
  1048     done
  1049 qed
  1050 
  1051 lemma (in product_sigma_finite) product_nn_integral_insert:
  1052   assumes I[simp]: "finite I" "i \<notin> I"
  1053     and f: "f \<in> borel_measurable (Pi\<^sub>M (insert i I) M)"
  1054   shows "integral\<^sup>N (Pi\<^sub>M (insert i I) M) f = (\<integral>\<^sup>+ x. (\<integral>\<^sup>+ y. f (x(i := y)) \<partial>(M i)) \<partial>(Pi\<^sub>M I M))"
  1055 proof -
  1056   interpret I: finite_product_sigma_finite M I by standard auto
  1057   interpret i: finite_product_sigma_finite M "{i}" by standard auto
  1058   have IJ: "I \<inter> {i} = {}" and insert: "I \<union> {i} = insert i I"
  1059     using f by auto
  1060   show ?thesis
  1061     unfolding product_nn_integral_fold[OF IJ, unfolded insert, OF I(1) i.finite_index f]
  1062   proof (rule nn_integral_cong, subst product_nn_integral_singleton[symmetric])
  1063     fix x assume x: "x \<in> space (Pi\<^sub>M I M)"
  1064     let ?f = "\<lambda>y. f (x(i := y))"
  1065     show "?f \<in> borel_measurable (M i)"
  1066       using measurable_comp[OF measurable_component_update f, OF x \<open>i \<notin> I\<close>]
  1067       unfolding comp_def .
  1068     show "(\<integral>\<^sup>+ y. f (merge I {i} (x, y)) \<partial>Pi\<^sub>M {i} M) = (\<integral>\<^sup>+ y. f (x(i := y i)) \<partial>Pi\<^sub>M {i} M)"
  1069       using x
  1070       by (auto intro!: nn_integral_cong arg_cong[where f=f]
  1071                simp add: space_PiM extensional_def PiE_def)
  1072   qed
  1073 qed
  1074 
  1075 lemma (in product_sigma_finite) product_nn_integral_insert_rev:
  1076   assumes I[simp]: "finite I" "i \<notin> I"
  1077     and [measurable]: "f \<in> borel_measurable (Pi\<^sub>M (insert i I) M)"
  1078   shows "integral\<^sup>N (Pi\<^sub>M (insert i I) M) f = (\<integral>\<^sup>+ y. (\<integral>\<^sup>+ x. f (x(i := y)) \<partial>(Pi\<^sub>M I M)) \<partial>(M i))"
  1079   apply (subst product_nn_integral_insert[OF assms])
  1080   apply (rule pair_sigma_finite.Fubini')
  1081   apply intro_locales []
  1082   apply (rule sigma_finite[OF I(1)])
  1083   apply measurable
  1084   done
  1085 
  1086 lemma (in product_sigma_finite) product_nn_integral_setprod:
  1087   fixes f :: "'i \<Rightarrow> 'a \<Rightarrow> ereal"
  1088   assumes "finite I" and borel: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> borel_measurable (M i)"
  1089   and pos: "\<And>i x. i \<in> I \<Longrightarrow> 0 \<le> f i x"
  1090   shows "(\<integral>\<^sup>+ x. (\<Prod>i\<in>I. f i (x i)) \<partial>Pi\<^sub>M I M) = (\<Prod>i\<in>I. integral\<^sup>N (M i) (f i))"
  1091 using assms proof induct
  1092   case (insert i I)
  1093   note \<open>finite I\<close>[intro, simp]
  1094   interpret I: finite_product_sigma_finite M I by standard auto
  1095   have *: "\<And>x y. (\<Prod>j\<in>I. f j (if j = i then y else x j)) = (\<Prod>j\<in>I. f j (x j))"
  1096     using insert by (auto intro!: setprod.cong)
  1097   have prod: "\<And>J. J \<subseteq> insert i I \<Longrightarrow> (\<lambda>x. (\<Prod>i\<in>J. f i (x i))) \<in> borel_measurable (Pi\<^sub>M J M)"
  1098     using sets.sets_into_space insert
  1099     by (intro borel_measurable_ereal_setprod
  1100               measurable_comp[OF measurable_component_singleton, unfolded comp_def])
  1101        auto
  1102   then show ?case
  1103     apply (simp add: product_nn_integral_insert[OF insert(1,2) prod])
  1104     apply (simp add: insert(2-) * pos borel setprod_ereal_pos nn_integral_multc)
  1105     apply (subst nn_integral_cmult)
  1106     apply (auto simp add: pos borel insert(2-) setprod_ereal_pos nn_integral_nonneg)
  1107     done
  1108 qed (simp add: space_PiM)
  1109 
  1110 lemma (in product_sigma_finite) product_nn_integral_pair:
  1111   assumes [measurable]: "case_prod f \<in> borel_measurable (M x \<Otimes>\<^sub>M M y)"
  1112   assumes xy: "x \<noteq> y"
  1113   shows "(\<integral>\<^sup>+\<sigma>. f (\<sigma> x) (\<sigma> y) \<partial>PiM {x, y} M) = (\<integral>\<^sup>+z. f (fst z) (snd z) \<partial>(M x \<Otimes>\<^sub>M M y))"
  1114 proof-
  1115   interpret psm: pair_sigma_finite "M x" "M y"
  1116     unfolding pair_sigma_finite_def using sigma_finite_measures by simp_all
  1117   have "{x, y} = {y, x}" by auto
  1118   also have "(\<integral>\<^sup>+\<sigma>. f (\<sigma> x) (\<sigma> y) \<partial>PiM {y, x} M) = (\<integral>\<^sup>+y. \<integral>\<^sup>+\<sigma>. f (\<sigma> x) y \<partial>PiM {x} M \<partial>M y)"
  1119     using xy by (subst product_nn_integral_insert_rev) simp_all
  1120   also have "... = (\<integral>\<^sup>+y. \<integral>\<^sup>+x. f x y \<partial>M x \<partial>M y)"
  1121     by (intro nn_integral_cong, subst product_nn_integral_singleton) simp_all
  1122   also have "... = (\<integral>\<^sup>+z. f (fst z) (snd z) \<partial>(M x \<Otimes>\<^sub>M M y))"
  1123     by (subst psm.nn_integral_snd[symmetric]) simp_all
  1124   finally show ?thesis .
  1125 qed
  1126 
  1127 lemma (in product_sigma_finite) distr_component:
  1128   "distr (M i) (Pi\<^sub>M {i} M) (\<lambda>x. \<lambda>i\<in>{i}. x) = Pi\<^sub>M {i} M" (is "?D = ?P")
  1129 proof (intro PiM_eqI)
  1130   fix A assume "\<And>ia. ia \<in> {i} \<Longrightarrow> A ia \<in> sets (M ia)"
  1131   moreover then have "(\<lambda>x. \<lambda>i\<in>{i}. x) -` Pi\<^sub>E {i} A \<inter> space (M i) = A i"
  1132     by (auto dest: sets.sets_into_space)
  1133   ultimately show "emeasure (distr (M i) (Pi\<^sub>M {i} M) (\<lambda>x. \<lambda>i\<in>{i}. x)) (Pi\<^sub>E {i} A) = (\<Prod>i\<in>{i}. emeasure (M i) (A i))"
  1134     by (subst emeasure_distr) (auto intro!: sets_PiM_I_finite measurable_restrict)
  1135 qed simp_all
  1136 
  1137 lemma (in product_sigma_finite)
  1138   assumes IJ: "I \<inter> J = {}" "finite I" "finite J" and A: "A \<in> sets (Pi\<^sub>M (I \<union> J) M)"
  1139   shows emeasure_fold_integral:
  1140     "emeasure (Pi\<^sub>M (I \<union> J) M) A = (\<integral>\<^sup>+x. emeasure (Pi\<^sub>M J M) ((\<lambda>y. merge I J (x, y)) -` A \<inter> space (Pi\<^sub>M J M)) \<partial>Pi\<^sub>M I M)" (is ?I)
  1141     and emeasure_fold_measurable:
  1142     "(\<lambda>x. emeasure (Pi\<^sub>M J M) ((\<lambda>y. merge I J (x, y)) -` A \<inter> space (Pi\<^sub>M J M))) \<in> borel_measurable (Pi\<^sub>M I M)" (is ?B)
  1143 proof -
  1144   interpret I: finite_product_sigma_finite M I by standard fact
  1145   interpret J: finite_product_sigma_finite M J by standard fact
  1146   interpret IJ: pair_sigma_finite "Pi\<^sub>M I M" "Pi\<^sub>M J M" ..
  1147   have merge: "merge I J -` A \<inter> space (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M) \<in> sets (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M)"
  1148     by (intro measurable_sets[OF _ A] measurable_merge assms)
  1149 
  1150   show ?I
  1151     apply (subst distr_merge[symmetric, OF IJ])
  1152     apply (subst emeasure_distr[OF measurable_merge A])
  1153     apply (subst J.emeasure_pair_measure_alt[OF merge])
  1154     apply (auto intro!: nn_integral_cong arg_cong2[where f=emeasure] simp: space_pair_measure)
  1155     done
  1156 
  1157   show ?B
  1158     using IJ.measurable_emeasure_Pair1[OF merge]
  1159     by (simp add: vimage_comp comp_def space_pair_measure cong: measurable_cong)
  1160 qed
  1161 
  1162 lemma sets_Collect_single:
  1163   "i \<in> I \<Longrightarrow> A \<in> sets (M i) \<Longrightarrow> { x \<in> space (Pi\<^sub>M I M). x i \<in> A } \<in> sets (Pi\<^sub>M I M)"
  1164   by simp
  1165 
  1166 lemma pair_measure_eq_distr_PiM:
  1167   fixes M1 :: "'a measure" and M2 :: "'a measure"
  1168   assumes "sigma_finite_measure M1" "sigma_finite_measure M2"
  1169   shows "(M1 \<Otimes>\<^sub>M M2) = distr (Pi\<^sub>M UNIV (case_bool M1 M2)) (M1 \<Otimes>\<^sub>M M2) (\<lambda>x. (x True, x False))"
  1170     (is "?P = ?D")
  1171 proof (rule pair_measure_eqI[OF assms])
  1172   interpret B: product_sigma_finite "case_bool M1 M2"
  1173     unfolding product_sigma_finite_def using assms by (auto split: bool.split)
  1174   let ?B = "Pi\<^sub>M UNIV (case_bool M1 M2)"
  1175 
  1176   have [simp]: "fst \<circ> (\<lambda>x. (x True, x False)) = (\<lambda>x. x True)" "snd \<circ> (\<lambda>x. (x True, x False)) = (\<lambda>x. x False)"
  1177     by auto
  1178   fix A B assume A: "A \<in> sets M1" and B: "B \<in> sets M2"
  1179   have "emeasure M1 A * emeasure M2 B = (\<Prod> i\<in>UNIV. emeasure (case_bool M1 M2 i) (case_bool A B i))"
  1180     by (simp add: UNIV_bool ac_simps)
  1181   also have "\<dots> = emeasure ?B (Pi\<^sub>E UNIV (case_bool A B))"
  1182     using A B by (subst B.emeasure_PiM) (auto split: bool.split)
  1183   also have "Pi\<^sub>E UNIV (case_bool A B) = (\<lambda>x. (x True, x False)) -` (A \<times> B) \<inter> space ?B"
  1184     using A[THEN sets.sets_into_space] B[THEN sets.sets_into_space]
  1185     by (auto simp: PiE_iff all_bool_eq space_PiM split: bool.split)
  1186   finally show "emeasure M1 A * emeasure M2 B = emeasure ?D (A \<times> B)"
  1187     using A B
  1188       measurable_component_singleton[of True UNIV "case_bool M1 M2"]
  1189       measurable_component_singleton[of False UNIV "case_bool M1 M2"]
  1190     by (subst emeasure_distr) (auto simp: measurable_pair_iff)
  1191 qed simp
  1192 
  1193 end