author hoelzl
Fri Feb 19 13:40:50 2016 +0100 (2016-02-19)
changeset 62378 85ed00c1fe7c
parent 61973 0c7e865fa7cb
child 62397 5ae24f33d343
permissions -rw-r--r--
generalize more theorems to support enat and ennreal
     1 (*  Title:      HOL/Probability/Projective_Limit.thy
     2     Author:     Fabian Immler, TU M√ľnchen
     3 *)
     5 section \<open>Projective Limit\<close>
     7 theory Projective_Limit
     8   imports
     9     Caratheodory
    10     Fin_Map
    11     Regularity
    12     Projective_Family
    13     Infinite_Product_Measure
    14     "~~/src/HOL/Library/Diagonal_Subsequence"
    15 begin
    17 subsection \<open>Sequences of Finite Maps in Compact Sets\<close>
    19 locale finmap_seqs_into_compact =
    20   fixes K::"nat \<Rightarrow> (nat \<Rightarrow>\<^sub>F 'a::metric_space) set" and f::"nat \<Rightarrow> (nat \<Rightarrow>\<^sub>F 'a)" and M
    21   assumes compact: "\<And>n. compact (K n)"
    22   assumes f_in_K: "\<And>n. K n \<noteq> {}"
    23   assumes domain_K: "\<And>n. k \<in> K n \<Longrightarrow> domain k = domain (f n)"
    24   assumes proj_in_K:
    25     "\<And>t n m. m \<ge> n \<Longrightarrow> t \<in> domain (f n) \<Longrightarrow> (f m)\<^sub>F t \<in> (\<lambda>k. (k)\<^sub>F t) ` K n"
    26 begin
    28 lemma proj_in_K': "(\<exists>n. \<forall>m \<ge> n. (f m)\<^sub>F t \<in> (\<lambda>k. (k)\<^sub>F t) ` K n)"
    29   using proj_in_K f_in_K
    30 proof cases
    31   obtain k where "k \<in> K (Suc 0)" using f_in_K by auto
    32   assume "\<forall>n. t \<notin> domain (f n)"
    33   thus ?thesis
    34     by (auto intro!: exI[where x=1] image_eqI[OF _ \<open>k \<in> K (Suc 0)\<close>]
    35       simp: domain_K[OF \<open>k \<in> K (Suc 0)\<close>])
    36 qed blast
    38 lemma proj_in_KE:
    39   obtains n where "\<And>m. m \<ge> n \<Longrightarrow> (f m)\<^sub>F t \<in> (\<lambda>k. (k)\<^sub>F t) ` K n"
    40   using proj_in_K' by blast
    42 lemma compact_projset:
    43   shows "compact ((\<lambda>k. (k)\<^sub>F i) ` K n)"
    44   using continuous_proj compact by (rule compact_continuous_image)
    46 end
    48 lemma compactE':
    49   fixes S :: "'a :: metric_space set"
    50   assumes "compact S" "\<forall>n\<ge>m. f n \<in> S"
    51   obtains l r where "l \<in> S" "subseq r" "((f \<circ> r) \<longlongrightarrow> l) sequentially"
    52 proof atomize_elim
    53   have "subseq (op + m)" by (simp add: subseq_def)
    54   have "\<forall>n. (f o (\<lambda>i. m + i)) n \<in> S" using assms by auto
    55   from seq_compactE[OF \<open>compact S\<close>[unfolded compact_eq_seq_compact_metric] this] guess l r .
    56   hence "l \<in> S" "subseq ((\<lambda>i. m + i) o r) \<and> (f \<circ> ((\<lambda>i. m + i) o r)) \<longlonglongrightarrow> l"
    57     using subseq_o[OF \<open>subseq (op + m)\<close> \<open>subseq r\<close>] by (auto simp: o_def)
    58   thus "\<exists>l r. l \<in> S \<and> subseq r \<and> (f \<circ> r) \<longlonglongrightarrow> l" by blast
    59 qed
    61 sublocale finmap_seqs_into_compact \<subseteq> subseqs "\<lambda>n s. (\<exists>l. (\<lambda>i. ((f o s) i)\<^sub>F n) \<longlonglongrightarrow> l)"
    62 proof
    63   fix n s
    64   assume "subseq s"
    65   from proj_in_KE[of n] guess n0 . note n0 = this
    66   have "\<forall>i \<ge> n0. ((f \<circ> s) i)\<^sub>F n \<in> (\<lambda>k. (k)\<^sub>F n) ` K n0"
    67   proof safe
    68     fix i assume "n0 \<le> i"
    69     also have "\<dots> \<le> s i" by (rule seq_suble) fact
    70     finally have "n0 \<le> s i" .
    71     with n0 show "((f \<circ> s) i)\<^sub>F n \<in> (\<lambda>k. (k)\<^sub>F n) ` K n0 "
    72       by auto
    73   qed
    74   from compactE'[OF compact_projset this] guess ls rs .
    75   thus "\<exists>r'. subseq r' \<and> (\<exists>l. (\<lambda>i. ((f \<circ> (s \<circ> r')) i)\<^sub>F n) \<longlonglongrightarrow> l)" by (auto simp: o_def)
    76 qed
    78 lemma (in finmap_seqs_into_compact) diagonal_tendsto: "\<exists>l. (\<lambda>i. (f (diagseq i))\<^sub>F n) \<longlonglongrightarrow> l"
    79 proof -
    80   obtain l where "(\<lambda>i. ((f o (diagseq o op + (Suc n))) i)\<^sub>F n) \<longlonglongrightarrow> l"
    81   proof (atomize_elim, rule diagseq_holds)
    82     fix r s n
    83     assume "subseq r"
    84     assume "\<exists>l. (\<lambda>i. ((f \<circ> s) i)\<^sub>F n) \<longlonglongrightarrow> l"
    85     then obtain l where "((\<lambda>i. (f i)\<^sub>F n) o s) \<longlonglongrightarrow> l"
    86       by (auto simp: o_def)
    87     hence "((\<lambda>i. (f i)\<^sub>F n) o s o r) \<longlonglongrightarrow> l" using \<open>subseq r\<close>
    88       by (rule LIMSEQ_subseq_LIMSEQ)
    89     thus "\<exists>l. (\<lambda>i. ((f \<circ> (s \<circ> r)) i)\<^sub>F n) \<longlonglongrightarrow> l" by (auto simp add: o_def)
    90   qed
    91   hence "(\<lambda>i. ((f (diagseq (i + Suc n))))\<^sub>F n) \<longlonglongrightarrow> l" by (simp add: ac_simps)
    92   hence "(\<lambda>i. (f (diagseq i))\<^sub>F n) \<longlonglongrightarrow> l" by (rule LIMSEQ_offset)
    93   thus ?thesis ..
    94 qed
    96 subsection \<open>Daniell-Kolmogorov Theorem\<close>
    98 text \<open>Existence of Projective Limit\<close>
   100 locale polish_projective = projective_family I P "\<lambda>_. borel::'a::polish_space measure"
   101   for I::"'i set" and P
   102 begin
   104 lemma emeasure_lim_emb:
   105   assumes X: "J \<subseteq> I" "finite J" "X \<in> sets (\<Pi>\<^sub>M i\<in>J. borel)"
   106   shows "lim (emb I J X) = P J X"
   107 proof (rule emeasure_lim)
   108   write mu_G ("\<mu>G")
   109   interpret generator: algebra "space (PiM I (\<lambda>i. borel))" generator
   110     by (rule algebra_generator)
   112   fix J and B :: "nat \<Rightarrow> ('i \<Rightarrow> 'a) set"
   113   assume J: "\<And>n. finite (J n)" "\<And>n. J n \<subseteq> I" "\<And>n. B n \<in> sets (\<Pi>\<^sub>M i\<in>J n. borel)" "incseq J"
   114     and B: "decseq (\<lambda>n. emb I (J n) (B n))"
   115     and "0 < (INF i. P (J i) (B i))" (is "0 < ?a")
   116   moreover have "?a \<le> 1"
   117     using J by (auto intro!: INF_lower2[of 0] prob_space_P[THEN prob_space.measure_le_1])
   118   ultimately obtain r where r: "?a = ereal r" "0 < r" "r \<le> 1"
   119     by (cases "?a") auto
   120   def Z \<equiv> "\<lambda>n. emb I (J n) (B n)"
   121   have Z_mono: "n \<le> m \<Longrightarrow> Z m \<subseteq> Z n" for n m
   122     unfolding Z_def using B[THEN antimonoD, of n m] .
   123   have J_mono: "\<And>n m. n \<le> m \<Longrightarrow> J n \<subseteq> J m"
   124     using \<open>incseq J\<close> by (force simp: incseq_def)
   125   note [simp] = \<open>\<And>n. finite (J n)\<close>
   126   interpret prob_space "P (J i)" for i using J prob_space_P by simp
   128   have P_eq[simp]:
   129       "sets (P (J i)) = sets (\<Pi>\<^sub>M i\<in>J i. borel)" "space (P (J i)) = space (\<Pi>\<^sub>M i\<in>J i. borel)" for i
   130     using J by (auto simp: sets_P space_P)
   132   have "Z i \<in> generator" for i
   133     unfolding Z_def by (auto intro!: generator.intros J)
   135   have countable_UN_J: "countable (\<Union>n. J n)" by (simp add: countable_finite)
   136   def Utn \<equiv> "to_nat_on (\<Union>n. J n)"
   137   interpret function_to_finmap "J n" Utn "from_nat_into (\<Union>n. J n)" for n
   138     by unfold_locales (auto simp: Utn_def intro: from_nat_into_to_nat_on[OF countable_UN_J])
   139   have inj_on_Utn: "inj_on Utn (\<Union>n. J n)"
   140     unfolding Utn_def using countable_UN_J by (rule inj_on_to_nat_on)
   141   hence inj_on_Utn_J: "\<And>n. inj_on Utn (J n)" by (rule subset_inj_on) auto
   142   def P' \<equiv> "\<lambda>n. mapmeasure n (P (J n)) (\<lambda>_. borel)"
   143   interpret P': prob_space "P' n" for n
   144     unfolding P'_def mapmeasure_def using J
   145     by (auto intro!: prob_space_distr fm_measurable simp: measurable_cong_sets[OF sets_P])
   147   let ?SUP = "\<lambda>n. SUP K : {K. K \<subseteq> fm n ` (B n) \<and> compact K}. emeasure (P' n) K"
   148   { fix n
   149     have "emeasure (P (J n)) (B n) = emeasure (P' n) (fm n ` (B n))"
   150       using J by (auto simp: P'_def mapmeasure_PiM space_P sets_P)
   151     also
   152     have "\<dots> = ?SUP n"
   153     proof (rule inner_regular)
   154       show "sets (P' n) = sets borel" by (simp add: borel_eq_PiF_borel P'_def)
   155     next
   156       show "fm n ` B n \<in> sets borel"
   157         unfolding borel_eq_PiF_borel by (auto simp: P'_def fm_image_measurable_finite sets_P J(3))
   158     qed simp
   159     finally have "emeasure (P (J n)) (B n) = ?SUP n" "?SUP n \<noteq> \<infinity>" "?SUP n \<noteq> - \<infinity>" by auto
   160   } note R = this
   161   have "\<forall>n. \<exists>K. emeasure (P (J n)) (B n) - emeasure (P' n) K \<le> 2 powr (-n) * ?a \<and> compact K \<and> K \<subseteq> fm n ` B n"
   162   proof
   163     fix n show "\<exists>K. emeasure (P (J n)) (B n) - emeasure (P' n) K \<le> ereal (2 powr - real n) * ?a \<and>
   164         compact K \<and> K \<subseteq> fm n ` B n"
   165       unfolding R[of n]
   166     proof (rule ccontr)
   167       assume H: "\<not> (\<exists>K'. ?SUP n - emeasure (P' n) K' \<le> ereal (2 powr - real n)  * ?a \<and>
   168         compact K' \<and> K' \<subseteq> fm n ` B n)"
   169       have "?SUP n \<le> ?SUP n - 2 powr (-n) * ?a"
   170       proof (intro SUP_least)
   171         fix K
   172         assume "K \<in> {K. K \<subseteq> fm n ` B n \<and> compact K}"
   173         with H have "\<not> ?SUP n - emeasure (P' n) K \<le> 2 powr (-n) * ?a"
   174           by auto
   175         hence "?SUP n - emeasure (P' n) K > 2 powr (-n) * ?a"
   176           unfolding not_less[symmetric] by simp
   177         hence "?SUP n - 2 powr (-n) * ?a > emeasure (P' n) K"
   178           using \<open>0 < ?a\<close> by (auto simp add: ereal_less_minus_iff ac_simps)
   179         thus "?SUP n - 2 powr (-n) * ?a \<ge> emeasure (P' n) K" by simp
   180       qed
   181       hence "?SUP n + 0 \<le> ?SUP n - (2 powr (-n) * ?a)" using \<open>0 < ?a\<close> by simp
   182       hence "?SUP n + 0 \<le> ?SUP n + - (2 powr (-n) * ?a)" unfolding minus_ereal_def .
   183       hence "0 \<le> - (2 powr (-n) * ?a)"
   184         using \<open>?SUP n \<noteq> \<infinity>\<close> \<open>?SUP n \<noteq> - \<infinity>\<close>
   185         by (subst (asm) ereal_add_le_add_iff) (auto simp:)
   186       moreover have "ereal (2 powr - real n) * ?a > 0" using \<open>0 < ?a\<close>
   187         by (auto simp: ereal_zero_less_0_iff)
   188       ultimately show False by simp
   189     qed
   190   qed
   191   then obtain K' where K':
   192     "\<And>n. emeasure (P (J n)) (B n) - emeasure (P' n) (K' n) \<le> ereal (2 powr - real n) * ?a"
   193     "\<And>n. compact (K' n)" "\<And>n. K' n \<subseteq> fm n ` B n"
   194     unfolding choice_iff by blast
   195   def K \<equiv> "\<lambda>n. fm n -` K' n \<inter> space (Pi\<^sub>M (J n) (\<lambda>_. borel))"
   196   have K_sets: "\<And>n. K n \<in> sets (Pi\<^sub>M (J n) (\<lambda>_. borel))"
   197     unfolding K_def
   198     using compact_imp_closed[OF \<open>compact (K' _)\<close>]
   199     by (intro measurable_sets[OF fm_measurable, of _ "Collect finite"])
   200        (auto simp: borel_eq_PiF_borel[symmetric])
   201   have K_B: "\<And>n. K n \<subseteq> B n"
   202   proof
   203     fix x n assume "x \<in> K n"
   204     then have fm_in: "fm n x \<in> fm n ` B n"
   205       using K' by (force simp: K_def)
   206     show "x \<in> B n"
   207       using \<open>x \<in> K n\<close> K_sets sets.sets_into_space J(1,2,3)[of n] inj_on_image_mem_iff[OF inj_on_fm]
   208     by (metis (no_types) Int_iff K_def fm_in space_borel)
   209   qed
   210   def Z' \<equiv> "\<lambda>n. emb I (J n) (K n)"
   211   have Z': "\<And>n. Z' n \<subseteq> Z n"
   212     unfolding Z'_def Z_def
   213   proof (rule prod_emb_mono, safe)
   214     fix n x assume "x \<in> K n"
   215     hence "fm n x \<in> K' n" "x \<in> space (Pi\<^sub>M (J n) (\<lambda>_. borel))"
   216       by (simp_all add: K_def space_P)
   217     note this(1)
   218     also have "K' n \<subseteq> fm n ` B n" by (simp add: K')
   219     finally have "fm n x \<in> fm n ` B n" .
   220     thus "x \<in> B n"
   221     proof safe
   222       fix y assume y: "y \<in> B n"
   223       hence "y \<in> space (Pi\<^sub>M (J n) (\<lambda>_. borel))" using J sets.sets_into_space[of "B n" "P (J n)"]
   224         by (auto simp add: space_P sets_P)
   225       assume "fm n x = fm n y"
   226       note inj_onD[OF inj_on_fm[OF space_borel],
   227         OF \<open>fm n x = fm n y\<close> \<open>x \<in> space _\<close> \<open>y \<in> space _\<close>]
   228       with y show "x \<in> B n" by simp
   229     qed
   230   qed
   231   have "\<And>n. Z' n \<in> generator" using J K'(2) unfolding Z'_def
   232     by (auto intro!: generator.intros measurable_sets[OF fm_measurable[of _ "Collect finite"]]
   233              simp: K_def borel_eq_PiF_borel[symmetric] compact_imp_closed)
   234   def Y \<equiv> "\<lambda>n. \<Inter>i\<in>{1..n}. Z' i"
   235   hence "\<And>n k. Y (n + k) \<subseteq> Y n" by (induct_tac k) (auto simp: Y_def)
   236   hence Y_mono: "\<And>n m. n \<le> m \<Longrightarrow> Y m \<subseteq> Y n" by (auto simp: le_iff_add)
   237   have Y_Z': "\<And>n. n \<ge> 1 \<Longrightarrow> Y n \<subseteq> Z' n" by (auto simp: Y_def)
   238   hence Y_Z: "\<And>n. n \<ge> 1 \<Longrightarrow> Y n \<subseteq> Z n" using Z' by auto
   240   have Y_notempty: "\<And>n. n \<ge> 1 \<Longrightarrow> (Y n) \<noteq> {}"
   241   proof -
   242     fix n::nat assume "n \<ge> 1" hence "Y n \<subseteq> Z n" by fact
   243     have "Y n = (\<Inter>i\<in>{1..n}. emb I (J n) (emb (J n) (J i) (K i)))" using J J_mono
   244       by (auto simp: Y_def Z'_def)
   245     also have "\<dots> = prod_emb I (\<lambda>_. borel) (J n) (\<Inter>i\<in>{1..n}. emb (J n) (J i) (K i))"
   246       using \<open>n \<ge> 1\<close>
   247       by (subst prod_emb_INT) auto
   248     finally
   249     have Y_emb:
   250       "Y n = prod_emb I (\<lambda>_. borel) (J n) (\<Inter>i\<in>{1..n}. prod_emb (J n) (\<lambda>_. borel) (J i) (K i))" .
   251     hence "Y n \<in> generator" using J J_mono K_sets \<open>n \<ge> 1\<close>
   252       by (auto simp del: prod_emb_INT intro!: generator.intros)
   253     have *: "\<mu>G (Z n) = P (J n) (B n)"
   254       unfolding Z_def using J by (intro mu_G_spec) auto
   255     then have "\<bar>\<mu>G (Z n)\<bar> \<noteq> \<infinity>" by auto
   256     note *
   257     moreover have *: "\<mu>G (Y n) = P (J n) (\<Inter>i\<in>{Suc 0..n}. prod_emb (J n) (\<lambda>_. borel) (J i) (K i))"
   258       unfolding Y_emb using J J_mono K_sets \<open>n \<ge> 1\<close> by (subst mu_G_spec) auto
   259     then have "\<bar>\<mu>G (Y n)\<bar> \<noteq> \<infinity>" by auto
   260     note *
   261     moreover have "\<mu>G (Z n - Y n) =
   262         P (J n) (B n - (\<Inter>i\<in>{Suc 0..n}. prod_emb (J n) (\<lambda>_. borel) (J i) (K i)))"
   263       unfolding Z_def Y_emb prod_emb_Diff[symmetric] using J J_mono K_sets \<open>n \<ge> 1\<close>
   264       by (subst mu_G_spec) (auto intro!: sets.Diff)
   265     ultimately
   266     have "\<mu>G (Z n) - \<mu>G (Y n) = \<mu>G (Z n - Y n)"
   267       using J J_mono K_sets \<open>n \<ge> 1\<close>
   268       by (simp only: emeasure_eq_measure Z_def)
   269         (auto dest!: bspec[where x=n] intro!: measure_Diff[symmetric] set_mp[OF K_B]
   270           simp: extensional_restrict emeasure_eq_measure prod_emb_iff sets_P space_P)
   271     also have subs: "Z n - Y n \<subseteq> (\<Union>i\<in>{1..n}. (Z i - Z' i))"
   272       using \<open>n \<ge> 1\<close> unfolding Y_def UN_extend_simps(7) by (intro UN_mono Diff_mono Z_mono order_refl) auto
   273     have "Z n - Y n \<in> generator" "(\<Union>i\<in>{1..n}. (Z i - Z' i)) \<in> generator"
   274       using \<open>Z' _ \<in> generator\<close> \<open>Z _ \<in> generator\<close> \<open>Y _ \<in> generator\<close> by auto
   275     hence "\<mu>G (Z n - Y n) \<le> \<mu>G (\<Union>i\<in>{1..n}. (Z i - Z' i))"
   276       using subs generator.additive_increasing[OF positive_mu_G additive_mu_G]
   277       unfolding increasing_def by auto
   278     also have "\<dots> \<le> (\<Sum> i\<in>{1..n}. \<mu>G (Z i - Z' i))" using \<open>Z _ \<in> generator\<close> \<open>Z' _ \<in> generator\<close>
   279       by (intro generator.subadditive[OF positive_mu_G additive_mu_G]) auto
   280     also have "\<dots> \<le> (\<Sum> i\<in>{1..n}. 2 powr -real i * ?a)"
   281     proof (rule setsum_mono)
   282       fix i assume "i \<in> {1..n}" hence "i \<le> n" by simp
   283       have "\<mu>G (Z i - Z' i) = \<mu>G (prod_emb I (\<lambda>_. borel) (J i) (B i - K i))"
   284         unfolding Z'_def Z_def by simp
   285       also have "\<dots> = P (J i) (B i - K i)"
   286         using J K_sets by (subst mu_G_spec) auto
   287       also have "\<dots> = P (J i) (B i) - P (J i) (K i)"
   288         using K_sets J \<open>K _ \<subseteq> B _\<close> by (simp add: emeasure_Diff)
   289       also have "\<dots> = P (J i) (B i) - P' i (K' i)"
   290         unfolding K_def P'_def
   291         by (auto simp: mapmeasure_PiF borel_eq_PiF_borel[symmetric]
   292           compact_imp_closed[OF \<open>compact (K' _)\<close>] space_PiM PiE_def)
   293       also have "\<dots> \<le> ereal (2 powr - real i) * ?a" using K'(1)[of i] .
   294       finally show "\<mu>G (Z i - Z' i) \<le> (2 powr - real i) * ?a" .
   295     qed
   296     also have "\<dots> = ereal ((\<Sum> i\<in>{1..n}. (2 powr -real_of_ereal i)) * real_of_ereal ?a)"
   297       by (simp add: setsum_left_distrib r)
   298     also have "\<dots> < ereal (1 * real_of_ereal ?a)" unfolding less_ereal.simps
   299     proof (rule mult_strict_right_mono)
   300       have "(\<Sum>i = 1..n. 2 powr - real i) = (\<Sum>i = 1..<Suc n. (1/2) ^ i)"
   301         by (rule setsum.cong) (auto simp: powr_realpow powr_divide power_divide powr_minus_divide)  
   302       also have "{1..<Suc n} = {..<Suc n} - {0}" by auto
   303       also have "setsum (op ^ (1 / 2::real)) ({..<Suc n} - {0}) =
   304         setsum (op ^ (1 / 2)) ({..<Suc n}) - 1" by (auto simp: setsum_diff1)
   305       also have "\<dots> < 1" by (subst geometric_sum) auto
   306       finally show "(\<Sum>i = 1..n. 2 powr - real_of_ereal i) < 1" by simp
   307     qed (auto simp: r ereal_less_real_iff zero_ereal_def[symmetric])
   308     also have "\<dots> = ?a" by (auto simp: r)
   309     also have "\<dots> \<le> \<mu>G (Z n)"
   310       using J by (auto intro: INF_lower simp: Z_def mu_G_spec)
   311     finally have "\<mu>G (Z n) - \<mu>G (Y n) < \<mu>G (Z n)" .
   312     hence R: "\<mu>G (Z n) < \<mu>G (Z n) + \<mu>G (Y n)"
   313       using \<open>\<bar>\<mu>G (Y n)\<bar> \<noteq> \<infinity>\<close> by (simp add: ereal_minus_less)
   314     have "0 \<le> (- \<mu>G (Z n)) + \<mu>G (Z n)" using \<open>\<bar>\<mu>G (Z n)\<bar> \<noteq> \<infinity>\<close> by auto
   315     also have "\<dots> < (- \<mu>G (Z n)) + (\<mu>G (Z n) + \<mu>G (Y n))"
   316       apply (rule ereal_less_add[OF _ R]) using \<open>\<bar>\<mu>G (Z n)\<bar> \<noteq> \<infinity>\<close> by auto
   317     finally have "\<mu>G (Y n) > 0"
   318       using \<open>\<bar>\<mu>G (Z n)\<bar> \<noteq> \<infinity>\<close> by (auto simp: ac_simps zero_ereal_def[symmetric])
   319     thus "Y n \<noteq> {}" using positive_mu_G by (auto simp add: positive_def)
   320   qed
   321   hence "\<forall>n\<in>{1..}. \<exists>y. y \<in> Y n" by auto
   322   then obtain y where y: "\<And>n. n \<ge> 1 \<Longrightarrow> y n \<in> Y n" unfolding bchoice_iff by force
   323   {
   324     fix t and n m::nat
   325     assume "1 \<le> n" "n \<le> m" hence "1 \<le> m" by simp
   326     from Y_mono[OF \<open>m \<ge> n\<close>] y[OF \<open>1 \<le> m\<close>] have "y m \<in> Y n" by auto
   327     also have "\<dots> \<subseteq> Z' n" using Y_Z'[OF \<open>1 \<le> n\<close>] .
   328     finally
   329     have "fm n (restrict (y m) (J n)) \<in> K' n"
   330       unfolding Z'_def K_def prod_emb_iff by (simp add: Z'_def K_def prod_emb_iff)
   331     moreover have "finmap_of (J n) (restrict (y m) (J n)) = finmap_of (J n) (y m)"
   332       using J by (simp add: fm_def)
   333     ultimately have "fm n (y m) \<in> K' n" by simp
   334   } note fm_in_K' = this
   335   interpret finmap_seqs_into_compact "\<lambda>n. K' (Suc n)" "\<lambda>k. fm (Suc k) (y (Suc k))" borel
   336   proof
   337     fix n show "compact (K' n)" by fact
   338   next
   339     fix n
   340     from Y_mono[of n "Suc n"] y[of "Suc n"] have "y (Suc n) \<in> Y (Suc n)" by auto
   341     also have "\<dots> \<subseteq> Z' (Suc n)" using Y_Z' by auto
   342     finally
   343     have "fm (Suc n) (restrict (y (Suc n)) (J (Suc n))) \<in> K' (Suc n)"
   344       unfolding Z'_def K_def prod_emb_iff by (simp add: Z'_def K_def prod_emb_iff)
   345     thus "K' (Suc n) \<noteq> {}" by auto
   346     fix k
   347     assume "k \<in> K' (Suc n)"
   348     with K'[of "Suc n"] sets.sets_into_space have "k \<in> fm (Suc n) ` B (Suc n)" by auto
   349     then obtain b where "k = fm (Suc n) b" by auto
   350     thus "domain k = domain (fm (Suc n) (y (Suc n)))"
   351       by (simp_all add: fm_def)
   352   next
   353     fix t and n m::nat
   354     assume "n \<le> m" hence "Suc n \<le> Suc m" by simp
   355     assume "t \<in> domain (fm (Suc n) (y (Suc n)))"
   356     then obtain j where j: "t = Utn j" "j \<in> J (Suc n)" by auto
   357     hence "j \<in> J (Suc m)" using J_mono[OF \<open>Suc n \<le> Suc m\<close>] by auto
   358     have img: "fm (Suc n) (y (Suc m)) \<in> K' (Suc n)" using \<open>n \<le> m\<close>
   359       by (intro fm_in_K') simp_all
   360     show "(fm (Suc m) (y (Suc m)))\<^sub>F t \<in> (\<lambda>k. (k)\<^sub>F t) ` K' (Suc n)"
   361       apply (rule image_eqI[OF _ img])
   362       using \<open>j \<in> J (Suc n)\<close> \<open>j \<in> J (Suc m)\<close>
   363       unfolding j by (subst proj_fm, auto)+
   364   qed
   365   have "\<forall>t. \<exists>z. (\<lambda>i. (fm (Suc (diagseq i)) (y (Suc (diagseq i))))\<^sub>F t) \<longlonglongrightarrow> z"
   366     using diagonal_tendsto ..
   367   then obtain z where z:
   368     "\<And>t. (\<lambda>i. (fm (Suc (diagseq i)) (y (Suc (diagseq i))))\<^sub>F t) \<longlonglongrightarrow> z t"
   369     unfolding choice_iff by blast
   370   {
   371     fix n :: nat assume "n \<ge> 1"
   372     have "\<And>i. domain (fm n (y (Suc (diagseq i)))) = domain (finmap_of (Utn ` J n) z)"
   373       by simp
   374     moreover
   375     {
   376       fix t
   377       assume t: "t \<in> domain (finmap_of (Utn ` J n) z)"
   378       hence "t \<in> Utn ` J n" by simp
   379       then obtain j where j: "t = Utn j" "j \<in> J n" by auto
   380       have "(\<lambda>i. (fm n (y (Suc (diagseq i))))\<^sub>F t) \<longlonglongrightarrow> z t"
   381         apply (subst (2) tendsto_iff, subst eventually_sequentially)
   382       proof safe
   383         fix e :: real assume "0 < e"
   384         { fix i and x :: "'i \<Rightarrow> 'a" assume i: "i \<ge> n"
   385           assume "t \<in> domain (fm n x)"
   386           hence "t \<in> domain (fm i x)" using J_mono[OF \<open>i \<ge> n\<close>] by auto
   387           with i have "(fm i x)\<^sub>F t = (fm n x)\<^sub>F t"
   388             using j by (auto simp: proj_fm dest!: inj_onD[OF inj_on_Utn])
   389         } note index_shift = this
   390         have I: "\<And>i. i \<ge> n \<Longrightarrow> Suc (diagseq i) \<ge> n"
   391           apply (rule le_SucI)
   392           apply (rule order_trans) apply simp
   393           apply (rule seq_suble[OF subseq_diagseq])
   394           done
   395         from z
   396         have "\<exists>N. \<forall>i\<ge>N. dist ((fm (Suc (diagseq i)) (y (Suc (diagseq i))))\<^sub>F t) (z t) < e"
   397           unfolding tendsto_iff eventually_sequentially using \<open>0 < e\<close> by auto
   398         then obtain N where N: "\<And>i. i \<ge> N \<Longrightarrow>
   399           dist ((fm (Suc (diagseq i)) (y (Suc (diagseq i))))\<^sub>F t) (z t) < e" by auto
   400         show "\<exists>N. \<forall>na\<ge>N. dist ((fm n (y (Suc (diagseq na))))\<^sub>F t) (z t) < e "
   401         proof (rule exI[where x="max N n"], safe)
   402           fix na assume "max N n \<le> na"
   403           hence  "dist ((fm n (y (Suc (diagseq na))))\<^sub>F t) (z t) =
   404                   dist ((fm (Suc (diagseq na)) (y (Suc (diagseq na))))\<^sub>F t) (z t)" using t
   405             by (subst index_shift[OF I]) auto
   406           also have "\<dots> < e" using \<open>max N n \<le> na\<close> by (intro N) simp
   407           finally show "dist ((fm n (y (Suc (diagseq na))))\<^sub>F t) (z t) < e" .
   408         qed
   409       qed
   410       hence "(\<lambda>i. (fm n (y (Suc (diagseq i))))\<^sub>F t) \<longlonglongrightarrow> (finmap_of (Utn ` J n) z)\<^sub>F t"
   411         by (simp add: tendsto_intros)
   412     } ultimately
   413     have "(\<lambda>i. fm n (y (Suc (diagseq i)))) \<longlonglongrightarrow> finmap_of (Utn ` J n) z"
   414       by (rule tendsto_finmap)
   415     hence "((\<lambda>i. fm n (y (Suc (diagseq i)))) o (\<lambda>i. i + n)) \<longlonglongrightarrow> finmap_of (Utn ` J n) z"
   416       by (intro lim_subseq) (simp add: subseq_def)
   417     moreover
   418     have "(\<forall>i. ((\<lambda>i. fm n (y (Suc (diagseq i)))) o (\<lambda>i. i + n)) i \<in> K' n)"
   419       apply (auto simp add: o_def intro!: fm_in_K' \<open>1 \<le> n\<close> le_SucI)
   420       apply (rule le_trans)
   421       apply (rule le_add2)
   422       using seq_suble[OF subseq_diagseq]
   423       apply auto
   424       done
   425     moreover
   426     from \<open>compact (K' n)\<close> have "closed (K' n)" by (rule compact_imp_closed)
   427     ultimately
   428     have "finmap_of (Utn ` J n) z \<in> K' n"
   429       unfolding closed_sequential_limits by blast
   430     also have "finmap_of (Utn ` J n) z  = fm n (\<lambda>i. z (Utn i))"
   431       unfolding finmap_eq_iff
   432     proof clarsimp
   433       fix i assume i: "i \<in> J n"
   434       hence "from_nat_into (\<Union>n. J n) (Utn i) = i"
   435         unfolding Utn_def
   436         by (subst from_nat_into_to_nat_on[OF countable_UN_J]) auto
   437       with i show "z (Utn i) = (fm n (\<lambda>i. z (Utn i)))\<^sub>F (Utn i)"
   438         by (simp add: finmap_eq_iff fm_def compose_def)
   439     qed
   440     finally have "fm n (\<lambda>i. z (Utn i)) \<in> K' n" .
   441     moreover
   442     let ?J = "\<Union>n. J n"
   443     have "(?J \<inter> J n) = J n" by auto
   444     ultimately have "restrict (\<lambda>i. z (Utn i)) (?J \<inter> J n) \<in> K n"
   445       unfolding K_def by (auto simp: space_P space_PiM)
   446     hence "restrict (\<lambda>i. z (Utn i)) ?J \<in> Z' n" unfolding Z'_def
   447       using J by (auto simp: prod_emb_def PiE_def extensional_def)
   448     also have "\<dots> \<subseteq> Z n" using Z' by simp
   449     finally have "restrict (\<lambda>i. z (Utn i)) ?J \<in> Z n" .
   450   } note in_Z = this
   451   hence "(\<Inter>i\<in>{1..}. Z i) \<noteq> {}" by auto
   452   thus "(\<Inter>i. Z i) \<noteq> {}"
   453     using INT_decseq_offset[OF antimonoI[OF Z_mono]] by simp
   454 qed fact+
   456 lemma measure_lim_emb:
   457   "J \<subseteq> I \<Longrightarrow> finite J \<Longrightarrow> X \<in> sets (\<Pi>\<^sub>M i\<in>J. borel) \<Longrightarrow> measure lim (emb I J X) = measure (P J) X"
   458   unfolding measure_def by (subst emeasure_lim_emb) auto
   460 end
   462 hide_const (open) PiF
   463 hide_const (open) Pi\<^sub>F
   464 hide_const (open) Pi'
   465 hide_const (open) Abs_finmap
   466 hide_const (open) Rep_finmap
   467 hide_const (open) finmap_of
   468 hide_const (open) proj
   469 hide_const (open) domain
   470 hide_const (open) basis_finmap
   472 sublocale polish_projective \<subseteq> P: prob_space lim
   473 proof
   474   have *: "emb I {} {\<lambda>x. undefined} = space (\<Pi>\<^sub>M i\<in>I. borel)"
   475     by (auto simp: prod_emb_def space_PiM)
   476   interpret prob_space "P {}" 
   477     using prob_space_P by simp
   478   show "emeasure lim (space lim) = 1"
   479     using emeasure_lim_emb[of "{}" "{\<lambda>x. undefined}"] emeasure_space_1
   480     by (simp add: * PiM_empty space_P)
   481 qed
   483 locale polish_product_prob_space =
   484   product_prob_space "\<lambda>_. borel::('a::polish_space) measure" I for I::"'i set"
   486 sublocale polish_product_prob_space \<subseteq> P: polish_projective I "\<lambda>J. PiM J (\<lambda>_. borel::('a) measure)"
   487 proof qed
   489 lemma (in polish_product_prob_space) limP_eq_PiM: "lim = PiM I (\<lambda>_. borel)"
   490   by (rule PiM_eq) (auto simp: emeasure_PiM emeasure_lim_emb)
   492 end