src/HOL/Probability/Radon_Nikodym.thy
author hoelzl
Fri Feb 19 13:40:50 2016 +0100 (2016-02-19)
changeset 62378 85ed00c1fe7c
parent 62343 24106dc44def
child 62390 842917225d56
permissions -rw-r--r--
generalize more theorems to support enat and ennreal
     1 (*  Title:      HOL/Probability/Radon_Nikodym.thy
     2     Author:     Johannes Hölzl, TU München
     3 *)
     4 
     5 section \<open>Radon-Nikod{\'y}m derivative\<close>
     6 
     7 theory Radon_Nikodym
     8 imports Bochner_Integration
     9 begin
    10 
    11 definition "diff_measure M N =
    12   measure_of (space M) (sets M) (\<lambda>A. emeasure M A - emeasure N A)"
    13 
    14 lemma
    15   shows space_diff_measure[simp]: "space (diff_measure M N) = space M"
    16     and sets_diff_measure[simp]: "sets (diff_measure M N) = sets M"
    17   by (auto simp: diff_measure_def)
    18 
    19 lemma emeasure_diff_measure:
    20   assumes fin: "finite_measure M" "finite_measure N" and sets_eq: "sets M = sets N"
    21   assumes pos: "\<And>A. A \<in> sets M \<Longrightarrow> emeasure N A \<le> emeasure M A" and A: "A \<in> sets M"
    22   shows "emeasure (diff_measure M N) A = emeasure M A - emeasure N A" (is "_ = ?\<mu> A")
    23   unfolding diff_measure_def
    24 proof (rule emeasure_measure_of_sigma)
    25   show "sigma_algebra (space M) (sets M)" ..
    26   show "positive (sets M) ?\<mu>"
    27     using pos by (simp add: positive_def ereal_diff_positive)
    28   show "countably_additive (sets M) ?\<mu>"
    29   proof (rule countably_additiveI)
    30     fix A :: "nat \<Rightarrow> _"  assume A: "range A \<subseteq> sets M" and "disjoint_family A"
    31     then have suminf:
    32       "(\<Sum>i. emeasure M (A i)) = emeasure M (\<Union>i. A i)"
    33       "(\<Sum>i. emeasure N (A i)) = emeasure N (\<Union>i. A i)"
    34       by (simp_all add: suminf_emeasure sets_eq)
    35     with A have "(\<Sum>i. emeasure M (A i) - emeasure N (A i)) =
    36       (\<Sum>i. emeasure M (A i)) - (\<Sum>i. emeasure N (A i))"
    37       using fin
    38       by (intro suminf_ereal_minus pos emeasure_nonneg)
    39          (auto simp: sets_eq finite_measure.emeasure_eq_measure suminf_emeasure)
    40     then show "(\<Sum>i. emeasure M (A i) - emeasure N (A i)) =
    41       emeasure M (\<Union>i. A i) - emeasure N (\<Union>i. A i) "
    42       by (simp add: suminf)
    43   qed
    44 qed fact
    45 
    46 lemma (in sigma_finite_measure) Ex_finite_integrable_function:
    47   shows "\<exists>h\<in>borel_measurable M. integral\<^sup>N M h \<noteq> \<infinity> \<and> (\<forall>x\<in>space M. 0 < h x \<and> h x < \<infinity>) \<and> (\<forall>x. 0 \<le> h x)"
    48 proof -
    49   obtain A :: "nat \<Rightarrow> 'a set" where
    50     range[measurable]: "range A \<subseteq> sets M" and
    51     space: "(\<Union>i. A i) = space M" and
    52     measure: "\<And>i. emeasure M (A i) \<noteq> \<infinity>" and
    53     disjoint: "disjoint_family A"
    54     using sigma_finite_disjoint by blast
    55   let ?B = "\<lambda>i. 2^Suc i * emeasure M (A i)"
    56   have "\<forall>i. \<exists>x. 0 < x \<and> x < inverse (?B i)"
    57   proof
    58     fix i show "\<exists>x. 0 < x \<and> x < inverse (?B i)"
    59       using measure[of i] emeasure_nonneg[of M "A i"]
    60       by (auto intro!: dense simp: ereal_0_gt_inverse ereal_zero_le_0_iff)
    61   qed
    62   from choice[OF this] obtain n where n: "\<And>i. 0 < n i"
    63     "\<And>i. n i < inverse (2^Suc i * emeasure M (A i))" by auto
    64   { fix i have "0 \<le> n i" using n(1)[of i] by auto } note pos = this
    65   let ?h = "\<lambda>x. \<Sum>i. n i * indicator (A i) x"
    66   show ?thesis
    67   proof (safe intro!: bexI[of _ ?h] del: notI)
    68     have "\<And>i. A i \<in> sets M"
    69       using range by fastforce+
    70     then have "integral\<^sup>N M ?h = (\<Sum>i. n i * emeasure M (A i))" using pos
    71       by (simp add: nn_integral_suminf nn_integral_cmult_indicator)
    72     also have "\<dots> \<le> (\<Sum>i. (1 / 2)^Suc i)"
    73     proof (rule suminf_le_pos)
    74       fix N
    75       have "n N * emeasure M (A N) \<le> inverse (2^Suc N * emeasure M (A N)) * emeasure M (A N)"
    76         using n[of N]
    77         by (intro ereal_mult_right_mono) auto
    78       also have "\<dots> \<le> (1 / 2) ^ Suc N"
    79         using measure[of N] n[of N]
    80         by (cases rule: ereal2_cases[of "n N" "emeasure M (A N)"])
    81            (simp_all add: inverse_eq_divide power_divide one_ereal_def ereal_power_divide)
    82       finally show "n N * emeasure M (A N) \<le> (1 / 2) ^ Suc N" .
    83       show "0 \<le> n N * emeasure M (A N)" using n[of N] \<open>A N \<in> sets M\<close> by (simp add: emeasure_nonneg)
    84     qed
    85     finally show "integral\<^sup>N M ?h \<noteq> \<infinity>" unfolding suminf_half_series_ereal by auto
    86   next
    87     { fix x assume "x \<in> space M"
    88       then obtain i where "x \<in> A i" using space[symmetric] by auto
    89       with disjoint n have "?h x = n i"
    90         by (auto intro!: suminf_cmult_indicator intro: less_imp_le)
    91       then show "0 < ?h x" and "?h x < \<infinity>" using n[of i] by auto }
    92     note pos = this
    93     fix x show "0 \<le> ?h x"
    94     proof cases
    95       assume "x \<in> space M" then show "0 \<le> ?h x" using pos by (auto intro: less_imp_le)
    96     next
    97       assume "x \<notin> space M" then have "\<And>i. x \<notin> A i" using space by auto
    98       then show "0 \<le> ?h x" by auto
    99     qed
   100   qed measurable
   101 qed
   102 
   103 subsection "Absolutely continuous"
   104 
   105 definition absolutely_continuous :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> bool" where
   106   "absolutely_continuous M N \<longleftrightarrow> null_sets M \<subseteq> null_sets N"
   107 
   108 lemma absolutely_continuousI_count_space: "absolutely_continuous (count_space A) M"
   109   unfolding absolutely_continuous_def by (auto simp: null_sets_count_space)
   110 
   111 lemma absolutely_continuousI_density:
   112   "f \<in> borel_measurable M \<Longrightarrow> absolutely_continuous M (density M f)"
   113   by (force simp add: absolutely_continuous_def null_sets_density_iff dest: AE_not_in)
   114 
   115 lemma absolutely_continuousI_point_measure_finite:
   116   "(\<And>x. \<lbrakk> x \<in> A ; f x \<le> 0 \<rbrakk> \<Longrightarrow> g x \<le> 0) \<Longrightarrow> absolutely_continuous (point_measure A f) (point_measure A g)"
   117   unfolding absolutely_continuous_def by (force simp: null_sets_point_measure_iff)
   118 
   119 lemma absolutely_continuous_AE:
   120   assumes sets_eq: "sets M' = sets M"
   121     and "absolutely_continuous M M'" "AE x in M. P x"
   122    shows "AE x in M'. P x"
   123 proof -
   124   from \<open>AE x in M. P x\<close> obtain N where N: "N \<in> null_sets M" "{x\<in>space M. \<not> P x} \<subseteq> N"
   125     unfolding eventually_ae_filter by auto
   126   show "AE x in M'. P x"
   127   proof (rule AE_I')
   128     show "{x\<in>space M'. \<not> P x} \<subseteq> N" using sets_eq_imp_space_eq[OF sets_eq] N(2) by simp
   129     from \<open>absolutely_continuous M M'\<close> show "N \<in> null_sets M'"
   130       using N unfolding absolutely_continuous_def sets_eq null_sets_def by auto
   131   qed
   132 qed
   133 
   134 subsection "Existence of the Radon-Nikodym derivative"
   135 
   136 lemma (in finite_measure) Radon_Nikodym_aux_epsilon:
   137   fixes e :: real assumes "0 < e"
   138   assumes "finite_measure N" and sets_eq: "sets N = sets M"
   139   shows "\<exists>A\<in>sets M. measure M (space M) - measure N (space M) \<le> measure M A - measure N A \<and>
   140                     (\<forall>B\<in>sets M. B \<subseteq> A \<longrightarrow> - e < measure M B - measure N B)"
   141 proof -
   142   interpret M': finite_measure N by fact
   143   let ?d = "\<lambda>A. measure M A - measure N A"
   144   let ?A = "\<lambda>A. if (\<forall>B\<in>sets M. B \<subseteq> space M - A \<longrightarrow> -e < ?d B)
   145     then {}
   146     else (SOME B. B \<in> sets M \<and> B \<subseteq> space M - A \<and> ?d B \<le> -e)"
   147   def A \<equiv> "\<lambda>n. ((\<lambda>B. B \<union> ?A B) ^^ n) {}"
   148   have A_simps[simp]:
   149     "A 0 = {}"
   150     "\<And>n. A (Suc n) = (A n \<union> ?A (A n))" unfolding A_def by simp_all
   151   { fix A assume "A \<in> sets M"
   152     have "?A A \<in> sets M"
   153       by (auto intro!: someI2[of _ _ "\<lambda>A. A \<in> sets M"] simp: not_less) }
   154   note A'_in_sets = this
   155   { fix n have "A n \<in> sets M"
   156     proof (induct n)
   157       case (Suc n) thus "A (Suc n) \<in> sets M"
   158         using A'_in_sets[of "A n"] by (auto split: split_if_asm)
   159     qed (simp add: A_def) }
   160   note A_in_sets = this
   161   hence "range A \<subseteq> sets M" by auto
   162   { fix n B
   163     assume Ex: "\<exists>B. B \<in> sets M \<and> B \<subseteq> space M - A n \<and> ?d B \<le> -e"
   164     hence False: "\<not> (\<forall>B\<in>sets M. B \<subseteq> space M - A n \<longrightarrow> -e < ?d B)" by (auto simp: not_less)
   165     have "?d (A (Suc n)) \<le> ?d (A n) - e" unfolding A_simps if_not_P[OF False]
   166     proof (rule someI2_ex[OF Ex])
   167       fix B assume "B \<in> sets M \<and> B \<subseteq> space M - A n \<and> ?d B \<le> - e"
   168       hence "A n \<inter> B = {}" "B \<in> sets M" and dB: "?d B \<le> -e" by auto
   169       hence "?d (A n \<union> B) = ?d (A n) + ?d B"
   170         using \<open>A n \<in> sets M\<close> finite_measure_Union M'.finite_measure_Union by (simp add: sets_eq)
   171       also have "\<dots> \<le> ?d (A n) - e" using dB by simp
   172       finally show "?d (A n \<union> B) \<le> ?d (A n) - e" .
   173     qed }
   174   note dA_epsilon = this
   175   { fix n have "?d (A (Suc n)) \<le> ?d (A n)"
   176     proof (cases "\<exists>B. B\<in>sets M \<and> B \<subseteq> space M - A n \<and> ?d B \<le> - e")
   177       case True from dA_epsilon[OF this] show ?thesis using \<open>0 < e\<close> by simp
   178     next
   179       case False
   180       hence "\<forall>B\<in>sets M. B \<subseteq> space M - A n \<longrightarrow> -e < ?d B" by (auto simp: not_le)
   181       thus ?thesis by simp
   182     qed }
   183   note dA_mono = this
   184   show ?thesis
   185   proof (cases "\<exists>n. \<forall>B\<in>sets M. B \<subseteq> space M - A n \<longrightarrow> -e < ?d B")
   186     case True then obtain n where B: "\<And>B. \<lbrakk> B \<in> sets M; B \<subseteq> space M - A n\<rbrakk> \<Longrightarrow> -e < ?d B" by blast
   187     show ?thesis
   188     proof (safe intro!: bexI[of _ "space M - A n"])
   189       fix B assume "B \<in> sets M" "B \<subseteq> space M - A n"
   190       from B[OF this] show "-e < ?d B" .
   191     next
   192       show "space M - A n \<in> sets M" by (rule sets.compl_sets) fact
   193     next
   194       show "?d (space M) \<le> ?d (space M - A n)"
   195       proof (induct n)
   196         fix n assume "?d (space M) \<le> ?d (space M - A n)"
   197         also have "\<dots> \<le> ?d (space M - A (Suc n))"
   198           using A_in_sets sets.sets_into_space dA_mono[of n] finite_measure_compl M'.finite_measure_compl
   199           by (simp del: A_simps add: sets_eq sets_eq_imp_space_eq[OF sets_eq])
   200         finally show "?d (space M) \<le> ?d (space M - A (Suc n))" .
   201       qed simp
   202     qed
   203   next
   204     case False hence B: "\<And>n. \<exists>B. B\<in>sets M \<and> B \<subseteq> space M - A n \<and> ?d B \<le> - e"
   205       by (auto simp add: not_less)
   206     { fix n have "?d (A n) \<le> - real n * e"
   207       proof (induct n)
   208         case (Suc n) with dA_epsilon[of n, OF B] show ?case by (simp del: A_simps add: of_nat_Suc field_simps)
   209       next
   210         case 0 with measure_empty show ?case by (simp add: zero_ereal_def)
   211       qed } note dA_less = this
   212     have decseq: "decseq (\<lambda>n. ?d (A n))" unfolding decseq_eq_incseq
   213     proof (rule incseq_SucI)
   214       fix n show "- ?d (A n) \<le> - ?d (A (Suc n))" using dA_mono[of n] by auto
   215     qed
   216     have A: "incseq A" by (auto intro!: incseq_SucI)
   217     from finite_Lim_measure_incseq[OF _ A] \<open>range A \<subseteq> sets M\<close>
   218       M'.finite_Lim_measure_incseq[OF _ A]
   219     have convergent: "(\<lambda>i. ?d (A i)) \<longlonglongrightarrow> ?d (\<Union>i. A i)"
   220       by (auto intro!: tendsto_diff simp: sets_eq)
   221     obtain n :: nat where "- ?d (\<Union>i. A i) / e < real n" using reals_Archimedean2 by auto
   222     moreover from order_trans[OF decseq_le[OF decseq convergent] dA_less]
   223     have "real n \<le> - ?d (\<Union>i. A i) / e" using \<open>0<e\<close> by (simp add: field_simps)
   224     ultimately show ?thesis by auto
   225   qed
   226 qed
   227 
   228 lemma (in finite_measure) Radon_Nikodym_aux:
   229   assumes "finite_measure N" and sets_eq: "sets N = sets M"
   230   shows "\<exists>A\<in>sets M. measure M (space M) - measure N (space M) \<le>
   231                     measure M A - measure N A \<and>
   232                     (\<forall>B\<in>sets M. B \<subseteq> A \<longrightarrow> 0 \<le> measure M B - measure N B)"
   233 proof -
   234   interpret N: finite_measure N by fact
   235   let ?d = "\<lambda>A. measure M A - measure N A"
   236   let ?P = "\<lambda>A n. if n = 0 then A = space M else (\<forall>C\<in>sets M. C \<subseteq> A \<longrightarrow> - 1 / real (Suc n) < ?d C)"
   237   let ?Q = "\<lambda>A B. A \<subseteq> B \<and> ?d B \<le> ?d A"
   238 
   239   have "\<exists>A. \<forall>n. (A n \<in> sets M \<and> ?P (A n) n) \<and> ?Q (A (Suc n)) (A n)"
   240   proof (rule dependent_nat_choice)
   241     show "\<exists>A. A \<in> sets M \<and> ?P A 0"
   242       by auto
   243   next
   244     fix A n assume "A \<in> sets M \<and> ?P A n"
   245     then have A: "A \<in> sets M" by auto
   246     then have "finite_measure (density M (indicator A))" "0 < 1 / real (Suc (Suc n))"
   247          "finite_measure (density N (indicator A))" "sets (density N (indicator A)) = sets (density M (indicator A))"
   248       by (auto simp: finite_measure_restricted N.finite_measure_restricted sets_eq)
   249     from finite_measure.Radon_Nikodym_aux_epsilon[OF this] guess X .. note X = this
   250     with A have "A \<inter> X \<in> sets M \<and> ?P (A \<inter> X) (Suc n) \<and> ?Q (A \<inter> X) A"
   251       by (simp add: measure_restricted sets_eq sets.Int) (metis inf_absorb2)
   252     then show "\<exists>B. (B \<in> sets M \<and> ?P B (Suc n)) \<and> ?Q B A"
   253       by blast
   254   qed
   255   then obtain A where A: "\<And>n. A n \<in> sets M" "\<And>n. ?P (A n) n" "\<And>n. ?Q (A (Suc n)) (A n)"
   256     by metis
   257   then have mono_dA: "mono (\<lambda>i. ?d (A i))" and A_0[simp]: "A 0 = space M"
   258     by (auto simp add: mono_iff_le_Suc)
   259   show ?thesis
   260   proof (safe intro!: bexI[of _ "\<Inter>i. A i"])
   261     show "(\<Inter>i. A i) \<in> sets M" using \<open>\<And>n. A n \<in> sets M\<close> by auto
   262     have "decseq A" using A by (auto intro!: decseq_SucI)
   263     from A(1) finite_Lim_measure_decseq[OF _ this] N.finite_Lim_measure_decseq[OF _ this]
   264     have "(\<lambda>i. ?d (A i)) \<longlonglongrightarrow> ?d (\<Inter>i. A i)" by (auto intro!: tendsto_diff simp: sets_eq)
   265     thus "?d (space M) \<le> ?d (\<Inter>i. A i)" using mono_dA[THEN monoD, of 0 _]
   266       by (rule_tac LIMSEQ_le_const) auto
   267   next
   268     fix B assume B: "B \<in> sets M" "B \<subseteq> (\<Inter>i. A i)"
   269     show "0 \<le> ?d B"
   270     proof (rule ccontr)
   271       assume "\<not> 0 \<le> ?d B"
   272       hence "0 < - ?d B" by auto
   273       from ex_inverse_of_nat_Suc_less[OF this]
   274       obtain n where *: "?d B < - 1 / real (Suc n)"
   275         by (auto simp: field_simps)
   276       also have "\<dots> \<le> - 1 / real (Suc (Suc n))"
   277         by (auto simp: field_simps)
   278       finally show False
   279         using * A(2)[of "Suc n"] B by (auto elim!: ballE[of _ _ B])
   280     qed
   281   qed
   282 qed
   283 
   284 lemma (in finite_measure) Radon_Nikodym_finite_measure:
   285   assumes "finite_measure N" and sets_eq: "sets N = sets M"
   286   assumes "absolutely_continuous M N"
   287   shows "\<exists>f \<in> borel_measurable M. (\<forall>x. 0 \<le> f x) \<and> density M f = N"
   288 proof -
   289   interpret N: finite_measure N by fact
   290   def G \<equiv> "{g \<in> borel_measurable M. (\<forall>x. 0 \<le> g x) \<and> (\<forall>A\<in>sets M. (\<integral>\<^sup>+x. g x * indicator A x \<partial>M) \<le> N A)}"
   291   { fix f have "f \<in> G \<Longrightarrow> f \<in> borel_measurable M" by (auto simp: G_def) }
   292   note this[measurable_dest]
   293   have "(\<lambda>x. 0) \<in> G" unfolding G_def by auto
   294   hence "G \<noteq> {}" by auto
   295   { fix f g assume f: "f \<in> G" and g: "g \<in> G"
   296     have "(\<lambda>x. max (g x) (f x)) \<in> G" (is "?max \<in> G") unfolding G_def
   297     proof safe
   298       show "?max \<in> borel_measurable M" using f g unfolding G_def by auto
   299       let ?A = "{x \<in> space M. f x \<le> g x}"
   300       have "?A \<in> sets M" using f g unfolding G_def by auto
   301       fix A assume "A \<in> sets M"
   302       hence sets: "?A \<inter> A \<in> sets M" "(space M - ?A) \<inter> A \<in> sets M" using \<open>?A \<in> sets M\<close> by auto
   303       hence sets': "?A \<inter> A \<in> sets N" "(space M - ?A) \<inter> A \<in> sets N" by (auto simp: sets_eq)
   304       have union: "((?A \<inter> A) \<union> ((space M - ?A) \<inter> A)) = A"
   305         using sets.sets_into_space[OF \<open>A \<in> sets M\<close>] by auto
   306       have "\<And>x. x \<in> space M \<Longrightarrow> max (g x) (f x) * indicator A x =
   307         g x * indicator (?A \<inter> A) x + f x * indicator ((space M - ?A) \<inter> A) x"
   308         by (auto simp: indicator_def max_def)
   309       hence "(\<integral>\<^sup>+x. max (g x) (f x) * indicator A x \<partial>M) =
   310         (\<integral>\<^sup>+x. g x * indicator (?A \<inter> A) x \<partial>M) +
   311         (\<integral>\<^sup>+x. f x * indicator ((space M - ?A) \<inter> A) x \<partial>M)"
   312         using f g sets unfolding G_def
   313         by (auto cong: nn_integral_cong intro!: nn_integral_add)
   314       also have "\<dots> \<le> N (?A \<inter> A) + N ((space M - ?A) \<inter> A)"
   315         using f g sets unfolding G_def by (auto intro!: add_mono)
   316       also have "\<dots> = N A"
   317         using plus_emeasure[OF sets'] union by auto
   318       finally show "(\<integral>\<^sup>+x. max (g x) (f x) * indicator A x \<partial>M) \<le> N A" .
   319     next
   320       fix x show "0 \<le> max (g x) (f x)" using f g by (auto simp: G_def split: split_max)
   321     qed }
   322   note max_in_G = this
   323   { fix f assume  "incseq f" and f: "\<And>i. f i \<in> G"
   324     then have [measurable]: "\<And>i. f i \<in> borel_measurable M" by (auto simp: G_def)
   325     have "(\<lambda>x. SUP i. f i x) \<in> G" unfolding G_def
   326     proof safe
   327       show "(\<lambda>x. SUP i. f i x) \<in> borel_measurable M" by measurable
   328       { fix x show "0 \<le> (SUP i. f i x)"
   329           using f by (auto simp: G_def intro: SUP_upper2) }
   330     next
   331       fix A assume "A \<in> sets M"
   332       have "(\<integral>\<^sup>+x. (SUP i. f i x) * indicator A x \<partial>M) =
   333         (\<integral>\<^sup>+x. (SUP i. f i x * indicator A x) \<partial>M)"
   334         by (intro nn_integral_cong) (simp split: split_indicator)
   335       also have "\<dots> = (SUP i. (\<integral>\<^sup>+x. f i x * indicator A x \<partial>M))"
   336         using \<open>incseq f\<close> f \<open>A \<in> sets M\<close>
   337         by (intro nn_integral_monotone_convergence_SUP)
   338            (auto simp: G_def incseq_Suc_iff le_fun_def split: split_indicator)
   339       finally show "(\<integral>\<^sup>+x. (SUP i. f i x) * indicator A x \<partial>M) \<le> N A"
   340         using f \<open>A \<in> sets M\<close> by (auto intro!: SUP_least simp: G_def)
   341     qed }
   342   note SUP_in_G = this
   343   let ?y = "SUP g : G. integral\<^sup>N M g"
   344   have y_le: "?y \<le> N (space M)" unfolding G_def
   345   proof (safe intro!: SUP_least)
   346     fix g assume "\<forall>A\<in>sets M. (\<integral>\<^sup>+x. g x * indicator A x \<partial>M) \<le> N A"
   347     from this[THEN bspec, OF sets.top] show "integral\<^sup>N M g \<le> N (space M)"
   348       by (simp cong: nn_integral_cong)
   349   qed
   350   from SUP_countable_SUP [OF \<open>G \<noteq> {}\<close>, of "integral\<^sup>N M"] guess ys .. note ys = this
   351   then have "\<forall>n. \<exists>g. g\<in>G \<and> integral\<^sup>N M g = ys n"
   352   proof safe
   353     fix n assume "range ys \<subseteq> integral\<^sup>N M ` G"
   354     hence "ys n \<in> integral\<^sup>N M ` G" by auto
   355     thus "\<exists>g. g\<in>G \<and> integral\<^sup>N M g = ys n" by auto
   356   qed
   357   from choice[OF this] obtain gs where "\<And>i. gs i \<in> G" "\<And>n. integral\<^sup>N M (gs n) = ys n" by auto
   358   hence y_eq: "?y = (SUP i. integral\<^sup>N M (gs i))" using ys by auto
   359   let ?g = "\<lambda>i x. Max ((\<lambda>n. gs n x) ` {..i})"
   360   def f \<equiv> "\<lambda>x. SUP i. ?g i x"
   361   let ?F = "\<lambda>A x. f x * indicator A x"
   362   have gs_not_empty: "\<And>i x. (\<lambda>n. gs n x) ` {..i} \<noteq> {}" by auto
   363   { fix i have "?g i \<in> G"
   364     proof (induct i)
   365       case 0 thus ?case by simp fact
   366     next
   367       case (Suc i)
   368       with Suc gs_not_empty \<open>gs (Suc i) \<in> G\<close> show ?case
   369         by (auto simp add: atMost_Suc intro!: max_in_G)
   370     qed }
   371   note g_in_G = this
   372   have "incseq ?g" using gs_not_empty
   373     by (auto intro!: incseq_SucI le_funI simp add: atMost_Suc)
   374   from SUP_in_G[OF this g_in_G] have [measurable]: "f \<in> G" unfolding f_def .
   375   then have [simp, intro]: "f \<in> borel_measurable M" unfolding G_def by auto
   376   have "integral\<^sup>N M f = (SUP i. integral\<^sup>N M (?g i))" unfolding f_def
   377     using g_in_G \<open>incseq ?g\<close>
   378     by (auto intro!: nn_integral_monotone_convergence_SUP simp: G_def)
   379   also have "\<dots> = ?y"
   380   proof (rule antisym)
   381     show "(SUP i. integral\<^sup>N M (?g i)) \<le> ?y"
   382       using g_in_G by (auto intro: SUP_mono)
   383     show "?y \<le> (SUP i. integral\<^sup>N M (?g i))" unfolding y_eq
   384       by (auto intro!: SUP_mono nn_integral_mono Max_ge)
   385   qed
   386   finally have int_f_eq_y: "integral\<^sup>N M f = ?y" .
   387   have "\<And>x. 0 \<le> f x"
   388     unfolding f_def using \<open>\<And>i. gs i \<in> G\<close>
   389     by (auto intro!: SUP_upper2 Max_ge_iff[THEN iffD2] simp: G_def)
   390   let ?t = "\<lambda>A. N A - (\<integral>\<^sup>+x. ?F A x \<partial>M)"
   391   let ?M = "diff_measure N (density M f)"
   392   have f_le_N: "\<And>A. A \<in> sets M \<Longrightarrow> (\<integral>\<^sup>+x. ?F A x \<partial>M) \<le> N A"
   393     using \<open>f \<in> G\<close> unfolding G_def by auto
   394   have emeasure_M: "\<And>A. A \<in> sets M \<Longrightarrow> emeasure ?M A = ?t A"
   395   proof (subst emeasure_diff_measure)
   396     from f_le_N[of "space M"] show "finite_measure N" "finite_measure (density M f)"
   397       by (auto intro!: finite_measureI simp: emeasure_density cong: nn_integral_cong)
   398   next
   399     fix B assume "B \<in> sets N" with f_le_N[of B] show "emeasure (density M f) B \<le> emeasure N B"
   400       by (auto simp: sets_eq emeasure_density cong: nn_integral_cong)
   401   qed (auto simp: sets_eq emeasure_density)
   402   from emeasure_M[of "space M"] N.finite_emeasure_space nn_integral_nonneg[of M "?F (space M)"]
   403   interpret M': finite_measure ?M
   404     by (auto intro!: finite_measureI simp: sets_eq_imp_space_eq[OF sets_eq] N.emeasure_eq_measure ereal_minus_eq_PInfty_iff)
   405 
   406   have ac: "absolutely_continuous M ?M" unfolding absolutely_continuous_def
   407   proof
   408     fix A assume A_M: "A \<in> null_sets M"
   409     with \<open>absolutely_continuous M N\<close> have A_N: "A \<in> null_sets N"
   410       unfolding absolutely_continuous_def by auto
   411     moreover from A_M A_N have "(\<integral>\<^sup>+ x. ?F A x \<partial>M) \<le> N A" using \<open>f \<in> G\<close> by (auto simp: G_def)
   412     ultimately have "N A - (\<integral>\<^sup>+ x. ?F A x \<partial>M) = 0"
   413       using nn_integral_nonneg[of M] by (auto intro!: antisym)
   414     then show "A \<in> null_sets ?M"
   415       using A_M by (simp add: emeasure_M null_sets_def sets_eq)
   416   qed
   417   have upper_bound: "\<forall>A\<in>sets M. ?M A \<le> 0"
   418   proof (rule ccontr)
   419     assume "\<not> ?thesis"
   420     then obtain A where A: "A \<in> sets M" and pos: "0 < ?M A"
   421       by (auto simp: not_le)
   422     note pos
   423     also have "?M A \<le> ?M (space M)"
   424       using emeasure_space[of ?M A] by (simp add: sets_eq[THEN sets_eq_imp_space_eq])
   425     finally have pos_t: "0 < ?M (space M)" by simp
   426     moreover
   427     from pos_t have "emeasure M (space M) \<noteq> 0"
   428       using ac unfolding absolutely_continuous_def by (auto simp: null_sets_def)
   429     then have pos_M: "0 < emeasure M (space M)"
   430       using emeasure_nonneg[of M "space M"] by (simp add: le_less)
   431     moreover
   432     have "(\<integral>\<^sup>+x. f x * indicator (space M) x \<partial>M) \<le> N (space M)"
   433       using \<open>f \<in> G\<close> unfolding G_def by auto
   434     hence "(\<integral>\<^sup>+x. f x * indicator (space M) x \<partial>M) \<noteq> \<infinity>"
   435       using M'.finite_emeasure_space by auto
   436     moreover
   437     def b \<equiv> "?M (space M) / emeasure M (space M) / 2"
   438     ultimately have b: "b \<noteq> 0 \<and> 0 \<le> b \<and> b \<noteq> \<infinity>"
   439       by (auto simp: ereal_divide_eq)
   440     then have b: "b \<noteq> 0" "0 \<le> b" "0 < b"  "b \<noteq> \<infinity>" by auto
   441     let ?Mb = "density M (\<lambda>_. b)"
   442     have Mb: "finite_measure ?Mb" "sets ?Mb = sets ?M"
   443         using b by (auto simp: emeasure_density_const sets_eq intro!: finite_measureI)
   444     from M'.Radon_Nikodym_aux[OF this] guess A0 ..
   445     then have "A0 \<in> sets M"
   446       and space_less_A0: "measure ?M (space M) - real_of_ereal b * measure M (space M) \<le> measure ?M A0 - real_of_ereal b * measure M A0"
   447       and *: "\<And>B. B \<in> sets M \<Longrightarrow> B \<subseteq> A0 \<Longrightarrow> 0 \<le> measure ?M B - real_of_ereal b * measure M B"
   448       using b by (simp_all add: measure_density_const sets_eq_imp_space_eq[OF sets_eq] sets_eq)
   449     { fix B assume B: "B \<in> sets M" "B \<subseteq> A0"
   450       with *[OF this] have "b * emeasure M B \<le> ?M B"
   451         using b unfolding M'.emeasure_eq_measure emeasure_eq_measure by (cases b) auto }
   452     note bM_le_t = this
   453     let ?f0 = "\<lambda>x. f x + b * indicator A0 x"
   454     { fix A assume A: "A \<in> sets M"
   455       hence "A \<inter> A0 \<in> sets M" using \<open>A0 \<in> sets M\<close> by auto
   456       have "(\<integral>\<^sup>+x. ?f0 x  * indicator A x \<partial>M) =
   457         (\<integral>\<^sup>+x. f x * indicator A x + b * indicator (A \<inter> A0) x \<partial>M)"
   458         by (auto intro!: nn_integral_cong split: split_indicator)
   459       hence "(\<integral>\<^sup>+x. ?f0 x * indicator A x \<partial>M) =
   460           (\<integral>\<^sup>+x. f x * indicator A x \<partial>M) + b * emeasure M (A \<inter> A0)"
   461         using \<open>A0 \<in> sets M\<close> \<open>A \<inter> A0 \<in> sets M\<close> A b \<open>f \<in> G\<close>
   462         by (simp add: nn_integral_add nn_integral_cmult_indicator G_def) }
   463     note f0_eq = this
   464     { fix A assume A: "A \<in> sets M"
   465       hence "A \<inter> A0 \<in> sets M" using \<open>A0 \<in> sets M\<close> by auto
   466       have f_le_v: "(\<integral>\<^sup>+x. ?F A x \<partial>M) \<le> N A" using \<open>f \<in> G\<close> A unfolding G_def by auto
   467       note f0_eq[OF A]
   468       also have "(\<integral>\<^sup>+x. ?F A x \<partial>M) + b * emeasure M (A \<inter> A0) \<le> (\<integral>\<^sup>+x. ?F A x \<partial>M) + ?M (A \<inter> A0)"
   469         using bM_le_t[OF \<open>A \<inter> A0 \<in> sets M\<close>] \<open>A \<in> sets M\<close> \<open>A0 \<in> sets M\<close>
   470         by (auto intro!: add_left_mono)
   471       also have "\<dots> \<le> (\<integral>\<^sup>+x. f x * indicator A x \<partial>M) + ?M A"
   472         using emeasure_mono[of "A \<inter> A0" A ?M] \<open>A \<in> sets M\<close> \<open>A0 \<in> sets M\<close>
   473         by (auto intro!: add_left_mono simp: sets_eq)
   474       also have "\<dots> \<le> N A"
   475         unfolding emeasure_M[OF \<open>A \<in> sets M\<close>]
   476         using f_le_v N.emeasure_eq_measure[of A] nn_integral_nonneg[of M "?F A"]
   477         by (cases "\<integral>\<^sup>+x. ?F A x \<partial>M", cases "N A") auto
   478       finally have "(\<integral>\<^sup>+x. ?f0 x * indicator A x \<partial>M) \<le> N A" . }
   479     hence "?f0 \<in> G" using \<open>A0 \<in> sets M\<close> b \<open>f \<in> G\<close> by (auto simp: G_def)
   480     have int_f_finite: "integral\<^sup>N M f \<noteq> \<infinity>"
   481       by (metis N.emeasure_finite ereal_infty_less_eq2(1) int_f_eq_y y_le)
   482     have  "0 < ?M (space M) - emeasure ?Mb (space M)"
   483       using pos_t
   484       by (simp add: b emeasure_density_const)
   485          (simp add: M'.emeasure_eq_measure emeasure_eq_measure pos_M b_def)
   486     also have "\<dots> \<le> ?M A0 - b * emeasure M A0"
   487       using space_less_A0 \<open>A0 \<in> sets M\<close> b
   488       by (cases b) (auto simp add: b emeasure_density_const sets_eq M'.emeasure_eq_measure emeasure_eq_measure)
   489     finally have 1: "b * emeasure M A0 < ?M A0"
   490       by (metis M'.emeasure_real \<open>A0 \<in> sets M\<close> bM_le_t diff_self ereal_less(1) ereal_minus(1)
   491                 less_eq_ereal_def mult_zero_left not_square_less_zero subset_refl zero_ereal_def)
   492     with b have "0 < ?M A0"
   493       by (metis M'.emeasure_real MInfty_neq_PInfty(1) emeasure_real ereal_less_eq(5) ereal_zero_times
   494                ereal_mult_eq_MInfty ereal_mult_eq_PInfty ereal_zero_less_0_iff less_eq_ereal_def)
   495     then have "emeasure M A0 \<noteq> 0" using ac \<open>A0 \<in> sets M\<close>
   496       by (auto simp: absolutely_continuous_def null_sets_def)
   497     then have "0 < emeasure M A0" using emeasure_nonneg[of M A0] by auto
   498     hence "0 < b * emeasure M A0" using b by (auto simp: ereal_zero_less_0_iff)
   499     with int_f_finite have "?y + 0 < integral\<^sup>N M f + b * emeasure M A0" unfolding int_f_eq_y
   500       using \<open>f \<in> G\<close>
   501       by (intro ereal_add_strict_mono) (auto intro!: SUP_upper2 nn_integral_nonneg)
   502     also have "\<dots> = integral\<^sup>N M ?f0" using f0_eq[OF sets.top] \<open>A0 \<in> sets M\<close> sets.sets_into_space
   503       by (simp cong: nn_integral_cong)
   504     finally have "?y < integral\<^sup>N M ?f0" by simp
   505     moreover from \<open>?f0 \<in> G\<close> have "integral\<^sup>N M ?f0 \<le> ?y" by (auto intro!: SUP_upper)
   506     ultimately show False by auto
   507   qed
   508   let ?f = "\<lambda>x. max 0 (f x)"
   509   show ?thesis
   510   proof (intro bexI[of _ ?f] measure_eqI conjI)
   511     show "sets (density M ?f) = sets N"
   512       by (simp add: sets_eq)
   513     fix A assume A: "A\<in>sets (density M ?f)"
   514     then show "emeasure (density M ?f) A = emeasure N A"
   515       using \<open>f \<in> G\<close> A upper_bound[THEN bspec, of A] N.emeasure_eq_measure[of A]
   516       by (cases "integral\<^sup>N M (?F A)")
   517          (auto intro!: antisym simp add: emeasure_density G_def emeasure_M density_max_0[symmetric])
   518   qed auto
   519 qed
   520 
   521 lemma (in finite_measure) split_space_into_finite_sets_and_rest:
   522   assumes ac: "absolutely_continuous M N" and sets_eq: "sets N = sets M"
   523   shows "\<exists>A0\<in>sets M. \<exists>B::nat\<Rightarrow>'a set. disjoint_family B \<and> range B \<subseteq> sets M \<and> A0 = space M - (\<Union>i. B i) \<and>
   524     (\<forall>A\<in>sets M. A \<subseteq> A0 \<longrightarrow> (emeasure M A = 0 \<and> N A = 0) \<or> (emeasure M A > 0 \<and> N A = \<infinity>)) \<and>
   525     (\<forall>i. N (B i) \<noteq> \<infinity>)"
   526 proof -
   527   let ?Q = "{Q\<in>sets M. N Q \<noteq> \<infinity>}"
   528   let ?a = "SUP Q:?Q. emeasure M Q"
   529   have "{} \<in> ?Q" by auto
   530   then have Q_not_empty: "?Q \<noteq> {}" by blast
   531   have "?a \<le> emeasure M (space M)" using sets.sets_into_space
   532     by (auto intro!: SUP_least emeasure_mono)
   533   then have "?a \<noteq> \<infinity>" using finite_emeasure_space
   534     by auto
   535   from SUP_countable_SUP [OF Q_not_empty, of "emeasure M"]
   536   obtain Q'' where "range Q'' \<subseteq> emeasure M ` ?Q" and a: "?a = (SUP i::nat. Q'' i)"
   537     by auto
   538   then have "\<forall>i. \<exists>Q'. Q'' i = emeasure M Q' \<and> Q' \<in> ?Q" by auto
   539   from choice[OF this] obtain Q' where Q': "\<And>i. Q'' i = emeasure M (Q' i)" "\<And>i. Q' i \<in> ?Q"
   540     by auto
   541   then have a_Lim: "?a = (SUP i::nat. emeasure M (Q' i))" using a by simp
   542   let ?O = "\<lambda>n. \<Union>i\<le>n. Q' i"
   543   have Union: "(SUP i. emeasure M (?O i)) = emeasure M (\<Union>i. ?O i)"
   544   proof (rule SUP_emeasure_incseq[of ?O])
   545     show "range ?O \<subseteq> sets M" using Q' by auto
   546     show "incseq ?O" by (fastforce intro!: incseq_SucI)
   547   qed
   548   have Q'_sets: "\<And>i. Q' i \<in> sets M" using Q' by auto
   549   have O_sets: "\<And>i. ?O i \<in> sets M" using Q' by auto
   550   then have O_in_G: "\<And>i. ?O i \<in> ?Q"
   551   proof (safe del: notI)
   552     fix i have "Q' ` {..i} \<subseteq> sets M" using Q' by auto
   553     then have "N (?O i) \<le> (\<Sum>i\<le>i. N (Q' i))"
   554       by (simp add: sets_eq emeasure_subadditive_finite)
   555     also have "\<dots> < \<infinity>" using Q' by (simp add: setsum_Pinfty)
   556     finally show "N (?O i) \<noteq> \<infinity>" by simp
   557   qed auto
   558   have O_mono: "\<And>n. ?O n \<subseteq> ?O (Suc n)" by fastforce
   559   have a_eq: "?a = emeasure M (\<Union>i. ?O i)" unfolding Union[symmetric]
   560   proof (rule antisym)
   561     show "?a \<le> (SUP i. emeasure M (?O i))" unfolding a_Lim
   562       using Q' by (auto intro!: SUP_mono emeasure_mono)
   563     show "(SUP i. emeasure M (?O i)) \<le> ?a"
   564     proof (safe intro!: Sup_mono, unfold bex_simps)
   565       fix i
   566       have *: "(\<Union>(Q' ` {..i})) = ?O i" by auto
   567       then show "\<exists>x. (x \<in> sets M \<and> N x \<noteq> \<infinity>) \<and>
   568         emeasure M (\<Union>(Q' ` {..i})) \<le> emeasure M x"
   569         using O_in_G[of i] by (auto intro!: exI[of _ "?O i"])
   570     qed
   571   qed
   572   let ?O_0 = "(\<Union>i. ?O i)"
   573   have "?O_0 \<in> sets M" using Q' by auto
   574   def Q \<equiv> "\<lambda>i. case i of 0 \<Rightarrow> Q' 0 | Suc n \<Rightarrow> ?O (Suc n) - ?O n"
   575   { fix i have "Q i \<in> sets M" unfolding Q_def using Q'[of 0] by (cases i) (auto intro: O_sets) }
   576   note Q_sets = this
   577   show ?thesis
   578   proof (intro bexI exI conjI ballI impI allI)
   579     show "disjoint_family Q"
   580       by (fastforce simp: disjoint_family_on_def Q_def
   581         split: nat.split_asm)
   582     show "range Q \<subseteq> sets M"
   583       using Q_sets by auto
   584     { fix A assume A: "A \<in> sets M" "A \<subseteq> space M - ?O_0"
   585       show "emeasure M A = 0 \<and> N A = 0 \<or> 0 < emeasure M A \<and> N A = \<infinity>"
   586       proof (rule disjCI, simp)
   587         assume *: "0 < emeasure M A \<longrightarrow> N A \<noteq> \<infinity>"
   588         show "emeasure M A = 0 \<and> N A = 0"
   589         proof (cases "emeasure M A = 0")
   590           case True
   591           with ac A have "N A = 0"
   592             unfolding absolutely_continuous_def by auto
   593           with True show ?thesis by simp
   594         next
   595           case False
   596           with * have "N A \<noteq> \<infinity>" using emeasure_nonneg[of M A] by auto
   597           with A have "emeasure M ?O_0 + emeasure M A = emeasure M (?O_0 \<union> A)"
   598             using Q' by (auto intro!: plus_emeasure sets.countable_UN)
   599           also have "\<dots> = (SUP i. emeasure M (?O i \<union> A))"
   600           proof (rule SUP_emeasure_incseq[of "\<lambda>i. ?O i \<union> A", symmetric, simplified])
   601             show "range (\<lambda>i. ?O i \<union> A) \<subseteq> sets M"
   602               using \<open>N A \<noteq> \<infinity>\<close> O_sets A by auto
   603           qed (fastforce intro!: incseq_SucI)
   604           also have "\<dots> \<le> ?a"
   605           proof (safe intro!: SUP_least)
   606             fix i have "?O i \<union> A \<in> ?Q"
   607             proof (safe del: notI)
   608               show "?O i \<union> A \<in> sets M" using O_sets A by auto
   609               from O_in_G[of i] have "N (?O i \<union> A) \<le> N (?O i) + N A"
   610                 using emeasure_subadditive[of "?O i" N A] A O_sets by (auto simp: sets_eq)
   611               with O_in_G[of i] show "N (?O i \<union> A) \<noteq> \<infinity>"
   612                 using \<open>N A \<noteq> \<infinity>\<close> by auto
   613             qed
   614             then show "emeasure M (?O i \<union> A) \<le> ?a" by (rule SUP_upper)
   615           qed
   616           finally have "emeasure M A = 0"
   617             unfolding a_eq using measure_nonneg[of M A] by (simp add: emeasure_eq_measure)
   618           with \<open>emeasure M A \<noteq> 0\<close> show ?thesis by auto
   619         qed
   620       qed }
   621     { fix i show "N (Q i) \<noteq> \<infinity>"
   622       proof (cases i)
   623         case 0 then show ?thesis
   624           unfolding Q_def using Q'[of 0] by simp
   625       next
   626         case (Suc n)
   627         with \<open>?O n \<in> ?Q\<close> \<open>?O (Suc n) \<in> ?Q\<close>
   628             emeasure_Diff[OF _ _ _ O_mono, of N n] emeasure_nonneg[of N "(\<Union>x\<le>n. Q' x)"]
   629         show ?thesis
   630           by (auto simp: sets_eq ereal_minus_eq_PInfty_iff Q_def)
   631       qed }
   632     show "space M - ?O_0 \<in> sets M" using Q'_sets by auto
   633     { fix j have "(\<Union>i\<le>j. ?O i) = (\<Union>i\<le>j. Q i)"
   634       proof (induct j)
   635         case 0 then show ?case by (simp add: Q_def)
   636       next
   637         case (Suc j)
   638         have eq: "\<And>j. (\<Union>i\<le>j. ?O i) = (\<Union>i\<le>j. Q' i)" by fastforce
   639         have "{..j} \<union> {..Suc j} = {..Suc j}" by auto
   640         then have "(\<Union>i\<le>Suc j. Q' i) = (\<Union>i\<le>j. Q' i) \<union> Q (Suc j)"
   641           by (simp add: UN_Un[symmetric] Q_def del: UN_Un)
   642         then show ?case using Suc by (auto simp add: eq atMost_Suc)
   643       qed }
   644     then have "(\<Union>j. (\<Union>i\<le>j. ?O i)) = (\<Union>j. (\<Union>i\<le>j. Q i))" by simp
   645     then show "space M - ?O_0 = space M - (\<Union>i. Q i)" by fastforce
   646   qed
   647 qed
   648 
   649 lemma (in finite_measure) Radon_Nikodym_finite_measure_infinite:
   650   assumes "absolutely_continuous M N" and sets_eq: "sets N = sets M"
   651   shows "\<exists>f\<in>borel_measurable M. (\<forall>x. 0 \<le> f x) \<and> density M f = N"
   652 proof -
   653   from split_space_into_finite_sets_and_rest[OF assms]
   654   obtain Q0 and Q :: "nat \<Rightarrow> 'a set"
   655     where Q: "disjoint_family Q" "range Q \<subseteq> sets M"
   656     and Q0: "Q0 \<in> sets M" "Q0 = space M - (\<Union>i. Q i)"
   657     and in_Q0: "\<And>A. A \<in> sets M \<Longrightarrow> A \<subseteq> Q0 \<Longrightarrow> emeasure M A = 0 \<and> N A = 0 \<or> 0 < emeasure M A \<and> N A = \<infinity>"
   658     and Q_fin: "\<And>i. N (Q i) \<noteq> \<infinity>" by force
   659   from Q have Q_sets: "\<And>i. Q i \<in> sets M" by auto
   660   let ?N = "\<lambda>i. density N (indicator (Q i))" and ?M = "\<lambda>i. density M (indicator (Q i))"
   661   have "\<forall>i. \<exists>f\<in>borel_measurable (?M i). (\<forall>x. 0 \<le> f x) \<and> density (?M i) f = ?N i"
   662   proof (intro allI finite_measure.Radon_Nikodym_finite_measure)
   663     fix i
   664     from Q show "finite_measure (?M i)"
   665       by (auto intro!: finite_measureI cong: nn_integral_cong
   666                simp add: emeasure_density subset_eq sets_eq)
   667     from Q have "emeasure (?N i) (space N) = emeasure N (Q i)"
   668       by (simp add: sets_eq[symmetric] emeasure_density subset_eq cong: nn_integral_cong)
   669     with Q_fin show "finite_measure (?N i)"
   670       by (auto intro!: finite_measureI)
   671     show "sets (?N i) = sets (?M i)" by (simp add: sets_eq)
   672     have [measurable]: "\<And>A. A \<in> sets M \<Longrightarrow> A \<in> sets N" by (simp add: sets_eq)
   673     show "absolutely_continuous (?M i) (?N i)"
   674       using \<open>absolutely_continuous M N\<close> \<open>Q i \<in> sets M\<close>
   675       by (auto simp: absolutely_continuous_def null_sets_density_iff sets_eq
   676                intro!: absolutely_continuous_AE[OF sets_eq])
   677   qed
   678   from choice[OF this[unfolded Bex_def]]
   679   obtain f where borel: "\<And>i. f i \<in> borel_measurable M" "\<And>i x. 0 \<le> f i x"
   680     and f_density: "\<And>i. density (?M i) (f i) = ?N i"
   681     by force
   682   { fix A i assume A: "A \<in> sets M"
   683     with Q borel have "(\<integral>\<^sup>+x. f i x * indicator (Q i \<inter> A) x \<partial>M) = emeasure (density (?M i) (f i)) A"
   684       by (auto simp add: emeasure_density nn_integral_density subset_eq
   685                intro!: nn_integral_cong split: split_indicator)
   686     also have "\<dots> = emeasure N (Q i \<inter> A)"
   687       using A Q by (simp add: f_density emeasure_restricted subset_eq sets_eq)
   688     finally have "emeasure N (Q i \<inter> A) = (\<integral>\<^sup>+x. f i x * indicator (Q i \<inter> A) x \<partial>M)" .. }
   689   note integral_eq = this
   690   let ?f = "\<lambda>x. (\<Sum>i. f i x * indicator (Q i) x) + \<infinity> * indicator Q0 x"
   691   show ?thesis
   692   proof (safe intro!: bexI[of _ ?f])
   693     show "?f \<in> borel_measurable M" using Q0 borel Q_sets
   694       by (auto intro!: measurable_If)
   695     show "\<And>x. 0 \<le> ?f x" using borel by (auto intro!: suminf_0_le simp: indicator_def)
   696     show "density M ?f = N"
   697     proof (rule measure_eqI)
   698       fix A assume "A \<in> sets (density M ?f)"
   699       then have "A \<in> sets M" by simp
   700       have Qi: "\<And>i. Q i \<in> sets M" using Q by auto
   701       have [intro,simp]: "\<And>i. (\<lambda>x. f i x * indicator (Q i \<inter> A) x) \<in> borel_measurable M"
   702         "\<And>i. AE x in M. 0 \<le> f i x * indicator (Q i \<inter> A) x"
   703         using borel Qi Q0(1) \<open>A \<in> sets M\<close> by (auto intro!: borel_measurable_ereal_times)
   704       have "(\<integral>\<^sup>+x. ?f x * indicator A x \<partial>M) = (\<integral>\<^sup>+x. (\<Sum>i. f i x * indicator (Q i \<inter> A) x) + \<infinity> * indicator (Q0 \<inter> A) x \<partial>M)"
   705         using borel by (intro nn_integral_cong) (auto simp: indicator_def)
   706       also have "\<dots> = (\<integral>\<^sup>+x. (\<Sum>i. f i x * indicator (Q i \<inter> A) x) \<partial>M) + \<infinity> * emeasure M (Q0 \<inter> A)"
   707         using borel Qi Q0(1) \<open>A \<in> sets M\<close>
   708         by (subst nn_integral_add) (auto simp del: ereal_infty_mult
   709             simp add: nn_integral_cmult_indicator sets.Int intro!: suminf_0_le)
   710       also have "\<dots> = (\<Sum>i. N (Q i \<inter> A)) + \<infinity> * emeasure M (Q0 \<inter> A)"
   711         by (subst integral_eq[OF \<open>A \<in> sets M\<close>], subst nn_integral_suminf) auto
   712       finally have "(\<integral>\<^sup>+x. ?f x * indicator A x \<partial>M) = (\<Sum>i. N (Q i \<inter> A)) + \<infinity> * emeasure M (Q0 \<inter> A)" .
   713       moreover have "(\<Sum>i. N (Q i \<inter> A)) = N ((\<Union>i. Q i) \<inter> A)"
   714         using Q Q_sets \<open>A \<in> sets M\<close>
   715         by (subst suminf_emeasure) (auto simp: disjoint_family_on_def sets_eq)
   716       moreover have "\<infinity> * emeasure M (Q0 \<inter> A) = N (Q0 \<inter> A)"
   717       proof -
   718         have "Q0 \<inter> A \<in> sets M" using Q0(1) \<open>A \<in> sets M\<close> by blast
   719         from in_Q0[OF this] show ?thesis by auto
   720       qed
   721       moreover have "Q0 \<inter> A \<in> sets M" "((\<Union>i. Q i) \<inter> A) \<in> sets M"
   722         using Q_sets \<open>A \<in> sets M\<close> Q0(1) by auto
   723       moreover have "((\<Union>i. Q i) \<inter> A) \<union> (Q0 \<inter> A) = A" "((\<Union>i. Q i) \<inter> A) \<inter> (Q0 \<inter> A) = {}"
   724         using \<open>A \<in> sets M\<close> sets.sets_into_space Q0 by auto
   725       ultimately have "N A = (\<integral>\<^sup>+x. ?f x * indicator A x \<partial>M)"
   726         using plus_emeasure[of "(\<Union>i. Q i) \<inter> A" N "Q0 \<inter> A"] by (simp add: sets_eq)
   727       with \<open>A \<in> sets M\<close> borel Q Q0(1) show "emeasure (density M ?f) A = N A"
   728         by (auto simp: subset_eq emeasure_density)
   729     qed (simp add: sets_eq)
   730   qed
   731 qed
   732 
   733 lemma (in sigma_finite_measure) Radon_Nikodym:
   734   assumes ac: "absolutely_continuous M N" assumes sets_eq: "sets N = sets M"
   735   shows "\<exists>f \<in> borel_measurable M. (\<forall>x. 0 \<le> f x) \<and> density M f = N"
   736 proof -
   737   from Ex_finite_integrable_function
   738   obtain h where finite: "integral\<^sup>N M h \<noteq> \<infinity>" and
   739     borel: "h \<in> borel_measurable M" and
   740     nn: "\<And>x. 0 \<le> h x" and
   741     pos: "\<And>x. x \<in> space M \<Longrightarrow> 0 < h x" and
   742     "\<And>x. x \<in> space M \<Longrightarrow> h x < \<infinity>" by auto
   743   let ?T = "\<lambda>A. (\<integral>\<^sup>+x. h x * indicator A x \<partial>M)"
   744   let ?MT = "density M h"
   745   from borel finite nn interpret T: finite_measure ?MT
   746     by (auto intro!: finite_measureI cong: nn_integral_cong simp: emeasure_density)
   747   have "absolutely_continuous ?MT N" "sets N = sets ?MT"
   748   proof (unfold absolutely_continuous_def, safe)
   749     fix A assume "A \<in> null_sets ?MT"
   750     with borel have "A \<in> sets M" "AE x in M. x \<in> A \<longrightarrow> h x \<le> 0"
   751       by (auto simp add: null_sets_density_iff)
   752     with pos sets.sets_into_space have "AE x in M. x \<notin> A"
   753       by (elim eventually_mono) (auto simp: not_le[symmetric])
   754     then have "A \<in> null_sets M"
   755       using \<open>A \<in> sets M\<close> by (simp add: AE_iff_null_sets)
   756     with ac show "A \<in> null_sets N"
   757       by (auto simp: absolutely_continuous_def)
   758   qed (auto simp add: sets_eq)
   759   from T.Radon_Nikodym_finite_measure_infinite[OF this]
   760   obtain f where f_borel: "f \<in> borel_measurable M" "\<And>x. 0 \<le> f x" "density ?MT f = N" by auto
   761   with nn borel show ?thesis
   762     by (auto intro!: bexI[of _ "\<lambda>x. h x * f x"] simp: density_density_eq)
   763 qed
   764 
   765 subsection \<open>Uniqueness of densities\<close>
   766 
   767 lemma finite_density_unique:
   768   assumes borel: "f \<in> borel_measurable M" "g \<in> borel_measurable M"
   769   assumes pos: "AE x in M. 0 \<le> f x" "AE x in M. 0 \<le> g x"
   770   and fin: "integral\<^sup>N M f \<noteq> \<infinity>"
   771   shows "density M f = density M g \<longleftrightarrow> (AE x in M. f x = g x)"
   772 proof (intro iffI ballI)
   773   fix A assume eq: "AE x in M. f x = g x"
   774   with borel show "density M f = density M g"
   775     by (auto intro: density_cong)
   776 next
   777   let ?P = "\<lambda>f A. \<integral>\<^sup>+ x. f x * indicator A x \<partial>M"
   778   assume "density M f = density M g"
   779   with borel have eq: "\<forall>A\<in>sets M. ?P f A = ?P g A"
   780     by (simp add: emeasure_density[symmetric])
   781   from this[THEN bspec, OF sets.top] fin
   782   have g_fin: "integral\<^sup>N M g \<noteq> \<infinity>" by (simp cong: nn_integral_cong)
   783   { fix f g assume borel: "f \<in> borel_measurable M" "g \<in> borel_measurable M"
   784       and pos: "AE x in M. 0 \<le> f x" "AE x in M. 0 \<le> g x"
   785       and g_fin: "integral\<^sup>N M g \<noteq> \<infinity>" and eq: "\<forall>A\<in>sets M. ?P f A = ?P g A"
   786     let ?N = "{x\<in>space M. g x < f x}"
   787     have N: "?N \<in> sets M" using borel by simp
   788     have "?P g ?N \<le> integral\<^sup>N M g" using pos
   789       by (intro nn_integral_mono_AE) (auto split: split_indicator)
   790     then have Pg_fin: "?P g ?N \<noteq> \<infinity>" using g_fin by auto
   791     have "?P (\<lambda>x. (f x - g x)) ?N = (\<integral>\<^sup>+x. f x * indicator ?N x - g x * indicator ?N x \<partial>M)"
   792       by (auto intro!: nn_integral_cong simp: indicator_def)
   793     also have "\<dots> = ?P f ?N - ?P g ?N"
   794     proof (rule nn_integral_diff)
   795       show "(\<lambda>x. f x * indicator ?N x) \<in> borel_measurable M" "(\<lambda>x. g x * indicator ?N x) \<in> borel_measurable M"
   796         using borel N by auto
   797       show "AE x in M. g x * indicator ?N x \<le> f x * indicator ?N x"
   798            "AE x in M. 0 \<le> g x * indicator ?N x"
   799         using pos by (auto split: split_indicator)
   800     qed fact
   801     also have "\<dots> = 0"
   802       unfolding eq[THEN bspec, OF N] using nn_integral_nonneg[of M] Pg_fin by auto
   803     finally have "AE x in M. f x \<le> g x"
   804       using pos borel nn_integral_PInf_AE[OF borel(2) g_fin]
   805       by (subst (asm) nn_integral_0_iff_AE)
   806          (auto split: split_indicator simp: not_less ereal_minus_le_iff) }
   807   from this[OF borel pos g_fin eq] this[OF borel(2,1) pos(2,1) fin] eq
   808   show "AE x in M. f x = g x" by auto
   809 qed
   810 
   811 lemma (in finite_measure) density_unique_finite_measure:
   812   assumes borel: "f \<in> borel_measurable M" "f' \<in> borel_measurable M"
   813   assumes pos: "AE x in M. 0 \<le> f x" "AE x in M. 0 \<le> f' x"
   814   assumes f: "\<And>A. A \<in> sets M \<Longrightarrow> (\<integral>\<^sup>+x. f x * indicator A x \<partial>M) = (\<integral>\<^sup>+x. f' x * indicator A x \<partial>M)"
   815     (is "\<And>A. A \<in> sets M \<Longrightarrow> ?P f A = ?P f' A")
   816   shows "AE x in M. f x = f' x"
   817 proof -
   818   let ?D = "\<lambda>f. density M f"
   819   let ?N = "\<lambda>A. ?P f A" and ?N' = "\<lambda>A. ?P f' A"
   820   let ?f = "\<lambda>A x. f x * indicator A x" and ?f' = "\<lambda>A x. f' x * indicator A x"
   821 
   822   have ac: "absolutely_continuous M (density M f)" "sets (density M f) = sets M"
   823     using borel by (auto intro!: absolutely_continuousI_density)
   824   from split_space_into_finite_sets_and_rest[OF this]
   825   obtain Q0 and Q :: "nat \<Rightarrow> 'a set"
   826     where Q: "disjoint_family Q" "range Q \<subseteq> sets M"
   827     and Q0: "Q0 \<in> sets M" "Q0 = space M - (\<Union>i. Q i)"
   828     and in_Q0: "\<And>A. A \<in> sets M \<Longrightarrow> A \<subseteq> Q0 \<Longrightarrow> emeasure M A = 0 \<and> ?D f A = 0 \<or> 0 < emeasure M A \<and> ?D f A = \<infinity>"
   829     and Q_fin: "\<And>i. ?D f (Q i) \<noteq> \<infinity>" by force
   830   with borel pos have in_Q0: "\<And>A. A \<in> sets M \<Longrightarrow> A \<subseteq> Q0 \<Longrightarrow> emeasure M A = 0 \<and> ?N A = 0 \<or> 0 < emeasure M A \<and> ?N A = \<infinity>"
   831     and Q_fin: "\<And>i. ?N (Q i) \<noteq> \<infinity>" by (auto simp: emeasure_density subset_eq)
   832 
   833   from Q have Q_sets: "\<And>i. Q i \<in> sets M" by auto
   834   let ?D = "{x\<in>space M. f x \<noteq> f' x}"
   835   have "?D \<in> sets M" using borel by auto
   836   have *: "\<And>i x A. \<And>y::ereal. y * indicator (Q i) x * indicator A x = y * indicator (Q i \<inter> A) x"
   837     unfolding indicator_def by auto
   838   have "\<forall>i. AE x in M. ?f (Q i) x = ?f' (Q i) x" using borel Q_fin Q pos
   839     by (intro finite_density_unique[THEN iffD1] allI)
   840        (auto intro!: f measure_eqI simp: emeasure_density * subset_eq)
   841   moreover have "AE x in M. ?f Q0 x = ?f' Q0 x"
   842   proof (rule AE_I')
   843     { fix f :: "'a \<Rightarrow> ereal" assume borel: "f \<in> borel_measurable M"
   844         and eq: "\<And>A. A \<in> sets M \<Longrightarrow> ?N A = (\<integral>\<^sup>+x. f x * indicator A x \<partial>M)"
   845       let ?A = "\<lambda>i. Q0 \<inter> {x \<in> space M. f x < (i::nat)}"
   846       have "(\<Union>i. ?A i) \<in> null_sets M"
   847       proof (rule null_sets_UN)
   848         fix i ::nat have "?A i \<in> sets M"
   849           using borel Q0(1) by auto
   850         have "?N (?A i) \<le> (\<integral>\<^sup>+x. (i::ereal) * indicator (?A i) x \<partial>M)"
   851           unfolding eq[OF \<open>?A i \<in> sets M\<close>]
   852           by (auto intro!: nn_integral_mono simp: indicator_def)
   853         also have "\<dots> = i * emeasure M (?A i)"
   854           using \<open>?A i \<in> sets M\<close> by (auto intro!: nn_integral_cmult_indicator)
   855         also have "\<dots> < \<infinity>" using emeasure_real[of "?A i"] by simp
   856         finally have "?N (?A i) \<noteq> \<infinity>" by simp
   857         then show "?A i \<in> null_sets M" using in_Q0[OF \<open>?A i \<in> sets M\<close>] \<open>?A i \<in> sets M\<close> by auto
   858       qed
   859       also have "(\<Union>i. ?A i) = Q0 \<inter> {x\<in>space M. f x \<noteq> \<infinity>}"
   860         by (auto simp: less_PInf_Ex_of_nat)
   861       finally have "Q0 \<inter> {x\<in>space M. f x \<noteq> \<infinity>} \<in> null_sets M" by simp }
   862     from this[OF borel(1) refl] this[OF borel(2) f]
   863     have "Q0 \<inter> {x\<in>space M. f x \<noteq> \<infinity>} \<in> null_sets M" "Q0 \<inter> {x\<in>space M. f' x \<noteq> \<infinity>} \<in> null_sets M" by simp_all
   864     then show "(Q0 \<inter> {x\<in>space M. f x \<noteq> \<infinity>}) \<union> (Q0 \<inter> {x\<in>space M. f' x \<noteq> \<infinity>}) \<in> null_sets M" by (rule null_sets.Un)
   865     show "{x \<in> space M. ?f Q0 x \<noteq> ?f' Q0 x} \<subseteq>
   866       (Q0 \<inter> {x\<in>space M. f x \<noteq> \<infinity>}) \<union> (Q0 \<inter> {x\<in>space M. f' x \<noteq> \<infinity>})" by (auto simp: indicator_def)
   867   qed
   868   moreover have "AE x in M. (?f Q0 x = ?f' Q0 x) \<longrightarrow> (\<forall>i. ?f (Q i) x = ?f' (Q i) x) \<longrightarrow>
   869     ?f (space M) x = ?f' (space M) x"
   870     by (auto simp: indicator_def Q0)
   871   ultimately have "AE x in M. ?f (space M) x = ?f' (space M) x"
   872     unfolding AE_all_countable[symmetric]
   873     by eventually_elim (auto intro!: AE_I2 split: split_if_asm simp: indicator_def)
   874   then show "AE x in M. f x = f' x" by auto
   875 qed
   876 
   877 lemma (in sigma_finite_measure) density_unique:
   878   assumes f: "f \<in> borel_measurable M" "AE x in M. 0 \<le> f x"
   879   assumes f': "f' \<in> borel_measurable M" "AE x in M. 0 \<le> f' x"
   880   assumes density_eq: "density M f = density M f'"
   881   shows "AE x in M. f x = f' x"
   882 proof -
   883   obtain h where h_borel: "h \<in> borel_measurable M"
   884     and fin: "integral\<^sup>N M h \<noteq> \<infinity>" and pos: "\<And>x. x \<in> space M \<Longrightarrow> 0 < h x \<and> h x < \<infinity>" "\<And>x. 0 \<le> h x"
   885     using Ex_finite_integrable_function by auto
   886   then have h_nn: "AE x in M. 0 \<le> h x" by auto
   887   let ?H = "density M h"
   888   interpret h: finite_measure ?H
   889     using fin h_borel pos
   890     by (intro finite_measureI) (simp cong: nn_integral_cong emeasure_density add: fin)
   891   let ?fM = "density M f"
   892   let ?f'M = "density M f'"
   893   { fix A assume "A \<in> sets M"
   894     then have "{x \<in> space M. h x * indicator A x \<noteq> 0} = A"
   895       using pos(1) sets.sets_into_space by (force simp: indicator_def)
   896     then have "(\<integral>\<^sup>+x. h x * indicator A x \<partial>M) = 0 \<longleftrightarrow> A \<in> null_sets M"
   897       using h_borel \<open>A \<in> sets M\<close> h_nn by (subst nn_integral_0_iff) auto }
   898   note h_null_sets = this
   899   { fix A assume "A \<in> sets M"
   900     have "(\<integral>\<^sup>+x. f x * (h x * indicator A x) \<partial>M) = (\<integral>\<^sup>+x. h x * indicator A x \<partial>?fM)"
   901       using \<open>A \<in> sets M\<close> h_borel h_nn f f'
   902       by (intro nn_integral_density[symmetric]) auto
   903     also have "\<dots> = (\<integral>\<^sup>+x. h x * indicator A x \<partial>?f'M)"
   904       by (simp_all add: density_eq)
   905     also have "\<dots> = (\<integral>\<^sup>+x. f' x * (h x * indicator A x) \<partial>M)"
   906       using \<open>A \<in> sets M\<close> h_borel h_nn f f'
   907       by (intro nn_integral_density) auto
   908     finally have "(\<integral>\<^sup>+x. h x * (f x * indicator A x) \<partial>M) = (\<integral>\<^sup>+x. h x * (f' x * indicator A x) \<partial>M)"
   909       by (simp add: ac_simps)
   910     then have "(\<integral>\<^sup>+x. (f x * indicator A x) \<partial>?H) = (\<integral>\<^sup>+x. (f' x * indicator A x) \<partial>?H)"
   911       using \<open>A \<in> sets M\<close> h_borel h_nn f f'
   912       by (subst (asm) (1 2) nn_integral_density[symmetric]) auto }
   913   then have "AE x in ?H. f x = f' x" using h_borel h_nn f f'
   914     by (intro h.density_unique_finite_measure absolutely_continuous_AE[of M])
   915        (auto simp add: AE_density)
   916   then show "AE x in M. f x = f' x"
   917     unfolding eventually_ae_filter using h_borel pos
   918     by (auto simp add: h_null_sets null_sets_density_iff not_less[symmetric]
   919                           AE_iff_null_sets[symmetric]) blast
   920 qed
   921 
   922 lemma (in sigma_finite_measure) density_unique_iff:
   923   assumes f: "f \<in> borel_measurable M" and "AE x in M. 0 \<le> f x"
   924   assumes f': "f' \<in> borel_measurable M" and "AE x in M. 0 \<le> f' x"
   925   shows "density M f = density M f' \<longleftrightarrow> (AE x in M. f x = f' x)"
   926   using density_unique[OF assms] density_cong[OF f f'] by auto
   927 
   928 lemma sigma_finite_density_unique:
   929   assumes borel: "f \<in> borel_measurable M" "g \<in> borel_measurable M"
   930   assumes pos: "AE x in M. 0 \<le> f x" "AE x in M. 0 \<le> g x"
   931   and fin: "sigma_finite_measure (density M f)"
   932   shows "density M f = density M g \<longleftrightarrow> (AE x in M. f x = g x)"
   933 proof
   934   assume "AE x in M. f x = g x" with borel show "density M f = density M g"
   935     by (auto intro: density_cong)
   936 next
   937   assume eq: "density M f = density M g"
   938   interpret f: sigma_finite_measure "density M f" by fact
   939   from f.sigma_finite_incseq guess A . note cover = this
   940 
   941   have "AE x in M. \<forall>i. x \<in> A i \<longrightarrow> f x = g x"
   942     unfolding AE_all_countable
   943   proof
   944     fix i
   945     have "density (density M f) (indicator (A i)) = density (density M g) (indicator (A i))"
   946       unfolding eq ..
   947     moreover have "(\<integral>\<^sup>+x. f x * indicator (A i) x \<partial>M) \<noteq> \<infinity>"
   948       using cover(1) cover(3)[of i] borel by (auto simp: emeasure_density subset_eq)
   949     ultimately have "AE x in M. f x * indicator (A i) x = g x * indicator (A i) x"
   950       using borel pos cover(1) pos
   951       by (intro finite_density_unique[THEN iffD1])
   952          (auto simp: density_density_eq subset_eq)
   953     then show "AE x in M. x \<in> A i \<longrightarrow> f x = g x"
   954       by auto
   955   qed
   956   with AE_space show "AE x in M. f x = g x"
   957     apply eventually_elim
   958     using cover(2)[symmetric]
   959     apply auto
   960     done
   961 qed
   962 
   963 lemma (in sigma_finite_measure) sigma_finite_iff_density_finite':
   964   assumes f: "f \<in> borel_measurable M" "AE x in M. 0 \<le> f x"
   965   shows "sigma_finite_measure (density M f) \<longleftrightarrow> (AE x in M. f x \<noteq> \<infinity>)"
   966     (is "sigma_finite_measure ?N \<longleftrightarrow> _")
   967 proof
   968   assume "sigma_finite_measure ?N"
   969   then interpret N: sigma_finite_measure ?N .
   970   from N.Ex_finite_integrable_function obtain h where
   971     h: "h \<in> borel_measurable M" "integral\<^sup>N ?N h \<noteq> \<infinity>" and
   972     h_nn: "\<And>x. 0 \<le> h x" and
   973     fin: "\<forall>x\<in>space M. 0 < h x \<and> h x < \<infinity>" by auto
   974   have "AE x in M. f x * h x \<noteq> \<infinity>"
   975   proof (rule AE_I')
   976     have "integral\<^sup>N ?N h = (\<integral>\<^sup>+x. f x * h x \<partial>M)" using f h h_nn
   977       by (auto intro!: nn_integral_density)
   978     then have "(\<integral>\<^sup>+x. f x * h x \<partial>M) \<noteq> \<infinity>"
   979       using h(2) by simp
   980     then show "(\<lambda>x. f x * h x) -` {\<infinity>} \<inter> space M \<in> null_sets M"
   981       using f h(1) by (auto intro!: nn_integral_PInf borel_measurable_vimage)
   982   qed auto
   983   then show "AE x in M. f x \<noteq> \<infinity>"
   984     using fin by (auto elim!: AE_Ball_mp)
   985 next
   986   assume AE: "AE x in M. f x \<noteq> \<infinity>"
   987   from sigma_finite guess Q . note Q = this
   988   def A \<equiv> "\<lambda>i. f -` (case i of 0 \<Rightarrow> {\<infinity>} | Suc n \<Rightarrow> {.. ereal(of_nat (Suc n))}) \<inter> space M"
   989   { fix i j have "A i \<inter> Q j \<in> sets M"
   990     unfolding A_def using f Q
   991     apply (rule_tac sets.Int)
   992     by (cases i) (auto intro: measurable_sets[OF f(1)]) }
   993   note A_in_sets = this
   994 
   995   show "sigma_finite_measure ?N"
   996   proof (standard, intro exI conjI ballI)
   997     show "countable (range (\<lambda>(i, j). A i \<inter> Q j))"
   998       by auto
   999     show "range (\<lambda>(i, j). A i \<inter> Q j) \<subseteq> sets (density M f)"
  1000       using A_in_sets by auto
  1001   next
  1002     have "\<Union>range (\<lambda>(i, j). A i \<inter> Q j) = (\<Union>i j. A i \<inter> Q j)"
  1003       by auto
  1004     also have "\<dots> = (\<Union>i. A i) \<inter> space M" using Q by auto
  1005     also have "(\<Union>i. A i) = space M"
  1006     proof safe
  1007       fix x assume x: "x \<in> space M"
  1008       show "x \<in> (\<Union>i. A i)"
  1009       proof (cases "f x")
  1010         case PInf with x show ?thesis unfolding A_def by (auto intro: exI[of _ 0])
  1011       next
  1012         case (real r)
  1013         with less_PInf_Ex_of_nat[of "f x"] obtain n :: nat where "f x < n" by auto
  1014         then show ?thesis using x real unfolding A_def by (auto intro!: exI[of _ "Suc n"])
  1015       next
  1016         case MInf with x show ?thesis
  1017           unfolding A_def by (auto intro!: exI[of _ "Suc 0"])
  1018       qed
  1019     qed (auto simp: A_def)
  1020     finally show "\<Union>range (\<lambda>(i, j). A i \<inter> Q j) = space ?N" by simp
  1021   next
  1022     fix X assume "X \<in> range (\<lambda>(i, j). A i \<inter> Q j)"
  1023     then obtain i j where [simp]:"X = A i \<inter> Q j" by auto
  1024     have "(\<integral>\<^sup>+x. f x * indicator (A i \<inter> Q j) x \<partial>M) \<noteq> \<infinity>"
  1025     proof (cases i)
  1026       case 0
  1027       have "AE x in M. f x * indicator (A i \<inter> Q j) x = 0"
  1028         using AE by (auto simp: A_def \<open>i = 0\<close>)
  1029       from nn_integral_cong_AE[OF this] show ?thesis by simp
  1030     next
  1031       case (Suc n)
  1032       then have "(\<integral>\<^sup>+x. f x * indicator (A i \<inter> Q j) x \<partial>M) \<le>
  1033         (\<integral>\<^sup>+x. (Suc n :: ereal) * indicator (Q j) x \<partial>M)"
  1034         by (auto intro!: nn_integral_mono simp: indicator_def A_def)
  1035       also have "\<dots> = Suc n * emeasure M (Q j)"
  1036         using Q by (auto intro!: nn_integral_cmult_indicator)
  1037       also have "\<dots> < \<infinity>"
  1038         using Q by auto
  1039       finally show ?thesis by simp
  1040     qed
  1041     then show "emeasure ?N X \<noteq> \<infinity>"
  1042       using A_in_sets Q f by (auto simp: emeasure_density)
  1043   qed
  1044 qed
  1045 
  1046 lemma (in sigma_finite_measure) sigma_finite_iff_density_finite:
  1047   "f \<in> borel_measurable M \<Longrightarrow> sigma_finite_measure (density M f) \<longleftrightarrow> (AE x in M. f x \<noteq> \<infinity>)"
  1048   apply (subst density_max_0)
  1049   apply (subst sigma_finite_iff_density_finite')
  1050   apply (auto simp: max_def intro!: measurable_If)
  1051   done
  1052 
  1053 subsection \<open>Radon-Nikodym derivative\<close>
  1054 
  1055 definition RN_deriv :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> 'a \<Rightarrow> ereal" where
  1056   "RN_deriv M N =
  1057     (if \<exists>f. f \<in> borel_measurable M \<and> (\<forall>x. 0 \<le> f x) \<and> density M f = N
  1058        then SOME f. f \<in> borel_measurable M \<and> (\<forall>x. 0 \<le> f x) \<and> density M f = N
  1059        else (\<lambda>_. 0))"
  1060 
  1061 lemma RN_derivI:
  1062   assumes "f \<in> borel_measurable M" "\<And>x. 0 \<le> f x" "density M f = N"
  1063   shows "density M (RN_deriv M N) = N"
  1064 proof -
  1065   have "\<exists>f. f \<in> borel_measurable M \<and> (\<forall>x. 0 \<le> f x) \<and> density M f = N"
  1066     using assms by auto
  1067   moreover then have "density M (SOME f. f \<in> borel_measurable M \<and> (\<forall>x. 0 \<le> f x) \<and> density M f = N) = N"
  1068     by (rule someI2_ex) auto
  1069   ultimately show ?thesis
  1070     by (auto simp: RN_deriv_def)
  1071 qed
  1072 
  1073 lemma
  1074   shows borel_measurable_RN_deriv[measurable]: "RN_deriv M N \<in> borel_measurable M" (is ?m)
  1075     and RN_deriv_nonneg: "0 \<le> RN_deriv M N x" (is ?nn)
  1076 proof -
  1077   { assume ex: "\<exists>f. f \<in> borel_measurable M \<and> (\<forall>x. 0 \<le> f x) \<and> density M f = N"
  1078     have 1: "(SOME f. f \<in> borel_measurable M \<and> (\<forall>x. 0 \<le> f x) \<and> density M f = N) \<in> borel_measurable M"
  1079       using ex by (rule someI2_ex) auto
  1080     moreover
  1081     have 2: "0 \<le> (SOME f. f \<in> borel_measurable M \<and> (\<forall>x. 0 \<le> f x) \<and> density M f = N) x"
  1082       using ex by (rule someI2_ex) auto
  1083     note 1 2 }
  1084   from this show ?m ?nn
  1085     by (auto simp: RN_deriv_def)
  1086 qed
  1087 
  1088 lemma density_RN_deriv_density:
  1089   assumes f: "f \<in> borel_measurable M" "AE x in M. 0 \<le> f x"
  1090   shows "density M (RN_deriv M (density M f)) = density M f"
  1091 proof (rule RN_derivI)
  1092   show "(\<lambda>x. max 0 (f x)) \<in> borel_measurable M" "\<And>x. 0 \<le> max 0 (f x)"
  1093     using f by auto
  1094   show "density M (\<lambda>x. max 0 (f x)) = density M f"
  1095     using f by (intro density_cong) (auto simp: max_def)
  1096 qed
  1097 
  1098 lemma (in sigma_finite_measure) density_RN_deriv:
  1099   "absolutely_continuous M N \<Longrightarrow> sets N = sets M \<Longrightarrow> density M (RN_deriv M N) = N"
  1100   by (metis RN_derivI Radon_Nikodym)
  1101 
  1102 lemma (in sigma_finite_measure) RN_deriv_nn_integral:
  1103   assumes N: "absolutely_continuous M N" "sets N = sets M"
  1104     and f: "f \<in> borel_measurable M"
  1105   shows "integral\<^sup>N N f = (\<integral>\<^sup>+x. RN_deriv M N x * f x \<partial>M)"
  1106 proof -
  1107   have "integral\<^sup>N N f = integral\<^sup>N (density M (RN_deriv M N)) f"
  1108     using N by (simp add: density_RN_deriv)
  1109   also have "\<dots> = (\<integral>\<^sup>+x. RN_deriv M N x * f x \<partial>M)"
  1110     using f by (simp add: nn_integral_density RN_deriv_nonneg)
  1111   finally show ?thesis by simp
  1112 qed
  1113 
  1114 lemma null_setsD_AE: "N \<in> null_sets M \<Longrightarrow> AE x in M. x \<notin> N"
  1115   using AE_iff_null_sets[of N M] by auto
  1116 
  1117 lemma (in sigma_finite_measure) RN_deriv_unique:
  1118   assumes f: "f \<in> borel_measurable M" "AE x in M. 0 \<le> f x"
  1119   and eq: "density M f = N"
  1120   shows "AE x in M. f x = RN_deriv M N x"
  1121   unfolding eq[symmetric]
  1122   by (intro density_unique_iff[THEN iffD1] f borel_measurable_RN_deriv
  1123             RN_deriv_nonneg[THEN AE_I2] density_RN_deriv_density[symmetric])
  1124 
  1125 lemma RN_deriv_unique_sigma_finite:
  1126   assumes f: "f \<in> borel_measurable M" "AE x in M. 0 \<le> f x"
  1127   and eq: "density M f = N" and fin: "sigma_finite_measure N"
  1128   shows "AE x in M. f x = RN_deriv M N x"
  1129   using fin unfolding eq[symmetric]
  1130   by (intro sigma_finite_density_unique[THEN iffD1] f borel_measurable_RN_deriv
  1131             RN_deriv_nonneg[THEN AE_I2] density_RN_deriv_density[symmetric])
  1132 
  1133 lemma (in sigma_finite_measure) RN_deriv_distr:
  1134   fixes T :: "'a \<Rightarrow> 'b"
  1135   assumes T: "T \<in> measurable M M'" and T': "T' \<in> measurable M' M"
  1136     and inv: "\<forall>x\<in>space M. T' (T x) = x"
  1137   and ac[simp]: "absolutely_continuous (distr M M' T) (distr N M' T)"
  1138   and N: "sets N = sets M"
  1139   shows "AE x in M. RN_deriv (distr M M' T) (distr N M' T) (T x) = RN_deriv M N x"
  1140 proof (rule RN_deriv_unique)
  1141   have [simp]: "sets N = sets M" by fact
  1142   note sets_eq_imp_space_eq[OF N, simp]
  1143   have measurable_N[simp]: "\<And>M'. measurable N M' = measurable M M'" by (auto simp: measurable_def)
  1144   { fix A assume "A \<in> sets M"
  1145     with inv T T' sets.sets_into_space[OF this]
  1146     have "T -` T' -` A \<inter> T -` space M' \<inter> space M = A"
  1147       by (auto simp: measurable_def) }
  1148   note eq = this[simp]
  1149   { fix A assume "A \<in> sets M"
  1150     with inv T T' sets.sets_into_space[OF this]
  1151     have "(T' \<circ> T) -` A \<inter> space M = A"
  1152       by (auto simp: measurable_def) }
  1153   note eq2 = this[simp]
  1154   let ?M' = "distr M M' T" and ?N' = "distr N M' T"
  1155   interpret M': sigma_finite_measure ?M'
  1156   proof
  1157     from sigma_finite_countable guess F .. note F = this
  1158     show "\<exists>A. countable A \<and> A \<subseteq> sets (distr M M' T) \<and> \<Union>A = space (distr M M' T) \<and> (\<forall>a\<in>A. emeasure (distr M M' T) a \<noteq> \<infinity>)"
  1159     proof (intro exI conjI ballI)
  1160       show *: "(\<lambda>A. T' -` A \<inter> space ?M') ` F \<subseteq> sets ?M'"
  1161         using F T' by (auto simp: measurable_def)
  1162       show "\<Union>((\<lambda>A. T' -` A \<inter> space ?M')`F) = space ?M'"
  1163         using F T'[THEN measurable_space] by (auto simp: set_eq_iff)
  1164     next
  1165       fix X assume "X \<in> (\<lambda>A. T' -` A \<inter> space ?M')`F"
  1166       then obtain A where [simp]: "X = T' -` A \<inter> space ?M'" and "A \<in> F" by auto
  1167       have "X \<in> sets M'" using F T' \<open>A\<in>F\<close> by auto
  1168       moreover
  1169       have Fi: "A \<in> sets M" using F \<open>A\<in>F\<close> by auto
  1170       ultimately show "emeasure ?M' X \<noteq> \<infinity>"
  1171         using F T T' \<open>A\<in>F\<close> by (simp add: emeasure_distr)
  1172     qed (insert F, auto)
  1173   qed
  1174   have "(RN_deriv ?M' ?N') \<circ> T \<in> borel_measurable M"
  1175     using T ac by measurable
  1176   then show "(\<lambda>x. RN_deriv ?M' ?N' (T x)) \<in> borel_measurable M"
  1177     by (simp add: comp_def)
  1178   show "AE x in M. 0 \<le> RN_deriv ?M' ?N' (T x)" by (auto intro: RN_deriv_nonneg)
  1179 
  1180   have "N = distr N M (T' \<circ> T)"
  1181     by (subst measure_of_of_measure[of N, symmetric])
  1182        (auto simp add: distr_def sets.sigma_sets_eq intro!: measure_of_eq sets.space_closed)
  1183   also have "\<dots> = distr (distr N M' T) M T'"
  1184     using T T' by (simp add: distr_distr)
  1185   also have "\<dots> = distr (density (distr M M' T) (RN_deriv (distr M M' T) (distr N M' T))) M T'"
  1186     using ac by (simp add: M'.density_RN_deriv)
  1187   also have "\<dots> = density M (RN_deriv (distr M M' T) (distr N M' T) \<circ> T)"
  1188     by (simp add: distr_density_distr[OF T T', OF inv])
  1189   finally show "density M (\<lambda>x. RN_deriv (distr M M' T) (distr N M' T) (T x)) = N"
  1190     by (simp add: comp_def)
  1191 qed
  1192 
  1193 lemma (in sigma_finite_measure) RN_deriv_finite:
  1194   assumes N: "sigma_finite_measure N" and ac: "absolutely_continuous M N" "sets N = sets M"
  1195   shows "AE x in M. RN_deriv M N x \<noteq> \<infinity>"
  1196 proof -
  1197   interpret N: sigma_finite_measure N by fact
  1198   from N show ?thesis
  1199     using sigma_finite_iff_density_finite[OF borel_measurable_RN_deriv, of N]
  1200       density_RN_deriv[OF ac]
  1201     by (simp add: RN_deriv_nonneg)
  1202 qed
  1203 
  1204 lemma (in sigma_finite_measure)
  1205   assumes N: "sigma_finite_measure N" and ac: "absolutely_continuous M N" "sets N = sets M"
  1206     and f: "f \<in> borel_measurable M"
  1207   shows RN_deriv_integrable: "integrable N f \<longleftrightarrow>
  1208       integrable M (\<lambda>x. real_of_ereal (RN_deriv M N x) * f x)" (is ?integrable)
  1209     and RN_deriv_integral: "integral\<^sup>L N f = (\<integral>x. real_of_ereal (RN_deriv M N x) * f x \<partial>M)" (is ?integral)
  1210 proof -
  1211   note ac(2)[simp] and sets_eq_imp_space_eq[OF ac(2), simp]
  1212   interpret N: sigma_finite_measure N by fact
  1213 
  1214   have eq: "density M (RN_deriv M N) = density M (\<lambda>x. real_of_ereal (RN_deriv M N x))"
  1215   proof (rule density_cong)
  1216     from RN_deriv_finite[OF assms(1,2,3)]
  1217     show "AE x in M. RN_deriv M N x = ereal (real_of_ereal (RN_deriv M N x))"
  1218       by eventually_elim (insert RN_deriv_nonneg[of M N], auto simp: ereal_real)
  1219   qed (insert ac, auto)
  1220 
  1221   show ?integrable
  1222     apply (subst density_RN_deriv[OF ac, symmetric])
  1223     unfolding eq
  1224     apply (intro integrable_real_density f AE_I2 real_of_ereal_pos RN_deriv_nonneg)
  1225     apply (insert ac, auto)
  1226     done
  1227 
  1228   show ?integral
  1229     apply (subst density_RN_deriv[OF ac, symmetric])
  1230     unfolding eq
  1231     apply (intro integral_real_density f AE_I2 real_of_ereal_pos RN_deriv_nonneg)
  1232     apply (insert ac, auto)
  1233     done
  1234 qed
  1235 
  1236 lemma (in sigma_finite_measure) real_RN_deriv:
  1237   assumes "finite_measure N"
  1238   assumes ac: "absolutely_continuous M N" "sets N = sets M"
  1239   obtains D where "D \<in> borel_measurable M"
  1240     and "AE x in M. RN_deriv M N x = ereal (D x)"
  1241     and "AE x in N. 0 < D x"
  1242     and "\<And>x. 0 \<le> D x"
  1243 proof
  1244   interpret N: finite_measure N by fact
  1245 
  1246   note RN = borel_measurable_RN_deriv density_RN_deriv[OF ac] RN_deriv_nonneg[of M N]
  1247 
  1248   let ?RN = "\<lambda>t. {x \<in> space M. RN_deriv M N x = t}"
  1249 
  1250   show "(\<lambda>x. real_of_ereal (RN_deriv M N x)) \<in> borel_measurable M"
  1251     using RN by auto
  1252 
  1253   have "N (?RN \<infinity>) = (\<integral>\<^sup>+ x. RN_deriv M N x * indicator (?RN \<infinity>) x \<partial>M)"
  1254     using RN(1,3) by (subst RN(2)[symmetric]) (auto simp: emeasure_density)
  1255   also have "\<dots> = (\<integral>\<^sup>+ x. \<infinity> * indicator (?RN \<infinity>) x \<partial>M)"
  1256     by (intro nn_integral_cong) (auto simp: indicator_def)
  1257   also have "\<dots> = \<infinity> * emeasure M (?RN \<infinity>)"
  1258     using RN by (intro nn_integral_cmult_indicator) auto
  1259   finally have eq: "N (?RN \<infinity>) = \<infinity> * emeasure M (?RN \<infinity>)" .
  1260   moreover
  1261   have "emeasure M (?RN \<infinity>) = 0"
  1262   proof (rule ccontr)
  1263     assume "emeasure M {x \<in> space M. RN_deriv M N x = \<infinity>} \<noteq> 0"
  1264     moreover from RN have "0 \<le> emeasure M {x \<in> space M. RN_deriv M N x = \<infinity>}" by auto
  1265     ultimately have "0 < emeasure M {x \<in> space M. RN_deriv M N x = \<infinity>}" by auto
  1266     with eq have "N (?RN \<infinity>) = \<infinity>" by simp
  1267     with N.emeasure_finite[of "?RN \<infinity>"] RN show False by auto
  1268   qed
  1269   ultimately have "AE x in M. RN_deriv M N x < \<infinity>"
  1270     using RN by (intro AE_iff_measurable[THEN iffD2]) auto
  1271   then show "AE x in M. RN_deriv M N x = ereal (real_of_ereal (RN_deriv M N x))"
  1272     using RN(3) by (auto simp: ereal_real)
  1273   then have eq: "AE x in N. RN_deriv M N x = ereal (real_of_ereal (RN_deriv M N x))"
  1274     using ac absolutely_continuous_AE by auto
  1275 
  1276   show "\<And>x. 0 \<le> real_of_ereal (RN_deriv M N x)"
  1277     using RN by (auto intro: real_of_ereal_pos)
  1278 
  1279   have "N (?RN 0) = (\<integral>\<^sup>+ x. RN_deriv M N x * indicator (?RN 0) x \<partial>M)"
  1280     using RN(1,3) by (subst RN(2)[symmetric]) (auto simp: emeasure_density)
  1281   also have "\<dots> = (\<integral>\<^sup>+ x. 0 \<partial>M)"
  1282     by (intro nn_integral_cong) (auto simp: indicator_def)
  1283   finally have "AE x in N. RN_deriv M N x \<noteq> 0"
  1284     using RN by (subst AE_iff_measurable[OF _ refl]) (auto simp: ac cong: sets_eq_imp_space_eq)
  1285   with RN(3) eq show "AE x in N. 0 < real_of_ereal (RN_deriv M N x)"
  1286     by (auto simp: zero_less_real_of_ereal le_less)
  1287 qed
  1288 
  1289 lemma (in sigma_finite_measure) RN_deriv_singleton:
  1290   assumes ac: "absolutely_continuous M N" "sets N = sets M"
  1291   and x: "{x} \<in> sets M"
  1292   shows "N {x} = RN_deriv M N x * emeasure M {x}"
  1293 proof -
  1294   from \<open>{x} \<in> sets M\<close>
  1295   have "density M (RN_deriv M N) {x} = (\<integral>\<^sup>+w. RN_deriv M N x * indicator {x} w \<partial>M)"
  1296     by (auto simp: indicator_def emeasure_density intro!: nn_integral_cong)
  1297   with x density_RN_deriv[OF ac] RN_deriv_nonneg[of M N] show ?thesis
  1298     by (auto simp: max_def)
  1299 qed
  1300 
  1301 end