src/HOL/Series.thy
author hoelzl
Fri Feb 19 13:40:50 2016 +0100 (2016-02-19)
changeset 62378 85ed00c1fe7c
parent 62377 ace69956d018
child 62379 340738057c8c
permissions -rw-r--r--
generalize more theorems to support enat and ennreal
     1 (*  Title       : Series.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4 
     5 Converted to Isar and polished by lcp
     6 Converted to setsum and polished yet more by TNN
     7 Additional contributions by Jeremy Avigad
     8 *)
     9 
    10 section \<open>Infinite Series\<close>
    11 
    12 theory Series
    13 imports Limits Inequalities
    14 begin
    15 
    16 subsection \<open>Definition of infinite summability\<close>
    17 
    18 definition
    19   sums :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> 'a \<Rightarrow> bool"
    20   (infixr "sums" 80)
    21 where
    22   "f sums s \<longleftrightarrow> (\<lambda>n. \<Sum>i<n. f i) \<longlonglongrightarrow> s"
    23 
    24 definition summable :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> bool" where
    25    "summable f \<longleftrightarrow> (\<exists>s. f sums s)"
    26 
    27 definition
    28   suminf :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> 'a"
    29   (binder "\<Sum>" 10)
    30 where
    31   "suminf f = (THE s. f sums s)"
    32 
    33 lemma sums_def': "f sums s \<longleftrightarrow> (\<lambda>n. \<Sum>i = 0..n. f i) \<longlonglongrightarrow> s"
    34   apply (simp add: sums_def)
    35   apply (subst LIMSEQ_Suc_iff [symmetric])
    36   apply (simp only: lessThan_Suc_atMost atLeast0AtMost)
    37   done
    38 
    39 subsection \<open>Infinite summability on topological monoids\<close>
    40 
    41 lemma sums_subst[trans]: "f = g \<Longrightarrow> g sums z \<Longrightarrow> f sums z"
    42   by simp
    43 
    44 lemma sums_cong: "(\<And>n. f n = g n) \<Longrightarrow> f sums c \<longleftrightarrow> g sums c"
    45   by (drule ext) simp
    46 
    47 lemma sums_summable: "f sums l \<Longrightarrow> summable f"
    48   by (simp add: sums_def summable_def, blast)
    49 
    50 lemma summable_iff_convergent: "summable f \<longleftrightarrow> convergent (\<lambda>n. \<Sum>i<n. f i)"
    51   by (simp add: summable_def sums_def convergent_def)
    52 
    53 lemma summable_iff_convergent':
    54   "summable f \<longleftrightarrow> convergent (\<lambda>n. setsum f {..n})"
    55   by (simp_all only: summable_iff_convergent convergent_def
    56         lessThan_Suc_atMost [symmetric] LIMSEQ_Suc_iff[of "\<lambda>n. setsum f {..<n}"])
    57 
    58 lemma suminf_eq_lim: "suminf f = lim (\<lambda>n. \<Sum>i<n. f i)"
    59   by (simp add: suminf_def sums_def lim_def)
    60 
    61 lemma sums_zero[simp, intro]: "(\<lambda>n. 0) sums 0"
    62   unfolding sums_def by simp
    63 
    64 lemma summable_zero[simp, intro]: "summable (\<lambda>n. 0)"
    65   by (rule sums_zero [THEN sums_summable])
    66 
    67 lemma sums_group: "f sums s \<Longrightarrow> 0 < k \<Longrightarrow> (\<lambda>n. setsum f {n * k ..< n * k + k}) sums s"
    68   apply (simp only: sums_def setsum_nat_group tendsto_def eventually_sequentially)
    69   apply safe
    70   apply (erule_tac x=S in allE)
    71   apply safe
    72   apply (rule_tac x="N" in exI, safe)
    73   apply (drule_tac x="n*k" in spec)
    74   apply (erule mp)
    75   apply (erule order_trans)
    76   apply simp
    77   done
    78 
    79 lemma suminf_cong: "(\<And>n. f n = g n) \<Longrightarrow> suminf f = suminf g"
    80   by (rule arg_cong[of f g], rule ext) simp
    81 
    82 lemma summable_cong:
    83   assumes "eventually (\<lambda>x. f x = (g x :: 'a :: real_normed_vector)) sequentially"
    84   shows   "summable f = summable g"
    85 proof -
    86   from assms obtain N where N: "\<forall>n\<ge>N. f n = g n" by (auto simp: eventually_at_top_linorder)
    87   def C \<equiv> "(\<Sum>k<N. f k - g k)"
    88   from eventually_ge_at_top[of N]
    89     have "eventually (\<lambda>n. setsum f {..<n} = C + setsum g {..<n}) sequentially"
    90   proof eventually_elim
    91     fix n assume n: "n \<ge> N"
    92     from n have "{..<n} = {..<N} \<union> {N..<n}" by auto
    93     also have "setsum f ... = setsum f {..<N} + setsum f {N..<n}"
    94       by (intro setsum.union_disjoint) auto
    95     also from N have "setsum f {N..<n} = setsum g {N..<n}" by (intro setsum.cong) simp_all
    96     also have "setsum f {..<N} + setsum g {N..<n} = C + (setsum g {..<N} + setsum g {N..<n})"
    97       unfolding C_def by (simp add: algebra_simps setsum_subtractf)
    98     also have "setsum g {..<N} + setsum g {N..<n} = setsum g ({..<N} \<union> {N..<n})"
    99       by (intro setsum.union_disjoint [symmetric]) auto
   100     also from n have "{..<N} \<union> {N..<n} = {..<n}" by auto
   101     finally show "setsum f {..<n} = C + setsum g {..<n}" .
   102   qed
   103   from convergent_cong[OF this] show ?thesis
   104     by (simp add: summable_iff_convergent convergent_add_const_iff)
   105 qed
   106 
   107 lemma sums_finite:
   108   assumes [simp]: "finite N" and f: "\<And>n. n \<notin> N \<Longrightarrow> f n = 0"
   109   shows "f sums (\<Sum>n\<in>N. f n)"
   110 proof -
   111   { fix n
   112     have "setsum f {..<n + Suc (Max N)} = setsum f N"
   113     proof cases
   114       assume "N = {}"
   115       with f have "f = (\<lambda>x. 0)" by auto
   116       then show ?thesis by simp
   117     next
   118       assume [simp]: "N \<noteq> {}"
   119       show ?thesis
   120       proof (safe intro!: setsum.mono_neutral_right f)
   121         fix i assume "i \<in> N"
   122         then have "i \<le> Max N" by simp
   123         then show "i < n + Suc (Max N)" by simp
   124       qed
   125     qed }
   126   note eq = this
   127   show ?thesis unfolding sums_def
   128     by (rule LIMSEQ_offset[of _ "Suc (Max N)"])
   129        (simp add: eq atLeast0LessThan del: add_Suc_right)
   130 qed
   131 
   132 corollary sums_0:
   133    "(\<And>n. f n = 0) \<Longrightarrow> (f sums 0)"
   134     by (metis (no_types) finite.emptyI setsum.empty sums_finite)
   135 
   136 lemma summable_finite: "finite N \<Longrightarrow> (\<And>n. n \<notin> N \<Longrightarrow> f n = 0) \<Longrightarrow> summable f"
   137   by (rule sums_summable) (rule sums_finite)
   138 
   139 lemma sums_If_finite_set: "finite A \<Longrightarrow> (\<lambda>r. if r \<in> A then f r else 0) sums (\<Sum>r\<in>A. f r)"
   140   using sums_finite[of A "(\<lambda>r. if r \<in> A then f r else 0)"] by simp
   141 
   142 lemma summable_If_finite_set[simp, intro]: "finite A \<Longrightarrow> summable (\<lambda>r. if r \<in> A then f r else 0)"
   143   by (rule sums_summable) (rule sums_If_finite_set)
   144 
   145 lemma sums_If_finite: "finite {r. P r} \<Longrightarrow> (\<lambda>r. if P r then f r else 0) sums (\<Sum>r | P r. f r)"
   146   using sums_If_finite_set[of "{r. P r}"] by simp
   147 
   148 lemma summable_If_finite[simp, intro]: "finite {r. P r} \<Longrightarrow> summable (\<lambda>r. if P r then f r else 0)"
   149   by (rule sums_summable) (rule sums_If_finite)
   150 
   151 lemma sums_single: "(\<lambda>r. if r = i then f r else 0) sums f i"
   152   using sums_If_finite[of "\<lambda>r. r = i"] by simp
   153 
   154 lemma summable_single[simp, intro]: "summable (\<lambda>r. if r = i then f r else 0)"
   155   by (rule sums_summable) (rule sums_single)
   156 
   157 context
   158   fixes f :: "nat \<Rightarrow> 'a::{t2_space, comm_monoid_add}"
   159 begin
   160 
   161 lemma summable_sums[intro]: "summable f \<Longrightarrow> f sums (suminf f)"
   162   by (simp add: summable_def sums_def suminf_def)
   163      (metis convergent_LIMSEQ_iff convergent_def lim_def)
   164 
   165 lemma summable_LIMSEQ: "summable f \<Longrightarrow> (\<lambda>n. \<Sum>i<n. f i) \<longlonglongrightarrow> suminf f"
   166   by (rule summable_sums [unfolded sums_def])
   167 
   168 lemma sums_unique: "f sums s \<Longrightarrow> s = suminf f"
   169   by (metis limI suminf_eq_lim sums_def)
   170 
   171 lemma sums_iff: "f sums x \<longleftrightarrow> summable f \<and> (suminf f = x)"
   172   by (metis summable_sums sums_summable sums_unique)
   173 
   174 lemma summable_sums_iff:
   175   "summable (f :: nat \<Rightarrow> 'a :: {comm_monoid_add,t2_space}) \<longleftrightarrow> f sums suminf f"
   176   by (auto simp: sums_iff summable_sums)
   177 
   178 lemma sums_unique2:
   179   fixes a b :: "'a::{comm_monoid_add,t2_space}"
   180   shows "f sums a \<Longrightarrow> f sums b \<Longrightarrow> a = b"
   181 by (simp add: sums_iff)
   182 
   183 lemma suminf_finite:
   184   assumes N: "finite N" and f: "\<And>n. n \<notin> N \<Longrightarrow> f n = 0"
   185   shows "suminf f = (\<Sum>n\<in>N. f n)"
   186   using sums_finite[OF assms, THEN sums_unique] by simp
   187 
   188 end
   189 
   190 lemma suminf_zero[simp]: "suminf (\<lambda>n. 0::'a::{t2_space, comm_monoid_add}) = 0"
   191   by (rule sums_zero [THEN sums_unique, symmetric])
   192 
   193 
   194 subsection \<open>Infinite summability on ordered, topological monoids\<close>
   195 
   196 lemma sums_le:
   197   fixes f g :: "nat \<Rightarrow> 'a::{ordered_comm_monoid_add, linorder_topology}"
   198   shows "\<forall>n. f n \<le> g n \<Longrightarrow> f sums s \<Longrightarrow> g sums t \<Longrightarrow> s \<le> t"
   199   by (rule LIMSEQ_le) (auto intro: setsum_mono simp: sums_def)
   200 
   201 context
   202   fixes f :: "nat \<Rightarrow> 'a::{ordered_comm_monoid_add, linorder_topology}"
   203 begin
   204 
   205 lemma suminf_le: "\<lbrakk>\<forall>n. f n \<le> g n; summable f; summable g\<rbrakk> \<Longrightarrow> suminf f \<le> suminf g"
   206   by (auto dest: sums_summable intro: sums_le)
   207 
   208 lemma setsum_le_suminf: "summable f \<Longrightarrow> \<forall>m\<ge>n. 0 \<le> f m \<Longrightarrow> setsum f {..<n} \<le> suminf f"
   209   by (rule sums_le[OF _ sums_If_finite_set summable_sums]) auto
   210 
   211 lemma suminf_nonneg: "summable f \<Longrightarrow> \<forall>n. 0 \<le> f n \<Longrightarrow> 0 \<le> suminf f"
   212   using setsum_le_suminf[of 0] by simp
   213 
   214 lemma suminf_le_const: "summable f \<Longrightarrow> (\<And>n. setsum f {..<n} \<le> x) \<Longrightarrow> suminf f \<le> x"
   215   by (metis LIMSEQ_le_const2 summable_LIMSEQ)
   216 
   217 lemma suminf_eq_zero_iff: "summable f \<Longrightarrow> \<forall>n. 0 \<le> f n \<Longrightarrow> suminf f = 0 \<longleftrightarrow> (\<forall>n. f n = 0)"
   218 proof
   219   assume "summable f" "suminf f = 0" and pos: "\<forall>n. 0 \<le> f n"
   220   then have f: "(\<lambda>n. \<Sum>i<n. f i) \<longlonglongrightarrow> 0"
   221     using summable_LIMSEQ[of f] by simp
   222   then have "\<And>i. (\<Sum>n\<in>{i}. f n) \<le> 0"
   223   proof (rule LIMSEQ_le_const)
   224     fix i show "\<exists>N. \<forall>n\<ge>N. (\<Sum>n\<in>{i}. f n) \<le> setsum f {..<n}"
   225       using pos by (intro exI[of _ "Suc i"] allI impI setsum_mono2) auto
   226   qed
   227   with pos show "\<forall>n. f n = 0"
   228     by (auto intro!: antisym)
   229 qed (metis suminf_zero fun_eq_iff)
   230 
   231 lemma suminf_pos_iff:
   232   "summable f \<Longrightarrow> \<forall>n. 0 \<le> f n \<Longrightarrow> 0 < suminf f \<longleftrightarrow> (\<exists>i. 0 < f i)"
   233   using setsum_le_suminf[of 0] suminf_eq_zero_iff by (simp add: less_le)
   234 
   235 lemma suminf_pos2:
   236   assumes "summable f" "\<forall>n. 0 \<le> f n" "0 < f i"
   237   shows "0 < suminf f"
   238 proof -
   239   have "0 < (\<Sum>n<Suc i. f n)"
   240     using assms by (intro setsum_pos2[where i=i]) auto
   241   also have "\<dots> \<le> suminf f"
   242     using assms by (intro setsum_le_suminf) auto
   243   finally show ?thesis .
   244 qed
   245 
   246 lemma suminf_pos: "summable f \<Longrightarrow> \<forall>n. 0 < f n \<Longrightarrow> 0 < suminf f"
   247   by (intro suminf_pos2[where i=0]) (auto intro: less_imp_le)
   248 
   249 end
   250 
   251 context
   252   fixes f :: "nat \<Rightarrow> 'a::{ordered_cancel_comm_monoid_add, linorder_topology}"
   253 begin
   254 
   255 lemma setsum_less_suminf2: "summable f \<Longrightarrow> \<forall>m\<ge>n. 0 \<le> f m \<Longrightarrow> n \<le> i \<Longrightarrow> 0 < f i \<Longrightarrow> setsum f {..<n} < suminf f"
   256   using
   257     setsum_le_suminf[of f "Suc i"]
   258     add_strict_increasing[of "f i" "setsum f {..<n}" "setsum f {..<i}"]
   259     setsum_mono2[of "{..<i}" "{..<n}" f]
   260   by (auto simp: less_imp_le ac_simps)
   261 
   262 lemma setsum_less_suminf: "summable f \<Longrightarrow> \<forall>m\<ge>n. 0 < f m \<Longrightarrow> setsum f {..<n} < suminf f"
   263   using setsum_less_suminf2[of n n] by (simp add: less_imp_le)
   264 
   265 end
   266 
   267 lemma summableI_nonneg_bounded:
   268   fixes f:: "nat \<Rightarrow> 'a::{ordered_comm_monoid_add, linorder_topology, conditionally_complete_linorder}"
   269   assumes pos[simp]: "\<And>n. 0 \<le> f n" and le: "\<And>n. (\<Sum>i<n. f i) \<le> x"
   270   shows "summable f"
   271   unfolding summable_def sums_def[abs_def]
   272 proof (rule exI LIMSEQ_incseq_SUP)+
   273   show "bdd_above (range (\<lambda>n. setsum f {..<n}))"
   274     using le by (auto simp: bdd_above_def)
   275   show "incseq (\<lambda>n. setsum f {..<n})"
   276     by (auto simp: mono_def intro!: setsum_mono2)
   277 qed
   278 
   279 lemma summableI[intro, simp]:
   280   fixes f:: "nat \<Rightarrow> 'a::{canonically_ordered_monoid_add, linorder_topology, complete_linorder}"
   281   shows "summable f"
   282   by (intro summableI_nonneg_bounded[where x=top] zero_le top_greatest)
   283 
   284 subsection \<open>Infinite summability on topological monoids\<close>
   285 
   286 lemma Zero_notin_Suc: "0 \<notin> Suc ` A"
   287   by auto
   288 
   289 context
   290   fixes f g :: "nat \<Rightarrow> 'a :: {t2_space, topological_comm_monoid_add}"
   291 begin
   292 
   293 lemma sums_Suc:
   294   assumes "(\<lambda>n. f (Suc n)) sums l" shows "f sums (l + f 0)"
   295 proof  -
   296   have "(\<lambda>n. (\<Sum>i<n. f (Suc i)) + f 0) \<longlonglongrightarrow> l + f 0"
   297     using assms by (auto intro!: tendsto_add simp: sums_def)
   298   moreover have "(\<Sum>i<n. f (Suc i)) + f 0 = (\<Sum>i<Suc n. f i)" for n
   299     unfolding lessThan_Suc_eq_insert_0 by (simp add: Zero_notin_Suc ac_simps setsum.reindex)
   300   ultimately show ?thesis
   301     by (auto simp add: sums_def simp del: setsum_lessThan_Suc intro: LIMSEQ_Suc_iff[THEN iffD1])
   302 qed
   303 
   304 lemma sums_add: "f sums a \<Longrightarrow> g sums b \<Longrightarrow> (\<lambda>n. f n + g n) sums (a + b)"
   305   unfolding sums_def by (simp add: setsum.distrib tendsto_add)
   306 
   307 lemma summable_add: "summable f \<Longrightarrow> summable g \<Longrightarrow> summable (\<lambda>n. f n + g n)"
   308   unfolding summable_def by (auto intro: sums_add)
   309 
   310 lemma suminf_add: "summable f \<Longrightarrow> summable g \<Longrightarrow> suminf f + suminf g = (\<Sum>n. f n + g n)"
   311   by (intro sums_unique sums_add summable_sums)
   312 
   313 end
   314 
   315 context
   316   fixes f :: "'i \<Rightarrow> nat \<Rightarrow> 'a::{t2_space, topological_comm_monoid_add}" and I :: "'i set"
   317 begin
   318 
   319 lemma sums_setsum: "(\<And>i. i \<in> I \<Longrightarrow> (f i) sums (x i)) \<Longrightarrow> (\<lambda>n. \<Sum>i\<in>I. f i n) sums (\<Sum>i\<in>I. x i)"
   320   by (induct I rule: infinite_finite_induct) (auto intro!: sums_add)
   321 
   322 lemma suminf_setsum: "(\<And>i. i \<in> I \<Longrightarrow> summable (f i)) \<Longrightarrow> (\<Sum>n. \<Sum>i\<in>I. f i n) = (\<Sum>i\<in>I. \<Sum>n. f i n)"
   323   using sums_unique[OF sums_setsum, OF summable_sums] by simp
   324 
   325 lemma summable_setsum: "(\<And>i. i \<in> I \<Longrightarrow> summable (f i)) \<Longrightarrow> summable (\<lambda>n. \<Sum>i\<in>I. f i n)"
   326   using sums_summable[OF sums_setsum[OF summable_sums]] .
   327 
   328 end
   329 
   330 subsection \<open>Infinite summability on real normed vector spaces\<close>
   331 
   332 context
   333   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   334 begin
   335 
   336 lemma sums_Suc_iff: "(\<lambda>n. f (Suc n)) sums s \<longleftrightarrow> f sums (s + f 0)"
   337 proof -
   338   have "f sums (s + f 0) \<longleftrightarrow> (\<lambda>i. \<Sum>j<Suc i. f j) \<longlonglongrightarrow> s + f 0"
   339     by (subst LIMSEQ_Suc_iff) (simp add: sums_def)
   340   also have "\<dots> \<longleftrightarrow> (\<lambda>i. (\<Sum>j<i. f (Suc j)) + f 0) \<longlonglongrightarrow> s + f 0"
   341     by (simp add: ac_simps setsum.reindex image_iff lessThan_Suc_eq_insert_0)
   342   also have "\<dots> \<longleftrightarrow> (\<lambda>n. f (Suc n)) sums s"
   343   proof
   344     assume "(\<lambda>i. (\<Sum>j<i. f (Suc j)) + f 0) \<longlonglongrightarrow> s + f 0"
   345     with tendsto_add[OF this tendsto_const, of "- f 0"]
   346     show "(\<lambda>i. f (Suc i)) sums s"
   347       by (simp add: sums_def)
   348   qed (auto intro: tendsto_add simp: sums_def)
   349   finally show ?thesis ..
   350 qed
   351 
   352 lemma summable_Suc_iff: "summable (\<lambda>n. f (Suc n)) = summable f"
   353 proof
   354   assume "summable f"
   355   hence "f sums suminf f" by (rule summable_sums)
   356   hence "(\<lambda>n. f (Suc n)) sums (suminf f - f 0)" by (simp add: sums_Suc_iff)
   357   thus "summable (\<lambda>n. f (Suc n))" unfolding summable_def by blast
   358 qed (auto simp: sums_Suc_iff summable_def)
   359 
   360 end
   361 
   362 context
   363   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   364 begin
   365 
   366 lemma sums_diff: "f sums a \<Longrightarrow> g sums b \<Longrightarrow> (\<lambda>n. f n - g n) sums (a - b)"
   367   unfolding sums_def by (simp add: setsum_subtractf tendsto_diff)
   368 
   369 lemma summable_diff: "summable f \<Longrightarrow> summable g \<Longrightarrow> summable (\<lambda>n. f n - g n)"
   370   unfolding summable_def by (auto intro: sums_diff)
   371 
   372 lemma suminf_diff: "summable f \<Longrightarrow> summable g \<Longrightarrow> suminf f - suminf g = (\<Sum>n. f n - g n)"
   373   by (intro sums_unique sums_diff summable_sums)
   374 
   375 lemma sums_minus: "f sums a \<Longrightarrow> (\<lambda>n. - f n) sums (- a)"
   376   unfolding sums_def by (simp add: setsum_negf tendsto_minus)
   377 
   378 lemma summable_minus: "summable f \<Longrightarrow> summable (\<lambda>n. - f n)"
   379   unfolding summable_def by (auto intro: sums_minus)
   380 
   381 lemma suminf_minus: "summable f \<Longrightarrow> (\<Sum>n. - f n) = - (\<Sum>n. f n)"
   382   by (intro sums_unique [symmetric] sums_minus summable_sums)
   383 
   384 lemma sums_iff_shift: "(\<lambda>i. f (i + n)) sums s \<longleftrightarrow> f sums (s + (\<Sum>i<n. f i))"
   385 proof (induct n arbitrary: s)
   386   case (Suc n)
   387   moreover have "(\<lambda>i. f (Suc i + n)) sums s \<longleftrightarrow> (\<lambda>i. f (i + n)) sums (s + f n)"
   388     by (subst sums_Suc_iff) simp
   389   ultimately show ?case
   390     by (simp add: ac_simps)
   391 qed simp
   392 
   393 lemma summable_iff_shift: "summable (\<lambda>n. f (n + k)) \<longleftrightarrow> summable f"
   394   by (metis diff_add_cancel summable_def sums_iff_shift[abs_def])
   395 
   396 lemma sums_split_initial_segment: "f sums s \<Longrightarrow> (\<lambda>i. f (i + n)) sums (s - (\<Sum>i<n. f i))"
   397   by (simp add: sums_iff_shift)
   398 
   399 lemma summable_ignore_initial_segment: "summable f \<Longrightarrow> summable (\<lambda>n. f(n + k))"
   400   by (simp add: summable_iff_shift)
   401 
   402 lemma suminf_minus_initial_segment: "summable f \<Longrightarrow> (\<Sum>n. f (n + k)) = (\<Sum>n. f n) - (\<Sum>i<k. f i)"
   403   by (rule sums_unique[symmetric]) (auto simp: sums_iff_shift)
   404 
   405 lemma suminf_split_initial_segment: "summable f \<Longrightarrow> suminf f = (\<Sum>n. f(n + k)) + (\<Sum>i<k. f i)"
   406   by (auto simp add: suminf_minus_initial_segment)
   407 
   408 lemma suminf_split_head: "summable f \<Longrightarrow> (\<Sum>n. f (Suc n)) = suminf f - f 0"
   409   using suminf_split_initial_segment[of 1] by simp
   410 
   411 lemma suminf_exist_split:
   412   fixes r :: real assumes "0 < r" and "summable f"
   413   shows "\<exists>N. \<forall>n\<ge>N. norm (\<Sum>i. f (i + n)) < r"
   414 proof -
   415   from LIMSEQ_D[OF summable_LIMSEQ[OF \<open>summable f\<close>] \<open>0 < r\<close>]
   416   obtain N :: nat where "\<forall> n \<ge> N. norm (setsum f {..<n} - suminf f) < r" by auto
   417   thus ?thesis
   418     by (auto simp: norm_minus_commute suminf_minus_initial_segment[OF \<open>summable f\<close>])
   419 qed
   420 
   421 lemma summable_LIMSEQ_zero: "summable f \<Longrightarrow> f \<longlonglongrightarrow> 0"
   422   apply (drule summable_iff_convergent [THEN iffD1])
   423   apply (drule convergent_Cauchy)
   424   apply (simp only: Cauchy_iff LIMSEQ_iff, safe)
   425   apply (drule_tac x="r" in spec, safe)
   426   apply (rule_tac x="M" in exI, safe)
   427   apply (drule_tac x="Suc n" in spec, simp)
   428   apply (drule_tac x="n" in spec, simp)
   429   done
   430 
   431 lemma summable_imp_convergent: "summable f \<Longrightarrow> convergent f"
   432   by (force dest!: summable_LIMSEQ_zero simp: convergent_def)
   433 
   434 lemma summable_imp_Bseq: "summable f \<Longrightarrow> Bseq f"
   435   by (simp add: convergent_imp_Bseq summable_imp_convergent)
   436 
   437 end
   438 
   439 lemma summable_minus_iff:
   440   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   441   shows "summable (\<lambda>n. - f n) \<longleftrightarrow> summable f"
   442   by (auto dest: summable_minus) \<comment>\<open>used two ways, hence must be outside the context above\<close>
   443 
   444 lemma (in bounded_linear) sums: "(\<lambda>n. X n) sums a \<Longrightarrow> (\<lambda>n. f (X n)) sums (f a)"
   445   unfolding sums_def by (drule tendsto, simp only: setsum)
   446 
   447 lemma (in bounded_linear) summable: "summable (\<lambda>n. X n) \<Longrightarrow> summable (\<lambda>n. f (X n))"
   448   unfolding summable_def by (auto intro: sums)
   449 
   450 lemma (in bounded_linear) suminf: "summable (\<lambda>n. X n) \<Longrightarrow> f (\<Sum>n. X n) = (\<Sum>n. f (X n))"
   451   by (intro sums_unique sums summable_sums)
   452 
   453 lemmas sums_of_real = bounded_linear.sums [OF bounded_linear_of_real]
   454 lemmas summable_of_real = bounded_linear.summable [OF bounded_linear_of_real]
   455 lemmas suminf_of_real = bounded_linear.suminf [OF bounded_linear_of_real]
   456 
   457 lemmas sums_scaleR_left = bounded_linear.sums[OF bounded_linear_scaleR_left]
   458 lemmas summable_scaleR_left = bounded_linear.summable[OF bounded_linear_scaleR_left]
   459 lemmas suminf_scaleR_left = bounded_linear.suminf[OF bounded_linear_scaleR_left]
   460 
   461 lemmas sums_scaleR_right = bounded_linear.sums[OF bounded_linear_scaleR_right]
   462 lemmas summable_scaleR_right = bounded_linear.summable[OF bounded_linear_scaleR_right]
   463 lemmas suminf_scaleR_right = bounded_linear.suminf[OF bounded_linear_scaleR_right]
   464 
   465 lemma summable_const_iff: "summable (\<lambda>_. c) \<longleftrightarrow> (c :: 'a :: real_normed_vector) = 0"
   466 proof -
   467   {
   468     assume "c \<noteq> 0"
   469     hence "filterlim (\<lambda>n. of_nat n * norm c) at_top sequentially"
   470       by (subst mult.commute)
   471          (auto intro!: filterlim_tendsto_pos_mult_at_top filterlim_real_sequentially)
   472     hence "\<not>convergent (\<lambda>n. norm (\<Sum>k<n. c))"
   473       by (intro filterlim_at_infinity_imp_not_convergent filterlim_at_top_imp_at_infinity)
   474          (simp_all add: setsum_constant_scaleR)
   475     hence "\<not>summable (\<lambda>_. c)" unfolding summable_iff_convergent using convergent_norm by blast
   476   }
   477   thus ?thesis by auto
   478 qed
   479 
   480 
   481 subsection \<open>Infinite summability on real normed algebras\<close>
   482 
   483 context
   484   fixes f :: "nat \<Rightarrow> 'a::real_normed_algebra"
   485 begin
   486 
   487 lemma sums_mult: "f sums a \<Longrightarrow> (\<lambda>n. c * f n) sums (c * a)"
   488   by (rule bounded_linear.sums [OF bounded_linear_mult_right])
   489 
   490 lemma summable_mult: "summable f \<Longrightarrow> summable (\<lambda>n. c * f n)"
   491   by (rule bounded_linear.summable [OF bounded_linear_mult_right])
   492 
   493 lemma suminf_mult: "summable f \<Longrightarrow> suminf (\<lambda>n. c * f n) = c * suminf f"
   494   by (rule bounded_linear.suminf [OF bounded_linear_mult_right, symmetric])
   495 
   496 lemma sums_mult2: "f sums a \<Longrightarrow> (\<lambda>n. f n * c) sums (a * c)"
   497   by (rule bounded_linear.sums [OF bounded_linear_mult_left])
   498 
   499 lemma summable_mult2: "summable f \<Longrightarrow> summable (\<lambda>n. f n * c)"
   500   by (rule bounded_linear.summable [OF bounded_linear_mult_left])
   501 
   502 lemma suminf_mult2: "summable f \<Longrightarrow> suminf f * c = (\<Sum>n. f n * c)"
   503   by (rule bounded_linear.suminf [OF bounded_linear_mult_left])
   504 
   505 end
   506 
   507 lemma sums_mult_iff:
   508   assumes "c \<noteq> 0"
   509   shows   "(\<lambda>n. c * f n :: 'a :: {real_normed_algebra,field}) sums (c * d) \<longleftrightarrow> f sums d"
   510   using sums_mult[of f d c] sums_mult[of "\<lambda>n. c * f n" "c * d" "inverse c"]
   511   by (force simp: field_simps assms)
   512 
   513 lemma sums_mult2_iff:
   514   assumes "c \<noteq> (0 :: 'a :: {real_normed_algebra, field})"
   515   shows   "(\<lambda>n. f n * c) sums (d * c) \<longleftrightarrow> f sums d"
   516   using sums_mult_iff[OF assms, of f d] by (simp add: mult.commute)
   517 
   518 lemma sums_of_real_iff:
   519   "(\<lambda>n. of_real (f n) :: 'a :: real_normed_div_algebra) sums of_real c \<longleftrightarrow> f sums c"
   520   by (simp add: sums_def of_real_setsum[symmetric] tendsto_of_real_iff del: of_real_setsum)
   521 
   522 
   523 subsection \<open>Infinite summability on real normed fields\<close>
   524 
   525 context
   526   fixes c :: "'a::real_normed_field"
   527 begin
   528 
   529 lemma sums_divide: "f sums a \<Longrightarrow> (\<lambda>n. f n / c) sums (a / c)"
   530   by (rule bounded_linear.sums [OF bounded_linear_divide])
   531 
   532 lemma summable_divide: "summable f \<Longrightarrow> summable (\<lambda>n. f n / c)"
   533   by (rule bounded_linear.summable [OF bounded_linear_divide])
   534 
   535 lemma suminf_divide: "summable f \<Longrightarrow> suminf (\<lambda>n. f n / c) = suminf f / c"
   536   by (rule bounded_linear.suminf [OF bounded_linear_divide, symmetric])
   537 
   538 text\<open>Sum of a geometric progression.\<close>
   539 
   540 lemma geometric_sums: "norm c < 1 \<Longrightarrow> (\<lambda>n. c^n) sums (1 / (1 - c))"
   541 proof -
   542   assume less_1: "norm c < 1"
   543   hence neq_1: "c \<noteq> 1" by auto
   544   hence neq_0: "c - 1 \<noteq> 0" by simp
   545   from less_1 have lim_0: "(\<lambda>n. c^n) \<longlonglongrightarrow> 0"
   546     by (rule LIMSEQ_power_zero)
   547   hence "(\<lambda>n. c ^ n / (c - 1) - 1 / (c - 1)) \<longlonglongrightarrow> 0 / (c - 1) - 1 / (c - 1)"
   548     using neq_0 by (intro tendsto_intros)
   549   hence "(\<lambda>n. (c ^ n - 1) / (c - 1)) \<longlonglongrightarrow> 1 / (1 - c)"
   550     by (simp add: nonzero_minus_divide_right [OF neq_0] diff_divide_distrib)
   551   thus "(\<lambda>n. c ^ n) sums (1 / (1 - c))"
   552     by (simp add: sums_def geometric_sum neq_1)
   553 qed
   554 
   555 lemma summable_geometric: "norm c < 1 \<Longrightarrow> summable (\<lambda>n. c^n)"
   556   by (rule geometric_sums [THEN sums_summable])
   557 
   558 lemma suminf_geometric: "norm c < 1 \<Longrightarrow> suminf (\<lambda>n. c^n) = 1 / (1 - c)"
   559   by (rule sums_unique[symmetric]) (rule geometric_sums)
   560 
   561 lemma summable_geometric_iff: "summable (\<lambda>n. c ^ n) \<longleftrightarrow> norm c < 1"
   562 proof
   563   assume "summable (\<lambda>n. c ^ n :: 'a :: real_normed_field)"
   564   hence "(\<lambda>n. norm c ^ n) \<longlonglongrightarrow> 0"
   565     by (simp add: norm_power [symmetric] tendsto_norm_zero_iff summable_LIMSEQ_zero)
   566   from order_tendstoD(2)[OF this zero_less_one] obtain n where "norm c ^ n < 1"
   567     by (auto simp: eventually_at_top_linorder)
   568   thus "norm c < 1" using one_le_power[of "norm c" n] by (cases "norm c \<ge> 1") (linarith, simp)
   569 qed (rule summable_geometric)
   570 
   571 end
   572 
   573 lemma power_half_series: "(\<lambda>n. (1/2::real)^Suc n) sums 1"
   574 proof -
   575   have 2: "(\<lambda>n. (1/2::real)^n) sums 2" using geometric_sums [of "1/2::real"]
   576     by auto
   577   have "(\<lambda>n. (1/2::real)^Suc n) = (\<lambda>n. (1 / 2) ^ n / 2)"
   578     by (simp add: mult.commute)
   579   thus ?thesis using sums_divide [OF 2, of 2]
   580     by simp
   581 qed
   582 
   583 
   584 subsection \<open>Telescoping\<close>
   585 
   586 lemma telescope_sums:
   587   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   588   shows   "(\<lambda>n. f (Suc n) - f n) sums (c - f 0)"
   589   unfolding sums_def
   590 proof (subst LIMSEQ_Suc_iff [symmetric])
   591   have "(\<lambda>n. \<Sum>k<Suc n. f (Suc k) - f k) = (\<lambda>n. f (Suc n) - f 0)"
   592     by (simp add: lessThan_Suc_atMost atLeast0AtMost [symmetric] setsum_Suc_diff)
   593   also have "\<dots> \<longlonglongrightarrow> c - f 0" by (intro tendsto_diff LIMSEQ_Suc[OF assms] tendsto_const)
   594   finally show "(\<lambda>n. \<Sum>n<Suc n. f (Suc n) - f n) \<longlonglongrightarrow> c - f 0" .
   595 qed
   596 
   597 lemma telescope_sums':
   598   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   599   shows   "(\<lambda>n. f n - f (Suc n)) sums (f 0 - c)"
   600   using sums_minus[OF telescope_sums[OF assms]] by (simp add: algebra_simps)
   601 
   602 lemma telescope_summable:
   603   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   604   shows   "summable (\<lambda>n. f (Suc n) - f n)"
   605   using telescope_sums[OF assms] by (simp add: sums_iff)
   606 
   607 lemma telescope_summable':
   608   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   609   shows   "summable (\<lambda>n. f n - f (Suc n))"
   610   using summable_minus[OF telescope_summable[OF assms]] by (simp add: algebra_simps)
   611 
   612 
   613 subsection \<open>Infinite summability on Banach spaces\<close>
   614 
   615 text\<open>Cauchy-type criterion for convergence of series (c.f. Harrison)\<close>
   616 
   617 lemma summable_Cauchy:
   618   fixes f :: "nat \<Rightarrow> 'a::banach"
   619   shows "summable f \<longleftrightarrow> (\<forall>e>0. \<exists>N. \<forall>m\<ge>N. \<forall>n. norm (setsum f {m..<n}) < e)"
   620   apply (simp only: summable_iff_convergent Cauchy_convergent_iff [symmetric] Cauchy_iff, safe)
   621   apply (drule spec, drule (1) mp)
   622   apply (erule exE, rule_tac x="M" in exI, clarify)
   623   apply (rule_tac x="m" and y="n" in linorder_le_cases)
   624   apply (frule (1) order_trans)
   625   apply (drule_tac x="n" in spec, drule (1) mp)
   626   apply (drule_tac x="m" in spec, drule (1) mp)
   627   apply (simp_all add: setsum_diff [symmetric])
   628   apply (drule spec, drule (1) mp)
   629   apply (erule exE, rule_tac x="N" in exI, clarify)
   630   apply (rule_tac x="m" and y="n" in linorder_le_cases)
   631   apply (subst norm_minus_commute)
   632   apply (simp_all add: setsum_diff [symmetric])
   633   done
   634 
   635 context
   636   fixes f :: "nat \<Rightarrow> 'a::banach"
   637 begin
   638 
   639 text\<open>Absolute convergence imples normal convergence\<close>
   640 
   641 lemma summable_norm_cancel: "summable (\<lambda>n. norm (f n)) \<Longrightarrow> summable f"
   642   apply (simp only: summable_Cauchy, safe)
   643   apply (drule_tac x="e" in spec, safe)
   644   apply (rule_tac x="N" in exI, safe)
   645   apply (drule_tac x="m" in spec, safe)
   646   apply (rule order_le_less_trans [OF norm_setsum])
   647   apply (rule order_le_less_trans [OF abs_ge_self])
   648   apply simp
   649   done
   650 
   651 lemma summable_norm: "summable (\<lambda>n. norm (f n)) \<Longrightarrow> norm (suminf f) \<le> (\<Sum>n. norm (f n))"
   652   by (auto intro: LIMSEQ_le tendsto_norm summable_norm_cancel summable_LIMSEQ norm_setsum)
   653 
   654 text \<open>Comparison tests\<close>
   655 
   656 lemma summable_comparison_test: "\<exists>N. \<forall>n\<ge>N. norm (f n) \<le> g n \<Longrightarrow> summable g \<Longrightarrow> summable f"
   657   apply (simp add: summable_Cauchy, safe)
   658   apply (drule_tac x="e" in spec, safe)
   659   apply (rule_tac x = "N + Na" in exI, safe)
   660   apply (rotate_tac 2)
   661   apply (drule_tac x = m in spec)
   662   apply (auto, rotate_tac 2, drule_tac x = n in spec)
   663   apply (rule_tac y = "\<Sum>k=m..<n. norm (f k)" in order_le_less_trans)
   664   apply (rule norm_setsum)
   665   apply (rule_tac y = "setsum g {m..<n}" in order_le_less_trans)
   666   apply (auto intro: setsum_mono simp add: abs_less_iff)
   667   done
   668 
   669 lemma summable_comparison_test_ev:
   670   shows "eventually (\<lambda>n. norm (f n) \<le> g n) sequentially \<Longrightarrow> summable g \<Longrightarrow> summable f"
   671   by (rule summable_comparison_test) (auto simp: eventually_at_top_linorder)
   672 
   673 (*A better argument order*)
   674 lemma summable_comparison_test': "summable g \<Longrightarrow> (\<And>n. n \<ge> N \<Longrightarrow> norm(f n) \<le> g n) \<Longrightarrow> summable f"
   675   by (rule summable_comparison_test) auto
   676 
   677 subsection \<open>The Ratio Test\<close>
   678 
   679 lemma summable_ratio_test:
   680   assumes "c < 1" "\<And>n. n \<ge> N \<Longrightarrow> norm (f (Suc n)) \<le> c * norm (f n)"
   681   shows "summable f"
   682 proof cases
   683   assume "0 < c"
   684   show "summable f"
   685   proof (rule summable_comparison_test)
   686     show "\<exists>N'. \<forall>n\<ge>N'. norm (f n) \<le> (norm (f N) / (c ^ N)) * c ^ n"
   687     proof (intro exI allI impI)
   688       fix n assume "N \<le> n" then show "norm (f n) \<le> (norm (f N) / (c ^ N)) * c ^ n"
   689       proof (induct rule: inc_induct)
   690         case (step m)
   691         moreover have "norm (f (Suc m)) / c ^ Suc m * c ^ n \<le> norm (f m) / c ^ m * c ^ n"
   692           using \<open>0 < c\<close> \<open>c < 1\<close> assms(2)[OF \<open>N \<le> m\<close>] by (simp add: field_simps)
   693         ultimately show ?case by simp
   694       qed (insert \<open>0 < c\<close>, simp)
   695     qed
   696     show "summable (\<lambda>n. norm (f N) / c ^ N * c ^ n)"
   697       using \<open>0 < c\<close> \<open>c < 1\<close> by (intro summable_mult summable_geometric) simp
   698   qed
   699 next
   700   assume c: "\<not> 0 < c"
   701   { fix n assume "n \<ge> N"
   702     then have "norm (f (Suc n)) \<le> c * norm (f n)"
   703       by fact
   704     also have "\<dots> \<le> 0"
   705       using c by (simp add: not_less mult_nonpos_nonneg)
   706     finally have "f (Suc n) = 0"
   707       by auto }
   708   then show "summable f"
   709     by (intro sums_summable[OF sums_finite, of "{.. Suc N}"]) (auto simp: not_le Suc_less_eq2)
   710 qed
   711 
   712 end
   713 
   714 text\<open>Relations among convergence and absolute convergence for power series.\<close>
   715 
   716 lemma Abel_lemma:
   717   fixes a :: "nat \<Rightarrow> 'a::real_normed_vector"
   718   assumes r: "0 \<le> r" and r0: "r < r0" and M: "\<And>n. norm (a n) * r0^n \<le> M"
   719     shows "summable (\<lambda>n. norm (a n) * r^n)"
   720 proof (rule summable_comparison_test')
   721   show "summable (\<lambda>n. M * (r / r0) ^ n)"
   722     using assms
   723     by (auto simp add: summable_mult summable_geometric)
   724 next
   725   fix n
   726   show "norm (norm (a n) * r ^ n) \<le> M * (r / r0) ^ n"
   727     using r r0 M [of n]
   728     apply (auto simp add: abs_mult field_simps)
   729     apply (cases "r=0", simp)
   730     apply (cases n, auto)
   731     done
   732 qed
   733 
   734 
   735 text\<open>Summability of geometric series for real algebras\<close>
   736 
   737 lemma complete_algebra_summable_geometric:
   738   fixes x :: "'a::{real_normed_algebra_1,banach}"
   739   shows "norm x < 1 \<Longrightarrow> summable (\<lambda>n. x ^ n)"
   740 proof (rule summable_comparison_test)
   741   show "\<exists>N. \<forall>n\<ge>N. norm (x ^ n) \<le> norm x ^ n"
   742     by (simp add: norm_power_ineq)
   743   show "norm x < 1 \<Longrightarrow> summable (\<lambda>n. norm x ^ n)"
   744     by (simp add: summable_geometric)
   745 qed
   746 
   747 subsection \<open>Cauchy Product Formula\<close>
   748 
   749 text \<open>
   750   Proof based on Analysis WebNotes: Chapter 07, Class 41
   751   @{url "http://www.math.unl.edu/~webnotes/classes/class41/prp77.htm"}
   752 \<close>
   753 
   754 lemma Cauchy_product_sums:
   755   fixes a b :: "nat \<Rightarrow> 'a::{real_normed_algebra,banach}"
   756   assumes a: "summable (\<lambda>k. norm (a k))"
   757   assumes b: "summable (\<lambda>k. norm (b k))"
   758   shows "(\<lambda>k. \<Sum>i\<le>k. a i * b (k - i)) sums ((\<Sum>k. a k) * (\<Sum>k. b k))"
   759 proof -
   760   let ?S1 = "\<lambda>n::nat. {..<n} \<times> {..<n}"
   761   let ?S2 = "\<lambda>n::nat. {(i,j). i + j < n}"
   762   have S1_mono: "\<And>m n. m \<le> n \<Longrightarrow> ?S1 m \<subseteq> ?S1 n" by auto
   763   have S2_le_S1: "\<And>n. ?S2 n \<subseteq> ?S1 n" by auto
   764   have S1_le_S2: "\<And>n. ?S1 (n div 2) \<subseteq> ?S2 n" by auto
   765   have finite_S1: "\<And>n. finite (?S1 n)" by simp
   766   with S2_le_S1 have finite_S2: "\<And>n. finite (?S2 n)" by (rule finite_subset)
   767 
   768   let ?g = "\<lambda>(i,j). a i * b j"
   769   let ?f = "\<lambda>(i,j). norm (a i) * norm (b j)"
   770   have f_nonneg: "\<And>x. 0 \<le> ?f x" by (auto)
   771   hence norm_setsum_f: "\<And>A. norm (setsum ?f A) = setsum ?f A"
   772     unfolding real_norm_def
   773     by (simp only: abs_of_nonneg setsum_nonneg [rule_format])
   774 
   775   have "(\<lambda>n. (\<Sum>k<n. a k) * (\<Sum>k<n. b k)) \<longlonglongrightarrow> (\<Sum>k. a k) * (\<Sum>k. b k)"
   776     by (intro tendsto_mult summable_LIMSEQ summable_norm_cancel [OF a] summable_norm_cancel [OF b])
   777   hence 1: "(\<lambda>n. setsum ?g (?S1 n)) \<longlonglongrightarrow> (\<Sum>k. a k) * (\<Sum>k. b k)"
   778     by (simp only: setsum_product setsum.Sigma [rule_format] finite_lessThan)
   779 
   780   have "(\<lambda>n. (\<Sum>k<n. norm (a k)) * (\<Sum>k<n. norm (b k))) \<longlonglongrightarrow> (\<Sum>k. norm (a k)) * (\<Sum>k. norm (b k))"
   781     using a b by (intro tendsto_mult summable_LIMSEQ)
   782   hence "(\<lambda>n. setsum ?f (?S1 n)) \<longlonglongrightarrow> (\<Sum>k. norm (a k)) * (\<Sum>k. norm (b k))"
   783     by (simp only: setsum_product setsum.Sigma [rule_format] finite_lessThan)
   784   hence "convergent (\<lambda>n. setsum ?f (?S1 n))"
   785     by (rule convergentI)
   786   hence Cauchy: "Cauchy (\<lambda>n. setsum ?f (?S1 n))"
   787     by (rule convergent_Cauchy)
   788   have "Zfun (\<lambda>n. setsum ?f (?S1 n - ?S2 n)) sequentially"
   789   proof (rule ZfunI, simp only: eventually_sequentially norm_setsum_f)
   790     fix r :: real
   791     assume r: "0 < r"
   792     from CauchyD [OF Cauchy r] obtain N
   793     where "\<forall>m\<ge>N. \<forall>n\<ge>N. norm (setsum ?f (?S1 m) - setsum ?f (?S1 n)) < r" ..
   794     hence "\<And>m n. \<lbrakk>N \<le> n; n \<le> m\<rbrakk> \<Longrightarrow> norm (setsum ?f (?S1 m - ?S1 n)) < r"
   795       by (simp only: setsum_diff finite_S1 S1_mono)
   796     hence N: "\<And>m n. \<lbrakk>N \<le> n; n \<le> m\<rbrakk> \<Longrightarrow> setsum ?f (?S1 m - ?S1 n) < r"
   797       by (simp only: norm_setsum_f)
   798     show "\<exists>N. \<forall>n\<ge>N. setsum ?f (?S1 n - ?S2 n) < r"
   799     proof (intro exI allI impI)
   800       fix n assume "2 * N \<le> n"
   801       hence n: "N \<le> n div 2" by simp
   802       have "setsum ?f (?S1 n - ?S2 n) \<le> setsum ?f (?S1 n - ?S1 (n div 2))"
   803         by (intro setsum_mono2 finite_Diff finite_S1 f_nonneg
   804                   Diff_mono subset_refl S1_le_S2)
   805       also have "\<dots> < r"
   806         using n div_le_dividend by (rule N)
   807       finally show "setsum ?f (?S1 n - ?S2 n) < r" .
   808     qed
   809   qed
   810   hence "Zfun (\<lambda>n. setsum ?g (?S1 n - ?S2 n)) sequentially"
   811     apply (rule Zfun_le [rule_format])
   812     apply (simp only: norm_setsum_f)
   813     apply (rule order_trans [OF norm_setsum setsum_mono])
   814     apply (auto simp add: norm_mult_ineq)
   815     done
   816   hence 2: "(\<lambda>n. setsum ?g (?S1 n) - setsum ?g (?S2 n)) \<longlonglongrightarrow> 0"
   817     unfolding tendsto_Zfun_iff diff_0_right
   818     by (simp only: setsum_diff finite_S1 S2_le_S1)
   819 
   820   with 1 have "(\<lambda>n. setsum ?g (?S2 n)) \<longlonglongrightarrow> (\<Sum>k. a k) * (\<Sum>k. b k)"
   821     by (rule Lim_transform2)
   822   thus ?thesis by (simp only: sums_def setsum_triangle_reindex)
   823 qed
   824 
   825 lemma Cauchy_product:
   826   fixes a b :: "nat \<Rightarrow> 'a::{real_normed_algebra,banach}"
   827   assumes a: "summable (\<lambda>k. norm (a k))"
   828   assumes b: "summable (\<lambda>k. norm (b k))"
   829   shows "(\<Sum>k. a k) * (\<Sum>k. b k) = (\<Sum>k. \<Sum>i\<le>k. a i * b (k - i))"
   830   using a b
   831   by (rule Cauchy_product_sums [THEN sums_unique])
   832 
   833 lemma summable_Cauchy_product:
   834   assumes "summable (\<lambda>k. norm (a k :: 'a :: {real_normed_algebra,banach}))"
   835           "summable (\<lambda>k. norm (b k))"
   836   shows   "summable (\<lambda>k. \<Sum>i\<le>k. a i * b (k - i))"
   837   using Cauchy_product_sums[OF assms] by (simp add: sums_iff)
   838 
   839 subsection \<open>Series on @{typ real}s\<close>
   840 
   841 lemma summable_norm_comparison_test: "\<exists>N. \<forall>n\<ge>N. norm (f n) \<le> g n \<Longrightarrow> summable g \<Longrightarrow> summable (\<lambda>n. norm (f n))"
   842   by (rule summable_comparison_test) auto
   843 
   844 lemma summable_rabs_comparison_test: "\<lbrakk>\<exists>N. \<forall>n\<ge>N. \<bar>f n\<bar> \<le> g n; summable g\<rbrakk> \<Longrightarrow> summable (\<lambda>n. \<bar>f n :: real\<bar>)"
   845   by (rule summable_comparison_test) auto
   846 
   847 lemma summable_rabs_cancel: "summable (\<lambda>n. \<bar>f n :: real\<bar>) \<Longrightarrow> summable f"
   848   by (rule summable_norm_cancel) simp
   849 
   850 lemma summable_rabs: "summable (\<lambda>n. \<bar>f n :: real\<bar>) \<Longrightarrow> \<bar>suminf f\<bar> \<le> (\<Sum>n. \<bar>f n\<bar>)"
   851   by (fold real_norm_def) (rule summable_norm)
   852 
   853 lemma summable_zero_power [simp]: "summable (\<lambda>n. 0 ^ n :: 'a :: {comm_ring_1,topological_space})"
   854 proof -
   855   have "(\<lambda>n. 0 ^ n :: 'a) = (\<lambda>n. if n = 0 then 0^0 else 0)" by (intro ext) (simp add: zero_power)
   856   moreover have "summable \<dots>" by simp
   857   ultimately show ?thesis by simp
   858 qed
   859 
   860 lemma summable_zero_power' [simp]: "summable (\<lambda>n. f n * 0 ^ n :: 'a :: {ring_1,topological_space})"
   861 proof -
   862   have "(\<lambda>n. f n * 0 ^ n :: 'a) = (\<lambda>n. if n = 0 then f 0 * 0^0 else 0)"
   863     by (intro ext) (simp add: zero_power)
   864   moreover have "summable \<dots>" by simp
   865   ultimately show ?thesis by simp
   866 qed
   867 
   868 lemma summable_power_series:
   869   fixes z :: real
   870   assumes le_1: "\<And>i. f i \<le> 1" and nonneg: "\<And>i. 0 \<le> f i" and z: "0 \<le> z" "z < 1"
   871   shows "summable (\<lambda>i. f i * z^i)"
   872 proof (rule summable_comparison_test[OF _ summable_geometric])
   873   show "norm z < 1" using z by (auto simp: less_imp_le)
   874   show "\<And>n. \<exists>N. \<forall>na\<ge>N. norm (f na * z ^ na) \<le> z ^ na"
   875     using z by (auto intro!: exI[of _ 0] mult_left_le_one_le simp: abs_mult nonneg power_abs less_imp_le le_1)
   876 qed
   877 
   878 lemma summable_0_powser:
   879   "summable (\<lambda>n. f n * 0 ^ n :: 'a :: real_normed_div_algebra)"
   880 proof -
   881   have A: "(\<lambda>n. f n * 0 ^ n) = (\<lambda>n. if n = 0 then f n else 0)"
   882     by (intro ext) auto
   883   thus ?thesis by (subst A) simp_all
   884 qed
   885 
   886 lemma summable_powser_split_head:
   887   "summable (\<lambda>n. f (Suc n) * z ^ n :: 'a :: real_normed_div_algebra) = summable (\<lambda>n. f n * z ^ n)"
   888 proof -
   889   have "summable (\<lambda>n. f (Suc n) * z ^ n) \<longleftrightarrow> summable (\<lambda>n. f (Suc n) * z ^ Suc n)"
   890   proof
   891     assume "summable (\<lambda>n. f (Suc n) * z ^ n)"
   892     from summable_mult2[OF this, of z] show "summable (\<lambda>n. f (Suc n) * z ^ Suc n)"
   893       by (simp add: power_commutes algebra_simps)
   894   next
   895     assume "summable (\<lambda>n. f (Suc n) * z ^ Suc n)"
   896     from summable_mult2[OF this, of "inverse z"] show "summable (\<lambda>n. f (Suc n) * z ^ n)"
   897       by (cases "z \<noteq> 0", subst (asm) power_Suc2) (simp_all add: algebra_simps)
   898   qed
   899   also have "\<dots> \<longleftrightarrow> summable (\<lambda>n. f n * z ^ n)" by (rule summable_Suc_iff)
   900   finally show ?thesis .
   901 qed
   902 
   903 lemma powser_split_head:
   904   assumes "summable (\<lambda>n. f n * z ^ n :: 'a :: {real_normed_div_algebra,banach})"
   905   shows   "suminf (\<lambda>n. f n * z ^ n) = f 0 + suminf (\<lambda>n. f (Suc n) * z ^ n) * z"
   906           "suminf (\<lambda>n. f (Suc n) * z ^ n) * z = suminf (\<lambda>n. f n * z ^ n) - f 0"
   907           "summable (\<lambda>n. f (Suc n) * z ^ n)"
   908 proof -
   909   from assms show "summable (\<lambda>n. f (Suc n) * z ^ n)" by (subst summable_powser_split_head)
   910 
   911   from suminf_mult2[OF this, of z]
   912     have "(\<Sum>n. f (Suc n) * z ^ n) * z = (\<Sum>n. f (Suc n) * z ^ Suc n)"
   913     by (simp add: power_commutes algebra_simps)
   914   also from assms have "\<dots> = suminf (\<lambda>n. f n * z ^ n) - f 0"
   915     by (subst suminf_split_head) simp_all
   916   finally show "suminf (\<lambda>n. f n * z ^ n) = f 0 + suminf (\<lambda>n. f (Suc n) * z ^ n) * z" by simp
   917   thus "suminf (\<lambda>n. f (Suc n) * z ^ n) * z = suminf (\<lambda>n. f n * z ^ n) - f 0" by simp
   918 qed
   919 
   920 lemma summable_partial_sum_bound:
   921   fixes f :: "nat \<Rightarrow> 'a :: banach"
   922   assumes summable: "summable f" and e: "e > (0::real)"
   923   obtains N where "\<And>m n. m \<ge> N \<Longrightarrow> norm (\<Sum>k=m..n. f k) < e"
   924 proof -
   925   from summable have "Cauchy (\<lambda>n. \<Sum>k<n. f k)"
   926     by (simp add: Cauchy_convergent_iff summable_iff_convergent)
   927   from CauchyD[OF this e] obtain N
   928     where N: "\<And>m n. m \<ge> N \<Longrightarrow> n \<ge> N \<Longrightarrow> norm ((\<Sum>k<m. f k) - (\<Sum>k<n. f k)) < e" by blast
   929   {
   930     fix m n :: nat assume m: "m \<ge> N"
   931     have "norm (\<Sum>k=m..n. f k) < e"
   932     proof (cases "n \<ge> m")
   933       assume n: "n \<ge> m"
   934       with m have "norm ((\<Sum>k<Suc n. f k) - (\<Sum>k<m. f k)) < e" by (intro N) simp_all
   935       also from n have "(\<Sum>k<Suc n. f k) - (\<Sum>k<m. f k) = (\<Sum>k=m..n. f k)"
   936         by (subst setsum_diff [symmetric]) (simp_all add: setsum_last_plus)
   937       finally show ?thesis .
   938     qed (insert e, simp_all)
   939   }
   940   thus ?thesis by (rule that)
   941 qed
   942 
   943 lemma powser_sums_if:
   944   "(\<lambda>n. (if n = m then (1 :: 'a :: {ring_1,topological_space}) else 0) * z^n) sums z^m"
   945 proof -
   946   have "(\<lambda>n. (if n = m then 1 else 0) * z^n) = (\<lambda>n. if n = m then z^n else 0)"
   947     by (intro ext) auto
   948   thus ?thesis by (simp add: sums_single)
   949 qed
   950 
   951 lemma
   952    fixes f :: "nat \<Rightarrow> real"
   953    assumes "summable f"
   954    and "inj g"
   955    and pos: "\<And>x. 0 \<le> f x"
   956    shows summable_reindex: "summable (f o g)"
   957    and suminf_reindex_mono: "suminf (f o g) \<le> suminf f"
   958    and suminf_reindex: "(\<And>x. x \<notin> range g \<Longrightarrow> f x = 0) \<Longrightarrow> suminf (f \<circ> g) = suminf f"
   959 proof -
   960   from \<open>inj g\<close> have [simp]: "\<And>A. inj_on g A" by(rule subset_inj_on) simp
   961 
   962   have smaller: "\<forall>n. (\<Sum>i<n. (f \<circ> g) i) \<le> suminf f"
   963   proof
   964     fix n
   965     have "\<forall> n' \<in> (g ` {..<n}). n' < Suc (Max (g ` {..<n}))"
   966       by(metis Max_ge finite_imageI finite_lessThan not_le not_less_eq)
   967     then obtain m where n: "\<And>n'. n' < n \<Longrightarrow> g n' < m" by blast
   968 
   969     have "(\<Sum>i<n. f (g i)) = setsum f (g ` {..<n})"
   970       by (simp add: setsum.reindex)
   971     also have "\<dots> \<le> (\<Sum>i<m. f i)"
   972       by (rule setsum_mono3) (auto simp add: pos n[rule_format])
   973     also have "\<dots> \<le> suminf f"
   974       using \<open>summable f\<close>
   975       by (rule setsum_le_suminf) (simp add: pos)
   976     finally show "(\<Sum>i<n. (f \<circ>  g) i) \<le> suminf f" by simp
   977   qed
   978 
   979   have "incseq (\<lambda>n. \<Sum>i<n. (f \<circ> g) i)"
   980     by (rule incseq_SucI) (auto simp add: pos)
   981   then obtain  L where L: "(\<lambda> n. \<Sum>i<n. (f \<circ> g) i) \<longlonglongrightarrow> L"
   982     using smaller by(rule incseq_convergent)
   983   hence "(f \<circ> g) sums L" by (simp add: sums_def)
   984   thus "summable (f o g)" by (auto simp add: sums_iff)
   985 
   986   hence "(\<lambda>n. \<Sum>i<n. (f \<circ> g) i) \<longlonglongrightarrow> suminf (f \<circ> g)"
   987     by(rule summable_LIMSEQ)
   988   thus le: "suminf (f \<circ> g) \<le> suminf f"
   989     by(rule LIMSEQ_le_const2)(blast intro: smaller[rule_format])
   990 
   991   assume f: "\<And>x. x \<notin> range g \<Longrightarrow> f x = 0"
   992 
   993   from \<open>summable f\<close> have "suminf f \<le> suminf (f \<circ> g)"
   994   proof(rule suminf_le_const)
   995     fix n
   996     have "\<forall> n' \<in> (g -` {..<n}). n' < Suc (Max (g -` {..<n}))"
   997       by(auto intro: Max_ge simp add: finite_vimageI less_Suc_eq_le)
   998     then obtain m where n: "\<And>n'. g n' < n \<Longrightarrow> n' < m" by blast
   999 
  1000     have "(\<Sum>i<n. f i) = (\<Sum>i\<in>{..<n} \<inter> range g. f i)"
  1001       using f by(auto intro: setsum.mono_neutral_cong_right)
  1002     also have "\<dots> = (\<Sum>i\<in>g -` {..<n}. (f \<circ> g) i)"
  1003       by(rule setsum.reindex_cong[where l=g])(auto)
  1004     also have "\<dots> \<le> (\<Sum>i<m. (f \<circ> g) i)"
  1005       by(rule setsum_mono3)(auto simp add: pos n)
  1006     also have "\<dots> \<le> suminf (f \<circ> g)"
  1007       using \<open>summable (f o g)\<close>
  1008       by(rule setsum_le_suminf)(simp add: pos)
  1009     finally show "setsum f {..<n} \<le> suminf (f \<circ> g)" .
  1010   qed
  1011   with le show "suminf (f \<circ> g) = suminf f" by(rule antisym)
  1012 qed
  1013 
  1014 lemma sums_mono_reindex:
  1015   assumes subseq: "subseq g" and zero: "\<And>n. n \<notin> range g \<Longrightarrow> f n = 0"
  1016   shows   "(\<lambda>n. f (g n)) sums c \<longleftrightarrow> f sums c"
  1017 unfolding sums_def
  1018 proof
  1019   assume lim: "(\<lambda>n. \<Sum>k<n. f k) \<longlonglongrightarrow> c"
  1020   have "(\<lambda>n. \<Sum>k<n. f (g k)) = (\<lambda>n. \<Sum>k<g n. f k)"
  1021   proof
  1022     fix n :: nat
  1023     from subseq have "(\<Sum>k<n. f (g k)) = (\<Sum>k\<in>g`{..<n}. f k)"
  1024       by (subst setsum.reindex) (auto intro: subseq_imp_inj_on)
  1025     also from subseq have "\<dots> = (\<Sum>k<g n. f k)"
  1026       by (intro setsum.mono_neutral_left ballI zero)
  1027          (auto dest: subseq_strict_mono simp: strict_mono_less strict_mono_less_eq)
  1028     finally show "(\<Sum>k<n. f (g k)) = (\<Sum>k<g n. f k)" .
  1029   qed
  1030   also from LIMSEQ_subseq_LIMSEQ[OF lim subseq] have "\<dots> \<longlonglongrightarrow> c" unfolding o_def .
  1031   finally show "(\<lambda>n. \<Sum>k<n. f (g k)) \<longlonglongrightarrow> c" .
  1032 next
  1033   assume lim: "(\<lambda>n. \<Sum>k<n. f (g k)) \<longlonglongrightarrow> c"
  1034   def g_inv \<equiv> "\<lambda>n. LEAST m. g m \<ge> n"
  1035   from filterlim_subseq[OF subseq] have g_inv_ex: "\<exists>m. g m \<ge> n" for n
  1036     by (auto simp: filterlim_at_top eventually_at_top_linorder)
  1037   hence g_inv: "g (g_inv n) \<ge> n" for n unfolding g_inv_def by (rule LeastI_ex)
  1038   have g_inv_least: "m \<ge> g_inv n" if "g m \<ge> n" for m n using that
  1039     unfolding g_inv_def by (rule Least_le)
  1040   have g_inv_least': "g m < n" if "m < g_inv n" for m n using that g_inv_least[of n m] by linarith
  1041   have "(\<lambda>n. \<Sum>k<n. f k) = (\<lambda>n. \<Sum>k<g_inv n. f (g k))"
  1042   proof
  1043     fix n :: nat
  1044     {
  1045       fix k assume k: "k \<in> {..<n} - g`{..<g_inv n}"
  1046       have "k \<notin> range g"
  1047       proof (rule notI, elim imageE)
  1048         fix l assume l: "k = g l"
  1049         have "g l < g (g_inv n)" by (rule less_le_trans[OF _ g_inv]) (insert k l, simp_all)
  1050         with subseq have "l < g_inv n" by (simp add: subseq_strict_mono strict_mono_less)
  1051         with k l show False by simp
  1052       qed
  1053       hence "f k = 0" by (rule zero)
  1054     }
  1055     with g_inv_least' g_inv have "(\<Sum>k<n. f k) = (\<Sum>k\<in>g`{..<g_inv n}. f k)"
  1056       by (intro setsum.mono_neutral_right) auto
  1057     also from subseq have "\<dots> = (\<Sum>k<g_inv n. f (g k))" using subseq_imp_inj_on
  1058       by (subst setsum.reindex) simp_all
  1059     finally show "(\<Sum>k<n. f k) = (\<Sum>k<g_inv n. f (g k))" .
  1060   qed
  1061   also {
  1062     fix K n :: nat assume "g K \<le> n"
  1063     also have "n \<le> g (g_inv n)" by (rule g_inv)
  1064     finally have "K \<le> g_inv n" using subseq by (simp add: strict_mono_less_eq subseq_strict_mono)
  1065   }
  1066   hence "filterlim g_inv at_top sequentially"
  1067     by (auto simp: filterlim_at_top eventually_at_top_linorder)
  1068   from lim and this have "(\<lambda>n. \<Sum>k<g_inv n. f (g k)) \<longlonglongrightarrow> c" by (rule filterlim_compose)
  1069   finally show "(\<lambda>n. \<Sum>k<n. f k) \<longlonglongrightarrow> c" .
  1070 qed
  1071 
  1072 lemma summable_mono_reindex:
  1073   assumes subseq: "subseq g" and zero: "\<And>n. n \<notin> range g \<Longrightarrow> f n = 0"
  1074   shows   "summable (\<lambda>n. f (g n)) \<longleftrightarrow> summable f"
  1075   using sums_mono_reindex[of g f, OF assms] by (simp add: summable_def)
  1076 
  1077 lemma suminf_mono_reindex:
  1078   assumes "subseq g" "\<And>n. n \<notin> range g \<Longrightarrow> f n = (0 :: 'a :: {t2_space,comm_monoid_add})"
  1079   shows   "suminf (\<lambda>n. f (g n)) = suminf f"
  1080 proof (cases "summable f")
  1081   case False
  1082   hence "\<not>(\<exists>c. f sums c)" unfolding summable_def by blast
  1083   hence "suminf f = The (\<lambda>_. False)" by (simp add: suminf_def)
  1084   moreover from False have "\<not>summable (\<lambda>n. f (g n))"
  1085     using summable_mono_reindex[of g f, OF assms] by simp
  1086   hence "\<not>(\<exists>c. (\<lambda>n. f (g n)) sums c)" unfolding summable_def by blast
  1087   hence "suminf (\<lambda>n. f (g n)) = The (\<lambda>_. False)" by (simp add: suminf_def)
  1088   ultimately show ?thesis by simp
  1089 qed (insert sums_mono_reindex[of g f, OF assms] summable_mono_reindex[of g f, OF assms],
  1090      simp_all add: sums_iff)
  1091 
  1092 end