src/HOL/Series.thy
author hoelzl
Wed Feb 10 18:43:19 2016 +0100 (2016-02-10)
changeset 62376 85f38d5f8807
parent 62368 106569399cd6
child 62377 ace69956d018
permissions -rw-r--r--
Rename ordered_comm_monoid_add to ordered_cancel_comm_monoid_add. Introduce ordreed_comm_monoid_add, canonically_ordered_comm_monoid and dioid. Setup nat, entat and ennreal as dioids.
     1 (*  Title       : Series.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4 
     5 Converted to Isar and polished by lcp
     6 Converted to setsum and polished yet more by TNN
     7 Additional contributions by Jeremy Avigad
     8 *)
     9 
    10 section \<open>Infinite Series\<close>
    11 
    12 theory Series
    13 imports Limits Inequalities
    14 begin
    15 
    16 subsection \<open>Definition of infinite summability\<close>
    17 
    18 definition
    19   sums :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> 'a \<Rightarrow> bool"
    20   (infixr "sums" 80)
    21 where
    22   "f sums s \<longleftrightarrow> (\<lambda>n. \<Sum>i<n. f i) \<longlonglongrightarrow> s"
    23 
    24 definition summable :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> bool" where
    25    "summable f \<longleftrightarrow> (\<exists>s. f sums s)"
    26 
    27 definition
    28   suminf :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> 'a"
    29   (binder "\<Sum>" 10)
    30 where
    31   "suminf f = (THE s. f sums s)"
    32 
    33 lemma sums_def': "f sums s \<longleftrightarrow> (\<lambda>n. \<Sum>i = 0..n. f i) \<longlonglongrightarrow> s"
    34   apply (simp add: sums_def)
    35   apply (subst LIMSEQ_Suc_iff [symmetric])
    36   apply (simp only: lessThan_Suc_atMost atLeast0AtMost)
    37   done
    38 
    39 subsection \<open>Infinite summability on topological monoids\<close>
    40 
    41 lemma sums_subst[trans]: "f = g \<Longrightarrow> g sums z \<Longrightarrow> f sums z"
    42   by simp
    43 
    44 lemma sums_cong: "(\<And>n. f n = g n) \<Longrightarrow> f sums c \<longleftrightarrow> g sums c"
    45   by (drule ext) simp
    46 
    47 lemma sums_summable: "f sums l \<Longrightarrow> summable f"
    48   by (simp add: sums_def summable_def, blast)
    49 
    50 lemma summable_iff_convergent: "summable f \<longleftrightarrow> convergent (\<lambda>n. \<Sum>i<n. f i)"
    51   by (simp add: summable_def sums_def convergent_def)
    52 
    53 lemma summable_iff_convergent':
    54   "summable f \<longleftrightarrow> convergent (\<lambda>n. setsum f {..n})"
    55   by (simp_all only: summable_iff_convergent convergent_def
    56         lessThan_Suc_atMost [symmetric] LIMSEQ_Suc_iff[of "\<lambda>n. setsum f {..<n}"])
    57 
    58 lemma suminf_eq_lim: "suminf f = lim (\<lambda>n. \<Sum>i<n. f i)"
    59   by (simp add: suminf_def sums_def lim_def)
    60 
    61 lemma sums_zero[simp, intro]: "(\<lambda>n. 0) sums 0"
    62   unfolding sums_def by simp
    63 
    64 lemma summable_zero[simp, intro]: "summable (\<lambda>n. 0)"
    65   by (rule sums_zero [THEN sums_summable])
    66 
    67 lemma sums_group: "f sums s \<Longrightarrow> 0 < k \<Longrightarrow> (\<lambda>n. setsum f {n * k ..< n * k + k}) sums s"
    68   apply (simp only: sums_def setsum_nat_group tendsto_def eventually_sequentially)
    69   apply safe
    70   apply (erule_tac x=S in allE)
    71   apply safe
    72   apply (rule_tac x="N" in exI, safe)
    73   apply (drule_tac x="n*k" in spec)
    74   apply (erule mp)
    75   apply (erule order_trans)
    76   apply simp
    77   done
    78 
    79 lemma suminf_cong: "(\<And>n. f n = g n) \<Longrightarrow> suminf f = suminf g"
    80   by (rule arg_cong[of f g], rule ext) simp
    81 
    82 lemma summable_cong:
    83   assumes "eventually (\<lambda>x. f x = (g x :: 'a :: real_normed_vector)) sequentially"
    84   shows   "summable f = summable g"
    85 proof -
    86   from assms obtain N where N: "\<forall>n\<ge>N. f n = g n" by (auto simp: eventually_at_top_linorder)
    87   def C \<equiv> "(\<Sum>k<N. f k - g k)"
    88   from eventually_ge_at_top[of N]
    89     have "eventually (\<lambda>n. setsum f {..<n} = C + setsum g {..<n}) sequentially"
    90   proof eventually_elim
    91     fix n assume n: "n \<ge> N"
    92     from n have "{..<n} = {..<N} \<union> {N..<n}" by auto
    93     also have "setsum f ... = setsum f {..<N} + setsum f {N..<n}"
    94       by (intro setsum.union_disjoint) auto
    95     also from N have "setsum f {N..<n} = setsum g {N..<n}" by (intro setsum.cong) simp_all
    96     also have "setsum f {..<N} + setsum g {N..<n} = C + (setsum g {..<N} + setsum g {N..<n})"
    97       unfolding C_def by (simp add: algebra_simps setsum_subtractf)
    98     also have "setsum g {..<N} + setsum g {N..<n} = setsum g ({..<N} \<union> {N..<n})"
    99       by (intro setsum.union_disjoint [symmetric]) auto
   100     also from n have "{..<N} \<union> {N..<n} = {..<n}" by auto
   101     finally show "setsum f {..<n} = C + setsum g {..<n}" .
   102   qed
   103   from convergent_cong[OF this] show ?thesis
   104     by (simp add: summable_iff_convergent convergent_add_const_iff)
   105 qed
   106 
   107 lemma sums_finite:
   108   assumes [simp]: "finite N" and f: "\<And>n. n \<notin> N \<Longrightarrow> f n = 0"
   109   shows "f sums (\<Sum>n\<in>N. f n)"
   110 proof -
   111   { fix n
   112     have "setsum f {..<n + Suc (Max N)} = setsum f N"
   113     proof cases
   114       assume "N = {}"
   115       with f have "f = (\<lambda>x. 0)" by auto
   116       then show ?thesis by simp
   117     next
   118       assume [simp]: "N \<noteq> {}"
   119       show ?thesis
   120       proof (safe intro!: setsum.mono_neutral_right f)
   121         fix i assume "i \<in> N"
   122         then have "i \<le> Max N" by simp
   123         then show "i < n + Suc (Max N)" by simp
   124       qed
   125     qed }
   126   note eq = this
   127   show ?thesis unfolding sums_def
   128     by (rule LIMSEQ_offset[of _ "Suc (Max N)"])
   129        (simp add: eq atLeast0LessThan del: add_Suc_right)
   130 qed
   131 
   132 corollary sums_0:
   133    "(\<And>n. f n = 0) \<Longrightarrow> (f sums 0)"
   134     by (metis (no_types) finite.emptyI setsum.empty sums_finite)
   135 
   136 lemma summable_finite: "finite N \<Longrightarrow> (\<And>n. n \<notin> N \<Longrightarrow> f n = 0) \<Longrightarrow> summable f"
   137   by (rule sums_summable) (rule sums_finite)
   138 
   139 lemma sums_If_finite_set: "finite A \<Longrightarrow> (\<lambda>r. if r \<in> A then f r else 0) sums (\<Sum>r\<in>A. f r)"
   140   using sums_finite[of A "(\<lambda>r. if r \<in> A then f r else 0)"] by simp
   141 
   142 lemma summable_If_finite_set[simp, intro]: "finite A \<Longrightarrow> summable (\<lambda>r. if r \<in> A then f r else 0)"
   143   by (rule sums_summable) (rule sums_If_finite_set)
   144 
   145 lemma sums_If_finite: "finite {r. P r} \<Longrightarrow> (\<lambda>r. if P r then f r else 0) sums (\<Sum>r | P r. f r)"
   146   using sums_If_finite_set[of "{r. P r}"] by simp
   147 
   148 lemma summable_If_finite[simp, intro]: "finite {r. P r} \<Longrightarrow> summable (\<lambda>r. if P r then f r else 0)"
   149   by (rule sums_summable) (rule sums_If_finite)
   150 
   151 lemma sums_single: "(\<lambda>r. if r = i then f r else 0) sums f i"
   152   using sums_If_finite[of "\<lambda>r. r = i"] by simp
   153 
   154 lemma summable_single[simp, intro]: "summable (\<lambda>r. if r = i then f r else 0)"
   155   by (rule sums_summable) (rule sums_single)
   156 
   157 context
   158   fixes f :: "nat \<Rightarrow> 'a::{t2_space, comm_monoid_add}"
   159 begin
   160 
   161 lemma summable_sums[intro]: "summable f \<Longrightarrow> f sums (suminf f)"
   162   by (simp add: summable_def sums_def suminf_def)
   163      (metis convergent_LIMSEQ_iff convergent_def lim_def)
   164 
   165 lemma summable_LIMSEQ: "summable f \<Longrightarrow> (\<lambda>n. \<Sum>i<n. f i) \<longlonglongrightarrow> suminf f"
   166   by (rule summable_sums [unfolded sums_def])
   167 
   168 lemma sums_unique: "f sums s \<Longrightarrow> s = suminf f"
   169   by (metis limI suminf_eq_lim sums_def)
   170 
   171 lemma sums_iff: "f sums x \<longleftrightarrow> summable f \<and> (suminf f = x)"
   172   by (metis summable_sums sums_summable sums_unique)
   173 
   174 lemma summable_sums_iff:
   175   "summable (f :: nat \<Rightarrow> 'a :: {comm_monoid_add,t2_space}) \<longleftrightarrow> f sums suminf f"
   176   by (auto simp: sums_iff summable_sums)
   177 
   178 lemma sums_unique2:
   179   fixes a b :: "'a::{comm_monoid_add,t2_space}"
   180   shows "f sums a \<Longrightarrow> f sums b \<Longrightarrow> a = b"
   181 by (simp add: sums_iff)
   182 
   183 lemma suminf_finite:
   184   assumes N: "finite N" and f: "\<And>n. n \<notin> N \<Longrightarrow> f n = 0"
   185   shows "suminf f = (\<Sum>n\<in>N. f n)"
   186   using sums_finite[OF assms, THEN sums_unique] by simp
   187 
   188 end
   189 
   190 lemma suminf_zero[simp]: "suminf (\<lambda>n. 0::'a::{t2_space, comm_monoid_add}) = 0"
   191   by (rule sums_zero [THEN sums_unique, symmetric])
   192 
   193 
   194 subsection \<open>Infinite summability on ordered, topological monoids\<close>
   195 
   196 lemma sums_le:
   197   fixes f g :: "nat \<Rightarrow> 'a::{ordered_comm_monoid_add, linorder_topology}"
   198   shows "\<forall>n. f n \<le> g n \<Longrightarrow> f sums s \<Longrightarrow> g sums t \<Longrightarrow> s \<le> t"
   199   by (rule LIMSEQ_le) (auto intro: setsum_mono simp: sums_def)
   200 
   201 context
   202   fixes f :: "nat \<Rightarrow> 'a::{ordered_comm_monoid_add, linorder_topology}"
   203 begin
   204 
   205 lemma suminf_le: "\<lbrakk>\<forall>n. f n \<le> g n; summable f; summable g\<rbrakk> \<Longrightarrow> suminf f \<le> suminf g"
   206   by (auto dest: sums_summable intro: sums_le)
   207 
   208 lemma setsum_le_suminf: "summable f \<Longrightarrow> \<forall>m\<ge>n. 0 \<le> f m \<Longrightarrow> setsum f {..<n} \<le> suminf f"
   209   by (rule sums_le[OF _ sums_If_finite_set summable_sums]) auto
   210 
   211 lemma suminf_nonneg: "summable f \<Longrightarrow> \<forall>n. 0 \<le> f n \<Longrightarrow> 0 \<le> suminf f"
   212   using setsum_le_suminf[of 0] by simp
   213 
   214 lemma suminf_le_const: "summable f \<Longrightarrow> (\<And>n. setsum f {..<n} \<le> x) \<Longrightarrow> suminf f \<le> x"
   215   by (metis LIMSEQ_le_const2 summable_LIMSEQ)
   216 
   217 lemma suminf_eq_zero_iff: "summable f \<Longrightarrow> \<forall>n. 0 \<le> f n \<Longrightarrow> suminf f = 0 \<longleftrightarrow> (\<forall>n. f n = 0)"
   218 proof
   219   assume "summable f" "suminf f = 0" and pos: "\<forall>n. 0 \<le> f n"
   220   then have f: "(\<lambda>n. \<Sum>i<n. f i) \<longlonglongrightarrow> 0"
   221     using summable_LIMSEQ[of f] by simp
   222   then have "\<And>i. (\<Sum>n\<in>{i}. f n) \<le> 0"
   223   proof (rule LIMSEQ_le_const)
   224     fix i show "\<exists>N. \<forall>n\<ge>N. (\<Sum>n\<in>{i}. f n) \<le> setsum f {..<n}"
   225       using pos by (intro exI[of _ "Suc i"] allI impI setsum_mono2) auto
   226   qed
   227   with pos show "\<forall>n. f n = 0"
   228     by (auto intro!: antisym)
   229 qed (metis suminf_zero fun_eq_iff)
   230 
   231 end
   232 
   233 context
   234   fixes f :: "nat \<Rightarrow> 'a::{ordered_cancel_comm_monoid_add, linorder_topology}"
   235 begin
   236 
   237 lemma setsum_less_suminf2: "summable f \<Longrightarrow> \<forall>m\<ge>n. 0 \<le> f m \<Longrightarrow> n \<le> i \<Longrightarrow> 0 < f i \<Longrightarrow> setsum f {..<n} < suminf f"
   238   using
   239     setsum_le_suminf[of f "Suc i"]
   240     add_strict_increasing[of "f i" "setsum f {..<n}" "setsum f {..<i}"]
   241     setsum_mono2[of "{..<i}" "{..<n}" f]
   242   by (auto simp: less_imp_le ac_simps)
   243 
   244 lemma setsum_less_suminf: "summable f \<Longrightarrow> \<forall>m\<ge>n. 0 < f m \<Longrightarrow> setsum f {..<n} < suminf f"
   245   using setsum_less_suminf2[of n n] by (simp add: less_imp_le)
   246 
   247 lemma suminf_pos2: "summable f \<Longrightarrow> \<forall>n. 0 \<le> f n \<Longrightarrow> 0 < f i \<Longrightarrow> 0 < suminf f"
   248   using setsum_less_suminf2[of 0 i] by simp
   249 
   250 lemma suminf_pos: "summable f \<Longrightarrow> \<forall>n. 0 < f n \<Longrightarrow> 0 < suminf f"
   251   using suminf_pos2[of 0] by (simp add: less_imp_le)
   252 
   253 lemma suminf_pos_iff:
   254   "summable f \<Longrightarrow> \<forall>n. 0 \<le> f n \<Longrightarrow> 0 < suminf f \<longleftrightarrow> (\<exists>i. 0 < f i)"
   255   using setsum_le_suminf[of f 0] suminf_eq_zero_iff[of f] by (simp add: less_le)
   256 
   257 end
   258 
   259 lemma summableI_nonneg_bounded:
   260   fixes f:: "nat \<Rightarrow> 'a::{ordered_comm_monoid_add, linorder_topology, conditionally_complete_linorder}"
   261   assumes pos[simp]: "\<And>n. 0 \<le> f n" and le: "\<And>n. (\<Sum>i<n. f i) \<le> x"
   262   shows "summable f"
   263   unfolding summable_def sums_def[abs_def]
   264 proof (intro exI order_tendstoI)
   265   have [simp, intro]: "bdd_above (range (\<lambda>n. \<Sum>i<n. f i))"
   266     using le by (auto simp: bdd_above_def)
   267   { fix a assume "a < (SUP n. \<Sum>i<n. f i)"
   268     then obtain n where "a < (\<Sum>i<n. f i)"
   269       by (auto simp add: less_cSUP_iff)
   270     then have "\<And>m. n \<le> m \<Longrightarrow> a < (\<Sum>i<m. f i)"
   271       by (rule less_le_trans) (auto intro!: setsum_mono2)
   272     then show "eventually (\<lambda>n. a < (\<Sum>i<n. f i)) sequentially"
   273       by (auto simp: eventually_sequentially) }
   274   { fix a assume "(SUP n. \<Sum>i<n. f i) < a"
   275     moreover have "\<And>n. (\<Sum>i<n. f i) \<le> (SUP n. \<Sum>i<n. f i)"
   276       by (auto intro: cSUP_upper)
   277     ultimately show "eventually (\<lambda>n. (\<Sum>i<n. f i) < a) sequentially"
   278       by (auto intro: le_less_trans simp: eventually_sequentially) }
   279 qed
   280 
   281 subsection \<open>Infinite summability on topological monoids\<close>
   282 
   283 lemma Zero_notin_Suc: "0 \<notin> Suc ` A"
   284   by auto
   285 
   286 context
   287   fixes f g :: "nat \<Rightarrow> 'a :: {t2_space, topological_comm_monoid_add}"
   288 begin
   289 
   290 lemma sums_Suc:
   291   assumes "(\<lambda>n. f (Suc n)) sums l" shows "f sums (l + f 0)"
   292 proof  -
   293   have "(\<lambda>n. (\<Sum>i<n. f (Suc i)) + f 0) \<longlonglongrightarrow> l + f 0"
   294     using assms by (auto intro!: tendsto_add simp: sums_def)
   295   moreover have "(\<Sum>i<n. f (Suc i)) + f 0 = (\<Sum>i<Suc n. f i)" for n
   296     unfolding lessThan_Suc_eq_insert_0 by (simp add: Zero_notin_Suc ac_simps setsum.reindex)
   297   ultimately show ?thesis
   298     by (auto simp add: sums_def simp del: setsum_lessThan_Suc intro: LIMSEQ_Suc_iff[THEN iffD1])
   299 qed
   300 
   301 lemma sums_add: "f sums a \<Longrightarrow> g sums b \<Longrightarrow> (\<lambda>n. f n + g n) sums (a + b)"
   302   unfolding sums_def by (simp add: setsum.distrib tendsto_add)
   303 
   304 lemma summable_add: "summable f \<Longrightarrow> summable g \<Longrightarrow> summable (\<lambda>n. f n + g n)"
   305   unfolding summable_def by (auto intro: sums_add)
   306 
   307 lemma suminf_add: "summable f \<Longrightarrow> summable g \<Longrightarrow> suminf f + suminf g = (\<Sum>n. f n + g n)"
   308   by (intro sums_unique sums_add summable_sums)
   309 
   310 end
   311 
   312 context
   313   fixes f :: "'i \<Rightarrow> nat \<Rightarrow> 'a::{t2_space, topological_comm_monoid_add}" and I :: "'i set"
   314 begin
   315 
   316 lemma sums_setsum: "(\<And>i. i \<in> I \<Longrightarrow> (f i) sums (x i)) \<Longrightarrow> (\<lambda>n. \<Sum>i\<in>I. f i n) sums (\<Sum>i\<in>I. x i)"
   317   by (induct I rule: infinite_finite_induct) (auto intro!: sums_add)
   318 
   319 lemma suminf_setsum: "(\<And>i. i \<in> I \<Longrightarrow> summable (f i)) \<Longrightarrow> (\<Sum>n. \<Sum>i\<in>I. f i n) = (\<Sum>i\<in>I. \<Sum>n. f i n)"
   320   using sums_unique[OF sums_setsum, OF summable_sums] by simp
   321 
   322 lemma summable_setsum: "(\<And>i. i \<in> I \<Longrightarrow> summable (f i)) \<Longrightarrow> summable (\<lambda>n. \<Sum>i\<in>I. f i n)"
   323   using sums_summable[OF sums_setsum[OF summable_sums]] .
   324 
   325 end
   326 
   327 subsection \<open>Infinite summability on real normed vector spaces\<close>
   328 
   329 context
   330   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   331 begin
   332 
   333 lemma sums_Suc_iff: "(\<lambda>n. f (Suc n)) sums s \<longleftrightarrow> f sums (s + f 0)"
   334 proof -
   335   have "f sums (s + f 0) \<longleftrightarrow> (\<lambda>i. \<Sum>j<Suc i. f j) \<longlonglongrightarrow> s + f 0"
   336     by (subst LIMSEQ_Suc_iff) (simp add: sums_def)
   337   also have "\<dots> \<longleftrightarrow> (\<lambda>i. (\<Sum>j<i. f (Suc j)) + f 0) \<longlonglongrightarrow> s + f 0"
   338     by (simp add: ac_simps setsum.reindex image_iff lessThan_Suc_eq_insert_0)
   339   also have "\<dots> \<longleftrightarrow> (\<lambda>n. f (Suc n)) sums s"
   340   proof
   341     assume "(\<lambda>i. (\<Sum>j<i. f (Suc j)) + f 0) \<longlonglongrightarrow> s + f 0"
   342     with tendsto_add[OF this tendsto_const, of "- f 0"]
   343     show "(\<lambda>i. f (Suc i)) sums s"
   344       by (simp add: sums_def)
   345   qed (auto intro: tendsto_add simp: sums_def)
   346   finally show ?thesis ..
   347 qed
   348 
   349 lemma summable_Suc_iff: "summable (\<lambda>n. f (Suc n)) = summable f"
   350 proof
   351   assume "summable f"
   352   hence "f sums suminf f" by (rule summable_sums)
   353   hence "(\<lambda>n. f (Suc n)) sums (suminf f - f 0)" by (simp add: sums_Suc_iff)
   354   thus "summable (\<lambda>n. f (Suc n))" unfolding summable_def by blast
   355 qed (auto simp: sums_Suc_iff summable_def)
   356 
   357 end
   358 
   359 context
   360   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   361 begin
   362 
   363 lemma sums_diff: "f sums a \<Longrightarrow> g sums b \<Longrightarrow> (\<lambda>n. f n - g n) sums (a - b)"
   364   unfolding sums_def by (simp add: setsum_subtractf tendsto_diff)
   365 
   366 lemma summable_diff: "summable f \<Longrightarrow> summable g \<Longrightarrow> summable (\<lambda>n. f n - g n)"
   367   unfolding summable_def by (auto intro: sums_diff)
   368 
   369 lemma suminf_diff: "summable f \<Longrightarrow> summable g \<Longrightarrow> suminf f - suminf g = (\<Sum>n. f n - g n)"
   370   by (intro sums_unique sums_diff summable_sums)
   371 
   372 lemma sums_minus: "f sums a \<Longrightarrow> (\<lambda>n. - f n) sums (- a)"
   373   unfolding sums_def by (simp add: setsum_negf tendsto_minus)
   374 
   375 lemma summable_minus: "summable f \<Longrightarrow> summable (\<lambda>n. - f n)"
   376   unfolding summable_def by (auto intro: sums_minus)
   377 
   378 lemma suminf_minus: "summable f \<Longrightarrow> (\<Sum>n. - f n) = - (\<Sum>n. f n)"
   379   by (intro sums_unique [symmetric] sums_minus summable_sums)
   380 
   381 lemma sums_iff_shift: "(\<lambda>i. f (i + n)) sums s \<longleftrightarrow> f sums (s + (\<Sum>i<n. f i))"
   382 proof (induct n arbitrary: s)
   383   case (Suc n)
   384   moreover have "(\<lambda>i. f (Suc i + n)) sums s \<longleftrightarrow> (\<lambda>i. f (i + n)) sums (s + f n)"
   385     by (subst sums_Suc_iff) simp
   386   ultimately show ?case
   387     by (simp add: ac_simps)
   388 qed simp
   389 
   390 lemma summable_iff_shift: "summable (\<lambda>n. f (n + k)) \<longleftrightarrow> summable f"
   391   by (metis diff_add_cancel summable_def sums_iff_shift[abs_def])
   392 
   393 lemma sums_split_initial_segment: "f sums s \<Longrightarrow> (\<lambda>i. f (i + n)) sums (s - (\<Sum>i<n. f i))"
   394   by (simp add: sums_iff_shift)
   395 
   396 lemma summable_ignore_initial_segment: "summable f \<Longrightarrow> summable (\<lambda>n. f(n + k))"
   397   by (simp add: summable_iff_shift)
   398 
   399 lemma suminf_minus_initial_segment: "summable f \<Longrightarrow> (\<Sum>n. f (n + k)) = (\<Sum>n. f n) - (\<Sum>i<k. f i)"
   400   by (rule sums_unique[symmetric]) (auto simp: sums_iff_shift)
   401 
   402 lemma suminf_split_initial_segment: "summable f \<Longrightarrow> suminf f = (\<Sum>n. f(n + k)) + (\<Sum>i<k. f i)"
   403   by (auto simp add: suminf_minus_initial_segment)
   404 
   405 lemma suminf_split_head: "summable f \<Longrightarrow> (\<Sum>n. f (Suc n)) = suminf f - f 0"
   406   using suminf_split_initial_segment[of 1] by simp
   407 
   408 lemma suminf_exist_split:
   409   fixes r :: real assumes "0 < r" and "summable f"
   410   shows "\<exists>N. \<forall>n\<ge>N. norm (\<Sum>i. f (i + n)) < r"
   411 proof -
   412   from LIMSEQ_D[OF summable_LIMSEQ[OF \<open>summable f\<close>] \<open>0 < r\<close>]
   413   obtain N :: nat where "\<forall> n \<ge> N. norm (setsum f {..<n} - suminf f) < r" by auto
   414   thus ?thesis
   415     by (auto simp: norm_minus_commute suminf_minus_initial_segment[OF \<open>summable f\<close>])
   416 qed
   417 
   418 lemma summable_LIMSEQ_zero: "summable f \<Longrightarrow> f \<longlonglongrightarrow> 0"
   419   apply (drule summable_iff_convergent [THEN iffD1])
   420   apply (drule convergent_Cauchy)
   421   apply (simp only: Cauchy_iff LIMSEQ_iff, safe)
   422   apply (drule_tac x="r" in spec, safe)
   423   apply (rule_tac x="M" in exI, safe)
   424   apply (drule_tac x="Suc n" in spec, simp)
   425   apply (drule_tac x="n" in spec, simp)
   426   done
   427 
   428 lemma summable_imp_convergent: "summable f \<Longrightarrow> convergent f"
   429   by (force dest!: summable_LIMSEQ_zero simp: convergent_def)
   430 
   431 lemma summable_imp_Bseq: "summable f \<Longrightarrow> Bseq f"
   432   by (simp add: convergent_imp_Bseq summable_imp_convergent)
   433 
   434 end
   435 
   436 lemma summable_minus_iff:
   437   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   438   shows "summable (\<lambda>n. - f n) \<longleftrightarrow> summable f"
   439   by (auto dest: summable_minus) \<comment>\<open>used two ways, hence must be outside the context above\<close>
   440 
   441 lemma (in bounded_linear) sums: "(\<lambda>n. X n) sums a \<Longrightarrow> (\<lambda>n. f (X n)) sums (f a)"
   442   unfolding sums_def by (drule tendsto, simp only: setsum)
   443 
   444 lemma (in bounded_linear) summable: "summable (\<lambda>n. X n) \<Longrightarrow> summable (\<lambda>n. f (X n))"
   445   unfolding summable_def by (auto intro: sums)
   446 
   447 lemma (in bounded_linear) suminf: "summable (\<lambda>n. X n) \<Longrightarrow> f (\<Sum>n. X n) = (\<Sum>n. f (X n))"
   448   by (intro sums_unique sums summable_sums)
   449 
   450 lemmas sums_of_real = bounded_linear.sums [OF bounded_linear_of_real]
   451 lemmas summable_of_real = bounded_linear.summable [OF bounded_linear_of_real]
   452 lemmas suminf_of_real = bounded_linear.suminf [OF bounded_linear_of_real]
   453 
   454 lemmas sums_scaleR_left = bounded_linear.sums[OF bounded_linear_scaleR_left]
   455 lemmas summable_scaleR_left = bounded_linear.summable[OF bounded_linear_scaleR_left]
   456 lemmas suminf_scaleR_left = bounded_linear.suminf[OF bounded_linear_scaleR_left]
   457 
   458 lemmas sums_scaleR_right = bounded_linear.sums[OF bounded_linear_scaleR_right]
   459 lemmas summable_scaleR_right = bounded_linear.summable[OF bounded_linear_scaleR_right]
   460 lemmas suminf_scaleR_right = bounded_linear.suminf[OF bounded_linear_scaleR_right]
   461 
   462 lemma summable_const_iff: "summable (\<lambda>_. c) \<longleftrightarrow> (c :: 'a :: real_normed_vector) = 0"
   463 proof -
   464   {
   465     assume "c \<noteq> 0"
   466     hence "filterlim (\<lambda>n. of_nat n * norm c) at_top sequentially"
   467       by (subst mult.commute)
   468          (auto intro!: filterlim_tendsto_pos_mult_at_top filterlim_real_sequentially)
   469     hence "\<not>convergent (\<lambda>n. norm (\<Sum>k<n. c))"
   470       by (intro filterlim_at_infinity_imp_not_convergent filterlim_at_top_imp_at_infinity)
   471          (simp_all add: setsum_constant_scaleR)
   472     hence "\<not>summable (\<lambda>_. c)" unfolding summable_iff_convergent using convergent_norm by blast
   473   }
   474   thus ?thesis by auto
   475 qed
   476 
   477 
   478 subsection \<open>Infinite summability on real normed algebras\<close>
   479 
   480 context
   481   fixes f :: "nat \<Rightarrow> 'a::real_normed_algebra"
   482 begin
   483 
   484 lemma sums_mult: "f sums a \<Longrightarrow> (\<lambda>n. c * f n) sums (c * a)"
   485   by (rule bounded_linear.sums [OF bounded_linear_mult_right])
   486 
   487 lemma summable_mult: "summable f \<Longrightarrow> summable (\<lambda>n. c * f n)"
   488   by (rule bounded_linear.summable [OF bounded_linear_mult_right])
   489 
   490 lemma suminf_mult: "summable f \<Longrightarrow> suminf (\<lambda>n. c * f n) = c * suminf f"
   491   by (rule bounded_linear.suminf [OF bounded_linear_mult_right, symmetric])
   492 
   493 lemma sums_mult2: "f sums a \<Longrightarrow> (\<lambda>n. f n * c) sums (a * c)"
   494   by (rule bounded_linear.sums [OF bounded_linear_mult_left])
   495 
   496 lemma summable_mult2: "summable f \<Longrightarrow> summable (\<lambda>n. f n * c)"
   497   by (rule bounded_linear.summable [OF bounded_linear_mult_left])
   498 
   499 lemma suminf_mult2: "summable f \<Longrightarrow> suminf f * c = (\<Sum>n. f n * c)"
   500   by (rule bounded_linear.suminf [OF bounded_linear_mult_left])
   501 
   502 end
   503 
   504 lemma sums_mult_iff:
   505   assumes "c \<noteq> 0"
   506   shows   "(\<lambda>n. c * f n :: 'a :: {real_normed_algebra,field}) sums (c * d) \<longleftrightarrow> f sums d"
   507   using sums_mult[of f d c] sums_mult[of "\<lambda>n. c * f n" "c * d" "inverse c"]
   508   by (force simp: field_simps assms)
   509 
   510 lemma sums_mult2_iff:
   511   assumes "c \<noteq> (0 :: 'a :: {real_normed_algebra, field})"
   512   shows   "(\<lambda>n. f n * c) sums (d * c) \<longleftrightarrow> f sums d"
   513   using sums_mult_iff[OF assms, of f d] by (simp add: mult.commute)
   514 
   515 lemma sums_of_real_iff:
   516   "(\<lambda>n. of_real (f n) :: 'a :: real_normed_div_algebra) sums of_real c \<longleftrightarrow> f sums c"
   517   by (simp add: sums_def of_real_setsum[symmetric] tendsto_of_real_iff del: of_real_setsum)
   518 
   519 
   520 subsection \<open>Infinite summability on real normed fields\<close>
   521 
   522 context
   523   fixes c :: "'a::real_normed_field"
   524 begin
   525 
   526 lemma sums_divide: "f sums a \<Longrightarrow> (\<lambda>n. f n / c) sums (a / c)"
   527   by (rule bounded_linear.sums [OF bounded_linear_divide])
   528 
   529 lemma summable_divide: "summable f \<Longrightarrow> summable (\<lambda>n. f n / c)"
   530   by (rule bounded_linear.summable [OF bounded_linear_divide])
   531 
   532 lemma suminf_divide: "summable f \<Longrightarrow> suminf (\<lambda>n. f n / c) = suminf f / c"
   533   by (rule bounded_linear.suminf [OF bounded_linear_divide, symmetric])
   534 
   535 text\<open>Sum of a geometric progression.\<close>
   536 
   537 lemma geometric_sums: "norm c < 1 \<Longrightarrow> (\<lambda>n. c^n) sums (1 / (1 - c))"
   538 proof -
   539   assume less_1: "norm c < 1"
   540   hence neq_1: "c \<noteq> 1" by auto
   541   hence neq_0: "c - 1 \<noteq> 0" by simp
   542   from less_1 have lim_0: "(\<lambda>n. c^n) \<longlonglongrightarrow> 0"
   543     by (rule LIMSEQ_power_zero)
   544   hence "(\<lambda>n. c ^ n / (c - 1) - 1 / (c - 1)) \<longlonglongrightarrow> 0 / (c - 1) - 1 / (c - 1)"
   545     using neq_0 by (intro tendsto_intros)
   546   hence "(\<lambda>n. (c ^ n - 1) / (c - 1)) \<longlonglongrightarrow> 1 / (1 - c)"
   547     by (simp add: nonzero_minus_divide_right [OF neq_0] diff_divide_distrib)
   548   thus "(\<lambda>n. c ^ n) sums (1 / (1 - c))"
   549     by (simp add: sums_def geometric_sum neq_1)
   550 qed
   551 
   552 lemma summable_geometric: "norm c < 1 \<Longrightarrow> summable (\<lambda>n. c^n)"
   553   by (rule geometric_sums [THEN sums_summable])
   554 
   555 lemma suminf_geometric: "norm c < 1 \<Longrightarrow> suminf (\<lambda>n. c^n) = 1 / (1 - c)"
   556   by (rule sums_unique[symmetric]) (rule geometric_sums)
   557 
   558 lemma summable_geometric_iff: "summable (\<lambda>n. c ^ n) \<longleftrightarrow> norm c < 1"
   559 proof
   560   assume "summable (\<lambda>n. c ^ n :: 'a :: real_normed_field)"
   561   hence "(\<lambda>n. norm c ^ n) \<longlonglongrightarrow> 0"
   562     by (simp add: norm_power [symmetric] tendsto_norm_zero_iff summable_LIMSEQ_zero)
   563   from order_tendstoD(2)[OF this zero_less_one] obtain n where "norm c ^ n < 1"
   564     by (auto simp: eventually_at_top_linorder)
   565   thus "norm c < 1" using one_le_power[of "norm c" n] by (cases "norm c \<ge> 1") (linarith, simp)
   566 qed (rule summable_geometric)
   567 
   568 end
   569 
   570 lemma power_half_series: "(\<lambda>n. (1/2::real)^Suc n) sums 1"
   571 proof -
   572   have 2: "(\<lambda>n. (1/2::real)^n) sums 2" using geometric_sums [of "1/2::real"]
   573     by auto
   574   have "(\<lambda>n. (1/2::real)^Suc n) = (\<lambda>n. (1 / 2) ^ n / 2)"
   575     by (simp add: mult.commute)
   576   thus ?thesis using sums_divide [OF 2, of 2]
   577     by simp
   578 qed
   579 
   580 
   581 subsection \<open>Telescoping\<close>
   582 
   583 lemma telescope_sums:
   584   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   585   shows   "(\<lambda>n. f (Suc n) - f n) sums (c - f 0)"
   586   unfolding sums_def
   587 proof (subst LIMSEQ_Suc_iff [symmetric])
   588   have "(\<lambda>n. \<Sum>k<Suc n. f (Suc k) - f k) = (\<lambda>n. f (Suc n) - f 0)"
   589     by (simp add: lessThan_Suc_atMost atLeast0AtMost [symmetric] setsum_Suc_diff)
   590   also have "\<dots> \<longlonglongrightarrow> c - f 0" by (intro tendsto_diff LIMSEQ_Suc[OF assms] tendsto_const)
   591   finally show "(\<lambda>n. \<Sum>n<Suc n. f (Suc n) - f n) \<longlonglongrightarrow> c - f 0" .
   592 qed
   593 
   594 lemma telescope_sums':
   595   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   596   shows   "(\<lambda>n. f n - f (Suc n)) sums (f 0 - c)"
   597   using sums_minus[OF telescope_sums[OF assms]] by (simp add: algebra_simps)
   598 
   599 lemma telescope_summable:
   600   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   601   shows   "summable (\<lambda>n. f (Suc n) - f n)"
   602   using telescope_sums[OF assms] by (simp add: sums_iff)
   603 
   604 lemma telescope_summable':
   605   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   606   shows   "summable (\<lambda>n. f n - f (Suc n))"
   607   using summable_minus[OF telescope_summable[OF assms]] by (simp add: algebra_simps)
   608 
   609 
   610 subsection \<open>Infinite summability on Banach spaces\<close>
   611 
   612 text\<open>Cauchy-type criterion for convergence of series (c.f. Harrison)\<close>
   613 
   614 lemma summable_Cauchy:
   615   fixes f :: "nat \<Rightarrow> 'a::banach"
   616   shows "summable f \<longleftrightarrow> (\<forall>e>0. \<exists>N. \<forall>m\<ge>N. \<forall>n. norm (setsum f {m..<n}) < e)"
   617   apply (simp only: summable_iff_convergent Cauchy_convergent_iff [symmetric] Cauchy_iff, safe)
   618   apply (drule spec, drule (1) mp)
   619   apply (erule exE, rule_tac x="M" in exI, clarify)
   620   apply (rule_tac x="m" and y="n" in linorder_le_cases)
   621   apply (frule (1) order_trans)
   622   apply (drule_tac x="n" in spec, drule (1) mp)
   623   apply (drule_tac x="m" in spec, drule (1) mp)
   624   apply (simp_all add: setsum_diff [symmetric])
   625   apply (drule spec, drule (1) mp)
   626   apply (erule exE, rule_tac x="N" in exI, clarify)
   627   apply (rule_tac x="m" and y="n" in linorder_le_cases)
   628   apply (subst norm_minus_commute)
   629   apply (simp_all add: setsum_diff [symmetric])
   630   done
   631 
   632 context
   633   fixes f :: "nat \<Rightarrow> 'a::banach"
   634 begin
   635 
   636 text\<open>Absolute convergence imples normal convergence\<close>
   637 
   638 lemma summable_norm_cancel: "summable (\<lambda>n. norm (f n)) \<Longrightarrow> summable f"
   639   apply (simp only: summable_Cauchy, safe)
   640   apply (drule_tac x="e" in spec, safe)
   641   apply (rule_tac x="N" in exI, safe)
   642   apply (drule_tac x="m" in spec, safe)
   643   apply (rule order_le_less_trans [OF norm_setsum])
   644   apply (rule order_le_less_trans [OF abs_ge_self])
   645   apply simp
   646   done
   647 
   648 lemma summable_norm: "summable (\<lambda>n. norm (f n)) \<Longrightarrow> norm (suminf f) \<le> (\<Sum>n. norm (f n))"
   649   by (auto intro: LIMSEQ_le tendsto_norm summable_norm_cancel summable_LIMSEQ norm_setsum)
   650 
   651 text \<open>Comparison tests\<close>
   652 
   653 lemma summable_comparison_test: "\<exists>N. \<forall>n\<ge>N. norm (f n) \<le> g n \<Longrightarrow> summable g \<Longrightarrow> summable f"
   654   apply (simp add: summable_Cauchy, safe)
   655   apply (drule_tac x="e" in spec, safe)
   656   apply (rule_tac x = "N + Na" in exI, safe)
   657   apply (rotate_tac 2)
   658   apply (drule_tac x = m in spec)
   659   apply (auto, rotate_tac 2, drule_tac x = n in spec)
   660   apply (rule_tac y = "\<Sum>k=m..<n. norm (f k)" in order_le_less_trans)
   661   apply (rule norm_setsum)
   662   apply (rule_tac y = "setsum g {m..<n}" in order_le_less_trans)
   663   apply (auto intro: setsum_mono simp add: abs_less_iff)
   664   done
   665 
   666 lemma summable_comparison_test_ev:
   667   shows "eventually (\<lambda>n. norm (f n) \<le> g n) sequentially \<Longrightarrow> summable g \<Longrightarrow> summable f"
   668   by (rule summable_comparison_test) (auto simp: eventually_at_top_linorder)
   669 
   670 (*A better argument order*)
   671 lemma summable_comparison_test': "summable g \<Longrightarrow> (\<And>n. n \<ge> N \<Longrightarrow> norm(f n) \<le> g n) \<Longrightarrow> summable f"
   672   by (rule summable_comparison_test) auto
   673 
   674 subsection \<open>The Ratio Test\<close>
   675 
   676 lemma summable_ratio_test:
   677   assumes "c < 1" "\<And>n. n \<ge> N \<Longrightarrow> norm (f (Suc n)) \<le> c * norm (f n)"
   678   shows "summable f"
   679 proof cases
   680   assume "0 < c"
   681   show "summable f"
   682   proof (rule summable_comparison_test)
   683     show "\<exists>N'. \<forall>n\<ge>N'. norm (f n) \<le> (norm (f N) / (c ^ N)) * c ^ n"
   684     proof (intro exI allI impI)
   685       fix n assume "N \<le> n" then show "norm (f n) \<le> (norm (f N) / (c ^ N)) * c ^ n"
   686       proof (induct rule: inc_induct)
   687         case (step m)
   688         moreover have "norm (f (Suc m)) / c ^ Suc m * c ^ n \<le> norm (f m) / c ^ m * c ^ n"
   689           using \<open>0 < c\<close> \<open>c < 1\<close> assms(2)[OF \<open>N \<le> m\<close>] by (simp add: field_simps)
   690         ultimately show ?case by simp
   691       qed (insert \<open>0 < c\<close>, simp)
   692     qed
   693     show "summable (\<lambda>n. norm (f N) / c ^ N * c ^ n)"
   694       using \<open>0 < c\<close> \<open>c < 1\<close> by (intro summable_mult summable_geometric) simp
   695   qed
   696 next
   697   assume c: "\<not> 0 < c"
   698   { fix n assume "n \<ge> N"
   699     then have "norm (f (Suc n)) \<le> c * norm (f n)"
   700       by fact
   701     also have "\<dots> \<le> 0"
   702       using c by (simp add: not_less mult_nonpos_nonneg)
   703     finally have "f (Suc n) = 0"
   704       by auto }
   705   then show "summable f"
   706     by (intro sums_summable[OF sums_finite, of "{.. Suc N}"]) (auto simp: not_le Suc_less_eq2)
   707 qed
   708 
   709 end
   710 
   711 text\<open>Relations among convergence and absolute convergence for power series.\<close>
   712 
   713 lemma Abel_lemma:
   714   fixes a :: "nat \<Rightarrow> 'a::real_normed_vector"
   715   assumes r: "0 \<le> r" and r0: "r < r0" and M: "\<And>n. norm (a n) * r0^n \<le> M"
   716     shows "summable (\<lambda>n. norm (a n) * r^n)"
   717 proof (rule summable_comparison_test')
   718   show "summable (\<lambda>n. M * (r / r0) ^ n)"
   719     using assms
   720     by (auto simp add: summable_mult summable_geometric)
   721 next
   722   fix n
   723   show "norm (norm (a n) * r ^ n) \<le> M * (r / r0) ^ n"
   724     using r r0 M [of n]
   725     apply (auto simp add: abs_mult field_simps)
   726     apply (cases "r=0", simp)
   727     apply (cases n, auto)
   728     done
   729 qed
   730 
   731 
   732 text\<open>Summability of geometric series for real algebras\<close>
   733 
   734 lemma complete_algebra_summable_geometric:
   735   fixes x :: "'a::{real_normed_algebra_1,banach}"
   736   shows "norm x < 1 \<Longrightarrow> summable (\<lambda>n. x ^ n)"
   737 proof (rule summable_comparison_test)
   738   show "\<exists>N. \<forall>n\<ge>N. norm (x ^ n) \<le> norm x ^ n"
   739     by (simp add: norm_power_ineq)
   740   show "norm x < 1 \<Longrightarrow> summable (\<lambda>n. norm x ^ n)"
   741     by (simp add: summable_geometric)
   742 qed
   743 
   744 subsection \<open>Cauchy Product Formula\<close>
   745 
   746 text \<open>
   747   Proof based on Analysis WebNotes: Chapter 07, Class 41
   748   @{url "http://www.math.unl.edu/~webnotes/classes/class41/prp77.htm"}
   749 \<close>
   750 
   751 lemma Cauchy_product_sums:
   752   fixes a b :: "nat \<Rightarrow> 'a::{real_normed_algebra,banach}"
   753   assumes a: "summable (\<lambda>k. norm (a k))"
   754   assumes b: "summable (\<lambda>k. norm (b k))"
   755   shows "(\<lambda>k. \<Sum>i\<le>k. a i * b (k - i)) sums ((\<Sum>k. a k) * (\<Sum>k. b k))"
   756 proof -
   757   let ?S1 = "\<lambda>n::nat. {..<n} \<times> {..<n}"
   758   let ?S2 = "\<lambda>n::nat. {(i,j). i + j < n}"
   759   have S1_mono: "\<And>m n. m \<le> n \<Longrightarrow> ?S1 m \<subseteq> ?S1 n" by auto
   760   have S2_le_S1: "\<And>n. ?S2 n \<subseteq> ?S1 n" by auto
   761   have S1_le_S2: "\<And>n. ?S1 (n div 2) \<subseteq> ?S2 n" by auto
   762   have finite_S1: "\<And>n. finite (?S1 n)" by simp
   763   with S2_le_S1 have finite_S2: "\<And>n. finite (?S2 n)" by (rule finite_subset)
   764 
   765   let ?g = "\<lambda>(i,j). a i * b j"
   766   let ?f = "\<lambda>(i,j). norm (a i) * norm (b j)"
   767   have f_nonneg: "\<And>x. 0 \<le> ?f x" by (auto)
   768   hence norm_setsum_f: "\<And>A. norm (setsum ?f A) = setsum ?f A"
   769     unfolding real_norm_def
   770     by (simp only: abs_of_nonneg setsum_nonneg [rule_format])
   771 
   772   have "(\<lambda>n. (\<Sum>k<n. a k) * (\<Sum>k<n. b k)) \<longlonglongrightarrow> (\<Sum>k. a k) * (\<Sum>k. b k)"
   773     by (intro tendsto_mult summable_LIMSEQ summable_norm_cancel [OF a] summable_norm_cancel [OF b])
   774   hence 1: "(\<lambda>n. setsum ?g (?S1 n)) \<longlonglongrightarrow> (\<Sum>k. a k) * (\<Sum>k. b k)"
   775     by (simp only: setsum_product setsum.Sigma [rule_format] finite_lessThan)
   776 
   777   have "(\<lambda>n. (\<Sum>k<n. norm (a k)) * (\<Sum>k<n. norm (b k))) \<longlonglongrightarrow> (\<Sum>k. norm (a k)) * (\<Sum>k. norm (b k))"
   778     using a b by (intro tendsto_mult summable_LIMSEQ)
   779   hence "(\<lambda>n. setsum ?f (?S1 n)) \<longlonglongrightarrow> (\<Sum>k. norm (a k)) * (\<Sum>k. norm (b k))"
   780     by (simp only: setsum_product setsum.Sigma [rule_format] finite_lessThan)
   781   hence "convergent (\<lambda>n. setsum ?f (?S1 n))"
   782     by (rule convergentI)
   783   hence Cauchy: "Cauchy (\<lambda>n. setsum ?f (?S1 n))"
   784     by (rule convergent_Cauchy)
   785   have "Zfun (\<lambda>n. setsum ?f (?S1 n - ?S2 n)) sequentially"
   786   proof (rule ZfunI, simp only: eventually_sequentially norm_setsum_f)
   787     fix r :: real
   788     assume r: "0 < r"
   789     from CauchyD [OF Cauchy r] obtain N
   790     where "\<forall>m\<ge>N. \<forall>n\<ge>N. norm (setsum ?f (?S1 m) - setsum ?f (?S1 n)) < r" ..
   791     hence "\<And>m n. \<lbrakk>N \<le> n; n \<le> m\<rbrakk> \<Longrightarrow> norm (setsum ?f (?S1 m - ?S1 n)) < r"
   792       by (simp only: setsum_diff finite_S1 S1_mono)
   793     hence N: "\<And>m n. \<lbrakk>N \<le> n; n \<le> m\<rbrakk> \<Longrightarrow> setsum ?f (?S1 m - ?S1 n) < r"
   794       by (simp only: norm_setsum_f)
   795     show "\<exists>N. \<forall>n\<ge>N. setsum ?f (?S1 n - ?S2 n) < r"
   796     proof (intro exI allI impI)
   797       fix n assume "2 * N \<le> n"
   798       hence n: "N \<le> n div 2" by simp
   799       have "setsum ?f (?S1 n - ?S2 n) \<le> setsum ?f (?S1 n - ?S1 (n div 2))"
   800         by (intro setsum_mono2 finite_Diff finite_S1 f_nonneg
   801                   Diff_mono subset_refl S1_le_S2)
   802       also have "\<dots> < r"
   803         using n div_le_dividend by (rule N)
   804       finally show "setsum ?f (?S1 n - ?S2 n) < r" .
   805     qed
   806   qed
   807   hence "Zfun (\<lambda>n. setsum ?g (?S1 n - ?S2 n)) sequentially"
   808     apply (rule Zfun_le [rule_format])
   809     apply (simp only: norm_setsum_f)
   810     apply (rule order_trans [OF norm_setsum setsum_mono])
   811     apply (auto simp add: norm_mult_ineq)
   812     done
   813   hence 2: "(\<lambda>n. setsum ?g (?S1 n) - setsum ?g (?S2 n)) \<longlonglongrightarrow> 0"
   814     unfolding tendsto_Zfun_iff diff_0_right
   815     by (simp only: setsum_diff finite_S1 S2_le_S1)
   816 
   817   with 1 have "(\<lambda>n. setsum ?g (?S2 n)) \<longlonglongrightarrow> (\<Sum>k. a k) * (\<Sum>k. b k)"
   818     by (rule Lim_transform2)
   819   thus ?thesis by (simp only: sums_def setsum_triangle_reindex)
   820 qed
   821 
   822 lemma Cauchy_product:
   823   fixes a b :: "nat \<Rightarrow> 'a::{real_normed_algebra,banach}"
   824   assumes a: "summable (\<lambda>k. norm (a k))"
   825   assumes b: "summable (\<lambda>k. norm (b k))"
   826   shows "(\<Sum>k. a k) * (\<Sum>k. b k) = (\<Sum>k. \<Sum>i\<le>k. a i * b (k - i))"
   827   using a b
   828   by (rule Cauchy_product_sums [THEN sums_unique])
   829 
   830 lemma summable_Cauchy_product:
   831   assumes "summable (\<lambda>k. norm (a k :: 'a :: {real_normed_algebra,banach}))"
   832           "summable (\<lambda>k. norm (b k))"
   833   shows   "summable (\<lambda>k. \<Sum>i\<le>k. a i * b (k - i))"
   834   using Cauchy_product_sums[OF assms] by (simp add: sums_iff)
   835 
   836 subsection \<open>Series on @{typ real}s\<close>
   837 
   838 lemma summable_norm_comparison_test: "\<exists>N. \<forall>n\<ge>N. norm (f n) \<le> g n \<Longrightarrow> summable g \<Longrightarrow> summable (\<lambda>n. norm (f n))"
   839   by (rule summable_comparison_test) auto
   840 
   841 lemma summable_rabs_comparison_test: "\<lbrakk>\<exists>N. \<forall>n\<ge>N. \<bar>f n\<bar> \<le> g n; summable g\<rbrakk> \<Longrightarrow> summable (\<lambda>n. \<bar>f n :: real\<bar>)"
   842   by (rule summable_comparison_test) auto
   843 
   844 lemma summable_rabs_cancel: "summable (\<lambda>n. \<bar>f n :: real\<bar>) \<Longrightarrow> summable f"
   845   by (rule summable_norm_cancel) simp
   846 
   847 lemma summable_rabs: "summable (\<lambda>n. \<bar>f n :: real\<bar>) \<Longrightarrow> \<bar>suminf f\<bar> \<le> (\<Sum>n. \<bar>f n\<bar>)"
   848   by (fold real_norm_def) (rule summable_norm)
   849 
   850 lemma summable_zero_power [simp]: "summable (\<lambda>n. 0 ^ n :: 'a :: {comm_ring_1,topological_space})"
   851 proof -
   852   have "(\<lambda>n. 0 ^ n :: 'a) = (\<lambda>n. if n = 0 then 0^0 else 0)" by (intro ext) (simp add: zero_power)
   853   moreover have "summable \<dots>" by simp
   854   ultimately show ?thesis by simp
   855 qed
   856 
   857 lemma summable_zero_power' [simp]: "summable (\<lambda>n. f n * 0 ^ n :: 'a :: {ring_1,topological_space})"
   858 proof -
   859   have "(\<lambda>n. f n * 0 ^ n :: 'a) = (\<lambda>n. if n = 0 then f 0 * 0^0 else 0)"
   860     by (intro ext) (simp add: zero_power)
   861   moreover have "summable \<dots>" by simp
   862   ultimately show ?thesis by simp
   863 qed
   864 
   865 lemma summable_power_series:
   866   fixes z :: real
   867   assumes le_1: "\<And>i. f i \<le> 1" and nonneg: "\<And>i. 0 \<le> f i" and z: "0 \<le> z" "z < 1"
   868   shows "summable (\<lambda>i. f i * z^i)"
   869 proof (rule summable_comparison_test[OF _ summable_geometric])
   870   show "norm z < 1" using z by (auto simp: less_imp_le)
   871   show "\<And>n. \<exists>N. \<forall>na\<ge>N. norm (f na * z ^ na) \<le> z ^ na"
   872     using z by (auto intro!: exI[of _ 0] mult_left_le_one_le simp: abs_mult nonneg power_abs less_imp_le le_1)
   873 qed
   874 
   875 lemma summable_0_powser:
   876   "summable (\<lambda>n. f n * 0 ^ n :: 'a :: real_normed_div_algebra)"
   877 proof -
   878   have A: "(\<lambda>n. f n * 0 ^ n) = (\<lambda>n. if n = 0 then f n else 0)"
   879     by (intro ext) auto
   880   thus ?thesis by (subst A) simp_all
   881 qed
   882 
   883 lemma summable_powser_split_head:
   884   "summable (\<lambda>n. f (Suc n) * z ^ n :: 'a :: real_normed_div_algebra) = summable (\<lambda>n. f n * z ^ n)"
   885 proof -
   886   have "summable (\<lambda>n. f (Suc n) * z ^ n) \<longleftrightarrow> summable (\<lambda>n. f (Suc n) * z ^ Suc n)"
   887   proof
   888     assume "summable (\<lambda>n. f (Suc n) * z ^ n)"
   889     from summable_mult2[OF this, of z] show "summable (\<lambda>n. f (Suc n) * z ^ Suc n)"
   890       by (simp add: power_commutes algebra_simps)
   891   next
   892     assume "summable (\<lambda>n. f (Suc n) * z ^ Suc n)"
   893     from summable_mult2[OF this, of "inverse z"] show "summable (\<lambda>n. f (Suc n) * z ^ n)"
   894       by (cases "z \<noteq> 0", subst (asm) power_Suc2) (simp_all add: algebra_simps)
   895   qed
   896   also have "\<dots> \<longleftrightarrow> summable (\<lambda>n. f n * z ^ n)" by (rule summable_Suc_iff)
   897   finally show ?thesis .
   898 qed
   899 
   900 lemma powser_split_head:
   901   assumes "summable (\<lambda>n. f n * z ^ n :: 'a :: {real_normed_div_algebra,banach})"
   902   shows   "suminf (\<lambda>n. f n * z ^ n) = f 0 + suminf (\<lambda>n. f (Suc n) * z ^ n) * z"
   903           "suminf (\<lambda>n. f (Suc n) * z ^ n) * z = suminf (\<lambda>n. f n * z ^ n) - f 0"
   904           "summable (\<lambda>n. f (Suc n) * z ^ n)"
   905 proof -
   906   from assms show "summable (\<lambda>n. f (Suc n) * z ^ n)" by (subst summable_powser_split_head)
   907 
   908   from suminf_mult2[OF this, of z]
   909     have "(\<Sum>n. f (Suc n) * z ^ n) * z = (\<Sum>n. f (Suc n) * z ^ Suc n)"
   910     by (simp add: power_commutes algebra_simps)
   911   also from assms have "\<dots> = suminf (\<lambda>n. f n * z ^ n) - f 0"
   912     by (subst suminf_split_head) simp_all
   913   finally show "suminf (\<lambda>n. f n * z ^ n) = f 0 + suminf (\<lambda>n. f (Suc n) * z ^ n) * z" by simp
   914   thus "suminf (\<lambda>n. f (Suc n) * z ^ n) * z = suminf (\<lambda>n. f n * z ^ n) - f 0" by simp
   915 qed
   916 
   917 lemma summable_partial_sum_bound:
   918   fixes f :: "nat \<Rightarrow> 'a :: banach"
   919   assumes summable: "summable f" and e: "e > (0::real)"
   920   obtains N where "\<And>m n. m \<ge> N \<Longrightarrow> norm (\<Sum>k=m..n. f k) < e"
   921 proof -
   922   from summable have "Cauchy (\<lambda>n. \<Sum>k<n. f k)"
   923     by (simp add: Cauchy_convergent_iff summable_iff_convergent)
   924   from CauchyD[OF this e] obtain N
   925     where N: "\<And>m n. m \<ge> N \<Longrightarrow> n \<ge> N \<Longrightarrow> norm ((\<Sum>k<m. f k) - (\<Sum>k<n. f k)) < e" by blast
   926   {
   927     fix m n :: nat assume m: "m \<ge> N"
   928     have "norm (\<Sum>k=m..n. f k) < e"
   929     proof (cases "n \<ge> m")
   930       assume n: "n \<ge> m"
   931       with m have "norm ((\<Sum>k<Suc n. f k) - (\<Sum>k<m. f k)) < e" by (intro N) simp_all
   932       also from n have "(\<Sum>k<Suc n. f k) - (\<Sum>k<m. f k) = (\<Sum>k=m..n. f k)"
   933         by (subst setsum_diff [symmetric]) (simp_all add: setsum_last_plus)
   934       finally show ?thesis .
   935     qed (insert e, simp_all)
   936   }
   937   thus ?thesis by (rule that)
   938 qed
   939 
   940 lemma powser_sums_if:
   941   "(\<lambda>n. (if n = m then (1 :: 'a :: {ring_1,topological_space}) else 0) * z^n) sums z^m"
   942 proof -
   943   have "(\<lambda>n. (if n = m then 1 else 0) * z^n) = (\<lambda>n. if n = m then z^n else 0)"
   944     by (intro ext) auto
   945   thus ?thesis by (simp add: sums_single)
   946 qed
   947 
   948 lemma
   949    fixes f :: "nat \<Rightarrow> real"
   950    assumes "summable f"
   951    and "inj g"
   952    and pos: "\<And>x. 0 \<le> f x"
   953    shows summable_reindex: "summable (f o g)"
   954    and suminf_reindex_mono: "suminf (f o g) \<le> suminf f"
   955    and suminf_reindex: "(\<And>x. x \<notin> range g \<Longrightarrow> f x = 0) \<Longrightarrow> suminf (f \<circ> g) = suminf f"
   956 proof -
   957   from \<open>inj g\<close> have [simp]: "\<And>A. inj_on g A" by(rule subset_inj_on) simp
   958 
   959   have smaller: "\<forall>n. (\<Sum>i<n. (f \<circ> g) i) \<le> suminf f"
   960   proof
   961     fix n
   962     have "\<forall> n' \<in> (g ` {..<n}). n' < Suc (Max (g ` {..<n}))"
   963       by(metis Max_ge finite_imageI finite_lessThan not_le not_less_eq)
   964     then obtain m where n: "\<And>n'. n' < n \<Longrightarrow> g n' < m" by blast
   965 
   966     have "(\<Sum>i<n. f (g i)) = setsum f (g ` {..<n})"
   967       by (simp add: setsum.reindex)
   968     also have "\<dots> \<le> (\<Sum>i<m. f i)"
   969       by (rule setsum_mono3) (auto simp add: pos n[rule_format])
   970     also have "\<dots> \<le> suminf f"
   971       using \<open>summable f\<close>
   972       by (rule setsum_le_suminf) (simp add: pos)
   973     finally show "(\<Sum>i<n. (f \<circ>  g) i) \<le> suminf f" by simp
   974   qed
   975 
   976   have "incseq (\<lambda>n. \<Sum>i<n. (f \<circ> g) i)"
   977     by (rule incseq_SucI) (auto simp add: pos)
   978   then obtain  L where L: "(\<lambda> n. \<Sum>i<n. (f \<circ> g) i) \<longlonglongrightarrow> L"
   979     using smaller by(rule incseq_convergent)
   980   hence "(f \<circ> g) sums L" by (simp add: sums_def)
   981   thus "summable (f o g)" by (auto simp add: sums_iff)
   982 
   983   hence "(\<lambda>n. \<Sum>i<n. (f \<circ> g) i) \<longlonglongrightarrow> suminf (f \<circ> g)"
   984     by(rule summable_LIMSEQ)
   985   thus le: "suminf (f \<circ> g) \<le> suminf f"
   986     by(rule LIMSEQ_le_const2)(blast intro: smaller[rule_format])
   987 
   988   assume f: "\<And>x. x \<notin> range g \<Longrightarrow> f x = 0"
   989 
   990   from \<open>summable f\<close> have "suminf f \<le> suminf (f \<circ> g)"
   991   proof(rule suminf_le_const)
   992     fix n
   993     have "\<forall> n' \<in> (g -` {..<n}). n' < Suc (Max (g -` {..<n}))"
   994       by(auto intro: Max_ge simp add: finite_vimageI less_Suc_eq_le)
   995     then obtain m where n: "\<And>n'. g n' < n \<Longrightarrow> n' < m" by blast
   996 
   997     have "(\<Sum>i<n. f i) = (\<Sum>i\<in>{..<n} \<inter> range g. f i)"
   998       using f by(auto intro: setsum.mono_neutral_cong_right)
   999     also have "\<dots> = (\<Sum>i\<in>g -` {..<n}. (f \<circ> g) i)"
  1000       by(rule setsum.reindex_cong[where l=g])(auto)
  1001     also have "\<dots> \<le> (\<Sum>i<m. (f \<circ> g) i)"
  1002       by(rule setsum_mono3)(auto simp add: pos n)
  1003     also have "\<dots> \<le> suminf (f \<circ> g)"
  1004       using \<open>summable (f o g)\<close>
  1005       by(rule setsum_le_suminf)(simp add: pos)
  1006     finally show "setsum f {..<n} \<le> suminf (f \<circ> g)" .
  1007   qed
  1008   with le show "suminf (f \<circ> g) = suminf f" by(rule antisym)
  1009 qed
  1010 
  1011 lemma sums_mono_reindex:
  1012   assumes subseq: "subseq g" and zero: "\<And>n. n \<notin> range g \<Longrightarrow> f n = 0"
  1013   shows   "(\<lambda>n. f (g n)) sums c \<longleftrightarrow> f sums c"
  1014 unfolding sums_def
  1015 proof
  1016   assume lim: "(\<lambda>n. \<Sum>k<n. f k) \<longlonglongrightarrow> c"
  1017   have "(\<lambda>n. \<Sum>k<n. f (g k)) = (\<lambda>n. \<Sum>k<g n. f k)"
  1018   proof
  1019     fix n :: nat
  1020     from subseq have "(\<Sum>k<n. f (g k)) = (\<Sum>k\<in>g`{..<n}. f k)"
  1021       by (subst setsum.reindex) (auto intro: subseq_imp_inj_on)
  1022     also from subseq have "\<dots> = (\<Sum>k<g n. f k)"
  1023       by (intro setsum.mono_neutral_left ballI zero)
  1024          (auto dest: subseq_strict_mono simp: strict_mono_less strict_mono_less_eq)
  1025     finally show "(\<Sum>k<n. f (g k)) = (\<Sum>k<g n. f k)" .
  1026   qed
  1027   also from LIMSEQ_subseq_LIMSEQ[OF lim subseq] have "\<dots> \<longlonglongrightarrow> c" unfolding o_def .
  1028   finally show "(\<lambda>n. \<Sum>k<n. f (g k)) \<longlonglongrightarrow> c" .
  1029 next
  1030   assume lim: "(\<lambda>n. \<Sum>k<n. f (g k)) \<longlonglongrightarrow> c"
  1031   def g_inv \<equiv> "\<lambda>n. LEAST m. g m \<ge> n"
  1032   from filterlim_subseq[OF subseq] have g_inv_ex: "\<exists>m. g m \<ge> n" for n
  1033     by (auto simp: filterlim_at_top eventually_at_top_linorder)
  1034   hence g_inv: "g (g_inv n) \<ge> n" for n unfolding g_inv_def by (rule LeastI_ex)
  1035   have g_inv_least: "m \<ge> g_inv n" if "g m \<ge> n" for m n using that
  1036     unfolding g_inv_def by (rule Least_le)
  1037   have g_inv_least': "g m < n" if "m < g_inv n" for m n using that g_inv_least[of n m] by linarith
  1038   have "(\<lambda>n. \<Sum>k<n. f k) = (\<lambda>n. \<Sum>k<g_inv n. f (g k))"
  1039   proof
  1040     fix n :: nat
  1041     {
  1042       fix k assume k: "k \<in> {..<n} - g`{..<g_inv n}"
  1043       have "k \<notin> range g"
  1044       proof (rule notI, elim imageE)
  1045         fix l assume l: "k = g l"
  1046         have "g l < g (g_inv n)" by (rule less_le_trans[OF _ g_inv]) (insert k l, simp_all)
  1047         with subseq have "l < g_inv n" by (simp add: subseq_strict_mono strict_mono_less)
  1048         with k l show False by simp
  1049       qed
  1050       hence "f k = 0" by (rule zero)
  1051     }
  1052     with g_inv_least' g_inv have "(\<Sum>k<n. f k) = (\<Sum>k\<in>g`{..<g_inv n}. f k)"
  1053       by (intro setsum.mono_neutral_right) auto
  1054     also from subseq have "\<dots> = (\<Sum>k<g_inv n. f (g k))" using subseq_imp_inj_on
  1055       by (subst setsum.reindex) simp_all
  1056     finally show "(\<Sum>k<n. f k) = (\<Sum>k<g_inv n. f (g k))" .
  1057   qed
  1058   also {
  1059     fix K n :: nat assume "g K \<le> n"
  1060     also have "n \<le> g (g_inv n)" by (rule g_inv)
  1061     finally have "K \<le> g_inv n" using subseq by (simp add: strict_mono_less_eq subseq_strict_mono)
  1062   }
  1063   hence "filterlim g_inv at_top sequentially"
  1064     by (auto simp: filterlim_at_top eventually_at_top_linorder)
  1065   from lim and this have "(\<lambda>n. \<Sum>k<g_inv n. f (g k)) \<longlonglongrightarrow> c" by (rule filterlim_compose)
  1066   finally show "(\<lambda>n. \<Sum>k<n. f k) \<longlonglongrightarrow> c" .
  1067 qed
  1068 
  1069 lemma summable_mono_reindex:
  1070   assumes subseq: "subseq g" and zero: "\<And>n. n \<notin> range g \<Longrightarrow> f n = 0"
  1071   shows   "summable (\<lambda>n. f (g n)) \<longleftrightarrow> summable f"
  1072   using sums_mono_reindex[of g f, OF assms] by (simp add: summable_def)
  1073 
  1074 lemma suminf_mono_reindex:
  1075   assumes "subseq g" "\<And>n. n \<notin> range g \<Longrightarrow> f n = (0 :: 'a :: {t2_space,comm_monoid_add})"
  1076   shows   "suminf (\<lambda>n. f (g n)) = suminf f"
  1077 proof (cases "summable f")
  1078   case False
  1079   hence "\<not>(\<exists>c. f sums c)" unfolding summable_def by blast
  1080   hence "suminf f = The (\<lambda>_. False)" by (simp add: suminf_def)
  1081   moreover from False have "\<not>summable (\<lambda>n. f (g n))"
  1082     using summable_mono_reindex[of g f, OF assms] by simp
  1083   hence "\<not>(\<exists>c. (\<lambda>n. f (g n)) sums c)" unfolding summable_def by blast
  1084   hence "suminf (\<lambda>n. f (g n)) = The (\<lambda>_. False)" by (simp add: suminf_def)
  1085   ultimately show ?thesis by simp
  1086 qed (insert sums_mono_reindex[of g f, OF assms] summable_mono_reindex[of g f, OF assms],
  1087      simp_all add: sums_iff)
  1088 
  1089 end