src/Tools/quickcheck.ML
author blanchet
Fri Dec 18 14:02:58 2009 +0100 (2009-12-18)
changeset 34128 8650a073dd9b
parent 33583 b5e0909cd5ea
child 34948 2d5f2a9f7601
permissions -rw-r--r--
made Quickcheck take structured proof assumptions into account (like Refute and Nitpick) by default;
up to now, only Auto Quickcheck did -- the old behavior is available by passing "no_assms" as option
     1 (*  Title:      Tools/quickcheck.ML
     2     Author:     Stefan Berghofer, Florian Haftmann, TU Muenchen
     3 
     4 Generic counterexample search engine.
     5 *)
     6 
     7 signature QUICKCHECK =
     8 sig
     9   val auto: bool Unsynchronized.ref
    10   val test_term: Proof.context -> bool -> string option -> int -> int -> term ->
    11     (string * term) list option
    12   val add_generator: string * (Proof.context -> term -> int -> term list option) -> theory -> theory
    13   val setup: theory -> theory
    14   val quickcheck: (string * string) list -> int -> Proof.state -> (string * term) list option
    15 end;
    16 
    17 structure Quickcheck : QUICKCHECK =
    18 struct
    19 
    20 (* preferences *)
    21 
    22 val auto = Unsynchronized.ref false;
    23 
    24 val _ =
    25   ProofGeneralPgip.add_preference Preferences.category_tracing
    26   (setmp_CRITICAL auto true (fn () =>
    27     Preferences.bool_pref auto
    28       "auto-quickcheck"
    29       "Whether to run Quickcheck automatically.") ());
    30 
    31 
    32 (* quickcheck configuration -- default parameters, test generators *)
    33 
    34 datatype test_params = Test_Params of
    35   { size: int, iterations: int, default_type: typ option, no_assms: bool };
    36 
    37 fun dest_test_params (Test_Params { size, iterations, default_type, no_assms }) =
    38   ((size, iterations), (default_type, no_assms));
    39 fun make_test_params ((size, iterations), (default_type, no_assms)) =
    40   Test_Params { size = size, iterations = iterations, default_type = default_type,
    41                 no_assms = no_assms };
    42 fun map_test_params f (Test_Params { size, iterations, default_type, no_assms }) =
    43   make_test_params (f ((size, iterations), (default_type, no_assms)));
    44 fun merge_test_params (Test_Params { size = size1, iterations = iterations1, default_type = default_type1,
    45                                      no_assms = no_assms1 },
    46   Test_Params { size = size2, iterations = iterations2, default_type = default_type2,
    47                 no_assms = no_assms2 }) =
    48   make_test_params ((Int.max (size1, size2), Int.max (iterations1, iterations2)),
    49     (case default_type1 of NONE => default_type2 | _ => default_type1, no_assms1 orelse no_assms2));
    50 
    51 structure Data = Theory_Data
    52 (
    53   type T = (string * (Proof.context -> term -> int -> term list option)) list
    54     * test_params;
    55   val empty = ([], Test_Params { size = 10, iterations = 100, default_type = NONE, no_assms = false });
    56   val extend = I;
    57   fun merge ((generators1, params1), (generators2, params2)) : T =
    58     (AList.merge (op =) (K true) (generators1, generators2),
    59       merge_test_params (params1, params2));
    60 );
    61 
    62 val add_generator = Data.map o apfst o AList.update (op =);
    63 
    64 
    65 (* generating tests *)
    66 
    67 fun mk_tester_select name ctxt =
    68   case AList.lookup (op =) ((fst o Data.get o ProofContext.theory_of) ctxt) name
    69    of NONE => error ("No such quickcheck generator: " ^ name)
    70     | SOME generator => generator ctxt;
    71 
    72 fun mk_testers ctxt t =
    73   (map snd o fst o Data.get o ProofContext.theory_of) ctxt
    74   |> map_filter (fn generator => try (generator ctxt) t);
    75 
    76 fun mk_testers_strict ctxt t =
    77   let
    78     val generators = ((map snd o fst o Data.get o ProofContext.theory_of) ctxt)
    79     val testers = map (fn generator => Exn.capture (generator ctxt) t) generators;
    80   in if forall (is_none o Exn.get_result) testers
    81     then [(Exn.release o snd o split_last) testers]
    82     else map_filter Exn.get_result testers
    83   end;
    84 
    85 
    86 (* testing propositions *)
    87 
    88 fun prep_test_term t =
    89   let
    90     val _ = (null (Term.add_tvars t []) andalso null (Term.add_tfrees t [])) orelse
    91       error "Term to be tested contains type variables";
    92     val _ = null (Term.add_vars t []) orelse
    93       error "Term to be tested contains schematic variables";
    94     val frees = Term.add_frees t [];
    95   in (map fst frees, list_abs_free (frees, t)) end
    96 
    97 fun test_term ctxt quiet generator_name size i t =
    98   let
    99     val (names, t') = prep_test_term t;
   100     val testers = case generator_name
   101      of NONE => if quiet then mk_testers ctxt t' else mk_testers_strict ctxt t'
   102       | SOME name => [mk_tester_select name ctxt t'];
   103     fun iterate f 0 = NONE
   104       | iterate f j = case f () handle Match => (if quiet then ()
   105              else warning "Exception Match raised during quickcheck"; NONE)
   106           of NONE => iterate f (j - 1) | SOME q => SOME q;
   107     fun with_testers k [] = NONE
   108       | with_testers k (tester :: testers) =
   109           case iterate (fn () => tester (k - 1)) i
   110            of NONE => with_testers k testers
   111             | SOME q => SOME q;
   112     fun with_size k = if k > size then NONE
   113       else (if quiet then () else priority ("Test data size: " ^ string_of_int k);
   114         case with_testers k testers
   115          of NONE => with_size (k + 1) | SOME q => SOME q);
   116   in case with_size 1
   117    of NONE => NONE
   118     | SOME ts => SOME (names ~~ ts)
   119   end;
   120 
   121 fun monomorphic_term thy insts default_T = 
   122   let
   123     fun subst (T as TFree (v, S)) =
   124           let
   125             val T' = AList.lookup (op =) insts v
   126               |> the_default (the_default T default_T)
   127           in if Sign.of_sort thy (T, S) then T'
   128             else error ("Type " ^ Syntax.string_of_typ_global thy T ^
   129               " to be substituted for variable " ^
   130               Syntax.string_of_typ_global thy T ^ "\ndoes not have sort " ^
   131               Syntax.string_of_sort_global thy S)
   132           end
   133       | subst T = T;
   134   in (map_types o map_atyps) subst end;
   135 
   136 fun test_goal quiet generator_name size iterations default_T no_assms insts i assms state =
   137   let
   138     val ctxt = Proof.context_of state;
   139     val thy = Proof.theory_of state;
   140     fun strip (Const ("all", _) $ Abs (_, _, t)) = strip t
   141       | strip t = t;
   142     val {goal = st, ...} = Proof.raw_goal state;
   143     val (gi, frees) = Logic.goal_params (prop_of st) i;
   144     val gi' = Logic.list_implies (if no_assms then [] else assms,
   145                                   subst_bounds (frees, strip gi))
   146       |> monomorphic_term thy insts default_T
   147       |> ObjectLogic.atomize_term thy;
   148   in test_term ctxt quiet generator_name size iterations gi' end;
   149 
   150 fun pretty_counterex ctxt NONE = Pretty.str "No counterexamples found."
   151   | pretty_counterex ctxt (SOME cex) =
   152       Pretty.chunks (Pretty.str "Counterexample found:\n" ::
   153         map (fn (s, t) =>
   154           Pretty.block [Pretty.str (s ^ " ="), Pretty.brk 1, Syntax.pretty_term ctxt t]) cex);
   155 
   156 
   157 (* automatic testing *)
   158 
   159 fun auto_quickcheck state =
   160   if not (!auto) then
   161     (false, state)
   162   else
   163     let
   164       val ctxt = Proof.context_of state;
   165       val assms = map term_of (Assumption.all_assms_of ctxt);
   166       val Test_Params { size, iterations, default_type, no_assms } =
   167         (snd o Data.get o Proof.theory_of) state;
   168       val res =
   169         try (test_goal true NONE size iterations default_type no_assms [] 1 assms) state;
   170     in
   171       case res of
   172         NONE => (false, state)
   173       | SOME NONE => (false, state)
   174       | SOME cex => (true, Proof.goal_message (K (Pretty.chunks [Pretty.str "",
   175           Pretty.mark Markup.hilite (pretty_counterex ctxt cex)])) state)
   176     end
   177 
   178 val setup = Auto_Counterexample.register_tool ("quickcheck", auto_quickcheck)
   179 
   180 
   181 (* Isar commands *)
   182 
   183 fun read_nat s = case (Library.read_int o Symbol.explode) s
   184  of (k, []) => if k >= 0 then k
   185       else error ("Not a natural number: " ^ s)
   186   | (_, _ :: _) => error ("Not a natural number: " ^ s);
   187 fun read_bool "false" = false
   188   | read_bool "true" = true
   189   | read_bool s = error ("Not a Boolean value: " ^ s)
   190 
   191 fun parse_test_param ctxt ("size", arg) =
   192       (apfst o apfst o K) (read_nat arg)
   193   | parse_test_param ctxt ("iterations", arg) =
   194       (apfst o apsnd o K) (read_nat arg)
   195   | parse_test_param ctxt ("default_type", arg) =
   196       (apsnd o apfst o K o SOME) (ProofContext.read_typ ctxt arg)
   197   | parse_test_param ctxt ("no_assms", arg) =
   198       (apsnd o apsnd o K) (read_bool arg)
   199   | parse_test_param ctxt (name, _) =
   200       error ("Unknown test parameter: " ^ name);
   201 
   202 fun parse_test_param_inst ctxt ("generator", arg) =
   203       (apsnd o apfst o K o SOME) arg
   204   | parse_test_param_inst ctxt (name, arg) =
   205       case try (ProofContext.read_typ ctxt) name
   206        of SOME (TFree (v, _)) => (apsnd o apsnd o AList.update (op =))
   207               (v, ProofContext.read_typ ctxt arg)
   208         | _ => (apfst o parse_test_param ctxt) (name, arg);
   209 
   210 fun quickcheck_params_cmd args thy =
   211   let
   212     val ctxt = ProofContext.init thy;
   213     val f = fold (parse_test_param ctxt) args;
   214   in
   215     thy
   216     |> (Data.map o apsnd o map_test_params) f
   217   end;
   218 
   219 fun quickcheck args i state =
   220   let
   221     val thy = Proof.theory_of state;
   222     val ctxt = Proof.context_of state;
   223     val assms = map term_of (Assumption.all_assms_of ctxt);
   224     val default_params = (dest_test_params o snd o Data.get) thy;
   225     val f = fold (parse_test_param_inst ctxt) args;
   226     val (((size, iterations), (default_type, no_assms)), (generator_name, insts)) =
   227       f (default_params, (NONE, []));
   228   in
   229     test_goal false generator_name size iterations default_type no_assms insts i assms state
   230   end;
   231 
   232 fun quickcheck_cmd args i state =
   233   quickcheck args i (Toplevel.proof_of state)
   234   |> Pretty.writeln o pretty_counterex (Toplevel.context_of state);
   235 
   236 local structure P = OuterParse and K = OuterKeyword in
   237 
   238 val parse_arg = P.name -- (Scan.optional (P.$$$ "=" |-- P.name) "true")
   239 
   240 val parse_args = P.$$$ "[" |-- P.list1 parse_arg --| P.$$$ "]"
   241   || Scan.succeed [];
   242 
   243 val _ = OuterSyntax.command "quickcheck_params" "set parameters for random testing" K.thy_decl
   244   (parse_args >> (fn args => Toplevel.theory (quickcheck_params_cmd args)));
   245 
   246 val _ = OuterSyntax.improper_command "quickcheck" "try to find counterexample for subgoal" K.diag
   247   (parse_args -- Scan.optional P.nat 1
   248     >> (fn (args, i) => Toplevel.no_timing o Toplevel.keep (quickcheck_cmd args i)));
   249 
   250 end; (*local*)
   251 
   252 end;
   253 
   254 
   255 val auto_quickcheck = Quickcheck.auto;