src/Pure/library.ML
author haftmann
Tue Oct 10 13:59:13 2006 +0200 (2006-10-10)
changeset 20951 868120282837
parent 20882 90b3f8047f55
child 20972 db0425645cc7
permissions -rw-r--r--
gen_rem(s) abandoned in favour of remove / subtract
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, balanced trees, orders, current directory, misc.
     8 *)
     9 
    10 infix 1 |> |-> ||> ||>> |>> |>>> #> #->;
    11 infix 2 ?;
    12 infix 3 o oo ooo oooo;
    13 
    14 infix 4 ~~ upto downto;
    15 infix orf andf \ \\ mem mem_int mem_string union union_int
    16   union_string inter inter_int inter_string subset subset_int subset_string;
    17 
    18 signature BASIC_LIBRARY =
    19 sig
    20   (*functions*)
    21   val I: 'a -> 'a
    22   val K: 'a -> 'b -> 'a
    23   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    24   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    25   val |> : 'a * ('a -> 'b) -> 'b
    26   val |-> : ('c * 'a) * ('c -> 'a -> 'b) -> 'b
    27   val ||> : ('c * 'a) * ('a -> 'b) -> 'c * 'b
    28   val ||>> : ('c * 'a) * ('a -> 'd * 'b) -> ('c * 'd) * 'b
    29   val |>> : ('a * 'c) * ('a -> 'b) -> 'b * 'c
    30   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    31   val #> : ('a -> 'b) * ('b -> 'c) -> 'a -> 'c
    32   val #-> : ('a -> 'c * 'b) * ('c -> 'b -> 'd) -> 'a -> 'd
    33   val ? : ('a -> bool) * ('a -> 'a) -> 'a -> 'a
    34   val ` : ('b -> 'a) -> 'b -> 'a * 'b
    35   val tap: ('b -> 'a) -> 'b -> 'b
    36   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    37   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    38   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    39   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    40 
    41   (*options*)
    42   val the: 'a option -> 'a
    43   val these: 'a list option -> 'a list
    44   val the_default: 'a -> 'a option -> 'a
    45   val the_list: 'a option -> 'a list
    46   val is_some: 'a option -> bool
    47   val is_none: 'a option -> bool
    48   val perhaps: ('a -> 'a option) -> 'a -> 'a
    49   val merge_opt: ('a * 'a -> bool) -> 'a option * 'a option -> 'a option
    50 
    51   (*exceptions*)
    52   val try: ('a -> 'b) -> 'a -> 'b option
    53   val can: ('a -> 'b) -> 'a -> bool
    54   exception EXCEPTION of exn * string
    55   val do_transform_failure: bool ref
    56   val transform_failure: (exn -> exn) -> ('a -> 'b) -> 'a -> 'b
    57   datatype 'a result = Result of 'a | Exn of exn
    58   val capture: ('a -> 'b) -> 'a -> 'b result
    59   val release: 'a result -> 'a
    60   val get_result: 'a result -> 'a option
    61   val get_exn: 'a result -> exn option
    62 
    63   (*errors*)
    64   exception SYS_ERROR of string
    65   val sys_error: string -> 'a
    66   exception ERROR of string
    67   val error: string -> 'a
    68   val cat_error: string -> string -> 'a
    69   val assert: bool -> string -> unit
    70   val deny: bool -> string -> unit
    71   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    72 
    73   (*pairs*)
    74   val pair: 'a -> 'b -> 'a * 'b
    75   val rpair: 'a -> 'b -> 'b * 'a
    76   val fst: 'a * 'b -> 'a
    77   val snd: 'a * 'b -> 'b
    78   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    79   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    80   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    81   val swap: 'a * 'b -> 'b * 'a
    82   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    83   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    84   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    85   val string_of_pair: ('a -> string) -> ('b -> string) -> 'a * 'b -> string
    86 
    87   (*booleans*)
    88   val equal: ''a -> ''a -> bool
    89   val not_equal: ''a -> ''a -> bool
    90   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    91   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    92   val exists: ('a -> bool) -> 'a list -> bool
    93   val forall: ('a -> bool) -> 'a list -> bool
    94   val set: bool ref -> bool
    95   val reset: bool ref -> bool
    96   val toggle: bool ref -> bool
    97   val change: 'a ref -> ('a -> 'a) -> unit
    98   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    99   val conditional: bool -> (unit -> unit) -> unit
   100 
   101   (*lists*)
   102   exception UnequalLengths
   103   val cons: 'a -> 'a list -> 'a list
   104   val single: 'a -> 'a list
   105   val the_single: 'a list -> 'a
   106   val singleton: ('a list -> 'b list) -> 'a -> 'b
   107   val append: 'a list -> 'a list -> 'a list
   108   val apply: ('a -> 'a) list -> 'a -> 'a
   109   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   110   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   111   val fold_map: ('a -> 'b -> 'c * 'b) -> 'a list -> 'b -> 'c list * 'b
   112   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
   113   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   114   val flat: 'a list list -> 'a list
   115   val maps: ('a -> 'b list) -> 'a list -> 'b list
   116   val unflat: 'a list list -> 'b list -> 'b list list
   117   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
   118   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
   119   val chop: int -> 'a list -> 'a list * 'a list
   120   val dropwhile: ('a -> bool) -> 'a list -> 'a list
   121   val nth: 'a list -> int -> 'a
   122   val nth_update: int * 'a -> 'a list -> 'a list
   123   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
   124   val nth_list: 'a list list -> int -> 'a list
   125   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
   126   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   127   val split_last: 'a list -> 'a list * 'a
   128   val find_index: ('a -> bool) -> 'a list -> int
   129   val find_index_eq: ''a -> ''a list -> int
   130   val find_first: ('a -> bool) -> 'a list -> 'a option
   131   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
   132   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   133   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   134   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   135   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   136   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   137   val ~~ : 'a list * 'b list -> ('a * 'b) list
   138   val split_list: ('a * 'b) list -> 'a list * 'b list
   139   val separate: 'a -> 'a list -> 'a list
   140   val replicate: int -> 'a -> 'a list
   141   val multiply: 'a list -> 'a list list -> 'a list list
   142   val product: 'a list -> 'b list -> ('a * 'b) list
   143   val filter: ('a -> bool) -> 'a list -> 'a list
   144   val filter_out: ('a -> bool) -> 'a list -> 'a list
   145   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
   146   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   147   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   148   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   149   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   150   val prefixes1: 'a list -> 'a list list
   151   val prefixes: 'a list -> 'a list list
   152   val suffixes1: 'a list -> 'a list list
   153   val suffixes: 'a list -> 'a list list
   154 
   155   (*integers*)
   156   val gcd: IntInf.int * IntInf.int -> IntInf.int
   157   val lcm: IntInf.int * IntInf.int -> IntInf.int
   158   val inc: int ref -> int
   159   val dec: int ref -> int
   160   val upto: int * int -> int list
   161   val downto: int * int -> int list
   162   val downto0: int list * int -> bool
   163   val radixpand: int * int -> int list
   164   val radixstring: int * string * int -> string
   165   val string_of_int: int -> string
   166   val string_of_indexname: string * int -> string
   167   val read_intinf: int -> string list -> IntInf.int * string list
   168   val read_int: string list -> int * string list
   169   val oct_char: string -> string
   170 
   171   (*strings*)
   172   val nth_string: string -> int -> string
   173   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   174   val exists_string: (string -> bool) -> string -> bool
   175   val forall_string: (string -> bool) -> string -> bool
   176   val enclose: string -> string -> string -> string
   177   val unenclose: string -> string
   178   val quote: string -> string
   179   val space_implode: string -> string list -> string
   180   val commas: string list -> string
   181   val commas_quote: string list -> string
   182   val cat_lines: string list -> string
   183   val space_explode: string -> string -> string list
   184   val split_lines: string -> string list
   185   val prefix_lines: string -> string -> string
   186   val untabify: string list -> string list
   187   val prefix: string -> string -> string
   188   val suffix: string -> string -> string
   189   val unprefix: string -> string -> string
   190   val unsuffix: string -> string -> string
   191   val replicate_string: int -> string -> string
   192   val translate_string: (string -> string) -> string -> string
   193   val string_of_list: ('a -> string) -> 'a list -> string
   194   val string_of_option: ('a -> string) -> 'a option -> string
   195 
   196   (*lists as sets -- see also Pure/General/ord_list.ML*)
   197   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   198   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   199   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   200   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   201   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   202   val mem: ''a * ''a list -> bool
   203   val mem_int: int * int list -> bool
   204   val mem_string: string * string list -> bool
   205   val union: ''a list * ''a list -> ''a list
   206   val union_int: int list * int list -> int list
   207   val union_string: string list * string list -> string list
   208   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   209   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   210   val inter: ''a list * ''a list -> ''a list
   211   val inter_int: int list * int list -> int list
   212   val inter_string: string list * string list -> string list
   213   val subset: ''a list * ''a list -> bool
   214   val subset_int: int list * int list -> bool
   215   val subset_string: string list * string list -> bool
   216   val eq_set: ''a list * ''a list -> bool
   217   val eq_set_string: string list * string list -> bool
   218   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   219   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   220   val \ : ''a list * ''a -> ''a list
   221   val \\ : ''a list * ''a list -> ''a list
   222   val findrep: ''a list -> ''a list
   223   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   224   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   225   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   226 
   227   (*lists as tables -- see also Pure/General/alist.ML*)
   228   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   229   val merge_lists: ''a list -> ''a list -> ''a list
   230   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   231 
   232   (*balanced trees*)
   233   exception Balance
   234   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   235   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   236   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   237 
   238   (*orders*)
   239   val is_equal: order -> bool
   240   val rev_order: order -> order
   241   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   242   val int_ord: int * int -> order
   243   val string_ord: string * string -> order
   244   val fast_string_ord: string * string -> order
   245   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   246   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   247   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   248   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   249   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   250   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   251   val sort_strings: string list -> string list
   252   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   253 
   254   (*random numbers*)
   255   exception RANDOM
   256   val random: unit -> real
   257   val random_range: int -> int -> int
   258   val one_of: 'a list -> 'a
   259   val frequency: (int * 'a) list -> 'a
   260 
   261   (*current directory*)
   262   val cd: string -> unit
   263   val pwd: unit -> string
   264 
   265   (*misc*)
   266   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   267   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   268   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   269   val gensym: string -> string
   270   val scanwords: (string -> bool) -> string list -> string list
   271   type stamp
   272   val stamp: unit -> stamp
   273   type serial
   274   val serial: unit -> serial
   275   val serial_string: unit -> string
   276   structure Object: sig type T end
   277 end;
   278 
   279 signature LIBRARY =
   280 sig
   281   include BASIC_LIBRARY
   282   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   283   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   284   val take: int * 'a list -> 'a list
   285   val drop: int * 'a list -> 'a list
   286   val last_elem: 'a list -> 'a
   287   val seq: ('a -> unit) -> 'a list -> unit
   288 end;
   289 
   290 structure Library: LIBRARY =
   291 struct
   292 
   293 
   294 (** functions **)
   295 
   296 fun I x = x;
   297 fun K x = fn _ => x;
   298 fun curry f x y = f (x, y);
   299 fun uncurry f (x, y) = f x y;
   300 
   301 (*reverse application and structured results*)
   302 fun x |> f = f x;
   303 fun (x, y) |-> f = f x y;
   304 fun (x, y) |>> f = (f x, y);
   305 fun (x, y) ||> f = (x, f y);
   306 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   307 fun (x, y) ||>> f = let val (z, y') = f y in ((x, z), y') end;
   308 
   309 (*reverse composition*)
   310 fun f #> g = g o f;
   311 fun f #-> g = uncurry g o f;
   312 
   313 (*conditional application*)
   314 fun b ? f = fn x => if b x then f x else x;
   315 
   316 (*view results*)
   317 fun `f = fn x => (f x, x);
   318 fun tap f = fn x => (f x; x);
   319 
   320 (*composition with multiple args*)
   321 fun (f oo g) x y = f (g x y);
   322 fun (f ooo g) x y z = f (g x y z);
   323 fun (f oooo g) x y z w = f (g x y z w);
   324 
   325 (*function exponentiation: f(...(f x)...) with n applications of f*)
   326 fun funpow n f x =
   327   let fun rep (0, x) = x
   328         | rep (n, x) = rep (n - 1, f x)
   329   in rep (n, x) end;
   330 
   331 
   332 (** options **)
   333 
   334 val the = Option.valOf;
   335 
   336 fun these (SOME x) = x
   337   | these _ = [];
   338 
   339 fun the_default x (SOME y) = y
   340   | the_default x _ = x;
   341 
   342 fun the_list (SOME x) = [x]
   343   | the_list _ = []
   344 
   345 fun is_some (SOME _) = true
   346   | is_some NONE = false;
   347 
   348 fun is_none (SOME _) = false
   349   | is_none NONE = true;
   350 
   351 fun perhaps f x = the_default x (f x);
   352 
   353 fun merge_opt _ (NONE, y) = y
   354   | merge_opt _ (x, NONE) = x
   355   | merge_opt eq (SOME x, SOME y) = if eq (x, y) then SOME y else raise Option;
   356 
   357 
   358 (* exceptions *)
   359 
   360 val do_transform_failure = ref true;
   361 
   362 fun transform_failure exn f x =
   363   if ! do_transform_failure then
   364     f x handle Interrupt => raise Interrupt | e => raise exn e
   365   else f x;
   366 
   367 exception EXCEPTION of exn * string;
   368 
   369 
   370 fun try f x = SOME (f x)
   371   handle Interrupt => raise Interrupt | _ => NONE;
   372 
   373 fun can f x = is_some (try f x);
   374 
   375 
   376 datatype 'a result =
   377   Result of 'a |
   378   Exn of exn;
   379 
   380 fun capture f x = Result (f x) handle e => Exn e;
   381 
   382 fun release (Result y) = y
   383   | release (Exn e) = raise e;
   384 
   385 fun get_result (Result x) = SOME x
   386   | get_result _ = NONE;
   387 
   388 fun get_exn (Exn exn) = SOME exn
   389   | get_exn _ = NONE;
   390 
   391 
   392 (* errors *)
   393 
   394 exception SYS_ERROR of string;
   395 fun sys_error msg = raise SYS_ERROR msg;
   396 
   397 exception ERROR of string;
   398 fun error msg = raise ERROR msg;
   399 
   400 fun cat_error "" msg = error msg
   401   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   402 
   403 fun assert p msg = if p then () else error msg;
   404 fun deny p msg = if p then error msg else ();
   405 
   406 fun assert_all pred list msg =
   407   let
   408     fun ass [] = ()
   409       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   410   in ass list end;
   411 
   412 
   413 (** pairs **)
   414 
   415 fun pair x y = (x, y);
   416 fun rpair x y = (y, x);
   417 
   418 fun fst (x, y) = x;
   419 fun snd (x, y) = y;
   420 
   421 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   422 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   423 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   424 
   425 fun swap (x, y) = (y, x);
   426 
   427 (*apply function to components*)
   428 fun apfst f (x, y) = (f x, y);
   429 fun apsnd f (x, y) = (x, f y);
   430 fun pairself f (x, y) = (f x, f y);
   431 
   432 fun string_of_pair f1 f2 (x, y) = "(" ^ f1 x ^ ", " ^ f2 y ^ ")";
   433 
   434 
   435 (** booleans **)
   436 
   437 (* equality *)
   438 
   439 fun equal x y = x = y;
   440 fun not_equal x y = x <> y;
   441 
   442 (* operators for combining predicates *)
   443 
   444 fun p orf q = fn x => p x orelse q x;
   445 fun p andf q = fn x => p x andalso q x;
   446 
   447 (* predicates on lists *)
   448 
   449 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   450 fun exists (pred: 'a -> bool) : 'a list -> bool =
   451   let fun boolf [] = false
   452         | boolf (x :: xs) = pred x orelse boolf xs
   453   in boolf end;
   454 
   455 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   456 fun forall (pred: 'a -> bool) : 'a list -> bool =
   457   let fun boolf [] = true
   458         | boolf (x :: xs) = pred x andalso boolf xs
   459   in boolf end;
   460 
   461 
   462 (* flags *)
   463 
   464 fun set flag = (flag := true; true);
   465 fun reset flag = (flag := false; false);
   466 fun toggle flag = (flag := not (! flag); ! flag);
   467 
   468 fun change r f = r := f (! r);
   469 
   470 (*temporarily set flag during execution*)
   471 fun setmp flag value f x =
   472   let
   473     val orig_value = ! flag;
   474     val _ = flag := value;
   475     val result = capture f x;
   476     val _ = flag := orig_value;
   477   in release result end;
   478 
   479 
   480 (* conditional execution *)
   481 
   482 fun conditional b f = if b then f () else ();
   483 
   484 
   485 (** lists **)
   486 
   487 exception UnequalLengths;
   488 
   489 fun cons x xs = x :: xs;
   490 
   491 fun single x = [x];
   492 
   493 fun the_single [x] = x
   494   | the_single _ = raise Empty;
   495 
   496 fun singleton f x = the_single (f [x]);
   497 
   498 fun append xs ys = xs @ ys;
   499 
   500 fun apply [] x = x
   501   | apply (f :: fs) x = apply fs (f x);
   502 
   503 
   504 (* fold *)
   505 
   506 fun fold f =
   507   let
   508     fun fold_aux [] y = y
   509       | fold_aux (x :: xs) y = fold_aux xs (f x y);
   510   in fold_aux end;
   511 
   512 fun fold_rev f =
   513   let
   514     fun fold_aux [] y = y
   515       | fold_aux (x :: xs) y = f x (fold_aux xs y);
   516   in fold_aux end;
   517 
   518 fun fold_map f =
   519   let
   520     fun fold_aux [] y = ([], y)
   521       | fold_aux (x :: xs) y =
   522           let
   523             val (x', y') = f x y;
   524             val (xs', y'') = fold_aux xs y';
   525           in (x' :: xs', y'') end;
   526   in fold_aux end;
   527 
   528 (*the following versions of fold are designed to fit nicely with infixes*)
   529 
   530 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   531     for operators that associate to the left (TAIL RECURSIVE)*)
   532 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   533   let fun itl (e, [])  = e
   534         | itl (e, a::l) = itl (f(e, a), l)
   535   in  itl end;
   536 
   537 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   538     for operators that associate to the right (not tail recursive)*)
   539 fun foldr f (l, e) =
   540   let fun itr [] = e
   541         | itr (a::l) = f(a, itr l)
   542   in  itr l  end;
   543 
   544 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   545     for n > 0, operators that associate to the right (not tail recursive)*)
   546 fun foldr1 f [] = raise Empty
   547   | foldr1 f l =
   548       let fun itr [x] = x
   549             | itr (x::l) = f(x, itr l)
   550       in  itr l  end;
   551 
   552 fun fold_index f =
   553   let
   554     fun fold_aux _ [] y = y
   555       | fold_aux i (x :: xs) y = fold_aux (i+1) xs (f (i, x) y);
   556   in fold_aux 0 end;
   557 
   558 fun foldl_map f =
   559   let
   560     fun fold_aux (x, []) = (x, [])
   561       | fold_aux (x, y :: ys) =
   562           let
   563             val (x', y') = f (x, y);
   564             val (x'', ys') = fold_aux (x', ys);
   565           in (x'', y' :: ys') end;
   566   in fold_aux end;
   567 
   568 
   569 (* basic list functions *)
   570 
   571 fun eq_list eq (list1, list2) =
   572   let
   573     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   574       | eq_lst _ = true;
   575   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   576 
   577 fun maps f [] = []
   578   | maps f (x :: xs) = f x @ maps f xs;
   579 
   580 fun chop 0 xs = ([], xs)
   581   | chop _ [] = ([], [])
   582   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   583 
   584 (*take the first n elements from a list*)
   585 fun take (n, []) = []
   586   | take (n, x :: xs) =
   587       if n > 0 then x :: take (n - 1, xs) else [];
   588 
   589 (*drop the first n elements from a list*)
   590 fun drop (n, []) = []
   591   | drop (n, x :: xs) =
   592       if n > 0 then drop (n - 1, xs) else x :: xs;
   593 
   594 fun dropwhile P [] = []
   595   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   596 
   597 (*return nth element of a list, where 0 designates the first element;
   598   raise Subscript if list too short*)
   599 fun nth xs i = List.nth (xs, i);
   600 
   601 fun nth_list xss i = nth xss i handle Subscript => [];
   602 
   603 (*update nth element*)
   604 fun nth_update (n, x) xs =
   605   (case chop n xs of
   606     (_, []) => raise Subscript
   607   | (prfx, _ :: sffx') => prfx @ (x :: sffx'));
   608 
   609 fun nth_map 0 f (x :: xs) = f x :: xs
   610   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   611   | nth_map _ _ [] = raise Subscript;
   612 
   613 fun map_index f =
   614   let
   615     fun mapp _ [] = []
   616       | mapp i (x :: xs) = f (i, x) :: mapp (i+1) xs
   617   in mapp 0 end;
   618 
   619 val last_elem = List.last;
   620 
   621 (*rear decomposition*)
   622 fun split_last [] = raise Empty
   623   | split_last [x] = ([], x)
   624   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   625 
   626 (*find the position of an element in a list*)
   627 fun find_index pred =
   628   let fun find _ [] = ~1
   629         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   630   in find 0 end;
   631 
   632 fun find_index_eq x = find_index (equal x);
   633 
   634 (*find first element satisfying predicate*)
   635 fun find_first _ [] = NONE
   636   | find_first pred (x :: xs) =
   637       if pred x then SOME x else find_first pred xs;
   638 
   639 (*get first element by lookup function*)
   640 fun get_first _ [] = NONE
   641   | get_first f (x :: xs) =
   642       (case f x of
   643         NONE => get_first f xs
   644       | some => some);
   645 
   646 fun get_index f =
   647   let
   648     fun get _ [] = NONE
   649       | get i (x :: xs) =
   650           case f x
   651            of NONE => get (i + 1) xs
   652             | SOME y => SOME (i, y)
   653   in get 0 end;
   654 
   655 val flat = List.concat;
   656 
   657 fun unflat (xs :: xss) ys =
   658       let val (ps, qs) = chop (length xs) ys
   659       in ps :: unflat xss qs end
   660   | unflat [] [] = []
   661   | unflat _ _ = raise UnequalLengths;
   662 
   663 fun burrow f xss =
   664   unflat xss ((f o flat) xss);
   665 
   666 fun fold_burrow f xss s =
   667   apfst (unflat xss) (f (flat xss) s);
   668 
   669 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   670   (proc x1; ...; proc xn) for side effects*)
   671 val seq = List.app;
   672 
   673 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   674 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   675   | separate _ xs = xs;
   676 
   677 (*make the list [x, x, ..., x] of length n*)
   678 fun replicate n (x: 'a) : 'a list =
   679   let fun rep (0, xs) = xs
   680         | rep (n, xs) = rep (n - 1, x :: xs)
   681   in
   682     if n < 0 then raise Subscript
   683     else rep (n, [])
   684   end;
   685 
   686 fun translate_string f = String.translate (f o String.str);
   687 
   688 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   689 fun multiply [] _ = []
   690   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   691 
   692 (*direct product*)
   693 fun product _ [] = []
   694   | product [] _ = []
   695   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   696 
   697 
   698 (* filter *)
   699 
   700 (*copy the list preserving elements that satisfy the predicate*)
   701 val filter = List.filter;
   702 fun filter_out f = filter (not o f);
   703 val map_filter = List.mapPartial;
   704 
   705 
   706 (* lists of pairs *)
   707 
   708 exception UnequalLengths;
   709 
   710 fun map2 _ [] [] = []
   711   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   712   | map2 _ _ _ = raise UnequalLengths;
   713 
   714 fun fold2 f =
   715   let
   716     fun fold_aux [] [] z = z
   717       | fold_aux (x :: xs) (y :: ys) z = fold_aux xs ys (f x y z)
   718       | fold_aux _ _ _ = raise UnequalLengths;
   719   in fold_aux end;
   720 
   721 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   722   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   723   | zip_options _ [] = []
   724   | zip_options [] _ = raise UnequalLengths;
   725 
   726 (*combine two lists forming a list of pairs:
   727   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   728 fun [] ~~ [] = []
   729   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   730   | _ ~~ _ = raise UnequalLengths;
   731 
   732 (*inverse of ~~; the old 'split':
   733   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   734 val split_list = ListPair.unzip;
   735 
   736 
   737 (* prefixes, suffixes *)
   738 
   739 fun is_prefix _ [] _ = true
   740   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   741   | is_prefix eq _ _ = false;
   742 
   743 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   744    where xi is the first element that does not satisfy the predicate*)
   745 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   746   let fun take (rxs, []) = (rev rxs, [])
   747         | take (rxs, x :: xs) =
   748             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   749   in  take([], xs)  end;
   750 
   751 fun chop_prefix eq ([], ys) = ([], ([], ys))
   752   | chop_prefix eq (xs, []) = ([], (xs, []))
   753   | chop_prefix eq (xs as x::xs', ys as y::ys') =
   754       if eq (x, y) then
   755         let val (ps', xys'') = chop_prefix eq (xs', ys')
   756         in (x::ps', xys'') end
   757       else ([], (xs, ys));
   758 
   759 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   760    where xi is the last element that does not satisfy the predicate*)
   761 fun take_suffix _ [] = ([], [])
   762   | take_suffix pred (x :: xs) =
   763       (case take_suffix pred xs of
   764         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   765       | (prfx, sffx) => (x :: prfx, sffx));
   766 
   767 fun prefixes1 [] = []
   768   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   769 
   770 fun prefixes xs = [] :: prefixes1 xs;
   771 
   772 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   773 fun suffixes xs = [] :: suffixes1 xs;
   774 
   775 
   776 (** integers **)
   777 
   778 fun gcd (x, y) =
   779   let fun gxd x y : IntInf.int =
   780     if y = 0 then x else gxd y (x mod y)
   781   in if x < y then gxd y x else gxd x y end;
   782 
   783 fun lcm (x, y) = (x * y) div gcd (x, y);
   784 
   785 fun inc i = (i := ! i + 1; ! i);
   786 fun dec i = (i := ! i - 1; ! i);
   787 
   788 
   789 (* lists of integers *)
   790 
   791 (*make the list [from, from + 1, ..., to]*)
   792 fun (from upto to) =
   793   if from > to then [] else from :: ((from + 1) upto to);
   794 
   795 (*make the list [from, from - 1, ..., to]*)
   796 fun (from downto to) =
   797   if from < to then [] else from :: ((from - 1) downto to);
   798 
   799 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   800 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   801   | downto0 ([], n) = n = ~1;
   802 
   803 
   804 (* convert integers to strings *)
   805 
   806 (*expand the number in the given base;
   807   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   808 fun radixpand (base, num) : int list =
   809   let
   810     fun radix (n, tail) =
   811       if n < base then n :: tail
   812       else radix (n div base, (n mod base) :: tail)
   813   in radix (num, []) end;
   814 
   815 (*expands a number into a string of characters starting from "zerochar";
   816   example: radixstring (2, "0", 8) gives "1000"*)
   817 fun radixstring (base, zerochar, num) =
   818   let val offset = ord zerochar;
   819       fun chrof n = chr (offset + n)
   820   in implode (map chrof (radixpand (base, num))) end;
   821 
   822 
   823 val string_of_int = Int.toString;
   824 
   825 fun string_of_indexname (a,0) = a
   826   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   827 
   828 
   829 (* read integers *)
   830 
   831 fun read_intinf radix cs =
   832   let
   833     val zero = ord "0";
   834     val limit = zero + radix;
   835     fun scan (num, []) = (num, [])
   836       | scan (num, c :: cs) =
   837         if zero <= ord c andalso ord c < limit then
   838           scan (IntInf.fromInt radix * num + IntInf.fromInt (ord c - zero), cs)
   839         else (num, c :: cs);
   840   in scan (0, cs) end;
   841 
   842 fun read_int cs = apfst IntInf.toInt (read_intinf 10 cs);
   843 
   844 fun oct_char s = chr (IntInf.toInt (#1 (read_intinf 8 (explode s))));
   845 
   846 
   847 
   848 (** strings **)
   849 
   850 (* functions tuned for strings, avoiding explode *)
   851 
   852 fun nth_string str i =
   853   (case try String.substring (str, i, 1) of
   854     SOME s => s
   855   | NONE => raise Subscript);
   856 
   857 fun fold_string f str x0 =
   858   let
   859     val n = size str;
   860     fun iter (x, i) =
   861       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   862   in iter (x0, 0) end;
   863 
   864 fun exists_string pred str =
   865   let
   866     val n = size str;
   867     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   868   in ex 0 end;
   869 
   870 fun forall_string pred = not o exists_string (not o pred);
   871 
   872 (*enclose in brackets*)
   873 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   874 fun unenclose str = String.substring (str, 1, size str - 2);
   875 
   876 (*simple quoting (does not escape special chars)*)
   877 val quote = enclose "\"" "\"";
   878 
   879 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   880 fun space_implode a bs = implode (separate a bs);
   881 
   882 val commas = space_implode ", ";
   883 val commas_quote = commas o map quote;
   884 
   885 (*concatenate messages, one per line, into a string*)
   886 val cat_lines = space_implode "\n";
   887 
   888 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   889 fun space_explode _ "" = []
   890   | space_explode sep str =
   891       let
   892         fun expl chs =
   893           (case take_prefix (fn s => s <> sep) chs of
   894             (cs, []) => [implode cs]
   895           | (cs, _ :: cs') => implode cs :: expl cs');
   896       in expl (explode str) end;
   897 
   898 val split_lines = space_explode "\n";
   899 
   900 fun prefix_lines "" txt = txt
   901   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   902 
   903 fun untabify chs =
   904   let
   905     val tab_width = 8;
   906 
   907     fun untab (_, "\n") = (0, ["\n"])
   908       | untab (pos, "\t") =
   909           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   910       | untab (pos, c) = (pos + 1, [c]);
   911   in
   912     if not (exists (fn c => c = "\t") chs) then chs
   913     else flat (#2 (foldl_map untab (0, chs)))
   914   end;
   915 
   916 fun prefix prfx s = prfx ^ s;
   917 fun suffix sffx s = s ^ sffx;
   918 
   919 fun unprefix prfx s =
   920   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   921   else raise Fail "unprefix";
   922 
   923 fun unsuffix sffx s =
   924   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   925   else raise Fail "unsuffix";
   926 
   927 fun replicate_string 0 _ = ""
   928   | replicate_string 1 a = a
   929   | replicate_string k a =
   930       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   931       else replicate_string (k div 2) (a ^ a) ^ a;
   932 
   933 fun string_of_list f = enclose "[" "]" o commas o map f;
   934 
   935 fun string_of_option f NONE = "NONE"
   936   | string_of_option f (SOME x) = "SOME (" ^ f x ^ ")";
   937 
   938 
   939 
   940 (** lists as sets -- see also Pure/General/ord_list.ML **)
   941 
   942 (*canonical member, insert, remove*)
   943 fun member eq list x =
   944   let
   945     fun memb [] = false
   946       | memb (y :: ys) = eq (x, y) orelse memb ys;
   947   in memb list end;
   948 
   949 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   950 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   951 
   952 fun subtract eq = fold (remove eq);
   953 
   954 fun merge _ ([], ys) = ys
   955   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   956 
   957 (*old-style infixes*)
   958 fun x mem xs = member (op =) xs x;
   959 fun (x: int) mem_int xs = member (op =) xs x;
   960 fun (x: string) mem_string xs = member (op =) xs x;
   961 
   962 
   963 (*union of sets represented as lists: no repetitions*)
   964 fun xs union [] = xs
   965   | [] union ys = ys
   966   | (x :: xs) union ys = xs union (insert (op =) x ys);
   967 
   968 (*union of sets, optimized version for ints*)
   969 fun (xs:int list) union_int [] = xs
   970   | [] union_int ys = ys
   971   | (x :: xs) union_int ys = xs union_int (insert (op =) x ys);
   972 
   973 (*union of sets, optimized version for strings*)
   974 fun (xs:string list) union_string [] = xs
   975   | [] union_string ys = ys
   976   | (x :: xs) union_string ys = xs union_string (insert (op =) x ys);
   977 
   978 (*generalized union*)
   979 fun gen_union eq (xs, []) = xs
   980   | gen_union eq ([], ys) = ys
   981   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   982 
   983 
   984 (*intersection*)
   985 fun [] inter ys = []
   986   | (x :: xs) inter ys =
   987       if x mem ys then x :: (xs inter ys) else xs inter ys;
   988 
   989 (*intersection, optimized version for ints*)
   990 fun ([]:int list) inter_int ys = []
   991   | (x :: xs) inter_int ys =
   992       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   993 
   994 (*intersection, optimized version for strings *)
   995 fun ([]:string list) inter_string ys = []
   996   | (x :: xs) inter_string ys =
   997       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   998 
   999 (*generalized intersection*)
  1000 fun gen_inter eq ([], ys) = []
  1001   | gen_inter eq (x::xs, ys) =
  1002       if member eq ys x then x :: gen_inter eq (xs, ys)
  1003       else gen_inter eq (xs, ys);
  1004 
  1005 
  1006 (*subset*)
  1007 fun [] subset ys = true
  1008   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
  1009 
  1010 (*subset, optimized version for ints*)
  1011 fun ([]: int list) subset_int ys = true
  1012   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
  1013 
  1014 (*subset, optimized version for strings*)
  1015 fun ([]: string list) subset_string ys = true
  1016   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
  1017 
  1018 (*set equality*)
  1019 fun eq_set (xs, ys) =
  1020   xs = ys orelse (xs subset ys andalso ys subset xs);
  1021 
  1022 (*set equality for strings*)
  1023 fun eq_set_string ((xs: string list), ys) =
  1024   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
  1025 
  1026 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
  1027 
  1028 fun gen_eq_set eq (xs, ys) =
  1029   eq_list eq (xs, ys) orelse
  1030     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
  1031 
  1032 
  1033 (*removing an element from a list WITHOUT duplicates*)
  1034 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
  1035   | [] \ x = [];
  1036 fun ys \\ xs = foldl (op \) (ys,xs);
  1037 
  1038 
  1039 (*returns the tail beginning with the first repeated element, or []*)
  1040 fun findrep [] = []
  1041   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
  1042 
  1043 
  1044 (*makes a list of the distinct members of the input; preserves order, takes
  1045   first of equal elements*)
  1046 fun distinct eq lst =
  1047   let
  1048     fun dist (rev_seen, []) = rev rev_seen
  1049       | dist (rev_seen, x :: xs) =
  1050           if member eq rev_seen x then dist (rev_seen, xs)
  1051           else dist (x :: rev_seen, xs);
  1052   in dist ([], lst) end;
  1053 
  1054 (*returns a list containing all repeated elements exactly once; preserves
  1055   order, takes first of equal elements*)
  1056 fun duplicates eq lst =
  1057   let
  1058     fun dups (rev_dups, []) = rev rev_dups
  1059       | dups (rev_dups, x :: xs) =
  1060           if member eq rev_dups x orelse not (member eq xs x) then
  1061             dups (rev_dups, xs)
  1062           else dups (x :: rev_dups, xs);
  1063   in dups ([], lst) end;
  1064 
  1065 fun has_duplicates eq =
  1066   let
  1067     fun dups [] = false
  1068       | dups (x :: xs) = member eq xs x orelse dups xs;
  1069   in dups end;
  1070 
  1071 
  1072 (** association lists -- legacy operations **)
  1073 
  1074 fun gen_merge_lists _ xs [] = xs
  1075   | gen_merge_lists _ [] ys = ys
  1076   | gen_merge_lists eq xs ys = xs @ filter_out (member eq xs) ys;
  1077 
  1078 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1079 fun merge_alists xs = gen_merge_lists (eq_fst (op =)) xs;
  1080 
  1081 
  1082 (** balanced trees **)
  1083 
  1084 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1085 
  1086 (*balanced folding; avoids deep nesting*)
  1087 fun fold_bal f [x] = x
  1088   | fold_bal f [] = raise Balance
  1089   | fold_bal f xs =
  1090       let val (ps, qs) = chop (length xs div 2) xs
  1091       in  f (fold_bal f ps, fold_bal f qs)  end;
  1092 
  1093 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1094 fun access_bal (f, g, x) n i =
  1095   let fun acc n i =     (*1<=i<=n*)
  1096           if n=1 then x else
  1097           let val n2 = n div 2
  1098           in  if i<=n2 then f (acc n2 i)
  1099                        else g (acc (n-n2) (i-n2))
  1100           end
  1101   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1102 
  1103 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1104 fun accesses_bal (f, g, x) n =
  1105   let fun acc n =
  1106           if n=1 then [x] else
  1107           let val n2 = n div 2
  1108               val acc2 = acc n2
  1109           in  if n-n2=n2 then map f acc2 @ map g acc2
  1110                          else map f acc2 @ map g (acc (n-n2)) end
  1111   in  if 1<=n then acc n else raise Balance  end;
  1112 
  1113 
  1114 
  1115 (** orders **)
  1116 
  1117 fun is_equal EQUAL = true
  1118   | is_equal _ = false;
  1119 
  1120 fun rev_order LESS = GREATER
  1121   | rev_order EQUAL = EQUAL
  1122   | rev_order GREATER = LESS;
  1123 
  1124 (*assume rel is a linear strict order*)
  1125 fun make_ord rel (x, y) =
  1126   if rel (x, y) then LESS
  1127   else if rel (y, x) then GREATER
  1128   else EQUAL;
  1129 
  1130 val int_ord = Int.compare;
  1131 val string_ord = String.compare;
  1132 
  1133 fun fast_string_ord (s1, s2) =
  1134   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
  1135 
  1136 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1137   | option_ord _ (NONE, NONE) = EQUAL
  1138   | option_ord _ (NONE, SOME _) = LESS
  1139   | option_ord _ (SOME _, NONE) = GREATER;
  1140 
  1141 (*lexicographic product*)
  1142 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1143   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1144 
  1145 (*dictionary order -- in general NOT well-founded!*)
  1146 fun dict_ord elem_ord (x :: xs, y :: ys) =
  1147       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
  1148   | dict_ord _ ([], []) = EQUAL
  1149   | dict_ord _ ([], _ :: _) = LESS
  1150   | dict_ord _ (_ :: _, []) = GREATER;
  1151 
  1152 (*lexicographic product of lists*)
  1153 fun list_ord elem_ord (xs, ys) =
  1154   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1155 
  1156 
  1157 (* sorting *)
  1158 
  1159 (*quicksort -- stable, i.e. does not reorder equal elements*)
  1160 fun quicksort unique ord =
  1161   let
  1162     fun qsort [] = []
  1163       | qsort (xs as [_]) = xs
  1164       | qsort (xs as [x, y]) =
  1165           (case ord (x, y) of
  1166             LESS => xs
  1167           | EQUAL => if unique then [x] else xs
  1168           | GREATER => [y, x])
  1169       | qsort xs =
  1170           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
  1171           in qsort lts @ eqs @ qsort gts end
  1172     and part _ [] = ([], [], [])
  1173       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1174     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1175       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
  1176       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
  1177       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1178   in qsort end;
  1179 
  1180 fun sort ord = quicksort false ord;
  1181 fun sort_distinct ord = quicksort true ord;
  1182 
  1183 val sort_strings = sort string_ord;
  1184 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1185 
  1186 
  1187 
  1188 (** random numbers **)
  1189 
  1190 exception RANDOM;
  1191 
  1192 fun rmod x y = x - y * Real.realFloor (x / y);
  1193 
  1194 local
  1195   val a = 16807.0;
  1196   val m = 2147483647.0;
  1197   val random_seed = ref 1.0;
  1198 in
  1199 
  1200 fun random () =
  1201   let val r = rmod (a * !random_seed) m
  1202   in (random_seed := r; r) end;
  1203 
  1204 end;
  1205 
  1206 fun random_range l h =
  1207   if h < l orelse l < 0 then raise RANDOM
  1208   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1209 
  1210 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1211 
  1212 fun frequency xs =
  1213   let
  1214     val sum = foldl op + (0, map fst xs);
  1215     fun pick n ((k: int, x) :: xs) =
  1216       if n <= k then x else pick (n - k) xs
  1217   in pick (random_range 1 sum) xs end;
  1218 
  1219 
  1220 (** current directory **)
  1221 
  1222 val cd = OS.FileSys.chDir;
  1223 val pwd = OS.FileSys.getDir;
  1224 
  1225 
  1226 
  1227 (** misc **)
  1228 
  1229 fun divide_and_conquer decomp x =
  1230   let val (ys, recomb) = decomp x
  1231   in recomb (map (divide_and_conquer decomp) ys) end;
  1232 
  1233 
  1234 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1235    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1236 fun partition_list p i j =
  1237   let fun part k xs =
  1238             if k>j then
  1239               (case xs of [] => []
  1240                          | _ => raise Fail "partition_list")
  1241             else
  1242             let val (ns, rest) = List.partition (p k) xs;
  1243             in  ns :: part(k+1)rest  end
  1244   in  part i end;
  1245 
  1246 fun partition_eq (eq:'a * 'a -> bool) =
  1247   let
  1248     fun part [] = []
  1249       | part (x :: ys) =
  1250           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1251           in (x::xs)::(part xs') end
  1252   in part end;
  1253 
  1254 
  1255 
  1256 (* generating identifiers *)
  1257 
  1258 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1259 local
  1260 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1261 fun char i =      if i<26 then chr (ord "A" + i)
  1262              else if i<52 then chr (ord "a" + i - 26)
  1263              else if i<62 then chr (ord"0" + i - 52)
  1264              else if i=62 then "_"
  1265              else  (*i=63*)    "'";
  1266 
  1267 val charVec = Vector.tabulate (64, char);
  1268 
  1269 fun newid n =
  1270   let
  1271   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1272 
  1273 val seedr = ref 0;
  1274 
  1275 in
  1276 
  1277 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1278 
  1279 end;
  1280 
  1281 
  1282 (* lexical scanning *)
  1283 
  1284 (*scan a list of characters into "words" composed of "letters" (recognized by
  1285   is_let) and separated by any number of non-"letters"*)
  1286 fun scanwords is_let cs =
  1287   let fun scan1 [] = []
  1288         | scan1 cs =
  1289             let val (lets, rest) = take_prefix is_let cs
  1290             in implode lets :: scanwords is_let rest end;
  1291   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1292 
  1293 
  1294 (* stamps and serial numbers *)
  1295 
  1296 type stamp = unit ref;
  1297 val stamp: unit -> stamp = ref;
  1298 
  1299 type serial = int;
  1300 local val count = ref 0
  1301 in fun serial () = inc count end;
  1302 
  1303 val serial_string = string_of_int o serial;
  1304 
  1305 
  1306 (* generic objects *)
  1307 
  1308 (*note that the builtin exception datatype may be extended by new
  1309   constructors at any time*)
  1310 structure Object = struct type T = exn end;
  1311 
  1312 end;
  1313 
  1314 structure BasicLibrary: BASIC_LIBRARY = Library;
  1315 open BasicLibrary;