src/HOL/Product_Type.thy
author Andreas Lochbihler
Tue Apr 14 11:32:01 2015 +0200 (2015-04-14)
changeset 60057 86fa63ce8156
parent 59880 30687c3f2b10
child 60758 d8d85a8172b5
permissions -rw-r--r--
add lemmas
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 section {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 keywords "inductive_set" "coinductive_set" :: thy_decl
    11 begin
    12 
    13 subsection {* @{typ bool} is a datatype *}
    14 
    15 free_constructors case_bool for True | False
    16   by auto
    17 
    18 text {* Avoid name clashes by prefixing the output of @{text old_rep_datatype} with @{text old}. *}
    19 
    20 setup {* Sign.mandatory_path "old" *}
    21 
    22 old_rep_datatype True False by (auto intro: bool_induct)
    23 
    24 setup {* Sign.parent_path *}
    25 
    26 text {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
    27 
    28 setup {* Sign.mandatory_path "bool" *}
    29 
    30 lemmas induct = old.bool.induct
    31 lemmas inducts = old.bool.inducts
    32 lemmas rec = old.bool.rec
    33 lemmas simps = bool.distinct bool.case bool.rec
    34 
    35 setup {* Sign.parent_path *}
    36 
    37 declare case_split [cases type: bool]
    38   -- "prefer plain propositional version"
    39 
    40 lemma
    41   shows [code]: "HOL.equal False P \<longleftrightarrow> \<not> P"
    42     and [code]: "HOL.equal True P \<longleftrightarrow> P" 
    43     and [code]: "HOL.equal P False \<longleftrightarrow> \<not> P"
    44     and [code]: "HOL.equal P True \<longleftrightarrow> P"
    45     and [code nbe]: "HOL.equal P P \<longleftrightarrow> True"
    46   by (simp_all add: equal)
    47 
    48 lemma If_case_cert:
    49   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
    50   shows "(CASE True \<equiv> f) &&& (CASE False \<equiv> g)"
    51   using assms by simp_all
    52 
    53 setup {* Code.add_case @{thm If_case_cert} *}
    54 
    55 code_printing
    56   constant "HOL.equal :: bool \<Rightarrow> bool \<Rightarrow> bool" \<rightharpoonup> (Haskell) infix 4 "=="
    57 | class_instance "bool" :: "equal" \<rightharpoonup> (Haskell) -
    58 
    59 
    60 subsection {* The @{text unit} type *}
    61 
    62 typedef unit = "{True}"
    63   by auto
    64 
    65 definition Unity :: unit  ("'(')")
    66   where "() = Abs_unit True"
    67 
    68 lemma unit_eq [no_atp]: "u = ()"
    69   by (induct u) (simp add: Unity_def)
    70 
    71 text {*
    72   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    73   this rule directly --- it loops!
    74 *}
    75 
    76 simproc_setup unit_eq ("x::unit") = {*
    77   fn _ => fn _ => fn ct =>
    78     if HOLogic.is_unit (Thm.term_of ct) then NONE
    79     else SOME (mk_meta_eq @{thm unit_eq})
    80 *}
    81 
    82 free_constructors case_unit for "()"
    83   by auto
    84 
    85 text {* Avoid name clashes by prefixing the output of @{text old_rep_datatype} with @{text old}. *}
    86 
    87 setup {* Sign.mandatory_path "old" *}
    88 
    89 old_rep_datatype "()" by simp
    90 
    91 setup {* Sign.parent_path *}
    92 
    93 text {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
    94 
    95 setup {* Sign.mandatory_path "unit" *}
    96 
    97 lemmas induct = old.unit.induct
    98 lemmas inducts = old.unit.inducts
    99 lemmas rec = old.unit.rec
   100 lemmas simps = unit.case unit.rec
   101 
   102 setup {* Sign.parent_path *}
   103 
   104 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
   105   by simp
   106 
   107 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
   108   by (rule triv_forall_equality)
   109 
   110 text {*
   111   This rewrite counters the effect of simproc @{text unit_eq} on @{term
   112   [source] "%u::unit. f u"}, replacing it by @{term [source]
   113   f} rather than by @{term [source] "%u. f ()"}.
   114 *}
   115 
   116 lemma unit_abs_eta_conv [simp]: "(%u::unit. f ()) = f"
   117   by (rule ext) simp
   118 
   119 lemma UNIV_unit:
   120   "UNIV = {()}" by auto
   121 
   122 instantiation unit :: default
   123 begin
   124 
   125 definition "default = ()"
   126 
   127 instance ..
   128 
   129 end
   130 
   131 instantiation unit :: "{complete_boolean_algebra, complete_linorder, wellorder}"
   132 begin
   133 
   134 definition less_eq_unit :: "unit \<Rightarrow> unit \<Rightarrow> bool"
   135 where
   136   "(_::unit) \<le> _ \<longleftrightarrow> True"
   137 
   138 lemma less_eq_unit [iff]:
   139   "(u::unit) \<le> v"
   140   by (simp add: less_eq_unit_def)
   141 
   142 definition less_unit :: "unit \<Rightarrow> unit \<Rightarrow> bool"
   143 where
   144   "(_::unit) < _ \<longleftrightarrow> False"
   145 
   146 lemma less_unit [iff]:
   147   "\<not> (u::unit) < v"
   148   by (simp_all add: less_eq_unit_def less_unit_def)
   149 
   150 definition bot_unit :: unit
   151 where
   152   [code_unfold]: "\<bottom> = ()"
   153 
   154 definition top_unit :: unit
   155 where
   156   [code_unfold]: "\<top> = ()"
   157 
   158 definition inf_unit :: "unit \<Rightarrow> unit \<Rightarrow> unit"
   159 where
   160   [simp]: "_ \<sqinter> _ = ()"
   161 
   162 definition sup_unit :: "unit \<Rightarrow> unit \<Rightarrow> unit"
   163 where
   164   [simp]: "_ \<squnion> _ = ()"
   165 
   166 definition Inf_unit :: "unit set \<Rightarrow> unit"
   167 where
   168   [simp]: "\<Sqinter>_ = ()"
   169 
   170 definition Sup_unit :: "unit set \<Rightarrow> unit"
   171 where
   172   [simp]: "\<Squnion>_ = ()"
   173 
   174 definition uminus_unit :: "unit \<Rightarrow> unit"
   175 where
   176   [simp]: "- _ = ()"
   177 
   178 declare less_eq_unit_def [abs_def, code_unfold]
   179   less_unit_def [abs_def, code_unfold]
   180   inf_unit_def [abs_def, code_unfold]
   181   sup_unit_def [abs_def, code_unfold]
   182   Inf_unit_def [abs_def, code_unfold]
   183   Sup_unit_def [abs_def, code_unfold]
   184   uminus_unit_def [abs_def, code_unfold]
   185 
   186 instance
   187   by intro_classes auto
   188 
   189 end
   190 
   191 lemma [code]:
   192   "HOL.equal (u\<Colon>unit) v \<longleftrightarrow> True" unfolding equal unit_eq [of u] unit_eq [of v] by rule+
   193 
   194 code_printing
   195   type_constructor unit \<rightharpoonup>
   196     (SML) "unit"
   197     and (OCaml) "unit"
   198     and (Haskell) "()"
   199     and (Scala) "Unit"
   200 | constant Unity \<rightharpoonup>
   201     (SML) "()"
   202     and (OCaml) "()"
   203     and (Haskell) "()"
   204     and (Scala) "()"
   205 | class_instance unit :: equal \<rightharpoonup>
   206     (Haskell) -
   207 | constant "HOL.equal :: unit \<Rightarrow> unit \<Rightarrow> bool" \<rightharpoonup>
   208     (Haskell) infix 4 "=="
   209 
   210 code_reserved SML
   211   unit
   212 
   213 code_reserved OCaml
   214   unit
   215 
   216 code_reserved Scala
   217   Unit
   218 
   219 
   220 subsection {* The product type *}
   221 
   222 subsubsection {* Type definition *}
   223 
   224 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   225   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   226 
   227 definition "prod = {f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   228 
   229 typedef ('a, 'b) prod (infixr "*" 20) = "prod :: ('a \<Rightarrow> 'b \<Rightarrow> bool) set"
   230   unfolding prod_def by auto
   231 
   232 type_notation (xsymbols)
   233   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   234 type_notation (HTML output)
   235   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   236 
   237 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   238   "Pair a b = Abs_prod (Pair_Rep a b)"
   239 
   240 lemma prod_cases: "(\<And>a b. P (Pair a b)) \<Longrightarrow> P p"
   241   by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   242 
   243 free_constructors case_prod for Pair fst snd
   244 proof -
   245   fix P :: bool and p :: "'a \<times> 'b"
   246   show "(\<And>x1 x2. p = Pair x1 x2 \<Longrightarrow> P) \<Longrightarrow> P"
   247     by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   248 next
   249   fix a c :: 'a and b d :: 'b
   250   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   251     by (auto simp add: Pair_Rep_def fun_eq_iff)
   252   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   253     by (auto simp add: prod_def)
   254   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   255     by (simp add: Pair_def Abs_prod_inject)
   256 qed
   257 
   258 text {* Avoid name clashes by prefixing the output of @{text old_rep_datatype} with @{text old}. *}
   259 
   260 setup {* Sign.mandatory_path "old" *}
   261 
   262 old_rep_datatype Pair
   263 by (erule prod_cases) (rule prod.inject)
   264 
   265 setup {* Sign.parent_path *}
   266 
   267 text {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
   268 
   269 setup {* Sign.mandatory_path "prod" *}
   270 
   271 declare
   272   old.prod.inject[iff del]
   273 
   274 lemmas induct = old.prod.induct
   275 lemmas inducts = old.prod.inducts
   276 lemmas rec = old.prod.rec
   277 lemmas simps = prod.inject prod.case prod.rec
   278 
   279 setup {* Sign.parent_path *}
   280 
   281 declare prod.case [nitpick_simp del]
   282 declare prod.case_cong_weak [cong del]
   283 
   284 
   285 subsubsection {* Tuple syntax *}
   286 
   287 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   288   "split \<equiv> case_prod"
   289 
   290 text {*
   291   Patterns -- extends pre-defined type @{typ pttrn} used in
   292   abstractions.
   293 *}
   294 
   295 nonterminal tuple_args and patterns
   296 
   297 syntax
   298   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   299   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   300   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   301   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   302   ""            :: "pttrn => patterns"                  ("_")
   303   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   304 
   305 translations
   306   "(x, y)" == "CONST Pair x y"
   307   "_pattern x y" => "CONST Pair x y"
   308   "_patterns x y" => "CONST Pair x y"
   309   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   310   "%(x, y, zs). b" == "CONST case_prod (%x (y, zs). b)"
   311   "%(x, y). b" == "CONST case_prod (%x y. b)"
   312   "_abs (CONST Pair x y) t" => "%(x, y). t"
   313   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   314      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   315 
   316 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   317   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   318 print_translation {*
   319   let
   320     fun split_tr' [Abs (x, T, t as (Abs abs))] =
   321           (* split (%x y. t) => %(x,y) t *)
   322           let
   323             val (y, t') = Syntax_Trans.atomic_abs_tr' abs;
   324             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   325           in
   326             Syntax.const @{syntax_const "_abs"} $
   327               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   328           end
   329       | split_tr' [Abs (x, T, (s as Const (@{const_syntax case_prod}, _) $ t))] =
   330           (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   331           let
   332             val Const (@{syntax_const "_abs"}, _) $
   333               (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   334             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   335           in
   336             Syntax.const @{syntax_const "_abs"} $
   337               (Syntax.const @{syntax_const "_pattern"} $ x' $
   338                 (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   339           end
   340       | split_tr' [Const (@{const_syntax case_prod}, _) $ t] =
   341           (* split (split (%x y z. t)) => %((x, y), z). t *)
   342           split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   343       | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   344           (* split (%pttrn z. t) => %(pttrn,z). t *)
   345           let val (z, t) = Syntax_Trans.atomic_abs_tr' abs in
   346             Syntax.const @{syntax_const "_abs"} $
   347               (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   348           end
   349       | split_tr' _ = raise Match;
   350   in [(@{const_syntax case_prod}, K split_tr')] end
   351 *}
   352 
   353 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   354 typed_print_translation {*
   355   let
   356     fun split_guess_names_tr' T [Abs (x, _, Abs _)] = raise Match
   357       | split_guess_names_tr' T [Abs (x, xT, t)] =
   358           (case (head_of t) of
   359             Const (@{const_syntax case_prod}, _) => raise Match
   360           | _ =>
   361             let 
   362               val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   363               val (y, t') = Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   364               val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, xT, t');
   365             in
   366               Syntax.const @{syntax_const "_abs"} $
   367                 (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   368             end)
   369       | split_guess_names_tr' T [t] =
   370           (case head_of t of
   371             Const (@{const_syntax case_prod}, _) => raise Match
   372           | _ =>
   373             let
   374               val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   375               val (y, t') =
   376                 Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   377               val (x', t'') = Syntax_Trans.atomic_abs_tr' ("x", xT, t');
   378             in
   379               Syntax.const @{syntax_const "_abs"} $
   380                 (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   381             end)
   382       | split_guess_names_tr' _ _ = raise Match;
   383   in [(@{const_syntax case_prod}, K split_guess_names_tr')] end
   384 *}
   385 
   386 
   387 subsubsection {* Code generator setup *}
   388 
   389 code_printing
   390   type_constructor prod \<rightharpoonup>
   391     (SML) infix 2 "*"
   392     and (OCaml) infix 2 "*"
   393     and (Haskell) "!((_),/ (_))"
   394     and (Scala) "((_),/ (_))"
   395 | constant Pair \<rightharpoonup>
   396     (SML) "!((_),/ (_))"
   397     and (OCaml) "!((_),/ (_))"
   398     and (Haskell) "!((_),/ (_))"
   399     and (Scala) "!((_),/ (_))"
   400 | class_instance  prod :: equal \<rightharpoonup>
   401     (Haskell) -
   402 | constant "HOL.equal :: 'a \<times> 'b \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool" \<rightharpoonup>
   403     (Haskell) infix 4 "=="
   404 
   405 
   406 subsubsection {* Fundamental operations and properties *}
   407 
   408 lemma Pair_inject:
   409   assumes "(a, b) = (a', b')"
   410     and "a = a' ==> b = b' ==> R"
   411   shows R
   412   using assms by simp
   413 
   414 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   415   by (cases p) simp
   416 
   417 code_printing
   418   constant fst \<rightharpoonup> (Haskell) "fst"
   419 | constant snd \<rightharpoonup> (Haskell) "snd"
   420 
   421 lemma case_prod_unfold [nitpick_unfold]: "case_prod = (%c p. c (fst p) (snd p))"
   422   by (simp add: fun_eq_iff split: prod.split)
   423 
   424 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   425   by simp
   426 
   427 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   428   by simp
   429 
   430 lemmas surjective_pairing = prod.collapse [symmetric]
   431 
   432 lemma prod_eq_iff: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   433   by (cases s, cases t) simp
   434 
   435 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   436   by (simp add: prod_eq_iff)
   437 
   438 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   439   by (fact prod.case)
   440 
   441 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   442   by (rule split_conv [THEN iffD2])
   443 
   444 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   445   by (rule split_conv [THEN iffD1])
   446 
   447 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   448   by (simp add: fun_eq_iff split: prod.split)
   449 
   450 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   451   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   452   by (simp add: fun_eq_iff split: prod.split)
   453 
   454 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   455   by (cases x) simp
   456 
   457 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   458   by (cases p) simp
   459 
   460 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   461   by (simp add: case_prod_unfold)
   462 
   463 lemmas split_weak_cong = prod.case_cong_weak
   464   -- {* Prevents simplification of @{term c}: much faster *}
   465 
   466 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   467   by (simp add: split_eta)
   468 
   469 lemma split_paired_all [no_atp]: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   470 proof
   471   fix a b
   472   assume "!!x. PROP P x"
   473   then show "PROP P (a, b)" .
   474 next
   475   fix x
   476   assume "!!a b. PROP P (a, b)"
   477   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   478 qed
   479 
   480 lemma case_prod_distrib: "f (case x of (x, y) \<Rightarrow> g x y) = (case x of (x, y) \<Rightarrow> f (g x y))"
   481   by (cases x) simp
   482 
   483 text {*
   484   The rule @{thm [source] split_paired_all} does not work with the
   485   Simplifier because it also affects premises in congrence rules,
   486   where this can lead to premises of the form @{text "!!a b. ... =
   487   ?P(a, b)"} which cannot be solved by reflexivity.
   488 *}
   489 
   490 lemmas split_tupled_all = split_paired_all unit_all_eq2
   491 
   492 ML {*
   493   (* replace parameters of product type by individual component parameters *)
   494   local (* filtering with exists_paired_all is an essential optimization *)
   495     fun exists_paired_all (Const (@{const_name Pure.all}, _) $ Abs (_, T, t)) =
   496           can HOLogic.dest_prodT T orelse exists_paired_all t
   497       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   498       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   499       | exists_paired_all _ = false;
   500     val ss =
   501       simpset_of
   502        (put_simpset HOL_basic_ss @{context}
   503         addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   504         addsimprocs [@{simproc unit_eq}]);
   505   in
   506     fun split_all_tac ctxt = SUBGOAL (fn (t, i) =>
   507       if exists_paired_all t then safe_full_simp_tac (put_simpset ss ctxt) i else no_tac);
   508 
   509     fun unsafe_split_all_tac ctxt = SUBGOAL (fn (t, i) =>
   510       if exists_paired_all t then full_simp_tac (put_simpset ss ctxt) i else no_tac);
   511 
   512     fun split_all ctxt th =
   513       if exists_paired_all (Thm.prop_of th)
   514       then full_simplify (put_simpset ss ctxt) th else th;
   515   end;
   516 *}
   517 
   518 setup {* map_theory_claset (fn ctxt => ctxt addSbefore ("split_all_tac", split_all_tac)) *}
   519 
   520 lemma split_paired_All [simp, no_atp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   521   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   522   by fast
   523 
   524 lemma split_paired_Ex [simp, no_atp]: "(EX x. P x) = (EX a b. P (a, b))"
   525   by fast
   526 
   527 lemma split_paired_The [no_atp]: "(THE x. P x) = (THE (a, b). P (a, b))"
   528   -- {* Can't be added to simpset: loops! *}
   529   by (simp add: split_eta)
   530 
   531 text {*
   532   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   533   @{thm [source] split_eta} as a rewrite rule is not general enough,
   534   and using @{thm [source] cond_split_eta} directly would render some
   535   existing proofs very inefficient; similarly for @{text
   536   split_beta}.
   537 *}
   538 
   539 ML {*
   540 local
   541   val cond_split_eta_ss =
   542     simpset_of (put_simpset HOL_basic_ss @{context} addsimps @{thms cond_split_eta});
   543   fun Pair_pat k 0 (Bound m) = (m = k)
   544     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   545         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   546     | Pair_pat _ _ _ = false;
   547   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   548     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   549     | no_args k i (Bound m) = m < k orelse m > k + i
   550     | no_args _ _ _ = true;
   551   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   552     | split_pat tp i (Const (@{const_name case_prod}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   553     | split_pat tp i _ = NONE;
   554   fun metaeq ctxt lhs rhs = mk_meta_eq (Goal.prove ctxt [] []
   555         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   556         (K (simp_tac (put_simpset cond_split_eta_ss ctxt) 1)));
   557 
   558   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   559     | beta_term_pat k i (t $ u) =
   560         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   561     | beta_term_pat k i t = no_args k i t;
   562   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   563     | eta_term_pat _ _ _ = false;
   564   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   565     | subst arg k i (t $ u) =
   566         if Pair_pat k i (t $ u) then incr_boundvars k arg
   567         else (subst arg k i t $ subst arg k i u)
   568     | subst arg k i t = t;
   569 in
   570   fun beta_proc ctxt (s as Const (@{const_name case_prod}, _) $ Abs (_, _, t) $ arg) =
   571         (case split_pat beta_term_pat 1 t of
   572           SOME (i, f) => SOME (metaeq ctxt s (subst arg 0 i f))
   573         | NONE => NONE)
   574     | beta_proc _ _ = NONE;
   575   fun eta_proc ctxt (s as Const (@{const_name case_prod}, _) $ Abs (_, _, t)) =
   576         (case split_pat eta_term_pat 1 t of
   577           SOME (_, ft) => SOME (metaeq ctxt s (let val f $ _ = ft in f end))
   578         | NONE => NONE)
   579     | eta_proc _ _ = NONE;
   580 end;
   581 *}
   582 simproc_setup split_beta ("split f z") =
   583   {* fn _ => fn ctxt => fn ct => beta_proc ctxt (Thm.term_of ct) *}
   584 simproc_setup split_eta ("split f") =
   585   {* fn _ => fn ctxt => fn ct => eta_proc ctxt (Thm.term_of ct) *}
   586 
   587 lemmas split_beta [mono] = prod.case_eq_if
   588 
   589 lemma split_beta': "(\<lambda>(x,y). f x y) = (\<lambda>x. f (fst x) (snd x))"
   590   by (auto simp: fun_eq_iff)
   591 
   592 lemmas split_split [no_atp] = prod.split
   593   -- {* For use with @{text split} and the Simplifier. *}
   594 
   595 text {*
   596   @{thm [source] split_split} could be declared as @{text "[split]"}
   597   done after the Splitter has been speeded up significantly;
   598   precompute the constants involved and don't do anything unless the
   599   current goal contains one of those constants.
   600 *}
   601 
   602 lemmas split_split_asm [no_atp] = prod.split_asm
   603 
   604 text {*
   605   \medskip @{term split} used as a logical connective or set former.
   606 
   607   \medskip These rules are for use with @{text blast}; could instead
   608   call @{text simp} using @{thm [source] prod.split} as rewrite. *}
   609 
   610 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   611   apply (simp only: split_tupled_all)
   612   apply (simp (no_asm_simp))
   613   done
   614 
   615 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   616   apply (simp only: split_tupled_all)
   617   apply (simp (no_asm_simp))
   618   done
   619 
   620 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   621   by (induct p) auto
   622 
   623 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   624   by (induct p) auto
   625 
   626 lemma splitE2:
   627   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   628 proof -
   629   assume q: "Q (split P z)"
   630   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   631   show R
   632     apply (rule r surjective_pairing)+
   633     apply (rule split_beta [THEN subst], rule q)
   634     done
   635 qed
   636 
   637 lemma splitD': "split R (a,b) c ==> R a b c"
   638   by simp
   639 
   640 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   641   by simp
   642 
   643 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   644 by (simp only: split_tupled_all, simp)
   645 
   646 lemma mem_splitE:
   647   assumes "z \<in> split c p"
   648   obtains x y where "p = (x, y)" and "z \<in> c x y"
   649   using assms by (rule splitE2)
   650 
   651 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   652 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   653 
   654 ML {*
   655 local (* filtering with exists_p_split is an essential optimization *)
   656   fun exists_p_split (Const (@{const_name case_prod},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   657     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   658     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   659     | exists_p_split _ = false;
   660 in
   661 fun split_conv_tac ctxt = SUBGOAL (fn (t, i) =>
   662   if exists_p_split t
   663   then safe_full_simp_tac (put_simpset HOL_basic_ss ctxt addsimps @{thms split_conv}) i
   664   else no_tac);
   665 end;
   666 *}
   667 
   668 (* This prevents applications of splitE for already splitted arguments leading
   669    to quite time-consuming computations (in particular for nested tuples) *)
   670 setup {* map_theory_claset (fn ctxt => ctxt addSbefore ("split_conv_tac", split_conv_tac)) *}
   671 
   672 lemma split_eta_SetCompr [simp, no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   673   by (rule ext) fast
   674 
   675 lemma split_eta_SetCompr2 [simp, no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   676   by (rule ext) fast
   677 
   678 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   679   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   680   by (rule ext) blast
   681 
   682 (* Do NOT make this a simp rule as it
   683    a) only helps in special situations
   684    b) can lead to nontermination in the presence of split_def
   685 *)
   686 lemma split_comp_eq: 
   687   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   688   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   689   by (rule ext) auto
   690 
   691 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   692   apply (rule_tac x = "(a, b)" in image_eqI)
   693    apply auto
   694   done
   695 
   696 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   697   by blast
   698 
   699 (*
   700 the following  would be slightly more general,
   701 but cannot be used as rewrite rule:
   702 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   703 ### ?y = .x
   704 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   705 by (rtac some_equality 1)
   706 by ( Simp_tac 1)
   707 by (split_all_tac 1)
   708 by (Asm_full_simp_tac 1)
   709 qed "The_split_eq";
   710 *)
   711 
   712 text {*
   713   Setup of internal @{text split_rule}.
   714 *}
   715 
   716 lemmas case_prodI = prod.case [THEN iffD2]
   717 
   718 lemma case_prodI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> case_prod c p"
   719   by (fact splitI2)
   720 
   721 lemma case_prodI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> case_prod c p x"
   722   by (fact splitI2')
   723 
   724 lemma case_prodE: "case_prod c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   725   by (fact splitE)
   726 
   727 lemma case_prodE': "case_prod c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   728   by (fact splitE')
   729 
   730 declare case_prodI [intro!]
   731 
   732 lemma case_prod_beta:
   733   "case_prod f p = f (fst p) (snd p)"
   734   by (fact split_beta)
   735 
   736 lemma prod_cases3 [cases type]:
   737   obtains (fields) a b c where "y = (a, b, c)"
   738   by (cases y, case_tac b) blast
   739 
   740 lemma prod_induct3 [case_names fields, induct type]:
   741     "(!!a b c. P (a, b, c)) ==> P x"
   742   by (cases x) blast
   743 
   744 lemma prod_cases4 [cases type]:
   745   obtains (fields) a b c d where "y = (a, b, c, d)"
   746   by (cases y, case_tac c) blast
   747 
   748 lemma prod_induct4 [case_names fields, induct type]:
   749     "(!!a b c d. P (a, b, c, d)) ==> P x"
   750   by (cases x) blast
   751 
   752 lemma prod_cases5 [cases type]:
   753   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   754   by (cases y, case_tac d) blast
   755 
   756 lemma prod_induct5 [case_names fields, induct type]:
   757     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   758   by (cases x) blast
   759 
   760 lemma prod_cases6 [cases type]:
   761   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   762   by (cases y, case_tac e) blast
   763 
   764 lemma prod_induct6 [case_names fields, induct type]:
   765     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   766   by (cases x) blast
   767 
   768 lemma prod_cases7 [cases type]:
   769   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   770   by (cases y, case_tac f) blast
   771 
   772 lemma prod_induct7 [case_names fields, induct type]:
   773     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   774   by (cases x) blast
   775 
   776 lemma split_def:
   777   "split = (\<lambda>c p. c (fst p) (snd p))"
   778   by (fact case_prod_unfold)
   779 
   780 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   781   "internal_split == split"
   782 
   783 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   784   by (simp only: internal_split_def split_conv)
   785 
   786 ML_file "Tools/split_rule.ML"
   787 
   788 hide_const internal_split
   789 
   790 
   791 subsubsection {* Derived operations *}
   792 
   793 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   794   "curry = (\<lambda>c x y. c (x, y))"
   795 
   796 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   797   by (simp add: curry_def)
   798 
   799 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   800   by (simp add: curry_def)
   801 
   802 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   803   by (simp add: curry_def)
   804 
   805 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   806   by (simp add: curry_def)
   807 
   808 lemma curry_split [simp]: "curry (split f) = f"
   809   by (simp add: curry_def split_def)
   810 
   811 lemma split_curry [simp]: "split (curry f) = f"
   812   by (simp add: curry_def split_def)
   813 
   814 lemma curry_K: "curry (\<lambda>x. c) = (\<lambda>x y. c)"
   815 by(simp add: fun_eq_iff)
   816 
   817 text {*
   818   The composition-uncurry combinator.
   819 *}
   820 
   821 notation fcomp (infixl "\<circ>>" 60)
   822 
   823 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "\<circ>\<rightarrow>" 60) where
   824   "f \<circ>\<rightarrow> g = (\<lambda>x. case_prod g (f x))"
   825 
   826 lemma scomp_unfold: "scomp = (\<lambda>f g x. g (fst (f x)) (snd (f x)))"
   827   by (simp add: fun_eq_iff scomp_def case_prod_unfold)
   828 
   829 lemma scomp_apply [simp]: "(f \<circ>\<rightarrow> g) x = case_prod g (f x)"
   830   by (simp add: scomp_unfold case_prod_unfold)
   831 
   832 lemma Pair_scomp: "Pair x \<circ>\<rightarrow> f = f x"
   833   by (simp add: fun_eq_iff)
   834 
   835 lemma scomp_Pair: "x \<circ>\<rightarrow> Pair = x"
   836   by (simp add: fun_eq_iff)
   837 
   838 lemma scomp_scomp: "(f \<circ>\<rightarrow> g) \<circ>\<rightarrow> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>\<rightarrow> h)"
   839   by (simp add: fun_eq_iff scomp_unfold)
   840 
   841 lemma scomp_fcomp: "(f \<circ>\<rightarrow> g) \<circ>> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>> h)"
   842   by (simp add: fun_eq_iff scomp_unfold fcomp_def)
   843 
   844 lemma fcomp_scomp: "(f \<circ>> g) \<circ>\<rightarrow> h = f \<circ>> (g \<circ>\<rightarrow> h)"
   845   by (simp add: fun_eq_iff scomp_unfold)
   846 
   847 code_printing
   848   constant scomp \<rightharpoonup> (Eval) infixl 3 "#->"
   849 
   850 no_notation fcomp (infixl "\<circ>>" 60)
   851 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   852 
   853 text {*
   854   @{term map_prod} --- action of the product functor upon
   855   functions.
   856 *}
   857 
   858 definition map_prod :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   859   "map_prod f g = (\<lambda>(x, y). (f x, g y))"
   860 
   861 lemma map_prod_simp [simp, code]:
   862   "map_prod f g (a, b) = (f a, g b)"
   863   by (simp add: map_prod_def)
   864 
   865 functor map_prod: map_prod
   866   by (auto simp add: split_paired_all)
   867 
   868 lemma fst_map_prod [simp]:
   869   "fst (map_prod f g x) = f (fst x)"
   870   by (cases x) simp_all
   871 
   872 lemma snd_map_prod [simp]:
   873   "snd (map_prod f g x) = g (snd x)"
   874   by (cases x) simp_all
   875 
   876 lemma fst_comp_map_prod [simp]:
   877   "fst \<circ> map_prod f g = f \<circ> fst"
   878   by (rule ext) simp_all
   879 
   880 lemma snd_comp_map_prod [simp]:
   881   "snd \<circ> map_prod f g = g \<circ> snd"
   882   by (rule ext) simp_all
   883 
   884 lemma map_prod_compose:
   885   "map_prod (f1 o f2) (g1 o g2) = (map_prod f1 g1 o map_prod f2 g2)"
   886   by (rule ext) (simp add: map_prod.compositionality comp_def)
   887 
   888 lemma map_prod_ident [simp]:
   889   "map_prod (%x. x) (%y. y) = (%z. z)"
   890   by (rule ext) (simp add: map_prod.identity)
   891 
   892 lemma map_prod_imageI [intro]:
   893   "(a, b) \<in> R \<Longrightarrow> (f a, g b) \<in> map_prod f g ` R"
   894   by (rule image_eqI) simp_all
   895 
   896 lemma prod_fun_imageE [elim!]:
   897   assumes major: "c \<in> map_prod f g ` R"
   898     and cases: "\<And>x y. c = (f x, g y) \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> P"
   899   shows P
   900   apply (rule major [THEN imageE])
   901   apply (case_tac x)
   902   apply (rule cases)
   903   apply simp_all
   904   done
   905 
   906 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   907   "apfst f = map_prod f id"
   908 
   909 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   910   "apsnd f = map_prod id f"
   911 
   912 lemma apfst_conv [simp, code]:
   913   "apfst f (x, y) = (f x, y)" 
   914   by (simp add: apfst_def)
   915 
   916 lemma apsnd_conv [simp, code]:
   917   "apsnd f (x, y) = (x, f y)" 
   918   by (simp add: apsnd_def)
   919 
   920 lemma fst_apfst [simp]:
   921   "fst (apfst f x) = f (fst x)"
   922   by (cases x) simp
   923 
   924 lemma fst_comp_apfst [simp]:
   925   "fst \<circ> apfst f = f \<circ> fst"
   926   by (simp add: fun_eq_iff)
   927 
   928 lemma fst_apsnd [simp]:
   929   "fst (apsnd f x) = fst x"
   930   by (cases x) simp
   931 
   932 lemma fst_comp_apsnd [simp]:
   933   "fst \<circ> apsnd f = fst"
   934   by (simp add: fun_eq_iff)
   935 
   936 lemma snd_apfst [simp]:
   937   "snd (apfst f x) = snd x"
   938   by (cases x) simp
   939 
   940 lemma snd_comp_apfst [simp]:
   941   "snd \<circ> apfst f = snd"
   942   by (simp add: fun_eq_iff)
   943 
   944 lemma snd_apsnd [simp]:
   945   "snd (apsnd f x) = f (snd x)"
   946   by (cases x) simp
   947 
   948 lemma snd_comp_apsnd [simp]:
   949   "snd \<circ> apsnd f = f \<circ> snd"
   950   by (simp add: fun_eq_iff)
   951 
   952 lemma apfst_compose:
   953   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   954   by (cases x) simp
   955 
   956 lemma apsnd_compose:
   957   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   958   by (cases x) simp
   959 
   960 lemma apfst_apsnd [simp]:
   961   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   962   by (cases x) simp
   963 
   964 lemma apsnd_apfst [simp]:
   965   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   966   by (cases x) simp
   967 
   968 lemma apfst_id [simp] :
   969   "apfst id = id"
   970   by (simp add: fun_eq_iff)
   971 
   972 lemma apsnd_id [simp] :
   973   "apsnd id = id"
   974   by (simp add: fun_eq_iff)
   975 
   976 lemma apfst_eq_conv [simp]:
   977   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   978   by (cases x) simp
   979 
   980 lemma apsnd_eq_conv [simp]:
   981   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   982   by (cases x) simp
   983 
   984 lemma apsnd_apfst_commute:
   985   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   986   by simp
   987 
   988 context
   989 begin
   990 
   991 local_setup {* Local_Theory.map_background_naming (Name_Space.mandatory_path "prod") *}
   992 
   993 definition swap :: "'a \<times> 'b \<Rightarrow> 'b \<times> 'a"
   994 where
   995   "swap p = (snd p, fst p)"
   996 
   997 end
   998 
   999 lemma swap_simp [simp]:
  1000   "prod.swap (x, y) = (y, x)"
  1001   by (simp add: prod.swap_def)
  1002 
  1003 lemma swap_swap [simp]:
  1004   "prod.swap (prod.swap p) = p"
  1005   by (cases p) simp
  1006 
  1007 lemma swap_comp_swap [simp]:
  1008   "prod.swap \<circ> prod.swap = id"
  1009   by (simp add: fun_eq_iff)
  1010 
  1011 lemma pair_in_swap_image [simp]:
  1012   "(y, x) \<in> prod.swap ` A \<longleftrightarrow> (x, y) \<in> A"
  1013   by (auto intro!: image_eqI)
  1014 
  1015 lemma inj_swap [simp]:
  1016   "inj_on prod.swap A"
  1017   by (rule inj_onI) auto
  1018 
  1019 lemma swap_inj_on:
  1020   "inj_on (\<lambda>(i, j). (j, i)) A"
  1021   by (rule inj_onI) auto
  1022 
  1023 lemma surj_swap [simp]:
  1024   "surj prod.swap"
  1025   by (rule surjI [of _ prod.swap]) simp
  1026 
  1027 lemma bij_swap [simp]:
  1028   "bij prod.swap"
  1029   by (simp add: bij_def)
  1030 
  1031 lemma case_swap [simp]:
  1032   "(case prod.swap p of (y, x) \<Rightarrow> f x y) = (case p of (x, y) \<Rightarrow> f x y)"
  1033   by (cases p) simp
  1034 
  1035 text {*
  1036   Disjoint union of a family of sets -- Sigma.
  1037 *}
  1038 
  1039 definition Sigma :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<times> 'b) set" where
  1040   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
  1041 
  1042 abbreviation
  1043   Times :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set"
  1044     (infixr "<*>" 80) where
  1045   "A <*> B == Sigma A (%_. B)"
  1046 
  1047 notation (xsymbols)
  1048   Times  (infixr "\<times>" 80)
  1049 
  1050 notation (HTML output)
  1051   Times  (infixr "\<times>" 80)
  1052 
  1053 hide_const (open) Times
  1054 
  1055 syntax
  1056   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
  1057 translations
  1058   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
  1059 
  1060 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
  1061   by (unfold Sigma_def) blast
  1062 
  1063 lemma SigmaE [elim!]:
  1064     "[| c: Sigma A B;
  1065         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
  1066      |] ==> P"
  1067   -- {* The general elimination rule. *}
  1068   by (unfold Sigma_def) blast
  1069 
  1070 text {*
  1071   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
  1072   eigenvariables.
  1073 *}
  1074 
  1075 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
  1076   by blast
  1077 
  1078 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
  1079   by blast
  1080 
  1081 lemma SigmaE2:
  1082     "[| (a, b) : Sigma A B;
  1083         [| a:A;  b:B(a) |] ==> P
  1084      |] ==> P"
  1085   by blast
  1086 
  1087 lemma Sigma_cong:
  1088      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
  1089       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
  1090   by auto
  1091 
  1092 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
  1093   by blast
  1094 
  1095 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
  1096   by blast
  1097 
  1098 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
  1099   by blast
  1100 
  1101 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
  1102   by auto
  1103 
  1104 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
  1105   by auto
  1106 
  1107 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
  1108   by auto
  1109 
  1110 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
  1111   by blast
  1112 
  1113 lemma Sigma_empty_iff: "(SIGMA i:I. X i) = {} \<longleftrightarrow> (\<forall>i\<in>I. X i = {})"
  1114   by auto
  1115 
  1116 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
  1117   by blast
  1118 
  1119 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
  1120   by (blast elim: equalityE)
  1121 
  1122 lemma SetCompr_Sigma_eq:
  1123     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
  1124   by blast
  1125 
  1126 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
  1127   by blast
  1128 
  1129 lemma UN_Times_distrib:
  1130   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
  1131   -- {* Suggested by Pierre Chartier *}
  1132   by blast
  1133 
  1134 lemma split_paired_Ball_Sigma [simp, no_atp]:
  1135     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
  1136   by blast
  1137 
  1138 lemma split_paired_Bex_Sigma [simp, no_atp]:
  1139     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
  1140   by blast
  1141 
  1142 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
  1143   by blast
  1144 
  1145 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
  1146   by blast
  1147 
  1148 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
  1149   by blast
  1150 
  1151 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
  1152   by blast
  1153 
  1154 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
  1155   by blast
  1156 
  1157 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
  1158   by blast
  1159 
  1160 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
  1161   by blast
  1162 
  1163 text {*
  1164   Non-dependent versions are needed to avoid the need for higher-order
  1165   matching, especially when the rules are re-oriented.
  1166 *}
  1167 
  1168 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1169   by (fact Sigma_Un_distrib1)
  1170 
  1171 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1172   by (fact Sigma_Int_distrib1)
  1173 
  1174 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1175   by (fact Sigma_Diff_distrib1)
  1176 
  1177 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1178   by auto
  1179 
  1180 lemma times_eq_iff: "A \<times> B = C \<times> D \<longleftrightarrow> A = C \<and> B = D \<or> ((A = {} \<or> B = {}) \<and> (C = {} \<or> D = {}))"
  1181   by auto
  1182 
  1183 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1184   by force
  1185 
  1186 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1187   by force
  1188 
  1189 lemma vimage_fst:
  1190   "fst -` A = A \<times> UNIV"
  1191   by auto
  1192 
  1193 lemma vimage_snd:
  1194   "snd -` A = UNIV \<times> A"
  1195   by auto
  1196 
  1197 lemma insert_times_insert[simp]:
  1198   "insert a A \<times> insert b B =
  1199    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1200 by blast
  1201 
  1202 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1203   apply auto
  1204   apply (case_tac "f x")
  1205   apply auto
  1206   done
  1207 
  1208 lemma times_Int_times: "A \<times> B \<inter> C \<times> D = (A \<inter> C) \<times> (B \<inter> D)"
  1209   by auto
  1210 
  1211 lemma product_swap:
  1212   "prod.swap ` (A \<times> B) = B \<times> A"
  1213   by (auto simp add: set_eq_iff)
  1214 
  1215 lemma swap_product:
  1216   "(\<lambda>(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1217   by (auto simp add: set_eq_iff)
  1218 
  1219 lemma image_split_eq_Sigma:
  1220   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1221 proof (safe intro!: imageI)
  1222   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1223   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1224     using * eq[symmetric] by auto
  1225 qed simp_all
  1226 
  1227 lemma inj_on_apfst [simp]: "inj_on (apfst f) (A \<times> UNIV) \<longleftrightarrow> inj_on f A"
  1228 by(auto simp add: inj_on_def)
  1229 
  1230 lemma inj_apfst [simp]: "inj (apfst f) \<longleftrightarrow> inj f"
  1231 using inj_on_apfst[of f UNIV] by simp
  1232 
  1233 lemma inj_on_apsnd [simp]: "inj_on (apsnd f) (UNIV \<times> A) \<longleftrightarrow> inj_on f A"
  1234 by(auto simp add: inj_on_def)
  1235 
  1236 lemma inj_apsnd [simp]: "inj (apsnd f) \<longleftrightarrow> inj f"
  1237 using inj_on_apsnd[of f UNIV] by simp
  1238 
  1239 definition product :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set" where
  1240   [code_abbrev]: "product A B = A \<times> B"
  1241 
  1242 hide_const (open) product
  1243 
  1244 lemma member_product:
  1245   "x \<in> Product_Type.product A B \<longleftrightarrow> x \<in> A \<times> B"
  1246   by (simp add: product_def)
  1247 
  1248 text {* The following @{const map_prod} lemmas are due to Joachim Breitner: *}
  1249 
  1250 lemma map_prod_inj_on:
  1251   assumes "inj_on f A" and "inj_on g B"
  1252   shows "inj_on (map_prod f g) (A \<times> B)"
  1253 proof (rule inj_onI)
  1254   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1255   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1256   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1257   assume "map_prod f g x = map_prod f g y"
  1258   hence "fst (map_prod f g x) = fst (map_prod f g y)" by (auto)
  1259   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1260   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1261   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1262   moreover from `map_prod f g x = map_prod f g y`
  1263   have "snd (map_prod f g x) = snd (map_prod f g y)" by (auto)
  1264   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1265   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1266   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1267   ultimately show "x = y" by(rule prod_eqI)
  1268 qed
  1269 
  1270 lemma map_prod_surj:
  1271   fixes f :: "'a \<Rightarrow> 'b" and g :: "'c \<Rightarrow> 'd"
  1272   assumes "surj f" and "surj g"
  1273   shows "surj (map_prod f g)"
  1274 unfolding surj_def
  1275 proof
  1276   fix y :: "'b \<times> 'd"
  1277   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1278   moreover
  1279   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1280   ultimately have "(fst y, snd y) = map_prod f g (a,b)" by auto
  1281   thus "\<exists>x. y = map_prod f g x" by auto
  1282 qed
  1283 
  1284 lemma map_prod_surj_on:
  1285   assumes "f ` A = A'" and "g ` B = B'"
  1286   shows "map_prod f g ` (A \<times> B) = A' \<times> B'"
  1287 unfolding image_def
  1288 proof(rule set_eqI,rule iffI)
  1289   fix x :: "'a \<times> 'c"
  1290   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = map_prod f g x}"
  1291   then obtain y where "y \<in> A \<times> B" and "x = map_prod f g y" by blast
  1292   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1293   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1294   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1295   with `x = map_prod f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1296 next
  1297   fix x :: "'a \<times> 'c"
  1298   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1299   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1300   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1301   moreover from `image g B = B'` and `snd x \<in> B'`
  1302   obtain b where "b \<in> B" and "snd x = g b" by auto
  1303   ultimately have "(fst x, snd x) = map_prod f g (a,b)" by auto
  1304   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1305   ultimately have "\<exists>y \<in> A \<times> B. x = map_prod f g y" by auto
  1306   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = map_prod f g y}" by auto
  1307 qed
  1308 
  1309 
  1310 subsection {* Simproc for rewriting a set comprehension into a pointfree expression *}
  1311 
  1312 ML_file "Tools/set_comprehension_pointfree.ML"
  1313 
  1314 setup {*
  1315   Code_Preproc.map_pre (fn ctxt => ctxt addsimprocs
  1316     [Raw_Simplifier.make_simproc {name = "set comprehension", lhss = [@{cpat "Collect ?P"}],
  1317     proc = K Set_Comprehension_Pointfree.code_simproc, identifier = []}])
  1318 *}
  1319 
  1320 
  1321 subsection {* Inductively defined sets *}
  1322 
  1323 (* simplify {(x1, ..., xn). (x1, ..., xn) : S} to S *)
  1324 simproc_setup Collect_mem ("Collect t") = {*
  1325   fn _ => fn ctxt => fn ct =>
  1326     (case Thm.term_of ct of
  1327       S as Const (@{const_name Collect}, Type (@{type_name fun}, [_, T])) $ t =>
  1328         let val (u, _, ps) = HOLogic.strip_psplits t in
  1329           (case u of
  1330             (c as Const (@{const_name Set.member}, _)) $ q $ S' =>
  1331               (case try (HOLogic.strip_ptuple ps) q of
  1332                 NONE => NONE
  1333               | SOME ts =>
  1334                   if not (Term.is_open S') andalso
  1335                     ts = map Bound (length ps downto 0)
  1336                   then
  1337                     let val simp =
  1338                       full_simp_tac (put_simpset HOL_basic_ss ctxt
  1339                         addsimps [@{thm split_paired_all}, @{thm split_conv}]) 1
  1340                     in
  1341                       SOME (Goal.prove ctxt [] []
  1342                         (Const (@{const_name Pure.eq}, T --> T --> propT) $ S $ S')
  1343                         (K (EVERY
  1344                           [resolve_tac ctxt [eq_reflection] 1,
  1345                            resolve_tac ctxt @{thms subset_antisym} 1,
  1346                            resolve_tac ctxt [subsetI] 1, dresolve_tac ctxt [CollectD] 1, simp,
  1347                            resolve_tac ctxt [subsetI] 1, resolve_tac ctxt [CollectI] 1, simp])))
  1348                     end
  1349                   else NONE)
  1350           | _ => NONE)
  1351         end
  1352     | _ => NONE)
  1353 *}
  1354 
  1355 ML_file "Tools/inductive_set.ML"
  1356 
  1357 
  1358 subsection {* Legacy theorem bindings and duplicates *}
  1359 
  1360 lemma PairE:
  1361   obtains x y where "p = (x, y)"
  1362   by (fact prod.exhaust)
  1363 
  1364 lemmas Pair_eq = prod.inject
  1365 lemmas fst_conv = prod.sel(1)
  1366 lemmas snd_conv = prod.sel(2)
  1367 lemmas pair_collapse = prod.collapse
  1368 lemmas split = split_conv
  1369 lemmas Pair_fst_snd_eq = prod_eq_iff
  1370 
  1371 hide_const (open) prod
  1372 
  1373 end