src/HOL/Relation.thy
author Andreas Lochbihler
Tue Apr 14 11:32:01 2015 +0200 (2015-04-14)
changeset 60057 86fa63ce8156
parent 59518 28cfc60dea7a
child 60758 d8d85a8172b5
permissions -rw-r--r--
add lemmas
     1 (*  Title:      HOL/Relation.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory; Stefan Berghofer, TU Muenchen
     3 *)
     4 
     5 section {* Relations -- as sets of pairs, and binary predicates *}
     6 
     7 theory Relation
     8 imports Finite_Set
     9 begin
    10 
    11 text {* A preliminary: classical rules for reasoning on predicates *}
    12 
    13 declare predicate1I [Pure.intro!, intro!]
    14 declare predicate1D [Pure.dest, dest]
    15 declare predicate2I [Pure.intro!, intro!]
    16 declare predicate2D [Pure.dest, dest]
    17 declare bot1E [elim!] 
    18 declare bot2E [elim!]
    19 declare top1I [intro!]
    20 declare top2I [intro!]
    21 declare inf1I [intro!]
    22 declare inf2I [intro!]
    23 declare inf1E [elim!]
    24 declare inf2E [elim!]
    25 declare sup1I1 [intro?]
    26 declare sup2I1 [intro?]
    27 declare sup1I2 [intro?]
    28 declare sup2I2 [intro?]
    29 declare sup1E [elim!]
    30 declare sup2E [elim!]
    31 declare sup1CI [intro!]
    32 declare sup2CI [intro!]
    33 declare Inf1_I [intro!]
    34 declare INF1_I [intro!]
    35 declare Inf2_I [intro!]
    36 declare INF2_I [intro!]
    37 declare Inf1_D [elim]
    38 declare INF1_D [elim]
    39 declare Inf2_D [elim]
    40 declare INF2_D [elim]
    41 declare Inf1_E [elim]
    42 declare INF1_E [elim]
    43 declare Inf2_E [elim]
    44 declare INF2_E [elim]
    45 declare Sup1_I [intro]
    46 declare SUP1_I [intro]
    47 declare Sup2_I [intro]
    48 declare SUP2_I [intro]
    49 declare Sup1_E [elim!]
    50 declare SUP1_E [elim!]
    51 declare Sup2_E [elim!]
    52 declare SUP2_E [elim!]
    53 
    54 subsection {* Fundamental *}
    55 
    56 subsubsection {* Relations as sets of pairs *}
    57 
    58 type_synonym 'a rel = "('a * 'a) set"
    59 
    60 lemma subrelI: -- {* Version of @{thm [source] subsetI} for binary relations *}
    61   "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (x, y) \<in> s) \<Longrightarrow> r \<subseteq> s"
    62   by auto
    63 
    64 lemma lfp_induct2: -- {* Version of @{thm [source] lfp_induct} for binary relations *}
    65   "(a, b) \<in> lfp f \<Longrightarrow> mono f \<Longrightarrow>
    66     (\<And>a b. (a, b) \<in> f (lfp f \<inter> {(x, y). P x y}) \<Longrightarrow> P a b) \<Longrightarrow> P a b"
    67   using lfp_induct_set [of "(a, b)" f "case_prod P"] by auto
    68 
    69 
    70 subsubsection {* Conversions between set and predicate relations *}
    71 
    72 lemma pred_equals_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) = (\<lambda>x. x \<in> S) \<longleftrightarrow> R = S"
    73   by (simp add: set_eq_iff fun_eq_iff)
    74 
    75 lemma pred_equals_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) = (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R = S"
    76   by (simp add: set_eq_iff fun_eq_iff)
    77 
    78 lemma pred_subset_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<le> (\<lambda>x. x \<in> S) \<longleftrightarrow> R \<subseteq> S"
    79   by (simp add: subset_iff le_fun_def)
    80 
    81 lemma pred_subset_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<le> (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R \<subseteq> S"
    82   by (simp add: subset_iff le_fun_def)
    83 
    84 lemma bot_empty_eq [pred_set_conv]: "\<bottom> = (\<lambda>x. x \<in> {})"
    85   by (auto simp add: fun_eq_iff)
    86 
    87 lemma bot_empty_eq2 [pred_set_conv]: "\<bottom> = (\<lambda>x y. (x, y) \<in> {})"
    88   by (auto simp add: fun_eq_iff)
    89 
    90 lemma top_empty_eq [pred_set_conv]: "\<top> = (\<lambda>x. x \<in> UNIV)"
    91   by (auto simp add: fun_eq_iff)
    92 
    93 lemma top_empty_eq2 [pred_set_conv]: "\<top> = (\<lambda>x y. (x, y) \<in> UNIV)"
    94   by (auto simp add: fun_eq_iff)
    95 
    96 lemma inf_Int_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<sqinter> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<inter> S)"
    97   by (simp add: inf_fun_def)
    98 
    99 lemma inf_Int_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<sqinter> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<inter> S)"
   100   by (simp add: inf_fun_def)
   101 
   102 lemma sup_Un_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<squnion> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<union> S)"
   103   by (simp add: sup_fun_def)
   104 
   105 lemma sup_Un_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<squnion> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<union> S)"
   106   by (simp add: sup_fun_def)
   107 
   108 lemma INF_INT_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Inter>i\<in>S. r i))"
   109   by (simp add: fun_eq_iff)
   110 
   111 lemma INF_INT_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Inter>i\<in>S. r i))"
   112   by (simp add: fun_eq_iff)
   113 
   114 lemma SUP_UN_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Union>i\<in>S. r i))"
   115   by (simp add: fun_eq_iff)
   116 
   117 lemma SUP_UN_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Union>i\<in>S. r i))"
   118   by (simp add: fun_eq_iff)
   119 
   120 lemma Inf_INT_eq [pred_set_conv]: "\<Sqinter>S = (\<lambda>x. x \<in> INTER S Collect)"
   121   by (simp add: fun_eq_iff)
   122 
   123 lemma INF_Int_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Inter>S)"
   124   by (simp add: fun_eq_iff)
   125 
   126 lemma Inf_INT_eq2 [pred_set_conv]: "\<Sqinter>S = (\<lambda>x y. (x, y) \<in> INTER (case_prod ` S) Collect)"
   127   by (simp add: fun_eq_iff)
   128 
   129 lemma INF_Int_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Inter>S)"
   130   by (simp add: fun_eq_iff)
   131 
   132 lemma Sup_SUP_eq [pred_set_conv]: "\<Squnion>S = (\<lambda>x. x \<in> UNION S Collect)"
   133   by (simp add: fun_eq_iff)
   134 
   135 lemma SUP_Sup_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Union>S)"
   136   by (simp add: fun_eq_iff)
   137 
   138 lemma Sup_SUP_eq2 [pred_set_conv]: "\<Squnion>S = (\<lambda>x y. (x, y) \<in> UNION (case_prod ` S) Collect)"
   139   by (simp add: fun_eq_iff)
   140 
   141 lemma SUP_Sup_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Union>S)"
   142   by (simp add: fun_eq_iff)
   143 
   144 subsection {* Properties of relations *}
   145 
   146 subsubsection {* Reflexivity *}
   147 
   148 definition refl_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   149 where
   150   "refl_on A r \<longleftrightarrow> r \<subseteq> A \<times> A \<and> (\<forall>x\<in>A. (x, x) \<in> r)"
   151 
   152 abbreviation refl :: "'a rel \<Rightarrow> bool"
   153 where -- {* reflexivity over a type *}
   154   "refl \<equiv> refl_on UNIV"
   155 
   156 definition reflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   157 where
   158   "reflp r \<longleftrightarrow> (\<forall>x. r x x)"
   159 
   160 lemma reflp_refl_eq [pred_set_conv]:
   161   "reflp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> refl r" 
   162   by (simp add: refl_on_def reflp_def)
   163 
   164 lemma refl_onI: "r \<subseteq> A \<times> A ==> (!!x. x : A ==> (x, x) : r) ==> refl_on A r"
   165   by (unfold refl_on_def) (iprover intro!: ballI)
   166 
   167 lemma refl_onD: "refl_on A r ==> a : A ==> (a, a) : r"
   168   by (unfold refl_on_def) blast
   169 
   170 lemma refl_onD1: "refl_on A r ==> (x, y) : r ==> x : A"
   171   by (unfold refl_on_def) blast
   172 
   173 lemma refl_onD2: "refl_on A r ==> (x, y) : r ==> y : A"
   174   by (unfold refl_on_def) blast
   175 
   176 lemma reflpI:
   177   "(\<And>x. r x x) \<Longrightarrow> reflp r"
   178   by (auto intro: refl_onI simp add: reflp_def)
   179 
   180 lemma reflpE:
   181   assumes "reflp r"
   182   obtains "r x x"
   183   using assms by (auto dest: refl_onD simp add: reflp_def)
   184 
   185 lemma reflpD:
   186   assumes "reflp r"
   187   shows "r x x"
   188   using assms by (auto elim: reflpE)
   189 
   190 lemma refl_on_Int: "refl_on A r ==> refl_on B s ==> refl_on (A \<inter> B) (r \<inter> s)"
   191   by (unfold refl_on_def) blast
   192 
   193 lemma reflp_inf:
   194   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<sqinter> s)"
   195   by (auto intro: reflpI elim: reflpE)
   196 
   197 lemma refl_on_Un: "refl_on A r ==> refl_on B s ==> refl_on (A \<union> B) (r \<union> s)"
   198   by (unfold refl_on_def) blast
   199 
   200 lemma reflp_sup:
   201   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<squnion> s)"
   202   by (auto intro: reflpI elim: reflpE)
   203 
   204 lemma refl_on_INTER:
   205   "ALL x:S. refl_on (A x) (r x) ==> refl_on (INTER S A) (INTER S r)"
   206   by (unfold refl_on_def) fast
   207 
   208 lemma refl_on_UNION:
   209   "ALL x:S. refl_on (A x) (r x) \<Longrightarrow> refl_on (UNION S A) (UNION S r)"
   210   by (unfold refl_on_def) blast
   211 
   212 lemma refl_on_empty [simp]: "refl_on {} {}"
   213   by (simp add:refl_on_def)
   214 
   215 lemma refl_on_def' [nitpick_unfold, code]:
   216   "refl_on A r \<longleftrightarrow> (\<forall>(x, y) \<in> r. x \<in> A \<and> y \<in> A) \<and> (\<forall>x \<in> A. (x, x) \<in> r)"
   217   by (auto intro: refl_onI dest: refl_onD refl_onD1 refl_onD2)
   218 
   219 lemma reflp_equality [simp]: "reflp op ="
   220 by(simp add: reflp_def)
   221 
   222 subsubsection {* Irreflexivity *}
   223 
   224 definition irrefl :: "'a rel \<Rightarrow> bool"
   225 where
   226   "irrefl r \<longleftrightarrow> (\<forall>a. (a, a) \<notin> r)"
   227 
   228 definition irreflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   229 where
   230   "irreflp R \<longleftrightarrow> (\<forall>a. \<not> R a a)"
   231 
   232 lemma irreflp_irrefl_eq [pred_set_conv]:
   233   "irreflp (\<lambda>a b. (a, b) \<in> R) \<longleftrightarrow> irrefl R" 
   234   by (simp add: irrefl_def irreflp_def)
   235 
   236 lemma irreflI:
   237   "(\<And>a. (a, a) \<notin> R) \<Longrightarrow> irrefl R"
   238   by (simp add: irrefl_def)
   239 
   240 lemma irreflpI:
   241   "(\<And>a. \<not> R a a) \<Longrightarrow> irreflp R"
   242   by (fact irreflI [to_pred])
   243 
   244 lemma irrefl_distinct [code]:
   245   "irrefl r \<longleftrightarrow> (\<forall>(a, b) \<in> r. a \<noteq> b)"
   246   by (auto simp add: irrefl_def)
   247 
   248 
   249 subsubsection {* Asymmetry *}
   250 
   251 inductive asym :: "'a rel \<Rightarrow> bool"
   252 where
   253   asymI: "irrefl R \<Longrightarrow> (\<And>a b. (a, b) \<in> R \<Longrightarrow> (b, a) \<notin> R) \<Longrightarrow> asym R"
   254 
   255 inductive asymp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   256 where
   257   asympI: "irreflp R \<Longrightarrow> (\<And>a b. R a b \<Longrightarrow> \<not> R b a) \<Longrightarrow> asymp R"
   258 
   259 lemma asymp_asym_eq [pred_set_conv]:
   260   "asymp (\<lambda>a b. (a, b) \<in> R) \<longleftrightarrow> asym R" 
   261   by (auto intro!: asymI asympI elim: asym.cases asymp.cases simp add: irreflp_irrefl_eq)
   262 
   263 
   264 subsubsection {* Symmetry *}
   265 
   266 definition sym :: "'a rel \<Rightarrow> bool"
   267 where
   268   "sym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r)"
   269 
   270 definition symp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   271 where
   272   "symp r \<longleftrightarrow> (\<forall>x y. r x y \<longrightarrow> r y x)"
   273 
   274 lemma symp_sym_eq [pred_set_conv]:
   275   "symp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> sym r" 
   276   by (simp add: sym_def symp_def)
   277 
   278 lemma symI:
   279   "(\<And>a b. (a, b) \<in> r \<Longrightarrow> (b, a) \<in> r) \<Longrightarrow> sym r"
   280   by (unfold sym_def) iprover
   281 
   282 lemma sympI:
   283   "(\<And>a b. r a b \<Longrightarrow> r b a) \<Longrightarrow> symp r"
   284   by (fact symI [to_pred])
   285 
   286 lemma symE:
   287   assumes "sym r" and "(b, a) \<in> r"
   288   obtains "(a, b) \<in> r"
   289   using assms by (simp add: sym_def)
   290 
   291 lemma sympE:
   292   assumes "symp r" and "r b a"
   293   obtains "r a b"
   294   using assms by (rule symE [to_pred])
   295 
   296 lemma symD:
   297   assumes "sym r" and "(b, a) \<in> r"
   298   shows "(a, b) \<in> r"
   299   using assms by (rule symE)
   300 
   301 lemma sympD:
   302   assumes "symp r" and "r b a"
   303   shows "r a b"
   304   using assms by (rule symD [to_pred])
   305 
   306 lemma sym_Int:
   307   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<inter> s)"
   308   by (fast intro: symI elim: symE)
   309 
   310 lemma symp_inf:
   311   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<sqinter> s)"
   312   by (fact sym_Int [to_pred])
   313 
   314 lemma sym_Un:
   315   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<union> s)"
   316   by (fast intro: symI elim: symE)
   317 
   318 lemma symp_sup:
   319   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<squnion> s)"
   320   by (fact sym_Un [to_pred])
   321 
   322 lemma sym_INTER:
   323   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (INTER S r)"
   324   by (fast intro: symI elim: symE)
   325 
   326 lemma symp_INF:
   327   "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (INFIMUM S r)"
   328   by (fact sym_INTER [to_pred])
   329 
   330 lemma sym_UNION:
   331   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (UNION S r)"
   332   by (fast intro: symI elim: symE)
   333 
   334 lemma symp_SUP:
   335   "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (SUPREMUM S r)"
   336   by (fact sym_UNION [to_pred])
   337 
   338 
   339 subsubsection {* Antisymmetry *}
   340 
   341 definition antisym :: "'a rel \<Rightarrow> bool"
   342 where
   343   "antisym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r \<longrightarrow> x = y)"
   344 
   345 abbreviation antisymP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   346 where
   347   "antisymP r \<equiv> antisym {(x, y). r x y}"
   348 
   349 lemma antisymI:
   350   "(!!x y. (x, y) : r ==> (y, x) : r ==> x=y) ==> antisym r"
   351   by (unfold antisym_def) iprover
   352 
   353 lemma antisymD: "antisym r ==> (a, b) : r ==> (b, a) : r ==> a = b"
   354   by (unfold antisym_def) iprover
   355 
   356 lemma antisym_subset: "r \<subseteq> s ==> antisym s ==> antisym r"
   357   by (unfold antisym_def) blast
   358 
   359 lemma antisym_empty [simp]: "antisym {}"
   360   by (unfold antisym_def) blast
   361 
   362 lemma antisymP_equality [simp]: "antisymP op ="
   363 by(auto intro: antisymI)
   364 
   365 subsubsection {* Transitivity *}
   366 
   367 definition trans :: "'a rel \<Rightarrow> bool"
   368 where
   369   "trans r \<longleftrightarrow> (\<forall>x y z. (x, y) \<in> r \<longrightarrow> (y, z) \<in> r \<longrightarrow> (x, z) \<in> r)"
   370 
   371 definition transp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   372 where
   373   "transp r \<longleftrightarrow> (\<forall>x y z. r x y \<longrightarrow> r y z \<longrightarrow> r x z)"
   374 
   375 lemma transp_trans_eq [pred_set_conv]:
   376   "transp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> trans r" 
   377   by (simp add: trans_def transp_def)
   378 
   379 abbreviation transP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   380 where -- {* FIXME drop *}
   381   "transP r \<equiv> trans {(x, y). r x y}"
   382 
   383 lemma transI:
   384   "(\<And>x y z. (x, y) \<in> r \<Longrightarrow> (y, z) \<in> r \<Longrightarrow> (x, z) \<in> r) \<Longrightarrow> trans r"
   385   by (unfold trans_def) iprover
   386 
   387 lemma transpI:
   388   "(\<And>x y z. r x y \<Longrightarrow> r y z \<Longrightarrow> r x z) \<Longrightarrow> transp r"
   389   by (fact transI [to_pred])
   390 
   391 lemma transE:
   392   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   393   obtains "(x, z) \<in> r"
   394   using assms by (unfold trans_def) iprover
   395 
   396 lemma transpE:
   397   assumes "transp r" and "r x y" and "r y z"
   398   obtains "r x z"
   399   using assms by (rule transE [to_pred])
   400 
   401 lemma transD:
   402   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   403   shows "(x, z) \<in> r"
   404   using assms by (rule transE)
   405 
   406 lemma transpD:
   407   assumes "transp r" and "r x y" and "r y z"
   408   shows "r x z"
   409   using assms by (rule transD [to_pred])
   410 
   411 lemma trans_Int:
   412   "trans r \<Longrightarrow> trans s \<Longrightarrow> trans (r \<inter> s)"
   413   by (fast intro: transI elim: transE)
   414 
   415 lemma transp_inf:
   416   "transp r \<Longrightarrow> transp s \<Longrightarrow> transp (r \<sqinter> s)"
   417   by (fact trans_Int [to_pred])
   418 
   419 lemma trans_INTER:
   420   "\<forall>x\<in>S. trans (r x) \<Longrightarrow> trans (INTER S r)"
   421   by (fast intro: transI elim: transD)
   422 
   423 (* FIXME thm trans_INTER [to_pred] *)
   424 
   425 lemma trans_join [code]:
   426   "trans r \<longleftrightarrow> (\<forall>(x, y1) \<in> r. \<forall>(y2, z) \<in> r. y1 = y2 \<longrightarrow> (x, z) \<in> r)"
   427   by (auto simp add: trans_def)
   428 
   429 lemma transp_trans:
   430   "transp r \<longleftrightarrow> trans {(x, y). r x y}"
   431   by (simp add: trans_def transp_def)
   432 
   433 lemma transp_equality [simp]: "transp op ="
   434 by(auto intro: transpI)
   435 
   436 subsubsection {* Totality *}
   437 
   438 definition total_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   439 where
   440   "total_on A r \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. x \<noteq> y \<longrightarrow> (x, y) \<in> r \<or> (y, x) \<in> r)"
   441 
   442 abbreviation "total \<equiv> total_on UNIV"
   443 
   444 lemma total_on_empty [simp]: "total_on {} r"
   445   by (simp add: total_on_def)
   446 
   447 
   448 subsubsection {* Single valued relations *}
   449 
   450 definition single_valued :: "('a \<times> 'b) set \<Rightarrow> bool"
   451 where
   452   "single_valued r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (\<forall>z. (x, z) \<in> r \<longrightarrow> y = z))"
   453 
   454 abbreviation single_valuedP :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool" where
   455   "single_valuedP r \<equiv> single_valued {(x, y). r x y}"
   456 
   457 lemma single_valuedI:
   458   "ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z) ==> single_valued r"
   459   by (unfold single_valued_def)
   460 
   461 lemma single_valuedD:
   462   "single_valued r ==> (x, y) : r ==> (x, z) : r ==> y = z"
   463   by (simp add: single_valued_def)
   464 
   465 lemma single_valued_empty[simp]: "single_valued {}"
   466 by(simp add: single_valued_def)
   467 
   468 lemma single_valued_subset:
   469   "r \<subseteq> s ==> single_valued s ==> single_valued r"
   470   by (unfold single_valued_def) blast
   471 
   472 
   473 subsection {* Relation operations *}
   474 
   475 subsubsection {* The identity relation *}
   476 
   477 definition Id :: "'a rel"
   478 where
   479   [code del]: "Id = {p. \<exists>x. p = (x, x)}"
   480 
   481 lemma IdI [intro]: "(a, a) : Id"
   482   by (simp add: Id_def)
   483 
   484 lemma IdE [elim!]: "p : Id ==> (!!x. p = (x, x) ==> P) ==> P"
   485   by (unfold Id_def) (iprover elim: CollectE)
   486 
   487 lemma pair_in_Id_conv [iff]: "((a, b) : Id) = (a = b)"
   488   by (unfold Id_def) blast
   489 
   490 lemma refl_Id: "refl Id"
   491   by (simp add: refl_on_def)
   492 
   493 lemma antisym_Id: "antisym Id"
   494   -- {* A strange result, since @{text Id} is also symmetric. *}
   495   by (simp add: antisym_def)
   496 
   497 lemma sym_Id: "sym Id"
   498   by (simp add: sym_def)
   499 
   500 lemma trans_Id: "trans Id"
   501   by (simp add: trans_def)
   502 
   503 lemma single_valued_Id [simp]: "single_valued Id"
   504   by (unfold single_valued_def) blast
   505 
   506 lemma irrefl_diff_Id [simp]: "irrefl (r - Id)"
   507   by (simp add:irrefl_def)
   508 
   509 lemma trans_diff_Id: "trans r \<Longrightarrow> antisym r \<Longrightarrow> trans (r - Id)"
   510   unfolding antisym_def trans_def by blast
   511 
   512 lemma total_on_diff_Id [simp]: "total_on A (r - Id) = total_on A r"
   513   by (simp add: total_on_def)
   514 
   515 
   516 subsubsection {* Diagonal: identity over a set *}
   517 
   518 definition Id_on  :: "'a set \<Rightarrow> 'a rel"
   519 where
   520   "Id_on A = (\<Union>x\<in>A. {(x, x)})"
   521 
   522 lemma Id_on_empty [simp]: "Id_on {} = {}"
   523   by (simp add: Id_on_def) 
   524 
   525 lemma Id_on_eqI: "a = b ==> a : A ==> (a, b) : Id_on A"
   526   by (simp add: Id_on_def)
   527 
   528 lemma Id_onI [intro!]: "a : A ==> (a, a) : Id_on A"
   529   by (rule Id_on_eqI) (rule refl)
   530 
   531 lemma Id_onE [elim!]:
   532   "c : Id_on A ==> (!!x. x : A ==> c = (x, x) ==> P) ==> P"
   533   -- {* The general elimination rule. *}
   534   by (unfold Id_on_def) (iprover elim!: UN_E singletonE)
   535 
   536 lemma Id_on_iff: "((x, y) : Id_on A) = (x = y & x : A)"
   537   by blast
   538 
   539 lemma Id_on_def' [nitpick_unfold]:
   540   "Id_on {x. A x} = Collect (\<lambda>(x, y). x = y \<and> A x)"
   541   by auto
   542 
   543 lemma Id_on_subset_Times: "Id_on A \<subseteq> A \<times> A"
   544   by blast
   545 
   546 lemma refl_on_Id_on: "refl_on A (Id_on A)"
   547   by (rule refl_onI [OF Id_on_subset_Times Id_onI])
   548 
   549 lemma antisym_Id_on [simp]: "antisym (Id_on A)"
   550   by (unfold antisym_def) blast
   551 
   552 lemma sym_Id_on [simp]: "sym (Id_on A)"
   553   by (rule symI) clarify
   554 
   555 lemma trans_Id_on [simp]: "trans (Id_on A)"
   556   by (fast intro: transI elim: transD)
   557 
   558 lemma single_valued_Id_on [simp]: "single_valued (Id_on A)"
   559   by (unfold single_valued_def) blast
   560 
   561 
   562 subsubsection {* Composition *}
   563 
   564 inductive_set relcomp  :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'c) set \<Rightarrow> ('a \<times> 'c) set" (infixr "O" 75)
   565   for r :: "('a \<times> 'b) set" and s :: "('b \<times> 'c) set"
   566 where
   567   relcompI [intro]: "(a, b) \<in> r \<Longrightarrow> (b, c) \<in> s \<Longrightarrow> (a, c) \<in> r O s"
   568 
   569 notation relcompp (infixr "OO" 75)
   570 
   571 lemmas relcomppI = relcompp.intros
   572 
   573 text {*
   574   For historic reasons, the elimination rules are not wholly corresponding.
   575   Feel free to consolidate this.
   576 *}
   577 
   578 inductive_cases relcompEpair: "(a, c) \<in> r O s"
   579 inductive_cases relcomppE [elim!]: "(r OO s) a c"
   580 
   581 lemma relcompE [elim!]: "xz \<in> r O s \<Longrightarrow>
   582   (\<And>x y z. xz = (x, z) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> (y, z) \<in> s  \<Longrightarrow> P) \<Longrightarrow> P"
   583   by (cases xz) (simp, erule relcompEpair, iprover)
   584 
   585 lemma R_O_Id [simp]:
   586   "R O Id = R"
   587   by fast
   588 
   589 lemma Id_O_R [simp]:
   590   "Id O R = R"
   591   by fast
   592 
   593 lemma relcomp_empty1 [simp]:
   594   "{} O R = {}"
   595   by blast
   596 
   597 lemma relcompp_bot1 [simp]:
   598   "\<bottom> OO R = \<bottom>"
   599   by (fact relcomp_empty1 [to_pred])
   600 
   601 lemma relcomp_empty2 [simp]:
   602   "R O {} = {}"
   603   by blast
   604 
   605 lemma relcompp_bot2 [simp]:
   606   "R OO \<bottom> = \<bottom>"
   607   by (fact relcomp_empty2 [to_pred])
   608 
   609 lemma O_assoc:
   610   "(R O S) O T = R O (S O T)"
   611   by blast
   612 
   613 lemma relcompp_assoc:
   614   "(r OO s) OO t = r OO (s OO t)"
   615   by (fact O_assoc [to_pred])
   616 
   617 lemma trans_O_subset:
   618   "trans r \<Longrightarrow> r O r \<subseteq> r"
   619   by (unfold trans_def) blast
   620 
   621 lemma transp_relcompp_less_eq:
   622   "transp r \<Longrightarrow> r OO r \<le> r "
   623   by (fact trans_O_subset [to_pred])
   624 
   625 lemma relcomp_mono:
   626   "r' \<subseteq> r \<Longrightarrow> s' \<subseteq> s \<Longrightarrow> r' O s' \<subseteq> r O s"
   627   by blast
   628 
   629 lemma relcompp_mono:
   630   "r' \<le> r \<Longrightarrow> s' \<le> s \<Longrightarrow> r' OO s' \<le> r OO s "
   631   by (fact relcomp_mono [to_pred])
   632 
   633 lemma relcomp_subset_Sigma:
   634   "r \<subseteq> A \<times> B \<Longrightarrow> s \<subseteq> B \<times> C \<Longrightarrow> r O s \<subseteq> A \<times> C"
   635   by blast
   636 
   637 lemma relcomp_distrib [simp]:
   638   "R O (S \<union> T) = (R O S) \<union> (R O T)" 
   639   by auto
   640 
   641 lemma relcompp_distrib [simp]:
   642   "R OO (S \<squnion> T) = R OO S \<squnion> R OO T"
   643   by (fact relcomp_distrib [to_pred])
   644 
   645 lemma relcomp_distrib2 [simp]:
   646   "(S \<union> T) O R = (S O R) \<union> (T O R)"
   647   by auto
   648 
   649 lemma relcompp_distrib2 [simp]:
   650   "(S \<squnion> T) OO R = S OO R \<squnion> T OO R"
   651   by (fact relcomp_distrib2 [to_pred])
   652 
   653 lemma relcomp_UNION_distrib:
   654   "s O UNION I r = (\<Union>i\<in>I. s O r i) "
   655   by auto
   656 
   657 (* FIXME thm relcomp_UNION_distrib [to_pred] *)
   658 
   659 lemma relcomp_UNION_distrib2:
   660   "UNION I r O s = (\<Union>i\<in>I. r i O s) "
   661   by auto
   662 
   663 (* FIXME thm relcomp_UNION_distrib2 [to_pred] *)
   664 
   665 lemma single_valued_relcomp:
   666   "single_valued r \<Longrightarrow> single_valued s \<Longrightarrow> single_valued (r O s)"
   667   by (unfold single_valued_def) blast
   668 
   669 lemma relcomp_unfold:
   670   "r O s = {(x, z). \<exists>y. (x, y) \<in> r \<and> (y, z) \<in> s}"
   671   by (auto simp add: set_eq_iff)
   672 
   673 lemma relcompp_apply: "(R OO S) a c \<longleftrightarrow> (\<exists>b. R a b \<and> S b c)"
   674   unfolding relcomp_unfold [to_pred] ..
   675 
   676 lemma eq_OO: "op= OO R = R"
   677 by blast
   678 
   679 
   680 subsubsection {* Converse *}
   681 
   682 inductive_set converse :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'a) set" ("(_^-1)" [1000] 999)
   683   for r :: "('a \<times> 'b) set"
   684 where
   685   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r^-1"
   686 
   687 notation (xsymbols)
   688   converse  ("(_\<inverse>)" [1000] 999)
   689 
   690 notation
   691   conversep ("(_^--1)" [1000] 1000)
   692 
   693 notation (xsymbols)
   694   conversep  ("(_\<inverse>\<inverse>)" [1000] 1000)
   695 
   696 lemma converseI [sym]:
   697   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r\<inverse>"
   698   by (fact converse.intros)
   699 
   700 lemma conversepI (* CANDIDATE [sym] *):
   701   "r a b \<Longrightarrow> r\<inverse>\<inverse> b a"
   702   by (fact conversep.intros)
   703 
   704 lemma converseD [sym]:
   705   "(a, b) \<in> r\<inverse> \<Longrightarrow> (b, a) \<in> r"
   706   by (erule converse.cases) iprover
   707 
   708 lemma conversepD (* CANDIDATE [sym] *):
   709   "r\<inverse>\<inverse> b a \<Longrightarrow> r a b"
   710   by (fact converseD [to_pred])
   711 
   712 lemma converseE [elim!]:
   713   -- {* More general than @{text converseD}, as it ``splits'' the member of the relation. *}
   714   "yx \<in> r\<inverse> \<Longrightarrow> (\<And>x y. yx = (y, x) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> P) \<Longrightarrow> P"
   715   by (cases yx) (simp, erule converse.cases, iprover)
   716 
   717 lemmas conversepE [elim!] = conversep.cases
   718 
   719 lemma converse_iff [iff]:
   720   "(a, b) \<in> r\<inverse> \<longleftrightarrow> (b, a) \<in> r"
   721   by (auto intro: converseI)
   722 
   723 lemma conversep_iff [iff]:
   724   "r\<inverse>\<inverse> a b = r b a"
   725   by (fact converse_iff [to_pred])
   726 
   727 lemma converse_converse [simp]:
   728   "(r\<inverse>)\<inverse> = r"
   729   by (simp add: set_eq_iff)
   730 
   731 lemma conversep_conversep [simp]:
   732   "(r\<inverse>\<inverse>)\<inverse>\<inverse> = r"
   733   by (fact converse_converse [to_pred])
   734 
   735 lemma converse_empty[simp]: "{}\<inverse> = {}"
   736 by auto
   737 
   738 lemma converse_UNIV[simp]: "UNIV\<inverse> = UNIV"
   739 by auto
   740 
   741 lemma converse_relcomp: "(r O s)^-1 = s^-1 O r^-1"
   742   by blast
   743 
   744 lemma converse_relcompp: "(r OO s)^--1 = s^--1 OO r^--1"
   745   by (iprover intro: order_antisym conversepI relcomppI
   746     elim: relcomppE dest: conversepD)
   747 
   748 lemma converse_Int: "(r \<inter> s)^-1 = r^-1 \<inter> s^-1"
   749   by blast
   750 
   751 lemma converse_meet: "(r \<sqinter> s)^--1 = r^--1 \<sqinter> s^--1"
   752   by (simp add: inf_fun_def) (iprover intro: conversepI ext dest: conversepD)
   753 
   754 lemma converse_Un: "(r \<union> s)^-1 = r^-1 \<union> s^-1"
   755   by blast
   756 
   757 lemma converse_join: "(r \<squnion> s)^--1 = r^--1 \<squnion> s^--1"
   758   by (simp add: sup_fun_def) (iprover intro: conversepI ext dest: conversepD)
   759 
   760 lemma converse_INTER: "(INTER S r)^-1 = (INT x:S. (r x)^-1)"
   761   by fast
   762 
   763 lemma converse_UNION: "(UNION S r)^-1 = (UN x:S. (r x)^-1)"
   764   by blast
   765 
   766 lemma converse_mono[simp]: "r^-1 \<subseteq> s ^-1 \<longleftrightarrow> r \<subseteq> s"
   767   by auto
   768 
   769 lemma conversep_mono[simp]: "r^--1 \<le> s ^--1 \<longleftrightarrow> r \<le> s"
   770   by (fact converse_mono[to_pred])
   771 
   772 lemma converse_inject[simp]: "r^-1 = s ^-1 \<longleftrightarrow> r = s"
   773   by auto
   774 
   775 lemma conversep_inject[simp]: "r^--1 = s ^--1 \<longleftrightarrow> r = s"
   776   by (fact converse_inject[to_pred])
   777 
   778 lemma converse_subset_swap: "r \<subseteq> s ^-1 = (r ^-1 \<subseteq> s)"
   779   by auto
   780 
   781 lemma conversep_le_swap: "r \<le> s ^--1 = (r ^--1 \<le> s)"
   782   by (fact converse_subset_swap[to_pred])
   783 
   784 lemma converse_Id [simp]: "Id^-1 = Id"
   785   by blast
   786 
   787 lemma converse_Id_on [simp]: "(Id_on A)^-1 = Id_on A"
   788   by blast
   789 
   790 lemma refl_on_converse [simp]: "refl_on A (converse r) = refl_on A r"
   791   by (unfold refl_on_def) auto
   792 
   793 lemma sym_converse [simp]: "sym (converse r) = sym r"
   794   by (unfold sym_def) blast
   795 
   796 lemma antisym_converse [simp]: "antisym (converse r) = antisym r"
   797   by (unfold antisym_def) blast
   798 
   799 lemma trans_converse [simp]: "trans (converse r) = trans r"
   800   by (unfold trans_def) blast
   801 
   802 lemma sym_conv_converse_eq: "sym r = (r^-1 = r)"
   803   by (unfold sym_def) fast
   804 
   805 lemma sym_Un_converse: "sym (r \<union> r^-1)"
   806   by (unfold sym_def) blast
   807 
   808 lemma sym_Int_converse: "sym (r \<inter> r^-1)"
   809   by (unfold sym_def) blast
   810 
   811 lemma total_on_converse [simp]: "total_on A (r^-1) = total_on A r"
   812   by (auto simp: total_on_def)
   813 
   814 lemma finite_converse [iff]: "finite (r^-1) = finite r"  
   815   unfolding converse_def conversep_iff using [[simproc add: finite_Collect]]
   816   by (auto elim: finite_imageD simp: inj_on_def)
   817 
   818 lemma conversep_noteq [simp]: "(op \<noteq>)^--1 = op \<noteq>"
   819   by (auto simp add: fun_eq_iff)
   820 
   821 lemma conversep_eq [simp]: "(op =)^--1 = op ="
   822   by (auto simp add: fun_eq_iff)
   823 
   824 lemma converse_unfold [code]:
   825   "r\<inverse> = {(y, x). (x, y) \<in> r}"
   826   by (simp add: set_eq_iff)
   827 
   828 
   829 subsubsection {* Domain, range and field *}
   830 
   831 inductive_set Domain :: "('a \<times> 'b) set \<Rightarrow> 'a set"
   832   for r :: "('a \<times> 'b) set"
   833 where
   834   DomainI [intro]: "(a, b) \<in> r \<Longrightarrow> a \<in> Domain r"
   835 
   836 abbreviation (input) "DomainP \<equiv> Domainp"
   837 
   838 lemmas DomainPI = Domainp.DomainI
   839 
   840 inductive_cases DomainE [elim!]: "a \<in> Domain r"
   841 inductive_cases DomainpE [elim!]: "Domainp r a"
   842 
   843 inductive_set Range :: "('a \<times> 'b) set \<Rightarrow> 'b set"
   844   for r :: "('a \<times> 'b) set"
   845 where
   846   RangeI [intro]: "(a, b) \<in> r \<Longrightarrow> b \<in> Range r"
   847 
   848 abbreviation (input) "RangeP \<equiv> Rangep"
   849 
   850 lemmas RangePI = Rangep.RangeI
   851 
   852 inductive_cases RangeE [elim!]: "b \<in> Range r"
   853 inductive_cases RangepE [elim!]: "Rangep r b"
   854 
   855 definition Field :: "'a rel \<Rightarrow> 'a set"
   856 where
   857   "Field r = Domain r \<union> Range r"
   858 
   859 lemma Domain_fst [code]:
   860   "Domain r = fst ` r"
   861   by force
   862 
   863 lemma Range_snd [code]:
   864   "Range r = snd ` r"
   865   by force
   866 
   867 lemma fst_eq_Domain: "fst ` R = Domain R"
   868   by force
   869 
   870 lemma snd_eq_Range: "snd ` R = Range R"
   871   by force
   872 
   873 lemma Domain_empty [simp]: "Domain {} = {}"
   874   by auto
   875 
   876 lemma Range_empty [simp]: "Range {} = {}"
   877   by auto
   878 
   879 lemma Field_empty [simp]: "Field {} = {}"
   880   by (simp add: Field_def)
   881 
   882 lemma Domain_empty_iff: "Domain r = {} \<longleftrightarrow> r = {}"
   883   by auto
   884 
   885 lemma Range_empty_iff: "Range r = {} \<longleftrightarrow> r = {}"
   886   by auto
   887 
   888 lemma Domain_insert [simp]: "Domain (insert (a, b) r) = insert a (Domain r)"
   889   by blast
   890 
   891 lemma Range_insert [simp]: "Range (insert (a, b) r) = insert b (Range r)"
   892   by blast
   893 
   894 lemma Field_insert [simp]: "Field (insert (a, b) r) = {a, b} \<union> Field r"
   895   by (auto simp add: Field_def)
   896 
   897 lemma Domain_iff: "a \<in> Domain r \<longleftrightarrow> (\<exists>y. (a, y) \<in> r)"
   898   by blast
   899 
   900 lemma Range_iff: "a \<in> Range r \<longleftrightarrow> (\<exists>y. (y, a) \<in> r)"
   901   by blast
   902 
   903 lemma Domain_Id [simp]: "Domain Id = UNIV"
   904   by blast
   905 
   906 lemma Range_Id [simp]: "Range Id = UNIV"
   907   by blast
   908 
   909 lemma Domain_Id_on [simp]: "Domain (Id_on A) = A"
   910   by blast
   911 
   912 lemma Range_Id_on [simp]: "Range (Id_on A) = A"
   913   by blast
   914 
   915 lemma Domain_Un_eq: "Domain (A \<union> B) = Domain A \<union> Domain B"
   916   by blast
   917 
   918 lemma Range_Un_eq: "Range (A \<union> B) = Range A \<union> Range B"
   919   by blast
   920 
   921 lemma Field_Un [simp]: "Field (r \<union> s) = Field r \<union> Field s"
   922   by (auto simp: Field_def)
   923 
   924 lemma Domain_Int_subset: "Domain (A \<inter> B) \<subseteq> Domain A \<inter> Domain B"
   925   by blast
   926 
   927 lemma Range_Int_subset: "Range (A \<inter> B) \<subseteq> Range A \<inter> Range B"
   928   by blast
   929 
   930 lemma Domain_Diff_subset: "Domain A - Domain B \<subseteq> Domain (A - B)"
   931   by blast
   932 
   933 lemma Range_Diff_subset: "Range A - Range B \<subseteq> Range (A - B)"
   934   by blast
   935 
   936 lemma Domain_Union: "Domain (\<Union>S) = (\<Union>A\<in>S. Domain A)"
   937   by blast
   938 
   939 lemma Range_Union: "Range (\<Union>S) = (\<Union>A\<in>S. Range A)"
   940   by blast
   941 
   942 lemma Field_Union [simp]: "Field (\<Union>R) = \<Union>(Field ` R)"
   943   by (auto simp: Field_def)
   944 
   945 lemma Domain_converse [simp]: "Domain (r\<inverse>) = Range r"
   946   by auto
   947 
   948 lemma Range_converse [simp]: "Range (r\<inverse>) = Domain r"
   949   by blast
   950 
   951 lemma Field_converse [simp]: "Field (r\<inverse>) = Field r"
   952   by (auto simp: Field_def)
   953 
   954 lemma Domain_Collect_split [simp]: "Domain {(x, y). P x y} = {x. EX y. P x y}"
   955   by auto
   956 
   957 lemma Range_Collect_split [simp]: "Range {(x, y). P x y} = {y. EX x. P x y}"
   958   by auto
   959 
   960 lemma finite_Domain: "finite r \<Longrightarrow> finite (Domain r)"
   961   by (induct set: finite) auto
   962 
   963 lemma finite_Range: "finite r \<Longrightarrow> finite (Range r)"
   964   by (induct set: finite) auto
   965 
   966 lemma finite_Field: "finite r \<Longrightarrow> finite (Field r)"
   967   by (simp add: Field_def finite_Domain finite_Range)
   968 
   969 lemma Domain_mono: "r \<subseteq> s \<Longrightarrow> Domain r \<subseteq> Domain s"
   970   by blast
   971 
   972 lemma Range_mono: "r \<subseteq> s \<Longrightarrow> Range r \<subseteq> Range s"
   973   by blast
   974 
   975 lemma mono_Field: "r \<subseteq> s \<Longrightarrow> Field r \<subseteq> Field s"
   976   by (auto simp: Field_def Domain_def Range_def)
   977 
   978 lemma Domain_unfold:
   979   "Domain r = {x. \<exists>y. (x, y) \<in> r}"
   980   by blast
   981 
   982 
   983 subsubsection {* Image of a set under a relation *}
   984 
   985 definition Image :: "('a \<times> 'b) set \<Rightarrow> 'a set \<Rightarrow> 'b set" (infixr "``" 90)
   986 where
   987   "r `` s = {y. \<exists>x\<in>s. (x, y) \<in> r}"
   988 
   989 lemma Image_iff: "(b : r``A) = (EX x:A. (x, b) : r)"
   990   by (simp add: Image_def)
   991 
   992 lemma Image_singleton: "r``{a} = {b. (a, b) : r}"
   993   by (simp add: Image_def)
   994 
   995 lemma Image_singleton_iff [iff]: "(b : r``{a}) = ((a, b) : r)"
   996   by (rule Image_iff [THEN trans]) simp
   997 
   998 lemma ImageI [intro]: "(a, b) : r ==> a : A ==> b : r``A"
   999   by (unfold Image_def) blast
  1000 
  1001 lemma ImageE [elim!]:
  1002   "b : r `` A ==> (!!x. (x, b) : r ==> x : A ==> P) ==> P"
  1003   by (unfold Image_def) (iprover elim!: CollectE bexE)
  1004 
  1005 lemma rev_ImageI: "a : A ==> (a, b) : r ==> b : r `` A"
  1006   -- {* This version's more effective when we already have the required @{text a} *}
  1007   by blast
  1008 
  1009 lemma Image_empty [simp]: "R``{} = {}"
  1010   by blast
  1011 
  1012 lemma Image_Id [simp]: "Id `` A = A"
  1013   by blast
  1014 
  1015 lemma Image_Id_on [simp]: "Id_on A `` B = A \<inter> B"
  1016   by blast
  1017 
  1018 lemma Image_Int_subset: "R `` (A \<inter> B) \<subseteq> R `` A \<inter> R `` B"
  1019   by blast
  1020 
  1021 lemma Image_Int_eq:
  1022   "single_valued (converse R) ==> R `` (A \<inter> B) = R `` A \<inter> R `` B"
  1023   by (simp add: single_valued_def, blast) 
  1024 
  1025 lemma Image_Un: "R `` (A \<union> B) = R `` A \<union> R `` B"
  1026   by blast
  1027 
  1028 lemma Un_Image: "(R \<union> S) `` A = R `` A \<union> S `` A"
  1029   by blast
  1030 
  1031 lemma Image_subset: "r \<subseteq> A \<times> B ==> r``C \<subseteq> B"
  1032   by (iprover intro!: subsetI elim!: ImageE dest!: subsetD SigmaD2)
  1033 
  1034 lemma Image_eq_UN: "r``B = (\<Union>y\<in> B. r``{y})"
  1035   -- {* NOT suitable for rewriting *}
  1036   by blast
  1037 
  1038 lemma Image_mono: "r' \<subseteq> r ==> A' \<subseteq> A ==> (r' `` A') \<subseteq> (r `` A)"
  1039   by blast
  1040 
  1041 lemma Image_UN: "(r `` (UNION A B)) = (\<Union>x\<in>A. r `` (B x))"
  1042   by blast
  1043 
  1044 lemma UN_Image: "(\<Union>i\<in>I. X i) `` S = (\<Union>i\<in>I. X i `` S)"
  1045   by auto
  1046 
  1047 lemma Image_INT_subset: "(r `` INTER A B) \<subseteq> (\<Inter>x\<in>A. r `` (B x))"
  1048   by blast
  1049 
  1050 text{*Converse inclusion requires some assumptions*}
  1051 lemma Image_INT_eq:
  1052      "[|single_valued (r\<inverse>); A\<noteq>{}|] ==> r `` INTER A B = (\<Inter>x\<in>A. r `` B x)"
  1053 apply (rule equalityI)
  1054  apply (rule Image_INT_subset) 
  1055 apply  (simp add: single_valued_def, blast)
  1056 done
  1057 
  1058 lemma Image_subset_eq: "(r``A \<subseteq> B) = (A \<subseteq> - ((r^-1) `` (-B)))"
  1059   by blast
  1060 
  1061 lemma Image_Collect_split [simp]: "{(x, y). P x y} `` A = {y. EX x:A. P x y}"
  1062   by auto
  1063 
  1064 lemma Sigma_Image: "(SIGMA x:A. B x) `` X = (\<Union>x\<in>X \<inter> A. B x)"
  1065   by auto
  1066 
  1067 lemma relcomp_Image: "(X O Y) `` Z = Y `` (X `` Z)"
  1068   by auto
  1069 
  1070 subsubsection {* Inverse image *}
  1071 
  1072 definition inv_image :: "'b rel \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a rel"
  1073 where
  1074   "inv_image r f = {(x, y). (f x, f y) \<in> r}"
  1075 
  1076 definition inv_imagep :: "('b \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
  1077 where
  1078   "inv_imagep r f = (\<lambda>x y. r (f x) (f y))"
  1079 
  1080 lemma [pred_set_conv]: "inv_imagep (\<lambda>x y. (x, y) \<in> r) f = (\<lambda>x y. (x, y) \<in> inv_image r f)"
  1081   by (simp add: inv_image_def inv_imagep_def)
  1082 
  1083 lemma sym_inv_image: "sym r ==> sym (inv_image r f)"
  1084   by (unfold sym_def inv_image_def) blast
  1085 
  1086 lemma trans_inv_image: "trans r ==> trans (inv_image r f)"
  1087   apply (unfold trans_def inv_image_def)
  1088   apply (simp (no_asm))
  1089   apply blast
  1090   done
  1091 
  1092 lemma in_inv_image[simp]: "((x,y) : inv_image r f) = ((f x, f y) : r)"
  1093   by (auto simp:inv_image_def)
  1094 
  1095 lemma converse_inv_image[simp]: "(inv_image R f)^-1 = inv_image (R^-1) f"
  1096   unfolding inv_image_def converse_unfold by auto
  1097 
  1098 lemma in_inv_imagep [simp]: "inv_imagep r f x y = r (f x) (f y)"
  1099   by (simp add: inv_imagep_def)
  1100 
  1101 
  1102 subsubsection {* Powerset *}
  1103 
  1104 definition Powp :: "('a \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> bool"
  1105 where
  1106   "Powp A = (\<lambda>B. \<forall>x \<in> B. A x)"
  1107 
  1108 lemma Powp_Pow_eq [pred_set_conv]: "Powp (\<lambda>x. x \<in> A) = (\<lambda>x. x \<in> Pow A)"
  1109   by (auto simp add: Powp_def fun_eq_iff)
  1110 
  1111 lemmas Powp_mono [mono] = Pow_mono [to_pred]
  1112 
  1113 subsubsection {* Expressing relation operations via @{const Finite_Set.fold} *}
  1114 
  1115 lemma Id_on_fold:
  1116   assumes "finite A"
  1117   shows "Id_on A = Finite_Set.fold (\<lambda>x. Set.insert (Pair x x)) {} A"
  1118 proof -
  1119   interpret comp_fun_commute "\<lambda>x. Set.insert (Pair x x)" by default auto
  1120   show ?thesis using assms unfolding Id_on_def by (induct A) simp_all
  1121 qed
  1122 
  1123 lemma comp_fun_commute_Image_fold:
  1124   "comp_fun_commute (\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A)"
  1125 proof -
  1126   interpret comp_fun_idem Set.insert
  1127       by (fact comp_fun_idem_insert)
  1128   show ?thesis 
  1129   by default (auto simp add: fun_eq_iff comp_fun_commute split:prod.split)
  1130 qed
  1131 
  1132 lemma Image_fold:
  1133   assumes "finite R"
  1134   shows "R `` S = Finite_Set.fold (\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A) {} R"
  1135 proof -
  1136   interpret comp_fun_commute "(\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A)" 
  1137     by (rule comp_fun_commute_Image_fold)
  1138   have *: "\<And>x F. Set.insert x F `` S = (if fst x \<in> S then Set.insert (snd x) (F `` S) else (F `` S))"
  1139     by (force intro: rev_ImageI)
  1140   show ?thesis using assms by (induct R) (auto simp: *)
  1141 qed
  1142 
  1143 lemma insert_relcomp_union_fold:
  1144   assumes "finite S"
  1145   shows "{x} O S \<union> X = Finite_Set.fold (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A') X S"
  1146 proof -
  1147   interpret comp_fun_commute "\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A'"
  1148   proof - 
  1149     interpret comp_fun_idem Set.insert by (fact comp_fun_idem_insert)
  1150     show "comp_fun_commute (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A')"
  1151     by default (auto simp add: fun_eq_iff split:prod.split)
  1152   qed
  1153   have *: "{x} O S = {(x', z). x' = fst x \<and> (snd x,z) \<in> S}" by (auto simp: relcomp_unfold intro!: exI)
  1154   show ?thesis unfolding *
  1155   using `finite S` by (induct S) (auto split: prod.split)
  1156 qed
  1157 
  1158 lemma insert_relcomp_fold:
  1159   assumes "finite S"
  1160   shows "Set.insert x R O S = 
  1161     Finite_Set.fold (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A') (R O S) S"
  1162 proof -
  1163   have "Set.insert x R O S = ({x} O S) \<union> (R O S)" by auto
  1164   then show ?thesis by (auto simp: insert_relcomp_union_fold[OF assms])
  1165 qed
  1166 
  1167 lemma comp_fun_commute_relcomp_fold:
  1168   assumes "finite S"
  1169   shows "comp_fun_commute (\<lambda>(x,y) A. 
  1170     Finite_Set.fold (\<lambda>(w,z) A'. if y = w then Set.insert (x,z) A' else A') A S)"
  1171 proof -
  1172   have *: "\<And>a b A. 
  1173     Finite_Set.fold (\<lambda>(w, z) A'. if b = w then Set.insert (a, z) A' else A') A S = {(a,b)} O S \<union> A"
  1174     by (auto simp: insert_relcomp_union_fold[OF assms] cong: if_cong)
  1175   show ?thesis by default (auto simp: *)
  1176 qed
  1177 
  1178 lemma relcomp_fold:
  1179   assumes "finite R"
  1180   assumes "finite S"
  1181   shows "R O S = Finite_Set.fold 
  1182     (\<lambda>(x,y) A. Finite_Set.fold (\<lambda>(w,z) A'. if y = w then Set.insert (x,z) A' else A') A S) {} R"
  1183   using assms by (induct R)
  1184     (auto simp: comp_fun_commute.fold_insert comp_fun_commute_relcomp_fold insert_relcomp_fold
  1185       cong: if_cong)
  1186 
  1187 end