src/HOLCF/Cprod.thy
author huffman
Thu Jan 31 21:48:14 2008 +0100 (2008-01-31)
changeset 26027 87cb69d27558
parent 26025 ca6876116bb4
child 26029 46e84ca065f1
permissions -rw-r--r--
add lemma cpo_lubI
     1 (*  Title:      HOLCF/Cprod.thy
     2     ID:         $Id$
     3     Author:     Franz Regensburger
     4 
     5 Partial ordering for cartesian product of HOL products.
     6 *)
     7 
     8 header {* The cpo of cartesian products *}
     9 
    10 theory Cprod
    11 imports Bifinite
    12 begin
    13 
    14 defaultsort cpo
    15 
    16 subsection {* Type @{typ unit} is a pcpo *}
    17 
    18 instantiation unit :: sq_ord
    19 begin
    20 
    21 definition
    22   less_unit_def [simp]: "x \<sqsubseteq> (y::unit) \<equiv> True"
    23 
    24 instance ..
    25 end
    26 
    27 instance unit :: discrete_cpo
    28 by intro_classes simp
    29 
    30 instance unit :: finite_po ..
    31 
    32 instance unit :: pcpo
    33 by intro_classes simp
    34 
    35 definition
    36   unit_when :: "'a \<rightarrow> unit \<rightarrow> 'a" where
    37   "unit_when = (\<Lambda> a _. a)"
    38 
    39 translations
    40   "\<Lambda>(). t" == "CONST unit_when\<cdot>t"
    41 
    42 lemma unit_when [simp]: "unit_when\<cdot>a\<cdot>u = a"
    43 by (simp add: unit_when_def)
    44 
    45 
    46 subsection {* Product type is a partial order *}
    47 
    48 instantiation "*" :: (po, po) po
    49 begin
    50 
    51 definition
    52   less_cprod_def: "(op \<sqsubseteq>) \<equiv> \<lambda>p1 p2. (fst p1 \<sqsubseteq> fst p2 \<and> snd p1 \<sqsubseteq> snd p2)"
    53 
    54 instance
    55 proof
    56   fix x :: "'a \<times> 'b"
    57   show "x \<sqsubseteq> x"
    58     unfolding less_cprod_def by simp
    59 next
    60   fix x y :: "'a \<times> 'b"
    61   assume "x \<sqsubseteq> y" "y \<sqsubseteq> x" thus "x = y"
    62     unfolding less_cprod_def Pair_fst_snd_eq
    63     by (fast intro: antisym_less)
    64 next
    65   fix x y z :: "'a \<times> 'b"
    66   assume "x \<sqsubseteq> y" "y \<sqsubseteq> z" thus "x \<sqsubseteq> z"
    67     unfolding less_cprod_def
    68     by (fast intro: trans_less)
    69 qed
    70 
    71 end
    72 
    73 subsection {* Monotonicity of @{text "(_,_)"}, @{term fst}, @{term snd} *}
    74 
    75 text {* Pair @{text "(_,_)"}  is monotone in both arguments *}
    76 
    77 lemma monofun_pair1: "monofun (\<lambda>x. (x, y))"
    78 by (simp add: monofun_def less_cprod_def)
    79 
    80 lemma monofun_pair2: "monofun (\<lambda>y. (x, y))"
    81 by (simp add: monofun_def less_cprod_def)
    82 
    83 lemma monofun_pair:
    84   "\<lbrakk>x1 \<sqsubseteq> x2; y1 \<sqsubseteq> y2\<rbrakk> \<Longrightarrow> (x1, y1) \<sqsubseteq> (x2, y2)"
    85 by (simp add: less_cprod_def)
    86 
    87 text {* @{term fst} and @{term snd} are monotone *}
    88 
    89 lemma monofun_fst: "monofun fst"
    90 by (simp add: monofun_def less_cprod_def)
    91 
    92 lemma monofun_snd: "monofun snd"
    93 by (simp add: monofun_def less_cprod_def)
    94 
    95 subsection {* Product type is a cpo *}
    96 
    97 lemma is_lub_Pair:
    98   "\<lbrakk>range X <<| x; range Y <<| y\<rbrakk> \<Longrightarrow> range (\<lambda>i. (X i, Y i)) <<| (x, y)"
    99 apply (rule is_lubI [OF ub_rangeI])
   100 apply (simp add: less_cprod_def is_ub_lub)
   101 apply (frule ub2ub_monofun [OF monofun_fst])
   102 apply (drule ub2ub_monofun [OF monofun_snd])
   103 apply (simp add: less_cprod_def is_lub_lub)
   104 done
   105 
   106 lemma lub_cprod:
   107   fixes S :: "nat \<Rightarrow> ('a::cpo \<times> 'b::cpo)"
   108   assumes S: "chain S"
   109   shows "range S <<| (\<Squnion>i. fst (S i), \<Squnion>i. snd (S i))"
   110 proof -
   111   have "chain (\<lambda>i. fst (S i))"
   112     using monofun_fst S by (rule ch2ch_monofun)
   113   hence 1: "range (\<lambda>i. fst (S i)) <<| (\<Squnion>i. fst (S i))"
   114     by (rule cpo_lubI)
   115   have "chain (\<lambda>i. snd (S i))"
   116     using monofun_snd S by (rule ch2ch_monofun)
   117   hence 2: "range (\<lambda>i. snd (S i)) <<| (\<Squnion>i. snd (S i))"
   118     by (rule cpo_lubI)
   119   show "range S <<| (\<Squnion>i. fst (S i), \<Squnion>i. snd (S i))"
   120     using is_lub_Pair [OF 1 2] by simp
   121 qed
   122 
   123 lemma thelub_cprod:
   124   "chain (S::nat \<Rightarrow> 'a::cpo \<times> 'b::cpo)
   125     \<Longrightarrow> lub (range S) = (\<Squnion>i. fst (S i), \<Squnion>i. snd (S i))"
   126 by (rule lub_cprod [THEN thelubI])
   127 
   128 instance "*" :: (cpo, cpo) cpo
   129 proof
   130   fix S :: "nat \<Rightarrow> ('a \<times> 'b)"
   131   assume "chain S"
   132   hence "range S <<| (\<Squnion>i. fst (S i), \<Squnion>i. snd (S i))"
   133     by (rule lub_cprod)
   134   thus "\<exists>x. range S <<| x" ..
   135 qed
   136 
   137 instance "*" :: (finite_po, finite_po) finite_po ..
   138 
   139 instance "*" :: (discrete_cpo, discrete_cpo) discrete_cpo
   140 proof
   141   fix x y :: "'a \<times> 'b"
   142   show "x \<sqsubseteq> y \<longleftrightarrow> x = y"
   143     unfolding less_cprod_def Pair_fst_snd_eq
   144     by simp
   145 qed
   146 
   147 subsection {* Product type is pointed *}
   148 
   149 lemma minimal_cprod: "(\<bottom>, \<bottom>) \<sqsubseteq> p"
   150 by (simp add: less_cprod_def)
   151 
   152 instance "*" :: (pcpo, pcpo) pcpo
   153 by intro_classes (fast intro: minimal_cprod)
   154 
   155 lemma inst_cprod_pcpo: "\<bottom> = (\<bottom>, \<bottom>)"
   156 by (rule minimal_cprod [THEN UU_I, symmetric])
   157 
   158 
   159 subsection {* Continuity of @{text "(_,_)"}, @{term fst}, @{term snd} *}
   160 
   161 lemma cont_pair1: "cont (\<lambda>x. (x, y))"
   162 apply (rule contI)
   163 apply (rule is_lub_Pair)
   164 apply (erule cpo_lubI)
   165 apply (rule lub_const)
   166 done
   167 
   168 lemma cont_pair2: "cont (\<lambda>y. (x, y))"
   169 apply (rule contI)
   170 apply (rule is_lub_Pair)
   171 apply (rule lub_const)
   172 apply (erule cpo_lubI)
   173 done
   174 
   175 lemma contlub_fst: "contlub fst"
   176 apply (rule contlubI)
   177 apply (simp add: thelub_cprod)
   178 done
   179 
   180 lemma contlub_snd: "contlub snd"
   181 apply (rule contlubI)
   182 apply (simp add: thelub_cprod)
   183 done
   184 
   185 lemma cont_fst: "cont fst"
   186 apply (rule monocontlub2cont)
   187 apply (rule monofun_fst)
   188 apply (rule contlub_fst)
   189 done
   190 
   191 lemma cont_snd: "cont snd"
   192 apply (rule monocontlub2cont)
   193 apply (rule monofun_snd)
   194 apply (rule contlub_snd)
   195 done
   196 
   197 subsection {* Continuous versions of constants *}
   198 
   199 definition
   200   cpair :: "'a \<rightarrow> 'b \<rightarrow> ('a * 'b)"  -- {* continuous pairing *}  where
   201   "cpair = (\<Lambda> x y. (x, y))"
   202 
   203 definition
   204   cfst :: "('a * 'b) \<rightarrow> 'a" where
   205   "cfst = (\<Lambda> p. fst p)"
   206 
   207 definition
   208   csnd :: "('a * 'b) \<rightarrow> 'b" where
   209   "csnd = (\<Lambda> p. snd p)"      
   210 
   211 definition
   212   csplit :: "('a \<rightarrow> 'b \<rightarrow> 'c) \<rightarrow> ('a * 'b) \<rightarrow> 'c" where
   213   "csplit = (\<Lambda> f p. f\<cdot>(cfst\<cdot>p)\<cdot>(csnd\<cdot>p))"
   214 
   215 syntax
   216   "_ctuple" :: "['a, args] \<Rightarrow> 'a * 'b"  ("(1<_,/ _>)")
   217 
   218 syntax (xsymbols)
   219   "_ctuple" :: "['a, args] \<Rightarrow> 'a * 'b"  ("(1\<langle>_,/ _\<rangle>)")
   220 
   221 translations
   222   "\<langle>x, y, z\<rangle>" == "\<langle>x, \<langle>y, z\<rangle>\<rangle>"
   223   "\<langle>x, y\<rangle>"    == "CONST cpair\<cdot>x\<cdot>y"
   224 
   225 translations
   226   "\<Lambda>(CONST cpair\<cdot>x\<cdot>y). t" == "CONST csplit\<cdot>(\<Lambda> x y. t)"
   227 
   228 
   229 subsection {* Convert all lemmas to the continuous versions *}
   230 
   231 lemma cpair_eq_pair: "<x, y> = (x, y)"
   232 by (simp add: cpair_def cont_pair1 cont_pair2)
   233 
   234 lemma pair_eq_cpair: "(x, y) = <x, y>"
   235 by (simp add: cpair_def cont_pair1 cont_pair2)
   236 
   237 lemma inject_cpair: "<a,b> = <aa,ba> \<Longrightarrow> a = aa \<and> b = ba"
   238 by (simp add: cpair_eq_pair)
   239 
   240 lemma cpair_eq [iff]: "(<a, b> = <a', b'>) = (a = a' \<and> b = b')"
   241 by (simp add: cpair_eq_pair)
   242 
   243 lemma cpair_less [iff]: "(<a, b> \<sqsubseteq> <a', b'>) = (a \<sqsubseteq> a' \<and> b \<sqsubseteq> b')"
   244 by (simp add: cpair_eq_pair less_cprod_def)
   245 
   246 lemma cpair_defined_iff [iff]: "(<x, y> = \<bottom>) = (x = \<bottom> \<and> y = \<bottom>)"
   247 by (simp add: inst_cprod_pcpo cpair_eq_pair)
   248 
   249 lemma cpair_strict [simp]: "\<langle>\<bottom>, \<bottom>\<rangle> = \<bottom>"
   250 by simp
   251 
   252 lemma inst_cprod_pcpo2: "\<bottom> = <\<bottom>, \<bottom>>"
   253 by (rule cpair_strict [symmetric])
   254 
   255 lemma defined_cpair_rev: 
   256  "<a,b> = \<bottom> \<Longrightarrow> a = \<bottom> \<and> b = \<bottom>"
   257 by simp
   258 
   259 lemma Exh_Cprod2: "\<exists>a b. z = <a, b>"
   260 by (simp add: cpair_eq_pair)
   261 
   262 lemma cprodE: "\<lbrakk>\<And>x y. p = <x, y> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
   263 by (cut_tac Exh_Cprod2, auto)
   264 
   265 lemma cfst_cpair [simp]: "cfst\<cdot><x, y> = x"
   266 by (simp add: cpair_eq_pair cfst_def cont_fst)
   267 
   268 lemma csnd_cpair [simp]: "csnd\<cdot><x, y> = y"
   269 by (simp add: cpair_eq_pair csnd_def cont_snd)
   270 
   271 lemma cfst_strict [simp]: "cfst\<cdot>\<bottom> = \<bottom>"
   272 unfolding inst_cprod_pcpo2 by (rule cfst_cpair)
   273 
   274 lemma csnd_strict [simp]: "csnd\<cdot>\<bottom> = \<bottom>"
   275 unfolding inst_cprod_pcpo2 by (rule csnd_cpair)
   276 
   277 lemma cpair_cfst_csnd: "\<langle>cfst\<cdot>p, csnd\<cdot>p\<rangle> = p"
   278 by (cases p rule: cprodE, simp)
   279 
   280 lemmas surjective_pairing_Cprod2 = cpair_cfst_csnd
   281 
   282 lemma less_cprod: "x \<sqsubseteq> y = (cfst\<cdot>x \<sqsubseteq> cfst\<cdot>y \<and> csnd\<cdot>x \<sqsubseteq> csnd\<cdot>y)"
   283 by (simp add: less_cprod_def cfst_def csnd_def cont_fst cont_snd)
   284 
   285 lemma eq_cprod: "(x = y) = (cfst\<cdot>x = cfst\<cdot>y \<and> csnd\<cdot>x = csnd\<cdot>y)"
   286 by (auto simp add: po_eq_conv less_cprod)
   287 
   288 lemma cfst_less_iff: "cfst\<cdot>x \<sqsubseteq> y = x \<sqsubseteq> <y, csnd\<cdot>x>"
   289 by (simp add: less_cprod)
   290 
   291 lemma csnd_less_iff: "csnd\<cdot>x \<sqsubseteq> y = x \<sqsubseteq> <cfst\<cdot>x, y>"
   292 by (simp add: less_cprod)
   293 
   294 lemma compact_cfst: "compact x \<Longrightarrow> compact (cfst\<cdot>x)"
   295 by (rule compactI, simp add: cfst_less_iff)
   296 
   297 lemma compact_csnd: "compact x \<Longrightarrow> compact (csnd\<cdot>x)"
   298 by (rule compactI, simp add: csnd_less_iff)
   299 
   300 lemma compact_cpair: "\<lbrakk>compact x; compact y\<rbrakk> \<Longrightarrow> compact <x, y>"
   301 by (rule compactI, simp add: less_cprod)
   302 
   303 lemma compact_cpair_iff [simp]: "compact <x, y> = (compact x \<and> compact y)"
   304 apply (safe intro!: compact_cpair)
   305 apply (drule compact_cfst, simp)
   306 apply (drule compact_csnd, simp)
   307 done
   308 
   309 instance "*" :: (chfin, chfin) chfin
   310 apply intro_classes
   311 apply (erule compact_imp_max_in_chain)
   312 apply (rule_tac p="\<Squnion>i. Y i" in cprodE, simp)
   313 done
   314 
   315 lemma lub_cprod2: 
   316   "chain S \<Longrightarrow> range S <<| <\<Squnion>i. cfst\<cdot>(S i), \<Squnion>i. csnd\<cdot>(S i)>"
   317 apply (simp add: cpair_eq_pair cfst_def csnd_def cont_fst cont_snd)
   318 apply (erule lub_cprod)
   319 done
   320 
   321 lemma thelub_cprod2:
   322   "chain S \<Longrightarrow> lub (range S) = <\<Squnion>i. cfst\<cdot>(S i), \<Squnion>i. csnd\<cdot>(S i)>"
   323 by (rule lub_cprod2 [THEN thelubI])
   324 
   325 lemma csplit1 [simp]: "csplit\<cdot>f\<cdot>\<bottom> = f\<cdot>\<bottom>\<cdot>\<bottom>"
   326 by (simp add: csplit_def)
   327 
   328 lemma csplit2 [simp]: "csplit\<cdot>f\<cdot><x,y> = f\<cdot>x\<cdot>y"
   329 by (simp add: csplit_def)
   330 
   331 lemma csplit3 [simp]: "csplit\<cdot>cpair\<cdot>z = z"
   332 by (simp add: csplit_def cpair_cfst_csnd)
   333 
   334 lemmas Cprod_rews = cfst_cpair csnd_cpair csplit2
   335 
   336 subsection {* Product type is a bifinite domain *}
   337 
   338 instance "*" :: (bifinite_cpo, bifinite_cpo) approx ..
   339 
   340 defs (overloaded)
   341   approx_cprod_def:
   342     "approx \<equiv> \<lambda>n. \<Lambda>\<langle>x, y\<rangle>. \<langle>approx n\<cdot>x, approx n\<cdot>y\<rangle>"
   343 
   344 instance "*" :: (bifinite_cpo, bifinite_cpo) bifinite_cpo
   345 proof
   346   fix i :: nat and x :: "'a \<times> 'b"
   347   show "chain (\<lambda>i. approx i\<cdot>x)"
   348     unfolding approx_cprod_def by simp
   349   show "(\<Squnion>i. approx i\<cdot>x) = x"
   350     unfolding approx_cprod_def
   351     by (simp add: lub_distribs eta_cfun)
   352   show "approx i\<cdot>(approx i\<cdot>x) = approx i\<cdot>x"
   353     unfolding approx_cprod_def csplit_def by simp
   354   have "{x::'a \<times> 'b. approx i\<cdot>x = x} \<subseteq>
   355         {x::'a. approx i\<cdot>x = x} \<times> {x::'b. approx i\<cdot>x = x}"
   356     unfolding approx_cprod_def
   357     by (clarsimp simp add: pair_eq_cpair)
   358   thus "finite {x::'a \<times> 'b. approx i\<cdot>x = x}"
   359     by (rule finite_subset,
   360         intro finite_cartesian_product finite_fixes_approx)
   361 qed
   362 
   363 instance "*" :: (bifinite, bifinite) bifinite ..
   364 
   365 lemma approx_cpair [simp]:
   366   "approx i\<cdot>\<langle>x, y\<rangle> = \<langle>approx i\<cdot>x, approx i\<cdot>y\<rangle>"
   367 unfolding approx_cprod_def by simp
   368 
   369 lemma cfst_approx: "cfst\<cdot>(approx i\<cdot>p) = approx i\<cdot>(cfst\<cdot>p)"
   370 by (cases p rule: cprodE, simp)
   371 
   372 lemma csnd_approx: "csnd\<cdot>(approx i\<cdot>p) = approx i\<cdot>(csnd\<cdot>p)"
   373 by (cases p rule: cprodE, simp)
   374 
   375 end