src/HOL/Transitive_Closure.thy
author nipkow
Sun Jun 22 12:37:55 2014 +0200 (2014-06-22)
changeset 57284 886ff14f20cc
parent 57283 1f133cd8d3eb
child 58889 5b7a9633cfa8
permissions -rw-r--r--
r_into_(r)trancl should not be [simp]: helps little and comlicates some AFP proofs
     1 (*  Title:      HOL/Transitive_Closure.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Reflexive and Transitive closure of a relation *}
     7 
     8 theory Transitive_Closure
     9 imports Relation
    10 begin
    11 
    12 ML_file "~~/src/Provers/trancl.ML"
    13 
    14 text {*
    15   @{text rtrancl} is reflexive/transitive closure,
    16   @{text trancl} is transitive closure,
    17   @{text reflcl} is reflexive closure.
    18 
    19   These postfix operators have \emph{maximum priority}, forcing their
    20   operands to be atomic.
    21 *}
    22 
    23 inductive_set
    24   rtrancl :: "('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"   ("(_^*)" [1000] 999)
    25   for r :: "('a \<times> 'a) set"
    26 where
    27     rtrancl_refl [intro!, Pure.intro!, simp]: "(a, a) : r^*"
    28   | rtrancl_into_rtrancl [Pure.intro]: "(a, b) : r^* ==> (b, c) : r ==> (a, c) : r^*"
    29 
    30 inductive_set
    31   trancl :: "('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"  ("(_^+)" [1000] 999)
    32   for r :: "('a \<times> 'a) set"
    33 where
    34     r_into_trancl [intro, Pure.intro]: "(a, b) : r ==> (a, b) : r^+"
    35   | trancl_into_trancl [Pure.intro]: "(a, b) : r^+ ==> (b, c) : r ==> (a, c) : r^+"
    36 
    37 declare rtrancl_def [nitpick_unfold del]
    38         rtranclp_def [nitpick_unfold del]
    39         trancl_def [nitpick_unfold del]
    40         tranclp_def [nitpick_unfold del]
    41 
    42 notation
    43   rtranclp  ("(_^**)" [1000] 1000) and
    44   tranclp  ("(_^++)" [1000] 1000)
    45 
    46 abbreviation
    47   reflclp :: "('a => 'a => bool) => 'a => 'a => bool"  ("(_^==)" [1000] 1000) where
    48   "r^== \<equiv> sup r op ="
    49 
    50 abbreviation
    51   reflcl :: "('a \<times> 'a) set => ('a \<times> 'a) set"  ("(_^=)" [1000] 999) where
    52   "r^= \<equiv> r \<union> Id"
    53 
    54 notation (xsymbols)
    55   rtranclp  ("(_\<^sup>*\<^sup>*)" [1000] 1000) and
    56   tranclp  ("(_\<^sup>+\<^sup>+)" [1000] 1000) and
    57   reflclp  ("(_\<^sup>=\<^sup>=)" [1000] 1000) and
    58   rtrancl  ("(_\<^sup>*)" [1000] 999) and
    59   trancl  ("(_\<^sup>+)" [1000] 999) and
    60   reflcl  ("(_\<^sup>=)" [1000] 999)
    61 
    62 notation (HTML output)
    63   rtranclp  ("(_\<^sup>*\<^sup>*)" [1000] 1000) and
    64   tranclp  ("(_\<^sup>+\<^sup>+)" [1000] 1000) and
    65   reflclp  ("(_\<^sup>=\<^sup>=)" [1000] 1000) and
    66   rtrancl  ("(_\<^sup>*)" [1000] 999) and
    67   trancl  ("(_\<^sup>+)" [1000] 999) and
    68   reflcl  ("(_\<^sup>=)" [1000] 999)
    69 
    70 
    71 subsection {* Reflexive closure *}
    72 
    73 lemma refl_reflcl[simp]: "refl(r^=)"
    74 by(simp add:refl_on_def)
    75 
    76 lemma antisym_reflcl[simp]: "antisym(r^=) = antisym r"
    77 by(simp add:antisym_def)
    78 
    79 lemma trans_reflclI[simp]: "trans r \<Longrightarrow> trans(r^=)"
    80 unfolding trans_def by blast
    81 
    82 lemma reflclp_idemp [simp]: "(P^==)^==  =  P^=="
    83 by blast
    84 
    85 subsection {* Reflexive-transitive closure *}
    86 
    87 lemma reflcl_set_eq [pred_set_conv]: "(sup (\<lambda>x y. (x, y) \<in> r) op =) = (\<lambda>x y. (x, y) \<in> r \<union> Id)"
    88   by (auto simp add: fun_eq_iff)
    89 
    90 lemma r_into_rtrancl [intro]: "!!p. p \<in> r ==> p \<in> r^*"
    91   -- {* @{text rtrancl} of @{text r} contains @{text r} *}
    92   apply (simp only: split_tupled_all)
    93   apply (erule rtrancl_refl [THEN rtrancl_into_rtrancl])
    94   done
    95 
    96 lemma r_into_rtranclp [intro]: "r x y ==> r^** x y"
    97   -- {* @{text rtrancl} of @{text r} contains @{text r} *}
    98   by (erule rtranclp.rtrancl_refl [THEN rtranclp.rtrancl_into_rtrancl])
    99 
   100 lemma rtranclp_mono: "r \<le> s ==> r^** \<le> s^**"
   101   -- {* monotonicity of @{text rtrancl} *}
   102   apply (rule predicate2I)
   103   apply (erule rtranclp.induct)
   104    apply (rule_tac [2] rtranclp.rtrancl_into_rtrancl, blast+)
   105   done
   106 
   107 lemmas rtrancl_mono = rtranclp_mono [to_set]
   108 
   109 theorem rtranclp_induct [consumes 1, case_names base step, induct set: rtranclp]:
   110   assumes a: "r^** a b"
   111     and cases: "P a" "!!y z. [| r^** a y; r y z; P y |] ==> P z"
   112   shows "P b" using a
   113   by (induct x\<equiv>a b) (rule cases)+
   114 
   115 lemmas rtrancl_induct [induct set: rtrancl] = rtranclp_induct [to_set]
   116 
   117 lemmas rtranclp_induct2 =
   118   rtranclp_induct[of _ "(ax,ay)" "(bx,by)", split_rule,
   119                  consumes 1, case_names refl step]
   120 
   121 lemmas rtrancl_induct2 =
   122   rtrancl_induct[of "(ax,ay)" "(bx,by)", split_format (complete),
   123                  consumes 1, case_names refl step]
   124 
   125 lemma refl_rtrancl: "refl (r^*)"
   126 by (unfold refl_on_def) fast
   127 
   128 text {* Transitivity of transitive closure. *}
   129 lemma trans_rtrancl: "trans (r^*)"
   130 proof (rule transI)
   131   fix x y z
   132   assume "(x, y) \<in> r\<^sup>*"
   133   assume "(y, z) \<in> r\<^sup>*"
   134   then show "(x, z) \<in> r\<^sup>*"
   135   proof induct
   136     case base
   137     show "(x, y) \<in> r\<^sup>*" by fact
   138   next
   139     case (step u v)
   140     from `(x, u) \<in> r\<^sup>*` and `(u, v) \<in> r`
   141     show "(x, v) \<in> r\<^sup>*" ..
   142   qed
   143 qed
   144 
   145 lemmas rtrancl_trans = trans_rtrancl [THEN transD]
   146 
   147 lemma rtranclp_trans:
   148   assumes xy: "r^** x y"
   149   and yz: "r^** y z"
   150   shows "r^** x z" using yz xy
   151   by induct iprover+
   152 
   153 lemma rtranclE [cases set: rtrancl]:
   154   assumes major: "(a::'a, b) : r^*"
   155   obtains
   156     (base) "a = b"
   157   | (step) y where "(a, y) : r^*" and "(y, b) : r"
   158   -- {* elimination of @{text rtrancl} -- by induction on a special formula *}
   159   apply (subgoal_tac "(a::'a) = b | (EX y. (a,y) : r^* & (y,b) : r)")
   160    apply (rule_tac [2] major [THEN rtrancl_induct])
   161     prefer 2 apply blast
   162    prefer 2 apply blast
   163   apply (erule asm_rl exE disjE conjE base step)+
   164   done
   165 
   166 lemma rtrancl_Int_subset: "[| Id \<subseteq> s; (r^* \<inter> s) O r \<subseteq> s|] ==> r^* \<subseteq> s"
   167   apply (rule subsetI)
   168   apply (rule_tac p="x" in PairE, clarify)
   169   apply (erule rtrancl_induct, auto) 
   170   done
   171 
   172 lemma converse_rtranclp_into_rtranclp:
   173   "r a b \<Longrightarrow> r\<^sup>*\<^sup>* b c \<Longrightarrow> r\<^sup>*\<^sup>* a c"
   174   by (rule rtranclp_trans) iprover+
   175 
   176 lemmas converse_rtrancl_into_rtrancl = converse_rtranclp_into_rtranclp [to_set]
   177 
   178 text {*
   179   \medskip More @{term "r^*"} equations and inclusions.
   180 *}
   181 
   182 lemma rtranclp_idemp [simp]: "(r^**)^** = r^**"
   183   apply (auto intro!: order_antisym)
   184   apply (erule rtranclp_induct)
   185    apply (rule rtranclp.rtrancl_refl)
   186   apply (blast intro: rtranclp_trans)
   187   done
   188 
   189 lemmas rtrancl_idemp [simp] = rtranclp_idemp [to_set]
   190 
   191 lemma rtrancl_idemp_self_comp [simp]: "R^* O R^* = R^*"
   192   apply (rule set_eqI)
   193   apply (simp only: split_tupled_all)
   194   apply (blast intro: rtrancl_trans)
   195   done
   196 
   197 lemma rtrancl_subset_rtrancl: "r \<subseteq> s^* ==> r^* \<subseteq> s^*"
   198   apply (drule rtrancl_mono)
   199   apply simp
   200   done
   201 
   202 lemma rtranclp_subset: "R \<le> S ==> S \<le> R^** ==> S^** = R^**"
   203   apply (drule rtranclp_mono)
   204   apply (drule rtranclp_mono)
   205   apply simp
   206   done
   207 
   208 lemmas rtrancl_subset = rtranclp_subset [to_set]
   209 
   210 lemma rtranclp_sup_rtranclp: "(sup (R^**) (S^**))^** = (sup R S)^**"
   211 by (blast intro!: rtranclp_subset intro: rtranclp_mono [THEN predicate2D])
   212 
   213 lemmas rtrancl_Un_rtrancl = rtranclp_sup_rtranclp [to_set]
   214 
   215 lemma rtranclp_reflclp [simp]: "(R^==)^** = R^**"
   216 by (blast intro!: rtranclp_subset)
   217 
   218 lemmas rtrancl_reflcl [simp] = rtranclp_reflclp [to_set]
   219 
   220 lemma rtrancl_r_diff_Id: "(r - Id)^* = r^*"
   221   apply (rule sym)
   222   apply (rule rtrancl_subset, blast, clarify)
   223   apply (rename_tac a b)
   224   apply (case_tac "a = b")
   225    apply blast
   226   apply blast
   227   done
   228 
   229 lemma rtranclp_r_diff_Id: "(inf r op ~=)^** = r^**"
   230   apply (rule sym)
   231   apply (rule rtranclp_subset)
   232    apply blast+
   233   done
   234 
   235 theorem rtranclp_converseD:
   236   assumes r: "(r^--1)^** x y"
   237   shows "r^** y x"
   238 proof -
   239   from r show ?thesis
   240     by induct (iprover intro: rtranclp_trans dest!: conversepD)+
   241 qed
   242 
   243 lemmas rtrancl_converseD = rtranclp_converseD [to_set]
   244 
   245 theorem rtranclp_converseI:
   246   assumes "r^** y x"
   247   shows "(r^--1)^** x y"
   248   using assms
   249   by induct (iprover intro: rtranclp_trans conversepI)+
   250 
   251 lemmas rtrancl_converseI = rtranclp_converseI [to_set]
   252 
   253 lemma rtrancl_converse: "(r^-1)^* = (r^*)^-1"
   254   by (fast dest!: rtrancl_converseD intro!: rtrancl_converseI)
   255 
   256 lemma sym_rtrancl: "sym r ==> sym (r^*)"
   257   by (simp only: sym_conv_converse_eq rtrancl_converse [symmetric])
   258 
   259 theorem converse_rtranclp_induct [consumes 1, case_names base step]:
   260   assumes major: "r^** a b"
   261     and cases: "P b" "!!y z. [| r y z; r^** z b; P z |] ==> P y"
   262   shows "P a"
   263   using rtranclp_converseI [OF major]
   264   by induct (iprover intro: cases dest!: conversepD rtranclp_converseD)+
   265 
   266 lemmas converse_rtrancl_induct = converse_rtranclp_induct [to_set]
   267 
   268 lemmas converse_rtranclp_induct2 =
   269   converse_rtranclp_induct [of _ "(ax,ay)" "(bx,by)", split_rule,
   270                  consumes 1, case_names refl step]
   271 
   272 lemmas converse_rtrancl_induct2 =
   273   converse_rtrancl_induct [of "(ax,ay)" "(bx,by)", split_format (complete),
   274                  consumes 1, case_names refl step]
   275 
   276 lemma converse_rtranclpE [consumes 1, case_names base step]:
   277   assumes major: "r^** x z"
   278     and cases: "x=z ==> P"
   279       "!!y. [| r x y; r^** y z |] ==> P"
   280   shows P
   281   apply (subgoal_tac "x = z | (EX y. r x y & r^** y z)")
   282    apply (rule_tac [2] major [THEN converse_rtranclp_induct])
   283     prefer 2 apply iprover
   284    prefer 2 apply iprover
   285   apply (erule asm_rl exE disjE conjE cases)+
   286   done
   287 
   288 lemmas converse_rtranclE = converse_rtranclpE [to_set]
   289 
   290 lemmas converse_rtranclpE2 = converse_rtranclpE [of _ "(xa,xb)" "(za,zb)", split_rule]
   291 
   292 lemmas converse_rtranclE2 = converse_rtranclE [of "(xa,xb)" "(za,zb)", split_rule]
   293 
   294 lemma r_comp_rtrancl_eq: "r O r^* = r^* O r"
   295   by (blast elim: rtranclE converse_rtranclE
   296     intro: rtrancl_into_rtrancl converse_rtrancl_into_rtrancl)
   297 
   298 lemma rtrancl_unfold: "r^* = Id Un r^* O r"
   299   by (auto intro: rtrancl_into_rtrancl elim: rtranclE)
   300 
   301 lemma rtrancl_Un_separatorE:
   302   "(a,b) : (P \<union> Q)^* \<Longrightarrow> \<forall>x y. (a,x) : P^* \<longrightarrow> (x,y) : Q \<longrightarrow> x=y \<Longrightarrow> (a,b) : P^*"
   303 apply (induct rule:rtrancl.induct)
   304  apply blast
   305 apply (blast intro:rtrancl_trans)
   306 done
   307 
   308 lemma rtrancl_Un_separator_converseE:
   309   "(a,b) : (P \<union> Q)^* \<Longrightarrow> \<forall>x y. (x,b) : P^* \<longrightarrow> (y,x) : Q \<longrightarrow> y=x \<Longrightarrow> (a,b) : P^*"
   310 apply (induct rule:converse_rtrancl_induct)
   311  apply blast
   312 apply (blast intro:rtrancl_trans)
   313 done
   314 
   315 lemma Image_closed_trancl:
   316   assumes "r `` X \<subseteq> X" shows "r\<^sup>* `` X = X"
   317 proof -
   318   from assms have **: "{y. \<exists>x\<in>X. (x, y) \<in> r} \<subseteq> X" by auto
   319   have "\<And>x y. (y, x) \<in> r\<^sup>* \<Longrightarrow> y \<in> X \<Longrightarrow> x \<in> X"
   320   proof -
   321     fix x y
   322     assume *: "y \<in> X"
   323     assume "(y, x) \<in> r\<^sup>*"
   324     then show "x \<in> X"
   325     proof induct
   326       case base show ?case by (fact *)
   327     next
   328       case step with ** show ?case by auto
   329     qed
   330   qed
   331   then show ?thesis by auto
   332 qed
   333 
   334 
   335 subsection {* Transitive closure *}
   336 
   337 lemma trancl_mono: "!!p. p \<in> r^+ ==> r \<subseteq> s ==> p \<in> s^+"
   338   apply (simp add: split_tupled_all)
   339   apply (erule trancl.induct)
   340    apply (iprover dest: subsetD)+
   341   done
   342 
   343 lemma r_into_trancl': "!!p. p : r ==> p : r^+"
   344   by (simp only: split_tupled_all) (erule r_into_trancl)
   345 
   346 text {*
   347   \medskip Conversions between @{text trancl} and @{text rtrancl}.
   348 *}
   349 
   350 lemma tranclp_into_rtranclp: "r^++ a b ==> r^** a b"
   351   by (erule tranclp.induct) iprover+
   352 
   353 lemmas trancl_into_rtrancl = tranclp_into_rtranclp [to_set]
   354 
   355 lemma rtranclp_into_tranclp1: assumes r: "r^** a b"
   356   shows "!!c. r b c ==> r^++ a c" using r
   357   by induct iprover+
   358 
   359 lemmas rtrancl_into_trancl1 = rtranclp_into_tranclp1 [to_set]
   360 
   361 lemma rtranclp_into_tranclp2: "[| r a b; r^** b c |] ==> r^++ a c"
   362   -- {* intro rule from @{text r} and @{text rtrancl} *}
   363   apply (erule rtranclp.cases)
   364    apply iprover
   365   apply (rule rtranclp_trans [THEN rtranclp_into_tranclp1])
   366     apply (simp | rule r_into_rtranclp)+
   367   done
   368 
   369 lemmas rtrancl_into_trancl2 = rtranclp_into_tranclp2 [to_set]
   370 
   371 text {* Nice induction rule for @{text trancl} *}
   372 lemma tranclp_induct [consumes 1, case_names base step, induct pred: tranclp]:
   373   assumes a: "r^++ a b"
   374   and cases: "!!y. r a y ==> P y"
   375     "!!y z. r^++ a y ==> r y z ==> P y ==> P z"
   376   shows "P b" using a
   377   by (induct x\<equiv>a b) (iprover intro: cases)+
   378 
   379 lemmas trancl_induct [induct set: trancl] = tranclp_induct [to_set]
   380 
   381 lemmas tranclp_induct2 =
   382   tranclp_induct [of _ "(ax,ay)" "(bx,by)", split_rule,
   383     consumes 1, case_names base step]
   384 
   385 lemmas trancl_induct2 =
   386   trancl_induct [of "(ax,ay)" "(bx,by)", split_format (complete),
   387     consumes 1, case_names base step]
   388 
   389 lemma tranclp_trans_induct:
   390   assumes major: "r^++ x y"
   391     and cases: "!!x y. r x y ==> P x y"
   392       "!!x y z. [| r^++ x y; P x y; r^++ y z; P y z |] ==> P x z"
   393   shows "P x y"
   394   -- {* Another induction rule for trancl, incorporating transitivity *}
   395   by (iprover intro: major [THEN tranclp_induct] cases)
   396 
   397 lemmas trancl_trans_induct = tranclp_trans_induct [to_set]
   398 
   399 lemma tranclE [cases set: trancl]:
   400   assumes "(a, b) : r^+"
   401   obtains
   402     (base) "(a, b) : r"
   403   | (step) c where "(a, c) : r^+" and "(c, b) : r"
   404   using assms by cases simp_all
   405 
   406 lemma trancl_Int_subset: "[| r \<subseteq> s; (r^+ \<inter> s) O r \<subseteq> s|] ==> r^+ \<subseteq> s"
   407   apply (rule subsetI)
   408   apply (rule_tac p = x in PairE)
   409   apply clarify
   410   apply (erule trancl_induct)
   411    apply auto
   412   done
   413 
   414 lemma trancl_unfold: "r^+ = r Un r^+ O r"
   415   by (auto intro: trancl_into_trancl elim: tranclE)
   416 
   417 text {* Transitivity of @{term "r^+"} *}
   418 lemma trans_trancl [simp]: "trans (r^+)"
   419 proof (rule transI)
   420   fix x y z
   421   assume "(x, y) \<in> r^+"
   422   assume "(y, z) \<in> r^+"
   423   then show "(x, z) \<in> r^+"
   424   proof induct
   425     case (base u)
   426     from `(x, y) \<in> r^+` and `(y, u) \<in> r`
   427     show "(x, u) \<in> r^+" ..
   428   next
   429     case (step u v)
   430     from `(x, u) \<in> r^+` and `(u, v) \<in> r`
   431     show "(x, v) \<in> r^+" ..
   432   qed
   433 qed
   434 
   435 lemmas trancl_trans = trans_trancl [THEN transD]
   436 
   437 lemma tranclp_trans:
   438   assumes xy: "r^++ x y"
   439   and yz: "r^++ y z"
   440   shows "r^++ x z" using yz xy
   441   by induct iprover+
   442 
   443 lemma trancl_id [simp]: "trans r \<Longrightarrow> r^+ = r"
   444   apply auto
   445   apply (erule trancl_induct)
   446    apply assumption
   447   apply (unfold trans_def)
   448   apply blast
   449   done
   450 
   451 lemma rtranclp_tranclp_tranclp:
   452   assumes "r^** x y"
   453   shows "!!z. r^++ y z ==> r^++ x z" using assms
   454   by induct (iprover intro: tranclp_trans)+
   455 
   456 lemmas rtrancl_trancl_trancl = rtranclp_tranclp_tranclp [to_set]
   457 
   458 lemma tranclp_into_tranclp2: "r a b ==> r^++ b c ==> r^++ a c"
   459   by (erule tranclp_trans [OF tranclp.r_into_trancl])
   460 
   461 lemmas trancl_into_trancl2 = tranclp_into_tranclp2 [to_set]
   462 
   463 lemma tranclp_converseI: "(r^++)^--1 x y ==> (r^--1)^++ x y"
   464   apply (drule conversepD)
   465   apply (erule tranclp_induct)
   466   apply (iprover intro: conversepI tranclp_trans)+
   467   done
   468 
   469 lemmas trancl_converseI = tranclp_converseI [to_set]
   470 
   471 lemma tranclp_converseD: "(r^--1)^++ x y ==> (r^++)^--1 x y"
   472   apply (rule conversepI)
   473   apply (erule tranclp_induct)
   474   apply (iprover dest: conversepD intro: tranclp_trans)+
   475   done
   476 
   477 lemmas trancl_converseD = tranclp_converseD [to_set]
   478 
   479 lemma tranclp_converse: "(r^--1)^++ = (r^++)^--1"
   480   by (fastforce simp add: fun_eq_iff
   481     intro!: tranclp_converseI dest!: tranclp_converseD)
   482 
   483 lemmas trancl_converse = tranclp_converse [to_set]
   484 
   485 lemma sym_trancl: "sym r ==> sym (r^+)"
   486   by (simp only: sym_conv_converse_eq trancl_converse [symmetric])
   487 
   488 lemma converse_tranclp_induct [consumes 1, case_names base step]:
   489   assumes major: "r^++ a b"
   490     and cases: "!!y. r y b ==> P(y)"
   491       "!!y z.[| r y z;  r^++ z b;  P(z) |] ==> P(y)"
   492   shows "P a"
   493   apply (rule tranclp_induct [OF tranclp_converseI, OF conversepI, OF major])
   494    apply (rule cases)
   495    apply (erule conversepD)
   496   apply (blast intro: assms dest!: tranclp_converseD)
   497   done
   498 
   499 lemmas converse_trancl_induct = converse_tranclp_induct [to_set]
   500 
   501 lemma tranclpD: "R^++ x y ==> EX z. R x z \<and> R^** z y"
   502   apply (erule converse_tranclp_induct)
   503    apply auto
   504   apply (blast intro: rtranclp_trans)
   505   done
   506 
   507 lemmas tranclD = tranclpD [to_set]
   508 
   509 lemma converse_tranclpE:
   510   assumes major: "tranclp r x z"
   511   assumes base: "r x z ==> P"
   512   assumes step: "\<And> y. [| r x y; tranclp r y z |] ==> P"
   513   shows P
   514 proof -
   515   from tranclpD[OF major]
   516   obtain y where "r x y" and "rtranclp r y z" by iprover
   517   from this(2) show P
   518   proof (cases rule: rtranclp.cases)
   519     case rtrancl_refl
   520     with `r x y` base show P by iprover
   521   next
   522     case rtrancl_into_rtrancl
   523     from this have "tranclp r y z"
   524       by (iprover intro: rtranclp_into_tranclp1)
   525     with `r x y` step show P by iprover
   526   qed
   527 qed
   528 
   529 lemmas converse_tranclE = converse_tranclpE [to_set]
   530 
   531 lemma tranclD2:
   532   "(x, y) \<in> R\<^sup>+ \<Longrightarrow> \<exists>z. (x, z) \<in> R\<^sup>* \<and> (z, y) \<in> R"
   533   by (blast elim: tranclE intro: trancl_into_rtrancl)
   534 
   535 lemma irrefl_tranclI: "r^-1 \<inter> r^* = {} ==> (x, x) \<notin> r^+"
   536   by (blast elim: tranclE dest: trancl_into_rtrancl)
   537 
   538 lemma irrefl_trancl_rD: "!!X. ALL x. (x, x) \<notin> r^+ ==> (x, y) \<in> r ==> x \<noteq> y"
   539   by (blast dest: r_into_trancl)
   540 
   541 lemma trancl_subset_Sigma_aux:
   542     "(a, b) \<in> r^* ==> r \<subseteq> A \<times> A ==> a = b \<or> a \<in> A"
   543   by (induct rule: rtrancl_induct) auto
   544 
   545 lemma trancl_subset_Sigma: "r \<subseteq> A \<times> A ==> r^+ \<subseteq> A \<times> A"
   546   apply (rule subsetI)
   547   apply (simp only: split_tupled_all)
   548   apply (erule tranclE)
   549    apply (blast dest!: trancl_into_rtrancl trancl_subset_Sigma_aux)+
   550   done
   551 
   552 lemma reflclp_tranclp [simp]: "(r^++)^== = r^**"
   553   apply (safe intro!: order_antisym)
   554    apply (erule tranclp_into_rtranclp)
   555   apply (blast elim: rtranclp.cases dest: rtranclp_into_tranclp1)
   556   done
   557 
   558 lemmas reflcl_trancl [simp] = reflclp_tranclp [to_set]
   559 
   560 lemma trancl_reflcl [simp]: "(r^=)^+ = r^*"
   561   apply safe
   562    apply (drule trancl_into_rtrancl, simp)
   563   apply (erule rtranclE, safe)
   564    apply (rule r_into_trancl, simp)
   565   apply (rule rtrancl_into_trancl1)
   566    apply (erule rtrancl_reflcl [THEN equalityD2, THEN subsetD], fast)
   567   done
   568 
   569 lemma rtrancl_trancl_reflcl [code]: "r^* = (r^+)^="
   570   by simp
   571 
   572 lemma trancl_empty [simp]: "{}^+ = {}"
   573   by (auto elim: trancl_induct)
   574 
   575 lemma rtrancl_empty [simp]: "{}^* = Id"
   576   by (rule subst [OF reflcl_trancl]) simp
   577 
   578 lemma rtranclpD: "R^** a b ==> a = b \<or> a \<noteq> b \<and> R^++ a b"
   579 by (force simp add: reflclp_tranclp [symmetric] simp del: reflclp_tranclp)
   580 
   581 lemmas rtranclD = rtranclpD [to_set]
   582 
   583 lemma rtrancl_eq_or_trancl:
   584   "(x,y) \<in> R\<^sup>* = (x=y \<or> x\<noteq>y \<and> (x,y) \<in> R\<^sup>+)"
   585   by (fast elim: trancl_into_rtrancl dest: rtranclD)
   586 
   587 lemma trancl_unfold_right: "r^+ = r^* O r"
   588 by (auto dest: tranclD2 intro: rtrancl_into_trancl1)
   589 
   590 lemma trancl_unfold_left: "r^+ = r O r^*"
   591 by (auto dest: tranclD intro: rtrancl_into_trancl2)
   592 
   593 lemma trancl_insert:
   594   "(insert (y, x) r)^+ = r^+ \<union> {(a, b). (a, y) \<in> r^* \<and> (x, b) \<in> r^*}"
   595   -- {* primitive recursion for @{text trancl} over finite relations *}
   596   apply (rule equalityI)
   597    apply (rule subsetI)
   598    apply (simp only: split_tupled_all)
   599    apply (erule trancl_induct, blast)
   600    apply (blast intro: rtrancl_into_trancl1 trancl_into_rtrancl trancl_trans)
   601   apply (rule subsetI)
   602   apply (blast intro: trancl_mono rtrancl_mono
   603     [THEN [2] rev_subsetD] rtrancl_trancl_trancl rtrancl_into_trancl2)
   604   done
   605 
   606 lemma trancl_insert2:
   607   "(insert (a,b) r)^+ = r^+ \<union> {(x,y). ((x,a) : r^+ \<or> x=a) \<and> ((b,y) \<in> r^+ \<or> y=b)}"
   608 by(auto simp add: trancl_insert rtrancl_eq_or_trancl)
   609 
   610 lemma rtrancl_insert:
   611   "(insert (a,b) r)^* = r^* \<union> {(x,y). (x,a) : r^* \<and> (b,y) \<in> r^*}"
   612 using trancl_insert[of a b r]
   613 by(simp add: rtrancl_trancl_reflcl del: reflcl_trancl) blast
   614 
   615 
   616 text {* Simplifying nested closures *}
   617 
   618 lemma rtrancl_trancl_absorb[simp]: "(R^*)^+ = R^*"
   619 by (simp add: trans_rtrancl)
   620 
   621 lemma trancl_rtrancl_absorb[simp]: "(R^+)^* = R^*"
   622 by (subst reflcl_trancl[symmetric]) simp
   623 
   624 lemma rtrancl_reflcl_absorb[simp]: "(R^*)^= = R^*"
   625 by auto
   626 
   627 
   628 text {* @{text Domain} and @{text Range} *}
   629 
   630 lemma Domain_rtrancl [simp]: "Domain (R^*) = UNIV"
   631   by blast
   632 
   633 lemma Range_rtrancl [simp]: "Range (R^*) = UNIV"
   634   by blast
   635 
   636 lemma rtrancl_Un_subset: "(R^* \<union> S^*) \<subseteq> (R Un S)^*"
   637   by (rule rtrancl_Un_rtrancl [THEN subst]) fast
   638 
   639 lemma in_rtrancl_UnI: "x \<in> R^* \<or> x \<in> S^* ==> x \<in> (R \<union> S)^*"
   640   by (blast intro: subsetD [OF rtrancl_Un_subset])
   641 
   642 lemma trancl_domain [simp]: "Domain (r^+) = Domain r"
   643   by (unfold Domain_unfold) (blast dest: tranclD)
   644 
   645 lemma trancl_range [simp]: "Range (r^+) = Range r"
   646   unfolding Domain_converse [symmetric] by (simp add: trancl_converse [symmetric])
   647 
   648 lemma Not_Domain_rtrancl:
   649     "x ~: Domain R ==> ((x, y) : R^*) = (x = y)"
   650   apply auto
   651   apply (erule rev_mp)
   652   apply (erule rtrancl_induct)
   653    apply auto
   654   done
   655 
   656 lemma trancl_subset_Field2: "r^+ <= Field r \<times> Field r"
   657   apply clarify
   658   apply (erule trancl_induct)
   659    apply (auto simp add: Field_def)
   660   done
   661 
   662 lemma finite_trancl[simp]: "finite (r^+) = finite r"
   663   apply auto
   664    prefer 2
   665    apply (rule trancl_subset_Field2 [THEN finite_subset])
   666    apply (rule finite_SigmaI)
   667     prefer 3
   668     apply (blast intro: r_into_trancl' finite_subset)
   669    apply (auto simp add: finite_Field)
   670   done
   671 
   672 text {* More about converse @{text rtrancl} and @{text trancl}, should
   673   be merged with main body. *}
   674 
   675 lemma single_valued_confluent:
   676   "\<lbrakk> single_valued r; (x,y) \<in> r^*; (x,z) \<in> r^* \<rbrakk>
   677   \<Longrightarrow> (y,z) \<in> r^* \<or> (z,y) \<in> r^*"
   678   apply (erule rtrancl_induct)
   679   apply simp
   680   apply (erule disjE)
   681    apply (blast elim:converse_rtranclE dest:single_valuedD)
   682   apply(blast intro:rtrancl_trans)
   683   done
   684 
   685 lemma r_r_into_trancl: "(a, b) \<in> R ==> (b, c) \<in> R ==> (a, c) \<in> R^+"
   686   by (fast intro: trancl_trans)
   687 
   688 lemma trancl_into_trancl [rule_format]:
   689     "(a, b) \<in> r\<^sup>+ ==> (b, c) \<in> r --> (a,c) \<in> r\<^sup>+"
   690   apply (erule trancl_induct)
   691    apply (fast intro: r_r_into_trancl)
   692   apply (fast intro: r_r_into_trancl trancl_trans)
   693   done
   694 
   695 lemma tranclp_rtranclp_tranclp:
   696     "r\<^sup>+\<^sup>+ a b ==> r\<^sup>*\<^sup>* b c ==> r\<^sup>+\<^sup>+ a c"
   697   apply (drule tranclpD)
   698   apply (elim exE conjE)
   699   apply (drule rtranclp_trans, assumption)
   700   apply (drule rtranclp_into_tranclp2, assumption, assumption)
   701   done
   702 
   703 lemmas trancl_rtrancl_trancl = tranclp_rtranclp_tranclp [to_set]
   704 
   705 lemmas transitive_closure_trans [trans] =
   706   r_r_into_trancl trancl_trans rtrancl_trans
   707   trancl.trancl_into_trancl trancl_into_trancl2
   708   rtrancl.rtrancl_into_rtrancl converse_rtrancl_into_rtrancl
   709   rtrancl_trancl_trancl trancl_rtrancl_trancl
   710 
   711 lemmas transitive_closurep_trans' [trans] =
   712   tranclp_trans rtranclp_trans
   713   tranclp.trancl_into_trancl tranclp_into_tranclp2
   714   rtranclp.rtrancl_into_rtrancl converse_rtranclp_into_rtranclp
   715   rtranclp_tranclp_tranclp tranclp_rtranclp_tranclp
   716 
   717 declare trancl_into_rtrancl [elim]
   718 
   719 subsection {* The power operation on relations *}
   720 
   721 text {* @{text "R ^^ n = R O ... O R"}, the n-fold composition of @{text R} *}
   722 
   723 overloading
   724   relpow == "compow :: nat \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"
   725   relpowp == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool)"
   726 begin
   727 
   728 primrec relpow :: "nat \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set" where
   729     "relpow 0 R = Id"
   730   | "relpow (Suc n) R = (R ^^ n) O R"
   731 
   732 primrec relpowp :: "nat \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool)" where
   733     "relpowp 0 R = HOL.eq"
   734   | "relpowp (Suc n) R = (R ^^ n) OO R"
   735 
   736 end
   737 
   738 lemma relpowp_relpow_eq [pred_set_conv]:
   739   fixes R :: "'a rel"
   740   shows "(\<lambda>x y. (x, y) \<in> R) ^^ n = (\<lambda>x y. (x, y) \<in> R ^^ n)"
   741   by (induct n) (simp_all add: relcompp_relcomp_eq)
   742 
   743 text {* for code generation *}
   744 
   745 definition relpow :: "nat \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set" where
   746   relpow_code_def [code_abbrev]: "relpow = compow"
   747 
   748 definition relpowp :: "nat \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool)" where
   749   relpowp_code_def [code_abbrev]: "relpowp = compow"
   750 
   751 lemma [code]:
   752   "relpow (Suc n) R = (relpow n R) O R"
   753   "relpow 0 R = Id"
   754   by (simp_all add: relpow_code_def)
   755 
   756 lemma [code]:
   757   "relpowp (Suc n) R = (R ^^ n) OO R"
   758   "relpowp 0 R = HOL.eq"
   759   by (simp_all add: relpowp_code_def)
   760 
   761 hide_const (open) relpow
   762 hide_const (open) relpowp
   763 
   764 lemma relpow_1 [simp]:
   765   fixes R :: "('a \<times> 'a) set"
   766   shows "R ^^ 1 = R"
   767   by simp
   768 
   769 lemma relpowp_1 [simp]:
   770   fixes P :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   771   shows "P ^^ 1 = P"
   772   by (fact relpow_1 [to_pred])
   773 
   774 lemma relpow_0_I: 
   775   "(x, x) \<in> R ^^ 0"
   776   by simp
   777 
   778 lemma relpowp_0_I:
   779   "(P ^^ 0) x x"
   780   by (fact relpow_0_I [to_pred])
   781 
   782 lemma relpow_Suc_I:
   783   "(x, y) \<in>  R ^^ n \<Longrightarrow> (y, z) \<in> R \<Longrightarrow> (x, z) \<in> R ^^ Suc n"
   784   by auto
   785 
   786 lemma relpowp_Suc_I:
   787   "(P ^^ n) x y \<Longrightarrow> P y z \<Longrightarrow> (P ^^ Suc n) x z"
   788   by (fact relpow_Suc_I [to_pred])
   789 
   790 lemma relpow_Suc_I2:
   791   "(x, y) \<in> R \<Longrightarrow> (y, z) \<in> R ^^ n \<Longrightarrow> (x, z) \<in> R ^^ Suc n"
   792   by (induct n arbitrary: z) (simp, fastforce)
   793 
   794 lemma relpowp_Suc_I2:
   795   "P x y \<Longrightarrow> (P ^^ n) y z \<Longrightarrow> (P ^^ Suc n) x z"
   796   by (fact relpow_Suc_I2 [to_pred])
   797 
   798 lemma relpow_0_E:
   799   "(x, y) \<in> R ^^ 0 \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> P"
   800   by simp
   801 
   802 lemma relpowp_0_E:
   803   "(P ^^ 0) x y \<Longrightarrow> (x = y \<Longrightarrow> Q) \<Longrightarrow> Q"
   804   by (fact relpow_0_E [to_pred])
   805 
   806 lemma relpow_Suc_E:
   807   "(x, z) \<in> R ^^ Suc n \<Longrightarrow> (\<And>y. (x, y) \<in> R ^^ n \<Longrightarrow> (y, z) \<in> R \<Longrightarrow> P) \<Longrightarrow> P"
   808   by auto
   809 
   810 lemma relpowp_Suc_E:
   811   "(P ^^ Suc n) x z \<Longrightarrow> (\<And>y. (P ^^ n) x y \<Longrightarrow> P y z \<Longrightarrow> Q) \<Longrightarrow> Q"
   812   by (fact relpow_Suc_E [to_pred])
   813 
   814 lemma relpow_E:
   815   "(x, z) \<in>  R ^^ n \<Longrightarrow>  (n = 0 \<Longrightarrow> x = z \<Longrightarrow> P)
   816    \<Longrightarrow> (\<And>y m. n = Suc m \<Longrightarrow> (x, y) \<in>  R ^^ m \<Longrightarrow> (y, z) \<in> R \<Longrightarrow> P)
   817    \<Longrightarrow> P"
   818   by (cases n) auto
   819 
   820 lemma relpowp_E:
   821   "(P ^^ n) x z \<Longrightarrow> (n = 0 \<Longrightarrow> x = z \<Longrightarrow> Q)
   822   \<Longrightarrow> (\<And>y m. n = Suc m \<Longrightarrow> (P ^^ m) x y \<Longrightarrow> P y z \<Longrightarrow> Q)
   823   \<Longrightarrow> Q"
   824   by (fact relpow_E [to_pred])
   825 
   826 lemma relpow_Suc_D2:
   827   "(x, z) \<in> R ^^ Suc n \<Longrightarrow> (\<exists>y. (x, y) \<in> R \<and> (y, z) \<in> R ^^ n)"
   828   apply (induct n arbitrary: x z)
   829    apply (blast intro: relpow_0_I elim: relpow_0_E relpow_Suc_E)
   830   apply (blast intro: relpow_Suc_I elim: relpow_0_E relpow_Suc_E)
   831   done
   832 
   833 lemma relpowp_Suc_D2:
   834   "(P ^^ Suc n) x z \<Longrightarrow> \<exists>y. P x y \<and> (P ^^ n) y z"
   835   by (fact relpow_Suc_D2 [to_pred])
   836 
   837 lemma relpow_Suc_E2:
   838   "(x, z) \<in> R ^^ Suc n \<Longrightarrow> (\<And>y. (x, y) \<in> R \<Longrightarrow> (y, z) \<in> R ^^ n \<Longrightarrow> P) \<Longrightarrow> P"
   839   by (blast dest: relpow_Suc_D2)
   840 
   841 lemma relpowp_Suc_E2:
   842   "(P ^^ Suc n) x z \<Longrightarrow> (\<And>y. P x y \<Longrightarrow> (P ^^ n) y z \<Longrightarrow> Q) \<Longrightarrow> Q"
   843   by (fact relpow_Suc_E2 [to_pred])
   844 
   845 lemma relpow_Suc_D2':
   846   "\<forall>x y z. (x, y) \<in> R ^^ n \<and> (y, z) \<in> R \<longrightarrow> (\<exists>w. (x, w) \<in> R \<and> (w, z) \<in> R ^^ n)"
   847   by (induct n) (simp_all, blast)
   848 
   849 lemma relpowp_Suc_D2':
   850   "\<forall>x y z. (P ^^ n) x y \<and> P y z \<longrightarrow> (\<exists>w. P x w \<and> (P ^^ n) w z)"
   851   by (fact relpow_Suc_D2' [to_pred])
   852 
   853 lemma relpow_E2:
   854   "(x, z) \<in> R ^^ n \<Longrightarrow>  (n = 0 \<Longrightarrow> x = z \<Longrightarrow> P)
   855      \<Longrightarrow> (\<And>y m. n = Suc m \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> (y, z) \<in> R ^^ m \<Longrightarrow> P)
   856    \<Longrightarrow> P"
   857   apply (cases n, simp)
   858   apply (rename_tac nat)
   859   apply (cut_tac n=nat and R=R in relpow_Suc_D2', simp, blast)
   860   done
   861 
   862 lemma relpowp_E2:
   863   "(P ^^ n) x z \<Longrightarrow> (n = 0 \<Longrightarrow> x = z \<Longrightarrow> Q)
   864     \<Longrightarrow> (\<And>y m. n = Suc m \<Longrightarrow> P x y \<Longrightarrow> (P ^^ m) y z \<Longrightarrow> Q)
   865   \<Longrightarrow> Q"
   866   by (fact relpow_E2 [to_pred])
   867 
   868 lemma relpow_add: "R ^^ (m+n) = R^^m O R^^n"
   869   by (induct n) auto
   870 
   871 lemma relpowp_add: "P ^^ (m + n) = P ^^ m OO P ^^ n"
   872   by (fact relpow_add [to_pred])
   873 
   874 lemma relpow_commute: "R O R ^^ n = R ^^ n O R"
   875   by (induct n) (simp, simp add: O_assoc [symmetric])
   876 
   877 lemma relpowp_commute: "P OO P ^^ n = P ^^ n OO P"
   878   by (fact relpow_commute [to_pred])
   879 
   880 lemma relpow_empty:
   881   "0 < n \<Longrightarrow> ({} :: ('a \<times> 'a) set) ^^ n = {}"
   882   by (cases n) auto
   883 
   884 lemma relpowp_bot:
   885   "0 < n \<Longrightarrow> (\<bottom> :: 'a \<Rightarrow> 'a \<Rightarrow> bool) ^^ n = \<bottom>"
   886   by (fact relpow_empty [to_pred])
   887 
   888 lemma rtrancl_imp_UN_relpow:
   889   assumes "p \<in> R^*"
   890   shows "p \<in> (\<Union>n. R ^^ n)"
   891 proof (cases p)
   892   case (Pair x y)
   893   with assms have "(x, y) \<in> R^*" by simp
   894   then have "(x, y) \<in> (\<Union>n. R ^^ n)" proof induct
   895     case base show ?case by (blast intro: relpow_0_I)
   896   next
   897     case step then show ?case by (blast intro: relpow_Suc_I)
   898   qed
   899   with Pair show ?thesis by simp
   900 qed
   901 
   902 lemma rtranclp_imp_Sup_relpowp:
   903   assumes "(P^**) x y"
   904   shows "(\<Squnion>n. P ^^ n) x y"
   905   using assms and rtrancl_imp_UN_relpow [to_pred] by blast
   906 
   907 lemma relpow_imp_rtrancl:
   908   assumes "p \<in> R ^^ n"
   909   shows "p \<in> R^*"
   910 proof (cases p)
   911   case (Pair x y)
   912   with assms have "(x, y) \<in> R ^^ n" by simp
   913   then have "(x, y) \<in> R^*" proof (induct n arbitrary: x y)
   914     case 0 then show ?case by simp
   915   next
   916     case Suc then show ?case
   917       by (blast elim: relpow_Suc_E intro: rtrancl_into_rtrancl)
   918   qed
   919   with Pair show ?thesis by simp
   920 qed
   921 
   922 lemma relpowp_imp_rtranclp:
   923   assumes "(P ^^ n) x y"
   924   shows "(P^**) x y"
   925   using assms and relpow_imp_rtrancl [to_pred] by blast
   926 
   927 lemma rtrancl_is_UN_relpow:
   928   "R^* = (\<Union>n. R ^^ n)"
   929   by (blast intro: rtrancl_imp_UN_relpow relpow_imp_rtrancl)
   930 
   931 lemma rtranclp_is_Sup_relpowp:
   932   "P^** = (\<Squnion>n. P ^^ n)"
   933   using rtrancl_is_UN_relpow [to_pred, of P] by auto
   934 
   935 lemma rtrancl_power:
   936   "p \<in> R^* \<longleftrightarrow> (\<exists>n. p \<in> R ^^ n)"
   937   by (simp add: rtrancl_is_UN_relpow)
   938 
   939 lemma rtranclp_power:
   940   "(P^**) x y \<longleftrightarrow> (\<exists>n. (P ^^ n) x y)"
   941   by (simp add: rtranclp_is_Sup_relpowp)
   942 
   943 lemma trancl_power:
   944   "p \<in> R^+ \<longleftrightarrow> (\<exists>n > 0. p \<in> R ^^ n)"
   945   apply (cases p)
   946   apply simp
   947   apply (rule iffI)
   948    apply (drule tranclD2)
   949    apply (clarsimp simp: rtrancl_is_UN_relpow)
   950    apply (rule_tac x="Suc n" in exI)
   951    apply (clarsimp simp: relcomp_unfold)
   952    apply fastforce
   953   apply clarsimp
   954   apply (case_tac n, simp)
   955   apply clarsimp
   956   apply (drule relpow_imp_rtrancl)
   957   apply (drule rtrancl_into_trancl1) apply auto
   958   done
   959 
   960 lemma tranclp_power:
   961   "(P^++) x y \<longleftrightarrow> (\<exists>n > 0. (P ^^ n) x y)"
   962   using trancl_power [to_pred, of P "(x, y)"] by simp
   963 
   964 lemma rtrancl_imp_relpow:
   965   "p \<in> R^* \<Longrightarrow> \<exists>n. p \<in> R ^^ n"
   966   by (auto dest: rtrancl_imp_UN_relpow)
   967 
   968 lemma rtranclp_imp_relpowp:
   969   "(P^**) x y \<Longrightarrow> \<exists>n. (P ^^ n) x y"
   970   by (auto dest: rtranclp_imp_Sup_relpowp)
   971 
   972 text{* By Sternagel/Thiemann: *}
   973 lemma relpow_fun_conv:
   974   "((a,b) \<in> R ^^ n) = (\<exists>f. f 0 = a \<and> f n = b \<and> (\<forall>i<n. (f i, f(Suc i)) \<in> R))"
   975 proof (induct n arbitrary: b)
   976   case 0 show ?case by auto
   977 next
   978   case (Suc n)
   979   show ?case
   980   proof (simp add: relcomp_unfold Suc)
   981     show "(\<exists>y. (\<exists>f. f 0 = a \<and> f n = y \<and> (\<forall>i<n. (f i,f(Suc i)) \<in> R)) \<and> (y,b) \<in> R)
   982      = (\<exists>f. f 0 = a \<and> f(Suc n) = b \<and> (\<forall>i<Suc n. (f i, f (Suc i)) \<in> R))"
   983     (is "?l = ?r")
   984     proof
   985       assume ?l
   986       then obtain c f where 1: "f 0 = a"  "f n = c"  "\<And>i. i < n \<Longrightarrow> (f i, f (Suc i)) \<in> R"  "(c,b) \<in> R" by auto
   987       let ?g = "\<lambda> m. if m = Suc n then b else f m"
   988       show ?r by (rule exI[of _ ?g], simp add: 1)
   989     next
   990       assume ?r
   991       then obtain f where 1: "f 0 = a"  "b = f (Suc n)"  "\<And>i. i < Suc n \<Longrightarrow> (f i, f (Suc i)) \<in> R" by auto
   992       show ?l by (rule exI[of _ "f n"], rule conjI, rule exI[of _ f], insert 1, auto)
   993     qed
   994   qed
   995 qed
   996 
   997 lemma relpowp_fun_conv:
   998   "(P ^^ n) x y \<longleftrightarrow> (\<exists>f. f 0 = x \<and> f n = y \<and> (\<forall>i<n. P (f i) (f (Suc i))))"
   999   by (fact relpow_fun_conv [to_pred])
  1000 
  1001 lemma relpow_finite_bounded1:
  1002 assumes "finite(R :: ('a*'a)set)" and "k>0"
  1003 shows "R^^k \<subseteq> (UN n:{n. 0<n & n <= card R}. R^^n)" (is "_ \<subseteq> ?r")
  1004 proof-
  1005   { fix a b k
  1006     have "(a,b) : R^^(Suc k) \<Longrightarrow> EX n. 0<n & n <= card R & (a,b) : R^^n"
  1007     proof(induct k arbitrary: b)
  1008       case 0
  1009       hence "R \<noteq> {}" by auto
  1010       with card_0_eq[OF `finite R`] have "card R >= Suc 0" by auto
  1011       thus ?case using 0 by force
  1012     next
  1013       case (Suc k)
  1014       then obtain a' where "(a,a') : R^^(Suc k)" and "(a',b) : R" by auto
  1015       from Suc(1)[OF `(a,a') : R^^(Suc k)`]
  1016       obtain n where "n \<le> card R" and "(a,a') \<in> R ^^ n" by auto
  1017       have "(a,b) : R^^(Suc n)" using `(a,a') \<in> R^^n` and `(a',b)\<in> R` by auto
  1018       { assume "n < card R"
  1019         hence ?case using `(a,b): R^^(Suc n)` Suc_leI[OF `n < card R`] by blast
  1020       } moreover
  1021       { assume "n = card R"
  1022         from `(a,b) \<in> R ^^ (Suc n)`[unfolded relpow_fun_conv]
  1023         obtain f where "f 0 = a" and "f(Suc n) = b"
  1024           and steps: "\<And>i. i <= n \<Longrightarrow> (f i, f (Suc i)) \<in> R" by auto
  1025         let ?p = "%i. (f i, f(Suc i))"
  1026         let ?N = "{i. i \<le> n}"
  1027         have "?p ` ?N <= R" using steps by auto
  1028         from card_mono[OF assms(1) this]
  1029         have "card(?p ` ?N) <= card R" .
  1030         also have "\<dots> < card ?N" using `n = card R` by simp
  1031         finally have "~ inj_on ?p ?N" by(rule pigeonhole)
  1032         then obtain i j where i: "i <= n" and j: "j <= n" and ij: "i \<noteq> j" and
  1033           pij: "?p i = ?p j" by(auto simp: inj_on_def)
  1034         let ?i = "min i j" let ?j = "max i j"
  1035         have i: "?i <= n" and j: "?j <= n" and pij: "?p ?i = ?p ?j" 
  1036           and ij: "?i < ?j"
  1037           using i j ij pij unfolding min_def max_def by auto
  1038         from i j pij ij obtain i j where i: "i<=n" and j: "j<=n" and ij: "i<j"
  1039           and pij: "?p i = ?p j" by blast
  1040         let ?g = "\<lambda> l. if l \<le> i then f l else f (l + (j - i))"
  1041         let ?n = "Suc(n - (j - i))"
  1042         have abl: "(a,b) \<in> R ^^ ?n" unfolding relpow_fun_conv
  1043         proof (rule exI[of _ ?g], intro conjI impI allI)
  1044           show "?g ?n = b" using `f(Suc n) = b` j ij by auto
  1045         next
  1046           fix k assume "k < ?n"
  1047           show "(?g k, ?g (Suc k)) \<in> R"
  1048           proof (cases "k < i")
  1049             case True
  1050             with i have "k <= n" by auto
  1051             from steps[OF this] show ?thesis using True by simp
  1052           next
  1053             case False
  1054             hence "i \<le> k" by auto
  1055             show ?thesis
  1056             proof (cases "k = i")
  1057               case True
  1058               thus ?thesis using ij pij steps[OF i] by simp
  1059             next
  1060               case False
  1061               with `i \<le> k` have "i < k" by auto
  1062               hence small: "k + (j - i) <= n" using `k<?n` by arith
  1063               show ?thesis using steps[OF small] `i<k` by auto
  1064             qed
  1065           qed
  1066         qed (simp add: `f 0 = a`)
  1067         moreover have "?n <= n" using i j ij by arith
  1068         ultimately have ?case using `n = card R` by blast
  1069       }
  1070       ultimately show ?case using `n \<le> card R` by force
  1071     qed
  1072   }
  1073   thus ?thesis using gr0_implies_Suc[OF `k>0`] by auto
  1074 qed
  1075 
  1076 lemma relpow_finite_bounded:
  1077 assumes "finite(R :: ('a*'a)set)"
  1078 shows "R^^k \<subseteq> (UN n:{n. n <= card R}. R^^n)"
  1079 apply(cases k)
  1080  apply force
  1081 using relpow_finite_bounded1[OF assms, of k] by auto
  1082 
  1083 lemma rtrancl_finite_eq_relpow:
  1084   "finite R \<Longrightarrow> R^* = (UN n : {n. n <= card R}. R^^n)"
  1085 by(fastforce simp: rtrancl_power dest: relpow_finite_bounded)
  1086 
  1087 lemma trancl_finite_eq_relpow:
  1088   "finite R \<Longrightarrow> R^+ = (UN n : {n. 0 < n & n <= card R}. R^^n)"
  1089 apply(auto simp add: trancl_power)
  1090 apply(auto dest: relpow_finite_bounded1)
  1091 done
  1092 
  1093 lemma finite_relcomp[simp,intro]:
  1094 assumes "finite R" and "finite S"
  1095 shows "finite(R O S)"
  1096 proof-
  1097   have "R O S = (UN (x,y) : R. \<Union>((%(u,v). if u=y then {(x,v)} else {}) ` S))"
  1098     by(force simp add: split_def)
  1099   thus ?thesis using assms by(clarsimp)
  1100 qed
  1101 
  1102 lemma finite_relpow[simp,intro]:
  1103   assumes "finite(R :: ('a*'a)set)" shows "n>0 \<Longrightarrow> finite(R^^n)"
  1104 apply(induct n)
  1105  apply simp
  1106 apply(case_tac n)
  1107  apply(simp_all add: assms)
  1108 done
  1109 
  1110 lemma single_valued_relpow:
  1111   fixes R :: "('a * 'a) set"
  1112   shows "single_valued R \<Longrightarrow> single_valued (R ^^ n)"
  1113 apply (induct n arbitrary: R)
  1114 apply simp_all
  1115 apply (rule single_valuedI)
  1116 apply (fast dest: single_valuedD elim: relpow_Suc_E)
  1117 done
  1118 
  1119 
  1120 subsection {* Bounded transitive closure *}
  1121 
  1122 definition ntrancl :: "nat \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"
  1123 where
  1124   "ntrancl n R = (\<Union>i\<in>{i. 0 < i \<and> i \<le> Suc n}. R ^^ i)"
  1125 
  1126 lemma ntrancl_Zero [simp, code]:
  1127   "ntrancl 0 R = R"
  1128 proof
  1129   show "R \<subseteq> ntrancl 0 R"
  1130     unfolding ntrancl_def by fastforce
  1131 next
  1132   { 
  1133     fix i have "0 < i \<and> i \<le> Suc 0 \<longleftrightarrow> i = 1" by auto
  1134   }
  1135   from this show "ntrancl 0 R \<le> R"
  1136     unfolding ntrancl_def by auto
  1137 qed
  1138 
  1139 lemma ntrancl_Suc [simp]:
  1140   "ntrancl (Suc n) R = ntrancl n R O (Id \<union> R)"
  1141 proof
  1142   {
  1143     fix a b
  1144     assume "(a, b) \<in> ntrancl (Suc n) R"
  1145     from this obtain i where "0 < i" "i \<le> Suc (Suc n)" "(a, b) \<in> R ^^ i"
  1146       unfolding ntrancl_def by auto
  1147     have "(a, b) \<in> ntrancl n R O (Id \<union> R)"
  1148     proof (cases "i = 1")
  1149       case True
  1150       from this `(a, b) \<in> R ^^ i` show ?thesis
  1151         unfolding ntrancl_def by auto
  1152     next
  1153       case False
  1154       from this `0 < i` obtain j where j: "i = Suc j" "0 < j"
  1155         by (cases i) auto
  1156       from this `(a, b) \<in> R ^^ i` obtain c where c1: "(a, c) \<in> R ^^ j" and c2:"(c, b) \<in> R"
  1157         by auto
  1158       from c1 j `i \<le> Suc (Suc n)` have "(a, c) \<in> ntrancl n R"
  1159         unfolding ntrancl_def by fastforce
  1160       from this c2 show ?thesis by fastforce
  1161     qed
  1162   }
  1163   from this show "ntrancl (Suc n) R \<subseteq> ntrancl n R O (Id \<union> R)"
  1164     by auto
  1165 next
  1166   show "ntrancl n R O (Id \<union> R) \<subseteq> ntrancl (Suc n) R"
  1167     unfolding ntrancl_def by fastforce
  1168 qed
  1169 
  1170 lemma [code]:
  1171   "ntrancl (Suc n) r = (let r' = ntrancl n r in r' Un r' O r)"
  1172 unfolding Let_def by auto
  1173 
  1174 lemma finite_trancl_ntranl:
  1175   "finite R \<Longrightarrow> trancl R = ntrancl (card R - 1) R"
  1176   by (cases "card R") (auto simp add: trancl_finite_eq_relpow relpow_empty ntrancl_def)
  1177 
  1178 
  1179 subsection {* Acyclic relations *}
  1180 
  1181 definition acyclic :: "('a * 'a) set => bool" where
  1182   "acyclic r \<longleftrightarrow> (!x. (x,x) ~: r^+)"
  1183 
  1184 abbreviation acyclicP :: "('a => 'a => bool) => bool" where
  1185   "acyclicP r \<equiv> acyclic {(x, y). r x y}"
  1186 
  1187 lemma acyclic_irrefl [code]:
  1188   "acyclic r \<longleftrightarrow> irrefl (r^+)"
  1189   by (simp add: acyclic_def irrefl_def)
  1190 
  1191 lemma acyclicI: "ALL x. (x, x) ~: r^+ ==> acyclic r"
  1192   by (simp add: acyclic_def)
  1193 
  1194 lemma (in order) acyclicI_order:
  1195   assumes *: "\<And>a b. (a, b) \<in> r \<Longrightarrow> f b < f a"
  1196   shows "acyclic r"
  1197 proof -
  1198   { fix a b assume "(a, b) \<in> r\<^sup>+"
  1199     then have "f b < f a"
  1200       by induct (auto intro: * less_trans) }
  1201   then show ?thesis
  1202     by (auto intro!: acyclicI)
  1203 qed
  1204 
  1205 lemma acyclic_insert [iff]:
  1206      "acyclic(insert (y,x) r) = (acyclic r & (x,y) ~: r^*)"
  1207 apply (simp add: acyclic_def trancl_insert)
  1208 apply (blast intro: rtrancl_trans)
  1209 done
  1210 
  1211 lemma acyclic_converse [iff]: "acyclic(r^-1) = acyclic r"
  1212 by (simp add: acyclic_def trancl_converse)
  1213 
  1214 lemmas acyclicP_converse [iff] = acyclic_converse [to_pred]
  1215 
  1216 lemma acyclic_impl_antisym_rtrancl: "acyclic r ==> antisym(r^*)"
  1217 apply (simp add: acyclic_def antisym_def)
  1218 apply (blast elim: rtranclE intro: rtrancl_into_trancl1 rtrancl_trancl_trancl)
  1219 done
  1220 
  1221 (* Other direction:
  1222 acyclic = no loops
  1223 antisym = only self loops
  1224 Goalw [acyclic_def,antisym_def] "antisym( r^* ) ==> acyclic(r - Id)
  1225 ==> antisym( r^* ) = acyclic(r - Id)";
  1226 *)
  1227 
  1228 lemma acyclic_subset: "[| acyclic s; r <= s |] ==> acyclic r"
  1229 apply (simp add: acyclic_def)
  1230 apply (blast intro: trancl_mono)
  1231 done
  1232 
  1233 
  1234 subsection {* Setup of transitivity reasoner *}
  1235 
  1236 ML {*
  1237 
  1238 structure Trancl_Tac = Trancl_Tac
  1239 (
  1240   val r_into_trancl = @{thm trancl.r_into_trancl};
  1241   val trancl_trans  = @{thm trancl_trans};
  1242   val rtrancl_refl = @{thm rtrancl.rtrancl_refl};
  1243   val r_into_rtrancl = @{thm r_into_rtrancl};
  1244   val trancl_into_rtrancl = @{thm trancl_into_rtrancl};
  1245   val rtrancl_trancl_trancl = @{thm rtrancl_trancl_trancl};
  1246   val trancl_rtrancl_trancl = @{thm trancl_rtrancl_trancl};
  1247   val rtrancl_trans = @{thm rtrancl_trans};
  1248 
  1249   fun decomp (@{const Trueprop} $ t) =
  1250     let fun dec (Const (@{const_name Set.member}, _) $ (Const (@{const_name Pair}, _) $ a $ b) $ rel ) =
  1251         let fun decr (Const (@{const_name rtrancl}, _ ) $ r) = (r,"r*")
  1252               | decr (Const (@{const_name trancl}, _ ) $ r)  = (r,"r+")
  1253               | decr r = (r,"r");
  1254             val (rel,r) = decr (Envir.beta_eta_contract rel);
  1255         in SOME (a,b,rel,r) end
  1256       | dec _ =  NONE
  1257     in dec t end
  1258     | decomp _ = NONE;
  1259 );
  1260 
  1261 structure Tranclp_Tac = Trancl_Tac
  1262 (
  1263   val r_into_trancl = @{thm tranclp.r_into_trancl};
  1264   val trancl_trans  = @{thm tranclp_trans};
  1265   val rtrancl_refl = @{thm rtranclp.rtrancl_refl};
  1266   val r_into_rtrancl = @{thm r_into_rtranclp};
  1267   val trancl_into_rtrancl = @{thm tranclp_into_rtranclp};
  1268   val rtrancl_trancl_trancl = @{thm rtranclp_tranclp_tranclp};
  1269   val trancl_rtrancl_trancl = @{thm tranclp_rtranclp_tranclp};
  1270   val rtrancl_trans = @{thm rtranclp_trans};
  1271 
  1272   fun decomp (@{const Trueprop} $ t) =
  1273     let fun dec (rel $ a $ b) =
  1274         let fun decr (Const (@{const_name rtranclp}, _ ) $ r) = (r,"r*")
  1275               | decr (Const (@{const_name tranclp}, _ ) $ r)  = (r,"r+")
  1276               | decr r = (r,"r");
  1277             val (rel,r) = decr rel;
  1278         in SOME (a, b, rel, r) end
  1279       | dec _ =  NONE
  1280     in dec t end
  1281     | decomp _ = NONE;
  1282 );
  1283 *}
  1284 
  1285 setup {*
  1286   map_theory_simpset (fn ctxt => ctxt
  1287     addSolver (mk_solver "Trancl" Trancl_Tac.trancl_tac)
  1288     addSolver (mk_solver "Rtrancl" Trancl_Tac.rtrancl_tac)
  1289     addSolver (mk_solver "Tranclp" Tranclp_Tac.trancl_tac)
  1290     addSolver (mk_solver "Rtranclp" Tranclp_Tac.rtrancl_tac))
  1291 *}
  1292 
  1293 
  1294 text {* Optional methods. *}
  1295 
  1296 method_setup trancl =
  1297   {* Scan.succeed (SIMPLE_METHOD' o Trancl_Tac.trancl_tac) *}
  1298   {* simple transitivity reasoner *}
  1299 method_setup rtrancl =
  1300   {* Scan.succeed (SIMPLE_METHOD' o Trancl_Tac.rtrancl_tac) *}
  1301   {* simple transitivity reasoner *}
  1302 method_setup tranclp =
  1303   {* Scan.succeed (SIMPLE_METHOD' o Tranclp_Tac.trancl_tac) *}
  1304   {* simple transitivity reasoner (predicate version) *}
  1305 method_setup rtranclp =
  1306   {* Scan.succeed (SIMPLE_METHOD' o Tranclp_Tac.rtrancl_tac) *}
  1307   {* simple transitivity reasoner (predicate version) *}
  1308 
  1309 end