src/Pure/theory.ML
author haftmann
Thu Aug 17 09:24:50 2006 +0200 (2006-08-17)
changeset 20392 88cab786d024
parent 20155 da0505518e69
child 20549 c643984eb94b
permissions -rw-r--r--
dropped definitions_of
     1 (*  Title:      Pure/theory.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical theory content: axioms, definitions, oracles.
     6 *)
     7 
     8 signature BASIC_THEORY =
     9 sig
    10   type theory
    11   type theory_ref
    12   val sign_of: theory -> theory    (*obsolete*)
    13   val rep_theory: theory ->
    14    {axioms: term NameSpace.table,
    15     defs: Defs.T,
    16     oracles: ((theory * Object.T -> term) * stamp) NameSpace.table}
    17   val parents_of: theory -> theory list
    18   val ancestors_of: theory -> theory list
    19   val eq_thy: theory * theory -> bool
    20   val subthy: theory * theory -> bool
    21   val cert_axm: theory -> string * term -> string * term
    22   val read_def_axm: theory * (indexname -> typ option) * (indexname -> sort option) ->
    23     string list -> string * string -> string * term
    24   val read_axm: theory -> string * string -> string * term
    25   val inferT_axm: theory -> string * term -> string * term
    26 end
    27 
    28 signature THEORY =
    29 sig
    30   include BASIC_THEORY
    31   include SIGN_THEORY
    32   val begin_theory: string -> theory list -> theory
    33   val end_theory: theory -> theory
    34   val checkpoint: theory -> theory
    35   val copy: theory -> theory
    36   val init_data: theory -> theory
    37   val axiom_space: theory -> NameSpace.T
    38   val oracle_space: theory -> NameSpace.T
    39   val axioms_of: theory -> (string * term) list
    40   val all_axioms_of: theory -> (string * term) list
    41   val defs_of : theory -> Defs.T
    42   val self_ref: theory -> theory_ref
    43   val deref: theory_ref -> theory
    44   val merge: theory * theory -> theory                     (*exception TERM*)
    45   val merge_refs: theory_ref * theory_ref -> theory_ref    (*exception TERM*)
    46   val requires: theory -> string -> string -> unit
    47   val assert_super: theory -> theory -> theory
    48   val add_axioms: (bstring * string) list -> theory -> theory
    49   val add_axioms_i: (bstring * term) list -> theory -> theory
    50   val add_deps: string -> string * typ -> (string * typ) list -> theory -> theory
    51   val add_defs: bool -> bool -> (bstring * string) list -> theory -> theory
    52   val add_defs_i: bool -> bool -> (bstring * term) list -> theory -> theory
    53   val add_finals: bool -> string list -> theory -> theory
    54   val add_finals_i: bool -> term list -> theory -> theory
    55   val add_oracle: bstring * (theory * Object.T -> term) -> theory -> theory
    56 end
    57 
    58 structure Theory: THEORY =
    59 struct
    60 
    61 
    62 (** type theory **)
    63 
    64 (* context operations *)
    65 
    66 type theory = Context.theory;
    67 type theory_ref = Context.theory_ref;
    68 
    69 val eq_thy = Context.eq_thy;
    70 val subthy = Context.subthy;
    71 
    72 val parents_of = Context.parents_of;
    73 val ancestors_of = Context.ancestors_of;
    74 
    75 val self_ref = Context.self_ref;
    76 val deref = Context.deref;
    77 val merge = Context.merge;
    78 val merge_refs = Context.merge_refs;
    79 
    80 val begin_theory = Sign.local_path oo Context.begin_thy Sign.pp;
    81 val end_theory = Context.finish_thy;
    82 val checkpoint = Context.checkpoint_thy;
    83 val copy = Context.copy_thy;
    84 
    85 
    86 (* signature operations *)
    87 
    88 val sign_of = I;
    89 
    90 structure SignTheory: SIGN_THEORY = Sign;
    91 open SignTheory;
    92 
    93 
    94 
    95 (** datatype thy **)
    96 
    97 datatype thy = Thy of
    98  {axioms: term NameSpace.table,
    99   defs: Defs.T,
   100   oracles: ((theory * Object.T -> term) * stamp) NameSpace.table};
   101 
   102 fun make_thy (axioms, defs, oracles) =
   103   Thy {axioms = axioms, defs = defs, oracles = oracles};
   104 
   105 fun err_dup_axms dups = error ("Duplicate axiom(s): " ^ commas_quote dups);
   106 fun err_dup_oras dups = error ("Duplicate oracle(s): " ^ commas_quote dups);
   107 
   108 structure ThyData = TheoryDataFun
   109 (struct
   110   val name = "Pure/theory";
   111   type T = thy;
   112   val empty = make_thy (NameSpace.empty_table, Defs.empty, NameSpace.empty_table);
   113   val copy = I;
   114 
   115   fun extend (Thy {axioms, defs, oracles}) = make_thy (NameSpace.empty_table, defs, oracles);
   116 
   117   fun merge pp (thy1, thy2) =
   118     let
   119       val Thy {axioms = _, defs = defs1, oracles = oracles1} = thy1;
   120       val Thy {axioms = _, defs = defs2, oracles = oracles2} = thy2;
   121 
   122       val axioms = NameSpace.empty_table;
   123       val defs = Defs.merge pp (defs1, defs2);
   124       val oracles = NameSpace.merge_tables (eq_snd (op =)) (oracles1, oracles2)
   125         handle Symtab.DUPS dups => err_dup_oras dups;
   126     in make_thy (axioms, defs, oracles) end;
   127 
   128   fun print _ _ = ();
   129 end);
   130 
   131 val init_data = ThyData.init;
   132 
   133 fun rep_theory thy = ThyData.get thy |> (fn Thy args => args);
   134 
   135 fun map_thy f = ThyData.map (fn (Thy {axioms, defs, oracles}) =>
   136   make_thy (f (axioms, defs, oracles)));
   137 
   138 fun map_axioms f = map_thy (fn (axioms, defs, oracles) => (f axioms, defs, oracles));
   139 fun map_defs f = map_thy (fn (axioms, defs, oracles) => (axioms, f defs, oracles));
   140 fun map_oracles f = map_thy (fn (axioms, defs, oracles) => (axioms, defs, f oracles));
   141 
   142 
   143 (* basic operations *)
   144 
   145 val axiom_space = #1 o #axioms o rep_theory;
   146 val oracle_space = #1 o #oracles o rep_theory;
   147 
   148 val axioms_of = Symtab.dest o #2 o #axioms o rep_theory;
   149 fun all_axioms_of thy = maps axioms_of (thy :: ancestors_of thy);
   150 
   151 val defs_of = #defs o rep_theory;
   152 
   153 fun requires thy name what =
   154   if Context.exists_name name thy then ()
   155   else error ("Require theory " ^ quote name ^ " as an ancestor for " ^ what);
   156 
   157 fun assert_super thy1 thy2 =
   158   if subthy (thy1, thy2) then thy2
   159   else raise THEORY ("Not a super theory", [thy1, thy2]);
   160 
   161 
   162 
   163 (** add axioms **)
   164 
   165 (* prepare axioms *)
   166 
   167 fun err_in_axm msg name =
   168   cat_error msg ("The error(s) above occurred in axiom " ^ quote name);
   169 
   170 fun cert_axm thy (name, raw_tm) =
   171   let
   172     val (t, T, _) = Sign.certify_prop thy raw_tm
   173       handle TYPE (msg, _, _) => error msg
   174         | TERM (msg, _) => error msg;
   175   in
   176     Term.no_dummy_patterns t handle TERM (msg, _) => error msg;
   177     (name, Sign.no_vars (Sign.pp thy) t)
   178   end;
   179 
   180 fun read_def_axm (thy, types, sorts) used (name, str) =
   181   let
   182     val ts = Syntax.read (Context.Theory thy) (Sign.is_logtype thy) (Sign.syn_of thy) propT str;
   183     val (t, _) =
   184       Sign.infer_types (Sign.pp thy) thy (Sign.consts_of thy)
   185         types sorts (Name.make_context used) true (ts, propT);
   186   in cert_axm thy (name, t) end
   187   handle ERROR msg => err_in_axm msg name;
   188 
   189 fun read_axm thy name_str = read_def_axm (thy, K NONE, K NONE) [] name_str;
   190 
   191 fun inferT_axm thy (name, pre_tm) =
   192   let
   193     val pp = Sign.pp thy;
   194     val (t, _) =
   195       Sign.infer_types pp thy (Sign.consts_of thy)
   196         (K NONE) (K NONE) Name.context true ([pre_tm], propT);
   197   in (name, Sign.no_vars pp t) end
   198   handle ERROR msg => err_in_axm msg name;
   199 
   200 
   201 (* add_axioms(_i) *)
   202 
   203 local
   204 
   205 fun gen_add_axioms prep_axm raw_axms thy = thy |> map_axioms (fn axioms =>
   206   let
   207     val axms = map (apsnd (Compress.term thy o Logic.varify) o prep_axm thy) raw_axms;
   208     val axioms' = NameSpace.extend_table (Sign.naming_of thy) (axioms, axms)
   209       handle Symtab.DUPS dups => err_dup_axms dups;
   210   in axioms' end);
   211 
   212 in
   213 
   214 val add_axioms = gen_add_axioms read_axm;
   215 val add_axioms_i = gen_add_axioms cert_axm;
   216 
   217 end;
   218 
   219 
   220 
   221 (** add constant definitions **)
   222 
   223 (* dependencies *)
   224 
   225 fun dependencies thy unchecked is_def name lhs rhs =
   226   let
   227     val pp = Sign.pp thy;
   228     val consts = Sign.consts_of thy;
   229     fun prep const =
   230       let val Const (c, T) = Sign.no_vars pp (Const const)
   231       in (c, Consts.typargs consts (c, Compress.typ thy (Logic.varifyT T))) end;
   232 
   233     val lhs_vars = Term.add_tfreesT (#2 lhs) [];
   234     val rhs_extras = fold (#2 #> Term.fold_atyps (fn TFree v =>
   235       if member (op =) lhs_vars v then I else insert (op =) v | _ => I)) rhs [];
   236     val _ =
   237       if null rhs_extras then ()
   238       else error ("Specification depends on extra type variables: " ^
   239         commas_quote (map (Pretty.string_of_typ pp o TFree) rhs_extras) ^
   240         "\nThe error(s) above occurred in " ^ quote name);
   241   in Defs.define pp unchecked is_def (Context.theory_name thy) name (prep lhs) (map prep rhs) end;
   242 
   243 fun add_deps a raw_lhs raw_rhs thy =
   244   let
   245     val lhs :: rhs = map (dest_Const o Sign.cert_term thy o Const) (raw_lhs :: raw_rhs);
   246     val name = if a = "" then (#1 lhs ^ " axiom") else a;
   247   in thy |> map_defs (dependencies thy false false name lhs rhs) end;
   248 
   249 
   250 (* check_overloading *)
   251 
   252 fun check_overloading thy overloaded (c, T) =
   253   let
   254     val declT =
   255       (case Sign.const_constraint thy c of
   256         NONE => error ("Undeclared constant " ^ quote c)
   257       | SOME declT => declT);
   258     val T' = Logic.varifyT T;
   259 
   260     fun message txt =
   261       [Pretty.block [Pretty.str "Specification of constant ",
   262         Pretty.str c, Pretty.str " ::", Pretty.brk 1, Pretty.quote (Sign.pretty_typ thy T)],
   263         Pretty.str txt] |> Pretty.chunks |> Pretty.string_of;
   264   in
   265     if Sign.typ_instance thy (declT, T') then ()
   266     else if Type.raw_instance (declT, T') then
   267       error (Library.setmp show_sorts true
   268         message "imposes additional sort constraints on the constant declaration")
   269     else if overloaded then ()
   270     else warning (message "is strictly less general than the declared type");
   271     (c, T)
   272   end;
   273 
   274 
   275 (* check_def *)
   276 
   277 fun check_def thy unchecked overloaded (bname, tm) defs =
   278   let
   279     val name = Sign.full_name thy bname;
   280     val (lhs_const, rhs) = Sign.cert_def (Sign.pp thy) tm;
   281     val rhs_consts = fold_aterms (fn Const const => insert (op =) const | _ => I) rhs [];
   282     val _ = check_overloading thy overloaded lhs_const;
   283   in defs |> dependencies thy unchecked true name lhs_const rhs_consts end
   284   handle ERROR msg => cat_error msg (Pretty.string_of (Pretty.block
   285    [Pretty.str ("The error(s) above occurred in definition " ^ quote bname ^ ":"),
   286     Pretty.fbrk, Pretty.quote (Sign.pretty_term thy tm)]));
   287 
   288 
   289 (* add_defs(_i) *)
   290 
   291 local
   292 
   293 fun gen_add_defs prep_axm unchecked overloaded raw_axms thy =
   294   let val axms = map (prep_axm thy) raw_axms in
   295     thy
   296     |> map_defs (fold (check_def thy unchecked overloaded) axms)
   297     |> add_axioms_i axms
   298   end;
   299 
   300 in
   301 
   302 val add_defs_i = gen_add_defs cert_axm;
   303 val add_defs = gen_add_defs read_axm;
   304 
   305 end;
   306 
   307 
   308 (* add_finals(_i) *)
   309 
   310 local
   311 
   312 fun gen_add_finals prep_term overloaded args thy =
   313   let
   314     fun const_of (Const const) = const
   315       | const_of (Free _) = error "Attempt to finalize variable (or undeclared constant)"
   316       | const_of _ = error "Attempt to finalize non-constant term";
   317     fun specify (c, T) = dependencies thy false false (c ^ " axiom") (c, T) [];
   318     val finalize = specify o check_overloading thy overloaded o const_of o prep_term thy;
   319   in thy |> map_defs (fold finalize args) end;
   320 
   321 in
   322 
   323 val add_finals = gen_add_finals Sign.read_term;
   324 val add_finals_i = gen_add_finals Sign.cert_term;
   325 
   326 end;
   327 
   328 
   329 
   330 (** add oracle **)
   331 
   332 fun add_oracle (bname, oracle) thy = thy |> map_oracles (fn oracles =>
   333   NameSpace.extend_table (Sign.naming_of thy) (oracles, [(bname, (oracle, stamp ()))])
   334     handle Symtab.DUPS dups => err_dup_oras dups);
   335 
   336 end;
   337 
   338 structure BasicTheory: BASIC_THEORY = Theory;
   339 open BasicTheory;