src/HOL/Analysis/Complex_Analysis_Basics.thy
author Manuel Eberl <eberlm@in.tum.de>
Tue Dec 12 10:01:14 2017 +0100 (17 months ago)
changeset 67167 88d1c9d86f48
parent 67135 1a94352812f4
child 67371 2d9cf74943e1
permissions -rw-r--r--
Moved analysis material from AFP
     1 (*  Author: John Harrison, Marco Maggesi, Graziano Gentili, Gianni Ciolli, Valentina Bruno
     2     Ported from "hol_light/Multivariate/canal.ml" by L C Paulson (2014)
     3 *)
     4 
     5 section \<open>Complex Analysis Basics\<close>
     6 
     7 theory Complex_Analysis_Basics
     8 imports Equivalence_Lebesgue_Henstock_Integration "HOL-Library.Nonpos_Ints"
     9 begin
    10 
    11 
    12 subsection\<open>General lemmas\<close>
    13 
    14 lemma nonneg_Reals_cmod_eq_Re: "z \<in> \<real>\<^sub>\<ge>\<^sub>0 \<Longrightarrow> norm z = Re z"
    15   by (simp add: complex_nonneg_Reals_iff cmod_eq_Re)
    16 
    17 lemma has_derivative_mult_right:
    18   fixes c:: "'a :: real_normed_algebra"
    19   shows "((op * c) has_derivative (op * c)) F"
    20 by (rule has_derivative_mult_right [OF has_derivative_id])
    21 
    22 lemma has_derivative_of_real[derivative_intros, simp]:
    23   "(f has_derivative f') F \<Longrightarrow> ((\<lambda>x. of_real (f x)) has_derivative (\<lambda>x. of_real (f' x))) F"
    24   using bounded_linear.has_derivative[OF bounded_linear_of_real] .
    25 
    26 lemma has_vector_derivative_real_field:
    27   "DERIV f (of_real a) :> f' \<Longrightarrow> ((\<lambda>x. f (of_real x)) has_vector_derivative f') (at a within s)"
    28   using has_derivative_compose[of of_real of_real a _ f "op * f'"]
    29   by (simp add: scaleR_conv_of_real ac_simps has_vector_derivative_def has_field_derivative_def)
    30 lemmas has_vector_derivative_real_complex = has_vector_derivative_real_field
    31 
    32 lemma fact_cancel:
    33   fixes c :: "'a::real_field"
    34   shows "of_nat (Suc n) * c / (fact (Suc n)) = c / (fact n)"
    35   by (simp add: of_nat_mult del: of_nat_Suc times_nat.simps)
    36 
    37 lemma bilinear_times:
    38   fixes c::"'a::real_algebra" shows "bilinear (\<lambda>x y::'a. x*y)"
    39   by (auto simp: bilinear_def distrib_left distrib_right intro!: linearI)
    40 
    41 lemma linear_cnj: "linear cnj"
    42   using bounded_linear.linear[OF bounded_linear_cnj] .
    43 
    44 lemma tendsto_Re_upper:
    45   assumes "~ (trivial_limit F)"
    46           "(f \<longlongrightarrow> l) F"
    47           "eventually (\<lambda>x. Re(f x) \<le> b) F"
    48     shows  "Re(l) \<le> b"
    49   by (metis assms tendsto_le [OF _ tendsto_const]  tendsto_Re)
    50 
    51 lemma tendsto_Re_lower:
    52   assumes "~ (trivial_limit F)"
    53           "(f \<longlongrightarrow> l) F"
    54           "eventually (\<lambda>x. b \<le> Re(f x)) F"
    55     shows  "b \<le> Re(l)"
    56   by (metis assms tendsto_le [OF _ _ tendsto_const]  tendsto_Re)
    57 
    58 lemma tendsto_Im_upper:
    59   assumes "~ (trivial_limit F)"
    60           "(f \<longlongrightarrow> l) F"
    61           "eventually (\<lambda>x. Im(f x) \<le> b) F"
    62     shows  "Im(l) \<le> b"
    63   by (metis assms tendsto_le [OF _ tendsto_const]  tendsto_Im)
    64 
    65 lemma tendsto_Im_lower:
    66   assumes "~ (trivial_limit F)"
    67           "(f \<longlongrightarrow> l) F"
    68           "eventually (\<lambda>x. b \<le> Im(f x)) F"
    69     shows  "b \<le> Im(l)"
    70   by (metis assms tendsto_le [OF _ _ tendsto_const]  tendsto_Im)
    71 
    72 lemma lambda_zero: "(\<lambda>h::'a::mult_zero. 0) = op * 0"
    73   by auto
    74 
    75 lemma lambda_one: "(\<lambda>x::'a::monoid_mult. x) = op * 1"
    76   by auto
    77 
    78 lemma continuous_mult_left:
    79   fixes c::"'a::real_normed_algebra"
    80   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. c * f x)"
    81 by (rule continuous_mult [OF continuous_const])
    82 
    83 lemma continuous_mult_right:
    84   fixes c::"'a::real_normed_algebra"
    85   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. f x * c)"
    86 by (rule continuous_mult [OF _ continuous_const])
    87 
    88 lemma continuous_on_mult_left:
    89   fixes c::"'a::real_normed_algebra"
    90   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. c * f x)"
    91 by (rule continuous_on_mult [OF continuous_on_const])
    92 
    93 lemma continuous_on_mult_right:
    94   fixes c::"'a::real_normed_algebra"
    95   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. f x * c)"
    96 by (rule continuous_on_mult [OF _ continuous_on_const])
    97 
    98 lemma uniformly_continuous_on_cmul_right [continuous_intros]:
    99   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
   100   shows "uniformly_continuous_on s f \<Longrightarrow> uniformly_continuous_on s (\<lambda>x. f x * c)"
   101   using bounded_linear.uniformly_continuous_on[OF bounded_linear_mult_left] .
   102 
   103 lemma uniformly_continuous_on_cmul_left[continuous_intros]:
   104   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
   105   assumes "uniformly_continuous_on s f"
   106     shows "uniformly_continuous_on s (\<lambda>x. c * f x)"
   107 by (metis assms bounded_linear.uniformly_continuous_on bounded_linear_mult_right)
   108 
   109 lemma continuous_within_norm_id [continuous_intros]: "continuous (at x within S) norm"
   110   by (rule continuous_norm [OF continuous_ident])
   111 
   112 lemma continuous_on_norm_id [continuous_intros]: "continuous_on S norm"
   113   by (intro continuous_on_id continuous_on_norm)
   114 
   115 subsection\<open>DERIV stuff\<close>
   116 
   117 lemma DERIV_zero_connected_constant:
   118   fixes f :: "'a::{real_normed_field,euclidean_space} \<Rightarrow> 'a"
   119   assumes "connected s"
   120       and "open s"
   121       and "finite k"
   122       and "continuous_on s f"
   123       and "\<forall>x\<in>(s - k). DERIV f x :> 0"
   124     obtains c where "\<And>x. x \<in> s \<Longrightarrow> f(x) = c"
   125 using has_derivative_zero_connected_constant [OF assms(1-4)] assms
   126 by (metis DERIV_const has_derivative_const Diff_iff at_within_open frechet_derivative_at has_field_derivative_def)
   127 
   128 lemmas DERIV_zero_constant = has_field_derivative_zero_constant
   129 
   130 lemma DERIV_zero_unique:
   131   assumes "convex s"
   132       and d0: "\<And>x. x\<in>s \<Longrightarrow> (f has_field_derivative 0) (at x within s)"
   133       and "a \<in> s"
   134       and "x \<in> s"
   135     shows "f x = f a"
   136   by (rule has_derivative_zero_unique [OF assms(1) _ assms(4,3)])
   137      (metis d0 has_field_derivative_imp_has_derivative lambda_zero)
   138 
   139 lemma DERIV_zero_connected_unique:
   140   assumes "connected s"
   141       and "open s"
   142       and d0: "\<And>x. x\<in>s \<Longrightarrow> DERIV f x :> 0"
   143       and "a \<in> s"
   144       and "x \<in> s"
   145     shows "f x = f a"
   146     by (rule has_derivative_zero_unique_connected [OF assms(2,1) _ assms(5,4)])
   147        (metis has_field_derivative_def lambda_zero d0)
   148 
   149 lemma DERIV_transform_within:
   150   assumes "(f has_field_derivative f') (at a within s)"
   151       and "0 < d" "a \<in> s"
   152       and "\<And>x. x\<in>s \<Longrightarrow> dist x a < d \<Longrightarrow> f x = g x"
   153     shows "(g has_field_derivative f') (at a within s)"
   154   using assms unfolding has_field_derivative_def
   155   by (blast intro: has_derivative_transform_within)
   156 
   157 lemma DERIV_transform_within_open:
   158   assumes "DERIV f a :> f'"
   159       and "open s" "a \<in> s"
   160       and "\<And>x. x\<in>s \<Longrightarrow> f x = g x"
   161     shows "DERIV g a :> f'"
   162   using assms unfolding has_field_derivative_def
   163 by (metis has_derivative_transform_within_open)
   164 
   165 lemma DERIV_transform_at:
   166   assumes "DERIV f a :> f'"
   167       and "0 < d"
   168       and "\<And>x. dist x a < d \<Longrightarrow> f x = g x"
   169     shows "DERIV g a :> f'"
   170   by (blast intro: assms DERIV_transform_within)
   171 
   172 (*generalising DERIV_isconst_all, which requires type real (using the ordering)*)
   173 lemma DERIV_zero_UNIV_unique:
   174   "(\<And>x. DERIV f x :> 0) \<Longrightarrow> f x = f a"
   175   by (metis DERIV_zero_unique UNIV_I convex_UNIV)
   176 
   177 subsection \<open>Some limit theorems about real part of real series etc.\<close>
   178 
   179 (*MOVE? But not to Finite_Cartesian_Product*)
   180 lemma sums_vec_nth :
   181   assumes "f sums a"
   182   shows "(\<lambda>x. f x $ i) sums a $ i"
   183 using assms unfolding sums_def
   184 by (auto dest: tendsto_vec_nth [where i=i])
   185 
   186 lemma summable_vec_nth :
   187   assumes "summable f"
   188   shows "summable (\<lambda>x. f x $ i)"
   189 using assms unfolding summable_def
   190 by (blast intro: sums_vec_nth)
   191 
   192 subsection \<open>Complex number lemmas\<close>
   193 
   194 lemma
   195   shows open_halfspace_Re_lt: "open {z. Re(z) < b}"
   196     and open_halfspace_Re_gt: "open {z. Re(z) > b}"
   197     and closed_halfspace_Re_ge: "closed {z. Re(z) \<ge> b}"
   198     and closed_halfspace_Re_le: "closed {z. Re(z) \<le> b}"
   199     and closed_halfspace_Re_eq: "closed {z. Re(z) = b}"
   200     and open_halfspace_Im_lt: "open {z. Im(z) < b}"
   201     and open_halfspace_Im_gt: "open {z. Im(z) > b}"
   202     and closed_halfspace_Im_ge: "closed {z. Im(z) \<ge> b}"
   203     and closed_halfspace_Im_le: "closed {z. Im(z) \<le> b}"
   204     and closed_halfspace_Im_eq: "closed {z. Im(z) = b}"
   205   by (intro open_Collect_less closed_Collect_le closed_Collect_eq continuous_on_Re
   206             continuous_on_Im continuous_on_id continuous_on_const)+
   207 
   208 lemma closed_complex_Reals: "closed (\<real> :: complex set)"
   209 proof -
   210   have "(\<real> :: complex set) = {z. Im z = 0}"
   211     by (auto simp: complex_is_Real_iff)
   212   then show ?thesis
   213     by (metis closed_halfspace_Im_eq)
   214 qed
   215 
   216 lemma closed_Real_halfspace_Re_le: "closed (\<real> \<inter> {w. Re w \<le> x})"
   217   by (simp add: closed_Int closed_complex_Reals closed_halfspace_Re_le)
   218 
   219 corollary closed_nonpos_Reals_complex [simp]: "closed (\<real>\<^sub>\<le>\<^sub>0 :: complex set)"
   220 proof -
   221   have "\<real>\<^sub>\<le>\<^sub>0 = \<real> \<inter> {z. Re(z) \<le> 0}"
   222     using complex_nonpos_Reals_iff complex_is_Real_iff by auto
   223   then show ?thesis
   224     by (metis closed_Real_halfspace_Re_le)
   225 qed
   226 
   227 lemma closed_Real_halfspace_Re_ge: "closed (\<real> \<inter> {w. x \<le> Re(w)})"
   228   using closed_halfspace_Re_ge
   229   by (simp add: closed_Int closed_complex_Reals)
   230 
   231 corollary closed_nonneg_Reals_complex [simp]: "closed (\<real>\<^sub>\<ge>\<^sub>0 :: complex set)"
   232 proof -
   233   have "\<real>\<^sub>\<ge>\<^sub>0 = \<real> \<inter> {z. Re(z) \<ge> 0}"
   234     using complex_nonneg_Reals_iff complex_is_Real_iff by auto
   235   then show ?thesis
   236     by (metis closed_Real_halfspace_Re_ge)
   237 qed
   238 
   239 lemma closed_real_abs_le: "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   240 proof -
   241   have "{w \<in> \<real>. \<bar>Re w\<bar> \<le> r} = (\<real> \<inter> {w. Re w \<le> r}) \<inter> (\<real> \<inter> {w. Re w \<ge> -r})"
   242     by auto
   243   then show "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   244     by (simp add: closed_Int closed_Real_halfspace_Re_ge closed_Real_halfspace_Re_le)
   245 qed
   246 
   247 lemma real_lim:
   248   fixes l::complex
   249   assumes "(f \<longlongrightarrow> l) F" and "~(trivial_limit F)" and "eventually P F" and "\<And>a. P a \<Longrightarrow> f a \<in> \<real>"
   250   shows  "l \<in> \<real>"
   251 proof (rule Lim_in_closed_set[OF closed_complex_Reals _ assms(2,1)])
   252   show "eventually (\<lambda>x. f x \<in> \<real>) F"
   253     using assms(3, 4) by (auto intro: eventually_mono)
   254 qed
   255 
   256 lemma real_lim_sequentially:
   257   fixes l::complex
   258   shows "(f \<longlongrightarrow> l) sequentially \<Longrightarrow> (\<exists>N. \<forall>n\<ge>N. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   259 by (rule real_lim [where F=sequentially]) (auto simp: eventually_sequentially)
   260 
   261 lemma real_series:
   262   fixes l::complex
   263   shows "f sums l \<Longrightarrow> (\<And>n. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   264 unfolding sums_def
   265 by (metis real_lim_sequentially sum_in_Reals)
   266 
   267 lemma Lim_null_comparison_Re:
   268   assumes "eventually (\<lambda>x. norm(f x) \<le> Re(g x)) F" "(g \<longlongrightarrow> 0) F" shows "(f \<longlongrightarrow> 0) F"
   269   by (rule Lim_null_comparison[OF assms(1)] tendsto_eq_intros assms(2))+ simp
   270 
   271 subsection\<open>Holomorphic functions\<close>
   272 
   273 subsection\<open>Holomorphic functions\<close>
   274 
   275 definition holomorphic_on :: "[complex \<Rightarrow> complex, complex set] \<Rightarrow> bool"
   276            (infixl "(holomorphic'_on)" 50)
   277   where "f holomorphic_on s \<equiv> \<forall>x\<in>s. f field_differentiable (at x within s)"
   278 
   279 named_theorems holomorphic_intros "structural introduction rules for holomorphic_on"
   280 
   281 lemma holomorphic_onI [intro?]: "(\<And>x. x \<in> s \<Longrightarrow> f field_differentiable (at x within s)) \<Longrightarrow> f holomorphic_on s"
   282   by (simp add: holomorphic_on_def)
   283 
   284 lemma holomorphic_onD [dest?]: "\<lbrakk>f holomorphic_on s; x \<in> s\<rbrakk> \<Longrightarrow> f field_differentiable (at x within s)"
   285   by (simp add: holomorphic_on_def)
   286 
   287 lemma holomorphic_on_imp_differentiable_on:
   288     "f holomorphic_on s \<Longrightarrow> f differentiable_on s"
   289   unfolding holomorphic_on_def differentiable_on_def
   290   by (simp add: field_differentiable_imp_differentiable)
   291 
   292 lemma holomorphic_on_imp_differentiable_at:
   293    "\<lbrakk>f holomorphic_on s; open s; x \<in> s\<rbrakk> \<Longrightarrow> f field_differentiable (at x)"
   294 using at_within_open holomorphic_on_def by fastforce
   295 
   296 lemma holomorphic_on_empty [holomorphic_intros]: "f holomorphic_on {}"
   297   by (simp add: holomorphic_on_def)
   298 
   299 lemma holomorphic_on_open:
   300     "open s \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> (\<forall>x \<in> s. \<exists>f'. DERIV f x :> f')"
   301   by (auto simp: holomorphic_on_def field_differentiable_def has_field_derivative_def at_within_open [of _ s])
   302 
   303 lemma holomorphic_on_imp_continuous_on:
   304     "f holomorphic_on s \<Longrightarrow> continuous_on s f"
   305   by (metis field_differentiable_imp_continuous_at continuous_on_eq_continuous_within holomorphic_on_def)
   306 
   307 lemma holomorphic_on_subset [elim]:
   308     "f holomorphic_on s \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f holomorphic_on t"
   309   unfolding holomorphic_on_def
   310   by (metis field_differentiable_within_subset subsetD)
   311 
   312 lemma holomorphic_transform: "\<lbrakk>f holomorphic_on s; \<And>x. x \<in> s \<Longrightarrow> f x = g x\<rbrakk> \<Longrightarrow> g holomorphic_on s"
   313   by (metis field_differentiable_transform_within linordered_field_no_ub holomorphic_on_def)
   314 
   315 lemma holomorphic_cong: "s = t ==> (\<And>x. x \<in> s \<Longrightarrow> f x = g x) \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> g holomorphic_on t"
   316   by (metis holomorphic_transform)
   317 
   318 lemma holomorphic_on_linear [simp, holomorphic_intros]: "(op * c) holomorphic_on s"
   319   unfolding holomorphic_on_def by (metis field_differentiable_linear)
   320 
   321 lemma holomorphic_on_const [simp, holomorphic_intros]: "(\<lambda>z. c) holomorphic_on s"
   322   unfolding holomorphic_on_def by (metis field_differentiable_const)
   323 
   324 lemma holomorphic_on_ident [simp, holomorphic_intros]: "(\<lambda>x. x) holomorphic_on s"
   325   unfolding holomorphic_on_def by (metis field_differentiable_ident)
   326 
   327 lemma holomorphic_on_id [simp, holomorphic_intros]: "id holomorphic_on s"
   328   unfolding id_def by (rule holomorphic_on_ident)
   329 
   330 lemma holomorphic_on_compose:
   331   "f holomorphic_on s \<Longrightarrow> g holomorphic_on (f ` s) \<Longrightarrow> (g o f) holomorphic_on s"
   332   using field_differentiable_compose_within[of f _ s g]
   333   by (auto simp: holomorphic_on_def)
   334 
   335 lemma holomorphic_on_compose_gen:
   336   "f holomorphic_on s \<Longrightarrow> g holomorphic_on t \<Longrightarrow> f ` s \<subseteq> t \<Longrightarrow> (g o f) holomorphic_on s"
   337   by (metis holomorphic_on_compose holomorphic_on_subset)
   338 
   339 lemma holomorphic_on_minus [holomorphic_intros]: "f holomorphic_on s \<Longrightarrow> (\<lambda>z. -(f z)) holomorphic_on s"
   340   by (metis field_differentiable_minus holomorphic_on_def)
   341 
   342 lemma holomorphic_on_add [holomorphic_intros]:
   343   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z + g z) holomorphic_on s"
   344   unfolding holomorphic_on_def by (metis field_differentiable_add)
   345 
   346 lemma holomorphic_on_diff [holomorphic_intros]:
   347   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z - g z) holomorphic_on s"
   348   unfolding holomorphic_on_def by (metis field_differentiable_diff)
   349 
   350 lemma holomorphic_on_mult [holomorphic_intros]:
   351   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z * g z) holomorphic_on s"
   352   unfolding holomorphic_on_def by (metis field_differentiable_mult)
   353 
   354 lemma holomorphic_on_inverse [holomorphic_intros]:
   355   "\<lbrakk>f holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> f z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. inverse (f z)) holomorphic_on s"
   356   unfolding holomorphic_on_def by (metis field_differentiable_inverse)
   357 
   358 lemma holomorphic_on_divide [holomorphic_intros]:
   359   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> g z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. f z / g z) holomorphic_on s"
   360   unfolding holomorphic_on_def by (metis field_differentiable_divide)
   361 
   362 lemma holomorphic_on_power [holomorphic_intros]:
   363   "f holomorphic_on s \<Longrightarrow> (\<lambda>z. (f z)^n) holomorphic_on s"
   364   unfolding holomorphic_on_def by (metis field_differentiable_power)
   365 
   366 lemma holomorphic_on_sum [holomorphic_intros]:
   367   "(\<And>i. i \<in> I \<Longrightarrow> (f i) holomorphic_on s) \<Longrightarrow> (\<lambda>x. sum (\<lambda>i. f i x) I) holomorphic_on s"
   368   unfolding holomorphic_on_def by (metis field_differentiable_sum)
   369 
   370 lemma holomorphic_on_prod [holomorphic_intros]:
   371   "(\<And>i. i \<in> I \<Longrightarrow> (f i) holomorphic_on s) \<Longrightarrow> (\<lambda>x. prod (\<lambda>i. f i x) I) holomorphic_on s"
   372   by (induction I rule: infinite_finite_induct) (auto intro: holomorphic_intros)
   373 
   374 lemma holomorphic_pochhammer [holomorphic_intros]:
   375   "f holomorphic_on A \<Longrightarrow> (\<lambda>s. pochhammer (f s) n) holomorphic_on A"
   376   by (induction n) (auto intro!: holomorphic_intros simp: pochhammer_Suc)
   377 
   378 lemma holomorphic_on_scaleR [holomorphic_intros]:
   379   "f holomorphic_on A \<Longrightarrow> (\<lambda>x. c *\<^sub>R f x) holomorphic_on A"
   380   by (auto simp: scaleR_conv_of_real intro!: holomorphic_intros)
   381 
   382 lemma holomorphic_on_Un [holomorphic_intros]:
   383   assumes "f holomorphic_on A" "f holomorphic_on B" "open A" "open B"
   384   shows   "f holomorphic_on (A \<union> B)"
   385   using assms by (auto simp: holomorphic_on_def  at_within_open[of _ A] 
   386                              at_within_open[of _ B]  at_within_open[of _ "A \<union> B"] open_Un)
   387 
   388 lemma holomorphic_on_If_Un [holomorphic_intros]:
   389   assumes "f holomorphic_on A" "g holomorphic_on B" "open A" "open B"
   390   assumes "\<And>z. z \<in> A \<Longrightarrow> z \<in> B \<Longrightarrow> f z = g z"
   391   shows   "(\<lambda>z. if z \<in> A then f z else g z) holomorphic_on (A \<union> B)" (is "?h holomorphic_on _")
   392 proof (intro holomorphic_on_Un)
   393   note \<open>f holomorphic_on A\<close>
   394   also have "f holomorphic_on A \<longleftrightarrow> ?h holomorphic_on A"
   395     by (intro holomorphic_cong) auto
   396   finally show \<dots> .
   397 next
   398   note \<open>g holomorphic_on B\<close>
   399   also have "g holomorphic_on B \<longleftrightarrow> ?h holomorphic_on B"
   400     using assms by (intro holomorphic_cong) auto
   401   finally show \<dots> .
   402 qed (insert assms, auto)
   403 
   404 lemma DERIV_deriv_iff_field_differentiable:
   405   "DERIV f x :> deriv f x \<longleftrightarrow> f field_differentiable at x"
   406   unfolding field_differentiable_def by (metis DERIV_imp_deriv)
   407 
   408 lemma holomorphic_derivI:
   409      "\<lbrakk>f holomorphic_on S; open S; x \<in> S\<rbrakk>
   410       \<Longrightarrow> (f has_field_derivative deriv f x) (at x within T)"
   411 by (metis DERIV_deriv_iff_field_differentiable at_within_open  holomorphic_on_def has_field_derivative_at_within)
   412 
   413 lemma complex_derivative_chain:
   414   "f field_differentiable at x \<Longrightarrow> g field_differentiable at (f x)
   415     \<Longrightarrow> deriv (g o f) x = deriv g (f x) * deriv f x"
   416   by (metis DERIV_deriv_iff_field_differentiable DERIV_chain DERIV_imp_deriv)
   417 
   418 lemma deriv_linear [simp]: "deriv (\<lambda>w. c * w) = (\<lambda>z. c)"
   419   by (metis DERIV_imp_deriv DERIV_cmult_Id)
   420 
   421 lemma deriv_ident [simp]: "deriv (\<lambda>w. w) = (\<lambda>z. 1)"
   422   by (metis DERIV_imp_deriv DERIV_ident)
   423 
   424 lemma deriv_id [simp]: "deriv id = (\<lambda>z. 1)"
   425   by (simp add: id_def)
   426 
   427 lemma deriv_const [simp]: "deriv (\<lambda>w. c) = (\<lambda>z. 0)"
   428   by (metis DERIV_imp_deriv DERIV_const)
   429 
   430 lemma deriv_add [simp]:
   431   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   432    \<Longrightarrow> deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   433   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   434   by (auto intro!: DERIV_imp_deriv derivative_intros)
   435 
   436 lemma deriv_diff [simp]:
   437   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   438    \<Longrightarrow> deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   439   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   440   by (auto intro!: DERIV_imp_deriv derivative_intros)
   441 
   442 lemma deriv_mult [simp]:
   443   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   444    \<Longrightarrow> deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   445   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   446   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   447 
   448 lemma deriv_cmult [simp]:
   449   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. c * f w) z = c * deriv f z"
   450   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   451   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   452 
   453 lemma deriv_cmult_right [simp]:
   454   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w * c) z = deriv f z * c"
   455   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   456   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   457 
   458 lemma deriv_cdivide_right [simp]:
   459   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w / c) z = deriv f z / c"
   460   unfolding Fields.field_class.field_divide_inverse
   461   by (blast intro: deriv_cmult_right)
   462 
   463 lemma complex_derivative_transform_within_open:
   464   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; open s; z \<in> s; \<And>w. w \<in> s \<Longrightarrow> f w = g w\<rbrakk>
   465    \<Longrightarrow> deriv f z = deriv g z"
   466   unfolding holomorphic_on_def
   467   by (rule DERIV_imp_deriv)
   468      (metis DERIV_deriv_iff_field_differentiable DERIV_transform_within_open at_within_open)
   469 
   470 lemma deriv_compose_linear:
   471   "f field_differentiable at (c * z) \<Longrightarrow> deriv (\<lambda>w. f (c * w)) z = c * deriv f (c * z)"
   472 apply (rule DERIV_imp_deriv)
   473 apply (simp add: DERIV_deriv_iff_field_differentiable [symmetric])
   474 apply (drule DERIV_chain' [of "times c" c z UNIV f "deriv f (c * z)", OF DERIV_cmult_Id])
   475 apply (simp add: algebra_simps)
   476 done
   477 
   478 lemma nonzero_deriv_nonconstant:
   479   assumes df: "DERIV f \<xi> :> df" and S: "open S" "\<xi> \<in> S" and "df \<noteq> 0"
   480     shows "\<not> f constant_on S"
   481 unfolding constant_on_def
   482 by (metis \<open>df \<noteq> 0\<close> DERIV_transform_within_open [OF df S] DERIV_const DERIV_unique)
   483 
   484 lemma holomorphic_nonconstant:
   485   assumes holf: "f holomorphic_on S" and "open S" "\<xi> \<in> S" "deriv f \<xi> \<noteq> 0"
   486     shows "\<not> f constant_on S"
   487     apply (rule nonzero_deriv_nonconstant [of f "deriv f \<xi>" \<xi> S])
   488     using assms
   489     apply (auto simp: holomorphic_derivI)
   490     done
   491 
   492 subsection\<open>Caratheodory characterization\<close>
   493 
   494 lemma field_differentiable_caratheodory_at:
   495   "f field_differentiable (at z) \<longleftrightarrow>
   496          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z) g)"
   497   using CARAT_DERIV [of f]
   498   by (simp add: field_differentiable_def has_field_derivative_def)
   499 
   500 lemma field_differentiable_caratheodory_within:
   501   "f field_differentiable (at z within s) \<longleftrightarrow>
   502          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z within s) g)"
   503   using DERIV_caratheodory_within [of f]
   504   by (simp add: field_differentiable_def has_field_derivative_def)
   505 
   506 subsection\<open>Analyticity on a set\<close>
   507 
   508 definition analytic_on (infixl "(analytic'_on)" 50)
   509   where
   510    "f analytic_on s \<equiv> \<forall>x \<in> s. \<exists>e. 0 < e \<and> f holomorphic_on (ball x e)"
   511 
   512 named_theorems analytic_intros "introduction rules for proving analyticity"
   513 
   514 lemma analytic_imp_holomorphic: "f analytic_on s \<Longrightarrow> f holomorphic_on s"
   515   by (simp add: at_within_open [OF _ open_ball] analytic_on_def holomorphic_on_def)
   516      (metis centre_in_ball field_differentiable_at_within)
   517 
   518 lemma analytic_on_open: "open s \<Longrightarrow> f analytic_on s \<longleftrightarrow> f holomorphic_on s"
   519 apply (auto simp: analytic_imp_holomorphic)
   520 apply (auto simp: analytic_on_def holomorphic_on_def)
   521 by (metis holomorphic_on_def holomorphic_on_subset open_contains_ball)
   522 
   523 lemma analytic_on_imp_differentiable_at:
   524   "f analytic_on s \<Longrightarrow> x \<in> s \<Longrightarrow> f field_differentiable (at x)"
   525  apply (auto simp: analytic_on_def holomorphic_on_def)
   526 by (metis open_ball centre_in_ball field_differentiable_within_open)
   527 
   528 lemma analytic_on_subset: "f analytic_on s \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f analytic_on t"
   529   by (auto simp: analytic_on_def)
   530 
   531 lemma analytic_on_Un: "f analytic_on (s \<union> t) \<longleftrightarrow> f analytic_on s \<and> f analytic_on t"
   532   by (auto simp: analytic_on_def)
   533 
   534 lemma analytic_on_Union: "f analytic_on (\<Union>s) \<longleftrightarrow> (\<forall>t \<in> s. f analytic_on t)"
   535   by (auto simp: analytic_on_def)
   536 
   537 lemma analytic_on_UN: "f analytic_on (\<Union>i\<in>I. s i) \<longleftrightarrow> (\<forall>i\<in>I. f analytic_on (s i))"
   538   by (auto simp: analytic_on_def)
   539 
   540 lemma analytic_on_holomorphic:
   541   "f analytic_on s \<longleftrightarrow> (\<exists>t. open t \<and> s \<subseteq> t \<and> f holomorphic_on t)"
   542   (is "?lhs = ?rhs")
   543 proof -
   544   have "?lhs \<longleftrightarrow> (\<exists>t. open t \<and> s \<subseteq> t \<and> f analytic_on t)"
   545   proof safe
   546     assume "f analytic_on s"
   547     then show "\<exists>t. open t \<and> s \<subseteq> t \<and> f analytic_on t"
   548       apply (simp add: analytic_on_def)
   549       apply (rule exI [where x="\<Union>{u. open u \<and> f analytic_on u}"], auto)
   550       apply (metis open_ball analytic_on_open centre_in_ball)
   551       by (metis analytic_on_def)
   552   next
   553     fix t
   554     assume "open t" "s \<subseteq> t" "f analytic_on t"
   555     then show "f analytic_on s"
   556         by (metis analytic_on_subset)
   557   qed
   558   also have "... \<longleftrightarrow> ?rhs"
   559     by (auto simp: analytic_on_open)
   560   finally show ?thesis .
   561 qed
   562 
   563 lemma analytic_on_linear [analytic_intros,simp]: "(op * c) analytic_on s"
   564   by (auto simp add: analytic_on_holomorphic)
   565 
   566 lemma analytic_on_const [analytic_intros,simp]: "(\<lambda>z. c) analytic_on s"
   567   by (metis analytic_on_def holomorphic_on_const zero_less_one)
   568 
   569 lemma analytic_on_ident [analytic_intros,simp]: "(\<lambda>x. x) analytic_on s"
   570   by (simp add: analytic_on_def gt_ex)
   571 
   572 lemma analytic_on_id [analytic_intros]: "id analytic_on s"
   573   unfolding id_def by (rule analytic_on_ident)
   574 
   575 lemma analytic_on_compose:
   576   assumes f: "f analytic_on s"
   577       and g: "g analytic_on (f ` s)"
   578     shows "(g o f) analytic_on s"
   579 unfolding analytic_on_def
   580 proof (intro ballI)
   581   fix x
   582   assume x: "x \<in> s"
   583   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball x e" using f
   584     by (metis analytic_on_def)
   585   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball (f x) e'" using g
   586     by (metis analytic_on_def g image_eqI x)
   587   have "isCont f x"
   588     by (metis analytic_on_imp_differentiable_at field_differentiable_imp_continuous_at f x)
   589   with e' obtain d where d: "0 < d" and fd: "f ` ball x d \<subseteq> ball (f x) e'"
   590      by (auto simp: continuous_at_ball)
   591   have "g \<circ> f holomorphic_on ball x (min d e)"
   592     apply (rule holomorphic_on_compose)
   593     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   594     by (metis fd gh holomorphic_on_subset image_mono min.cobounded1 subset_ball)
   595   then show "\<exists>e>0. g \<circ> f holomorphic_on ball x e"
   596     by (metis d e min_less_iff_conj)
   597 qed
   598 
   599 lemma analytic_on_compose_gen:
   600   "f analytic_on s \<Longrightarrow> g analytic_on t \<Longrightarrow> (\<And>z. z \<in> s \<Longrightarrow> f z \<in> t)
   601              \<Longrightarrow> g o f analytic_on s"
   602 by (metis analytic_on_compose analytic_on_subset image_subset_iff)
   603 
   604 lemma analytic_on_neg [analytic_intros]:
   605   "f analytic_on s \<Longrightarrow> (\<lambda>z. -(f z)) analytic_on s"
   606 by (metis analytic_on_holomorphic holomorphic_on_minus)
   607 
   608 lemma analytic_on_add [analytic_intros]:
   609   assumes f: "f analytic_on s"
   610       and g: "g analytic_on s"
   611     shows "(\<lambda>z. f z + g z) analytic_on s"
   612 unfolding analytic_on_def
   613 proof (intro ballI)
   614   fix z
   615   assume z: "z \<in> s"
   616   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   617     by (metis analytic_on_def)
   618   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   619     by (metis analytic_on_def g z)
   620   have "(\<lambda>z. f z + g z) holomorphic_on ball z (min e e')"
   621     apply (rule holomorphic_on_add)
   622     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   623     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   624   then show "\<exists>e>0. (\<lambda>z. f z + g z) holomorphic_on ball z e"
   625     by (metis e e' min_less_iff_conj)
   626 qed
   627 
   628 lemma analytic_on_diff [analytic_intros]:
   629   assumes f: "f analytic_on s"
   630       and g: "g analytic_on s"
   631     shows "(\<lambda>z. f z - g z) analytic_on s"
   632 unfolding analytic_on_def
   633 proof (intro ballI)
   634   fix z
   635   assume z: "z \<in> s"
   636   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   637     by (metis analytic_on_def)
   638   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   639     by (metis analytic_on_def g z)
   640   have "(\<lambda>z. f z - g z) holomorphic_on ball z (min e e')"
   641     apply (rule holomorphic_on_diff)
   642     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   643     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   644   then show "\<exists>e>0. (\<lambda>z. f z - g z) holomorphic_on ball z e"
   645     by (metis e e' min_less_iff_conj)
   646 qed
   647 
   648 lemma analytic_on_mult [analytic_intros]:
   649   assumes f: "f analytic_on s"
   650       and g: "g analytic_on s"
   651     shows "(\<lambda>z. f z * g z) analytic_on s"
   652 unfolding analytic_on_def
   653 proof (intro ballI)
   654   fix z
   655   assume z: "z \<in> s"
   656   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   657     by (metis analytic_on_def)
   658   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   659     by (metis analytic_on_def g z)
   660   have "(\<lambda>z. f z * g z) holomorphic_on ball z (min e e')"
   661     apply (rule holomorphic_on_mult)
   662     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   663     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   664   then show "\<exists>e>0. (\<lambda>z. f z * g z) holomorphic_on ball z e"
   665     by (metis e e' min_less_iff_conj)
   666 qed
   667 
   668 lemma analytic_on_inverse [analytic_intros]:
   669   assumes f: "f analytic_on s"
   670       and nz: "(\<And>z. z \<in> s \<Longrightarrow> f z \<noteq> 0)"
   671     shows "(\<lambda>z. inverse (f z)) analytic_on s"
   672 unfolding analytic_on_def
   673 proof (intro ballI)
   674   fix z
   675   assume z: "z \<in> s"
   676   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   677     by (metis analytic_on_def)
   678   have "continuous_on (ball z e) f"
   679     by (metis fh holomorphic_on_imp_continuous_on)
   680   then obtain e' where e': "0 < e'" and nz': "\<And>y. dist z y < e' \<Longrightarrow> f y \<noteq> 0"
   681     by (metis open_ball centre_in_ball continuous_on_open_avoid e z nz)
   682   have "(\<lambda>z. inverse (f z)) holomorphic_on ball z (min e e')"
   683     apply (rule holomorphic_on_inverse)
   684     apply (metis fh holomorphic_on_subset min.cobounded2 min.commute subset_ball)
   685     by (metis nz' mem_ball min_less_iff_conj)
   686   then show "\<exists>e>0. (\<lambda>z. inverse (f z)) holomorphic_on ball z e"
   687     by (metis e e' min_less_iff_conj)
   688 qed
   689 
   690 lemma analytic_on_divide [analytic_intros]:
   691   assumes f: "f analytic_on s"
   692       and g: "g analytic_on s"
   693       and nz: "(\<And>z. z \<in> s \<Longrightarrow> g z \<noteq> 0)"
   694     shows "(\<lambda>z. f z / g z) analytic_on s"
   695 unfolding divide_inverse
   696 by (metis analytic_on_inverse analytic_on_mult f g nz)
   697 
   698 lemma analytic_on_power [analytic_intros]:
   699   "f analytic_on s \<Longrightarrow> (\<lambda>z. (f z) ^ n) analytic_on s"
   700 by (induct n) (auto simp: analytic_on_mult)
   701 
   702 lemma analytic_on_sum [analytic_intros]:
   703   "(\<And>i. i \<in> I \<Longrightarrow> (f i) analytic_on s) \<Longrightarrow> (\<lambda>x. sum (\<lambda>i. f i x) I) analytic_on s"
   704   by (induct I rule: infinite_finite_induct) (auto simp: analytic_on_const analytic_on_add)
   705 
   706 lemma deriv_left_inverse:
   707   assumes "f holomorphic_on S" and "g holomorphic_on T"
   708       and "open S" and "open T"
   709       and "f ` S \<subseteq> T"
   710       and [simp]: "\<And>z. z \<in> S \<Longrightarrow> g (f z) = z"
   711       and "w \<in> S"
   712     shows "deriv f w * deriv g (f w) = 1"
   713 proof -
   714   have "deriv f w * deriv g (f w) = deriv g (f w) * deriv f w"
   715     by (simp add: algebra_simps)
   716   also have "... = deriv (g o f) w"
   717     using assms
   718     by (metis analytic_on_imp_differentiable_at analytic_on_open complex_derivative_chain image_subset_iff)
   719   also have "... = deriv id w"
   720     apply (rule complex_derivative_transform_within_open [where s=S])
   721     apply (rule assms holomorphic_on_compose_gen holomorphic_intros)+
   722     apply simp
   723     done
   724   also have "... = 1"
   725     by simp
   726   finally show ?thesis .
   727 qed
   728 
   729 subsection\<open>analyticity at a point\<close>
   730 
   731 lemma analytic_at_ball:
   732   "f analytic_on {z} \<longleftrightarrow> (\<exists>e. 0<e \<and> f holomorphic_on ball z e)"
   733 by (metis analytic_on_def singleton_iff)
   734 
   735 lemma analytic_at:
   736     "f analytic_on {z} \<longleftrightarrow> (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s)"
   737 by (metis analytic_on_holomorphic empty_subsetI insert_subset)
   738 
   739 lemma analytic_on_analytic_at:
   740     "f analytic_on s \<longleftrightarrow> (\<forall>z \<in> s. f analytic_on {z})"
   741 by (metis analytic_at_ball analytic_on_def)
   742 
   743 lemma analytic_at_two:
   744   "f analytic_on {z} \<and> g analytic_on {z} \<longleftrightarrow>
   745    (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s \<and> g holomorphic_on s)"
   746   (is "?lhs = ?rhs")
   747 proof
   748   assume ?lhs
   749   then obtain s t
   750     where st: "open s" "z \<in> s" "f holomorphic_on s"
   751               "open t" "z \<in> t" "g holomorphic_on t"
   752     by (auto simp: analytic_at)
   753   show ?rhs
   754     apply (rule_tac x="s \<inter> t" in exI)
   755     using st
   756     apply (auto simp: Diff_subset holomorphic_on_subset)
   757     done
   758 next
   759   assume ?rhs
   760   then show ?lhs
   761     by (force simp add: analytic_at)
   762 qed
   763 
   764 subsection\<open>Combining theorems for derivative with ``analytic at'' hypotheses\<close>
   765 
   766 lemma
   767   assumes "f analytic_on {z}" "g analytic_on {z}"
   768   shows complex_derivative_add_at: "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   769     and complex_derivative_diff_at: "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   770     and complex_derivative_mult_at: "deriv (\<lambda>w. f w * g w) z =
   771            f z * deriv g z + deriv f z * g z"
   772 proof -
   773   obtain s where s: "open s" "z \<in> s" "f holomorphic_on s" "g holomorphic_on s"
   774     using assms by (metis analytic_at_two)
   775   show "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   776     apply (rule DERIV_imp_deriv [OF DERIV_add])
   777     using s
   778     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   779     done
   780   show "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   781     apply (rule DERIV_imp_deriv [OF DERIV_diff])
   782     using s
   783     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   784     done
   785   show "deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   786     apply (rule DERIV_imp_deriv [OF DERIV_mult'])
   787     using s
   788     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   789     done
   790 qed
   791 
   792 lemma deriv_cmult_at:
   793   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. c * f w) z = c * deriv f z"
   794 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   795 
   796 lemma deriv_cmult_right_at:
   797   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. f w * c) z = deriv f z * c"
   798 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   799 
   800 subsection\<open>Complex differentiation of sequences and series\<close>
   801 
   802 (* TODO: Could probably be simplified using Uniform_Limit *)
   803 lemma has_complex_derivative_sequence:
   804   fixes s :: "complex set"
   805   assumes cvs: "convex s"
   806       and df:  "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x within s)"
   807       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> s \<longrightarrow> norm (f' n x - g' x) \<le> e"
   808       and "\<exists>x l. x \<in> s \<and> ((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   809     shows "\<exists>g. \<forall>x \<in> s. ((\<lambda>n. f n x) \<longlongrightarrow> g x) sequentially \<and>
   810                        (g has_field_derivative (g' x)) (at x within s)"
   811 proof -
   812   from assms obtain x l where x: "x \<in> s" and tf: "((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   813     by blast
   814   { fix e::real assume e: "e > 0"
   815     then obtain N where N: "\<forall>n\<ge>N. \<forall>x. x \<in> s \<longrightarrow> cmod (f' n x - g' x) \<le> e"
   816       by (metis conv)
   817     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   818     proof (rule exI [of _ N], clarify)
   819       fix n y h
   820       assume "N \<le> n" "y \<in> s"
   821       then have "cmod (f' n y - g' y) \<le> e"
   822         by (metis N)
   823       then have "cmod h * cmod (f' n y - g' y) \<le> cmod h * e"
   824         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   825       then show "cmod (f' n y * h - g' y * h) \<le> e * cmod h"
   826         by (simp add: norm_mult [symmetric] field_simps)
   827     qed
   828   } note ** = this
   829   show ?thesis
   830   unfolding has_field_derivative_def
   831   proof (rule has_derivative_sequence [OF cvs _ _ x])
   832     show "\<forall>n. \<forall>x\<in>s. (f n has_derivative (op * (f' n x))) (at x within s)"
   833       by (metis has_field_derivative_def df)
   834   next show "(\<lambda>n. f n x) \<longlonglongrightarrow> l"
   835     by (rule tf)
   836   next show "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   837     by (blast intro: **)
   838   qed
   839 qed
   840 
   841 lemma has_complex_derivative_series:
   842   fixes s :: "complex set"
   843   assumes cvs: "convex s"
   844       and df:  "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x within s)"
   845       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> s
   846                 \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   847       and "\<exists>x l. x \<in> s \<and> ((\<lambda>n. f n x) sums l)"
   848     shows "\<exists>g. \<forall>x \<in> s. ((\<lambda>n. f n x) sums g x) \<and> ((g has_field_derivative g' x) (at x within s))"
   849 proof -
   850   from assms obtain x l where x: "x \<in> s" and sf: "((\<lambda>n. f n x) sums l)"
   851     by blast
   852   { fix e::real assume e: "e > 0"
   853     then obtain N where N: "\<forall>n x. n \<ge> N \<longrightarrow> x \<in> s
   854             \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   855       by (metis conv)
   856     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   857     proof (rule exI [of _ N], clarify)
   858       fix n y h
   859       assume "N \<le> n" "y \<in> s"
   860       then have "cmod ((\<Sum>i<n. f' i y) - g' y) \<le> e"
   861         by (metis N)
   862       then have "cmod h * cmod ((\<Sum>i<n. f' i y) - g' y) \<le> cmod h * e"
   863         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   864       then show "cmod ((\<Sum>i<n. h * f' i y) - g' y * h) \<le> e * cmod h"
   865         by (simp add: norm_mult [symmetric] field_simps sum_distrib_left)
   866     qed
   867   } note ** = this
   868   show ?thesis
   869   unfolding has_field_derivative_def
   870   proof (rule has_derivative_series [OF cvs _ _ x])
   871     fix n x
   872     assume "x \<in> s"
   873     then show "((f n) has_derivative (\<lambda>z. z * f' n x)) (at x within s)"
   874       by (metis df has_field_derivative_def mult_commute_abs)
   875   next show " ((\<lambda>n. f n x) sums l)"
   876     by (rule sf)
   877   next show "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. \<forall>x\<in>s. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   878     by (blast intro: **)
   879   qed
   880 qed
   881 
   882 
   883 lemma field_differentiable_series:
   884   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach} \<Rightarrow> 'a"
   885   assumes "convex s" "open s"
   886   assumes "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x)"
   887   assumes "uniformly_convergent_on s (\<lambda>n x. \<Sum>i<n. f' i x)"
   888   assumes "x0 \<in> s" "summable (\<lambda>n. f n x0)" and x: "x \<in> s"
   889   shows   "summable (\<lambda>n. f n x)" and "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x)"
   890 proof -
   891   from assms(4) obtain g' where A: "uniform_limit s (\<lambda>n x. \<Sum>i<n. f' i x) g' sequentially"
   892     unfolding uniformly_convergent_on_def by blast
   893   from x and \<open>open s\<close> have s: "at x within s = at x" by (rule at_within_open)
   894   have "\<exists>g. \<forall>x\<in>s. (\<lambda>n. f n x) sums g x \<and> (g has_field_derivative g' x) (at x within s)"
   895     by (intro has_field_derivative_series[of s f f' g' x0] assms A has_field_derivative_at_within)
   896   then obtain g where g: "\<And>x. x \<in> s \<Longrightarrow> (\<lambda>n. f n x) sums g x"
   897     "\<And>x. x \<in> s \<Longrightarrow> (g has_field_derivative g' x) (at x within s)" by blast
   898   from g[OF x] show "summable (\<lambda>n. f n x)" by (auto simp: summable_def)
   899   from g(2)[OF x] have g': "(g has_derivative op * (g' x)) (at x)"
   900     by (simp add: has_field_derivative_def s)
   901   have "((\<lambda>x. \<Sum>n. f n x) has_derivative op * (g' x)) (at x)"
   902     by (rule has_derivative_transform_within_open[OF g' \<open>open s\<close> x])
   903        (insert g, auto simp: sums_iff)
   904   thus "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x)" unfolding differentiable_def
   905     by (auto simp: summable_def field_differentiable_def has_field_derivative_def)
   906 qed
   907 
   908 lemma field_differentiable_series':
   909   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach} \<Rightarrow> 'a"
   910   assumes "convex s" "open s"
   911   assumes "\<And>n x. x \<in> s \<Longrightarrow> (f n has_field_derivative f' n x) (at x)"
   912   assumes "uniformly_convergent_on s (\<lambda>n x. \<Sum>i<n. f' i x)"
   913   assumes "x0 \<in> s" "summable (\<lambda>n. f n x0)"
   914   shows   "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x0)"
   915   using field_differentiable_series[OF assms, of x0] \<open>x0 \<in> s\<close> by blast+
   916 
   917 subsection\<open>Bound theorem\<close>
   918 
   919 lemma field_differentiable_bound:
   920   fixes s :: "'a::real_normed_field set"
   921   assumes cvs: "convex s"
   922       and df:  "\<And>z. z \<in> s \<Longrightarrow> (f has_field_derivative f' z) (at z within s)"
   923       and dn:  "\<And>z. z \<in> s \<Longrightarrow> norm (f' z) \<le> B"
   924       and "x \<in> s"  "y \<in> s"
   925     shows "norm(f x - f y) \<le> B * norm(x - y)"
   926   apply (rule differentiable_bound [OF cvs])
   927   apply (rule ballI, erule df [unfolded has_field_derivative_def])
   928   apply (rule ballI, rule onorm_le, simp add: norm_mult mult_right_mono dn)
   929   apply fact
   930   apply fact
   931   done
   932 
   933 subsection\<open>Inverse function theorem for complex derivatives\<close>
   934 
   935 lemma has_field_derivative_inverse_basic:
   936   shows "DERIV f (g y) :> f' \<Longrightarrow>
   937         f' \<noteq> 0 \<Longrightarrow>
   938         continuous (at y) g \<Longrightarrow>
   939         open t \<Longrightarrow>
   940         y \<in> t \<Longrightarrow>
   941         (\<And>z. z \<in> t \<Longrightarrow> f (g z) = z)
   942         \<Longrightarrow> DERIV g y :> inverse (f')"
   943   unfolding has_field_derivative_def
   944   apply (rule has_derivative_inverse_basic)
   945   apply (auto simp:  bounded_linear_mult_right)
   946   done
   947 
   948 lemmas has_complex_derivative_inverse_basic = has_field_derivative_inverse_basic
   949 
   950 lemma has_field_derivative_inverse_strong:
   951   fixes f :: "'a::{euclidean_space,real_normed_field} \<Rightarrow> 'a"
   952   shows "DERIV f x :> f' \<Longrightarrow>
   953          f' \<noteq> 0 \<Longrightarrow>
   954          open s \<Longrightarrow>
   955          x \<in> s \<Longrightarrow>
   956          continuous_on s f \<Longrightarrow>
   957          (\<And>z. z \<in> s \<Longrightarrow> g (f z) = z)
   958          \<Longrightarrow> DERIV g (f x) :> inverse (f')"
   959   unfolding has_field_derivative_def
   960   apply (rule has_derivative_inverse_strong [of s x f g ])
   961   by auto
   962 lemmas has_complex_derivative_inverse_strong = has_field_derivative_inverse_strong
   963 
   964 lemma has_field_derivative_inverse_strong_x:
   965   fixes f :: "'a::{euclidean_space,real_normed_field} \<Rightarrow> 'a"
   966   shows  "DERIV f (g y) :> f' \<Longrightarrow>
   967           f' \<noteq> 0 \<Longrightarrow>
   968           open s \<Longrightarrow>
   969           continuous_on s f \<Longrightarrow>
   970           g y \<in> s \<Longrightarrow> f(g y) = y \<Longrightarrow>
   971           (\<And>z. z \<in> s \<Longrightarrow> g (f z) = z)
   972           \<Longrightarrow> DERIV g y :> inverse (f')"
   973   unfolding has_field_derivative_def
   974   apply (rule has_derivative_inverse_strong_x [of s g y f])
   975   by auto
   976 lemmas has_complex_derivative_inverse_strong_x = has_field_derivative_inverse_strong_x
   977 
   978 subsection \<open>Taylor on Complex Numbers\<close>
   979 
   980 lemma sum_Suc_reindex:
   981   fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
   982     shows  "sum f {0..n} = f 0 - f (Suc n) + sum (\<lambda>i. f (Suc i)) {0..n}"
   983 by (induct n) auto
   984 
   985 lemma field_taylor:
   986   assumes s: "convex s"
   987       and f: "\<And>i x. x \<in> s \<Longrightarrow> i \<le> n \<Longrightarrow> (f i has_field_derivative f (Suc i) x) (at x within s)"
   988       and B: "\<And>x. x \<in> s \<Longrightarrow> norm (f (Suc n) x) \<le> B"
   989       and w: "w \<in> s"
   990       and z: "z \<in> s"
   991     shows "norm(f 0 z - (\<Sum>i\<le>n. f i w * (z-w) ^ i / (fact i)))
   992           \<le> B * norm(z - w)^(Suc n) / fact n"
   993 proof -
   994   have wzs: "closed_segment w z \<subseteq> s" using assms
   995     by (metis convex_contains_segment)
   996   { fix u
   997     assume "u \<in> closed_segment w z"
   998     then have "u \<in> s"
   999       by (metis wzs subsetD)
  1000     have "(\<Sum>i\<le>n. f i u * (- of_nat i * (z-u)^(i - 1)) / (fact i) +
  1001                       f (Suc i) u * (z-u)^i / (fact i)) =
  1002               f (Suc n) u * (z-u) ^ n / (fact n)"
  1003     proof (induction n)
  1004       case 0 show ?case by simp
  1005     next
  1006       case (Suc n)
  1007       have "(\<Sum>i\<le>Suc n. f i u * (- of_nat i * (z-u) ^ (i - 1)) / (fact i) +
  1008                              f (Suc i) u * (z-u) ^ i / (fact i)) =
  1009            f (Suc n) u * (z-u) ^ n / (fact n) +
  1010            f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n) / (fact (Suc n)) -
  1011            f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n) / (fact (Suc n))"
  1012         using Suc by simp
  1013       also have "... = f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n))"
  1014       proof -
  1015         have "(fact(Suc n)) *
  1016              (f(Suc n) u *(z-u) ^ n / (fact n) +
  1017                f(Suc(Suc n)) u *((z-u) *(z-u) ^ n) / (fact(Suc n)) -
  1018                f(Suc n) u *((1 + of_nat n) *(z-u) ^ n) / (fact(Suc n))) =
  1019             ((fact(Suc n)) *(f(Suc n) u *(z-u) ^ n)) / (fact n) +
  1020             ((fact(Suc n)) *(f(Suc(Suc n)) u *((z-u) *(z-u) ^ n)) / (fact(Suc n))) -
  1021             ((fact(Suc n)) *(f(Suc n) u *(of_nat(Suc n) *(z-u) ^ n))) / (fact(Suc n))"
  1022           by (simp add: algebra_simps del: fact_Suc)
  1023         also have "... = ((fact (Suc n)) * (f (Suc n) u * (z-u) ^ n)) / (fact n) +
  1024                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
  1025                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
  1026           by (simp del: fact_Suc)
  1027         also have "... = (of_nat (Suc n) * (f (Suc n) u * (z-u) ^ n)) +
  1028                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
  1029                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
  1030           by (simp only: fact_Suc of_nat_mult ac_simps) simp
  1031         also have "... = f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)"
  1032           by (simp add: algebra_simps)
  1033         finally show ?thesis
  1034         by (simp add: mult_left_cancel [where c = "(fact (Suc n))", THEN iffD1] del: fact_Suc)
  1035       qed
  1036       finally show ?case .
  1037     qed
  1038     then have "((\<lambda>v. (\<Sum>i\<le>n. f i v * (z - v)^i / (fact i)))
  1039                 has_field_derivative f (Suc n) u * (z-u) ^ n / (fact n))
  1040                (at u within s)"
  1041       apply (intro derivative_eq_intros)
  1042       apply (blast intro: assms \<open>u \<in> s\<close>)
  1043       apply (rule refl)+
  1044       apply (auto simp: field_simps)
  1045       done
  1046   } note sum_deriv = this
  1047   { fix u
  1048     assume u: "u \<in> closed_segment w z"
  1049     then have us: "u \<in> s"
  1050       by (metis wzs subsetD)
  1051     have "norm (f (Suc n) u) * norm (z - u) ^ n \<le> norm (f (Suc n) u) * norm (u - z) ^ n"
  1052       by (metis norm_minus_commute order_refl)
  1053     also have "... \<le> norm (f (Suc n) u) * norm (z - w) ^ n"
  1054       by (metis mult_left_mono norm_ge_zero power_mono segment_bound [OF u])
  1055     also have "... \<le> B * norm (z - w) ^ n"
  1056       by (metis norm_ge_zero zero_le_power mult_right_mono  B [OF us])
  1057     finally have "norm (f (Suc n) u) * norm (z - u) ^ n \<le> B * norm (z - w) ^ n" .
  1058   } note cmod_bound = this
  1059   have "(\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)) = (\<Sum>i\<le>n. (f i z / (fact i)) * 0 ^ i)"
  1060     by simp
  1061   also have "\<dots> = f 0 z / (fact 0)"
  1062     by (subst sum_zero_power) simp
  1063   finally have "norm (f 0 z - (\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)))
  1064                 \<le> norm ((\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)) -
  1065                         (\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)))"
  1066     by (simp add: norm_minus_commute)
  1067   also have "... \<le> B * norm (z - w) ^ n / (fact n) * norm (w - z)"
  1068     apply (rule field_differentiable_bound
  1069       [where f' = "\<lambda>w. f (Suc n) w * (z - w)^n / (fact n)"
  1070          and s = "closed_segment w z", OF convex_closed_segment])
  1071     apply (auto simp: ends_in_segment DERIV_subset [OF sum_deriv wzs]
  1072                   norm_divide norm_mult norm_power divide_le_cancel cmod_bound)
  1073     done
  1074   also have "...  \<le> B * norm (z - w) ^ Suc n / (fact n)"
  1075     by (simp add: algebra_simps norm_minus_commute)
  1076   finally show ?thesis .
  1077 qed
  1078 
  1079 lemma complex_taylor:
  1080   assumes s: "convex s"
  1081       and f: "\<And>i x. x \<in> s \<Longrightarrow> i \<le> n \<Longrightarrow> (f i has_field_derivative f (Suc i) x) (at x within s)"
  1082       and B: "\<And>x. x \<in> s \<Longrightarrow> cmod (f (Suc n) x) \<le> B"
  1083       and w: "w \<in> s"
  1084       and z: "z \<in> s"
  1085     shows "cmod(f 0 z - (\<Sum>i\<le>n. f i w * (z-w) ^ i / (fact i)))
  1086           \<le> B * cmod(z - w)^(Suc n) / fact n"
  1087   using assms by (rule field_taylor)
  1088 
  1089 
  1090 text\<open>Something more like the traditional MVT for real components\<close>
  1091 
  1092 lemma complex_mvt_line:
  1093   assumes "\<And>u. u \<in> closed_segment w z \<Longrightarrow> (f has_field_derivative f'(u)) (at u)"
  1094     shows "\<exists>u. u \<in> closed_segment w z \<and> Re(f z) - Re(f w) = Re(f'(u) * (z - w))"
  1095 proof -
  1096   have twz: "\<And>t. (1 - t) *\<^sub>R w + t *\<^sub>R z = w + t *\<^sub>R (z - w)"
  1097     by (simp add: real_vector.scale_left_diff_distrib real_vector.scale_right_diff_distrib)
  1098   note assms[unfolded has_field_derivative_def, derivative_intros]
  1099   show ?thesis
  1100     apply (cut_tac mvt_simple
  1101                      [of 0 1 "Re o f o (\<lambda>t. (1 - t) *\<^sub>R w +  t *\<^sub>R z)"
  1102                       "\<lambda>u. Re o (\<lambda>h. f'((1 - u) *\<^sub>R w + u *\<^sub>R z) * h) o (\<lambda>t. t *\<^sub>R (z - w))"])
  1103     apply auto
  1104     apply (rule_tac x="(1 - x) *\<^sub>R w + x *\<^sub>R z" in exI)
  1105     apply (auto simp: closed_segment_def twz) []
  1106     apply (intro derivative_eq_intros has_derivative_at_within, simp_all)
  1107     apply (simp add: fun_eq_iff real_vector.scale_right_diff_distrib)
  1108     apply (force simp: twz closed_segment_def)
  1109     done
  1110 qed
  1111 
  1112 lemma complex_taylor_mvt:
  1113   assumes "\<And>i x. \<lbrakk>x \<in> closed_segment w z; i \<le> n\<rbrakk> \<Longrightarrow> ((f i) has_field_derivative f (Suc i) x) (at x)"
  1114     shows "\<exists>u. u \<in> closed_segment w z \<and>
  1115             Re (f 0 z) =
  1116             Re ((\<Sum>i = 0..n. f i w * (z - w) ^ i / (fact i)) +
  1117                 (f (Suc n) u * (z-u)^n / (fact n)) * (z - w))"
  1118 proof -
  1119   { fix u
  1120     assume u: "u \<in> closed_segment w z"
  1121     have "(\<Sum>i = 0..n.
  1122                (f (Suc i) u * (z-u) ^ i - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) /
  1123                (fact i)) =
  1124           f (Suc 0) u -
  1125              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1126              (fact (Suc n)) +
  1127              (\<Sum>i = 0..n.
  1128                  (f (Suc (Suc i)) u * ((z-u) ^ Suc i) - of_nat (Suc i) * (f (Suc i) u * (z-u) ^ i)) /
  1129                  (fact (Suc i)))"
  1130        by (subst sum_Suc_reindex) simp
  1131     also have "... = f (Suc 0) u -
  1132              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1133              (fact (Suc n)) +
  1134              (\<Sum>i = 0..n.
  1135                  f (Suc (Suc i)) u * ((z-u) ^ Suc i) / (fact (Suc i))  -
  1136                  f (Suc i) u * (z-u) ^ i / (fact i))"
  1137       by (simp only: diff_divide_distrib fact_cancel ac_simps)
  1138     also have "... = f (Suc 0) u -
  1139              (f (Suc (Suc n)) u * (z-u) ^ Suc n - of_nat (Suc n) * (z-u) ^ n * f (Suc n) u) /
  1140              (fact (Suc n)) +
  1141              f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n)) - f (Suc 0) u"
  1142       by (subst sum_Suc_diff) auto
  1143     also have "... = f (Suc n) u * (z-u) ^ n / (fact n)"
  1144       by (simp only: algebra_simps diff_divide_distrib fact_cancel)
  1145     finally have "(\<Sum>i = 0..n. (f (Suc i) u * (z - u) ^ i
  1146                              - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) / (fact i)) =
  1147                   f (Suc n) u * (z - u) ^ n / (fact n)" .
  1148     then have "((\<lambda>u. \<Sum>i = 0..n. f i u * (z - u) ^ i / (fact i)) has_field_derivative
  1149                 f (Suc n) u * (z - u) ^ n / (fact n))  (at u)"
  1150       apply (intro derivative_eq_intros)+
  1151       apply (force intro: u assms)
  1152       apply (rule refl)+
  1153       apply (auto simp: ac_simps)
  1154       done
  1155   }
  1156   then show ?thesis
  1157     apply (cut_tac complex_mvt_line [of w z "\<lambda>u. \<Sum>i = 0..n. f i u * (z-u) ^ i / (fact i)"
  1158                "\<lambda>u. (f (Suc n) u * (z-u)^n / (fact n))"])
  1159     apply (auto simp add: intro: open_closed_segment)
  1160     done
  1161 qed
  1162 
  1163 
  1164 subsection \<open>Polynomal function extremal theorem, from HOL Light\<close>
  1165 
  1166 lemma polyfun_extremal_lemma: (*COMPLEX_POLYFUN_EXTREMAL_LEMMA in HOL Light*)
  1167     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1168   assumes "0 < e"
  1169     shows "\<exists>M. \<forall>z. M \<le> norm(z) \<longrightarrow> norm (\<Sum>i\<le>n. c(i) * z^i) \<le> e * norm(z) ^ (Suc n)"
  1170 proof (induct n)
  1171   case 0 with assms
  1172   show ?case
  1173     apply (rule_tac x="norm (c 0) / e" in exI)
  1174     apply (auto simp: field_simps)
  1175     done
  1176 next
  1177   case (Suc n)
  1178   obtain M where M: "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1179     using Suc assms by blast
  1180   show ?case
  1181   proof (rule exI [where x= "max M (1 + norm(c(Suc n)) / e)"], clarsimp simp del: power_Suc)
  1182     fix z::'a
  1183     assume z1: "M \<le> norm z" and "1 + norm (c (Suc n)) / e \<le> norm z"
  1184     then have z2: "e + norm (c (Suc n)) \<le> e * norm z"
  1185       using assms by (simp add: field_simps)
  1186     have "norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1187       using M [OF z1] by simp
  1188     then have "norm (\<Sum>i\<le>n. c i * z^i) + norm (c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1189       by simp
  1190     then have "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1191       by (blast intro: norm_triangle_le elim: )
  1192     also have "... \<le> (e + norm (c (Suc n))) * norm z ^ Suc n"
  1193       by (simp add: norm_power norm_mult algebra_simps)
  1194     also have "... \<le> (e * norm z) * norm z ^ Suc n"
  1195       by (metis z2 mult.commute mult_left_mono norm_ge_zero norm_power)
  1196     finally show "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc (Suc n)"
  1197       by simp
  1198   qed
  1199 qed
  1200 
  1201 lemma polyfun_extremal: (*COMPLEX_POLYFUN_EXTREMAL in HOL Light*)
  1202     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1203   assumes k: "c k \<noteq> 0" "1\<le>k" and kn: "k\<le>n"
  1204     shows "eventually (\<lambda>z. norm (\<Sum>i\<le>n. c(i) * z^i) \<ge> B) at_infinity"
  1205 using kn
  1206 proof (induction n)
  1207   case 0
  1208   then show ?case
  1209     using k  by simp
  1210 next
  1211   case (Suc m)
  1212   let ?even = ?case
  1213   show ?even
  1214   proof (cases "c (Suc m) = 0")
  1215     case True
  1216     then show ?even using Suc k
  1217       by auto (metis antisym_conv less_eq_Suc_le not_le)
  1218   next
  1219     case False
  1220     then obtain M where M:
  1221           "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>m. c i * z^i) \<le> norm (c (Suc m)) / 2 * norm z ^ Suc m"
  1222       using polyfun_extremal_lemma [of "norm(c (Suc m)) / 2" c m] Suc
  1223       by auto
  1224     have "\<exists>b. \<forall>z. b \<le> norm z \<longrightarrow> B \<le> norm (\<Sum>i\<le>Suc m. c i * z^i)"
  1225     proof (rule exI [where x="max M (max 1 (\<bar>B\<bar> / (norm(c (Suc m)) / 2)))"], clarsimp simp del: power_Suc)
  1226       fix z::'a
  1227       assume z1: "M \<le> norm z" "1 \<le> norm z"
  1228          and "\<bar>B\<bar> * 2 / norm (c (Suc m)) \<le> norm z"
  1229       then have z2: "\<bar>B\<bar> \<le> norm (c (Suc m)) * norm z / 2"
  1230         using False by (simp add: field_simps)
  1231       have nz: "norm z \<le> norm z ^ Suc m"
  1232         by (metis \<open>1 \<le> norm z\<close> One_nat_def less_eq_Suc_le power_increasing power_one_right zero_less_Suc)
  1233       have *: "\<And>y x. norm (c (Suc m)) * norm z / 2 \<le> norm y - norm x \<Longrightarrow> B \<le> norm (x + y)"
  1234         by (metis abs_le_iff add.commute norm_diff_ineq order_trans z2)
  1235       have "norm z * norm (c (Suc m)) + 2 * norm (\<Sum>i\<le>m. c i * z^i)
  1236             \<le> norm (c (Suc m)) * norm z + norm (c (Suc m)) * norm z ^ Suc m"
  1237         using M [of z] Suc z1  by auto
  1238       also have "... \<le> 2 * (norm (c (Suc m)) * norm z ^ Suc m)"
  1239         using nz by (simp add: mult_mono del: power_Suc)
  1240       finally show "B \<le> norm ((\<Sum>i\<le>m. c i * z^i) + c (Suc m) * z ^ Suc m)"
  1241         using Suc.IH
  1242         apply (auto simp: eventually_at_infinity)
  1243         apply (rule *)
  1244         apply (simp add: field_simps norm_mult norm_power)
  1245         done
  1246     qed
  1247     then show ?even
  1248       by (simp add: eventually_at_infinity)
  1249   qed
  1250 qed
  1251 
  1252 end