src/Pure/Isar/proof.ML
author wenzelm
Wed Mar 27 14:19:18 2013 +0100 (2013-03-27)
changeset 51551 88d1d19fb74f
parent 51383 50fb0f35a14f
child 51553 63327f679cff
permissions -rw-r--r--
tuned signature and module arrangement;
     1 (*  Title:      Pure/Isar/proof.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 The Isar/VM proof language interpreter: maintains a structured flow of
     5 context elements, goals, refinements, and facts.
     6 *)
     7 
     8 signature PROOF =
     9 sig
    10   type context = Proof.context
    11   type method = Method.method
    12   type state
    13   val init: context -> state
    14   val level: state -> int
    15   val assert_bottom: bool -> state -> state
    16   val context_of: state -> context
    17   val theory_of: state -> theory
    18   val map_context: (context -> context) -> state -> state
    19   val map_context_result : (context -> 'a * context) -> state -> 'a * state
    20   val map_contexts: (context -> context) -> state -> state
    21   val propagate_ml_env: state -> state
    22   val bind_terms: (indexname * term option) list -> state -> state
    23   val put_thms: bool -> string * thm list option -> state -> state
    24   val the_facts: state -> thm list
    25   val the_fact: state -> thm
    26   val set_facts: thm list -> state -> state
    27   val reset_facts: state -> state
    28   val assert_forward: state -> state
    29   val assert_chain: state -> state
    30   val assert_forward_or_chain: state -> state
    31   val assert_backward: state -> state
    32   val assert_no_chain: state -> state
    33   val enter_forward: state -> state
    34   val goal_message: (unit -> Pretty.T) -> state -> state
    35   val pretty_state: int -> state -> Pretty.T list
    36   val refine: Method.text -> state -> state Seq.seq
    37   val refine_end: Method.text -> state -> state Seq.seq
    38   val refine_insert: thm list -> state -> state
    39   val refine_goals: (context -> thm -> unit) -> context -> thm list -> state -> state Seq.seq
    40   val raw_goal: state -> {context: context, facts: thm list, goal: thm}
    41   val goal: state -> {context: context, facts: thm list, goal: thm}
    42   val simple_goal: state -> {context: context, goal: thm}
    43   val status_markup: state -> Markup.T
    44   val let_bind: (term list * term) list -> state -> state
    45   val let_bind_cmd: (string list * string) list -> state -> state
    46   val write: Syntax.mode -> (term * mixfix) list -> state -> state
    47   val write_cmd: Syntax.mode -> (string * mixfix) list -> state -> state
    48   val fix: (binding * typ option * mixfix) list -> state -> state
    49   val fix_cmd: (binding * string option * mixfix) list -> state -> state
    50   val assm: Assumption.export ->
    51     (Thm.binding * (term * term list) list) list -> state -> state
    52   val assm_cmd: Assumption.export ->
    53     (Attrib.binding * (string * string list) list) list -> state -> state
    54   val assume: (Thm.binding * (term * term list) list) list -> state -> state
    55   val assume_cmd: (Attrib.binding * (string * string list) list) list -> state -> state
    56   val presume: (Thm.binding * (term * term list) list) list -> state -> state
    57   val presume_cmd: (Attrib.binding * (string * string list) list) list -> state -> state
    58   val def: (Thm.binding * ((binding * mixfix) * (term * term list))) list -> state -> state
    59   val def_cmd: (Attrib.binding * ((binding * mixfix) * (string * string list))) list -> state -> state
    60   val chain: state -> state
    61   val chain_facts: thm list -> state -> state
    62   val note_thmss: (Thm.binding * (thm list * attribute list) list) list -> state -> state
    63   val note_thmss_cmd: (Attrib.binding * (Facts.ref * Attrib.src list) list) list -> state -> state
    64   val from_thmss: ((thm list * attribute list) list) list -> state -> state
    65   val from_thmss_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    66   val with_thmss: ((thm list * attribute list) list) list -> state -> state
    67   val with_thmss_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    68   val using: ((thm list * attribute list) list) list -> state -> state
    69   val using_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    70   val unfolding: ((thm list * attribute list) list) list -> state -> state
    71   val unfolding_cmd: ((Facts.ref * Attrib.src list) list) list -> state -> state
    72   val invoke_case: string * binding option list * attribute list -> state -> state
    73   val invoke_case_cmd: string * binding option list * Attrib.src list -> state -> state
    74   val begin_block: state -> state
    75   val next_block: state -> state
    76   val end_block: state -> state
    77   val begin_notepad: context -> state
    78   val end_notepad: state -> context
    79   val proof: Method.text option -> state -> state Seq.seq
    80   val proof_results: Method.text_range option -> state -> state Seq.result Seq.seq
    81   val defer: int -> state -> state
    82   val prefer: int -> state -> state
    83   val apply: Method.text -> state -> state Seq.seq
    84   val apply_end: Method.text -> state -> state Seq.seq
    85   val apply_results: Method.text_range -> state -> state Seq.result Seq.seq
    86   val apply_end_results: Method.text_range -> state -> state Seq.result Seq.seq
    87   val local_goal: (context -> ((string * string) * (string * thm list) list) -> unit) ->
    88     (context -> 'a -> attribute) ->
    89     ('b list -> context -> (term list list * (context -> context)) * context) ->
    90     string -> Method.text option -> (thm list list -> state -> state) ->
    91     ((binding * 'a list) * 'b) list -> state -> state
    92   val local_qed: Method.text_range option * bool -> state -> state
    93   val theorem: Method.text option -> (thm list list -> context -> context) ->
    94     (term * term list) list list -> context -> state
    95   val theorem_cmd: Method.text option -> (thm list list -> context -> context) ->
    96     (string * string list) list list -> context -> state
    97   val global_qed: Method.text_range option * bool -> state -> context
    98   val local_terminal_proof: Method.text_range * Method.text_range option -> state -> state
    99   val local_default_proof: state -> state
   100   val local_immediate_proof: state -> state
   101   val local_skip_proof: bool -> state -> state
   102   val local_done_proof: state -> state
   103   val global_terminal_proof: Method.text_range * Method.text_range option -> state -> context
   104   val global_default_proof: state -> context
   105   val global_immediate_proof: state -> context
   106   val global_skip_proof: bool -> state -> context
   107   val global_done_proof: state -> context
   108   val have: Method.text option -> (thm list list -> state -> state) ->
   109     (Thm.binding * (term * term list) list) list -> bool -> state -> state
   110   val have_cmd: Method.text option -> (thm list list -> state -> state) ->
   111     (Attrib.binding * (string * string list) list) list -> bool -> state -> state
   112   val show: Method.text option -> (thm list list -> state -> state) ->
   113     (Thm.binding * (term * term list) list) list -> bool -> state -> state
   114   val show_cmd: Method.text option -> (thm list list -> state -> state) ->
   115     (Attrib.binding * (string * string list) list) list -> bool -> state -> state
   116   val schematic_goal: state -> bool
   117   val is_relevant: state -> bool
   118   val future_proof: (state -> ('a * context) future) -> state -> 'a future * state
   119   val local_future_terminal_proof: Method.text_range * Method.text_range option -> bool ->
   120     state -> state
   121   val global_future_terminal_proof: Method.text_range * Method.text_range option -> bool ->
   122     state -> context
   123 end;
   124 
   125 structure Proof: PROOF =
   126 struct
   127 
   128 type context = Proof.context;
   129 type method = Method.method;
   130 
   131 
   132 (** proof state **)
   133 
   134 (* datatype state *)
   135 
   136 datatype mode = Forward | Chain | Backward;
   137 
   138 datatype state =
   139   State of node Stack.T
   140 and node =
   141   Node of
   142    {context: context,
   143     facts: thm list option,
   144     mode: mode,
   145     goal: goal option}
   146 and goal =
   147   Goal of
   148    {statement: (string * Position.T) * term list list * term,
   149       (*goal kind and statement (starting with vars), initial proposition*)
   150     messages: (unit -> Pretty.T) list,    (*persistent messages (hints etc.)*)
   151     using: thm list,                      (*goal facts*)
   152     goal: thm,                            (*subgoals ==> statement*)
   153     before_qed: Method.text option,
   154     after_qed:
   155       (thm list list -> state -> state) *
   156       (thm list list -> context -> context)};
   157 
   158 fun make_goal (statement, messages, using, goal, before_qed, after_qed) =
   159   Goal {statement = statement, messages = messages, using = using, goal = goal,
   160     before_qed = before_qed, after_qed = after_qed};
   161 
   162 fun make_node (context, facts, mode, goal) =
   163   Node {context = context, facts = facts, mode = mode, goal = goal};
   164 
   165 fun map_node f (Node {context, facts, mode, goal}) =
   166   make_node (f (context, facts, mode, goal));
   167 
   168 val init_context =
   169   Proof_Context.set_stmt true #>
   170   Proof_Context.map_naming (K Name_Space.local_naming);
   171 
   172 fun init ctxt =
   173   State (Stack.init (make_node (init_context ctxt, NONE, Forward, NONE)));
   174 
   175 fun top (State st) = Stack.top st |> (fn Node node => node);
   176 fun map_top f (State st) = State (Stack.map_top (map_node f) st);
   177 fun map_all f (State st) = State (Stack.map_all (map_node f) st);
   178 
   179 
   180 
   181 (** basic proof state operations **)
   182 
   183 (* block structure *)
   184 
   185 fun open_block (State st) = State (Stack.push st);
   186 
   187 fun close_block (State st) = State (Stack.pop st)
   188   handle List.Empty => error "Unbalanced block parentheses";
   189 
   190 fun level (State st) = Stack.level st;
   191 
   192 fun assert_bottom b state =
   193   let val b' = level state <= 2 in
   194     if b andalso not b' then error "Not at bottom of proof"
   195     else if not b andalso b' then error "Already at bottom of proof"
   196     else state
   197   end;
   198 
   199 
   200 (* context *)
   201 
   202 val context_of = #context o top;
   203 val theory_of = Proof_Context.theory_of o context_of;
   204 
   205 fun map_node_context f =
   206   map_node (fn (ctxt, facts, mode, goal) => (f ctxt, facts, mode, goal));
   207 
   208 fun map_context f =
   209   map_top (fn (ctxt, facts, mode, goal) => (f ctxt, facts, mode, goal));
   210 
   211 fun map_context_result f state =
   212   f (context_of state) ||> (fn ctxt => map_context (K ctxt) state);
   213 
   214 fun map_contexts f = map_all (fn (ctxt, facts, mode, goal) => (f ctxt, facts, mode, goal));
   215 
   216 fun propagate_ml_env state = map_contexts
   217   (Context.proof_map (ML_Env.inherit (Context.Proof (context_of state)))) state;
   218 
   219 val bind_terms = map_context o Proof_Context.bind_terms;
   220 val put_thms = map_context oo Proof_Context.put_thms;
   221 
   222 
   223 (* facts *)
   224 
   225 val get_facts = #facts o top;
   226 
   227 fun the_facts state =
   228   (case get_facts state of SOME facts => facts
   229   | NONE => error "No current facts available");
   230 
   231 fun the_fact state =
   232   (case the_facts state of [thm] => thm
   233   | _ => error "Single theorem expected");
   234 
   235 fun put_facts facts =
   236   map_top (fn (ctxt, _, mode, goal) => (ctxt, facts, mode, goal)) #>
   237   put_thms true (Auto_Bind.thisN, facts);
   238 
   239 val set_facts = put_facts o SOME;
   240 val reset_facts = put_facts NONE;
   241 
   242 fun these_factss more_facts (named_factss, state) =
   243   (named_factss, state |> set_facts (maps snd named_factss @ more_facts));
   244 
   245 fun export_facts inner outer =
   246   (case get_facts inner of
   247     NONE => reset_facts outer
   248   | SOME thms =>
   249       thms
   250       |> Proof_Context.export (context_of inner) (context_of outer)
   251       |> (fn ths => set_facts ths outer));
   252 
   253 
   254 (* mode *)
   255 
   256 val get_mode = #mode o top;
   257 fun put_mode mode = map_top (fn (ctxt, facts, _, goal) => (ctxt, facts, mode, goal));
   258 
   259 val mode_name = (fn Forward => "state" | Chain => "chain" | Backward => "prove");
   260 
   261 fun assert_mode pred state =
   262   let val mode = get_mode state in
   263     if pred mode then state
   264     else error ("Illegal application of proof command in " ^ quote (mode_name mode) ^ " mode")
   265   end;
   266 
   267 val assert_forward = assert_mode (fn mode => mode = Forward);
   268 val assert_chain = assert_mode (fn mode => mode = Chain);
   269 val assert_forward_or_chain = assert_mode (fn mode => mode = Forward orelse mode = Chain);
   270 val assert_backward = assert_mode (fn mode => mode = Backward);
   271 val assert_no_chain = assert_mode (fn mode => mode <> Chain);
   272 
   273 val enter_forward = put_mode Forward;
   274 val enter_chain = put_mode Chain;
   275 val enter_backward = put_mode Backward;
   276 
   277 
   278 (* current goal *)
   279 
   280 fun current_goal state =
   281   (case top state of
   282     {context, goal = SOME (Goal goal), ...} => (context, goal)
   283   | _ => error "No current goal");
   284 
   285 fun assert_current_goal g state =
   286   let val g' = can current_goal state in
   287     if g andalso not g' then error "No goal in this block"
   288     else if not g andalso g' then error "Goal present in this block"
   289     else state
   290   end;
   291 
   292 fun put_goal goal = map_top (fn (ctxt, using, mode, _) => (ctxt, using, mode, goal));
   293 
   294 val set_goal = put_goal o SOME;
   295 val reset_goal = put_goal NONE;
   296 
   297 val before_qed = #before_qed o #2 o current_goal;
   298 
   299 
   300 (* nested goal *)
   301 
   302 fun map_goal f g h (State (Node {context, facts, mode, goal = SOME goal}, node :: nodes)) =
   303       let
   304         val Goal {statement, messages, using, goal, before_qed, after_qed} = goal;
   305         val goal' = make_goal (g (statement, messages, using, goal, before_qed, after_qed));
   306         val node' = map_node_context h node;
   307       in State (make_node (f context, facts, mode, SOME goal'), node' :: nodes) end
   308   | map_goal f g h (State (nd, node :: nodes)) =
   309       let
   310         val nd' = map_node_context f nd;
   311         val State (node', nodes') = map_goal f g h (State (node, nodes));
   312       in State (nd', node' :: nodes') end
   313   | map_goal _ _ _ state = state;
   314 
   315 fun provide_goal goal = map_goal I (fn (statement, _, using, _, before_qed, after_qed) =>
   316   (statement, [], using, goal, before_qed, after_qed)) I;
   317 
   318 fun goal_message msg = map_goal I (fn (statement, messages, using, goal, before_qed, after_qed) =>
   319   (statement, msg :: messages, using, goal, before_qed, after_qed)) I;
   320 
   321 fun using_facts using = map_goal I (fn (statement, _, _, goal, before_qed, after_qed) =>
   322   (statement, [], using, goal, before_qed, after_qed)) I;
   323 
   324 local
   325   fun find i state =
   326     (case try current_goal state of
   327       SOME (ctxt, goal) => (ctxt, (i, goal))
   328     | NONE => find (i + 1) (close_block state handle ERROR _ => error "No goal present"));
   329 in val find_goal = find 0 end;
   330 
   331 fun get_goal state =
   332   let val (ctxt, (_, {using, goal, ...})) = find_goal state
   333   in (ctxt, (using, goal)) end;
   334 
   335 
   336 
   337 (** pretty_state **)
   338 
   339 fun pretty_facts _ _ NONE = []
   340   | pretty_facts s ctxt (SOME ths) =
   341       [(Pretty.block o Pretty.fbreaks)
   342         ((if s = "" then Pretty.str "this:"
   343           else Pretty.block [Pretty.command s, Pretty.brk 1, Pretty.str "this:"]) ::
   344           map (Display.pretty_thm ctxt) ths),
   345         Pretty.str ""];
   346 
   347 fun pretty_state nr state =
   348   let
   349     val {context = ctxt, facts, mode, goal = _} = top state;
   350     val verbose = Config.get ctxt Proof_Context.verbose;
   351 
   352     fun prt_goal (SOME (_, (_,
   353       {statement = ((_, pos), _, _), messages, using, goal, before_qed = _, after_qed = _}))) =
   354           pretty_facts "using" ctxt
   355             (if mode <> Backward orelse null using then NONE else SOME using) @
   356           [Proof_Display.pretty_goal_header goal] @ Goal_Display.pretty_goals ctxt goal @
   357           (map (fn msg => Position.setmp_thread_data pos msg ()) (rev messages))
   358       | prt_goal NONE = [];
   359 
   360     val prt_ctxt =
   361       if verbose orelse mode = Forward then Proof_Context.pretty_context ctxt
   362       else if mode = Backward then Proof_Context.pretty_ctxt ctxt
   363       else [];
   364   in
   365     [Pretty.str ("proof (" ^ mode_name mode ^ "): step " ^ string_of_int nr ^
   366       (if verbose then ", depth " ^ string_of_int (level state div 2 - 1) else "")),
   367       Pretty.str ""] @
   368     (if null prt_ctxt then [] else prt_ctxt @ [Pretty.str ""]) @
   369     (if verbose orelse mode = Forward then
   370        pretty_facts "" ctxt facts @ prt_goal (try find_goal state)
   371      else if mode = Chain then pretty_facts "picking" ctxt facts
   372      else prt_goal (try find_goal state))
   373   end;
   374 
   375 
   376 
   377 (** proof steps **)
   378 
   379 (* refine via method *)
   380 
   381 local
   382 
   383 fun goalN i = "goal" ^ string_of_int i;
   384 fun goals st = map goalN (1 upto Thm.nprems_of st);
   385 
   386 fun no_goal_cases st = map (rpair NONE) (goals st);
   387 
   388 fun goal_cases st =
   389   Rule_Cases.make_common
   390     (Thm.theory_of_thm st, Thm.prop_of st) (map (rpair [] o rpair []) (goals st));
   391 
   392 fun apply_method current_context meth state =
   393   let
   394     val (goal_ctxt, (_, {statement, messages = _, using, goal, before_qed, after_qed})) =
   395       find_goal state;
   396     val ctxt = if current_context then context_of state else goal_ctxt;
   397   in
   398     Method.apply meth ctxt using goal |> Seq.map (fn (meth_cases, goal') =>
   399       state
   400       |> map_goal
   401           (Proof_Context.add_cases false (no_goal_cases goal @ goal_cases goal') #>
   402            Proof_Context.add_cases true meth_cases)
   403           (K (statement, [], using, goal', before_qed, after_qed)) I)
   404   end;
   405 
   406 fun select_goals n meth state =
   407   ALLGOALS Goal.conjunction_tac (#2 (#2 (get_goal state)))
   408   |> Seq.maps (fn goal =>
   409     state
   410     |> Seq.lift provide_goal (Goal.extract 1 n goal |> Seq.maps (Goal.conjunction_tac 1))
   411     |> Seq.maps meth
   412     |> Seq.maps (fn state' => state'
   413       |> Seq.lift provide_goal (Goal.retrofit 1 n (#2 (#2 (get_goal state'))) goal))
   414     |> Seq.maps (apply_method true (K Method.succeed)));
   415 
   416 fun apply_text cc text state =
   417   let
   418     val thy = theory_of state;
   419 
   420     fun eval (Method.Basic m) = apply_method cc m
   421       | eval (Method.Source src) = apply_method cc (Method.method thy src)
   422       | eval (Method.Source_i src) = apply_method cc (Method.method_i thy src)
   423       | eval (Method.Then txts) = Seq.EVERY (map eval txts)
   424       | eval (Method.Orelse txts) = Seq.FIRST (map eval txts)
   425       | eval (Method.Try txt) = Seq.TRY (eval txt)
   426       | eval (Method.Repeat1 txt) = Seq.REPEAT1 (eval txt)
   427       | eval (Method.Select_Goals (n, txt)) = select_goals n (eval txt);
   428   in eval text state end;
   429 
   430 in
   431 
   432 val refine = apply_text true;
   433 val refine_end = apply_text false;
   434 fun refine_insert ths = Seq.hd o refine (Method.Basic (K (Method.insert ths)));
   435 
   436 end;
   437 
   438 
   439 (* refine via sub-proof *)
   440 
   441 local
   442 
   443 fun finish_tac 0 = K all_tac
   444   | finish_tac n =
   445       Goal.norm_hhf_tac THEN'
   446       SUBGOAL (fn (goal, i) =>
   447         if can Logic.unprotect (Logic.strip_assums_concl goal) then
   448           Tactic.etac Drule.protectI i THEN finish_tac (n - 1) i
   449         else finish_tac (n - 1) (i + 1));
   450 
   451 fun goal_tac rule =
   452   Goal.norm_hhf_tac THEN'
   453   Tactic.rtac rule THEN'
   454   finish_tac (Thm.nprems_of rule);
   455 
   456 fun FINDGOAL tac st =
   457   let fun find i n = if i > n then Seq.fail else Seq.APPEND (tac i, find (i + 1) n)
   458   in find 1 (Thm.nprems_of st) st end;
   459 
   460 in
   461 
   462 fun refine_goals print_rule inner raw_rules state =
   463   let
   464     val (outer, (_, goal)) = get_goal state;
   465     fun refine rule st = (print_rule outer rule; FINDGOAL (goal_tac rule) st);
   466   in
   467     raw_rules
   468     |> Proof_Context.goal_export inner outer
   469     |> (fn rules => Seq.lift provide_goal (EVERY (map refine rules) goal) state)
   470   end;
   471 
   472 end;
   473 
   474 
   475 (* conclude goal *)
   476 
   477 fun conclude_goal ctxt goal propss =
   478   let
   479     val thy = Proof_Context.theory_of ctxt;
   480     val string_of_term = Syntax.string_of_term ctxt;
   481     val string_of_thm = Display.string_of_thm ctxt;
   482 
   483     val _ = Thm.no_prems goal orelse error (Proof_Display.string_of_goal ctxt goal);
   484 
   485     val extra_hyps = Assumption.extra_hyps ctxt goal;
   486     val _ = null extra_hyps orelse
   487       error ("Additional hypotheses:\n" ^ cat_lines (map string_of_term extra_hyps));
   488 
   489     fun lost_structure () = error ("Lost goal structure:\n" ^ string_of_thm goal);
   490 
   491     val th = Goal.conclude
   492       (if length (flat propss) > 1 then Thm.norm_proof goal else goal)
   493       handle THM _ => lost_structure ();
   494     val goal_propss = filter_out null propss;
   495     val results =
   496       Conjunction.elim_balanced (length goal_propss) th
   497       |> map2 Conjunction.elim_balanced (map length goal_propss)
   498       handle THM _ => lost_structure ();
   499     val _ = Unify.matches_list thy (flat goal_propss) (map Thm.prop_of (flat results)) orelse
   500       error ("Proved a different theorem:\n" ^ string_of_thm th);
   501     val _ = Thm.check_shyps (Variable.sorts_of ctxt) th;
   502 
   503     fun recover_result ([] :: pss) thss = [] :: recover_result pss thss
   504       | recover_result (_ :: pss) (ths :: thss) = ths :: recover_result pss thss
   505       | recover_result [] [] = []
   506       | recover_result _ _ = lost_structure ();
   507   in recover_result propss results end;
   508 
   509 val finished_goal_error = "Failed to finish proof";
   510 
   511 fun finished_goal pos state =
   512   let val (ctxt, (_, goal)) = get_goal state in
   513     if Thm.no_prems goal then Seq.Result state
   514     else
   515       Seq.Error (fn () =>
   516         finished_goal_error ^ Position.here pos ^ ":\n" ^
   517           Proof_Display.string_of_goal ctxt goal)
   518   end;
   519 
   520 
   521 (* goal views -- corresponding to methods *)
   522 
   523 fun raw_goal state =
   524   let val (ctxt, (facts, goal)) = get_goal state
   525   in {context = ctxt, facts = facts, goal = goal} end;
   526 
   527 val goal = raw_goal o refine_insert [];
   528 
   529 fun simple_goal state =
   530   let
   531     val (_, (facts, _)) = get_goal state;
   532     val (ctxt, (_, goal)) = get_goal (refine_insert facts state);
   533   in {context = ctxt, goal = goal} end;
   534 
   535 fun status_markup state =
   536   (case try goal state of
   537     SOME {goal, ...} => Markup.proof_state (Thm.nprems_of goal)
   538   | NONE => Markup.empty);
   539 
   540 fun method_error kind pos state =
   541   Seq.single (Proof_Display.method_error kind pos (raw_goal state));
   542 
   543 
   544 
   545 (*** structured proof commands ***)
   546 
   547 (** context elements **)
   548 
   549 (* let bindings *)
   550 
   551 local
   552 
   553 fun gen_bind bind args state =
   554   state
   555   |> assert_forward
   556   |> map_context (bind true args #> snd)
   557   |> reset_facts;
   558 
   559 in
   560 
   561 val let_bind = gen_bind Proof_Context.match_bind_i;
   562 val let_bind_cmd = gen_bind Proof_Context.match_bind;
   563 
   564 end;
   565 
   566 
   567 (* concrete syntax *)
   568 
   569 local
   570 
   571 fun gen_write prep_arg mode args =
   572   assert_forward
   573   #> map_context (fn ctxt => ctxt |> Proof_Context.notation true mode (map (prep_arg ctxt) args))
   574   #> reset_facts;
   575 
   576 in
   577 
   578 val write = gen_write (K I);
   579 
   580 val write_cmd =
   581   gen_write (fn ctxt => fn (c, mx) =>
   582     (Proof_Context.read_const ctxt false (Mixfix.mixfixT mx) c, mx));
   583 
   584 end;
   585 
   586 
   587 (* fix *)
   588 
   589 local
   590 
   591 fun gen_fix prep_vars args =
   592   assert_forward
   593   #> map_context (fn ctxt => snd (Proof_Context.add_fixes (fst (prep_vars args ctxt)) ctxt))
   594   #> reset_facts;
   595 
   596 in
   597 
   598 val fix = gen_fix Proof_Context.cert_vars;
   599 val fix_cmd = gen_fix Proof_Context.read_vars;
   600 
   601 end;
   602 
   603 
   604 (* assume etc. *)
   605 
   606 local
   607 
   608 fun gen_assume asm prep_att exp args state =
   609   state
   610   |> assert_forward
   611   |> map_context_result (asm exp (Attrib.map_specs (map (prep_att (context_of state))) args))
   612   |> these_factss [] |> #2;
   613 
   614 in
   615 
   616 val assm = gen_assume Proof_Context.add_assms_i (K I);
   617 val assm_cmd = gen_assume Proof_Context.add_assms Attrib.attribute_cmd;
   618 val assume = assm Assumption.assume_export;
   619 val assume_cmd = assm_cmd Assumption.assume_export;
   620 val presume = assm Assumption.presume_export;
   621 val presume_cmd = assm_cmd Assumption.presume_export;
   622 
   623 end;
   624 
   625 
   626 (* def *)
   627 
   628 local
   629 
   630 fun gen_def prep_att prep_vars prep_binds args state =
   631   let
   632     val _ = assert_forward state;
   633     val (raw_name_atts, (raw_vars, raw_rhss)) = args |> split_list ||> split_list;
   634     val name_atts = map (apsnd (map (prep_att (context_of state)))) raw_name_atts;
   635   in
   636     state
   637     |> map_context_result (prep_vars (map (fn (x, mx) => (x, NONE, mx)) raw_vars))
   638     |>> map (fn (x, _, mx) => (x, mx))
   639     |-> (fn vars =>
   640       map_context_result (prep_binds false (map swap raw_rhss))
   641       #-> (fn rhss =>
   642         let
   643           val defs = (vars ~~ (name_atts ~~ rhss)) |> map (fn ((x, mx), ((a, atts), rhs)) =>
   644             ((x, mx), ((Thm.def_binding_optional x a, atts), rhs)));
   645         in map_context_result (Local_Defs.add_defs defs) end))
   646     |-> (set_facts o map (#2 o #2))
   647   end;
   648 
   649 in
   650 
   651 val def = gen_def (K I) Proof_Context.cert_vars Proof_Context.match_bind_i;
   652 val def_cmd = gen_def Attrib.attribute_cmd Proof_Context.read_vars Proof_Context.match_bind;
   653 
   654 end;
   655 
   656 
   657 
   658 (** facts **)
   659 
   660 (* chain *)
   661 
   662 fun clean_facts ctxt =
   663   set_facts (filter_out Thm.is_dummy (the_facts ctxt)) ctxt;
   664 
   665 val chain =
   666   assert_forward
   667   #> clean_facts
   668   #> enter_chain;
   669 
   670 fun chain_facts facts =
   671   set_facts facts
   672   #> chain;
   673 
   674 
   675 (* note etc. *)
   676 
   677 fun no_binding args = map (pair (Binding.empty, [])) args;
   678 
   679 local
   680 
   681 fun gen_thmss more_facts opt_chain opt_result prep_atts prep_fact args state =
   682   state
   683   |> assert_forward
   684   |> map_context_result (fn ctxt => ctxt |> Proof_Context.note_thmss ""
   685     (Attrib.map_facts_refs (map (prep_atts ctxt)) (prep_fact ctxt) args))
   686   |> these_factss (more_facts state)
   687   ||> opt_chain
   688   |> opt_result;
   689 
   690 in
   691 
   692 val note_thmss = gen_thmss (K []) I #2 (K I) (K I);
   693 val note_thmss_cmd = gen_thmss (K []) I #2 Attrib.attribute_cmd Proof_Context.get_fact;
   694 
   695 val from_thmss = gen_thmss (K []) chain #2 (K I) (K I) o no_binding;
   696 val from_thmss_cmd =
   697   gen_thmss (K []) chain #2 Attrib.attribute_cmd Proof_Context.get_fact o no_binding;
   698 
   699 val with_thmss = gen_thmss the_facts chain #2 (K I) (K I) o no_binding;
   700 val with_thmss_cmd =
   701   gen_thmss the_facts chain #2 Attrib.attribute_cmd Proof_Context.get_fact o no_binding;
   702 
   703 val local_results = gen_thmss (K []) I I (K I) (K I) o map (apsnd Thm.simple_fact);
   704 
   705 end;
   706 
   707 
   708 (* using/unfolding *)
   709 
   710 local
   711 
   712 fun gen_using f g prep_att prep_fact args state =
   713   state
   714   |> assert_backward
   715   |> map_context_result
   716     (fn ctxt => ctxt |> Proof_Context.note_thmss ""
   717       (Attrib.map_facts_refs (map (prep_att ctxt)) (prep_fact ctxt) (no_binding args)))
   718   |> (fn (named_facts, state') =>
   719     state' |> map_goal I (fn (statement, _, using, goal, before_qed, after_qed) =>
   720       let
   721         val ctxt = context_of state';
   722         val ths = maps snd named_facts;
   723       in (statement, [], f ctxt ths using, g ctxt ths goal, before_qed, after_qed) end) I);
   724 
   725 fun append_using _ ths using = using @ filter_out Thm.is_dummy ths;
   726 fun unfold_using ctxt ths = map (Local_Defs.unfold ctxt ths);
   727 val unfold_goals = Local_Defs.unfold_goals;
   728 
   729 in
   730 
   731 val using = gen_using append_using (K (K I)) (K I) (K I);
   732 val using_cmd = gen_using append_using (K (K I)) Attrib.attribute_cmd Proof_Context.get_fact;
   733 val unfolding = gen_using unfold_using unfold_goals (K I) (K I);
   734 val unfolding_cmd = gen_using unfold_using unfold_goals Attrib.attribute_cmd Proof_Context.get_fact;
   735 
   736 end;
   737 
   738 
   739 (* case *)
   740 
   741 local
   742 
   743 fun qualified_binding a =
   744   Binding.qualify true (Long_Name.qualifier a) (Binding.name (Long_Name.base_name a));
   745 
   746 fun gen_invoke_case prep_att (name, xs, raw_atts) state =
   747   let
   748     val atts = map (prep_att (context_of state)) raw_atts;
   749     val (asms, state') = state |> map_context_result (fn ctxt =>
   750       ctxt |> Proof_Context.apply_case (Proof_Context.get_case ctxt name xs));
   751     val assumptions = asms |> map (fn (a, ts) => ((qualified_binding a, atts), map (rpair []) ts));
   752   in
   753     state'
   754     |> assume assumptions
   755     |> bind_terms Auto_Bind.no_facts
   756     |> `the_facts |-> (fn thms => note_thmss [((Binding.name name, []), [(thms, [])])])
   757   end;
   758 
   759 in
   760 
   761 val invoke_case = gen_invoke_case (K I);
   762 val invoke_case_cmd = gen_invoke_case Attrib.attribute_cmd;
   763 
   764 end;
   765 
   766 
   767 
   768 (** proof structure **)
   769 
   770 (* blocks *)
   771 
   772 val begin_block =
   773   assert_forward
   774   #> open_block
   775   #> reset_goal
   776   #> open_block;
   777 
   778 val next_block =
   779   assert_forward
   780   #> close_block
   781   #> open_block
   782   #> reset_goal
   783   #> reset_facts;
   784 
   785 fun end_block state =
   786   state
   787   |> assert_forward
   788   |> assert_bottom false
   789   |> close_block
   790   |> assert_current_goal false
   791   |> close_block
   792   |> export_facts state;
   793 
   794 
   795 (* global notepad *)
   796 
   797 val begin_notepad =
   798   init
   799   #> open_block
   800   #> map_context (Variable.set_body true)
   801   #> open_block;
   802 
   803 val end_notepad =
   804   assert_forward
   805   #> assert_bottom true
   806   #> close_block
   807   #> assert_current_goal false
   808   #> close_block
   809   #> context_of;
   810 
   811 
   812 (* sub-proofs *)
   813 
   814 fun proof opt_text =
   815   assert_backward
   816   #> refine (the_default Method.default_text opt_text)
   817   #> Seq.map (using_facts [] #> enter_forward);
   818 
   819 fun proof_results arg =
   820   Seq.APPEND (proof (Method.text arg) #> Seq.make_results,
   821     method_error "initial" (Method.position arg));
   822 
   823 fun end_proof bot (prev_pos, (opt_text, immed)) =
   824   let
   825     val (finish_text, terminal_pos, finished_pos) =
   826       (case opt_text of
   827         NONE => (Method.finish_text (NONE, immed), Position.none, prev_pos)
   828       | SOME (text, (pos, end_pos)) =>
   829           (Method.finish_text (SOME text, immed), Position.set_range (pos, end_pos), end_pos));
   830   in
   831     Seq.APPEND (fn state =>
   832       state
   833       |> assert_forward
   834       |> assert_bottom bot
   835       |> close_block
   836       |> assert_current_goal true
   837       |> using_facts []
   838       |> `before_qed |-> (refine o the_default Method.succeed_text)
   839       |> Seq.maps (refine finish_text)
   840       |> Seq.make_results, method_error "terminal" terminal_pos)
   841     #> Seq.maps_results (Seq.single o finished_goal finished_pos)
   842   end;
   843 
   844 fun check_result msg sq =
   845   (case Seq.pull sq of
   846     NONE => error msg
   847   | SOME (s, _) => s);
   848 
   849 
   850 (* unstructured refinement *)
   851 
   852 fun defer i =
   853   assert_no_chain #>
   854   refine (Method.Basic (fn _ => METHOD (fn _ => ASSERT_SUBGOAL defer_tac i))) #> Seq.hd;
   855 
   856 fun prefer i =
   857   assert_no_chain #>
   858   refine (Method.Basic (fn _ => METHOD (fn _ => ASSERT_SUBGOAL prefer_tac i))) #> Seq.hd;
   859 
   860 fun apply text = assert_backward #> refine text #> Seq.map (using_facts []);
   861 
   862 fun apply_end text = assert_forward #> refine_end text;
   863 
   864 fun apply_results (text, range) =
   865   Seq.APPEND (apply text #> Seq.make_results, method_error "" (Position.set_range range));
   866 
   867 fun apply_end_results (text, range) =
   868   Seq.APPEND (apply_end text #> Seq.make_results, method_error "" (Position.set_range range));
   869 
   870 
   871 
   872 (** goals **)
   873 
   874 (* generic goals *)
   875 
   876 local
   877 
   878 val is_var =
   879   can (dest_TVar o Logic.dest_type o Logic.dest_term) orf
   880   can (dest_Var o Logic.dest_term);
   881 
   882 fun implicit_vars props =
   883   let
   884     val (var_props, _) = take_prefix is_var props;
   885     val explicit_vars = fold Term.add_vars var_props [];
   886     val vars = filter_out (member (op =) explicit_vars) (fold Term.add_vars props []);
   887   in map (Logic.mk_term o Var) vars end;
   888 
   889 fun refine_terms n =
   890   refine (Method.Basic (K (RAW_METHOD
   891     (K (HEADGOAL (PRECISE_CONJUNCTS n
   892       (HEADGOAL (CONJUNCTS (ALLGOALS (rtac Drule.termI))))))))))
   893   #> Seq.hd;
   894 
   895 in
   896 
   897 fun generic_goal prepp kind before_qed after_qed raw_propp state =
   898   let
   899     val thy = theory_of state;
   900     val cert = Thm.cterm_of thy;
   901     val chaining = can assert_chain state;
   902     val pos = Position.thread_data ();
   903 
   904     val ((propss, after_ctxt), goal_state) =
   905       state
   906       |> assert_forward_or_chain
   907       |> enter_forward
   908       |> open_block
   909       |> map_context_result (prepp raw_propp);
   910     val props = flat propss;
   911 
   912     val vars = implicit_vars props;
   913     val propss' = vars :: propss;
   914     val goal_propss = filter_out null propss';
   915     val goal =
   916       cert (Logic.mk_conjunction_balanced (map Logic.mk_conjunction_balanced goal_propss))
   917       |> Thm.weaken_sorts (Variable.sorts_of (context_of goal_state));
   918     val statement = ((kind, pos), propss', Thm.term_of goal);
   919     val after_qed' = after_qed |>> (fn after_local =>
   920       fn results => map_context after_ctxt #> after_local results);
   921   in
   922     goal_state
   923     |> map_context (init_context #> Variable.set_body true)
   924     |> set_goal (make_goal (statement, [], [], Goal.init goal, before_qed, after_qed'))
   925     |> map_context (Proof_Context.auto_bind_goal props)
   926     |> chaining ? (`the_facts #-> using_facts)
   927     |> reset_facts
   928     |> open_block
   929     |> reset_goal
   930     |> enter_backward
   931     |> not (null vars) ? refine_terms (length goal_propss)
   932     |> null props ? (refine (Method.Basic Method.assumption) #> Seq.hd)
   933   end;
   934 
   935 fun generic_qed after_ctxt state =
   936   let
   937     val (goal_ctxt, {statement = (_, stmt, _), goal, after_qed, ...}) = current_goal state;
   938     val outer_state = state |> close_block;
   939     val outer_ctxt = context_of outer_state;
   940 
   941     val props =
   942       flat (tl stmt)
   943       |> Variable.exportT_terms goal_ctxt outer_ctxt;
   944     val results =
   945       tl (conclude_goal goal_ctxt goal stmt)
   946       |> burrow (Proof_Context.export goal_ctxt outer_ctxt);
   947   in
   948     outer_state
   949     |> map_context (after_ctxt props)
   950     |> pair (after_qed, results)
   951   end;
   952 
   953 end;
   954 
   955 
   956 (* local goals *)
   957 
   958 fun local_goal print_results prep_att prepp kind before_qed after_qed stmt state =
   959   let
   960     val ((names, attss), propp) =
   961       Attrib.map_specs (map (prep_att (context_of state))) stmt |> split_list |>> split_list;
   962 
   963     fun after_qed' results =
   964       local_results ((names ~~ attss) ~~ results)
   965       #-> (fn res => tap (fn st => print_results (context_of st) ((kind, ""), res) : unit))
   966       #> after_qed results;
   967   in
   968     state
   969     |> generic_goal prepp kind before_qed (after_qed', K I) propp
   970     |> tap (Variable.warn_extra_tfrees (context_of state) o context_of)
   971   end;
   972 
   973 fun local_qeds arg =
   974   end_proof false arg
   975   #> Seq.map_result (generic_qed Proof_Context.auto_bind_facts #->
   976     (fn ((after_qed, _), results) => after_qed results));
   977 
   978 fun local_qed arg =
   979   local_qeds (Position.none, arg) #> Seq.the_result finished_goal_error;
   980 
   981 
   982 (* global goals *)
   983 
   984 fun prepp_auto_fixes prepp args =
   985   prepp args #>
   986   (fn ((propss, a), ctxt) => ((propss, a), (fold o fold) Variable.auto_fixes propss ctxt));
   987 
   988 fun global_goal prepp before_qed after_qed propp =
   989   init #>
   990   generic_goal (prepp_auto_fixes prepp) "" before_qed (K I, after_qed) propp;
   991 
   992 val theorem = global_goal Proof_Context.bind_propp_schematic_i;
   993 val theorem_cmd = global_goal Proof_Context.bind_propp_schematic;
   994 
   995 fun global_qeds arg =
   996   end_proof true arg
   997   #> Seq.map_result (generic_qed (K I) #> (fn (((_, after_qed), results), state) =>
   998     after_qed results (context_of state)));
   999 
  1000 fun global_qed arg =
  1001   global_qeds (Position.none, arg) #> Seq.the_result finished_goal_error;
  1002 
  1003 
  1004 (* terminal proof steps *)
  1005 
  1006 local
  1007 
  1008 fun terminal_proof qeds initial terminal =
  1009   proof_results (SOME initial) #> Seq.maps_results (qeds (#2 (#2 initial), terminal))
  1010   #> Seq.the_result "";
  1011 
  1012 in
  1013 
  1014 fun local_terminal_proof (text, opt_text) = terminal_proof local_qeds text (opt_text, true);
  1015 val local_default_proof = local_terminal_proof ((Method.default_text, Position.no_range), NONE);
  1016 val local_immediate_proof = local_terminal_proof ((Method.this_text, Position.no_range), NONE);
  1017 val local_done_proof = terminal_proof local_qeds (Method.done_text, Position.no_range) (NONE, false);
  1018 
  1019 fun global_terminal_proof (text, opt_text) = terminal_proof global_qeds text (opt_text, true);
  1020 val global_default_proof = global_terminal_proof ((Method.default_text, Position.no_range), NONE);
  1021 val global_immediate_proof = global_terminal_proof ((Method.this_text, Position.no_range), NONE);
  1022 val global_done_proof = terminal_proof global_qeds (Method.done_text, Position.no_range) (NONE, false);
  1023 
  1024 end;
  1025 
  1026 
  1027 (* skip proofs *)
  1028 
  1029 fun local_skip_proof int state =
  1030   local_terminal_proof ((Method.sorry_text int, Position.no_range), NONE) state before
  1031   Skip_Proof.report (context_of state);
  1032 
  1033 fun global_skip_proof int state =
  1034   global_terminal_proof ((Method.sorry_text int, Position.no_range), NONE) state before
  1035   Skip_Proof.report (context_of state);
  1036 
  1037 
  1038 (* common goal statements *)
  1039 
  1040 local
  1041 
  1042 fun gen_have prep_att prepp before_qed after_qed stmt int =
  1043   local_goal (Proof_Display.print_results Markup.state int)
  1044     prep_att prepp "have" before_qed after_qed stmt;
  1045 
  1046 fun gen_show prep_att prepp before_qed after_qed stmt int state =
  1047   let
  1048     val testing = Unsynchronized.ref false;
  1049     val rule = Unsynchronized.ref (NONE: thm option);
  1050     fun fail_msg ctxt =
  1051       "Local statement fails to refine any pending goal" ::
  1052       (case ! rule of NONE => [] | SOME th => [Proof_Display.string_of_rule ctxt "Failed" th])
  1053       |> cat_lines;
  1054 
  1055     fun print_results ctxt res =
  1056       if ! testing then ()
  1057       else Proof_Display.print_results Markup.state int ctxt res;
  1058     fun print_rule ctxt th =
  1059       if ! testing then rule := SOME th
  1060       else if int then
  1061         writeln (Markup.markup Markup.state (Proof_Display.string_of_rule ctxt "Successful" th))
  1062       else ();
  1063     val test_proof =
  1064       local_skip_proof true
  1065       |> Unsynchronized.setmp testing true
  1066       |> Exn.interruptible_capture;
  1067 
  1068     fun after_qed' results =
  1069       refine_goals print_rule (context_of state) (flat results)
  1070       #> check_result "Failed to refine any pending goal"
  1071       #> after_qed results;
  1072   in
  1073     state
  1074     |> local_goal print_results prep_att prepp "show" before_qed after_qed' stmt
  1075     |> int ? (fn goal_state =>
  1076       (case test_proof (map_context (Context_Position.set_visible false) goal_state) of
  1077         Exn.Res _ => goal_state
  1078       | Exn.Exn exn => raise Exn.EXCEPTIONS ([exn, ERROR (fail_msg (context_of goal_state))])))
  1079   end;
  1080 
  1081 in
  1082 
  1083 val have = gen_have (K I) Proof_Context.bind_propp_i;
  1084 val have_cmd = gen_have Attrib.attribute_cmd Proof_Context.bind_propp;
  1085 val show = gen_show (K I) Proof_Context.bind_propp_i;
  1086 val show_cmd = gen_show Attrib.attribute_cmd Proof_Context.bind_propp;
  1087 
  1088 end;
  1089 
  1090 
  1091 
  1092 (** future proofs **)
  1093 
  1094 (* relevant proof states *)
  1095 
  1096 fun is_schematic t =
  1097   Term.exists_subterm Term.is_Var t orelse
  1098   Term.exists_type (Term.exists_subtype Term.is_TVar) t;
  1099 
  1100 fun schematic_goal state =
  1101   let val (_, (_, {statement = (_, _, prop), ...})) = find_goal state
  1102   in is_schematic prop end;
  1103 
  1104 fun is_relevant state =
  1105   (case try find_goal state of
  1106     NONE => true
  1107   | SOME (_, (_, {statement = (_, _, prop), goal, ...})) =>
  1108       is_schematic prop orelse not (Logic.protect prop aconv Thm.concl_of goal));
  1109 
  1110 
  1111 (* full proofs *)
  1112 
  1113 local
  1114 
  1115 structure Result = Proof_Data
  1116 (
  1117   type T = thm option;
  1118   val empty = NONE;
  1119   fun init _ = empty;
  1120 );
  1121 
  1122 fun the_result ctxt =
  1123   (case Result.get ctxt of
  1124     NONE => error "No result of forked proof"
  1125   | SOME th => th);
  1126 
  1127 val set_result = Result.put o SOME;
  1128 val reset_result = Result.put NONE;
  1129 
  1130 in
  1131 
  1132 fun future_proof fork_proof state =
  1133   let
  1134     val _ = assert_backward state;
  1135     val (goal_ctxt, (_, goal)) = find_goal state;
  1136     val {statement as (kind, _, prop), messages, using, goal, before_qed, after_qed} = goal;
  1137     val goal_tfrees =
  1138       fold Term.add_tfrees
  1139         (prop :: map Thm.term_of (Assumption.all_assms_of goal_ctxt)) [];
  1140 
  1141     val _ = is_relevant state andalso error "Cannot fork relevant proof";
  1142 
  1143     val prop' = Logic.protect prop;
  1144     val statement' = (kind, [[], [prop']], prop');
  1145     val goal' = Thm.adjust_maxidx_thm (Thm.maxidx_of goal)
  1146       (Drule.comp_no_flatten (goal, Thm.nprems_of goal) 1 Drule.protectI);
  1147     val after_qed' = (fn [[th]] => map_context (set_result th), fn [[th]] => set_result th);
  1148 
  1149     val result_ctxt =
  1150       state
  1151       |> map_context reset_result
  1152       |> map_goal I (K (statement', messages, using, goal', before_qed, after_qed'))
  1153         (fold (Variable.declare_typ o TFree) goal_tfrees)
  1154       |> fork_proof;
  1155 
  1156     val future_thm = Future.map (the_result o snd) result_ctxt;
  1157     val finished_goal = Goal.future_result goal_ctxt future_thm prop';
  1158     val state' =
  1159       state
  1160       |> map_goal I (K (statement, messages, using, finished_goal, NONE, after_qed)) I;
  1161   in (Future.map fst result_ctxt, state') end;
  1162 
  1163 end;
  1164 
  1165 
  1166 (* terminal proofs *)
  1167 
  1168 local
  1169 
  1170 fun future_terminal_proof n proof1 proof2 done int state =
  1171   if (Goal.future_enabled_level 4 orelse Goal.future_enabled_nested n andalso not int)
  1172     andalso not (is_relevant state)
  1173   then
  1174     state |> future_proof (fn state' =>
  1175       Goal.fork_name "Proof.future_terminal_proof" ~1
  1176         (fn () => ((), proof2 state'))) |> snd |> done
  1177   else proof1 state;
  1178 
  1179 in
  1180 
  1181 fun local_future_terminal_proof meths =
  1182   future_terminal_proof 3
  1183     (local_terminal_proof meths)
  1184     (local_terminal_proof meths #> context_of) local_done_proof;
  1185 
  1186 fun global_future_terminal_proof meths =
  1187   future_terminal_proof 3
  1188     (global_terminal_proof meths)
  1189     (global_terminal_proof meths) global_done_proof;
  1190 
  1191 end;
  1192 
  1193 end;
  1194