src/HOL/List.thy
author paulson
Wed Aug 21 15:53:30 2002 +0200 (2002-08-21)
changeset 13508 890d736b93a5
parent 13480 bb72bd43c6c3
child 13585 db4005b40cc6
permissions -rw-r--r--
Frederic Blanqui's new "guard" examples
     1 (*  Title:      HOL/List.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow
     4     License:    GPL (GNU GENERAL PUBLIC LICENSE)
     5 *)
     6 
     7 header {* The datatype of finite lists *}
     8 
     9 theory List = PreList:
    10 
    11 datatype 'a list =
    12     Nil    ("[]")
    13   | Cons 'a  "'a list"    (infixr "#" 65)
    14 
    15 consts
    16   "@" :: "'a list => 'a list => 'a list"    (infixr 65)
    17   filter:: "('a => bool) => 'a list => 'a list"
    18   concat:: "'a list list => 'a list"
    19   foldl :: "('b => 'a => 'b) => 'b => 'a list => 'b"
    20   foldr :: "('a => 'b => 'b) => 'a list => 'b => 'b"
    21   hd:: "'a list => 'a"
    22   tl:: "'a list => 'a list"
    23   last:: "'a list => 'a"
    24   butlast :: "'a list => 'a list"
    25   set :: "'a list => 'a set"
    26   list_all:: "('a => bool) => ('a list => bool)"
    27   list_all2 :: "('a => 'b => bool) => 'a list => 'b list => bool"
    28   map :: "('a=>'b) => ('a list => 'b list)"
    29   mem :: "'a => 'a list => bool"    (infixl 55)
    30   nth :: "'a list => nat => 'a"    (infixl "!" 100)
    31   list_update :: "'a list => nat => 'a => 'a list"
    32   take:: "nat => 'a list => 'a list"
    33   drop:: "nat => 'a list => 'a list"
    34   takeWhile :: "('a => bool) => 'a list => 'a list"
    35   dropWhile :: "('a => bool) => 'a list => 'a list"
    36   rev :: "'a list => 'a list"
    37   zip :: "'a list => 'b list => ('a * 'b) list"
    38   upt :: "nat => nat => nat list" ("(1[_../_'(])")
    39   remdups :: "'a list => 'a list"
    40   null:: "'a list => bool"
    41   "distinct":: "'a list => bool"
    42   replicate :: "nat => 'a => 'a list"
    43 
    44 nonterminals lupdbinds lupdbind
    45 
    46 syntax
    47   -- {* list Enumeration *}
    48   "@list" :: "args => 'a list"    ("[(_)]")
    49 
    50   -- {* Special syntax for filter *}
    51   "@filter" :: "[pttrn, 'a list, bool] => 'a list"    ("(1[_:_./ _])")
    52 
    53   -- {* list update *}
    54   "_lupdbind":: "['a, 'a] => lupdbind"    ("(2_ :=/ _)")
    55   "" :: "lupdbind => lupdbinds"    ("_")
    56   "_lupdbinds" :: "[lupdbind, lupdbinds] => lupdbinds"    ("_,/ _")
    57   "_LUpdate" :: "['a, lupdbinds] => 'a"    ("_/[(_)]" [900,0] 900)
    58 
    59   upto:: "nat => nat => nat list"    ("(1[_../_])")
    60 
    61 translations
    62   "[x, xs]" == "x#[xs]"
    63   "[x]" == "x#[]"
    64   "[x:xs . P]"== "filter (%x. P) xs"
    65 
    66   "_LUpdate xs (_lupdbinds b bs)"== "_LUpdate (_LUpdate xs b) bs"
    67   "xs[i:=x]" == "list_update xs i x"
    68 
    69   "[i..j]" == "[i..(Suc j)(]"
    70 
    71 
    72 syntax (xsymbols)
    73   "@filter" :: "[pttrn, 'a list, bool] => 'a list"("(1[_\<in>_ ./ _])")
    74 
    75 
    76 text {*
    77   Function @{text size} is overloaded for all datatypes.Users may
    78   refer to the list version as @{text length}. *}
    79 
    80 syntax length :: "'a list => nat"
    81 translations "length" => "size :: _ list => nat"
    82 
    83 typed_print_translation {*
    84   let
    85     fun size_tr' _ (Type ("fun", (Type ("list", _) :: _))) [t] =
    86           Syntax.const "length" $ t
    87       | size_tr' _ _ _ = raise Match;
    88   in [("size", size_tr')] end
    89 *}
    90 
    91 primrec
    92 "hd(x#xs) = x"
    93 primrec
    94 "tl([]) = []"
    95 "tl(x#xs) = xs"
    96 primrec
    97 "null([]) = True"
    98 "null(x#xs) = False"
    99 primrec
   100 "last(x#xs) = (if xs=[] then x else last xs)"
   101 primrec
   102 "butlast []= []"
   103 "butlast(x#xs) = (if xs=[] then [] else x#butlast xs)"
   104 primrec
   105 "x mem [] = False"
   106 "x mem (y#ys) = (if y=x then True else x mem ys)"
   107 primrec
   108 "set [] = {}"
   109 "set (x#xs) = insert x (set xs)"
   110 primrec
   111 list_all_Nil:"list_all P [] = True"
   112 list_all_Cons: "list_all P (x#xs) = (P(x) \<and> list_all P xs)"
   113 primrec
   114 "map f [] = []"
   115 "map f (x#xs) = f(x)#map f xs"
   116 primrec
   117 append_Nil:"[]@ys = ys"
   118 append_Cons: "(x#xs)@ys = x#(xs@ys)"
   119 primrec
   120 "rev([]) = []"
   121 "rev(x#xs) = rev(xs) @ [x]"
   122 primrec
   123 "filter P [] = []"
   124 "filter P (x#xs) = (if P x then x#filter P xs else filter P xs)"
   125 primrec
   126 foldl_Nil:"foldl f a [] = a"
   127 foldl_Cons: "foldl f a (x#xs) = foldl f (f a x) xs"
   128 primrec
   129 "foldr f [] a = a"
   130 "foldr f (x#xs) a = f x (foldr f xs a)"
   131 primrec
   132 "concat([]) = []"
   133 "concat(x#xs) = x @ concat(xs)"
   134 primrec
   135 drop_Nil:"drop n [] = []"
   136 drop_Cons: "drop n (x#xs) = (case n of 0 => x#xs | Suc(m) => drop m xs)"
   137 -- {* Warning: simpset does not contain this definition *}
   138 -- {* but separate theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   139 primrec
   140 take_Nil:"take n [] = []"
   141 take_Cons: "take n (x#xs) = (case n of 0 => [] | Suc(m) => x # take m xs)"
   142 -- {* Warning: simpset does not contain this definition *}
   143 -- {* but separate theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   144 primrec
   145 nth_Cons:"(x#xs)!n = (case n of 0 => x | (Suc k) => xs!k)"
   146 -- {* Warning: simpset does not contain this definition *}
   147 -- {* but separate theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   148 primrec
   149 "[][i:=v] = []"
   150 "(x#xs)[i:=v] =
   151 (case i of 0 => v # xs
   152 | Suc j => x # xs[j:=v])"
   153 primrec
   154 "takeWhile P [] = []"
   155 "takeWhile P (x#xs) = (if P x then x#takeWhile P xs else [])"
   156 primrec
   157 "dropWhile P [] = []"
   158 "dropWhile P (x#xs) = (if P x then dropWhile P xs else x#xs)"
   159 primrec
   160 "zip xs [] = []"
   161 zip_Cons: "zip xs (y#ys) = (case xs of [] => [] | z#zs => (z,y)#zip zs ys)"
   162 -- {* Warning: simpset does not contain this definition *}
   163 -- {* but separate theorems for @{text "xs = []"} and @{text "xs = z # zs"} *}
   164 primrec
   165 upt_0: "[i..0(] = []"
   166 upt_Suc: "[i..(Suc j)(] = (if i <= j then [i..j(] @ [j] else [])"
   167 primrec
   168 "distinct [] = True"
   169 "distinct (x#xs) = (x ~: set xs \<and> distinct xs)"
   170 primrec
   171 "remdups [] = []"
   172 "remdups (x#xs) = (if x : set xs then remdups xs else x # remdups xs)"
   173 primrec
   174 replicate_0: "replicate 0 x = []"
   175 replicate_Suc: "replicate (Suc n) x = x # replicate n x"
   176 defs
   177  list_all2_def:
   178  "list_all2 P xs ys == length xs = length ys \<and> (\<forall>(x, y) \<in> set (zip xs ys). P x y)"
   179 
   180 
   181 subsection {* Lexicographic orderings on lists *}
   182 
   183 consts
   184 lexn :: "('a * 'a)set => nat => ('a list * 'a list)set"
   185 primrec
   186 "lexn r 0 = {}"
   187 "lexn r (Suc n) =
   188 (prod_fun (%(x,xs). x#xs) (%(x,xs). x#xs) ` (r <*lex*> lexn r n)) Int
   189 {(xs,ys). length xs = Suc n \<and> length ys = Suc n}"
   190 
   191 constdefs
   192 lex :: "('a \<times> 'a) set => ('a list \<times> 'a list) set"
   193 "lex r == \<Union>n. lexn r n"
   194 
   195 lexico :: "('a \<times> 'a) set => ('a list \<times> 'a list) set"
   196 "lexico r == inv_image (less_than <*lex*> lex r) (%xs. (length xs, xs))"
   197 
   198 sublist :: "'a list => nat set => 'a list"
   199 "sublist xs A == map fst (filter (%p. snd p : A) (zip xs [0..size xs(]))"
   200 
   201 
   202 lemma not_Cons_self [simp]: "xs \<noteq> x # xs"
   203 by (induct xs) auto
   204 
   205 lemmas not_Cons_self2 [simp] = not_Cons_self [symmetric]
   206 
   207 lemma neq_Nil_conv: "(xs \<noteq> []) = (\<exists>y ys. xs = y # ys)"
   208 by (induct xs) auto
   209 
   210 lemma length_induct:
   211 "(!!xs. \<forall>ys. length ys < length xs --> P ys ==> P xs) ==> P xs"
   212 by (rule measure_induct [of length]) rules
   213 
   214 
   215 subsection {* @{text lists}: the list-forming operator over sets *}
   216 
   217 consts lists :: "'a set => 'a list set"
   218 inductive "lists A"
   219 intros
   220 Nil [intro!]: "[]: lists A"
   221 Cons [intro!]: "[| a: A;l: lists A|] ==> a#l : lists A"
   222 
   223 inductive_cases listsE [elim!]: "x#l : lists A"
   224 
   225 lemma lists_mono [mono]: "A \<subseteq> B ==> lists A \<subseteq> lists B"
   226 by (unfold lists.defs) (blast intro!: lfp_mono)
   227 
   228 lemma lists_IntI [rule_format]:
   229 "l: lists A ==> l: lists B --> l: lists (A Int B)"
   230 apply (erule lists.induct)
   231 apply blast+
   232 done
   233 
   234 lemma lists_Int_eq [simp]: "lists (A \<inter> B) = lists A \<inter> lists B"
   235 apply (rule mono_Int [THEN equalityI])
   236 apply (simp add: mono_def lists_mono)
   237 apply (blast intro!: lists_IntI)
   238 done
   239 
   240 lemma append_in_lists_conv [iff]:
   241 "(xs @ ys : lists A) = (xs : lists A \<and> ys : lists A)"
   242 by (induct xs) auto
   243 
   244 
   245 subsection {* @{text length} *}
   246 
   247 text {*
   248 Needs to come before @{text "@"} because of theorem @{text
   249 append_eq_append_conv}.
   250 *}
   251 
   252 lemma length_append [simp]: "length (xs @ ys) = length xs + length ys"
   253 by (induct xs) auto
   254 
   255 lemma length_map [simp]: "length (map f xs) = length xs"
   256 by (induct xs) auto
   257 
   258 lemma length_rev [simp]: "length (rev xs) = length xs"
   259 by (induct xs) auto
   260 
   261 lemma length_tl [simp]: "length (tl xs) = length xs - 1"
   262 by (cases xs) auto
   263 
   264 lemma length_0_conv [iff]: "(length xs = 0) = (xs = [])"
   265 by (induct xs) auto
   266 
   267 lemma length_greater_0_conv [iff]: "(0 < length xs) = (xs \<noteq> [])"
   268 by (induct xs) auto
   269 
   270 lemma length_Suc_conv:
   271 "(length xs = Suc n) = (\<exists>y ys. xs = y # ys \<and> length ys = n)"
   272 by (induct xs) auto
   273 
   274 
   275 subsection {* @{text "@"} -- append *}
   276 
   277 lemma append_assoc [simp]: "(xs @ ys) @ zs = xs @ (ys @ zs)"
   278 by (induct xs) auto
   279 
   280 lemma append_Nil2 [simp]: "xs @ [] = xs"
   281 by (induct xs) auto
   282 
   283 lemma append_is_Nil_conv [iff]: "(xs @ ys = []) = (xs = [] \<and> ys = [])"
   284 by (induct xs) auto
   285 
   286 lemma Nil_is_append_conv [iff]: "([] = xs @ ys) = (xs = [] \<and> ys = [])"
   287 by (induct xs) auto
   288 
   289 lemma append_self_conv [iff]: "(xs @ ys = xs) = (ys = [])"
   290 by (induct xs) auto
   291 
   292 lemma self_append_conv [iff]: "(xs = xs @ ys) = (ys = [])"
   293 by (induct xs) auto
   294 
   295 lemma append_eq_append_conv [rule_format, simp]:
   296  "\<forall>ys. length xs = length ys \<or> length us = length vs
   297  --> (xs@us = ys@vs) = (xs=ys \<and> us=vs)"
   298 apply (induct_tac xs)
   299  apply(rule allI)
   300  apply (case_tac ys)
   301 apply simp
   302  apply force
   303 apply (rule allI)
   304 apply (case_tac ys)
   305  apply force
   306 apply simp
   307 done
   308 
   309 lemma same_append_eq [iff]: "(xs @ ys = xs @ zs) = (ys = zs)"
   310 by simp
   311 
   312 lemma append1_eq_conv [iff]: "(xs @ [x] = ys @ [y]) = (xs = ys \<and> x = y)"
   313 by simp
   314 
   315 lemma append_same_eq [iff]: "(ys @ xs = zs @ xs) = (ys = zs)"
   316 by simp
   317 
   318 lemma append_self_conv2 [iff]: "(xs @ ys = ys) = (xs = [])"
   319 using append_same_eq [of _ _ "[]"] by auto
   320 
   321 lemma self_append_conv2 [iff]: "(ys = xs @ ys) = (xs = [])"
   322 using append_same_eq [of "[]"] by auto
   323 
   324 lemma hd_Cons_tl [simp]: "xs \<noteq> [] ==> hd xs # tl xs = xs"
   325 by (induct xs) auto
   326 
   327 lemma hd_append: "hd (xs @ ys) = (if xs = [] then hd ys else hd xs)"
   328 by (induct xs) auto
   329 
   330 lemma hd_append2 [simp]: "xs \<noteq> [] ==> hd (xs @ ys) = hd xs"
   331 by (simp add: hd_append split: list.split)
   332 
   333 lemma tl_append: "tl (xs @ ys) = (case xs of [] => tl ys | z#zs => zs @ ys)"
   334 by (simp split: list.split)
   335 
   336 lemma tl_append2 [simp]: "xs \<noteq> [] ==> tl (xs @ ys) = tl xs @ ys"
   337 by (simp add: tl_append split: list.split)
   338 
   339 
   340 text {* Trivial rules for solving @{text "@"}-equations automatically. *}
   341 
   342 lemma eq_Nil_appendI: "xs = ys ==> xs = [] @ ys"
   343 by simp
   344 
   345 lemma Cons_eq_appendI:
   346 "[| x # xs1 = ys; xs = xs1 @ zs |] ==> x # xs = ys @ zs"
   347 by (drule sym) simp
   348 
   349 lemma append_eq_appendI:
   350 "[| xs @ xs1 = zs; ys = xs1 @ us |] ==> xs @ ys = zs @ us"
   351 by (drule sym) simp
   352 
   353 
   354 text {*
   355 Simplification procedure for all list equalities.
   356 Currently only tries to rearrange @{text "@"} to see if
   357 - both lists end in a singleton list,
   358 - or both lists end in the same list.
   359 *}
   360 
   361 ML_setup {*
   362 local
   363 
   364 val append_assoc = thm "append_assoc";
   365 val append_Nil = thm "append_Nil";
   366 val append_Cons = thm "append_Cons";
   367 val append1_eq_conv = thm "append1_eq_conv";
   368 val append_same_eq = thm "append_same_eq";
   369 
   370 fun last (cons as Const("List.list.Cons",_) $ _ $ xs) =
   371   (case xs of Const("List.list.Nil",_) => cons | _ => last xs)
   372   | last (Const("List.op @",_) $ _ $ ys) = last ys
   373   | last t = t;
   374 
   375 fun list1 (Const("List.list.Cons",_) $ _ $ Const("List.list.Nil",_)) = true
   376   | list1 _ = false;
   377 
   378 fun butlast ((cons as Const("List.list.Cons",_) $ x) $ xs) =
   379   (case xs of Const("List.list.Nil",_) => xs | _ => cons $ butlast xs)
   380   | butlast ((app as Const("List.op @",_) $ xs) $ ys) = app $ butlast ys
   381   | butlast xs = Const("List.list.Nil",fastype_of xs);
   382 
   383 val rearr_tac =
   384   simp_tac (HOL_basic_ss addsimps [append_assoc, append_Nil, append_Cons]);
   385 
   386 fun list_eq sg _ (F as (eq as Const(_,eqT)) $ lhs $ rhs) =
   387   let
   388     val lastl = last lhs and lastr = last rhs;
   389     fun rearr conv =
   390       let
   391         val lhs1 = butlast lhs and rhs1 = butlast rhs;
   392         val Type(_,listT::_) = eqT
   393         val appT = [listT,listT] ---> listT
   394         val app = Const("List.op @",appT)
   395         val F2 = eq $ (app$lhs1$lastl) $ (app$rhs1$lastr)
   396         val eq = HOLogic.mk_Trueprop (HOLogic.mk_eq (F,F2));
   397         val thm = Tactic.prove sg [] [] eq (K (rearr_tac 1));
   398       in Some ((conv RS (thm RS trans)) RS eq_reflection) end;
   399 
   400   in
   401     if list1 lastl andalso list1 lastr then rearr append1_eq_conv
   402     else if lastl aconv lastr then rearr append_same_eq
   403     else None
   404   end;
   405 
   406 in
   407 
   408 val list_eq_simproc =
   409   Simplifier.simproc (Theory.sign_of (the_context ())) "list_eq" ["(xs::'a list) = ys"] list_eq;
   410 
   411 end;
   412 
   413 Addsimprocs [list_eq_simproc];
   414 *}
   415 
   416 
   417 subsection {* @{text map} *}
   418 
   419 lemma map_ext: "(!!x. x : set xs --> f x = g x) ==> map f xs = map g xs"
   420 by (induct xs) simp_all
   421 
   422 lemma map_ident [simp]: "map (\<lambda>x. x) = (\<lambda>xs. xs)"
   423 by (rule ext, induct_tac xs) auto
   424 
   425 lemma map_append [simp]: "map f (xs @ ys) = map f xs @ map f ys"
   426 by (induct xs) auto
   427 
   428 lemma map_compose: "map (f o g) xs = map f (map g xs)"
   429 by (induct xs) (auto simp add: o_def)
   430 
   431 lemma rev_map: "rev (map f xs) = map f (rev xs)"
   432 by (induct xs) auto
   433 
   434 lemma map_cong [recdef_cong]:
   435 "xs = ys ==> (!!x. x : set ys ==> f x = g x) ==> map f xs = map g ys"
   436 -- {* a congruence rule for @{text map} *}
   437 by (clarify, induct ys) auto
   438 
   439 lemma map_is_Nil_conv [iff]: "(map f xs = []) = (xs = [])"
   440 by (cases xs) auto
   441 
   442 lemma Nil_is_map_conv [iff]: "([] = map f xs) = (xs = [])"
   443 by (cases xs) auto
   444 
   445 lemma map_eq_Cons:
   446 "(map f xs = y # ys) = (\<exists>x xs'. xs = x # xs' \<and> f x = y \<and> map f xs' = ys)"
   447 by (cases xs) auto
   448 
   449 lemma map_injective:
   450 "!!xs. map f xs = map f ys ==> (\<forall>x y. f x = f y --> x = y) ==> xs = ys"
   451 by (induct ys) (auto simp add: map_eq_Cons)
   452 
   453 lemma inj_mapI: "inj f ==> inj (map f)"
   454 by (rules dest: map_injective injD intro: injI)
   455 
   456 lemma inj_mapD: "inj (map f) ==> inj f"
   457 apply (unfold inj_on_def)
   458 apply clarify
   459 apply (erule_tac x = "[x]" in ballE)
   460  apply (erule_tac x = "[y]" in ballE)
   461 apply simp
   462  apply blast
   463 apply blast
   464 done
   465 
   466 lemma inj_map: "inj (map f) = inj f"
   467 by (blast dest: inj_mapD intro: inj_mapI)
   468 
   469 
   470 subsection {* @{text rev} *}
   471 
   472 lemma rev_append [simp]: "rev (xs @ ys) = rev ys @ rev xs"
   473 by (induct xs) auto
   474 
   475 lemma rev_rev_ident [simp]: "rev (rev xs) = xs"
   476 by (induct xs) auto
   477 
   478 lemma rev_is_Nil_conv [iff]: "(rev xs = []) = (xs = [])"
   479 by (induct xs) auto
   480 
   481 lemma Nil_is_rev_conv [iff]: "([] = rev xs) = (xs = [])"
   482 by (induct xs) auto
   483 
   484 lemma rev_is_rev_conv [iff]: "!!ys. (rev xs = rev ys) = (xs = ys)"
   485 apply (induct xs)
   486  apply force
   487 apply (case_tac ys)
   488  apply simp
   489 apply force
   490 done
   491 
   492 lemma rev_induct [case_names Nil snoc]:
   493   "[| P []; !!x xs. P xs ==> P (xs @ [x]) |] ==> P xs"
   494 apply(subst rev_rev_ident[symmetric])
   495 apply(rule_tac list = "rev xs" in list.induct, simp_all)
   496 done
   497 
   498 ML {* val rev_induct_tac = induct_thm_tac (thm "rev_induct") *}-- "compatibility"
   499 
   500 lemma rev_exhaust [case_names Nil snoc]:
   501   "(xs = [] ==> P) ==>(!!ys y. xs = ys @ [y] ==> P) ==> P"
   502 by (induct xs rule: rev_induct) auto
   503 
   504 lemmas rev_cases = rev_exhaust
   505 
   506 
   507 subsection {* @{text set} *}
   508 
   509 lemma finite_set [iff]: "finite (set xs)"
   510 by (induct xs) auto
   511 
   512 lemma set_append [simp]: "set (xs @ ys) = (set xs \<union> set ys)"
   513 by (induct xs) auto
   514 
   515 lemma set_subset_Cons: "set xs \<subseteq> set (x # xs)"
   516 by auto
   517 
   518 lemma set_empty [iff]: "(set xs = {}) = (xs = [])"
   519 by (induct xs) auto
   520 
   521 lemma set_rev [simp]: "set (rev xs) = set xs"
   522 by (induct xs) auto
   523 
   524 lemma set_map [simp]: "set (map f xs) = f`(set xs)"
   525 by (induct xs) auto
   526 
   527 lemma set_filter [simp]: "set (filter P xs) = {x. x : set xs \<and> P x}"
   528 by (induct xs) auto
   529 
   530 lemma set_upt [simp]: "set[i..j(] = {k. i \<le> k \<and> k < j}"
   531 apply (induct j)
   532  apply simp_all
   533 apply(erule ssubst)
   534 apply auto
   535 done
   536 
   537 lemma in_set_conv_decomp: "(x : set xs) = (\<exists>ys zs. xs = ys @ x # zs)"
   538 apply (induct xs)
   539  apply simp
   540 apply simp
   541 apply (rule iffI)
   542  apply (blast intro: eq_Nil_appendI Cons_eq_appendI)
   543 apply (erule exE)+
   544 apply (case_tac ys)
   545 apply auto
   546 done
   547 
   548 lemma in_lists_conv_set: "(xs : lists A) = (\<forall>x \<in> set xs. x : A)"
   549 -- {* eliminate @{text lists} in favour of @{text set} *}
   550 by (induct xs) auto
   551 
   552 lemma in_listsD [dest!]: "xs \<in> lists A ==> \<forall>x\<in>set xs. x \<in> A"
   553 by (rule in_lists_conv_set [THEN iffD1])
   554 
   555 lemma in_listsI [intro!]: "\<forall>x\<in>set xs. x \<in> A ==> xs \<in> lists A"
   556 by (rule in_lists_conv_set [THEN iffD2])
   557 
   558 lemma finite_list: "finite A ==> EX l. set l = A"
   559 apply (erule finite_induct, auto)
   560 apply (rule_tac x="x#l" in exI, auto)
   561 done
   562 
   563 
   564 subsection {* @{text mem} *}
   565 
   566 lemma set_mem_eq: "(x mem xs) = (x : set xs)"
   567 by (induct xs) auto
   568 
   569 
   570 subsection {* @{text list_all} *}
   571 
   572 lemma list_all_conv: "list_all P xs = (\<forall>x \<in> set xs. P x)"
   573 by (induct xs) auto
   574 
   575 lemma list_all_append [simp]:
   576 "list_all P (xs @ ys) = (list_all P xs \<and> list_all P ys)"
   577 by (induct xs) auto
   578 
   579 
   580 subsection {* @{text filter} *}
   581 
   582 lemma filter_append [simp]: "filter P (xs @ ys) = filter P xs @ filter P ys"
   583 by (induct xs) auto
   584 
   585 lemma filter_filter [simp]: "filter P (filter Q xs) = filter (\<lambda>x. Q x \<and> P x) xs"
   586 by (induct xs) auto
   587 
   588 lemma filter_True [simp]: "\<forall>x \<in> set xs. P x ==> filter P xs = xs"
   589 by (induct xs) auto
   590 
   591 lemma filter_False [simp]: "\<forall>x \<in> set xs. \<not> P x ==> filter P xs = []"
   592 by (induct xs) auto
   593 
   594 lemma length_filter [simp]: "length (filter P xs) \<le> length xs"
   595 by (induct xs) (auto simp add: le_SucI)
   596 
   597 lemma filter_is_subset [simp]: "set (filter P xs) \<le> set xs"
   598 by auto
   599 
   600 
   601 subsection {* @{text concat} *}
   602 
   603 lemma concat_append [simp]: "concat (xs @ ys) = concat xs @ concat ys"
   604 by (induct xs) auto
   605 
   606 lemma concat_eq_Nil_conv [iff]: "(concat xss = []) = (\<forall>xs \<in> set xss. xs = [])"
   607 by (induct xss) auto
   608 
   609 lemma Nil_eq_concat_conv [iff]: "([] = concat xss) = (\<forall>xs \<in> set xss. xs = [])"
   610 by (induct xss) auto
   611 
   612 lemma set_concat [simp]: "set (concat xs) = \<Union>(set ` set xs)"
   613 by (induct xs) auto
   614 
   615 lemma map_concat: "map f (concat xs) = concat (map (map f) xs)"
   616 by (induct xs) auto
   617 
   618 lemma filter_concat: "filter p (concat xs) = concat (map (filter p) xs)"
   619 by (induct xs) auto
   620 
   621 lemma rev_concat: "rev (concat xs) = concat (map rev (rev xs))"
   622 by (induct xs) auto
   623 
   624 
   625 subsection {* @{text nth} *}
   626 
   627 lemma nth_Cons_0 [simp]: "(x # xs)!0 = x"
   628 by auto
   629 
   630 lemma nth_Cons_Suc [simp]: "(x # xs)!(Suc n) = xs!n"
   631 by auto
   632 
   633 declare nth.simps [simp del]
   634 
   635 lemma nth_append:
   636 "!!n. (xs @ ys)!n = (if n < length xs then xs!n else ys!(n - length xs))"
   637 apply(induct "xs")
   638  apply simp
   639 apply (case_tac n)
   640  apply auto
   641 done
   642 
   643 lemma nth_map [simp]: "!!n. n < length xs ==> (map f xs)!n = f(xs!n)"
   644 apply(induct xs)
   645  apply simp
   646 apply (case_tac n)
   647  apply auto
   648 done
   649 
   650 lemma set_conv_nth: "set xs = {xs!i | i. i < length xs}"
   651 apply (induct_tac xs)
   652  apply simp
   653 apply simp
   654 apply safe
   655 apply (rule_tac x = 0 in exI)
   656 apply simp
   657  apply (rule_tac x = "Suc i" in exI)
   658  apply simp
   659 apply (case_tac i)
   660  apply simp
   661 apply (rename_tac j)
   662 apply (rule_tac x = j in exI)
   663 apply simp
   664 done
   665 
   666 lemma list_ball_nth: "[| n < length xs; !x : set xs. P x|] ==> P(xs!n)"
   667 by (auto simp add: set_conv_nth)
   668 
   669 lemma nth_mem [simp]: "n < length xs ==> xs!n : set xs"
   670 by (auto simp add: set_conv_nth)
   671 
   672 lemma all_nth_imp_all_set:
   673 "[| !i < length xs. P(xs!i); x : set xs|] ==> P x"
   674 by (auto simp add: set_conv_nth)
   675 
   676 lemma all_set_conv_all_nth:
   677 "(\<forall>x \<in> set xs. P x) = (\<forall>i. i < length xs --> P (xs ! i))"
   678 by (auto simp add: set_conv_nth)
   679 
   680 
   681 subsection {* @{text list_update} *}
   682 
   683 lemma length_list_update [simp]: "!!i. length(xs[i:=x]) = length xs"
   684 by (induct xs) (auto split: nat.split)
   685 
   686 lemma nth_list_update:
   687 "!!i j. i < length xs==> (xs[i:=x])!j = (if i = j then x else xs!j)"
   688 by (induct xs) (auto simp add: nth_Cons split: nat.split)
   689 
   690 lemma nth_list_update_eq [simp]: "i < length xs ==> (xs[i:=x])!i = x"
   691 by (simp add: nth_list_update)
   692 
   693 lemma nth_list_update_neq [simp]: "!!i j. i \<noteq> j ==> xs[i:=x]!j = xs!j"
   694 by (induct xs) (auto simp add: nth_Cons split: nat.split)
   695 
   696 lemma list_update_overwrite [simp]:
   697 "!!i. i < size xs ==> xs[i:=x, i:=y] = xs[i:=y]"
   698 by (induct xs) (auto split: nat.split)
   699 
   700 lemma list_update_same_conv:
   701 "!!i. i < length xs ==> (xs[i := x] = xs) = (xs!i = x)"
   702 by (induct xs) (auto split: nat.split)
   703 
   704 lemma update_zip:
   705 "!!i xy xs. length xs = length ys ==>
   706 (zip xs ys)[i:=xy] = zip (xs[i:=fst xy]) (ys[i:=snd xy])"
   707 by (induct ys) (auto, case_tac xs, auto split: nat.split)
   708 
   709 lemma set_update_subset_insert: "!!i. set(xs[i:=x]) <= insert x (set xs)"
   710 by (induct xs) (auto split: nat.split)
   711 
   712 lemma set_update_subsetI: "[| set xs <= A; x:A |] ==> set(xs[i := x]) <= A"
   713 by (blast dest!: set_update_subset_insert [THEN subsetD])
   714 
   715 
   716 subsection {* @{text last} and @{text butlast} *}
   717 
   718 lemma last_snoc [simp]: "last (xs @ [x]) = x"
   719 by (induct xs) auto
   720 
   721 lemma butlast_snoc [simp]: "butlast (xs @ [x]) = xs"
   722 by (induct xs) auto
   723 
   724 lemma length_butlast [simp]: "length (butlast xs) = length xs - 1"
   725 by (induct xs rule: rev_induct) auto
   726 
   727 lemma butlast_append:
   728 "!!ys. butlast (xs @ ys) = (if ys = [] then butlast xs else xs @ butlast ys)"
   729 by (induct xs) auto
   730 
   731 lemma append_butlast_last_id [simp]:
   732 "xs \<noteq> [] ==> butlast xs @ [last xs] = xs"
   733 by (induct xs) auto
   734 
   735 lemma in_set_butlastD: "x : set (butlast xs) ==> x : set xs"
   736 by (induct xs) (auto split: split_if_asm)
   737 
   738 lemma in_set_butlast_appendI:
   739 "x : set (butlast xs) | x : set (butlast ys) ==> x : set (butlast (xs @ ys))"
   740 by (auto dest: in_set_butlastD simp add: butlast_append)
   741 
   742 
   743 subsection {* @{text take} and @{text drop} *}
   744 
   745 lemma take_0 [simp]: "take 0 xs = []"
   746 by (induct xs) auto
   747 
   748 lemma drop_0 [simp]: "drop 0 xs = xs"
   749 by (induct xs) auto
   750 
   751 lemma take_Suc_Cons [simp]: "take (Suc n) (x # xs) = x # take n xs"
   752 by simp
   753 
   754 lemma drop_Suc_Cons [simp]: "drop (Suc n) (x # xs) = drop n xs"
   755 by simp
   756 
   757 declare take_Cons [simp del] and drop_Cons [simp del]
   758 
   759 lemma length_take [simp]: "!!xs. length (take n xs) = min (length xs) n"
   760 by (induct n) (auto, case_tac xs, auto)
   761 
   762 lemma length_drop [simp]: "!!xs. length (drop n xs) = (length xs - n)"
   763 by (induct n) (auto, case_tac xs, auto)
   764 
   765 lemma take_all [simp]: "!!xs. length xs <= n ==> take n xs = xs"
   766 by (induct n) (auto, case_tac xs, auto)
   767 
   768 lemma drop_all [simp]: "!!xs. length xs <= n ==> drop n xs = []"
   769 by (induct n) (auto, case_tac xs, auto)
   770 
   771 lemma take_append [simp]:
   772 "!!xs. take n (xs @ ys) = (take n xs @ take (n - length xs) ys)"
   773 by (induct n) (auto, case_tac xs, auto)
   774 
   775 lemma drop_append [simp]:
   776 "!!xs. drop n (xs @ ys) = drop n xs @ drop (n - length xs) ys"
   777 by (induct n) (auto, case_tac xs, auto)
   778 
   779 lemma take_take [simp]: "!!xs n. take n (take m xs) = take (min n m) xs"
   780 apply (induct m)
   781  apply auto
   782 apply (case_tac xs)
   783  apply auto
   784 apply (case_tac na)
   785  apply auto
   786 done
   787 
   788 lemma drop_drop [simp]: "!!xs. drop n (drop m xs) = drop (n + m) xs"
   789 apply (induct m)
   790  apply auto
   791 apply (case_tac xs)
   792  apply auto
   793 done
   794 
   795 lemma take_drop: "!!xs n. take n (drop m xs) = drop m (take (n + m) xs)"
   796 apply (induct m)
   797  apply auto
   798 apply (case_tac xs)
   799  apply auto
   800 done
   801 
   802 lemma append_take_drop_id [simp]: "!!xs. take n xs @ drop n xs = xs"
   803 apply (induct n)
   804  apply auto
   805 apply (case_tac xs)
   806  apply auto
   807 done
   808 
   809 lemma take_map: "!!xs. take n (map f xs) = map f (take n xs)"
   810 apply (induct n)
   811  apply auto
   812 apply (case_tac xs)
   813  apply auto
   814 done
   815 
   816 lemma drop_map: "!!xs. drop n (map f xs) = map f (drop n xs)"
   817 apply (induct n)
   818  apply auto
   819 apply (case_tac xs)
   820  apply auto
   821 done
   822 
   823 lemma rev_take: "!!i. rev (take i xs) = drop (length xs - i) (rev xs)"
   824 apply (induct xs)
   825  apply auto
   826 apply (case_tac i)
   827  apply auto
   828 done
   829 
   830 lemma rev_drop: "!!i. rev (drop i xs) = take (length xs - i) (rev xs)"
   831 apply (induct xs)
   832  apply auto
   833 apply (case_tac i)
   834  apply auto
   835 done
   836 
   837 lemma nth_take [simp]: "!!n i. i < n ==> (take n xs)!i = xs!i"
   838 apply (induct xs)
   839  apply auto
   840 apply (case_tac n)
   841  apply(blast )
   842 apply (case_tac i)
   843  apply auto
   844 done
   845 
   846 lemma nth_drop [simp]:
   847 "!!xs i. n + i <= length xs ==> (drop n xs)!i = xs!(n + i)"
   848 apply (induct n)
   849  apply auto
   850 apply (case_tac xs)
   851  apply auto
   852 done
   853 
   854 lemma append_eq_conv_conj:
   855 "!!zs. (xs @ ys = zs) = (xs = take (length xs) zs \<and> ys = drop (length xs) zs)"
   856 apply(induct xs)
   857  apply simp
   858 apply clarsimp
   859 apply (case_tac zs)
   860 apply auto
   861 done
   862 
   863 
   864 subsection {* @{text takeWhile} and @{text dropWhile} *}
   865 
   866 lemma takeWhile_dropWhile_id [simp]: "takeWhile P xs @ dropWhile P xs = xs"
   867 by (induct xs) auto
   868 
   869 lemma takeWhile_append1 [simp]:
   870 "[| x:set xs; ~P(x)|] ==> takeWhile P (xs @ ys) = takeWhile P xs"
   871 by (induct xs) auto
   872 
   873 lemma takeWhile_append2 [simp]:
   874 "(!!x. x : set xs ==> P x) ==> takeWhile P (xs @ ys) = xs @ takeWhile P ys"
   875 by (induct xs) auto
   876 
   877 lemma takeWhile_tail: "\<not> P x ==> takeWhile P (xs @ (x#l)) = takeWhile P xs"
   878 by (induct xs) auto
   879 
   880 lemma dropWhile_append1 [simp]:
   881 "[| x : set xs; ~P(x)|] ==> dropWhile P (xs @ ys) = (dropWhile P xs)@ys"
   882 by (induct xs) auto
   883 
   884 lemma dropWhile_append2 [simp]:
   885 "(!!x. x:set xs ==> P(x)) ==> dropWhile P (xs @ ys) = dropWhile P ys"
   886 by (induct xs) auto
   887 
   888 lemma set_take_whileD: "x : set (takeWhile P xs) ==> x : set xs \<and> P x"
   889 by (induct xs) (auto split: split_if_asm)
   890 
   891 
   892 subsection {* @{text zip} *}
   893 
   894 lemma zip_Nil [simp]: "zip [] ys = []"
   895 by (induct ys) auto
   896 
   897 lemma zip_Cons_Cons [simp]: "zip (x # xs) (y # ys) = (x, y) # zip xs ys"
   898 by simp
   899 
   900 declare zip_Cons [simp del]
   901 
   902 lemma length_zip [simp]:
   903 "!!xs. length (zip xs ys) = min (length xs) (length ys)"
   904 apply(induct ys)
   905  apply simp
   906 apply (case_tac xs)
   907  apply auto
   908 done
   909 
   910 lemma zip_append1:
   911 "!!xs. zip (xs @ ys) zs =
   912 zip xs (take (length xs) zs) @ zip ys (drop (length xs) zs)"
   913 apply (induct zs)
   914  apply simp
   915 apply (case_tac xs)
   916  apply simp_all
   917 done
   918 
   919 lemma zip_append2:
   920 "!!ys. zip xs (ys @ zs) =
   921 zip (take (length ys) xs) ys @ zip (drop (length ys) xs) zs"
   922 apply (induct xs)
   923  apply simp
   924 apply (case_tac ys)
   925  apply simp_all
   926 done
   927 
   928 lemma zip_append [simp]:
   929  "[| length xs = length us; length ys = length vs |] ==>
   930 zip (xs@ys) (us@vs) = zip xs us @ zip ys vs"
   931 by (simp add: zip_append1)
   932 
   933 lemma zip_rev:
   934 "!!xs. length xs = length ys ==> zip (rev xs) (rev ys) = rev (zip xs ys)"
   935 apply(induct ys)
   936  apply simp
   937 apply (case_tac xs)
   938  apply simp_all
   939 done
   940 
   941 lemma nth_zip [simp]:
   942 "!!i xs. [| i < length xs; i < length ys|] ==> (zip xs ys)!i = (xs!i, ys!i)"
   943 apply (induct ys)
   944  apply simp
   945 apply (case_tac xs)
   946  apply (simp_all add: nth.simps split: nat.split)
   947 done
   948 
   949 lemma set_zip:
   950 "set (zip xs ys) = {(xs!i, ys!i) | i. i < min (length xs) (length ys)}"
   951 by (simp add: set_conv_nth cong: rev_conj_cong)
   952 
   953 lemma zip_update:
   954 "length xs = length ys ==> zip (xs[i:=x]) (ys[i:=y]) = (zip xs ys)[i:=(x,y)]"
   955 by (rule sym, simp add: update_zip)
   956 
   957 lemma zip_replicate [simp]:
   958 "!!j. zip (replicate i x) (replicate j y) = replicate (min i j) (x,y)"
   959 apply (induct i)
   960  apply auto
   961 apply (case_tac j)
   962  apply auto
   963 done
   964 
   965 
   966 subsection {* @{text list_all2} *}
   967 
   968 lemma list_all2_lengthD: "list_all2 P xs ys ==> length xs = length ys"
   969 by (simp add: list_all2_def)
   970 
   971 lemma list_all2_Nil [iff]: "list_all2 P [] ys = (ys = [])"
   972 by (simp add: list_all2_def)
   973 
   974 lemma list_all2_Nil2[iff]: "list_all2 P xs [] = (xs = [])"
   975 by (simp add: list_all2_def)
   976 
   977 lemma list_all2_Cons [iff]:
   978 "list_all2 P (x # xs) (y # ys) = (P x y \<and> list_all2 P xs ys)"
   979 by (auto simp add: list_all2_def)
   980 
   981 lemma list_all2_Cons1:
   982 "list_all2 P (x # xs) ys = (\<exists>z zs. ys = z # zs \<and> P x z \<and> list_all2 P xs zs)"
   983 by (cases ys) auto
   984 
   985 lemma list_all2_Cons2:
   986 "list_all2 P xs (y # ys) = (\<exists>z zs. xs = z # zs \<and> P z y \<and> list_all2 P zs ys)"
   987 by (cases xs) auto
   988 
   989 lemma list_all2_rev [iff]:
   990 "list_all2 P (rev xs) (rev ys) = list_all2 P xs ys"
   991 by (simp add: list_all2_def zip_rev cong: conj_cong)
   992 
   993 lemma list_all2_append1:
   994 "list_all2 P (xs @ ys) zs =
   995 (EX us vs. zs = us @ vs \<and> length us = length xs \<and> length vs = length ys \<and>
   996 list_all2 P xs us \<and> list_all2 P ys vs)"
   997 apply (simp add: list_all2_def zip_append1)
   998 apply (rule iffI)
   999  apply (rule_tac x = "take (length xs) zs" in exI)
  1000  apply (rule_tac x = "drop (length xs) zs" in exI)
  1001  apply (force split: nat_diff_split simp add: min_def)
  1002 apply clarify
  1003 apply (simp add: ball_Un)
  1004 done
  1005 
  1006 lemma list_all2_append2:
  1007 "list_all2 P xs (ys @ zs) =
  1008 (EX us vs. xs = us @ vs \<and> length us = length ys \<and> length vs = length zs \<and>
  1009 list_all2 P us ys \<and> list_all2 P vs zs)"
  1010 apply (simp add: list_all2_def zip_append2)
  1011 apply (rule iffI)
  1012  apply (rule_tac x = "take (length ys) xs" in exI)
  1013  apply (rule_tac x = "drop (length ys) xs" in exI)
  1014  apply (force split: nat_diff_split simp add: min_def)
  1015 apply clarify
  1016 apply (simp add: ball_Un)
  1017 done
  1018 
  1019 lemma list_all2_conv_all_nth:
  1020 "list_all2 P xs ys =
  1021 (length xs = length ys \<and> (\<forall>i < length xs. P (xs!i) (ys!i)))"
  1022 by (force simp add: list_all2_def set_zip)
  1023 
  1024 lemma list_all2_trans[rule_format]:
  1025 "\<forall>a b c. P1 a b --> P2 b c --> P3 a c ==>
  1026 \<forall>bs cs. list_all2 P1 as bs --> list_all2 P2 bs cs --> list_all2 P3 as cs"
  1027 apply(induct_tac as)
  1028  apply simp
  1029 apply(rule allI)
  1030 apply(induct_tac bs)
  1031  apply simp
  1032 apply(rule allI)
  1033 apply(induct_tac cs)
  1034  apply auto
  1035 done
  1036 
  1037 
  1038 subsection {* @{text foldl} *}
  1039 
  1040 lemma foldl_append [simp]:
  1041 "!!a. foldl f a (xs @ ys) = foldl f (foldl f a xs) ys"
  1042 by (induct xs) auto
  1043 
  1044 text {*
  1045 Note: @{text "n \<le> foldl (op +) n ns"} looks simpler, but is more
  1046 difficult to use because it requires an additional transitivity step.
  1047 *}
  1048 
  1049 lemma start_le_sum: "!!n::nat. m <= n ==> m <= foldl (op +) n ns"
  1050 by (induct ns) auto
  1051 
  1052 lemma elem_le_sum: "!!n::nat. n : set ns ==> n <= foldl (op +) 0 ns"
  1053 by (force intro: start_le_sum simp add: in_set_conv_decomp)
  1054 
  1055 lemma sum_eq_0_conv [iff]:
  1056 "!!m::nat. (foldl (op +) m ns = 0) = (m = 0 \<and> (\<forall>n \<in> set ns. n = 0))"
  1057 by (induct ns) auto
  1058 
  1059 
  1060 subsection {* @{text upto} *}
  1061 
  1062 lemma upt_rec: "[i..j(] = (if i<j then i#[Suc i..j(] else [])"
  1063 -- {* Does not terminate! *}
  1064 by (induct j) auto
  1065 
  1066 lemma upt_conv_Nil [simp]: "j <= i ==> [i..j(] = []"
  1067 by (subst upt_rec) simp
  1068 
  1069 lemma upt_Suc_append: "i <= j ==> [i..(Suc j)(] = [i..j(]@[j]"
  1070 -- {* Only needed if @{text upt_Suc} is deleted from the simpset. *}
  1071 by simp
  1072 
  1073 lemma upt_conv_Cons: "i < j ==> [i..j(] = i # [Suc i..j(]"
  1074 apply(rule trans)
  1075 apply(subst upt_rec)
  1076  prefer 2 apply(rule refl)
  1077 apply simp
  1078 done
  1079 
  1080 lemma upt_add_eq_append: "i<=j ==> [i..j+k(] = [i..j(]@[j..j+k(]"
  1081 -- {* LOOPS as a simprule, since @{text "j <= j"}. *}
  1082 by (induct k) auto
  1083 
  1084 lemma length_upt [simp]: "length [i..j(] = j - i"
  1085 by (induct j) (auto simp add: Suc_diff_le)
  1086 
  1087 lemma nth_upt [simp]: "i + k < j ==> [i..j(] ! k = i + k"
  1088 apply (induct j)
  1089 apply (auto simp add: less_Suc_eq nth_append split: nat_diff_split)
  1090 done
  1091 
  1092 lemma take_upt [simp]: "!!i. i+m <= n ==> take m [i..n(] = [i..i+m(]"
  1093 apply (induct m)
  1094  apply simp
  1095 apply (subst upt_rec)
  1096 apply (rule sym)
  1097 apply (subst upt_rec)
  1098 apply (simp del: upt.simps)
  1099 done
  1100 
  1101 lemma map_Suc_upt: "map Suc [m..n(] = [Suc m..n]"
  1102 by (induct n) auto
  1103 
  1104 lemma nth_map_upt: "!!i. i < n-m ==> (map f [m..n(]) ! i = f(m+i)"
  1105 apply (induct n m rule: diff_induct)
  1106 prefer 3 apply (subst map_Suc_upt[symmetric])
  1107 apply (auto simp add: less_diff_conv nth_upt)
  1108 done
  1109 
  1110 lemma nth_take_lemma [rule_format]:
  1111 "ALL xs ys. k <= length xs --> k <= length ys
  1112 --> (ALL i. i < k --> xs!i = ys!i)
  1113 --> take k xs = take k ys"
  1114 apply (induct k)
  1115 apply (simp_all add: less_Suc_eq_0_disj all_conj_distrib)
  1116 apply clarify
  1117 txt {* Both lists must be non-empty *}
  1118 apply (case_tac xs)
  1119  apply simp
  1120 apply (case_tac ys)
  1121  apply clarify
  1122  apply (simp (no_asm_use))
  1123 apply clarify
  1124 txt {* prenexing's needed, not miniscoping *}
  1125 apply (simp (no_asm_use) add: all_simps [symmetric] del: all_simps)
  1126 apply blast
  1127 done
  1128 
  1129 lemma nth_equalityI:
  1130  "[| length xs = length ys; ALL i < length xs. xs!i = ys!i |] ==> xs = ys"
  1131 apply (frule nth_take_lemma [OF le_refl eq_imp_le])
  1132 apply (simp_all add: take_all)
  1133 done
  1134 
  1135 lemma take_equalityI: "(\<forall>i. take i xs = take i ys) ==> xs = ys"
  1136 -- {* The famous take-lemma. *}
  1137 apply (drule_tac x = "max (length xs) (length ys)" in spec)
  1138 apply (simp add: le_max_iff_disj take_all)
  1139 done
  1140 
  1141 
  1142 subsection {* @{text "distinct"} and @{text remdups} *}
  1143 
  1144 lemma distinct_append [simp]:
  1145 "distinct (xs @ ys) = (distinct xs \<and> distinct ys \<and> set xs \<inter> set ys = {})"
  1146 by (induct xs) auto
  1147 
  1148 lemma set_remdups [simp]: "set (remdups xs) = set xs"
  1149 by (induct xs) (auto simp add: insert_absorb)
  1150 
  1151 lemma distinct_remdups [iff]: "distinct (remdups xs)"
  1152 by (induct xs) auto
  1153 
  1154 lemma distinct_filter [simp]: "distinct xs ==> distinct (filter P xs)"
  1155 by (induct xs) auto
  1156 
  1157 text {*
  1158 It is best to avoid this indexed version of distinct, but sometimes
  1159 it is useful. *}
  1160 lemma distinct_conv_nth:
  1161 "distinct xs = (\<forall>i j. i < size xs \<and> j < size xs \<and> i \<noteq> j --> xs!i \<noteq> xs!j)"
  1162 apply (induct_tac xs)
  1163  apply simp
  1164 apply simp
  1165 apply (rule iffI)
  1166  apply clarsimp
  1167  apply (case_tac i)
  1168 apply (case_tac j)
  1169  apply simp
  1170 apply (simp add: set_conv_nth)
  1171  apply (case_tac j)
  1172 apply (clarsimp simp add: set_conv_nth)
  1173  apply simp
  1174 apply (rule conjI)
  1175  apply (clarsimp simp add: set_conv_nth)
  1176  apply (erule_tac x = 0 in allE)
  1177  apply (erule_tac x = "Suc i" in allE)
  1178  apply simp
  1179 apply clarsimp
  1180 apply (erule_tac x = "Suc i" in allE)
  1181 apply (erule_tac x = "Suc j" in allE)
  1182 apply simp
  1183 done
  1184 
  1185 
  1186 subsection {* @{text replicate} *}
  1187 
  1188 lemma length_replicate [simp]: "length (replicate n x) = n"
  1189 by (induct n) auto
  1190 
  1191 lemma map_replicate [simp]: "map f (replicate n x) = replicate n (f x)"
  1192 by (induct n) auto
  1193 
  1194 lemma replicate_app_Cons_same:
  1195 "(replicate n x) @ (x # xs) = x # replicate n x @ xs"
  1196 by (induct n) auto
  1197 
  1198 lemma rev_replicate [simp]: "rev (replicate n x) = replicate n x"
  1199 apply(induct n)
  1200  apply simp
  1201 apply (simp add: replicate_app_Cons_same)
  1202 done
  1203 
  1204 lemma replicate_add: "replicate (n + m) x = replicate n x @ replicate m x"
  1205 by (induct n) auto
  1206 
  1207 lemma hd_replicate [simp]: "n \<noteq> 0 ==> hd (replicate n x) = x"
  1208 by (induct n) auto
  1209 
  1210 lemma tl_replicate [simp]: "n \<noteq> 0 ==> tl (replicate n x) = replicate (n - 1) x"
  1211 by (induct n) auto
  1212 
  1213 lemma last_replicate [simp]: "n \<noteq> 0 ==> last (replicate n x) = x"
  1214 by (atomize (full), induct n) auto
  1215 
  1216 lemma nth_replicate[simp]: "!!i. i < n ==> (replicate n x)!i = x"
  1217 apply(induct n)
  1218  apply simp
  1219 apply (simp add: nth_Cons split: nat.split)
  1220 done
  1221 
  1222 lemma set_replicate_Suc: "set (replicate (Suc n) x) = {x}"
  1223 by (induct n) auto
  1224 
  1225 lemma set_replicate [simp]: "n \<noteq> 0 ==> set (replicate n x) = {x}"
  1226 by (fast dest!: not0_implies_Suc intro!: set_replicate_Suc)
  1227 
  1228 lemma set_replicate_conv_if: "set (replicate n x) = (if n = 0 then {} else {x})"
  1229 by auto
  1230 
  1231 lemma in_set_replicateD: "x : set (replicate n y) ==> x = y"
  1232 by (simp add: set_replicate_conv_if split: split_if_asm)
  1233 
  1234 
  1235 subsection {* Lexcicographic orderings on lists *}
  1236 
  1237 lemma wf_lexn: "wf r ==> wf (lexn r n)"
  1238 apply (induct_tac n)
  1239  apply simp
  1240 apply simp
  1241 apply(rule wf_subset)
  1242  prefer 2 apply (rule Int_lower1)
  1243 apply(rule wf_prod_fun_image)
  1244  prefer 2 apply (rule injI)
  1245 apply auto
  1246 done
  1247 
  1248 lemma lexn_length:
  1249 "!!xs ys. (xs, ys) : lexn r n ==> length xs = n \<and> length ys = n"
  1250 by (induct n) auto
  1251 
  1252 lemma wf_lex [intro!]: "wf r ==> wf (lex r)"
  1253 apply (unfold lex_def)
  1254 apply (rule wf_UN)
  1255 apply (blast intro: wf_lexn)
  1256 apply clarify
  1257 apply (rename_tac m n)
  1258 apply (subgoal_tac "m \<noteq> n")
  1259  prefer 2 apply blast
  1260 apply (blast dest: lexn_length not_sym)
  1261 done
  1262 
  1263 lemma lexn_conv:
  1264 "lexn r n =
  1265 {(xs,ys). length xs = n \<and> length ys = n \<and>
  1266 (\<exists>xys x y xs' ys'. xs= xys @ x#xs' \<and> ys= xys @ y # ys' \<and> (x, y):r)}"
  1267 apply (induct_tac n)
  1268  apply simp
  1269  apply blast
  1270 apply (simp add: image_Collect lex_prod_def)
  1271 apply auto
  1272 apply blast
  1273  apply (rename_tac a xys x xs' y ys')
  1274  apply (rule_tac x = "a # xys" in exI)
  1275  apply simp
  1276 apply (case_tac xys)
  1277  apply simp_all
  1278 apply blast
  1279 done
  1280 
  1281 lemma lex_conv:
  1282 "lex r =
  1283 {(xs,ys). length xs = length ys \<and>
  1284 (\<exists>xys x y xs' ys'. xs = xys @ x # xs' \<and> ys = xys @ y # ys' \<and> (x, y):r)}"
  1285 by (force simp add: lex_def lexn_conv)
  1286 
  1287 lemma wf_lexico [intro!]: "wf r ==> wf (lexico r)"
  1288 by (unfold lexico_def) blast
  1289 
  1290 lemma lexico_conv:
  1291 "lexico r = {(xs,ys). length xs < length ys |
  1292 length xs = length ys \<and> (xs, ys) : lex r}"
  1293 by (simp add: lexico_def diag_def lex_prod_def measure_def inv_image_def)
  1294 
  1295 lemma Nil_notin_lex [iff]: "([], ys) \<notin> lex r"
  1296 by (simp add: lex_conv)
  1297 
  1298 lemma Nil2_notin_lex [iff]: "(xs, []) \<notin> lex r"
  1299 by (simp add:lex_conv)
  1300 
  1301 lemma Cons_in_lex [iff]:
  1302 "((x # xs, y # ys) : lex r) =
  1303 ((x, y) : r \<and> length xs = length ys | x = y \<and> (xs, ys) : lex r)"
  1304 apply (simp add: lex_conv)
  1305 apply (rule iffI)
  1306  prefer 2 apply (blast intro: Cons_eq_appendI)
  1307 apply clarify
  1308 apply (case_tac xys)
  1309  apply simp
  1310 apply simp
  1311 apply blast
  1312 done
  1313 
  1314 
  1315 subsection {* @{text sublist} --- a generalization of @{text nth} to sets *}
  1316 
  1317 lemma sublist_empty [simp]: "sublist xs {} = []"
  1318 by (auto simp add: sublist_def)
  1319 
  1320 lemma sublist_nil [simp]: "sublist [] A = []"
  1321 by (auto simp add: sublist_def)
  1322 
  1323 lemma sublist_shift_lemma:
  1324 "map fst [p:zip xs [i..i + length xs(] . snd p : A] =
  1325 map fst [p:zip xs [0..length xs(] . snd p + i : A]"
  1326 by (induct xs rule: rev_induct) (simp_all add: add_commute)
  1327 
  1328 lemma sublist_append:
  1329 "sublist (l @ l') A = sublist l A @ sublist l' {j. j + length l : A}"
  1330 apply (unfold sublist_def)
  1331 apply (induct l' rule: rev_induct)
  1332  apply simp
  1333 apply (simp add: upt_add_eq_append[of 0] zip_append sublist_shift_lemma)
  1334 apply (simp add: add_commute)
  1335 done
  1336 
  1337 lemma sublist_Cons:
  1338 "sublist (x # l) A = (if 0:A then [x] else []) @ sublist l {j. Suc j : A}"
  1339 apply (induct l rule: rev_induct)
  1340  apply (simp add: sublist_def)
  1341 apply (simp del: append_Cons add: append_Cons[symmetric] sublist_append)
  1342 done
  1343 
  1344 lemma sublist_singleton [simp]: "sublist [x] A = (if 0 : A then [x] else [])"
  1345 by (simp add: sublist_Cons)
  1346 
  1347 lemma sublist_upt_eq_take [simp]: "sublist l {..n(} = take n l"
  1348 apply (induct l rule: rev_induct)
  1349  apply simp
  1350 apply (simp split: nat_diff_split add: sublist_append)
  1351 done
  1352 
  1353 
  1354 lemma take_Cons':
  1355 "take n (x # xs) = (if n = 0 then [] else x # take (n - 1) xs)"
  1356 by (cases n) simp_all
  1357 
  1358 lemma drop_Cons':
  1359 "drop n (x # xs) = (if n = 0 then x # xs else drop (n - 1) xs)"
  1360 by (cases n) simp_all
  1361 
  1362 lemma nth_Cons': "(x # xs)!n = (if n = 0 then x else xs!(n - 1))"
  1363 by (cases n) simp_all
  1364 
  1365 lemmas [simp] = take_Cons'[of "number_of v",standard]
  1366                 drop_Cons'[of "number_of v",standard]
  1367                 nth_Cons'[of _ _ "number_of v",standard]
  1368 
  1369 
  1370 subsection {* Characters and strings *}
  1371 
  1372 datatype nibble =
  1373     Nibble0 | Nibble1 | Nibble2 | Nibble3 | Nibble4 | Nibble5 | Nibble6 | Nibble7
  1374   | Nibble8 | Nibble9 | NibbleA | NibbleB | NibbleC | NibbleD | NibbleE | NibbleF
  1375 
  1376 datatype char = Char nibble nibble
  1377   -- "Note: canonical order of character encoding coincides with standard term ordering"
  1378 
  1379 types string = "char list"
  1380 
  1381 syntax
  1382   "_Char" :: "xstr => char"    ("CHR _")
  1383   "_String" :: "xstr => string"    ("_")
  1384 
  1385 parse_ast_translation {*
  1386   let
  1387     val constants = Syntax.Appl o map Syntax.Constant;
  1388 
  1389     fun mk_nib n = "Nibble" ^ chr (n + (if n <= 9 then ord "0" else ord "A" - 10));
  1390     fun mk_char c =
  1391       if Symbol.is_ascii c andalso Symbol.is_printable c then
  1392         constants ["Char", mk_nib (ord c div 16), mk_nib (ord c mod 16)]
  1393       else error ("Printable ASCII character expected: " ^ quote c);
  1394 
  1395     fun mk_string [] = Syntax.Constant "Nil"
  1396       | mk_string (c :: cs) = Syntax.Appl [Syntax.Constant "Cons", mk_char c, mk_string cs];
  1397 
  1398     fun char_ast_tr [Syntax.Variable xstr] =
  1399         (case Syntax.explode_xstr xstr of
  1400           [c] => mk_char c
  1401         | _ => error ("Single character expected: " ^ xstr))
  1402       | char_ast_tr asts = raise AST ("char_ast_tr", asts);
  1403 
  1404     fun string_ast_tr [Syntax.Variable xstr] =
  1405         (case Syntax.explode_xstr xstr of
  1406           [] => constants [Syntax.constrainC, "Nil", "string"]
  1407         | cs => mk_string cs)
  1408       | string_ast_tr asts = raise AST ("string_tr", asts);
  1409   in [("_Char", char_ast_tr), ("_String", string_ast_tr)] end;
  1410 *}
  1411 
  1412 print_ast_translation {*
  1413   let
  1414     fun dest_nib (Syntax.Constant c) =
  1415         (case explode c of
  1416           ["N", "i", "b", "b", "l", "e", h] =>
  1417             if "0" <= h andalso h <= "9" then ord h - ord "0"
  1418             else if "A" <= h andalso h <= "F" then ord h - ord "A" + 10
  1419             else raise Match
  1420         | _ => raise Match)
  1421       | dest_nib _ = raise Match;
  1422 
  1423     fun dest_chr c1 c2 =
  1424       let val c = chr (dest_nib c1 * 16 + dest_nib c2)
  1425       in if Symbol.is_printable c then c else raise Match end;
  1426 
  1427     fun dest_char (Syntax.Appl [Syntax.Constant "Char", c1, c2]) = dest_chr c1 c2
  1428       | dest_char _ = raise Match;
  1429 
  1430     fun xstr cs = Syntax.Appl [Syntax.Constant "_xstr", Syntax.Variable (Syntax.implode_xstr cs)];
  1431 
  1432     fun char_ast_tr' [c1, c2] = Syntax.Appl [Syntax.Constant "_Char", xstr [dest_chr c1 c2]]
  1433       | char_ast_tr' _ = raise Match;
  1434 
  1435     fun list_ast_tr' [args] = Syntax.Appl [Syntax.Constant "_String",
  1436             xstr (map dest_char (Syntax.unfold_ast "_args" args))]
  1437       | list_ast_tr' ts = raise Match;
  1438   in [("Char", char_ast_tr'), ("@list", list_ast_tr')] end;
  1439 *}
  1440 
  1441 end