src/HOL/Tools/Ctr_Sugar/ctr_sugar.ML
author blanchet
Fri Jan 10 14:39:37 2014 +0100 (2014-01-10)
changeset 54970 891141de5672
parent 54900 136fe16e726a
child 55342 1bd9e637ac9f
permissions -rw-r--r--
only destruct cases equipped with the right stuff (in particular, 'sel_split')
     1 (*  Title:      HOL/Tools/Ctr_Sugar/ctr_sugar.ML
     2     Author:     Jasmin Blanchette, TU Muenchen
     3     Copyright   2012, 2013
     4 
     5 Wrapping existing freely generated type's constructors.
     6 *)
     7 
     8 signature CTR_SUGAR =
     9 sig
    10   type ctr_sugar =
    11     {ctrs: term list,
    12      casex: term,
    13      discs: term list,
    14      selss: term list list,
    15      exhaust: thm,
    16      nchotomy: thm,
    17      injects: thm list,
    18      distincts: thm list,
    19      case_thms: thm list,
    20      case_cong: thm,
    21      weak_case_cong: thm,
    22      split: thm,
    23      split_asm: thm,
    24      disc_thmss: thm list list,
    25      discIs: thm list,
    26      sel_thmss: thm list list,
    27      disc_excludesss: thm list list list,
    28      disc_exhausts: thm list,
    29      sel_exhausts: thm list,
    30      collapses: thm list,
    31      expands: thm list,
    32      sel_splits: thm list,
    33      sel_split_asms: thm list,
    34      case_eq_ifs: thm list};
    35 
    36   val morph_ctr_sugar: morphism -> ctr_sugar -> ctr_sugar
    37   val transfer_ctr_sugar: Proof.context -> ctr_sugar -> ctr_sugar
    38   val ctr_sugar_of: Proof.context -> string -> ctr_sugar option
    39   val ctr_sugars_of: Proof.context -> ctr_sugar list
    40   val ctr_sugar_of_case: Proof.context -> string -> ctr_sugar option
    41   val register_ctr_sugar: string -> ctr_sugar -> local_theory -> local_theory
    42   val register_ctr_sugar_global: string -> ctr_sugar -> theory -> theory
    43 
    44   val rep_compat_prefix: string
    45 
    46   val mk_half_pairss: 'a list * 'a list -> ('a * 'a) list list
    47   val join_halves: int -> 'a list list -> 'a list list -> 'a list * 'a list list list
    48 
    49   val mk_ctr: typ list -> term -> term
    50   val mk_case: typ list -> typ -> term -> term
    51   val mk_disc_or_sel: typ list -> term -> term
    52   val name_of_ctr: term -> string
    53   val name_of_disc: term -> string
    54   val dest_ctr: Proof.context -> string -> term -> term * term list
    55   val dest_case: Proof.context -> string -> typ list -> term ->
    56     (ctr_sugar * term list * term list) option
    57 
    58   val wrap_free_constructors: ({prems: thm list, context: Proof.context} -> tactic) list list ->
    59     (((bool * (bool * bool)) * term list) * binding) *
    60       (binding list * (binding list list * (binding * term) list list)) -> local_theory ->
    61     ctr_sugar * local_theory
    62   val parse_wrap_free_constructors_options: (bool * (bool * bool)) parser
    63   val parse_bound_term: (binding * string) parser
    64 end;
    65 
    66 structure Ctr_Sugar : CTR_SUGAR =
    67 struct
    68 
    69 open Ctr_Sugar_Util
    70 open Ctr_Sugar_Tactics
    71 open Ctr_Sugar_Code
    72 
    73 type ctr_sugar =
    74   {ctrs: term list,
    75    casex: term,
    76    discs: term list,
    77    selss: term list list,
    78    exhaust: thm,
    79    nchotomy: thm,
    80    injects: thm list,
    81    distincts: thm list,
    82    case_thms: thm list,
    83    case_cong: thm,
    84    weak_case_cong: thm,
    85    split: thm,
    86    split_asm: thm,
    87    disc_thmss: thm list list,
    88    discIs: thm list,
    89    sel_thmss: thm list list,
    90    disc_excludesss: thm list list list,
    91    disc_exhausts: thm list,
    92    sel_exhausts: thm list,
    93    collapses: thm list,
    94    expands: thm list,
    95    sel_splits: thm list,
    96    sel_split_asms: thm list,
    97    case_eq_ifs: thm list};
    98 
    99 fun eq_ctr_sugar ({ctrs = ctrs1, casex = case1, discs = discs1, selss = selss1, ...} : ctr_sugar,
   100     {ctrs = ctrs2, casex = case2, discs = discs2, selss = selss2, ...} : ctr_sugar) =
   101   ctrs1 = ctrs2 andalso case1 = case2 andalso discs1 = discs2 andalso selss1 = selss2;
   102 
   103 fun morph_ctr_sugar phi {ctrs, casex, discs, selss, exhaust, nchotomy, injects, distincts,
   104     case_thms, case_cong, weak_case_cong, split, split_asm, disc_thmss, discIs, sel_thmss,
   105     disc_excludesss, disc_exhausts, sel_exhausts, collapses, expands, sel_splits, sel_split_asms,
   106     case_eq_ifs} =
   107   {ctrs = map (Morphism.term phi) ctrs,
   108    casex = Morphism.term phi casex,
   109    discs = map (Morphism.term phi) discs,
   110    selss = map (map (Morphism.term phi)) selss,
   111    exhaust = Morphism.thm phi exhaust,
   112    nchotomy = Morphism.thm phi nchotomy,
   113    injects = map (Morphism.thm phi) injects,
   114    distincts = map (Morphism.thm phi) distincts,
   115    case_thms = map (Morphism.thm phi) case_thms,
   116    case_cong = Morphism.thm phi case_cong,
   117    weak_case_cong = Morphism.thm phi weak_case_cong,
   118    split = Morphism.thm phi split,
   119    split_asm = Morphism.thm phi split_asm,
   120    disc_thmss = map (map (Morphism.thm phi)) disc_thmss,
   121    discIs = map (Morphism.thm phi) discIs,
   122    sel_thmss = map (map (Morphism.thm phi)) sel_thmss,
   123    disc_excludesss = map (map (map (Morphism.thm phi))) disc_excludesss,
   124    disc_exhausts = map (Morphism.thm phi) disc_exhausts,
   125    sel_exhausts = map (Morphism.thm phi) sel_exhausts,
   126    collapses = map (Morphism.thm phi) collapses,
   127    expands = map (Morphism.thm phi) expands,
   128    sel_splits = map (Morphism.thm phi) sel_splits,
   129    sel_split_asms = map (Morphism.thm phi) sel_split_asms,
   130    case_eq_ifs = map (Morphism.thm phi) case_eq_ifs};
   131 
   132 val transfer_ctr_sugar =
   133   morph_ctr_sugar o Morphism.transfer_morphism o Proof_Context.theory_of;
   134 
   135 structure Data = Generic_Data
   136 (
   137   type T = ctr_sugar Symtab.table;
   138   val empty = Symtab.empty;
   139   val extend = I;
   140   val merge = Symtab.merge eq_ctr_sugar;
   141 );
   142 
   143 fun ctr_sugar_of ctxt =
   144   Symtab.lookup (Data.get (Context.Proof ctxt))
   145   #> Option.map (transfer_ctr_sugar ctxt);
   146 
   147 fun ctr_sugars_of ctxt =
   148   Symtab.fold (cons o transfer_ctr_sugar ctxt o snd) (Data.get (Context.Proof ctxt)) [];
   149 
   150 fun ctr_sugar_of_case ctxt s =
   151   find_first (fn {casex = Const (s', _), ...} => s' = s | _ => false) (ctr_sugars_of ctxt);
   152 
   153 fun register_ctr_sugar key ctr_sugar =
   154   Local_Theory.declaration {syntax = false, pervasive = true}
   155     (fn phi => Data.map (Symtab.default (key, morph_ctr_sugar phi ctr_sugar)));
   156 
   157 fun register_ctr_sugar_global key ctr_sugar =
   158   Context.theory_map (Data.map (Symtab.default (key, ctr_sugar)));
   159 
   160 val rep_compat_prefix = "new";
   161 
   162 val isN = "is_";
   163 val unN = "un_";
   164 fun mk_unN 1 1 suf = unN ^ suf
   165   | mk_unN _ l suf = unN ^ suf ^ string_of_int l;
   166 
   167 val caseN = "case";
   168 val case_congN = "case_cong";
   169 val case_eq_ifN = "case_eq_if";
   170 val collapseN = "collapse";
   171 val disc_excludeN = "disc_exclude";
   172 val disc_exhaustN = "disc_exhaust";
   173 val discN = "disc";
   174 val discIN = "discI";
   175 val distinctN = "distinct";
   176 val exhaustN = "exhaust";
   177 val expandN = "expand";
   178 val injectN = "inject";
   179 val nchotomyN = "nchotomy";
   180 val selN = "sel";
   181 val sel_exhaustN = "sel_exhaust";
   182 val sel_splitN = "sel_split";
   183 val sel_split_asmN = "sel_split_asm";
   184 val splitN = "split";
   185 val splitsN = "splits";
   186 val split_asmN = "split_asm";
   187 val weak_case_cong_thmsN = "weak_case_cong";
   188 
   189 val cong_attrs = @{attributes [cong]};
   190 val dest_attrs = @{attributes [dest]};
   191 val safe_elim_attrs = @{attributes [elim!]};
   192 val iff_attrs = @{attributes [iff]};
   193 val inductsimp_attrs = @{attributes [induct_simp]};
   194 val nitpicksimp_attrs = @{attributes [nitpick_simp]};
   195 val simp_attrs = @{attributes [simp]};
   196 val code_nitpicksimp_attrs = Code.add_default_eqn_attrib :: nitpicksimp_attrs;
   197 val code_nitpicksimp_simp_attrs = code_nitpicksimp_attrs @ simp_attrs;
   198 
   199 fun unflat_lookup eq xs ys = map (fn xs' => permute_like eq xs xs' ys);
   200 
   201 fun mk_half_pairss' _ ([], []) = []
   202   | mk_half_pairss' indent (x :: xs, _ :: ys) =
   203     indent @ fold_rev (cons o single o pair x) ys (mk_half_pairss' ([] :: indent) (xs, ys));
   204 
   205 fun mk_half_pairss p = mk_half_pairss' [[]] p;
   206 
   207 fun join_halves n half_xss other_half_xss =
   208   let
   209     val xsss =
   210       map2 (map2 append) (Library.chop_groups n half_xss)
   211         (transpose (Library.chop_groups n other_half_xss))
   212     val xs = splice (flat half_xss) (flat other_half_xss);
   213   in (xs, xsss) end;
   214 
   215 fun mk_undefined T = Const (@{const_name undefined}, T);
   216 
   217 fun mk_ctr Ts t =
   218   let val Type (_, Ts0) = body_type (fastype_of t) in
   219     subst_nonatomic_types (Ts0 ~~ Ts) t
   220   end;
   221 
   222 fun mk_case Ts T t =
   223   let val (Type (_, Ts0), body) = strip_type (fastype_of t) |>> List.last in
   224     subst_nonatomic_types ((body, T) :: (Ts0 ~~ Ts)) t
   225   end;
   226 
   227 fun mk_disc_or_sel Ts t =
   228   subst_nonatomic_types (snd (Term.dest_Type (domain_type (fastype_of t))) ~~ Ts) t;
   229 
   230 fun name_of_const what t =
   231   (case head_of t of
   232     Const (s, _) => s
   233   | Free (s, _) => s
   234   | _ => error ("Cannot extract name of " ^ what));
   235 
   236 val name_of_ctr = name_of_const "constructor";
   237 
   238 val notN = "not_";
   239 val eqN = "eq_";
   240 val neqN = "neq_";
   241 
   242 fun name_of_disc t =
   243   (case head_of t of
   244     Abs (_, _, @{const Not} $ (t' $ Bound 0)) =>
   245     Long_Name.map_base_name (prefix notN) (name_of_disc t')
   246   | Abs (_, _, Const (@{const_name HOL.eq}, _) $ Bound 0 $ t') =>
   247     Long_Name.map_base_name (prefix eqN) (name_of_disc t')
   248   | Abs (_, _, @{const Not} $ (Const (@{const_name HOL.eq}, _) $ Bound 0 $ t')) =>
   249     Long_Name.map_base_name (prefix neqN) (name_of_disc t')
   250   | t' => name_of_const "destructor" t');
   251 
   252 val base_name_of_ctr = Long_Name.base_name o name_of_ctr;
   253 
   254 fun dest_ctr ctxt s t =
   255   let
   256     val (f, args) = Term.strip_comb t;
   257   in
   258     (case ctr_sugar_of ctxt s of
   259       SOME {ctrs, ...} =>
   260       (case find_first (can (fo_match ctxt f)) ctrs of
   261         SOME f' => (f', args)
   262       | NONE => raise Fail "dest_ctr")
   263     | NONE => raise Fail "dest_ctr")
   264   end;
   265 
   266 fun dest_case ctxt s Ts t =
   267   (case Term.strip_comb t of
   268     (Const (c, _), args as _ :: _) =>
   269     (case ctr_sugar_of ctxt s of
   270       SOME (ctr_sugar as {casex = Const (case_name, _), discs = discs0, selss = selss0, ...}) =>
   271       if case_name = c then
   272         let val n = length discs0 in
   273           if n < length args then
   274             let
   275               val (branches, obj :: leftovers) = chop n args;
   276               val discs = map (mk_disc_or_sel Ts) discs0;
   277               val selss = map (map (mk_disc_or_sel Ts)) selss0;
   278               val conds = map (rapp obj) discs;
   279               val branch_argss = map (fn sels => map (rapp obj) sels @ leftovers) selss;
   280               val branches' = map2 (curry Term.betapplys) branches branch_argss;
   281             in
   282               SOME (ctr_sugar, conds, branches')
   283             end
   284           else
   285             NONE
   286         end
   287       else
   288         NONE
   289     | _ => NONE)
   290   | _ => NONE);
   291 
   292 fun eta_expand_arg xs f_xs = fold_rev Term.lambda xs f_xs;
   293 
   294 fun prepare_wrap_free_constructors prep_term ((((no_discs_sels, (no_code, rep_compat)), raw_ctrs),
   295     raw_case_binding), (raw_disc_bindings, (raw_sel_bindingss, raw_sel_defaultss))) no_defs_lthy =
   296   let
   297     (* TODO: sanity checks on arguments *)
   298 
   299     val n = length raw_ctrs;
   300     val ks = 1 upto n;
   301 
   302     val _ = if n > 0 then () else error "No constructors specified";
   303 
   304     val ctrs0 = map (prep_term no_defs_lthy) raw_ctrs;
   305     val sel_defaultss =
   306       pad_list [] n (map (map (apsnd (prep_term no_defs_lthy))) raw_sel_defaultss);
   307 
   308     val Type (fcT_name, As0) = body_type (fastype_of (hd ctrs0));
   309     val fc_b_name = Long_Name.base_name fcT_name;
   310     val fc_b = Binding.name fc_b_name;
   311 
   312     fun qualify mandatory =
   313       Binding.qualify mandatory fc_b_name o (rep_compat ? Binding.qualify false rep_compat_prefix);
   314 
   315     fun dest_TFree_or_TVar (TFree sS) = sS
   316       | dest_TFree_or_TVar (TVar ((s, _), S)) = (s, S)
   317       | dest_TFree_or_TVar _ = error "Invalid type argument";
   318 
   319     val (unsorted_As, B) =
   320       no_defs_lthy
   321       |> variant_tfrees (map (fst o dest_TFree_or_TVar) As0)
   322       ||> the_single o fst o mk_TFrees 1;
   323 
   324     val As = map2 (resort_tfree o snd o dest_TFree_or_TVar) As0 unsorted_As;
   325 
   326     val fcT = Type (fcT_name, As);
   327     val ctrs = map (mk_ctr As) ctrs0;
   328     val ctr_Tss = map (binder_types o fastype_of) ctrs;
   329 
   330     val ms = map length ctr_Tss;
   331 
   332     val raw_disc_bindings' = pad_list Binding.empty n raw_disc_bindings;
   333 
   334     fun can_definitely_rely_on_disc k = not (Binding.is_empty (nth raw_disc_bindings' (k - 1)));
   335     fun can_rely_on_disc k =
   336       can_definitely_rely_on_disc k orelse (k = 1 andalso not (can_definitely_rely_on_disc 2));
   337     fun should_omit_disc_binding k = n = 1 orelse (n = 2 andalso can_rely_on_disc (3 - k));
   338 
   339     fun is_disc_binding_valid b =
   340       not (Binding.is_empty b orelse Binding.eq_name (b, equal_binding));
   341 
   342     val standard_disc_binding = Binding.name o prefix isN o base_name_of_ctr;
   343 
   344     val disc_bindings =
   345       raw_disc_bindings'
   346       |> map4 (fn k => fn m => fn ctr => fn disc =>
   347         qualify false
   348           (if Binding.is_empty disc then
   349              if should_omit_disc_binding k then disc else standard_disc_binding ctr
   350            else if Binding.eq_name (disc, equal_binding) then
   351              if m = 0 then disc
   352              else error "Cannot use \"=\" syntax for discriminating nonnullary constructor"
   353            else if Binding.eq_name (disc, standard_binding) then
   354              standard_disc_binding ctr
   355            else
   356              disc)) ks ms ctrs0;
   357 
   358     fun standard_sel_binding m l = Binding.name o mk_unN m l o base_name_of_ctr;
   359 
   360     val sel_bindingss =
   361       pad_list [] n raw_sel_bindingss
   362       |> map3 (fn ctr => fn m => map2 (fn l => fn sel =>
   363         qualify false
   364           (if Binding.is_empty sel orelse Binding.eq_name (sel, standard_binding) then
   365             standard_sel_binding m l ctr
   366           else
   367             sel)) (1 upto m) o pad_list Binding.empty m) ctrs0 ms;
   368 
   369     val case_Ts = map (fn Ts => Ts ---> B) ctr_Tss;
   370 
   371     val ((((((((xss, xss'), yss), fs), gs), [u', v']), [w]), (p, p')), names_lthy) = no_defs_lthy |>
   372       mk_Freess' "x" ctr_Tss
   373       ||>> mk_Freess "y" ctr_Tss
   374       ||>> mk_Frees "f" case_Ts
   375       ||>> mk_Frees "g" case_Ts
   376       ||>> (apfst (map (rpair fcT)) oo Variable.variant_fixes) [fc_b_name, fc_b_name ^ "'"]
   377       ||>> mk_Frees "z" [B]
   378       ||>> yield_singleton (apfst (op ~~) oo mk_Frees' "P") HOLogic.boolT;
   379 
   380     val u = Free u';
   381     val v = Free v';
   382     val q = Free (fst p', mk_pred1T B);
   383 
   384     val xctrs = map2 (curry Term.list_comb) ctrs xss;
   385     val yctrs = map2 (curry Term.list_comb) ctrs yss;
   386 
   387     val xfs = map2 (curry Term.list_comb) fs xss;
   388     val xgs = map2 (curry Term.list_comb) gs xss;
   389 
   390     (* TODO: Eta-expension is for compatibility with the old datatype package (but it also provides
   391        nicer names). Consider removing. *)
   392     val eta_fs = map2 eta_expand_arg xss xfs;
   393     val eta_gs = map2 eta_expand_arg xss xgs;
   394 
   395     val case_binding =
   396       qualify false
   397         (if Binding.is_empty raw_case_binding orelse
   398             Binding.eq_name (raw_case_binding, standard_binding) then
   399            Binding.prefix_name (caseN ^ "_") fc_b
   400          else
   401            raw_case_binding);
   402 
   403     fun mk_case_disj xctr xf xs =
   404       list_exists_free xs (HOLogic.mk_conj (HOLogic.mk_eq (u, xctr), HOLogic.mk_eq (w, xf)));
   405 
   406     val case_rhs = fold_rev (fold_rev Term.lambda) [fs, [u]]
   407       (Const (@{const_name The}, (B --> HOLogic.boolT) --> B) $
   408          Term.lambda w (Library.foldr1 HOLogic.mk_disj (map3 mk_case_disj xctrs xfs xss)));
   409 
   410     val ((raw_case, (_, raw_case_def)), (lthy', lthy)) = no_defs_lthy
   411       |> Local_Theory.define ((case_binding, NoSyn),
   412         ((Binding.conceal (Thm.def_binding case_binding), []), case_rhs))
   413       ||> `Local_Theory.restore;
   414 
   415     val phi = Proof_Context.export_morphism lthy lthy';
   416 
   417     val case_def = Morphism.thm phi raw_case_def;
   418 
   419     val case0 = Morphism.term phi raw_case;
   420     val casex = mk_case As B case0;
   421 
   422     val fcase = Term.list_comb (casex, fs);
   423 
   424     val ufcase = fcase $ u;
   425     val vfcase = fcase $ v;
   426 
   427     val eta_fcase = Term.list_comb (casex, eta_fs);
   428     val eta_gcase = Term.list_comb (casex, eta_gs);
   429 
   430     val eta_ufcase = eta_fcase $ u;
   431     val eta_vgcase = eta_gcase $ v;
   432 
   433     fun mk_uu_eq () = HOLogic.mk_eq (u, u);
   434 
   435     val uv_eq = mk_Trueprop_eq (u, v);
   436 
   437     val exist_xs_u_eq_ctrs =
   438       map2 (fn xctr => fn xs => list_exists_free xs (HOLogic.mk_eq (u, xctr))) xctrs xss;
   439 
   440     val unique_disc_no_def = TrueI; (*arbitrary marker*)
   441     val alternate_disc_no_def = FalseE; (*arbitrary marker*)
   442 
   443     fun alternate_disc_lhs get_udisc k =
   444       HOLogic.mk_not
   445         (let val b = nth disc_bindings (k - 1) in
   446            if is_disc_binding_valid b then get_udisc b (k - 1) else nth exist_xs_u_eq_ctrs (k - 1)
   447          end);
   448 
   449     val (all_sels_distinct, discs, selss, disc_defs, sel_defs, sel_defss, lthy') =
   450       if no_discs_sels then
   451         (true, [], [], [], [], [], lthy)
   452       else
   453         let
   454           fun disc_free b = Free (Binding.name_of b, mk_pred1T fcT);
   455 
   456           fun disc_spec b exist_xs_u_eq_ctr = mk_Trueprop_eq (disc_free b $ u, exist_xs_u_eq_ctr);
   457 
   458           fun alternate_disc k =
   459             Term.lambda u (alternate_disc_lhs (K o rapp u o disc_free) (3 - k));
   460 
   461           fun mk_sel_case_args b proto_sels T =
   462             map2 (fn Ts => fn k =>
   463               (case AList.lookup (op =) proto_sels k of
   464                 NONE =>
   465                 (case AList.lookup Binding.eq_name (rev (nth sel_defaultss (k - 1))) b of
   466                   NONE => fold_rev (Term.lambda o curry Free Name.uu) Ts (mk_undefined T)
   467                 | SOME t => t |> Type.constraint (Ts ---> T) |> Syntax.check_term lthy)
   468               | SOME (xs, x) => fold_rev Term.lambda xs x)) ctr_Tss ks;
   469 
   470           fun sel_spec b proto_sels =
   471             let
   472               val _ =
   473                 (case duplicates (op =) (map fst proto_sels) of
   474                    k :: _ => error ("Duplicate selector name " ^ quote (Binding.name_of b) ^
   475                      " for constructor " ^
   476                      quote (Syntax.string_of_term lthy (nth ctrs (k - 1))))
   477                  | [] => ())
   478               val T =
   479                 (case distinct (op =) (map (fastype_of o snd o snd) proto_sels) of
   480                   [T] => T
   481                 | T :: T' :: _ => error ("Inconsistent range type for selector " ^
   482                     quote (Binding.name_of b) ^ ": " ^ quote (Syntax.string_of_typ lthy T) ^ " vs. "
   483                     ^ quote (Syntax.string_of_typ lthy T')));
   484             in
   485               mk_Trueprop_eq (Free (Binding.name_of b, fcT --> T) $ u,
   486                 Term.list_comb (mk_case As T case0, mk_sel_case_args b proto_sels T) $ u)
   487             end;
   488 
   489           val sel_bindings = flat sel_bindingss;
   490           val uniq_sel_bindings = distinct Binding.eq_name sel_bindings;
   491           val all_sels_distinct = (length uniq_sel_bindings = length sel_bindings);
   492 
   493           val sel_binding_index =
   494             if all_sels_distinct then 1 upto length sel_bindings
   495             else map (fn b => find_index (curry Binding.eq_name b) uniq_sel_bindings) sel_bindings;
   496 
   497           val proto_sels = flat (map3 (fn k => fn xs => map (fn x => (k, (xs, x)))) ks xss xss);
   498           val sel_infos =
   499             AList.group (op =) (sel_binding_index ~~ proto_sels)
   500             |> sort (int_ord o pairself fst)
   501             |> map snd |> curry (op ~~) uniq_sel_bindings;
   502           val sel_bindings = map fst sel_infos;
   503 
   504           fun unflat_selss xs = unflat_lookup Binding.eq_name sel_bindings xs sel_bindingss;
   505 
   506           val (((raw_discs, raw_disc_defs), (raw_sels, raw_sel_defs)), (lthy', lthy)) =
   507             lthy
   508             |> apfst split_list o fold_map3 (fn k => fn exist_xs_u_eq_ctr => fn b =>
   509                 if Binding.is_empty b then
   510                   if n = 1 then pair (Term.lambda u (mk_uu_eq ()), unique_disc_no_def)
   511                   else pair (alternate_disc k, alternate_disc_no_def)
   512                 else if Binding.eq_name (b, equal_binding) then
   513                   pair (Term.lambda u exist_xs_u_eq_ctr, refl)
   514                 else
   515                   Specification.definition (SOME (b, NONE, NoSyn),
   516                     ((Thm.def_binding b, []), disc_spec b exist_xs_u_eq_ctr)) #>> apsnd snd)
   517               ks exist_xs_u_eq_ctrs disc_bindings
   518             ||>> apfst split_list o fold_map (fn (b, proto_sels) =>
   519               Specification.definition (SOME (b, NONE, NoSyn),
   520                 ((Thm.def_binding b, []), sel_spec b proto_sels)) #>> apsnd snd) sel_infos
   521             ||> `Local_Theory.restore;
   522 
   523           val phi = Proof_Context.export_morphism lthy lthy';
   524 
   525           val disc_defs = map (Morphism.thm phi) raw_disc_defs;
   526           val sel_defs = map (Morphism.thm phi) raw_sel_defs;
   527           val sel_defss = unflat_selss sel_defs;
   528 
   529           val discs0 = map (Morphism.term phi) raw_discs;
   530           val selss0 = unflat_selss (map (Morphism.term phi) raw_sels);
   531 
   532           val discs = map (mk_disc_or_sel As) discs0;
   533           val selss = map (map (mk_disc_or_sel As)) selss0;
   534         in
   535           (all_sels_distinct, discs, selss, disc_defs, sel_defs, sel_defss, lthy')
   536         end;
   537 
   538     fun mk_imp_p Qs = Logic.list_implies (Qs, HOLogic.mk_Trueprop p);
   539 
   540     val exhaust_goal =
   541       let fun mk_prem xctr xs = fold_rev Logic.all xs (mk_imp_p [mk_Trueprop_eq (u, xctr)]) in
   542         fold_rev Logic.all [p, u] (mk_imp_p (map2 mk_prem xctrs xss))
   543       end;
   544 
   545     val inject_goalss =
   546       let
   547         fun mk_goal _ _ [] [] = []
   548           | mk_goal xctr yctr xs ys =
   549             [fold_rev Logic.all (xs @ ys) (mk_Trueprop_eq (HOLogic.mk_eq (xctr, yctr),
   550               Library.foldr1 HOLogic.mk_conj (map2 (curry HOLogic.mk_eq) xs ys)))];
   551       in
   552         map4 mk_goal xctrs yctrs xss yss
   553       end;
   554 
   555     val half_distinct_goalss =
   556       let
   557         fun mk_goal ((xs, xc), (xs', xc')) =
   558           fold_rev Logic.all (xs @ xs')
   559             (HOLogic.mk_Trueprop (HOLogic.mk_not (HOLogic.mk_eq (xc, xc'))));
   560       in
   561         map (map mk_goal) (mk_half_pairss (`I (xss ~~ xctrs)))
   562       end;
   563 
   564     val goalss = [exhaust_goal] :: inject_goalss @ half_distinct_goalss;
   565 
   566     fun after_qed thmss lthy =
   567       let
   568         val ([exhaust_thm], (inject_thmss, half_distinct_thmss)) = (hd thmss, chop n (tl thmss));
   569 
   570         val inject_thms = flat inject_thmss;
   571 
   572         val rho_As = map (pairself (certifyT lthy)) (map Logic.varifyT_global As ~~ As);
   573 
   574         fun inst_thm t thm =
   575           Drule.instantiate' [] [SOME (certify lthy t)]
   576             (Thm.instantiate (rho_As, []) (Drule.zero_var_indexes thm));
   577 
   578         val uexhaust_thm = inst_thm u exhaust_thm;
   579 
   580         val exhaust_cases = map base_name_of_ctr ctrs;
   581 
   582         val other_half_distinct_thmss = map (map (fn thm => thm RS not_sym)) half_distinct_thmss;
   583 
   584         val (distinct_thms, (distinct_thmsss', distinct_thmsss)) =
   585           join_halves n half_distinct_thmss other_half_distinct_thmss ||> `transpose;
   586 
   587         val nchotomy_thm =
   588           let
   589             val goal =
   590               HOLogic.mk_Trueprop (HOLogic.mk_all (fst u', snd u',
   591                 Library.foldr1 HOLogic.mk_disj exist_xs_u_eq_ctrs));
   592           in
   593             Goal.prove_sorry lthy [] [] goal (fn _ => mk_nchotomy_tac n exhaust_thm)
   594             |> Thm.close_derivation
   595           end;
   596 
   597         val case_thms =
   598           let
   599             val goals =
   600               map3 (fn xctr => fn xf => fn xs =>
   601                 fold_rev Logic.all (fs @ xs) (mk_Trueprop_eq (fcase $ xctr, xf))) xctrs xfs xss;
   602           in
   603             map4 (fn k => fn goal => fn injects => fn distinctss =>
   604                 Goal.prove_sorry lthy [] [] goal (fn {context = ctxt, ...} =>
   605                   mk_case_tac ctxt n k case_def injects distinctss)
   606                 |> Thm.close_derivation)
   607               ks goals inject_thmss distinct_thmsss
   608           end;
   609 
   610         val (case_cong_thm, weak_case_cong_thm) =
   611           let
   612             fun mk_prem xctr xs xf xg =
   613               fold_rev Logic.all xs (Logic.mk_implies (mk_Trueprop_eq (v, xctr),
   614                 mk_Trueprop_eq (xf, xg)));
   615 
   616             val goal =
   617               Logic.list_implies (uv_eq :: map4 mk_prem xctrs xss xfs xgs,
   618                  mk_Trueprop_eq (eta_ufcase, eta_vgcase));
   619             val weak_goal = Logic.mk_implies (uv_eq, mk_Trueprop_eq (ufcase, vfcase));
   620           in
   621             (Goal.prove_sorry lthy [] [] goal (fn _ => mk_case_cong_tac lthy uexhaust_thm case_thms),
   622              Goal.prove_sorry lthy [] [] weak_goal (K (etac arg_cong 1)))
   623             |> pairself (Thm.close_derivation #> singleton (Proof_Context.export names_lthy lthy))
   624           end;
   625 
   626         val split_lhs = q $ ufcase;
   627 
   628         fun mk_split_conjunct xctr xs f_xs =
   629           list_all_free xs (HOLogic.mk_imp (HOLogic.mk_eq (u, xctr), q $ f_xs));
   630         fun mk_split_disjunct xctr xs f_xs =
   631           list_exists_free xs (HOLogic.mk_conj (HOLogic.mk_eq (u, xctr),
   632             HOLogic.mk_not (q $ f_xs)));
   633 
   634         fun mk_split_goal xctrs xss xfs =
   635           mk_Trueprop_eq (split_lhs, Library.foldr1 HOLogic.mk_conj
   636             (map3 mk_split_conjunct xctrs xss xfs));
   637         fun mk_split_asm_goal xctrs xss xfs =
   638           mk_Trueprop_eq (split_lhs, HOLogic.mk_not (Library.foldr1 HOLogic.mk_disj
   639             (map3 mk_split_disjunct xctrs xss xfs)));
   640 
   641         fun prove_split selss goal =
   642           Goal.prove_sorry lthy [] [] goal (fn _ =>
   643             mk_split_tac lthy uexhaust_thm case_thms selss inject_thmss distinct_thmsss)
   644           |> Thm.close_derivation
   645           |> singleton (Proof_Context.export names_lthy lthy);
   646 
   647         fun prove_split_asm asm_goal split_thm =
   648           Goal.prove_sorry lthy [] [] asm_goal (fn {context = ctxt, ...} =>
   649             mk_split_asm_tac ctxt split_thm)
   650           |> Thm.close_derivation
   651           |> singleton (Proof_Context.export names_lthy lthy);
   652 
   653         val (split_thm, split_asm_thm) =
   654           let
   655             val goal = mk_split_goal xctrs xss xfs;
   656             val asm_goal = mk_split_asm_goal xctrs xss xfs;
   657 
   658             val thm = prove_split (replicate n []) goal;
   659             val asm_thm = prove_split_asm asm_goal thm;
   660           in
   661             (thm, asm_thm)
   662           end;
   663 
   664         val (all_sel_thms, sel_thmss, disc_thmss, nontriv_disc_thms, discI_thms, nontriv_discI_thms,
   665              disc_exclude_thms, disc_exclude_thmsss, disc_exhaust_thms, sel_exhaust_thms,
   666              all_collapse_thms, safe_collapse_thms, expand_thms, sel_split_thms, sel_split_asm_thms,
   667              case_eq_if_thms) =
   668           if no_discs_sels then
   669             ([], [], [], [], [], [], [], [], [], [], [], [], [], [], [], [])
   670           else
   671             let
   672               val udiscs = map (rapp u) discs;
   673               val uselss = map (map (rapp u)) selss;
   674               val usel_ctrs = map2 (curry Term.list_comb) ctrs uselss;
   675               val usel_fs = map2 (curry Term.list_comb) fs uselss;
   676 
   677               val vdiscs = map (rapp v) discs;
   678               val vselss = map (map (rapp v)) selss;
   679 
   680               fun make_sel_thm xs' case_thm sel_def =
   681                 zero_var_indexes (Drule.gen_all (Drule.rename_bvars' (map (SOME o fst) xs')
   682                     (Drule.forall_intr_vars (case_thm RS (sel_def RS trans)))));
   683 
   684               val sel_thmss = map3 (map oo make_sel_thm) xss' case_thms sel_defss;
   685 
   686               fun has_undefined_rhs thm =
   687                 (case snd (HOLogic.dest_eq (HOLogic.dest_Trueprop (prop_of thm))) of
   688                   Const (@{const_name undefined}, _) => true
   689                 | _ => false);
   690 
   691               val all_sel_thms =
   692                 (if all_sels_distinct andalso forall null sel_defaultss then
   693                    flat sel_thmss
   694                  else
   695                    map_product (fn s => fn (xs', c) => make_sel_thm xs' c s) sel_defs
   696                      (xss' ~~ case_thms))
   697                 |> filter_out has_undefined_rhs;
   698 
   699               fun mk_unique_disc_def () =
   700                 let
   701                   val m = the_single ms;
   702                   val goal = mk_Trueprop_eq (mk_uu_eq (), the_single exist_xs_u_eq_ctrs);
   703                 in
   704                   Goal.prove_sorry lthy [] [] goal (fn _ => mk_unique_disc_def_tac m uexhaust_thm)
   705                   |> Thm.close_derivation
   706                   |> singleton (Proof_Context.export names_lthy lthy)
   707                 end;
   708 
   709               fun mk_alternate_disc_def k =
   710                 let
   711                   val goal =
   712                     mk_Trueprop_eq (alternate_disc_lhs (K (nth udiscs)) (3 - k),
   713                       nth exist_xs_u_eq_ctrs (k - 1));
   714                 in
   715                   Goal.prove_sorry lthy [] [] goal (fn {context = ctxt, ...} =>
   716                     mk_alternate_disc_def_tac ctxt k (nth disc_defs (2 - k))
   717                       (nth distinct_thms (2 - k)) uexhaust_thm)
   718                   |> Thm.close_derivation
   719                   |> singleton (Proof_Context.export names_lthy lthy)
   720                 end;
   721 
   722               val has_alternate_disc_def =
   723                 exists (fn def => Thm.eq_thm_prop (def, alternate_disc_no_def)) disc_defs;
   724 
   725               val disc_defs' =
   726                 map2 (fn k => fn def =>
   727                   if Thm.eq_thm_prop (def, unique_disc_no_def) then mk_unique_disc_def ()
   728                   else if Thm.eq_thm_prop (def, alternate_disc_no_def) then mk_alternate_disc_def k
   729                   else def) ks disc_defs;
   730 
   731               val discD_thms = map (fn def => def RS iffD1) disc_defs';
   732               val discI_thms =
   733                 map2 (fn m => fn def => funpow m (fn thm => exI RS thm) (def RS iffD2)) ms
   734                   disc_defs';
   735               val not_discI_thms =
   736                 map2 (fn m => fn def => funpow m (fn thm => allI RS thm)
   737                     (unfold_thms lthy @{thms not_ex} (def RS @{thm ssubst[of _ _ Not]})))
   738                   ms disc_defs';
   739 
   740               val (disc_thmss', disc_thmss) =
   741                 let
   742                   fun mk_thm discI _ [] = refl RS discI
   743                     | mk_thm _ not_discI [distinct] = distinct RS not_discI;
   744                   fun mk_thms discI not_discI distinctss = map (mk_thm discI not_discI) distinctss;
   745                 in
   746                   map3 mk_thms discI_thms not_discI_thms distinct_thmsss' |> `transpose
   747                 end;
   748 
   749               val nontriv_disc_thms =
   750                 flat (map2 (fn b => if is_disc_binding_valid b then I else K [])
   751                   disc_bindings disc_thmss);
   752 
   753               fun is_discI_boring b =
   754                 (n = 1 andalso Binding.is_empty b) orelse Binding.eq_name (b, equal_binding);
   755 
   756               val nontriv_discI_thms =
   757                 flat (map2 (fn b => if is_discI_boring b then K [] else single) disc_bindings
   758                   discI_thms);
   759 
   760               val (disc_exclude_thms, (disc_exclude_thmsss', disc_exclude_thmsss)) =
   761                 let
   762                   fun mk_goal [] = []
   763                     | mk_goal [((_, udisc), (_, udisc'))] =
   764                       [Logic.all u (Logic.mk_implies (HOLogic.mk_Trueprop udisc,
   765                          HOLogic.mk_Trueprop (HOLogic.mk_not udisc')))];
   766 
   767                   fun prove tac goal =
   768                     Goal.prove_sorry lthy [] [] goal (K tac)
   769                     |> Thm.close_derivation;
   770 
   771                   val half_pairss = mk_half_pairss (`I (ms ~~ discD_thms ~~ udiscs));
   772 
   773                   val half_goalss = map mk_goal half_pairss;
   774                   val half_thmss =
   775                     map3 (fn [] => K (K []) | [goal] => fn [(((m, discD), _), _)] =>
   776                         fn disc_thm => [prove (mk_half_disc_exclude_tac lthy m discD disc_thm) goal])
   777                       half_goalss half_pairss (flat disc_thmss');
   778 
   779                   val other_half_goalss = map (mk_goal o map swap) half_pairss;
   780                   val other_half_thmss =
   781                     map2 (map2 (prove o mk_other_half_disc_exclude_tac)) half_thmss
   782                       other_half_goalss;
   783                 in
   784                   join_halves n half_thmss other_half_thmss ||> `transpose
   785                   |>> has_alternate_disc_def ? K []
   786                 end;
   787 
   788               val disc_exhaust_thm =
   789                 let
   790                   fun mk_prem udisc = mk_imp_p [HOLogic.mk_Trueprop udisc];
   791                   val goal = fold_rev Logic.all [p, u] (mk_imp_p (map mk_prem udiscs));
   792                 in
   793                   Goal.prove_sorry lthy [] [] goal (fn _ =>
   794                     mk_disc_exhaust_tac n exhaust_thm discI_thms)
   795                   |> Thm.close_derivation
   796                 end;
   797 
   798               val (safe_collapse_thms, all_collapse_thms) =
   799                 let
   800                   fun mk_goal m udisc usel_ctr =
   801                     let
   802                       val prem = HOLogic.mk_Trueprop udisc;
   803                       val concl = mk_Trueprop_eq ((usel_ctr, u) |> m = 0 ? swap);
   804                     in
   805                       (prem aconv concl, Logic.all u (Logic.mk_implies (prem, concl)))
   806                     end;
   807                   val (trivs, goals) = map3 mk_goal ms udiscs usel_ctrs |> split_list;
   808                   val thms =
   809                     map5 (fn m => fn discD => fn sel_thms => fn triv => fn goal =>
   810                         Goal.prove_sorry lthy [] [] goal (fn {context = ctxt, ...} =>
   811                           mk_collapse_tac ctxt m discD sel_thms ORELSE HEADGOAL atac)
   812                         |> Thm.close_derivation
   813                         |> not triv ? perhaps (try (fn thm => refl RS thm)))
   814                       ms discD_thms sel_thmss trivs goals;
   815                 in
   816                   (map_filter (fn (true, _) => NONE | (false, thm) => SOME thm) (trivs ~~ thms),
   817                    thms)
   818                 end;
   819 
   820               val swapped_all_collapse_thms =
   821                 map2 (fn m => fn thm => if m = 0 then thm else thm RS sym) ms all_collapse_thms;
   822 
   823               val sel_exhaust_thm =
   824                 let
   825                   fun mk_prem usel_ctr = mk_imp_p [mk_Trueprop_eq (u, usel_ctr)];
   826                   val goal = fold_rev Logic.all [p, u] (mk_imp_p (map mk_prem usel_ctrs));
   827                 in
   828                   Goal.prove_sorry lthy [] [] goal (fn _ =>
   829                     mk_sel_exhaust_tac n disc_exhaust_thm swapped_all_collapse_thms)
   830                   |> Thm.close_derivation
   831                 end;
   832 
   833               val expand_thm =
   834                 let
   835                   fun mk_prems k udisc usels vdisc vsels =
   836                     (if k = n then [] else [mk_Trueprop_eq (udisc, vdisc)]) @
   837                     (if null usels then
   838                        []
   839                      else
   840                        [Logic.list_implies
   841                           (if n = 1 then [] else map HOLogic.mk_Trueprop [udisc, vdisc],
   842                              HOLogic.mk_Trueprop (Library.foldr1 HOLogic.mk_conj
   843                                (map2 (curry HOLogic.mk_eq) usels vsels)))]);
   844 
   845                   val goal =
   846                     Library.foldr Logic.list_implies
   847                       (map5 mk_prems ks udiscs uselss vdiscs vselss, uv_eq);
   848                   val uncollapse_thms =
   849                     map2 (fn thm => fn [] => thm | _ => thm RS sym) all_collapse_thms uselss;
   850                 in
   851                   Goal.prove_sorry lthy [] [] goal (fn _ =>
   852                     mk_expand_tac lthy n ms (inst_thm u disc_exhaust_thm)
   853                       (inst_thm v disc_exhaust_thm) uncollapse_thms disc_exclude_thmsss
   854                       disc_exclude_thmsss')
   855                   |> Thm.close_derivation
   856                   |> singleton (Proof_Context.export names_lthy lthy)
   857                 end;
   858 
   859               val (sel_split_thm, sel_split_asm_thm) =
   860                 let
   861                   val zss = map (K []) xss;
   862                   val goal = mk_split_goal usel_ctrs zss usel_fs;
   863                   val asm_goal = mk_split_asm_goal usel_ctrs zss usel_fs;
   864 
   865                   val thm = prove_split sel_thmss goal;
   866                   val asm_thm = prove_split_asm asm_goal thm;
   867                 in
   868                   (thm, asm_thm)
   869                 end;
   870 
   871               val case_eq_if_thm =
   872                 let
   873                   val goal = mk_Trueprop_eq (ufcase, mk_IfN B udiscs usel_fs);
   874                 in
   875                   Goal.prove_sorry lthy [] [] goal (fn {context = ctxt, ...} =>
   876                     mk_case_eq_if_tac ctxt n uexhaust_thm case_thms disc_thmss' sel_thmss)
   877                   |> Thm.close_derivation
   878                   |> singleton (Proof_Context.export names_lthy lthy)
   879                 end;
   880             in
   881               (all_sel_thms, sel_thmss, disc_thmss, nontriv_disc_thms, discI_thms,
   882                nontriv_discI_thms, disc_exclude_thms, disc_exclude_thmsss, [disc_exhaust_thm],
   883                [sel_exhaust_thm], all_collapse_thms, safe_collapse_thms, [expand_thm],
   884                [sel_split_thm], [sel_split_asm_thm], [case_eq_if_thm])
   885             end;
   886 
   887         val exhaust_case_names_attr = Attrib.internal (K (Rule_Cases.case_names exhaust_cases));
   888         val cases_type_attr = Attrib.internal (K (Induct.cases_type fcT_name));
   889 
   890         val anonymous_notes =
   891           [(map (fn th => th RS notE) distinct_thms, safe_elim_attrs),
   892            (map (fn th => th RS @{thm eq_False[THEN iffD2]}
   893               handle THM _ => th RS @{thm eq_True[THEN iffD2]}) nontriv_disc_thms,
   894             code_nitpicksimp_attrs)]
   895           |> map (fn (thms, attrs) => ((Binding.empty, attrs), [(thms, [])]));
   896 
   897         val notes =
   898           [(caseN, case_thms, code_nitpicksimp_simp_attrs),
   899            (case_congN, [case_cong_thm], []),
   900            (case_eq_ifN, case_eq_if_thms, []),
   901            (collapseN, safe_collapse_thms, simp_attrs),
   902            (discN, nontriv_disc_thms, simp_attrs),
   903            (discIN, nontriv_discI_thms, []),
   904            (disc_excludeN, disc_exclude_thms, dest_attrs),
   905            (disc_exhaustN, disc_exhaust_thms, [exhaust_case_names_attr]),
   906            (distinctN, distinct_thms, simp_attrs @ inductsimp_attrs),
   907            (exhaustN, [exhaust_thm], [exhaust_case_names_attr, cases_type_attr]),
   908            (expandN, expand_thms, []),
   909            (injectN, inject_thms, iff_attrs @ inductsimp_attrs),
   910            (nchotomyN, [nchotomy_thm], []),
   911            (selN, all_sel_thms, code_nitpicksimp_simp_attrs),
   912            (sel_exhaustN, sel_exhaust_thms, [exhaust_case_names_attr]),
   913            (sel_splitN, sel_split_thms, []),
   914            (sel_split_asmN, sel_split_asm_thms, []),
   915            (splitN, [split_thm], []),
   916            (split_asmN, [split_asm_thm], []),
   917            (splitsN, [split_thm, split_asm_thm], []),
   918            (weak_case_cong_thmsN, [weak_case_cong_thm], cong_attrs)]
   919           |> filter_out (null o #2)
   920           |> map (fn (thmN, thms, attrs) =>
   921             ((qualify true (Binding.name thmN), attrs), [(thms, [])]));
   922 
   923         val ctr_sugar =
   924           {ctrs = ctrs, casex = casex, discs = discs, selss = selss, exhaust = exhaust_thm,
   925            nchotomy = nchotomy_thm, injects = inject_thms, distincts = distinct_thms,
   926            case_thms = case_thms, case_cong = case_cong_thm, weak_case_cong = weak_case_cong_thm,
   927            split = split_thm, split_asm = split_asm_thm, disc_thmss = disc_thmss,
   928            discIs = discI_thms, sel_thmss = sel_thmss, disc_excludesss = disc_exclude_thmsss,
   929            disc_exhausts = disc_exhaust_thms, sel_exhausts = sel_exhaust_thms,
   930            collapses = all_collapse_thms, expands = expand_thms, sel_splits = sel_split_thms,
   931            sel_split_asms = sel_split_asm_thms, case_eq_ifs = case_eq_if_thms};
   932       in
   933         (ctr_sugar,
   934          lthy
   935          |> not rep_compat ?
   936             Local_Theory.declaration {syntax = false, pervasive = true}
   937               (fn phi => Case_Translation.register
   938                  (Morphism.term phi casex) (map (Morphism.term phi) ctrs))
   939          |> Local_Theory.background_theory (fold (fold Code.del_eqn) [disc_defs, sel_defs])
   940          |> not no_code ?
   941             Local_Theory.declaration {syntax = false, pervasive = false}
   942               (fn phi => Context.mapping
   943                 (add_ctr_code fcT_name (map (Morphism.typ phi) As)
   944                   (map (dest_Const o Morphism.term phi) ctrs) (Morphism.fact phi inject_thms)
   945                   (Morphism.fact phi distinct_thms) (Morphism.fact phi case_thms))
   946                 I)
   947          |> Local_Theory.notes (anonymous_notes @ notes) |> snd
   948          |> register_ctr_sugar fcT_name ctr_sugar)
   949       end;
   950   in
   951     (goalss, after_qed, lthy')
   952   end;
   953 
   954 fun wrap_free_constructors tacss = (fn (goalss, after_qed, lthy) =>
   955   map2 (map2 (Thm.close_derivation oo Goal.prove_sorry lthy [] [])) goalss tacss
   956   |> (fn thms => after_qed thms lthy)) oo prepare_wrap_free_constructors (K I);
   957 
   958 val wrap_free_constructors_cmd = (fn (goalss, after_qed, lthy) =>
   959   Proof.theorem NONE (snd oo after_qed) (map (map (rpair [])) goalss) lthy) oo
   960   prepare_wrap_free_constructors Syntax.read_term;
   961 
   962 fun parse_bracket_list parser = @{keyword "["} |-- Parse.list parser --|  @{keyword "]"};
   963 
   964 val parse_bindings = parse_bracket_list parse_binding;
   965 val parse_bindingss = parse_bracket_list parse_bindings;
   966 
   967 val parse_bound_term = (parse_binding --| @{keyword ":"}) -- Parse.term;
   968 val parse_bound_terms = parse_bracket_list parse_bound_term;
   969 val parse_bound_termss = parse_bracket_list parse_bound_terms;
   970 
   971 val parse_wrap_free_constructors_options =
   972   Scan.optional (@{keyword "("} |-- Parse.list1
   973         (Parse.reserved "no_discs_sels" >> K 0 || Parse.reserved "no_code" >> K 1 ||
   974          Parse.reserved "rep_compat" >> K 2) --| @{keyword ")"}
   975       >> (fn js => (member (op =) js 0, (member (op =) js 1, member (op =) js 2))))
   976     (false, (false, false));
   977 
   978 val _ =
   979   Outer_Syntax.local_theory_to_proof @{command_spec "wrap_free_constructors"}
   980     "wrap an existing freely generated type's constructors"
   981     ((parse_wrap_free_constructors_options -- (@{keyword "["} |-- Parse.list Parse.term --|
   982         @{keyword "]"}) --
   983       parse_binding -- Scan.optional (parse_bindings -- Scan.optional (parse_bindingss --
   984         Scan.optional parse_bound_termss []) ([], [])) ([], ([], [])))
   985      >> wrap_free_constructors_cmd);
   986 
   987 end;