src/HOL/Rings.thy
author paulson <lp15@cam.ac.uk>
Tue Mar 31 16:48:48 2015 +0100 (2015-03-31)
changeset 59865 8a20dd967385
parent 59833 ab828c2c5d67
child 59910 815de5506080
permissions -rw-r--r--
rationalised and generalised some theorems concerning abs and x^2.
     1 (*  Title:      HOL/Rings.thy
     2     Author:     Gertrud Bauer
     3     Author:     Steven Obua
     4     Author:     Tobias Nipkow
     5     Author:     Lawrence C Paulson
     6     Author:     Markus Wenzel
     7     Author:     Jeremy Avigad
     8 *)
     9 
    10 section {* Rings *}
    11 
    12 theory Rings
    13 imports Groups
    14 begin
    15 
    16 class semiring = ab_semigroup_add + semigroup_mult +
    17   assumes distrib_right[algebra_simps]: "(a + b) * c = a * c + b * c"
    18   assumes distrib_left[algebra_simps]: "a * (b + c) = a * b + a * c"
    19 begin
    20 
    21 text{*For the @{text combine_numerals} simproc*}
    22 lemma combine_common_factor:
    23   "a * e + (b * e + c) = (a + b) * e + c"
    24 by (simp add: distrib_right ac_simps)
    25 
    26 end
    27 
    28 class mult_zero = times + zero +
    29   assumes mult_zero_left [simp]: "0 * a = 0"
    30   assumes mult_zero_right [simp]: "a * 0 = 0"
    31 begin
    32 
    33 lemma mult_not_zero:
    34   "a * b \<noteq> 0 \<Longrightarrow> a \<noteq> 0 \<and> b \<noteq> 0"
    35   by auto
    36 
    37 end
    38 
    39 class semiring_0 = semiring + comm_monoid_add + mult_zero
    40 
    41 class semiring_0_cancel = semiring + cancel_comm_monoid_add
    42 begin
    43 
    44 subclass semiring_0
    45 proof
    46   fix a :: 'a
    47   have "0 * a + 0 * a = 0 * a + 0" by (simp add: distrib_right [symmetric])
    48   thus "0 * a = 0" by (simp only: add_left_cancel)
    49 next
    50   fix a :: 'a
    51   have "a * 0 + a * 0 = a * 0 + 0" by (simp add: distrib_left [symmetric])
    52   thus "a * 0 = 0" by (simp only: add_left_cancel)
    53 qed
    54 
    55 end
    56 
    57 class comm_semiring = ab_semigroup_add + ab_semigroup_mult +
    58   assumes distrib: "(a + b) * c = a * c + b * c"
    59 begin
    60 
    61 subclass semiring
    62 proof
    63   fix a b c :: 'a
    64   show "(a + b) * c = a * c + b * c" by (simp add: distrib)
    65   have "a * (b + c) = (b + c) * a" by (simp add: ac_simps)
    66   also have "... = b * a + c * a" by (simp only: distrib)
    67   also have "... = a * b + a * c" by (simp add: ac_simps)
    68   finally show "a * (b + c) = a * b + a * c" by blast
    69 qed
    70 
    71 end
    72 
    73 class comm_semiring_0 = comm_semiring + comm_monoid_add + mult_zero
    74 begin
    75 
    76 subclass semiring_0 ..
    77 
    78 end
    79 
    80 class comm_semiring_0_cancel = comm_semiring + cancel_comm_monoid_add
    81 begin
    82 
    83 subclass semiring_0_cancel ..
    84 
    85 subclass comm_semiring_0 ..
    86 
    87 end
    88 
    89 class zero_neq_one = zero + one +
    90   assumes zero_neq_one [simp]: "0 \<noteq> 1"
    91 begin
    92 
    93 lemma one_neq_zero [simp]: "1 \<noteq> 0"
    94 by (rule not_sym) (rule zero_neq_one)
    95 
    96 definition of_bool :: "bool \<Rightarrow> 'a"
    97 where
    98   "of_bool p = (if p then 1 else 0)" 
    99 
   100 lemma of_bool_eq [simp, code]:
   101   "of_bool False = 0"
   102   "of_bool True = 1"
   103   by (simp_all add: of_bool_def)
   104 
   105 lemma of_bool_eq_iff:
   106   "of_bool p = of_bool q \<longleftrightarrow> p = q"
   107   by (simp add: of_bool_def)
   108 
   109 lemma split_of_bool [split]:
   110   "P (of_bool p) \<longleftrightarrow> (p \<longrightarrow> P 1) \<and> (\<not> p \<longrightarrow> P 0)"
   111   by (cases p) simp_all
   112 
   113 lemma split_of_bool_asm:
   114   "P (of_bool p) \<longleftrightarrow> \<not> (p \<and> \<not> P 1 \<or> \<not> p \<and> \<not> P 0)"
   115   by (cases p) simp_all
   116   
   117 end  
   118 
   119 class semiring_1 = zero_neq_one + semiring_0 + monoid_mult
   120 
   121 text {* Abstract divisibility *}
   122 
   123 class dvd = times
   124 begin
   125 
   126 definition dvd :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "dvd" 50) where
   127   "b dvd a \<longleftrightarrow> (\<exists>k. a = b * k)"
   128 
   129 lemma dvdI [intro?]: "a = b * k \<Longrightarrow> b dvd a"
   130   unfolding dvd_def ..
   131 
   132 lemma dvdE [elim?]: "b dvd a \<Longrightarrow> (\<And>k. a = b * k \<Longrightarrow> P) \<Longrightarrow> P"
   133   unfolding dvd_def by blast 
   134 
   135 end
   136 
   137 context comm_monoid_mult
   138 begin
   139 
   140 subclass dvd .
   141 
   142 lemma dvd_refl [simp]:
   143   "a dvd a"
   144 proof
   145   show "a = a * 1" by simp
   146 qed
   147 
   148 lemma dvd_trans:
   149   assumes "a dvd b" and "b dvd c"
   150   shows "a dvd c"
   151 proof -
   152   from assms obtain v where "b = a * v" by (auto elim!: dvdE)
   153   moreover from assms obtain w where "c = b * w" by (auto elim!: dvdE)
   154   ultimately have "c = a * (v * w)" by (simp add: mult.assoc)
   155   then show ?thesis ..
   156 qed
   157 
   158 lemma one_dvd [simp]:
   159   "1 dvd a"
   160   by (auto intro!: dvdI)
   161 
   162 lemma dvd_mult [simp]:
   163   "a dvd c \<Longrightarrow> a dvd (b * c)"
   164   by (auto intro!: mult.left_commute dvdI elim!: dvdE)
   165 
   166 lemma dvd_mult2 [simp]:
   167   "a dvd b \<Longrightarrow> a dvd (b * c)"
   168   using dvd_mult [of a b c] by (simp add: ac_simps) 
   169 
   170 lemma dvd_triv_right [simp]:
   171   "a dvd b * a"
   172   by (rule dvd_mult) (rule dvd_refl)
   173 
   174 lemma dvd_triv_left [simp]:
   175   "a dvd a * b"
   176   by (rule dvd_mult2) (rule dvd_refl)
   177 
   178 lemma mult_dvd_mono:
   179   assumes "a dvd b"
   180     and "c dvd d"
   181   shows "a * c dvd b * d"
   182 proof -
   183   from `a dvd b` obtain b' where "b = a * b'" ..
   184   moreover from `c dvd d` obtain d' where "d = c * d'" ..
   185   ultimately have "b * d = (a * c) * (b' * d')" by (simp add: ac_simps)
   186   then show ?thesis ..
   187 qed
   188 
   189 lemma dvd_mult_left:
   190   "a * b dvd c \<Longrightarrow> a dvd c"
   191   by (simp add: dvd_def mult.assoc) blast
   192 
   193 lemma dvd_mult_right:
   194   "a * b dvd c \<Longrightarrow> b dvd c"
   195   using dvd_mult_left [of b a c] by (simp add: ac_simps)
   196   
   197 end
   198 
   199 class comm_semiring_1 = zero_neq_one + comm_semiring_0 + comm_monoid_mult
   200 begin
   201 
   202 subclass semiring_1 ..
   203 
   204 lemma dvd_0_left_iff [simp]:
   205   "0 dvd a \<longleftrightarrow> a = 0"
   206   by (auto intro: dvd_refl elim!: dvdE)
   207 
   208 lemma dvd_0_right [iff]:
   209   "a dvd 0"
   210 proof
   211   show "0 = a * 0" by simp
   212 qed
   213 
   214 lemma dvd_0_left:
   215   "0 dvd a \<Longrightarrow> a = 0"
   216   by simp
   217 
   218 lemma dvd_add [simp]:
   219   assumes "a dvd b" and "a dvd c"
   220   shows "a dvd (b + c)"
   221 proof -
   222   from `a dvd b` obtain b' where "b = a * b'" ..
   223   moreover from `a dvd c` obtain c' where "c = a * c'" ..
   224   ultimately have "b + c = a * (b' + c')" by (simp add: distrib_left)
   225   then show ?thesis ..
   226 qed
   227 
   228 end
   229 
   230 class semiring_1_cancel = semiring + cancel_comm_monoid_add
   231   + zero_neq_one + monoid_mult
   232 begin
   233 
   234 subclass semiring_0_cancel ..
   235 
   236 subclass semiring_1 ..
   237 
   238 end
   239 
   240 class comm_semiring_1_cancel = comm_semiring + cancel_comm_monoid_add
   241   + zero_neq_one + comm_monoid_mult
   242 begin
   243 
   244 subclass semiring_1_cancel ..
   245 subclass comm_semiring_0_cancel ..
   246 subclass comm_semiring_1 ..
   247 
   248 end
   249 
   250 class comm_semiring_1_diff_distrib = comm_semiring_1_cancel +
   251   assumes right_diff_distrib' [algebra_simps]: "a * (b - c) = a * b - a * c"
   252 begin
   253 
   254 lemma left_diff_distrib' [algebra_simps]:
   255   "(b - c) * a = b * a - c * a"
   256   by (simp add: algebra_simps)
   257 
   258 lemma dvd_add_times_triv_left_iff [simp]:
   259   "a dvd c * a + b \<longleftrightarrow> a dvd b"
   260 proof -
   261   have "a dvd a * c + b \<longleftrightarrow> a dvd b" (is "?P \<longleftrightarrow> ?Q")
   262   proof
   263     assume ?Q then show ?P by simp
   264   next
   265     assume ?P
   266     then obtain d where "a * c + b = a * d" ..
   267     then have "a * c + b - a * c = a * d - a * c" by simp
   268     then have "b = a * d - a * c" by simp
   269     then have "b = a * (d - c)" by (simp add: algebra_simps) 
   270     then show ?Q ..
   271   qed
   272   then show "a dvd c * a + b \<longleftrightarrow> a dvd b" by (simp add: ac_simps)
   273 qed
   274 
   275 lemma dvd_add_times_triv_right_iff [simp]:
   276   "a dvd b + c * a \<longleftrightarrow> a dvd b"
   277   using dvd_add_times_triv_left_iff [of a c b] by (simp add: ac_simps)
   278 
   279 lemma dvd_add_triv_left_iff [simp]:
   280   "a dvd a + b \<longleftrightarrow> a dvd b"
   281   using dvd_add_times_triv_left_iff [of a 1 b] by simp
   282 
   283 lemma dvd_add_triv_right_iff [simp]:
   284   "a dvd b + a \<longleftrightarrow> a dvd b"
   285   using dvd_add_times_triv_right_iff [of a b 1] by simp
   286 
   287 lemma dvd_add_right_iff:
   288   assumes "a dvd b"
   289   shows "a dvd b + c \<longleftrightarrow> a dvd c" (is "?P \<longleftrightarrow> ?Q")
   290 proof
   291   assume ?P then obtain d where "b + c = a * d" ..
   292   moreover from `a dvd b` obtain e where "b = a * e" ..
   293   ultimately have "a * e + c = a * d" by simp
   294   then have "a * e + c - a * e = a * d - a * e" by simp
   295   then have "c = a * d - a * e" by simp
   296   then have "c = a * (d - e)" by (simp add: algebra_simps)
   297   then show ?Q ..
   298 next
   299   assume ?Q with assms show ?P by simp
   300 qed
   301 
   302 lemma dvd_add_left_iff:
   303   assumes "a dvd c"
   304   shows "a dvd b + c \<longleftrightarrow> a dvd b"
   305   using assms dvd_add_right_iff [of a c b] by (simp add: ac_simps)
   306 
   307 end
   308 
   309 class ring = semiring + ab_group_add
   310 begin
   311 
   312 subclass semiring_0_cancel ..
   313 
   314 text {* Distribution rules *}
   315 
   316 lemma minus_mult_left: "- (a * b) = - a * b"
   317 by (rule minus_unique) (simp add: distrib_right [symmetric]) 
   318 
   319 lemma minus_mult_right: "- (a * b) = a * - b"
   320 by (rule minus_unique) (simp add: distrib_left [symmetric]) 
   321 
   322 text{*Extract signs from products*}
   323 lemmas mult_minus_left [simp] = minus_mult_left [symmetric]
   324 lemmas mult_minus_right [simp] = minus_mult_right [symmetric]
   325 
   326 lemma minus_mult_minus [simp]: "- a * - b = a * b"
   327 by simp
   328 
   329 lemma minus_mult_commute: "- a * b = a * - b"
   330 by simp
   331 
   332 lemma right_diff_distrib [algebra_simps]:
   333   "a * (b - c) = a * b - a * c"
   334   using distrib_left [of a b "-c "] by simp
   335 
   336 lemma left_diff_distrib [algebra_simps]:
   337   "(a - b) * c = a * c - b * c"
   338   using distrib_right [of a "- b" c] by simp
   339 
   340 lemmas ring_distribs =
   341   distrib_left distrib_right left_diff_distrib right_diff_distrib
   342 
   343 lemma eq_add_iff1:
   344   "a * e + c = b * e + d \<longleftrightarrow> (a - b) * e + c = d"
   345 by (simp add: algebra_simps)
   346 
   347 lemma eq_add_iff2:
   348   "a * e + c = b * e + d \<longleftrightarrow> c = (b - a) * e + d"
   349 by (simp add: algebra_simps)
   350 
   351 end
   352 
   353 lemmas ring_distribs =
   354   distrib_left distrib_right left_diff_distrib right_diff_distrib
   355 
   356 class comm_ring = comm_semiring + ab_group_add
   357 begin
   358 
   359 subclass ring ..
   360 subclass comm_semiring_0_cancel ..
   361 
   362 lemma square_diff_square_factored:
   363   "x * x - y * y = (x + y) * (x - y)"
   364   by (simp add: algebra_simps)
   365 
   366 end
   367 
   368 class ring_1 = ring + zero_neq_one + monoid_mult
   369 begin
   370 
   371 subclass semiring_1_cancel ..
   372 
   373 lemma square_diff_one_factored:
   374   "x * x - 1 = (x + 1) * (x - 1)"
   375   by (simp add: algebra_simps)
   376 
   377 end
   378 
   379 class comm_ring_1 = comm_ring + zero_neq_one + comm_monoid_mult
   380 begin
   381 
   382 subclass ring_1 ..
   383 subclass comm_semiring_1_cancel ..
   384 
   385 subclass comm_semiring_1_diff_distrib
   386   by unfold_locales (simp add: algebra_simps)
   387 
   388 lemma dvd_minus_iff [simp]: "x dvd - y \<longleftrightarrow> x dvd y"
   389 proof
   390   assume "x dvd - y"
   391   then have "x dvd - 1 * - y" by (rule dvd_mult)
   392   then show "x dvd y" by simp
   393 next
   394   assume "x dvd y"
   395   then have "x dvd - 1 * y" by (rule dvd_mult)
   396   then show "x dvd - y" by simp
   397 qed
   398 
   399 lemma minus_dvd_iff [simp]: "- x dvd y \<longleftrightarrow> x dvd y"
   400 proof
   401   assume "- x dvd y"
   402   then obtain k where "y = - x * k" ..
   403   then have "y = x * - k" by simp
   404   then show "x dvd y" ..
   405 next
   406   assume "x dvd y"
   407   then obtain k where "y = x * k" ..
   408   then have "y = - x * - k" by simp
   409   then show "- x dvd y" ..
   410 qed
   411 
   412 lemma dvd_diff [simp]:
   413   "x dvd y \<Longrightarrow> x dvd z \<Longrightarrow> x dvd (y - z)"
   414   using dvd_add [of x y "- z"] by simp
   415 
   416 end
   417 
   418 class semiring_no_zero_divisors = semiring_0 +
   419   assumes no_zero_divisors: "a \<noteq> 0 \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> a * b \<noteq> 0"
   420 begin
   421 
   422 lemma divisors_zero:
   423   assumes "a * b = 0"
   424   shows "a = 0 \<or> b = 0"
   425 proof (rule classical)
   426   assume "\<not> (a = 0 \<or> b = 0)"
   427   then have "a \<noteq> 0" and "b \<noteq> 0" by auto
   428   with no_zero_divisors have "a * b \<noteq> 0" by blast
   429   with assms show ?thesis by simp
   430 qed
   431 
   432 lemma mult_eq_0_iff [simp]:
   433   shows "a * b = 0 \<longleftrightarrow> a = 0 \<or> b = 0"
   434 proof (cases "a = 0 \<or> b = 0")
   435   case False then have "a \<noteq> 0" and "b \<noteq> 0" by auto
   436     then show ?thesis using no_zero_divisors by simp
   437 next
   438   case True then show ?thesis by auto
   439 qed
   440 
   441 end
   442 
   443 class ring_no_zero_divisors = ring + semiring_no_zero_divisors
   444 begin
   445 
   446 text{*Cancellation of equalities with a common factor*}
   447 lemma mult_cancel_right [simp]:
   448   "a * c = b * c \<longleftrightarrow> c = 0 \<or> a = b"
   449 proof -
   450   have "(a * c = b * c) = ((a - b) * c = 0)"
   451     by (simp add: algebra_simps)
   452   thus ?thesis by (simp add: disj_commute)
   453 qed
   454 
   455 lemma mult_cancel_left [simp]:
   456   "c * a = c * b \<longleftrightarrow> c = 0 \<or> a = b"
   457 proof -
   458   have "(c * a = c * b) = (c * (a - b) = 0)"
   459     by (simp add: algebra_simps)
   460   thus ?thesis by simp
   461 qed
   462 
   463 lemma mult_left_cancel:
   464   "c \<noteq> 0 \<Longrightarrow> c * a = c * b \<longleftrightarrow> a = b"
   465   by simp 
   466 
   467 lemma mult_right_cancel:
   468   "c \<noteq> 0 \<Longrightarrow> a * c = b * c \<longleftrightarrow> a = b"
   469   by simp 
   470 
   471 end
   472 
   473 class ring_1_no_zero_divisors = ring_1 + ring_no_zero_divisors
   474 begin
   475 
   476 lemma square_eq_1_iff:
   477   "x * x = 1 \<longleftrightarrow> x = 1 \<or> x = - 1"
   478 proof -
   479   have "(x - 1) * (x + 1) = x * x - 1"
   480     by (simp add: algebra_simps)
   481   hence "x * x = 1 \<longleftrightarrow> (x - 1) * (x + 1) = 0"
   482     by simp
   483   thus ?thesis
   484     by (simp add: eq_neg_iff_add_eq_0)
   485 qed
   486 
   487 lemma mult_cancel_right1 [simp]:
   488   "c = b * c \<longleftrightarrow> c = 0 \<or> b = 1"
   489 by (insert mult_cancel_right [of 1 c b], force)
   490 
   491 lemma mult_cancel_right2 [simp]:
   492   "a * c = c \<longleftrightarrow> c = 0 \<or> a = 1"
   493 by (insert mult_cancel_right [of a c 1], simp)
   494  
   495 lemma mult_cancel_left1 [simp]:
   496   "c = c * b \<longleftrightarrow> c = 0 \<or> b = 1"
   497 by (insert mult_cancel_left [of c 1 b], force)
   498 
   499 lemma mult_cancel_left2 [simp]:
   500   "c * a = c \<longleftrightarrow> c = 0 \<or> a = 1"
   501 by (insert mult_cancel_left [of c a 1], simp)
   502 
   503 end
   504 
   505 class semidom = comm_semiring_1_cancel + semiring_no_zero_divisors
   506 
   507 class idom = comm_ring_1 + semiring_no_zero_divisors
   508 begin
   509 
   510 subclass semidom ..
   511 
   512 subclass ring_1_no_zero_divisors ..
   513 
   514 lemma dvd_mult_cancel_right [simp]:
   515   "a * c dvd b * c \<longleftrightarrow> c = 0 \<or> a dvd b"
   516 proof -
   517   have "a * c dvd b * c \<longleftrightarrow> (\<exists>k. b * c = (a * k) * c)"
   518     unfolding dvd_def by (simp add: ac_simps)
   519   also have "(\<exists>k. b * c = (a * k) * c) \<longleftrightarrow> c = 0 \<or> a dvd b"
   520     unfolding dvd_def by simp
   521   finally show ?thesis .
   522 qed
   523 
   524 lemma dvd_mult_cancel_left [simp]:
   525   "c * a dvd c * b \<longleftrightarrow> c = 0 \<or> a dvd b"
   526 proof -
   527   have "c * a dvd c * b \<longleftrightarrow> (\<exists>k. b * c = (a * k) * c)"
   528     unfolding dvd_def by (simp add: ac_simps)
   529   also have "(\<exists>k. b * c = (a * k) * c) \<longleftrightarrow> c = 0 \<or> a dvd b"
   530     unfolding dvd_def by simp
   531   finally show ?thesis .
   532 qed
   533 
   534 lemma square_eq_iff: "a * a = b * b \<longleftrightarrow> (a = b \<or> a = - b)"
   535 proof
   536   assume "a * a = b * b"
   537   then have "(a - b) * (a + b) = 0"
   538     by (simp add: algebra_simps)
   539   then show "a = b \<or> a = - b"
   540     by (simp add: eq_neg_iff_add_eq_0)
   541 next
   542   assume "a = b \<or> a = - b"
   543   then show "a * a = b * b" by auto
   544 qed
   545 
   546 end
   547 
   548 text {*
   549   The theory of partially ordered rings is taken from the books:
   550   \begin{itemize}
   551   \item \emph{Lattice Theory} by Garret Birkhoff, American Mathematical Society 1979 
   552   \item \emph{Partially Ordered Algebraic Systems}, Pergamon Press 1963
   553   \end{itemize}
   554   Most of the used notions can also be looked up in 
   555   \begin{itemize}
   556   \item @{url "http://www.mathworld.com"} by Eric Weisstein et. al.
   557   \item \emph{Algebra I} by van der Waerden, Springer.
   558   \end{itemize}
   559 *}
   560 
   561 class ordered_semiring = semiring + comm_monoid_add + ordered_ab_semigroup_add +
   562   assumes mult_left_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> c * a \<le> c * b"
   563   assumes mult_right_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * c"
   564 begin
   565 
   566 lemma mult_mono:
   567   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * d"
   568 apply (erule mult_right_mono [THEN order_trans], assumption)
   569 apply (erule mult_left_mono, assumption)
   570 done
   571 
   572 lemma mult_mono':
   573   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * d"
   574 apply (rule mult_mono)
   575 apply (fast intro: order_trans)+
   576 done
   577 
   578 end
   579 
   580 class ordered_cancel_semiring = ordered_semiring + cancel_comm_monoid_add
   581 begin
   582 
   583 subclass semiring_0_cancel ..
   584 
   585 lemma mult_nonneg_nonneg[simp]: "0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> a * b"
   586 using mult_left_mono [of 0 b a] by simp
   587 
   588 lemma mult_nonneg_nonpos: "0 \<le> a \<Longrightarrow> b \<le> 0 \<Longrightarrow> a * b \<le> 0"
   589 using mult_left_mono [of b 0 a] by simp
   590 
   591 lemma mult_nonpos_nonneg: "a \<le> 0 \<Longrightarrow> 0 \<le> b \<Longrightarrow> a * b \<le> 0"
   592 using mult_right_mono [of a 0 b] by simp
   593 
   594 text {* Legacy - use @{text mult_nonpos_nonneg} *}
   595 lemma mult_nonneg_nonpos2: "0 \<le> a \<Longrightarrow> b \<le> 0 \<Longrightarrow> b * a \<le> 0" 
   596 by (drule mult_right_mono [of b 0], auto)
   597 
   598 lemma split_mult_neg_le: "(0 \<le> a & b \<le> 0) | (a \<le> 0 & 0 \<le> b) \<Longrightarrow> a * b \<le> 0" 
   599 by (auto simp add: mult_nonneg_nonpos mult_nonneg_nonpos2)
   600 
   601 end
   602 
   603 class linordered_semiring = ordered_semiring + linordered_cancel_ab_semigroup_add
   604 begin
   605 
   606 subclass ordered_cancel_semiring ..
   607 
   608 subclass ordered_comm_monoid_add ..
   609 
   610 lemma mult_left_less_imp_less:
   611   "c * a < c * b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a < b"
   612 by (force simp add: mult_left_mono not_le [symmetric])
   613  
   614 lemma mult_right_less_imp_less:
   615   "a * c < b * c \<Longrightarrow> 0 \<le> c \<Longrightarrow> a < b"
   616 by (force simp add: mult_right_mono not_le [symmetric])
   617 
   618 end
   619 
   620 class linordered_semiring_1 = linordered_semiring + semiring_1
   621 begin
   622 
   623 lemma convex_bound_le:
   624   assumes "x \<le> a" "y \<le> a" "0 \<le> u" "0 \<le> v" "u + v = 1"
   625   shows "u * x + v * y \<le> a"
   626 proof-
   627   from assms have "u * x + v * y \<le> u * a + v * a"
   628     by (simp add: add_mono mult_left_mono)
   629   thus ?thesis using assms unfolding distrib_right[symmetric] by simp
   630 qed
   631 
   632 end
   633 
   634 class linordered_semiring_strict = semiring + comm_monoid_add + linordered_cancel_ab_semigroup_add +
   635   assumes mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   636   assumes mult_strict_right_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> a * c < b * c"
   637 begin
   638 
   639 subclass semiring_0_cancel ..
   640 
   641 subclass linordered_semiring
   642 proof
   643   fix a b c :: 'a
   644   assume A: "a \<le> b" "0 \<le> c"
   645   from A show "c * a \<le> c * b"
   646     unfolding le_less
   647     using mult_strict_left_mono by (cases "c = 0") auto
   648   from A show "a * c \<le> b * c"
   649     unfolding le_less
   650     using mult_strict_right_mono by (cases "c = 0") auto
   651 qed
   652 
   653 lemma mult_left_le_imp_le:
   654   "c * a \<le> c * b \<Longrightarrow> 0 < c \<Longrightarrow> a \<le> b"
   655 by (force simp add: mult_strict_left_mono _not_less [symmetric])
   656  
   657 lemma mult_right_le_imp_le:
   658   "a * c \<le> b * c \<Longrightarrow> 0 < c \<Longrightarrow> a \<le> b"
   659 by (force simp add: mult_strict_right_mono not_less [symmetric])
   660 
   661 lemma mult_pos_pos[simp]: "0 < a \<Longrightarrow> 0 < b \<Longrightarrow> 0 < a * b"
   662 using mult_strict_left_mono [of 0 b a] by simp
   663 
   664 lemma mult_pos_neg: "0 < a \<Longrightarrow> b < 0 \<Longrightarrow> a * b < 0"
   665 using mult_strict_left_mono [of b 0 a] by simp
   666 
   667 lemma mult_neg_pos: "a < 0 \<Longrightarrow> 0 < b \<Longrightarrow> a * b < 0"
   668 using mult_strict_right_mono [of a 0 b] by simp
   669 
   670 text {* Legacy - use @{text mult_neg_pos} *}
   671 lemma mult_pos_neg2: "0 < a \<Longrightarrow> b < 0 \<Longrightarrow> b * a < 0" 
   672 by (drule mult_strict_right_mono [of b 0], auto)
   673 
   674 lemma zero_less_mult_pos:
   675   "0 < a * b \<Longrightarrow> 0 < a \<Longrightarrow> 0 < b"
   676 apply (cases "b\<le>0")
   677  apply (auto simp add: le_less not_less)
   678 apply (drule_tac mult_pos_neg [of a b])
   679  apply (auto dest: less_not_sym)
   680 done
   681 
   682 lemma zero_less_mult_pos2:
   683   "0 < b * a \<Longrightarrow> 0 < a \<Longrightarrow> 0 < b"
   684 apply (cases "b\<le>0")
   685  apply (auto simp add: le_less not_less)
   686 apply (drule_tac mult_pos_neg2 [of a b])
   687  apply (auto dest: less_not_sym)
   688 done
   689 
   690 text{*Strict monotonicity in both arguments*}
   691 lemma mult_strict_mono:
   692   assumes "a < b" and "c < d" and "0 < b" and "0 \<le> c"
   693   shows "a * c < b * d"
   694   using assms apply (cases "c=0")
   695   apply (simp)
   696   apply (erule mult_strict_right_mono [THEN less_trans])
   697   apply (force simp add: le_less)
   698   apply (erule mult_strict_left_mono, assumption)
   699   done
   700 
   701 text{*This weaker variant has more natural premises*}
   702 lemma mult_strict_mono':
   703   assumes "a < b" and "c < d" and "0 \<le> a" and "0 \<le> c"
   704   shows "a * c < b * d"
   705 by (rule mult_strict_mono) (insert assms, auto)
   706 
   707 lemma mult_less_le_imp_less:
   708   assumes "a < b" and "c \<le> d" and "0 \<le> a" and "0 < c"
   709   shows "a * c < b * d"
   710   using assms apply (subgoal_tac "a * c < b * c")
   711   apply (erule less_le_trans)
   712   apply (erule mult_left_mono)
   713   apply simp
   714   apply (erule mult_strict_right_mono)
   715   apply assumption
   716   done
   717 
   718 lemma mult_le_less_imp_less:
   719   assumes "a \<le> b" and "c < d" and "0 < a" and "0 \<le> c"
   720   shows "a * c < b * d"
   721   using assms apply (subgoal_tac "a * c \<le> b * c")
   722   apply (erule le_less_trans)
   723   apply (erule mult_strict_left_mono)
   724   apply simp
   725   apply (erule mult_right_mono)
   726   apply simp
   727   done
   728 
   729 end
   730 
   731 class linordered_semiring_1_strict = linordered_semiring_strict + semiring_1
   732 begin
   733 
   734 subclass linordered_semiring_1 ..
   735 
   736 lemma convex_bound_lt:
   737   assumes "x < a" "y < a" "0 \<le> u" "0 \<le> v" "u + v = 1"
   738   shows "u * x + v * y < a"
   739 proof -
   740   from assms have "u * x + v * y < u * a + v * a"
   741     by (cases "u = 0")
   742        (auto intro!: add_less_le_mono mult_strict_left_mono mult_left_mono)
   743   thus ?thesis using assms unfolding distrib_right[symmetric] by simp
   744 qed
   745 
   746 end
   747 
   748 class ordered_comm_semiring = comm_semiring_0 + ordered_ab_semigroup_add + 
   749   assumes comm_mult_left_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> c * a \<le> c * b"
   750 begin
   751 
   752 subclass ordered_semiring
   753 proof
   754   fix a b c :: 'a
   755   assume "a \<le> b" "0 \<le> c"
   756   thus "c * a \<le> c * b" by (rule comm_mult_left_mono)
   757   thus "a * c \<le> b * c" by (simp only: mult.commute)
   758 qed
   759 
   760 end
   761 
   762 class ordered_cancel_comm_semiring = ordered_comm_semiring + cancel_comm_monoid_add
   763 begin
   764 
   765 subclass comm_semiring_0_cancel ..
   766 subclass ordered_comm_semiring ..
   767 subclass ordered_cancel_semiring ..
   768 
   769 end
   770 
   771 class linordered_comm_semiring_strict = comm_semiring_0 + linordered_cancel_ab_semigroup_add +
   772   assumes comm_mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   773 begin
   774 
   775 subclass linordered_semiring_strict
   776 proof
   777   fix a b c :: 'a
   778   assume "a < b" "0 < c"
   779   thus "c * a < c * b" by (rule comm_mult_strict_left_mono)
   780   thus "a * c < b * c" by (simp only: mult.commute)
   781 qed
   782 
   783 subclass ordered_cancel_comm_semiring
   784 proof
   785   fix a b c :: 'a
   786   assume "a \<le> b" "0 \<le> c"
   787   thus "c * a \<le> c * b"
   788     unfolding le_less
   789     using mult_strict_left_mono by (cases "c = 0") auto
   790 qed
   791 
   792 end
   793 
   794 class ordered_ring = ring + ordered_cancel_semiring 
   795 begin
   796 
   797 subclass ordered_ab_group_add ..
   798 
   799 lemma less_add_iff1:
   800   "a * e + c < b * e + d \<longleftrightarrow> (a - b) * e + c < d"
   801 by (simp add: algebra_simps)
   802 
   803 lemma less_add_iff2:
   804   "a * e + c < b * e + d \<longleftrightarrow> c < (b - a) * e + d"
   805 by (simp add: algebra_simps)
   806 
   807 lemma le_add_iff1:
   808   "a * e + c \<le> b * e + d \<longleftrightarrow> (a - b) * e + c \<le> d"
   809 by (simp add: algebra_simps)
   810 
   811 lemma le_add_iff2:
   812   "a * e + c \<le> b * e + d \<longleftrightarrow> c \<le> (b - a) * e + d"
   813 by (simp add: algebra_simps)
   814 
   815 lemma mult_left_mono_neg:
   816   "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> c * a \<le> c * b"
   817   apply (drule mult_left_mono [of _ _ "- c"])
   818   apply simp_all
   819   done
   820 
   821 lemma mult_right_mono_neg:
   822   "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> a * c \<le> b * c"
   823   apply (drule mult_right_mono [of _ _ "- c"])
   824   apply simp_all
   825   done
   826 
   827 lemma mult_nonpos_nonpos: "a \<le> 0 \<Longrightarrow> b \<le> 0 \<Longrightarrow> 0 \<le> a * b"
   828 using mult_right_mono_neg [of a 0 b] by simp
   829 
   830 lemma split_mult_pos_le:
   831   "(0 \<le> a \<and> 0 \<le> b) \<or> (a \<le> 0 \<and> b \<le> 0) \<Longrightarrow> 0 \<le> a * b"
   832 by (auto simp add: mult_nonpos_nonpos)
   833 
   834 end
   835 
   836 class linordered_ring = ring + linordered_semiring + linordered_ab_group_add + abs_if
   837 begin
   838 
   839 subclass ordered_ring ..
   840 
   841 subclass ordered_ab_group_add_abs
   842 proof
   843   fix a b
   844   show "\<bar>a + b\<bar> \<le> \<bar>a\<bar> + \<bar>b\<bar>"
   845     by (auto simp add: abs_if not_le not_less algebra_simps simp del: add.commute dest: add_neg_neg add_nonneg_nonneg)
   846 qed (auto simp add: abs_if)
   847 
   848 lemma zero_le_square [simp]: "0 \<le> a * a"
   849   using linear [of 0 a]
   850   by (auto simp add: mult_nonpos_nonpos)
   851 
   852 lemma not_square_less_zero [simp]: "\<not> (a * a < 0)"
   853   by (simp add: not_less)
   854 
   855 end
   856 
   857 class linordered_ring_strict = ring + linordered_semiring_strict
   858   + ordered_ab_group_add + abs_if
   859 begin
   860 
   861 subclass linordered_ring ..
   862 
   863 lemma mult_strict_left_mono_neg: "b < a \<Longrightarrow> c < 0 \<Longrightarrow> c * a < c * b"
   864 using mult_strict_left_mono [of b a "- c"] by simp
   865 
   866 lemma mult_strict_right_mono_neg: "b < a \<Longrightarrow> c < 0 \<Longrightarrow> a * c < b * c"
   867 using mult_strict_right_mono [of b a "- c"] by simp
   868 
   869 lemma mult_neg_neg: "a < 0 \<Longrightarrow> b < 0 \<Longrightarrow> 0 < a * b"
   870 using mult_strict_right_mono_neg [of a 0 b] by simp
   871 
   872 subclass ring_no_zero_divisors
   873 proof
   874   fix a b
   875   assume "a \<noteq> 0" then have A: "a < 0 \<or> 0 < a" by (simp add: neq_iff)
   876   assume "b \<noteq> 0" then have B: "b < 0 \<or> 0 < b" by (simp add: neq_iff)
   877   have "a * b < 0 \<or> 0 < a * b"
   878   proof (cases "a < 0")
   879     case True note A' = this
   880     show ?thesis proof (cases "b < 0")
   881       case True with A'
   882       show ?thesis by (auto dest: mult_neg_neg)
   883     next
   884       case False with B have "0 < b" by auto
   885       with A' show ?thesis by (auto dest: mult_strict_right_mono)
   886     qed
   887   next
   888     case False with A have A': "0 < a" by auto
   889     show ?thesis proof (cases "b < 0")
   890       case True with A'
   891       show ?thesis by (auto dest: mult_strict_right_mono_neg)
   892     next
   893       case False with B have "0 < b" by auto
   894       with A' show ?thesis by auto
   895     qed
   896   qed
   897   then show "a * b \<noteq> 0" by (simp add: neq_iff)
   898 qed
   899 
   900 lemma zero_less_mult_iff: "0 < a * b \<longleftrightarrow> 0 < a \<and> 0 < b \<or> a < 0 \<and> b < 0"
   901   by (cases a 0 b 0 rule: linorder_cases[case_product linorder_cases])
   902      (auto simp add: mult_neg_neg not_less le_less dest: zero_less_mult_pos zero_less_mult_pos2)
   903 
   904 lemma zero_le_mult_iff: "0 \<le> a * b \<longleftrightarrow> 0 \<le> a \<and> 0 \<le> b \<or> a \<le> 0 \<and> b \<le> 0"
   905   by (auto simp add: eq_commute [of 0] le_less not_less zero_less_mult_iff)
   906 
   907 lemma mult_less_0_iff:
   908   "a * b < 0 \<longleftrightarrow> 0 < a \<and> b < 0 \<or> a < 0 \<and> 0 < b"
   909   apply (insert zero_less_mult_iff [of "-a" b])
   910   apply force
   911   done
   912 
   913 lemma mult_le_0_iff:
   914   "a * b \<le> 0 \<longleftrightarrow> 0 \<le> a \<and> b \<le> 0 \<or> a \<le> 0 \<and> 0 \<le> b"
   915   apply (insert zero_le_mult_iff [of "-a" b]) 
   916   apply force
   917   done
   918 
   919 text{*Cancellation laws for @{term "c*a < c*b"} and @{term "a*c < b*c"},
   920    also with the relations @{text "\<le>"} and equality.*}
   921 
   922 text{*These ``disjunction'' versions produce two cases when the comparison is
   923  an assumption, but effectively four when the comparison is a goal.*}
   924 
   925 lemma mult_less_cancel_right_disj:
   926   "a * c < b * c \<longleftrightarrow> 0 < c \<and> a < b \<or> c < 0 \<and>  b < a"
   927   apply (cases "c = 0")
   928   apply (auto simp add: neq_iff mult_strict_right_mono 
   929                       mult_strict_right_mono_neg)
   930   apply (auto simp add: not_less 
   931                       not_le [symmetric, of "a*c"]
   932                       not_le [symmetric, of a])
   933   apply (erule_tac [!] notE)
   934   apply (auto simp add: less_imp_le mult_right_mono 
   935                       mult_right_mono_neg)
   936   done
   937 
   938 lemma mult_less_cancel_left_disj:
   939   "c * a < c * b \<longleftrightarrow> 0 < c \<and> a < b \<or> c < 0 \<and>  b < a"
   940   apply (cases "c = 0")
   941   apply (auto simp add: neq_iff mult_strict_left_mono 
   942                       mult_strict_left_mono_neg)
   943   apply (auto simp add: not_less 
   944                       not_le [symmetric, of "c*a"]
   945                       not_le [symmetric, of a])
   946   apply (erule_tac [!] notE)
   947   apply (auto simp add: less_imp_le mult_left_mono 
   948                       mult_left_mono_neg)
   949   done
   950 
   951 text{*The ``conjunction of implication'' lemmas produce two cases when the
   952 comparison is a goal, but give four when the comparison is an assumption.*}
   953 
   954 lemma mult_less_cancel_right:
   955   "a * c < b * c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < b) \<and> (c \<le> 0 \<longrightarrow> b < a)"
   956   using mult_less_cancel_right_disj [of a c b] by auto
   957 
   958 lemma mult_less_cancel_left:
   959   "c * a < c * b \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < b) \<and> (c \<le> 0 \<longrightarrow> b < a)"
   960   using mult_less_cancel_left_disj [of c a b] by auto
   961 
   962 lemma mult_le_cancel_right:
   963    "a * c \<le> b * c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   964 by (simp add: not_less [symmetric] mult_less_cancel_right_disj)
   965 
   966 lemma mult_le_cancel_left:
   967   "c * a \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   968 by (simp add: not_less [symmetric] mult_less_cancel_left_disj)
   969 
   970 lemma mult_le_cancel_left_pos:
   971   "0 < c \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> a \<le> b"
   972 by (auto simp: mult_le_cancel_left)
   973 
   974 lemma mult_le_cancel_left_neg:
   975   "c < 0 \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> b \<le> a"
   976 by (auto simp: mult_le_cancel_left)
   977 
   978 lemma mult_less_cancel_left_pos:
   979   "0 < c \<Longrightarrow> c * a < c * b \<longleftrightarrow> a < b"
   980 by (auto simp: mult_less_cancel_left)
   981 
   982 lemma mult_less_cancel_left_neg:
   983   "c < 0 \<Longrightarrow> c * a < c * b \<longleftrightarrow> b < a"
   984 by (auto simp: mult_less_cancel_left)
   985 
   986 end
   987 
   988 lemmas mult_sign_intros =
   989   mult_nonneg_nonneg mult_nonneg_nonpos
   990   mult_nonpos_nonneg mult_nonpos_nonpos
   991   mult_pos_pos mult_pos_neg
   992   mult_neg_pos mult_neg_neg
   993 
   994 class ordered_comm_ring = comm_ring + ordered_comm_semiring
   995 begin
   996 
   997 subclass ordered_ring ..
   998 subclass ordered_cancel_comm_semiring ..
   999 
  1000 end
  1001 
  1002 class linordered_semidom = semidom + linordered_comm_semiring_strict +
  1003   assumes zero_less_one [simp]: "0 < 1"
  1004 begin
  1005 
  1006 lemma pos_add_strict:
  1007   shows "0 < a \<Longrightarrow> b < c \<Longrightarrow> b < a + c"
  1008   using add_strict_mono [of 0 a b c] by simp
  1009 
  1010 lemma zero_le_one [simp]: "0 \<le> 1"
  1011 by (rule zero_less_one [THEN less_imp_le]) 
  1012 
  1013 lemma not_one_le_zero [simp]: "\<not> 1 \<le> 0"
  1014 by (simp add: not_le) 
  1015 
  1016 lemma not_one_less_zero [simp]: "\<not> 1 < 0"
  1017 by (simp add: not_less) 
  1018 
  1019 lemma less_1_mult:
  1020   assumes "1 < m" and "1 < n"
  1021   shows "1 < m * n"
  1022   using assms mult_strict_mono [of 1 m 1 n]
  1023     by (simp add:  less_trans [OF zero_less_one]) 
  1024 
  1025 lemma mult_left_le: "c \<le> 1 \<Longrightarrow> 0 \<le> a \<Longrightarrow> a * c \<le> a"
  1026   using mult_left_mono[of c 1 a] by simp
  1027 
  1028 lemma mult_le_one: "a \<le> 1 \<Longrightarrow> 0 \<le> b \<Longrightarrow> b \<le> 1 \<Longrightarrow> a * b \<le> 1"
  1029   using mult_mono[of a 1 b 1] by simp
  1030 
  1031 end
  1032 
  1033 class linordered_idom = comm_ring_1 +
  1034   linordered_comm_semiring_strict + ordered_ab_group_add +
  1035   abs_if + sgn_if
  1036 begin
  1037 
  1038 subclass linordered_semiring_1_strict ..
  1039 subclass linordered_ring_strict ..
  1040 subclass ordered_comm_ring ..
  1041 subclass idom ..
  1042 
  1043 subclass linordered_semidom
  1044 proof
  1045   have "0 \<le> 1 * 1" by (rule zero_le_square)
  1046   thus "0 < 1" by (simp add: le_less)
  1047 qed 
  1048 
  1049 lemma linorder_neqE_linordered_idom:
  1050   assumes "x \<noteq> y" obtains "x < y" | "y < x"
  1051   using assms by (rule neqE)
  1052 
  1053 text {* These cancellation simprules also produce two cases when the comparison is a goal. *}
  1054 
  1055 lemma mult_le_cancel_right1:
  1056   "c \<le> b * c \<longleftrightarrow> (0 < c \<longrightarrow> 1 \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> 1)"
  1057 by (insert mult_le_cancel_right [of 1 c b], simp)
  1058 
  1059 lemma mult_le_cancel_right2:
  1060   "a * c \<le> c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> 1) \<and> (c < 0 \<longrightarrow> 1 \<le> a)"
  1061 by (insert mult_le_cancel_right [of a c 1], simp)
  1062 
  1063 lemma mult_le_cancel_left1:
  1064   "c \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> 1 \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> 1)"
  1065 by (insert mult_le_cancel_left [of c 1 b], simp)
  1066 
  1067 lemma mult_le_cancel_left2:
  1068   "c * a \<le> c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> 1) \<and> (c < 0 \<longrightarrow> 1 \<le> a)"
  1069 by (insert mult_le_cancel_left [of c a 1], simp)
  1070 
  1071 lemma mult_less_cancel_right1:
  1072   "c < b * c \<longleftrightarrow> (0 \<le> c \<longrightarrow> 1 < b) \<and> (c \<le> 0 \<longrightarrow> b < 1)"
  1073 by (insert mult_less_cancel_right [of 1 c b], simp)
  1074 
  1075 lemma mult_less_cancel_right2:
  1076   "a * c < c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < 1) \<and> (c \<le> 0 \<longrightarrow> 1 < a)"
  1077 by (insert mult_less_cancel_right [of a c 1], simp)
  1078 
  1079 lemma mult_less_cancel_left1:
  1080   "c < c * b \<longleftrightarrow> (0 \<le> c \<longrightarrow> 1 < b) \<and> (c \<le> 0 \<longrightarrow> b < 1)"
  1081 by (insert mult_less_cancel_left [of c 1 b], simp)
  1082 
  1083 lemma mult_less_cancel_left2:
  1084   "c * a < c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < 1) \<and> (c \<le> 0 \<longrightarrow> 1 < a)"
  1085 by (insert mult_less_cancel_left [of c a 1], simp)
  1086 
  1087 lemma sgn_sgn [simp]:
  1088   "sgn (sgn a) = sgn a"
  1089 unfolding sgn_if by simp
  1090 
  1091 lemma sgn_0_0:
  1092   "sgn a = 0 \<longleftrightarrow> a = 0"
  1093 unfolding sgn_if by simp
  1094 
  1095 lemma sgn_1_pos:
  1096   "sgn a = 1 \<longleftrightarrow> a > 0"
  1097 unfolding sgn_if by simp
  1098 
  1099 lemma sgn_1_neg:
  1100   "sgn a = - 1 \<longleftrightarrow> a < 0"
  1101 unfolding sgn_if by auto
  1102 
  1103 lemma sgn_pos [simp]:
  1104   "0 < a \<Longrightarrow> sgn a = 1"
  1105 unfolding sgn_1_pos .
  1106 
  1107 lemma sgn_neg [simp]:
  1108   "a < 0 \<Longrightarrow> sgn a = - 1"
  1109 unfolding sgn_1_neg .
  1110 
  1111 lemma sgn_times:
  1112   "sgn (a * b) = sgn a * sgn b"
  1113 by (auto simp add: sgn_if zero_less_mult_iff)
  1114 
  1115 lemma abs_sgn: "\<bar>k\<bar> = k * sgn k"
  1116 unfolding sgn_if abs_if by auto
  1117 
  1118 lemma sgn_greater [simp]:
  1119   "0 < sgn a \<longleftrightarrow> 0 < a"
  1120   unfolding sgn_if by auto
  1121 
  1122 lemma sgn_less [simp]:
  1123   "sgn a < 0 \<longleftrightarrow> a < 0"
  1124   unfolding sgn_if by auto
  1125 
  1126 lemma abs_dvd_iff [simp]: "\<bar>m\<bar> dvd k \<longleftrightarrow> m dvd k"
  1127   by (simp add: abs_if)
  1128 
  1129 lemma dvd_abs_iff [simp]: "m dvd \<bar>k\<bar> \<longleftrightarrow> m dvd k"
  1130   by (simp add: abs_if)
  1131 
  1132 lemma dvd_if_abs_eq:
  1133   "\<bar>l\<bar> = \<bar>k\<bar> \<Longrightarrow> l dvd k"
  1134 by(subst abs_dvd_iff[symmetric]) simp
  1135 
  1136 text {* The following lemmas can be proven in more general structures, but
  1137 are dangerous as simp rules in absence of @{thm neg_equal_zero}, 
  1138 @{thm neg_less_pos}, @{thm neg_less_eq_nonneg}. *}
  1139 
  1140 lemma equation_minus_iff_1 [simp, no_atp]:
  1141   "1 = - a \<longleftrightarrow> a = - 1"
  1142   by (fact equation_minus_iff)
  1143 
  1144 lemma minus_equation_iff_1 [simp, no_atp]:
  1145   "- a = 1 \<longleftrightarrow> a = - 1"
  1146   by (subst minus_equation_iff, auto)
  1147 
  1148 lemma le_minus_iff_1 [simp, no_atp]:
  1149   "1 \<le> - b \<longleftrightarrow> b \<le> - 1"
  1150   by (fact le_minus_iff)
  1151 
  1152 lemma minus_le_iff_1 [simp, no_atp]:
  1153   "- a \<le> 1 \<longleftrightarrow> - 1 \<le> a"
  1154   by (fact minus_le_iff)
  1155 
  1156 lemma less_minus_iff_1 [simp, no_atp]:
  1157   "1 < - b \<longleftrightarrow> b < - 1"
  1158   by (fact less_minus_iff)
  1159 
  1160 lemma minus_less_iff_1 [simp, no_atp]:
  1161   "- a < 1 \<longleftrightarrow> - 1 < a"
  1162   by (fact minus_less_iff)
  1163 
  1164 end
  1165 
  1166 text {* Simprules for comparisons where common factors can be cancelled. *}
  1167 
  1168 lemmas mult_compare_simps =
  1169     mult_le_cancel_right mult_le_cancel_left
  1170     mult_le_cancel_right1 mult_le_cancel_right2
  1171     mult_le_cancel_left1 mult_le_cancel_left2
  1172     mult_less_cancel_right mult_less_cancel_left
  1173     mult_less_cancel_right1 mult_less_cancel_right2
  1174     mult_less_cancel_left1 mult_less_cancel_left2
  1175     mult_cancel_right mult_cancel_left
  1176     mult_cancel_right1 mult_cancel_right2
  1177     mult_cancel_left1 mult_cancel_left2
  1178 
  1179 text {* Reasoning about inequalities with division *}
  1180 
  1181 context linordered_semidom
  1182 begin
  1183 
  1184 lemma less_add_one: "a < a + 1"
  1185 proof -
  1186   have "a + 0 < a + 1"
  1187     by (blast intro: zero_less_one add_strict_left_mono)
  1188   thus ?thesis by simp
  1189 qed
  1190 
  1191 lemma zero_less_two: "0 < 1 + 1"
  1192 by (blast intro: less_trans zero_less_one less_add_one)
  1193 
  1194 end
  1195 
  1196 context linordered_idom
  1197 begin
  1198 
  1199 lemma mult_right_le_one_le:
  1200   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> y \<le> 1 \<Longrightarrow> x * y \<le> x"
  1201   by (rule mult_left_le)
  1202 
  1203 lemma mult_left_le_one_le:
  1204   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> y \<le> 1 \<Longrightarrow> y * x \<le> x"
  1205   by (auto simp add: mult_le_cancel_right2)
  1206 
  1207 end
  1208 
  1209 text {* Absolute Value *}
  1210 
  1211 context linordered_idom
  1212 begin
  1213 
  1214 lemma mult_sgn_abs:
  1215   "sgn x * \<bar>x\<bar> = x"
  1216   unfolding abs_if sgn_if by auto
  1217 
  1218 lemma abs_one [simp]:
  1219   "\<bar>1\<bar> = 1"
  1220   by (simp add: abs_if)
  1221 
  1222 end
  1223 
  1224 class ordered_ring_abs = ordered_ring + ordered_ab_group_add_abs +
  1225   assumes abs_eq_mult:
  1226     "(0 \<le> a \<or> a \<le> 0) \<and> (0 \<le> b \<or> b \<le> 0) \<Longrightarrow> \<bar>a * b\<bar> = \<bar>a\<bar> * \<bar>b\<bar>"
  1227 
  1228 context linordered_idom
  1229 begin
  1230 
  1231 subclass ordered_ring_abs proof
  1232 qed (auto simp add: abs_if not_less mult_less_0_iff)
  1233 
  1234 lemma abs_mult:
  1235   "\<bar>a * b\<bar> = \<bar>a\<bar> * \<bar>b\<bar>" 
  1236   by (rule abs_eq_mult) auto
  1237 
  1238 lemma abs_mult_self:
  1239   "\<bar>a\<bar> * \<bar>a\<bar> = a * a"
  1240   by (simp add: abs_if) 
  1241 
  1242 lemma abs_mult_less:
  1243   "\<bar>a\<bar> < c \<Longrightarrow> \<bar>b\<bar> < d \<Longrightarrow> \<bar>a\<bar> * \<bar>b\<bar> < c * d"
  1244 proof -
  1245   assume ac: "\<bar>a\<bar> < c"
  1246   hence cpos: "0<c" by (blast intro: le_less_trans abs_ge_zero)
  1247   assume "\<bar>b\<bar> < d"
  1248   thus ?thesis by (simp add: ac cpos mult_strict_mono) 
  1249 qed
  1250 
  1251 lemma abs_less_iff:
  1252   "\<bar>a\<bar> < b \<longleftrightarrow> a < b \<and> - a < b" 
  1253   by (simp add: less_le abs_le_iff) (auto simp add: abs_if)
  1254 
  1255 lemma abs_mult_pos:
  1256   "0 \<le> x \<Longrightarrow> \<bar>y\<bar> * x = \<bar>y * x\<bar>"
  1257   by (simp add: abs_mult)
  1258 
  1259 lemma abs_diff_less_iff:
  1260   "\<bar>x - a\<bar> < r \<longleftrightarrow> a - r < x \<and> x < a + r"
  1261   by (auto simp add: diff_less_eq ac_simps abs_less_iff)
  1262 
  1263 lemma abs_diff_le_iff:
  1264    "\<bar>x - a\<bar> \<le> r \<longleftrightarrow> a - r \<le> x \<and> x \<le> a + r"
  1265   by (auto simp add: diff_le_eq ac_simps abs_le_iff)
  1266 
  1267 end
  1268 
  1269 hide_fact (open) comm_mult_left_mono comm_mult_strict_left_mono distrib
  1270 
  1271 code_identifier
  1272   code_module Rings \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  1273 
  1274 end