src/HOL/Finite_Set.thy
author haftmann
Sun Jul 17 19:48:02 2011 +0200 (2011-07-17)
changeset 43866 8a50dc70cbff
parent 42875 d1aad0957eb2
child 43991 f4a7697011c5
permissions -rw-r--r--
moving UNIV = ... equations to their proper theories
     1 (*  Title:      HOL/Finite_Set.thy
     2     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     3                 with contributions by Jeremy Avigad
     4 *)
     5 
     6 header {* Finite sets *}
     7 
     8 theory Finite_Set
     9 imports Option Power
    10 begin
    11 
    12 subsection {* Predicate for finite sets *}
    13 
    14 inductive finite :: "'a set \<Rightarrow> bool"
    15   where
    16     emptyI [simp, intro!]: "finite {}"
    17   | insertI [simp, intro!]: "finite A \<Longrightarrow> finite (insert a A)"
    18 
    19 lemma finite_induct [case_names empty insert, induct set: finite]:
    20   -- {* Discharging @{text "x \<notin> F"} entails extra work. *}
    21   assumes "finite F"
    22   assumes "P {}"
    23     and insert: "\<And>x F. finite F \<Longrightarrow> x \<notin> F \<Longrightarrow> P F \<Longrightarrow> P (insert x F)"
    24   shows "P F"
    25 using `finite F` proof induct
    26   show "P {}" by fact
    27   fix x F assume F: "finite F" and P: "P F"
    28   show "P (insert x F)"
    29   proof cases
    30     assume "x \<in> F"
    31     hence "insert x F = F" by (rule insert_absorb)
    32     with P show ?thesis by (simp only:)
    33   next
    34     assume "x \<notin> F"
    35     from F this P show ?thesis by (rule insert)
    36   qed
    37 qed
    38 
    39 
    40 subsubsection {* Choice principles *}
    41 
    42 lemma ex_new_if_finite: -- "does not depend on def of finite at all"
    43   assumes "\<not> finite (UNIV :: 'a set)" and "finite A"
    44   shows "\<exists>a::'a. a \<notin> A"
    45 proof -
    46   from assms have "A \<noteq> UNIV" by blast
    47   then show ?thesis by blast
    48 qed
    49 
    50 text {* A finite choice principle. Does not need the SOME choice operator. *}
    51 
    52 lemma finite_set_choice:
    53   "finite A \<Longrightarrow> \<forall>x\<in>A. \<exists>y. P x y \<Longrightarrow> \<exists>f. \<forall>x\<in>A. P x (f x)"
    54 proof (induct rule: finite_induct)
    55   case empty then show ?case by simp
    56 next
    57   case (insert a A)
    58   then obtain f b where f: "ALL x:A. P x (f x)" and ab: "P a b" by auto
    59   show ?case (is "EX f. ?P f")
    60   proof
    61     show "?P(%x. if x = a then b else f x)" using f ab by auto
    62   qed
    63 qed
    64 
    65 
    66 subsubsection {* Finite sets are the images of initial segments of natural numbers *}
    67 
    68 lemma finite_imp_nat_seg_image_inj_on:
    69   assumes "finite A" 
    70   shows "\<exists>(n::nat) f. A = f ` {i. i < n} \<and> inj_on f {i. i < n}"
    71 using assms proof induct
    72   case empty
    73   show ?case
    74   proof
    75     show "\<exists>f. {} = f ` {i::nat. i < 0} \<and> inj_on f {i. i < 0}" by simp 
    76   qed
    77 next
    78   case (insert a A)
    79   have notinA: "a \<notin> A" by fact
    80   from insert.hyps obtain n f
    81     where "A = f ` {i::nat. i < n}" "inj_on f {i. i < n}" by blast
    82   hence "insert a A = f(n:=a) ` {i. i < Suc n}"
    83         "inj_on (f(n:=a)) {i. i < Suc n}" using notinA
    84     by (auto simp add: image_def Ball_def inj_on_def less_Suc_eq)
    85   thus ?case by blast
    86 qed
    87 
    88 lemma nat_seg_image_imp_finite:
    89   "A = f ` {i::nat. i < n} \<Longrightarrow> finite A"
    90 proof (induct n arbitrary: A)
    91   case 0 thus ?case by simp
    92 next
    93   case (Suc n)
    94   let ?B = "f ` {i. i < n}"
    95   have finB: "finite ?B" by(rule Suc.hyps[OF refl])
    96   show ?case
    97   proof cases
    98     assume "\<exists>k<n. f n = f k"
    99     hence "A = ?B" using Suc.prems by(auto simp:less_Suc_eq)
   100     thus ?thesis using finB by simp
   101   next
   102     assume "\<not>(\<exists> k<n. f n = f k)"
   103     hence "A = insert (f n) ?B" using Suc.prems by(auto simp:less_Suc_eq)
   104     thus ?thesis using finB by simp
   105   qed
   106 qed
   107 
   108 lemma finite_conv_nat_seg_image:
   109   "finite A \<longleftrightarrow> (\<exists>(n::nat) f. A = f ` {i::nat. i < n})"
   110   by (blast intro: nat_seg_image_imp_finite dest: finite_imp_nat_seg_image_inj_on)
   111 
   112 lemma finite_imp_inj_to_nat_seg:
   113   assumes "finite A"
   114   shows "\<exists>f n::nat. f ` A = {i. i < n} \<and> inj_on f A"
   115 proof -
   116   from finite_imp_nat_seg_image_inj_on[OF `finite A`]
   117   obtain f and n::nat where bij: "bij_betw f {i. i<n} A"
   118     by (auto simp:bij_betw_def)
   119   let ?f = "the_inv_into {i. i<n} f"
   120   have "inj_on ?f A & ?f ` A = {i. i<n}"
   121     by (fold bij_betw_def) (rule bij_betw_the_inv_into[OF bij])
   122   thus ?thesis by blast
   123 qed
   124 
   125 lemma finite_Collect_less_nat [iff]:
   126   "finite {n::nat. n < k}"
   127   by (fastsimp simp: finite_conv_nat_seg_image)
   128 
   129 lemma finite_Collect_le_nat [iff]:
   130   "finite {n::nat. n \<le> k}"
   131   by (simp add: le_eq_less_or_eq Collect_disj_eq)
   132 
   133 
   134 subsubsection {* Finiteness and common set operations *}
   135 
   136 lemma rev_finite_subset:
   137   "finite B \<Longrightarrow> A \<subseteq> B \<Longrightarrow> finite A"
   138 proof (induct arbitrary: A rule: finite_induct)
   139   case empty
   140   then show ?case by simp
   141 next
   142   case (insert x F A)
   143   have A: "A \<subseteq> insert x F" and r: "A - {x} \<subseteq> F \<Longrightarrow> finite (A - {x})" by fact+
   144   show "finite A"
   145   proof cases
   146     assume x: "x \<in> A"
   147     with A have "A - {x} \<subseteq> F" by (simp add: subset_insert_iff)
   148     with r have "finite (A - {x})" .
   149     hence "finite (insert x (A - {x}))" ..
   150     also have "insert x (A - {x}) = A" using x by (rule insert_Diff)
   151     finally show ?thesis .
   152   next
   153     show "A \<subseteq> F ==> ?thesis" by fact
   154     assume "x \<notin> A"
   155     with A show "A \<subseteq> F" by (simp add: subset_insert_iff)
   156   qed
   157 qed
   158 
   159 lemma finite_subset:
   160   "A \<subseteq> B \<Longrightarrow> finite B \<Longrightarrow> finite A"
   161   by (rule rev_finite_subset)
   162 
   163 lemma finite_UnI:
   164   assumes "finite F" and "finite G"
   165   shows "finite (F \<union> G)"
   166   using assms by induct simp_all
   167 
   168 lemma finite_Un [iff]:
   169   "finite (F \<union> G) \<longleftrightarrow> finite F \<and> finite G"
   170   by (blast intro: finite_UnI finite_subset [of _ "F \<union> G"])
   171 
   172 lemma finite_insert [simp]: "finite (insert a A) \<longleftrightarrow> finite A"
   173 proof -
   174   have "finite {a} \<and> finite A \<longleftrightarrow> finite A" by simp
   175   then have "finite ({a} \<union> A) \<longleftrightarrow> finite A" by (simp only: finite_Un)
   176   then show ?thesis by simp
   177 qed
   178 
   179 lemma finite_Int [simp, intro]:
   180   "finite F \<or> finite G \<Longrightarrow> finite (F \<inter> G)"
   181   by (blast intro: finite_subset)
   182 
   183 lemma finite_Collect_conjI [simp, intro]:
   184   "finite {x. P x} \<or> finite {x. Q x} \<Longrightarrow> finite {x. P x \<and> Q x}"
   185   by (simp add: Collect_conj_eq)
   186 
   187 lemma finite_Collect_disjI [simp]:
   188   "finite {x. P x \<or> Q x} \<longleftrightarrow> finite {x. P x} \<and> finite {x. Q x}"
   189   by (simp add: Collect_disj_eq)
   190 
   191 lemma finite_Diff [simp, intro]:
   192   "finite A \<Longrightarrow> finite (A - B)"
   193   by (rule finite_subset, rule Diff_subset)
   194 
   195 lemma finite_Diff2 [simp]:
   196   assumes "finite B"
   197   shows "finite (A - B) \<longleftrightarrow> finite A"
   198 proof -
   199   have "finite A \<longleftrightarrow> finite((A - B) \<union> (A \<inter> B))" by (simp add: Un_Diff_Int)
   200   also have "\<dots> \<longleftrightarrow> finite (A - B)" using `finite B` by simp
   201   finally show ?thesis ..
   202 qed
   203 
   204 lemma finite_Diff_insert [iff]:
   205   "finite (A - insert a B) \<longleftrightarrow> finite (A - B)"
   206 proof -
   207   have "finite (A - B) \<longleftrightarrow> finite (A - B - {a})" by simp
   208   moreover have "A - insert a B = A - B - {a}" by auto
   209   ultimately show ?thesis by simp
   210 qed
   211 
   212 lemma finite_compl[simp]:
   213   "finite (A :: 'a set) \<Longrightarrow> finite (- A) \<longleftrightarrow> finite (UNIV :: 'a set)"
   214   by (simp add: Compl_eq_Diff_UNIV)
   215 
   216 lemma finite_Collect_not[simp]:
   217   "finite {x :: 'a. P x} \<Longrightarrow> finite {x. \<not> P x} \<longleftrightarrow> finite (UNIV :: 'a set)"
   218   by (simp add: Collect_neg_eq)
   219 
   220 lemma finite_Union [simp, intro]:
   221   "finite A \<Longrightarrow> (\<And>M. M \<in> A \<Longrightarrow> finite M) \<Longrightarrow> finite(\<Union>A)"
   222   by (induct rule: finite_induct) simp_all
   223 
   224 lemma finite_UN_I [intro]:
   225   "finite A \<Longrightarrow> (\<And>a. a \<in> A \<Longrightarrow> finite (B a)) \<Longrightarrow> finite (\<Union>a\<in>A. B a)"
   226   by (induct rule: finite_induct) simp_all
   227 
   228 lemma finite_UN [simp]:
   229   "finite A \<Longrightarrow> finite (UNION A B) \<longleftrightarrow> (\<forall>x\<in>A. finite (B x))"
   230   by (blast intro: finite_subset)
   231 
   232 lemma finite_Inter [intro]:
   233   "\<exists>A\<in>M. finite A \<Longrightarrow> finite (\<Inter>M)"
   234   by (blast intro: Inter_lower finite_subset)
   235 
   236 lemma finite_INT [intro]:
   237   "\<exists>x\<in>I. finite (A x) \<Longrightarrow> finite (\<Inter>x\<in>I. A x)"
   238   by (blast intro: INT_lower finite_subset)
   239 
   240 lemma finite_imageI [simp, intro]:
   241   "finite F \<Longrightarrow> finite (h ` F)"
   242   by (induct rule: finite_induct) simp_all
   243 
   244 lemma finite_image_set [simp]:
   245   "finite {x. P x} \<Longrightarrow> finite { f x | x. P x }"
   246   by (simp add: image_Collect [symmetric])
   247 
   248 lemma finite_imageD:
   249   assumes "finite (f ` A)" and "inj_on f A"
   250   shows "finite A"
   251 using assms proof (induct "f ` A" arbitrary: A)
   252   case empty then show ?case by simp
   253 next
   254   case (insert x B)
   255   then have B_A: "insert x B = f ` A" by simp
   256   then obtain y where "x = f y" and "y \<in> A" by blast
   257   from B_A `x \<notin> B` have "B = f ` A - {x}" by blast
   258   with B_A `x \<notin> B` `x = f y` `inj_on f A` `y \<in> A` have "B = f ` (A - {y})" by (simp add: inj_on_image_set_diff)
   259   moreover from `inj_on f A` have "inj_on f (A - {y})" by (rule inj_on_diff)
   260   ultimately have "finite (A - {y})" by (rule insert.hyps)
   261   then show "finite A" by simp
   262 qed
   263 
   264 lemma finite_surj:
   265   "finite A \<Longrightarrow> B \<subseteq> f ` A \<Longrightarrow> finite B"
   266   by (erule finite_subset) (rule finite_imageI)
   267 
   268 lemma finite_range_imageI:
   269   "finite (range g) \<Longrightarrow> finite (range (\<lambda>x. f (g x)))"
   270   by (drule finite_imageI) (simp add: range_composition)
   271 
   272 lemma finite_subset_image:
   273   assumes "finite B"
   274   shows "B \<subseteq> f ` A \<Longrightarrow> \<exists>C\<subseteq>A. finite C \<and> B = f ` C"
   275 using assms proof induct
   276   case empty then show ?case by simp
   277 next
   278   case insert then show ?case
   279     by (clarsimp simp del: image_insert simp add: image_insert [symmetric])
   280        blast
   281 qed
   282 
   283 lemma finite_vimageI:
   284   "finite F \<Longrightarrow> inj h \<Longrightarrow> finite (h -` F)"
   285   apply (induct rule: finite_induct)
   286    apply simp_all
   287   apply (subst vimage_insert)
   288   apply (simp add: finite_subset [OF inj_vimage_singleton])
   289   done
   290 
   291 lemma finite_vimageD:
   292   assumes fin: "finite (h -` F)" and surj: "surj h"
   293   shows "finite F"
   294 proof -
   295   have "finite (h ` (h -` F))" using fin by (rule finite_imageI)
   296   also have "h ` (h -` F) = F" using surj by (rule surj_image_vimage_eq)
   297   finally show "finite F" .
   298 qed
   299 
   300 lemma finite_vimage_iff: "bij h \<Longrightarrow> finite (h -` F) \<longleftrightarrow> finite F"
   301   unfolding bij_def by (auto elim: finite_vimageD finite_vimageI)
   302 
   303 lemma finite_Collect_bex [simp]:
   304   assumes "finite A"
   305   shows "finite {x. \<exists>y\<in>A. Q x y} \<longleftrightarrow> (\<forall>y\<in>A. finite {x. Q x y})"
   306 proof -
   307   have "{x. \<exists>y\<in>A. Q x y} = (\<Union>y\<in>A. {x. Q x y})" by auto
   308   with assms show ?thesis by simp
   309 qed
   310 
   311 lemma finite_Collect_bounded_ex [simp]:
   312   assumes "finite {y. P y}"
   313   shows "finite {x. \<exists>y. P y \<and> Q x y} \<longleftrightarrow> (\<forall>y. P y \<longrightarrow> finite {x. Q x y})"
   314 proof -
   315   have "{x. EX y. P y & Q x y} = (\<Union>y\<in>{y. P y}. {x. Q x y})" by auto
   316   with assms show ?thesis by simp
   317 qed
   318 
   319 lemma finite_Plus:
   320   "finite A \<Longrightarrow> finite B \<Longrightarrow> finite (A <+> B)"
   321   by (simp add: Plus_def)
   322 
   323 lemma finite_PlusD: 
   324   fixes A :: "'a set" and B :: "'b set"
   325   assumes fin: "finite (A <+> B)"
   326   shows "finite A" "finite B"
   327 proof -
   328   have "Inl ` A \<subseteq> A <+> B" by auto
   329   then have "finite (Inl ` A :: ('a + 'b) set)" using fin by (rule finite_subset)
   330   then show "finite A" by (rule finite_imageD) (auto intro: inj_onI)
   331 next
   332   have "Inr ` B \<subseteq> A <+> B" by auto
   333   then have "finite (Inr ` B :: ('a + 'b) set)" using fin by (rule finite_subset)
   334   then show "finite B" by (rule finite_imageD) (auto intro: inj_onI)
   335 qed
   336 
   337 lemma finite_Plus_iff [simp]:
   338   "finite (A <+> B) \<longleftrightarrow> finite A \<and> finite B"
   339   by (auto intro: finite_PlusD finite_Plus)
   340 
   341 lemma finite_Plus_UNIV_iff [simp]:
   342   "finite (UNIV :: ('a + 'b) set) \<longleftrightarrow> finite (UNIV :: 'a set) \<and> finite (UNIV :: 'b set)"
   343   by (subst UNIV_Plus_UNIV [symmetric]) (rule finite_Plus_iff)
   344 
   345 lemma finite_SigmaI [simp, intro]:
   346   "finite A \<Longrightarrow> (\<And>a. a\<in>A \<Longrightarrow> finite (B a)) ==> finite (SIGMA a:A. B a)"
   347   by (unfold Sigma_def) blast
   348 
   349 lemma finite_cartesian_product:
   350   "finite A \<Longrightarrow> finite B \<Longrightarrow> finite (A \<times> B)"
   351   by (rule finite_SigmaI)
   352 
   353 lemma finite_Prod_UNIV:
   354   "finite (UNIV :: 'a set) \<Longrightarrow> finite (UNIV :: 'b set) \<Longrightarrow> finite (UNIV :: ('a \<times> 'b) set)"
   355   by (simp only: UNIV_Times_UNIV [symmetric] finite_cartesian_product)
   356 
   357 lemma finite_cartesian_productD1:
   358   assumes "finite (A \<times> B)" and "B \<noteq> {}"
   359   shows "finite A"
   360 proof -
   361   from assms obtain n f where "A \<times> B = f ` {i::nat. i < n}"
   362     by (auto simp add: finite_conv_nat_seg_image)
   363   then have "fst ` (A \<times> B) = fst ` f ` {i::nat. i < n}" by simp
   364   with `B \<noteq> {}` have "A = (fst \<circ> f) ` {i::nat. i < n}"
   365     by (simp add: image_compose)
   366   then have "\<exists>n f. A = f ` {i::nat. i < n}" by blast
   367   then show ?thesis
   368     by (auto simp add: finite_conv_nat_seg_image)
   369 qed
   370 
   371 lemma finite_cartesian_productD2:
   372   assumes "finite (A \<times> B)" and "A \<noteq> {}"
   373   shows "finite B"
   374 proof -
   375   from assms obtain n f where "A \<times> B = f ` {i::nat. i < n}"
   376     by (auto simp add: finite_conv_nat_seg_image)
   377   then have "snd ` (A \<times> B) = snd ` f ` {i::nat. i < n}" by simp
   378   with `A \<noteq> {}` have "B = (snd \<circ> f) ` {i::nat. i < n}"
   379     by (simp add: image_compose)
   380   then have "\<exists>n f. B = f ` {i::nat. i < n}" by blast
   381   then show ?thesis
   382     by (auto simp add: finite_conv_nat_seg_image)
   383 qed
   384 
   385 lemma finite_Pow_iff [iff]:
   386   "finite (Pow A) \<longleftrightarrow> finite A"
   387 proof
   388   assume "finite (Pow A)"
   389   then have "finite ((%x. {x}) ` A)" by (blast intro: finite_subset)
   390   then show "finite A" by (rule finite_imageD [unfolded inj_on_def]) simp
   391 next
   392   assume "finite A"
   393   then show "finite (Pow A)"
   394     by induct (simp_all add: Pow_insert)
   395 qed
   396 
   397 corollary finite_Collect_subsets [simp, intro]:
   398   "finite A \<Longrightarrow> finite {B. B \<subseteq> A}"
   399   by (simp add: Pow_def [symmetric])
   400 
   401 lemma finite_UnionD: "finite(\<Union>A) \<Longrightarrow> finite A"
   402   by (blast intro: finite_subset [OF subset_Pow_Union])
   403 
   404 
   405 subsubsection {* Further induction rules on finite sets *}
   406 
   407 lemma finite_ne_induct [case_names singleton insert, consumes 2]:
   408   assumes "finite F" and "F \<noteq> {}"
   409   assumes "\<And>x. P {x}"
   410     and "\<And>x F. finite F \<Longrightarrow> F \<noteq> {} \<Longrightarrow> x \<notin> F \<Longrightarrow> P F  \<Longrightarrow> P (insert x F)"
   411   shows "P F"
   412 using assms proof induct
   413   case empty then show ?case by simp
   414 next
   415   case (insert x F) then show ?case by cases auto
   416 qed
   417 
   418 lemma finite_subset_induct [consumes 2, case_names empty insert]:
   419   assumes "finite F" and "F \<subseteq> A"
   420   assumes empty: "P {}"
   421     and insert: "\<And>a F. finite F \<Longrightarrow> a \<in> A \<Longrightarrow> a \<notin> F \<Longrightarrow> P F \<Longrightarrow> P (insert a F)"
   422   shows "P F"
   423 using `finite F` `F \<subseteq> A` proof induct
   424   show "P {}" by fact
   425 next
   426   fix x F
   427   assume "finite F" and "x \<notin> F" and
   428     P: "F \<subseteq> A \<Longrightarrow> P F" and i: "insert x F \<subseteq> A"
   429   show "P (insert x F)"
   430   proof (rule insert)
   431     from i show "x \<in> A" by blast
   432     from i have "F \<subseteq> A" by blast
   433     with P show "P F" .
   434     show "finite F" by fact
   435     show "x \<notin> F" by fact
   436   qed
   437 qed
   438 
   439 lemma finite_empty_induct:
   440   assumes "finite A"
   441   assumes "P A"
   442     and remove: "\<And>a A. finite A \<Longrightarrow> a \<in> A \<Longrightarrow> P A \<Longrightarrow> P (A - {a})"
   443   shows "P {}"
   444 proof -
   445   have "\<And>B. B \<subseteq> A \<Longrightarrow> P (A - B)"
   446   proof -
   447     fix B :: "'a set"
   448     assume "B \<subseteq> A"
   449     with `finite A` have "finite B" by (rule rev_finite_subset)
   450     from this `B \<subseteq> A` show "P (A - B)"
   451     proof induct
   452       case empty
   453       from `P A` show ?case by simp
   454     next
   455       case (insert b B)
   456       have "P (A - B - {b})"
   457       proof (rule remove)
   458         from `finite A` show "finite (A - B)" by induct auto
   459         from insert show "b \<in> A - B" by simp
   460         from insert show "P (A - B)" by simp
   461       qed
   462       also have "A - B - {b} = A - insert b B" by (rule Diff_insert [symmetric])
   463       finally show ?case .
   464     qed
   465   qed
   466   then have "P (A - A)" by blast
   467   then show ?thesis by simp
   468 qed
   469 
   470 
   471 subsection {* Class @{text finite}  *}
   472 
   473 class finite =
   474   assumes finite_UNIV: "finite (UNIV \<Colon> 'a set)"
   475 begin
   476 
   477 lemma finite [simp]: "finite (A \<Colon> 'a set)"
   478   by (rule subset_UNIV finite_UNIV finite_subset)+
   479 
   480 lemma finite_code [code]: "finite (A \<Colon> 'a set) \<longleftrightarrow> True"
   481   by simp
   482 
   483 end
   484 
   485 instance unit :: finite proof
   486 qed (simp add: UNIV_unit)
   487 
   488 instance bool :: finite proof
   489 qed (simp add: UNIV_bool)
   490 
   491 instance prod :: (finite, finite) finite proof
   492 qed (simp only: UNIV_Times_UNIV [symmetric] finite_cartesian_product finite)
   493 
   494 lemma finite_option_UNIV [simp]:
   495   "finite (UNIV :: 'a option set) = finite (UNIV :: 'a set)"
   496   by (auto simp add: UNIV_option_conv elim: finite_imageD intro: inj_Some)
   497 
   498 instance option :: (finite) finite proof
   499 qed (simp add: UNIV_option_conv)
   500 
   501 lemma inj_graph: "inj (%f. {(x, y). y = f x})"
   502   by (rule inj_onI, auto simp add: set_eq_iff fun_eq_iff)
   503 
   504 instance "fun" :: (finite, finite) finite
   505 proof
   506   show "finite (UNIV :: ('a => 'b) set)"
   507   proof (rule finite_imageD)
   508     let ?graph = "%f::'a => 'b. {(x, y). y = f x}"
   509     have "range ?graph \<subseteq> Pow UNIV" by simp
   510     moreover have "finite (Pow (UNIV :: ('a * 'b) set))"
   511       by (simp only: finite_Pow_iff finite)
   512     ultimately show "finite (range ?graph)"
   513       by (rule finite_subset)
   514     show "inj ?graph" by (rule inj_graph)
   515   qed
   516 qed
   517 
   518 instance sum :: (finite, finite) finite proof
   519 qed (simp only: UNIV_Plus_UNIV [symmetric] finite_Plus finite)
   520 
   521 
   522 subsection {* A basic fold functional for finite sets *}
   523 
   524 text {* The intended behaviour is
   525 @{text "fold f z {x\<^isub>1, ..., x\<^isub>n} = f x\<^isub>1 (\<dots> (f x\<^isub>n z)\<dots>)"}
   526 if @{text f} is ``left-commutative'':
   527 *}
   528 
   529 locale comp_fun_commute =
   530   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b"
   531   assumes comp_fun_commute: "f y \<circ> f x = f x \<circ> f y"
   532 begin
   533 
   534 lemma fun_left_comm: "f x (f y z) = f y (f x z)"
   535   using comp_fun_commute by (simp add: fun_eq_iff)
   536 
   537 end
   538 
   539 inductive fold_graph :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> bool"
   540 for f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b" and z :: 'b where
   541   emptyI [intro]: "fold_graph f z {} z" |
   542   insertI [intro]: "x \<notin> A \<Longrightarrow> fold_graph f z A y
   543       \<Longrightarrow> fold_graph f z (insert x A) (f x y)"
   544 
   545 inductive_cases empty_fold_graphE [elim!]: "fold_graph f z {} x"
   546 
   547 definition fold :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b" where
   548   "fold f z A = (THE y. fold_graph f z A y)"
   549 
   550 text{*A tempting alternative for the definiens is
   551 @{term "if finite A then THE y. fold_graph f z A y else e"}.
   552 It allows the removal of finiteness assumptions from the theorems
   553 @{text fold_comm}, @{text fold_reindex} and @{text fold_distrib}.
   554 The proofs become ugly. It is not worth the effort. (???) *}
   555 
   556 lemma finite_imp_fold_graph: "finite A \<Longrightarrow> \<exists>x. fold_graph f z A x"
   557 by (induct rule: finite_induct) auto
   558 
   559 
   560 subsubsection{*From @{const fold_graph} to @{term fold}*}
   561 
   562 context comp_fun_commute
   563 begin
   564 
   565 lemma fold_graph_insertE_aux:
   566   "fold_graph f z A y \<Longrightarrow> a \<in> A \<Longrightarrow> \<exists>y'. y = f a y' \<and> fold_graph f z (A - {a}) y'"
   567 proof (induct set: fold_graph)
   568   case (insertI x A y) show ?case
   569   proof (cases "x = a")
   570     assume "x = a" with insertI show ?case by auto
   571   next
   572     assume "x \<noteq> a"
   573     then obtain y' where y: "y = f a y'" and y': "fold_graph f z (A - {a}) y'"
   574       using insertI by auto
   575     have "f x y = f a (f x y')"
   576       unfolding y by (rule fun_left_comm)
   577     moreover have "fold_graph f z (insert x A - {a}) (f x y')"
   578       using y' and `x \<noteq> a` and `x \<notin> A`
   579       by (simp add: insert_Diff_if fold_graph.insertI)
   580     ultimately show ?case by fast
   581   qed
   582 qed simp
   583 
   584 lemma fold_graph_insertE:
   585   assumes "fold_graph f z (insert x A) v" and "x \<notin> A"
   586   obtains y where "v = f x y" and "fold_graph f z A y"
   587 using assms by (auto dest: fold_graph_insertE_aux [OF _ insertI1])
   588 
   589 lemma fold_graph_determ:
   590   "fold_graph f z A x \<Longrightarrow> fold_graph f z A y \<Longrightarrow> y = x"
   591 proof (induct arbitrary: y set: fold_graph)
   592   case (insertI x A y v)
   593   from `fold_graph f z (insert x A) v` and `x \<notin> A`
   594   obtain y' where "v = f x y'" and "fold_graph f z A y'"
   595     by (rule fold_graph_insertE)
   596   from `fold_graph f z A y'` have "y' = y" by (rule insertI)
   597   with `v = f x y'` show "v = f x y" by simp
   598 qed fast
   599 
   600 lemma fold_equality:
   601   "fold_graph f z A y \<Longrightarrow> fold f z A = y"
   602 by (unfold fold_def) (blast intro: fold_graph_determ)
   603 
   604 lemma fold_graph_fold:
   605   assumes "finite A"
   606   shows "fold_graph f z A (fold f z A)"
   607 proof -
   608   from assms have "\<exists>x. fold_graph f z A x" by (rule finite_imp_fold_graph)
   609   moreover note fold_graph_determ
   610   ultimately have "\<exists>!x. fold_graph f z A x" by (rule ex_ex1I)
   611   then have "fold_graph f z A (The (fold_graph f z A))" by (rule theI')
   612   then show ?thesis by (unfold fold_def)
   613 qed
   614 
   615 text{* The base case for @{text fold}: *}
   616 
   617 lemma (in -) fold_empty [simp]: "fold f z {} = z"
   618 by (unfold fold_def) blast
   619 
   620 text{* The various recursion equations for @{const fold}: *}
   621 
   622 lemma fold_insert [simp]:
   623   assumes "finite A" and "x \<notin> A"
   624   shows "fold f z (insert x A) = f x (fold f z A)"
   625 proof (rule fold_equality)
   626   from `finite A` have "fold_graph f z A (fold f z A)" by (rule fold_graph_fold)
   627   with `x \<notin> A`show "fold_graph f z (insert x A) (f x (fold f z A))" by (rule fold_graph.insertI)
   628 qed
   629 
   630 lemma fold_fun_comm:
   631   "finite A \<Longrightarrow> f x (fold f z A) = fold f (f x z) A"
   632 proof (induct rule: finite_induct)
   633   case empty then show ?case by simp
   634 next
   635   case (insert y A) then show ?case
   636     by (simp add: fun_left_comm[of x])
   637 qed
   638 
   639 lemma fold_insert2:
   640   "finite A \<Longrightarrow> x \<notin> A \<Longrightarrow> fold f z (insert x A) = fold f (f x z) A"
   641 by (simp add: fold_fun_comm)
   642 
   643 lemma fold_rec:
   644   assumes "finite A" and "x \<in> A"
   645   shows "fold f z A = f x (fold f z (A - {x}))"
   646 proof -
   647   have A: "A = insert x (A - {x})" using `x \<in> A` by blast
   648   then have "fold f z A = fold f z (insert x (A - {x}))" by simp
   649   also have "\<dots> = f x (fold f z (A - {x}))"
   650     by (rule fold_insert) (simp add: `finite A`)+
   651   finally show ?thesis .
   652 qed
   653 
   654 lemma fold_insert_remove:
   655   assumes "finite A"
   656   shows "fold f z (insert x A) = f x (fold f z (A - {x}))"
   657 proof -
   658   from `finite A` have "finite (insert x A)" by auto
   659   moreover have "x \<in> insert x A" by auto
   660   ultimately have "fold f z (insert x A) = f x (fold f z (insert x A - {x}))"
   661     by (rule fold_rec)
   662   then show ?thesis by simp
   663 qed
   664 
   665 end
   666 
   667 text{* A simplified version for idempotent functions: *}
   668 
   669 locale comp_fun_idem = comp_fun_commute +
   670   assumes comp_fun_idem: "f x o f x = f x"
   671 begin
   672 
   673 lemma fun_left_idem: "f x (f x z) = f x z"
   674   using comp_fun_idem by (simp add: fun_eq_iff)
   675 
   676 lemma fold_insert_idem:
   677   assumes fin: "finite A"
   678   shows "fold f z (insert x A) = f x (fold f z A)"
   679 proof cases
   680   assume "x \<in> A"
   681   then obtain B where "A = insert x B" and "x \<notin> B" by (rule set_insert)
   682   then show ?thesis using assms by (simp add:fun_left_idem)
   683 next
   684   assume "x \<notin> A" then show ?thesis using assms by simp
   685 qed
   686 
   687 declare fold_insert[simp del] fold_insert_idem[simp]
   688 
   689 lemma fold_insert_idem2:
   690   "finite A \<Longrightarrow> fold f z (insert x A) = fold f (f x z) A"
   691 by(simp add:fold_fun_comm)
   692 
   693 end
   694 
   695 
   696 subsubsection {* Expressing set operations via @{const fold} *}
   697 
   698 lemma (in comp_fun_commute) comp_comp_fun_commute:
   699   "comp_fun_commute (f \<circ> g)"
   700 proof
   701 qed (simp_all add: comp_fun_commute)
   702 
   703 lemma (in comp_fun_idem) comp_comp_fun_idem:
   704   "comp_fun_idem (f \<circ> g)"
   705   by (rule comp_fun_idem.intro, rule comp_comp_fun_commute, unfold_locales)
   706     (simp_all add: comp_fun_idem)
   707 
   708 lemma comp_fun_idem_insert:
   709   "comp_fun_idem insert"
   710 proof
   711 qed auto
   712 
   713 lemma comp_fun_idem_remove:
   714   "comp_fun_idem (\<lambda>x A. A - {x})"
   715 proof
   716 qed auto
   717 
   718 lemma (in semilattice_inf) comp_fun_idem_inf:
   719   "comp_fun_idem inf"
   720 proof
   721 qed (auto simp add: inf_left_commute)
   722 
   723 lemma (in semilattice_sup) comp_fun_idem_sup:
   724   "comp_fun_idem sup"
   725 proof
   726 qed (auto simp add: sup_left_commute)
   727 
   728 lemma union_fold_insert:
   729   assumes "finite A"
   730   shows "A \<union> B = fold insert B A"
   731 proof -
   732   interpret comp_fun_idem insert by (fact comp_fun_idem_insert)
   733   from `finite A` show ?thesis by (induct A arbitrary: B) simp_all
   734 qed
   735 
   736 lemma minus_fold_remove:
   737   assumes "finite A"
   738   shows "B - A = fold (\<lambda>x A. A - {x}) B A"
   739 proof -
   740   interpret comp_fun_idem "\<lambda>x A. A - {x}" by (fact comp_fun_idem_remove)
   741   from `finite A` show ?thesis by (induct A arbitrary: B) auto
   742 qed
   743 
   744 context complete_lattice
   745 begin
   746 
   747 lemma inf_Inf_fold_inf:
   748   assumes "finite A"
   749   shows "inf B (Inf A) = fold inf B A"
   750 proof -
   751   interpret comp_fun_idem inf by (fact comp_fun_idem_inf)
   752   from `finite A` show ?thesis by (induct A arbitrary: B)
   753     (simp_all add: Inf_insert inf_commute fold_fun_comm)
   754 qed
   755 
   756 lemma sup_Sup_fold_sup:
   757   assumes "finite A"
   758   shows "sup B (Sup A) = fold sup B A"
   759 proof -
   760   interpret comp_fun_idem sup by (fact comp_fun_idem_sup)
   761   from `finite A` show ?thesis by (induct A arbitrary: B)
   762     (simp_all add: Sup_insert sup_commute fold_fun_comm)
   763 qed
   764 
   765 lemma Inf_fold_inf:
   766   assumes "finite A"
   767   shows "Inf A = fold inf top A"
   768   using assms inf_Inf_fold_inf [of A top] by (simp add: inf_absorb2)
   769 
   770 lemma Sup_fold_sup:
   771   assumes "finite A"
   772   shows "Sup A = fold sup bot A"
   773   using assms sup_Sup_fold_sup [of A bot] by (simp add: sup_absorb2)
   774 
   775 lemma inf_INFI_fold_inf:
   776   assumes "finite A"
   777   shows "inf B (INFI A f) = fold (inf \<circ> f) B A" (is "?inf = ?fold") 
   778 proof (rule sym)
   779   interpret comp_fun_idem inf by (fact comp_fun_idem_inf)
   780   interpret comp_fun_idem "inf \<circ> f" by (fact comp_comp_fun_idem)
   781   from `finite A` show "?fold = ?inf"
   782     by (induct A arbitrary: B)
   783       (simp_all add: INFI_def Inf_insert inf_left_commute)
   784 qed
   785 
   786 lemma sup_SUPR_fold_sup:
   787   assumes "finite A"
   788   shows "sup B (SUPR A f) = fold (sup \<circ> f) B A" (is "?sup = ?fold") 
   789 proof (rule sym)
   790   interpret comp_fun_idem sup by (fact comp_fun_idem_sup)
   791   interpret comp_fun_idem "sup \<circ> f" by (fact comp_comp_fun_idem)
   792   from `finite A` show "?fold = ?sup"
   793     by (induct A arbitrary: B)
   794       (simp_all add: SUPR_def Sup_insert sup_left_commute)
   795 qed
   796 
   797 lemma INFI_fold_inf:
   798   assumes "finite A"
   799   shows "INFI A f = fold (inf \<circ> f) top A"
   800   using assms inf_INFI_fold_inf [of A top] by simp
   801 
   802 lemma SUPR_fold_sup:
   803   assumes "finite A"
   804   shows "SUPR A f = fold (sup \<circ> f) bot A"
   805   using assms sup_SUPR_fold_sup [of A bot] by simp
   806 
   807 end
   808 
   809 
   810 subsection {* The derived combinator @{text fold_image} *}
   811 
   812 definition fold_image :: "('b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b"
   813   where "fold_image f g = fold (\<lambda>x y. f (g x) y)"
   814 
   815 lemma fold_image_empty[simp]: "fold_image f g z {} = z"
   816   by (simp add:fold_image_def)
   817 
   818 context ab_semigroup_mult
   819 begin
   820 
   821 lemma fold_image_insert[simp]:
   822   assumes "finite A" and "a \<notin> A"
   823   shows "fold_image times g z (insert a A) = g a * (fold_image times g z A)"
   824 proof -
   825   interpret comp_fun_commute "%x y. (g x) * y" proof
   826   qed (simp add: fun_eq_iff mult_ac)
   827   show ?thesis using assms by (simp add: fold_image_def)
   828 qed
   829 
   830 lemma fold_image_reindex:
   831   assumes "finite A"
   832   shows "inj_on h A \<Longrightarrow> fold_image times g z (h ` A) = fold_image times (g \<circ> h) z A"
   833   using assms by induct auto
   834 
   835 lemma fold_image_cong:
   836   assumes "finite A" and g_h: "\<And>x. x\<in>A \<Longrightarrow> g x = h x"
   837   shows "fold_image times g z A = fold_image times h z A"
   838 proof -
   839   from `finite A`
   840   have "\<And>C. C <= A --> (ALL x:C. g x = h x) --> fold_image times g z C = fold_image times h z C"
   841   proof (induct arbitrary: C)
   842     case empty then show ?case by simp
   843   next
   844     case (insert x F) then show ?case apply -
   845     apply (simp add: subset_insert_iff, clarify)
   846     apply (subgoal_tac "finite C")
   847       prefer 2 apply (blast dest: finite_subset [COMP swap_prems_rl])
   848     apply (subgoal_tac "C = insert x (C - {x})")
   849       prefer 2 apply blast
   850     apply (erule ssubst)
   851     apply (simp add: Ball_def del: insert_Diff_single)
   852     done
   853   qed
   854   with g_h show ?thesis by simp
   855 qed
   856 
   857 end
   858 
   859 context comm_monoid_mult
   860 begin
   861 
   862 lemma fold_image_1:
   863   "finite S \<Longrightarrow> (\<forall>x\<in>S. f x = 1) \<Longrightarrow> fold_image op * f 1 S = 1"
   864   apply (induct rule: finite_induct)
   865   apply simp by auto
   866 
   867 lemma fold_image_Un_Int:
   868   "finite A ==> finite B ==>
   869     fold_image times g 1 A * fold_image times g 1 B =
   870     fold_image times g 1 (A Un B) * fold_image times g 1 (A Int B)"
   871   apply (induct rule: finite_induct)
   872 by (induct set: finite) 
   873    (auto simp add: mult_ac insert_absorb Int_insert_left)
   874 
   875 lemma fold_image_Un_one:
   876   assumes fS: "finite S" and fT: "finite T"
   877   and I0: "\<forall>x \<in> S\<inter>T. f x = 1"
   878   shows "fold_image (op *) f 1 (S \<union> T) = fold_image (op *) f 1 S * fold_image (op *) f 1 T"
   879 proof-
   880   have "fold_image op * f 1 (S \<inter> T) = 1" 
   881     apply (rule fold_image_1)
   882     using fS fT I0 by auto 
   883   with fold_image_Un_Int[OF fS fT] show ?thesis by simp
   884 qed
   885 
   886 corollary fold_Un_disjoint:
   887   "finite A ==> finite B ==> A Int B = {} ==>
   888    fold_image times g 1 (A Un B) =
   889    fold_image times g 1 A * fold_image times g 1 B"
   890 by (simp add: fold_image_Un_Int)
   891 
   892 lemma fold_image_UN_disjoint:
   893   "\<lbrakk> finite I; ALL i:I. finite (A i);
   894      ALL i:I. ALL j:I. i \<noteq> j --> A i Int A j = {} \<rbrakk>
   895    \<Longrightarrow> fold_image times g 1 (UNION I A) =
   896        fold_image times (%i. fold_image times g 1 (A i)) 1 I"
   897 apply (induct rule: finite_induct)
   898 apply simp
   899 apply atomize
   900 apply (subgoal_tac "ALL i:F. x \<noteq> i")
   901  prefer 2 apply blast
   902 apply (subgoal_tac "A x Int UNION F A = {}")
   903  prefer 2 apply blast
   904 apply (simp add: fold_Un_disjoint)
   905 done
   906 
   907 lemma fold_image_Sigma: "finite A ==> ALL x:A. finite (B x) ==>
   908   fold_image times (%x. fold_image times (g x) 1 (B x)) 1 A =
   909   fold_image times (split g) 1 (SIGMA x:A. B x)"
   910 apply (subst Sigma_def)
   911 apply (subst fold_image_UN_disjoint, assumption, simp)
   912  apply blast
   913 apply (erule fold_image_cong)
   914 apply (subst fold_image_UN_disjoint, simp, simp)
   915  apply blast
   916 apply simp
   917 done
   918 
   919 lemma fold_image_distrib: "finite A \<Longrightarrow>
   920    fold_image times (%x. g x * h x) 1 A =
   921    fold_image times g 1 A *  fold_image times h 1 A"
   922 by (erule finite_induct) (simp_all add: mult_ac)
   923 
   924 lemma fold_image_related: 
   925   assumes Re: "R e e" 
   926   and Rop: "\<forall>x1 y1 x2 y2. R x1 x2 \<and> R y1 y2 \<longrightarrow> R (x1 * y1) (x2 * y2)" 
   927   and fS: "finite S" and Rfg: "\<forall>x\<in>S. R (h x) (g x)"
   928   shows "R (fold_image (op *) h e S) (fold_image (op *) g e S)"
   929   using fS by (rule finite_subset_induct) (insert assms, auto)
   930 
   931 lemma  fold_image_eq_general:
   932   assumes fS: "finite S"
   933   and h: "\<forall>y\<in>S'. \<exists>!x. x\<in> S \<and> h(x) = y" 
   934   and f12:  "\<forall>x\<in>S. h x \<in> S' \<and> f2(h x) = f1 x"
   935   shows "fold_image (op *) f1 e S = fold_image (op *) f2 e S'"
   936 proof-
   937   from h f12 have hS: "h ` S = S'" by auto
   938   {fix x y assume H: "x \<in> S" "y \<in> S" "h x = h y"
   939     from f12 h H  have "x = y" by auto }
   940   hence hinj: "inj_on h S" unfolding inj_on_def Ex1_def by blast
   941   from f12 have th: "\<And>x. x \<in> S \<Longrightarrow> (f2 \<circ> h) x = f1 x" by auto 
   942   from hS have "fold_image (op *) f2 e S' = fold_image (op *) f2 e (h ` S)" by simp
   943   also have "\<dots> = fold_image (op *) (f2 o h) e S" 
   944     using fold_image_reindex[OF fS hinj, of f2 e] .
   945   also have "\<dots> = fold_image (op *) f1 e S " using th fold_image_cong[OF fS, of "f2 o h" f1 e]
   946     by blast
   947   finally show ?thesis ..
   948 qed
   949 
   950 lemma fold_image_eq_general_inverses:
   951   assumes fS: "finite S" 
   952   and kh: "\<And>y. y \<in> T \<Longrightarrow> k y \<in> S \<and> h (k y) = y"
   953   and hk: "\<And>x. x \<in> S \<Longrightarrow> h x \<in> T \<and> k (h x) = x  \<and> g (h x) = f x"
   954   shows "fold_image (op *) f e S = fold_image (op *) g e T"
   955   (* metis solves it, but not yet available here *)
   956   apply (rule fold_image_eq_general[OF fS, of T h g f e])
   957   apply (rule ballI)
   958   apply (frule kh)
   959   apply (rule ex1I[])
   960   apply blast
   961   apply clarsimp
   962   apply (drule hk) apply simp
   963   apply (rule sym)
   964   apply (erule conjunct1[OF conjunct2[OF hk]])
   965   apply (rule ballI)
   966   apply (drule  hk)
   967   apply blast
   968   done
   969 
   970 end
   971 
   972 
   973 subsection {* A fold functional for non-empty sets *}
   974 
   975 text{* Does not require start value. *}
   976 
   977 inductive
   978   fold1Set :: "('a => 'a => 'a) => 'a set => 'a => bool"
   979   for f :: "'a => 'a => 'a"
   980 where
   981   fold1Set_insertI [intro]:
   982    "\<lbrakk> fold_graph f a A x; a \<notin> A \<rbrakk> \<Longrightarrow> fold1Set f (insert a A) x"
   983 
   984 definition fold1 :: "('a => 'a => 'a) => 'a set => 'a" where
   985   "fold1 f A == THE x. fold1Set f A x"
   986 
   987 lemma fold1Set_nonempty:
   988   "fold1Set f A x \<Longrightarrow> A \<noteq> {}"
   989 by(erule fold1Set.cases, simp_all)
   990 
   991 inductive_cases empty_fold1SetE [elim!]: "fold1Set f {} x"
   992 
   993 inductive_cases insert_fold1SetE [elim!]: "fold1Set f (insert a X) x"
   994 
   995 
   996 lemma fold1Set_sing [iff]: "(fold1Set f {a} b) = (a = b)"
   997 by (blast elim: fold_graph.cases)
   998 
   999 lemma fold1_singleton [simp]: "fold1 f {a} = a"
  1000 by (unfold fold1_def) blast
  1001 
  1002 lemma finite_nonempty_imp_fold1Set:
  1003   "\<lbrakk> finite A; A \<noteq> {} \<rbrakk> \<Longrightarrow> EX x. fold1Set f A x"
  1004 apply (induct A rule: finite_induct)
  1005 apply (auto dest: finite_imp_fold_graph [of _ f])
  1006 done
  1007 
  1008 text{*First, some lemmas about @{const fold_graph}.*}
  1009 
  1010 context ab_semigroup_mult
  1011 begin
  1012 
  1013 lemma comp_fun_commute: "comp_fun_commute (op *)" proof
  1014 qed (simp add: fun_eq_iff mult_ac)
  1015 
  1016 lemma fold_graph_insert_swap:
  1017 assumes fold: "fold_graph times (b::'a) A y" and "b \<notin> A"
  1018 shows "fold_graph times z (insert b A) (z * y)"
  1019 proof -
  1020   interpret comp_fun_commute "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a" by (rule comp_fun_commute)
  1021 from assms show ?thesis
  1022 proof (induct rule: fold_graph.induct)
  1023   case emptyI show ?case by (subst mult_commute [of z b], fast)
  1024 next
  1025   case (insertI x A y)
  1026     have "fold_graph times z (insert x (insert b A)) (x * (z * y))"
  1027       using insertI by force  --{*how does @{term id} get unfolded?*}
  1028     thus ?case by (simp add: insert_commute mult_ac)
  1029 qed
  1030 qed
  1031 
  1032 lemma fold_graph_permute_diff:
  1033 assumes fold: "fold_graph times b A x"
  1034 shows "!!a. \<lbrakk>a \<in> A; b \<notin> A\<rbrakk> \<Longrightarrow> fold_graph times a (insert b (A-{a})) x"
  1035 using fold
  1036 proof (induct rule: fold_graph.induct)
  1037   case emptyI thus ?case by simp
  1038 next
  1039   case (insertI x A y)
  1040   have "a = x \<or> a \<in> A" using insertI by simp
  1041   thus ?case
  1042   proof
  1043     assume "a = x"
  1044     with insertI show ?thesis
  1045       by (simp add: id_def [symmetric], blast intro: fold_graph_insert_swap)
  1046   next
  1047     assume ainA: "a \<in> A"
  1048     hence "fold_graph times a (insert x (insert b (A - {a}))) (x * y)"
  1049       using insertI by force
  1050     moreover
  1051     have "insert x (insert b (A - {a})) = insert b (insert x A - {a})"
  1052       using ainA insertI by blast
  1053     ultimately show ?thesis by simp
  1054   qed
  1055 qed
  1056 
  1057 lemma fold1_eq_fold:
  1058 assumes "finite A" "a \<notin> A" shows "fold1 times (insert a A) = fold times a A"
  1059 proof -
  1060   interpret comp_fun_commute "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a" by (rule comp_fun_commute)
  1061   from assms show ?thesis
  1062 apply (simp add: fold1_def fold_def)
  1063 apply (rule the_equality)
  1064 apply (best intro: fold_graph_determ theI dest: finite_imp_fold_graph [of _ times])
  1065 apply (rule sym, clarify)
  1066 apply (case_tac "Aa=A")
  1067  apply (best intro: fold_graph_determ)
  1068 apply (subgoal_tac "fold_graph times a A x")
  1069  apply (best intro: fold_graph_determ)
  1070 apply (subgoal_tac "insert aa (Aa - {a}) = A")
  1071  prefer 2 apply (blast elim: equalityE)
  1072 apply (auto dest: fold_graph_permute_diff [where a=a])
  1073 done
  1074 qed
  1075 
  1076 lemma nonempty_iff: "(A \<noteq> {}) = (\<exists>x B. A = insert x B & x \<notin> B)"
  1077 apply safe
  1078  apply simp
  1079  apply (drule_tac x=x in spec)
  1080  apply (drule_tac x="A-{x}" in spec, auto)
  1081 done
  1082 
  1083 lemma fold1_insert:
  1084   assumes nonempty: "A \<noteq> {}" and A: "finite A" "x \<notin> A"
  1085   shows "fold1 times (insert x A) = x * fold1 times A"
  1086 proof -
  1087   interpret comp_fun_commute "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a" by (rule comp_fun_commute)
  1088   from nonempty obtain a A' where "A = insert a A' & a ~: A'"
  1089     by (auto simp add: nonempty_iff)
  1090   with A show ?thesis
  1091     by (simp add: insert_commute [of x] fold1_eq_fold eq_commute)
  1092 qed
  1093 
  1094 end
  1095 
  1096 context ab_semigroup_idem_mult
  1097 begin
  1098 
  1099 lemma comp_fun_idem: "comp_fun_idem (op *)" proof
  1100 qed (simp_all add: fun_eq_iff mult_left_commute)
  1101 
  1102 lemma fold1_insert_idem [simp]:
  1103   assumes nonempty: "A \<noteq> {}" and A: "finite A" 
  1104   shows "fold1 times (insert x A) = x * fold1 times A"
  1105 proof -
  1106   interpret comp_fun_idem "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a"
  1107     by (rule comp_fun_idem)
  1108   from nonempty obtain a A' where A': "A = insert a A' & a ~: A'"
  1109     by (auto simp add: nonempty_iff)
  1110   show ?thesis
  1111   proof cases
  1112     assume a: "a = x"
  1113     show ?thesis
  1114     proof cases
  1115       assume "A' = {}"
  1116       with A' a show ?thesis by simp
  1117     next
  1118       assume "A' \<noteq> {}"
  1119       with A A' a show ?thesis
  1120         by (simp add: fold1_insert mult_assoc [symmetric])
  1121     qed
  1122   next
  1123     assume "a \<noteq> x"
  1124     with A A' show ?thesis
  1125       by (simp add: insert_commute fold1_eq_fold)
  1126   qed
  1127 qed
  1128 
  1129 lemma hom_fold1_commute:
  1130 assumes hom: "!!x y. h (x * y) = h x * h y"
  1131 and N: "finite N" "N \<noteq> {}" shows "h (fold1 times N) = fold1 times (h ` N)"
  1132 using N proof (induct rule: finite_ne_induct)
  1133   case singleton thus ?case by simp
  1134 next
  1135   case (insert n N)
  1136   then have "h (fold1 times (insert n N)) = h (n * fold1 times N)" by simp
  1137   also have "\<dots> = h n * h (fold1 times N)" by(rule hom)
  1138   also have "h (fold1 times N) = fold1 times (h ` N)" by(rule insert)
  1139   also have "times (h n) \<dots> = fold1 times (insert (h n) (h ` N))"
  1140     using insert by(simp)
  1141   also have "insert (h n) (h ` N) = h ` insert n N" by simp
  1142   finally show ?case .
  1143 qed
  1144 
  1145 lemma fold1_eq_fold_idem:
  1146   assumes "finite A"
  1147   shows "fold1 times (insert a A) = fold times a A"
  1148 proof (cases "a \<in> A")
  1149   case False
  1150   with assms show ?thesis by (simp add: fold1_eq_fold)
  1151 next
  1152   interpret comp_fun_idem times by (fact comp_fun_idem)
  1153   case True then obtain b B
  1154     where A: "A = insert a B" and "a \<notin> B" by (rule set_insert)
  1155   with assms have "finite B" by auto
  1156   then have "fold times a (insert a B) = fold times (a * a) B"
  1157     using `a \<notin> B` by (rule fold_insert2)
  1158   then show ?thesis
  1159     using `a \<notin> B` `finite B` by (simp add: fold1_eq_fold A)
  1160 qed
  1161 
  1162 end
  1163 
  1164 
  1165 text{* Now the recursion rules for definitions: *}
  1166 
  1167 lemma fold1_singleton_def: "g = fold1 f \<Longrightarrow> g {a} = a"
  1168 by simp
  1169 
  1170 lemma (in ab_semigroup_mult) fold1_insert_def:
  1171   "\<lbrakk> g = fold1 times; finite A; x \<notin> A; A \<noteq> {} \<rbrakk> \<Longrightarrow> g (insert x A) = x * g A"
  1172 by (simp add:fold1_insert)
  1173 
  1174 lemma (in ab_semigroup_idem_mult) fold1_insert_idem_def:
  1175   "\<lbrakk> g = fold1 times; finite A; A \<noteq> {} \<rbrakk> \<Longrightarrow> g (insert x A) = x * g A"
  1176 by simp
  1177 
  1178 subsubsection{* Determinacy for @{term fold1Set} *}
  1179 
  1180 (*Not actually used!!*)
  1181 (*
  1182 context ab_semigroup_mult
  1183 begin
  1184 
  1185 lemma fold_graph_permute:
  1186   "[|fold_graph times id b (insert a A) x; a \<notin> A; b \<notin> A|]
  1187    ==> fold_graph times id a (insert b A) x"
  1188 apply (cases "a=b") 
  1189 apply (auto dest: fold_graph_permute_diff) 
  1190 done
  1191 
  1192 lemma fold1Set_determ:
  1193   "fold1Set times A x ==> fold1Set times A y ==> y = x"
  1194 proof (clarify elim!: fold1Set.cases)
  1195   fix A x B y a b
  1196   assume Ax: "fold_graph times id a A x"
  1197   assume By: "fold_graph times id b B y"
  1198   assume anotA:  "a \<notin> A"
  1199   assume bnotB:  "b \<notin> B"
  1200   assume eq: "insert a A = insert b B"
  1201   show "y=x"
  1202   proof cases
  1203     assume same: "a=b"
  1204     hence "A=B" using anotA bnotB eq by (blast elim!: equalityE)
  1205     thus ?thesis using Ax By same by (blast intro: fold_graph_determ)
  1206   next
  1207     assume diff: "a\<noteq>b"
  1208     let ?D = "B - {a}"
  1209     have B: "B = insert a ?D" and A: "A = insert b ?D"
  1210      and aB: "a \<in> B" and bA: "b \<in> A"
  1211       using eq anotA bnotB diff by (blast elim!:equalityE)+
  1212     with aB bnotB By
  1213     have "fold_graph times id a (insert b ?D) y" 
  1214       by (auto intro: fold_graph_permute simp add: insert_absorb)
  1215     moreover
  1216     have "fold_graph times id a (insert b ?D) x"
  1217       by (simp add: A [symmetric] Ax) 
  1218     ultimately show ?thesis by (blast intro: fold_graph_determ) 
  1219   qed
  1220 qed
  1221 
  1222 lemma fold1Set_equality: "fold1Set times A y ==> fold1 times A = y"
  1223   by (unfold fold1_def) (blast intro: fold1Set_determ)
  1224 
  1225 end
  1226 *)
  1227 
  1228 declare
  1229   empty_fold_graphE [rule del]  fold_graph.intros [rule del]
  1230   empty_fold1SetE [rule del]  insert_fold1SetE [rule del]
  1231   -- {* No more proofs involve these relations. *}
  1232 
  1233 subsubsection {* Lemmas about @{text fold1} *}
  1234 
  1235 context ab_semigroup_mult
  1236 begin
  1237 
  1238 lemma fold1_Un:
  1239 assumes A: "finite A" "A \<noteq> {}"
  1240 shows "finite B \<Longrightarrow> B \<noteq> {} \<Longrightarrow> A Int B = {} \<Longrightarrow>
  1241        fold1 times (A Un B) = fold1 times A * fold1 times B"
  1242 using A by (induct rule: finite_ne_induct)
  1243   (simp_all add: fold1_insert mult_assoc)
  1244 
  1245 lemma fold1_in:
  1246   assumes A: "finite (A)" "A \<noteq> {}" and elem: "\<And>x y. x * y \<in> {x,y}"
  1247   shows "fold1 times A \<in> A"
  1248 using A
  1249 proof (induct rule:finite_ne_induct)
  1250   case singleton thus ?case by simp
  1251 next
  1252   case insert thus ?case using elem by (force simp add:fold1_insert)
  1253 qed
  1254 
  1255 end
  1256 
  1257 lemma (in ab_semigroup_idem_mult) fold1_Un2:
  1258 assumes A: "finite A" "A \<noteq> {}"
  1259 shows "finite B \<Longrightarrow> B \<noteq> {} \<Longrightarrow>
  1260        fold1 times (A Un B) = fold1 times A * fold1 times B"
  1261 using A
  1262 proof(induct rule:finite_ne_induct)
  1263   case singleton thus ?case by simp
  1264 next
  1265   case insert thus ?case by (simp add: mult_assoc)
  1266 qed
  1267 
  1268 
  1269 subsection {* Locales as mini-packages for fold operations *}
  1270 
  1271 subsubsection {* The natural case *}
  1272 
  1273 locale folding =
  1274   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1275   fixes F :: "'a set \<Rightarrow> 'b \<Rightarrow> 'b"
  1276   assumes comp_fun_commute: "f y \<circ> f x = f x \<circ> f y"
  1277   assumes eq_fold: "finite A \<Longrightarrow> F A s = fold f s A"
  1278 begin
  1279 
  1280 lemma empty [simp]:
  1281   "F {} = id"
  1282   by (simp add: eq_fold fun_eq_iff)
  1283 
  1284 lemma insert [simp]:
  1285   assumes "finite A" and "x \<notin> A"
  1286   shows "F (insert x A) = F A \<circ> f x"
  1287 proof -
  1288   interpret comp_fun_commute f proof
  1289   qed (insert comp_fun_commute, simp add: fun_eq_iff)
  1290   from fold_insert2 assms
  1291   have "\<And>s. fold f s (insert x A) = fold f (f x s) A" .
  1292   with `finite A` show ?thesis by (simp add: eq_fold fun_eq_iff)
  1293 qed
  1294 
  1295 lemma remove:
  1296   assumes "finite A" and "x \<in> A"
  1297   shows "F A = F (A - {x}) \<circ> f x"
  1298 proof -
  1299   from `x \<in> A` obtain B where A: "A = insert x B" and "x \<notin> B"
  1300     by (auto dest: mk_disjoint_insert)
  1301   moreover from `finite A` this have "finite B" by simp
  1302   ultimately show ?thesis by simp
  1303 qed
  1304 
  1305 lemma insert_remove:
  1306   assumes "finite A"
  1307   shows "F (insert x A) = F (A - {x}) \<circ> f x"
  1308   using assms by (cases "x \<in> A") (simp_all add: remove insert_absorb)
  1309 
  1310 lemma commute_left_comp:
  1311   "f y \<circ> (f x \<circ> g) = f x \<circ> (f y \<circ> g)"
  1312   by (simp add: o_assoc comp_fun_commute)
  1313 
  1314 lemma comp_fun_commute':
  1315   assumes "finite A"
  1316   shows "f x \<circ> F A = F A \<circ> f x"
  1317   using assms by (induct A)
  1318     (simp, simp del: o_apply add: o_assoc, simp del: o_apply add: o_assoc [symmetric] comp_fun_commute)
  1319 
  1320 lemma commute_left_comp':
  1321   assumes "finite A"
  1322   shows "f x \<circ> (F A \<circ> g) = F A \<circ> (f x \<circ> g)"
  1323   using assms by (simp add: o_assoc comp_fun_commute')
  1324 
  1325 lemma comp_fun_commute'':
  1326   assumes "finite A" and "finite B"
  1327   shows "F B \<circ> F A = F A \<circ> F B"
  1328   using assms by (induct A)
  1329     (simp_all add: o_assoc, simp add: o_assoc [symmetric] comp_fun_commute')
  1330 
  1331 lemma commute_left_comp'':
  1332   assumes "finite A" and "finite B"
  1333   shows "F B \<circ> (F A \<circ> g) = F A \<circ> (F B \<circ> g)"
  1334   using assms by (simp add: o_assoc comp_fun_commute'')
  1335 
  1336 lemmas comp_fun_commutes = o_assoc [symmetric] comp_fun_commute commute_left_comp
  1337   comp_fun_commute' commute_left_comp' comp_fun_commute'' commute_left_comp''
  1338 
  1339 lemma union_inter:
  1340   assumes "finite A" and "finite B"
  1341   shows "F (A \<union> B) \<circ> F (A \<inter> B) = F A \<circ> F B"
  1342   using assms by (induct A)
  1343     (simp_all del: o_apply add: insert_absorb Int_insert_left comp_fun_commutes,
  1344       simp add: o_assoc)
  1345 
  1346 lemma union:
  1347   assumes "finite A" and "finite B"
  1348   and "A \<inter> B = {}"
  1349   shows "F (A \<union> B) = F A \<circ> F B"
  1350 proof -
  1351   from union_inter `finite A` `finite B` have "F (A \<union> B) \<circ> F (A \<inter> B) = F A \<circ> F B" .
  1352   with `A \<inter> B = {}` show ?thesis by simp
  1353 qed
  1354 
  1355 end
  1356 
  1357 
  1358 subsubsection {* The natural case with idempotency *}
  1359 
  1360 locale folding_idem = folding +
  1361   assumes idem_comp: "f x \<circ> f x = f x"
  1362 begin
  1363 
  1364 lemma idem_left_comp:
  1365   "f x \<circ> (f x \<circ> g) = f x \<circ> g"
  1366   by (simp add: o_assoc idem_comp)
  1367 
  1368 lemma in_comp_idem:
  1369   assumes "finite A" and "x \<in> A"
  1370   shows "F A \<circ> f x = F A"
  1371 using assms by (induct A)
  1372   (auto simp add: comp_fun_commutes idem_comp, simp add: commute_left_comp' [symmetric] comp_fun_commute')
  1373 
  1374 lemma subset_comp_idem:
  1375   assumes "finite A" and "B \<subseteq> A"
  1376   shows "F A \<circ> F B = F A"
  1377 proof -
  1378   from assms have "finite B" by (blast dest: finite_subset)
  1379   then show ?thesis using `B \<subseteq> A` by (induct B)
  1380     (simp_all add: o_assoc in_comp_idem `finite A`)
  1381 qed
  1382 
  1383 declare insert [simp del]
  1384 
  1385 lemma insert_idem [simp]:
  1386   assumes "finite A"
  1387   shows "F (insert x A) = F A \<circ> f x"
  1388   using assms by (cases "x \<in> A") (simp_all add: insert in_comp_idem insert_absorb)
  1389 
  1390 lemma union_idem:
  1391   assumes "finite A" and "finite B"
  1392   shows "F (A \<union> B) = F A \<circ> F B"
  1393 proof -
  1394   from assms have "finite (A \<union> B)" and "A \<inter> B \<subseteq> A \<union> B" by auto
  1395   then have "F (A \<union> B) \<circ> F (A \<inter> B) = F (A \<union> B)" by (rule subset_comp_idem)
  1396   with assms show ?thesis by (simp add: union_inter)
  1397 qed
  1398 
  1399 end
  1400 
  1401 
  1402 subsubsection {* The image case with fixed function *}
  1403 
  1404 no_notation times (infixl "*" 70)
  1405 no_notation Groups.one ("1")
  1406 
  1407 locale folding_image_simple = comm_monoid +
  1408   fixes g :: "('b \<Rightarrow> 'a)"
  1409   fixes F :: "'b set \<Rightarrow> 'a"
  1410   assumes eq_fold_g: "finite A \<Longrightarrow> F A = fold_image f g 1 A"
  1411 begin
  1412 
  1413 lemma empty [simp]:
  1414   "F {} = 1"
  1415   by (simp add: eq_fold_g)
  1416 
  1417 lemma insert [simp]:
  1418   assumes "finite A" and "x \<notin> A"
  1419   shows "F (insert x A) = g x * F A"
  1420 proof -
  1421   interpret comp_fun_commute "%x y. (g x) * y" proof
  1422   qed (simp add: ac_simps fun_eq_iff)
  1423   with assms have "fold_image (op *) g 1 (insert x A) = g x * fold_image (op *) g 1 A"
  1424     by (simp add: fold_image_def)
  1425   with `finite A` show ?thesis by (simp add: eq_fold_g)
  1426 qed
  1427 
  1428 lemma remove:
  1429   assumes "finite A" and "x \<in> A"
  1430   shows "F A = g x * F (A - {x})"
  1431 proof -
  1432   from `x \<in> A` obtain B where A: "A = insert x B" and "x \<notin> B"
  1433     by (auto dest: mk_disjoint_insert)
  1434   moreover from `finite A` this have "finite B" by simp
  1435   ultimately show ?thesis by simp
  1436 qed
  1437 
  1438 lemma insert_remove:
  1439   assumes "finite A"
  1440   shows "F (insert x A) = g x * F (A - {x})"
  1441   using assms by (cases "x \<in> A") (simp_all add: remove insert_absorb)
  1442 
  1443 lemma neutral:
  1444   assumes "finite A" and "\<forall>x\<in>A. g x = 1"
  1445   shows "F A = 1"
  1446   using assms by (induct A) simp_all
  1447 
  1448 lemma union_inter:
  1449   assumes "finite A" and "finite B"
  1450   shows "F (A \<union> B) * F (A \<inter> B) = F A * F B"
  1451 using assms proof (induct A)
  1452   case empty then show ?case by simp
  1453 next
  1454   case (insert x A) then show ?case
  1455     by (auto simp add: insert_absorb Int_insert_left commute [of _ "g x"] assoc left_commute)
  1456 qed
  1457 
  1458 corollary union_inter_neutral:
  1459   assumes "finite A" and "finite B"
  1460   and I0: "\<forall>x \<in> A\<inter>B. g x = 1"
  1461   shows "F (A \<union> B) = F A * F B"
  1462   using assms by (simp add: union_inter [symmetric] neutral)
  1463 
  1464 corollary union_disjoint:
  1465   assumes "finite A" and "finite B"
  1466   assumes "A \<inter> B = {}"
  1467   shows "F (A \<union> B) = F A * F B"
  1468   using assms by (simp add: union_inter_neutral)
  1469 
  1470 end
  1471 
  1472 
  1473 subsubsection {* The image case with flexible function *}
  1474 
  1475 locale folding_image = comm_monoid +
  1476   fixes F :: "('b \<Rightarrow> 'a) \<Rightarrow> 'b set \<Rightarrow> 'a"
  1477   assumes eq_fold: "\<And>g. finite A \<Longrightarrow> F g A = fold_image f g 1 A"
  1478 
  1479 sublocale folding_image < folding_image_simple "op *" 1 g "F g" proof
  1480 qed (fact eq_fold)
  1481 
  1482 context folding_image
  1483 begin
  1484 
  1485 lemma reindex: (* FIXME polymorhism *)
  1486   assumes "finite A" and "inj_on h A"
  1487   shows "F g (h ` A) = F (g \<circ> h) A"
  1488   using assms by (induct A) auto
  1489 
  1490 lemma cong:
  1491   assumes "finite A" and "\<And>x. x \<in> A \<Longrightarrow> g x = h x"
  1492   shows "F g A = F h A"
  1493 proof -
  1494   from assms have "ALL C. C <= A --> (ALL x:C. g x = h x) --> F g C = F h C"
  1495   apply - apply (erule finite_induct) apply simp
  1496   apply (simp add: subset_insert_iff, clarify)
  1497   apply (subgoal_tac "finite C")
  1498   prefer 2 apply (blast dest: finite_subset [COMP swap_prems_rl])
  1499   apply (subgoal_tac "C = insert x (C - {x})")
  1500   prefer 2 apply blast
  1501   apply (erule ssubst)
  1502   apply (drule spec)
  1503   apply (erule (1) notE impE)
  1504   apply (simp add: Ball_def del: insert_Diff_single)
  1505   done
  1506   with assms show ?thesis by simp
  1507 qed
  1508 
  1509 lemma UNION_disjoint:
  1510   assumes "finite I" and "\<forall>i\<in>I. finite (A i)"
  1511   and "\<forall>i\<in>I. \<forall>j\<in>I. i \<noteq> j \<longrightarrow> A i \<inter> A j = {}"
  1512   shows "F g (UNION I A) = F (F g \<circ> A) I"
  1513 apply (insert assms)
  1514 apply (induct rule: finite_induct)
  1515 apply simp
  1516 apply atomize
  1517 apply (subgoal_tac "\<forall>i\<in>Fa. x \<noteq> i")
  1518  prefer 2 apply blast
  1519 apply (subgoal_tac "A x Int UNION Fa A = {}")
  1520  prefer 2 apply blast
  1521 apply (simp add: union_disjoint)
  1522 done
  1523 
  1524 lemma distrib:
  1525   assumes "finite A"
  1526   shows "F (\<lambda>x. g x * h x) A = F g A * F h A"
  1527   using assms by (rule finite_induct) (simp_all add: assoc commute left_commute)
  1528 
  1529 lemma related: 
  1530   assumes Re: "R 1 1" 
  1531   and Rop: "\<forall>x1 y1 x2 y2. R x1 x2 \<and> R y1 y2 \<longrightarrow> R (x1 * y1) (x2 * y2)" 
  1532   and fS: "finite S" and Rfg: "\<forall>x\<in>S. R (h x) (g x)"
  1533   shows "R (F h S) (F g S)"
  1534   using fS by (rule finite_subset_induct) (insert assms, auto)
  1535 
  1536 lemma eq_general:
  1537   assumes fS: "finite S"
  1538   and h: "\<forall>y\<in>S'. \<exists>!x. x \<in> S \<and> h x = y" 
  1539   and f12:  "\<forall>x\<in>S. h x \<in> S' \<and> f2 (h x) = f1 x"
  1540   shows "F f1 S = F f2 S'"
  1541 proof-
  1542   from h f12 have hS: "h ` S = S'" by blast
  1543   {fix x y assume H: "x \<in> S" "y \<in> S" "h x = h y"
  1544     from f12 h H  have "x = y" by auto }
  1545   hence hinj: "inj_on h S" unfolding inj_on_def Ex1_def by blast
  1546   from f12 have th: "\<And>x. x \<in> S \<Longrightarrow> (f2 \<circ> h) x = f1 x" by auto 
  1547   from hS have "F f2 S' = F f2 (h ` S)" by simp
  1548   also have "\<dots> = F (f2 o h) S" using reindex [OF fS hinj, of f2] .
  1549   also have "\<dots> = F f1 S " using th cong [OF fS, of "f2 o h" f1]
  1550     by blast
  1551   finally show ?thesis ..
  1552 qed
  1553 
  1554 lemma eq_general_inverses:
  1555   assumes fS: "finite S" 
  1556   and kh: "\<And>y. y \<in> T \<Longrightarrow> k y \<in> S \<and> h (k y) = y"
  1557   and hk: "\<And>x. x \<in> S \<Longrightarrow> h x \<in> T \<and> k (h x) = x \<and> g (h x) = j x"
  1558   shows "F j S = F g T"
  1559   (* metis solves it, but not yet available here *)
  1560   apply (rule eq_general [OF fS, of T h g j])
  1561   apply (rule ballI)
  1562   apply (frule kh)
  1563   apply (rule ex1I[])
  1564   apply blast
  1565   apply clarsimp
  1566   apply (drule hk) apply simp
  1567   apply (rule sym)
  1568   apply (erule conjunct1[OF conjunct2[OF hk]])
  1569   apply (rule ballI)
  1570   apply (drule hk)
  1571   apply blast
  1572   done
  1573 
  1574 end
  1575 
  1576 
  1577 subsubsection {* The image case with fixed function and idempotency *}
  1578 
  1579 locale folding_image_simple_idem = folding_image_simple +
  1580   assumes idem: "x * x = x"
  1581 
  1582 sublocale folding_image_simple_idem < semilattice proof
  1583 qed (fact idem)
  1584 
  1585 context folding_image_simple_idem
  1586 begin
  1587 
  1588 lemma in_idem:
  1589   assumes "finite A" and "x \<in> A"
  1590   shows "g x * F A = F A"
  1591   using assms by (induct A) (auto simp add: left_commute)
  1592 
  1593 lemma subset_idem:
  1594   assumes "finite A" and "B \<subseteq> A"
  1595   shows "F B * F A = F A"
  1596 proof -
  1597   from assms have "finite B" by (blast dest: finite_subset)
  1598   then show ?thesis using `B \<subseteq> A` by (induct B)
  1599     (auto simp add: assoc in_idem `finite A`)
  1600 qed
  1601 
  1602 declare insert [simp del]
  1603 
  1604 lemma insert_idem [simp]:
  1605   assumes "finite A"
  1606   shows "F (insert x A) = g x * F A"
  1607   using assms by (cases "x \<in> A") (simp_all add: insert in_idem insert_absorb)
  1608 
  1609 lemma union_idem:
  1610   assumes "finite A" and "finite B"
  1611   shows "F (A \<union> B) = F A * F B"
  1612 proof -
  1613   from assms have "finite (A \<union> B)" and "A \<inter> B \<subseteq> A \<union> B" by auto
  1614   then have "F (A \<inter> B) * F (A \<union> B) = F (A \<union> B)" by (rule subset_idem)
  1615   with assms show ?thesis by (simp add: union_inter [of A B, symmetric] commute)
  1616 qed
  1617 
  1618 end
  1619 
  1620 
  1621 subsubsection {* The image case with flexible function and idempotency *}
  1622 
  1623 locale folding_image_idem = folding_image +
  1624   assumes idem: "x * x = x"
  1625 
  1626 sublocale folding_image_idem < folding_image_simple_idem "op *" 1 g "F g" proof
  1627 qed (fact idem)
  1628 
  1629 
  1630 subsubsection {* The neutral-less case *}
  1631 
  1632 locale folding_one = abel_semigroup +
  1633   fixes F :: "'a set \<Rightarrow> 'a"
  1634   assumes eq_fold: "finite A \<Longrightarrow> F A = fold1 f A"
  1635 begin
  1636 
  1637 lemma singleton [simp]:
  1638   "F {x} = x"
  1639   by (simp add: eq_fold)
  1640 
  1641 lemma eq_fold':
  1642   assumes "finite A" and "x \<notin> A"
  1643   shows "F (insert x A) = fold (op *) x A"
  1644 proof -
  1645   interpret ab_semigroup_mult "op *" proof qed (simp_all add: ac_simps)
  1646   with assms show ?thesis by (simp add: eq_fold fold1_eq_fold)
  1647 qed
  1648 
  1649 lemma insert [simp]:
  1650   assumes "finite A" and "x \<notin> A" and "A \<noteq> {}"
  1651   shows "F (insert x A) = x * F A"
  1652 proof -
  1653   from `A \<noteq> {}` obtain b where "b \<in> A" by blast
  1654   then obtain B where *: "A = insert b B" "b \<notin> B" by (blast dest: mk_disjoint_insert)
  1655   with `finite A` have "finite B" by simp
  1656   interpret fold: folding "op *" "\<lambda>a b. fold (op *) b a" proof
  1657   qed (simp_all add: fun_eq_iff ac_simps)
  1658   thm fold.comp_fun_commute' [of B b, simplified fun_eq_iff, simplified]
  1659   from `finite B` fold.comp_fun_commute' [of B x]
  1660     have "op * x \<circ> (\<lambda>b. fold op * b B) = (\<lambda>b. fold op * b B) \<circ> op * x" by simp
  1661   then have A: "x * fold op * b B = fold op * (b * x) B" by (simp add: fun_eq_iff commute)
  1662   from `finite B` * fold.insert [of B b]
  1663     have "(\<lambda>x. fold op * x (insert b B)) = (\<lambda>x. fold op * x B) \<circ> op * b" by simp
  1664   then have B: "fold op * x (insert b B) = fold op * (b * x) B" by (simp add: fun_eq_iff)
  1665   from A B assms * show ?thesis by (simp add: eq_fold' del: fold.insert)
  1666 qed
  1667 
  1668 lemma remove:
  1669   assumes "finite A" and "x \<in> A"
  1670   shows "F A = (if A - {x} = {} then x else x * F (A - {x}))"
  1671 proof -
  1672   from assms obtain B where "A = insert x B" and "x \<notin> B" by (blast dest: mk_disjoint_insert)
  1673   with assms show ?thesis by simp
  1674 qed
  1675 
  1676 lemma insert_remove:
  1677   assumes "finite A"
  1678   shows "F (insert x A) = (if A - {x} = {} then x else x * F (A - {x}))"
  1679   using assms by (cases "x \<in> A") (simp_all add: insert_absorb remove)
  1680 
  1681 lemma union_disjoint:
  1682   assumes "finite A" "A \<noteq> {}" and "finite B" "B \<noteq> {}" and "A \<inter> B = {}"
  1683   shows "F (A \<union> B) = F A * F B"
  1684   using assms by (induct A rule: finite_ne_induct) (simp_all add: ac_simps)
  1685 
  1686 lemma union_inter:
  1687   assumes "finite A" and "finite B" and "A \<inter> B \<noteq> {}"
  1688   shows "F (A \<union> B) * F (A \<inter> B) = F A * F B"
  1689 proof -
  1690   from assms have "A \<noteq> {}" and "B \<noteq> {}" by auto
  1691   from `finite A` `A \<noteq> {}` `A \<inter> B \<noteq> {}` show ?thesis proof (induct A rule: finite_ne_induct)
  1692     case (singleton x) then show ?case by (simp add: insert_absorb ac_simps)
  1693   next
  1694     case (insert x A) show ?case proof (cases "x \<in> B")
  1695       case True then have "B \<noteq> {}" by auto
  1696       with insert True `finite B` show ?thesis by (cases "A \<inter> B = {}")
  1697         (simp_all add: insert_absorb ac_simps union_disjoint)
  1698     next
  1699       case False with insert have "F (A \<union> B) * F (A \<inter> B) = F A * F B" by simp
  1700       moreover from False `finite B` insert have "finite (A \<union> B)" "x \<notin> A \<union> B" "A \<union> B \<noteq> {}"
  1701         by auto
  1702       ultimately show ?thesis using False `finite A` `x \<notin> A` `A \<noteq> {}` by (simp add: assoc)
  1703     qed
  1704   qed
  1705 qed
  1706 
  1707 lemma closed:
  1708   assumes "finite A" "A \<noteq> {}" and elem: "\<And>x y. x * y \<in> {x, y}"
  1709   shows "F A \<in> A"
  1710 using `finite A` `A \<noteq> {}` proof (induct rule: finite_ne_induct)
  1711   case singleton then show ?case by simp
  1712 next
  1713   case insert with elem show ?case by force
  1714 qed
  1715 
  1716 end
  1717 
  1718 
  1719 subsubsection {* The neutral-less case with idempotency *}
  1720 
  1721 locale folding_one_idem = folding_one +
  1722   assumes idem: "x * x = x"
  1723 
  1724 sublocale folding_one_idem < semilattice proof
  1725 qed (fact idem)
  1726 
  1727 context folding_one_idem
  1728 begin
  1729 
  1730 lemma in_idem:
  1731   assumes "finite A" and "x \<in> A"
  1732   shows "x * F A = F A"
  1733 proof -
  1734   from assms have "A \<noteq> {}" by auto
  1735   with `finite A` show ?thesis using `x \<in> A` by (induct A rule: finite_ne_induct) (auto simp add: ac_simps)
  1736 qed
  1737 
  1738 lemma subset_idem:
  1739   assumes "finite A" "B \<noteq> {}" and "B \<subseteq> A"
  1740   shows "F B * F A = F A"
  1741 proof -
  1742   from assms have "finite B" by (blast dest: finite_subset)
  1743   then show ?thesis using `B \<noteq> {}` `B \<subseteq> A` by (induct B rule: finite_ne_induct)
  1744     (simp_all add: assoc in_idem `finite A`)
  1745 qed
  1746 
  1747 lemma eq_fold_idem':
  1748   assumes "finite A"
  1749   shows "F (insert a A) = fold (op *) a A"
  1750 proof -
  1751   interpret ab_semigroup_idem_mult "op *" proof qed (simp_all add: ac_simps)
  1752   with assms show ?thesis by (simp add: eq_fold fold1_eq_fold_idem)
  1753 qed
  1754 
  1755 lemma insert_idem [simp]:
  1756   assumes "finite A" and "A \<noteq> {}"
  1757   shows "F (insert x A) = x * F A"
  1758 proof (cases "x \<in> A")
  1759   case False from `finite A` `x \<notin> A` `A \<noteq> {}` show ?thesis by (rule insert)
  1760 next
  1761   case True
  1762   from `finite A` `A \<noteq> {}` show ?thesis by (simp add: in_idem insert_absorb True)
  1763 qed
  1764   
  1765 lemma union_idem:
  1766   assumes "finite A" "A \<noteq> {}" and "finite B" "B \<noteq> {}"
  1767   shows "F (A \<union> B) = F A * F B"
  1768 proof (cases "A \<inter> B = {}")
  1769   case True with assms show ?thesis by (simp add: union_disjoint)
  1770 next
  1771   case False
  1772   from assms have "finite (A \<union> B)" and "A \<inter> B \<subseteq> A \<union> B" by auto
  1773   with False have "F (A \<inter> B) * F (A \<union> B) = F (A \<union> B)" by (auto intro: subset_idem)
  1774   with assms False show ?thesis by (simp add: union_inter [of A B, symmetric] commute)
  1775 qed
  1776 
  1777 lemma hom_commute:
  1778   assumes hom: "\<And>x y. h (x * y) = h x * h y"
  1779   and N: "finite N" "N \<noteq> {}" shows "h (F N) = F (h ` N)"
  1780 using N proof (induct rule: finite_ne_induct)
  1781   case singleton thus ?case by simp
  1782 next
  1783   case (insert n N)
  1784   then have "h (F (insert n N)) = h (n * F N)" by simp
  1785   also have "\<dots> = h n * h (F N)" by (rule hom)
  1786   also have "h (F N) = F (h ` N)" by(rule insert)
  1787   also have "h n * \<dots> = F (insert (h n) (h ` N))"
  1788     using insert by(simp)
  1789   also have "insert (h n) (h ` N) = h ` insert n N" by simp
  1790   finally show ?case .
  1791 qed
  1792 
  1793 end
  1794 
  1795 notation times (infixl "*" 70)
  1796 notation Groups.one ("1")
  1797 
  1798 
  1799 subsection {* Finite cardinality *}
  1800 
  1801 text {* This definition, although traditional, is ugly to work with:
  1802 @{text "card A == LEAST n. EX f. A = {f i | i. i < n}"}.
  1803 But now that we have @{text fold_image} things are easy:
  1804 *}
  1805 
  1806 definition card :: "'a set \<Rightarrow> nat" where
  1807   "card A = (if finite A then fold_image (op +) (\<lambda>x. 1) 0 A else 0)"
  1808 
  1809 interpretation card: folding_image_simple "op +" 0 "\<lambda>x. 1" card proof
  1810 qed (simp add: card_def)
  1811 
  1812 lemma card_infinite [simp]:
  1813   "\<not> finite A \<Longrightarrow> card A = 0"
  1814   by (simp add: card_def)
  1815 
  1816 lemma card_empty:
  1817   "card {} = 0"
  1818   by (fact card.empty)
  1819 
  1820 lemma card_insert_disjoint:
  1821   "finite A ==> x \<notin> A ==> card (insert x A) = Suc (card A)"
  1822   by simp
  1823 
  1824 lemma card_insert_if:
  1825   "finite A ==> card (insert x A) = (if x \<in> A then card A else Suc (card A))"
  1826   by auto (simp add: card.insert_remove card.remove)
  1827 
  1828 lemma card_ge_0_finite:
  1829   "card A > 0 \<Longrightarrow> finite A"
  1830   by (rule ccontr) simp
  1831 
  1832 lemma card_0_eq [simp, no_atp]:
  1833   "finite A \<Longrightarrow> card A = 0 \<longleftrightarrow> A = {}"
  1834   by (auto dest: mk_disjoint_insert)
  1835 
  1836 lemma finite_UNIV_card_ge_0:
  1837   "finite (UNIV :: 'a set) \<Longrightarrow> card (UNIV :: 'a set) > 0"
  1838   by (rule ccontr) simp
  1839 
  1840 lemma card_eq_0_iff:
  1841   "card A = 0 \<longleftrightarrow> A = {} \<or> \<not> finite A"
  1842   by auto
  1843 
  1844 lemma card_gt_0_iff:
  1845   "0 < card A \<longleftrightarrow> A \<noteq> {} \<and> finite A"
  1846   by (simp add: neq0_conv [symmetric] card_eq_0_iff) 
  1847 
  1848 lemma card_Suc_Diff1: "finite A ==> x: A ==> Suc (card (A - {x})) = card A"
  1849 apply(rule_tac t = A in insert_Diff [THEN subst], assumption)
  1850 apply(simp del:insert_Diff_single)
  1851 done
  1852 
  1853 lemma card_Diff_singleton:
  1854   "finite A ==> x: A ==> card (A - {x}) = card A - 1"
  1855 by (simp add: card_Suc_Diff1 [symmetric])
  1856 
  1857 lemma card_Diff_singleton_if:
  1858   "finite A ==> card (A-{x}) = (if x : A then card A - 1 else card A)"
  1859 by (simp add: card_Diff_singleton)
  1860 
  1861 lemma card_Diff_insert[simp]:
  1862 assumes "finite A" and "a:A" and "a ~: B"
  1863 shows "card(A - insert a B) = card(A - B) - 1"
  1864 proof -
  1865   have "A - insert a B = (A - B) - {a}" using assms by blast
  1866   then show ?thesis using assms by(simp add:card_Diff_singleton)
  1867 qed
  1868 
  1869 lemma card_insert: "finite A ==> card (insert x A) = Suc (card (A - {x}))"
  1870 by (simp add: card_insert_if card_Suc_Diff1 del:card_Diff_insert)
  1871 
  1872 lemma card_insert_le: "finite A ==> card A <= card (insert x A)"
  1873 by (simp add: card_insert_if)
  1874 
  1875 lemma card_Collect_less_nat[simp]: "card{i::nat. i < n} = n"
  1876 by (induct n) (simp_all add:less_Suc_eq Collect_disj_eq)
  1877 
  1878 lemma card_Collect_le_nat[simp]: "card{i::nat. i <= n} = Suc n"
  1879 using card_Collect_less_nat[of "Suc n"] by(simp add: less_Suc_eq_le)
  1880 
  1881 lemma card_mono:
  1882   assumes "finite B" and "A \<subseteq> B"
  1883   shows "card A \<le> card B"
  1884 proof -
  1885   from assms have "finite A" by (auto intro: finite_subset)
  1886   then show ?thesis using assms proof (induct A arbitrary: B)
  1887     case empty then show ?case by simp
  1888   next
  1889     case (insert x A)
  1890     then have "x \<in> B" by simp
  1891     from insert have "A \<subseteq> B - {x}" and "finite (B - {x})" by auto
  1892     with insert.hyps have "card A \<le> card (B - {x})" by auto
  1893     with `finite A` `x \<notin> A` `finite B` `x \<in> B` show ?case by simp (simp only: card.remove)
  1894   qed
  1895 qed
  1896 
  1897 lemma card_seteq: "finite B ==> (!!A. A <= B ==> card B <= card A ==> A = B)"
  1898 apply (induct rule: finite_induct)
  1899 apply simp
  1900 apply clarify
  1901 apply (subgoal_tac "finite A & A - {x} <= F")
  1902  prefer 2 apply (blast intro: finite_subset, atomize)
  1903 apply (drule_tac x = "A - {x}" in spec)
  1904 apply (simp add: card_Diff_singleton_if split add: split_if_asm)
  1905 apply (case_tac "card A", auto)
  1906 done
  1907 
  1908 lemma psubset_card_mono: "finite B ==> A < B ==> card A < card B"
  1909 apply (simp add: psubset_eq linorder_not_le [symmetric])
  1910 apply (blast dest: card_seteq)
  1911 done
  1912 
  1913 lemma card_Un_Int: "finite A ==> finite B
  1914     ==> card A + card B = card (A Un B) + card (A Int B)"
  1915   by (fact card.union_inter [symmetric])
  1916 
  1917 lemma card_Un_disjoint: "finite A ==> finite B
  1918     ==> A Int B = {} ==> card (A Un B) = card A + card B"
  1919   by (fact card.union_disjoint)
  1920 
  1921 lemma card_Diff_subset:
  1922   assumes "finite B" and "B \<subseteq> A"
  1923   shows "card (A - B) = card A - card B"
  1924 proof (cases "finite A")
  1925   case False with assms show ?thesis by simp
  1926 next
  1927   case True with assms show ?thesis by (induct B arbitrary: A) simp_all
  1928 qed
  1929 
  1930 lemma card_Diff_subset_Int:
  1931   assumes AB: "finite (A \<inter> B)" shows "card (A - B) = card A - card (A \<inter> B)"
  1932 proof -
  1933   have "A - B = A - A \<inter> B" by auto
  1934   thus ?thesis
  1935     by (simp add: card_Diff_subset AB) 
  1936 qed
  1937 
  1938 lemma diff_card_le_card_Diff:
  1939 assumes "finite B" shows "card A - card B \<le> card(A - B)"
  1940 proof-
  1941   have "card A - card B \<le> card A - card (A \<inter> B)"
  1942     using card_mono[OF assms Int_lower2, of A] by arith
  1943   also have "\<dots> = card(A-B)" using assms by(simp add: card_Diff_subset_Int)
  1944   finally show ?thesis .
  1945 qed
  1946 
  1947 lemma card_Diff1_less: "finite A ==> x: A ==> card (A - {x}) < card A"
  1948 apply (rule Suc_less_SucD)
  1949 apply (simp add: card_Suc_Diff1 del:card_Diff_insert)
  1950 done
  1951 
  1952 lemma card_Diff2_less:
  1953   "finite A ==> x: A ==> y: A ==> card (A - {x} - {y}) < card A"
  1954 apply (case_tac "x = y")
  1955  apply (simp add: card_Diff1_less del:card_Diff_insert)
  1956 apply (rule less_trans)
  1957  prefer 2 apply (auto intro!: card_Diff1_less simp del:card_Diff_insert)
  1958 done
  1959 
  1960 lemma card_Diff1_le: "finite A ==> card (A - {x}) <= card A"
  1961 apply (case_tac "x : A")
  1962  apply (simp_all add: card_Diff1_less less_imp_le)
  1963 done
  1964 
  1965 lemma card_psubset: "finite B ==> A \<subseteq> B ==> card A < card B ==> A < B"
  1966 by (erule psubsetI, blast)
  1967 
  1968 lemma insert_partition:
  1969   "\<lbrakk> x \<notin> F; \<forall>c1 \<in> insert x F. \<forall>c2 \<in> insert x F. c1 \<noteq> c2 \<longrightarrow> c1 \<inter> c2 = {} \<rbrakk>
  1970   \<Longrightarrow> x \<inter> \<Union> F = {}"
  1971 by auto
  1972 
  1973 lemma finite_psubset_induct[consumes 1, case_names psubset]:
  1974   assumes fin: "finite A" 
  1975   and     major: "\<And>A. finite A \<Longrightarrow> (\<And>B. B \<subset> A \<Longrightarrow> P B) \<Longrightarrow> P A" 
  1976   shows "P A"
  1977 using fin
  1978 proof (induct A taking: card rule: measure_induct_rule)
  1979   case (less A)
  1980   have fin: "finite A" by fact
  1981   have ih: "\<And>B. \<lbrakk>card B < card A; finite B\<rbrakk> \<Longrightarrow> P B" by fact
  1982   { fix B 
  1983     assume asm: "B \<subset> A"
  1984     from asm have "card B < card A" using psubset_card_mono fin by blast
  1985     moreover
  1986     from asm have "B \<subseteq> A" by auto
  1987     then have "finite B" using fin finite_subset by blast
  1988     ultimately 
  1989     have "P B" using ih by simp
  1990   }
  1991   with fin show "P A" using major by blast
  1992 qed
  1993 
  1994 text{* main cardinality theorem *}
  1995 lemma card_partition [rule_format]:
  1996   "finite C ==>
  1997      finite (\<Union> C) -->
  1998      (\<forall>c\<in>C. card c = k) -->
  1999      (\<forall>c1 \<in> C. \<forall>c2 \<in> C. c1 \<noteq> c2 --> c1 \<inter> c2 = {}) -->
  2000      k * card(C) = card (\<Union> C)"
  2001 apply (erule finite_induct, simp)
  2002 apply (simp add: card_Un_disjoint insert_partition 
  2003        finite_subset [of _ "\<Union> (insert x F)"])
  2004 done
  2005 
  2006 lemma card_eq_UNIV_imp_eq_UNIV:
  2007   assumes fin: "finite (UNIV :: 'a set)"
  2008   and card: "card A = card (UNIV :: 'a set)"
  2009   shows "A = (UNIV :: 'a set)"
  2010 proof
  2011   show "A \<subseteq> UNIV" by simp
  2012   show "UNIV \<subseteq> A"
  2013   proof
  2014     fix x
  2015     show "x \<in> A"
  2016     proof (rule ccontr)
  2017       assume "x \<notin> A"
  2018       then have "A \<subset> UNIV" by auto
  2019       with fin have "card A < card (UNIV :: 'a set)" by (fact psubset_card_mono)
  2020       with card show False by simp
  2021     qed
  2022   qed
  2023 qed
  2024 
  2025 text{*The form of a finite set of given cardinality*}
  2026 
  2027 lemma card_eq_SucD:
  2028 assumes "card A = Suc k"
  2029 shows "\<exists>b B. A = insert b B & b \<notin> B & card B = k & (k=0 \<longrightarrow> B={})"
  2030 proof -
  2031   have fin: "finite A" using assms by (auto intro: ccontr)
  2032   moreover have "card A \<noteq> 0" using assms by auto
  2033   ultimately obtain b where b: "b \<in> A" by auto
  2034   show ?thesis
  2035   proof (intro exI conjI)
  2036     show "A = insert b (A-{b})" using b by blast
  2037     show "b \<notin> A - {b}" by blast
  2038     show "card (A - {b}) = k" and "k = 0 \<longrightarrow> A - {b} = {}"
  2039       using assms b fin by(fastsimp dest:mk_disjoint_insert)+
  2040   qed
  2041 qed
  2042 
  2043 lemma card_Suc_eq:
  2044   "(card A = Suc k) =
  2045    (\<exists>b B. A = insert b B & b \<notin> B & card B = k & (k=0 \<longrightarrow> B={}))"
  2046 apply(rule iffI)
  2047  apply(erule card_eq_SucD)
  2048 apply(auto)
  2049 apply(subst card_insert)
  2050  apply(auto intro:ccontr)
  2051 done
  2052 
  2053 lemma finite_fun_UNIVD2:
  2054   assumes fin: "finite (UNIV :: ('a \<Rightarrow> 'b) set)"
  2055   shows "finite (UNIV :: 'b set)"
  2056 proof -
  2057   from fin have "finite (range (\<lambda>f :: 'a \<Rightarrow> 'b. f arbitrary))"
  2058     by(rule finite_imageI)
  2059   moreover have "UNIV = range (\<lambda>f :: 'a \<Rightarrow> 'b. f arbitrary)"
  2060     by(rule UNIV_eq_I) auto
  2061   ultimately show "finite (UNIV :: 'b set)" by simp
  2062 qed
  2063 
  2064 lemma card_UNIV_unit: "card (UNIV :: unit set) = 1"
  2065   unfolding UNIV_unit by simp
  2066 
  2067 
  2068 subsubsection {* Cardinality of image *}
  2069 
  2070 lemma card_image_le: "finite A ==> card (f ` A) <= card A"
  2071 apply (induct rule: finite_induct)
  2072  apply simp
  2073 apply (simp add: le_SucI card_insert_if)
  2074 done
  2075 
  2076 lemma card_image:
  2077   assumes "inj_on f A"
  2078   shows "card (f ` A) = card A"
  2079 proof (cases "finite A")
  2080   case True then show ?thesis using assms by (induct A) simp_all
  2081 next
  2082   case False then have "\<not> finite (f ` A)" using assms by (auto dest: finite_imageD)
  2083   with False show ?thesis by simp
  2084 qed
  2085 
  2086 lemma bij_betw_same_card: "bij_betw f A B \<Longrightarrow> card A = card B"
  2087 by(auto simp: card_image bij_betw_def)
  2088 
  2089 lemma endo_inj_surj: "finite A ==> f ` A \<subseteq> A ==> inj_on f A ==> f ` A = A"
  2090 by (simp add: card_seteq card_image)
  2091 
  2092 lemma eq_card_imp_inj_on:
  2093   "[| finite A; card(f ` A) = card A |] ==> inj_on f A"
  2094 apply (induct rule:finite_induct)
  2095 apply simp
  2096 apply(frule card_image_le[where f = f])
  2097 apply(simp add:card_insert_if split:if_splits)
  2098 done
  2099 
  2100 lemma inj_on_iff_eq_card:
  2101   "finite A ==> inj_on f A = (card(f ` A) = card A)"
  2102 by(blast intro: card_image eq_card_imp_inj_on)
  2103 
  2104 
  2105 lemma card_inj_on_le:
  2106   "[|inj_on f A; f ` A \<subseteq> B; finite B |] ==> card A \<le> card B"
  2107 apply (subgoal_tac "finite A") 
  2108  apply (force intro: card_mono simp add: card_image [symmetric])
  2109 apply (blast intro: finite_imageD dest: finite_subset) 
  2110 done
  2111 
  2112 lemma card_bij_eq:
  2113   "[|inj_on f A; f ` A \<subseteq> B; inj_on g B; g ` B \<subseteq> A;
  2114      finite A; finite B |] ==> card A = card B"
  2115 by (auto intro: le_antisym card_inj_on_le)
  2116 
  2117 lemma bij_betw_finite:
  2118   assumes "bij_betw f A B"
  2119   shows "finite A \<longleftrightarrow> finite B"
  2120 using assms unfolding bij_betw_def
  2121 using finite_imageD[of f A] by auto
  2122 
  2123 
  2124 subsubsection {* Pigeonhole Principles *}
  2125 
  2126 lemma pigeonhole: "card A > card(f ` A) \<Longrightarrow> ~ inj_on f A "
  2127 by (auto dest: card_image less_irrefl_nat)
  2128 
  2129 lemma pigeonhole_infinite:
  2130 assumes  "~ finite A" and "finite(f`A)"
  2131 shows "EX a0:A. ~finite{a:A. f a = f a0}"
  2132 proof -
  2133   have "finite(f`A) \<Longrightarrow> ~ finite A \<Longrightarrow> EX a0:A. ~finite{a:A. f a = f a0}"
  2134   proof(induct "f`A" arbitrary: A rule: finite_induct)
  2135     case empty thus ?case by simp
  2136   next
  2137     case (insert b F)
  2138     show ?case
  2139     proof cases
  2140       assume "finite{a:A. f a = b}"
  2141       hence "~ finite(A - {a:A. f a = b})" using `\<not> finite A` by simp
  2142       also have "A - {a:A. f a = b} = {a:A. f a \<noteq> b}" by blast
  2143       finally have "~ finite({a:A. f a \<noteq> b})" .
  2144       from insert(3)[OF _ this]
  2145       show ?thesis using insert(2,4) by simp (blast intro: rev_finite_subset)
  2146     next
  2147       assume 1: "~finite{a:A. f a = b}"
  2148       hence "{a \<in> A. f a = b} \<noteq> {}" by force
  2149       thus ?thesis using 1 by blast
  2150     qed
  2151   qed
  2152   from this[OF assms(2,1)] show ?thesis .
  2153 qed
  2154 
  2155 lemma pigeonhole_infinite_rel:
  2156 assumes "~finite A" and "finite B" and "ALL a:A. EX b:B. R a b"
  2157 shows "EX b:B. ~finite{a:A. R a b}"
  2158 proof -
  2159    let ?F = "%a. {b:B. R a b}"
  2160    from finite_Pow_iff[THEN iffD2, OF `finite B`]
  2161    have "finite(?F ` A)" by(blast intro: rev_finite_subset)
  2162    from pigeonhole_infinite[where f = ?F, OF assms(1) this]
  2163    obtain a0 where "a0\<in>A" and 1: "\<not> finite {a\<in>A. ?F a = ?F a0}" ..
  2164    obtain b0 where "b0 : B" and "R a0 b0" using `a0:A` assms(3) by blast
  2165    { assume "finite{a:A. R a b0}"
  2166      then have "finite {a\<in>A. ?F a = ?F a0}"
  2167        using `b0 : B` `R a0 b0` by(blast intro: rev_finite_subset)
  2168    }
  2169    with 1 `b0 : B` show ?thesis by blast
  2170 qed
  2171 
  2172 
  2173 subsubsection {* Cardinality of sums *}
  2174 
  2175 lemma card_Plus:
  2176   assumes "finite A" and "finite B"
  2177   shows "card (A <+> B) = card A + card B"
  2178 proof -
  2179   have "Inl`A \<inter> Inr`B = {}" by fast
  2180   with assms show ?thesis
  2181     unfolding Plus_def
  2182     by (simp add: card_Un_disjoint card_image)
  2183 qed
  2184 
  2185 lemma card_Plus_conv_if:
  2186   "card (A <+> B) = (if finite A \<and> finite B then card A + card B else 0)"
  2187   by (auto simp add: card_Plus)
  2188 
  2189 
  2190 subsubsection {* Cardinality of the Powerset *}
  2191 
  2192 lemma card_Pow: "finite A ==> card (Pow A) = Suc (Suc 0) ^ card A"  (* FIXME numeral 2 (!?) *)
  2193 apply (induct rule: finite_induct)
  2194  apply (simp_all add: Pow_insert)
  2195 apply (subst card_Un_disjoint, blast)
  2196   apply (blast, blast)
  2197 apply (subgoal_tac "inj_on (insert x) (Pow F)")
  2198  apply (simp add: card_image Pow_insert)
  2199 apply (unfold inj_on_def)
  2200 apply (blast elim!: equalityE)
  2201 done
  2202 
  2203 text {* Relates to equivalence classes.  Based on a theorem of F. Kamm\"uller.  *}
  2204 
  2205 lemma dvd_partition:
  2206   "finite (Union C) ==>
  2207     ALL c : C. k dvd card c ==>
  2208     (ALL c1: C. ALL c2: C. c1 \<noteq> c2 --> c1 Int c2 = {}) ==>
  2209   k dvd card (Union C)"
  2210 apply (frule finite_UnionD)
  2211 apply (rotate_tac -1)
  2212 apply (induct rule: finite_induct)
  2213 apply simp_all
  2214 apply clarify
  2215 apply (subst card_Un_disjoint)
  2216    apply (auto simp add: disjoint_eq_subset_Compl)
  2217 done
  2218 
  2219 
  2220 subsubsection {* Relating injectivity and surjectivity *}
  2221 
  2222 lemma finite_surj_inj: "finite A \<Longrightarrow> A \<subseteq> f ` A \<Longrightarrow> inj_on f A"
  2223 apply(rule eq_card_imp_inj_on, assumption)
  2224 apply(frule finite_imageI)
  2225 apply(drule (1) card_seteq)
  2226  apply(erule card_image_le)
  2227 apply simp
  2228 done
  2229 
  2230 lemma finite_UNIV_surj_inj: fixes f :: "'a \<Rightarrow> 'a"
  2231 shows "finite(UNIV:: 'a set) \<Longrightarrow> surj f \<Longrightarrow> inj f"
  2232 by (blast intro: finite_surj_inj subset_UNIV)
  2233 
  2234 lemma finite_UNIV_inj_surj: fixes f :: "'a \<Rightarrow> 'a"
  2235 shows "finite(UNIV:: 'a set) \<Longrightarrow> inj f \<Longrightarrow> surj f"
  2236 by(fastsimp simp:surj_def dest!: endo_inj_surj)
  2237 
  2238 corollary infinite_UNIV_nat[iff]: "~finite(UNIV::nat set)"
  2239 proof
  2240   assume "finite(UNIV::nat set)"
  2241   with finite_UNIV_inj_surj[of Suc]
  2242   show False by simp (blast dest: Suc_neq_Zero surjD)
  2243 qed
  2244 
  2245 (* Often leads to bogus ATP proofs because of reduced type information, hence no_atp *)
  2246 lemma infinite_UNIV_char_0[no_atp]:
  2247   "\<not> finite (UNIV::'a::semiring_char_0 set)"
  2248 proof
  2249   assume "finite (UNIV::'a set)"
  2250   with subset_UNIV have "finite (range of_nat::'a set)"
  2251     by (rule finite_subset)
  2252   moreover have "inj (of_nat::nat \<Rightarrow> 'a)"
  2253     by (simp add: inj_on_def)
  2254   ultimately have "finite (UNIV::nat set)"
  2255     by (rule finite_imageD)
  2256   then show "False"
  2257     by simp
  2258 qed
  2259 
  2260 end