src/HOL/Product_Type.thy
author haftmann
Sun Jul 17 19:48:02 2011 +0200 (2011-07-17)
changeset 43866 8a50dc70cbff
parent 43654 3f1a44c2d645
child 44066 d74182c93f04
permissions -rw-r--r--
moving UNIV = ... equations to their proper theories
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 uses
    11   ("Tools/split_rule.ML")
    12   ("Tools/inductive_codegen.ML")
    13   ("Tools/inductive_set.ML")
    14 begin
    15 
    16 subsection {* @{typ bool} is a datatype *}
    17 
    18 rep_datatype True False by (auto intro: bool_induct)
    19 
    20 declare case_split [cases type: bool]
    21   -- "prefer plain propositional version"
    22 
    23 lemma
    24   shows [code]: "HOL.equal False P \<longleftrightarrow> \<not> P"
    25     and [code]: "HOL.equal True P \<longleftrightarrow> P" 
    26     and [code]: "HOL.equal P False \<longleftrightarrow> \<not> P" 
    27     and [code]: "HOL.equal P True \<longleftrightarrow> P"
    28     and [code nbe]: "HOL.equal P P \<longleftrightarrow> True"
    29   by (simp_all add: equal)
    30 
    31 lemma If_case_cert:
    32   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
    33   shows "(CASE True \<equiv> f) &&& (CASE False \<equiv> g)"
    34   using assms by simp_all
    35 
    36 setup {*
    37   Code.add_case @{thm If_case_cert}
    38 *}
    39 
    40 code_const "HOL.equal \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    41   (Haskell infix 4 "==")
    42 
    43 code_instance bool :: equal
    44   (Haskell -)
    45 
    46 
    47 subsection {* The @{text unit} type *}
    48 
    49 typedef (open) unit = "{True}"
    50 proof
    51   show "True : ?unit" ..
    52 qed
    53 
    54 definition
    55   Unity :: unit    ("'(')")
    56 where
    57   "() = Abs_unit True"
    58 
    59 lemma unit_eq [no_atp]: "u = ()"
    60   by (induct u) (simp add: Unity_def)
    61 
    62 text {*
    63   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    64   this rule directly --- it loops!
    65 *}
    66 
    67 simproc_setup unit_eq ("x::unit") = {*
    68   fn _ => fn _ => fn ct =>
    69     if HOLogic.is_unit (term_of ct) then NONE
    70     else SOME (mk_meta_eq @{thm unit_eq})
    71 *}
    72 
    73 rep_datatype "()" by simp
    74 
    75 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    76   by simp
    77 
    78 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    79   by (rule triv_forall_equality)
    80 
    81 text {*
    82   This rewrite counters the effect of simproc @{text unit_eq} on @{term
    83   [source] "%u::unit. f u"}, replacing it by @{term [source]
    84   f} rather than by @{term [source] "%u. f ()"}.
    85 *}
    86 
    87 lemma unit_abs_eta_conv [simp, no_atp]: "(%u::unit. f ()) = f"
    88   by (rule ext) simp
    89 
    90 lemma UNIV_unit [no_atp]:
    91   "UNIV = {()}" by auto
    92 
    93 instantiation unit :: default
    94 begin
    95 
    96 definition "default = ()"
    97 
    98 instance ..
    99 
   100 end
   101 
   102 lemma [code]:
   103   "HOL.equal (u\<Colon>unit) v \<longleftrightarrow> True" unfolding equal unit_eq [of u] unit_eq [of v] by rule+
   104 
   105 code_type unit
   106   (SML "unit")
   107   (OCaml "unit")
   108   (Haskell "()")
   109   (Scala "Unit")
   110 
   111 code_const Unity
   112   (SML "()")
   113   (OCaml "()")
   114   (Haskell "()")
   115   (Scala "()")
   116 
   117 code_instance unit :: equal
   118   (Haskell -)
   119 
   120 code_const "HOL.equal \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   121   (Haskell infix 4 "==")
   122 
   123 code_reserved SML
   124   unit
   125 
   126 code_reserved OCaml
   127   unit
   128 
   129 code_reserved Scala
   130   Unit
   131 
   132 
   133 subsection {* The product type *}
   134 
   135 subsubsection {* Type definition *}
   136 
   137 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   138   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   139 
   140 typedef ('a, 'b) prod (infixr "*" 20)
   141   = "{f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   142 proof
   143   fix a b show "Pair_Rep a b \<in> ?prod"
   144     by rule+
   145 qed
   146 
   147 type_notation (xsymbols)
   148   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   149 type_notation (HTML output)
   150   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   151 
   152 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   153   "Pair a b = Abs_prod (Pair_Rep a b)"
   154 
   155 rep_datatype Pair proof -
   156   fix P :: "'a \<times> 'b \<Rightarrow> bool" and p
   157   assume "\<And>a b. P (Pair a b)"
   158   then show "P p" by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   159 next
   160   fix a c :: 'a and b d :: 'b
   161   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   162     by (auto simp add: Pair_Rep_def fun_eq_iff)
   163   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   164     by (auto simp add: prod_def)
   165   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   166     by (simp add: Pair_def Abs_prod_inject)
   167 qed
   168 
   169 declare prod.simps(2) [nitpick_simp del]
   170 
   171 declare prod.weak_case_cong [cong del]
   172 
   173 
   174 subsubsection {* Tuple syntax *}
   175 
   176 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   177   "split \<equiv> prod_case"
   178 
   179 text {*
   180   Patterns -- extends pre-defined type @{typ pttrn} used in
   181   abstractions.
   182 *}
   183 
   184 nonterminal tuple_args and patterns
   185 
   186 syntax
   187   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   188   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   189   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   190   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   191   ""            :: "pttrn => patterns"                  ("_")
   192   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   193 
   194 translations
   195   "(x, y)" == "CONST Pair x y"
   196   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   197   "%(x, y, zs). b" == "CONST prod_case (%x (y, zs). b)"
   198   "%(x, y). b" == "CONST prod_case (%x y. b)"
   199   "_abs (CONST Pair x y) t" => "%(x, y). t"
   200   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   201      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   202 
   203 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   204   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   205 print_translation {*
   206 let
   207   fun split_tr' [Abs (x, T, t as (Abs abs))] =
   208         (* split (%x y. t) => %(x,y) t *)
   209         let
   210           val (y, t') = Syntax_Trans.atomic_abs_tr' abs;
   211           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   212         in
   213           Syntax.const @{syntax_const "_abs"} $
   214             (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   215         end
   216     | split_tr' [Abs (x, T, (s as Const (@{const_syntax prod_case}, _) $ t))] =
   217         (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   218         let
   219           val Const (@{syntax_const "_abs"}, _) $
   220             (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   221           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   222         in
   223           Syntax.const @{syntax_const "_abs"} $
   224             (Syntax.const @{syntax_const "_pattern"} $ x' $
   225               (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   226         end
   227     | split_tr' [Const (@{const_syntax prod_case}, _) $ t] =
   228         (* split (split (%x y z. t)) => %((x, y), z). t *)
   229         split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   230     | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   231         (* split (%pttrn z. t) => %(pttrn,z). t *)
   232         let val (z, t) = Syntax_Trans.atomic_abs_tr' abs in
   233           Syntax.const @{syntax_const "_abs"} $
   234             (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   235         end
   236     | split_tr' _ = raise Match;
   237 in [(@{const_syntax prod_case}, split_tr')] end
   238 *}
   239 
   240 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   241 typed_print_translation {*
   242 let
   243   fun split_guess_names_tr' T [Abs (x, _, Abs _)] = raise Match
   244     | split_guess_names_tr' T [Abs (x, xT, t)] =
   245         (case (head_of t) of
   246           Const (@{const_syntax prod_case}, _) => raise Match
   247         | _ =>
   248           let 
   249             val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   250             val (y, t') = Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   251             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, xT, t');
   252           in
   253             Syntax.const @{syntax_const "_abs"} $
   254               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   255           end)
   256     | split_guess_names_tr' T [t] =
   257         (case head_of t of
   258           Const (@{const_syntax prod_case}, _) => raise Match
   259         | _ =>
   260           let
   261             val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   262             val (y, t') =
   263               Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   264             val (x', t'') = Syntax_Trans.atomic_abs_tr' ("x", xT, t');
   265           in
   266             Syntax.const @{syntax_const "_abs"} $
   267               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   268           end)
   269     | split_guess_names_tr' _ _ = raise Match;
   270 in [(@{const_syntax prod_case}, split_guess_names_tr')] end
   271 *}
   272 
   273 (* Force eta-contraction for terms of the form "Q A (%p. prod_case P p)"
   274    where Q is some bounded quantifier or set operator.
   275    Reason: the above prints as "Q p : A. case p of (x,y) \<Rightarrow> P x y"
   276    whereas we want "Q (x,y):A. P x y".
   277    Otherwise prevent eta-contraction.
   278 *)
   279 print_translation {*
   280 let
   281   fun contract Q f ts =
   282     case ts of
   283       [A, Abs(_, _, (s as Const (@{const_syntax prod_case},_) $ t) $ Bound 0)]
   284       => if Term.is_dependent t then f ts else Syntax.const Q $ A $ s
   285     | _ => f ts;
   286   fun contract2 (Q,f) = (Q, contract Q f);
   287   val pairs =
   288     [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Ball} @{syntax_const "_Ball"},
   289      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Bex} @{syntax_const "_Bex"},
   290      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   291      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   292 in map contract2 pairs end
   293 *}
   294 
   295 subsubsection {* Code generator setup *}
   296 
   297 code_type prod
   298   (SML infix 2 "*")
   299   (OCaml infix 2 "*")
   300   (Haskell "!((_),/ (_))")
   301   (Scala "((_),/ (_))")
   302 
   303 code_const Pair
   304   (SML "!((_),/ (_))")
   305   (OCaml "!((_),/ (_))")
   306   (Haskell "!((_),/ (_))")
   307   (Scala "!((_),/ (_))")
   308 
   309 code_instance prod :: equal
   310   (Haskell -)
   311 
   312 code_const "HOL.equal \<Colon> 'a \<times> 'b \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
   313   (Haskell infix 4 "==")
   314 
   315 types_code
   316   "prod"     ("(_ */ _)")
   317 attach (term_of) {*
   318 fun term_of_prod aF aT bF bT (x, y) = HOLogic.pair_const aT bT $ aF x $ bF y;
   319 *}
   320 attach (test) {*
   321 fun gen_prod aG aT bG bT i =
   322   let
   323     val (x, t) = aG i;
   324     val (y, u) = bG i
   325   in ((x, y), fn () => HOLogic.pair_const aT bT $ t () $ u ()) end;
   326 *}
   327 
   328 consts_code
   329   "Pair"    ("(_,/ _)")
   330 
   331 setup {*
   332 let
   333 
   334 fun strip_abs_split 0 t = ([], t)
   335   | strip_abs_split i (Abs (s, T, t)) =
   336       let
   337         val s' = Codegen.new_name t s;
   338         val v = Free (s', T)
   339       in apfst (cons v) (strip_abs_split (i-1) (subst_bound (v, t))) end
   340   | strip_abs_split i (u as Const (@{const_name prod_case}, _) $ t) =
   341       (case strip_abs_split (i+1) t of
   342         (v :: v' :: vs, u) => (HOLogic.mk_prod (v, v') :: vs, u)
   343       | _ => ([], u))
   344   | strip_abs_split i t =
   345       strip_abs_split i (Abs ("x", hd (binder_types (fastype_of t)), t $ Bound 0));
   346 
   347 fun let_codegen thy mode defs dep thyname brack t gr =
   348   (case strip_comb t of
   349     (t1 as Const (@{const_name Let}, _), t2 :: t3 :: ts) =>
   350     let
   351       fun dest_let (l as Const (@{const_name Let}, _) $ t $ u) =
   352           (case strip_abs_split 1 u of
   353              ([p], u') => apfst (cons (p, t)) (dest_let u')
   354            | _ => ([], l))
   355         | dest_let t = ([], t);
   356       fun mk_code (l, r) gr =
   357         let
   358           val (pl, gr1) = Codegen.invoke_codegen thy mode defs dep thyname false l gr;
   359           val (pr, gr2) = Codegen.invoke_codegen thy mode defs dep thyname false r gr1;
   360         in ((pl, pr), gr2) end
   361     in case dest_let (t1 $ t2 $ t3) of
   362         ([], _) => NONE
   363       | (ps, u) =>
   364           let
   365             val (qs, gr1) = fold_map mk_code ps gr;
   366             val (pu, gr2) = Codegen.invoke_codegen thy mode defs dep thyname false u gr1;
   367             val (pargs, gr3) = fold_map
   368               (Codegen.invoke_codegen thy mode defs dep thyname true) ts gr2
   369           in
   370             SOME (Codegen.mk_app brack
   371               (Pretty.blk (0, [Codegen.str "let ", Pretty.blk (0, flat
   372                   (separate [Codegen.str ";", Pretty.brk 1] (map (fn (pl, pr) =>
   373                     [Pretty.block [Codegen.str "val ", pl, Codegen.str " =",
   374                        Pretty.brk 1, pr]]) qs))),
   375                 Pretty.brk 1, Codegen.str "in ", pu,
   376                 Pretty.brk 1, Codegen.str "end"])) pargs, gr3)
   377           end
   378     end
   379   | _ => NONE);
   380 
   381 fun split_codegen thy mode defs dep thyname brack t gr = (case strip_comb t of
   382     (t1 as Const (@{const_name prod_case}, _), t2 :: ts) =>
   383       let
   384         val ([p], u) = strip_abs_split 1 (t1 $ t2);
   385         val (q, gr1) = Codegen.invoke_codegen thy mode defs dep thyname false p gr;
   386         val (pu, gr2) = Codegen.invoke_codegen thy mode defs dep thyname false u gr1;
   387         val (pargs, gr3) = fold_map
   388           (Codegen.invoke_codegen thy mode defs dep thyname true) ts gr2
   389       in
   390         SOME (Codegen.mk_app brack
   391           (Pretty.block [Codegen.str "(fn ", q, Codegen.str " =>",
   392             Pretty.brk 1, pu, Codegen.str ")"]) pargs, gr2)
   393       end
   394   | _ => NONE);
   395 
   396 in
   397 
   398   Codegen.add_codegen "let_codegen" let_codegen
   399   #> Codegen.add_codegen "split_codegen" split_codegen
   400 
   401 end
   402 *}
   403 
   404 
   405 subsubsection {* Fundamental operations and properties *}
   406 
   407 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   408   by (cases p) simp
   409 
   410 definition fst :: "'a \<times> 'b \<Rightarrow> 'a" where
   411   "fst p = (case p of (a, b) \<Rightarrow> a)"
   412 
   413 definition snd :: "'a \<times> 'b \<Rightarrow> 'b" where
   414   "snd p = (case p of (a, b) \<Rightarrow> b)"
   415 
   416 lemma fst_conv [simp, code]: "fst (a, b) = a"
   417   unfolding fst_def by simp
   418 
   419 lemma snd_conv [simp, code]: "snd (a, b) = b"
   420   unfolding snd_def by simp
   421 
   422 code_const fst and snd
   423   (Haskell "fst" and "snd")
   424 
   425 lemma prod_case_unfold [nitpick_unfold]: "prod_case = (%c p. c (fst p) (snd p))"
   426   by (simp add: fun_eq_iff split: prod.split)
   427 
   428 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   429   by simp
   430 
   431 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   432   by simp
   433 
   434 lemma pair_collapse [simp]: "(fst p, snd p) = p"
   435   by (cases p) simp
   436 
   437 lemmas surjective_pairing = pair_collapse [symmetric]
   438 
   439 lemma Pair_fst_snd_eq: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   440   by (cases s, cases t) simp
   441 
   442 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   443   by (simp add: Pair_fst_snd_eq)
   444 
   445 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   446   by (fact prod.cases)
   447 
   448 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   449   by (rule split_conv [THEN iffD2])
   450 
   451 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   452   by (rule split_conv [THEN iffD1])
   453 
   454 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   455   by (simp add: fun_eq_iff split: prod.split)
   456 
   457 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   458   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   459   by (simp add: fun_eq_iff split: prod.split)
   460 
   461 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   462   by (cases x) simp
   463 
   464 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   465   by (cases p) simp
   466 
   467 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   468   by (simp add: prod_case_unfold)
   469 
   470 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   471   -- {* Prevents simplification of @{term c}: much faster *}
   472   by (fact prod.weak_case_cong)
   473 
   474 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   475   by (simp add: split_eta)
   476 
   477 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   478 proof
   479   fix a b
   480   assume "!!x. PROP P x"
   481   then show "PROP P (a, b)" .
   482 next
   483   fix x
   484   assume "!!a b. PROP P (a, b)"
   485   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   486 qed
   487 
   488 text {*
   489   The rule @{thm [source] split_paired_all} does not work with the
   490   Simplifier because it also affects premises in congrence rules,
   491   where this can lead to premises of the form @{text "!!a b. ... =
   492   ?P(a, b)"} which cannot be solved by reflexivity.
   493 *}
   494 
   495 lemmas split_tupled_all = split_paired_all unit_all_eq2
   496 
   497 ML {*
   498   (* replace parameters of product type by individual component parameters *)
   499   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   500   local (* filtering with exists_paired_all is an essential optimization *)
   501     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   502           can HOLogic.dest_prodT T orelse exists_paired_all t
   503       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   504       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   505       | exists_paired_all _ = false;
   506     val ss = HOL_basic_ss
   507       addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   508       addsimprocs [@{simproc unit_eq}];
   509   in
   510     val split_all_tac = SUBGOAL (fn (t, i) =>
   511       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   512     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   513       if exists_paired_all t then full_simp_tac ss i else no_tac);
   514     fun split_all th =
   515    if exists_paired_all (Thm.prop_of th) then full_simplify ss th else th;
   516   end;
   517 *}
   518 
   519 declaration {* fn _ =>
   520   Classical.map_cs (fn cs => cs addSbefore ("split_all_tac", split_all_tac))
   521 *}
   522 
   523 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   524   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   525   by fast
   526 
   527 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   528   by fast
   529 
   530 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   531   -- {* Can't be added to simpset: loops! *}
   532   by (simp add: split_eta)
   533 
   534 text {*
   535   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   536   @{thm [source] split_eta} as a rewrite rule is not general enough,
   537   and using @{thm [source] cond_split_eta} directly would render some
   538   existing proofs very inefficient; similarly for @{text
   539   split_beta}.
   540 *}
   541 
   542 ML {*
   543 local
   544   val cond_split_eta_ss = HOL_basic_ss addsimps @{thms cond_split_eta};
   545   fun Pair_pat k 0 (Bound m) = (m = k)
   546     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   547         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   548     | Pair_pat _ _ _ = false;
   549   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   550     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   551     | no_args k i (Bound m) = m < k orelse m > k + i
   552     | no_args _ _ _ = true;
   553   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   554     | split_pat tp i (Const (@{const_name prod_case}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   555     | split_pat tp i _ = NONE;
   556   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   557         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   558         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   559 
   560   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   561     | beta_term_pat k i (t $ u) =
   562         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   563     | beta_term_pat k i t = no_args k i t;
   564   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   565     | eta_term_pat _ _ _ = false;
   566   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   567     | subst arg k i (t $ u) =
   568         if Pair_pat k i (t $ u) then incr_boundvars k arg
   569         else (subst arg k i t $ subst arg k i u)
   570     | subst arg k i t = t;
   571 in
   572   fun beta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t) $ arg) =
   573         (case split_pat beta_term_pat 1 t of
   574           SOME (i, f) => SOME (metaeq ss s (subst arg 0 i f))
   575         | NONE => NONE)
   576     | beta_proc _ _ = NONE;
   577   fun eta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t)) =
   578         (case split_pat eta_term_pat 1 t of
   579           SOME (_, ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   580         | NONE => NONE)
   581     | eta_proc _ _ = NONE;
   582 end;
   583 *}
   584 simproc_setup split_beta ("split f z") = {* fn _ => fn ss => fn ct => beta_proc ss (term_of ct) *}
   585 simproc_setup split_eta ("split f") = {* fn _ => fn ss => fn ct => eta_proc ss (term_of ct) *}
   586 
   587 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   588   by (subst surjective_pairing, rule split_conv)
   589 
   590 lemma split_split [no_atp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   591   -- {* For use with @{text split} and the Simplifier. *}
   592   by (insert surj_pair [of p], clarify, simp)
   593 
   594 text {*
   595   @{thm [source] split_split} could be declared as @{text "[split]"}
   596   done after the Splitter has been speeded up significantly;
   597   precompute the constants involved and don't do anything unless the
   598   current goal contains one of those constants.
   599 *}
   600 
   601 lemma split_split_asm [no_atp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   602 by (subst split_split, simp)
   603 
   604 text {*
   605   \medskip @{term split} used as a logical connective or set former.
   606 
   607   \medskip These rules are for use with @{text blast}; could instead
   608   call @{text simp} using @{thm [source] prod.split} as rewrite. *}
   609 
   610 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   611   apply (simp only: split_tupled_all)
   612   apply (simp (no_asm_simp))
   613   done
   614 
   615 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   616   apply (simp only: split_tupled_all)
   617   apply (simp (no_asm_simp))
   618   done
   619 
   620 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   621   by (induct p) auto
   622 
   623 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   624   by (induct p) auto
   625 
   626 lemma splitE2:
   627   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   628 proof -
   629   assume q: "Q (split P z)"
   630   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   631   show R
   632     apply (rule r surjective_pairing)+
   633     apply (rule split_beta [THEN subst], rule q)
   634     done
   635 qed
   636 
   637 lemma splitD': "split R (a,b) c ==> R a b c"
   638   by simp
   639 
   640 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   641   by simp
   642 
   643 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   644 by (simp only: split_tupled_all, simp)
   645 
   646 lemma mem_splitE:
   647   assumes major: "z \<in> split c p"
   648     and cases: "\<And>x y. p = (x, y) \<Longrightarrow> z \<in> c x y \<Longrightarrow> Q"
   649   shows Q
   650   by (rule major [unfolded prod_case_unfold] cases surjective_pairing)+
   651 
   652 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   653 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   654 
   655 ML {*
   656 local (* filtering with exists_p_split is an essential optimization *)
   657   fun exists_p_split (Const (@{const_name prod_case},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   658     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   659     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   660     | exists_p_split _ = false;
   661   val ss = HOL_basic_ss addsimps @{thms split_conv};
   662 in
   663 val split_conv_tac = SUBGOAL (fn (t, i) =>
   664     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   665 end;
   666 *}
   667 
   668 (* This prevents applications of splitE for already splitted arguments leading
   669    to quite time-consuming computations (in particular for nested tuples) *)
   670 declaration {* fn _ =>
   671   Classical.map_cs (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac))
   672 *}
   673 
   674 lemma split_eta_SetCompr [simp,no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   675   by (rule ext) fast
   676 
   677 lemma split_eta_SetCompr2 [simp,no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   678   by (rule ext) fast
   679 
   680 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   681   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   682   by (rule ext) blast
   683 
   684 (* Do NOT make this a simp rule as it
   685    a) only helps in special situations
   686    b) can lead to nontermination in the presence of split_def
   687 *)
   688 lemma split_comp_eq: 
   689   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   690   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   691   by (rule ext) auto
   692 
   693 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   694   apply (rule_tac x = "(a, b)" in image_eqI)
   695    apply auto
   696   done
   697 
   698 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   699   by blast
   700 
   701 (*
   702 the following  would be slightly more general,
   703 but cannot be used as rewrite rule:
   704 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   705 ### ?y = .x
   706 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   707 by (rtac some_equality 1)
   708 by ( Simp_tac 1)
   709 by (split_all_tac 1)
   710 by (Asm_full_simp_tac 1)
   711 qed "The_split_eq";
   712 *)
   713 
   714 text {*
   715   Setup of internal @{text split_rule}.
   716 *}
   717 
   718 lemmas prod_caseI = prod.cases [THEN iffD2, standard]
   719 
   720 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   721   by (fact splitI2)
   722 
   723 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   724   by (fact splitI2')
   725 
   726 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   727   by (fact splitE)
   728 
   729 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   730   by (fact splitE')
   731 
   732 declare prod_caseI [intro!]
   733 
   734 lemma prod_case_beta:
   735   "prod_case f p = f (fst p) (snd p)"
   736   by (fact split_beta)
   737 
   738 lemma prod_cases3 [cases type]:
   739   obtains (fields) a b c where "y = (a, b, c)"
   740   by (cases y, case_tac b) blast
   741 
   742 lemma prod_induct3 [case_names fields, induct type]:
   743     "(!!a b c. P (a, b, c)) ==> P x"
   744   by (cases x) blast
   745 
   746 lemma prod_cases4 [cases type]:
   747   obtains (fields) a b c d where "y = (a, b, c, d)"
   748   by (cases y, case_tac c) blast
   749 
   750 lemma prod_induct4 [case_names fields, induct type]:
   751     "(!!a b c d. P (a, b, c, d)) ==> P x"
   752   by (cases x) blast
   753 
   754 lemma prod_cases5 [cases type]:
   755   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   756   by (cases y, case_tac d) blast
   757 
   758 lemma prod_induct5 [case_names fields, induct type]:
   759     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   760   by (cases x) blast
   761 
   762 lemma prod_cases6 [cases type]:
   763   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   764   by (cases y, case_tac e) blast
   765 
   766 lemma prod_induct6 [case_names fields, induct type]:
   767     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   768   by (cases x) blast
   769 
   770 lemma prod_cases7 [cases type]:
   771   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   772   by (cases y, case_tac f) blast
   773 
   774 lemma prod_induct7 [case_names fields, induct type]:
   775     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   776   by (cases x) blast
   777 
   778 lemma split_def:
   779   "split = (\<lambda>c p. c (fst p) (snd p))"
   780   by (fact prod_case_unfold)
   781 
   782 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   783   "internal_split == split"
   784 
   785 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   786   by (simp only: internal_split_def split_conv)
   787 
   788 use "Tools/split_rule.ML"
   789 setup Split_Rule.setup
   790 
   791 hide_const internal_split
   792 
   793 
   794 subsubsection {* Derived operations *}
   795 
   796 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   797   "curry = (\<lambda>c x y. c (x, y))"
   798 
   799 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   800   by (simp add: curry_def)
   801 
   802 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   803   by (simp add: curry_def)
   804 
   805 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   806   by (simp add: curry_def)
   807 
   808 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   809   by (simp add: curry_def)
   810 
   811 lemma curry_split [simp]: "curry (split f) = f"
   812   by (simp add: curry_def split_def)
   813 
   814 lemma split_curry [simp]: "split (curry f) = f"
   815   by (simp add: curry_def split_def)
   816 
   817 text {*
   818   The composition-uncurry combinator.
   819 *}
   820 
   821 notation fcomp (infixl "\<circ>>" 60)
   822 
   823 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "\<circ>\<rightarrow>" 60) where
   824   "f \<circ>\<rightarrow> g = (\<lambda>x. prod_case g (f x))"
   825 
   826 lemma scomp_unfold: "scomp = (\<lambda>f g x. g (fst (f x)) (snd (f x)))"
   827   by (simp add: fun_eq_iff scomp_def prod_case_unfold)
   828 
   829 lemma scomp_apply [simp]: "(f \<circ>\<rightarrow> g) x = prod_case g (f x)"
   830   by (simp add: scomp_unfold prod_case_unfold)
   831 
   832 lemma Pair_scomp: "Pair x \<circ>\<rightarrow> f = f x"
   833   by (simp add: fun_eq_iff scomp_apply)
   834 
   835 lemma scomp_Pair: "x \<circ>\<rightarrow> Pair = x"
   836   by (simp add: fun_eq_iff scomp_apply)
   837 
   838 lemma scomp_scomp: "(f \<circ>\<rightarrow> g) \<circ>\<rightarrow> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>\<rightarrow> h)"
   839   by (simp add: fun_eq_iff scomp_unfold)
   840 
   841 lemma scomp_fcomp: "(f \<circ>\<rightarrow> g) \<circ>> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>> h)"
   842   by (simp add: fun_eq_iff scomp_unfold fcomp_def)
   843 
   844 lemma fcomp_scomp: "(f \<circ>> g) \<circ>\<rightarrow> h = f \<circ>> (g \<circ>\<rightarrow> h)"
   845   by (simp add: fun_eq_iff scomp_unfold fcomp_apply)
   846 
   847 code_const scomp
   848   (Eval infixl 3 "#->")
   849 
   850 no_notation fcomp (infixl "\<circ>>" 60)
   851 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   852 
   853 text {*
   854   @{term map_pair} --- action of the product functor upon
   855   functions.
   856 *}
   857 
   858 definition map_pair :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   859   "map_pair f g = (\<lambda>(x, y). (f x, g y))"
   860 
   861 lemma map_pair_simp [simp, code]:
   862   "map_pair f g (a, b) = (f a, g b)"
   863   by (simp add: map_pair_def)
   864 
   865 enriched_type map_pair: map_pair
   866   by (auto simp add: split_paired_all intro: ext)
   867 
   868 lemma fst_map_pair [simp]:
   869   "fst (map_pair f g x) = f (fst x)"
   870   by (cases x) simp_all
   871 
   872 lemma snd_prod_fun [simp]:
   873   "snd (map_pair f g x) = g (snd x)"
   874   by (cases x) simp_all
   875 
   876 lemma fst_comp_map_pair [simp]:
   877   "fst \<circ> map_pair f g = f \<circ> fst"
   878   by (rule ext) simp_all
   879 
   880 lemma snd_comp_map_pair [simp]:
   881   "snd \<circ> map_pair f g = g \<circ> snd"
   882   by (rule ext) simp_all
   883 
   884 lemma map_pair_compose:
   885   "map_pair (f1 o f2) (g1 o g2) = (map_pair f1 g1 o map_pair f2 g2)"
   886   by (rule ext) (simp add: map_pair.compositionality comp_def)
   887 
   888 lemma map_pair_ident [simp]:
   889   "map_pair (%x. x) (%y. y) = (%z. z)"
   890   by (rule ext) (simp add: map_pair.identity)
   891 
   892 lemma map_pair_imageI [intro]:
   893   "(a, b) \<in> R \<Longrightarrow> (f a, g b) \<in> map_pair f g ` R"
   894   by (rule image_eqI) simp_all
   895 
   896 lemma prod_fun_imageE [elim!]:
   897   assumes major: "c \<in> map_pair f g ` R"
   898     and cases: "\<And>x y. c = (f x, g y) \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> P"
   899   shows P
   900   apply (rule major [THEN imageE])
   901   apply (case_tac x)
   902   apply (rule cases)
   903   apply simp_all
   904   done
   905 
   906 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   907   "apfst f = map_pair f id"
   908 
   909 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   910   "apsnd f = map_pair id f"
   911 
   912 lemma apfst_conv [simp, code]:
   913   "apfst f (x, y) = (f x, y)" 
   914   by (simp add: apfst_def)
   915 
   916 lemma apsnd_conv [simp, code]:
   917   "apsnd f (x, y) = (x, f y)" 
   918   by (simp add: apsnd_def)
   919 
   920 lemma fst_apfst [simp]:
   921   "fst (apfst f x) = f (fst x)"
   922   by (cases x) simp
   923 
   924 lemma fst_apsnd [simp]:
   925   "fst (apsnd f x) = fst x"
   926   by (cases x) simp
   927 
   928 lemma snd_apfst [simp]:
   929   "snd (apfst f x) = snd x"
   930   by (cases x) simp
   931 
   932 lemma snd_apsnd [simp]:
   933   "snd (apsnd f x) = f (snd x)"
   934   by (cases x) simp
   935 
   936 lemma apfst_compose:
   937   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   938   by (cases x) simp
   939 
   940 lemma apsnd_compose:
   941   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   942   by (cases x) simp
   943 
   944 lemma apfst_apsnd [simp]:
   945   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   946   by (cases x) simp
   947 
   948 lemma apsnd_apfst [simp]:
   949   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   950   by (cases x) simp
   951 
   952 lemma apfst_id [simp] :
   953   "apfst id = id"
   954   by (simp add: fun_eq_iff)
   955 
   956 lemma apsnd_id [simp] :
   957   "apsnd id = id"
   958   by (simp add: fun_eq_iff)
   959 
   960 lemma apfst_eq_conv [simp]:
   961   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   962   by (cases x) simp
   963 
   964 lemma apsnd_eq_conv [simp]:
   965   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   966   by (cases x) simp
   967 
   968 lemma apsnd_apfst_commute:
   969   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   970   by simp
   971 
   972 text {*
   973   Disjoint union of a family of sets -- Sigma.
   974 *}
   975 
   976 definition Sigma :: "['a set, 'a => 'b set] => ('a \<times> 'b) set" where
   977   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   978 
   979 abbreviation
   980   Times :: "['a set, 'b set] => ('a * 'b) set"
   981     (infixr "<*>" 80) where
   982   "A <*> B == Sigma A (%_. B)"
   983 
   984 notation (xsymbols)
   985   Times  (infixr "\<times>" 80)
   986 
   987 notation (HTML output)
   988   Times  (infixr "\<times>" 80)
   989 
   990 syntax
   991   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   992 translations
   993   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
   994 
   995 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   996   by (unfold Sigma_def) blast
   997 
   998 lemma SigmaE [elim!]:
   999     "[| c: Sigma A B;
  1000         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
  1001      |] ==> P"
  1002   -- {* The general elimination rule. *}
  1003   by (unfold Sigma_def) blast
  1004 
  1005 text {*
  1006   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
  1007   eigenvariables.
  1008 *}
  1009 
  1010 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
  1011   by blast
  1012 
  1013 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
  1014   by blast
  1015 
  1016 lemma SigmaE2:
  1017     "[| (a, b) : Sigma A B;
  1018         [| a:A;  b:B(a) |] ==> P
  1019      |] ==> P"
  1020   by blast
  1021 
  1022 lemma Sigma_cong:
  1023      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
  1024       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
  1025   by auto
  1026 
  1027 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
  1028   by blast
  1029 
  1030 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
  1031   by blast
  1032 
  1033 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
  1034   by blast
  1035 
  1036 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
  1037   by auto
  1038 
  1039 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
  1040   by auto
  1041 
  1042 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
  1043   by auto
  1044 
  1045 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
  1046   by blast
  1047 
  1048 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
  1049   by blast
  1050 
  1051 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
  1052   by (blast elim: equalityE)
  1053 
  1054 lemma SetCompr_Sigma_eq:
  1055     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
  1056   by blast
  1057 
  1058 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
  1059   by blast
  1060 
  1061 lemma UN_Times_distrib:
  1062   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
  1063   -- {* Suggested by Pierre Chartier *}
  1064   by blast
  1065 
  1066 lemma split_paired_Ball_Sigma [simp,no_atp]:
  1067     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
  1068   by blast
  1069 
  1070 lemma split_paired_Bex_Sigma [simp,no_atp]:
  1071     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
  1072   by blast
  1073 
  1074 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
  1075   by blast
  1076 
  1077 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
  1078   by blast
  1079 
  1080 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
  1081   by blast
  1082 
  1083 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
  1084   by blast
  1085 
  1086 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
  1087   by blast
  1088 
  1089 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
  1090   by blast
  1091 
  1092 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
  1093   by blast
  1094 
  1095 text {*
  1096   Non-dependent versions are needed to avoid the need for higher-order
  1097   matching, especially when the rules are re-oriented.
  1098 *}
  1099 
  1100 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1101 by blast
  1102 
  1103 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1104 by blast
  1105 
  1106 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1107 by blast
  1108 
  1109 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1110   by auto
  1111 
  1112 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1113   by (auto intro!: image_eqI)
  1114 
  1115 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1116   by (auto intro!: image_eqI)
  1117 
  1118 lemma insert_times_insert[simp]:
  1119   "insert a A \<times> insert b B =
  1120    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1121 by blast
  1122 
  1123 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1124   by (auto, case_tac "f x", auto)
  1125 
  1126 lemma swap_inj_on:
  1127   "inj_on (\<lambda>(i, j). (j, i)) A"
  1128   by (auto intro!: inj_onI)
  1129 
  1130 lemma swap_product:
  1131   "(%(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1132   by (simp add: split_def image_def) blast
  1133 
  1134 lemma image_split_eq_Sigma:
  1135   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1136 proof (safe intro!: imageI vimageI)
  1137   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1138   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1139     using * eq[symmetric] by auto
  1140 qed simp_all
  1141 
  1142 text {* The following @{const map_pair} lemmas are due to Joachim Breitner: *}
  1143 
  1144 lemma map_pair_inj_on:
  1145   assumes "inj_on f A" and "inj_on g B"
  1146   shows "inj_on (map_pair f g) (A \<times> B)"
  1147 proof (rule inj_onI)
  1148   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1149   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1150   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1151   assume "map_pair f g x = map_pair f g y"
  1152   hence "fst (map_pair f g x) = fst (map_pair f g y)" by (auto)
  1153   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1154   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1155   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1156   moreover from `map_pair f g x = map_pair f g y`
  1157   have "snd (map_pair f g x) = snd (map_pair f g y)" by (auto)
  1158   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1159   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1160   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1161   ultimately show "x = y" by(rule prod_eqI)
  1162 qed
  1163 
  1164 lemma map_pair_surj:
  1165   fixes f :: "'a \<Rightarrow> 'b" and g :: "'c \<Rightarrow> 'd"
  1166   assumes "surj f" and "surj g"
  1167   shows "surj (map_pair f g)"
  1168 unfolding surj_def
  1169 proof
  1170   fix y :: "'b \<times> 'd"
  1171   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1172   moreover
  1173   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1174   ultimately have "(fst y, snd y) = map_pair f g (a,b)" by auto
  1175   thus "\<exists>x. y = map_pair f g x" by auto
  1176 qed
  1177 
  1178 lemma map_pair_surj_on:
  1179   assumes "f ` A = A'" and "g ` B = B'"
  1180   shows "map_pair f g ` (A \<times> B) = A' \<times> B'"
  1181 unfolding image_def
  1182 proof(rule set_eqI,rule iffI)
  1183   fix x :: "'a \<times> 'c"
  1184   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = map_pair f g x}"
  1185   then obtain y where "y \<in> A \<times> B" and "x = map_pair f g y" by blast
  1186   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1187   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1188   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1189   with `x = map_pair f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1190 next
  1191   fix x :: "'a \<times> 'c"
  1192   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1193   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1194   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1195   moreover from `image g B = B'` and `snd x \<in> B'`
  1196   obtain b where "b \<in> B" and "snd x = g b" by auto
  1197   ultimately have "(fst x, snd x) = map_pair f g (a,b)" by auto
  1198   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1199   ultimately have "\<exists>y \<in> A \<times> B. x = map_pair f g y" by auto
  1200   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = map_pair f g y}" by auto
  1201 qed
  1202 
  1203 
  1204 subsection {* Inductively defined sets *}
  1205 
  1206 use "Tools/inductive_codegen.ML"
  1207 setup Inductive_Codegen.setup
  1208 
  1209 use "Tools/inductive_set.ML"
  1210 setup Inductive_Set.setup
  1211 
  1212 
  1213 subsection {* Legacy theorem bindings and duplicates *}
  1214 
  1215 lemma PairE:
  1216   obtains x y where "p = (x, y)"
  1217   by (fact prod.exhaust)
  1218 
  1219 lemma Pair_inject:
  1220   assumes "(a, b) = (a', b')"
  1221     and "a = a' ==> b = b' ==> R"
  1222   shows R
  1223   using assms by simp
  1224 
  1225 lemmas Pair_eq = prod.inject
  1226 
  1227 lemmas split = split_conv  -- {* for backwards compatibility *}
  1228 
  1229 end