src/Pure/Thy/markdown.ML
author wenzelm
Sun Mar 06 16:19:02 2016 +0100 (2016-03-06)
changeset 62529 8b7bdfc09f3b
parent 61595 3591274c607e
child 62804 7b9c5416f30e
permissions -rw-r--r--
clarified treatment of fragments of Isabelle symbols during bootstrap;
     1 (*  Title:      Pure/Thy/markdown.ML
     2     Author:     Makarius
     3 
     4 Minimal support for Markdown documents (see also http://commonmark.org)
     5 that consist only of paragraphs and (nested) lists:
     6 
     7   * list items start with marker \<^item> (itemize), \<^enum> (enumerate), \<^descr> (description)
     8   * adjacent list items with same indentation and same marker are grouped
     9     into a single list
    10   * singleton blank lines separate paragraphs
    11   * multiple blank lines escape from the current list hierarchy
    12 
    13 Notable differences to official Markdown:
    14 
    15   * indentation of list items needs to match exactly
    16   * indentation is unlimited (Markdown interprets 4 spaces as block quote)
    17   * list items always consist of paragraphs -- no notion of "tight" list
    18 *)
    19 
    20 signature MARKDOWN =
    21 sig
    22   datatype kind = Itemize | Enumerate | Description
    23   val print_kind: kind -> string
    24   val is_control: Symbol.symbol -> bool
    25   type line
    26   val line_source: line -> Antiquote.text_antiquote list
    27   val line_is_item: line -> bool
    28   val line_content: line -> Antiquote.text_antiquote list
    29   val make_line: Antiquote.text_antiquote list -> line
    30   val empty_line: line
    31   datatype block = Paragraph of line list | List of {indent: int, kind: kind, body: block list}
    32   val read_lines: line list -> block list
    33   val read_antiquotes: Antiquote.text_antiquote list -> block list
    34   val read_source: Input.source -> block list
    35   val text_reports: Antiquote.text_antiquote list -> Position.report list
    36   val reports: block list -> Position.report list
    37 end;
    38 
    39 structure Markdown: MARKDOWN =
    40 struct
    41 
    42 (* item kinds *)
    43 
    44 datatype kind = Itemize | Enumerate | Description;
    45 
    46 fun print_kind Itemize = "itemize"
    47   | print_kind Enumerate = "enumerate"
    48   | print_kind Description = "description";
    49 
    50 val kinds = [("item", Itemize), ("enum", Enumerate), ("descr", Description)];
    51 
    52 val is_control = member (op =) ["\<^item>", "\<^enum>", "\<^descr>"];
    53 
    54 
    55 (* document lines *)
    56 
    57 datatype line =
    58   Line of
    59    {source: Antiquote.text_antiquote list,
    60     is_empty: bool,
    61     indent: int,
    62     item: kind option,
    63     item_pos: Position.T,
    64     content: Antiquote.text_antiquote list};
    65 
    66 val eof_line =
    67   Line {source = [Antiquote.Text [(Symbol.eof, Position.none)]],
    68     is_empty = false, indent = 0, item = NONE, item_pos = Position.none, content = []};
    69 
    70 fun line_source (Line {source, ...}) = source;
    71 fun line_is_empty (Line {is_empty, ...}) = is_empty;
    72 fun line_is_item (Line {item, ...}) = is_some item;
    73 fun line_content (Line {content, ...}) = content;
    74 
    75 
    76 (* make line *)
    77 
    78 local
    79 
    80 fun bad_blank ((s, _): Symbol_Pos.T) = Symbol.is_ascii_blank s andalso s <> Symbol.space;
    81 val bad_blanks = maps (fn Antiquote.Text ss => filter bad_blank ss | _ => []);
    82 
    83 fun check_blanks source =
    84   (case bad_blanks source of
    85     [] => ()
    86   | (c, pos) :: _ =>
    87       error ("Bad blank character " ^ quote (ML_Syntax.print_char c) ^ Position.here pos));
    88 
    89 fun is_space ((s, _): Symbol_Pos.T) = s = Symbol.space;
    90 val is_empty = forall (fn Antiquote.Text ss => forall is_space ss | _ => false);
    91 
    92 fun strip_spaces (Antiquote.Text ss :: rest) =
    93       let val (sp, ss') = take_prefix is_space ss
    94       in (length sp, if null ss' then rest else Antiquote.Text ss' :: rest) end
    95   | strip_spaces source = (0, source);
    96 
    97 fun read_marker source =
    98   let val (indent, source') = strip_spaces source in
    99     (case source' of
   100       (control as Antiquote.Control {name = (name, pos), body = [], ...}) :: rest =>
   101         let
   102           val item = AList.lookup (op =) kinds name;
   103           val item_pos = if is_some item then pos else Position.none;
   104           val (_, rest') = strip_spaces (if is_some item then rest else control :: rest);
   105         in ((indent, item, item_pos), rest') end
   106     | _ => ((indent, NONE, Position.none), source'))
   107   end;
   108 
   109 in
   110 
   111 fun make_line source =
   112   let
   113     val _ = check_blanks source;
   114     val ((indent, item, item_pos), content) = read_marker source;
   115   in
   116     Line {source = source, is_empty = is_empty source, indent = indent,
   117       item = item, item_pos = item_pos, content = content}
   118   end;
   119 
   120 val empty_line = make_line [];
   121 
   122 end;
   123 
   124 
   125 (* document blocks *)
   126 
   127 datatype block =
   128   Paragraph of line list | List of {indent: int, kind: kind, body: block list};
   129 
   130 fun block_lines (Paragraph lines) = lines
   131   | block_lines (List {body, ...}) = maps block_lines body;
   132 
   133 fun block_range (Paragraph lines) = Antiquote.range (maps line_content lines)
   134   | block_range (List {body, ...}) = Antiquote.range (maps line_source (maps block_lines body));
   135 
   136 fun block_indent (List {indent, ...}) = indent
   137   | block_indent (Paragraph (Line {indent, ...} :: _)) = indent
   138   | block_indent _ = 0;
   139 
   140 fun block_list indent0 kind0 (List {indent, kind, body}) =
   141       if indent0 = indent andalso kind0 = kind then SOME body else NONE
   142   | block_list _ _ _ = NONE;
   143 
   144 val is_list = fn List _ => true | _ => false;
   145 
   146 
   147 (* read document *)
   148 
   149 local
   150 
   151 fun build (indent, item, rev_body) document =
   152   (case (item, document) of
   153     (SOME kind, block :: blocks) =>
   154       (case block_list indent kind block of
   155         SOME list => List {indent = indent, kind = kind, body = fold cons rev_body list} :: blocks
   156       | NONE =>
   157           if (if is_list block then indent < block_indent block else indent <= block_indent block)
   158           then build (indent, item, block :: rev_body) blocks
   159           else List {indent = indent, kind = kind, body = rev rev_body} :: document)
   160   | (SOME kind, []) => [List {indent = indent, kind = kind, body = rev rev_body}]
   161   | (NONE, _) => fold cons rev_body document);
   162 
   163 fun plain_line (line as Line {is_empty, item, ...}) =
   164   not is_empty andalso is_none item andalso line <> eof_line;
   165 
   166 val parse_paragraph =
   167   Scan.one (fn line => line <> eof_line) -- Scan.many plain_line >> (fn (line, lines) =>
   168     let
   169       val Line {indent, item, ...} = line;
   170       val block = Paragraph (line :: lines);
   171     in (indent, item, [block]) end);
   172 
   173 val parse_document =
   174   parse_paragraph ::: Scan.repeat (Scan.option (Scan.one line_is_empty) |-- parse_paragraph)
   175     >> (fn pars => fold_rev build pars []);
   176 
   177 in
   178 
   179 val read_lines =
   180   Scan.read (Scan.stopper (K eof_line) (fn line => line = eof_line))
   181     (Scan.repeat (Scan.many line_is_empty |-- parse_document) --| Scan.many line_is_empty) #>
   182   the_default [] #> flat;
   183 
   184 val read_antiquotes = Antiquote.split_lines #> map make_line #> read_lines;
   185 val read_source = Antiquote.read #> read_antiquotes;
   186 
   187 end;
   188 
   189 
   190 (* PIDE reports *)
   191 
   192 val text_reports =
   193   maps (fn Antiquote.Text ss => [(#1 (Symbol_Pos.range ss), Markup.words)] | _ => []);
   194 
   195 local
   196 
   197 fun line_reports depth (Line {item_pos, content, ...}) =
   198   cons (item_pos, Markup.markdown_item depth) #> append (text_reports content);
   199 
   200 fun block_reports depth block =
   201   (case block of
   202     Paragraph lines =>
   203       cons (#1 (block_range block), Markup.markdown_paragraph) #>
   204       fold (line_reports depth) lines
   205   | List {kind, body, ...} =>
   206       cons (#1 (block_range block), Markup.markdown_list (print_kind kind)) #>
   207       fold (block_reports (depth + 1)) body);
   208 
   209 in
   210 
   211 fun reports blocks =
   212   filter (Position.is_reported o #1) (fold (block_reports 0) blocks []);
   213 
   214 end;
   215 
   216 end;