src/HOL/Groebner_Basis.thy
author huffman
Tue Dec 09 20:36:20 2008 -0800 (2008-12-09)
changeset 29039 8b9207f82a78
parent 28987 dc0ab579a5ca
child 29230 155f6c110dfc
permissions -rw-r--r--
separate neg_simps from rel_simps
     1 (*  Title:      HOL/Groebner_Basis.thy
     2     ID:         $Id$
     3     Author:     Amine Chaieb, TU Muenchen
     4 *)
     5 
     6 header {* Semiring normalization and Groebner Bases *}
     7 
     8 theory Groebner_Basis
     9 imports Arith_Tools
    10 uses
    11   "Tools/Groebner_Basis/misc.ML"
    12   "Tools/Groebner_Basis/normalizer_data.ML"
    13   ("Tools/Groebner_Basis/normalizer.ML")
    14   ("Tools/Groebner_Basis/groebner.ML")
    15 begin
    16 
    17 subsection {* Semiring normalization *}
    18 
    19 setup NormalizerData.setup
    20 
    21 
    22 locale gb_semiring =
    23   fixes add mul pwr r0 r1
    24   assumes add_a:"(add x (add y z) = add (add x y) z)"
    25     and add_c: "add x y = add y x" and add_0:"add r0 x = x"
    26     and mul_a:"mul x (mul y z) = mul (mul x y) z" and mul_c:"mul x y = mul y x"
    27     and mul_1:"mul r1 x = x" and  mul_0:"mul r0 x = r0"
    28     and mul_d:"mul x (add y z) = add (mul x y) (mul x z)"
    29     and pwr_0:"pwr x 0 = r1" and pwr_Suc:"pwr x (Suc n) = mul x (pwr x n)"
    30 begin
    31 
    32 lemma mul_pwr:"mul (pwr x p) (pwr x q) = pwr x (p + q)"
    33 proof (induct p)
    34   case 0
    35   then show ?case by (auto simp add: pwr_0 mul_1)
    36 next
    37   case Suc
    38   from this [symmetric] show ?case
    39     by (auto simp add: pwr_Suc mul_1 mul_a)
    40 qed
    41 
    42 lemma pwr_mul: "pwr (mul x y) q = mul (pwr x q) (pwr y q)"
    43 proof (induct q arbitrary: x y, auto simp add:pwr_0 pwr_Suc mul_1)
    44   fix q x y
    45   assume "\<And>x y. pwr (mul x y) q = mul (pwr x q) (pwr y q)"
    46   have "mul (mul x y) (mul (pwr x q) (pwr y q)) = mul x (mul y (mul (pwr x q) (pwr y q)))"
    47     by (simp add: mul_a)
    48   also have "\<dots> = (mul (mul y (mul (pwr y q) (pwr x q))) x)" by (simp add: mul_c)
    49   also have "\<dots> = (mul (mul y (pwr y q)) (mul (pwr x q) x))" by (simp add: mul_a)
    50   finally show "mul (mul x y) (mul (pwr x q) (pwr y q)) =
    51     mul (mul x (pwr x q)) (mul y (pwr y q))" by (simp add: mul_c)
    52 qed
    53 
    54 lemma pwr_pwr: "pwr (pwr x p) q = pwr x (p * q)"
    55 proof (induct p arbitrary: q)
    56   case 0
    57   show ?case using pwr_Suc mul_1 pwr_0 by (induct q) auto
    58 next
    59   case Suc
    60   thus ?case by (auto simp add: mul_pwr [symmetric] pwr_mul pwr_Suc)
    61 qed
    62 
    63 
    64 subsubsection {* Declaring the abstract theory *}
    65 
    66 lemma semiring_ops:
    67   shows "TERM (add x y)" and "TERM (mul x y)" and "TERM (pwr x n)"
    68     and "TERM r0" and "TERM r1" .
    69 
    70 lemma semiring_rules:
    71   "add (mul a m) (mul b m) = mul (add a b) m"
    72   "add (mul a m) m = mul (add a r1) m"
    73   "add m (mul a m) = mul (add a r1) m"
    74   "add m m = mul (add r1 r1) m"
    75   "add r0 a = a"
    76   "add a r0 = a"
    77   "mul a b = mul b a"
    78   "mul (add a b) c = add (mul a c) (mul b c)"
    79   "mul r0 a = r0"
    80   "mul a r0 = r0"
    81   "mul r1 a = a"
    82   "mul a r1 = a"
    83   "mul (mul lx ly) (mul rx ry) = mul (mul lx rx) (mul ly ry)"
    84   "mul (mul lx ly) (mul rx ry) = mul lx (mul ly (mul rx ry))"
    85   "mul (mul lx ly) (mul rx ry) = mul rx (mul (mul lx ly) ry)"
    86   "mul (mul lx ly) rx = mul (mul lx rx) ly"
    87   "mul (mul lx ly) rx = mul lx (mul ly rx)"
    88   "mul lx (mul rx ry) = mul (mul lx rx) ry"
    89   "mul lx (mul rx ry) = mul rx (mul lx ry)"
    90   "add (add a b) (add c d) = add (add a c) (add b d)"
    91   "add (add a b) c = add a (add b c)"
    92   "add a (add c d) = add c (add a d)"
    93   "add (add a b) c = add (add a c) b"
    94   "add a c = add c a"
    95   "add a (add c d) = add (add a c) d"
    96   "mul (pwr x p) (pwr x q) = pwr x (p + q)"
    97   "mul x (pwr x q) = pwr x (Suc q)"
    98   "mul (pwr x q) x = pwr x (Suc q)"
    99   "mul x x = pwr x 2"
   100   "pwr (mul x y) q = mul (pwr x q) (pwr y q)"
   101   "pwr (pwr x p) q = pwr x (p * q)"
   102   "pwr x 0 = r1"
   103   "pwr x 1 = x"
   104   "mul x (add y z) = add (mul x y) (mul x z)"
   105   "pwr x (Suc q) = mul x (pwr x q)"
   106   "pwr x (2*n) = mul (pwr x n) (pwr x n)"
   107   "pwr x (Suc (2*n)) = mul x (mul (pwr x n) (pwr x n))"
   108 proof -
   109   show "add (mul a m) (mul b m) = mul (add a b) m" using mul_d mul_c by simp
   110 next show"add (mul a m) m = mul (add a r1) m" using mul_d mul_c mul_1 by simp
   111 next show "add m (mul a m) = mul (add a r1) m" using mul_c mul_d mul_1 add_c by simp
   112 next show "add m m = mul (add r1 r1) m" using mul_c mul_d mul_1 by simp
   113 next show "add r0 a = a" using add_0 by simp
   114 next show "add a r0 = a" using add_0 add_c by simp
   115 next show "mul a b = mul b a" using mul_c by simp
   116 next show "mul (add a b) c = add (mul a c) (mul b c)" using mul_c mul_d by simp
   117 next show "mul r0 a = r0" using mul_0 by simp
   118 next show "mul a r0 = r0" using mul_0 mul_c by simp
   119 next show "mul r1 a = a" using mul_1 by simp
   120 next show "mul a r1 = a" using mul_1 mul_c by simp
   121 next show "mul (mul lx ly) (mul rx ry) = mul (mul lx rx) (mul ly ry)"
   122     using mul_c mul_a by simp
   123 next show "mul (mul lx ly) (mul rx ry) = mul lx (mul ly (mul rx ry))"
   124     using mul_a by simp
   125 next
   126   have "mul (mul lx ly) (mul rx ry) = mul (mul rx ry) (mul lx ly)" by (rule mul_c)
   127   also have "\<dots> = mul rx (mul ry (mul lx ly))" using mul_a by simp
   128   finally
   129   show "mul (mul lx ly) (mul rx ry) = mul rx (mul (mul lx ly) ry)"
   130     using mul_c by simp
   131 next show "mul (mul lx ly) rx = mul (mul lx rx) ly" using mul_c mul_a by simp
   132 next
   133   show "mul (mul lx ly) rx = mul lx (mul ly rx)" by (simp add: mul_a)
   134 next show "mul lx (mul rx ry) = mul (mul lx rx) ry" by (simp add: mul_a )
   135 next show "mul lx (mul rx ry) = mul rx (mul lx ry)" by (simp add: mul_a,simp add: mul_c)
   136 next show "add (add a b) (add c d) = add (add a c) (add b d)"
   137     using add_c add_a by simp
   138 next show "add (add a b) c = add a (add b c)" using add_a by simp
   139 next show "add a (add c d) = add c (add a d)"
   140     apply (simp add: add_a) by (simp only: add_c)
   141 next show "add (add a b) c = add (add a c) b" using add_a add_c by simp
   142 next show "add a c = add c a" by (rule add_c)
   143 next show "add a (add c d) = add (add a c) d" using add_a by simp
   144 next show "mul (pwr x p) (pwr x q) = pwr x (p + q)" by (rule mul_pwr)
   145 next show "mul x (pwr x q) = pwr x (Suc q)" using pwr_Suc by simp
   146 next show "mul (pwr x q) x = pwr x (Suc q)" using pwr_Suc mul_c by simp
   147 next show "mul x x = pwr x 2" by (simp add: nat_number pwr_Suc pwr_0 mul_1 mul_c)
   148 next show "pwr (mul x y) q = mul (pwr x q) (pwr y q)" by (rule pwr_mul)
   149 next show "pwr (pwr x p) q = pwr x (p * q)" by (rule pwr_pwr)
   150 next show "pwr x 0 = r1" using pwr_0 .
   151 next show "pwr x 1 = x" by (simp add: nat_number pwr_Suc pwr_0 mul_1 mul_c)
   152 next show "mul x (add y z) = add (mul x y) (mul x z)" using mul_d by simp
   153 next show "pwr x (Suc q) = mul x (pwr x q)" using pwr_Suc by simp
   154 next show "pwr x (2 * n) = mul (pwr x n) (pwr x n)" by (simp add: nat_number mul_pwr)
   155 next show "pwr x (Suc (2 * n)) = mul x (mul (pwr x n) (pwr x n))"
   156     by (simp add: nat_number pwr_Suc mul_pwr)
   157 qed
   158 
   159 
   160 lemmas gb_semiring_axioms' =
   161   gb_semiring_axioms [normalizer
   162     semiring ops: semiring_ops
   163     semiring rules: semiring_rules]
   164 
   165 end
   166 
   167 interpretation class_semiring: gb_semiring
   168     ["op +" "op *" "op ^" "0::'a::{comm_semiring_1, recpower}" "1"]
   169   proof qed (auto simp add: ring_simps power_Suc)
   170 
   171 lemmas nat_arith =
   172   add_nat_number_of
   173   diff_nat_number_of
   174   mult_nat_number_of
   175   eq_nat_number_of
   176   less_nat_number_of
   177 
   178 lemma not_iszero_Numeral1: "\<not> iszero (Numeral1::'a::number_ring)"
   179   by (simp add: numeral_1_eq_1)
   180 
   181 lemmas comp_arith =
   182   Let_def arith_simps nat_arith rel_simps neg_simps if_False
   183   if_True add_0 add_Suc add_number_of_left mult_number_of_left
   184   numeral_1_eq_1[symmetric] Suc_eq_add_numeral_1
   185   numeral_0_eq_0[symmetric] numerals[symmetric]
   186   iszero_simps not_iszero_Numeral1
   187 
   188 lemmas semiring_norm = comp_arith
   189 
   190 ML {*
   191 local
   192 
   193 open Conv;
   194 
   195 fun numeral_is_const ct =
   196   can HOLogic.dest_number (Thm.term_of ct);
   197 
   198 fun int_of_rat x =
   199   (case Rat.quotient_of_rat x of (i, 1) => i
   200   | _ => error "int_of_rat: bad int");
   201 
   202 val numeral_conv =
   203   Simplifier.rewrite (HOL_basic_ss addsimps @{thms semiring_norm}) then_conv
   204   Simplifier.rewrite (HOL_basic_ss addsimps
   205     (@{thms numeral_1_eq_1} @ @{thms numeral_0_eq_0} @ @{thms numerals(1-2)}));
   206 
   207 in
   208 
   209 fun normalizer_funs key =
   210   NormalizerData.funs key
   211    {is_const = fn phi => numeral_is_const,
   212     dest_const = fn phi => fn ct =>
   213       Rat.rat_of_int (snd
   214         (HOLogic.dest_number (Thm.term_of ct)
   215           handle TERM _ => error "ring_dest_const")),
   216     mk_const = fn phi => fn cT => fn x => Numeral.mk_cnumber cT (int_of_rat x),
   217     conv = fn phi => K numeral_conv}
   218 
   219 end
   220 *}
   221 
   222 declaration {* normalizer_funs @{thm class_semiring.gb_semiring_axioms'} *}
   223 
   224 
   225 locale gb_ring = gb_semiring +
   226   fixes sub :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   227     and neg :: "'a \<Rightarrow> 'a"
   228   assumes neg_mul: "neg x = mul (neg r1) x"
   229     and sub_add: "sub x y = add x (neg y)"
   230 begin
   231 
   232 lemma ring_ops: shows "TERM (sub x y)" and "TERM (neg x)" .
   233 
   234 lemmas ring_rules = neg_mul sub_add
   235 
   236 lemmas gb_ring_axioms' =
   237   gb_ring_axioms [normalizer
   238     semiring ops: semiring_ops
   239     semiring rules: semiring_rules
   240     ring ops: ring_ops
   241     ring rules: ring_rules]
   242 
   243 end
   244 
   245 
   246 interpretation class_ring: gb_ring ["op +" "op *" "op ^"
   247     "0::'a::{comm_semiring_1,recpower,number_ring}" 1 "op -" "uminus"]
   248   proof qed simp_all
   249 
   250 
   251 declaration {* normalizer_funs @{thm class_ring.gb_ring_axioms'} *}
   252 
   253 use "Tools/Groebner_Basis/normalizer.ML"
   254 
   255 
   256 method_setup sring_norm = {*
   257   Method.ctxt_args (fn ctxt => Method.SIMPLE_METHOD' (Normalizer.semiring_normalize_tac ctxt))
   258 *} "semiring normalizer"
   259 
   260 
   261 locale gb_field = gb_ring +
   262   fixes divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   263     and inverse:: "'a \<Rightarrow> 'a"
   264   assumes divide: "divide x y = mul x (inverse y)"
   265      and inverse: "inverse x = divide r1 x"
   266 begin
   267 
   268 lemmas gb_field_axioms' =
   269   gb_field_axioms [normalizer
   270     semiring ops: semiring_ops
   271     semiring rules: semiring_rules
   272     ring ops: ring_ops
   273     ring rules: ring_rules]
   274 
   275 end
   276 
   277 
   278 subsection {* Groebner Bases *}
   279 
   280 locale semiringb = gb_semiring +
   281   assumes add_cancel: "add (x::'a) y = add x z \<longleftrightarrow> y = z"
   282   and add_mul_solve: "add (mul w y) (mul x z) =
   283     add (mul w z) (mul x y) \<longleftrightarrow> w = x \<or> y = z"
   284 begin
   285 
   286 lemma noteq_reduce: "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   287 proof-
   288   have "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> \<not> (a = b \<or> c = d)" by simp
   289   also have "\<dots> \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   290     using add_mul_solve by blast
   291   finally show "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   292     by simp
   293 qed
   294 
   295 lemma add_scale_eq_noteq: "\<lbrakk>r \<noteq> r0 ; (a = b) \<and> ~(c = d)\<rbrakk>
   296   \<Longrightarrow> add a (mul r c) \<noteq> add b (mul r d)"
   297 proof(clarify)
   298   assume nz: "r\<noteq> r0" and cnd: "c\<noteq>d"
   299     and eq: "add b (mul r c) = add b (mul r d)"
   300   hence "mul r c = mul r d" using cnd add_cancel by simp
   301   hence "add (mul r0 d) (mul r c) = add (mul r0 c) (mul r d)"
   302     using mul_0 add_cancel by simp
   303   thus "False" using add_mul_solve nz cnd by simp
   304 qed
   305 
   306 lemma add_r0_iff: " x = add x a \<longleftrightarrow> a = r0"
   307 proof-
   308   have "a = r0 \<longleftrightarrow> add x a = add x r0" by (simp add: add_cancel)
   309   thus "x = add x a \<longleftrightarrow> a = r0" by (auto simp add: add_c add_0)
   310 qed
   311 
   312 declare gb_semiring_axioms' [normalizer del]
   313 
   314 lemmas semiringb_axioms' = semiringb_axioms [normalizer
   315   semiring ops: semiring_ops
   316   semiring rules: semiring_rules
   317   idom rules: noteq_reduce add_scale_eq_noteq]
   318 
   319 end
   320 
   321 locale ringb = semiringb + gb_ring + 
   322   assumes subr0_iff: "sub x y = r0 \<longleftrightarrow> x = y"
   323 begin
   324 
   325 declare gb_ring_axioms' [normalizer del]
   326 
   327 lemmas ringb_axioms' = ringb_axioms [normalizer
   328   semiring ops: semiring_ops
   329   semiring rules: semiring_rules
   330   ring ops: ring_ops
   331   ring rules: ring_rules
   332   idom rules: noteq_reduce add_scale_eq_noteq
   333   ideal rules: subr0_iff add_r0_iff]
   334 
   335 end
   336 
   337 
   338 lemma no_zero_divirors_neq0:
   339   assumes az: "(a::'a::no_zero_divisors) \<noteq> 0"
   340     and ab: "a*b = 0" shows "b = 0"
   341 proof -
   342   { assume bz: "b \<noteq> 0"
   343     from no_zero_divisors [OF az bz] ab have False by blast }
   344   thus "b = 0" by blast
   345 qed
   346 
   347 interpretation class_ringb: ringb
   348   ["op +" "op *" "op ^" "0::'a::{idom,recpower,number_ring}" "1" "op -" "uminus"]
   349 proof(unfold_locales, simp add: ring_simps power_Suc, auto)
   350   fix w x y z ::"'a::{idom,recpower,number_ring}"
   351   assume p: "w * y + x * z = w * z + x * y" and ynz: "y \<noteq> z"
   352   hence ynz': "y - z \<noteq> 0" by simp
   353   from p have "w * y + x* z - w*z - x*y = 0" by simp
   354   hence "w* (y - z) - x * (y - z) = 0" by (simp add: ring_simps)
   355   hence "(y - z) * (w - x) = 0" by (simp add: ring_simps)
   356   with  no_zero_divirors_neq0 [OF ynz']
   357   have "w - x = 0" by blast
   358   thus "w = x"  by simp
   359 qed
   360 
   361 declaration {* normalizer_funs @{thm class_ringb.ringb_axioms'} *}
   362 
   363 interpretation natgb: semiringb
   364   ["op +" "op *" "op ^" "0::nat" "1"]
   365 proof (unfold_locales, simp add: ring_simps power_Suc)
   366   fix w x y z ::"nat"
   367   { assume p: "w * y + x * z = w * z + x * y" and ynz: "y \<noteq> z"
   368     hence "y < z \<or> y > z" by arith
   369     moreover {
   370       assume lt:"y <z" hence "\<exists>k. z = y + k \<and> k > 0" by (rule_tac x="z - y" in exI, auto)
   371       then obtain k where kp: "k>0" and yz:"z = y + k" by blast
   372       from p have "(w * y + x *y) + x*k = (w * y + x*y) + w*k" by (simp add: yz ring_simps)
   373       hence "x*k = w*k" by simp
   374       hence "w = x" using kp by (simp add: mult_cancel2) }
   375     moreover {
   376       assume lt: "y >z" hence "\<exists>k. y = z + k \<and> k>0" by (rule_tac x="y - z" in exI, auto)
   377       then obtain k where kp: "k>0" and yz:"y = z + k" by blast
   378       from p have "(w * z + x *z) + w*k = (w * z + x*z) + x*k" by (simp add: yz ring_simps)
   379       hence "w*k = x*k" by simp
   380       hence "w = x" using kp by (simp add: mult_cancel2)}
   381     ultimately have "w=x" by blast }
   382   thus "(w * y + x * z = w * z + x * y) = (w = x \<or> y = z)" by auto
   383 qed
   384 
   385 declaration {* normalizer_funs @{thm natgb.semiringb_axioms'} *}
   386 
   387 locale fieldgb = ringb + gb_field
   388 begin
   389 
   390 declare gb_field_axioms' [normalizer del]
   391 
   392 lemmas fieldgb_axioms' = fieldgb_axioms [normalizer
   393   semiring ops: semiring_ops
   394   semiring rules: semiring_rules
   395   ring ops: ring_ops
   396   ring rules: ring_rules
   397   idom rules: noteq_reduce add_scale_eq_noteq
   398   ideal rules: subr0_iff add_r0_iff]
   399 
   400 end
   401 
   402 
   403 lemmas bool_simps = simp_thms(1-34)
   404 lemma dnf:
   405     "(P & (Q | R)) = ((P&Q) | (P&R))" "((Q | R) & P) = ((Q&P) | (R&P))"
   406     "(P \<and> Q) = (Q \<and> P)" "(P \<or> Q) = (Q \<or> P)"
   407   by blast+
   408 
   409 lemmas weak_dnf_simps = dnf bool_simps
   410 
   411 lemma nnf_simps:
   412     "(\<not>(P \<and> Q)) = (\<not>P \<or> \<not>Q)" "(\<not>(P \<or> Q)) = (\<not>P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)"
   413     "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not> \<not>(P)) = P"
   414   by blast+
   415 
   416 lemma PFalse:
   417     "P \<equiv> False \<Longrightarrow> \<not> P"
   418     "\<not> P \<Longrightarrow> (P \<equiv> False)"
   419   by auto
   420 use "Tools/Groebner_Basis/groebner.ML"
   421 
   422 method_setup algebra =
   423 {*
   424 let
   425  fun keyword k = Scan.lift (Args.$$$ k -- Args.colon) >> K ()
   426  val addN = "add"
   427  val delN = "del"
   428  val any_keyword = keyword addN || keyword delN
   429  val thms = Scan.repeat (Scan.unless any_keyword Attrib.multi_thm) >> flat;
   430 in
   431 fn src => Method.syntax 
   432     ((Scan.optional (keyword addN |-- thms) []) -- 
   433     (Scan.optional (keyword delN |-- thms) [])) src 
   434  #> (fn ((add_ths, del_ths), ctxt) => 
   435        Method.SIMPLE_METHOD' (Groebner.algebra_tac add_ths del_ths ctxt))
   436 end
   437 *} "solve polynomial equations over (semi)rings and ideal membership problems using Groebner bases"
   438 declare dvd_def[algebra]
   439 declare dvd_eq_mod_eq_0[symmetric, algebra]
   440 declare nat_mod_div_trivial[algebra]
   441 declare nat_mod_mod_trivial[algebra]
   442 declare conjunct1[OF DIVISION_BY_ZERO, algebra]
   443 declare conjunct2[OF DIVISION_BY_ZERO, algebra]
   444 declare zmod_zdiv_equality[symmetric,algebra]
   445 declare zdiv_zmod_equality[symmetric, algebra]
   446 declare zdiv_zminus_zminus[algebra]
   447 declare zmod_zminus_zminus[algebra]
   448 declare zdiv_zminus2[algebra]
   449 declare zmod_zminus2[algebra]
   450 declare zdiv_zero[algebra]
   451 declare zmod_zero[algebra]
   452 declare zmod_1[algebra]
   453 declare zdiv_1[algebra]
   454 declare zmod_minus1_right[algebra]
   455 declare zdiv_minus1_right[algebra]
   456 declare mod_div_trivial[algebra]
   457 declare mod_mod_trivial[algebra]
   458 declare zmod_zmult_self1[algebra]
   459 declare zmod_zmult_self2[algebra]
   460 declare zmod_eq_0_iff[algebra]
   461 declare zdvd_0_left[algebra]
   462 declare zdvd1_eq[algebra]
   463 declare zmod_eq_dvd_iff[algebra]
   464 declare nat_mod_eq_iff[algebra]
   465 
   466 subsection{* Groebner Bases for fields *}
   467 
   468 interpretation class_fieldgb:
   469   fieldgb["op +" "op *" "op ^" "0::'a::{field,recpower,number_ring}" "1" "op -" "uminus" "op /" "inverse"] apply (unfold_locales) by (simp_all add: divide_inverse)
   470 
   471 lemma divide_Numeral1: "(x::'a::{field,number_ring}) / Numeral1 = x" by simp
   472 lemma divide_Numeral0: "(x::'a::{field,number_ring, division_by_zero}) / Numeral0 = 0"
   473   by simp
   474 lemma mult_frac_frac: "((x::'a::{field,division_by_zero}) / y) * (z / w) = (x*z) / (y*w)"
   475   by simp
   476 lemma mult_frac_num: "((x::'a::{field, division_by_zero}) / y) * z  = (x*z) / y"
   477   by simp
   478 lemma mult_num_frac: "((x::'a::{field, division_by_zero}) / y) * z  = (x*z) / y"
   479   by simp
   480 
   481 lemma Numeral1_eq1_nat: "(1::nat) = Numeral1" by simp
   482 
   483 lemma add_frac_num: "y\<noteq> 0 \<Longrightarrow> (x::'a::{field, division_by_zero}) / y + z = (x + z*y) / y"
   484   by (simp add: add_divide_distrib)
   485 lemma add_num_frac: "y\<noteq> 0 \<Longrightarrow> z + (x::'a::{field, division_by_zero}) / y = (x + z*y) / y"
   486   by (simp add: add_divide_distrib)
   487 
   488 
   489 ML{* 
   490 local
   491  val zr = @{cpat "0"}
   492  val zT = ctyp_of_term zr
   493  val geq = @{cpat "op ="}
   494  val eqT = Thm.dest_ctyp (ctyp_of_term geq) |> hd
   495  val add_frac_eq = mk_meta_eq @{thm "add_frac_eq"}
   496  val add_frac_num = mk_meta_eq @{thm "add_frac_num"}
   497  val add_num_frac = mk_meta_eq @{thm "add_num_frac"}
   498 
   499  fun prove_nz ss T t =
   500     let
   501       val z = instantiate_cterm ([(zT,T)],[]) zr
   502       val eq = instantiate_cterm ([(eqT,T)],[]) geq
   503       val th = Simplifier.rewrite (ss addsimps simp_thms)
   504            (Thm.capply @{cterm "Trueprop"} (Thm.capply @{cterm "Not"}
   505                   (Thm.capply (Thm.capply eq t) z)))
   506     in equal_elim (symmetric th) TrueI
   507     end
   508 
   509  fun proc phi ss ct =
   510   let
   511     val ((x,y),(w,z)) =
   512          (Thm.dest_binop #> (fn (a,b) => (Thm.dest_binop a, Thm.dest_binop b))) ct
   513     val _ = map (HOLogic.dest_number o term_of) [x,y,z,w]
   514     val T = ctyp_of_term x
   515     val [y_nz, z_nz] = map (prove_nz ss T) [y, z]
   516     val th = instantiate' [SOME T] (map SOME [y,z,x,w]) add_frac_eq
   517   in SOME (implies_elim (implies_elim th y_nz) z_nz)
   518   end
   519   handle CTERM _ => NONE | TERM _ => NONE | THM _ => NONE
   520 
   521  fun proc2 phi ss ct =
   522   let
   523     val (l,r) = Thm.dest_binop ct
   524     val T = ctyp_of_term l
   525   in (case (term_of l, term_of r) of
   526       (Const(@{const_name "HOL.divide"},_)$_$_, _) =>
   527         let val (x,y) = Thm.dest_binop l val z = r
   528             val _ = map (HOLogic.dest_number o term_of) [x,y,z]
   529             val ynz = prove_nz ss T y
   530         in SOME (implies_elim (instantiate' [SOME T] (map SOME [y,x,z]) add_frac_num) ynz)
   531         end
   532      | (_, Const (@{const_name "HOL.divide"},_)$_$_) =>
   533         let val (x,y) = Thm.dest_binop r val z = l
   534             val _ = map (HOLogic.dest_number o term_of) [x,y,z]
   535             val ynz = prove_nz ss T y
   536         in SOME (implies_elim (instantiate' [SOME T] (map SOME [y,z,x]) add_num_frac) ynz)
   537         end
   538      | _ => NONE)
   539   end
   540   handle CTERM _ => NONE | TERM _ => NONE | THM _ => NONE
   541 
   542  fun is_number (Const(@{const_name "HOL.divide"},_)$a$b) = is_number a andalso is_number b
   543    | is_number t = can HOLogic.dest_number t
   544 
   545  val is_number = is_number o term_of
   546 
   547  fun proc3 phi ss ct =
   548   (case term_of ct of
   549     Const(@{const_name HOL.less},_)$(Const(@{const_name "HOL.divide"},_)$_$_)$_ =>
   550       let
   551         val ((a,b),c) = Thm.dest_binop ct |>> Thm.dest_binop
   552         val _ = map is_number [a,b,c]
   553         val T = ctyp_of_term c
   554         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "divide_less_eq"}
   555       in SOME (mk_meta_eq th) end
   556   | Const(@{const_name HOL.less_eq},_)$(Const(@{const_name "HOL.divide"},_)$_$_)$_ =>
   557       let
   558         val ((a,b),c) = Thm.dest_binop ct |>> Thm.dest_binop
   559         val _ = map is_number [a,b,c]
   560         val T = ctyp_of_term c
   561         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "divide_le_eq"}
   562       in SOME (mk_meta_eq th) end
   563   | Const("op =",_)$(Const(@{const_name "HOL.divide"},_)$_$_)$_ =>
   564       let
   565         val ((a,b),c) = Thm.dest_binop ct |>> Thm.dest_binop
   566         val _ = map is_number [a,b,c]
   567         val T = ctyp_of_term c
   568         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "divide_eq_eq"}
   569       in SOME (mk_meta_eq th) end
   570   | Const(@{const_name HOL.less},_)$_$(Const(@{const_name "HOL.divide"},_)$_$_) =>
   571     let
   572       val (a,(b,c)) = Thm.dest_binop ct ||> Thm.dest_binop
   573         val _ = map is_number [a,b,c]
   574         val T = ctyp_of_term c
   575         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "less_divide_eq"}
   576       in SOME (mk_meta_eq th) end
   577   | Const(@{const_name HOL.less_eq},_)$_$(Const(@{const_name "HOL.divide"},_)$_$_) =>
   578     let
   579       val (a,(b,c)) = Thm.dest_binop ct ||> Thm.dest_binop
   580         val _ = map is_number [a,b,c]
   581         val T = ctyp_of_term c
   582         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "le_divide_eq"}
   583       in SOME (mk_meta_eq th) end
   584   | Const("op =",_)$_$(Const(@{const_name "HOL.divide"},_)$_$_) =>
   585     let
   586       val (a,(b,c)) = Thm.dest_binop ct ||> Thm.dest_binop
   587         val _ = map is_number [a,b,c]
   588         val T = ctyp_of_term c
   589         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "eq_divide_eq"}
   590       in SOME (mk_meta_eq th) end
   591   | _ => NONE)
   592   handle TERM _ => NONE | CTERM _ => NONE | THM _ => NONE
   593 
   594 val add_frac_frac_simproc =
   595        make_simproc {lhss = [@{cpat "(?x::?'a::field)/?y + (?w::?'a::field)/?z"}],
   596                      name = "add_frac_frac_simproc",
   597                      proc = proc, identifier = []}
   598 
   599 val add_frac_num_simproc =
   600        make_simproc {lhss = [@{cpat "(?x::?'a::field)/?y + ?z"}, @{cpat "?z + (?x::?'a::field)/?y"}],
   601                      name = "add_frac_num_simproc",
   602                      proc = proc2, identifier = []}
   603 
   604 val ord_frac_simproc =
   605   make_simproc
   606     {lhss = [@{cpat "(?a::(?'a::{field, ord}))/?b < ?c"},
   607              @{cpat "(?a::(?'a::{field, ord}))/?b \<le> ?c"},
   608              @{cpat "?c < (?a::(?'a::{field, ord}))/?b"},
   609              @{cpat "?c \<le> (?a::(?'a::{field, ord}))/?b"},
   610              @{cpat "?c = ((?a::(?'a::{field, ord}))/?b)"},
   611              @{cpat "((?a::(?'a::{field, ord}))/ ?b) = ?c"}],
   612              name = "ord_frac_simproc", proc = proc3, identifier = []}
   613 
   614 val ths = [@{thm "mult_numeral_1"}, @{thm "mult_numeral_1_right"},
   615            @{thm "divide_Numeral1"},
   616            @{thm "Ring_and_Field.divide_zero"}, @{thm "divide_Numeral0"},
   617            @{thm "divide_divide_eq_left"}, @{thm "mult_frac_frac"},
   618            @{thm "mult_num_frac"}, @{thm "mult_frac_num"},
   619            @{thm "mult_frac_frac"}, @{thm "times_divide_eq_right"},
   620            @{thm "times_divide_eq_left"}, @{thm "divide_divide_eq_right"},
   621            @{thm "diff_def"}, @{thm "minus_divide_left"},
   622            @{thm "Numeral1_eq1_nat"}, @{thm "add_divide_distrib"} RS sym]
   623 
   624 local
   625 open Conv
   626 in
   627 val comp_conv = (Simplifier.rewrite
   628 (HOL_basic_ss addsimps @{thms "Groebner_Basis.comp_arith"}
   629               addsimps ths addsimps simp_thms
   630               addsimprocs field_cancel_numeral_factors
   631                addsimprocs [add_frac_frac_simproc, add_frac_num_simproc,
   632                             ord_frac_simproc]
   633                 addcongs [@{thm "if_weak_cong"}]))
   634 then_conv (Simplifier.rewrite (HOL_basic_ss addsimps
   635   [@{thm numeral_1_eq_1},@{thm numeral_0_eq_0}] @ @{thms numerals(1-2)}))
   636 end
   637 
   638 fun numeral_is_const ct =
   639   case term_of ct of
   640    Const (@{const_name "HOL.divide"},_) $ a $ b =>
   641      numeral_is_const (Thm.dest_arg1 ct) andalso numeral_is_const (Thm.dest_arg ct)
   642  | Const (@{const_name "HOL.uminus"},_)$t => numeral_is_const (Thm.dest_arg ct)
   643  | t => can HOLogic.dest_number t
   644 
   645 fun dest_const ct = ((case term_of ct of
   646    Const (@{const_name "HOL.divide"},_) $ a $ b=>
   647     Rat.rat_of_quotient (snd (HOLogic.dest_number a), snd (HOLogic.dest_number b))
   648  | t => Rat.rat_of_int (snd (HOLogic.dest_number t))) 
   649    handle TERM _ => error "ring_dest_const")
   650 
   651 fun mk_const phi cT x =
   652  let val (a, b) = Rat.quotient_of_rat x
   653  in if b = 1 then Numeral.mk_cnumber cT a
   654     else Thm.capply
   655          (Thm.capply (Drule.cterm_rule (instantiate' [SOME cT] []) @{cpat "op /"})
   656                      (Numeral.mk_cnumber cT a))
   657          (Numeral.mk_cnumber cT b)
   658   end
   659 
   660 in
   661  val field_comp_conv = comp_conv;
   662  val fieldgb_declaration = 
   663   NormalizerData.funs @{thm class_fieldgb.fieldgb_axioms'}
   664    {is_const = K numeral_is_const,
   665     dest_const = K dest_const,
   666     mk_const = mk_const,
   667     conv = K (K comp_conv)}
   668 end;
   669 *}
   670 
   671 declaration fieldgb_declaration
   672 
   673 end