src/HOL/Tools/inductive.ML
author blanchet
Tue Jun 01 15:38:47 2010 +0200 (2010-06-01)
changeset 37264 8b931fb51cc6
parent 36960 01594f816e3a
child 37734 489ac1ecb9f1
permissions -rw-r--r--
removed "nitpick_intro" attribute -- Nitpick noew uses Spec_Rules instead
     1 (*  Title:      HOL/Tools/inductive.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Stefan Berghofer and Markus Wenzel, TU Muenchen
     4 
     5 (Co)Inductive Definition module for HOL.
     6 
     7 Features:
     8   * least or greatest fixedpoints
     9   * mutually recursive definitions
    10   * definitions involving arbitrary monotone operators
    11   * automatically proves introduction and elimination rules
    12 
    13   Introduction rules have the form
    14   [| M Pj ti, ..., Q x, ... |] ==> Pk t
    15   where M is some monotone operator (usually the identity)
    16   Q x is any side condition on the free variables
    17   ti, t are any terms
    18   Pj, Pk are two of the predicates being defined in mutual recursion
    19 *)
    20 
    21 signature BASIC_INDUCTIVE =
    22 sig
    23   type inductive_result =
    24     {preds: term list, elims: thm list, raw_induct: thm,
    25      induct: thm, inducts: thm list, intrs: thm list}
    26   val morph_result: morphism -> inductive_result -> inductive_result
    27   type inductive_info = {names: string list, coind: bool} * inductive_result
    28   val the_inductive: Proof.context -> string -> inductive_info
    29   val print_inductives: Proof.context -> unit
    30   val mono_add: attribute
    31   val mono_del: attribute
    32   val get_monos: Proof.context -> thm list
    33   val mk_cases: Proof.context -> term -> thm
    34   val inductive_forall_name: string
    35   val inductive_forall_def: thm
    36   val rulify: thm -> thm
    37   val inductive_cases: (Attrib.binding * string list) list -> local_theory ->
    38     thm list list * local_theory
    39   val inductive_cases_i: (Attrib.binding * term list) list -> local_theory ->
    40     thm list list * local_theory
    41   type inductive_flags =
    42     {quiet_mode: bool, verbose: bool, alt_name: binding, coind: bool,
    43       no_elim: bool, no_ind: bool, skip_mono: bool, fork_mono: bool}
    44   val add_inductive_i:
    45     inductive_flags -> ((binding * typ) * mixfix) list ->
    46     (string * typ) list -> (Attrib.binding * term) list -> thm list -> local_theory ->
    47     inductive_result * local_theory
    48   val add_inductive: bool -> bool ->
    49     (binding * string option * mixfix) list ->
    50     (binding * string option * mixfix) list ->
    51     (Attrib.binding * string) list ->
    52     (Facts.ref * Attrib.src list) list ->
    53     bool -> local_theory -> inductive_result * local_theory
    54   val add_inductive_global: inductive_flags ->
    55     ((binding * typ) * mixfix) list -> (string * typ) list -> (Attrib.binding * term) list ->
    56     thm list -> theory -> inductive_result * theory
    57   val arities_of: thm -> (string * int) list
    58   val params_of: thm -> term list
    59   val partition_rules: thm -> thm list -> (string * thm list) list
    60   val partition_rules': thm -> (thm * 'a) list -> (string * (thm * 'a) list) list
    61   val unpartition_rules: thm list -> (string * 'a list) list -> 'a list
    62   val infer_intro_vars: thm -> int -> thm list -> term list list
    63   val setup: theory -> theory
    64 end;
    65 
    66 signature INDUCTIVE =
    67 sig
    68   include BASIC_INDUCTIVE
    69   type add_ind_def =
    70     inductive_flags ->
    71     term list -> (Attrib.binding * term) list -> thm list ->
    72     term list -> (binding * mixfix) list ->
    73     local_theory -> inductive_result * local_theory
    74   val declare_rules: binding -> bool -> bool -> string list -> term list ->
    75     thm list -> binding list -> Attrib.src list list -> (thm * string list * int) list ->
    76     thm -> local_theory -> thm list * thm list * thm * thm list * local_theory
    77   val add_ind_def: add_ind_def
    78   val gen_add_inductive_i: add_ind_def -> inductive_flags ->
    79     ((binding * typ) * mixfix) list -> (string * typ) list -> (Attrib.binding * term) list ->
    80     thm list -> local_theory -> inductive_result * local_theory
    81   val gen_add_inductive: add_ind_def -> bool -> bool ->
    82     (binding * string option * mixfix) list ->
    83     (binding * string option * mixfix) list ->
    84     (Attrib.binding * string) list -> (Facts.ref * Attrib.src list) list ->
    85     bool -> local_theory -> inductive_result * local_theory
    86   val gen_ind_decl: add_ind_def -> bool -> (bool -> local_theory -> local_theory) parser
    87 end;
    88 
    89 structure Inductive: INDUCTIVE =
    90 struct
    91 
    92 
    93 (** theory context references **)
    94 
    95 val inductive_forall_name = "HOL.induct_forall";
    96 val inductive_forall_def = @{thm induct_forall_def};
    97 val inductive_conj_name = "HOL.induct_conj";
    98 val inductive_conj_def = @{thm induct_conj_def};
    99 val inductive_conj = @{thms induct_conj};
   100 val inductive_atomize = @{thms induct_atomize};
   101 val inductive_rulify = @{thms induct_rulify};
   102 val inductive_rulify_fallback = @{thms induct_rulify_fallback};
   103 
   104 val notTrueE = TrueI RSN (2, notE);
   105 val notFalseI = Seq.hd (atac 1 notI);
   106 
   107 val simp_thms' = map mk_meta_eq
   108   @{lemma "(~True) = False" "(~False) = True"
   109       "(True --> P) = P" "(False --> P) = True"
   110       "(P & True) = P" "(True & P) = P"
   111     by (fact simp_thms)+};
   112 
   113 val simp_thms'' = map mk_meta_eq [@{thm inf_fun_eq}, @{thm inf_bool_eq}] @ simp_thms';
   114 
   115 val simp_thms''' = map mk_meta_eq
   116   [@{thm le_fun_def}, @{thm le_bool_def}, @{thm sup_fun_eq}, @{thm sup_bool_eq}];
   117 
   118 
   119 (** context data **)
   120 
   121 type inductive_result =
   122   {preds: term list, elims: thm list, raw_induct: thm,
   123    induct: thm, inducts: thm list, intrs: thm list};
   124 
   125 fun morph_result phi {preds, elims, raw_induct: thm, induct, inducts, intrs} =
   126   let
   127     val term = Morphism.term phi;
   128     val thm = Morphism.thm phi;
   129     val fact = Morphism.fact phi;
   130   in
   131    {preds = map term preds, elims = fact elims, raw_induct = thm raw_induct,
   132     induct = thm induct, inducts = fact inducts, intrs = fact intrs}
   133   end;
   134 
   135 type inductive_info =
   136   {names: string list, coind: bool} * inductive_result;
   137 
   138 structure InductiveData = Generic_Data
   139 (
   140   type T = inductive_info Symtab.table * thm list;
   141   val empty = (Symtab.empty, []);
   142   val extend = I;
   143   fun merge ((tab1, monos1), (tab2, monos2)) : T =
   144     (Symtab.merge (K true) (tab1, tab2), Thm.merge_thms (monos1, monos2));
   145 );
   146 
   147 val get_inductives = InductiveData.get o Context.Proof;
   148 
   149 fun print_inductives ctxt =
   150   let
   151     val (tab, monos) = get_inductives ctxt;
   152     val space = Consts.space_of (ProofContext.consts_of ctxt);
   153   in
   154     [Pretty.strs ("(co)inductives:" :: map #1 (Name_Space.extern_table (space, tab))),
   155      Pretty.big_list "monotonicity rules:" (map (Display.pretty_thm ctxt) monos)]
   156     |> Pretty.chunks |> Pretty.writeln
   157   end;
   158 
   159 
   160 (* get and put data *)
   161 
   162 fun the_inductive ctxt name =
   163   (case Symtab.lookup (#1 (get_inductives ctxt)) name of
   164     NONE => error ("Unknown (co)inductive predicate " ^ quote name)
   165   | SOME info => info);
   166 
   167 fun put_inductives names info = InductiveData.map
   168   (apfst (fold (fn name => Symtab.update (name, info)) names));
   169 
   170 
   171 
   172 (** monotonicity rules **)
   173 
   174 val get_monos = #2 o get_inductives;
   175 val map_monos = InductiveData.map o apsnd;
   176 
   177 fun mk_mono thm =
   178   let
   179     fun eq2mono thm' = thm' RS (thm' RS eq_to_mono);
   180     fun dest_less_concl thm = dest_less_concl (thm RS @{thm le_funD})
   181       handle THM _ => thm RS @{thm le_boolD}
   182   in
   183     case concl_of thm of
   184       Const ("==", _) $ _ $ _ => eq2mono (thm RS meta_eq_to_obj_eq)
   185     | _ $ (Const (@{const_name "op ="}, _) $ _ $ _) => eq2mono thm
   186     | _ $ (Const (@{const_name Orderings.less_eq}, _) $ _ $ _) =>
   187       dest_less_concl (Seq.hd (REPEAT (FIRSTGOAL
   188         (resolve_tac [@{thm le_funI}, @{thm le_boolI'}])) thm))
   189     | _ => thm
   190   end handle THM _ =>
   191     error ("Bad monotonicity theorem:\n" ^ Display.string_of_thm_without_context thm);
   192 
   193 val mono_add = Thm.declaration_attribute (map_monos o Thm.add_thm o mk_mono);
   194 val mono_del = Thm.declaration_attribute (map_monos o Thm.del_thm o mk_mono);
   195 
   196 
   197 
   198 (** misc utilities **)
   199 
   200 fun message quiet_mode s = if quiet_mode then () else writeln s;
   201 fun clean_message quiet_mode s = if ! quick_and_dirty then () else message quiet_mode s;
   202 
   203 fun coind_prefix true = "co"
   204   | coind_prefix false = "";
   205 
   206 fun log (b:int) m n = if m >= n then 0 else 1 + log b (b * m) n;
   207 
   208 fun make_bool_args f g [] i = []
   209   | make_bool_args f g (x :: xs) i =
   210       (if i mod 2 = 0 then f x else g x) :: make_bool_args f g xs (i div 2);
   211 
   212 fun make_bool_args' xs =
   213   make_bool_args (K HOLogic.false_const) (K HOLogic.true_const) xs;
   214 
   215 fun arg_types_of k c = drop k (binder_types (fastype_of c));
   216 
   217 fun find_arg T x [] = sys_error "find_arg"
   218   | find_arg T x ((p as (_, (SOME _, _))) :: ps) =
   219       apsnd (cons p) (find_arg T x ps)
   220   | find_arg T x ((p as (U, (NONE, y))) :: ps) =
   221       if (T: typ) = U then (y, (U, (SOME x, y)) :: ps)
   222       else apsnd (cons p) (find_arg T x ps);
   223 
   224 fun make_args Ts xs =
   225   map (fn (T, (NONE, ())) => Const (@{const_name undefined}, T) | (_, (SOME t, ())) => t)
   226     (fold (fn (t, T) => snd o find_arg T t) xs (map (rpair (NONE, ())) Ts));
   227 
   228 fun make_args' Ts xs Us =
   229   fst (fold_map (fn T => find_arg T ()) Us (Ts ~~ map (pair NONE) xs));
   230 
   231 fun dest_predicate cs params t =
   232   let
   233     val k = length params;
   234     val (c, ts) = strip_comb t;
   235     val (xs, ys) = chop k ts;
   236     val i = find_index (fn c' => c' = c) cs;
   237   in
   238     if xs = params andalso i >= 0 then
   239       SOME (c, i, ys, chop (length ys) (arg_types_of k c))
   240     else NONE
   241   end;
   242 
   243 fun mk_names a 0 = []
   244   | mk_names a 1 = [a]
   245   | mk_names a n = map (fn i => a ^ string_of_int i) (1 upto n);
   246 
   247 
   248 
   249 (** process rules **)
   250 
   251 local
   252 
   253 fun err_in_rule ctxt name t msg =
   254   error (cat_lines ["Ill-formed introduction rule " ^ quote name,
   255     Syntax.string_of_term ctxt t, msg]);
   256 
   257 fun err_in_prem ctxt name t p msg =
   258   error (cat_lines ["Ill-formed premise", Syntax.string_of_term ctxt p,
   259     "in introduction rule " ^ quote name, Syntax.string_of_term ctxt t, msg]);
   260 
   261 val bad_concl = "Conclusion of introduction rule must be an inductive predicate";
   262 
   263 val bad_ind_occ = "Inductive predicate occurs in argument of inductive predicate";
   264 
   265 val bad_app = "Inductive predicate must be applied to parameter(s) ";
   266 
   267 fun atomize_term thy = MetaSimplifier.rewrite_term thy inductive_atomize [];
   268 
   269 in
   270 
   271 fun check_rule ctxt cs params ((binding, att), rule) =
   272   let
   273     val err_name = Binding.str_of binding;
   274     val params' = Term.variant_frees rule (Logic.strip_params rule);
   275     val frees = rev (map Free params');
   276     val concl = subst_bounds (frees, Logic.strip_assums_concl rule);
   277     val prems = map (curry subst_bounds frees) (Logic.strip_assums_hyp rule);
   278     val rule' = Logic.list_implies (prems, concl);
   279     val aprems = map (atomize_term (ProofContext.theory_of ctxt)) prems;
   280     val arule = list_all_free (params', Logic.list_implies (aprems, concl));
   281 
   282     fun check_ind err t = case dest_predicate cs params t of
   283         NONE => err (bad_app ^
   284           commas (map (Syntax.string_of_term ctxt) params))
   285       | SOME (_, _, ys, _) =>
   286           if exists (fn c => exists (fn t => Logic.occs (c, t)) ys) cs
   287           then err bad_ind_occ else ();
   288 
   289     fun check_prem' prem t =
   290       if member (op =) cs (head_of t) then
   291         check_ind (err_in_prem ctxt err_name rule prem) t
   292       else (case t of
   293           Abs (_, _, t) => check_prem' prem t
   294         | t $ u => (check_prem' prem t; check_prem' prem u)
   295         | _ => ());
   296 
   297     fun check_prem (prem, aprem) =
   298       if can HOLogic.dest_Trueprop aprem then check_prem' prem prem
   299       else err_in_prem ctxt err_name rule prem "Non-atomic premise";
   300   in
   301     (case concl of
   302        Const (@{const_name Trueprop}, _) $ t =>
   303          if member (op =) cs (head_of t) then
   304            (check_ind (err_in_rule ctxt err_name rule') t;
   305             List.app check_prem (prems ~~ aprems))
   306          else err_in_rule ctxt err_name rule' bad_concl
   307      | _ => err_in_rule ctxt err_name rule' bad_concl);
   308     ((binding, att), arule)
   309   end;
   310 
   311 val rulify =
   312   hol_simplify inductive_conj
   313   #> hol_simplify inductive_rulify
   314   #> hol_simplify inductive_rulify_fallback
   315   #> Simplifier.norm_hhf;
   316 
   317 end;
   318 
   319 
   320 
   321 (** proofs for (co)inductive predicates **)
   322 
   323 (* prove monotonicity *)
   324 
   325 fun prove_mono quiet_mode skip_mono fork_mono predT fp_fun monos ctxt =
   326  (message (quiet_mode orelse skip_mono andalso !quick_and_dirty orelse fork_mono)
   327     "  Proving monotonicity ...";
   328   (if skip_mono then Skip_Proof.prove else if fork_mono then Goal.prove_future else Goal.prove) ctxt
   329     [] []
   330     (HOLogic.mk_Trueprop
   331       (Const (@{const_name Orderings.mono}, (predT --> predT) --> HOLogic.boolT) $ fp_fun))
   332     (fn _ => EVERY [rtac @{thm monoI} 1,
   333       REPEAT (resolve_tac [@{thm le_funI}, @{thm le_boolI'}] 1),
   334       REPEAT (FIRST
   335         [atac 1,
   336          resolve_tac (map mk_mono monos @ get_monos ctxt) 1,
   337          etac @{thm le_funE} 1, dtac @{thm le_boolD} 1])]));
   338 
   339 
   340 (* prove introduction rules *)
   341 
   342 fun prove_intrs quiet_mode coind mono fp_def k intr_ts rec_preds_defs ctxt ctxt' =
   343   let
   344     val _ = clean_message quiet_mode "  Proving the introduction rules ...";
   345 
   346     val unfold = funpow k (fn th => th RS fun_cong)
   347       (mono RS (fp_def RS
   348         (if coind then @{thm def_gfp_unfold} else @{thm def_lfp_unfold})));
   349 
   350     fun select_disj 1 1 = []
   351       | select_disj _ 1 = [rtac disjI1]
   352       | select_disj n i = (rtac disjI2)::(select_disj (n - 1) (i - 1));
   353 
   354     val rules = [refl, TrueI, notFalseI, exI, conjI];
   355 
   356     val intrs = map_index (fn (i, intr) =>
   357       Skip_Proof.prove ctxt [] [] intr (fn _ => EVERY
   358        [rewrite_goals_tac rec_preds_defs,
   359         rtac (unfold RS iffD2) 1,
   360         EVERY1 (select_disj (length intr_ts) (i + 1)),
   361         (*Not ares_tac, since refl must be tried before any equality assumptions;
   362           backtracking may occur if the premises have extra variables!*)
   363         DEPTH_SOLVE_1 (resolve_tac rules 1 APPEND assume_tac 1)])
   364        |> rulify
   365        |> singleton (ProofContext.export ctxt ctxt')) intr_ts
   366 
   367   in (intrs, unfold) end;
   368 
   369 
   370 (* prove elimination rules *)
   371 
   372 fun prove_elims quiet_mode cs params intr_ts intr_names unfold rec_preds_defs ctxt ctxt''' =
   373   let
   374     val _ = clean_message quiet_mode "  Proving the elimination rules ...";
   375 
   376     val ([pname], ctxt') = Variable.variant_fixes ["P"] ctxt;
   377     val P = HOLogic.mk_Trueprop (Free (pname, HOLogic.boolT));
   378 
   379     fun dest_intr r =
   380       (the (dest_predicate cs params (HOLogic.dest_Trueprop (Logic.strip_assums_concl r))),
   381        Logic.strip_assums_hyp r, Logic.strip_params r);
   382 
   383     val intrs = map dest_intr intr_ts ~~ intr_names;
   384 
   385     val rules1 = [disjE, exE, FalseE];
   386     val rules2 = [conjE, FalseE, notTrueE];
   387 
   388     fun prove_elim c =
   389       let
   390         val Ts = arg_types_of (length params) c;
   391         val (anames, ctxt'') = Variable.variant_fixes (mk_names "a" (length Ts)) ctxt';
   392         val frees = map Free (anames ~~ Ts);
   393 
   394         fun mk_elim_prem ((_, _, us, _), ts, params') =
   395           list_all (params',
   396             Logic.list_implies (map (HOLogic.mk_Trueprop o HOLogic.mk_eq)
   397               (frees ~~ us) @ ts, P));
   398         val c_intrs = filter (equal c o #1 o #1 o #1) intrs;
   399         val prems = HOLogic.mk_Trueprop (list_comb (c, params @ frees)) ::
   400            map mk_elim_prem (map #1 c_intrs)
   401       in
   402         (Skip_Proof.prove ctxt'' [] prems P
   403           (fn {prems, ...} => EVERY
   404             [cut_facts_tac [hd prems] 1,
   405              rewrite_goals_tac rec_preds_defs,
   406              dtac (unfold RS iffD1) 1,
   407              REPEAT (FIRSTGOAL (eresolve_tac rules1)),
   408              REPEAT (FIRSTGOAL (eresolve_tac rules2)),
   409              EVERY (map (fn prem =>
   410                DEPTH_SOLVE_1 (ares_tac [rewrite_rule rec_preds_defs prem, conjI] 1)) (tl prems))])
   411           |> rulify
   412           |> singleton (ProofContext.export ctxt'' ctxt'''),
   413          map #2 c_intrs, length Ts)
   414       end
   415 
   416    in map prove_elim cs end;
   417 
   418 
   419 (* derivation of simplified elimination rules *)
   420 
   421 local
   422 
   423 (*delete needless equality assumptions*)
   424 val refl_thin = Goal.prove_global @{theory HOL} [] [] @{prop "!!P. a = a ==> P ==> P"}
   425   (fn _ => assume_tac 1);
   426 val elim_rls = [asm_rl, FalseE, refl_thin, conjE, exE];
   427 val elim_tac = REPEAT o Tactic.eresolve_tac elim_rls;
   428 
   429 fun simp_case_tac ss i =
   430   EVERY' [elim_tac, asm_full_simp_tac ss, elim_tac, REPEAT o bound_hyp_subst_tac] i;
   431 
   432 in
   433 
   434 fun mk_cases ctxt prop =
   435   let
   436     val thy = ProofContext.theory_of ctxt;
   437     val ss = simpset_of ctxt;
   438 
   439     fun err msg =
   440       error (Pretty.string_of (Pretty.block
   441         [Pretty.str msg, Pretty.fbrk, Syntax.pretty_term ctxt prop]));
   442 
   443     val elims = Induct.find_casesP ctxt prop;
   444 
   445     val cprop = Thm.cterm_of thy prop;
   446     val tac = ALLGOALS (simp_case_tac ss) THEN prune_params_tac;
   447     fun mk_elim rl =
   448       Thm.implies_intr cprop (Tactic.rule_by_tactic ctxt tac (Thm.assume cprop RS rl))
   449       |> singleton (Variable.export (Variable.auto_fixes prop ctxt) ctxt);
   450   in
   451     (case get_first (try mk_elim) elims of
   452       SOME r => r
   453     | NONE => err "Proposition not an inductive predicate:")
   454   end;
   455 
   456 end;
   457 
   458 
   459 (* inductive_cases *)
   460 
   461 fun gen_inductive_cases prep_att prep_prop args lthy =
   462   let
   463     val thy = ProofContext.theory_of lthy;
   464     val facts = args |> map (fn ((a, atts), props) =>
   465       ((a, map (prep_att thy) atts),
   466         map (Thm.no_attributes o single o mk_cases lthy o prep_prop lthy) props));
   467   in lthy |> Local_Theory.notes facts |>> map snd end;
   468 
   469 val inductive_cases = gen_inductive_cases Attrib.intern_src Syntax.read_prop;
   470 val inductive_cases_i = gen_inductive_cases (K I) Syntax.check_prop;
   471 
   472 
   473 val ind_cases_setup =
   474   Method.setup @{binding ind_cases}
   475     (Scan.lift (Scan.repeat1 Args.name_source --
   476       Scan.optional (Args.$$$ "for" |-- Scan.repeat1 Args.name) []) >>
   477       (fn (raw_props, fixes) => fn ctxt =>
   478         let
   479           val (_, ctxt') = Variable.add_fixes fixes ctxt;
   480           val props = Syntax.read_props ctxt' raw_props;
   481           val ctxt'' = fold Variable.declare_term props ctxt';
   482           val rules = ProofContext.export ctxt'' ctxt (map (mk_cases ctxt'') props)
   483         in Method.erule 0 rules end))
   484     "dynamic case analysis on predicates";
   485 
   486 
   487 (* prove induction rule *)
   488 
   489 fun prove_indrule quiet_mode cs argTs bs xs rec_const params intr_ts mono
   490     fp_def rec_preds_defs ctxt ctxt''' =
   491   let
   492     val _ = clean_message quiet_mode "  Proving the induction rule ...";
   493     val thy = ProofContext.theory_of ctxt;
   494 
   495     (* predicates for induction rule *)
   496 
   497     val (pnames, ctxt') = Variable.variant_fixes (mk_names "P" (length cs)) ctxt;
   498     val preds = map2 (curry Free) pnames
   499       (map (fn c => arg_types_of (length params) c ---> HOLogic.boolT) cs);
   500 
   501     (* transform an introduction rule into a premise for induction rule *)
   502 
   503     fun mk_ind_prem r =
   504       let
   505         fun subst s =
   506           (case dest_predicate cs params s of
   507             SOME (_, i, ys, (_, Ts)) =>
   508               let
   509                 val k = length Ts;
   510                 val bs = map Bound (k - 1 downto 0);
   511                 val P = list_comb (List.nth (preds, i),
   512                   map (incr_boundvars k) ys @ bs);
   513                 val Q = list_abs (mk_names "x" k ~~ Ts,
   514                   HOLogic.mk_binop inductive_conj_name
   515                     (list_comb (incr_boundvars k s, bs), P))
   516               in (Q, case Ts of [] => SOME (s, P) | _ => NONE) end
   517           | NONE =>
   518               (case s of
   519                 (t $ u) => (fst (subst t) $ fst (subst u), NONE)
   520               | (Abs (a, T, t)) => (Abs (a, T, fst (subst t)), NONE)
   521               | _ => (s, NONE)));
   522 
   523         fun mk_prem s prems =
   524           (case subst s of
   525             (_, SOME (t, u)) => t :: u :: prems
   526           | (t, _) => t :: prems);
   527 
   528         val SOME (_, i, ys, _) = dest_predicate cs params
   529           (HOLogic.dest_Trueprop (Logic.strip_assums_concl r))
   530 
   531       in list_all_free (Logic.strip_params r,
   532         Logic.list_implies (map HOLogic.mk_Trueprop (fold_rev mk_prem
   533           (map HOLogic.dest_Trueprop (Logic.strip_assums_hyp r)) []),
   534             HOLogic.mk_Trueprop (list_comb (List.nth (preds, i), ys))))
   535       end;
   536 
   537     val ind_prems = map mk_ind_prem intr_ts;
   538 
   539 
   540     (* make conclusions for induction rules *)
   541 
   542     val Tss = map (binder_types o fastype_of) preds;
   543     val (xnames, ctxt'') =
   544       Variable.variant_fixes (mk_names "x" (length (flat Tss))) ctxt';
   545     val mutual_ind_concl = HOLogic.mk_Trueprop (foldr1 HOLogic.mk_conj
   546         (map (fn (((xnames, Ts), c), P) =>
   547            let val frees = map Free (xnames ~~ Ts)
   548            in HOLogic.mk_imp
   549              (list_comb (c, params @ frees), list_comb (P, frees))
   550            end) (unflat Tss xnames ~~ Tss ~~ cs ~~ preds)));
   551 
   552 
   553     (* make predicate for instantiation of abstract induction rule *)
   554 
   555     val ind_pred = fold_rev lambda (bs @ xs) (foldr1 HOLogic.mk_conj
   556       (map_index (fn (i, P) => fold_rev (curry HOLogic.mk_imp)
   557          (make_bool_args HOLogic.mk_not I bs i)
   558          (list_comb (P, make_args' argTs xs (binder_types (fastype_of P))))) preds));
   559 
   560     val ind_concl = HOLogic.mk_Trueprop
   561       (HOLogic.mk_binrel @{const_name Orderings.less_eq} (rec_const, ind_pred));
   562 
   563     val raw_fp_induct = (mono RS (fp_def RS @{thm def_lfp_induct}));
   564 
   565     val induct = Skip_Proof.prove ctxt'' [] ind_prems ind_concl
   566       (fn {prems, ...} => EVERY
   567         [rewrite_goals_tac [inductive_conj_def],
   568          DETERM (rtac raw_fp_induct 1),
   569          REPEAT (resolve_tac [@{thm le_funI}, @{thm le_boolI}] 1),
   570          rewrite_goals_tac simp_thms'',
   571          (*This disjE separates out the introduction rules*)
   572          REPEAT (FIRSTGOAL (eresolve_tac [disjE, exE, FalseE])),
   573          (*Now break down the individual cases.  No disjE here in case
   574            some premise involves disjunction.*)
   575          REPEAT (FIRSTGOAL (etac conjE ORELSE' bound_hyp_subst_tac)),
   576          REPEAT (FIRSTGOAL
   577            (resolve_tac [conjI, impI] ORELSE' (etac notE THEN' atac))),
   578          EVERY (map (fn prem => DEPTH_SOLVE_1 (ares_tac [rewrite_rule
   579              (inductive_conj_def :: rec_preds_defs @ simp_thms'') prem,
   580            conjI, refl] 1)) prems)]);
   581 
   582     val lemma = Skip_Proof.prove ctxt'' [] []
   583       (Logic.mk_implies (ind_concl, mutual_ind_concl)) (fn _ => EVERY
   584         [rewrite_goals_tac rec_preds_defs,
   585          REPEAT (EVERY
   586            [REPEAT (resolve_tac [conjI, impI] 1),
   587             REPEAT (eresolve_tac [@{thm le_funE}, @{thm le_boolE}] 1),
   588             atac 1,
   589             rewrite_goals_tac simp_thms',
   590             atac 1])])
   591 
   592   in singleton (ProofContext.export ctxt'' ctxt''') (induct RS lemma) end;
   593 
   594 
   595 
   596 (** specification of (co)inductive predicates **)
   597 
   598 fun mk_ind_def quiet_mode skip_mono fork_mono alt_name coind
   599     cs intr_ts monos params cnames_syn lthy =
   600   let
   601     val fp_name = if coind then @{const_name Inductive.gfp} else @{const_name Inductive.lfp};
   602 
   603     val argTs = fold (combine (op =) o arg_types_of (length params)) cs [];
   604     val k = log 2 1 (length cs);
   605     val predT = replicate k HOLogic.boolT ---> argTs ---> HOLogic.boolT;
   606     val p :: xs = map Free (Variable.variant_frees lthy intr_ts
   607       (("p", predT) :: (mk_names "x" (length argTs) ~~ argTs)));
   608     val bs = map Free (Variable.variant_frees lthy (p :: xs @ intr_ts)
   609       (map (rpair HOLogic.boolT) (mk_names "b" k)));
   610 
   611     fun subst t =
   612       (case dest_predicate cs params t of
   613         SOME (_, i, ts, (Ts, Us)) =>
   614           let
   615             val l = length Us;
   616             val zs = map Bound (l - 1 downto 0);
   617           in
   618             list_abs (map (pair "z") Us, list_comb (p,
   619               make_bool_args' bs i @ make_args argTs
   620                 ((map (incr_boundvars l) ts ~~ Ts) @ (zs ~~ Us))))
   621           end
   622       | NONE =>
   623           (case t of
   624             t1 $ t2 => subst t1 $ subst t2
   625           | Abs (x, T, u) => Abs (x, T, subst u)
   626           | _ => t));
   627 
   628     (* transform an introduction rule into a conjunction  *)
   629     (*   [| p_i t; ... |] ==> p_j u                       *)
   630     (* is transformed into                                *)
   631     (*   b_j & x_j = u & p b_j t & ...                    *)
   632 
   633     fun transform_rule r =
   634       let
   635         val SOME (_, i, ts, (Ts, _)) = dest_predicate cs params
   636           (HOLogic.dest_Trueprop (Logic.strip_assums_concl r));
   637         val ps = make_bool_args HOLogic.mk_not I bs i @
   638           map HOLogic.mk_eq (make_args' argTs xs Ts ~~ ts) @
   639           map (subst o HOLogic.dest_Trueprop)
   640             (Logic.strip_assums_hyp r)
   641       in
   642         fold_rev (fn (x, T) => fn P => HOLogic.exists_const T $ Abs (x, T, P))
   643           (Logic.strip_params r)
   644           (if null ps then HOLogic.true_const else foldr1 HOLogic.mk_conj ps)
   645       end
   646 
   647     (* make a disjunction of all introduction rules *)
   648 
   649     val fp_fun = fold_rev lambda (p :: bs @ xs)
   650       (if null intr_ts then HOLogic.false_const
   651        else foldr1 HOLogic.mk_disj (map transform_rule intr_ts));
   652 
   653     (* add definiton of recursive predicates to theory *)
   654 
   655     val rec_name =
   656       if Binding.is_empty alt_name then
   657         Binding.name (space_implode "_" (map (Binding.name_of o fst) cnames_syn))
   658       else alt_name;
   659 
   660     val ((rec_const, (_, fp_def)), lthy') = lthy
   661       |> Local_Theory.conceal
   662       |> Local_Theory.define
   663         ((rec_name, case cnames_syn of [(_, syn)] => syn | _ => NoSyn),
   664          ((Binding.empty, [Attrib.internal (K Nitpick_Defs.add)]),
   665          fold_rev lambda params
   666            (Const (fp_name, (predT --> predT) --> predT) $ fp_fun)))
   667       ||> Local_Theory.restore_naming lthy;
   668     val fp_def' = Simplifier.rewrite (HOL_basic_ss addsimps [fp_def])
   669       (cterm_of (ProofContext.theory_of lthy') (list_comb (rec_const, params)));
   670     val specs =
   671       if length cs < 2 then []
   672       else
   673         map_index (fn (i, (name_mx, c)) =>
   674           let
   675             val Ts = arg_types_of (length params) c;
   676             val xs = map Free (Variable.variant_frees lthy intr_ts
   677               (mk_names "x" (length Ts) ~~ Ts))
   678           in
   679             (name_mx, (Attrib.empty_binding, fold_rev lambda (params @ xs)
   680               (list_comb (rec_const, params @ make_bool_args' bs i @
   681                 make_args argTs (xs ~~ Ts)))))
   682           end) (cnames_syn ~~ cs);
   683     val (consts_defs, lthy'') = lthy'
   684       |> Local_Theory.conceal
   685       |> fold_map Local_Theory.define specs
   686       ||> Local_Theory.restore_naming lthy';
   687     val preds = (case cs of [_] => [rec_const] | _ => map #1 consts_defs);
   688 
   689     val (_, lthy''') = Variable.add_fixes (map (fst o dest_Free) params) lthy'';
   690     val mono = prove_mono quiet_mode skip_mono fork_mono predT fp_fun monos lthy''';
   691     val (_, lthy'''') =
   692       Local_Theory.note (apfst Binding.conceal Attrib.empty_binding,
   693         ProofContext.export lthy''' lthy'' [mono]) lthy'';
   694 
   695   in (lthy'''', lthy''', rec_name, mono, fp_def', map (#2 o #2) consts_defs,
   696     list_comb (rec_const, params), preds, argTs, bs, xs)
   697   end;
   698 
   699 fun declare_rules rec_binding coind no_ind cnames
   700     preds intrs intr_bindings intr_atts elims raw_induct lthy =
   701   let
   702     val rec_name = Binding.name_of rec_binding;
   703     fun rec_qualified qualified = Binding.qualify qualified rec_name;
   704     val intr_names = map Binding.name_of intr_bindings;
   705     val ind_case_names = Rule_Cases.case_names intr_names;
   706     val induct =
   707       if coind then
   708         (raw_induct, [Rule_Cases.case_names [rec_name],
   709           Rule_Cases.case_conclusion (rec_name, intr_names),
   710           Rule_Cases.consumes 1, Induct.coinduct_pred (hd cnames)])
   711       else if no_ind orelse length cnames > 1 then
   712         (raw_induct, [ind_case_names, Rule_Cases.consumes 0])
   713       else (raw_induct RSN (2, rev_mp), [ind_case_names, Rule_Cases.consumes 1]);
   714 
   715     val (intrs', lthy1) =
   716       lthy |>
   717       Spec_Rules.add
   718         (if coind then Spec_Rules.Co_Inductive else Spec_Rules.Inductive) (preds, intrs) |>
   719       Local_Theory.notes
   720         (map (rec_qualified false) intr_bindings ~~ intr_atts ~~
   721           map (fn th => [([th],
   722            [Attrib.internal (K (Context_Rules.intro_query NONE))])]) intrs) |>>
   723       map (hd o snd);
   724     val (((_, elims'), (_, [induct'])), lthy2) =
   725       lthy1 |>
   726       Local_Theory.note ((rec_qualified true (Binding.name "intros"), []), intrs') ||>>
   727       fold_map (fn (name, (elim, cases, k)) =>
   728         Local_Theory.note
   729           ((Binding.qualify true (Long_Name.base_name name) (Binding.name "cases"),
   730             [Attrib.internal (K (Rule_Cases.case_names cases)),
   731              Attrib.internal (K (Rule_Cases.consumes 1)),
   732              Attrib.internal (K (Rule_Cases.constraints k)),
   733              Attrib.internal (K (Induct.cases_pred name)),
   734              Attrib.internal (K (Context_Rules.elim_query NONE))]), [elim]) #>
   735         apfst (hd o snd)) (if null elims then [] else cnames ~~ elims) ||>>
   736       Local_Theory.note
   737         ((rec_qualified true (Binding.name (coind_prefix coind ^ "induct")),
   738           map (Attrib.internal o K) (#2 induct)), [rulify (#1 induct)]);
   739 
   740     val (inducts, lthy3) =
   741       if no_ind orelse coind then ([], lthy2)
   742       else
   743         let val inducts = cnames ~~ Project_Rule.projects lthy2 (1 upto length cnames) induct' in
   744           lthy2 |>
   745           Local_Theory.notes [((rec_qualified true (Binding.name "inducts"), []),
   746             inducts |> map (fn (name, th) => ([th],
   747               [Attrib.internal (K ind_case_names),
   748                Attrib.internal (K (Rule_Cases.consumes 1)),
   749                Attrib.internal (K (Induct.induct_pred name))])))] |>> snd o hd
   750         end;
   751   in (intrs', elims', induct', inducts, lthy3) end;
   752 
   753 type inductive_flags =
   754   {quiet_mode: bool, verbose: bool, alt_name: binding, coind: bool,
   755     no_elim: bool, no_ind: bool, skip_mono: bool, fork_mono: bool};
   756 
   757 type add_ind_def =
   758   inductive_flags ->
   759   term list -> (Attrib.binding * term) list -> thm list ->
   760   term list -> (binding * mixfix) list ->
   761   local_theory -> inductive_result * local_theory;
   762 
   763 fun add_ind_def {quiet_mode, verbose, alt_name, coind, no_elim, no_ind, skip_mono, fork_mono}
   764     cs intros monos params cnames_syn lthy =
   765   let
   766     val _ = null cnames_syn andalso error "No inductive predicates given";
   767     val names = map (Binding.name_of o fst) cnames_syn;
   768     val _ = message (quiet_mode andalso not verbose)
   769       ("Proofs for " ^ coind_prefix coind ^ "inductive predicate(s) " ^ commas_quote names);
   770 
   771     val cnames = map (Local_Theory.full_name lthy o #1) cnames_syn;  (* FIXME *)
   772     val ((intr_names, intr_atts), intr_ts) =
   773       apfst split_list (split_list (map (check_rule lthy cs params) intros));
   774 
   775     val (lthy1, lthy2, rec_name, mono, fp_def, rec_preds_defs, rec_const, preds,
   776       argTs, bs, xs) = mk_ind_def quiet_mode skip_mono fork_mono alt_name coind cs intr_ts
   777         monos params cnames_syn lthy;
   778 
   779     val (intrs, unfold) = prove_intrs quiet_mode coind mono fp_def (length bs + length xs)
   780       intr_ts rec_preds_defs lthy2 lthy1;
   781     val elims =
   782       if no_elim then []
   783       else
   784         prove_elims quiet_mode cs params intr_ts (map Binding.name_of intr_names)
   785           unfold rec_preds_defs lthy2 lthy1;
   786     val raw_induct = zero_var_indexes
   787       (if no_ind then Drule.asm_rl
   788        else if coind then
   789          singleton (ProofContext.export lthy2 lthy1)
   790            (rotate_prems ~1 (Object_Logic.rulify
   791              (fold_rule rec_preds_defs
   792                (rewrite_rule simp_thms'''
   793                 (mono RS (fp_def RS @{thm def_coinduct}))))))
   794        else
   795          prove_indrule quiet_mode cs argTs bs xs rec_const params intr_ts mono fp_def
   796            rec_preds_defs lthy2 lthy1);
   797 
   798     val (intrs', elims', induct, inducts, lthy3) = declare_rules rec_name coind no_ind
   799       cnames preds intrs intr_names intr_atts elims raw_induct lthy1;
   800 
   801     val result =
   802       {preds = preds,
   803        intrs = intrs',
   804        elims = elims',
   805        raw_induct = rulify raw_induct,
   806        induct = induct,
   807        inducts = inducts};
   808 
   809     val lthy4 = lthy3
   810       |> Local_Theory.declaration false (fn phi =>
   811         let val result' = morph_result phi result;
   812         in put_inductives cnames (*global names!?*) ({names = cnames, coind = coind}, result') end);
   813   in (result, lthy4) end;
   814 
   815 
   816 (* external interfaces *)
   817 
   818 fun gen_add_inductive_i mk_def
   819     (flags as {quiet_mode, verbose, alt_name, coind, no_elim, no_ind, skip_mono, fork_mono})
   820     cnames_syn pnames spec monos lthy =
   821   let
   822     val thy = ProofContext.theory_of lthy;
   823     val _ = Theory.requires thy "Inductive" (coind_prefix coind ^ "inductive definitions");
   824 
   825 
   826     (* abbrevs *)
   827 
   828     val (_, ctxt1) = Variable.add_fixes (map (Binding.name_of o fst o fst) cnames_syn) lthy;
   829 
   830     fun get_abbrev ((name, atts), t) =
   831       if can (Logic.strip_assums_concl #> Logic.dest_equals) t then
   832         let
   833           val _ = Binding.is_empty name andalso null atts orelse
   834             error "Abbreviations may not have names or attributes";
   835           val ((x, T), rhs) = Local_Defs.abs_def (snd (Local_Defs.cert_def ctxt1 t));
   836           val var =
   837             (case find_first (fn ((c, _), _) => Binding.name_of c = x) cnames_syn of
   838               NONE => error ("Undeclared head of abbreviation " ^ quote x)
   839             | SOME ((b, T'), mx) =>
   840                 if T <> T' then error ("Bad type specification for abbreviation " ^ quote x)
   841                 else (b, mx));
   842         in SOME (var, rhs) end
   843       else NONE;
   844 
   845     val abbrevs = map_filter get_abbrev spec;
   846     val bs = map (Binding.name_of o fst o fst) abbrevs;
   847 
   848 
   849     (* predicates *)
   850 
   851     val pre_intros = filter_out (is_some o get_abbrev) spec;
   852     val cnames_syn' = filter_out (member (op =) bs o Binding.name_of o fst o fst) cnames_syn;
   853     val cs = map (Free o apfst Binding.name_of o fst) cnames_syn';
   854     val ps = map Free pnames;
   855 
   856     val (_, ctxt2) = lthy |> Variable.add_fixes (map (Binding.name_of o fst o fst) cnames_syn');
   857     val _ = map (fn abbr => Local_Defs.fixed_abbrev abbr ctxt2) abbrevs;
   858     val ctxt3 = ctxt2 |> fold (snd oo Local_Defs.fixed_abbrev) abbrevs;
   859     val expand = Assumption.export_term ctxt3 lthy #> ProofContext.cert_term lthy;
   860 
   861     fun close_rule r = list_all_free (rev (fold_aterms
   862       (fn t as Free (v as (s, _)) =>
   863           if Variable.is_fixed ctxt1 s orelse
   864             member (op =) ps t then I else insert (op =) v
   865         | _ => I) r []), r);
   866 
   867     val intros = map (apsnd (Syntax.check_term lthy #> close_rule #> expand)) pre_intros;
   868     val preds = map (fn ((c, _), mx) => (c, mx)) cnames_syn';
   869   in
   870     lthy
   871     |> mk_def flags cs intros monos ps preds
   872     ||> fold (snd oo Local_Theory.abbrev Syntax.mode_default) abbrevs
   873   end;
   874 
   875 fun gen_add_inductive mk_def verbose coind cnames_syn pnames_syn intro_srcs raw_monos int lthy =
   876   let
   877     val ((vars, intrs), _) = lthy
   878       |> ProofContext.set_mode ProofContext.mode_abbrev
   879       |> Specification.read_spec (cnames_syn @ pnames_syn) intro_srcs;
   880     val (cs, ps) = chop (length cnames_syn) vars;
   881     val monos = Attrib.eval_thms lthy raw_monos;
   882     val flags = {quiet_mode = false, verbose = verbose, alt_name = Binding.empty,
   883       coind = coind, no_elim = false, no_ind = false, skip_mono = false, fork_mono = not int};
   884   in
   885     lthy
   886     |> gen_add_inductive_i mk_def flags cs (map (apfst Binding.name_of o fst) ps) intrs monos
   887   end;
   888 
   889 val add_inductive_i = gen_add_inductive_i add_ind_def;
   890 val add_inductive = gen_add_inductive add_ind_def;
   891 
   892 fun add_inductive_global flags cnames_syn pnames pre_intros monos thy =
   893   let
   894     val name = Sign.full_name thy (fst (fst (hd cnames_syn)));
   895     val ctxt' = thy
   896       |> Theory_Target.init NONE
   897       |> add_inductive_i flags cnames_syn pnames pre_intros monos |> snd
   898       |> Local_Theory.exit;
   899     val info = #2 (the_inductive ctxt' name);
   900   in (info, ProofContext.theory_of ctxt') end;
   901 
   902 
   903 (* read off arities of inductive predicates from raw induction rule *)
   904 fun arities_of induct =
   905   map (fn (_ $ t $ u) =>
   906       (fst (dest_Const (head_of t)), length (snd (strip_comb u))))
   907     (HOLogic.dest_conj (HOLogic.dest_Trueprop (concl_of induct)));
   908 
   909 (* read off parameters of inductive predicate from raw induction rule *)
   910 fun params_of induct =
   911   let
   912     val (_ $ t $ u :: _) =
   913       HOLogic.dest_conj (HOLogic.dest_Trueprop (concl_of induct));
   914     val (_, ts) = strip_comb t;
   915     val (_, us) = strip_comb u
   916   in
   917     List.take (ts, length ts - length us)
   918   end;
   919 
   920 val pname_of_intr =
   921   concl_of #> HOLogic.dest_Trueprop #> head_of #> dest_Const #> fst;
   922 
   923 (* partition introduction rules according to predicate name *)
   924 fun gen_partition_rules f induct intros =
   925   fold_rev (fn r => AList.map_entry op = (pname_of_intr (f r)) (cons r)) intros
   926     (map (rpair [] o fst) (arities_of induct));
   927 
   928 val partition_rules = gen_partition_rules I;
   929 fun partition_rules' induct = gen_partition_rules fst induct;
   930 
   931 fun unpartition_rules intros xs =
   932   fold_map (fn r => AList.map_entry_yield op = (pname_of_intr r)
   933     (fn x :: xs => (x, xs)) #>> the) intros xs |> fst;
   934 
   935 (* infer order of variables in intro rules from order of quantifiers in elim rule *)
   936 fun infer_intro_vars elim arity intros =
   937   let
   938     val thy = theory_of_thm elim;
   939     val _ :: cases = prems_of elim;
   940     val used = map (fst o fst) (Term.add_vars (prop_of elim) []);
   941     fun mtch (t, u) =
   942       let
   943         val params = Logic.strip_params t;
   944         val vars = map (Var o apfst (rpair 0))
   945           (Name.variant_list used (map fst params) ~~ map snd params);
   946         val ts = map (curry subst_bounds (rev vars))
   947           (List.drop (Logic.strip_assums_hyp t, arity));
   948         val us = Logic.strip_imp_prems u;
   949         val tab = fold (Pattern.first_order_match thy) (ts ~~ us)
   950           (Vartab.empty, Vartab.empty);
   951       in
   952         map (Envir.subst_term tab) vars
   953       end
   954   in
   955     map (mtch o apsnd prop_of) (cases ~~ intros)
   956   end;
   957 
   958 
   959 
   960 (** package setup **)
   961 
   962 (* setup theory *)
   963 
   964 val setup =
   965   ind_cases_setup #>
   966   Attrib.setup @{binding mono} (Attrib.add_del mono_add mono_del)
   967     "declaration of monotonicity rule";
   968 
   969 
   970 (* outer syntax *)
   971 
   972 val _ = Keyword.keyword "monos";
   973 
   974 fun gen_ind_decl mk_def coind =
   975   Parse.fixes -- Parse.for_fixes --
   976   Scan.optional Parse_Spec.where_alt_specs [] --
   977   Scan.optional (Parse.$$$ "monos" |-- Parse.!!! Parse_Spec.xthms1) []
   978   >> (fn (((preds, params), specs), monos) =>
   979       (snd oo gen_add_inductive mk_def true coind preds params specs monos));
   980 
   981 val ind_decl = gen_ind_decl add_ind_def;
   982 
   983 val _ =
   984   Outer_Syntax.local_theory' "inductive" "define inductive predicates" Keyword.thy_decl
   985     (ind_decl false);
   986 
   987 val _ =
   988   Outer_Syntax.local_theory' "coinductive" "define coinductive predicates" Keyword.thy_decl
   989     (ind_decl true);
   990 
   991 val _ =
   992   Outer_Syntax.local_theory "inductive_cases"
   993     "create simplified instances of elimination rules (improper)" Keyword.thy_script
   994     (Parse.and_list1 Parse_Spec.specs >> (snd oo inductive_cases));
   995 
   996 end;