src/HOL/Divides.thy
author haftmann
Tue Jul 10 09:23:10 2007 +0200 (2007-07-10)
changeset 23684 8c508c4dc53b
parent 23162 b9853c187a1e
child 23948 261bd4678076
permissions -rw-r--r--
introduced (auxiliary) class dvd_mod for more convenient code generation
     1 (*  Title:      HOL/Divides.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1999  University of Cambridge
     5 *)
     6 
     7 header {* The division operators div, mod and the divides relation "dvd" *}
     8 
     9 theory Divides
    10 imports Datatype Power
    11 uses "~~/src/Provers/Arith/cancel_div_mod.ML"
    12 begin
    13 
    14 (*We use the same class for div and mod;
    15   moreover, dvd is defined whenever multiplication is*)
    16 class div = type +
    17   fixes div :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "\<^loc>div" 70)
    18   fixes mod :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "\<^loc>mod" 70)
    19 
    20 instance nat :: Divides.div
    21   div_def: "m div n == wfrec (pred_nat^+)
    22                           (%f j. if j<n | n=0 then 0 else Suc (f (j-n))) m"
    23   mod_def: "m mod n == wfrec (pred_nat^+)
    24                           (%f j. if j<n | n=0 then j else f (j-n)) m" ..
    25 
    26 definition (in times)
    27   dvd  :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infixl "\<^loc>dvd" 50)
    28 where
    29   "m \<^loc>dvd n \<longleftrightarrow> (\<exists>k. n = m \<^loc>* k)"
    30 lemmas dvd_def = dvd_def [folded times_class.dvd]
    31 
    32 class dvd_mod = times + div + zero + -- {* for code generation *}
    33   assumes dvd_def_mod: "times.dvd (op \<^loc>*) x y \<longleftrightarrow> y \<^loc>mod x = \<^loc>0"
    34 lemmas dvd_def_mod [code func] = dvd_def_mod [folded times_class.dvd]
    35 
    36 definition
    37   quorem :: "(nat*nat) * (nat*nat) => bool" where
    38   (*This definition helps prove the harder properties of div and mod.
    39     It is copied from IntDiv.thy; should it be overloaded?*)
    40   "quorem = (%((a,b), (q,r)).
    41                     a = b*q + r &
    42                     (if 0<b then 0\<le>r & r<b else b<r & r \<le>0))"
    43 
    44 
    45 
    46 subsection{*Initial Lemmas*}
    47 
    48 lemmas wf_less_trans =
    49        def_wfrec [THEN trans, OF eq_reflection wf_pred_nat [THEN wf_trancl],
    50                   standard]
    51 
    52 lemma mod_eq: "(%m. m mod n) =
    53               wfrec (pred_nat^+) (%f j. if j<n | n=0 then j else f (j-n))"
    54 by (simp add: mod_def)
    55 
    56 lemma div_eq: "(%m. m div n) = wfrec (pred_nat^+)
    57                (%f j. if j<n | n=0 then 0 else Suc (f (j-n)))"
    58 by (simp add: div_def)
    59 
    60 
    61 (** Aribtrary definitions for division by zero.  Useful to simplify
    62     certain equations **)
    63 
    64 lemma DIVISION_BY_ZERO_DIV [simp]: "a div 0 = (0::nat)"
    65   by (rule div_eq [THEN wf_less_trans], simp)
    66 
    67 lemma DIVISION_BY_ZERO_MOD [simp]: "a mod 0 = (a::nat)"
    68   by (rule mod_eq [THEN wf_less_trans], simp)
    69 
    70 
    71 subsection{*Remainder*}
    72 
    73 lemma mod_less [simp]: "m<n ==> m mod n = (m::nat)"
    74   by (rule mod_eq [THEN wf_less_trans]) simp
    75 
    76 lemma mod_geq: "~ m < (n::nat) ==> m mod n = (m-n) mod n"
    77   apply (cases "n=0")
    78    apply simp
    79   apply (rule mod_eq [THEN wf_less_trans])
    80   apply (simp add: cut_apply less_eq)
    81   done
    82 
    83 (*Avoids the ugly ~m<n above*)
    84 lemma le_mod_geq: "(n::nat) \<le> m ==> m mod n = (m-n) mod n"
    85   by (simp add: mod_geq linorder_not_less)
    86 
    87 lemma mod_if: "m mod (n::nat) = (if m<n then m else (m-n) mod n)"
    88   by (simp add: mod_geq)
    89 
    90 lemma mod_1 [simp]: "m mod Suc 0 = 0"
    91   by (induct m) (simp_all add: mod_geq)
    92 
    93 lemma mod_self [simp]: "n mod n = (0::nat)"
    94   by (cases "n = 0") (simp_all add: mod_geq)
    95 
    96 lemma mod_add_self2 [simp]: "(m+n) mod n = m mod (n::nat)"
    97   apply (subgoal_tac "(n + m) mod n = (n+m-n) mod n")
    98    apply (simp add: add_commute)
    99   apply (subst mod_geq [symmetric], simp_all)
   100   done
   101 
   102 lemma mod_add_self1 [simp]: "(n+m) mod n = m mod (n::nat)"
   103   by (simp add: add_commute mod_add_self2)
   104 
   105 lemma mod_mult_self1 [simp]: "(m + k*n) mod n = m mod (n::nat)"
   106   by (induct k) (simp_all add: add_left_commute [of _ n])
   107 
   108 lemma mod_mult_self2 [simp]: "(m + n*k) mod n = m mod (n::nat)"
   109   by (simp add: mult_commute mod_mult_self1)
   110 
   111 lemma mod_mult_distrib: "(m mod n) * (k::nat) = (m*k) mod (n*k)"
   112   apply (cases "n = 0", simp)
   113   apply (cases "k = 0", simp)
   114   apply (induct m rule: nat_less_induct)
   115   apply (subst mod_if, simp)
   116   apply (simp add: mod_geq diff_mult_distrib)
   117   done
   118 
   119 lemma mod_mult_distrib2: "(k::nat) * (m mod n) = (k*m) mod (k*n)"
   120   by (simp add: mult_commute [of k] mod_mult_distrib)
   121 
   122 lemma mod_mult_self_is_0 [simp]: "(m*n) mod n = (0::nat)"
   123   apply (cases "n = 0", simp)
   124   apply (induct m, simp)
   125   apply (rename_tac k)
   126   apply (cut_tac m = "k * n" and n = n in mod_add_self2)
   127   apply (simp add: add_commute)
   128   done
   129 
   130 lemma mod_mult_self1_is_0 [simp]: "(n*m) mod n = (0::nat)"
   131   by (simp add: mult_commute mod_mult_self_is_0)
   132 
   133 
   134 subsection{*Quotient*}
   135 
   136 lemma div_less [simp]: "m<n ==> m div n = (0::nat)"
   137   by (rule div_eq [THEN wf_less_trans], simp)
   138 
   139 lemma div_geq: "[| 0<n;  ~m<n |] ==> m div n = Suc((m-n) div n)"
   140   apply (rule div_eq [THEN wf_less_trans])
   141   apply (simp add: cut_apply less_eq)
   142   done
   143 
   144 (*Avoids the ugly ~m<n above*)
   145 lemma le_div_geq: "[| 0<n;  n\<le>m |] ==> m div n = Suc((m-n) div n)"
   146   by (simp add: div_geq linorder_not_less)
   147 
   148 lemma div_if: "0<n ==> m div n = (if m<n then 0 else Suc((m-n) div n))"
   149   by (simp add: div_geq)
   150 
   151 
   152 (*Main Result about quotient and remainder.*)
   153 lemma mod_div_equality: "(m div n)*n + m mod n = (m::nat)"
   154   apply (cases "n = 0", simp)
   155   apply (induct m rule: nat_less_induct)
   156   apply (subst mod_if)
   157   apply (simp_all add: add_assoc div_geq add_diff_inverse)
   158   done
   159 
   160 lemma mod_div_equality2: "n * (m div n) + m mod n = (m::nat)"
   161   apply (cut_tac m = m and n = n in mod_div_equality)
   162   apply (simp add: mult_commute)
   163   done
   164 
   165 subsection{*Simproc for Cancelling Div and Mod*}
   166 
   167 lemma div_mod_equality: "((m div n)*n + m mod n) + k = (m::nat) + k"
   168   by (simp add: mod_div_equality)
   169 
   170 lemma div_mod_equality2: "(n*(m div n) + m mod n) + k = (m::nat) + k"
   171   by (simp add: mod_div_equality2)
   172 
   173 ML
   174 {*
   175 structure CancelDivModData =
   176 struct
   177 
   178 val div_name = @{const_name Divides.div};
   179 val mod_name = @{const_name Divides.mod};
   180 val mk_binop = HOLogic.mk_binop;
   181 val mk_sum = NatArithUtils.mk_sum;
   182 val dest_sum = NatArithUtils.dest_sum;
   183 
   184 (*logic*)
   185 
   186 val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}]
   187 
   188 val trans = trans
   189 
   190 val prove_eq_sums =
   191   let val simps = @{thm add_0} :: @{thm add_0_right} :: @{thms add_ac}
   192   in NatArithUtils.prove_conv all_tac (NatArithUtils.simp_all_tac simps) end;
   193 
   194 end;
   195 
   196 structure CancelDivMod = CancelDivModFun(CancelDivModData);
   197 
   198 val cancel_div_mod_proc = NatArithUtils.prep_simproc
   199       ("cancel_div_mod", ["(m::nat) + n"], K CancelDivMod.proc);
   200 
   201 Addsimprocs[cancel_div_mod_proc];
   202 *}
   203 
   204 
   205 (* a simple rearrangement of mod_div_equality: *)
   206 lemma mult_div_cancel: "(n::nat) * (m div n) = m - (m mod n)"
   207   by (cut_tac m = m and n = n in mod_div_equality2, arith)
   208 
   209 lemma mod_less_divisor [simp]: "0<n ==> m mod n < (n::nat)"
   210   apply (induct m rule: nat_less_induct)
   211   apply (rename_tac m)
   212   apply (case_tac "m<n", simp)
   213   txt{*case @{term "n \<le> m"}*}
   214   apply (simp add: mod_geq)
   215   done
   216 
   217 lemma mod_le_divisor[simp]: "0 < n \<Longrightarrow> m mod n \<le> (n::nat)"
   218   apply (drule mod_less_divisor [where m = m])
   219   apply simp
   220   done
   221 
   222 lemma div_mult_self_is_m [simp]: "0<n ==> (m*n) div n = (m::nat)"
   223   by (cut_tac m = "m*n" and n = n in mod_div_equality, auto)
   224 
   225 lemma div_mult_self1_is_m [simp]: "0<n ==> (n*m) div n = (m::nat)"
   226   by (simp add: mult_commute div_mult_self_is_m)
   227 
   228 (*mod_mult_distrib2 above is the counterpart for remainder*)
   229 
   230 
   231 subsection{*Proving facts about Quotient and Remainder*}
   232 
   233 lemma unique_quotient_lemma:
   234      "[| b*q' + r'  \<le> b*q + r;  x < b;  r < b |]
   235       ==> q' \<le> (q::nat)"
   236   apply (rule leI)
   237   apply (subst less_iff_Suc_add)
   238   apply (auto simp add: add_mult_distrib2)
   239   done
   240 
   241 lemma unique_quotient:
   242      "[| quorem ((a,b), (q,r));  quorem ((a,b), (q',r'));  0 < b |]
   243       ==> q = q'"
   244   apply (simp add: split_ifs quorem_def)
   245   apply (blast intro: order_antisym
   246     dest: order_eq_refl [THEN unique_quotient_lemma] sym)
   247   done
   248 
   249 lemma unique_remainder:
   250      "[| quorem ((a,b), (q,r));  quorem ((a,b), (q',r'));  0 < b |]
   251       ==> r = r'"
   252   apply (subgoal_tac "q = q'")
   253    prefer 2 apply (blast intro: unique_quotient)
   254   apply (simp add: quorem_def)
   255   done
   256 
   257 lemma quorem_div_mod: "0 < b ==> quorem ((a, b), (a div b, a mod b))"
   258   unfolding quorem_def by simp
   259 
   260 lemma quorem_div: "[| quorem((a,b),(q,r));  0 < b |] ==> a div b = q"
   261   by (simp add: quorem_div_mod [THEN unique_quotient])
   262 
   263 lemma quorem_mod: "[| quorem((a,b),(q,r));  0 < b |] ==> a mod b = r"
   264   by (simp add: quorem_div_mod [THEN unique_remainder])
   265 
   266 (** A dividend of zero **)
   267 
   268 lemma div_0 [simp]: "0 div m = (0::nat)"
   269   by (cases "m = 0") simp_all
   270 
   271 lemma mod_0 [simp]: "0 mod m = (0::nat)"
   272   by (cases "m = 0") simp_all
   273 
   274 (** proving (a*b) div c = a * (b div c) + a * (b mod c) **)
   275 
   276 lemma quorem_mult1_eq:
   277      "[| quorem((b,c),(q,r));  0 < c |]
   278       ==> quorem ((a*b, c), (a*q + a*r div c, a*r mod c))"
   279   by (auto simp add: split_ifs mult_ac quorem_def add_mult_distrib2)
   280 
   281 lemma div_mult1_eq: "(a*b) div c = a*(b div c) + a*(b mod c) div (c::nat)"
   282   apply (cases "c = 0", simp)
   283   apply (blast intro: quorem_div_mod [THEN quorem_mult1_eq, THEN quorem_div])
   284   done
   285 
   286 lemma mod_mult1_eq: "(a*b) mod c = a*(b mod c) mod (c::nat)"
   287   apply (cases "c = 0", simp)
   288   apply (blast intro: quorem_div_mod [THEN quorem_mult1_eq, THEN quorem_mod])
   289   done
   290 
   291 lemma mod_mult1_eq': "(a*b) mod (c::nat) = ((a mod c) * b) mod c"
   292   apply (rule trans)
   293    apply (rule_tac s = "b*a mod c" in trans)
   294     apply (rule_tac [2] mod_mult1_eq)
   295    apply (simp_all add: mult_commute)
   296   done
   297 
   298 lemma mod_mult_distrib_mod: "(a*b) mod (c::nat) = ((a mod c) * (b mod c)) mod c"
   299   apply (rule mod_mult1_eq' [THEN trans])
   300   apply (rule mod_mult1_eq)
   301   done
   302 
   303 (** proving (a+b) div c = a div c + b div c + ((a mod c + b mod c) div c) **)
   304 
   305 lemma quorem_add1_eq:
   306      "[| quorem((a,c),(aq,ar));  quorem((b,c),(bq,br));  0 < c |]
   307       ==> quorem ((a+b, c), (aq + bq + (ar+br) div c, (ar+br) mod c))"
   308   by (auto simp add: split_ifs mult_ac quorem_def add_mult_distrib2)
   309 
   310 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
   311 lemma div_add1_eq:
   312      "(a+b) div (c::nat) = a div c + b div c + ((a mod c + b mod c) div c)"
   313   apply (cases "c = 0", simp)
   314   apply (blast intro: quorem_add1_eq [THEN quorem_div] quorem_div_mod quorem_div_mod)
   315   done
   316 
   317 lemma mod_add1_eq: "(a+b) mod (c::nat) = (a mod c + b mod c) mod c"
   318   apply (cases "c = 0", simp)
   319   apply (blast intro: quorem_div_mod quorem_div_mod quorem_add1_eq [THEN quorem_mod])
   320   done
   321 
   322 
   323 subsection{*Proving @{term "a div (b*c) = (a div b) div c"}*}
   324 
   325 (** first, a lemma to bound the remainder **)
   326 
   327 lemma mod_lemma: "[| (0::nat) < c; r < b |] ==> b * (q mod c) + r < b * c"
   328   apply (cut_tac m = q and n = c in mod_less_divisor)
   329   apply (drule_tac [2] m = "q mod c" in less_imp_Suc_add, auto)
   330   apply (erule_tac P = "%x. ?lhs < ?rhs x" in ssubst)
   331   apply (simp add: add_mult_distrib2)
   332   done
   333 
   334 lemma quorem_mult2_eq: "[| quorem ((a,b), (q,r));  0 < b;  0 < c |]
   335       ==> quorem ((a, b*c), (q div c, b*(q mod c) + r))"
   336   by (auto simp add: mult_ac quorem_def add_mult_distrib2 [symmetric] mod_lemma)
   337 
   338 lemma div_mult2_eq: "a div (b*c) = (a div b) div (c::nat)"
   339   apply (cases "b = 0", simp)
   340   apply (cases "c = 0", simp)
   341   apply (force simp add: quorem_div_mod [THEN quorem_mult2_eq, THEN quorem_div])
   342   done
   343 
   344 lemma mod_mult2_eq: "a mod (b*c) = b*(a div b mod c) + a mod (b::nat)"
   345   apply (cases "b = 0", simp)
   346   apply (cases "c = 0", simp)
   347   apply (auto simp add: mult_commute quorem_div_mod [THEN quorem_mult2_eq, THEN quorem_mod])
   348   done
   349 
   350 
   351 subsection{*Cancellation of Common Factors in Division*}
   352 
   353 lemma div_mult_mult_lemma:
   354     "[| (0::nat) < b;  0 < c |] ==> (c*a) div (c*b) = a div b"
   355   by (auto simp add: div_mult2_eq)
   356 
   357 lemma div_mult_mult1 [simp]: "(0::nat) < c ==> (c*a) div (c*b) = a div b"
   358   apply (cases "b = 0")
   359   apply (auto simp add: linorder_neq_iff [of b] div_mult_mult_lemma)
   360   done
   361 
   362 lemma div_mult_mult2 [simp]: "(0::nat) < c ==> (a*c) div (b*c) = a div b"
   363   apply (drule div_mult_mult1)
   364   apply (auto simp add: mult_commute)
   365   done
   366 
   367 
   368 subsection{*Further Facts about Quotient and Remainder*}
   369 
   370 lemma div_1 [simp]: "m div Suc 0 = m"
   371   by (induct m) (simp_all add: div_geq)
   372 
   373 lemma div_self [simp]: "0<n ==> n div n = (1::nat)"
   374   by (simp add: div_geq)
   375 
   376 lemma div_add_self2: "0<n ==> (m+n) div n = Suc (m div n)"
   377   apply (subgoal_tac "(n + m) div n = Suc ((n+m-n) div n) ")
   378    apply (simp add: add_commute)
   379   apply (subst div_geq [symmetric], simp_all)
   380   done
   381 
   382 lemma div_add_self1: "0<n ==> (n+m) div n = Suc (m div n)"
   383   by (simp add: add_commute div_add_self2)
   384 
   385 lemma div_mult_self1 [simp]: "!!n::nat. 0<n ==> (m + k*n) div n = k + m div n"
   386   apply (subst div_add1_eq)
   387   apply (subst div_mult1_eq, simp)
   388   done
   389 
   390 lemma div_mult_self2 [simp]: "0<n ==> (m + n*k) div n = k + m div (n::nat)"
   391   by (simp add: mult_commute div_mult_self1)
   392 
   393 
   394 (* Monotonicity of div in first argument *)
   395 lemma div_le_mono [rule_format (no_asm)]:
   396     "\<forall>m::nat. m \<le> n --> (m div k) \<le> (n div k)"
   397 apply (case_tac "k=0", simp)
   398 apply (induct "n" rule: nat_less_induct, clarify)
   399 apply (case_tac "n<k")
   400 (* 1  case n<k *)
   401 apply simp
   402 (* 2  case n >= k *)
   403 apply (case_tac "m<k")
   404 (* 2.1  case m<k *)
   405 apply simp
   406 (* 2.2  case m>=k *)
   407 apply (simp add: div_geq diff_le_mono)
   408 done
   409 
   410 (* Antimonotonicity of div in second argument *)
   411 lemma div_le_mono2: "!!m::nat. [| 0<m; m\<le>n |] ==> (k div n) \<le> (k div m)"
   412 apply (subgoal_tac "0<n")
   413  prefer 2 apply simp
   414 apply (induct_tac k rule: nat_less_induct)
   415 apply (rename_tac "k")
   416 apply (case_tac "k<n", simp)
   417 apply (subgoal_tac "~ (k<m) ")
   418  prefer 2 apply simp
   419 apply (simp add: div_geq)
   420 apply (subgoal_tac "(k-n) div n \<le> (k-m) div n")
   421  prefer 2
   422  apply (blast intro: div_le_mono diff_le_mono2)
   423 apply (rule le_trans, simp)
   424 apply (simp)
   425 done
   426 
   427 lemma div_le_dividend [simp]: "m div n \<le> (m::nat)"
   428 apply (case_tac "n=0", simp)
   429 apply (subgoal_tac "m div n \<le> m div 1", simp)
   430 apply (rule div_le_mono2)
   431 apply (simp_all (no_asm_simp))
   432 done
   433 
   434 (* Similar for "less than" *)
   435 lemma div_less_dividend [rule_format]:
   436      "!!n::nat. 1<n ==> 0 < m --> m div n < m"
   437 apply (induct_tac m rule: nat_less_induct)
   438 apply (rename_tac "m")
   439 apply (case_tac "m<n", simp)
   440 apply (subgoal_tac "0<n")
   441  prefer 2 apply simp
   442 apply (simp add: div_geq)
   443 apply (case_tac "n<m")
   444  apply (subgoal_tac "(m-n) div n < (m-n) ")
   445   apply (rule impI less_trans_Suc)+
   446 apply assumption
   447   apply (simp_all)
   448 done
   449 
   450 declare div_less_dividend [simp]
   451 
   452 text{*A fact for the mutilated chess board*}
   453 lemma mod_Suc: "Suc(m) mod n = (if Suc(m mod n) = n then 0 else Suc(m mod n))"
   454 apply (case_tac "n=0", simp)
   455 apply (induct "m" rule: nat_less_induct)
   456 apply (case_tac "Suc (na) <n")
   457 (* case Suc(na) < n *)
   458 apply (frule lessI [THEN less_trans], simp add: less_not_refl3)
   459 (* case n \<le> Suc(na) *)
   460 apply (simp add: linorder_not_less le_Suc_eq mod_geq)
   461 apply (auto simp add: Suc_diff_le le_mod_geq)
   462 done
   463 
   464 lemma nat_mod_div_trivial [simp]: "m mod n div n = (0 :: nat)"
   465   by (cases "n = 0") auto
   466 
   467 lemma nat_mod_mod_trivial [simp]: "m mod n mod n = (m mod n :: nat)"
   468   by (cases "n = 0") auto
   469 
   470 
   471 subsection{*The Divides Relation*}
   472 
   473 lemma dvdI [intro?]: "n = m * k ==> m dvd n"
   474   unfolding dvd_def by blast
   475 
   476 lemma dvdE [elim?]: "!!P. [|m dvd n;  !!k. n = m*k ==> P|] ==> P"
   477   unfolding dvd_def by blast
   478 
   479 lemma dvd_0_right [iff]: "m dvd (0::nat)"
   480   unfolding dvd_def by (blast intro: mult_0_right [symmetric])
   481 
   482 lemma dvd_0_left: "0 dvd m ==> m = (0::nat)"
   483   by (force simp add: dvd_def)
   484 
   485 lemma dvd_0_left_iff [iff]: "(0 dvd (m::nat)) = (m = 0)"
   486   by (blast intro: dvd_0_left)
   487 
   488 lemma dvd_1_left [iff]: "Suc 0 dvd k"
   489   unfolding dvd_def by simp
   490 
   491 lemma dvd_1_iff_1 [simp]: "(m dvd Suc 0) = (m = Suc 0)"
   492   by (simp add: dvd_def)
   493 
   494 lemma dvd_refl [simp]: "m dvd (m::nat)"
   495   unfolding dvd_def by (blast intro: mult_1_right [symmetric])
   496 
   497 lemma dvd_trans [trans]: "[| m dvd n; n dvd p |] ==> m dvd (p::nat)"
   498   unfolding dvd_def by (blast intro: mult_assoc)
   499 
   500 lemma dvd_anti_sym: "[| m dvd n; n dvd m |] ==> m = (n::nat)"
   501   unfolding dvd_def
   502   by (force dest: mult_eq_self_implies_10 simp add: mult_assoc mult_eq_1_iff)
   503 
   504 text {* @{term "op dvd"} is a partial order *}
   505 
   506 interpretation dvd: order ["op dvd" "\<lambda>n m \<Colon> nat. n dvd m \<and> m \<noteq> n"]
   507   by unfold_locales (auto intro: dvd_trans dvd_anti_sym)
   508 
   509 lemma dvd_add: "[| k dvd m; k dvd n |] ==> k dvd (m+n :: nat)"
   510   unfolding dvd_def
   511   by (blast intro: add_mult_distrib2 [symmetric])
   512 
   513 lemma dvd_diff: "[| k dvd m; k dvd n |] ==> k dvd (m-n :: nat)"
   514   unfolding dvd_def
   515   by (blast intro: diff_mult_distrib2 [symmetric])
   516 
   517 lemma dvd_diffD: "[| k dvd m-n; k dvd n; n\<le>m |] ==> k dvd (m::nat)"
   518   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
   519   apply (blast intro: dvd_add)
   520   done
   521 
   522 lemma dvd_diffD1: "[| k dvd m-n; k dvd m; n\<le>m |] ==> k dvd (n::nat)"
   523   by (drule_tac m = m in dvd_diff, auto)
   524 
   525 lemma dvd_mult: "k dvd n ==> k dvd (m*n :: nat)"
   526   unfolding dvd_def by (blast intro: mult_left_commute)
   527 
   528 lemma dvd_mult2: "k dvd m ==> k dvd (m*n :: nat)"
   529   apply (subst mult_commute)
   530   apply (erule dvd_mult)
   531   done
   532 
   533 lemma dvd_triv_right [iff]: "k dvd (m*k :: nat)"
   534   by (rule dvd_refl [THEN dvd_mult])
   535 
   536 lemma dvd_triv_left [iff]: "k dvd (k*m :: nat)"
   537   by (rule dvd_refl [THEN dvd_mult2])
   538 
   539 lemma dvd_reduce: "(k dvd n + k) = (k dvd (n::nat))"
   540   apply (rule iffI)
   541    apply (erule_tac [2] dvd_add)
   542    apply (rule_tac [2] dvd_refl)
   543   apply (subgoal_tac "n = (n+k) -k")
   544    prefer 2 apply simp
   545   apply (erule ssubst)
   546   apply (erule dvd_diff)
   547   apply (rule dvd_refl)
   548   done
   549 
   550 lemma dvd_mod: "!!n::nat. [| f dvd m; f dvd n |] ==> f dvd m mod n"
   551   unfolding dvd_def
   552   apply (case_tac "n = 0", auto)
   553   apply (blast intro: mod_mult_distrib2 [symmetric])
   554   done
   555 
   556 lemma dvd_mod_imp_dvd: "[| (k::nat) dvd m mod n;  k dvd n |] ==> k dvd m"
   557   apply (subgoal_tac "k dvd (m div n) *n + m mod n")
   558    apply (simp add: mod_div_equality)
   559   apply (simp only: dvd_add dvd_mult)
   560   done
   561 
   562 lemma dvd_mod_iff: "k dvd n ==> ((k::nat) dvd m mod n) = (k dvd m)"
   563   by (blast intro: dvd_mod_imp_dvd dvd_mod)
   564 
   565 lemma dvd_mult_cancel: "!!k::nat. [| k*m dvd k*n; 0<k |] ==> m dvd n"
   566   unfolding dvd_def
   567   apply (erule exE)
   568   apply (simp add: mult_ac)
   569   done
   570 
   571 lemma dvd_mult_cancel1: "0<m ==> (m*n dvd m) = (n = (1::nat))"
   572   apply auto
   573    apply (subgoal_tac "m*n dvd m*1")
   574    apply (drule dvd_mult_cancel, auto)
   575   done
   576 
   577 lemma dvd_mult_cancel2: "0<m ==> (n*m dvd m) = (n = (1::nat))"
   578   apply (subst mult_commute)
   579   apply (erule dvd_mult_cancel1)
   580   done
   581 
   582 lemma mult_dvd_mono: "[| i dvd m; j dvd n|] ==> i*j dvd (m*n :: nat)"
   583   apply (unfold dvd_def, clarify)
   584   apply (rule_tac x = "k*ka" in exI)
   585   apply (simp add: mult_ac)
   586   done
   587 
   588 lemma dvd_mult_left: "(i*j :: nat) dvd k ==> i dvd k"
   589   by (simp add: dvd_def mult_assoc, blast)
   590 
   591 lemma dvd_mult_right: "(i*j :: nat) dvd k ==> j dvd k"
   592   apply (unfold dvd_def, clarify)
   593   apply (rule_tac x = "i*k" in exI)
   594   apply (simp add: mult_ac)
   595   done
   596 
   597 lemma dvd_imp_le: "[| k dvd n; 0 < n |] ==> k \<le> (n::nat)"
   598   apply (unfold dvd_def, clarify)
   599   apply (simp_all (no_asm_use) add: zero_less_mult_iff)
   600   apply (erule conjE)
   601   apply (rule le_trans)
   602    apply (rule_tac [2] le_refl [THEN mult_le_mono])
   603    apply (erule_tac [2] Suc_leI, simp)
   604   done
   605 
   606 lemma dvd_eq_mod_eq_0: "!!k::nat. (k dvd n) = (n mod k = 0)"
   607   apply (unfold dvd_def)
   608   apply (case_tac "k=0", simp, safe)
   609    apply (simp add: mult_commute)
   610   apply (rule_tac t = n and n1 = k in mod_div_equality [THEN subst])
   611   apply (subst mult_commute, simp)
   612   done
   613 
   614 lemma dvd_mult_div_cancel: "n dvd m ==> n * (m div n) = (m::nat)"
   615   apply (subgoal_tac "m mod n = 0")
   616    apply (simp add: mult_div_cancel)
   617   apply (simp only: dvd_eq_mod_eq_0)
   618   done
   619 
   620 lemma le_imp_power_dvd: "!!i::nat. m \<le> n ==> i^m dvd i^n"
   621   apply (unfold dvd_def)
   622   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
   623   apply (simp add: power_add)
   624   done
   625 
   626 lemma nat_zero_less_power_iff [simp]: "(0 < x^n) = (x \<noteq> (0::nat) | n=0)"
   627   by (induct n) auto
   628 
   629 lemma power_le_dvd [rule_format]: "k^j dvd n --> i\<le>j --> k^i dvd (n::nat)"
   630   apply (induct j)
   631    apply (simp_all add: le_Suc_eq)
   632   apply (blast dest!: dvd_mult_right)
   633   done
   634 
   635 lemma power_dvd_imp_le: "[|i^m dvd i^n;  (1::nat) < i|] ==> m \<le> n"
   636   apply (rule power_le_imp_le_exp, assumption)
   637   apply (erule dvd_imp_le, simp)
   638   done
   639 
   640 lemma mod_eq_0_iff: "(m mod d = 0) = (\<exists>q::nat. m = d*q)"
   641   by (auto simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
   642 
   643 lemmas mod_eq_0D [dest!] = mod_eq_0_iff [THEN iffD1]
   644 
   645 (*Loses information, namely we also have r<d provided d is nonzero*)
   646 lemma mod_eqD: "(m mod d = r) ==> \<exists>q::nat. m = r + q*d"
   647   apply (cut_tac m = m in mod_div_equality)
   648   apply (simp only: add_ac)
   649   apply (blast intro: sym)
   650   done
   651 
   652 
   653 lemma split_div:
   654  "P(n div k :: nat) =
   655  ((k = 0 \<longrightarrow> P 0) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P i)))"
   656  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   657 proof
   658   assume P: ?P
   659   show ?Q
   660   proof (cases)
   661     assume "k = 0"
   662     with P show ?Q by(simp add:DIVISION_BY_ZERO_DIV)
   663   next
   664     assume not0: "k \<noteq> 0"
   665     thus ?Q
   666     proof (simp, intro allI impI)
   667       fix i j
   668       assume n: "n = k*i + j" and j: "j < k"
   669       show "P i"
   670       proof (cases)
   671         assume "i = 0"
   672         with n j P show "P i" by simp
   673       next
   674         assume "i \<noteq> 0"
   675         with not0 n j P show "P i" by(simp add:add_ac)
   676       qed
   677     qed
   678   qed
   679 next
   680   assume Q: ?Q
   681   show ?P
   682   proof (cases)
   683     assume "k = 0"
   684     with Q show ?P by(simp add:DIVISION_BY_ZERO_DIV)
   685   next
   686     assume not0: "k \<noteq> 0"
   687     with Q have R: ?R by simp
   688     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   689     show ?P by simp
   690   qed
   691 qed
   692 
   693 lemma split_div_lemma:
   694   "0 < n \<Longrightarrow> (n * q \<le> m \<and> m < n * (Suc q)) = (q = ((m::nat) div n))"
   695   apply (rule iffI)
   696   apply (rule_tac a=m and r = "m - n * q" and r' = "m mod n" in unique_quotient)
   697 prefer 3; apply assumption
   698   apply (simp_all add: quorem_def) apply arith
   699   apply (rule conjI)
   700   apply (rule_tac P="%x. n * (m div n) \<le> x" in
   701     subst [OF mod_div_equality [of _ n]])
   702   apply (simp only: add: mult_ac)
   703   apply (rule_tac P="%x. x < n + n * (m div n)" in
   704     subst [OF mod_div_equality [of _ n]])
   705   apply (simp only: add: mult_ac add_ac)
   706   apply (rule add_less_mono1, simp)
   707   done
   708 
   709 theorem split_div':
   710   "P ((m::nat) div n) = ((n = 0 \<and> P 0) \<or>
   711    (\<exists>q. (n * q \<le> m \<and> m < n * (Suc q)) \<and> P q))"
   712   apply (case_tac "0 < n")
   713   apply (simp only: add: split_div_lemma)
   714   apply (simp_all add: DIVISION_BY_ZERO_DIV)
   715   done
   716 
   717 lemma split_mod:
   718  "P(n mod k :: nat) =
   719  ((k = 0 \<longrightarrow> P n) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P j)))"
   720  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   721 proof
   722   assume P: ?P
   723   show ?Q
   724   proof (cases)
   725     assume "k = 0"
   726     with P show ?Q by(simp add:DIVISION_BY_ZERO_MOD)
   727   next
   728     assume not0: "k \<noteq> 0"
   729     thus ?Q
   730     proof (simp, intro allI impI)
   731       fix i j
   732       assume "n = k*i + j" "j < k"
   733       thus "P j" using not0 P by(simp add:add_ac mult_ac)
   734     qed
   735   qed
   736 next
   737   assume Q: ?Q
   738   show ?P
   739   proof (cases)
   740     assume "k = 0"
   741     with Q show ?P by(simp add:DIVISION_BY_ZERO_MOD)
   742   next
   743     assume not0: "k \<noteq> 0"
   744     with Q have R: ?R by simp
   745     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   746     show ?P by simp
   747   qed
   748 qed
   749 
   750 theorem mod_div_equality': "(m::nat) mod n = m - (m div n) * n"
   751   apply (rule_tac P="%x. m mod n = x - (m div n) * n" in
   752     subst [OF mod_div_equality [of _ n]])
   753   apply arith
   754   done
   755 
   756 lemma div_mod_equality':
   757   fixes m n :: nat
   758   shows "m div n * n = m - m mod n"
   759 proof -
   760   have "m mod n \<le> m mod n" ..
   761   from div_mod_equality have 
   762     "m div n * n + m mod n - m mod n = m - m mod n" by simp
   763   with diff_add_assoc [OF `m mod n \<le> m mod n`, of "m div n * n"] have
   764     "m div n * n + (m mod n - m mod n) = m - m mod n"
   765     by simp
   766   then show ?thesis by simp
   767 qed
   768 
   769 
   770 subsection {*An ``induction'' law for modulus arithmetic.*}
   771 
   772 lemma mod_induct_0:
   773   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
   774   and base: "P i" and i: "i<p"
   775   shows "P 0"
   776 proof (rule ccontr)
   777   assume contra: "\<not>(P 0)"
   778   from i have p: "0<p" by simp
   779   have "\<forall>k. 0<k \<longrightarrow> \<not> P (p-k)" (is "\<forall>k. ?A k")
   780   proof
   781     fix k
   782     show "?A k"
   783     proof (induct k)
   784       show "?A 0" by simp  -- "by contradiction"
   785     next
   786       fix n
   787       assume ih: "?A n"
   788       show "?A (Suc n)"
   789       proof (clarsimp)
   790         assume y: "P (p - Suc n)"
   791         have n: "Suc n < p"
   792         proof (rule ccontr)
   793           assume "\<not>(Suc n < p)"
   794           hence "p - Suc n = 0"
   795             by simp
   796           with y contra show "False"
   797             by simp
   798         qed
   799         hence n2: "Suc (p - Suc n) = p-n" by arith
   800         from p have "p - Suc n < p" by arith
   801         with y step have z: "P ((Suc (p - Suc n)) mod p)"
   802           by blast
   803         show "False"
   804         proof (cases "n=0")
   805           case True
   806           with z n2 contra show ?thesis by simp
   807         next
   808           case False
   809           with p have "p-n < p" by arith
   810           with z n2 False ih show ?thesis by simp
   811         qed
   812       qed
   813     qed
   814   qed
   815   moreover
   816   from i obtain k where "0<k \<and> i+k=p"
   817     by (blast dest: less_imp_add_positive)
   818   hence "0<k \<and> i=p-k" by auto
   819   moreover
   820   note base
   821   ultimately
   822   show "False" by blast
   823 qed
   824 
   825 lemma mod_induct:
   826   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
   827   and base: "P i" and i: "i<p" and j: "j<p"
   828   shows "P j"
   829 proof -
   830   have "\<forall>j<p. P j"
   831   proof
   832     fix j
   833     show "j<p \<longrightarrow> P j" (is "?A j")
   834     proof (induct j)
   835       from step base i show "?A 0"
   836         by (auto elim: mod_induct_0)
   837     next
   838       fix k
   839       assume ih: "?A k"
   840       show "?A (Suc k)"
   841       proof
   842         assume suc: "Suc k < p"
   843         hence k: "k<p" by simp
   844         with ih have "P k" ..
   845         with step k have "P (Suc k mod p)"
   846           by blast
   847         moreover
   848         from suc have "Suc k mod p = Suc k"
   849           by simp
   850         ultimately
   851         show "P (Suc k)" by simp
   852       qed
   853     qed
   854   qed
   855   with j show ?thesis by blast
   856 qed
   857 
   858 
   859 lemma mod_add_left_eq: "((a::nat) + b) mod c = (a mod c + b) mod c"
   860   apply (rule trans [symmetric])
   861    apply (rule mod_add1_eq, simp)
   862   apply (rule mod_add1_eq [symmetric])
   863   done
   864 
   865 lemma mod_add_right_eq: "(a+b) mod (c::nat) = (a + (b mod c)) mod c"
   866   apply (rule trans [symmetric])
   867    apply (rule mod_add1_eq, simp)
   868   apply (rule mod_add1_eq [symmetric])
   869   done
   870 
   871 lemma mod_div_decomp:
   872   fixes n k :: nat
   873   obtains m q where "m = n div k" and "q = n mod k"
   874     and "n = m * k + q"
   875 proof -
   876   from mod_div_equality have "n = n div k * k + n mod k" by auto
   877   moreover have "n div k = n div k" ..
   878   moreover have "n mod k = n mod k" ..
   879   note that ultimately show thesis by blast
   880 qed
   881 
   882 
   883 
   884 
   885 subsection {* Code generation for div, mod and dvd on nat *}
   886 
   887 definition [code func del]:
   888   "divmod (m\<Colon>nat) n = (m div n, m mod n)"
   889 
   890 lemma divmod_zero [code]: "divmod m 0 = (0, m)"
   891   unfolding divmod_def by simp
   892 
   893 lemma divmod_succ [code]:
   894   "divmod m (Suc k) = (if m < Suc k then (0, m) else
   895     let
   896       (p, q) = divmod (m - Suc k) (Suc k)
   897     in (Suc p, q))"
   898   unfolding divmod_def Let_def split_def
   899   by (auto intro: div_geq mod_geq)
   900 
   901 lemma div_divmod [code]: "m div n = fst (divmod m n)"
   902   unfolding divmod_def by simp
   903 
   904 lemma mod_divmod [code]: "m mod n = snd (divmod m n)"
   905   unfolding divmod_def by simp
   906 
   907 instance nat :: dvd_mod
   908   by default (simp add: times_class.dvd [symmetric] dvd_eq_mod_eq_0)
   909 
   910 code_modulename SML
   911   Divides Nat
   912 
   913 code_modulename OCaml
   914   Divides Nat
   915 
   916 code_modulename Haskell
   917   Divides Nat
   918 
   919 hide (open) const divmod
   920 
   921 end