src/HOL/Sum_Type.thy
author huffman
Tue Dec 09 15:31:38 2008 -0800 (2008-12-09)
changeset 29025 8c8859c0d734
parent 28524 644b62cf678f
child 29183 f1648e009dc1
permissions -rw-r--r--
move lemmas from Numeral_Type.thy to other theories
     1 (*  Title:      HOL/Sum_Type.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1992  University of Cambridge
     5 *)
     6 
     7 header{*The Disjoint Sum of Two Types*}
     8 
     9 theory Sum_Type
    10 imports Typedef Fun
    11 begin
    12 
    13 text{*The representations of the two injections*}
    14 
    15 constdefs
    16   Inl_Rep :: "['a, 'a, 'b, bool] => bool"
    17   "Inl_Rep == (%a. %x y p. x=a & p)"
    18 
    19   Inr_Rep :: "['b, 'a, 'b, bool] => bool"
    20   "Inr_Rep == (%b. %x y p. y=b & ~p)"
    21 
    22 
    23 global
    24 
    25 typedef (Sum)
    26   ('a, 'b) "+"          (infixr "+" 10)
    27     = "{f. (? a. f = Inl_Rep(a::'a)) | (? b. f = Inr_Rep(b::'b))}"
    28   by auto
    29 
    30 local
    31 
    32 
    33 text{*abstract constants and syntax*}
    34 
    35 constdefs
    36   Inl :: "'a => 'a + 'b"
    37    "Inl == (%a. Abs_Sum(Inl_Rep(a)))"
    38 
    39   Inr :: "'b => 'a + 'b"
    40    "Inr == (%b. Abs_Sum(Inr_Rep(b)))"
    41 
    42   Plus :: "['a set, 'b set] => ('a + 'b) set"        (infixr "<+>" 65)
    43    "A <+> B == (Inl`A) Un (Inr`B)"
    44     --{*disjoint sum for sets; the operator + is overloaded with wrong type!*}
    45 
    46   Part :: "['a set, 'b => 'a] => 'a set"
    47    "Part A h == A Int {x. ? z. x = h(z)}"
    48     --{*for selecting out the components of a mutually recursive definition*}
    49 
    50 
    51 
    52 (** Inl_Rep and Inr_Rep: Representations of the constructors **)
    53 
    54 (*This counts as a non-emptiness result for admitting 'a+'b as a type*)
    55 lemma Inl_RepI: "Inl_Rep(a) : Sum"
    56 by (auto simp add: Sum_def)
    57 
    58 lemma Inr_RepI: "Inr_Rep(b) : Sum"
    59 by (auto simp add: Sum_def)
    60 
    61 lemma inj_on_Abs_Sum: "inj_on Abs_Sum Sum"
    62 apply (rule inj_on_inverseI)
    63 apply (erule Abs_Sum_inverse)
    64 done
    65 
    66 subsection{*Freeness Properties for @{term Inl} and  @{term Inr}*}
    67 
    68 text{*Distinctness*}
    69 
    70 lemma Inl_Rep_not_Inr_Rep: "Inl_Rep(a) ~= Inr_Rep(b)"
    71 by (auto simp add: Inl_Rep_def Inr_Rep_def expand_fun_eq)
    72 
    73 lemma Inl_not_Inr [iff]: "Inl(a) ~= Inr(b)"
    74 apply (simp add: Inl_def Inr_def)
    75 apply (rule inj_on_Abs_Sum [THEN inj_on_contraD])
    76 apply (rule Inl_Rep_not_Inr_Rep)
    77 apply (rule Inl_RepI)
    78 apply (rule Inr_RepI)
    79 done
    80 
    81 lemmas Inr_not_Inl = Inl_not_Inr [THEN not_sym, standard]
    82 declare Inr_not_Inl [iff]
    83 
    84 lemmas Inl_neq_Inr = Inl_not_Inr [THEN notE, standard]
    85 lemmas Inr_neq_Inl = sym [THEN Inl_neq_Inr, standard]
    86 
    87 
    88 text{*Injectiveness*}
    89 
    90 lemma Inl_Rep_inject: "Inl_Rep(a) = Inl_Rep(c) ==> a=c"
    91 by (auto simp add: Inl_Rep_def expand_fun_eq)
    92 
    93 lemma Inr_Rep_inject: "Inr_Rep(b) = Inr_Rep(d) ==> b=d"
    94 by (auto simp add: Inr_Rep_def expand_fun_eq)
    95 
    96 lemma inj_Inl [simp]: "inj_on Inl A"
    97 apply (simp add: Inl_def)
    98 apply (rule inj_onI)
    99 apply (erule inj_on_Abs_Sum [THEN inj_onD, THEN Inl_Rep_inject])
   100 apply (rule Inl_RepI)
   101 apply (rule Inl_RepI)
   102 done
   103 
   104 lemmas Inl_inject = inj_Inl [THEN injD, standard]
   105 
   106 lemma inj_Inr [simp]: "inj_on Inr A"
   107 apply (simp add: Inr_def)
   108 apply (rule inj_onI)
   109 apply (erule inj_on_Abs_Sum [THEN inj_onD, THEN Inr_Rep_inject])
   110 apply (rule Inr_RepI)
   111 apply (rule Inr_RepI)
   112 done
   113 
   114 lemmas Inr_inject = inj_Inr [THEN injD, standard]
   115 
   116 lemma Inl_eq [iff]: "(Inl(x)=Inl(y)) = (x=y)"
   117 by (blast dest!: Inl_inject)
   118 
   119 lemma Inr_eq [iff]: "(Inr(x)=Inr(y)) = (x=y)"
   120 by (blast dest!: Inr_inject)
   121 
   122 
   123 subsection {* Projections *}
   124 
   125 definition 
   126   "sum_case f g x =
   127   (if (\<exists>!y. x = Inl y) 
   128   then f (THE y. x = Inl y) 
   129   else g (THE y. x = Inr y))"
   130 definition "Projl x = sum_case id undefined x"
   131 definition "Projr x = sum_case undefined id x"
   132 
   133 lemma sum_cases[simp]: 
   134   "sum_case f g (Inl x) = f x"
   135   "sum_case f g (Inr y) = g y"
   136   unfolding sum_case_def
   137   by auto
   138 
   139 lemma Projl_Inl[simp]: "Projl (Inl x) = x"
   140   unfolding Projl_def by simp
   141 
   142 lemma Projr_Inr[simp]: "Projr (Inr x) = x"
   143   unfolding Projr_def by simp
   144 
   145 
   146 subsection{*The Disjoint Sum of Sets*}
   147 
   148 (** Introduction rules for the injections **)
   149 
   150 lemma InlI [intro!]: "a : A ==> Inl(a) : A <+> B"
   151 by (simp add: Plus_def)
   152 
   153 lemma InrI [intro!]: "b : B ==> Inr(b) : A <+> B"
   154 by (simp add: Plus_def)
   155 
   156 (** Elimination rules **)
   157 
   158 lemma PlusE [elim!]: 
   159     "[| u: A <+> B;   
   160         !!x. [| x:A;  u=Inl(x) |] ==> P;  
   161         !!y. [| y:B;  u=Inr(y) |] ==> P  
   162      |] ==> P"
   163 by (auto simp add: Plus_def)
   164 
   165 
   166 
   167 text{*Exhaustion rule for sums, a degenerate form of induction*}
   168 lemma sumE: 
   169     "[| !!x::'a. s = Inl(x) ==> P;  !!y::'b. s = Inr(y) ==> P  
   170      |] ==> P"
   171 apply (rule Abs_Sum_cases [of s]) 
   172 apply (auto simp add: Sum_def Inl_def Inr_def)
   173 done
   174 
   175 
   176 lemma UNIV_Plus_UNIV [simp]: "UNIV <+> UNIV = UNIV"
   177 apply (rule set_ext)
   178 apply(rename_tac s)
   179 apply(rule_tac s=s in sumE)
   180 apply auto
   181 done
   182 
   183 
   184 subsection{*The @{term Part} Primitive*}
   185 
   186 lemma Part_eqI [intro]: "[| a : A;  a=h(b) |] ==> a : Part A h"
   187 by (auto simp add: Part_def)
   188 
   189 lemmas PartI = Part_eqI [OF _ refl, standard]
   190 
   191 lemma PartE [elim!]: "[| a : Part A h;  !!z. [| a : A;  a=h(z) |] ==> P |] ==> P"
   192 by (auto simp add: Part_def)
   193 
   194 
   195 lemma Part_subset: "Part A h <= A"
   196 by (auto simp add: Part_def)
   197 
   198 lemma Part_mono: "A<=B ==> Part A h <= Part B h"
   199 by blast
   200 
   201 lemmas basic_monos = basic_monos Part_mono
   202 
   203 lemma PartD1: "a : Part A h ==> a : A"
   204 by (simp add: Part_def)
   205 
   206 lemma Part_id: "Part A (%x. x) = A"
   207 by blast
   208 
   209 lemma Part_Int: "Part (A Int B) h = (Part A h) Int (Part B h)"
   210 by blast
   211 
   212 lemma Part_Collect: "Part (A Int {x. P x}) h = (Part A h) Int {x. P x}"
   213 by blast
   214 
   215 
   216 ML
   217 {*
   218 val Inl_RepI = thm "Inl_RepI";
   219 val Inr_RepI = thm "Inr_RepI";
   220 val inj_on_Abs_Sum = thm "inj_on_Abs_Sum";
   221 val Inl_Rep_not_Inr_Rep = thm "Inl_Rep_not_Inr_Rep";
   222 val Inl_not_Inr = thm "Inl_not_Inr";
   223 val Inr_not_Inl = thm "Inr_not_Inl";
   224 val Inl_neq_Inr = thm "Inl_neq_Inr";
   225 val Inr_neq_Inl = thm "Inr_neq_Inl";
   226 val Inl_Rep_inject = thm "Inl_Rep_inject";
   227 val Inr_Rep_inject = thm "Inr_Rep_inject";
   228 val inj_Inl = thm "inj_Inl";
   229 val Inl_inject = thm "Inl_inject";
   230 val inj_Inr = thm "inj_Inr";
   231 val Inr_inject = thm "Inr_inject";
   232 val Inl_eq = thm "Inl_eq";
   233 val Inr_eq = thm "Inr_eq";
   234 val InlI = thm "InlI";
   235 val InrI = thm "InrI";
   236 val PlusE = thm "PlusE";
   237 val sumE = thm "sumE";
   238 val Part_eqI = thm "Part_eqI";
   239 val PartI = thm "PartI";
   240 val PartE = thm "PartE";
   241 val Part_subset = thm "Part_subset";
   242 val Part_mono = thm "Part_mono";
   243 val PartD1 = thm "PartD1";
   244 val Part_id = thm "Part_id";
   245 val Part_Int = thm "Part_Int";
   246 val Part_Collect = thm "Part_Collect";
   247 
   248 val basic_monos = thms "basic_monos";
   249 *}
   250 
   251 end