src/HOL/Analysis/Complex_Transcendental.thy
author paulson <lp15@cam.ac.uk>
Wed Apr 26 15:53:35 2017 +0100 (2017-04-26)
changeset 65583 8d53b3bebab4
parent 65578 e4997c181cce
child 65585 a043de9ad41e
permissions -rw-r--r--
Further new material. The simprule status of some exp and ln identities was reverted.
     1 section \<open>Complex Transcendental Functions\<close>
     2 
     3 text\<open>By John Harrison et al.  Ported from HOL Light by L C Paulson (2015)\<close>
     4 
     5 theory Complex_Transcendental
     6 imports
     7   Complex_Analysis_Basics
     8   Summation_Tests
     9    "~~/src/HOL/Library/Periodic_Fun"
    10 begin
    11 
    12 (* TODO: Figure out what to do with Möbius transformations *)
    13 definition "moebius a b c d = (\<lambda>z. (a*z+b) / (c*z+d :: 'a :: field))"
    14 
    15 lemma moebius_inverse:
    16   assumes "a * d \<noteq> b * c" "c * z + d \<noteq> 0"
    17   shows   "moebius d (-b) (-c) a (moebius a b c d z) = z"
    18 proof -
    19   from assms have "(-c) * moebius a b c d z + a \<noteq> 0" unfolding moebius_def
    20     by (simp add: field_simps)
    21   with assms show ?thesis
    22     unfolding moebius_def by (simp add: moebius_def divide_simps) (simp add: algebra_simps)?
    23 qed
    24 
    25 lemma moebius_inverse':
    26   assumes "a * d \<noteq> b * c" "c * z - a \<noteq> 0"
    27   shows   "moebius a b c d (moebius d (-b) (-c) a z) = z"
    28   using assms moebius_inverse[of d a "-b" "-c" z]
    29   by (auto simp: algebra_simps)
    30 
    31 lemma cmod_add_real_less:
    32   assumes "Im z \<noteq> 0" "r\<noteq>0"
    33     shows "cmod (z + r) < cmod z + \<bar>r\<bar>"
    34 proof (cases z)
    35   case (Complex x y)
    36   have "r * x / \<bar>r\<bar> < sqrt (x*x + y*y)"
    37     apply (rule real_less_rsqrt)
    38     using assms
    39     apply (simp add: Complex power2_eq_square)
    40     using not_real_square_gt_zero by blast
    41   then show ?thesis using assms Complex
    42     apply (auto simp: cmod_def)
    43     apply (rule power2_less_imp_less, auto)
    44     apply (simp add: power2_eq_square field_simps)
    45     done
    46 qed
    47 
    48 lemma cmod_diff_real_less: "Im z \<noteq> 0 \<Longrightarrow> x\<noteq>0 \<Longrightarrow> cmod (z - x) < cmod z + \<bar>x\<bar>"
    49   using cmod_add_real_less [of z "-x"]
    50   by simp
    51 
    52 lemma cmod_square_less_1_plus:
    53   assumes "Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1"
    54     shows "(cmod z)\<^sup>2 < 1 + cmod (1 - z\<^sup>2)"
    55   using assms
    56   apply (cases "Im z = 0 \<or> Re z = 0")
    57   using abs_square_less_1
    58     apply (force simp add: Re_power2 Im_power2 cmod_def)
    59   using cmod_diff_real_less [of "1 - z\<^sup>2" "1"]
    60   apply (simp add: norm_power Im_power2)
    61   done
    62 
    63 subsection\<open>The Exponential Function is Differentiable and Continuous\<close>
    64 
    65 lemma field_differentiable_within_exp: "exp field_differentiable (at z within s)"
    66   using DERIV_exp field_differentiable_at_within field_differentiable_def by blast
    67 
    68 lemma continuous_within_exp:
    69   fixes z::"'a::{real_normed_field,banach}"
    70   shows "continuous (at z within s) exp"
    71 by (simp add: continuous_at_imp_continuous_within)
    72 
    73 lemma holomorphic_on_exp [holomorphic_intros]: "exp holomorphic_on s"
    74   by (simp add: field_differentiable_within_exp holomorphic_on_def)
    75 
    76 subsection\<open>Euler and de Moivre formulas.\<close>
    77 
    78 text\<open>The sine series times @{term i}\<close>
    79 lemma sin_i_eq: "(\<lambda>n. (\<i> * sin_coeff n) * z^n) sums (\<i> * sin z)"
    80 proof -
    81   have "(\<lambda>n. \<i> * sin_coeff n *\<^sub>R z^n) sums (\<i> * sin z)"
    82     using sin_converges sums_mult by blast
    83   then show ?thesis
    84     by (simp add: scaleR_conv_of_real field_simps)
    85 qed
    86 
    87 theorem exp_Euler: "exp(\<i> * z) = cos(z) + \<i> * sin(z)"
    88 proof -
    89   have "(\<lambda>n. (cos_coeff n + \<i> * sin_coeff n) * z^n)
    90         = (\<lambda>n. (\<i> * z) ^ n /\<^sub>R (fact n))"
    91   proof
    92     fix n
    93     show "(cos_coeff n + \<i> * sin_coeff n) * z^n = (\<i> * z) ^ n /\<^sub>R (fact n)"
    94       by (auto simp: cos_coeff_def sin_coeff_def scaleR_conv_of_real field_simps elim!: evenE oddE)
    95   qed
    96   also have "... sums (exp (\<i> * z))"
    97     by (rule exp_converges)
    98   finally have "(\<lambda>n. (cos_coeff n + \<i> * sin_coeff n) * z^n) sums (exp (\<i> * z))" .
    99   moreover have "(\<lambda>n. (cos_coeff n + \<i> * sin_coeff n) * z^n) sums (cos z + \<i> * sin z)"
   100     using sums_add [OF cos_converges [of z] sin_i_eq [of z]]
   101     by (simp add: field_simps scaleR_conv_of_real)
   102   ultimately show ?thesis
   103     using sums_unique2 by blast
   104 qed
   105 
   106 corollary exp_minus_Euler: "exp(-(\<i> * z)) = cos(z) - \<i> * sin(z)"
   107   using exp_Euler [of "-z"]
   108   by simp
   109 
   110 lemma sin_exp_eq: "sin z = (exp(\<i> * z) - exp(-(\<i> * z))) / (2*\<i>)"
   111   by (simp add: exp_Euler exp_minus_Euler)
   112 
   113 lemma sin_exp_eq': "sin z = \<i> * (exp(-(\<i> * z)) - exp(\<i> * z)) / 2"
   114   by (simp add: exp_Euler exp_minus_Euler)
   115 
   116 lemma cos_exp_eq:  "cos z = (exp(\<i> * z) + exp(-(\<i> * z))) / 2"
   117   by (simp add: exp_Euler exp_minus_Euler)
   118 
   119 subsection\<open>Relationships between real and complex trig functions\<close>
   120 
   121 lemma real_sin_eq [simp]:
   122   fixes x::real
   123   shows "Re(sin(of_real x)) = sin x"
   124   by (simp add: sin_of_real)
   125 
   126 lemma real_cos_eq [simp]:
   127   fixes x::real
   128   shows "Re(cos(of_real x)) = cos x"
   129   by (simp add: cos_of_real)
   130 
   131 lemma DeMoivre: "(cos z + \<i> * sin z) ^ n = cos(n * z) + \<i> * sin(n * z)"
   132   apply (simp add: exp_Euler [symmetric])
   133   by (metis exp_of_nat_mult mult.left_commute)
   134 
   135 lemma exp_cnj:
   136   fixes z::complex
   137   shows "cnj (exp z) = exp (cnj z)"
   138 proof -
   139   have "(\<lambda>n. cnj (z ^ n /\<^sub>R (fact n))) = (\<lambda>n. (cnj z)^n /\<^sub>R (fact n))"
   140     by auto
   141   also have "... sums (exp (cnj z))"
   142     by (rule exp_converges)
   143   finally have "(\<lambda>n. cnj (z ^ n /\<^sub>R (fact n))) sums (exp (cnj z))" .
   144   moreover have "(\<lambda>n. cnj (z ^ n /\<^sub>R (fact n))) sums (cnj (exp z))"
   145     by (metis exp_converges sums_cnj)
   146   ultimately show ?thesis
   147     using sums_unique2
   148     by blast
   149 qed
   150 
   151 lemma cnj_sin: "cnj(sin z) = sin(cnj z)"
   152   by (simp add: sin_exp_eq exp_cnj field_simps)
   153 
   154 lemma cnj_cos: "cnj(cos z) = cos(cnj z)"
   155   by (simp add: cos_exp_eq exp_cnj field_simps)
   156 
   157 lemma field_differentiable_at_sin: "sin field_differentiable at z"
   158   using DERIV_sin field_differentiable_def by blast
   159 
   160 lemma field_differentiable_within_sin: "sin field_differentiable (at z within s)"
   161   by (simp add: field_differentiable_at_sin field_differentiable_at_within)
   162 
   163 lemma field_differentiable_at_cos: "cos field_differentiable at z"
   164   using DERIV_cos field_differentiable_def by blast
   165 
   166 lemma field_differentiable_within_cos: "cos field_differentiable (at z within s)"
   167   by (simp add: field_differentiable_at_cos field_differentiable_at_within)
   168 
   169 lemma holomorphic_on_sin: "sin holomorphic_on s"
   170   by (simp add: field_differentiable_within_sin holomorphic_on_def)
   171 
   172 lemma holomorphic_on_cos: "cos holomorphic_on s"
   173   by (simp add: field_differentiable_within_cos holomorphic_on_def)
   174 
   175 subsection\<open>Get a nice real/imaginary separation in Euler's formula.\<close>
   176 
   177 lemma Euler: "exp(z) = of_real(exp(Re z)) *
   178               (of_real(cos(Im z)) + \<i> * of_real(sin(Im z)))"
   179 by (cases z) (simp add: exp_add exp_Euler cos_of_real exp_of_real sin_of_real Complex_eq)
   180 
   181 lemma Re_sin: "Re(sin z) = sin(Re z) * (exp(Im z) + exp(-(Im z))) / 2"
   182   by (simp add: sin_exp_eq field_simps Re_divide Im_exp)
   183 
   184 lemma Im_sin: "Im(sin z) = cos(Re z) * (exp(Im z) - exp(-(Im z))) / 2"
   185   by (simp add: sin_exp_eq field_simps Im_divide Re_exp)
   186 
   187 lemma Re_cos: "Re(cos z) = cos(Re z) * (exp(Im z) + exp(-(Im z))) / 2"
   188   by (simp add: cos_exp_eq field_simps Re_divide Re_exp)
   189 
   190 lemma Im_cos: "Im(cos z) = sin(Re z) * (exp(-(Im z)) - exp(Im z)) / 2"
   191   by (simp add: cos_exp_eq field_simps Im_divide Im_exp)
   192 
   193 lemma Re_sin_pos: "0 < Re z \<Longrightarrow> Re z < pi \<Longrightarrow> Re (sin z) > 0"
   194   by (auto simp: Re_sin Im_sin add_pos_pos sin_gt_zero)
   195 
   196 lemma Im_sin_nonneg: "Re z = 0 \<Longrightarrow> 0 \<le> Im z \<Longrightarrow> 0 \<le> Im (sin z)"
   197   by (simp add: Re_sin Im_sin algebra_simps)
   198 
   199 lemma Im_sin_nonneg2: "Re z = pi \<Longrightarrow> Im z \<le> 0 \<Longrightarrow> 0 \<le> Im (sin z)"
   200   by (simp add: Re_sin Im_sin algebra_simps)
   201 
   202 subsection\<open>More on the Polar Representation of Complex Numbers\<close>
   203 
   204 lemma exp_Complex: "exp(Complex r t) = of_real(exp r) * Complex (cos t) (sin t)"
   205   by (simp add: Complex_eq exp_add exp_Euler exp_of_real sin_of_real cos_of_real)
   206 
   207 lemma exp_eq_1: "exp z = 1 \<longleftrightarrow> Re(z) = 0 \<and> (\<exists>n::int. Im(z) = of_int (2 * n) * pi)"
   208                  (is "?lhs = ?rhs")
   209 proof 
   210   assume "exp z = 1"
   211   then have "Re z = 0"
   212     by (metis exp_eq_one_iff norm_exp_eq_Re norm_one)
   213   with \<open>?lhs\<close> show ?rhs
   214     by (metis Re_exp complex_Re_of_int cos_one_2pi_int exp_zero mult.commute mult_numeral_1 numeral_One of_int_mult of_int_numeral)
   215 next
   216   assume ?rhs then show ?lhs
   217     using Im_exp Re_exp complex_Re_Im_cancel_iff by force
   218 qed
   219 
   220 lemma exp_eq: "exp w = exp z \<longleftrightarrow> (\<exists>n::int. w = z + (of_int (2 * n) * pi) * \<i>)"
   221                 (is "?lhs = ?rhs")
   222 proof -
   223   have "exp w = exp z \<longleftrightarrow> exp (w-z) = 1"
   224     by (simp add: exp_diff)
   225   also have "... \<longleftrightarrow> (Re w = Re z \<and> (\<exists>n::int. Im w - Im z = of_int (2 * n) * pi))"
   226     by (simp add: exp_eq_1)
   227   also have "... \<longleftrightarrow> ?rhs"
   228     by (auto simp: algebra_simps intro!: complex_eqI)
   229   finally show ?thesis .
   230 qed
   231 
   232 lemma exp_complex_eqI: "\<bar>Im w - Im z\<bar> < 2*pi \<Longrightarrow> exp w = exp z \<Longrightarrow> w = z"
   233   by (auto simp: exp_eq abs_mult)
   234 
   235 lemma exp_integer_2pi:
   236   assumes "n \<in> \<int>"
   237   shows "exp((2 * n * pi) * \<i>) = 1"
   238 proof -
   239   have "exp((2 * n * pi) * \<i>) = exp 0"
   240     using assms
   241     by (simp only: Ints_def exp_eq) auto
   242   also have "... = 1"
   243     by simp
   244   finally show ?thesis .
   245 qed
   246 
   247 lemma exp_plus_2pin [simp]: "exp (z + \<i> * (of_int n * (of_real pi * 2))) = exp z"
   248   by (simp add: exp_eq)
   249 
   250 lemma inj_on_exp_pi:
   251   fixes z::complex shows "inj_on exp (ball z pi)"
   252 proof (clarsimp simp: inj_on_def exp_eq)
   253   fix y n
   254   assume "dist z (y + 2 * of_int n * of_real pi * \<i>) < pi"
   255          "dist z y < pi"
   256   then have "dist y (y + 2 * of_int n * of_real pi * \<i>) < pi+pi"
   257     using dist_commute_lessI dist_triangle_less_add by blast
   258   then have "norm (2 * of_int n * of_real pi * \<i>) < 2*pi"
   259     by (simp add: dist_norm)
   260   then show "n = 0"
   261     by (auto simp: norm_mult)
   262 qed
   263 
   264 lemma sin_cos_eq_iff: "sin y = sin x \<and> cos y = cos x \<longleftrightarrow> (\<exists>n::int. y = x + 2 * n * pi)"
   265 proof -
   266   { assume "sin y = sin x" "cos y = cos x"
   267     then have "cos (y-x) = 1"
   268       using cos_add [of y "-x"] by simp
   269     then have "\<exists>n::int. y-x = n * 2 * pi"
   270       using cos_one_2pi_int by blast }
   271   then show ?thesis
   272   apply (auto simp: sin_add cos_add)
   273   apply (metis add.commute diff_add_cancel mult.commute)
   274   done
   275 qed
   276 
   277 lemma exp_i_ne_1:
   278   assumes "0 < x" "x < 2*pi"
   279   shows "exp(\<i> * of_real x) \<noteq> 1"
   280 proof
   281   assume "exp (\<i> * of_real x) = 1"
   282   then have "exp (\<i> * of_real x) = exp 0"
   283     by simp
   284   then obtain n where "\<i> * of_real x = (of_int (2 * n) * pi) * \<i>"
   285     by (simp only: Ints_def exp_eq) auto
   286   then have  "of_real x = (of_int (2 * n) * pi)"
   287     by (metis complex_i_not_zero mult.commute mult_cancel_left of_real_eq_iff real_scaleR_def scaleR_conv_of_real)
   288   then have  "x = (of_int (2 * n) * pi)"
   289     by simp
   290   then show False using assms
   291     by (cases n) (auto simp: zero_less_mult_iff mult_less_0_iff)
   292 qed
   293 
   294 lemma sin_eq_0:
   295   fixes z::complex
   296   shows "sin z = 0 \<longleftrightarrow> (\<exists>n::int. z = of_real(n * pi))"
   297   by (simp add: sin_exp_eq exp_eq of_real_numeral)
   298 
   299 lemma cos_eq_0:
   300   fixes z::complex
   301   shows "cos z = 0 \<longleftrightarrow> (\<exists>n::int. z = of_real(n * pi) + of_real pi/2)"
   302   using sin_eq_0 [of "z - of_real pi/2"]
   303   by (simp add: sin_diff algebra_simps)
   304 
   305 lemma cos_eq_1:
   306   fixes z::complex
   307   shows "cos z = 1 \<longleftrightarrow> (\<exists>n::int. z = of_real(2 * n * pi))"
   308 proof -
   309   have "cos z = cos (2*(z/2))"
   310     by simp
   311   also have "... = 1 - 2 * sin (z/2) ^ 2"
   312     by (simp only: cos_double_sin)
   313   finally have [simp]: "cos z = 1 \<longleftrightarrow> sin (z/2) = 0"
   314     by simp
   315   show ?thesis
   316     by (auto simp: sin_eq_0 of_real_numeral)
   317 qed
   318 
   319 lemma csin_eq_1:
   320   fixes z::complex
   321   shows "sin z = 1 \<longleftrightarrow> (\<exists>n::int. z = of_real(2 * n * pi) + of_real pi/2)"
   322   using cos_eq_1 [of "z - of_real pi/2"]
   323   by (simp add: cos_diff algebra_simps)
   324 
   325 lemma csin_eq_minus1:
   326   fixes z::complex
   327   shows "sin z = -1 \<longleftrightarrow> (\<exists>n::int. z = of_real(2 * n * pi) + 3/2*pi)"
   328         (is "_ = ?rhs")
   329 proof -
   330   have "sin z = -1 \<longleftrightarrow> sin (-z) = 1"
   331     by (simp add: equation_minus_iff)
   332   also have "...  \<longleftrightarrow> (\<exists>n::int. -z = of_real(2 * n * pi) + of_real pi/2)"
   333     by (simp only: csin_eq_1)
   334   also have "...  \<longleftrightarrow> (\<exists>n::int. z = - of_real(2 * n * pi) - of_real pi/2)"
   335     apply (rule iff_exI)
   336     by (metis (no_types)  is_num_normalize(8) minus_minus of_real_def real_vector.scale_minus_left uminus_add_conv_diff)
   337   also have "... = ?rhs"
   338     apply (auto simp: of_real_numeral)
   339     apply (rule_tac [2] x="-(x+1)" in exI)
   340     apply (rule_tac x="-(x+1)" in exI)
   341     apply (simp_all add: algebra_simps)
   342     done
   343   finally show ?thesis .
   344 qed
   345 
   346 lemma ccos_eq_minus1:
   347   fixes z::complex
   348   shows "cos z = -1 \<longleftrightarrow> (\<exists>n::int. z = of_real(2 * n * pi) + pi)"
   349   using csin_eq_1 [of "z - of_real pi/2"]
   350   apply (simp add: sin_diff)
   351   apply (simp add: algebra_simps of_real_numeral equation_minus_iff)
   352   done
   353 
   354 lemma sin_eq_1: "sin x = 1 \<longleftrightarrow> (\<exists>n::int. x = (2 * n + 1 / 2) * pi)"
   355                 (is "_ = ?rhs")
   356 proof -
   357   have "sin x = 1 \<longleftrightarrow> sin (complex_of_real x) = 1"
   358     by (metis of_real_1 one_complex.simps(1) real_sin_eq sin_of_real)
   359   also have "...  \<longleftrightarrow> (\<exists>n::int. complex_of_real x = of_real(2 * n * pi) + of_real pi/2)"
   360     by (simp only: csin_eq_1)
   361   also have "...  \<longleftrightarrow> (\<exists>n::int. x = of_real(2 * n * pi) + of_real pi/2)"
   362     apply (rule iff_exI)
   363     apply (auto simp: algebra_simps of_real_numeral)
   364     apply (rule injD [OF inj_of_real [where 'a = complex]])
   365     apply (auto simp: of_real_numeral)
   366     done
   367   also have "... = ?rhs"
   368     by (auto simp: algebra_simps)
   369   finally show ?thesis .
   370 qed
   371 
   372 lemma sin_eq_minus1: "sin x = -1 \<longleftrightarrow> (\<exists>n::int. x = (2*n + 3/2) * pi)"  (is "_ = ?rhs")
   373 proof -
   374   have "sin x = -1 \<longleftrightarrow> sin (complex_of_real x) = -1"
   375     by (metis Re_complex_of_real of_real_def scaleR_minus1_left sin_of_real)
   376   also have "...  \<longleftrightarrow> (\<exists>n::int. complex_of_real x = of_real(2 * n * pi) + 3/2*pi)"
   377     by (simp only: csin_eq_minus1)
   378   also have "...  \<longleftrightarrow> (\<exists>n::int. x = of_real(2 * n * pi) + 3/2*pi)"
   379     apply (rule iff_exI)
   380     apply (auto simp: algebra_simps)
   381     apply (rule injD [OF inj_of_real [where 'a = complex]], auto)
   382     done
   383   also have "... = ?rhs"
   384     by (auto simp: algebra_simps)
   385   finally show ?thesis .
   386 qed
   387 
   388 lemma cos_eq_minus1: "cos x = -1 \<longleftrightarrow> (\<exists>n::int. x = (2*n + 1) * pi)"
   389                       (is "_ = ?rhs")
   390 proof -
   391   have "cos x = -1 \<longleftrightarrow> cos (complex_of_real x) = -1"
   392     by (metis Re_complex_of_real of_real_def scaleR_minus1_left cos_of_real)
   393   also have "...  \<longleftrightarrow> (\<exists>n::int. complex_of_real x = of_real(2 * n * pi) + pi)"
   394     by (simp only: ccos_eq_minus1)
   395   also have "...  \<longleftrightarrow> (\<exists>n::int. x = of_real(2 * n * pi) + pi)"
   396     apply (rule iff_exI)
   397     apply (auto simp: algebra_simps)
   398     apply (rule injD [OF inj_of_real [where 'a = complex]], auto)
   399     done
   400   also have "... = ?rhs"
   401     by (auto simp: algebra_simps)
   402   finally show ?thesis .
   403 qed
   404 
   405 lemma dist_exp_i_1: "norm(exp(\<i> * of_real t) - 1) = 2 * \<bar>sin(t / 2)\<bar>"
   406   apply (simp add: exp_Euler cmod_def power2_diff sin_of_real cos_of_real algebra_simps)
   407   using cos_double_sin [of "t/2"]
   408   apply (simp add: real_sqrt_mult)
   409   done
   410 
   411 
   412 lemma complex_sin_eq:
   413   fixes w :: complex
   414   shows "sin w = sin z \<longleftrightarrow> (\<exists>n \<in> \<int>. w = z + of_real(2*n*pi) \<or> w = -z + of_real((2*n + 1)*pi))"
   415         (is "?lhs = ?rhs")
   416 proof
   417   assume ?lhs
   418   then have "sin w - sin z = 0"
   419     by (auto simp: algebra_simps)
   420   then have "sin ((w - z) / 2)*cos ((w + z) / 2) = 0"
   421     by (auto simp: sin_diff_sin)
   422   then consider "sin ((w - z) / 2) = 0" | "cos ((w + z) / 2) = 0"
   423     using mult_eq_0_iff by blast
   424   then show ?rhs
   425   proof cases
   426     case 1
   427     then show ?thesis
   428       apply (auto simp: sin_eq_0 algebra_simps)
   429       by (metis Ints_of_int of_real_of_int_eq)
   430   next
   431     case 2
   432     then show ?thesis
   433       apply (auto simp: cos_eq_0 algebra_simps)
   434       by (metis Ints_of_int of_real_of_int_eq)
   435   qed
   436 next
   437   assume ?rhs
   438   then obtain n::int where w: "w = z + of_real (2* of_int n*pi) \<or>
   439                                w = -z + of_real ((2* of_int n + 1)*pi)"
   440     using Ints_cases by blast
   441   then show ?lhs
   442     using Periodic_Fun.sin.plus_of_int [of z n]
   443     apply (auto simp: algebra_simps)
   444     by (metis (no_types, hide_lams) add_diff_cancel_left add_diff_cancel_left' add_minus_cancel
   445               mult.commute sin.plus_of_int sin_minus sin_plus_pi)
   446 qed
   447 
   448 lemma complex_cos_eq:
   449   fixes w :: complex
   450   shows "cos w = cos z \<longleftrightarrow>
   451          (\<exists>n \<in> \<int>. w = z + of_real(2*n*pi) \<or> w = -z + of_real(2*n*pi))"
   452         (is "?lhs = ?rhs")
   453 proof
   454   assume ?lhs
   455   then have "cos w - cos z = 0"
   456     by (auto simp: algebra_simps)
   457   then have "sin ((w + z) / 2) * sin ((z - w) / 2) = 0"
   458     by (auto simp: cos_diff_cos)
   459   then consider "sin ((w + z) / 2) = 0" | "sin ((z - w) / 2) = 0"
   460     using mult_eq_0_iff by blast
   461   then show ?rhs
   462   proof cases
   463     case 1
   464     then show ?thesis
   465       apply (auto simp: sin_eq_0 algebra_simps)
   466       by (metis Ints_of_int of_real_of_int_eq)
   467   next
   468     case 2
   469     then show ?thesis
   470       apply (auto simp: sin_eq_0 algebra_simps)
   471       by (metis Ints_of_int add_minus_cancel distrib_right mult_of_int_commute mult_zero_right of_int_0 of_int_add of_real_of_int_eq)
   472   qed
   473 next
   474   assume ?rhs
   475   then obtain n::int where w: "w = z + of_real (2* of_int n*pi) \<or>
   476                                w = -z + of_real(2*n*pi)"
   477     using Ints_cases  by (metis of_int_mult of_int_numeral)
   478   then show ?lhs
   479     using Periodic_Fun.cos.plus_of_int [of z n]
   480     apply (auto simp: algebra_simps)
   481     by (metis cos.plus_of_int cos_minus minus_add_cancel mult.commute)
   482 qed
   483 
   484 lemma sin_eq:
   485    "sin x = sin y \<longleftrightarrow> (\<exists>n \<in> \<int>. x = y + 2*n*pi \<or> x = -y + (2*n + 1)*pi)"
   486   using complex_sin_eq [of x y]
   487   by (simp only: sin_of_real Re_complex_of_real of_real_add [symmetric] of_real_minus [symmetric] of_real_mult [symmetric] of_real_eq_iff)
   488 
   489 lemma cos_eq:
   490    "cos x = cos y \<longleftrightarrow> (\<exists>n \<in> \<int>. x = y + 2*n*pi \<or> x = -y + 2*n*pi)"
   491   using complex_cos_eq [of x y]
   492   by (simp only: cos_of_real Re_complex_of_real of_real_add [symmetric] of_real_minus [symmetric] of_real_mult [symmetric] of_real_eq_iff)
   493 
   494 lemma sinh_complex:
   495   fixes z :: complex
   496   shows "(exp z - inverse (exp z)) / 2 = -\<i> * sin(\<i> * z)"
   497   by (simp add: sin_exp_eq divide_simps exp_minus)
   498 
   499 lemma sin_i_times:
   500   fixes z :: complex
   501   shows "sin(\<i> * z) = \<i> * ((exp z - inverse (exp z)) / 2)"
   502   using sinh_complex by auto
   503 
   504 lemma sinh_real:
   505   fixes x :: real
   506   shows "of_real((exp x - inverse (exp x)) / 2) = -\<i> * sin(\<i> * of_real x)"
   507   by (simp add: exp_of_real sin_i_times)
   508 
   509 lemma cosh_complex:
   510   fixes z :: complex
   511   shows "(exp z + inverse (exp z)) / 2 = cos(\<i> * z)"
   512   by (simp add: cos_exp_eq divide_simps exp_minus exp_of_real)
   513 
   514 lemma cosh_real:
   515   fixes x :: real
   516   shows "of_real((exp x + inverse (exp x)) / 2) = cos(\<i> * of_real x)"
   517   by (simp add: cos_exp_eq divide_simps exp_minus exp_of_real)
   518 
   519 lemmas cos_i_times = cosh_complex [symmetric]
   520 
   521 lemma norm_cos_squared:
   522     "norm(cos z) ^ 2 = cos(Re z) ^ 2 + (exp(Im z) - inverse(exp(Im z))) ^ 2 / 4"
   523   apply (cases z)
   524   apply (simp add: cos_add cmod_power2 cos_of_real sin_of_real Complex_eq)
   525   apply (simp add: cos_exp_eq sin_exp_eq exp_minus exp_of_real Re_divide Im_divide power_divide)
   526   apply (simp only: left_diff_distrib [symmetric] power_mult_distrib)
   527   apply (simp add: sin_squared_eq)
   528   apply (simp add: power2_eq_square algebra_simps divide_simps)
   529   done
   530 
   531 lemma norm_sin_squared:
   532     "norm(sin z) ^ 2 = (exp(2 * Im z) + inverse(exp(2 * Im z)) - 2 * cos(2 * Re z)) / 4"
   533   apply (cases z)
   534   apply (simp add: sin_add cmod_power2 cos_of_real sin_of_real cos_double_cos exp_double Complex_eq)
   535   apply (simp add: cos_exp_eq sin_exp_eq exp_minus exp_of_real Re_divide Im_divide power_divide)
   536   apply (simp only: left_diff_distrib [symmetric] power_mult_distrib)
   537   apply (simp add: cos_squared_eq)
   538   apply (simp add: power2_eq_square algebra_simps divide_simps)
   539   done
   540 
   541 lemma exp_uminus_Im: "exp (- Im z) \<le> exp (cmod z)"
   542   using abs_Im_le_cmod linear order_trans by fastforce
   543 
   544 lemma norm_cos_le:
   545   fixes z::complex
   546   shows "norm(cos z) \<le> exp(norm z)"
   547 proof -
   548   have "Im z \<le> cmod z"
   549     using abs_Im_le_cmod abs_le_D1 by auto
   550   with exp_uminus_Im show ?thesis
   551     apply (simp add: cos_exp_eq norm_divide)
   552     apply (rule order_trans [OF norm_triangle_ineq], simp)
   553     apply (metis add_mono exp_le_cancel_iff mult_2_right)
   554     done
   555 qed
   556 
   557 lemma norm_cos_plus1_le:
   558   fixes z::complex
   559   shows "norm(1 + cos z) \<le> 2 * exp(norm z)"
   560 proof -
   561   have mono: "\<And>u w z::real. (1 \<le> w | 1 \<le> z) \<Longrightarrow> (w \<le> u & z \<le> u) \<Longrightarrow> 2 + w + z \<le> 4 * u"
   562       by arith
   563   have *: "Im z \<le> cmod z"
   564     using abs_Im_le_cmod abs_le_D1 by auto
   565   have triangle3: "\<And>x y z. norm(x + y + z) \<le> norm(x) + norm(y) + norm(z)"
   566     by (simp add: norm_add_rule_thm)
   567   have "norm(1 + cos z) = cmod (1 + (exp (\<i> * z) + exp (- (\<i> * z))) / 2)"
   568     by (simp add: cos_exp_eq)
   569   also have "... = cmod ((2 + exp (\<i> * z) + exp (- (\<i> * z))) / 2)"
   570     by (simp add: field_simps)
   571   also have "... = cmod (2 + exp (\<i> * z) + exp (- (\<i> * z))) / 2"
   572     by (simp add: norm_divide)
   573   finally show ?thesis
   574     apply (rule ssubst, simp)
   575     apply (rule order_trans [OF triangle3], simp)
   576     using exp_uminus_Im *
   577     apply (auto intro: mono)
   578     done
   579 qed
   580 
   581 subsection\<open>Taylor series for complex exponential, sine and cosine.\<close>
   582 
   583 declare power_Suc [simp del]
   584 
   585 lemma Taylor_exp:
   586   "norm(exp z - (\<Sum>k\<le>n. z ^ k / (fact k))) \<le> exp\<bar>Re z\<bar> * (norm z) ^ (Suc n) / (fact n)"
   587 proof (rule complex_taylor [of _ n "\<lambda>k. exp" "exp\<bar>Re z\<bar>" 0 z, simplified])
   588   show "convex (closed_segment 0 z)"
   589     by (rule convex_closed_segment [of 0 z])
   590 next
   591   fix k x
   592   assume "x \<in> closed_segment 0 z" "k \<le> n"
   593   show "(exp has_field_derivative exp x) (at x within closed_segment 0 z)"
   594     using DERIV_exp DERIV_subset by blast
   595 next
   596   fix x
   597   assume "x \<in> closed_segment 0 z"
   598   then show "Re x \<le> \<bar>Re z\<bar>"
   599     apply (auto simp: closed_segment_def scaleR_conv_of_real)
   600     by (meson abs_ge_self abs_ge_zero linear mult_left_le_one_le mult_nonneg_nonpos order_trans)
   601 next
   602   show "0 \<in> closed_segment 0 z"
   603     by (auto simp: closed_segment_def)
   604 next
   605   show "z \<in> closed_segment 0 z"
   606     apply (simp add: closed_segment_def scaleR_conv_of_real)
   607     using of_real_1 zero_le_one by blast
   608 qed
   609 
   610 lemma
   611   assumes "0 \<le> u" "u \<le> 1"
   612   shows cmod_sin_le_exp: "cmod (sin (u *\<^sub>R z)) \<le> exp \<bar>Im z\<bar>"
   613     and cmod_cos_le_exp: "cmod (cos (u *\<^sub>R z)) \<le> exp \<bar>Im z\<bar>"
   614 proof -
   615   have mono: "\<And>u w z::real. w \<le> u \<Longrightarrow> z \<le> u \<Longrightarrow> w + z \<le> u*2"
   616     by arith
   617   show "cmod (sin (u *\<^sub>R z)) \<le> exp \<bar>Im z\<bar>" using assms
   618     apply (auto simp: scaleR_conv_of_real norm_mult norm_power sin_exp_eq norm_divide)
   619     apply (rule order_trans [OF norm_triangle_ineq4])
   620     apply (rule mono)
   621     apply (auto simp: abs_if mult_left_le_one_le)
   622     apply (meson mult_nonneg_nonneg neg_le_0_iff_le not_le order_trans)
   623     apply (meson less_eq_real_def mult_nonneg_nonpos neg_0_le_iff_le order_trans)
   624     done
   625   show "cmod (cos (u *\<^sub>R z)) \<le> exp \<bar>Im z\<bar>" using assms
   626     apply (auto simp: scaleR_conv_of_real norm_mult norm_power cos_exp_eq norm_divide)
   627     apply (rule order_trans [OF norm_triangle_ineq])
   628     apply (rule mono)
   629     apply (auto simp: abs_if mult_left_le_one_le)
   630     apply (meson mult_nonneg_nonneg neg_le_0_iff_le not_le order_trans)
   631     apply (meson less_eq_real_def mult_nonneg_nonpos neg_0_le_iff_le order_trans)
   632     done
   633 qed
   634 
   635 lemma Taylor_sin:
   636   "norm(sin z - (\<Sum>k\<le>n. complex_of_real (sin_coeff k) * z ^ k))
   637    \<le> exp\<bar>Im z\<bar> * (norm z) ^ (Suc n) / (fact n)"
   638 proof -
   639   have mono: "\<And>u w z::real. w \<le> u \<Longrightarrow> z \<le> u \<Longrightarrow> w + z \<le> u*2"
   640       by arith
   641   have *: "cmod (sin z -
   642                  (\<Sum>i\<le>n. (-1) ^ (i div 2) * (if even i then sin 0 else cos 0) * z ^ i / (fact i)))
   643            \<le> exp \<bar>Im z\<bar> * cmod z ^ Suc n / (fact n)"
   644   proof (rule complex_taylor [of "closed_segment 0 z" n
   645                                  "\<lambda>k x. (-1)^(k div 2) * (if even k then sin x else cos x)"
   646                                  "exp\<bar>Im z\<bar>" 0 z,  simplified])
   647     fix k x
   648     show "((\<lambda>x. (- 1) ^ (k div 2) * (if even k then sin x else cos x)) has_field_derivative
   649             (- 1) ^ (Suc k div 2) * (if odd k then sin x else cos x))
   650             (at x within closed_segment 0 z)"
   651       apply (auto simp: power_Suc)
   652       apply (intro derivative_eq_intros | simp)+
   653       done
   654   next
   655     fix x
   656     assume "x \<in> closed_segment 0 z"
   657     then show "cmod ((- 1) ^ (Suc n div 2) * (if odd n then sin x else cos x)) \<le> exp \<bar>Im z\<bar>"
   658       by (auto simp: closed_segment_def norm_mult norm_power cmod_sin_le_exp cmod_cos_le_exp)
   659   qed
   660   have **: "\<And>k. complex_of_real (sin_coeff k) * z ^ k
   661             = (-1)^(k div 2) * (if even k then sin 0 else cos 0) * z^k / of_nat (fact k)"
   662     by (auto simp: sin_coeff_def elim!: oddE)
   663   show ?thesis
   664     apply (rule order_trans [OF _ *])
   665     apply (simp add: **)
   666     done
   667 qed
   668 
   669 lemma Taylor_cos:
   670   "norm(cos z - (\<Sum>k\<le>n. complex_of_real (cos_coeff k) * z ^ k))
   671    \<le> exp\<bar>Im z\<bar> * (norm z) ^ Suc n / (fact n)"
   672 proof -
   673   have mono: "\<And>u w z::real. w \<le> u \<Longrightarrow> z \<le> u \<Longrightarrow> w + z \<le> u*2"
   674       by arith
   675   have *: "cmod (cos z -
   676                  (\<Sum>i\<le>n. (-1) ^ (Suc i div 2) * (if even i then cos 0 else sin 0) * z ^ i / (fact i)))
   677            \<le> exp \<bar>Im z\<bar> * cmod z ^ Suc n / (fact n)"
   678   proof (rule complex_taylor [of "closed_segment 0 z" n "\<lambda>k x. (-1)^(Suc k div 2) * (if even k then cos x else sin x)" "exp\<bar>Im z\<bar>" 0 z,
   679 simplified])
   680     fix k x
   681     assume "x \<in> closed_segment 0 z" "k \<le> n"
   682     show "((\<lambda>x. (- 1) ^ (Suc k div 2) * (if even k then cos x else sin x)) has_field_derivative
   683             (- 1) ^ Suc (k div 2) * (if odd k then cos x else sin x))
   684              (at x within closed_segment 0 z)"
   685       apply (auto simp: power_Suc)
   686       apply (intro derivative_eq_intros | simp)+
   687       done
   688   next
   689     fix x
   690     assume "x \<in> closed_segment 0 z"
   691     then show "cmod ((- 1) ^ Suc (n div 2) * (if odd n then cos x else sin x)) \<le> exp \<bar>Im z\<bar>"
   692       by (auto simp: closed_segment_def norm_mult norm_power cmod_sin_le_exp cmod_cos_le_exp)
   693   qed
   694   have **: "\<And>k. complex_of_real (cos_coeff k) * z ^ k
   695             = (-1)^(Suc k div 2) * (if even k then cos 0 else sin 0) * z^k / of_nat (fact k)"
   696     by (auto simp: cos_coeff_def elim!: evenE)
   697   show ?thesis
   698     apply (rule order_trans [OF _ *])
   699     apply (simp add: **)
   700     done
   701 qed
   702 
   703 declare power_Suc [simp]
   704 
   705 text\<open>32-bit Approximation to e\<close>
   706 lemma e_approx_32: "\<bar>exp(1) - 5837465777 / 2147483648\<bar> \<le> (inverse(2 ^ 32)::real)"
   707   using Taylor_exp [of 1 14] exp_le
   708   apply (simp add: sum_distrib_right in_Reals_norm Re_exp atMost_nat_numeral fact_numeral)
   709   apply (simp only: pos_le_divide_eq [symmetric], linarith)
   710   done
   711 
   712 text\<open>An odd contrast with the much more easily proved @{thm exp_le}\<close>
   713 lemma e_less_3: "exp 1 < (3::real)"
   714   using e_approx_32
   715   by (simp add: abs_if split: if_split_asm)
   716 
   717 lemma ln3_gt_1: "ln 3 > (1::real)"
   718   by (metis e_less_3 exp_less_cancel_iff exp_ln_iff less_trans ln_exp)
   719 
   720 
   721 subsection\<open>The argument of a complex number\<close>
   722 
   723 definition Arg :: "complex \<Rightarrow> real" where
   724  "Arg z \<equiv> if z = 0 then 0
   725            else THE t. 0 \<le> t \<and> t < 2*pi \<and>
   726                     z = of_real(norm z) * exp(\<i> * of_real t)"
   727 
   728 lemma Arg_0 [simp]: "Arg(0) = 0"
   729   by (simp add: Arg_def)
   730 
   731 lemma Arg_unique_lemma:
   732   assumes z:  "z = of_real(norm z) * exp(\<i> * of_real t)"
   733       and z': "z = of_real(norm z) * exp(\<i> * of_real t')"
   734       and t:  "0 \<le> t"  "t < 2*pi"
   735       and t': "0 \<le> t'" "t' < 2*pi"
   736       and nz: "z \<noteq> 0"
   737   shows "t' = t"
   738 proof -
   739   have [dest]: "\<And>x y z::real. x\<ge>0 \<Longrightarrow> x+y < z \<Longrightarrow> y<z"
   740     by arith
   741   have "of_real (cmod z) * exp (\<i> * of_real t') = of_real (cmod z) * exp (\<i> * of_real t)"
   742     by (metis z z')
   743   then have "exp (\<i> * of_real t') = exp (\<i> * of_real t)"
   744     by (metis nz mult_left_cancel mult_zero_left z)
   745   then have "sin t' = sin t \<and> cos t' = cos t"
   746     apply (simp add: exp_Euler sin_of_real cos_of_real)
   747     by (metis Complex_eq complex.sel)
   748   then obtain n::int where n: "t' = t + 2 * n * pi"
   749     by (auto simp: sin_cos_eq_iff)
   750   then have "n=0"
   751     apply (rule_tac z=n in int_cases)
   752     using t t'
   753     apply (auto simp: mult_less_0_iff algebra_simps)
   754     done
   755   then show "t' = t"
   756       by (simp add: n)
   757 qed
   758 
   759 lemma Arg: "0 \<le> Arg z & Arg z < 2*pi & z = of_real(norm z) * exp(\<i> * of_real(Arg z))"
   760 proof (cases "z=0")
   761   case True then show ?thesis
   762     by (simp add: Arg_def)
   763 next
   764   case False
   765   obtain t where t: "0 \<le> t" "t < 2*pi"
   766              and ReIm: "Re z / cmod z = cos t" "Im z / cmod z = sin t"
   767     using sincos_total_2pi [OF complex_unit_circle [OF False]]
   768     by blast
   769   have z: "z = of_real(norm z) * exp(\<i> * of_real t)"
   770     apply (rule complex_eqI)
   771     using t False ReIm
   772     apply (auto simp: exp_Euler sin_of_real cos_of_real divide_simps)
   773     done
   774   show ?thesis
   775     apply (simp add: Arg_def False)
   776     apply (rule theI [where a=t])
   777     using t z False
   778     apply (auto intro: Arg_unique_lemma)
   779     done
   780 qed
   781 
   782 corollary
   783   shows Arg_ge_0: "0 \<le> Arg z"
   784     and Arg_lt_2pi: "Arg z < 2*pi"
   785     and Arg_eq: "z = of_real(norm z) * exp(\<i> * of_real(Arg z))"
   786   using Arg by auto
   787 
   788 lemma complex_norm_eq_1_exp: "norm z = 1 \<longleftrightarrow> exp(\<i> * of_real (Arg z)) = z"
   789   by (metis Arg_eq cis_conv_exp mult.left_neutral norm_cis of_real_1)
   790 
   791 lemma Arg_unique: "\<lbrakk>of_real r * exp(\<i> * of_real a) = z; 0 < r; 0 \<le> a; a < 2*pi\<rbrakk> \<Longrightarrow> Arg z = a"
   792   apply (rule Arg_unique_lemma [OF _ Arg_eq])
   793   using Arg [of z]
   794   apply (auto simp: norm_mult)
   795   done
   796 
   797 lemma Arg_minus: "z \<noteq> 0 \<Longrightarrow> Arg (-z) = (if Arg z < pi then Arg z + pi else Arg z - pi)"
   798   apply (rule Arg_unique [of "norm z"])
   799   apply (rule complex_eqI)
   800   using Arg_ge_0 [of z] Arg_eq [of z] Arg_lt_2pi [of z] Arg_eq [of z]
   801   apply auto
   802   apply (auto simp: Re_exp Im_exp cos_diff sin_diff cis_conv_exp [symmetric])
   803   apply (metis Re_rcis Im_rcis rcis_def)+
   804   done
   805 
   806 lemma Arg_times_of_real [simp]: "0 < r \<Longrightarrow> Arg (of_real r * z) = Arg z"
   807   apply (cases "z=0", simp)
   808   apply (rule Arg_unique [of "r * norm z"])
   809   using Arg
   810   apply auto
   811   done
   812 
   813 lemma Arg_times_of_real2 [simp]: "0 < r \<Longrightarrow> Arg (z * of_real r) = Arg z"
   814   by (metis Arg_times_of_real mult.commute)
   815 
   816 lemma Arg_divide_of_real [simp]: "0 < r \<Longrightarrow> Arg (z / of_real r) = Arg z"
   817   by (metis Arg_times_of_real2 less_numeral_extra(3) nonzero_eq_divide_eq of_real_eq_0_iff)
   818 
   819 lemma Arg_le_pi: "Arg z \<le> pi \<longleftrightarrow> 0 \<le> Im z"
   820 proof (cases "z=0")
   821   case True then show ?thesis
   822     by simp
   823 next
   824   case False
   825   have "0 \<le> Im z \<longleftrightarrow> 0 \<le> Im (of_real (cmod z) * exp (\<i> * complex_of_real (Arg z)))"
   826     by (metis Arg_eq)
   827   also have "... = (0 \<le> Im (exp (\<i> * complex_of_real (Arg z))))"
   828     using False
   829     by (simp add: zero_le_mult_iff)
   830   also have "... \<longleftrightarrow> Arg z \<le> pi"
   831     by (simp add: Im_exp) (metis Arg_ge_0 Arg_lt_2pi sin_lt_zero sin_ge_zero not_le)
   832   finally show ?thesis
   833     by blast
   834 qed
   835 
   836 lemma Arg_lt_pi: "0 < Arg z \<and> Arg z < pi \<longleftrightarrow> 0 < Im z"
   837 proof (cases "z=0")
   838   case True then show ?thesis
   839     by simp
   840 next
   841   case False
   842   have "0 < Im z \<longleftrightarrow> 0 < Im (of_real (cmod z) * exp (\<i> * complex_of_real (Arg z)))"
   843     by (metis Arg_eq)
   844   also have "... = (0 < Im (exp (\<i> * complex_of_real (Arg z))))"
   845     using False
   846     by (simp add: zero_less_mult_iff)
   847   also have "... \<longleftrightarrow> 0 < Arg z \<and> Arg z < pi"
   848     using Arg_ge_0  Arg_lt_2pi sin_le_zero sin_gt_zero
   849     apply (auto simp: Im_exp)
   850     using le_less apply fastforce
   851     using not_le by blast
   852   finally show ?thesis
   853     by blast
   854 qed
   855 
   856 lemma Arg_eq_0: "Arg z = 0 \<longleftrightarrow> z \<in> \<real> \<and> 0 \<le> Re z"
   857 proof (cases "z=0")
   858   case True then show ?thesis
   859     by simp
   860 next
   861   case False
   862   have "z \<in> \<real> \<and> 0 \<le> Re z \<longleftrightarrow> z \<in> \<real> \<and> 0 \<le> Re (of_real (cmod z) * exp (\<i> * complex_of_real (Arg z)))"
   863     by (metis Arg_eq)
   864   also have "... \<longleftrightarrow> z \<in> \<real> \<and> 0 \<le> Re (exp (\<i> * complex_of_real (Arg z)))"
   865     using False
   866     by (simp add: zero_le_mult_iff)
   867   also have "... \<longleftrightarrow> Arg z = 0"
   868     apply (auto simp: Re_exp)
   869     apply (metis Arg_lt_pi Arg_ge_0 Arg_le_pi cos_pi complex_is_Real_iff leD less_linear less_minus_one_simps(2) minus_minus neg_less_eq_nonneg order_refl)
   870     using Arg_eq [of z]
   871     apply (auto simp: Reals_def)
   872     done
   873   finally show ?thesis
   874     by blast
   875 qed
   876 
   877 corollary Arg_gt_0:
   878   assumes "z \<in> \<real> \<Longrightarrow> Re z < 0"
   879     shows "Arg z > 0"
   880   using Arg_eq_0 Arg_ge_0 assms dual_order.strict_iff_order by fastforce
   881 
   882 lemma Arg_of_real: "Arg(of_real x) = 0 \<longleftrightarrow> 0 \<le> x"
   883   by (simp add: Arg_eq_0)
   884 
   885 lemma Arg_eq_pi: "Arg z = pi \<longleftrightarrow> z \<in> \<real> \<and> Re z < 0"
   886   apply  (cases "z=0", simp)
   887   using Arg_eq_0 [of "-z"]
   888   apply (auto simp: complex_is_Real_iff Arg_minus)
   889   apply (simp add: complex_Re_Im_cancel_iff)
   890   apply (metis Arg_minus pi_gt_zero add.left_neutral minus_minus minus_zero)
   891   done
   892 
   893 lemma Arg_eq_0_pi: "Arg z = 0 \<or> Arg z = pi \<longleftrightarrow> z \<in> \<real>"
   894   using Arg_eq_0 Arg_eq_pi not_le by auto
   895 
   896 lemma Arg_inverse: "Arg(inverse z) = (if z \<in> \<real> \<and> 0 \<le> Re z then Arg z else 2*pi - Arg z)"
   897   apply (cases "z=0", simp)
   898   apply (rule Arg_unique [of "inverse (norm z)"])
   899   using Arg_ge_0 [of z] Arg_lt_2pi [of z] Arg_eq [of z] Arg_eq_0 [of z] exp_two_pi_i
   900   apply (auto simp: of_real_numeral algebra_simps exp_diff divide_simps)
   901   done
   902 
   903 lemma Arg_eq_iff:
   904   assumes "w \<noteq> 0" "z \<noteq> 0"
   905      shows "Arg w = Arg z \<longleftrightarrow> (\<exists>x. 0 < x & w = of_real x * z)"
   906   using assms Arg_eq [of z] Arg_eq [of w]
   907   apply auto
   908   apply (rule_tac x="norm w / norm z" in exI)
   909   apply (simp add: divide_simps)
   910   by (metis mult.commute mult.left_commute)
   911 
   912 lemma Arg_inverse_eq_0: "Arg(inverse z) = 0 \<longleftrightarrow> Arg z = 0"
   913   using complex_is_Real_iff
   914   apply (simp add: Arg_eq_0)
   915   apply (auto simp: divide_simps not_sum_power2_lt_zero)
   916   done
   917 
   918 lemma Arg_divide:
   919   assumes "w \<noteq> 0" "z \<noteq> 0" "Arg w \<le> Arg z"
   920     shows "Arg(z / w) = Arg z - Arg w"
   921   apply (rule Arg_unique [of "norm(z / w)"])
   922   using assms Arg_eq [of z] Arg_eq [of w] Arg_ge_0 [of w] Arg_lt_2pi [of z]
   923   apply (auto simp: exp_diff norm_divide algebra_simps divide_simps)
   924   done
   925 
   926 lemma Arg_le_div_sum:
   927   assumes "w \<noteq> 0" "z \<noteq> 0" "Arg w \<le> Arg z"
   928     shows "Arg z = Arg w + Arg(z / w)"
   929   by (simp add: Arg_divide assms)
   930 
   931 lemma Arg_le_div_sum_eq:
   932   assumes "w \<noteq> 0" "z \<noteq> 0"
   933     shows "Arg w \<le> Arg z \<longleftrightarrow> Arg z = Arg w + Arg(z / w)"
   934   using assms
   935   by (auto simp: Arg_ge_0 intro: Arg_le_div_sum)
   936 
   937 lemma Arg_diff:
   938   assumes "w \<noteq> 0" "z \<noteq> 0"
   939     shows "Arg w - Arg z = (if Arg z \<le> Arg w then Arg(w / z) else Arg(w/z) - 2*pi)"
   940   using assms
   941   apply (auto simp: Arg_ge_0 Arg_divide not_le)
   942   using Arg_divide [of w z] Arg_inverse [of "w/z"]
   943   apply auto
   944   by (metis Arg_eq_0 less_irrefl minus_diff_eq right_minus_eq)
   945 
   946 lemma Arg_add:
   947   assumes "w \<noteq> 0" "z \<noteq> 0"
   948     shows "Arg w + Arg z = (if Arg w + Arg z < 2*pi then Arg(w * z) else Arg(w * z) + 2*pi)"
   949   using assms
   950   using Arg_diff [of "w*z" z] Arg_le_div_sum_eq [of z "w*z"]
   951   apply (auto simp: Arg_ge_0 Arg_divide not_le)
   952   apply (metis Arg_lt_2pi add.commute)
   953   apply (metis (no_types) Arg add.commute diff_0 diff_add_cancel diff_less_eq diff_minus_eq_add not_less)
   954   done
   955 
   956 lemma Arg_times:
   957   assumes "w \<noteq> 0" "z \<noteq> 0"
   958     shows "Arg (w * z) = (if Arg w + Arg z < 2*pi then Arg w + Arg z
   959                             else (Arg w + Arg z) - 2*pi)"
   960   using Arg_add [OF assms]
   961   by auto
   962 
   963 lemma Arg_cnj: "Arg(cnj z) = (if z \<in> \<real> \<and> 0 \<le> Re z then Arg z else 2*pi - Arg z)"
   964   apply (cases "z=0", simp)
   965   apply (rule trans [of _ "Arg(inverse z)"])
   966   apply (simp add: Arg_eq_iff divide_simps complex_norm_square [symmetric] mult.commute)
   967   apply (metis norm_eq_zero of_real_power zero_less_power2)
   968   apply (auto simp: of_real_numeral Arg_inverse)
   969   done
   970 
   971 lemma Arg_real: "z \<in> \<real> \<Longrightarrow> Arg z = (if 0 \<le> Re z then 0 else pi)"
   972   using Arg_eq_0 Arg_eq_0_pi
   973   by auto
   974 
   975 lemma Arg_exp: "0 \<le> Im z \<Longrightarrow> Im z < 2*pi \<Longrightarrow> Arg(exp z) = Im z"
   976   by (rule Arg_unique [of  "exp(Re z)"]) (auto simp: exp_eq_polar)
   977 
   978 lemma complex_split_polar:
   979   obtains r a::real where "z = complex_of_real r * (cos a + \<i> * sin a)" "0 \<le> r" "0 \<le> a" "a < 2*pi"
   980   using Arg cis.ctr cis_conv_exp unfolding Complex_eq by fastforce
   981 
   982 lemma Re_Im_le_cmod: "Im w * sin \<phi> + Re w * cos \<phi> \<le> cmod w"
   983 proof (cases w rule: complex_split_polar)
   984   case (1 r a) with sin_cos_le1 [of a \<phi>] show ?thesis
   985     apply (simp add: norm_mult cmod_unit_one)
   986     by (metis (no_types, hide_lams) abs_le_D1 distrib_left mult.commute mult.left_commute mult_left_le)
   987 qed
   988 
   989 subsection\<open>Analytic properties of tangent function\<close>
   990 
   991 lemma cnj_tan: "cnj(tan z) = tan(cnj z)"
   992   by (simp add: cnj_cos cnj_sin tan_def)
   993 
   994 lemma field_differentiable_at_tan: "~(cos z = 0) \<Longrightarrow> tan field_differentiable at z"
   995   unfolding field_differentiable_def
   996   using DERIV_tan by blast
   997 
   998 lemma field_differentiable_within_tan: "~(cos z = 0)
   999          \<Longrightarrow> tan field_differentiable (at z within s)"
  1000   using field_differentiable_at_tan field_differentiable_at_within by blast
  1001 
  1002 lemma continuous_within_tan: "~(cos z = 0) \<Longrightarrow> continuous (at z within s) tan"
  1003   using continuous_at_imp_continuous_within isCont_tan by blast
  1004 
  1005 lemma continuous_on_tan [continuous_intros]: "(\<And>z. z \<in> s \<Longrightarrow> ~(cos z = 0)) \<Longrightarrow> continuous_on s tan"
  1006   by (simp add: continuous_at_imp_continuous_on)
  1007 
  1008 lemma holomorphic_on_tan: "(\<And>z. z \<in> s \<Longrightarrow> ~(cos z = 0)) \<Longrightarrow> tan holomorphic_on s"
  1009   by (simp add: field_differentiable_within_tan holomorphic_on_def)
  1010 
  1011 
  1012 subsection\<open>Complex logarithms (the conventional principal value)\<close>
  1013 
  1014 instantiation complex :: ln
  1015 begin
  1016 
  1017 definition ln_complex :: "complex \<Rightarrow> complex"
  1018   where "ln_complex \<equiv> \<lambda>z. THE w. exp w = z & -pi < Im(w) & Im(w) \<le> pi"
  1019 
  1020 lemma
  1021   assumes "z \<noteq> 0"
  1022     shows exp_Ln [simp]:  "exp(ln z) = z"
  1023       and mpi_less_Im_Ln: "-pi < Im(ln z)"
  1024       and Im_Ln_le_pi:    "Im(ln z) \<le> pi"
  1025 proof -
  1026   obtain \<psi> where z: "z / (cmod z) = Complex (cos \<psi>) (sin \<psi>)"
  1027     using complex_unimodular_polar [of "z / (norm z)"] assms
  1028     by (auto simp: norm_divide divide_simps)
  1029   obtain \<phi> where \<phi>: "- pi < \<phi>" "\<phi> \<le> pi" "sin \<phi> = sin \<psi>" "cos \<phi> = cos \<psi>"
  1030     using sincos_principal_value [of "\<psi>"] assms
  1031     by (auto simp: norm_divide divide_simps)
  1032   have "exp(ln z) = z & -pi < Im(ln z) & Im(ln z) \<le> pi" unfolding ln_complex_def
  1033     apply (rule theI [where a = "Complex (ln(norm z)) \<phi>"])
  1034     using z assms \<phi>
  1035     apply (auto simp: field_simps exp_complex_eqI exp_eq_polar cis.code)
  1036     done
  1037   then show "exp(ln z) = z" "-pi < Im(ln z)" "Im(ln z) \<le> pi"
  1038     by auto
  1039 qed
  1040 
  1041 lemma Ln_exp [simp]:
  1042   assumes "-pi < Im(z)" "Im(z) \<le> pi"
  1043     shows "ln(exp z) = z"
  1044   apply (rule exp_complex_eqI)
  1045   using assms mpi_less_Im_Ln  [of "exp z"] Im_Ln_le_pi [of "exp z"]
  1046   apply auto
  1047   done
  1048 
  1049 lemma Ln_eq_zero_iff [simp]: "x \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> Ln x = 0 \<longleftrightarrow> x = 1"
  1050   by auto (metis exp_Ln exp_zero nonpos_Reals_zero_I)
  1051 
  1052 subsection\<open>Relation to Real Logarithm\<close>
  1053 
  1054 lemma Ln_of_real:
  1055   assumes "0 < z"
  1056     shows "ln(of_real z::complex) = of_real(ln z)"
  1057 proof -
  1058   have "ln(of_real (exp (ln z))::complex) = ln (exp (of_real (ln z)))"
  1059     by (simp add: exp_of_real)
  1060   also have "... = of_real(ln z)"
  1061     using assms
  1062     by (subst Ln_exp) auto
  1063   finally show ?thesis
  1064     using assms by simp
  1065 qed
  1066 
  1067 corollary Ln_in_Reals [simp]: "z \<in> \<real> \<Longrightarrow> Re z > 0 \<Longrightarrow> ln z \<in> \<real>"
  1068   by (auto simp: Ln_of_real elim: Reals_cases)
  1069 
  1070 corollary Im_Ln_of_real [simp]: "r > 0 \<Longrightarrow> Im (ln (of_real r)) = 0"
  1071   by (simp add: Ln_of_real)
  1072 
  1073 lemma cmod_Ln_Reals [simp]: "z \<in> \<real> \<Longrightarrow> 0 < Re z \<Longrightarrow> cmod (ln z) = norm (ln (Re z))"
  1074   using Ln_of_real by force
  1075 
  1076 lemma Ln_1: "ln 1 = (0::complex)"
  1077 proof -
  1078   have "ln (exp 0) = (0::complex)"
  1079     by (metis (mono_tags, hide_lams) Ln_of_real exp_zero ln_one of_real_0 of_real_1 zero_less_one)
  1080   then show ?thesis
  1081     by simp
  1082 qed
  1083 
  1084 instance
  1085   by intro_classes (rule ln_complex_def Ln_1)
  1086 
  1087 end
  1088 
  1089 abbreviation Ln :: "complex \<Rightarrow> complex"
  1090   where "Ln \<equiv> ln"
  1091 
  1092 lemma Ln_eq_iff: "w \<noteq> 0 \<Longrightarrow> z \<noteq> 0 \<Longrightarrow> (Ln w = Ln z \<longleftrightarrow> w = z)"
  1093   by (metis exp_Ln)
  1094 
  1095 lemma Ln_unique: "exp(z) = w \<Longrightarrow> -pi < Im(z) \<Longrightarrow> Im(z) \<le> pi \<Longrightarrow> Ln w = z"
  1096   using Ln_exp by blast
  1097 
  1098 lemma Re_Ln [simp]: "z \<noteq> 0 \<Longrightarrow> Re(Ln z) = ln(norm z)"
  1099   by (metis exp_Ln ln_exp norm_exp_eq_Re)
  1100 
  1101 corollary ln_cmod_le:
  1102   assumes z: "z \<noteq> 0"
  1103     shows "ln (cmod z) \<le> cmod (Ln z)"
  1104   using norm_exp [of "Ln z", simplified exp_Ln [OF z]]
  1105   by (metis Re_Ln complex_Re_le_cmod z)
  1106 
  1107 proposition exists_complex_root:
  1108   fixes z :: complex
  1109   assumes "n \<noteq> 0"  obtains w where "z = w ^ n"
  1110   apply (cases "z=0")
  1111   using assms apply (simp add: power_0_left)
  1112   apply (rule_tac w = "exp(Ln z / n)" in that)
  1113   apply (auto simp: assms exp_of_nat_mult [symmetric])
  1114   done
  1115 
  1116 corollary exists_complex_root_nonzero:
  1117   fixes z::complex
  1118   assumes "z \<noteq> 0" "n \<noteq> 0"
  1119   obtains w where "w \<noteq> 0" "z = w ^ n"
  1120   by (metis exists_complex_root [of n z] assms power_0_left)
  1121 
  1122 subsection\<open>The Unwinding Number and the Ln-product Formula\<close>
  1123 
  1124 text\<open>Note that in this special case the unwinding number is -1, 0 or 1.\<close>
  1125 
  1126 definition unwinding :: "complex \<Rightarrow> complex" where
  1127    "unwinding(z) = (z - Ln(exp z)) / (of_real(2*pi) * \<i>)"
  1128 
  1129 lemma unwinding_2pi: "(2*pi) * \<i> * unwinding(z) = z - Ln(exp z)"
  1130   by (simp add: unwinding_def)
  1131 
  1132 lemma Ln_times_unwinding:
  1133     "w \<noteq> 0 \<Longrightarrow> z \<noteq> 0 \<Longrightarrow> Ln(w * z) = Ln(w) + Ln(z) - (2*pi) * \<i> * unwinding(Ln w + Ln z)"
  1134   using unwinding_2pi by (simp add: exp_add)
  1135 
  1136 
  1137 subsection\<open>Derivative of Ln away from the branch cut\<close>
  1138 
  1139 lemma
  1140   assumes "z \<notin> \<real>\<^sub>\<le>\<^sub>0"
  1141     shows has_field_derivative_Ln: "(Ln has_field_derivative inverse(z)) (at z)"
  1142       and Im_Ln_less_pi:           "Im (Ln z) < pi"
  1143 proof -
  1144   have znz: "z \<noteq> 0"
  1145     using assms by auto
  1146   then have "Im (Ln z) \<noteq> pi"
  1147     by (metis (no_types) Im_exp Ln_in_Reals assms complex_nonpos_Reals_iff complex_is_Real_iff exp_Ln mult_zero_right not_less pi_neq_zero sin_pi znz)
  1148   then show *: "Im (Ln z) < pi" using assms Im_Ln_le_pi
  1149     by (simp add: le_neq_trans znz)
  1150   have "(exp has_field_derivative z) (at (Ln z))"
  1151     by (metis znz DERIV_exp exp_Ln)
  1152   then show "(Ln has_field_derivative inverse(z)) (at z)"
  1153     apply (rule has_complex_derivative_inverse_strong_x
  1154               [where s = "{w. -pi < Im(w) \<and> Im(w) < pi}"])
  1155     using znz *
  1156     apply (auto simp: Transcendental.continuous_on_exp [OF continuous_on_id] open_Collect_conj open_halfspace_Im_gt open_halfspace_Im_lt mpi_less_Im_Ln)
  1157     done
  1158 qed
  1159 
  1160 declare has_field_derivative_Ln [derivative_intros]
  1161 declare has_field_derivative_Ln [THEN DERIV_chain2, derivative_intros]
  1162 
  1163 lemma field_differentiable_at_Ln: "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> Ln field_differentiable at z"
  1164   using field_differentiable_def has_field_derivative_Ln by blast
  1165 
  1166 lemma field_differentiable_within_Ln: "z \<notin> \<real>\<^sub>\<le>\<^sub>0
  1167          \<Longrightarrow> Ln field_differentiable (at z within s)"
  1168   using field_differentiable_at_Ln field_differentiable_within_subset by blast
  1169 
  1170 lemma continuous_at_Ln: "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> continuous (at z) Ln"
  1171   by (simp add: field_differentiable_imp_continuous_at field_differentiable_within_Ln)
  1172 
  1173 lemma isCont_Ln' [simp]:
  1174    "\<lbrakk>isCont f z; f z \<notin> \<real>\<^sub>\<le>\<^sub>0\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. Ln (f x)) z"
  1175   by (blast intro: isCont_o2 [OF _ continuous_at_Ln])
  1176 
  1177 lemma continuous_within_Ln: "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> continuous (at z within s) Ln"
  1178   using continuous_at_Ln continuous_at_imp_continuous_within by blast
  1179 
  1180 lemma continuous_on_Ln [continuous_intros]: "(\<And>z. z \<in> s \<Longrightarrow> z \<notin> \<real>\<^sub>\<le>\<^sub>0) \<Longrightarrow> continuous_on s Ln"
  1181   by (simp add: continuous_at_imp_continuous_on continuous_within_Ln)
  1182 
  1183 lemma holomorphic_on_Ln: "(\<And>z. z \<in> s \<Longrightarrow> z \<notin> \<real>\<^sub>\<le>\<^sub>0) \<Longrightarrow> Ln holomorphic_on s"
  1184   by (simp add: field_differentiable_within_Ln holomorphic_on_def)
  1185 
  1186 
  1187 subsection\<open>Quadrant-type results for Ln\<close>
  1188 
  1189 lemma cos_lt_zero_pi: "pi/2 < x \<Longrightarrow> x < 3*pi/2 \<Longrightarrow> cos x < 0"
  1190   using cos_minus_pi cos_gt_zero_pi [of "x-pi"]
  1191   by simp
  1192 
  1193 lemma Re_Ln_pos_lt:
  1194   assumes "z \<noteq> 0"
  1195     shows "\<bar>Im(Ln z)\<bar> < pi/2 \<longleftrightarrow> 0 < Re(z)"
  1196 proof -
  1197   { fix w
  1198     assume "w = Ln z"
  1199     then have w: "Im w \<le> pi" "- pi < Im w"
  1200       using Im_Ln_le_pi [of z]  mpi_less_Im_Ln [of z]  assms
  1201       by auto
  1202     then have "\<bar>Im w\<bar> < pi/2 \<longleftrightarrow> 0 < Re(exp w)"
  1203       apply (auto simp: Re_exp zero_less_mult_iff cos_gt_zero_pi)
  1204       using cos_lt_zero_pi [of "-(Im w)"] cos_lt_zero_pi [of "(Im w)"]
  1205       apply (simp add: abs_if split: if_split_asm)
  1206       apply (metis (no_types) cos_minus cos_pi_half eq_divide_eq_numeral1(1) eq_numeral_simps(4)
  1207                less_numeral_extra(3) linorder_neqE_linordered_idom minus_mult_minus minus_mult_right
  1208                mult_numeral_1_right)
  1209       done
  1210   }
  1211   then show ?thesis using assms
  1212     by auto
  1213 qed
  1214 
  1215 lemma Re_Ln_pos_le:
  1216   assumes "z \<noteq> 0"
  1217     shows "\<bar>Im(Ln z)\<bar> \<le> pi/2 \<longleftrightarrow> 0 \<le> Re(z)"
  1218 proof -
  1219   { fix w
  1220     assume "w = Ln z"
  1221     then have w: "Im w \<le> pi" "- pi < Im w"
  1222       using Im_Ln_le_pi [of z]  mpi_less_Im_Ln [of z]  assms
  1223       by auto
  1224     then have "\<bar>Im w\<bar> \<le> pi/2 \<longleftrightarrow> 0 \<le> Re(exp w)"
  1225       apply (auto simp: Re_exp zero_le_mult_iff cos_ge_zero)
  1226       using cos_lt_zero_pi [of "- (Im w)"] cos_lt_zero_pi [of "(Im w)"] not_le
  1227       apply (auto simp: abs_if split: if_split_asm)
  1228       done
  1229   }
  1230   then show ?thesis using assms
  1231     by auto
  1232 qed
  1233 
  1234 lemma Im_Ln_pos_lt:
  1235   assumes "z \<noteq> 0"
  1236     shows "0 < Im(Ln z) \<and> Im(Ln z) < pi \<longleftrightarrow> 0 < Im(z)"
  1237 proof -
  1238   { fix w
  1239     assume "w = Ln z"
  1240     then have w: "Im w \<le> pi" "- pi < Im w"
  1241       using Im_Ln_le_pi [of z]  mpi_less_Im_Ln [of z]  assms
  1242       by auto
  1243     then have "0 < Im w \<and> Im w < pi \<longleftrightarrow> 0 < Im(exp w)"
  1244       using sin_gt_zero [of "- (Im w)"] sin_gt_zero [of "(Im w)"]
  1245       apply (auto simp: Im_exp zero_less_mult_iff)
  1246       using less_linear apply fastforce
  1247       using less_linear apply fastforce
  1248       done
  1249   }
  1250   then show ?thesis using assms
  1251     by auto
  1252 qed
  1253 
  1254 lemma Im_Ln_pos_le:
  1255   assumes "z \<noteq> 0"
  1256     shows "0 \<le> Im(Ln z) \<and> Im(Ln z) \<le> pi \<longleftrightarrow> 0 \<le> Im(z)"
  1257 proof -
  1258   { fix w
  1259     assume "w = Ln z"
  1260     then have w: "Im w \<le> pi" "- pi < Im w"
  1261       using Im_Ln_le_pi [of z]  mpi_less_Im_Ln [of z]  assms
  1262       by auto
  1263     then have "0 \<le> Im w \<and> Im w \<le> pi \<longleftrightarrow> 0 \<le> Im(exp w)"
  1264       using sin_ge_zero [of "- (Im w)"] sin_ge_zero [of "(Im w)"]
  1265       apply (auto simp: Im_exp zero_le_mult_iff sin_ge_zero)
  1266       apply (metis not_le not_less_iff_gr_or_eq pi_not_less_zero sin_eq_0_pi)
  1267       done }
  1268   then show ?thesis using assms
  1269     by auto
  1270 qed
  1271 
  1272 lemma Re_Ln_pos_lt_imp: "0 < Re(z) \<Longrightarrow> \<bar>Im(Ln z)\<bar> < pi/2"
  1273   by (metis Re_Ln_pos_lt less_irrefl zero_complex.simps(1))
  1274 
  1275 lemma Im_Ln_pos_lt_imp: "0 < Im(z) \<Longrightarrow> 0 < Im(Ln z) \<and> Im(Ln z) < pi"
  1276   by (metis Im_Ln_pos_lt not_le order_refl zero_complex.simps(2))
  1277 
  1278 text\<open>A reference to the set of positive real numbers\<close>
  1279 lemma Im_Ln_eq_0: "z \<noteq> 0 \<Longrightarrow> (Im(Ln z) = 0 \<longleftrightarrow> 0 < Re(z) \<and> Im(z) = 0)"
  1280 by (metis Im_complex_of_real Im_exp Ln_in_Reals Re_Ln_pos_lt Re_Ln_pos_lt_imp
  1281           Re_complex_of_real complex_is_Real_iff exp_Ln exp_of_real pi_gt_zero)
  1282 
  1283 lemma Im_Ln_eq_pi: "z \<noteq> 0 \<Longrightarrow> (Im(Ln z) = pi \<longleftrightarrow> Re(z) < 0 \<and> Im(z) = 0)"
  1284 by (metis Im_Ln_eq_0 Im_Ln_pos_le Im_Ln_pos_lt add.left_neutral complex_eq less_eq_real_def
  1285     mult_zero_right not_less_iff_gr_or_eq pi_ge_zero pi_neq_zero rcis_zero_arg rcis_zero_mod)
  1286 
  1287 
  1288 subsection\<open>More Properties of Ln\<close>
  1289 
  1290 lemma cnj_Ln: "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> cnj(Ln z) = Ln(cnj z)"
  1291   apply (cases "z=0", auto)
  1292   apply (rule exp_complex_eqI)
  1293   apply (auto simp: abs_if split: if_split_asm)
  1294   using Im_Ln_less_pi Im_Ln_le_pi apply force
  1295   apply (metis complex_cnj_zero_iff diff_minus_eq_add diff_strict_mono minus_less_iff
  1296           mpi_less_Im_Ln mult.commute mult_2_right)
  1297   by (metis exp_Ln exp_cnj)
  1298 
  1299 lemma Ln_inverse: "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> Ln(inverse z) = -(Ln z)"
  1300   apply (cases "z=0", auto)
  1301   apply (rule exp_complex_eqI)
  1302   using mpi_less_Im_Ln [of z] mpi_less_Im_Ln [of "inverse z"]
  1303   apply (auto simp: abs_if exp_minus split: if_split_asm)
  1304   apply (metis Im_Ln_less_pi Im_Ln_le_pi add.commute add_mono_thms_linordered_field(3) inverse_nonzero_iff_nonzero mult_2)
  1305   done
  1306 
  1307 lemma Ln_minus1 [simp]: "Ln(-1) = \<i> * pi"
  1308   apply (rule exp_complex_eqI)
  1309   using Im_Ln_le_pi [of "-1"] mpi_less_Im_Ln [of "-1"] cis_conv_exp cis_pi
  1310   apply (auto simp: abs_if)
  1311   done
  1312 
  1313 lemma Ln_ii [simp]: "Ln \<i> = \<i> * of_real pi/2"
  1314   using Ln_exp [of "\<i> * (of_real pi/2)"]
  1315   unfolding exp_Euler
  1316   by simp
  1317 
  1318 lemma Ln_minus_ii [simp]: "Ln(-\<i>) = - (\<i> * pi/2)"
  1319 proof -
  1320   have  "Ln(-\<i>) = Ln(inverse \<i>)"    by simp
  1321   also have "... = - (Ln \<i>)"         using Ln_inverse by blast
  1322   also have "... = - (\<i> * pi/2)"     by simp
  1323   finally show ?thesis .
  1324 qed
  1325 
  1326 lemma Ln_times:
  1327   assumes "w \<noteq> 0" "z \<noteq> 0"
  1328     shows "Ln(w * z) =
  1329                 (if Im(Ln w + Ln z) \<le> -pi then
  1330                   (Ln(w) + Ln(z)) + \<i> * of_real(2*pi)
  1331                 else if Im(Ln w + Ln z) > pi then
  1332                   (Ln(w) + Ln(z)) - \<i> * of_real(2*pi)
  1333                 else Ln(w) + Ln(z))"
  1334   using pi_ge_zero Im_Ln_le_pi [of w] Im_Ln_le_pi [of z]
  1335   using assms mpi_less_Im_Ln [of w] mpi_less_Im_Ln [of z]
  1336   by (auto simp: exp_add exp_diff sin_double cos_double exp_Euler intro!: Ln_unique)
  1337 
  1338 corollary Ln_times_simple:
  1339     "\<lbrakk>w \<noteq> 0; z \<noteq> 0; -pi < Im(Ln w) + Im(Ln z); Im(Ln w) + Im(Ln z) \<le> pi\<rbrakk>
  1340          \<Longrightarrow> Ln(w * z) = Ln(w) + Ln(z)"
  1341   by (simp add: Ln_times)
  1342 
  1343 corollary Ln_times_of_real:
  1344     "\<lbrakk>r > 0; z \<noteq> 0\<rbrakk> \<Longrightarrow> Ln(of_real r * z) = ln r + Ln(z)"
  1345   using mpi_less_Im_Ln Im_Ln_le_pi
  1346   by (force simp: Ln_times)
  1347 
  1348 corollary Ln_divide_of_real:
  1349     "\<lbrakk>r > 0; z \<noteq> 0\<rbrakk> \<Longrightarrow> Ln(z / of_real r) = Ln(z) - ln r"
  1350 using Ln_times_of_real [of "inverse r" z]
  1351 by (simp add: ln_inverse Ln_of_real mult.commute divide_inverse of_real_inverse [symmetric]
  1352          del: of_real_inverse)
  1353 
  1354 lemma Ln_minus:
  1355   assumes "z \<noteq> 0"
  1356     shows "Ln(-z) = (if Im(z) \<le> 0 \<and> ~(Re(z) < 0 \<and> Im(z) = 0)
  1357                      then Ln(z) + \<i> * pi
  1358                      else Ln(z) - \<i> * pi)" (is "_ = ?rhs")
  1359   using Im_Ln_le_pi [of z] mpi_less_Im_Ln [of z] assms
  1360         Im_Ln_eq_pi [of z] Im_Ln_pos_lt [of z]
  1361     by (fastforce simp: exp_add exp_diff exp_Euler intro!: Ln_unique)
  1362 
  1363 lemma Ln_inverse_if:
  1364   assumes "z \<noteq> 0"
  1365     shows "Ln (inverse z) = (if z \<in> \<real>\<^sub>\<le>\<^sub>0 then -(Ln z) + \<i> * 2 * complex_of_real pi else -(Ln z))"
  1366 proof (cases "z \<in> \<real>\<^sub>\<le>\<^sub>0")
  1367   case False then show ?thesis
  1368     by (simp add: Ln_inverse)
  1369 next
  1370   case True
  1371   then have z: "Im z = 0" "Re z < 0"
  1372     using assms
  1373     apply (auto simp: complex_nonpos_Reals_iff)
  1374     by (metis complex_is_Real_iff le_imp_less_or_eq of_real_0 of_real_Re)
  1375   have "Ln(inverse z) = Ln(- (inverse (-z)))"
  1376     by simp
  1377   also have "... = Ln (inverse (-z)) + \<i> * complex_of_real pi"
  1378     using assms z
  1379     apply (simp add: Ln_minus)
  1380     apply (simp add: field_simps)
  1381     done
  1382   also have "... = - Ln (- z) + \<i> * complex_of_real pi"
  1383     apply (subst Ln_inverse)
  1384     using z by (auto simp add: complex_nonneg_Reals_iff)
  1385   also have "... = - (Ln z) + \<i> * 2 * complex_of_real pi"
  1386     apply (subst Ln_minus [OF assms])
  1387     using assms z
  1388     apply simp
  1389     done
  1390   finally show ?thesis by (simp add: True)
  1391 qed
  1392 
  1393 lemma Ln_times_ii:
  1394   assumes "z \<noteq> 0"
  1395     shows  "Ln(\<i> * z) = (if 0 \<le> Re(z) | Im(z) < 0
  1396                           then Ln(z) + \<i> * of_real pi/2
  1397                           else Ln(z) - \<i> * of_real(3 * pi/2))"
  1398   using Im_Ln_le_pi [of z] mpi_less_Im_Ln [of z] assms
  1399         Im_Ln_eq_pi [of z] Im_Ln_pos_lt [of z] Re_Ln_pos_le [of z]
  1400   by (simp add: Ln_times) auto
  1401 
  1402 lemma Ln_of_nat: "0 < n \<Longrightarrow> Ln (of_nat n) = of_real (ln (of_nat n))"
  1403   by (subst of_real_of_nat_eq[symmetric], subst Ln_of_real[symmetric]) simp_all
  1404 
  1405 lemma Ln_of_nat_over_of_nat:
  1406   assumes "m > 0" "n > 0"
  1407   shows   "Ln (of_nat m / of_nat n) = of_real (ln (of_nat m) - ln (of_nat n))"
  1408 proof -
  1409   have "of_nat m / of_nat n = (of_real (of_nat m / of_nat n) :: complex)" by simp
  1410   also from assms have "Ln ... = of_real (ln (of_nat m / of_nat n))"
  1411     by (simp add: Ln_of_real[symmetric])
  1412   also from assms have "... = of_real (ln (of_nat m) - ln (of_nat n))"
  1413     by (simp add: ln_div)
  1414   finally show ?thesis .
  1415 qed
  1416 
  1417 
  1418 subsection\<open>Relation between Ln and Arg, and hence continuity of Arg\<close>
  1419 
  1420 lemma Arg_Ln:
  1421   assumes "0 < Arg z" shows "Arg z = Im(Ln(-z)) + pi"
  1422 proof (cases "z = 0")
  1423   case True
  1424   with assms show ?thesis
  1425     by simp
  1426 next
  1427   case False
  1428   then have "z / of_real(norm z) = exp(\<i> * of_real(Arg z))"
  1429     using Arg [of z]
  1430     by (metis abs_norm_cancel nonzero_mult_div_cancel_left norm_of_real zero_less_norm_iff)
  1431   then have "- z / of_real(norm z) = exp (\<i> * (of_real (Arg z) - pi))"
  1432     using cis_conv_exp cis_pi
  1433     by (auto simp: exp_diff algebra_simps)
  1434   then have "ln (- z / of_real(norm z)) = ln (exp (\<i> * (of_real (Arg z) - pi)))"
  1435     by simp
  1436   also have "... = \<i> * (of_real(Arg z) - pi)"
  1437     using Arg [of z] assms pi_not_less_zero
  1438     by auto
  1439   finally have "Arg z =  Im (Ln (- z / of_real (cmod z))) + pi"
  1440     by simp
  1441   also have "... = Im (Ln (-z) - ln (cmod z)) + pi"
  1442     by (metis diff_0_right minus_diff_eq zero_less_norm_iff Ln_divide_of_real False)
  1443   also have "... = Im (Ln (-z)) + pi"
  1444     by simp
  1445   finally show ?thesis .
  1446 qed
  1447 
  1448 lemma continuous_at_Arg:
  1449   assumes "z \<notin> \<real>\<^sub>\<ge>\<^sub>0"
  1450     shows "continuous (at z) Arg"
  1451 proof -
  1452   have *: "isCont (\<lambda>z. Im (Ln (- z)) + pi) z"
  1453     by (rule Complex.isCont_Im isCont_Ln' continuous_intros | simp add: assms complex_is_Real_iff)+
  1454   have [simp]: "\<And>x. \<lbrakk>Im x \<noteq> 0\<rbrakk> \<Longrightarrow> Im (Ln (- x)) + pi = Arg x"
  1455       using Arg_Ln Arg_gt_0 complex_is_Real_iff by auto
  1456   consider "Re z < 0" | "Im z \<noteq> 0" using assms
  1457     using complex_nonneg_Reals_iff not_le by blast
  1458   then have [simp]: "(\<lambda>z. Im (Ln (- z)) + pi) \<midarrow>z\<rightarrow> Arg z"
  1459       using "*"  by (simp add: isCont_def) (metis Arg_Ln Arg_gt_0 complex_is_Real_iff)
  1460   show ?thesis
  1461       apply (simp add: continuous_at)
  1462       apply (rule Lim_transform_within_open [where s= "-\<real>\<^sub>\<ge>\<^sub>0" and f = "\<lambda>z. Im(Ln(-z)) + pi"])
  1463       apply (auto simp add: not_le Arg_Ln [OF Arg_gt_0] complex_nonneg_Reals_iff closed_def [symmetric])
  1464       using assms apply (force simp add: complex_nonneg_Reals_iff)
  1465       done
  1466 qed
  1467 
  1468 lemma Ln_series:
  1469   fixes z :: complex
  1470   assumes "norm z < 1"
  1471   shows   "(\<lambda>n. (-1)^Suc n / of_nat n * z^n) sums ln (1 + z)" (is "(\<lambda>n. ?f n * z^n) sums _")
  1472 proof -
  1473   let ?F = "\<lambda>z. \<Sum>n. ?f n * z^n" and ?F' = "\<lambda>z. \<Sum>n. diffs ?f n * z^n"
  1474   have r: "conv_radius ?f = 1"
  1475     by (intro conv_radius_ratio_limit_nonzero[of _ 1])
  1476        (simp_all add: norm_divide LIMSEQ_Suc_n_over_n del: of_nat_Suc)
  1477 
  1478   have "\<exists>c. \<forall>z\<in>ball 0 1. ln (1 + z) - ?F z = c"
  1479   proof (rule has_field_derivative_zero_constant)
  1480     fix z :: complex assume z': "z \<in> ball 0 1"
  1481     hence z: "norm z < 1" by (simp add: dist_0_norm)
  1482     define t :: complex where "t = of_real (1 + norm z) / 2"
  1483     from z have t: "norm z < norm t" "norm t < 1" unfolding t_def
  1484       by (simp_all add: field_simps norm_divide del: of_real_add)
  1485 
  1486     have "Re (-z) \<le> norm (-z)" by (rule complex_Re_le_cmod)
  1487     also from z have "... < 1" by simp
  1488     finally have "((\<lambda>z. ln (1 + z)) has_field_derivative inverse (1+z)) (at z)"
  1489       by (auto intro!: derivative_eq_intros simp: complex_nonpos_Reals_iff)
  1490     moreover have "(?F has_field_derivative ?F' z) (at z)" using t r
  1491       by (intro termdiffs_strong[of _ t] summable_in_conv_radius) simp_all
  1492     ultimately have "((\<lambda>z. ln (1 + z) - ?F z) has_field_derivative (inverse (1 + z) - ?F' z))
  1493                        (at z within ball 0 1)"
  1494       by (intro derivative_intros) (simp_all add: at_within_open[OF z'])
  1495     also have "(\<lambda>n. of_nat n * ?f n * z ^ (n - Suc 0)) sums ?F' z" using t r
  1496       by (intro diffs_equiv termdiff_converges[OF t(1)] summable_in_conv_radius) simp_all
  1497     from sums_split_initial_segment[OF this, of 1]
  1498       have "(\<lambda>i. (-z) ^ i) sums ?F' z" by (simp add: power_minus[of z] del: of_nat_Suc)
  1499     hence "?F' z = inverse (1 + z)" using z by (simp add: sums_iff suminf_geometric divide_inverse)
  1500     also have "inverse (1 + z) - inverse (1 + z) = 0" by simp
  1501     finally show "((\<lambda>z. ln (1 + z) - ?F z) has_field_derivative 0) (at z within ball 0 1)" .
  1502   qed simp_all
  1503   then obtain c where c: "\<And>z. z \<in> ball 0 1 \<Longrightarrow> ln (1 + z) - ?F z = c" by blast
  1504   from c[of 0] have "c = 0" by (simp only: powser_zero) simp
  1505   with c[of z] assms have "ln (1 + z) = ?F z" by (simp add: dist_0_norm)
  1506   moreover have "summable (\<lambda>n. ?f n * z^n)" using assms r
  1507     by (intro summable_in_conv_radius) simp_all
  1508   ultimately show ?thesis by (simp add: sums_iff)
  1509 qed
  1510 
  1511 lemma Ln_series': "cmod z < 1 \<Longrightarrow> (\<lambda>n. - ((-z)^n) / of_nat n) sums ln (1 + z)"
  1512   by (drule Ln_series) (simp add: power_minus')
  1513 
  1514 lemma ln_series':
  1515   assumes "abs (x::real) < 1"
  1516   shows   "(\<lambda>n. - ((-x)^n) / of_nat n) sums ln (1 + x)"
  1517 proof -
  1518   from assms have "(\<lambda>n. - ((-of_real x)^n) / of_nat n) sums ln (1 + complex_of_real x)"
  1519     by (intro Ln_series') simp_all
  1520   also have "(\<lambda>n. - ((-of_real x)^n) / of_nat n) = (\<lambda>n. complex_of_real (- ((-x)^n) / of_nat n))"
  1521     by (rule ext) simp
  1522   also from assms have "ln (1 + complex_of_real x) = of_real (ln (1 + x))"
  1523     by (subst Ln_of_real [symmetric]) simp_all
  1524   finally show ?thesis by (subst (asm) sums_of_real_iff)
  1525 qed
  1526 
  1527 lemma Ln_approx_linear:
  1528   fixes z :: complex
  1529   assumes "norm z < 1"
  1530   shows   "norm (ln (1 + z) - z) \<le> norm z^2 / (1 - norm z)"
  1531 proof -
  1532   let ?f = "\<lambda>n. (-1)^Suc n / of_nat n"
  1533   from assms have "(\<lambda>n. ?f n * z^n) sums ln (1 + z)" using Ln_series by simp
  1534   moreover have "(\<lambda>n. (if n = 1 then 1 else 0) * z^n) sums z" using powser_sums_if[of 1] by simp
  1535   ultimately have "(\<lambda>n. (?f n - (if n = 1 then 1 else 0)) * z^n) sums (ln (1 + z) - z)"
  1536     by (subst left_diff_distrib, intro sums_diff) simp_all
  1537   from sums_split_initial_segment[OF this, of "Suc 1"]
  1538     have "(\<lambda>i. (-(z^2)) * inverse (2 + of_nat i) * (- z)^i) sums (Ln (1 + z) - z)"
  1539     by (simp add: power2_eq_square mult_ac power_minus[of z] divide_inverse)
  1540   hence "(Ln (1 + z) - z) = (\<Sum>i. (-(z^2)) * inverse (of_nat (i+2)) * (-z)^i)"
  1541     by (simp add: sums_iff)
  1542   also have A: "summable (\<lambda>n. norm z^2 * (inverse (real_of_nat (Suc (Suc n))) * cmod z ^ n))"
  1543     by (rule summable_mult, rule summable_comparison_test_ev[OF _ summable_geometric[of "norm z"]])
  1544        (auto simp: assms field_simps intro!: always_eventually)
  1545   hence "norm (\<Sum>i. (-(z^2)) * inverse (of_nat (i+2)) * (-z)^i) \<le>
  1546              (\<Sum>i. norm (-(z^2) * inverse (of_nat (i+2)) * (-z)^i))"
  1547     by (intro summable_norm)
  1548        (auto simp: norm_power norm_inverse norm_mult mult_ac simp del: of_nat_add of_nat_Suc)
  1549   also have "norm ((-z)^2 * (-z)^i) * inverse (of_nat (i+2)) \<le> norm ((-z)^2 * (-z)^i) * 1" for i
  1550     by (intro mult_left_mono) (simp_all add: divide_simps)
  1551   hence "(\<Sum>i. norm (-(z^2) * inverse (of_nat (i+2)) * (-z)^i)) \<le>
  1552            (\<Sum>i. norm (-(z^2) * (-z)^i))" using A assms
  1553     apply (simp_all only: norm_power norm_inverse norm_divide norm_mult)
  1554     apply (intro suminf_le summable_mult summable_geometric)
  1555     apply (auto simp: norm_power field_simps simp del: of_nat_add of_nat_Suc)
  1556     done
  1557   also have "... = norm z^2 * (\<Sum>i. norm z^i)" using assms
  1558     by (subst suminf_mult [symmetric]) (auto intro!: summable_geometric simp: norm_mult norm_power)
  1559   also have "(\<Sum>i. norm z^i) = inverse (1 - norm z)" using assms
  1560     by (subst suminf_geometric) (simp_all add: divide_inverse)
  1561   also have "norm z^2 * ... = norm z^2 / (1 - norm z)" by (simp add: divide_inverse)
  1562   finally show ?thesis .
  1563 qed
  1564 
  1565 
  1566 text\<open>Relation between Arg and arctangent in upper halfplane\<close>
  1567 lemma Arg_arctan_upperhalf:
  1568   assumes "0 < Im z"
  1569     shows "Arg z = pi/2 - arctan(Re z / Im z)"
  1570 proof (cases "z = 0")
  1571   case True with assms show ?thesis
  1572     by simp
  1573 next
  1574   case False
  1575   show ?thesis
  1576     apply (rule Arg_unique [of "norm z"])
  1577     using False assms arctan [of "Re z / Im z"] pi_ge_two pi_half_less_two
  1578     apply (auto simp: exp_Euler cos_diff sin_diff)
  1579     using norm_complex_def [of z, symmetric]
  1580     apply (simp add: sin_of_real cos_of_real sin_arctan cos_arctan field_simps real_sqrt_divide)
  1581     apply (metis complex_eq mult.assoc ring_class.ring_distribs(2))
  1582     done
  1583 qed
  1584 
  1585 lemma Arg_eq_Im_Ln:
  1586   assumes "0 \<le> Im z" "0 < Re z"
  1587     shows "Arg z = Im (Ln z)"
  1588 proof (cases "z = 0 \<or> Im z = 0")
  1589   case True then show ?thesis
  1590     using assms Arg_eq_0 complex_is_Real_iff
  1591     apply auto
  1592     by (metis Arg_eq_0_pi Arg_eq_pi Im_Ln_eq_0 Im_Ln_eq_pi less_numeral_extra(3) zero_complex.simps(1))
  1593 next
  1594   case False
  1595   then have "Arg z > 0"
  1596     using Arg_gt_0 complex_is_Real_iff by blast
  1597   then show ?thesis
  1598     using assms False
  1599     by (subst Arg_Ln) (auto simp: Ln_minus)
  1600 qed
  1601 
  1602 lemma continuous_within_upperhalf_Arg:
  1603   assumes "z \<noteq> 0"
  1604     shows "continuous (at z within {z. 0 \<le> Im z}) Arg"
  1605 proof (cases "z \<in> \<real>\<^sub>\<ge>\<^sub>0")
  1606   case False then show ?thesis
  1607     using continuous_at_Arg continuous_at_imp_continuous_within by auto
  1608 next
  1609   case True
  1610   then have z: "z \<in> \<real>" "0 < Re z"
  1611     using assms  by (auto simp: complex_nonneg_Reals_iff complex_is_Real_iff complex_neq_0)
  1612   then have [simp]: "Arg z = 0" "Im (Ln z) = 0"
  1613     by (auto simp: Arg_eq_0 Im_Ln_eq_0 assms complex_is_Real_iff)
  1614   show ?thesis
  1615   proof (clarsimp simp add: continuous_within Lim_within dist_norm)
  1616     fix e::real
  1617     assume "0 < e"
  1618     moreover have "continuous (at z) (\<lambda>x. Im (Ln x))"
  1619       using z by (simp add: continuous_at_Ln complex_nonpos_Reals_iff)
  1620     ultimately
  1621     obtain d where d: "d>0" "\<And>x. x \<noteq> z \<Longrightarrow> cmod (x - z) < d \<Longrightarrow> \<bar>Im (Ln x)\<bar> < e"
  1622       by (auto simp: continuous_within Lim_within dist_norm)
  1623     { fix x
  1624       assume "cmod (x - z) < Re z / 2"
  1625       then have "\<bar>Re x - Re z\<bar> < Re z / 2"
  1626         by (metis le_less_trans abs_Re_le_cmod minus_complex.simps(1))
  1627       then have "0 < Re x"
  1628         using z by linarith
  1629     }
  1630     then show "\<exists>d>0. \<forall>x. 0 \<le> Im x \<longrightarrow> x \<noteq> z \<and> cmod (x - z) < d \<longrightarrow> \<bar>Arg x\<bar> < e"
  1631       apply (rule_tac x="min d (Re z / 2)" in exI)
  1632       using z d
  1633       apply (auto simp: Arg_eq_Im_Ln)
  1634       done
  1635   qed
  1636 qed
  1637 
  1638 lemma continuous_on_upperhalf_Arg: "continuous_on ({z. 0 \<le> Im z} - {0}) Arg"
  1639   apply (auto simp: continuous_on_eq_continuous_within)
  1640   by (metis Diff_subset continuous_within_subset continuous_within_upperhalf_Arg)
  1641 
  1642 lemma open_Arg_less_Int:
  1643   assumes "0 \<le> s" "t \<le> 2*pi"
  1644     shows "open ({y. s < Arg y} \<inter> {y. Arg y < t})"
  1645 proof -
  1646   have 1: "continuous_on (UNIV - \<real>\<^sub>\<ge>\<^sub>0) Arg"
  1647     using continuous_at_Arg continuous_at_imp_continuous_within
  1648     by (auto simp: continuous_on_eq_continuous_within)
  1649   have 2: "open (UNIV - \<real>\<^sub>\<ge>\<^sub>0 :: complex set)"  by (simp add: open_Diff)
  1650   have "open ({z. s < z} \<inter> {z. z < t})"
  1651     using open_lessThan [of t] open_greaterThan [of s]
  1652     by (metis greaterThan_def lessThan_def open_Int)
  1653   moreover have "{y. s < Arg y} \<inter> {y. Arg y < t} \<subseteq> - \<real>\<^sub>\<ge>\<^sub>0"
  1654     using assms by (auto simp: Arg_real complex_nonneg_Reals_iff complex_is_Real_iff)
  1655   ultimately show ?thesis
  1656     using continuous_imp_open_vimage [OF 1 2, of  "{z. Re z > s} \<inter> {z. Re z < t}"]
  1657     by auto
  1658 qed
  1659 
  1660 lemma open_Arg_gt: "open {z. t < Arg z}"
  1661 proof (cases "t < 0")
  1662   case True then have "{z. t < Arg z} = UNIV"
  1663     using Arg_ge_0 less_le_trans by auto
  1664   then show ?thesis
  1665     by simp
  1666 next
  1667   case False then show ?thesis
  1668     using open_Arg_less_Int [of t "2*pi"] Arg_lt_2pi
  1669     by auto
  1670 qed
  1671 
  1672 lemma closed_Arg_le: "closed {z. Arg z \<le> t}"
  1673   using open_Arg_gt [of t]
  1674   by (simp add: closed_def Set.Collect_neg_eq [symmetric] not_le)
  1675 
  1676 subsection\<open>Complex Powers\<close>
  1677 
  1678 lemma powr_to_1 [simp]: "z powr 1 = (z::complex)"
  1679   by (simp add: powr_def)
  1680 
  1681 lemma powr_nat:
  1682   fixes n::nat and z::complex shows "z powr n = (if z = 0 then 0 else z^n)"
  1683   by (simp add: exp_of_nat_mult powr_def)
  1684 
  1685 lemma norm_powr_real: "w \<in> \<real> \<Longrightarrow> 0 < Re w \<Longrightarrow> norm(w powr z) = exp(Re z * ln(Re w))"
  1686   apply (simp add: powr_def)
  1687   using Im_Ln_eq_0 complex_is_Real_iff norm_complex_def
  1688   by auto
  1689 
  1690 lemma powr_complexpow [simp]:
  1691   fixes x::complex shows "x \<noteq> 0 \<Longrightarrow> x powr (of_nat n) = x^n"
  1692   by (induct n) (auto simp: ac_simps powr_add)
  1693 
  1694 lemma powr_complexnumeral [simp]:
  1695   fixes x::complex shows "x \<noteq> 0 \<Longrightarrow> x powr (numeral n) = x ^ (numeral n)"
  1696   by (metis of_nat_numeral powr_complexpow)
  1697 
  1698 lemma cnj_powr:
  1699   assumes "Im a = 0 \<Longrightarrow> Re a \<ge> 0"
  1700   shows   "cnj (a powr b) = cnj a powr cnj b"
  1701 proof (cases "a = 0")
  1702   case False
  1703   with assms have "a \<notin> \<real>\<^sub>\<le>\<^sub>0" by (auto simp: complex_eq_iff complex_nonpos_Reals_iff)
  1704   with False show ?thesis by (simp add: powr_def exp_cnj cnj_Ln)
  1705 qed simp
  1706 
  1707 lemma powr_real_real:
  1708     "\<lbrakk>w \<in> \<real>; z \<in> \<real>; 0 < Re w\<rbrakk> \<Longrightarrow> w powr z = exp(Re z * ln(Re w))"
  1709   apply (simp add: powr_def)
  1710   by (metis complex_eq complex_is_Real_iff diff_0 diff_0_right diff_minus_eq_add exp_ln exp_not_eq_zero
  1711        exp_of_real Ln_of_real mult_zero_right of_real_0 of_real_mult)
  1712 
  1713 lemma powr_of_real:
  1714   fixes x::real and y::real
  1715   shows "0 \<le> x \<Longrightarrow> of_real x powr (of_real y::complex) = of_real (x powr y)"
  1716   by (simp_all add: powr_def exp_eq_polar)
  1717 
  1718 lemma norm_powr_real_mono:
  1719     "\<lbrakk>w \<in> \<real>; 1 < Re w\<rbrakk>
  1720      \<Longrightarrow> cmod(w powr z1) \<le> cmod(w powr z2) \<longleftrightarrow> Re z1 \<le> Re z2"
  1721   by (auto simp: powr_def algebra_simps Reals_def Ln_of_real)
  1722 
  1723 lemma powr_times_real:
  1724     "\<lbrakk>x \<in> \<real>; y \<in> \<real>; 0 \<le> Re x; 0 \<le> Re y\<rbrakk>
  1725            \<Longrightarrow> (x * y) powr z = x powr z * y powr z"
  1726   by (auto simp: Reals_def powr_def Ln_times exp_add algebra_simps less_eq_real_def Ln_of_real)
  1727 
  1728 lemma powr_neg_real_complex:
  1729   shows   "(- of_real x) powr a = (-1) powr (of_real (sgn x) * a) * of_real x powr (a :: complex)"
  1730 proof (cases "x = 0")
  1731   assume x: "x \<noteq> 0"
  1732   hence "(-x) powr a = exp (a * ln (-of_real x))" by (simp add: powr_def)
  1733   also from x have "ln (-of_real x) = Ln (of_real x) + of_real (sgn x) * pi * \<i>"
  1734     by (simp add: Ln_minus Ln_of_real)
  1735   also from x have "exp (a * ...) = cis pi powr (of_real (sgn x) * a) * of_real x powr a"
  1736     by (simp add: powr_def exp_add algebra_simps Ln_of_real cis_conv_exp)
  1737   also note cis_pi
  1738   finally show ?thesis by simp
  1739 qed simp_all
  1740 
  1741 lemma has_field_derivative_powr:
  1742   fixes z :: complex
  1743   shows "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> ((\<lambda>z. z powr s) has_field_derivative (s * z powr (s - 1))) (at z)"
  1744   apply (cases "z=0", auto)
  1745   apply (simp add: powr_def)
  1746   apply (rule DERIV_transform_at [where d = "norm z" and f = "\<lambda>z. exp (s * Ln z)"])
  1747   apply (auto simp: dist_complex_def)
  1748   apply (intro derivative_eq_intros | simp)+
  1749   apply (simp add: field_simps exp_diff)
  1750   done
  1751 
  1752 declare has_field_derivative_powr[THEN DERIV_chain2, derivative_intros]
  1753 
  1754 
  1755 lemma has_field_derivative_powr_right [derivative_intros]:
  1756     "w \<noteq> 0 \<Longrightarrow> ((\<lambda>z. w powr z) has_field_derivative Ln w * w powr z) (at z)"
  1757   apply (simp add: powr_def)
  1758   apply (intro derivative_eq_intros | simp)+
  1759   done
  1760 
  1761 lemma field_differentiable_powr_right [derivative_intros]:
  1762   fixes w::complex
  1763   shows "w \<noteq> 0 \<Longrightarrow> (\<lambda>z. w powr z) field_differentiable (at z)"
  1764 using field_differentiable_def has_field_derivative_powr_right by blast
  1765 
  1766 lemma holomorphic_on_powr_right [holomorphic_intros]:
  1767     "f holomorphic_on s \<Longrightarrow> w \<noteq> 0 \<Longrightarrow> (\<lambda>z. w powr (f z)) holomorphic_on s"
  1768   unfolding holomorphic_on_def field_differentiable_def
  1769   by (metis (full_types) DERIV_chain' has_field_derivative_powr_right)
  1770 
  1771 lemma norm_powr_real_powr:
  1772   "w \<in> \<real> \<Longrightarrow> 0 \<le> Re w \<Longrightarrow> cmod (w powr z) = Re w powr Re z"
  1773   by (cases "w = 0") (auto simp add: norm_powr_real powr_def Im_Ln_eq_0
  1774                                      complex_is_Real_iff in_Reals_norm complex_eq_iff)
  1775 
  1776 lemma tendsto_ln_complex [tendsto_intros]:
  1777   assumes "(f \<longlongrightarrow> a) F" "a \<notin> \<real>\<^sub>\<le>\<^sub>0"
  1778   shows   "((\<lambda>z. ln (f z :: complex)) \<longlongrightarrow> ln a) F"
  1779   using tendsto_compose[OF continuous_at_Ln[of a, unfolded isCont_def] assms(1)] assms(2) by simp
  1780 
  1781 lemma tendsto_powr_complex:
  1782   fixes f g :: "_ \<Rightarrow> complex"
  1783   assumes a: "a \<notin> \<real>\<^sub>\<le>\<^sub>0"
  1784   assumes f: "(f \<longlongrightarrow> a) F" and g: "(g \<longlongrightarrow> b) F"
  1785   shows   "((\<lambda>z. f z powr g z) \<longlongrightarrow> a powr b) F"
  1786 proof -
  1787   from a have [simp]: "a \<noteq> 0" by auto
  1788   from f g a have "((\<lambda>z. exp (g z * ln (f z))) \<longlongrightarrow> a powr b) F" (is ?P)
  1789     by (auto intro!: tendsto_intros simp: powr_def)
  1790   also {
  1791     have "eventually (\<lambda>z. z \<noteq> 0) (nhds a)"
  1792       by (intro t1_space_nhds) simp_all
  1793     with f have "eventually (\<lambda>z. f z \<noteq> 0) F" using filterlim_iff by blast
  1794   }
  1795   hence "?P \<longleftrightarrow> ((\<lambda>z. f z powr g z) \<longlongrightarrow> a powr b) F"
  1796     by (intro tendsto_cong refl) (simp_all add: powr_def mult_ac)
  1797   finally show ?thesis .
  1798 qed
  1799 
  1800 lemma tendsto_powr_complex_0:
  1801   fixes f g :: "'a \<Rightarrow> complex"
  1802   assumes f: "(f \<longlongrightarrow> 0) F" and g: "(g \<longlongrightarrow> b) F" and b: "Re b > 0"
  1803   shows   "((\<lambda>z. f z powr g z) \<longlongrightarrow> 0) F"
  1804 proof (rule tendsto_norm_zero_cancel)
  1805   define h where
  1806     "h = (\<lambda>z. if f z = 0 then 0 else exp (Re (g z) * ln (cmod (f z)) + abs (Im (g z)) * pi))"
  1807   {
  1808     fix z :: 'a assume z: "f z \<noteq> 0"
  1809     define c where "c = abs (Im (g z)) * pi"
  1810     from mpi_less_Im_Ln[OF z] Im_Ln_le_pi[OF z]
  1811       have "abs (Im (Ln (f z))) \<le> pi" by simp
  1812     from mult_left_mono[OF this, of "abs (Im (g z))"]
  1813       have "abs (Im (g z) * Im (ln (f z))) \<le> c" by (simp add: abs_mult c_def)
  1814     hence "-Im (g z) * Im (ln (f z)) \<le> c" by simp
  1815     hence "norm (f z powr g z) \<le> h z" by (simp add: powr_def field_simps h_def c_def)
  1816   }
  1817   hence le: "norm (f z powr g z) \<le> h z" for z by (cases "f x = 0") (simp_all add: h_def)
  1818 
  1819   have g': "(g \<longlongrightarrow> b) (inf F (principal {z. f z \<noteq> 0}))"
  1820     by (rule tendsto_mono[OF _ g]) simp_all
  1821   have "((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) (inf F (principal {z. f z \<noteq> 0}))"
  1822     by (subst tendsto_norm_zero_iff, rule tendsto_mono[OF _ f]) simp_all
  1823   moreover {
  1824     have "filterlim (\<lambda>x. norm (f x)) (principal {0<..}) (principal {z. f z \<noteq> 0})"
  1825       by (auto simp: filterlim_def)
  1826     hence "filterlim (\<lambda>x. norm (f x)) (principal {0<..})
  1827              (inf F (principal {z. f z \<noteq> 0}))"
  1828       by (rule filterlim_mono) simp_all
  1829   }
  1830   ultimately have norm: "filterlim (\<lambda>x. norm (f x)) (at_right 0) (inf F (principal {z. f z \<noteq> 0}))"
  1831     by (simp add: filterlim_inf at_within_def)
  1832 
  1833   have A: "LIM x inf F (principal {z. f z \<noteq> 0}). Re (g x) * -ln (cmod (f x)) :> at_top"
  1834     by (rule filterlim_tendsto_pos_mult_at_top tendsto_intros g' b
  1835           filterlim_compose[OF filterlim_uminus_at_top_at_bot] filterlim_compose[OF ln_at_0] norm)+
  1836   have B: "LIM x inf F (principal {z. f z \<noteq> 0}).
  1837           -\<bar>Im (g x)\<bar> * pi + -(Re (g x) * ln (cmod (f x))) :> at_top"
  1838     by (rule filterlim_tendsto_add_at_top tendsto_intros g')+ (insert A, simp_all)
  1839   have C: "(h \<longlongrightarrow> 0) F" unfolding h_def
  1840     by (intro filterlim_If tendsto_const filterlim_compose[OF exp_at_bot])
  1841        (insert B, auto simp: filterlim_uminus_at_bot algebra_simps)
  1842   show "((\<lambda>x. norm (f x powr g x)) \<longlongrightarrow> 0) F"
  1843     by (rule Lim_null_comparison[OF always_eventually C]) (insert le, auto)
  1844 qed
  1845 
  1846 lemma tendsto_powr_complex' [tendsto_intros]:
  1847   fixes f g :: "_ \<Rightarrow> complex"
  1848   assumes fz: "a \<notin> \<real>\<^sub>\<le>\<^sub>0 \<or> (a = 0 \<and> Re b > 0)"
  1849   assumes fg: "(f \<longlongrightarrow> a) F" "(g \<longlongrightarrow> b) F"
  1850   shows   "((\<lambda>z. f z powr g z) \<longlongrightarrow> a powr b) F"
  1851 proof (cases "a = 0")
  1852   case True
  1853   with assms show ?thesis by (auto intro!: tendsto_powr_complex_0)
  1854 next
  1855   case False
  1856   with assms show ?thesis by (auto intro!: tendsto_powr_complex elim!: nonpos_Reals_cases)
  1857 qed
  1858 
  1859 lemma continuous_powr_complex:
  1860   assumes "f (netlimit F) \<notin> \<real>\<^sub>\<le>\<^sub>0" "continuous F f" "continuous F g"
  1861   shows   "continuous F (\<lambda>z. f z powr g z :: complex)"
  1862   using assms unfolding continuous_def by (intro tendsto_powr_complex) simp_all
  1863 
  1864 lemma isCont_powr_complex [continuous_intros]:
  1865   assumes "f z \<notin> \<real>\<^sub>\<le>\<^sub>0" "isCont f z" "isCont g z"
  1866   shows   "isCont (\<lambda>z. f z powr g z :: complex) z"
  1867   using assms unfolding isCont_def by (intro tendsto_powr_complex) simp_all
  1868 
  1869 lemma continuous_on_powr_complex [continuous_intros]:
  1870   assumes "A \<subseteq> {z. Re (f z) \<ge> 0 \<or> Im (f z) \<noteq> 0}"
  1871   assumes "\<And>z. z \<in> A \<Longrightarrow> f z = 0 \<Longrightarrow> Re (g z) > 0"
  1872   assumes "continuous_on A f" "continuous_on A g"
  1873   shows   "continuous_on A (\<lambda>z. f z powr g z)"
  1874   unfolding continuous_on_def
  1875 proof
  1876   fix z assume z: "z \<in> A"
  1877   show "((\<lambda>z. f z powr g z) \<longlongrightarrow> f z powr g z) (at z within A)"
  1878   proof (cases "f z = 0")
  1879     case False
  1880     from assms(1,2) z have "Re (f z) \<ge> 0 \<or> Im (f z) \<noteq> 0" "f z = 0 \<longrightarrow> Re (g z) > 0" by auto
  1881     with assms(3,4) z show ?thesis
  1882       by (intro tendsto_powr_complex')
  1883          (auto elim!: nonpos_Reals_cases simp: complex_eq_iff continuous_on_def)
  1884   next
  1885     case True
  1886     with assms z show ?thesis
  1887       by (auto intro!: tendsto_powr_complex_0 simp: continuous_on_def)
  1888   qed
  1889 qed
  1890 
  1891 
  1892 subsection\<open>Some Limits involving Logarithms\<close>
  1893 
  1894 lemma lim_Ln_over_power:
  1895   fixes s::complex
  1896   assumes "0 < Re s"
  1897     shows "((\<lambda>n. Ln n / (n powr s)) \<longlongrightarrow> 0) sequentially"
  1898 proof (simp add: lim_sequentially dist_norm, clarify)
  1899   fix e::real
  1900   assume e: "0 < e"
  1901   have "\<exists>xo>0. \<forall>x\<ge>xo. 0 < e * 2 + (e * Re s * 2 - 2) * x + e * (Re s)\<^sup>2 * x\<^sup>2"
  1902   proof (rule_tac x="2/(e * (Re s)\<^sup>2)" in exI, safe)
  1903     show "0 < 2 / (e * (Re s)\<^sup>2)"
  1904       using e assms by (simp add: field_simps)
  1905   next
  1906     fix x::real
  1907     assume x: "2 / (e * (Re s)\<^sup>2) \<le> x"
  1908     then have "x>0"
  1909     using e assms
  1910       by (metis less_le_trans mult_eq_0_iff mult_pos_pos pos_less_divide_eq power2_eq_square
  1911                 zero_less_numeral)
  1912     then show "0 < e * 2 + (e * Re s * 2 - 2) * x + e * (Re s)\<^sup>2 * x\<^sup>2"
  1913       using e assms x
  1914       apply (auto simp: field_simps)
  1915       apply (rule_tac y = "e * (x\<^sup>2 * (Re s)\<^sup>2)" in le_less_trans)
  1916       apply (auto simp: power2_eq_square field_simps add_pos_pos)
  1917       done
  1918   qed
  1919   then have "\<exists>xo>0. \<forall>x\<ge>xo. x / e < 1 + (Re s * x) + (1/2) * (Re s * x)^2"
  1920     using e  by (simp add: field_simps)
  1921   then have "\<exists>xo>0. \<forall>x\<ge>xo. x / e < exp (Re s * x)"
  1922     using assms
  1923     by (force intro: less_le_trans [OF _ exp_lower_taylor_quadratic])
  1924   then have "\<exists>xo>0. \<forall>x\<ge>xo. x < e * exp (Re s * x)"
  1925     using e   by (auto simp: field_simps)
  1926   with e show "\<exists>no. \<forall>n\<ge>no. norm (Ln (of_nat n) / of_nat n powr s) < e"
  1927     apply (auto simp: norm_divide norm_powr_real divide_simps)
  1928     apply (rule_tac x="nat \<lceil>exp xo\<rceil>" in exI)
  1929     apply clarify
  1930     apply (drule_tac x="ln n" in spec)
  1931     apply (auto simp: exp_less_mono nat_ceiling_le_eq not_le)
  1932     apply (metis exp_less_mono exp_ln not_le of_nat_0_less_iff)
  1933     done
  1934 qed
  1935 
  1936 lemma lim_Ln_over_n: "((\<lambda>n. Ln(of_nat n) / of_nat n) \<longlongrightarrow> 0) sequentially"
  1937   using lim_Ln_over_power [of 1]
  1938   by simp
  1939 
  1940 lemma Ln_Reals_eq: "x \<in> \<real> \<Longrightarrow> Re x > 0 \<Longrightarrow> Ln x = of_real (ln (Re x))"
  1941   using Ln_of_real by force
  1942 
  1943 lemma powr_Reals_eq: "x \<in> \<real> \<Longrightarrow> Re x > 0 \<Longrightarrow> x powr complex_of_real y = of_real (x powr y)"
  1944   by (simp add: powr_of_real)
  1945 
  1946 lemma lim_ln_over_power:
  1947   fixes s :: real
  1948   assumes "0 < s"
  1949     shows "((\<lambda>n. ln n / (n powr s)) \<longlongrightarrow> 0) sequentially"
  1950   using lim_Ln_over_power [of "of_real s", THEN filterlim_sequentially_Suc [THEN iffD2]] assms
  1951   apply (subst filterlim_sequentially_Suc [symmetric])
  1952   apply (simp add: lim_sequentially dist_norm
  1953           Ln_Reals_eq norm_powr_real_powr norm_divide)
  1954   done
  1955 
  1956 lemma lim_ln_over_n: "((\<lambda>n. ln(real_of_nat n) / of_nat n) \<longlongrightarrow> 0) sequentially"
  1957   using lim_ln_over_power [of 1, THEN filterlim_sequentially_Suc [THEN iffD2]]
  1958   apply (subst filterlim_sequentially_Suc [symmetric])
  1959   apply (simp add: lim_sequentially dist_norm)
  1960   done
  1961 
  1962 lemma lim_1_over_complex_power:
  1963   assumes "0 < Re s"
  1964     shows "((\<lambda>n. 1 / (of_nat n powr s)) \<longlongrightarrow> 0) sequentially"
  1965 proof -
  1966   have "\<forall>n>0. 3 \<le> n \<longrightarrow> 1 \<le> ln (real_of_nat n)"
  1967     using ln3_gt_1
  1968     by (force intro: order_trans [of _ "ln 3"] ln3_gt_1)
  1969   moreover have "(\<lambda>n. cmod (Ln (of_nat n) / of_nat n powr s)) \<longlonglongrightarrow> 0"
  1970     using lim_Ln_over_power [OF assms]
  1971     by (metis tendsto_norm_zero_iff)
  1972   ultimately show ?thesis
  1973     apply (auto intro!: Lim_null_comparison [where g = "\<lambda>n. norm (Ln(of_nat n) / of_nat n powr s)"])
  1974     apply (auto simp: norm_divide divide_simps eventually_sequentially)
  1975     done
  1976 qed
  1977 
  1978 lemma lim_1_over_real_power:
  1979   fixes s :: real
  1980   assumes "0 < s"
  1981     shows "((\<lambda>n. 1 / (of_nat n powr s)) \<longlongrightarrow> 0) sequentially"
  1982   using lim_1_over_complex_power [of "of_real s", THEN filterlim_sequentially_Suc [THEN iffD2]] assms
  1983   apply (subst filterlim_sequentially_Suc [symmetric])
  1984   apply (simp add: lim_sequentially dist_norm)
  1985   apply (simp add: Ln_Reals_eq norm_powr_real_powr norm_divide)
  1986   done
  1987 
  1988 lemma lim_1_over_Ln: "((\<lambda>n. 1 / Ln(of_nat n)) \<longlongrightarrow> 0) sequentially"
  1989 proof (clarsimp simp add: lim_sequentially dist_norm norm_divide divide_simps)
  1990   fix r::real
  1991   assume "0 < r"
  1992   have ir: "inverse (exp (inverse r)) > 0"
  1993     by simp
  1994   obtain n where n: "1 < of_nat n * inverse (exp (inverse r))"
  1995     using ex_less_of_nat_mult [of _ 1, OF ir]
  1996     by auto
  1997   then have "exp (inverse r) < of_nat n"
  1998     by (simp add: divide_simps)
  1999   then have "ln (exp (inverse r)) < ln (of_nat n)"
  2000     by (metis exp_gt_zero less_trans ln_exp ln_less_cancel_iff)
  2001   with \<open>0 < r\<close> have "1 < r * ln (real_of_nat n)"
  2002     by (simp add: field_simps)
  2003   moreover have "n > 0" using n
  2004     using neq0_conv by fastforce
  2005   ultimately show "\<exists>no. \<forall>n. Ln (of_nat n) \<noteq> 0 \<longrightarrow> no \<le> n \<longrightarrow> 1 < r * cmod (Ln (of_nat n))"
  2006     using n \<open>0 < r\<close>
  2007     apply (rule_tac x=n in exI)
  2008     apply (auto simp: divide_simps)
  2009     apply (erule less_le_trans, auto)
  2010     done
  2011 qed
  2012 
  2013 lemma lim_1_over_ln: "((\<lambda>n. 1 / ln(real_of_nat n)) \<longlongrightarrow> 0) sequentially"
  2014   using lim_1_over_Ln [THEN filterlim_sequentially_Suc [THEN iffD2]]
  2015   apply (subst filterlim_sequentially_Suc [symmetric])
  2016   apply (simp add: lim_sequentially dist_norm)
  2017   apply (simp add: Ln_Reals_eq norm_powr_real_powr norm_divide)
  2018   done
  2019 
  2020 
  2021 subsection\<open>Relation between Square Root and exp/ln, hence its derivative\<close>
  2022 
  2023 lemma csqrt_exp_Ln:
  2024   assumes "z \<noteq> 0"
  2025     shows "csqrt z = exp(Ln(z) / 2)"
  2026 proof -
  2027   have "(exp (Ln z / 2))\<^sup>2 = (exp (Ln z))"
  2028     by (metis exp_double nonzero_mult_div_cancel_left times_divide_eq_right zero_neq_numeral)
  2029   also have "... = z"
  2030     using assms exp_Ln by blast
  2031   finally have "csqrt z = csqrt ((exp (Ln z / 2))\<^sup>2)"
  2032     by simp
  2033   also have "... = exp (Ln z / 2)"
  2034     apply (subst csqrt_square)
  2035     using cos_gt_zero_pi [of "(Im (Ln z) / 2)"] Im_Ln_le_pi mpi_less_Im_Ln assms
  2036     apply (auto simp: Re_exp Im_exp zero_less_mult_iff zero_le_mult_iff, fastforce+)
  2037     done
  2038   finally show ?thesis using assms csqrt_square
  2039     by simp
  2040 qed
  2041 
  2042 lemma csqrt_inverse:
  2043   assumes "z \<notin> \<real>\<^sub>\<le>\<^sub>0"
  2044     shows "csqrt (inverse z) = inverse (csqrt z)"
  2045 proof (cases "z=0", simp)
  2046   assume "z \<noteq> 0"
  2047   then show ?thesis
  2048     using assms csqrt_exp_Ln Ln_inverse exp_minus
  2049     by (simp add: csqrt_exp_Ln Ln_inverse exp_minus)
  2050 qed
  2051 
  2052 lemma cnj_csqrt:
  2053   assumes "z \<notin> \<real>\<^sub>\<le>\<^sub>0"
  2054     shows "cnj(csqrt z) = csqrt(cnj z)"
  2055 proof (cases "z=0", simp)
  2056   assume "z \<noteq> 0"
  2057   then show ?thesis
  2058      by (simp add: assms cnj_Ln csqrt_exp_Ln exp_cnj)
  2059 qed
  2060 
  2061 lemma has_field_derivative_csqrt:
  2062   assumes "z \<notin> \<real>\<^sub>\<le>\<^sub>0"
  2063     shows "(csqrt has_field_derivative inverse(2 * csqrt z)) (at z)"
  2064 proof -
  2065   have z: "z \<noteq> 0"
  2066     using assms by auto
  2067   then have *: "inverse z = inverse (2*z) * 2"
  2068     by (simp add: divide_simps)
  2069   have [simp]: "exp (Ln z / 2) * inverse z = inverse (csqrt z)"
  2070     by (simp add: z field_simps csqrt_exp_Ln [symmetric]) (metis power2_csqrt power2_eq_square)
  2071   have "Im z = 0 \<Longrightarrow> 0 < Re z"
  2072     using assms complex_nonpos_Reals_iff not_less by blast
  2073   with z have "((\<lambda>z. exp (Ln z / 2)) has_field_derivative inverse (2 * csqrt z)) (at z)"
  2074     by (force intro: derivative_eq_intros * simp add: assms)
  2075   then show ?thesis
  2076     apply (rule DERIV_transform_at[where d = "norm z"])
  2077     apply (intro z derivative_eq_intros | simp add: assms)+
  2078     using z
  2079     apply (metis csqrt_exp_Ln dist_0_norm less_irrefl)
  2080     done
  2081 qed
  2082 
  2083 lemma field_differentiable_at_csqrt:
  2084     "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> csqrt field_differentiable at z"
  2085   using field_differentiable_def has_field_derivative_csqrt by blast
  2086 
  2087 lemma field_differentiable_within_csqrt:
  2088     "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> csqrt field_differentiable (at z within s)"
  2089   using field_differentiable_at_csqrt field_differentiable_within_subset by blast
  2090 
  2091 lemma continuous_at_csqrt:
  2092     "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> continuous (at z) csqrt"
  2093   by (simp add: field_differentiable_within_csqrt field_differentiable_imp_continuous_at)
  2094 
  2095 corollary isCont_csqrt' [simp]:
  2096    "\<lbrakk>isCont f z; f z \<notin> \<real>\<^sub>\<le>\<^sub>0\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. csqrt (f x)) z"
  2097   by (blast intro: isCont_o2 [OF _ continuous_at_csqrt])
  2098 
  2099 lemma continuous_within_csqrt:
  2100     "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> continuous (at z within s) csqrt"
  2101   by (simp add: field_differentiable_imp_continuous_at field_differentiable_within_csqrt)
  2102 
  2103 lemma continuous_on_csqrt [continuous_intros]:
  2104     "(\<And>z. z \<in> s \<Longrightarrow> z \<notin> \<real>\<^sub>\<le>\<^sub>0) \<Longrightarrow> continuous_on s csqrt"
  2105   by (simp add: continuous_at_imp_continuous_on continuous_within_csqrt)
  2106 
  2107 lemma holomorphic_on_csqrt:
  2108     "(\<And>z. z \<in> s \<Longrightarrow> z \<notin> \<real>\<^sub>\<le>\<^sub>0) \<Longrightarrow> csqrt holomorphic_on s"
  2109   by (simp add: field_differentiable_within_csqrt holomorphic_on_def)
  2110 
  2111 lemma continuous_within_closed_nontrivial:
  2112     "closed s \<Longrightarrow> a \<notin> s ==> continuous (at a within s) f"
  2113   using open_Compl
  2114   by (force simp add: continuous_def eventually_at_topological filterlim_iff open_Collect_neg)
  2115 
  2116 lemma continuous_within_csqrt_posreal:
  2117     "continuous (at z within (\<real> \<inter> {w. 0 \<le> Re(w)})) csqrt"
  2118 proof (cases "z \<in> \<real>\<^sub>\<le>\<^sub>0")
  2119   case True
  2120   then have "Im z = 0" "Re z < 0 \<or> z = 0"
  2121     using cnj.code complex_cnj_zero_iff  by (auto simp: Complex_eq complex_nonpos_Reals_iff) fastforce
  2122   then show ?thesis
  2123     apply (auto simp: continuous_within_closed_nontrivial [OF closed_Real_halfspace_Re_ge])
  2124     apply (auto simp: continuous_within_eps_delta norm_conv_dist [symmetric])
  2125     apply (rule_tac x="e^2" in exI)
  2126     apply (auto simp: Reals_def)
  2127     by (metis linear not_less real_sqrt_less_iff real_sqrt_pow2_iff real_sqrt_power)
  2128 next
  2129   case False
  2130     then show ?thesis   by (blast intro: continuous_within_csqrt)
  2131 qed
  2132 
  2133 subsection\<open>Complex arctangent\<close>
  2134 
  2135 text\<open>The branch cut gives standard bounds in the real case.\<close>
  2136 
  2137 definition Arctan :: "complex \<Rightarrow> complex" where
  2138     "Arctan \<equiv> \<lambda>z. (\<i>/2) * Ln((1 - \<i>*z) / (1 + \<i>*z))"
  2139 
  2140 lemma Arctan_def_moebius: "Arctan z = \<i>/2 * Ln (moebius (-\<i>) 1 \<i> 1 z)"
  2141   by (simp add: Arctan_def moebius_def add_ac)
  2142 
  2143 lemma Ln_conv_Arctan:
  2144   assumes "z \<noteq> -1"
  2145   shows   "Ln z = -2*\<i> * Arctan (moebius 1 (- 1) (- \<i>) (- \<i>) z)"
  2146 proof -
  2147   have "Arctan (moebius 1 (- 1) (- \<i>) (- \<i>) z) =
  2148              \<i>/2 * Ln (moebius (- \<i>) 1 \<i> 1 (moebius 1 (- 1) (- \<i>) (- \<i>) z))"
  2149     by (simp add: Arctan_def_moebius)
  2150   also from assms have "\<i> * z \<noteq> \<i> * (-1)" by (subst mult_left_cancel) simp
  2151   hence "\<i> * z - -\<i> \<noteq> 0" by (simp add: eq_neg_iff_add_eq_0)
  2152   from moebius_inverse'[OF _ this, of 1 1]
  2153     have "moebius (- \<i>) 1 \<i> 1 (moebius 1 (- 1) (- \<i>) (- \<i>) z) = z" by simp
  2154   finally show ?thesis by (simp add: field_simps)
  2155 qed
  2156 
  2157 lemma Arctan_0 [simp]: "Arctan 0 = 0"
  2158   by (simp add: Arctan_def)
  2159 
  2160 lemma Im_complex_div_lemma: "Im((1 - \<i>*z) / (1 + \<i>*z)) = 0 \<longleftrightarrow> Re z = 0"
  2161   by (auto simp: Im_complex_div_eq_0 algebra_simps)
  2162 
  2163 lemma Re_complex_div_lemma: "0 < Re((1 - \<i>*z) / (1 + \<i>*z)) \<longleftrightarrow> norm z < 1"
  2164   by (simp add: Re_complex_div_gt_0 algebra_simps cmod_def power2_eq_square)
  2165 
  2166 lemma tan_Arctan:
  2167   assumes "z\<^sup>2 \<noteq> -1"
  2168     shows [simp]:"tan(Arctan z) = z"
  2169 proof -
  2170   have "1 + \<i>*z \<noteq> 0"
  2171     by (metis assms complex_i_mult_minus i_squared minus_unique power2_eq_square power2_minus)
  2172   moreover
  2173   have "1 - \<i>*z \<noteq> 0"
  2174     by (metis assms complex_i_mult_minus i_squared power2_eq_square power2_minus right_minus_eq)
  2175   ultimately
  2176   show ?thesis
  2177     by (simp add: Arctan_def tan_def sin_exp_eq cos_exp_eq exp_minus csqrt_exp_Ln [symmetric]
  2178                   divide_simps power2_eq_square [symmetric])
  2179 qed
  2180 
  2181 lemma Arctan_tan [simp]:
  2182   assumes "\<bar>Re z\<bar> < pi/2"
  2183     shows "Arctan(tan z) = z"
  2184 proof -
  2185   have ge_pi2: "\<And>n::int. \<bar>of_int (2*n + 1) * pi/2\<bar> \<ge> pi/2"
  2186     by (case_tac n rule: int_cases) (auto simp: abs_mult)
  2187   have "exp (\<i>*z)*exp (\<i>*z) = -1 \<longleftrightarrow> exp (2*\<i>*z) = -1"
  2188     by (metis distrib_right exp_add mult_2)
  2189   also have "... \<longleftrightarrow> exp (2*\<i>*z) = exp (\<i>*pi)"
  2190     using cis_conv_exp cis_pi by auto
  2191   also have "... \<longleftrightarrow> exp (2*\<i>*z - \<i>*pi) = 1"
  2192     by (metis (no_types) diff_add_cancel diff_minus_eq_add exp_add exp_minus_inverse mult.commute)
  2193   also have "... \<longleftrightarrow> Re(\<i>*2*z - \<i>*pi) = 0 \<and> (\<exists>n::int. Im(\<i>*2*z - \<i>*pi) = of_int (2 * n) * pi)"
  2194     by (simp add: exp_eq_1)
  2195   also have "... \<longleftrightarrow> Im z = 0 \<and> (\<exists>n::int. 2 * Re z = of_int (2*n + 1) * pi)"
  2196     by (simp add: algebra_simps)
  2197   also have "... \<longleftrightarrow> False"
  2198     using assms ge_pi2
  2199     apply (auto simp: algebra_simps)
  2200     by (metis abs_mult_pos not_less of_nat_less_0_iff of_nat_numeral)
  2201   finally have *: "exp (\<i>*z)*exp (\<i>*z) + 1 \<noteq> 0"
  2202     by (auto simp: add.commute minus_unique)
  2203   show ?thesis
  2204     using assms *
  2205     apply (simp add: Arctan_def tan_def sin_exp_eq cos_exp_eq exp_minus divide_simps
  2206                      i_times_eq_iff power2_eq_square [symmetric])
  2207     apply (rule Ln_unique)
  2208     apply (auto simp: divide_simps exp_minus)
  2209     apply (simp add: algebra_simps exp_double [symmetric])
  2210     done
  2211 qed
  2212 
  2213 lemma
  2214   assumes "Re z = 0 \<Longrightarrow> \<bar>Im z\<bar> < 1"
  2215   shows Re_Arctan_bounds: "\<bar>Re(Arctan z)\<bar> < pi/2"
  2216     and has_field_derivative_Arctan: "(Arctan has_field_derivative inverse(1 + z\<^sup>2)) (at z)"
  2217 proof -
  2218   have nz0: "1 + \<i>*z \<noteq> 0"
  2219     using assms
  2220     by (metis abs_one complex_i_mult_minus diff_0_right diff_minus_eq_add imaginary_unit.simps
  2221               less_irrefl minus_diff_eq mult.right_neutral right_minus_eq)
  2222   have "z \<noteq> -\<i>" using assms
  2223     by auto
  2224   then have zz: "1 + z * z \<noteq> 0"
  2225     by (metis abs_one assms i_squared imaginary_unit.simps less_irrefl minus_unique square_eq_iff)
  2226   have nz1: "1 - \<i>*z \<noteq> 0"
  2227     using assms by (force simp add: i_times_eq_iff)
  2228   have nz2: "inverse (1 + \<i>*z) \<noteq> 0"
  2229     using assms
  2230     by (metis Im_complex_div_lemma Re_complex_div_lemma cmod_eq_Im divide_complex_def
  2231               less_irrefl mult_zero_right zero_complex.simps(1) zero_complex.simps(2))
  2232   have nzi: "((1 - \<i>*z) * inverse (1 + \<i>*z)) \<noteq> 0"
  2233     using nz1 nz2 by auto
  2234   have "Im ((1 - \<i>*z) / (1 + \<i>*z)) = 0 \<Longrightarrow> 0 < Re ((1 - \<i>*z) / (1 + \<i>*z))"
  2235     apply (simp add: divide_complex_def)
  2236     apply (simp add: divide_simps split: if_split_asm)
  2237     using assms
  2238     apply (auto simp: algebra_simps abs_square_less_1 [unfolded power2_eq_square])
  2239     done
  2240   then have *: "((1 - \<i>*z) / (1 + \<i>*z)) \<notin> \<real>\<^sub>\<le>\<^sub>0"
  2241     by (auto simp add: complex_nonpos_Reals_iff)
  2242   show "\<bar>Re(Arctan z)\<bar> < pi/2"
  2243     unfolding Arctan_def divide_complex_def
  2244     using mpi_less_Im_Ln [OF nzi]
  2245     apply (auto simp: abs_if intro!: Im_Ln_less_pi * [unfolded divide_complex_def])
  2246     done
  2247   show "(Arctan has_field_derivative inverse(1 + z\<^sup>2)) (at z)"
  2248     unfolding Arctan_def scaleR_conv_of_real
  2249     apply (rule DERIV_cong)
  2250     apply (intro derivative_eq_intros | simp add: nz0 *)+
  2251     using nz0 nz1 zz
  2252     apply (simp add: divide_simps power2_eq_square)
  2253     apply (auto simp: algebra_simps)
  2254     done
  2255 qed
  2256 
  2257 lemma field_differentiable_at_Arctan: "(Re z = 0 \<Longrightarrow> \<bar>Im z\<bar> < 1) \<Longrightarrow> Arctan field_differentiable at z"
  2258   using has_field_derivative_Arctan
  2259   by (auto simp: field_differentiable_def)
  2260 
  2261 lemma field_differentiable_within_Arctan:
  2262     "(Re z = 0 \<Longrightarrow> \<bar>Im z\<bar> < 1) \<Longrightarrow> Arctan field_differentiable (at z within s)"
  2263   using field_differentiable_at_Arctan field_differentiable_at_within by blast
  2264 
  2265 declare has_field_derivative_Arctan [derivative_intros]
  2266 declare has_field_derivative_Arctan [THEN DERIV_chain2, derivative_intros]
  2267 
  2268 lemma continuous_at_Arctan:
  2269     "(Re z = 0 \<Longrightarrow> \<bar>Im z\<bar> < 1) \<Longrightarrow> continuous (at z) Arctan"
  2270   by (simp add: field_differentiable_imp_continuous_at field_differentiable_within_Arctan)
  2271 
  2272 lemma continuous_within_Arctan:
  2273     "(Re z = 0 \<Longrightarrow> \<bar>Im z\<bar> < 1) \<Longrightarrow> continuous (at z within s) Arctan"
  2274   using continuous_at_Arctan continuous_at_imp_continuous_within by blast
  2275 
  2276 lemma continuous_on_Arctan [continuous_intros]:
  2277     "(\<And>z. z \<in> s \<Longrightarrow> Re z = 0 \<Longrightarrow> \<bar>Im z\<bar> < 1) \<Longrightarrow> continuous_on s Arctan"
  2278   by (auto simp: continuous_at_imp_continuous_on continuous_within_Arctan)
  2279 
  2280 lemma holomorphic_on_Arctan:
  2281     "(\<And>z. z \<in> s \<Longrightarrow> Re z = 0 \<Longrightarrow> \<bar>Im z\<bar> < 1) \<Longrightarrow> Arctan holomorphic_on s"
  2282   by (simp add: field_differentiable_within_Arctan holomorphic_on_def)
  2283 
  2284 lemma Arctan_series:
  2285   assumes z: "norm (z :: complex) < 1"
  2286   defines "g \<equiv> \<lambda>n. if odd n then -\<i>*\<i>^n / n else 0"
  2287   defines "h \<equiv> \<lambda>z n. (-1)^n / of_nat (2*n+1) * (z::complex)^(2*n+1)"
  2288   shows   "(\<lambda>n. g n * z^n) sums Arctan z"
  2289   and     "h z sums Arctan z"
  2290 proof -
  2291   define G where [abs_def]: "G z = (\<Sum>n. g n * z^n)" for z
  2292   have summable: "summable (\<lambda>n. g n * u^n)" if "norm u < 1" for u
  2293   proof (cases "u = 0")
  2294     assume u: "u \<noteq> 0"
  2295     have "(\<lambda>n. ereal (norm (h u n) / norm (h u (Suc n)))) = (\<lambda>n. ereal (inverse (norm u)^2) *
  2296               ereal ((2 + inverse (real (Suc n))) / (2 - inverse (real (Suc n)))))"
  2297     proof
  2298       fix n
  2299       have "ereal (norm (h u n) / norm (h u (Suc n))) =
  2300              ereal (inverse (norm u)^2) * ereal ((of_nat (2*Suc n+1) / of_nat (Suc n)) /
  2301                  (of_nat (2*Suc n-1) / of_nat (Suc n)))"
  2302       by (simp add: h_def norm_mult norm_power norm_divide divide_simps
  2303                     power2_eq_square eval_nat_numeral del: of_nat_add of_nat_Suc)
  2304       also have "of_nat (2*Suc n+1) / of_nat (Suc n) = (2::real) + inverse (real (Suc n))"
  2305         by (auto simp: divide_simps simp del: of_nat_Suc) simp_all?
  2306       also have "of_nat (2*Suc n-1) / of_nat (Suc n) = (2::real) - inverse (real (Suc n))"
  2307         by (auto simp: divide_simps simp del: of_nat_Suc) simp_all?
  2308       finally show "ereal (norm (h u n) / norm (h u (Suc n))) = ereal (inverse (norm u)^2) *
  2309               ereal ((2 + inverse (real (Suc n))) / (2 - inverse (real (Suc n))))" .
  2310     qed
  2311     also have "\<dots> \<longlonglongrightarrow> ereal (inverse (norm u)^2) * ereal ((2 + 0) / (2 - 0))"
  2312       by (intro tendsto_intros LIMSEQ_inverse_real_of_nat) simp_all
  2313     finally have "liminf (\<lambda>n. ereal (cmod (h u n) / cmod (h u (Suc n)))) = inverse (norm u)^2"
  2314       by (intro lim_imp_Liminf) simp_all
  2315     moreover from power_strict_mono[OF that, of 2] u have "inverse (norm u)^2 > 1"
  2316       by (simp add: divide_simps)
  2317     ultimately have A: "liminf (\<lambda>n. ereal (cmod (h u n) / cmod (h u (Suc n)))) > 1" by simp
  2318     from u have "summable (h u)"
  2319       by (intro summable_norm_cancel[OF ratio_test_convergence[OF _ A]])
  2320          (auto simp: h_def norm_divide norm_mult norm_power simp del: of_nat_Suc
  2321                intro!: mult_pos_pos divide_pos_pos always_eventually)
  2322     thus "summable (\<lambda>n. g n * u^n)"
  2323       by (subst summable_mono_reindex[of "\<lambda>n. 2*n+1", symmetric])
  2324          (auto simp: power_mult subseq_def g_def h_def elim!: oddE)
  2325   qed (simp add: h_def)
  2326 
  2327   have "\<exists>c. \<forall>u\<in>ball 0 1. Arctan u - G u = c"
  2328   proof (rule has_field_derivative_zero_constant)
  2329     fix u :: complex assume "u \<in> ball 0 1"
  2330     hence u: "norm u < 1" by (simp add: dist_0_norm)
  2331     define K where "K = (norm u + 1) / 2"
  2332     from u and abs_Im_le_cmod[of u] have Im_u: "\<bar>Im u\<bar> < 1" by linarith
  2333     from u have K: "0 \<le> K" "norm u < K" "K < 1" by (simp_all add: K_def)
  2334     hence "(G has_field_derivative (\<Sum>n. diffs g n * u ^ n)) (at u)" unfolding G_def
  2335       by (intro termdiffs_strong[of _ "of_real K"] summable) simp_all
  2336     also have "(\<lambda>n. diffs g n * u^n) = (\<lambda>n. if even n then (\<i>*u)^n else 0)"
  2337       by (intro ext) (simp_all del: of_nat_Suc add: g_def diffs_def power_mult_distrib)
  2338     also have "suminf \<dots> = (\<Sum>n. (-(u^2))^n)"
  2339       by (subst suminf_mono_reindex[of "\<lambda>n. 2*n", symmetric])
  2340          (auto elim!: evenE simp: subseq_def power_mult power_mult_distrib)
  2341     also from u have "norm u^2 < 1^2" by (intro power_strict_mono) simp_all
  2342     hence "(\<Sum>n. (-(u^2))^n) = inverse (1 + u^2)"
  2343       by (subst suminf_geometric) (simp_all add: norm_power inverse_eq_divide)
  2344     finally have "(G has_field_derivative inverse (1 + u\<^sup>2)) (at u)" .
  2345     from DERIV_diff[OF has_field_derivative_Arctan this] Im_u u
  2346       show "((\<lambda>u. Arctan u - G u) has_field_derivative 0) (at u within ball 0 1)"
  2347       by (simp_all add: dist_0_norm at_within_open[OF _ open_ball])
  2348   qed simp_all
  2349   then obtain c where c: "\<And>u. norm u < 1 \<Longrightarrow> Arctan u - G u = c" by (auto simp: dist_0_norm)
  2350   from this[of 0] have "c = 0" by (simp add: G_def g_def powser_zero)
  2351   with c z have "Arctan z = G z" by simp
  2352   with summable[OF z] show "(\<lambda>n. g n * z^n) sums Arctan z" unfolding G_def by (simp add: sums_iff)
  2353   thus "h z sums Arctan z" by (subst (asm) sums_mono_reindex[of "\<lambda>n. 2*n+1", symmetric])
  2354                               (auto elim!: oddE simp: subseq_def power_mult g_def h_def)
  2355 qed
  2356 
  2357 text \<open>A quickly-converging series for the logarithm, based on the arctangent.\<close>
  2358 lemma ln_series_quadratic:
  2359   assumes x: "x > (0::real)"
  2360   shows "(\<lambda>n. (2*((x - 1) / (x + 1)) ^ (2*n+1) / of_nat (2*n+1))) sums ln x"
  2361 proof -
  2362   define y :: complex where "y = of_real ((x-1)/(x+1))"
  2363   from x have x': "complex_of_real x \<noteq> of_real (-1)"  by (subst of_real_eq_iff) auto
  2364   from x have "\<bar>x - 1\<bar> < \<bar>x + 1\<bar>" by linarith
  2365   hence "norm (complex_of_real (x - 1) / complex_of_real (x + 1)) < 1"
  2366     by (simp add: norm_divide del: of_real_add of_real_diff)
  2367   hence "norm (\<i> * y) < 1" unfolding y_def by (subst norm_mult) simp
  2368   hence "(\<lambda>n. (-2*\<i>) * ((-1)^n / of_nat (2*n+1) * (\<i>*y)^(2*n+1))) sums ((-2*\<i>) * Arctan (\<i>*y))"
  2369     by (intro Arctan_series sums_mult) simp_all
  2370   also have "(\<lambda>n. (-2*\<i>) * ((-1)^n / of_nat (2*n+1) * (\<i>*y)^(2*n+1))) =
  2371                  (\<lambda>n. (-2*\<i>) * ((-1)^n * (\<i>*y*(-y\<^sup>2)^n)/of_nat (2*n+1)))"
  2372     by (intro ext) (simp_all add: power_mult power_mult_distrib)
  2373   also have "\<dots> = (\<lambda>n. 2*y* ((-1) * (-y\<^sup>2))^n/of_nat (2*n+1))"
  2374     by (intro ext, subst power_mult_distrib) (simp add: algebra_simps power_mult)
  2375   also have "\<dots> = (\<lambda>n. 2*y^(2*n+1) / of_nat (2*n+1))"
  2376     by (subst power_add, subst power_mult) (simp add: mult_ac)
  2377   also have "\<dots> = (\<lambda>n. of_real (2*((x-1)/(x+1))^(2*n+1) / of_nat (2*n+1)))"
  2378     by (intro ext) (simp add: y_def)
  2379   also have "\<i> * y = (of_real x - 1) / (-\<i> * (of_real x + 1))"
  2380     by (subst divide_divide_eq_left [symmetric]) (simp add: y_def)
  2381   also have "\<dots> = moebius 1 (-1) (-\<i>) (-\<i>) (of_real x)" by (simp add: moebius_def algebra_simps)
  2382   also from x' have "-2*\<i>*Arctan \<dots> = Ln (of_real x)" by (intro Ln_conv_Arctan [symmetric]) simp_all
  2383   also from x have "\<dots> = ln x" by (rule Ln_of_real)
  2384   finally show ?thesis by (subst (asm) sums_of_real_iff)
  2385 qed
  2386 
  2387 subsection \<open>Real arctangent\<close>
  2388 
  2389 lemma norm_exp_i_times [simp]: "norm (exp(\<i> * of_real y)) = 1"
  2390   by simp
  2391 
  2392 lemma norm_exp_imaginary: "norm(exp z) = 1 \<Longrightarrow> Re z = 0"
  2393   by simp
  2394 
  2395 lemma Im_Arctan_of_real [simp]: "Im (Arctan (of_real x)) = 0"
  2396   unfolding Arctan_def divide_complex_def
  2397   apply (simp add: complex_eq_iff)
  2398   apply (rule norm_exp_imaginary)
  2399   apply (subst exp_Ln, auto)
  2400   apply (simp_all add: cmod_def complex_eq_iff)
  2401   apply (auto simp: divide_simps)
  2402   apply (metis power_one sum_power2_eq_zero_iff zero_neq_one, algebra)
  2403   done
  2404 
  2405 lemma arctan_eq_Re_Arctan: "arctan x = Re (Arctan (of_real x))"
  2406 proof (rule arctan_unique)
  2407   show "- (pi / 2) < Re (Arctan (complex_of_real x))"
  2408     apply (simp add: Arctan_def)
  2409     apply (rule Im_Ln_less_pi)
  2410     apply (auto simp: Im_complex_div_lemma complex_nonpos_Reals_iff)
  2411     done
  2412 next
  2413   have *: " (1 - \<i>*x) / (1 + \<i>*x) \<noteq> 0"
  2414     by (simp add: divide_simps) ( simp add: complex_eq_iff)
  2415   show "Re (Arctan (complex_of_real x)) < pi / 2"
  2416     using mpi_less_Im_Ln [OF *]
  2417     by (simp add: Arctan_def)
  2418 next
  2419   have "tan (Re (Arctan (of_real x))) = Re (tan (Arctan (of_real x)))"
  2420     apply (auto simp: tan_def Complex.Re_divide Re_sin Re_cos Im_sin Im_cos)
  2421     apply (simp add: field_simps)
  2422     by (simp add: power2_eq_square)
  2423   also have "... = x"
  2424     apply (subst tan_Arctan, auto)
  2425     by (metis diff_0_right minus_diff_eq mult_zero_left not_le of_real_1 of_real_eq_iff of_real_minus of_real_power power2_eq_square real_minus_mult_self_le zero_less_one)
  2426   finally show "tan (Re (Arctan (complex_of_real x))) = x" .
  2427 qed
  2428 
  2429 lemma Arctan_of_real: "Arctan (of_real x) = of_real (arctan x)"
  2430   unfolding arctan_eq_Re_Arctan divide_complex_def
  2431   by (simp add: complex_eq_iff)
  2432 
  2433 lemma Arctan_in_Reals [simp]: "z \<in> \<real> \<Longrightarrow> Arctan z \<in> \<real>"
  2434   by (metis Reals_cases Reals_of_real Arctan_of_real)
  2435 
  2436 declare arctan_one [simp]
  2437 
  2438 lemma arctan_less_pi4_pos: "x < 1 \<Longrightarrow> arctan x < pi/4"
  2439   by (metis arctan_less_iff arctan_one)
  2440 
  2441 lemma arctan_less_pi4_neg: "-1 < x \<Longrightarrow> -(pi/4) < arctan x"
  2442   by (metis arctan_less_iff arctan_minus arctan_one)
  2443 
  2444 lemma arctan_less_pi4: "\<bar>x\<bar> < 1 \<Longrightarrow> \<bar>arctan x\<bar> < pi/4"
  2445   by (metis abs_less_iff arctan_less_pi4_pos arctan_minus)
  2446 
  2447 lemma arctan_le_pi4: "\<bar>x\<bar> \<le> 1 \<Longrightarrow> \<bar>arctan x\<bar> \<le> pi/4"
  2448   by (metis abs_le_iff arctan_le_iff arctan_minus arctan_one)
  2449 
  2450 lemma abs_arctan: "\<bar>arctan x\<bar> = arctan \<bar>x\<bar>"
  2451   by (simp add: abs_if arctan_minus)
  2452 
  2453 lemma arctan_add_raw:
  2454   assumes "\<bar>arctan x + arctan y\<bar> < pi/2"
  2455     shows "arctan x + arctan y = arctan((x + y) / (1 - x * y))"
  2456 proof (rule arctan_unique [symmetric])
  2457   show 12: "- (pi / 2) < arctan x + arctan y" "arctan x + arctan y < pi / 2"
  2458     using assms by linarith+
  2459   show "tan (arctan x + arctan y) = (x + y) / (1 - x * y)"
  2460     using cos_gt_zero_pi [OF 12]
  2461     by (simp add: arctan tan_add)
  2462 qed
  2463 
  2464 lemma arctan_inverse:
  2465   assumes "0 < x"
  2466     shows "arctan(inverse x) = pi/2 - arctan x"
  2467 proof -
  2468   have "arctan(inverse x) = arctan(inverse(tan(arctan x)))"
  2469     by (simp add: arctan)
  2470   also have "... = arctan (tan (pi / 2 - arctan x))"
  2471     by (simp add: tan_cot)
  2472   also have "... = pi/2 - arctan x"
  2473   proof -
  2474     have "0 < pi - arctan x"
  2475     using arctan_ubound [of x] pi_gt_zero by linarith
  2476     with assms show ?thesis
  2477       by (simp add: Transcendental.arctan_tan)
  2478   qed
  2479   finally show ?thesis .
  2480 qed
  2481 
  2482 lemma arctan_add_small:
  2483   assumes "\<bar>x * y\<bar> < 1"
  2484     shows "(arctan x + arctan y = arctan((x + y) / (1 - x * y)))"
  2485 proof (cases "x = 0 \<or> y = 0")
  2486   case True then show ?thesis
  2487     by auto
  2488 next
  2489   case False
  2490   then have *: "\<bar>arctan x\<bar> < pi / 2 - \<bar>arctan y\<bar>" using assms
  2491     apply (auto simp add: abs_arctan arctan_inverse [symmetric] arctan_less_iff)
  2492     apply (simp add: divide_simps abs_mult)
  2493     done
  2494   show ?thesis
  2495     apply (rule arctan_add_raw)
  2496     using * by linarith
  2497 qed
  2498 
  2499 lemma abs_arctan_le:
  2500   fixes x::real shows "\<bar>arctan x\<bar> \<le> \<bar>x\<bar>"
  2501 proof -
  2502   { fix w::complex and z::complex
  2503     assume *: "w \<in> \<real>" "z \<in> \<real>"
  2504     have "cmod (Arctan w - Arctan z) \<le> 1 * cmod (w-z)"
  2505       apply (rule field_differentiable_bound [OF convex_Reals, of Arctan _ 1])
  2506       apply (rule has_field_derivative_at_within [OF has_field_derivative_Arctan])
  2507       apply (force simp add: Reals_def)
  2508       apply (simp add: norm_divide divide_simps in_Reals_norm complex_is_Real_iff power2_eq_square)
  2509       using * by auto
  2510   }
  2511   then have "cmod (Arctan (of_real x) - Arctan 0) \<le> 1 * cmod (of_real x -0)"
  2512     using Reals_0 Reals_of_real by blast
  2513   then show ?thesis
  2514     by (simp add: Arctan_of_real)
  2515 qed
  2516 
  2517 lemma arctan_le_self: "0 \<le> x \<Longrightarrow> arctan x \<le> x"
  2518   by (metis abs_arctan_le abs_of_nonneg zero_le_arctan_iff)
  2519 
  2520 lemma abs_tan_ge: "\<bar>x\<bar> < pi/2 \<Longrightarrow> \<bar>x\<bar> \<le> \<bar>tan x\<bar>"
  2521   by (metis abs_arctan_le abs_less_iff arctan_tan minus_less_iff)
  2522 
  2523 lemma arctan_bounds:
  2524   assumes "0 \<le> x" "x < 1"
  2525   shows arctan_lower_bound:
  2526     "(\<Sum>k<2 * n. (- 1) ^ k * (1 / real (k * 2 + 1) * x ^ (k * 2 + 1))) \<le> arctan x"
  2527     (is "(\<Sum>k<_. (- 1)^ k * ?a k) \<le> _")
  2528     and arctan_upper_bound:
  2529     "arctan x \<le> (\<Sum>k<2 * n + 1. (- 1) ^ k * (1 / real (k * 2 + 1) * x ^ (k * 2 + 1)))"
  2530 proof -
  2531   have tendsto_zero: "?a \<longlonglongrightarrow> 0"
  2532     using assms
  2533     apply -
  2534     apply (rule tendsto_eq_rhs[where x="0 * 0"])
  2535     subgoal by (intro tendsto_mult real_tendsto_divide_at_top)
  2536         (auto simp: filterlim_real_sequentially filterlim_sequentially_iff_filterlim_real
  2537           intro!: real_tendsto_divide_at_top tendsto_power_zero filterlim_real_sequentially
  2538            tendsto_eq_intros filterlim_at_top_mult_tendsto_pos filterlim_tendsto_add_at_top)
  2539     subgoal by simp
  2540     done
  2541   have nonneg: "0 \<le> ?a n" for n
  2542     by (force intro!: divide_nonneg_nonneg mult_nonneg_nonneg zero_le_power assms)
  2543   have le: "?a (Suc n) \<le> ?a n" for n
  2544     by (rule mult_mono[OF _ power_decreasing]) (auto simp: divide_simps assms less_imp_le)
  2545   from summable_Leibniz'(4)[of ?a, OF tendsto_zero nonneg le, of n]
  2546     summable_Leibniz'(2)[of ?a, OF tendsto_zero nonneg le, of n]
  2547     assms
  2548   show "(\<Sum>k<2*n. (- 1)^ k * ?a k) \<le> arctan x" "arctan x \<le> (\<Sum>k<2 * n + 1. (- 1)^ k * ?a k)"
  2549     by (auto simp: arctan_series)
  2550 qed
  2551 
  2552 subsection \<open>Bounds on pi using real arctangent\<close>
  2553 
  2554 lemma pi_machin: "pi = 16 * arctan (1 / 5) - 4 * arctan (1 / 239)"
  2555   using machin
  2556   by simp
  2557 
  2558 lemma pi_approx: "3.141592653588 \<le> pi" "pi \<le> 3.1415926535899"
  2559   unfolding pi_machin
  2560   using arctan_bounds[of "1/5"   4]
  2561         arctan_bounds[of "1/239" 4]
  2562   by (simp_all add: eval_nat_numeral)
  2563     
  2564 corollary pi_gt3: "pi > 3"
  2565   using pi_approx by simp
  2566 
  2567 
  2568 subsection\<open>Inverse Sine\<close>
  2569 
  2570 definition Arcsin :: "complex \<Rightarrow> complex" where
  2571    "Arcsin \<equiv> \<lambda>z. -\<i> * Ln(\<i> * z + csqrt(1 - z\<^sup>2))"
  2572 
  2573 lemma Arcsin_body_lemma: "\<i> * z + csqrt(1 - z\<^sup>2) \<noteq> 0"
  2574   using power2_csqrt [of "1 - z\<^sup>2"]
  2575   apply auto
  2576   by (metis complex_i_mult_minus diff_add_cancel diff_minus_eq_add diff_self mult.assoc mult.left_commute numeral_One power2_csqrt power2_eq_square zero_neq_numeral)
  2577 
  2578 lemma Arcsin_range_lemma: "\<bar>Re z\<bar> < 1 \<Longrightarrow> 0 < Re(\<i> * z + csqrt(1 - z\<^sup>2))"
  2579   using Complex.cmod_power2 [of z, symmetric]
  2580   by (simp add: real_less_rsqrt algebra_simps Re_power2 cmod_square_less_1_plus)
  2581 
  2582 lemma Re_Arcsin: "Re(Arcsin z) = Im (Ln (\<i> * z + csqrt(1 - z\<^sup>2)))"
  2583   by (simp add: Arcsin_def)
  2584 
  2585 lemma Im_Arcsin: "Im(Arcsin z) = - ln (cmod (\<i> * z + csqrt (1 - z\<^sup>2)))"
  2586   by (simp add: Arcsin_def Arcsin_body_lemma)
  2587 
  2588 lemma one_minus_z2_notin_nonpos_Reals:
  2589   assumes "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1)"
  2590   shows "1 - z\<^sup>2 \<notin> \<real>\<^sub>\<le>\<^sub>0"
  2591     using assms
  2592     apply (auto simp: complex_nonpos_Reals_iff Re_power2 Im_power2)
  2593     using power2_less_0 [of "Im z"] apply force
  2594     using abs_square_less_1 not_le by blast
  2595 
  2596 lemma isCont_Arcsin_lemma:
  2597   assumes le0: "Re (\<i> * z + csqrt (1 - z\<^sup>2)) \<le> 0" and "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1)"
  2598     shows False
  2599 proof (cases "Im z = 0")
  2600   case True
  2601   then show ?thesis
  2602     using assms by (fastforce simp: cmod_def abs_square_less_1 [symmetric])
  2603 next
  2604   case False
  2605   have neq: "(cmod z)\<^sup>2 \<noteq> 1 + cmod (1 - z\<^sup>2)"
  2606   proof (clarsimp simp add: cmod_def)
  2607     assume "(Re z)\<^sup>2 + (Im z)\<^sup>2 = 1 + sqrt ((1 - Re (z\<^sup>2))\<^sup>2 + (Im (z\<^sup>2))\<^sup>2)"
  2608     then have "((Re z)\<^sup>2 + (Im z)\<^sup>2 - 1)\<^sup>2 = ((1 - Re (z\<^sup>2))\<^sup>2 + (Im (z\<^sup>2))\<^sup>2)"
  2609       by simp
  2610     then show False using False
  2611       by (simp add: power2_eq_square algebra_simps)
  2612   qed
  2613   moreover have 2: "(Im z)\<^sup>2 = (1 + ((Im z)\<^sup>2 + cmod (1 - z\<^sup>2)) - (Re z)\<^sup>2) / 2"
  2614     using le0
  2615     apply simp
  2616     apply (drule sqrt_le_D)
  2617     using cmod_power2 [of z] norm_triangle_ineq2 [of "z^2" 1]
  2618     apply (simp add: norm_power Re_power2 norm_minus_commute [of 1])
  2619     done
  2620   ultimately show False
  2621     by (simp add: Re_power2 Im_power2 cmod_power2)
  2622 qed
  2623 
  2624 lemma isCont_Arcsin:
  2625   assumes "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1)"
  2626     shows "isCont Arcsin z"
  2627 proof -
  2628   have *: "\<i> * z + csqrt (1 - z\<^sup>2) \<notin> \<real>\<^sub>\<le>\<^sub>0"
  2629     by (metis isCont_Arcsin_lemma assms complex_nonpos_Reals_iff)
  2630   show ?thesis
  2631     using assms
  2632     apply (simp add: Arcsin_def)
  2633     apply (rule isCont_Ln' isCont_csqrt' continuous_intros)+
  2634     apply (simp add: one_minus_z2_notin_nonpos_Reals assms)
  2635     apply (rule *)
  2636     done
  2637 qed
  2638 
  2639 lemma isCont_Arcsin' [simp]:
  2640   shows "isCont f z \<Longrightarrow> (Im (f z) = 0 \<Longrightarrow> \<bar>Re (f z)\<bar> < 1) \<Longrightarrow> isCont (\<lambda>x. Arcsin (f x)) z"
  2641   by (blast intro: isCont_o2 [OF _ isCont_Arcsin])
  2642 
  2643 lemma sin_Arcsin [simp]: "sin(Arcsin z) = z"
  2644 proof -
  2645   have "\<i>*z*2 + csqrt (1 - z\<^sup>2)*2 = 0 \<longleftrightarrow> (\<i>*z)*2 + csqrt (1 - z\<^sup>2)*2 = 0"
  2646     by (simp add: algebra_simps)  \<comment>\<open>Cancelling a factor of 2\<close>
  2647   moreover have "... \<longleftrightarrow> (\<i>*z) + csqrt (1 - z\<^sup>2) = 0"
  2648     by (metis Arcsin_body_lemma distrib_right no_zero_divisors zero_neq_numeral)
  2649   ultimately show ?thesis
  2650     apply (simp add: sin_exp_eq Arcsin_def Arcsin_body_lemma exp_minus divide_simps)
  2651     apply (simp add: algebra_simps)
  2652     apply (simp add: power2_eq_square [symmetric] algebra_simps)
  2653     done
  2654 qed
  2655 
  2656 lemma Re_eq_pihalf_lemma:
  2657     "\<bar>Re z\<bar> = pi/2 \<Longrightarrow> Im z = 0 \<Longrightarrow>
  2658       Re ((exp (\<i>*z) + inverse (exp (\<i>*z))) / 2) = 0 \<and> 0 \<le> Im ((exp (\<i>*z) + inverse (exp (\<i>*z))) / 2)"
  2659   apply (simp add: cos_i_times [symmetric] Re_cos Im_cos abs_if del: eq_divide_eq_numeral1)
  2660   by (metis cos_minus cos_pi_half)
  2661 
  2662 lemma Re_less_pihalf_lemma:
  2663   assumes "\<bar>Re z\<bar> < pi / 2"
  2664     shows "0 < Re ((exp (\<i>*z) + inverse (exp (\<i>*z))) / 2)"
  2665 proof -
  2666   have "0 < cos (Re z)" using assms
  2667     using cos_gt_zero_pi by auto
  2668   then show ?thesis
  2669     by (simp add: cos_i_times [symmetric] Re_cos Im_cos add_pos_pos)
  2670 qed
  2671 
  2672 lemma Arcsin_sin:
  2673     assumes "\<bar>Re z\<bar> < pi/2 \<or> (\<bar>Re z\<bar> = pi/2 \<and> Im z = 0)"
  2674       shows "Arcsin(sin z) = z"
  2675 proof -
  2676   have "Arcsin(sin z) = - (\<i> * Ln (csqrt (1 - (\<i> * (exp (\<i>*z) - inverse (exp (\<i>*z))))\<^sup>2 / 4) - (inverse (exp (\<i>*z)) - exp (\<i>*z)) / 2))"
  2677     by (simp add: sin_exp_eq Arcsin_def exp_minus power_divide)
  2678   also have "... = - (\<i> * Ln (csqrt (((exp (\<i>*z) + inverse (exp (\<i>*z)))/2)\<^sup>2) - (inverse (exp (\<i>*z)) - exp (\<i>*z)) / 2))"
  2679     by (simp add: field_simps power2_eq_square)
  2680   also have "... = - (\<i> * Ln (((exp (\<i>*z) + inverse (exp (\<i>*z)))/2) - (inverse (exp (\<i>*z)) - exp (\<i>*z)) / 2))"
  2681     apply (subst csqrt_square)
  2682     using assms Re_eq_pihalf_lemma Re_less_pihalf_lemma
  2683     apply auto
  2684     done
  2685   also have "... =  - (\<i> * Ln (exp (\<i>*z)))"
  2686     by (simp add: field_simps power2_eq_square)
  2687   also have "... = z"
  2688     apply (subst Complex_Transcendental.Ln_exp)
  2689     using assms
  2690     apply (auto simp: abs_if simp del: eq_divide_eq_numeral1 split: if_split_asm)
  2691     done
  2692   finally show ?thesis .
  2693 qed
  2694 
  2695 lemma Arcsin_unique:
  2696     "\<lbrakk>sin z = w; \<bar>Re z\<bar> < pi/2 \<or> (\<bar>Re z\<bar> = pi/2 \<and> Im z = 0)\<rbrakk> \<Longrightarrow> Arcsin w = z"
  2697   by (metis Arcsin_sin)
  2698 
  2699 lemma Arcsin_0 [simp]: "Arcsin 0 = 0"
  2700   by (metis Arcsin_sin norm_zero pi_half_gt_zero real_norm_def sin_zero zero_complex.simps(1))
  2701 
  2702 lemma Arcsin_1 [simp]: "Arcsin 1 = pi/2"
  2703   by (metis Arcsin_sin Im_complex_of_real Re_complex_of_real numeral_One of_real_numeral pi_half_ge_zero real_sqrt_abs real_sqrt_pow2 real_sqrt_power sin_of_real sin_pi_half)
  2704 
  2705 lemma Arcsin_minus_1 [simp]: "Arcsin(-1) = - (pi/2)"
  2706   by (metis Arcsin_1 Arcsin_sin Im_complex_of_real Re_complex_of_real abs_of_nonneg of_real_minus pi_half_ge_zero power2_minus real_sqrt_abs sin_Arcsin sin_minus)
  2707 
  2708 lemma has_field_derivative_Arcsin:
  2709   assumes "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1)"
  2710     shows "(Arcsin has_field_derivative inverse(cos(Arcsin z))) (at z)"
  2711 proof -
  2712   have "(sin (Arcsin z))\<^sup>2 \<noteq> 1"
  2713     using assms
  2714     apply atomize
  2715     apply (auto simp: complex_eq_iff Re_power2 Im_power2 abs_square_eq_1)
  2716     apply (metis abs_minus_cancel abs_one abs_power2 numeral_One numeral_neq_neg_one)
  2717     by (metis abs_minus_cancel abs_one abs_power2 one_neq_neg_one)
  2718   then have "cos (Arcsin z) \<noteq> 0"
  2719     by (metis diff_0_right power_zero_numeral sin_squared_eq)
  2720   then show ?thesis
  2721     apply (rule has_complex_derivative_inverse_basic [OF DERIV_sin _ _ open_ball [of z 1]])
  2722     apply (auto intro: isCont_Arcsin assms)
  2723     done
  2724 qed
  2725 
  2726 declare has_field_derivative_Arcsin [derivative_intros]
  2727 declare has_field_derivative_Arcsin [THEN DERIV_chain2, derivative_intros]
  2728 
  2729 lemma field_differentiable_at_Arcsin:
  2730     "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> Arcsin field_differentiable at z"
  2731   using field_differentiable_def has_field_derivative_Arcsin by blast
  2732 
  2733 lemma field_differentiable_within_Arcsin:
  2734     "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> Arcsin field_differentiable (at z within s)"
  2735   using field_differentiable_at_Arcsin field_differentiable_within_subset by blast
  2736 
  2737 lemma continuous_within_Arcsin:
  2738     "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> continuous (at z within s) Arcsin"
  2739   using continuous_at_imp_continuous_within isCont_Arcsin by blast
  2740 
  2741 lemma continuous_on_Arcsin [continuous_intros]:
  2742     "(\<And>z. z \<in> s \<Longrightarrow> Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> continuous_on s Arcsin"
  2743   by (simp add: continuous_at_imp_continuous_on)
  2744 
  2745 lemma holomorphic_on_Arcsin: "(\<And>z. z \<in> s \<Longrightarrow> Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> Arcsin holomorphic_on s"
  2746   by (simp add: field_differentiable_within_Arcsin holomorphic_on_def)
  2747 
  2748 
  2749 subsection\<open>Inverse Cosine\<close>
  2750 
  2751 definition Arccos :: "complex \<Rightarrow> complex" where
  2752    "Arccos \<equiv> \<lambda>z. -\<i> * Ln(z + \<i> * csqrt(1 - z\<^sup>2))"
  2753 
  2754 lemma Arccos_range_lemma: "\<bar>Re z\<bar> < 1 \<Longrightarrow> 0 < Im(z + \<i> * csqrt(1 - z\<^sup>2))"
  2755   using Arcsin_range_lemma [of "-z"]
  2756   by simp
  2757 
  2758 lemma Arccos_body_lemma: "z + \<i> * csqrt(1 - z\<^sup>2) \<noteq> 0"
  2759   using Arcsin_body_lemma [of z]
  2760   by (metis complex_i_mult_minus diff_add_cancel minus_diff_eq minus_unique mult.assoc mult.left_commute
  2761            power2_csqrt power2_eq_square zero_neq_one)
  2762 
  2763 lemma Re_Arccos: "Re(Arccos z) = Im (Ln (z + \<i> * csqrt(1 - z\<^sup>2)))"
  2764   by (simp add: Arccos_def)
  2765 
  2766 lemma Im_Arccos: "Im(Arccos z) = - ln (cmod (z + \<i> * csqrt (1 - z\<^sup>2)))"
  2767   by (simp add: Arccos_def Arccos_body_lemma)
  2768 
  2769 text\<open>A very tricky argument to find!\<close>
  2770 lemma isCont_Arccos_lemma:
  2771   assumes eq0: "Im (z + \<i> * csqrt (1 - z\<^sup>2)) = 0" and "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1)"
  2772     shows False
  2773 proof (cases "Im z = 0")
  2774   case True
  2775   then show ?thesis
  2776     using assms by (fastforce simp add: cmod_def abs_square_less_1 [symmetric])
  2777 next
  2778   case False
  2779   have Imz: "Im z = - sqrt ((1 + ((Im z)\<^sup>2 + cmod (1 - z\<^sup>2)) - (Re z)\<^sup>2) / 2)"
  2780     using eq0 abs_Re_le_cmod [of "1-z\<^sup>2"]
  2781     by (simp add: Re_power2 algebra_simps)
  2782   have "(cmod z)\<^sup>2 - 1 \<noteq> cmod (1 - z\<^sup>2)"
  2783   proof (clarsimp simp add: cmod_def)
  2784     assume "(Re z)\<^sup>2 + (Im z)\<^sup>2 - 1 = sqrt ((1 - Re (z\<^sup>2))\<^sup>2 + (Im (z\<^sup>2))\<^sup>2)"
  2785     then have "((Re z)\<^sup>2 + (Im z)\<^sup>2 - 1)\<^sup>2 = ((1 - Re (z\<^sup>2))\<^sup>2 + (Im (z\<^sup>2))\<^sup>2)"
  2786       by simp
  2787     then show False using False
  2788       by (simp add: power2_eq_square algebra_simps)
  2789   qed
  2790   moreover have "(Im z)\<^sup>2 = ((1 + ((Im z)\<^sup>2 + cmod (1 - z\<^sup>2)) - (Re z)\<^sup>2) / 2)"
  2791     apply (subst Imz)
  2792     using abs_Re_le_cmod [of "1-z\<^sup>2"]
  2793     apply (simp add: Re_power2)
  2794     done
  2795   ultimately show False
  2796     by (simp add: cmod_power2)
  2797 qed
  2798 
  2799 lemma isCont_Arccos:
  2800   assumes "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1)"
  2801     shows "isCont Arccos z"
  2802 proof -
  2803   have "z + \<i> * csqrt (1 - z\<^sup>2) \<notin> \<real>\<^sub>\<le>\<^sub>0"
  2804     by (metis complex_nonpos_Reals_iff isCont_Arccos_lemma assms)
  2805   with assms show ?thesis
  2806     apply (simp add: Arccos_def)
  2807     apply (rule isCont_Ln' isCont_csqrt' continuous_intros)+
  2808     apply (simp_all add: one_minus_z2_notin_nonpos_Reals assms)
  2809     done
  2810 qed
  2811 
  2812 lemma isCont_Arccos' [simp]:
  2813   shows "isCont f z \<Longrightarrow> (Im (f z) = 0 \<Longrightarrow> \<bar>Re (f z)\<bar> < 1) \<Longrightarrow> isCont (\<lambda>x. Arccos (f x)) z"
  2814   by (blast intro: isCont_o2 [OF _ isCont_Arccos])
  2815 
  2816 lemma cos_Arccos [simp]: "cos(Arccos z) = z"
  2817 proof -
  2818   have "z*2 + \<i> * (2 * csqrt (1 - z\<^sup>2)) = 0 \<longleftrightarrow> z*2 + \<i> * csqrt (1 - z\<^sup>2)*2 = 0"
  2819     by (simp add: algebra_simps)  \<comment>\<open>Cancelling a factor of 2\<close>
  2820   moreover have "... \<longleftrightarrow> z + \<i> * csqrt (1 - z\<^sup>2) = 0"
  2821     by (metis distrib_right mult_eq_0_iff zero_neq_numeral)
  2822   ultimately show ?thesis
  2823     apply (simp add: cos_exp_eq Arccos_def Arccos_body_lemma exp_minus field_simps)
  2824     apply (simp add: power2_eq_square [symmetric])
  2825     done
  2826 qed
  2827 
  2828 lemma Arccos_cos:
  2829     assumes "0 < Re z & Re z < pi \<or>
  2830              Re z = 0 & 0 \<le> Im z \<or>
  2831              Re z = pi & Im z \<le> 0"
  2832       shows "Arccos(cos z) = z"
  2833 proof -
  2834   have *: "((\<i> - (exp (\<i> * z))\<^sup>2 * \<i>) / (2 * exp (\<i> * z))) = sin z"
  2835     by (simp add: sin_exp_eq exp_minus field_simps power2_eq_square)
  2836   have "1 - (exp (\<i> * z) + inverse (exp (\<i> * z)))\<^sup>2 / 4 = ((\<i> - (exp (\<i> * z))\<^sup>2 * \<i>) / (2 * exp (\<i> * z)))\<^sup>2"
  2837     by (simp add: field_simps power2_eq_square)
  2838   then have "Arccos(cos z) = - (\<i> * Ln ((exp (\<i> * z) + inverse (exp (\<i> * z))) / 2 +
  2839                            \<i> * csqrt (((\<i> - (exp (\<i> * z))\<^sup>2 * \<i>) / (2 * exp (\<i> * z)))\<^sup>2)))"
  2840     by (simp add: cos_exp_eq Arccos_def exp_minus power_divide)
  2841   also have "... = - (\<i> * Ln ((exp (\<i> * z) + inverse (exp (\<i> * z))) / 2 +
  2842                               \<i> * ((\<i> - (exp (\<i> * z))\<^sup>2 * \<i>) / (2 * exp (\<i> * z)))))"
  2843     apply (subst csqrt_square)
  2844     using assms Re_sin_pos [of z] Im_sin_nonneg [of z] Im_sin_nonneg2 [of z]
  2845     apply (auto simp: * Re_sin Im_sin)
  2846     done
  2847   also have "... =  - (\<i> * Ln (exp (\<i>*z)))"
  2848     by (simp add: field_simps power2_eq_square)
  2849   also have "... = z"
  2850     using assms
  2851     apply (subst Complex_Transcendental.Ln_exp, auto)
  2852     done
  2853   finally show ?thesis .
  2854 qed
  2855 
  2856 lemma Arccos_unique:
  2857     "\<lbrakk>cos z = w;
  2858       0 < Re z \<and> Re z < pi \<or>
  2859       Re z = 0 \<and> 0 \<le> Im z \<or>
  2860       Re z = pi \<and> Im z \<le> 0\<rbrakk> \<Longrightarrow> Arccos w = z"
  2861   using Arccos_cos by blast
  2862 
  2863 lemma Arccos_0 [simp]: "Arccos 0 = pi/2"
  2864   by (rule Arccos_unique) (auto simp: of_real_numeral)
  2865 
  2866 lemma Arccos_1 [simp]: "Arccos 1 = 0"
  2867   by (rule Arccos_unique) auto
  2868 
  2869 lemma Arccos_minus1: "Arccos(-1) = pi"
  2870   by (rule Arccos_unique) auto
  2871 
  2872 lemma has_field_derivative_Arccos:
  2873   assumes "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1)"
  2874     shows "(Arccos has_field_derivative - inverse(sin(Arccos z))) (at z)"
  2875 proof -
  2876   have "(cos (Arccos z))\<^sup>2 \<noteq> 1"
  2877     using assms
  2878     apply atomize
  2879     apply (auto simp: complex_eq_iff Re_power2 Im_power2 abs_square_eq_1)
  2880     apply (metis abs_minus_cancel abs_one abs_power2 numeral_One numeral_neq_neg_one)
  2881     apply (metis left_minus less_irrefl power_one sum_power2_gt_zero_iff zero_neq_neg_one)
  2882     done
  2883   then have "- sin (Arccos z) \<noteq> 0"
  2884     by (metis cos_squared_eq diff_0_right mult_zero_left neg_0_equal_iff_equal power2_eq_square)
  2885   then have "(Arccos has_field_derivative inverse(- sin(Arccos z))) (at z)"
  2886     apply (rule has_complex_derivative_inverse_basic [OF DERIV_cos _ _ open_ball [of z 1]])
  2887     apply (auto intro: isCont_Arccos assms)
  2888     done
  2889   then show ?thesis
  2890     by simp
  2891 qed
  2892 
  2893 declare has_field_derivative_Arcsin [derivative_intros]
  2894 declare has_field_derivative_Arcsin [THEN DERIV_chain2, derivative_intros]
  2895 
  2896 lemma field_differentiable_at_Arccos:
  2897     "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> Arccos field_differentiable at z"
  2898   using field_differentiable_def has_field_derivative_Arccos by blast
  2899 
  2900 lemma field_differentiable_within_Arccos:
  2901     "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> Arccos field_differentiable (at z within s)"
  2902   using field_differentiable_at_Arccos field_differentiable_within_subset by blast
  2903 
  2904 lemma continuous_within_Arccos:
  2905     "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> continuous (at z within s) Arccos"
  2906   using continuous_at_imp_continuous_within isCont_Arccos by blast
  2907 
  2908 lemma continuous_on_Arccos [continuous_intros]:
  2909     "(\<And>z. z \<in> s \<Longrightarrow> Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> continuous_on s Arccos"
  2910   by (simp add: continuous_at_imp_continuous_on)
  2911 
  2912 lemma holomorphic_on_Arccos: "(\<And>z. z \<in> s \<Longrightarrow> Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> Arccos holomorphic_on s"
  2913   by (simp add: field_differentiable_within_Arccos holomorphic_on_def)
  2914 
  2915 
  2916 subsection\<open>Upper and Lower Bounds for Inverse Sine and Cosine\<close>
  2917 
  2918 lemma Arcsin_bounds: "\<bar>Re z\<bar> < 1 \<Longrightarrow> \<bar>Re(Arcsin z)\<bar> < pi/2"
  2919   unfolding Re_Arcsin
  2920   by (blast intro: Re_Ln_pos_lt_imp Arcsin_range_lemma)
  2921 
  2922 lemma Arccos_bounds: "\<bar>Re z\<bar> < 1 \<Longrightarrow> 0 < Re(Arccos z) \<and> Re(Arccos z) < pi"
  2923   unfolding Re_Arccos
  2924   by (blast intro!: Im_Ln_pos_lt_imp Arccos_range_lemma)
  2925 
  2926 lemma Re_Arccos_bounds: "-pi < Re(Arccos z) \<and> Re(Arccos z) \<le> pi"
  2927   unfolding Re_Arccos
  2928   by (blast intro!: mpi_less_Im_Ln Im_Ln_le_pi Arccos_body_lemma)
  2929 
  2930 lemma Re_Arccos_bound: "\<bar>Re(Arccos z)\<bar> \<le> pi"
  2931   by (meson Re_Arccos_bounds abs_le_iff less_eq_real_def minus_less_iff)
  2932 
  2933 lemma Im_Arccos_bound: "\<bar>Im (Arccos w)\<bar> \<le> cmod w"
  2934 proof -
  2935   have "(Im (Arccos w))\<^sup>2 \<le> (cmod (cos (Arccos w)))\<^sup>2 - (cos (Re (Arccos w)))\<^sup>2"
  2936     using norm_cos_squared [of "Arccos w"] real_le_abs_sinh [of "Im (Arccos w)"]
  2937     apply (simp only: abs_le_square_iff)
  2938     apply (simp add: divide_simps)
  2939     done
  2940   also have "... \<le> (cmod w)\<^sup>2"
  2941     by (auto simp: cmod_power2)
  2942   finally show ?thesis
  2943     using abs_le_square_iff by force
  2944 qed
  2945 
  2946 lemma Re_Arcsin_bounds: "-pi < Re(Arcsin z) & Re(Arcsin z) \<le> pi"
  2947   unfolding Re_Arcsin
  2948   by (blast intro!: mpi_less_Im_Ln Im_Ln_le_pi Arcsin_body_lemma)
  2949 
  2950 lemma Re_Arcsin_bound: "\<bar>Re(Arcsin z)\<bar> \<le> pi"
  2951   by (meson Re_Arcsin_bounds abs_le_iff less_eq_real_def minus_less_iff)
  2952 
  2953 lemma norm_Arccos_bounded:
  2954   fixes w :: complex
  2955   shows "norm (Arccos w) \<le> pi + norm w"
  2956 proof -
  2957   have Re: "(Re (Arccos w))\<^sup>2 \<le> pi\<^sup>2" "(Im (Arccos w))\<^sup>2 \<le> (cmod w)\<^sup>2"
  2958     using Re_Arccos_bound [of w] Im_Arccos_bound [of w] abs_le_square_iff by force+
  2959   have "Arccos w \<bullet> Arccos w \<le> pi\<^sup>2 + (cmod w)\<^sup>2"
  2960     using Re by (simp add: dot_square_norm cmod_power2 [of "Arccos w"])
  2961   then have "cmod (Arccos w) \<le> pi + cmod (cos (Arccos w))"
  2962     apply (simp add: norm_le_square)
  2963     by (metis dot_square_norm norm_ge_zero norm_le_square pi_ge_zero triangle_lemma)
  2964   then show "cmod (Arccos w) \<le> pi + cmod w"
  2965     by auto
  2966 qed
  2967 
  2968 
  2969 subsection\<open>Interrelations between Arcsin and Arccos\<close>
  2970 
  2971 lemma cos_Arcsin_nonzero:
  2972   assumes "z\<^sup>2 \<noteq> 1" shows "cos(Arcsin z) \<noteq> 0"
  2973 proof -
  2974   have eq: "(\<i> * z * (csqrt (1 - z\<^sup>2)))\<^sup>2 = z\<^sup>2 * (z\<^sup>2 - 1)"
  2975     by (simp add: power_mult_distrib algebra_simps)
  2976   have "\<i> * z * (csqrt (1 - z\<^sup>2)) \<noteq> z\<^sup>2 - 1"
  2977   proof
  2978     assume "\<i> * z * (csqrt (1 - z\<^sup>2)) = z\<^sup>2 - 1"
  2979     then have "(\<i> * z * (csqrt (1 - z\<^sup>2)))\<^sup>2 = (z\<^sup>2 - 1)\<^sup>2"
  2980       by simp
  2981     then have "z\<^sup>2 * (z\<^sup>2 - 1) = (z\<^sup>2 - 1)*(z\<^sup>2 - 1)"
  2982       using eq power2_eq_square by auto
  2983     then show False
  2984       using assms by simp
  2985   qed
  2986   then have "1 + \<i> * z * (csqrt (1 - z * z)) \<noteq> z\<^sup>2"
  2987     by (metis add_minus_cancel power2_eq_square uminus_add_conv_diff)
  2988   then have "2*(1 + \<i> * z * (csqrt (1 - z * z))) \<noteq> 2*z\<^sup>2"  (*FIXME cancel_numeral_factor*)
  2989     by (metis mult_cancel_left zero_neq_numeral)
  2990   then have "(\<i> * z + csqrt (1 - z\<^sup>2))\<^sup>2 \<noteq> -1"
  2991     using assms
  2992     apply (auto simp: power2_sum)
  2993     apply (simp add: power2_eq_square algebra_simps)
  2994     done
  2995   then show ?thesis
  2996     apply (simp add: cos_exp_eq Arcsin_def exp_minus)
  2997     apply (simp add: divide_simps Arcsin_body_lemma)
  2998     apply (metis add.commute minus_unique power2_eq_square)
  2999     done
  3000 qed
  3001 
  3002 lemma sin_Arccos_nonzero:
  3003   assumes "z\<^sup>2 \<noteq> 1" shows "sin(Arccos z) \<noteq> 0"
  3004 proof -
  3005   have eq: "(\<i> * z * (csqrt (1 - z\<^sup>2)))\<^sup>2 = -(z\<^sup>2) * (1 - z\<^sup>2)"
  3006     by (simp add: power_mult_distrib algebra_simps)
  3007   have "\<i> * z * (csqrt (1 - z\<^sup>2)) \<noteq> 1 - z\<^sup>2"
  3008   proof
  3009     assume "\<i> * z * (csqrt (1 - z\<^sup>2)) = 1 - z\<^sup>2"
  3010     then have "(\<i> * z * (csqrt (1 - z\<^sup>2)))\<^sup>2 = (1 - z\<^sup>2)\<^sup>2"
  3011       by simp
  3012     then have "-(z\<^sup>2) * (1 - z\<^sup>2) = (1 - z\<^sup>2)*(1 - z\<^sup>2)"
  3013       using eq power2_eq_square by auto
  3014     then have "-(z\<^sup>2) = (1 - z\<^sup>2)"
  3015       using assms
  3016       by (metis add.commute add.right_neutral diff_add_cancel mult_right_cancel)
  3017     then show False
  3018       using assms by simp
  3019   qed
  3020   then have "z\<^sup>2 + \<i> * z * (csqrt (1 - z\<^sup>2)) \<noteq> 1"
  3021     by (simp add: algebra_simps)
  3022   then have "2*(z\<^sup>2 + \<i> * z * (csqrt (1 - z\<^sup>2))) \<noteq> 2*1"
  3023     by (metis mult_cancel_left2 zero_neq_numeral)  (*FIXME cancel_numeral_factor*)
  3024   then have "(z + \<i> * csqrt (1 - z\<^sup>2))\<^sup>2 \<noteq> 1"
  3025     using assms
  3026     apply (auto simp: Power.comm_semiring_1_class.power2_sum power_mult_distrib)
  3027     apply (simp add: power2_eq_square algebra_simps)
  3028     done
  3029   then show ?thesis
  3030     apply (simp add: sin_exp_eq Arccos_def exp_minus)
  3031     apply (simp add: divide_simps Arccos_body_lemma)
  3032     apply (simp add: power2_eq_square)
  3033     done
  3034 qed
  3035 
  3036 lemma cos_sin_csqrt:
  3037   assumes "0 < cos(Re z)  \<or>  cos(Re z) = 0 \<and> Im z * sin(Re z) \<le> 0"
  3038     shows "cos z = csqrt(1 - (sin z)\<^sup>2)"
  3039   apply (rule csqrt_unique [THEN sym])
  3040   apply (simp add: cos_squared_eq)
  3041   using assms
  3042   apply (auto simp: Re_cos Im_cos add_pos_pos mult_le_0_iff zero_le_mult_iff)
  3043   done
  3044 
  3045 lemma sin_cos_csqrt:
  3046   assumes "0 < sin(Re z)  \<or>  sin(Re z) = 0 \<and> 0 \<le> Im z * cos(Re z)"
  3047     shows "sin z = csqrt(1 - (cos z)\<^sup>2)"
  3048   apply (rule csqrt_unique [THEN sym])
  3049   apply (simp add: sin_squared_eq)
  3050   using assms
  3051   apply (auto simp: Re_sin Im_sin add_pos_pos mult_le_0_iff zero_le_mult_iff)
  3052   done
  3053 
  3054 lemma Arcsin_Arccos_csqrt_pos:
  3055     "(0 < Re z | Re z = 0 & 0 \<le> Im z) \<Longrightarrow> Arcsin z = Arccos(csqrt(1 - z\<^sup>2))"
  3056   by (simp add: Arcsin_def Arccos_def Complex.csqrt_square add.commute)
  3057 
  3058 lemma Arccos_Arcsin_csqrt_pos:
  3059     "(0 < Re z | Re z = 0 & 0 \<le> Im z) \<Longrightarrow> Arccos z = Arcsin(csqrt(1 - z\<^sup>2))"
  3060   by (simp add: Arcsin_def Arccos_def Complex.csqrt_square add.commute)
  3061 
  3062 lemma sin_Arccos:
  3063     "0 < Re z | Re z = 0 & 0 \<le> Im z \<Longrightarrow> sin(Arccos z) = csqrt(1 - z\<^sup>2)"
  3064   by (simp add: Arccos_Arcsin_csqrt_pos)
  3065 
  3066 lemma cos_Arcsin:
  3067     "0 < Re z | Re z = 0 & 0 \<le> Im z \<Longrightarrow> cos(Arcsin z) = csqrt(1 - z\<^sup>2)"
  3068   by (simp add: Arcsin_Arccos_csqrt_pos)
  3069 
  3070 
  3071 subsection\<open>Relationship with Arcsin on the Real Numbers\<close>
  3072 
  3073 lemma Im_Arcsin_of_real:
  3074   assumes "\<bar>x\<bar> \<le> 1"
  3075     shows "Im (Arcsin (of_real x)) = 0"
  3076 proof -
  3077   have "csqrt (1 - (of_real x)\<^sup>2) = (if x^2 \<le> 1 then sqrt (1 - x^2) else \<i> * sqrt (x^2 - 1))"
  3078     by (simp add: of_real_sqrt del: csqrt_of_real_nonneg)
  3079   then have "cmod (\<i> * of_real x + csqrt (1 - (of_real x)\<^sup>2))^2 = 1"
  3080     using assms abs_square_le_1
  3081     by (force simp add: Complex.cmod_power2)
  3082   then have "cmod (\<i> * of_real x + csqrt (1 - (of_real x)\<^sup>2)) = 1"
  3083     by (simp add: norm_complex_def)
  3084   then show ?thesis
  3085     by (simp add: Im_Arcsin exp_minus)
  3086 qed
  3087 
  3088 corollary Arcsin_in_Reals [simp]: "z \<in> \<real> \<Longrightarrow> \<bar>Re z\<bar> \<le> 1 \<Longrightarrow> Arcsin z \<in> \<real>"
  3089   by (metis Im_Arcsin_of_real Re_complex_of_real Reals_cases complex_is_Real_iff)
  3090 
  3091 lemma arcsin_eq_Re_Arcsin:
  3092   assumes "\<bar>x\<bar> \<le> 1"
  3093     shows "arcsin x = Re (Arcsin (of_real x))"
  3094 unfolding arcsin_def
  3095 proof (rule the_equality, safe)
  3096   show "- (pi / 2) \<le> Re (Arcsin (complex_of_real x))"
  3097     using Re_Ln_pos_le [OF Arcsin_body_lemma, of "of_real x"]
  3098     by (auto simp: Complex.in_Reals_norm Re_Arcsin)
  3099 next
  3100   show "Re (Arcsin (complex_of_real x)) \<le> pi / 2"
  3101     using Re_Ln_pos_le [OF Arcsin_body_lemma, of "of_real x"]
  3102     by (auto simp: Complex.in_Reals_norm Re_Arcsin)
  3103 next
  3104   show "sin (Re (Arcsin (complex_of_real x))) = x"
  3105     using Re_sin [of "Arcsin (of_real x)"] Arcsin_body_lemma [of "of_real x"]
  3106     by (simp add: Im_Arcsin_of_real assms)
  3107 next
  3108   fix x'
  3109   assume "- (pi / 2) \<le> x'" "x' \<le> pi / 2" "x = sin x'"
  3110   then show "x' = Re (Arcsin (complex_of_real (sin x')))"
  3111     apply (simp add: sin_of_real [symmetric])
  3112     apply (subst Arcsin_sin)
  3113     apply (auto simp: )
  3114     done
  3115 qed
  3116 
  3117 lemma of_real_arcsin: "\<bar>x\<bar> \<le> 1 \<Longrightarrow> of_real(arcsin x) = Arcsin(of_real x)"
  3118   by (metis Im_Arcsin_of_real add.right_neutral arcsin_eq_Re_Arcsin complex_eq mult_zero_right of_real_0)
  3119 
  3120 
  3121 subsection\<open>Relationship with Arccos on the Real Numbers\<close>
  3122 
  3123 lemma Im_Arccos_of_real:
  3124   assumes "\<bar>x\<bar> \<le> 1"
  3125     shows "Im (Arccos (of_real x)) = 0"
  3126 proof -
  3127   have "csqrt (1 - (of_real x)\<^sup>2) = (if x^2 \<le> 1 then sqrt (1 - x^2) else \<i> * sqrt (x^2 - 1))"
  3128     by (simp add: of_real_sqrt del: csqrt_of_real_nonneg)
  3129   then have "cmod (of_real x + \<i> * csqrt (1 - (of_real x)\<^sup>2))^2 = 1"
  3130     using assms abs_square_le_1
  3131     by (force simp add: Complex.cmod_power2)
  3132   then have "cmod (of_real x + \<i> * csqrt (1 - (of_real x)\<^sup>2)) = 1"
  3133     by (simp add: norm_complex_def)
  3134   then show ?thesis
  3135     by (simp add: Im_Arccos exp_minus)
  3136 qed
  3137 
  3138 corollary Arccos_in_Reals [simp]: "z \<in> \<real> \<Longrightarrow> \<bar>Re z\<bar> \<le> 1 \<Longrightarrow> Arccos z \<in> \<real>"
  3139   by (metis Im_Arccos_of_real Re_complex_of_real Reals_cases complex_is_Real_iff)
  3140 
  3141 lemma arccos_eq_Re_Arccos:
  3142   assumes "\<bar>x\<bar> \<le> 1"
  3143     shows "arccos x = Re (Arccos (of_real x))"
  3144 unfolding arccos_def
  3145 proof (rule the_equality, safe)
  3146   show "0 \<le> Re (Arccos (complex_of_real x))"
  3147     using Im_Ln_pos_le [OF Arccos_body_lemma, of "of_real x"]
  3148     by (auto simp: Complex.in_Reals_norm Re_Arccos)
  3149 next
  3150   show "Re (Arccos (complex_of_real x)) \<le> pi"
  3151     using Im_Ln_pos_le [OF Arccos_body_lemma, of "of_real x"]
  3152     by (auto simp: Complex.in_Reals_norm Re_Arccos)
  3153 next
  3154   show "cos (Re (Arccos (complex_of_real x))) = x"
  3155     using Re_cos [of "Arccos (of_real x)"] Arccos_body_lemma [of "of_real x"]
  3156     by (simp add: Im_Arccos_of_real assms)
  3157 next
  3158   fix x'
  3159   assume "0 \<le> x'" "x' \<le> pi" "x = cos x'"
  3160   then show "x' = Re (Arccos (complex_of_real (cos x')))"
  3161     apply (simp add: cos_of_real [symmetric])
  3162     apply (subst Arccos_cos)
  3163     apply (auto simp: )
  3164     done
  3165 qed
  3166 
  3167 lemma of_real_arccos: "\<bar>x\<bar> \<le> 1 \<Longrightarrow> of_real(arccos x) = Arccos(of_real x)"
  3168   by (metis Im_Arccos_of_real add.right_neutral arccos_eq_Re_Arccos complex_eq mult_zero_right of_real_0)
  3169 
  3170 subsection\<open>Some interrelationships among the real inverse trig functions.\<close>
  3171 
  3172 lemma arccos_arctan:
  3173   assumes "-1 < x" "x < 1"
  3174     shows "arccos x = pi/2 - arctan(x / sqrt(1 - x\<^sup>2))"
  3175 proof -
  3176   have "arctan(x / sqrt(1 - x\<^sup>2)) - (pi/2 - arccos x) = 0"
  3177   proof (rule sin_eq_0_pi)
  3178     show "- pi < arctan (x / sqrt (1 - x\<^sup>2)) - (pi / 2 - arccos x)"
  3179       using arctan_lbound [of "x / sqrt(1 - x\<^sup>2)"]  arccos_bounded [of x] assms
  3180       by (simp add: algebra_simps)
  3181   next
  3182     show "arctan (x / sqrt (1 - x\<^sup>2)) - (pi / 2 - arccos x) < pi"
  3183       using arctan_ubound [of "x / sqrt(1 - x\<^sup>2)"]  arccos_bounded [of x] assms
  3184       by (simp add: algebra_simps)
  3185   next
  3186     show "sin (arctan (x / sqrt (1 - x\<^sup>2)) - (pi / 2 - arccos x)) = 0"
  3187       using assms
  3188       by (simp add: algebra_simps sin_diff cos_add sin_arccos sin_arctan cos_arctan
  3189                     power2_eq_square square_eq_1_iff)
  3190   qed
  3191   then show ?thesis
  3192     by simp
  3193 qed
  3194 
  3195 lemma arcsin_plus_arccos:
  3196   assumes "-1 \<le> x" "x \<le> 1"
  3197     shows "arcsin x + arccos x = pi/2"
  3198 proof -
  3199   have "arcsin x = pi/2 - arccos x"
  3200     apply (rule sin_inj_pi)
  3201     using assms arcsin [OF assms] arccos [OF assms]
  3202     apply (auto simp: algebra_simps sin_diff)
  3203     done
  3204   then show ?thesis
  3205     by (simp add: algebra_simps)
  3206 qed
  3207 
  3208 lemma arcsin_arccos_eq: "-1 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> arcsin x = pi/2 - arccos x"
  3209   using arcsin_plus_arccos by force
  3210 
  3211 lemma arccos_arcsin_eq: "-1 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> arccos x = pi/2 - arcsin x"
  3212   using arcsin_plus_arccos by force
  3213 
  3214 lemma arcsin_arctan: "-1 < x \<Longrightarrow> x < 1 \<Longrightarrow> arcsin x = arctan(x / sqrt(1 - x\<^sup>2))"
  3215   by (simp add: arccos_arctan arcsin_arccos_eq)
  3216 
  3217 lemma csqrt_1_diff_eq: "csqrt (1 - (of_real x)\<^sup>2) = (if x^2 \<le> 1 then sqrt (1 - x^2) else \<i> * sqrt (x^2 - 1))"
  3218   by ( simp add: of_real_sqrt del: csqrt_of_real_nonneg)
  3219 
  3220 lemma arcsin_arccos_sqrt_pos: "0 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> arcsin x = arccos(sqrt(1 - x\<^sup>2))"
  3221   apply (simp add: abs_square_le_1 arcsin_eq_Re_Arcsin arccos_eq_Re_Arccos)
  3222   apply (subst Arcsin_Arccos_csqrt_pos)
  3223   apply (auto simp: power_le_one csqrt_1_diff_eq)
  3224   done
  3225 
  3226 lemma arcsin_arccos_sqrt_neg: "-1 \<le> x \<Longrightarrow> x \<le> 0 \<Longrightarrow> arcsin x = -arccos(sqrt(1 - x\<^sup>2))"
  3227   using arcsin_arccos_sqrt_pos [of "-x"]
  3228   by (simp add: arcsin_minus)
  3229 
  3230 lemma arccos_arcsin_sqrt_pos: "0 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> arccos x = arcsin(sqrt(1 - x\<^sup>2))"
  3231   apply (simp add: abs_square_le_1 arcsin_eq_Re_Arcsin arccos_eq_Re_Arccos)
  3232   apply (subst Arccos_Arcsin_csqrt_pos)
  3233   apply (auto simp: power_le_one csqrt_1_diff_eq)
  3234   done
  3235 
  3236 lemma arccos_arcsin_sqrt_neg: "-1 \<le> x \<Longrightarrow> x \<le> 0 \<Longrightarrow> arccos x = pi - arcsin(sqrt(1 - x\<^sup>2))"
  3237   using arccos_arcsin_sqrt_pos [of "-x"]
  3238   by (simp add: arccos_minus)
  3239 
  3240 subsection\<open>continuity results for arcsin and arccos.\<close>
  3241 
  3242 lemma continuous_on_Arcsin_real [continuous_intros]:
  3243     "continuous_on {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1} Arcsin"
  3244 proof -
  3245   have "continuous_on {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1} (\<lambda>x. complex_of_real (arcsin (Re x))) =
  3246         continuous_on {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1} (\<lambda>x. complex_of_real (Re (Arcsin (of_real (Re x)))))"
  3247     by (rule continuous_on_cong [OF refl]) (simp add: arcsin_eq_Re_Arcsin)
  3248   also have "... = ?thesis"
  3249     by (rule continuous_on_cong [OF refl]) simp
  3250   finally show ?thesis
  3251     using continuous_on_arcsin [OF continuous_on_Re [OF continuous_on_id], of "{w \<in> \<real>. \<bar>Re w\<bar> \<le> 1}"]
  3252           continuous_on_of_real
  3253     by fastforce
  3254 qed
  3255 
  3256 lemma continuous_within_Arcsin_real:
  3257     "continuous (at z within {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1}) Arcsin"
  3258 proof (cases "z \<in> {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1}")
  3259   case True then show ?thesis
  3260     using continuous_on_Arcsin_real continuous_on_eq_continuous_within
  3261     by blast
  3262 next
  3263   case False
  3264   with closed_real_abs_le [of 1] show ?thesis
  3265     by (rule continuous_within_closed_nontrivial)
  3266 qed
  3267 
  3268 lemma continuous_on_Arccos_real:
  3269     "continuous_on {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1} Arccos"
  3270 proof -
  3271   have "continuous_on {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1} (\<lambda>x. complex_of_real (arccos (Re x))) =
  3272         continuous_on {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1} (\<lambda>x. complex_of_real (Re (Arccos (of_real (Re x)))))"
  3273     by (rule continuous_on_cong [OF refl]) (simp add: arccos_eq_Re_Arccos)
  3274   also have "... = ?thesis"
  3275     by (rule continuous_on_cong [OF refl]) simp
  3276   finally show ?thesis
  3277     using continuous_on_arccos [OF continuous_on_Re [OF continuous_on_id], of "{w \<in> \<real>. \<bar>Re w\<bar> \<le> 1}"]
  3278           continuous_on_of_real
  3279     by fastforce
  3280 qed
  3281 
  3282 lemma continuous_within_Arccos_real:
  3283     "continuous (at z within {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1}) Arccos"
  3284 proof (cases "z \<in> {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1}")
  3285   case True then show ?thesis
  3286     using continuous_on_Arccos_real continuous_on_eq_continuous_within
  3287     by blast
  3288 next
  3289   case False
  3290   with closed_real_abs_le [of 1] show ?thesis
  3291     by (rule continuous_within_closed_nontrivial)
  3292 qed
  3293 
  3294 
  3295 subsection\<open>Roots of unity\<close>
  3296 
  3297 lemma complex_root_unity:
  3298   fixes j::nat
  3299   assumes "n \<noteq> 0"
  3300     shows "exp(2 * of_real pi * \<i> * of_nat j / of_nat n)^n = 1"
  3301 proof -
  3302   have *: "of_nat j * (complex_of_real pi * 2) = complex_of_real (2 * real j * pi)"
  3303     by (simp add: of_real_numeral)
  3304   then show ?thesis
  3305     apply (simp add: exp_of_nat_mult [symmetric] mult_ac exp_Euler)
  3306     apply (simp only: * cos_of_real sin_of_real)
  3307     apply (simp add: )
  3308     done
  3309 qed
  3310 
  3311 lemma complex_root_unity_eq:
  3312   fixes j::nat and k::nat
  3313   assumes "1 \<le> n"
  3314     shows "(exp(2 * of_real pi * \<i> * of_nat j / of_nat n) = exp(2 * of_real pi * \<i> * of_nat k / of_nat n)
  3315            \<longleftrightarrow> j mod n = k mod n)"
  3316 proof -
  3317     have "(\<exists>z::int. \<i> * (of_nat j * (of_real pi * 2)) =
  3318                \<i> * (of_nat k * (of_real pi * 2)) + \<i> * (of_int z * (of_nat n * (of_real pi * 2)))) \<longleftrightarrow>
  3319           (\<exists>z::int. of_nat j * (\<i> * (of_real pi * 2)) =
  3320               (of_nat k + of_nat n * of_int z) * (\<i> * (of_real pi * 2)))"
  3321       by (simp add: algebra_simps)
  3322     also have "... \<longleftrightarrow> (\<exists>z::int. of_nat j = of_nat k + of_nat n * (of_int z :: complex))"
  3323       by simp
  3324     also have "... \<longleftrightarrow> (\<exists>z::int. of_nat j = of_nat k + of_nat n * z)"
  3325       apply (rule HOL.iff_exI)
  3326       apply (auto simp: )
  3327       using of_int_eq_iff apply fastforce
  3328       by (metis of_int_add of_int_mult of_int_of_nat_eq)
  3329     also have "... \<longleftrightarrow> int j mod int n = int k mod int n"
  3330       by (auto simp: mod_eq_dvd_iff dvd_def algebra_simps)
  3331     also have "... \<longleftrightarrow> j mod n = k mod n"
  3332       by (metis of_nat_eq_iff zmod_int)
  3333     finally have "(\<exists>z. \<i> * (of_nat j * (of_real pi * 2)) =
  3334              \<i> * (of_nat k * (of_real pi * 2)) + \<i> * (of_int z * (of_nat n * (of_real pi * 2)))) \<longleftrightarrow> j mod n = k mod n" .
  3335    note * = this
  3336   show ?thesis
  3337     using assms
  3338     by (simp add: exp_eq divide_simps mult_ac of_real_numeral *)
  3339 qed
  3340 
  3341 corollary bij_betw_roots_unity:
  3342     "bij_betw (\<lambda>j. exp(2 * of_real pi * \<i> * of_nat j / of_nat n))
  3343               {..<n}  {exp(2 * of_real pi * \<i> * of_nat j / of_nat n) | j. j < n}"
  3344   by (auto simp: bij_betw_def inj_on_def complex_root_unity_eq)
  3345 
  3346 lemma complex_root_unity_eq_1:
  3347   fixes j::nat and k::nat
  3348   assumes "1 \<le> n"
  3349     shows "exp(2 * of_real pi * \<i> * of_nat j / of_nat n) = 1 \<longleftrightarrow> n dvd j"
  3350 proof -
  3351   have "1 = exp(2 * of_real pi * \<i> * (of_nat n / of_nat n))"
  3352     using assms by simp
  3353   then have "exp(2 * of_real pi * \<i> * (of_nat j / of_nat n)) = 1 \<longleftrightarrow> j mod n = n mod n"
  3354      using complex_root_unity_eq [of n j n] assms
  3355      by simp
  3356   then show ?thesis
  3357     by auto
  3358 qed
  3359 
  3360 lemma finite_complex_roots_unity_explicit:
  3361      "finite {exp(2 * of_real pi * \<i> * of_nat j / of_nat n) | j::nat. j < n}"
  3362 by simp
  3363 
  3364 lemma card_complex_roots_unity_explicit:
  3365      "card {exp(2 * of_real pi * \<i> * of_nat j / of_nat n) | j::nat. j < n} = n"
  3366   by (simp add:  Finite_Set.bij_betw_same_card [OF bij_betw_roots_unity, symmetric])
  3367 
  3368 lemma complex_roots_unity:
  3369   assumes "1 \<le> n"
  3370     shows "{z::complex. z^n = 1} = {exp(2 * of_real pi * \<i> * of_nat j / of_nat n) | j::nat. j < n}"
  3371   apply (rule Finite_Set.card_seteq [symmetric])
  3372   using assms
  3373   apply (auto simp: card_complex_roots_unity_explicit finite_roots_unity complex_root_unity card_roots_unity)
  3374   done
  3375 
  3376 lemma card_complex_roots_unity: "1 \<le> n \<Longrightarrow> card {z::complex. z^n = 1} = n"
  3377   by (simp add: card_complex_roots_unity_explicit complex_roots_unity)
  3378 
  3379 lemma complex_not_root_unity:
  3380     "1 \<le> n \<Longrightarrow> \<exists>u::complex. norm u = 1 \<and> u^n \<noteq> 1"
  3381   apply (rule_tac x="exp (of_real pi * \<i> * of_real (1 / n))" in exI)
  3382   apply (auto simp: Re_complex_div_eq_0 exp_of_nat_mult [symmetric] mult_ac exp_Euler)
  3383   done
  3384 
  3385 subsection\<open> Formulation of loop homotopy in terms of maps out of type complex\<close>
  3386 
  3387 lemma homotopic_circlemaps_imp_homotopic_loops:
  3388   assumes "homotopic_with (\<lambda>h. True) (sphere 0 1) S f g"
  3389    shows "homotopic_loops S (f \<circ> exp \<circ> (\<lambda>t. 2 * of_real pi * of_real t * \<i>))
  3390                             (g \<circ> exp \<circ> (\<lambda>t. 2 * of_real pi * of_real t * \<i>))"
  3391 proof -
  3392   have "homotopic_with (\<lambda>f. True) {z. cmod z = 1} S f g"
  3393     using assms by (auto simp: sphere_def)
  3394   moreover have "continuous_on {0..1} (exp \<circ> (\<lambda>t. 2 * of_real pi * of_real t * \<i>))"
  3395      by (intro continuous_intros)
  3396   moreover have "(exp \<circ> (\<lambda>t. 2 * of_real pi * of_real t * \<i>)) ` {0..1} \<subseteq> {z. cmod z = 1}"
  3397     by (auto simp: norm_mult)
  3398   ultimately
  3399   show ?thesis
  3400     apply (simp add: homotopic_loops_def comp_assoc)
  3401     apply (rule homotopic_with_compose_continuous_right)
  3402       apply (auto simp: pathstart_def pathfinish_def)
  3403     done
  3404 qed
  3405 
  3406 lemma homotopic_loops_imp_homotopic_circlemaps:
  3407   assumes "homotopic_loops S p q"
  3408     shows "homotopic_with (\<lambda>h. True) (sphere 0 1) S
  3409                           (p \<circ> (\<lambda>z. (Arg z / (2 * pi))))
  3410                           (q \<circ> (\<lambda>z. (Arg z / (2 * pi))))"
  3411 proof -
  3412   obtain h where conth: "continuous_on ({0..1::real} \<times> {0..1}) h"
  3413              and him: "h ` ({0..1} \<times> {0..1}) \<subseteq> S"
  3414              and h0: "(\<forall>x. h (0, x) = p x)"
  3415              and h1: "(\<forall>x. h (1, x) = q x)"
  3416              and h01: "(\<forall>t\<in>{0..1}. h (t, 1) = h (t, 0)) "
  3417     using assms
  3418     by (auto simp: homotopic_loops_def sphere_def homotopic_with_def pathstart_def pathfinish_def)
  3419   define j where "j \<equiv> \<lambda>z. if 0 \<le> Im (snd z)
  3420                           then h (fst z, Arg (snd z) / (2 * pi))
  3421                           else h (fst z, 1 - Arg (cnj (snd z)) / (2 * pi))"
  3422   have Arg_eq: "1 - Arg (cnj y) / (2 * pi) = Arg y / (2 * pi) \<or> Arg y = 0 \<and> Arg (cnj y) = 0" if "cmod y = 1" for y
  3423     using that Arg_eq_0_pi Arg_eq_pi by (force simp: Arg_cnj divide_simps)
  3424   show ?thesis
  3425   proof (simp add: homotopic_with; intro conjI ballI exI)
  3426     show "continuous_on ({0..1} \<times> sphere 0 1) (\<lambda>w. h (fst w, Arg (snd w) / (2 * pi)))"
  3427     proof (rule continuous_on_eq)
  3428       show j: "j x = h (fst x, Arg (snd x) / (2 * pi))" if "x \<in> {0..1} \<times> sphere 0 1" for x
  3429         using Arg_eq that h01 by (force simp: j_def)
  3430       have eq:  "S = S \<inter> (UNIV \<times> {z. 0 \<le> Im z}) \<union> S \<inter> (UNIV \<times> {z. Im z \<le> 0})" for S :: "(real*complex)set"
  3431         by auto
  3432       have c1: "continuous_on ({0..1} \<times> sphere 0 1 \<inter> UNIV \<times> {z. 0 \<le> Im z}) (\<lambda>x. h (fst x, Arg (snd x) / (2 * pi)))"
  3433         apply (intro continuous_intros continuous_on_compose2 [OF conth]  continuous_on_compose2 [OF continuous_on_upperhalf_Arg])
  3434             apply (auto simp: Arg)
  3435         apply (meson Arg_lt_2pi linear not_le)
  3436         done
  3437       have c2: "continuous_on ({0..1} \<times> sphere 0 1 \<inter> UNIV \<times> {z. Im z \<le> 0}) (\<lambda>x. h (fst x, 1 - Arg (cnj (snd x)) / (2 * pi)))"
  3438         apply (intro continuous_intros continuous_on_compose2 [OF conth]  continuous_on_compose2 [OF continuous_on_upperhalf_Arg])
  3439             apply (auto simp: Arg)
  3440         apply (meson Arg_lt_2pi linear not_le)
  3441         done
  3442       show "continuous_on ({0..1} \<times> sphere 0 1) j"
  3443         apply (simp add: j_def)
  3444         apply (subst eq)
  3445         apply (rule continuous_on_cases_local)
  3446             apply (simp_all add: eq [symmetric] closedin_closed_Int closed_Times closed_halfspace_Im_le closed_halfspace_Im_ge c1 c2)
  3447         using Arg_eq h01
  3448         by force
  3449     qed
  3450     have "(\<lambda>w. h (fst w, Arg (snd w) / (2 * pi))) ` ({0..1} \<times> sphere 0 1) \<subseteq> h ` ({0..1} \<times> {0..1})"
  3451       by (auto simp: Arg_ge_0 Arg_lt_2pi less_imp_le)
  3452     also have "... \<subseteq> S"
  3453       using him by blast
  3454     finally show "(\<lambda>w. h (fst w, Arg (snd w) / (2 * pi))) ` ({0..1} \<times> sphere 0 1) \<subseteq> S" .
  3455   qed (auto simp: h0 h1)
  3456 qed
  3457 
  3458 lemma simply_connected_homotopic_loops:
  3459   "simply_connected S \<longleftrightarrow>
  3460        (\<forall>p q. homotopic_loops S p p \<and> homotopic_loops S q q \<longrightarrow> homotopic_loops S p q)"
  3461 unfolding simply_connected_def using homotopic_loops_refl by metis
  3462 
  3463 
  3464 lemma simply_connected_eq_homotopic_circlemaps1:
  3465   fixes f :: "complex \<Rightarrow> 'a::topological_space" and g :: "complex \<Rightarrow> 'a"
  3466   assumes S: "simply_connected S"
  3467       and contf: "continuous_on (sphere 0 1) f" and fim: "f ` (sphere 0 1) \<subseteq> S"
  3468       and contg: "continuous_on (sphere 0 1) g" and gim: "g ` (sphere 0 1) \<subseteq> S"
  3469     shows "homotopic_with (\<lambda>h. True) (sphere 0 1) S f g"
  3470 proof -
  3471   have "homotopic_loops S (f \<circ> exp \<circ> (\<lambda>t. of_real(2 * pi * t) * \<i>)) (g \<circ> exp \<circ> (\<lambda>t. of_real(2 * pi *  t) * \<i>))"
  3472     apply (rule S [unfolded simply_connected_homotopic_loops, rule_format])
  3473     apply (simp add: homotopic_circlemaps_imp_homotopic_loops homotopic_with_refl contf fim contg gim)
  3474     done
  3475   then show ?thesis
  3476     apply (rule homotopic_with_eq [OF homotopic_loops_imp_homotopic_circlemaps])
  3477       apply (auto simp: o_def complex_norm_eq_1_exp mult.commute)
  3478     done
  3479 qed
  3480 
  3481 lemma simply_connected_eq_homotopic_circlemaps2a:
  3482   fixes h :: "complex \<Rightarrow> 'a::topological_space"
  3483   assumes conth: "continuous_on (sphere 0 1) h" and him: "h ` (sphere 0 1) \<subseteq> S"
  3484       and hom: "\<And>f g::complex \<Rightarrow> 'a.
  3485                 \<lbrakk>continuous_on (sphere 0 1) f; f ` (sphere 0 1) \<subseteq> S;
  3486                 continuous_on (sphere 0 1) g; g ` (sphere 0 1) \<subseteq> S\<rbrakk>
  3487                 \<Longrightarrow> homotopic_with (\<lambda>h. True) (sphere 0 1) S f g"
  3488             shows "\<exists>a. homotopic_with (\<lambda>h. True) (sphere 0 1) S h (\<lambda>x. a)"
  3489     apply (rule_tac x="h 1" in exI)
  3490     apply (rule hom)
  3491     using assms
  3492     by (auto simp: continuous_on_const)
  3493 
  3494 lemma simply_connected_eq_homotopic_circlemaps2b:
  3495   fixes S :: "'a::real_normed_vector set"
  3496   assumes "\<And>f g::complex \<Rightarrow> 'a.
  3497                 \<lbrakk>continuous_on (sphere 0 1) f; f ` (sphere 0 1) \<subseteq> S;
  3498                 continuous_on (sphere 0 1) g; g ` (sphere 0 1) \<subseteq> S\<rbrakk>
  3499                 \<Longrightarrow> homotopic_with (\<lambda>h. True) (sphere 0 1) S f g"
  3500   shows "path_connected S"
  3501 proof (clarsimp simp add: path_connected_eq_homotopic_points)
  3502   fix a b
  3503   assume "a \<in> S" "b \<in> S"
  3504   then show "homotopic_loops S (linepath a a) (linepath b b)"
  3505     using homotopic_circlemaps_imp_homotopic_loops [OF assms [of "\<lambda>x. a" "\<lambda>x. b"]]
  3506     by (auto simp: o_def continuous_on_const linepath_def)
  3507 qed
  3508 
  3509 lemma simply_connected_eq_homotopic_circlemaps3:
  3510   fixes h :: "complex \<Rightarrow> 'a::real_normed_vector"
  3511   assumes "path_connected S"
  3512       and hom: "\<And>f::complex \<Rightarrow> 'a.
  3513                   \<lbrakk>continuous_on (sphere 0 1) f; f `(sphere 0 1) \<subseteq> S\<rbrakk>
  3514                   \<Longrightarrow> \<exists>a. homotopic_with (\<lambda>h. True) (sphere 0 1) S f (\<lambda>x. a)"
  3515     shows "simply_connected S"
  3516 proof (clarsimp simp add: simply_connected_eq_contractible_loop_some assms)
  3517   fix p
  3518   assume p: "path p" "path_image p \<subseteq> S" "pathfinish p = pathstart p"
  3519   then have "homotopic_loops S p p"
  3520     by (simp add: homotopic_loops_refl)
  3521   then obtain a where homp: "homotopic_with (\<lambda>h. True) (sphere 0 1) S (p \<circ> (\<lambda>z. Arg z / (2 * pi))) (\<lambda>x. a)"
  3522     by (metis homotopic_with_imp_subset2 homotopic_loops_imp_homotopic_circlemaps homotopic_with_imp_continuous hom)
  3523   show "\<exists>a. a \<in> S \<and> homotopic_loops S p (linepath a a)"
  3524   proof (intro exI conjI)
  3525     show "a \<in> S"
  3526       using homotopic_with_imp_subset2 [OF homp]
  3527       by (metis dist_0_norm image_subset_iff mem_sphere norm_one)
  3528     have teq: "\<And>t. \<lbrakk>0 \<le> t; t \<le> 1\<rbrakk>
  3529                \<Longrightarrow> t = Arg (exp (2 * of_real pi * of_real t * \<i>)) / (2 * pi) \<or> t=1 \<and> Arg (exp (2 * of_real pi * of_real t * \<i>)) = 0"
  3530       apply (rule disjCI)
  3531       using Arg_of_real [of 1] apply (auto simp: Arg_exp)
  3532       done
  3533     have "homotopic_loops S p (p \<circ> (\<lambda>z. Arg z / (2 * pi)) \<circ> exp \<circ> (\<lambda>t. 2 * complex_of_real pi * complex_of_real t * \<i>))"
  3534       apply (rule homotopic_loops_eq [OF p])
  3535       using p teq apply (fastforce simp: pathfinish_def pathstart_def)
  3536       done
  3537     then
  3538     show "homotopic_loops S p (linepath a a)"
  3539       by (simp add: linepath_refl  homotopic_loops_trans [OF _ homotopic_circlemaps_imp_homotopic_loops [OF homp, simplified K_record_comp]])
  3540   qed
  3541 qed
  3542 
  3543 
  3544 proposition simply_connected_eq_homotopic_circlemaps:
  3545   fixes S :: "'a::real_normed_vector set"
  3546   shows "simply_connected S \<longleftrightarrow>
  3547          (\<forall>f g::complex \<Rightarrow> 'a.
  3548               continuous_on (sphere 0 1) f \<and> f ` (sphere 0 1) \<subseteq> S \<and>
  3549               continuous_on (sphere 0 1) g \<and> g ` (sphere 0 1) \<subseteq> S
  3550               \<longrightarrow> homotopic_with (\<lambda>h. True) (sphere 0 1) S f g)"
  3551   apply (rule iffI)
  3552    apply (blast elim: dest: simply_connected_eq_homotopic_circlemaps1)
  3553   by (simp add: simply_connected_eq_homotopic_circlemaps2a simply_connected_eq_homotopic_circlemaps2b simply_connected_eq_homotopic_circlemaps3)
  3554 
  3555 proposition simply_connected_eq_contractible_circlemap:
  3556   fixes S :: "'a::real_normed_vector set"
  3557   shows "simply_connected S \<longleftrightarrow>
  3558          path_connected S \<and>
  3559          (\<forall>f::complex \<Rightarrow> 'a.
  3560               continuous_on (sphere 0 1) f \<and> f `(sphere 0 1) \<subseteq> S
  3561               \<longrightarrow> (\<exists>a. homotopic_with (\<lambda>h. True) (sphere 0 1) S f (\<lambda>x. a)))"
  3562   apply (rule iffI)
  3563    apply (simp add: simply_connected_eq_homotopic_circlemaps1 simply_connected_eq_homotopic_circlemaps2a simply_connected_eq_homotopic_circlemaps2b)
  3564   using simply_connected_eq_homotopic_circlemaps3 by blast
  3565 
  3566 corollary homotopy_eqv_simple_connectedness:
  3567   fixes S :: "'a::real_normed_vector set" and T :: "'b::real_normed_vector set"
  3568   shows "S homotopy_eqv T \<Longrightarrow> simply_connected S \<longleftrightarrow> simply_connected T"
  3569   by (simp add: simply_connected_eq_homotopic_circlemaps homotopy_eqv_homotopic_triviality)
  3570 
  3571 
  3572 subsection\<open>Homeomorphism of simple closed curves to circles\<close>
  3573 
  3574 proposition homeomorphic_simple_path_image_circle:
  3575   fixes a :: complex and \<gamma> :: "real \<Rightarrow> 'a::t2_space"
  3576   assumes "simple_path \<gamma>" and loop: "pathfinish \<gamma> = pathstart \<gamma>" and "0 < r"
  3577   shows "(path_image \<gamma>) homeomorphic sphere a r"
  3578 proof -
  3579   have "homotopic_loops (path_image \<gamma>) \<gamma> \<gamma>"
  3580     by (simp add: assms homotopic_loops_refl simple_path_imp_path)
  3581   then have hom: "homotopic_with (\<lambda>h. True) (sphere 0 1) (path_image \<gamma>)
  3582                (\<gamma> \<circ> (\<lambda>z. Arg z / (2*pi))) (\<gamma> \<circ> (\<lambda>z. Arg z / (2*pi)))"
  3583     by (rule homotopic_loops_imp_homotopic_circlemaps)
  3584   have "\<exists>g. homeomorphism (sphere 0 1) (path_image \<gamma>) (\<gamma> \<circ> (\<lambda>z. Arg z / (2*pi))) g"
  3585   proof (rule homeomorphism_compact)
  3586     show "continuous_on (sphere 0 1) (\<gamma> \<circ> (\<lambda>z. Arg z / (2*pi)))"
  3587       using hom homotopic_with_imp_continuous by blast
  3588     show "inj_on (\<gamma> \<circ> (\<lambda>z. Arg z / (2*pi))) (sphere 0 1)"
  3589     proof
  3590       fix x y
  3591       assume xy: "x \<in> sphere 0 1" "y \<in> sphere 0 1"
  3592          and eq: "(\<gamma> \<circ> (\<lambda>z. Arg z / (2*pi))) x = (\<gamma> \<circ> (\<lambda>z. Arg z / (2*pi))) y"
  3593       then have "(Arg x / (2*pi)) = (Arg y / (2*pi))"
  3594       proof -
  3595         have "(Arg x / (2*pi)) \<in> {0..1}" "(Arg y / (2*pi)) \<in> {0..1}"
  3596           using Arg_ge_0 Arg_lt_2pi dual_order.strict_iff_order by fastforce+
  3597         with eq show ?thesis
  3598           using \<open>simple_path \<gamma>\<close> Arg_lt_2pi unfolding simple_path_def o_def
  3599           by (metis eq_divide_eq_1 not_less_iff_gr_or_eq)
  3600       qed
  3601       with xy show "x = y"
  3602         by (metis Arg Arg_0 dist_0_norm divide_cancel_right dual_order.strict_iff_order mem_sphere)
  3603     qed
  3604     have "\<And>z. cmod z = 1 \<Longrightarrow> \<exists>x\<in>{0..1}. \<gamma> (Arg z / (2*pi)) = \<gamma> x"
  3605        by (metis Arg_ge_0 Arg_lt_2pi atLeastAtMost_iff divide_less_eq_1 less_eq_real_def zero_less_mult_iff pi_gt_zero zero_le_divide_iff zero_less_numeral)
  3606      moreover have "\<exists>z\<in>sphere 0 1. \<gamma> x = \<gamma> (Arg z / (2*pi))" if "0 \<le> x" "x \<le> 1" for x
  3607      proof (cases "x=1")
  3608        case True
  3609        then show ?thesis
  3610          apply (rule_tac x=1 in bexI)
  3611          apply (metis loop Arg_of_real divide_eq_0_iff of_real_1 pathfinish_def pathstart_def \<open>0 \<le> x\<close>, auto)
  3612          done
  3613      next
  3614        case False
  3615        then have *: "(Arg (exp (\<i>*(2* of_real pi* of_real x))) / (2*pi)) = x"
  3616          using that by (auto simp: Arg_exp divide_simps)
  3617        show ?thesis
  3618          by (rule_tac x="exp(\<i> * of_real(2*pi*x))" in bexI) (auto simp: *)
  3619     qed
  3620     ultimately show "(\<gamma> \<circ> (\<lambda>z. Arg z / (2*pi))) ` sphere 0 1 = path_image \<gamma>"
  3621       by (auto simp: path_image_def image_iff)
  3622     qed auto
  3623     then have "path_image \<gamma> homeomorphic sphere (0::complex) 1"
  3624       using homeomorphic_def homeomorphic_sym by blast
  3625   also have "... homeomorphic sphere a r"
  3626     by (simp add: assms homeomorphic_spheres)
  3627   finally show ?thesis .
  3628 qed
  3629 
  3630 lemma homeomorphic_simple_path_images:
  3631   fixes \<gamma>1 :: "real \<Rightarrow> 'a::t2_space" and \<gamma>2 :: "real \<Rightarrow> 'b::t2_space"
  3632   assumes "simple_path \<gamma>1" and loop: "pathfinish \<gamma>1 = pathstart \<gamma>1"
  3633   assumes "simple_path \<gamma>2" and loop: "pathfinish \<gamma>2 = pathstart \<gamma>2"
  3634   shows "(path_image \<gamma>1) homeomorphic (path_image \<gamma>2)"
  3635   by (meson assms homeomorphic_simple_path_image_circle homeomorphic_sym homeomorphic_trans loop pi_gt_zero)
  3636 
  3637 end