src/Pure/Tools/find_theorems.ML
author wenzelm
Fri Feb 27 15:46:22 2009 +0100 (2009-02-27)
changeset 30142 8d6145694bb5
parent 29882 src/Pure/Isar/find_theorems.ML@29154e67731d
child 30143 98a986b02022
permissions -rw-r--r--
moved find_theorems.ML and find_consts.ML to Pure/Tools, collecting main implementation in one place each;
     1 (*  Title:      Pure/Isar/find_theorems.ML
     2     Author:     Rafal Kolanski and Gerwin Klein, NICTA
     3 
     4 Retrieve theorems from proof context.
     5 *)
     6 
     7 signature FIND_THEOREMS =
     8 sig
     9   val limit: int ref
    10   val tac_limit: int ref
    11 
    12   datatype 'term criterion =
    13     Name of string | Intro | Elim | Dest | Solves | Simp of 'term |
    14     Pattern of 'term
    15 
    16   val find_theorems: Proof.context -> thm option -> bool ->
    17     (bool * string criterion) list -> (Facts.ref * thm) list
    18 
    19   val print_theorems: Proof.context -> thm option -> int option -> bool ->
    20     (bool * string criterion) list -> unit
    21 end;
    22 
    23 structure FindTheorems: FIND_THEOREMS =
    24 struct
    25 
    26 (** search criteria **)
    27 
    28 datatype 'term criterion =
    29   Name of string | Intro | Elim | Dest | Solves | Simp of 'term |
    30   Pattern of 'term;
    31 
    32 fun read_criterion _ (Name name) = Name name
    33   | read_criterion _ Intro = Intro
    34   | read_criterion _ Elim = Elim
    35   | read_criterion _ Dest = Dest
    36   | read_criterion _ Solves = Solves
    37   | read_criterion ctxt (Simp str) = Simp (ProofContext.read_term_pattern ctxt str)
    38   | read_criterion ctxt (Pattern str) = Pattern (ProofContext.read_term_pattern ctxt str);
    39 
    40 fun pretty_criterion ctxt (b, c) =
    41   let
    42     fun prfx s = if b then s else "-" ^ s;
    43   in
    44     (case c of
    45       Name name => Pretty.str (prfx "name: " ^ quote name)
    46     | Intro => Pretty.str (prfx "intro")
    47     | Elim => Pretty.str (prfx "elim")
    48     | Dest => Pretty.str (prfx "dest")
    49     | Solves => Pretty.str (prfx "solves")
    50     | Simp pat => Pretty.block [Pretty.str (prfx "simp:"), Pretty.brk 1,
    51         Pretty.quote (Syntax.pretty_term ctxt (Term.show_dummy_patterns pat))]
    52     | Pattern pat => Pretty.enclose (prfx " \"") "\""
    53         [Syntax.pretty_term ctxt (Term.show_dummy_patterns pat)])
    54   end;
    55 
    56 
    57 
    58 (** search criterion filters **)
    59 
    60 (*generated filters are to be of the form
    61   input: (Facts.ref * thm)
    62   output: (p:int, s:int) option, where
    63     NONE indicates no match
    64     p is the primary sorting criterion
    65       (eg. number of assumptions in the theorem)
    66     s is the secondary sorting criterion
    67       (eg. size of the substitution for intro, elim and dest)
    68   when applying a set of filters to a thm, fold results in:
    69     (biggest p, sum of all s)
    70   currently p and s only matter for intro, elim, dest and simp filters,
    71   otherwise the default ordering is used.
    72 *)
    73 
    74 
    75 (* matching theorems *)
    76 
    77 fun is_nontrivial thy = Term.is_Const o Term.head_of o ObjectLogic.drop_judgment thy;
    78 
    79 (*extract terms from term_src, refine them to the parts that concern us,
    80   if po try match them against obj else vice versa.
    81   trivial matches are ignored.
    82   returns: smallest substitution size*)
    83 fun is_matching_thm (extract_terms, refine_term) ctxt po obj term_src =
    84   let
    85     val thy = ProofContext.theory_of ctxt;
    86 
    87     fun matches pat =
    88       is_nontrivial thy pat andalso
    89       Pattern.matches thy (if po then (pat, obj) else (obj, pat));
    90 
    91     fun substsize pat =
    92       let val (_, subst) =
    93         Pattern.match thy (if po then (pat, obj) else (obj, pat)) (Vartab.empty, Vartab.empty)
    94       in Vartab.fold (fn (_, (_, t)) => fn n => size_of_term t + n) subst 0 end;
    95 
    96     fun bestmatch [] = NONE
    97      |  bestmatch xs = SOME (foldr1 Int.min xs);
    98 
    99     val match_thm = matches o refine_term;
   100   in
   101     map (substsize o refine_term) (filter match_thm (extract_terms term_src))
   102     |> bestmatch
   103   end;
   104 
   105 
   106 (* filter_name *)
   107 
   108 fun filter_name str_pat (thmref, _) =
   109   if match_string str_pat (Facts.name_of_ref thmref)
   110   then SOME (0, 0) else NONE;
   111 
   112 
   113 (* filter intro/elim/dest/solves rules *)
   114 
   115 fun filter_dest ctxt goal (_, thm) =
   116   let
   117     val extract_dest =
   118      (fn thm => if Thm.no_prems thm then [] else [Thm.full_prop_of thm],
   119       hd o Logic.strip_imp_prems);
   120     val prems = Logic.prems_of_goal goal 1;
   121 
   122     fun try_subst prem = is_matching_thm extract_dest ctxt true prem thm;
   123     val successful = prems |> map_filter try_subst;
   124   in
   125     (*if possible, keep best substitution (one with smallest size)*)
   126     (*dest rules always have assumptions, so a dest with one
   127       assumption is as good as an intro rule with none*)
   128     if not (null successful)
   129     then SOME (Thm.nprems_of thm - 1, foldr1 Int.min successful) else NONE
   130   end;
   131 
   132 fun filter_intro ctxt goal (_, thm) =
   133   let
   134     val extract_intro = (single o Thm.full_prop_of, Logic.strip_imp_concl);
   135     val concl = Logic.concl_of_goal goal 1;
   136     val ss = is_matching_thm extract_intro ctxt true concl thm;
   137   in
   138     if is_some ss then SOME (Thm.nprems_of thm, the ss) else NONE
   139   end;
   140 
   141 fun filter_elim ctxt goal (_, thm) =
   142   if not (Thm.no_prems thm) then
   143     let
   144       val rule = Thm.full_prop_of thm;
   145       val prems = Logic.prems_of_goal goal 1;
   146       val goal_concl = Logic.concl_of_goal goal 1;
   147       val rule_mp = hd (Logic.strip_imp_prems rule);
   148       val rule_concl = Logic.strip_imp_concl rule;
   149       fun combine t1 t2 = Const ("*combine*", dummyT --> dummyT) $ (t1 $ t2);
   150       val rule_tree = combine rule_mp rule_concl;
   151       fun goal_tree prem = combine prem goal_concl;
   152       fun try_subst prem =
   153         is_matching_thm (single, I) ctxt true (goal_tree prem) rule_tree;
   154       val successful = prems |> map_filter try_subst;
   155     in
   156     (*elim rules always have assumptions, so an elim with one
   157       assumption is as good as an intro rule with none*)
   158       if is_nontrivial (ProofContext.theory_of ctxt) (Thm.major_prem_of thm)
   159         andalso not (null successful)
   160       then SOME (Thm.nprems_of thm - 1, foldr1 Int.min successful) else NONE
   161     end
   162   else NONE
   163 
   164 val tac_limit = ref 5;
   165 
   166 fun filter_solves ctxt goal = let
   167     val baregoal = Logic.get_goal (prop_of goal) 1;
   168 
   169     fun etacn thm i = Seq.take (!tac_limit) o etac thm i;
   170     fun try_thm thm = if Thm.no_prems thm then rtac thm 1 goal
   171                       else (etacn thm THEN_ALL_NEW
   172                              (Goal.norm_hhf_tac THEN'
   173                                Method.assumption_tac ctxt)) 1 goal;
   174   in
   175     fn (_, thm) => if (is_some o Seq.pull o try_thm) thm
   176                    then SOME (Thm.nprems_of thm, 0) else NONE
   177   end;
   178 
   179 
   180 (* filter_simp *)
   181 
   182 fun filter_simp ctxt t (_, thm) =
   183   let
   184     val (_, {mk_rews = {mk, ...}, ...}) =
   185       Simplifier.rep_ss (Simplifier.local_simpset_of ctxt);
   186     val extract_simp =
   187       (map Thm.full_prop_of o mk, #1 o Logic.dest_equals o Logic.strip_imp_concl);
   188     val ss = is_matching_thm extract_simp ctxt false t thm
   189   in
   190     if is_some ss then SOME (Thm.nprems_of thm, the ss) else NONE
   191   end;
   192 
   193 
   194 (* filter_pattern *)
   195 
   196 fun get_names t = (Term.add_const_names t []) union (Term.add_free_names t []);
   197 fun get_thm_names (_, thm) = get_names (Thm.full_prop_of thm);
   198   (* Including all constants and frees is only sound because
   199      matching uses higher-order patterns. If full matching
   200      were used, then constants that may be subject to
   201      beta-reduction after substitution of frees should
   202      not be included for LHS set because they could be
   203      thrown away by the substituted function.
   204      e.g. for (?F 1 2) do not include 1 or 2, if it were
   205           possible for ?F to be (% x y. 3)
   206      The largest possible set should always be included on
   207      the RHS. *)
   208 
   209 fun filter_pattern ctxt pat = let
   210     val pat_consts = get_names pat;
   211 
   212     fun check (t, NONE) = check (t, SOME (get_thm_names t))
   213       | check ((_, thm), c as SOME thm_consts) =
   214           (if pat_consts subset_string thm_consts
   215               andalso (Pattern.matches_subterm (ProofContext.theory_of ctxt)
   216                                                (pat, Thm.full_prop_of thm))
   217            then SOME (0, 0) else NONE, c);
   218   in check end;
   219 
   220 
   221 (* interpret criteria as filters *)
   222 
   223 local
   224 
   225 fun err_no_goal c =
   226   error ("Current goal required for " ^ c ^ " search criterion");
   227 
   228 val fix_goal = Thm.prop_of;
   229 val fix_goalo = Option.map fix_goal;
   230 
   231 fun filter_crit _ _ (Name name) = apfst (filter_name name)
   232   | filter_crit _ NONE Intro = err_no_goal "intro"
   233   | filter_crit _ NONE Elim = err_no_goal "elim"
   234   | filter_crit _ NONE Dest = err_no_goal "dest"
   235   | filter_crit _ NONE Solves = err_no_goal "solves"
   236   | filter_crit ctxt (SOME goal) Intro = apfst (filter_intro ctxt
   237                                                   (fix_goal goal))
   238   | filter_crit ctxt (SOME goal) Elim = apfst (filter_elim ctxt 
   239                                                   (fix_goal goal))
   240   | filter_crit ctxt (SOME goal) Dest = apfst (filter_dest ctxt
   241                                                   (fix_goal goal))
   242   | filter_crit ctxt (SOME goal) Solves = apfst (filter_solves ctxt goal)
   243   | filter_crit ctxt _ (Simp pat) = apfst (filter_simp ctxt pat)
   244   | filter_crit ctxt _ (Pattern pat) = filter_pattern ctxt pat;
   245 
   246 fun opt_not x = if is_some x then NONE else SOME (0, 0);
   247 
   248 fun opt_add (SOME (a, x)) (SOME (b, y)) = SOME (Int.max (a, b), x + y : int)
   249   | opt_add _ _ = NONE;
   250 
   251 fun app_filters thm = let
   252     fun app (NONE, _, _) = NONE
   253       | app (SOME v, consts, []) = SOME (v, thm)
   254       | app (r, consts, f::fs) = let val (r', consts') = f (thm, consts)
   255                                  in app (opt_add r r', consts', fs) end;
   256   in app end;
   257 
   258 in
   259 
   260 fun filter_criterion ctxt opt_goal (b, c) =
   261   (if b then I else (apfst opt_not)) o filter_crit ctxt opt_goal c;
   262 
   263 fun all_filters filters thms =
   264   let
   265     fun eval_filters thm = app_filters thm (SOME (0, 0), NONE, filters);
   266 
   267     (*filters return: (number of assumptions, substitution size) option, so
   268       sort (desc. in both cases) according to number of assumptions first,
   269       then by the substitution size*)
   270     fun thm_ord (((p0, s0), _), ((p1, s1), _)) =
   271       prod_ord int_ord int_ord ((p1, s1), (p0, s0));
   272   in map_filter eval_filters thms |> sort thm_ord |> map #2 end;
   273 
   274 end;
   275 
   276 
   277 (* removing duplicates, preferring nicer names, roughly n log n *)
   278 
   279 local
   280 
   281 val index_ord = option_ord (K EQUAL);
   282 val hidden_ord = bool_ord o pairself NameSpace.is_hidden;
   283 val qual_ord = int_ord o pairself (length o NameSpace.explode);
   284 val txt_ord = int_ord o pairself size;
   285 
   286 fun nicer_name (x, i) (y, j) =
   287   (case hidden_ord (x, y) of EQUAL =>
   288     (case index_ord (i, j) of EQUAL =>
   289       (case qual_ord (x, y) of EQUAL => txt_ord (x, y) | ord => ord)
   290     | ord => ord)
   291   | ord => ord) <> GREATER;
   292 
   293 fun rem_cdups nicer xs =
   294   let
   295     fun rem_c rev_seen [] = rev rev_seen
   296       | rem_c rev_seen [x] = rem_c (x :: rev_seen) []
   297       | rem_c rev_seen ((x as ((n, t), _)) :: (y as ((n', t'), _)) :: xs) =
   298         if Thm.eq_thm_prop (t, t')
   299         then rem_c rev_seen ((if nicer n n' then x else y) :: xs)
   300         else rem_c (x :: rev_seen) (y :: xs)
   301   in rem_c [] xs end;
   302 
   303 in
   304 
   305 fun nicer_shortest ctxt = let
   306     val ns = ProofContext.theory_of ctxt
   307              |> PureThy.facts_of
   308              |> Facts.space_of;
   309 
   310     val len_sort = sort (int_ord o (pairself size));
   311     fun shorten s = (case len_sort (NameSpace.get_accesses ns s) of
   312                        [] => s
   313                      | s'::_ => s');
   314 
   315     fun nicer (Facts.Named ((x, _), i)) (Facts.Named ((y, _), j)) =
   316           nicer_name (shorten x, i) (shorten y, j)
   317       | nicer (Facts.Fact _) (Facts.Named _) = true
   318       | nicer (Facts.Named _) (Facts.Fact _) = false;
   319   in nicer end;
   320 
   321 fun rem_thm_dups nicer xs =
   322   xs ~~ (1 upto length xs)
   323   |> sort (TermOrd.fast_term_ord o pairself (Thm.prop_of o #2 o #1))
   324   |> rem_cdups nicer
   325   |> sort (int_ord o pairself #2)
   326   |> map #1;
   327 
   328 end;
   329 
   330 
   331 (* print_theorems *)
   332 
   333 fun all_facts_of ctxt =
   334   maps Facts.selections
   335    (Facts.dest_static [] (PureThy.facts_of (ProofContext.theory_of ctxt)) @
   336     Facts.dest_static [] (ProofContext.facts_of ctxt));
   337 
   338 val limit = ref 40;
   339 
   340 fun find_theorems ctxt opt_goal rem_dups raw_criteria =
   341   let
   342     val add_prems = Seq.hd o (TRY (Method.insert_tac
   343                                      (Assumption.prems_of ctxt) 1));
   344     val opt_goal' = Option.map add_prems opt_goal;
   345 
   346     val criteria = map (apsnd (read_criterion ctxt)) raw_criteria;
   347     val filters = map (filter_criterion ctxt opt_goal') criteria;
   348 
   349     val raw_matches = all_filters filters (all_facts_of ctxt);
   350 
   351     val matches =
   352       if rem_dups
   353       then rem_thm_dups (nicer_shortest ctxt) raw_matches
   354       else raw_matches;
   355   in matches end;
   356 
   357 fun print_theorems ctxt opt_goal opt_limit rem_dups raw_criteria = let
   358     val start = start_timing ();
   359 
   360     val criteria = map (apsnd (read_criterion ctxt)) raw_criteria;
   361     val matches = find_theorems ctxt opt_goal rem_dups raw_criteria;
   362 
   363     val len = length matches;
   364     val lim = the_default (! limit) opt_limit;
   365     val thms = Library.drop (len - lim, matches);
   366 
   367     val end_msg = " in " ^
   368                   (List.nth (String.tokens Char.isSpace (end_timing start), 3))
   369                   ^ " secs"
   370   in
   371     Pretty.big_list "searched for:" (map (pretty_criterion ctxt) criteria)
   372         :: Pretty.str "" ::
   373      (if null thms then [Pretty.str ("nothing found" ^ end_msg)]
   374       else
   375         [Pretty.str ("found " ^ string_of_int len ^ " theorems" ^
   376           (if len <= lim then ""
   377            else " (" ^ string_of_int lim ^ " displayed)")
   378            ^ end_msg ^ ":"), Pretty.str ""] @
   379         map Display.pretty_fact thms)
   380     |> Pretty.chunks |> Pretty.writeln
   381   end;
   382 
   383 
   384 
   385 (** command syntax **)
   386 
   387 fun find_theorems_cmd ((opt_lim, rem_dups), spec) =
   388   Toplevel.unknown_theory o Toplevel.keep (fn state =>
   389   let
   390     val proof_state = Toplevel.enter_proof_body state;
   391     val ctxt = Proof.context_of proof_state;
   392     val opt_goal = try Proof.get_goal proof_state |> Option.map (#2 o #2);
   393   in print_theorems ctxt opt_goal opt_lim rem_dups spec end);
   394 
   395 local
   396 
   397 structure P = OuterParse and K = OuterKeyword;
   398 
   399 val criterion =
   400   P.reserved "name" |-- P.!!! (P.$$$ ":" |-- P.xname) >> Name ||
   401   P.reserved "intro" >> K Intro ||
   402   P.reserved "elim" >> K Elim ||
   403   P.reserved "dest" >> K Dest ||
   404   P.reserved "solves" >> K Solves ||
   405   P.reserved "simp" |-- P.!!! (P.$$$ ":" |-- P.term) >> Simp ||
   406   P.term >> Pattern;
   407 
   408 val options =
   409   Scan.optional
   410     (P.$$$ "(" |--
   411       P.!!! (Scan.option P.nat -- Scan.optional (P.reserved "with_dups" >> K false) true
   412         --| P.$$$ ")")) (NONE, true);
   413 in
   414 
   415 val _ =
   416   OuterSyntax.improper_command "find_theorems" "print theorems meeting specified criteria" K.diag
   417     (options -- Scan.repeat (((Scan.option P.minus >> is_none) -- criterion))
   418       >> (Toplevel.no_timing oo find_theorems_cmd));
   419 
   420 end;
   421 
   422 end;