src/HOL/Library/FuncSet.thy
author paulson
Tue Jun 01 11:25:26 2004 +0200 (2004-06-01)
changeset 14853 8d710bece29f
parent 14762 bd349ff7907a
child 15131 c69542757a4d
permissions -rw-r--r--
more on bij_betw
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     ID:         $Id$
     3     Author:     Florian Kammueller and Lawrence C Paulson
     4 *)
     5 
     6 header {* Pi and Function Sets *}
     7 
     8 theory FuncSet = Main:
     9 
    10 constdefs
    11   Pi :: "['a set, 'a => 'b set] => ('a => 'b) set"
    12   "Pi A B == {f. \<forall>x. x \<in> A --> f x \<in> B x}"
    13 
    14   extensional :: "'a set => ('a => 'b) set"
    15   "extensional A == {f. \<forall>x. x~:A --> f x = arbitrary}"
    16 
    17   "restrict" :: "['a => 'b, 'a set] => ('a => 'b)"
    18   "restrict f A == (%x. if x \<in> A then f x else arbitrary)"
    19 
    20 syntax
    21   "@Pi"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PI _:_./ _)" 10)
    22   funcset :: "['a set, 'b set] => ('a => 'b) set"      (infixr "->" 60)
    23   "@lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    24 
    25 syntax (xsymbols)
    26   "@Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    27   funcset :: "['a set, 'b set] => ('a => 'b) set"  (infixr "\<rightarrow>" 60)
    28   "@lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    29 
    30 syntax (HTML output)
    31   "@Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    32   "@lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    33 
    34 translations
    35   "PI x:A. B" => "Pi A (%x. B)"
    36   "A -> B" => "Pi A (_K B)"
    37   "%x:A. f" == "restrict (%x. f) A"
    38 
    39 constdefs
    40   "compose" :: "['a set, 'b => 'c, 'a => 'b] => ('a => 'c)"
    41   "compose A g f == \<lambda>x\<in>A. g (f x)"
    42 
    43 print_translation {* [("Pi", dependent_tr' ("@Pi", "funcset"))] *}
    44 
    45 
    46 subsection{*Basic Properties of @{term Pi}*}
    47 
    48 lemma Pi_I: "(!!x. x \<in> A ==> f x \<in> B x) ==> f \<in> Pi A B"
    49   by (simp add: Pi_def)
    50 
    51 lemma funcsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f \<in> A -> B"
    52   by (simp add: Pi_def)
    53 
    54 lemma Pi_mem: "[|f: Pi A B; x \<in> A|] ==> f x \<in> B x"
    55   by (simp add: Pi_def)
    56 
    57 lemma funcset_mem: "[|f \<in> A -> B; x \<in> A|] ==> f x \<in> B"
    58   by (simp add: Pi_def)
    59 
    60 lemma funcset_image: "f \<in> A\<rightarrow>B ==> f ` A \<subseteq> B"
    61 by (auto simp add: Pi_def)
    62 
    63 lemma Pi_eq_empty: "((PI x: A. B x) = {}) = (\<exists>x\<in>A. B(x) = {})"
    64 apply (simp add: Pi_def, auto)
    65 txt{*Converse direction requires Axiom of Choice to exhibit a function
    66 picking an element from each non-empty @{term "B x"}*}
    67 apply (drule_tac x = "%u. SOME y. y \<in> B u" in spec, auto)
    68 apply (cut_tac P= "%y. y \<in> B x" in some_eq_ex, auto)
    69 done
    70 
    71 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    72   by (simp add: Pi_def)
    73 
    74 lemma Pi_UNIV [simp]: "A -> UNIV = UNIV"
    75   by (simp add: Pi_def)
    76 
    77 text{*Covariance of Pi-sets in their second argument*}
    78 lemma Pi_mono: "(!!x. x \<in> A ==> B x <= C x) ==> Pi A B <= Pi A C"
    79   by (simp add: Pi_def, blast)
    80 
    81 text{*Contravariance of Pi-sets in their first argument*}
    82 lemma Pi_anti_mono: "A' <= A ==> Pi A B <= Pi A' B"
    83   by (simp add: Pi_def, blast)
    84 
    85 
    86 subsection{*Composition With a Restricted Domain: @{term compose}*}
    87 
    88 lemma funcset_compose:
    89     "[| f \<in> A -> B; g \<in> B -> C |]==> compose A g f \<in> A -> C"
    90   by (simp add: Pi_def compose_def restrict_def)
    91 
    92 lemma compose_assoc:
    93     "[| f \<in> A -> B; g \<in> B -> C; h \<in> C -> D |]
    94       ==> compose A h (compose A g f) = compose A (compose B h g) f"
    95   by (simp add: expand_fun_eq Pi_def compose_def restrict_def)
    96 
    97 lemma compose_eq: "x \<in> A ==> compose A g f x = g(f(x))"
    98   by (simp add: compose_def restrict_def)
    99 
   100 lemma surj_compose: "[| f ` A = B; g ` B = C |] ==> compose A g f ` A = C"
   101   by (auto simp add: image_def compose_eq)
   102 
   103 
   104 subsection{*Bounded Abstraction: @{term restrict}*}
   105 
   106 lemma restrict_in_funcset: "(!!x. x \<in> A ==> f x \<in> B) ==> (\<lambda>x\<in>A. f x) \<in> A -> B"
   107   by (simp add: Pi_def restrict_def)
   108 
   109 lemma restrictI: "(!!x. x \<in> A ==> f x \<in> B x) ==> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   110   by (simp add: Pi_def restrict_def)
   111 
   112 lemma restrict_apply [simp]:
   113     "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else arbitrary)"
   114   by (simp add: restrict_def)
   115 
   116 lemma restrict_ext:
   117     "(!!x. x \<in> A ==> f x = g x) ==> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   118   by (simp add: expand_fun_eq Pi_def Pi_def restrict_def)
   119 
   120 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   121   by (simp add: inj_on_def restrict_def)
   122 
   123 lemma Id_compose:
   124     "[|f \<in> A -> B;  f \<in> extensional A|] ==> compose A (\<lambda>y\<in>B. y) f = f"
   125   by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)
   126 
   127 lemma compose_Id:
   128     "[|g \<in> A -> B;  g \<in> extensional A|] ==> compose A g (\<lambda>x\<in>A. x) = g"
   129   by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)
   130 
   131 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   132   by (auto simp add: restrict_def) 
   133 
   134 
   135 subsection{*Bijections Between Sets*}
   136 
   137 text{*The basic definition could be moved to @{text "Fun.thy"}, but most of
   138 the theorems belong here, or need at least @{term Hilbert_Choice}.*}
   139 
   140 constdefs
   141   bij_betw :: "['a => 'b, 'a set, 'b set] => bool"         (*bijective*)
   142     "bij_betw f A B == inj_on f A & f ` A = B"
   143 
   144 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   145 by (simp add: bij_betw_def)
   146 
   147 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   148 by (auto simp add: bij_betw_def inj_on_Inv Pi_def)
   149 
   150 lemma bij_betw_Inv: "bij_betw f A B \<Longrightarrow> bij_betw (Inv A f) B A"
   151 apply (auto simp add: bij_betw_def inj_on_Inv Inv_mem) 
   152 apply (simp add: image_compose [symmetric] o_def) 
   153 apply (simp add: image_def Inv_f_f) 
   154 done
   155 
   156 lemma inj_on_compose:
   157     "[| bij_betw f A B; inj_on g B |] ==> inj_on (compose A g f) A"
   158   by (auto simp add: bij_betw_def inj_on_def compose_eq)
   159 
   160 lemma bij_betw_compose:
   161     "[| bij_betw f A B; bij_betw g B C |] ==> bij_betw (compose A g f) A C"
   162 apply (simp add: bij_betw_def compose_eq inj_on_compose)
   163 apply (auto simp add: compose_def image_def)
   164 done
   165 
   166 lemma bij_betw_restrict_eq [simp]:
   167      "bij_betw (restrict f A) A B = bij_betw f A B"
   168   by (simp add: bij_betw_def)
   169 
   170 
   171 subsection{*Extensionality*}
   172 
   173 lemma extensional_arb: "[|f \<in> extensional A; x\<notin> A|] ==> f x = arbitrary"
   174   by (simp add: extensional_def)
   175 
   176 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   177   by (simp add: restrict_def extensional_def)
   178 
   179 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   180   by (simp add: compose_def)
   181 
   182 lemma extensionalityI:
   183     "[| f \<in> extensional A; g \<in> extensional A;
   184       !!x. x\<in>A ==> f x = g x |] ==> f = g"
   185   by (force simp add: expand_fun_eq extensional_def)
   186 
   187 lemma Inv_funcset: "f ` A = B ==> (\<lambda>x\<in>B. Inv A f x) : B -> A"
   188   by (unfold Inv_def) (fast intro: restrict_in_funcset someI2)
   189 
   190 lemma compose_Inv_id:
   191     "bij_betw f A B ==> compose A (\<lambda>y\<in>B. Inv A f y) f = (\<lambda>x\<in>A. x)"
   192   apply (simp add: bij_betw_def compose_def)
   193   apply (rule restrict_ext, auto)
   194   apply (erule subst)
   195   apply (simp add: Inv_f_f)
   196   done
   197 
   198 lemma compose_id_Inv:
   199     "f ` A = B ==> compose B f (\<lambda>y\<in>B. Inv A f y) = (\<lambda>x\<in>B. x)"
   200   apply (simp add: compose_def)
   201   apply (rule restrict_ext)
   202   apply (simp add: f_Inv_f)
   203   done
   204 
   205 
   206 subsection{*Cardinality*}
   207 
   208 lemma card_inj: "[|f \<in> A\<rightarrow>B; inj_on f A; finite B|] ==> card(A) \<le> card(B)"
   209 apply (rule card_inj_on_le)
   210 apply (auto simp add: Pi_def)
   211 done
   212 
   213 lemma card_bij:
   214      "[|f \<in> A\<rightarrow>B; inj_on f A;
   215         g \<in> B\<rightarrow>A; inj_on g B; finite A; finite B|] ==> card(A) = card(B)"
   216 by (blast intro: card_inj order_antisym)
   217 
   218 end