src/Pure/library.ML
author wenzelm
Mon Jan 10 15:19:48 2011 +0100 (2011-01-10)
changeset 41489 8e2b8649507d
parent 40936 10aeae27c7a6
child 41492 7a4138cb46db
permissions -rw-r--r--
standardized split_last/last_elem towards List.last;
eliminated obsolete Library.last_elem;
     1 (*  Title:      Pure/library.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Basic library: functions, pairs, booleans, lists, integers,
     6 strings, lists as sets, orders, current directory, misc.
     7 
     8 See also General/basics.ML for the most fundamental concepts.
     9 *)
    10 
    11 infix 2 ?
    12 infix 3 o oo ooo oooo
    13 infix 4 ~~ upto downto
    14 infix orf andf
    15 
    16 signature BASIC_LIBRARY =
    17 sig
    18   (*functions*)
    19   val undefined: 'a -> 'b
    20   val I: 'a -> 'a
    21   val K: 'a -> 'b -> 'a
    22   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    23   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    24   val ? : bool * ('a -> 'a) -> 'a -> 'a
    25   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    26   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    27   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    28   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    29   val funpow_yield: int -> ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    30 
    31   (*errors*)
    32   exception ERROR of string
    33   val error: string -> 'a
    34   val cat_error: string -> string -> 'a
    35   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    36 
    37   (*pairs*)
    38   val pair: 'a -> 'b -> 'a * 'b
    39   val rpair: 'a -> 'b -> 'b * 'a
    40   val fst: 'a * 'b -> 'a
    41   val snd: 'a * 'b -> 'b
    42   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    43   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    44   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    45   val swap: 'a * 'b -> 'b * 'a
    46   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    47   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    48   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    49 
    50   (*booleans*)
    51   val equal: ''a -> ''a -> bool
    52   val not_equal: ''a -> ''a -> bool
    53   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    54   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    55   val exists: ('a -> bool) -> 'a list -> bool
    56   val forall: ('a -> bool) -> 'a list -> bool
    57   val setmp_CRITICAL: 'a Unsynchronized.ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    58   val setmp_thread_data: 'a Universal.tag -> 'a -> 'a -> ('b -> 'c) -> 'b -> 'c
    59 
    60   (*lists*)
    61   val single: 'a -> 'a list
    62   val the_single: 'a list -> 'a
    63   val singleton: ('a list -> 'b list) -> 'a -> 'b
    64   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    65   val apply: ('a -> 'a) list -> 'a -> 'a
    66   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    67   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    68   val foldl1: ('a * 'a -> 'a) -> 'a list -> 'a
    69   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    70   val flat: 'a list list -> 'a list
    71   val unflat: 'a list list -> 'b list -> 'b list list
    72   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    73   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    74   val burrow_fst: ('a list -> 'b list) -> ('a * 'c) list -> ('b * 'c) list
    75   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    76   val maps: ('a -> 'b list) -> 'a list -> 'b list
    77   val filter: ('a -> bool) -> 'a list -> 'a list
    78   val filter_out: ('a -> bool) -> 'a list -> 'a list
    79   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    80   val take: int -> 'a list -> 'a list
    81   val drop: int -> 'a list -> 'a list
    82   val chop: int -> 'a list -> 'a list * 'a list
    83   val chop_while: ('a -> bool) -> 'a list -> 'a list * 'a list
    84   val nth: 'a list -> int -> 'a
    85   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    86   val nth_drop: int -> 'a list -> 'a list
    87   val nth_list: 'a list list -> int -> 'a list
    88   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    89   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    90   val map_range: (int -> 'a) -> int -> 'a list
    91   val split_last: 'a list -> 'a list * 'a
    92   val find_index: ('a -> bool) -> 'a list -> int
    93   val find_first: ('a -> bool) -> 'a list -> 'a option
    94   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
    95   val get_first: ('a -> 'b option) -> 'a list -> 'b option
    96   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
    97   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
    98   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
    99   val fold_rev2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   100   val forall2: ('a -> 'b -> bool) -> 'a list -> 'b list -> bool
   101   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   102   val ~~ : 'a list * 'b list -> ('a * 'b) list
   103   val map_split: ('a -> 'b * 'c) -> 'a list -> 'b list * 'c list
   104   val split_list: ('a * 'b) list -> 'a list * 'b list
   105   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   106   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   107   val map_transpose: ('a list -> 'b) -> 'a list list -> 'b list
   108   val separate: 'a -> 'a list -> 'a list
   109   val surround: 'a -> 'a list -> 'a list
   110   val replicate: int -> 'a -> 'a list
   111   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   112   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   113   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   114   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   115   val prefixes1: 'a list -> 'a list list
   116   val prefixes: 'a list -> 'a list list
   117   val suffixes1: 'a list -> 'a list list
   118   val suffixes: 'a list -> 'a list list
   119 
   120   (*integers*)
   121   val upto: int * int -> int list
   122   val downto: int * int -> int list
   123   val radixpand: int * int -> int list
   124   val radixstring: int * string * int -> string
   125   val string_of_int: int -> string
   126   val signed_string_of_int: int -> string
   127   val string_of_indexname: string * int -> string
   128   val read_radix_int: int -> string list -> int * string list
   129   val read_int: string list -> int * string list
   130   val oct_char: string -> string
   131 
   132   (*reals*)
   133   val string_of_real: real -> string
   134   val signed_string_of_real: real -> string
   135 
   136   (*strings*)
   137   val nth_string: string -> int -> string
   138   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   139   val exists_string: (string -> bool) -> string -> bool
   140   val forall_string: (string -> bool) -> string -> bool
   141   val first_field: string -> string -> (string * string) option
   142   val enclose: string -> string -> string -> string
   143   val unenclose: string -> string
   144   val quote: string -> string
   145   val space_implode: string -> string list -> string
   146   val commas: string list -> string
   147   val commas_quote: string list -> string
   148   val cat_lines: string list -> string
   149   val space_explode: string -> string -> string list
   150   val split_lines: string -> string list
   151   val prefix_lines: string -> string -> string
   152   val prefix: string -> string -> string
   153   val suffix: string -> string -> string
   154   val unprefix: string -> string -> string
   155   val unsuffix: string -> string -> string
   156   val replicate_string: int -> string -> string
   157   val translate_string: (string -> string) -> string -> string
   158   val match_string: string -> string -> bool
   159 
   160   (*lists as sets -- see also Pure/General/ord_list.ML*)
   161   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   162   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   163   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   164   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   165   val union: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   166   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   167   val inter: ('a * 'b -> bool) -> 'b list -> 'a list -> 'a list
   168   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   169   val subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   170   val eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   171   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   172   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   173   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   174 
   175   (*lists as multisets*)
   176   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   177   val combine: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   178   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   179 
   180   (*orders*)
   181   val is_equal: order -> bool
   182   val rev_order: order -> order
   183   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   184   val bool_ord: bool * bool -> order
   185   val int_ord: int * int -> order
   186   val string_ord: string * string -> order
   187   val fast_string_ord: string * string -> order
   188   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   189   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   190   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   191   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   192   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   193   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   194   val sort_strings: string list -> string list
   195   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   196   val tag_list: int -> 'a list -> (int * 'a) list
   197   val untag_list: (int * 'a) list -> 'a list
   198   val order_list: (int * 'a) list -> 'a list
   199 
   200   (*random numbers*)
   201   exception RANDOM
   202   val random: unit -> real
   203   val random_range: int -> int -> int
   204   val one_of: 'a list -> 'a
   205   val frequency: (int * 'a) list -> 'a
   206 
   207   (*misc*)
   208   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   209   val divide_and_conquer': ('a -> 'b -> ('a list * ('c list * 'b -> 'c * 'b)) * 'b) ->
   210     'a -> 'b -> 'c * 'b
   211   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   212   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   213   val gensym: string -> string
   214   type stamp = unit Unsynchronized.ref
   215   val stamp: unit -> stamp
   216   type serial = int
   217   val serial: unit -> serial
   218   val serial_string: unit -> string
   219   structure Object: sig type T = exn end
   220 end;
   221 
   222 signature LIBRARY =
   223 sig
   224   include BASIC_LIBRARY
   225   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   226   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   227   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   228 end;
   229 
   230 structure Library: LIBRARY =
   231 struct
   232 
   233 (* functions *)
   234 
   235 fun undefined _ = raise Match;
   236 
   237 fun I x = x;
   238 fun K x = fn _ => x;
   239 fun curry f x y = f (x, y);
   240 fun uncurry f (x, y) = f x y;
   241 
   242 (*conditional application*)
   243 fun b ? f = fn x => if b then f x else x;
   244 
   245 (*composition with multiple args*)
   246 fun (f oo g) x y = f (g x y);
   247 fun (f ooo g) x y z = f (g x y z);
   248 fun (f oooo g) x y z w = f (g x y z w);
   249 
   250 (*function exponentiation: f (... (f x) ...) with n applications of f*)
   251 fun funpow (0 : int) _ = I
   252   | funpow n f = f #> funpow (n - 1) f;
   253 
   254 fun funpow_yield (0 : int) _ x = ([], x)
   255   | funpow_yield n f x = x |> f ||>> funpow_yield (n - 1) f |>> op ::;
   256 
   257 
   258 (* errors *)
   259 
   260 exception ERROR of string;
   261 fun error msg = raise ERROR msg;
   262 
   263 fun cat_error "" msg = error msg
   264   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   265 
   266 fun assert_all pred list msg =
   267   let
   268     fun ass [] = ()
   269       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   270   in ass list end;
   271 
   272 
   273 (* pairs *)
   274 
   275 fun pair x y = (x, y);
   276 fun rpair x y = (y, x);
   277 
   278 fun fst (x, y) = x;
   279 fun snd (x, y) = y;
   280 
   281 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   282 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   283 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   284 
   285 fun swap (x, y) = (y, x);
   286 
   287 fun apfst f (x, y) = (f x, y);
   288 fun apsnd f (x, y) = (x, f y);
   289 fun pairself f (x, y) = (f x, f y);
   290 
   291 
   292 (* booleans *)
   293 
   294 (*polymorphic equality*)
   295 fun equal x y = x = y;
   296 fun not_equal x y = x <> y;
   297 
   298 (*combining predicates*)
   299 fun p orf q = fn x => p x orelse q x;
   300 fun p andf q = fn x => p x andalso q x;
   301 
   302 val exists = List.exists;
   303 val forall = List.all;
   304 
   305 
   306 (* flags *)
   307 
   308 fun setmp_CRITICAL flag value f x =
   309   NAMED_CRITICAL "setmp" (fn () => Unsynchronized.setmp flag value f x);
   310 
   311 fun setmp_thread_data tag orig_data data f x =
   312   uninterruptible (fn restore_attributes => fn () =>
   313     let
   314       val _ = Thread.setLocal (tag, data);
   315       val result = Exn.capture (restore_attributes f) x;
   316       val _ = Thread.setLocal (tag, orig_data);
   317     in Exn.release result end) ();
   318 
   319 
   320 
   321 (** lists **)
   322 
   323 fun single x = [x];
   324 
   325 fun the_single [x] = x
   326   | the_single _ = raise Empty;
   327 
   328 fun singleton f x = the_single (f [x]);
   329 
   330 fun yield_singleton f x = f [x] #>> the_single;
   331 
   332 fun apply [] x = x
   333   | apply (f :: fs) x = apply fs (f x);
   334 
   335 fun perhaps_apply funs arg =
   336   let
   337     fun app [] res = res
   338       | app (f :: fs) (changed, x) =
   339           (case f x of
   340             NONE => app fs (changed, x)
   341           | SOME x' => app fs (true, x'));
   342   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   343 
   344 fun perhaps_loop f arg =
   345   let
   346     fun loop (changed, x) =
   347       (case f x of
   348         NONE => (changed, x)
   349       | SOME x' => loop (true, x'));
   350   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   351 
   352 
   353 (* fold -- old versions *)
   354 
   355 (*the following versions of fold are designed to fit nicely with infixes*)
   356 
   357 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   358     for operators that associate to the left (TAIL RECURSIVE)*)
   359 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   360   let fun itl (e, [])  = e
   361         | itl (e, a::l) = itl (f(e, a), l)
   362   in  itl end;
   363 
   364 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   365     for operators that associate to the right (not tail recursive)*)
   366 fun foldr f (l, e) =
   367   let fun itr [] = e
   368         | itr (a::l) = f(a, itr l)
   369   in  itr l  end;
   370 
   371 (*  (op @) [x1, ..., xn]  ===>  ((x1 @ x2) @ x3) ... @ xn
   372     for operators that associate to the left (TAIL RECURSIVE)*)
   373 fun foldl1 f [] = raise Empty
   374   | foldl1 f (x :: xs) = foldl f (x, xs);
   375 
   376 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   377     for n > 0, operators that associate to the right (not tail recursive)*)
   378 fun foldr1 f [] = raise Empty
   379   | foldr1 f l =
   380       let fun itr [x] = x
   381             | itr (x::l) = f(x, itr l)
   382       in  itr l  end;
   383 
   384 fun foldl_map f =
   385   let
   386     fun fold_aux (x, []) = (x, [])
   387       | fold_aux (x, y :: ys) =
   388           let
   389             val (x', y') = f (x, y);
   390             val (x'', ys') = fold_aux (x', ys);
   391           in (x'', y' :: ys') end;
   392   in fold_aux end;
   393 
   394 
   395 (* basic list functions *)
   396 
   397 fun eq_list eq (list1, list2) =
   398   let
   399     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   400       | eq_lst _ = true;
   401   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   402 
   403 fun maps f [] = []
   404   | maps f (x :: xs) = f x @ maps f xs;
   405 
   406 val filter = List.filter;
   407 fun filter_out f = filter (not o f);
   408 val map_filter = List.mapPartial;
   409 
   410 fun take (0: int) xs = []
   411   | take _ [] = []
   412   | take n (x :: xs) = x :: take (n - 1) xs;
   413 
   414 fun drop (0: int) xs = xs
   415   | drop _ [] = []
   416   | drop n (x :: xs) = drop (n - 1) xs;
   417 
   418 fun chop (0: int) xs = ([], xs)
   419   | chop _ [] = ([], [])
   420   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   421 
   422 fun chop_while P [] = ([], [])
   423   | chop_while P (ys as x :: xs) =
   424       if P x then chop_while P xs |>> cons x else ([], ys);
   425 
   426 (*return nth element of a list, where 0 designates the first element;
   427   raise Subscript if list too short*)
   428 fun nth xs i = List.nth (xs, i);
   429 
   430 fun nth_list xss i = nth xss i handle Subscript => [];
   431 
   432 fun nth_map 0 f (x :: xs) = f x :: xs
   433   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   434   | nth_map (_: int) _ [] = raise Subscript;
   435 
   436 fun nth_drop n xs =
   437   List.take (xs, n) @ List.drop (xs, n + 1);
   438 
   439 fun map_index f =
   440   let
   441     fun mapp (_: int) [] = []
   442       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   443   in mapp 0 end;
   444 
   445 fun fold_index f =
   446   let
   447     fun fold_aux (_: int) [] y = y
   448       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   449   in fold_aux 0 end;
   450 
   451 fun map_range f i =
   452   let
   453     fun mapp (k: int) =
   454       if k < i then f k :: mapp (k + 1) else [];
   455   in mapp 0 end;
   456 
   457 (*rear decomposition*)
   458 fun split_last [] = raise Empty
   459   | split_last [x] = ([], x)
   460   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   461 
   462 (*find position of first element satisfying a predicate*)
   463 fun find_index pred =
   464   let fun find (_: int) [] = ~1
   465         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   466   in find 0 end;
   467 
   468 (*find first element satisfying predicate*)
   469 val find_first = List.find;
   470 
   471 (*get first element by lookup function*)
   472 fun get_first _ [] = NONE
   473   | get_first f (x :: xs) =
   474       (case f x of
   475         NONE => get_first f xs
   476       | some => some);
   477 
   478 fun get_index f =
   479   let
   480     fun get (_: int) [] = NONE
   481       | get i (x :: xs) =
   482           case f x
   483            of NONE => get (i + 1) xs
   484             | SOME y => SOME (i, y)
   485   in get 0 end;
   486 
   487 val flat = List.concat;
   488 
   489 fun unflat (xs :: xss) ys =
   490       let val (ps, qs) = chop (length xs) ys
   491       in ps :: unflat xss qs end
   492   | unflat [] [] = []
   493   | unflat _ _ = raise ListPair.UnequalLengths;
   494 
   495 fun burrow f xss = unflat xss (f (flat xss));
   496 
   497 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   498 
   499 fun fold_burrow f xss s =
   500   apfst (unflat xss) (f (flat xss) s);
   501 
   502 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   503 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   504   | separate _ xs = xs;
   505 
   506 fun surround s (x :: xs) = s :: x :: surround s xs
   507   | surround s [] = [s];
   508 
   509 (*make the list [x, x, ..., x] of length n*)
   510 fun replicate (n: int) x =
   511   let fun rep (0, xs) = xs
   512         | rep (n, xs) = rep (n - 1, x :: xs)
   513   in
   514     if n < 0 then raise Subscript
   515     else rep (n, [])
   516   end;
   517 
   518 
   519 (* direct product *)
   520 
   521 fun map_product f _ [] = []
   522   | map_product f [] _ = []
   523   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   524 
   525 fun fold_product f _ [] z = z
   526   | fold_product f [] _ z = z
   527   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   528 
   529 
   530 (* lists of pairs *)
   531 
   532 fun map2 _ [] [] = []
   533   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   534   | map2 _ _ _ = raise ListPair.UnequalLengths;
   535 
   536 fun fold2 f [] [] z = z
   537   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   538   | fold2 f _ _ _ = raise ListPair.UnequalLengths;
   539 
   540 fun fold_rev2 f [] [] z = z
   541   | fold_rev2 f (x :: xs) (y :: ys) z = f x y (fold_rev2 f xs ys z)
   542   | fold_rev2 f _ _ _ = raise ListPair.UnequalLengths;
   543 
   544 fun forall2 P [] [] = true
   545   | forall2 P (x :: xs) (y :: ys) = P x y andalso forall2 P xs ys
   546   | forall2 P _ _ = raise ListPair.UnequalLengths;
   547 
   548 fun map_split f [] = ([], [])
   549   | map_split f (x :: xs) =
   550       let
   551         val (y, w) = f x;
   552         val (ys, ws) = map_split f xs;
   553       in (y :: ys, w :: ws) end;
   554 
   555 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   556   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   557   | zip_options _ [] = []
   558   | zip_options [] _ = raise ListPair.UnequalLengths;
   559 
   560 (*combine two lists forming a list of pairs:
   561   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   562 fun [] ~~ [] = []
   563   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   564   | _ ~~ _ = raise ListPair.UnequalLengths;
   565 
   566 (*inverse of ~~; the old 'split':
   567   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   568 val split_list = ListPair.unzip;
   569 
   570 fun burrow_fst f xs = split_list xs |>> f |> op ~~;
   571 
   572 
   573 (* prefixes, suffixes *)
   574 
   575 fun is_prefix _ [] _ = true
   576   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   577   | is_prefix eq _ _ = false;
   578 
   579 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   580    where xi is the first element that does not satisfy the predicate*)
   581 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   582   let fun take (rxs, []) = (rev rxs, [])
   583         | take (rxs, x :: xs) =
   584             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   585   in  take([], xs)  end;
   586 
   587 fun chop_prefix eq ([], ys) = ([], ([], ys))
   588   | chop_prefix eq (xs, []) = ([], (xs, []))
   589   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   590       if eq (x, y) then
   591         let val (ps', xys'') = chop_prefix eq (xs', ys')
   592         in (x :: ps', xys'') end
   593       else ([], (xs, ys));
   594 
   595 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   596    where xi is the last element that does not satisfy the predicate*)
   597 fun take_suffix _ [] = ([], [])
   598   | take_suffix pred (x :: xs) =
   599       (case take_suffix pred xs of
   600         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   601       | (prfx, sffx) => (x :: prfx, sffx));
   602 
   603 fun prefixes1 [] = []
   604   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   605 
   606 fun prefixes xs = [] :: prefixes1 xs;
   607 
   608 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   609 fun suffixes xs = [] :: suffixes1 xs;
   610 
   611 
   612 
   613 (** integers **)
   614 
   615 (* lists of integers *)
   616 
   617 (*make the list [from, from + 1, ..., to]*)
   618 fun ((i: int) upto j) =
   619   if i > j then [] else i :: (i + 1 upto j);
   620 
   621 (*make the list [from, from - 1, ..., to]*)
   622 fun ((i: int) downto j) =
   623   if i < j then [] else i :: (i - 1 downto j);
   624 
   625 
   626 (* convert integers to strings *)
   627 
   628 (*expand the number in the given base;
   629   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   630 fun radixpand (base, num) : int list =
   631   let
   632     fun radix (n, tail) =
   633       if n < base then n :: tail
   634       else radix (n div base, (n mod base) :: tail)
   635   in radix (num, []) end;
   636 
   637 (*expands a number into a string of characters starting from "zerochar";
   638   example: radixstring (2, "0", 8) gives "1000"*)
   639 fun radixstring (base, zerochar, num) =
   640   let val offset = ord zerochar;
   641       fun chrof n = chr (offset + n)
   642   in implode (map chrof (radixpand (base, num))) end;
   643 
   644 
   645 val string_of_int = Int.toString;
   646 
   647 fun signed_string_of_int i =
   648   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   649 
   650 fun string_of_indexname (a, 0) = a
   651   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   652 
   653 
   654 (* read integers *)
   655 
   656 fun read_radix_int radix cs =
   657   let
   658     val zero = ord "0";
   659     val limit = zero + radix;
   660     fun scan (num, []) = (num, [])
   661       | scan (num, c :: cs) =
   662         if zero <= ord c andalso ord c < limit then
   663           scan (radix * num + (ord c - zero), cs)
   664         else (num, c :: cs);
   665   in scan (0, cs) end;
   666 
   667 val read_int = read_radix_int 10;
   668 
   669 fun oct_char s = chr (#1 (read_radix_int 8 (raw_explode s)));
   670 
   671 
   672 
   673 (** reals **)
   674 
   675 val string_of_real = Real.fmt (StringCvt.GEN NONE);
   676 
   677 fun signed_string_of_real x =
   678   if x < 0.0 then "-" ^ string_of_real (~ x) else string_of_real x;
   679 
   680 
   681 
   682 (** strings **)
   683 
   684 (* functions tuned for strings, avoiding explode *)
   685 
   686 fun nth_string str i =
   687   (case try String.substring (str, i, 1) of
   688     SOME s => s
   689   | NONE => raise Subscript);
   690 
   691 fun fold_string f str x0 =
   692   let
   693     val n = size str;
   694     fun iter (x, i) =
   695       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   696   in iter (x0, 0) end;
   697 
   698 fun exists_string pred str =
   699   let
   700     val n = size str;
   701     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   702   in ex 0 end;
   703 
   704 fun forall_string pred = not o exists_string (not o pred);
   705 
   706 fun first_field sep str =
   707   let
   708     val n = size sep;
   709     val len = size str;
   710     fun find i =
   711       if i + n > len then NONE
   712       else if String.substring (str, i, n) = sep then SOME i
   713       else find (i + 1);
   714   in
   715     (case find 0 of
   716       NONE => NONE
   717     | SOME i => SOME (String.substring (str, 0, i), String.extract (str, i + n, NONE)))
   718   end;
   719 
   720 (*enclose in brackets*)
   721 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   722 fun unenclose str = String.substring (str, 1, size str - 2);
   723 
   724 (*simple quoting (does not escape special chars)*)
   725 val quote = enclose "\"" "\"";
   726 
   727 fun space_implode a bs = implode (separate a bs);
   728 
   729 val commas = space_implode ", ";
   730 val commas_quote = commas o map quote;
   731 
   732 val cat_lines = space_implode "\n";
   733 
   734 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   735 fun space_explode _ "" = []
   736   | space_explode sep s = String.fields (fn c => str c = sep) s;
   737 
   738 val split_lines = space_explode "\n";
   739 
   740 fun prefix_lines "" txt = txt
   741   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   742 
   743 fun prefix prfx s = prfx ^ s;
   744 fun suffix sffx s = s ^ sffx;
   745 
   746 fun unprefix prfx s =
   747   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   748   else raise Fail "unprefix";
   749 
   750 fun unsuffix sffx s =
   751   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   752   else raise Fail "unsuffix";
   753 
   754 fun replicate_string (0: int) _ = ""
   755   | replicate_string 1 a = a
   756   | replicate_string k a =
   757       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   758       else replicate_string (k div 2) (a ^ a) ^ a;
   759 
   760 fun translate_string f = String.translate (f o String.str);
   761 
   762 (*crude matching of str against simple glob pat*)
   763 fun match_string pat str =
   764   let
   765     fun match [] _ = true
   766       | match (p :: ps) s =
   767           size p <= size s andalso
   768             (case try (unprefix p) s of
   769               SOME s' => match ps s'
   770             | NONE => match (p :: ps) (String.substring (s, 1, size s - 1)));
   771   in match (space_explode "*" pat) str end;
   772 
   773 
   774 
   775 (** lists as sets -- see also Pure/General/ord_list.ML **)
   776 
   777 (* canonical operations *)
   778 
   779 fun member eq list x =
   780   let
   781     fun memb [] = false
   782       | memb (y :: ys) = eq (x, y) orelse memb ys;
   783   in memb list end;
   784 
   785 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   786 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   787 fun update eq x xs = cons x (remove eq x xs);
   788 
   789 fun inter eq xs = filter (member eq xs);
   790 
   791 fun union eq = fold (insert eq);
   792 fun subtract eq = fold (remove eq);
   793 
   794 fun merge eq (xs, ys) =
   795   if pointer_eq (xs, ys) then xs
   796   else if null xs then ys
   797   else fold_rev (insert eq) ys xs;
   798 
   799 
   800 (* subset and set equality *)
   801 
   802 fun subset eq (xs, ys) = forall (member eq ys) xs;
   803 
   804 fun eq_set eq (xs, ys) =
   805   eq_list eq (xs, ys) orelse
   806     (subset eq (xs, ys) andalso subset (eq o swap) (ys, xs));
   807 
   808 
   809 (*makes a list of the distinct members of the input; preserves order, takes
   810   first of equal elements*)
   811 fun distinct eq lst =
   812   let
   813     fun dist (rev_seen, []) = rev rev_seen
   814       | dist (rev_seen, x :: xs) =
   815           if member eq rev_seen x then dist (rev_seen, xs)
   816           else dist (x :: rev_seen, xs);
   817   in dist ([], lst) end;
   818 
   819 (*returns a list containing all repeated elements exactly once; preserves
   820   order, takes first of equal elements*)
   821 fun duplicates eq lst =
   822   let
   823     fun dups (rev_dups, []) = rev rev_dups
   824       | dups (rev_dups, x :: xs) =
   825           if member eq rev_dups x orelse not (member eq xs x) then
   826             dups (rev_dups, xs)
   827           else dups (x :: rev_dups, xs);
   828   in dups ([], lst) end;
   829 
   830 fun has_duplicates eq =
   831   let
   832     fun dups [] = false
   833       | dups (x :: xs) = member eq xs x orelse dups xs;
   834   in dups end;
   835 
   836 
   837 (* matrices *)
   838 
   839 fun map_transpose f xss =
   840   let
   841     val n =
   842       (case distinct (op =) (map length xss) of
   843         [] => 0
   844       | [n] => n
   845       | _ => raise ListPair.UnequalLengths);
   846   in map_range (fn m => f (map (fn xs => nth xs m) xss)) n end;
   847 
   848 
   849 
   850 (** lists as multisets **)
   851 
   852 fun remove1 eq x [] = []
   853   | remove1 eq x (y :: ys) = if eq (x, y) then ys else y :: remove1 eq x ys;
   854 
   855 fun combine eq xs ys = fold (remove1 eq) ys xs @ ys;
   856 
   857 fun submultiset _ ([], _)  = true
   858   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   859 
   860 
   861 
   862 (** orders **)
   863 
   864 fun is_equal EQUAL = true
   865   | is_equal _ = false;
   866 
   867 fun rev_order LESS = GREATER
   868   | rev_order EQUAL = EQUAL
   869   | rev_order GREATER = LESS;
   870 
   871 (*assume rel is a linear strict order*)
   872 fun make_ord rel (x, y) =
   873   if rel (x, y) then LESS
   874   else if rel (y, x) then GREATER
   875   else EQUAL;
   876 
   877 fun bool_ord (false, true) = LESS
   878   | bool_ord (true, false) = GREATER
   879   | bool_ord _ = EQUAL;
   880 
   881 val int_ord = Int.compare;
   882 val string_ord = String.compare;
   883 
   884 fun fast_string_ord (s1, s2) =
   885   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   886 
   887 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   888   | option_ord _ (NONE, NONE) = EQUAL
   889   | option_ord _ (NONE, SOME _) = LESS
   890   | option_ord _ (SOME _, NONE) = GREATER;
   891 
   892 (*lexicographic product*)
   893 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   894   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   895 
   896 (*dictionary order -- in general NOT well-founded!*)
   897 fun dict_ord elem_ord (x :: xs, y :: ys) =
   898       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   899   | dict_ord _ ([], []) = EQUAL
   900   | dict_ord _ ([], _ :: _) = LESS
   901   | dict_ord _ (_ :: _, []) = GREATER;
   902 
   903 (*lexicographic product of lists*)
   904 fun list_ord elem_ord (xs, ys) =
   905   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   906 
   907 
   908 (* sorting *)
   909 
   910 (*quicksort -- stable, i.e. does not reorder equal elements*)
   911 fun quicksort unique ord =
   912   let
   913     fun qsort [] = []
   914       | qsort (xs as [_]) = xs
   915       | qsort (xs as [x, y]) =
   916           (case ord (x, y) of
   917             LESS => xs
   918           | EQUAL => if unique then [x] else xs
   919           | GREATER => [y, x])
   920       | qsort xs =
   921           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   922           in qsort lts @ eqs @ qsort gts end
   923     and part _ [] = ([], [], [])
   924       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   925     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   926       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   927       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   928       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   929   in qsort end;
   930 
   931 fun sort ord = quicksort false ord;
   932 fun sort_distinct ord = quicksort true ord;
   933 
   934 val sort_strings = sort string_ord;
   935 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   936 
   937 
   938 (* items tagged by integer index *)
   939 
   940 (*insert tags*)
   941 fun tag_list k [] = []
   942   | tag_list k (x :: xs) = (k:int, x) :: tag_list (k + 1) xs;
   943 
   944 (*remove tags and suppress duplicates -- list is assumed sorted!*)
   945 fun untag_list [] = []
   946   | untag_list [(k: int, x)] = [x]
   947   | untag_list ((k, x) :: (rest as (k', x') :: _)) =
   948       if k = k' then untag_list rest
   949       else x :: untag_list rest;
   950 
   951 (*return list elements in original order*)
   952 fun order_list list = untag_list (sort (int_ord o pairself fst) list);
   953 
   954 
   955 
   956 (** random numbers **)
   957 
   958 exception RANDOM;
   959 
   960 fun rmod x y = x - y * Real.realFloor (x / y);
   961 
   962 local
   963   val a = 16807.0;
   964   val m = 2147483647.0;
   965   val random_seed = Unsynchronized.ref 1.0;
   966 in
   967 
   968 fun random () = CRITICAL (fn () =>
   969   let val r = rmod (a * ! random_seed) m
   970   in (random_seed := r; r) end);
   971 
   972 end;
   973 
   974 fun random_range l h =
   975   if h < l orelse l < 0 then raise RANDOM
   976   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
   977 
   978 fun one_of xs = nth xs (random_range 0 (length xs - 1));
   979 
   980 fun frequency xs =
   981   let
   982     val sum = foldl op + (0, map fst xs);
   983     fun pick n ((k: int, x) :: xs) =
   984       if n <= k then x else pick (n - k) xs
   985   in pick (random_range 1 sum) xs end;
   986 
   987 
   988 
   989 (** misc **)
   990 
   991 fun divide_and_conquer decomp x =
   992   let val (ys, recomb) = decomp x
   993   in recomb (map (divide_and_conquer decomp) ys) end;
   994 
   995 fun divide_and_conquer' decomp x s =
   996   let val ((ys, recomb), s') = decomp x s
   997   in recomb (fold_map (divide_and_conquer' decomp) ys s') end;
   998 
   999 
  1000 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1001    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1002 fun partition_list p i j =
  1003   let
  1004     fun part (k: int) xs =
  1005       if k > j then
  1006         (case xs of
  1007           [] => []
  1008         | _ => raise Fail "partition_list")
  1009       else
  1010         let val (ns, rest) = List.partition (p k) xs
  1011         in ns :: part (k + 1) rest end;
  1012   in part (i: int) end;
  1013 
  1014 fun partition_eq (eq: 'a * 'a -> bool) =
  1015   let
  1016     fun part [] = []
  1017       | part (x :: ys) =
  1018           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1019           in (x :: xs) :: part xs' end;
  1020   in part end;
  1021 
  1022 
  1023 
  1024 (* generating identifiers *)
  1025 
  1026 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1027 local
  1028 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1029 fun gensym_char i =
  1030   if i<26 then chr (ord "A" + i)
  1031   else if i<52 then chr (ord "a" + i - 26)
  1032   else chr (ord "0" + i - 52);
  1033 
  1034 val char_vec = Vector.tabulate (62, gensym_char);
  1035 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1036 
  1037 val gensym_seed = Unsynchronized.ref (0: int);
  1038 
  1039 in
  1040   fun gensym pre =
  1041     pre ^ newid (NAMED_CRITICAL "gensym" (fn () => Unsynchronized.inc gensym_seed));
  1042 end;
  1043 
  1044 
  1045 (* stamps and serial numbers *)
  1046 
  1047 type stamp = unit Unsynchronized.ref;
  1048 val stamp: unit -> stamp = Unsynchronized.ref;
  1049 
  1050 type serial = int;
  1051 val serial = Multithreading.serial;
  1052 val serial_string = string_of_int o serial;
  1053 
  1054 
  1055 (* generic objects *)
  1056 
  1057 (*note that the builtin exception datatype may be extended by new
  1058   constructors at any time*)
  1059 structure Object = struct type T = exn end;
  1060 
  1061 end;
  1062 
  1063 structure Basic_Library: BASIC_LIBRARY = Library;
  1064 open Basic_Library;
  1065 
  1066 datatype legacy = UnequalLengths;