src/Pure/drule.ML
author wenzelm
Wed Jan 03 21:18:31 2001 +0100 (2001-01-03)
changeset 10767 8fa4aafa7314
parent 10667 75a1c9575edb
child 10815 dd5fb02ff872
permissions -rw-r--r--
Thm: dest_comb, dest_abs, capply, cabs no longer global;
     1 (*  Title:      Pure/drule.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Derived rules and other operations on theorems.
     7 *)
     8 
     9 infix 0 RS RSN RL RLN MRS MRL OF COMP;
    10 
    11 signature BASIC_DRULE =
    12 sig
    13   val mk_implies        : cterm * cterm -> cterm
    14   val list_implies      : cterm list * cterm -> cterm
    15   val dest_implies      : cterm -> cterm * cterm
    16   val dest_equals       : cterm -> cterm * cterm
    17   val skip_flexpairs    : cterm -> cterm
    18   val strip_imp_prems   : cterm -> cterm list
    19   val strip_imp_concl   : cterm -> cterm
    20   val cprems_of         : thm -> cterm list
    21   val read_insts        :
    22           Sign.sg -> (indexname -> typ option) * (indexname -> sort option)
    23                   -> (indexname -> typ option) * (indexname -> sort option)
    24                   -> string list -> (string*string)list
    25                   -> (indexname*ctyp)list * (cterm*cterm)list
    26   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    27   val strip_shyps_warning : thm -> thm
    28   val forall_intr_list  : cterm list -> thm -> thm
    29   val forall_intr_frees : thm -> thm
    30   val forall_intr_vars  : thm -> thm
    31   val forall_elim_list  : cterm list -> thm -> thm
    32   val forall_elim_var   : int -> thm -> thm
    33   val forall_elim_vars  : int -> thm -> thm
    34   val forall_elim_vars_safe  : thm -> thm
    35   val freeze_thaw       : thm -> thm * (thm -> thm)
    36   val implies_elim_list : thm -> thm list -> thm
    37   val implies_intr_list : cterm list -> thm -> thm
    38   val instantiate       :
    39     (indexname * ctyp) list * (cterm * cterm) list -> thm -> thm
    40   val zero_var_indexes  : thm -> thm
    41   val standard          : thm -> thm
    42   val rotate_prems      : int -> thm -> thm
    43   val assume_ax         : theory -> string -> thm
    44   val RSN               : thm * (int * thm) -> thm
    45   val RS                : thm * thm -> thm
    46   val RLN               : thm list * (int * thm list) -> thm list
    47   val RL                : thm list * thm list -> thm list
    48   val MRS               : thm list * thm -> thm
    49   val MRL               : thm list list * thm list -> thm list
    50   val OF                : thm * thm list -> thm
    51   val compose           : thm * int * thm -> thm list
    52   val COMP              : thm * thm -> thm
    53   val read_instantiate_sg: Sign.sg -> (string*string)list -> thm -> thm
    54   val read_instantiate  : (string*string)list -> thm -> thm
    55   val cterm_instantiate : (cterm*cterm)list -> thm -> thm
    56   val weak_eq_thm       : thm * thm -> bool
    57   val eq_thm_sg         : thm * thm -> bool
    58   val size_of_thm       : thm -> int
    59   val reflexive_thm     : thm
    60   val symmetric_thm     : thm
    61   val transitive_thm    : thm
    62   val refl_implies      : thm
    63   val symmetric_fun     : thm -> thm
    64   val imp_cong          : thm
    65   val swap_prems_eq     : thm
    66   val equal_abs_elim    : cterm  -> thm -> thm
    67   val equal_abs_elim_list: cterm list -> thm -> thm
    68   val flexpair_abs_elim_list: cterm list -> thm -> thm
    69   val asm_rl            : thm
    70   val cut_rl            : thm
    71   val revcut_rl         : thm
    72   val thin_rl           : thm
    73   val triv_forall_equality: thm
    74   val swap_prems_rl     : thm
    75   val equal_intr_rule   : thm
    76   val inst              : string -> string -> thm -> thm
    77   val instantiate'      : ctyp option list -> cterm option list -> thm -> thm
    78   val incr_indexes_wrt  : int list -> ctyp list -> cterm list -> thm list -> thm -> thm
    79 end;
    80 
    81 signature DRULE =
    82 sig
    83   include BASIC_DRULE
    84   val rule_attribute    : ('a -> thm -> thm) -> 'a attribute
    85   val tag_rule          : tag -> thm -> thm
    86   val untag_rule        : string -> thm -> thm
    87   val tag               : tag -> 'a attribute
    88   val untag             : string -> 'a attribute
    89   val tag_lemma         : 'a attribute
    90   val tag_assumption    : 'a attribute
    91   val tag_internal      : 'a attribute
    92   val has_internal	: tag list -> bool
    93   val close_derivation  : thm -> thm
    94   val compose_single    : thm * int * thm -> thm
    95   val add_rules		: thm list -> thm list -> thm list
    96   val del_rules		: thm list -> thm list -> thm list
    97   val merge_rules	: thm list * thm list -> thm list
    98   val norm_hhf_eq	: thm
    99   val triv_goal         : thm
   100   val rev_triv_goal     : thm
   101   val freeze_all        : thm -> thm
   102   val mk_triv_goal      : cterm -> thm
   103   val mk_cgoal          : cterm -> cterm
   104   val assume_goal       : cterm -> thm
   105   val tvars_of_terms    : term list -> (indexname * sort) list
   106   val vars_of_terms     : term list -> (indexname * typ) list
   107   val tvars_of          : thm -> (indexname * sort) list
   108   val vars_of           : thm -> (indexname * typ) list
   109   val unvarifyT         : thm -> thm
   110   val unvarify          : thm -> thm
   111   val tvars_intr_list	: string list -> thm -> thm
   112 end;
   113 
   114 structure Drule: DRULE =
   115 struct
   116 
   117 
   118 (** some cterm->cterm operations: much faster than calling cterm_of! **)
   119 
   120 (** SAME NAMES as in structure Logic: use compound identifiers! **)
   121 
   122 (*dest_implies for cterms. Note T=prop below*)
   123 fun dest_implies ct =
   124     case term_of ct of
   125         (Const("==>", _) $ _ $ _) =>
   126             let val (ct1,ct2) = Thm.dest_comb ct
   127             in  (#2 (Thm.dest_comb ct1), ct2)  end
   128       | _ => raise TERM ("dest_implies", [term_of ct]) ;
   129 
   130 fun dest_equals ct =
   131     case term_of ct of
   132         (Const("==", _) $ _ $ _) =>
   133             let val (ct1,ct2) = Thm.dest_comb ct
   134             in  (#2 (Thm.dest_comb ct1), ct2)  end
   135       | _ => raise TERM ("dest_equals", [term_of ct]) ;
   136 
   137 
   138 (*Discard flexflex pairs; return a cterm*)
   139 fun skip_flexpairs ct =
   140     case term_of ct of
   141         (Const("==>", _) $ (Const("=?=",_)$_$_) $ _) =>
   142             skip_flexpairs (#2 (dest_implies ct))
   143       | _ => ct;
   144 
   145 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   146 fun strip_imp_prems ct =
   147     let val (cA,cB) = dest_implies ct
   148     in  cA :: strip_imp_prems cB  end
   149     handle TERM _ => [];
   150 
   151 (* A1==>...An==>B  goes to B, where B is not an implication *)
   152 fun strip_imp_concl ct =
   153     case term_of ct of (Const("==>", _) $ _ $ _) =>
   154         strip_imp_concl (#2 (Thm.dest_comb ct))
   155   | _ => ct;
   156 
   157 (*The premises of a theorem, as a cterm list*)
   158 val cprems_of = strip_imp_prems o skip_flexpairs o cprop_of;
   159 
   160 val proto_sign = Theory.sign_of ProtoPure.thy;
   161 
   162 val implies = cterm_of proto_sign Term.implies;
   163 
   164 (*cterm version of mk_implies*)
   165 fun mk_implies(A,B) = Thm.capply (Thm.capply implies A) B;
   166 
   167 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   168 fun list_implies([], B) = B
   169   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   170 
   171 
   172 (** reading of instantiations **)
   173 
   174 fun absent ixn =
   175   error("No such variable in term: " ^ Syntax.string_of_vname ixn);
   176 
   177 fun inst_failure ixn =
   178   error("Instantiation of " ^ Syntax.string_of_vname ixn ^ " fails");
   179 
   180 fun read_insts sign (rtypes,rsorts) (types,sorts) used insts =
   181 let
   182     fun split([],tvs,vs) = (tvs,vs)
   183       | split((sv,st)::l,tvs,vs) = (case Symbol.explode sv of
   184                   "'"::cs => split(l,(Syntax.indexname cs,st)::tvs,vs)
   185                 | cs => split(l,tvs,(Syntax.indexname cs,st)::vs));
   186     val (tvs,vs) = split(insts,[],[]);
   187     fun readT((a,i),st) =
   188         let val ixn = ("'" ^ a,i);
   189             val S = case rsorts ixn of Some S => S | None => absent ixn;
   190             val T = Sign.read_typ (sign,sorts) st;
   191         in if Sign.typ_instance sign (T, TVar(ixn,S)) then (ixn,T)
   192            else inst_failure ixn
   193         end
   194     val tye = map readT tvs;
   195     fun mkty(ixn,st) = (case rtypes ixn of
   196                           Some T => (ixn,(st,typ_subst_TVars tye T))
   197                         | None => absent ixn);
   198     val ixnsTs = map mkty vs;
   199     val ixns = map fst ixnsTs
   200     and sTs  = map snd ixnsTs
   201     val (cts,tye2) = read_def_cterms(sign,types,sorts) used false sTs;
   202     fun mkcVar(ixn,T) =
   203         let val U = typ_subst_TVars tye2 T
   204         in cterm_of sign (Var(ixn,U)) end
   205     val ixnTs = ListPair.zip(ixns, map snd sTs)
   206 in (map (fn (ixn,T) => (ixn,ctyp_of sign T)) (tye2 @ tye),
   207     ListPair.zip(map mkcVar ixnTs,cts))
   208 end;
   209 
   210 
   211 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   212      Used for establishing default types (of variables) and sorts (of
   213      type variables) when reading another term.
   214      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   215 ***)
   216 
   217 fun types_sorts thm =
   218     let val {prop,hyps,...} = rep_thm thm;
   219         val big = list_comb(prop,hyps); (* bogus term! *)
   220         val vars = map dest_Var (term_vars big);
   221         val frees = map dest_Free (term_frees big);
   222         val tvars = term_tvars big;
   223         val tfrees = term_tfrees big;
   224         fun typ(a,i) = if i<0 then assoc(frees,a) else assoc(vars,(a,i));
   225         fun sort(a,i) = if i<0 then assoc(tfrees,a) else assoc(tvars,(a,i));
   226     in (typ,sort) end;
   227 
   228 
   229 
   230 (** basic attributes **)
   231 
   232 (* dependent rules *)
   233 
   234 fun rule_attribute f (x, thm) = (x, (f x thm));
   235 
   236 
   237 (* add / delete tags *)
   238 
   239 fun map_tags f thm =
   240   Thm.put_name_tags (Thm.name_of_thm thm, f (#2 (Thm.get_name_tags thm))) thm;
   241 
   242 fun tag_rule tg = map_tags (fn tgs => if tg mem tgs then tgs else tgs @ [tg]);
   243 fun untag_rule s = map_tags (filter_out (equal s o #1));
   244 
   245 fun tag tg x = rule_attribute (K (tag_rule tg)) x;
   246 fun untag s x = rule_attribute (K (untag_rule s)) x;
   247 
   248 fun simple_tag name x = tag (name, []) x;
   249 
   250 fun tag_lemma x = simple_tag "lemma" x;
   251 fun tag_assumption x = simple_tag "assumption" x;
   252 
   253 val internal_tag = ("internal", []);
   254 fun tag_internal x = tag internal_tag x;
   255 fun has_internal tags = exists (equal internal_tag) tags;
   256 
   257 
   258 
   259 (** Standardization of rules **)
   260 
   261 (*Strip extraneous shyps as far as possible*)
   262 fun strip_shyps_warning thm =
   263   let
   264     val str_of_sort = Sign.str_of_sort (Thm.sign_of_thm thm);
   265     val thm' = Thm.strip_shyps thm;
   266     val xshyps = Thm.extra_shyps thm';
   267   in
   268     if null xshyps then ()
   269     else warning ("Pending sort hypotheses: " ^ commas (map str_of_sort xshyps));
   270     thm'
   271   end;
   272 
   273 (*Generalization over a list of variables, IGNORING bad ones*)
   274 fun forall_intr_list [] th = th
   275   | forall_intr_list (y::ys) th =
   276         let val gth = forall_intr_list ys th
   277         in  forall_intr y gth   handle THM _ =>  gth  end;
   278 
   279 (*Generalization over all suitable Free variables*)
   280 fun forall_intr_frees th =
   281     let val {prop,sign,...} = rep_thm th
   282     in  forall_intr_list
   283          (map (cterm_of sign) (sort (make_ord atless) (term_frees prop)))
   284          th
   285     end;
   286 
   287 val forall_elim_var = PureThy.forall_elim_var;
   288 val forall_elim_vars = PureThy.forall_elim_vars;
   289 
   290 fun forall_elim_vars_safe th =
   291   forall_elim_vars_safe (forall_elim_var (#maxidx (Thm.rep_thm th) + 1) th)
   292     handle THM _ => th;
   293 
   294 
   295 (*Specialization over a list of cterms*)
   296 fun forall_elim_list cts th = foldr (uncurry forall_elim) (rev cts, th);
   297 
   298 (* maps [A1,...,An], B   to   [| A1;...;An |] ==> B  *)
   299 fun implies_intr_list cAs th = foldr (uncurry implies_intr) (cAs,th);
   300 
   301 (* maps [| A1;...;An |] ==> B and [A1,...,An]   to   B *)
   302 fun implies_elim_list impth ths = foldl (uncurry implies_elim) (impth,ths);
   303 
   304 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   305 fun zero_var_indexes th =
   306     let val {prop,sign,...} = rep_thm th;
   307         val vars = term_vars prop
   308         val bs = foldl add_new_id ([], map (fn Var((a,_),_)=>a) vars)
   309         val inrs = add_term_tvars(prop,[]);
   310         val nms' = rev(foldl add_new_id ([], map (#1 o #1) inrs));
   311         val tye = ListPair.map (fn ((v,rs),a) => (v, TVar((a,0),rs)))
   312                      (inrs, nms')
   313         val ctye = map (fn (v,T) => (v,ctyp_of sign T)) tye;
   314         fun varpairs([],[]) = []
   315           | varpairs((var as Var(v,T)) :: vars, b::bs) =
   316                 let val T' = typ_subst_TVars tye T
   317                 in (cterm_of sign (Var(v,T')),
   318                     cterm_of sign (Var((b,0),T'))) :: varpairs(vars,bs)
   319                 end
   320           | varpairs _ = raise TERM("varpairs", []);
   321     in Thm.instantiate (ctye, varpairs(vars,rev bs)) th end;
   322 
   323 
   324 (*Standard form of object-rule: no hypotheses, Frees, or outer quantifiers;
   325     all generality expressed by Vars having index 0.*)
   326 
   327 fun close_derivation thm =
   328   if Thm.get_name_tags thm = ("", []) then Thm.name_thm ("", thm)
   329   else thm;
   330 
   331 fun standard th =
   332   let val {maxidx,...} = rep_thm th in
   333     th
   334     |> implies_intr_hyps
   335     |> forall_intr_frees |> forall_elim_vars (maxidx + 1)
   336     |> strip_shyps_warning
   337     |> zero_var_indexes |> Thm.varifyT |> Thm.compress |> close_derivation
   338   end;
   339 
   340 
   341 (*Convert all Vars in a theorem to Frees.  Also return a function for
   342   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   343   Similar code in type/freeze_thaw*)
   344 fun freeze_thaw th =
   345  let val fth = freezeT th
   346      val {prop,sign,...} = rep_thm fth
   347  in
   348    case term_vars prop of
   349        [] => (fth, fn x => x)
   350      | vars =>
   351          let fun newName (Var(ix,_), (pairs,used)) =
   352                    let val v = variant used (string_of_indexname ix)
   353                    in  ((ix,v)::pairs, v::used)  end;
   354              val (alist, _) = foldr newName
   355                                 (vars, ([], add_term_names (prop, [])))
   356              fun mk_inst (Var(v,T)) =
   357                  (cterm_of sign (Var(v,T)),
   358                   cterm_of sign (Free(the (assoc(alist,v)), T)))
   359              val insts = map mk_inst vars
   360              fun thaw th' =
   361                  th' |> forall_intr_list (map #2 insts)
   362                      |> forall_elim_list (map #1 insts)
   363          in  (Thm.instantiate ([],insts) fth, thaw)  end
   364  end;
   365 
   366 
   367 (*Rotates a rule's premises to the left by k*)
   368 val rotate_prems = permute_prems 0;
   369 
   370 
   371 (*Assume a new formula, read following the same conventions as axioms.
   372   Generalizes over Free variables,
   373   creates the assumption, and then strips quantifiers.
   374   Example is [| ALL x:?A. ?P(x) |] ==> [| ?P(?a) |]
   375              [ !(A,P,a)[| ALL x:A. P(x) |] ==> [| P(a) |] ]    *)
   376 fun assume_ax thy sP =
   377     let val sign = Theory.sign_of thy
   378         val prop = Logic.close_form (term_of (read_cterm sign (sP, propT)))
   379     in forall_elim_vars 0 (assume (cterm_of sign prop))  end;
   380 
   381 (*Resolution: exactly one resolvent must be produced.*)
   382 fun tha RSN (i,thb) =
   383   case Seq.chop (2, biresolution false [(false,tha)] i thb) of
   384       ([th],_) => th
   385     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   386     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   387 
   388 (*resolution: P==>Q, Q==>R gives P==>R. *)
   389 fun tha RS thb = tha RSN (1,thb);
   390 
   391 (*For joining lists of rules*)
   392 fun thas RLN (i,thbs) =
   393   let val resolve = biresolution false (map (pair false) thas) i
   394       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   395   in  List.concat (map resb thbs)  end;
   396 
   397 fun thas RL thbs = thas RLN (1,thbs);
   398 
   399 (*Resolve a list of rules against bottom_rl from right to left;
   400   makes proof trees*)
   401 fun rls MRS bottom_rl =
   402   let fun rs_aux i [] = bottom_rl
   403         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   404   in  rs_aux 1 rls  end;
   405 
   406 (*As above, but for rule lists*)
   407 fun rlss MRL bottom_rls =
   408   let fun rs_aux i [] = bottom_rls
   409         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   410   in  rs_aux 1 rlss  end;
   411 
   412 (*A version of MRS with more appropriate argument order*)
   413 fun bottom_rl OF rls = rls MRS bottom_rl;
   414 
   415 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   416   with no lifting or renaming!  Q may contain ==> or meta-quants
   417   ALWAYS deletes premise i *)
   418 fun compose(tha,i,thb) =
   419     Seq.list_of (bicompose false (false,tha,0) i thb);
   420 
   421 fun compose_single (tha,i,thb) =
   422   (case compose (tha,i,thb) of
   423     [th] => th
   424   | _ => raise THM ("compose: unique result expected", i, [tha,thb]));
   425 
   426 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   427 fun tha COMP thb =
   428     case compose(tha,1,thb) of
   429         [th] => th
   430       | _ =>   raise THM("COMP", 1, [tha,thb]);
   431 
   432 (** theorem equality **)
   433 
   434 (*Do the two theorems have the same signature?*)
   435 fun eq_thm_sg (th1,th2) = Sign.eq_sg(#sign(rep_thm th1), #sign(rep_thm th2));
   436 
   437 (*Useful "distance" function for BEST_FIRST*)
   438 val size_of_thm = size_of_term o #prop o rep_thm;
   439 
   440 (*maintain lists of theorems --- preserving canonical order*)
   441 fun del_rules rs rules = Library.gen_rems Thm.eq_thm (rules, rs);
   442 fun add_rules rs rules = rs @ del_rules rs rules;
   443 fun merge_rules (rules1, rules2) = Library.generic_merge Thm.eq_thm I I rules1 rules2;
   444 
   445 
   446 (** Mark Staples's weaker version of eq_thm: ignores variable renaming and
   447     (some) type variable renaming **)
   448 
   449  (* Can't use term_vars, because it sorts the resulting list of variable names.
   450     We instead need the unique list noramlised by the order of appearance
   451     in the term. *)
   452 fun term_vars' (t as Var(v,T)) = [t]
   453   | term_vars' (Abs(_,_,b)) = term_vars' b
   454   | term_vars' (f$a) = (term_vars' f) @ (term_vars' a)
   455   | term_vars' _ = [];
   456 
   457 fun forall_intr_vars th =
   458   let val {prop,sign,...} = rep_thm th;
   459       val vars = distinct (term_vars' prop);
   460   in forall_intr_list (map (cterm_of sign) vars) th end;
   461 
   462 fun weak_eq_thm (tha,thb) =
   463     eq_thm(forall_intr_vars (freezeT tha), forall_intr_vars (freezeT thb));
   464 
   465 
   466 
   467 (*** Meta-Rewriting Rules ***)
   468 
   469 fun read_prop s = read_cterm proto_sign (s, propT);
   470 
   471 fun store_thm name thm = hd (PureThy.smart_store_thms (name, [thm]));
   472 fun store_standard_thm name thm = store_thm name (standard thm);
   473 
   474 val reflexive_thm =
   475   let val cx = cterm_of proto_sign (Var(("x",0),TVar(("'a",0),logicS)))
   476   in store_standard_thm "reflexive" (Thm.reflexive cx) end;
   477 
   478 val symmetric_thm =
   479   let val xy = read_prop "x::'a::logic == y"
   480   in store_standard_thm "symmetric" (Thm.implies_intr_hyps (Thm.symmetric (Thm.assume xy))) end;
   481 
   482 val transitive_thm =
   483   let val xy = read_prop "x::'a::logic == y"
   484       val yz = read_prop "y::'a::logic == z"
   485       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   486   in store_standard_thm "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   487 
   488 fun symmetric_fun thm = thm RS symmetric_thm;
   489 
   490 val imp_cong =
   491   let
   492     val ABC = read_prop "PROP A ==> PROP B == PROP C"
   493     val AB = read_prop "PROP A ==> PROP B"
   494     val AC = read_prop "PROP A ==> PROP C"
   495     val A = read_prop "PROP A"
   496   in
   497     store_standard_thm "imp_cong2" (implies_intr ABC (equal_intr
   498       (implies_intr AB (implies_intr A
   499         (equal_elim (implies_elim (assume ABC) (assume A))
   500           (implies_elim (assume AB) (assume A)))))
   501       (implies_intr AC (implies_intr A
   502         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   503           (implies_elim (assume AC) (assume A)))))))
   504   end;
   505 
   506 val swap_prems_eq =
   507   let
   508     val ABC = read_prop "PROP A ==> PROP B ==> PROP C"
   509     val BAC = read_prop "PROP B ==> PROP A ==> PROP C"
   510     val A = read_prop "PROP A"
   511     val B = read_prop "PROP B"
   512   in
   513     store_standard_thm "swap_prems_eq" (equal_intr
   514       (implies_intr ABC (implies_intr B (implies_intr A
   515         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   516       (implies_intr BAC (implies_intr A (implies_intr B
   517         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   518   end;
   519 
   520 val refl_implies = reflexive implies;
   521 
   522 
   523 (*** Some useful meta-theorems ***)
   524 
   525 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   526 val asm_rl = store_standard_thm "asm_rl" (Thm.trivial (read_prop "PROP ?psi"));
   527 val _ = store_thm "_" asm_rl;
   528 
   529 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   530 val cut_rl =
   531   store_standard_thm "cut_rl"
   532     (Thm.trivial (read_prop "PROP ?psi ==> PROP ?theta"));
   533 
   534 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   535      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   536 val revcut_rl =
   537   let val V = read_prop "PROP V"
   538       and VW = read_prop "PROP V ==> PROP W";
   539   in
   540     store_standard_thm "revcut_rl"
   541       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   542   end;
   543 
   544 (*for deleting an unwanted assumption*)
   545 val thin_rl =
   546   let val V = read_prop "PROP V"
   547       and W = read_prop "PROP W";
   548   in  store_standard_thm "thin_rl" (implies_intr V (implies_intr W (assume W)))
   549   end;
   550 
   551 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   552 val triv_forall_equality =
   553   let val V  = read_prop "PROP V"
   554       and QV = read_prop "!!x::'a. PROP V"
   555       and x  = read_cterm proto_sign ("x", TypeInfer.logicT);
   556   in
   557     store_standard_thm "triv_forall_equality"
   558       (standard (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   559         (implies_intr V  (forall_intr x (assume V)))))
   560   end;
   561 
   562 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   563    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   564    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   565 *)
   566 val swap_prems_rl =
   567   let val cmajor = read_prop "PROP PhiA ==> PROP PhiB ==> PROP Psi";
   568       val major = assume cmajor;
   569       val cminor1 = read_prop "PROP PhiA";
   570       val minor1 = assume cminor1;
   571       val cminor2 = read_prop "PROP PhiB";
   572       val minor2 = assume cminor2;
   573   in store_standard_thm "swap_prems_rl"
   574        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   575          (implies_elim (implies_elim major minor1) minor2))))
   576   end;
   577 
   578 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   579    ==> PROP ?phi == PROP ?psi
   580    Introduction rule for == as a meta-theorem.
   581 *)
   582 val equal_intr_rule =
   583   let val PQ = read_prop "PROP phi ==> PROP psi"
   584       and QP = read_prop "PROP psi ==> PROP phi"
   585   in
   586     store_standard_thm "equal_intr_rule"
   587       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   588   end;
   589 
   590 
   591 (*(PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x))
   592   Rewrite rule for HHF normalization.
   593 
   594   Note: the syntax of ProtoPure is insufficient to handle this
   595   statement; storing it would be asking for trouble, e.g. when someone
   596   tries to print the theory later.
   597 *)
   598 
   599 val norm_hhf_eq =
   600   let
   601     val cert = Thm.cterm_of proto_sign;
   602     val aT = TFree ("'a", Term.logicS);
   603     val all = Term.all aT;
   604     val x = Free ("x", aT);
   605     val phi = Free ("phi", propT);
   606     val psi = Free ("psi", aT --> propT);
   607 
   608     val cx = cert x;
   609     val cphi = cert phi;
   610     val lhs = cert (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   611     val rhs = cert (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   612   in
   613     Thm.equal_intr
   614       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   615         |> Thm.forall_elim cx
   616         |> Thm.implies_intr cphi
   617         |> Thm.forall_intr cx
   618         |> Thm.implies_intr lhs)
   619       (Thm.implies_elim
   620           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   621         |> Thm.forall_intr cx
   622         |> Thm.implies_intr cphi
   623         |> Thm.implies_intr rhs)
   624     |> store_standard_thm "norm_hhf_eq"
   625   end;
   626 
   627 
   628 (*** Instantiate theorem th, reading instantiations under signature sg ****)
   629 
   630 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   631 fun instantiate instpair th = Thm.instantiate instpair th  COMP   asm_rl;
   632 
   633 fun read_instantiate_sg sg sinsts th =
   634     let val ts = types_sorts th;
   635         val used = add_term_tvarnames(#prop(rep_thm th),[]);
   636     in  instantiate (read_insts sg ts ts used sinsts) th  end;
   637 
   638 (*Instantiate theorem th, reading instantiations under theory of th*)
   639 fun read_instantiate sinsts th =
   640     read_instantiate_sg (#sign (rep_thm th)) sinsts th;
   641 
   642 
   643 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   644   Instantiates distinct Vars by terms, inferring type instantiations. *)
   645 local
   646   fun add_types ((ct,cu), (sign,tye,maxidx)) =
   647     let val {sign=signt, t=t, T= T, maxidx=maxt,...} = rep_cterm ct
   648         and {sign=signu, t=u, T= U, maxidx=maxu,...} = rep_cterm cu;
   649         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   650         val sign' = Sign.merge(sign, Sign.merge(signt, signu))
   651         val (tye',maxi') = Type.unify (#tsig(Sign.rep_sg sign')) maxi tye (T,U)
   652           handle Type.TUNIFY => raise TYPE("Ill-typed instantiation", [T,U], [t,u])
   653     in  (sign', tye', maxi')  end;
   654 in
   655 fun cterm_instantiate ctpairs0 th =
   656   let val (sign,tye,_) = foldr add_types (ctpairs0, (#sign(rep_thm th), Vartab.empty, 0))
   657       fun instT(ct,cu) = let val inst = subst_TVars_Vartab tye
   658                          in (cterm_fun inst ct, cterm_fun inst cu) end
   659       fun ctyp2 (ix,T) = (ix, ctyp_of sign T)
   660   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   661   handle TERM _ =>
   662            raise THM("cterm_instantiate: incompatible signatures",0,[th])
   663        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   664 end;
   665 
   666 
   667 (** Derived rules mainly for METAHYPS **)
   668 
   669 (*Given the term "a", takes (%x.t)==(%x.u) to t[a/x]==u[a/x]*)
   670 fun equal_abs_elim ca eqth =
   671   let val {sign=signa, t=a, ...} = rep_cterm ca
   672       and combth = combination eqth (reflexive ca)
   673       val {sign,prop,...} = rep_thm eqth
   674       val (abst,absu) = Logic.dest_equals prop
   675       val cterm = cterm_of (Sign.merge (sign,signa))
   676   in  transitive (symmetric (beta_conversion false (cterm (abst$a))))
   677            (transitive combth (beta_conversion false (cterm (absu$a))))
   678   end
   679   handle THM _ => raise THM("equal_abs_elim", 0, [eqth]);
   680 
   681 (*Calling equal_abs_elim with multiple terms*)
   682 fun equal_abs_elim_list cts th = foldr (uncurry equal_abs_elim) (rev cts, th);
   683 
   684 local
   685   val alpha = TVar(("'a",0), [])     (*  type ?'a::{}  *)
   686   fun err th = raise THM("flexpair_inst: ", 0, [th])
   687   fun flexpair_inst def th =
   688     let val {prop = Const _ $ t $ u,  sign,...} = rep_thm th
   689         val cterm = cterm_of sign
   690         fun cvar a = cterm(Var((a,0),alpha))
   691         val def' = cterm_instantiate [(cvar"t", cterm t), (cvar"u", cterm u)]
   692                    def
   693     in  equal_elim def' th
   694     end
   695     handle THM _ => err th | Bind => err th
   696 in
   697 val flexpair_intr = flexpair_inst (symmetric ProtoPure.flexpair_def)
   698 and flexpair_elim = flexpair_inst ProtoPure.flexpair_def
   699 end;
   700 
   701 (*Version for flexflex pairs -- this supports lifting.*)
   702 fun flexpair_abs_elim_list cts =
   703     flexpair_intr o equal_abs_elim_list cts o flexpair_elim;
   704 
   705 
   706 (*** Goal (PROP A) <==> PROP A ***)
   707 
   708 local
   709   val cert = Thm.cterm_of proto_sign;
   710   val A = Free ("A", propT);
   711   val G = Logic.mk_goal A;
   712   val (G_def, _) = freeze_thaw ProtoPure.Goal_def;
   713 in
   714   val triv_goal = store_thm "triv_goal" (tag_rule internal_tag (standard
   715       (Thm.equal_elim (Thm.symmetric G_def) (Thm.assume (cert A)))));
   716   val rev_triv_goal = store_thm "rev_triv_goal" (tag_rule internal_tag (standard
   717       (Thm.equal_elim G_def (Thm.assume (cert G)))));
   718 end;
   719 
   720 val mk_cgoal = Thm.capply (Thm.cterm_of proto_sign Logic.goal_const);
   721 fun assume_goal ct = Thm.assume (mk_cgoal ct) RS rev_triv_goal;
   722 
   723 
   724 
   725 (** variations on instantiate **)
   726 
   727 (*shorthand for instantiating just one variable in the current theory*)
   728 fun inst x t = read_instantiate_sg (sign_of (the_context())) [(x,t)];
   729 
   730 
   731 (* collect vars *)
   732 
   733 val add_tvarsT = foldl_atyps (fn (vs, TVar v) => v ins vs | (vs, _) => vs);
   734 val add_tvars = foldl_types add_tvarsT;
   735 val add_vars = foldl_aterms (fn (vs, Var v) => v ins vs | (vs, _) => vs);
   736 
   737 fun tvars_of_terms ts = rev (foldl add_tvars ([], ts));
   738 fun vars_of_terms ts = rev (foldl add_vars ([], ts));
   739 
   740 fun tvars_of thm = tvars_of_terms [#prop (Thm.rep_thm thm)];
   741 fun vars_of thm = vars_of_terms [#prop (Thm.rep_thm thm)];
   742 
   743 
   744 (* instantiate by left-to-right occurrence of variables *)
   745 
   746 fun instantiate' cTs cts thm =
   747   let
   748     fun err msg =
   749       raise TYPE ("instantiate': " ^ msg,
   750         mapfilter (apsome Thm.typ_of) cTs,
   751         mapfilter (apsome Thm.term_of) cts);
   752 
   753     fun inst_of (v, ct) =
   754       (Thm.cterm_of (#sign (Thm.rep_cterm ct)) (Var v), ct)
   755         handle TYPE (msg, _, _) => err msg;
   756 
   757     fun zip_vars _ [] = []
   758       | zip_vars (_ :: vs) (None :: opt_ts) = zip_vars vs opt_ts
   759       | zip_vars (v :: vs) (Some t :: opt_ts) = (v, t) :: zip_vars vs opt_ts
   760       | zip_vars [] _ = err "more instantiations than variables in thm";
   761 
   762     (*instantiate types first!*)
   763     val thm' =
   764       if forall is_none cTs then thm
   765       else Thm.instantiate (zip_vars (map fst (tvars_of thm)) cTs, []) thm;
   766     in
   767       if forall is_none cts then thm'
   768       else Thm.instantiate ([], map inst_of (zip_vars (vars_of thm') cts)) thm'
   769     end;
   770 
   771 
   772 (* unvarify(T) *)
   773 
   774 (*assume thm in standard form, i.e. no frees, 0 var indexes*)
   775 
   776 fun unvarifyT thm =
   777   let
   778     val cT = Thm.ctyp_of (Thm.sign_of_thm thm);
   779     val tfrees = map (fn ((x, _), S) => Some (cT (TFree (x, S)))) (tvars_of thm);
   780   in instantiate' tfrees [] thm end;
   781 
   782 fun unvarify raw_thm =
   783   let
   784     val thm = unvarifyT raw_thm;
   785     val ct = Thm.cterm_of (Thm.sign_of_thm thm);
   786     val frees = map (fn ((x, _), T) => Some (ct (Free (x, T)))) (vars_of thm);
   787   in instantiate' [] frees thm end;
   788 
   789 
   790 (* tvars_intr_list *)
   791 
   792 fun tfrees_of thm =
   793   let val {hyps, prop, ...} = Thm.rep_thm thm
   794   in foldr Term.add_term_tfree_names (prop :: hyps, []) end;
   795 
   796 fun tvars_intr_list tfrees thm =
   797   Thm.varifyT' (tfrees_of thm \\ tfrees) thm;
   798 
   799 
   800 (* increment var indexes *)
   801 
   802 fun incr_indexes_wrt is cTs cts thms =
   803   let
   804     val maxidx =
   805       foldl Int.max (~1, is @
   806         map (maxidx_of_typ o #T o Thm.rep_ctyp) cTs @
   807         map (#maxidx o Thm.rep_cterm) cts @
   808         map (#maxidx o Thm.rep_thm) thms);
   809   in Thm.incr_indexes (maxidx + 1) end;
   810 
   811 
   812 (* freeze_all *)
   813 
   814 (*freeze all (T)Vars; assumes thm in standard form*)
   815 
   816 fun freeze_all_TVars thm =
   817   (case tvars_of thm of
   818     [] => thm
   819   | tvars =>
   820       let val cert = Thm.ctyp_of (Thm.sign_of_thm thm)
   821       in instantiate' (map (fn ((x, _), S) => Some (cert (TFree (x, S)))) tvars) [] thm end);
   822 
   823 fun freeze_all_Vars thm =
   824   (case vars_of thm of
   825     [] => thm
   826   | vars =>
   827       let val cert = Thm.cterm_of (Thm.sign_of_thm thm)
   828       in instantiate' [] (map (fn ((x, _), T) => Some (cert (Free (x, T)))) vars) thm end);
   829 
   830 val freeze_all = freeze_all_Vars o freeze_all_TVars;
   831 
   832 
   833 (* mk_triv_goal *)
   834 
   835 (*make an initial proof state, "PROP A ==> (PROP A)" *)
   836 fun mk_triv_goal ct = instantiate' [] [Some ct] triv_goal;
   837 
   838 end;
   839 
   840 
   841 structure BasicDrule: BASIC_DRULE = Drule;
   842 open BasicDrule;