src/HOL/Library/DAList_Multiset.thy
author wenzelm
Wed Jun 17 11:03:05 2015 +0200 (2015-06-17)
changeset 60500 903bb1495239
parent 60397 f8a513fedb31
child 60495 d7ff0a1df90a
permissions -rw-r--r--
isabelle update_cartouches;
     1 (*  Title:      HOL/Library/DAList_Multiset.thy
     2     Author:     Lukas Bulwahn, TU Muenchen
     3 *)
     4 
     5 section \<open>Multisets partially implemented by association lists\<close>
     6 
     7 theory DAList_Multiset
     8 imports Multiset DAList
     9 begin
    10 
    11 text \<open>Delete prexisting code equations\<close>
    12 
    13 lemma [code, code del]: "{#} = {#}" ..
    14 
    15 lemma [code, code del]: "single = single" ..
    16 
    17 lemma [code, code del]: "plus = (plus :: 'a multiset \<Rightarrow> _)" ..
    18 
    19 lemma [code, code del]: "minus = (minus :: 'a multiset \<Rightarrow> _)" ..
    20 
    21 lemma [code, code del]: "inf_subset_mset = (inf_subset_mset :: 'a multiset \<Rightarrow> _)" ..
    22 
    23 lemma [code, code del]: "sup_subset_mset = (sup_subset_mset :: 'a multiset \<Rightarrow> _)" ..
    24 
    25 lemma [code, code del]: "image_mset = image_mset" ..
    26 
    27 lemma [code, code del]: "filter_mset = filter_mset" ..
    28 
    29 lemma [code, code del]: "count = count" ..
    30 
    31 lemma [code, code del]: "size = (size :: _ multiset \<Rightarrow> nat)" ..
    32 
    33 lemma [code, code del]: "msetsum = msetsum" ..
    34 
    35 lemma [code, code del]: "msetprod = msetprod" ..
    36 
    37 lemma [code, code del]: "set_of = set_of" ..
    38 
    39 lemma [code, code del]: "sorted_list_of_multiset = sorted_list_of_multiset" ..
    40 
    41 lemma [code, code del]: "subset_mset = subset_mset" ..
    42 
    43 lemma [code, code del]: "subseteq_mset = subseteq_mset" ..
    44 
    45 lemma [code, code del]: "equal_multiset_inst.equal_multiset = equal_multiset_inst.equal_multiset" ..
    46 
    47 
    48 text \<open>Raw operations on lists\<close>
    49 
    50 definition join_raw ::
    51     "('key \<Rightarrow> 'val \<times> 'val \<Rightarrow> 'val) \<Rightarrow>
    52       ('key \<times> 'val) list \<Rightarrow> ('key \<times> 'val) list \<Rightarrow> ('key \<times> 'val) list"
    53   where "join_raw f xs ys = foldr (\<lambda>(k, v). map_default k v (\<lambda>v'. f k (v', v))) ys xs"
    54 
    55 lemma join_raw_Nil [simp]: "join_raw f xs [] = xs"
    56   by (simp add: join_raw_def)
    57 
    58 lemma join_raw_Cons [simp]:
    59   "join_raw f xs ((k, v) # ys) = map_default k v (\<lambda>v'. f k (v', v)) (join_raw f xs ys)"
    60   by (simp add: join_raw_def)
    61 
    62 lemma map_of_join_raw:
    63   assumes "distinct (map fst ys)"
    64   shows "map_of (join_raw f xs ys) x =
    65     (case map_of xs x of
    66       None \<Rightarrow> map_of ys x
    67     | Some v \<Rightarrow> (case map_of ys x of None \<Rightarrow> Some v | Some v' \<Rightarrow> Some (f x (v, v'))))"
    68   using assms
    69   apply (induct ys)
    70   apply (auto simp add: map_of_map_default split: option.split)
    71   apply (metis map_of_eq_None_iff option.simps(2) weak_map_of_SomeI)
    72   apply (metis Some_eq_map_of_iff map_of_eq_None_iff option.simps(2))
    73   done
    74 
    75 lemma distinct_join_raw:
    76   assumes "distinct (map fst xs)"
    77   shows "distinct (map fst (join_raw f xs ys))"
    78   using assms
    79 proof (induct ys)
    80   case Nil
    81   then show ?case by simp
    82 next
    83   case (Cons y ys)
    84   then show ?case by (cases y) (simp add: distinct_map_default)
    85 qed
    86 
    87 definition "subtract_entries_raw xs ys = foldr (\<lambda>(k, v). AList.map_entry k (\<lambda>v'. v' - v)) ys xs"
    88 
    89 lemma map_of_subtract_entries_raw:
    90   assumes "distinct (map fst ys)"
    91   shows "map_of (subtract_entries_raw xs ys) x =
    92     (case map_of xs x of
    93       None \<Rightarrow> None
    94     | Some v \<Rightarrow> (case map_of ys x of None \<Rightarrow> Some v | Some v' \<Rightarrow> Some (v - v')))"
    95   using assms
    96   unfolding subtract_entries_raw_def
    97   apply (induct ys)
    98   apply auto
    99   apply (simp split: option.split)
   100   apply (simp add: map_of_map_entry)
   101   apply (auto split: option.split)
   102   apply (metis map_of_eq_None_iff option.simps(3) option.simps(4))
   103   apply (metis map_of_eq_None_iff option.simps(4) option.simps(5))
   104   done
   105 
   106 lemma distinct_subtract_entries_raw:
   107   assumes "distinct (map fst xs)"
   108   shows "distinct (map fst (subtract_entries_raw xs ys))"
   109   using assms
   110   unfolding subtract_entries_raw_def
   111   by (induct ys) (auto simp add: distinct_map_entry)
   112 
   113 
   114 text \<open>Operations on alists with distinct keys\<close>
   115 
   116 lift_definition join :: "('a \<Rightarrow> 'b \<times> 'b \<Rightarrow> 'b) \<Rightarrow> ('a, 'b) alist \<Rightarrow> ('a, 'b) alist \<Rightarrow> ('a, 'b) alist"
   117   is join_raw
   118   by (simp add: distinct_join_raw)
   119 
   120 lift_definition subtract_entries :: "('a, ('b :: minus)) alist \<Rightarrow> ('a, 'b) alist \<Rightarrow> ('a, 'b) alist"
   121   is subtract_entries_raw
   122   by (simp add: distinct_subtract_entries_raw)
   123 
   124 
   125 text \<open>Implementing multisets by means of association lists\<close>
   126 
   127 definition count_of :: "('a \<times> nat) list \<Rightarrow> 'a \<Rightarrow> nat"
   128   where "count_of xs x = (case map_of xs x of None \<Rightarrow> 0 | Some n \<Rightarrow> n)"
   129 
   130 lemma count_of_multiset: "count_of xs \<in> multiset"
   131 proof -
   132   let ?A = "{x::'a. 0 < (case map_of xs x of None \<Rightarrow> 0::nat | Some n \<Rightarrow> n)}"
   133   have "?A \<subseteq> dom (map_of xs)"
   134   proof
   135     fix x
   136     assume "x \<in> ?A"
   137     then have "0 < (case map_of xs x of None \<Rightarrow> 0::nat | Some n \<Rightarrow> n)"
   138       by simp
   139     then have "map_of xs x \<noteq> None"
   140       by (cases "map_of xs x") auto
   141     then show "x \<in> dom (map_of xs)"
   142       by auto
   143   qed
   144   with finite_dom_map_of [of xs] have "finite ?A"
   145     by (auto intro: finite_subset)
   146   then show ?thesis
   147     by (simp add: count_of_def fun_eq_iff multiset_def)
   148 qed
   149 
   150 lemma count_simps [simp]:
   151   "count_of [] = (\<lambda>_. 0)"
   152   "count_of ((x, n) # xs) = (\<lambda>y. if x = y then n else count_of xs y)"
   153   by (simp_all add: count_of_def fun_eq_iff)
   154 
   155 lemma count_of_empty: "x \<notin> fst ` set xs \<Longrightarrow> count_of xs x = 0"
   156   by (induct xs) (simp_all add: count_of_def)
   157 
   158 lemma count_of_filter: "count_of (List.filter (P \<circ> fst) xs) x = (if P x then count_of xs x else 0)"
   159   by (induct xs) auto
   160 
   161 lemma count_of_map_default [simp]:
   162   "count_of (map_default x b (\<lambda>x. x + b) xs) y =
   163     (if x = y then count_of xs x + b else count_of xs y)"
   164   unfolding count_of_def by (simp add: map_of_map_default split: option.split)
   165 
   166 lemma count_of_join_raw:
   167   "distinct (map fst ys) \<Longrightarrow>
   168     count_of xs x + count_of ys x = count_of (join_raw (\<lambda>x (x, y). x + y) xs ys) x"
   169   unfolding count_of_def by (simp add: map_of_join_raw split: option.split)
   170 
   171 lemma count_of_subtract_entries_raw:
   172   "distinct (map fst ys) \<Longrightarrow>
   173     count_of xs x - count_of ys x = count_of (subtract_entries_raw xs ys) x"
   174   unfolding count_of_def by (simp add: map_of_subtract_entries_raw split: option.split)
   175 
   176 
   177 text \<open>Code equations for multiset operations\<close>
   178 
   179 definition Bag :: "('a, nat) alist \<Rightarrow> 'a multiset"
   180   where "Bag xs = Abs_multiset (count_of (DAList.impl_of xs))"
   181 
   182 code_datatype Bag
   183 
   184 lemma count_Bag [simp, code]: "count (Bag xs) = count_of (DAList.impl_of xs)"
   185   by (simp add: Bag_def count_of_multiset)
   186 
   187 lemma Mempty_Bag [code]: "{#} = Bag (DAList.empty)"
   188   by (simp add: multiset_eq_iff alist.Alist_inverse DAList.empty_def)
   189 
   190 lemma single_Bag [code]: "{#x#} = Bag (DAList.update x 1 DAList.empty)"
   191   by (simp add: multiset_eq_iff alist.Alist_inverse update.rep_eq empty.rep_eq)
   192 
   193 lemma union_Bag [code]: "Bag xs + Bag ys = Bag (join (\<lambda>x (n1, n2). n1 + n2) xs ys)"
   194   by (rule multiset_eqI)
   195     (simp add: count_of_join_raw alist.Alist_inverse distinct_join_raw join_def)
   196 
   197 lemma minus_Bag [code]: "Bag xs - Bag ys = Bag (subtract_entries xs ys)"
   198   by (rule multiset_eqI)
   199     (simp add: count_of_subtract_entries_raw alist.Alist_inverse
   200       distinct_subtract_entries_raw subtract_entries_def)
   201 
   202 lemma filter_Bag [code]: "filter_mset P (Bag xs) = Bag (DAList.filter (P \<circ> fst) xs)"
   203   by (rule multiset_eqI) (simp add: count_of_filter DAList.filter.rep_eq)
   204 
   205 
   206 lemma mset_eq [code]: "HOL.equal (m1::'a::equal multiset) m2 \<longleftrightarrow> m1 \<le># m2 \<and> m2 \<le># m1"
   207   by (metis equal_multiset_def subset_mset.eq_iff)
   208 
   209 text \<open>By default the code for @{text "<"} is @{prop"xs < ys \<longleftrightarrow> xs \<le> ys \<and> \<not> xs = ys"}.
   210 With equality implemented by @{text"\<le>"}, this leads to three calls of  @{text"\<le>"}.
   211 Here is a more efficient version:\<close>
   212 lemma mset_less[code]: "xs <# (ys :: 'a multiset) \<longleftrightarrow> xs \<le># ys \<and> \<not> ys \<le># xs"
   213   by (rule subset_mset.less_le_not_le)
   214 
   215 lemma mset_less_eq_Bag0:
   216   "Bag xs \<le># A \<longleftrightarrow> (\<forall>(x, n) \<in> set (DAList.impl_of xs). count_of (DAList.impl_of xs) x \<le> count A x)"
   217     (is "?lhs \<longleftrightarrow> ?rhs")
   218 proof
   219   assume ?lhs
   220   then show ?rhs by (auto simp add: subseteq_mset_def)
   221 next
   222   assume ?rhs
   223   show ?lhs
   224   proof (rule mset_less_eqI)
   225     fix x
   226     from \<open>?rhs\<close> have "count_of (DAList.impl_of xs) x \<le> count A x"
   227       by (cases "x \<in> fst ` set (DAList.impl_of xs)") (auto simp add: count_of_empty)
   228     then show "count (Bag xs) x \<le> count A x" by (simp add: subset_mset_def)
   229   qed
   230 qed
   231 
   232 lemma mset_less_eq_Bag [code]:
   233   "Bag xs \<le># (A :: 'a multiset) \<longleftrightarrow> (\<forall>(x, n) \<in> set (DAList.impl_of xs). n \<le> count A x)"
   234 proof -
   235   {
   236     fix x n
   237     assume "(x,n) \<in> set (DAList.impl_of xs)"
   238     then have "count_of (DAList.impl_of xs) x = n"
   239     proof transfer
   240       fix x n
   241       fix xs :: "('a \<times> nat) list"
   242       show "(distinct \<circ> map fst) xs \<Longrightarrow> (x, n) \<in> set xs \<Longrightarrow> count_of xs x = n"
   243       proof (induct xs)
   244         case Nil
   245         then show ?case by simp
   246       next
   247         case (Cons ym ys)
   248         obtain y m where ym: "ym = (y,m)" by force
   249         note Cons = Cons[unfolded ym]
   250         show ?case
   251         proof (cases "x = y")
   252           case False
   253           with Cons show ?thesis
   254             unfolding ym by auto
   255         next
   256           case True
   257           with Cons(2-3) have "m = n" by force
   258           with True show ?thesis
   259             unfolding ym by auto
   260         qed
   261       qed
   262     qed
   263   }
   264   then show ?thesis
   265     unfolding mset_less_eq_Bag0 by auto
   266 qed
   267 
   268 declare multiset_inter_def [code]
   269 declare sup_subset_mset_def [code]
   270 declare multiset_of.simps [code]
   271 
   272 
   273 fun fold_impl :: "('a \<Rightarrow> nat \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> ('a \<times> nat) list \<Rightarrow> 'b"
   274 where
   275   "fold_impl fn e ((a,n) # ms) = (fold_impl fn ((fn a n) e) ms)"
   276 | "fold_impl fn e [] = e"
   277 
   278 definition fold :: "('a \<Rightarrow> nat \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> ('a, nat) alist \<Rightarrow> 'b"
   279   where "fold f e al = fold_impl f e (DAList.impl_of al)"
   280 
   281 hide_const (open) fold
   282 
   283 context comp_fun_commute
   284 begin
   285 
   286 lemma DAList_Multiset_fold:
   287   assumes fn: "\<And>a n x. fn a n x = (f a ^^ n) x"
   288   shows "fold_mset f e (Bag al) = DAList_Multiset.fold fn e al"
   289   unfolding DAList_Multiset.fold_def
   290 proof (induct al)
   291   fix ys
   292   let ?inv = "{xs :: ('a \<times> nat) list. (distinct \<circ> map fst) xs}"
   293   note cs[simp del] = count_simps
   294   have count[simp]: "\<And>x. count (Abs_multiset (count_of x)) = count_of x"
   295     by (rule Abs_multiset_inverse[OF count_of_multiset])
   296   assume ys: "ys \<in> ?inv"
   297   then show "fold_mset f e (Bag (Alist ys)) = fold_impl fn e (DAList.impl_of (Alist ys))"
   298     unfolding Bag_def unfolding Alist_inverse[OF ys]
   299   proof (induct ys arbitrary: e rule: list.induct)
   300     case Nil
   301     show ?case
   302       by (rule trans[OF arg_cong[of _ "{#}" "fold_mset f e", OF multiset_eqI]])
   303          (auto, simp add: cs)
   304   next
   305     case (Cons pair ys e)
   306     obtain a n where pair: "pair = (a,n)"
   307       by force
   308     from fn[of a n] have [simp]: "fn a n = (f a ^^ n)"
   309       by auto
   310     have inv: "ys \<in> ?inv"
   311       using Cons(2) by auto
   312     note IH = Cons(1)[OF inv]
   313     def Ys \<equiv> "Abs_multiset (count_of ys)"
   314     have id: "Abs_multiset (count_of ((a, n) # ys)) = ((op + {# a #}) ^^ n) Ys"
   315       unfolding Ys_def
   316     proof (rule multiset_eqI, unfold count)
   317       fix c
   318       show "count_of ((a, n) # ys) c =
   319         count ((op + {#a#} ^^ n) (Abs_multiset (count_of ys))) c" (is "?l = ?r")
   320       proof (cases "c = a")
   321         case False
   322         then show ?thesis
   323           unfolding cs by (induct n) auto
   324       next
   325         case True
   326         then have "?l = n" by (simp add: cs)
   327         also have "n = ?r" unfolding True
   328         proof (induct n)
   329           case 0
   330           from Cons(2)[unfolded pair] have "a \<notin> fst ` set ys" by auto
   331           then show ?case by (induct ys) (simp, auto simp: cs)
   332         next
   333           case Suc
   334           then show ?case by simp
   335         qed
   336         finally show ?thesis .
   337       qed
   338     qed
   339     show ?case
   340       unfolding pair
   341       apply (simp add: IH[symmetric])
   342       unfolding id Ys_def[symmetric]
   343       apply (induct n)
   344       apply (auto simp: fold_mset_fun_left_comm[symmetric])
   345       done
   346   qed
   347 qed
   348 
   349 end
   350 
   351 lift_definition single_alist_entry :: "'a \<Rightarrow> 'b \<Rightarrow> ('a, 'b) alist" is "\<lambda>a b. [(a, b)]"
   352   by auto
   353 
   354 lemma image_mset_Bag [code]:
   355   "image_mset f (Bag ms) =
   356     DAList_Multiset.fold (\<lambda>a n m. Bag (single_alist_entry (f a) n) + m) {#} ms"
   357   unfolding image_mset_def
   358 proof (rule comp_fun_commute.DAList_Multiset_fold, unfold_locales, (auto simp: ac_simps)[1])
   359   fix a n m
   360   show "Bag (single_alist_entry (f a) n) + m = ((op + \<circ> single \<circ> f) a ^^ n) m" (is "?l = ?r")
   361   proof (rule multiset_eqI)
   362     fix x
   363     have "count ?r x = (if x = f a then n + count m x else count m x)"
   364       by (induct n) auto
   365     also have "\<dots> = count ?l x"
   366       by (simp add: single_alist_entry.rep_eq)
   367     finally show "count ?l x = count ?r x" ..
   368   qed
   369 qed
   370 
   371 hide_const single_alist_entry
   372 
   373 (* we cannot use (\<lambda>a n. op + (a * n)) for folding, since * is not defined
   374    in comm_monoid_add *)
   375 lemma msetsum_Bag[code]: "msetsum (Bag ms) = DAList_Multiset.fold (\<lambda>a n. ((op + a) ^^ n)) 0 ms"
   376   unfolding msetsum.eq_fold
   377   apply (rule comp_fun_commute.DAList_Multiset_fold)
   378   apply unfold_locales
   379   apply (auto simp: ac_simps)
   380   done
   381 
   382 (* we cannot use (\<lambda>a n. op * (a ^ n)) for folding, since ^ is not defined
   383    in comm_monoid_mult *)
   384 lemma msetprod_Bag[code]: "msetprod (Bag ms) = DAList_Multiset.fold (\<lambda>a n. ((op * a) ^^ n)) 1 ms"
   385   unfolding msetprod.eq_fold
   386   apply (rule comp_fun_commute.DAList_Multiset_fold)
   387   apply unfold_locales
   388   apply (auto simp: ac_simps)
   389   done
   390 
   391 lemma size_fold: "size A = fold_mset (\<lambda>_. Suc) 0 A" (is "_ = fold_mset ?f _ _")
   392 proof -
   393   interpret comp_fun_commute ?f by default auto
   394   show ?thesis by (induct A) auto
   395 qed
   396 
   397 lemma size_Bag[code]: "size (Bag ms) = DAList_Multiset.fold (\<lambda>a n. op + n) 0 ms"
   398   unfolding size_fold
   399 proof (rule comp_fun_commute.DAList_Multiset_fold, unfold_locales, simp)
   400   fix a n x
   401   show "n + x = (Suc ^^ n) x"
   402     by (induct n) auto
   403 qed
   404 
   405 
   406 lemma set_of_fold: "set_of A = fold_mset insert {} A" (is "_ = fold_mset ?f _ _")
   407 proof -
   408   interpret comp_fun_commute ?f by default auto
   409   show ?thesis by (induct A) auto
   410 qed
   411 
   412 lemma set_of_Bag[code]:
   413   "set_of (Bag ms) = DAList_Multiset.fold (\<lambda>a n. (if n = 0 then (\<lambda>m. m) else insert a)) {} ms"
   414   unfolding set_of_fold
   415 proof (rule comp_fun_commute.DAList_Multiset_fold, unfold_locales, (auto simp: ac_simps)[1])
   416   fix a n x
   417   show "(if n = 0 then \<lambda>m. m else insert a) x = (insert a ^^ n) x" (is "?l n = ?r n")
   418   proof (cases n)
   419     case 0
   420     then show ?thesis by simp
   421   next
   422     case (Suc m)
   423     then have "?l n = insert a x" by simp
   424     moreover have "?r n = insert a x" unfolding Suc by (induct m) auto
   425     ultimately show ?thesis by auto
   426   qed
   427 qed
   428 
   429 
   430 instantiation multiset :: (exhaustive) exhaustive
   431 begin
   432 
   433 definition exhaustive_multiset ::
   434   "('a multiset \<Rightarrow> (bool \<times> term list) option) \<Rightarrow> natural \<Rightarrow> (bool \<times> term list) option"
   435   where "exhaustive_multiset f i = Quickcheck_Exhaustive.exhaustive (\<lambda>xs. f (Bag xs)) i"
   436 
   437 instance ..
   438 
   439 end
   440 
   441 end
   442