src/Pure/meta_simplifier.ML
author wenzelm
Thu May 11 19:19:33 2006 +0200 (2006-05-11)
changeset 19618 9050a3b01e62
parent 19502 369cde91963d
child 19798 94f12468bbba
permissions -rw-r--r--
tuned;
     1 (*  Title:      Pure/meta_simplifier.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Stefan Berghofer
     4 
     5 Meta-level Simplification.
     6 *)
     7 
     8 infix 4
     9   addsimps delsimps addeqcongs deleqcongs addcongs delcongs addsimprocs delsimprocs
    10   setmksimps setmkcong setmksym setmkeqTrue settermless setsubgoaler
    11   setloop' setloop addloop addloop' delloop setSSolver addSSolver setSolver addSolver;
    12 
    13 signature BASIC_META_SIMPLIFIER =
    14 sig
    15   val debug_simp: bool ref
    16   val trace_simp: bool ref
    17   val simp_depth_limit: int ref
    18   val trace_simp_depth_limit: int ref
    19   type rrule
    20   val eq_rrule: rrule * rrule -> bool
    21   type cong
    22   type simpset
    23   type proc
    24   type solver
    25   val mk_solver': string -> (simpset -> int -> tactic) -> solver
    26   val mk_solver: string -> (thm list -> int -> tactic) -> solver
    27   val rep_ss: simpset ->
    28    {rules: rrule Net.net,
    29     prems: thm list,
    30     bounds: int * ((string * typ) * string) list,
    31     context: Context.proof option} *
    32    {congs: (string * cong) list * string list,
    33     procs: proc Net.net,
    34     mk_rews:
    35      {mk: thm -> thm list,
    36       mk_cong: thm -> thm,
    37       mk_sym: thm -> thm option,
    38       mk_eq_True: thm -> thm option,
    39       reorient: theory -> term list -> term -> term -> bool},
    40     termless: term * term -> bool,
    41     subgoal_tac: simpset -> int -> tactic,
    42     loop_tacs: (string * (simpset -> int -> tactic)) list,
    43     solvers: solver list * solver list}
    44   val print_ss: simpset -> unit
    45   val empty_ss: simpset
    46   val merge_ss: simpset * simpset -> simpset
    47   type simproc
    48   val mk_simproc: string -> cterm list ->
    49     (theory -> simpset -> term -> thm option) -> simproc
    50   val add_prems: thm list -> simpset -> simpset
    51   val prems_of_ss: simpset -> thm list
    52   val addsimps: simpset * thm list -> simpset
    53   val delsimps: simpset * thm list -> simpset
    54   val addeqcongs: simpset * thm list -> simpset
    55   val deleqcongs: simpset * thm list -> simpset
    56   val addcongs: simpset * thm list -> simpset
    57   val delcongs: simpset * thm list -> simpset
    58   val addsimprocs: simpset * simproc list -> simpset
    59   val delsimprocs: simpset * simproc list -> simpset
    60   val setmksimps: simpset * (thm -> thm list) -> simpset
    61   val setmkcong: simpset * (thm -> thm) -> simpset
    62   val setmksym: simpset * (thm -> thm option) -> simpset
    63   val setmkeqTrue: simpset * (thm -> thm option) -> simpset
    64   val settermless: simpset * (term * term -> bool) -> simpset
    65   val setsubgoaler: simpset * (simpset -> int -> tactic) -> simpset
    66   val setloop': simpset * (simpset -> int -> tactic) -> simpset
    67   val setloop: simpset * (int -> tactic) -> simpset
    68   val addloop': simpset * (string * (simpset -> int -> tactic)) -> simpset
    69   val addloop: simpset * (string * (int -> tactic)) -> simpset
    70   val delloop: simpset * string -> simpset
    71   val setSSolver: simpset * solver -> simpset
    72   val addSSolver: simpset * solver -> simpset
    73   val setSolver: simpset * solver -> simpset
    74   val addSolver: simpset * solver -> simpset
    75 end;
    76 
    77 signature META_SIMPLIFIER =
    78 sig
    79   include BASIC_META_SIMPLIFIER
    80   exception SIMPLIFIER of string * thm
    81   val solver: simpset -> solver -> int -> tactic
    82   val clear_ss: simpset -> simpset
    83   exception SIMPROC_FAIL of string * exn
    84   val simproc_i: theory -> string -> term list
    85     -> (theory -> simpset -> term -> thm option) -> simproc
    86   val simproc: theory -> string -> string list
    87     -> (theory -> simpset -> term -> thm option) -> simproc
    88   val inherit_context: simpset -> simpset -> simpset
    89   val the_context: simpset -> Context.proof
    90   val context: Context.proof -> simpset -> simpset
    91   val theory_context: theory  -> simpset -> simpset
    92   val debug_bounds: bool ref
    93   val set_reorient: (theory -> term list -> term -> term -> bool) -> simpset -> simpset
    94   val set_solvers: solver list -> simpset -> simpset
    95   val rewrite_cterm: bool * bool * bool ->
    96     (simpset -> thm -> thm option) -> simpset -> cterm -> thm
    97   val rewrite_aux: (simpset -> thm -> thm option) -> bool -> thm list -> cterm -> thm
    98   val simplify_aux: (simpset -> thm -> thm option) -> bool -> thm list -> thm -> thm
    99   val rewrite_term: theory -> thm list -> (term -> term option) list -> term -> term
   100   val rewrite_thm: bool * bool * bool ->
   101     (simpset -> thm -> thm option) -> simpset -> thm -> thm
   102   val rewrite_goals_rule_aux: (simpset -> thm -> thm option) -> thm list -> thm -> thm
   103   val rewrite_goal_rule: bool * bool * bool ->
   104     (simpset -> thm -> thm option) -> simpset -> int -> thm -> thm
   105 end;
   106 
   107 structure MetaSimplifier: META_SIMPLIFIER =
   108 struct
   109 
   110 
   111 (** datatype simpset **)
   112 
   113 (* rewrite rules *)
   114 
   115 type rrule = {thm: thm, name: string, lhs: term, elhs: cterm, fo: bool, perm: bool};
   116 
   117 (*thm: the rewrite rule;
   118   name: name of theorem from which rewrite rule was extracted;
   119   lhs: the left-hand side;
   120   elhs: the etac-contracted lhs;
   121   fo: use first-order matching;
   122   perm: the rewrite rule is permutative;
   123 
   124 Remarks:
   125   - elhs is used for matching,
   126     lhs only for preservation of bound variable names;
   127   - fo is set iff
   128     either elhs is first-order (no Var is applied),
   129       in which case fo-matching is complete,
   130     or elhs is not a pattern,
   131       in which case there is nothing better to do;*)
   132 
   133 fun eq_rrule ({thm = thm1, ...}: rrule, {thm = thm2, ...}: rrule) =
   134   Drule.eq_thm_prop (thm1, thm2);
   135 
   136 
   137 (* congruences *)
   138 
   139 type cong = {thm: thm, lhs: cterm};
   140 
   141 fun eq_cong ({thm = thm1, ...}: cong, {thm = thm2, ...}: cong) =
   142   Drule.eq_thm_prop (thm1, thm2);
   143 
   144 
   145 (* simplification sets, procedures, and solvers *)
   146 
   147 (*A simpset contains data required during conversion:
   148     rules: discrimination net of rewrite rules;
   149     prems: current premises;
   150     bounds: maximal index of bound variables already used
   151       (for generating new names when rewriting under lambda abstractions);
   152     congs: association list of congruence rules and
   153            a list of `weak' congruence constants.
   154            A congruence is `weak' if it avoids normalization of some argument.
   155     procs: discrimination net of simplification procedures
   156       (functions that prove rewrite rules on the fly);
   157     mk_rews:
   158       mk: turn simplification thms into rewrite rules;
   159       mk_cong: prepare congruence rules;
   160       mk_sym: turn == around;
   161       mk_eq_True: turn P into P == True;
   162     termless: relation for ordered rewriting;*)
   163 
   164 type mk_rews =
   165  {mk: thm -> thm list,
   166   mk_cong: thm -> thm,
   167   mk_sym: thm -> thm option,
   168   mk_eq_True: thm -> thm option,
   169   reorient: theory -> term list -> term -> term -> bool};
   170 
   171 datatype simpset =
   172   Simpset of
   173    {rules: rrule Net.net,
   174     prems: thm list,
   175     bounds: int * ((string * typ) * string) list,
   176     context: Context.proof option} *
   177    {congs: (string * cong) list * string list,
   178     procs: proc Net.net,
   179     mk_rews: mk_rews,
   180     termless: term * term -> bool,
   181     subgoal_tac: simpset -> int -> tactic,
   182     loop_tacs: (string * (simpset -> int -> tactic)) list,
   183     solvers: solver list * solver list}
   184 and proc =
   185   Proc of
   186    {name: string,
   187     lhs: cterm,
   188     proc: theory -> simpset -> term -> thm option,
   189     id: stamp}
   190 and solver =
   191   Solver of
   192    {name: string,
   193     solver: simpset -> int -> tactic,
   194     id: stamp};
   195 
   196 
   197 fun rep_ss (Simpset args) = args;
   198 
   199 fun make_ss1 (rules, prems, bounds, context) =
   200   {rules = rules, prems = prems, bounds = bounds, context = context};
   201 
   202 fun map_ss1 f {rules, prems, bounds, context} =
   203   make_ss1 (f (rules, prems, bounds, context));
   204 
   205 fun make_ss2 (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =
   206   {congs = congs, procs = procs, mk_rews = mk_rews, termless = termless,
   207     subgoal_tac = subgoal_tac, loop_tacs = loop_tacs, solvers = solvers};
   208 
   209 fun map_ss2 f {congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers} =
   210   make_ss2 (f (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   211 
   212 fun make_simpset (args1, args2) = Simpset (make_ss1 args1, make_ss2 args2);
   213 
   214 fun map_simpset f (Simpset ({rules, prems, bounds, context},
   215     {congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers})) =
   216   make_simpset (f ((rules, prems, bounds, context),
   217     (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers)));
   218 
   219 fun map_simpset1 f (Simpset (r1, r2)) = Simpset (map_ss1 f r1, r2);
   220 fun map_simpset2 f (Simpset (r1, r2)) = Simpset (r1, map_ss2 f r2);
   221 
   222 fun prems_of_ss (Simpset ({prems, ...}, _)) = prems;
   223 
   224 
   225 fun eq_proc (Proc {id = id1, ...}, Proc {id = id2, ...}) = (id1 = id2);
   226 
   227 fun mk_solver' name solver = Solver {name = name, solver = solver, id = stamp ()};
   228 fun mk_solver name solver = mk_solver' name (solver o prems_of_ss);
   229 
   230 fun solver_name (Solver {name, ...}) = name;
   231 fun solver ss (Solver {solver = tac, ...}) = tac ss;
   232 fun eq_solver (Solver {id = id1, ...}, Solver {id = id2, ...}) = (id1 = id2);
   233 val merge_solvers = gen_merge_lists eq_solver;
   234 
   235 
   236 (* diagnostics *)
   237 
   238 exception SIMPLIFIER of string * thm;
   239 
   240 val debug_simp = ref false;
   241 val trace_simp = ref false;
   242 val simp_depth = ref 0;
   243 val simp_depth_limit = ref 100;
   244 val trace_simp_depth_limit = ref 1;
   245 val trace_simp_depth_limit_exceeded = ref false;
   246 local
   247 
   248 fun println a =
   249   if ! simp_depth > ! trace_simp_depth_limit
   250   then if !trace_simp_depth_limit_exceeded then ()
   251        else (tracing "trace_simp_depth_limit exceeded!";
   252              trace_simp_depth_limit_exceeded := true)
   253   else (tracing (enclose "[" "]" (string_of_int (! simp_depth)) ^ a);
   254         trace_simp_depth_limit_exceeded := false);
   255 
   256 fun prnt warn a = if warn then warning a else println a;
   257 
   258 fun show_bounds (Simpset ({bounds = (_, bs), ...}, _)) t =
   259   let
   260     val used = Term.add_term_names (t, []);
   261     val xs = rev (Term.variantlist (rev (map #2 bs), used));
   262     fun subst (((b, T), _), x') = (Free (b, T), Syntax.mark_boundT (x', T));
   263   in Term.subst_atomic (ListPair.map subst (bs, xs)) t end;
   264 
   265 in
   266 
   267 fun print_term warn a ss thy t = prnt warn (a ^ "\n" ^
   268   Sign.string_of_term thy (if ! debug_simp then t else show_bounds ss t));
   269 
   270 fun debug warn a = if ! debug_simp then prnt warn a else ();
   271 fun trace warn a = if ! trace_simp then prnt warn a else ();
   272 
   273 fun debug_term warn a ss thy t = if ! debug_simp then print_term warn a ss thy t else ();
   274 fun trace_term warn a ss thy t = if ! trace_simp then print_term warn a ss thy t else ();
   275 
   276 fun trace_cterm warn a ss ct =
   277   if ! trace_simp then print_term warn a ss (Thm.theory_of_cterm ct) (Thm.term_of ct) else ();
   278 
   279 fun trace_thm a ss th =
   280   if ! trace_simp then print_term false a ss (Thm.theory_of_thm th) (Thm.full_prop_of th) else ();
   281 
   282 fun trace_named_thm a ss (th, name) =
   283   if ! trace_simp then
   284     print_term false (if name = "" then a else a ^ " " ^ quote name ^ ":") ss
   285       (Thm.theory_of_thm th) (Thm.full_prop_of th)
   286   else ();
   287 
   288 fun warn_thm a ss th = print_term true a ss (Thm.theory_of_thm th) (Thm.full_prop_of th);
   289 
   290 end;
   291 
   292 
   293 (* print simpsets *)
   294 
   295 fun print_ss ss =
   296   let
   297     val pretty_thms = map Display.pretty_thm;
   298 
   299     fun pretty_cong (name, th) =
   300       Pretty.block [Pretty.str (name ^ ":"), Pretty.brk 1, Display.pretty_thm th];
   301     fun pretty_proc (name, lhss) =
   302       Pretty.big_list (name ^ ":") (map Display.pretty_cterm lhss);
   303 
   304     val Simpset ({rules, ...}, {congs, procs, loop_tacs, solvers, ...}) = ss;
   305     val smps = map #thm (Net.entries rules);
   306     val cngs = map (fn (name, {thm, ...}) => (name, thm)) (#1 congs);
   307     val prcs = Net.entries procs |>
   308       map (fn Proc {name, lhs, id, ...} => ((name, lhs), id))
   309       |> partition_eq (eq_snd (op =))
   310       |> map (fn ps => (fst (fst (hd ps)), map (snd o fst) ps))
   311       |> Library.sort_wrt fst;
   312   in
   313     [Pretty.big_list "simplification rules:" (pretty_thms smps),
   314       Pretty.big_list "simplification procedures:" (map pretty_proc prcs),
   315       Pretty.big_list "congruences:" (map pretty_cong cngs),
   316       Pretty.strs ("loopers:" :: map (quote o #1) loop_tacs),
   317       Pretty.strs ("unsafe solvers:" :: map (quote o solver_name) (#1 solvers)),
   318       Pretty.strs ("safe solvers:" :: map (quote o solver_name) (#2 solvers))]
   319     |> Pretty.chunks |> Pretty.writeln
   320   end;
   321 
   322 
   323 (* simprocs *)
   324 
   325 exception SIMPROC_FAIL of string * exn;
   326 
   327 datatype simproc = Simproc of proc list;
   328 
   329 fun mk_simproc name lhss proc =
   330   let val id = stamp () in
   331     Simproc (lhss |> map (fn lhs =>
   332       Proc {name = name, lhs = lhs, proc = proc, id = id}))
   333   end;
   334 
   335 fun simproc_i thy name = mk_simproc name o map (Thm.cterm_of thy o Logic.varify);
   336 fun simproc thy name = simproc_i thy name o map (Sign.read_term thy);
   337 
   338 
   339 
   340 (** simpset operations **)
   341 
   342 (* context *)
   343 
   344 fun eq_bound (x: string, (y, _)) = x = y;
   345 
   346 fun add_bound bound = map_simpset1 (fn (rules, prems, (count, bounds), context) =>
   347   (rules, prems, (count + 1, bound :: bounds), context));
   348 
   349 fun add_prems ths = map_simpset1 (fn (rules, prems, bounds, context) =>
   350   (rules, ths @ prems, bounds, context));
   351 
   352 fun inherit_context (Simpset ({bounds, context, ...}, _)) =
   353   map_simpset1 (fn (rules, prems, _, _) => (rules, prems, bounds, context));
   354 
   355 fun the_context (Simpset ({context = SOME ctxt, ...}, _)) = ctxt
   356   | the_context _ = raise Fail "Simplifier: no proof context in simpset";
   357 
   358 fun context ctxt =
   359   map_simpset1 (fn (rules, prems, bounds, _) => (rules, prems, bounds, SOME ctxt));
   360 
   361 val theory_context = context o Context.init_proof;
   362 
   363 fun fallback_context _ (ss as Simpset ({context = SOME _, ...}, _)) = ss
   364   | fallback_context thy ss =
   365      (warning "Simplifier: no proof context in simpset -- fallback to theory context!";
   366       theory_context thy ss);
   367 
   368 
   369 (* addsimps *)
   370 
   371 fun mk_rrule2 {thm, name, lhs, elhs, perm} =
   372   let
   373     val fo = Pattern.first_order (term_of elhs) orelse not (Pattern.pattern (term_of elhs))
   374   in {thm = thm, name = name, lhs = lhs, elhs = elhs, fo = fo, perm = perm} end;
   375 
   376 fun insert_rrule quiet (ss, rrule as {thm, name, lhs, elhs, perm}) =
   377  (trace_named_thm "Adding rewrite rule" ss (thm, name);
   378   ss |> map_simpset1 (fn (rules, prems, bounds, context) =>
   379     let
   380       val rrule2 as {elhs, ...} = mk_rrule2 rrule;
   381       val rules' = Net.insert_term eq_rrule (term_of elhs, rrule2) rules;
   382     in (rules', prems, bounds, context) end)
   383   handle Net.INSERT =>
   384     (if quiet then () else warn_thm "Ignoring duplicate rewrite rule:" ss thm; ss));
   385 
   386 fun vperm (Var _, Var _) = true
   387   | vperm (Abs (_, _, s), Abs (_, _, t)) = vperm (s, t)
   388   | vperm (t1 $ t2, u1 $ u2) = vperm (t1, u1) andalso vperm (t2, u2)
   389   | vperm (t, u) = (t = u);
   390 
   391 fun var_perm (t, u) =
   392   vperm (t, u) andalso gen_eq_set (op =) (term_varnames t, term_varnames u);
   393 
   394 (* FIXME: it seems that the conditions on extra variables are too liberal if
   395 prems are nonempty: does solving the prems really guarantee instantiation of
   396 all its Vars? Better: a dynamic check each time a rule is applied.
   397 *)
   398 fun rewrite_rule_extra_vars prems elhs erhs =
   399   not (term_varnames erhs subset fold add_term_varnames prems (term_varnames elhs))
   400   orelse
   401   not (term_tvars erhs subset (term_tvars elhs union maps term_tvars prems));
   402 
   403 (*simple test for looping rewrite rules and stupid orientations*)
   404 fun default_reorient thy prems lhs rhs =
   405   rewrite_rule_extra_vars prems lhs rhs
   406     orelse
   407   is_Var (head_of lhs)
   408     orelse
   409 (* turns t = x around, which causes a headache if x is a local variable -
   410    usually it is very useful :-(
   411   is_Free rhs andalso not(is_Free lhs) andalso not(Logic.occs(rhs,lhs))
   412   andalso not(exists_subterm is_Var lhs)
   413     orelse
   414 *)
   415   exists (fn t => Logic.occs (lhs, t)) (rhs :: prems)
   416     orelse
   417   null prems andalso Pattern.matches thy (lhs, rhs)
   418     (*the condition "null prems" is necessary because conditional rewrites
   419       with extra variables in the conditions may terminate although
   420       the rhs is an instance of the lhs; example: ?m < ?n ==> f(?n) == f(?m)*)
   421     orelse
   422   is_Const lhs andalso not (is_Const rhs);
   423 
   424 fun decomp_simp thm =
   425   let
   426     val {thy, prop, ...} = Thm.rep_thm thm;
   427     val prems = Logic.strip_imp_prems prop;
   428     val concl = Drule.strip_imp_concl (Thm.cprop_of thm);
   429     val (lhs, rhs) = Drule.dest_equals concl handle TERM _ =>
   430       raise SIMPLIFIER ("Rewrite rule not a meta-equality", thm);
   431     val (_, elhs) = Drule.dest_equals (Thm.cprop_of (Thm.eta_conversion lhs));
   432     val elhs = if term_of elhs aconv term_of lhs then lhs else elhs;  (*share identical copies*)
   433     val erhs = Envir.eta_contract (term_of rhs);
   434     val perm =
   435       var_perm (term_of elhs, erhs) andalso
   436       not (term_of elhs aconv erhs) andalso
   437       not (is_Var (term_of elhs));
   438   in (thy, prems, term_of lhs, elhs, term_of rhs, perm) end;
   439 
   440 fun decomp_simp' thm =
   441   let val (_, _, lhs, _, rhs, _) = decomp_simp thm in
   442     if Thm.nprems_of thm > 0 then raise SIMPLIFIER ("Bad conditional rewrite rule", thm)
   443     else (lhs, rhs)
   444   end;
   445 
   446 fun mk_eq_True (Simpset (_, {mk_rews = {mk_eq_True, ...}, ...})) (thm, name) =
   447   (case mk_eq_True thm of
   448     NONE => []
   449   | SOME eq_True =>
   450       let val (_, _, lhs, elhs, _, _) = decomp_simp eq_True
   451       in [{thm = eq_True, name = name, lhs = lhs, elhs = elhs, perm = false}] end);
   452 
   453 (*create the rewrite rule and possibly also the eq_True variant,
   454   in case there are extra vars on the rhs*)
   455 fun rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm2) =
   456   let val rrule = {thm = thm, name = name, lhs = lhs, elhs = elhs, perm = false} in
   457     if term_varnames rhs subset term_varnames lhs andalso
   458       term_tvars rhs subset term_tvars lhs then [rrule]
   459     else mk_eq_True ss (thm2, name) @ [rrule]
   460   end;
   461 
   462 fun mk_rrule ss (thm, name) =
   463   let val (_, prems, lhs, elhs, rhs, perm) = decomp_simp thm in
   464     if perm then [{thm = thm, name = name, lhs = lhs, elhs = elhs, perm = true}]
   465     else
   466       (*weak test for loops*)
   467       if rewrite_rule_extra_vars prems lhs rhs orelse is_Var (term_of elhs)
   468       then mk_eq_True ss (thm, name)
   469       else rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm)
   470   end;
   471 
   472 fun orient_rrule ss (thm, name) =
   473   let
   474     val (thy, prems, lhs, elhs, rhs, perm) = decomp_simp thm;
   475     val Simpset (_, {mk_rews = {reorient, mk_sym, ...}, ...}) = ss;
   476   in
   477     if perm then [{thm = thm, name = name, lhs = lhs, elhs = elhs, perm = true}]
   478     else if reorient thy prems lhs rhs then
   479       if reorient thy prems rhs lhs
   480       then mk_eq_True ss (thm, name)
   481       else
   482         (case mk_sym thm of
   483           NONE => []
   484         | SOME thm' =>
   485             let val (_, _, lhs', elhs', rhs', _) = decomp_simp thm'
   486             in rrule_eq_True (thm', name, lhs', elhs', rhs', ss, thm) end)
   487     else rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm)
   488   end;
   489 
   490 fun extract_rews (Simpset (_, {mk_rews = {mk, ...}, ...}), thms) =
   491   maps (fn thm => map (rpair (Thm.name_of_thm thm)) (mk thm)) thms;
   492 
   493 fun orient_comb_simps comb mk_rrule (ss, thms) =
   494   let
   495     val rews = extract_rews (ss, thms);
   496     val rrules = maps mk_rrule rews;
   497   in Library.foldl comb (ss, rrules) end;
   498 
   499 fun extract_safe_rrules (ss, thm) =
   500   maps (orient_rrule ss) (extract_rews (ss, [thm]));
   501 
   502 (*add rewrite rules explicitly; do not reorient!*)
   503 fun ss addsimps thms =
   504   orient_comb_simps (insert_rrule false) (mk_rrule ss) (ss, thms);
   505 
   506 
   507 (* delsimps *)
   508 
   509 fun del_rrule (ss, rrule as {thm, elhs, ...}) =
   510   ss |> map_simpset1 (fn (rules, prems, bounds, context) =>
   511     (Net.delete_term eq_rrule (term_of elhs, rrule) rules, prems, bounds, context))
   512   handle Net.DELETE => (warn_thm "Rewrite rule not in simpset:" ss thm; ss);
   513 
   514 fun ss delsimps thms =
   515   orient_comb_simps del_rrule (map mk_rrule2 o mk_rrule ss) (ss, thms);
   516 
   517 
   518 (* congs *)
   519 
   520 fun cong_name (Const (a, _)) = SOME a
   521   | cong_name (Free (a, _)) = SOME ("Free: " ^ a)
   522   | cong_name _ = NONE;
   523 
   524 local
   525 
   526 fun is_full_cong_prems [] [] = true
   527   | is_full_cong_prems [] _ = false
   528   | is_full_cong_prems (p :: prems) varpairs =
   529       (case Logic.strip_assums_concl p of
   530         Const ("==", _) $ lhs $ rhs =>
   531           let val (x, xs) = strip_comb lhs and (y, ys) = strip_comb rhs in
   532             is_Var x andalso forall is_Bound xs andalso
   533             null (findrep xs) andalso xs = ys andalso
   534             (x, y) mem varpairs andalso
   535             is_full_cong_prems prems (remove (op =) (x, y) varpairs)
   536           end
   537       | _ => false);
   538 
   539 fun is_full_cong thm =
   540   let
   541     val prems = prems_of thm and concl = concl_of thm;
   542     val (lhs, rhs) = Logic.dest_equals concl;
   543     val (f, xs) = strip_comb lhs and (g, ys) = strip_comb rhs;
   544   in
   545     f = g andalso null (findrep (xs @ ys)) andalso length xs = length ys andalso
   546     is_full_cong_prems prems (xs ~~ ys)
   547   end;
   548 
   549 fun add_cong (ss, thm) = ss |>
   550   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   551     let
   552       val (lhs, _) = Drule.dest_equals (Drule.strip_imp_concl (Thm.cprop_of thm))
   553         handle TERM _ => raise SIMPLIFIER ("Congruence not a meta-equality", thm);
   554     (*val lhs = Envir.eta_contract lhs;*)
   555       val a = the (cong_name (head_of (term_of lhs))) handle Option =>
   556         raise SIMPLIFIER ("Congruence must start with a constant or free variable", thm);
   557       val (alist, weak) = congs;
   558       val alist2 = overwrite_warn (alist, (a, {lhs = lhs, thm = thm}))
   559         ("Overwriting congruence rule for " ^ quote a);
   560       val weak2 = if is_full_cong thm then weak else a :: weak;
   561     in ((alist2, weak2), procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) end);
   562 
   563 fun del_cong (ss, thm) = ss |>
   564   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   565     let
   566       val (lhs, _) = Logic.dest_equals (Thm.concl_of thm) handle TERM _ =>
   567         raise SIMPLIFIER ("Congruence not a meta-equality", thm);
   568     (*val lhs = Envir.eta_contract lhs;*)
   569       val a = the (cong_name (head_of lhs)) handle Option =>
   570         raise SIMPLIFIER ("Congruence must start with a constant", thm);
   571       val (alist, _) = congs;
   572       val alist2 = List.filter (fn (x, _) => x <> a) alist;
   573       val weak2 = alist2 |> map_filter (fn (a, {thm, ...}: cong) =>
   574         if is_full_cong thm then NONE else SOME a);
   575     in ((alist2, weak2), procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) end);
   576 
   577 fun mk_cong (Simpset (_, {mk_rews = {mk_cong = f, ...}, ...})) = f;
   578 
   579 in
   580 
   581 val (op addeqcongs) = Library.foldl add_cong;
   582 val (op deleqcongs) = Library.foldl del_cong;
   583 
   584 fun ss addcongs congs = ss addeqcongs map (mk_cong ss) congs;
   585 fun ss delcongs congs = ss deleqcongs map (mk_cong ss) congs;
   586 
   587 end;
   588 
   589 
   590 (* simprocs *)
   591 
   592 local
   593 
   594 fun add_proc (proc as Proc {name, lhs, ...}) ss =
   595  (trace_cterm false ("Adding simplification procedure " ^ quote name ^ " for") ss lhs;
   596   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   597     (congs, Net.insert_term eq_proc (term_of lhs, proc) procs,
   598       mk_rews, termless, subgoal_tac, loop_tacs, solvers)) ss
   599   handle Net.INSERT =>
   600     (warning ("Ignoring duplicate simplification procedure " ^ quote name); ss));
   601 
   602 fun del_proc (proc as Proc {name, lhs, ...}) ss =
   603   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   604     (congs, Net.delete_term eq_proc (term_of lhs, proc) procs,
   605       mk_rews, termless, subgoal_tac, loop_tacs, solvers)) ss
   606   handle Net.DELETE =>
   607     (warning ("Simplification procedure " ^ quote name ^ " not in simpset"); ss);
   608 
   609 in
   610 
   611 fun ss addsimprocs ps = fold (fn Simproc procs => fold add_proc procs) ps ss;
   612 fun ss delsimprocs ps = fold (fn Simproc procs => fold del_proc procs) ps ss;
   613 
   614 end;
   615 
   616 
   617 (* mk_rews *)
   618 
   619 local
   620 
   621 fun map_mk_rews f = map_simpset2 (fn (congs, procs, {mk, mk_cong, mk_sym, mk_eq_True, reorient},
   622       termless, subgoal_tac, loop_tacs, solvers) =>
   623   let
   624     val (mk', mk_cong', mk_sym', mk_eq_True', reorient') =
   625       f (mk, mk_cong, mk_sym, mk_eq_True, reorient);
   626     val mk_rews' = {mk = mk', mk_cong = mk_cong', mk_sym = mk_sym', mk_eq_True = mk_eq_True',
   627       reorient = reorient'};
   628   in (congs, procs, mk_rews', termless, subgoal_tac, loop_tacs, solvers) end);
   629 
   630 in
   631 
   632 fun ss setmksimps mk = ss |> map_mk_rews (fn (_, mk_cong, mk_sym, mk_eq_True, reorient) =>
   633   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   634 
   635 fun ss setmkcong mk_cong = ss |> map_mk_rews (fn (mk, _, mk_sym, mk_eq_True, reorient) =>
   636   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   637 
   638 fun ss setmksym mk_sym = ss |> map_mk_rews (fn (mk, mk_cong, _, mk_eq_True, reorient) =>
   639   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   640 
   641 fun ss setmkeqTrue mk_eq_True = ss |> map_mk_rews (fn (mk, mk_cong, mk_sym, _, reorient) =>
   642   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   643 
   644 fun set_reorient reorient = map_mk_rews (fn (mk, mk_cong, mk_sym, mk_eq_True, _) =>
   645   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   646 
   647 end;
   648 
   649 
   650 (* termless *)
   651 
   652 fun ss settermless termless = ss |>
   653   map_simpset2 (fn (congs, procs, mk_rews, _, subgoal_tac, loop_tacs, solvers) =>
   654    (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   655 
   656 
   657 (* tactics *)
   658 
   659 fun ss setsubgoaler subgoal_tac = ss |>
   660   map_simpset2 (fn (congs, procs, mk_rews, termless, _, loop_tacs, solvers) =>
   661    (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   662 
   663 fun ss setloop' tac = ss |>
   664   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, _, solvers) =>
   665    (congs, procs, mk_rews, termless, subgoal_tac, [("", tac)], solvers));
   666 
   667 fun ss setloop tac = ss setloop' (K tac);
   668 
   669 fun ss addloop' (name, tac) = ss |>
   670   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   671     (congs, procs, mk_rews, termless, subgoal_tac,
   672       overwrite_warn (loop_tacs, (name, tac)) ("Overwriting looper " ^ quote name),
   673       solvers));
   674 
   675 fun ss addloop (name, tac) = ss addloop' (name, K tac);
   676 
   677 fun ss delloop name = ss |>
   678   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   679     let val loop_tacs' = filter_out (equal name o fst) loop_tacs in
   680       if length loop_tacs <> length loop_tacs' then ()
   681       else warning ("No such looper in simpset: " ^ quote name);
   682       (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs', solvers)
   683     end);
   684 
   685 fun ss setSSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   686   subgoal_tac, loop_tacs, (unsafe_solvers, _)) =>
   687     (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, (unsafe_solvers, [solver])));
   688 
   689 fun ss addSSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   690   subgoal_tac, loop_tacs, (unsafe_solvers, solvers)) => (congs, procs, mk_rews, termless,
   691     subgoal_tac, loop_tacs, (unsafe_solvers, merge_solvers solvers [solver])));
   692 
   693 fun ss setSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   694   subgoal_tac, loop_tacs, (_, solvers)) => (congs, procs, mk_rews, termless,
   695     subgoal_tac, loop_tacs, ([solver], solvers)));
   696 
   697 fun ss addSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   698   subgoal_tac, loop_tacs, (unsafe_solvers, solvers)) => (congs, procs, mk_rews, termless,
   699     subgoal_tac, loop_tacs, (merge_solvers unsafe_solvers [solver], solvers)));
   700 
   701 fun set_solvers solvers = map_simpset2 (fn (congs, procs, mk_rews, termless,
   702   subgoal_tac, loop_tacs, _) => (congs, procs, mk_rews, termless,
   703   subgoal_tac, loop_tacs, (solvers, solvers)));
   704 
   705 
   706 (* empty *)
   707 
   708 fun init_ss mk_rews termless subgoal_tac solvers =
   709   make_simpset ((Net.empty, [], (0, []), NONE),
   710     (([], []), Net.empty, mk_rews, termless, subgoal_tac, [], solvers));
   711 
   712 fun clear_ss (ss as Simpset (_, {mk_rews, termless, subgoal_tac, solvers, ...})) =
   713   init_ss mk_rews termless subgoal_tac solvers
   714   |> inherit_context ss;
   715 
   716 val basic_mk_rews: mk_rews =
   717  {mk = fn th => if can Logic.dest_equals (Thm.concl_of th) then [th] else [],
   718   mk_cong = I,
   719   mk_sym = SOME o Drule.symmetric_fun,
   720   mk_eq_True = K NONE,
   721   reorient = default_reorient};
   722 
   723 val empty_ss = init_ss basic_mk_rews Term.termless (K (K no_tac)) ([], []);
   724 
   725 
   726 (* merge *)  (*NOTE: ignores some fields of 2nd simpset*)
   727 
   728 fun merge_ss (ss1, ss2) =
   729   let
   730     val Simpset ({rules = rules1, prems = prems1, bounds = bounds1, context = _},
   731      {congs = (congs1, weak1), procs = procs1, mk_rews, termless, subgoal_tac,
   732       loop_tacs = loop_tacs1, solvers = (unsafe_solvers1, solvers1)}) = ss1;
   733     val Simpset ({rules = rules2, prems = prems2, bounds = bounds2, context = _},
   734      {congs = (congs2, weak2), procs = procs2, mk_rews = _, termless = _, subgoal_tac = _,
   735       loop_tacs = loop_tacs2, solvers = (unsafe_solvers2, solvers2)}) = ss2;
   736 
   737     val rules' = Net.merge eq_rrule (rules1, rules2);
   738     val prems' = gen_merge_lists Drule.eq_thm_prop prems1 prems2;
   739     val bounds' = if #1 bounds1 < #1 bounds2 then bounds2 else bounds1;
   740     val congs' = gen_merge_lists (eq_cong o pairself #2) congs1 congs2;
   741     val weak' = merge_lists weak1 weak2;
   742     val procs' = Net.merge eq_proc (procs1, procs2);
   743     val loop_tacs' = merge_alists loop_tacs1 loop_tacs2;
   744     val unsafe_solvers' = merge_solvers unsafe_solvers1 unsafe_solvers2;
   745     val solvers' = merge_solvers solvers1 solvers2;
   746   in
   747     make_simpset ((rules', prems', bounds', NONE), ((congs', weak'), procs',
   748       mk_rews, termless, subgoal_tac, loop_tacs', (unsafe_solvers', solvers')))
   749   end;
   750 
   751 
   752 
   753 (** rewriting **)
   754 
   755 (*
   756   Uses conversions, see:
   757     L C Paulson, A higher-order implementation of rewriting,
   758     Science of Computer Programming 3 (1983), pages 119-149.
   759 *)
   760 
   761 val dest_eq = Drule.dest_equals o Thm.cprop_of;
   762 val lhs_of = #1 o dest_eq;
   763 val rhs_of = #2 o dest_eq;
   764 
   765 fun check_conv msg ss thm thm' =
   766   let
   767     val thm'' = transitive thm (transitive
   768       (symmetric (Drule.beta_eta_conversion (lhs_of thm'))) thm')
   769   in if msg then trace_thm "SUCCEEDED" ss thm' else (); SOME thm'' end
   770   handle THM _ =>
   771     let val {thy, prop = _ $ _ $ prop0, ...} = Thm.rep_thm thm in
   772       trace_thm "Proved wrong thm (Check subgoaler?)" ss thm';
   773       trace_term false "Should have proved:" ss thy prop0;
   774       NONE
   775     end;
   776 
   777 
   778 (* mk_procrule *)
   779 
   780 fun mk_procrule ss thm =
   781   let val (_, prems, lhs, elhs, rhs, _) = decomp_simp thm in
   782     if rewrite_rule_extra_vars prems lhs rhs
   783     then (warn_thm "Extra vars on rhs:" ss thm; [])
   784     else [mk_rrule2 {thm = thm, name = "", lhs = lhs, elhs = elhs, perm = false}]
   785   end;
   786 
   787 
   788 (* rewritec: conversion to apply the meta simpset to a term *)
   789 
   790 (*Since the rewriting strategy is bottom-up, we avoid re-normalizing already
   791   normalized terms by carrying around the rhs of the rewrite rule just
   792   applied. This is called the `skeleton'. It is decomposed in parallel
   793   with the term. Once a Var is encountered, the corresponding term is
   794   already in normal form.
   795   skel0 is a dummy skeleton that is to enforce complete normalization.*)
   796 
   797 val skel0 = Bound 0;
   798 
   799 (*Use rhs as skeleton only if the lhs does not contain unnormalized bits.
   800   The latter may happen iff there are weak congruence rules for constants
   801   in the lhs.*)
   802 
   803 fun uncond_skel ((_, weak), (lhs, rhs)) =
   804   if null weak then rhs  (*optimization*)
   805   else if exists_Const (fn (c, _) => c mem weak) lhs then skel0
   806   else rhs;
   807 
   808 (*Behaves like unconditional rule if rhs does not contain vars not in the lhs.
   809   Otherwise those vars may become instantiated with unnormalized terms
   810   while the premises are solved.*)
   811 
   812 fun cond_skel (args as (congs, (lhs, rhs))) =
   813   if term_varnames rhs subset term_varnames lhs then uncond_skel args
   814   else skel0;
   815 
   816 (*
   817   Rewriting -- we try in order:
   818     (1) beta reduction
   819     (2) unconditional rewrite rules
   820     (3) conditional rewrite rules
   821     (4) simplification procedures
   822 
   823   IMPORTANT: rewrite rules must not introduce new Vars or TVars!
   824 *)
   825 
   826 fun rewritec (prover, thyt, maxt) ss t =
   827   let
   828     val Simpset ({rules, ...}, {congs, procs, termless, ...}) = ss;
   829     val eta_thm = Thm.eta_conversion t;
   830     val eta_t' = rhs_of eta_thm;
   831     val eta_t = term_of eta_t';
   832     fun rew {thm, name, lhs, elhs, fo, perm} =
   833       let
   834         val {thy, prop, maxidx, ...} = rep_thm thm;
   835         val (rthm, elhs') = if maxt = ~1 then (thm, elhs)
   836           else (Thm.incr_indexes (maxt+1) thm, Thm.cterm_incr_indexes (maxt+1) elhs);
   837         val insts = if fo then Thm.cterm_first_order_match (elhs', eta_t')
   838                           else Thm.cterm_match (elhs', eta_t');
   839         val thm' = Thm.instantiate insts (Thm.rename_boundvars lhs eta_t rthm);
   840         val prop' = Thm.prop_of thm';
   841         val unconditional = (Logic.count_prems (prop',0) = 0);
   842         val (lhs', rhs') = Logic.dest_equals (Logic.strip_imp_concl prop')
   843       in
   844         if perm andalso not (termless (rhs', lhs'))
   845         then (trace_named_thm "Cannot apply permutative rewrite rule" ss (thm, name);
   846               trace_thm "Term does not become smaller:" ss thm'; NONE)
   847         else (trace_named_thm "Applying instance of rewrite rule" ss (thm, name);
   848            if unconditional
   849            then
   850              (trace_thm "Rewriting:" ss thm';
   851               let val lr = Logic.dest_equals prop;
   852                   val SOME thm'' = check_conv false ss eta_thm thm'
   853               in SOME (thm'', uncond_skel (congs, lr)) end)
   854            else
   855              (trace_thm "Trying to rewrite:" ss thm';
   856               if !simp_depth > !simp_depth_limit
   857               then let val s = "simp_depth_limit exceeded - giving up"
   858                    in trace false s; warning s; NONE end
   859               else
   860               case prover ss thm' of
   861                 NONE => (trace_thm "FAILED" ss thm'; NONE)
   862               | SOME thm2 =>
   863                   (case check_conv true ss eta_thm thm2 of
   864                      NONE => NONE |
   865                      SOME thm2' =>
   866                        let val concl = Logic.strip_imp_concl prop
   867                            val lr = Logic.dest_equals concl
   868                        in SOME (thm2', cond_skel (congs, lr)) end)))
   869       end
   870 
   871     fun rews [] = NONE
   872       | rews (rrule :: rrules) =
   873           let val opt = rew rrule handle Pattern.MATCH => NONE
   874           in case opt of NONE => rews rrules | some => some end;
   875 
   876     fun sort_rrules rrs = let
   877       fun is_simple({thm, ...}:rrule) = case Thm.prop_of thm of
   878                                       Const("==",_) $ _ $ _ => true
   879                                       | _                   => false
   880       fun sort []        (re1,re2) = re1 @ re2
   881         | sort (rr::rrs) (re1,re2) = if is_simple rr
   882                                      then sort rrs (rr::re1,re2)
   883                                      else sort rrs (re1,rr::re2)
   884     in sort rrs ([],[]) end
   885 
   886     fun proc_rews [] = NONE
   887       | proc_rews (Proc {name, proc, lhs, ...} :: ps) =
   888           if Pattern.matches thyt (Thm.term_of lhs, Thm.term_of t) then
   889             (debug_term false ("Trying procedure " ^ quote name ^ " on:") ss thyt eta_t;
   890              case transform_failure (curry SIMPROC_FAIL name)
   891                  (fn () => proc thyt ss eta_t) () of
   892                NONE => (debug false "FAILED"; proc_rews ps)
   893              | SOME raw_thm =>
   894                  (trace_thm ("Procedure " ^ quote name ^ " produced rewrite rule:") ss raw_thm;
   895                   (case rews (mk_procrule ss raw_thm) of
   896                     NONE => (trace_cterm true ("IGNORED result of simproc " ^ quote name ^
   897                       " -- does not match") ss t; proc_rews ps)
   898                   | some => some)))
   899           else proc_rews ps;
   900   in case eta_t of
   901        Abs _ $ _ => SOME (transitive eta_thm
   902          (beta_conversion false eta_t'), skel0)
   903      | _ => (case rews (sort_rrules (Net.match_term rules eta_t)) of
   904                NONE => proc_rews (Net.match_term procs eta_t)
   905              | some => some)
   906   end;
   907 
   908 
   909 (* conversion to apply a congruence rule to a term *)
   910 
   911 fun congc prover ss maxt {thm=cong,lhs=lhs} t =
   912   let val rthm = Thm.incr_indexes (maxt+1) cong;
   913       val rlhs = fst (Drule.dest_equals (Drule.strip_imp_concl (cprop_of rthm)));
   914       val insts = Thm.cterm_match (rlhs, t)
   915       (* Pattern.match can raise Pattern.MATCH;
   916          is handled when congc is called *)
   917       val thm' = Thm.instantiate insts (Thm.rename_boundvars (term_of rlhs) (term_of t) rthm);
   918       val unit = trace_thm "Applying congruence rule:" ss thm';
   919       fun err (msg, thm) = (trace_thm msg ss thm; NONE)
   920   in case prover thm' of
   921        NONE => err ("Congruence proof failed.  Could not prove", thm')
   922      | SOME thm2 => (case check_conv true ss (Drule.beta_eta_conversion t) thm2 of
   923           NONE => err ("Congruence proof failed.  Should not have proved", thm2)
   924         | SOME thm2' =>
   925             if op aconv (pairself term_of (dest_equals (cprop_of thm2')))
   926             then NONE else SOME thm2')
   927   end;
   928 
   929 val (cA, (cB, cC)) =
   930   apsnd dest_equals (dest_implies (hd (cprems_of Drule.imp_cong)));
   931 
   932 fun transitive1 NONE NONE = NONE
   933   | transitive1 (SOME thm1) NONE = SOME thm1
   934   | transitive1 NONE (SOME thm2) = SOME thm2
   935   | transitive1 (SOME thm1) (SOME thm2) = SOME (transitive thm1 thm2)
   936 
   937 fun transitive2 thm = transitive1 (SOME thm);
   938 fun transitive3 thm = transitive1 thm o SOME;
   939 
   940 fun bottomc ((simprem, useprem, mutsimp), prover, thy, maxidx) =
   941   let
   942     fun botc skel ss t =
   943           if is_Var skel then NONE
   944           else
   945           (case subc skel ss t of
   946              some as SOME thm1 =>
   947                (case rewritec (prover, thy, maxidx) ss (rhs_of thm1) of
   948                   SOME (thm2, skel2) =>
   949                     transitive2 (transitive thm1 thm2)
   950                       (botc skel2 ss (rhs_of thm2))
   951                 | NONE => some)
   952            | NONE =>
   953                (case rewritec (prover, thy, maxidx) ss t of
   954                   SOME (thm2, skel2) => transitive2 thm2
   955                     (botc skel2 ss (rhs_of thm2))
   956                 | NONE => NONE))
   957 
   958     and try_botc ss t =
   959           (case botc skel0 ss t of
   960              SOME trec1 => trec1 | NONE => (reflexive t))
   961 
   962     and subc skel (ss as Simpset ({bounds, ...}, {congs, ...})) t0 =
   963        (case term_of t0 of
   964            Abs (a, T, t) =>
   965              let
   966                  val b = Term.bound (#1 bounds);
   967                  val (v, t') = Thm.dest_abs (SOME b) t0;
   968                  val b' = #1 (Term.dest_Free (Thm.term_of v));
   969                  val _ = conditional (b <> b') (fn () =>
   970                    warning ("Simplifier: renamed bound variable " ^ quote b ^ " to " ^ quote b'));
   971                  val ss' = add_bound ((b', T), a) ss;
   972                  val skel' = case skel of Abs (_, _, sk) => sk | _ => skel0;
   973              in case botc skel' ss' t' of
   974                   SOME thm => SOME (abstract_rule a v thm)
   975                 | NONE => NONE
   976              end
   977          | t $ _ => (case t of
   978              Const ("==>", _) $ _  => impc t0 ss
   979            | Abs _ =>
   980                let val thm = beta_conversion false t0
   981                in case subc skel0 ss (rhs_of thm) of
   982                     NONE => SOME thm
   983                   | SOME thm' => SOME (transitive thm thm')
   984                end
   985            | _  =>
   986                let fun appc () =
   987                      let
   988                        val (tskel, uskel) = case skel of
   989                            tskel $ uskel => (tskel, uskel)
   990                          | _ => (skel0, skel0);
   991                        val (ct, cu) = Thm.dest_comb t0
   992                      in
   993                      (case botc tskel ss ct of
   994                         SOME thm1 =>
   995                           (case botc uskel ss cu of
   996                              SOME thm2 => SOME (combination thm1 thm2)
   997                            | NONE => SOME (combination thm1 (reflexive cu)))
   998                       | NONE =>
   999                           (case botc uskel ss cu of
  1000                              SOME thm1 => SOME (combination (reflexive ct) thm1)
  1001                            | NONE => NONE))
  1002                      end
  1003                    val (h, ts) = strip_comb t
  1004                in case cong_name h of
  1005                     SOME a =>
  1006                       (case AList.lookup (op =) (fst congs) a of
  1007                          NONE => appc ()
  1008                        | SOME cong =>
  1009   (*post processing: some partial applications h t1 ... tj, j <= length ts,
  1010     may be a redex. Example: map (%x. x) = (%xs. xs) wrt map_cong*)
  1011                           (let
  1012                              val thm = congc (prover ss) ss maxidx cong t0;
  1013                              val t = the_default t0 (Option.map rhs_of thm);
  1014                              val (cl, cr) = Thm.dest_comb t
  1015                              val dVar = Var(("", 0), dummyT)
  1016                              val skel =
  1017                                list_comb (h, replicate (length ts) dVar)
  1018                            in case botc skel ss cl of
  1019                                 NONE => thm
  1020                               | SOME thm' => transitive3 thm
  1021                                   (combination thm' (reflexive cr))
  1022                            end handle TERM _ => error "congc result"
  1023                                     | Pattern.MATCH => appc ()))
  1024                   | _ => appc ()
  1025                end)
  1026          | _ => NONE)
  1027 
  1028     and impc ct ss =
  1029       if mutsimp then mut_impc0 [] ct [] [] ss else nonmut_impc ct ss
  1030 
  1031     and rules_of_prem ss prem =
  1032       if maxidx_of_term (term_of prem) <> ~1
  1033       then (trace_cterm true
  1034         "Cannot add premise as rewrite rule because it contains (type) unknowns:" ss prem; ([], NONE))
  1035       else
  1036         let val asm = assume prem
  1037         in (extract_safe_rrules (ss, asm), SOME asm) end
  1038 
  1039     and add_rrules (rrss, asms) ss =
  1040       Library.foldl (insert_rrule true) (ss, flat rrss) |> add_prems (map_filter I asms)
  1041 
  1042     and disch r (prem, eq) =
  1043       let
  1044         val (lhs, rhs) = dest_eq eq;
  1045         val eq' = implies_elim (Thm.instantiate
  1046           ([], [(cA, prem), (cB, lhs), (cC, rhs)]) Drule.imp_cong)
  1047           (implies_intr prem eq)
  1048       in if not r then eq' else
  1049         let
  1050           val (prem', concl) = dest_implies lhs;
  1051           val (prem'', _) = dest_implies rhs
  1052         in transitive (transitive
  1053           (Thm.instantiate ([], [(cA, prem'), (cB, prem), (cC, concl)])
  1054              Drule.swap_prems_eq) eq')
  1055           (Thm.instantiate ([], [(cA, prem), (cB, prem''), (cC, concl)])
  1056              Drule.swap_prems_eq)
  1057         end
  1058       end
  1059 
  1060     and rebuild [] _ _ _ _ eq = eq
  1061       | rebuild (prem :: prems) concl (rrs :: rrss) (asm :: asms) ss eq =
  1062           let
  1063             val ss' = add_rrules (rev rrss, rev asms) ss;
  1064             val concl' =
  1065               Drule.mk_implies (prem, the_default concl (Option.map rhs_of eq));
  1066             val dprem = Option.map (curry (disch false) prem)
  1067           in case rewritec (prover, thy, maxidx) ss' concl' of
  1068               NONE => rebuild prems concl' rrss asms ss (dprem eq)
  1069             | SOME (eq', _) => transitive2 (Library.foldl (disch false o swap)
  1070                   (the (transitive3 (dprem eq) eq'), prems))
  1071                 (mut_impc0 (rev prems) (rhs_of eq') (rev rrss) (rev asms) ss)
  1072           end
  1073 
  1074     and mut_impc0 prems concl rrss asms ss =
  1075       let
  1076         val prems' = strip_imp_prems concl;
  1077         val (rrss', asms') = split_list (map (rules_of_prem ss) prems')
  1078       in mut_impc (prems @ prems') (strip_imp_concl concl) (rrss @ rrss')
  1079         (asms @ asms') [] [] [] [] ss ~1 ~1
  1080       end
  1081 
  1082     and mut_impc [] concl [] [] prems' rrss' asms' eqns ss changed k =
  1083         transitive1 (Library.foldl (fn (eq2, (eq1, prem)) => transitive1 eq1
  1084             (Option.map (curry (disch false) prem) eq2)) (NONE, eqns ~~ prems'))
  1085           (if changed > 0 then
  1086              mut_impc (rev prems') concl (rev rrss') (rev asms')
  1087                [] [] [] [] ss ~1 changed
  1088            else rebuild prems' concl rrss' asms' ss
  1089              (botc skel0 (add_rrules (rev rrss', rev asms') ss) concl))
  1090 
  1091       | mut_impc (prem :: prems) concl (rrs :: rrss) (asm :: asms)
  1092           prems' rrss' asms' eqns ss changed k =
  1093         case (if k = 0 then NONE else botc skel0 (add_rrules
  1094           (rev rrss' @ rrss, rev asms' @ asms) ss) prem) of
  1095             NONE => mut_impc prems concl rrss asms (prem :: prems')
  1096               (rrs :: rrss') (asm :: asms') (NONE :: eqns) ss changed
  1097               (if k = 0 then 0 else k - 1)
  1098           | SOME eqn =>
  1099             let
  1100               val prem' = rhs_of eqn;
  1101               val tprems = map term_of prems;
  1102               val i = 1 + Library.foldl Int.max (~1, map (fn p =>
  1103                 find_index (fn q => q aconv p) tprems) (#hyps (rep_thm eqn)));
  1104               val (rrs', asm') = rules_of_prem ss prem'
  1105             in mut_impc prems concl rrss asms (prem' :: prems')
  1106               (rrs' :: rrss') (asm' :: asms') (SOME (foldr (disch true)
  1107                 (Drule.imp_cong_rule eqn (reflexive (Drule.list_implies
  1108                   (Library.drop (i, prems), concl)))) (Library.take (i, prems))) :: eqns) ss (length prems') ~1
  1109             end
  1110 
  1111      (*legacy code - only for backwards compatibility*)
  1112      and nonmut_impc ct ss =
  1113        let val (prem, conc) = dest_implies ct;
  1114            val thm1 = if simprem then botc skel0 ss prem else NONE;
  1115            val prem1 = the_default prem (Option.map rhs_of thm1);
  1116            val ss1 = if not useprem then ss else add_rrules
  1117              (apsnd single (apfst single (rules_of_prem ss prem1))) ss
  1118        in (case botc skel0 ss1 conc of
  1119            NONE => (case thm1 of
  1120                NONE => NONE
  1121              | SOME thm1' => SOME (Drule.imp_cong_rule thm1' (reflexive conc)))
  1122          | SOME thm2 =>
  1123            let val thm2' = disch false (prem1, thm2)
  1124            in (case thm1 of
  1125                NONE => SOME thm2'
  1126              | SOME thm1' =>
  1127                  SOME (transitive (Drule.imp_cong_rule thm1' (reflexive conc)) thm2'))
  1128            end)
  1129        end
  1130 
  1131  in try_botc end;
  1132 
  1133 
  1134 (* Meta-rewriting: rewrites t to u and returns the theorem t==u *)
  1135 
  1136 (*
  1137   Parameters:
  1138     mode = (simplify A,
  1139             use A in simplifying B,
  1140             use prems of B (if B is again a meta-impl.) to simplify A)
  1141            when simplifying A ==> B
  1142     prover: how to solve premises in conditional rewrites and congruences
  1143 *)
  1144 
  1145 val debug_bounds = ref false;
  1146 
  1147 fun check_bounds ss ct = conditional (! debug_bounds) (fn () =>
  1148   let
  1149     val Simpset ({bounds = (_, bounds), ...}, _) = ss;
  1150     val bs = fold_aterms (fn Free (x, _) =>
  1151         if Term.is_bound x andalso not (AList.defined eq_bound bounds x)
  1152         then insert (op =) x else I
  1153       | _ => I) (term_of ct) [];
  1154   in
  1155     if null bs then ()
  1156     else print_term true ("Simplifier: term contains loose bounds: " ^ commas_quote bs) ss
  1157       (Thm.theory_of_cterm ct) (Thm.term_of ct)
  1158   end);
  1159 
  1160 fun rewrite_cterm mode prover raw_ss raw_ct =
  1161   let
  1162     val ct = Thm.adjust_maxidx raw_ct;
  1163     val {thy, t, maxidx, ...} = Thm.rep_cterm ct;
  1164     val ss = fallback_context thy raw_ss;
  1165     val _ = inc simp_depth;
  1166     val _ = conditional (!simp_depth mod 20 = 0) (fn () =>
  1167       warning ("Simplification depth " ^ string_of_int (! simp_depth)));
  1168     val _ = trace_cterm false "SIMPLIFIER INVOKED ON THE FOLLOWING TERM:" ss ct;
  1169     val _ = check_bounds ss ct;
  1170     val res = bottomc (mode, Option.map Drule.flexflex_unique oo prover, thy, maxidx) ss ct
  1171   in dec simp_depth; res end
  1172   handle exn => (dec simp_depth; raise exn);
  1173 
  1174 (*Rewrite a cterm*)
  1175 fun rewrite_aux _ _ [] ct = Thm.reflexive ct
  1176   | rewrite_aux prover full thms ct =
  1177       rewrite_cterm (full, false, false) prover
  1178       (theory_context (Thm.theory_of_cterm ct) empty_ss addsimps thms) ct;
  1179 
  1180 (*Rewrite a theorem*)
  1181 fun simplify_aux _ _ [] th = th
  1182   | simplify_aux prover full thms th =
  1183       Drule.fconv_rule (rewrite_cterm (full, false, false) prover
  1184         (theory_context (Thm.theory_of_thm th) empty_ss addsimps thms)) th;
  1185 
  1186 (*simple term rewriting -- no proof*)
  1187 fun rewrite_term thy rules procs =
  1188   Pattern.rewrite_term thy (map decomp_simp' rules) procs;
  1189 
  1190 fun rewrite_thm mode prover ss = Drule.fconv_rule (rewrite_cterm mode prover ss);
  1191 
  1192 (*Rewrite the subgoals of a proof state (represented by a theorem) *)
  1193 fun rewrite_goals_rule_aux prover thms th =
  1194   Drule.fconv_rule (Drule.goals_conv (K true) (rewrite_cterm (true, true, true) prover
  1195     (theory_context (Thm.theory_of_thm th) empty_ss addsimps thms))) th;
  1196 
  1197 (*Rewrite the subgoal of a proof state (represented by a theorem)*)
  1198 fun rewrite_goal_rule mode prover ss i thm =
  1199   if 0 < i  andalso  i <= nprems_of thm
  1200   then Drule.fconv_rule (Drule.goals_conv (fn j => j=i) (rewrite_cterm mode prover ss)) thm
  1201   else raise THM("rewrite_goal_rule",i,[thm]);
  1202 
  1203 end;
  1204 
  1205 structure BasicMetaSimplifier: BASIC_META_SIMPLIFIER = MetaSimplifier;
  1206 open BasicMetaSimplifier;