src/Pure/goal.ML
author wenzelm
Thu Aug 02 12:36:54 2012 +0200 (2012-08-02)
changeset 48646 91281e9472d8
parent 47415 c486ac962b89
child 48992 0518bf89c777
permissions -rw-r--r--
more official command specifications, including source position;
     1 (*  Title:      Pure/goal.ML
     2     Author:     Makarius
     3 
     4 Goals in tactical theorem proving.
     5 *)
     6 
     7 signature BASIC_GOAL =
     8 sig
     9   val parallel_proofs: int Unsynchronized.ref
    10   val parallel_proofs_threshold: int Unsynchronized.ref
    11   val SELECT_GOAL: tactic -> int -> tactic
    12   val CONJUNCTS: tactic -> int -> tactic
    13   val PRECISE_CONJUNCTS: int -> tactic -> int -> tactic
    14   val PARALLEL_CHOICE: tactic list -> tactic
    15   val PARALLEL_GOALS: tactic -> tactic
    16 end;
    17 
    18 signature GOAL =
    19 sig
    20   include BASIC_GOAL
    21   val init: cterm -> thm
    22   val protect: thm -> thm
    23   val conclude: thm -> thm
    24   val check_finished: Proof.context -> thm -> unit
    25   val finish: Proof.context -> thm -> thm
    26   val norm_result: thm -> thm
    27   val fork_name: string -> (unit -> 'a) -> 'a future
    28   val fork: (unit -> 'a) -> 'a future
    29   val future_enabled: unit -> bool
    30   val local_future_enabled: unit -> bool
    31   val future_result: Proof.context -> thm future -> term -> thm
    32   val prove_internal: cterm list -> cterm -> (thm list -> tactic) -> thm
    33   val prove_multi: Proof.context -> string list -> term list -> term list ->
    34     ({prems: thm list, context: Proof.context} -> tactic) -> thm list
    35   val prove_future: Proof.context -> string list -> term list -> term ->
    36     ({prems: thm list, context: Proof.context} -> tactic) -> thm
    37   val prove: Proof.context -> string list -> term list -> term ->
    38     ({prems: thm list, context: Proof.context} -> tactic) -> thm
    39   val prove_global: theory -> string list -> term list -> term ->
    40     ({prems: thm list, context: Proof.context} -> tactic) -> thm
    41   val extract: int -> int -> thm -> thm Seq.seq
    42   val retrofit: int -> int -> thm -> thm -> thm Seq.seq
    43   val conjunction_tac: int -> tactic
    44   val precise_conjunction_tac: int -> int -> tactic
    45   val recover_conjunction_tac: tactic
    46   val norm_hhf_tac: int -> tactic
    47   val compose_hhf_tac: thm -> int -> tactic
    48   val assume_rule_tac: Proof.context -> int -> tactic
    49 end;
    50 
    51 structure Goal: GOAL =
    52 struct
    53 
    54 (** goals **)
    55 
    56 (*
    57   -------- (init)
    58   C ==> #C
    59 *)
    60 val init =
    61   let val A = #1 (Thm.dest_implies (Thm.cprop_of Drule.protectI))
    62   in fn C => Thm.instantiate ([], [(A, C)]) Drule.protectI end;
    63 
    64 (*
    65    C
    66   --- (protect)
    67   #C
    68 *)
    69 fun protect th = Drule.comp_no_flatten (th, 0) 1 Drule.protectI;
    70 
    71 (*
    72   A ==> ... ==> #C
    73   ---------------- (conclude)
    74   A ==> ... ==> C
    75 *)
    76 fun conclude th = Drule.comp_no_flatten (th, Thm.nprems_of th) 1 Drule.protectD;
    77 
    78 (*
    79   #C
    80   --- (finish)
    81    C
    82 *)
    83 fun check_finished ctxt th =
    84   (case Thm.nprems_of th of
    85     0 => ()
    86   | n => raise THM ("Proof failed.\n" ^
    87       Pretty.string_of (Pretty.chunks
    88         (Goal_Display.pretty_goals
    89           (ctxt
    90             |> Config.put Goal_Display.goals_limit n
    91             |> Config.put Goal_Display.show_main_goal true) th)) ^
    92       "\n" ^ string_of_int n ^ " unsolved goal(s)!", 0, [th]));
    93 
    94 fun finish ctxt th = (check_finished ctxt th; conclude th);
    95 
    96 
    97 
    98 (** results **)
    99 
   100 (* normal form *)
   101 
   102 val norm_result =
   103   Drule.flexflex_unique
   104   #> Raw_Simplifier.norm_hhf_protect
   105   #> Thm.strip_shyps
   106   #> Drule.zero_var_indexes;
   107 
   108 
   109 (* forked proofs *)
   110 
   111 val forked_proofs = Synchronized.var "forked_proofs" 0;
   112 
   113 fun forked i =
   114   Synchronized.change forked_proofs (fn m =>
   115     let
   116       val n = m + i;
   117       val _ =
   118         Multithreading.tracing 2 (fn () =>
   119           ("PROOFS " ^ Time.toString (Time.now ()) ^ ": " ^ string_of_int n));
   120     in n end);
   121 
   122 fun fork_name name e =
   123   uninterruptible (fn _ => fn () =>
   124     let
   125       val _ = forked 1;
   126       val future =
   127         (singleton o Future.forks)
   128           {name = name, group = NONE, deps = [], pri = ~1, interrupts = false}
   129           (fn () =>
   130             Exn.release
   131               (Exn.capture (Future.status o Future.interruptible_task) e before forked ~1));
   132     in future end) ();
   133 
   134 fun fork e = fork_name "Goal.fork" e;
   135 
   136 
   137 (* scheduling parameters *)
   138 
   139 val parallel_proofs = Unsynchronized.ref 1;
   140 val parallel_proofs_threshold = Unsynchronized.ref 50;
   141 
   142 fun future_enabled () =
   143   Multithreading.enabled () andalso ! parallel_proofs >= 1 andalso
   144   is_some (Future.worker_task ());
   145 
   146 fun local_future_enabled () =
   147   future_enabled () andalso ! parallel_proofs >= 2 andalso
   148   Synchronized.value forked_proofs <
   149     ! parallel_proofs_threshold * Multithreading.max_threads_value ();
   150 
   151 
   152 (* future_result *)
   153 
   154 fun future_result ctxt result prop =
   155   let
   156     val thy = Proof_Context.theory_of ctxt;
   157     val _ = Context.reject_draft thy;
   158     val cert = Thm.cterm_of thy;
   159     val certT = Thm.ctyp_of thy;
   160 
   161     val assms = Assumption.all_assms_of ctxt;
   162     val As = map Thm.term_of assms;
   163 
   164     val xs = map Free (fold Term.add_frees (prop :: As) []);
   165     val fixes = map cert xs;
   166 
   167     val tfrees = fold Term.add_tfrees (prop :: As) [];
   168     val instT = map (fn (a, S) => (certT (TVar ((a, 0), S)), certT (TFree (a, S)))) tfrees;
   169 
   170     val global_prop =
   171       cert (Logic.varify_types_global (fold_rev Logic.all xs (Logic.list_implies (As, prop))))
   172       |> Thm.weaken_sorts (Variable.sorts_of ctxt);
   173     val global_result = result |> Future.map
   174       (Drule.flexflex_unique #>
   175         Thm.adjust_maxidx_thm ~1 #>
   176         Drule.implies_intr_list assms #>
   177         Drule.forall_intr_list fixes #>
   178         Thm.generalize (map #1 tfrees, []) 0 #>
   179         Thm.strip_shyps);
   180     val local_result =
   181       Thm.future global_result global_prop
   182       |> Thm.instantiate (instT, [])
   183       |> Drule.forall_elim_list fixes
   184       |> fold (Thm.elim_implies o Thm.assume) assms;
   185   in local_result end;
   186 
   187 
   188 
   189 (** tactical theorem proving **)
   190 
   191 (* prove_internal -- minimal checks, no normalization of result! *)
   192 
   193 fun prove_internal casms cprop tac =
   194   (case SINGLE (tac (map Assumption.assume casms)) (init cprop) of
   195     SOME th => Drule.implies_intr_list casms
   196       (finish (Syntax.init_pretty_global (Thm.theory_of_thm th)) th)
   197   | NONE => error "Tactic failed");
   198 
   199 
   200 (* prove_common etc. *)
   201 
   202 fun prove_common immediate ctxt xs asms props tac =
   203   let
   204     val thy = Proof_Context.theory_of ctxt;
   205     val string_of_term = Syntax.string_of_term ctxt;
   206 
   207     val pos = Position.thread_data ();
   208     fun err msg = cat_error msg
   209       ("The error(s) above occurred for the goal statement:\n" ^
   210         string_of_term (Logic.list_implies (asms, Logic.mk_conjunction_list props)) ^
   211         (case Position.str_of pos of "" => "" | s => "\n" ^ s));
   212 
   213     fun cert_safe t = Thm.cterm_of thy (Envir.beta_norm (Term.no_dummy_patterns t))
   214       handle TERM (msg, _) => err msg | TYPE (msg, _, _) => err msg;
   215     val casms = map cert_safe asms;
   216     val cprops = map cert_safe props;
   217 
   218     val (prems, ctxt') = ctxt
   219       |> Variable.add_fixes_direct xs
   220       |> fold Variable.declare_term (asms @ props)
   221       |> Assumption.add_assumes casms
   222       ||> Variable.set_body true;
   223     val sorts = Variable.sorts_of ctxt';
   224 
   225     val stmt = Thm.weaken_sorts sorts (Conjunction.mk_conjunction_balanced cprops);
   226 
   227     fun result () =
   228       (case SINGLE (tac {prems = prems, context = ctxt'}) (init stmt) of
   229         NONE => err "Tactic failed"
   230       | SOME st =>
   231           let val res = finish ctxt' st handle THM (msg, _, _) => err msg in
   232             if Unify.matches_list thy [Thm.term_of stmt] [Thm.prop_of res]
   233             then Thm.check_shyps sorts res
   234             else err ("Proved a different theorem: " ^ string_of_term (Thm.prop_of res))
   235           end);
   236     val res =
   237       if immediate orelse #maxidx (Thm.rep_cterm stmt) >= 0 orelse not (future_enabled ())
   238       then result ()
   239       else future_result ctxt' (fork result) (Thm.term_of stmt);
   240   in
   241     Conjunction.elim_balanced (length props) res
   242     |> map (Assumption.export false ctxt' ctxt)
   243     |> Variable.export ctxt' ctxt
   244     |> map Drule.zero_var_indexes
   245   end;
   246 
   247 val prove_multi = prove_common true;
   248 
   249 fun prove_future ctxt xs asms prop tac = hd (prove_common false ctxt xs asms [prop] tac);
   250 fun prove ctxt xs asms prop tac = hd (prove_common true ctxt xs asms [prop] tac);
   251 
   252 fun prove_global thy xs asms prop tac =
   253   Drule.export_without_context (prove (Proof_Context.init_global thy) xs asms prop tac);
   254 
   255 
   256 
   257 (** goal structure **)
   258 
   259 (* nested goals *)
   260 
   261 fun extract i n st =
   262   (if i < 1 orelse n < 1 orelse i + n - 1 > Thm.nprems_of st then Seq.empty
   263    else if n = 1 then Seq.single (Thm.cprem_of st i)
   264    else
   265      Seq.single (Conjunction.mk_conjunction_balanced (map (Thm.cprem_of st) (i upto i + n - 1))))
   266   |> Seq.map (Thm.adjust_maxidx_cterm ~1 #> init);
   267 
   268 fun retrofit i n st' st =
   269   (if n = 1 then st
   270    else st |> Drule.with_subgoal i (Conjunction.uncurry_balanced n))
   271   |> Thm.compose_no_flatten false (conclude st', Thm.nprems_of st') i;
   272 
   273 fun SELECT_GOAL tac i st =
   274   if Thm.nprems_of st = 1 andalso i = 1 then tac st
   275   else Seq.lifts (retrofit i 1) (Seq.maps tac (extract i 1 st)) st;
   276 
   277 
   278 (* multiple goals *)
   279 
   280 fun precise_conjunction_tac 0 i = eq_assume_tac i
   281   | precise_conjunction_tac 1 i = SUBGOAL (K all_tac) i
   282   | precise_conjunction_tac n i = PRIMITIVE (Drule.with_subgoal i (Conjunction.curry_balanced n));
   283 
   284 val adhoc_conjunction_tac = REPEAT_ALL_NEW
   285   (SUBGOAL (fn (goal, i) =>
   286     if can Logic.dest_conjunction goal then rtac Conjunction.conjunctionI i
   287     else no_tac));
   288 
   289 val conjunction_tac = SUBGOAL (fn (goal, i) =>
   290   precise_conjunction_tac (length (Logic.dest_conjunctions goal)) i ORELSE
   291   TRY (adhoc_conjunction_tac i));
   292 
   293 val recover_conjunction_tac = PRIMITIVE (fn th =>
   294   Conjunction.uncurry_balanced (Thm.nprems_of th) th);
   295 
   296 fun PRECISE_CONJUNCTS n tac =
   297   SELECT_GOAL (precise_conjunction_tac n 1
   298     THEN tac
   299     THEN recover_conjunction_tac);
   300 
   301 fun CONJUNCTS tac =
   302   SELECT_GOAL (conjunction_tac 1
   303     THEN tac
   304     THEN recover_conjunction_tac);
   305 
   306 
   307 (* hhf normal form *)
   308 
   309 val norm_hhf_tac =
   310   rtac Drule.asm_rl  (*cheap approximation -- thanks to builtin Logic.flatten_params*)
   311   THEN' SUBGOAL (fn (t, i) =>
   312     if Drule.is_norm_hhf t then all_tac
   313     else rewrite_goal_tac Drule.norm_hhf_eqs i);
   314 
   315 fun compose_hhf_tac th i st =
   316   PRIMSEQ (Thm.bicompose false (false, Drule.lift_all (Thm.cprem_of st i) th, 0) i) st;
   317 
   318 
   319 (* non-atomic goal assumptions *)
   320 
   321 fun non_atomic (Const ("==>", _) $ _ $ _) = true
   322   | non_atomic (Const ("all", _) $ _) = true
   323   | non_atomic _ = false;
   324 
   325 fun assume_rule_tac ctxt = norm_hhf_tac THEN' CSUBGOAL (fn (goal, i) =>
   326   let
   327     val ((_, goal'), ctxt') = Variable.focus_cterm goal ctxt;
   328     val goal'' = Drule.cterm_rule (singleton (Variable.export ctxt' ctxt)) goal';
   329     val Rs = filter (non_atomic o Thm.term_of) (Drule.strip_imp_prems goal'');
   330     val tacs = Rs |> map (fn R =>
   331       Tactic.etac (Raw_Simplifier.norm_hhf (Thm.trivial R)) THEN_ALL_NEW assume_tac);
   332   in fold_rev (curry op APPEND') tacs (K no_tac) i end);
   333 
   334 
   335 (* parallel tacticals *)
   336 
   337 (*parallel choice of single results*)
   338 fun PARALLEL_CHOICE tacs st =
   339   (case Par_List.get_some (fn tac => SINGLE tac st) tacs of
   340     NONE => Seq.empty
   341   | SOME st' => Seq.single st');
   342 
   343 (*parallel refinement of non-schematic goal by single results*)
   344 exception FAILED of unit;
   345 fun PARALLEL_GOALS tac =
   346   Thm.adjust_maxidx_thm ~1 #>
   347   (fn st =>
   348     if not (Multithreading.enabled ()) orelse Thm.maxidx_of st >= 0 orelse Thm.nprems_of st <= 1
   349     then DETERM tac st
   350     else
   351       let
   352         fun try_tac g =
   353           (case SINGLE tac g of
   354             NONE => raise FAILED ()
   355           | SOME g' => g');
   356 
   357         val goals = Drule.strip_imp_prems (Thm.cprop_of st);
   358         val results = Par_List.map (try_tac o init) goals;
   359       in ALLGOALS (fn i => retrofit i 1 (nth results (i - 1))) st end
   360       handle FAILED () => Seq.empty);
   361 
   362 end;
   363 
   364 structure Basic_Goal: BASIC_GOAL = Goal;
   365 open Basic_Goal;