src/Pure/variable.ML
author wenzelm
Thu Aug 02 12:36:54 2012 +0200 (2012-08-02)
changeset 48646 91281e9472d8
parent 47021 f35f654f297d
child 49674 dbadb4d03cbc
permissions -rw-r--r--
more official command specifications, including source position;
     1 (*  Title:      Pure/variable.ML
     2     Author:     Makarius
     3 
     4 Fixed type/term variables and polymorphic term abbreviations.
     5 *)
     6 
     7 signature VARIABLE =
     8 sig
     9   val is_body: Proof.context -> bool
    10   val set_body: bool -> Proof.context -> Proof.context
    11   val restore_body: Proof.context -> Proof.context -> Proof.context
    12   val names_of: Proof.context -> Name.context
    13   val binds_of: Proof.context -> (typ * term) Vartab.table
    14   val maxidx_of: Proof.context -> int
    15   val sorts_of: Proof.context -> sort list
    16   val constraints_of: Proof.context -> typ Vartab.table * sort Vartab.table
    17   val is_declared: Proof.context -> string -> bool
    18   val check_name: binding -> string
    19   val default_type: Proof.context -> string -> typ option
    20   val def_type: Proof.context -> bool -> indexname -> typ option
    21   val def_sort: Proof.context -> indexname -> sort option
    22   val declare_names: term -> Proof.context -> Proof.context
    23   val declare_constraints: term -> Proof.context -> Proof.context
    24   val declare_term: term -> Proof.context -> Proof.context
    25   val declare_typ: typ -> Proof.context -> Proof.context
    26   val declare_prf: Proofterm.proof -> Proof.context -> Proof.context
    27   val declare_thm: thm -> Proof.context -> Proof.context
    28   val global_thm_context: thm -> Proof.context
    29   val variant_frees: Proof.context -> term list -> (string * 'a) list -> (string * 'a) list
    30   val bind_term: indexname * term option -> Proof.context -> Proof.context
    31   val expand_binds: Proof.context -> term -> term
    32   val lookup_const: Proof.context -> string -> string option
    33   val is_const: Proof.context -> string -> bool
    34   val declare_const: string * string -> Proof.context -> Proof.context
    35   val is_fixed: Proof.context -> string -> bool
    36   val newly_fixed: Proof.context -> Proof.context -> string -> bool
    37   val fixed_ord: Proof.context -> string * string -> order
    38   val intern_fixed: Proof.context -> string -> string
    39   val markup_fixed: Proof.context -> string -> Markup.T
    40   val lookup_fixed: Proof.context -> string -> string option
    41   val revert_fixed: Proof.context -> string -> string
    42   val add_fixed_names: Proof.context -> term -> string list -> string list
    43   val add_fixed: Proof.context -> term -> (string * typ) list -> (string * typ) list
    44   val add_free_names: Proof.context -> term -> string list -> string list
    45   val add_frees: Proof.context -> term -> (string * typ) list -> (string * typ) list
    46   val add_fixes_binding: binding list -> Proof.context -> string list * Proof.context
    47   val add_fixes: string list -> Proof.context -> string list * Proof.context
    48   val add_fixes_direct: string list -> Proof.context -> Proof.context
    49   val auto_fixes: term -> Proof.context -> Proof.context
    50   val variant_fixes: string list -> Proof.context -> string list * Proof.context
    51   val dest_fixes: Proof.context -> (string * string) list
    52   val invent_types: sort list -> Proof.context -> (string * sort) list * Proof.context
    53   val export_terms: Proof.context -> Proof.context -> term list -> term list
    54   val exportT_terms: Proof.context -> Proof.context -> term list -> term list
    55   val exportT: Proof.context -> Proof.context -> thm list -> thm list
    56   val export_prf: Proof.context -> Proof.context -> Proofterm.proof -> Proofterm.proof
    57   val export: Proof.context -> Proof.context -> thm list -> thm list
    58   val export_morphism: Proof.context -> Proof.context -> morphism
    59   val importT_inst: term list -> Proof.context -> ((indexname * sort) * typ) list * Proof.context
    60   val import_inst: bool -> term list -> Proof.context ->
    61     (((indexname * sort) * typ) list * ((indexname * typ) * term) list) * Proof.context
    62   val importT_terms: term list -> Proof.context -> term list * Proof.context
    63   val import_terms: bool -> term list -> Proof.context -> term list * Proof.context
    64   val importT: thm list -> Proof.context -> ((ctyp * ctyp) list * thm list) * Proof.context
    65   val import_prf: bool -> Proofterm.proof -> Proof.context -> Proofterm.proof * Proof.context
    66   val import: bool -> thm list -> Proof.context ->
    67     (((ctyp * ctyp) list * (cterm * cterm) list) * thm list) * Proof.context
    68   val tradeT: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    69   val trade: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    70   val focus: term -> Proof.context -> ((string * (string * typ)) list * term) * Proof.context
    71   val focus_cterm: cterm -> Proof.context -> ((string * cterm) list * cterm) * Proof.context
    72   val focus_subgoal: int -> thm -> Proof.context -> ((string * cterm) list * cterm) * Proof.context
    73   val warn_extra_tfrees: Proof.context -> Proof.context -> unit
    74   val polymorphic_types: Proof.context -> term list -> (indexname * sort) list * term list
    75   val polymorphic: Proof.context -> term list -> term list
    76 end;
    77 
    78 structure Variable: VARIABLE =
    79 struct
    80 
    81 (** local context data **)
    82 
    83 type fixes = string Name_Space.table;
    84 val empty_fixes: fixes = Name_Space.empty_table Isabelle_Markup.fixedN;
    85 
    86 datatype data = Data of
    87  {is_body: bool,                        (*inner body mode*)
    88   names: Name.context,                  (*type/term variable names*)
    89   consts: string Symtab.table,          (*consts within the local scope*)
    90   fixes: fixes,                         (*term fixes -- global name space, intern ~> extern*)
    91   binds: (typ * term) Vartab.table,     (*term bindings*)
    92   type_occs: string list Symtab.table,  (*type variables -- possibly within term variables*)
    93   maxidx: int,                          (*maximum var index*)
    94   sorts: sort Ord_List.T,               (*declared sort occurrences*)
    95   constraints:
    96     typ Vartab.table *                  (*type constraints*)
    97     sort Vartab.table};                 (*default sorts*)
    98 
    99 fun make_data (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =
   100   Data {is_body = is_body, names = names, consts = consts, fixes = fixes, binds = binds,
   101     type_occs = type_occs, maxidx = maxidx, sorts = sorts, constraints = constraints};
   102 
   103 structure Data = Proof_Data
   104 (
   105   type T = data;
   106   fun init _ =
   107     make_data (false, Name.context, Symtab.empty, empty_fixes, Vartab.empty,
   108       Symtab.empty, ~1, [], (Vartab.empty, Vartab.empty));
   109 );
   110 
   111 fun map_data f =
   112   Data.map (fn Data {is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints} =>
   113     make_data (f (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints)));
   114 
   115 fun map_names f =
   116   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   117     (is_body, f names, consts, fixes, binds, type_occs, maxidx, sorts, constraints));
   118 
   119 fun map_consts f =
   120   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   121     (is_body, names, f consts, fixes, binds, type_occs, maxidx, sorts, constraints));
   122 
   123 fun map_fixes f =
   124   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   125     (is_body, names, consts, f fixes, binds, type_occs, maxidx, sorts, constraints));
   126 
   127 fun map_binds f =
   128   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   129     (is_body, names, consts, fixes, f binds, type_occs, maxidx, sorts, constraints));
   130 
   131 fun map_type_occs f =
   132   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   133     (is_body, names, consts, fixes, binds, f type_occs, maxidx, sorts, constraints));
   134 
   135 fun map_maxidx f =
   136   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   137     (is_body, names, consts, fixes, binds, type_occs, f maxidx, sorts, constraints));
   138 
   139 fun map_sorts f =
   140   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   141     (is_body, names, consts, fixes, binds, type_occs, maxidx, f sorts, constraints));
   142 
   143 fun map_constraints f =
   144   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   145     (is_body, names, consts, fixes, binds, type_occs, maxidx, sorts, f constraints));
   146 
   147 fun rep_data ctxt = Data.get ctxt |> (fn Data rep => rep);
   148 
   149 val is_body = #is_body o rep_data;
   150 
   151 fun set_body b =
   152   map_data (fn (_, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints) =>
   153     (b, names, consts, fixes, binds, type_occs, maxidx, sorts, constraints));
   154 
   155 fun restore_body ctxt = set_body (is_body ctxt);
   156 
   157 val names_of = #names o rep_data;
   158 val fixes_of = #fixes o rep_data;
   159 val fixes_space = #1 o fixes_of;
   160 val binds_of = #binds o rep_data;
   161 val type_occs_of = #type_occs o rep_data;
   162 val maxidx_of = #maxidx o rep_data;
   163 val sorts_of = #sorts o rep_data;
   164 val constraints_of = #constraints o rep_data;
   165 
   166 val is_declared = Name.is_declared o names_of;
   167 
   168 val check_name = Name_Space.base_name o tap Binding.check;
   169 
   170 
   171 
   172 (** declarations **)
   173 
   174 (* default sorts and types *)
   175 
   176 fun default_type ctxt x = Vartab.lookup (#1 (constraints_of ctxt)) (x, ~1);
   177 
   178 fun def_type ctxt pattern xi =
   179   let val {binds, constraints = (types, _), ...} = rep_data ctxt in
   180     (case Vartab.lookup types xi of
   181       NONE =>
   182         if pattern then NONE
   183         else Vartab.lookup binds xi |> Option.map (Type.mark_polymorphic o #1)
   184     | some => some)
   185   end;
   186 
   187 val def_sort = Vartab.lookup o #2 o constraints_of;
   188 
   189 
   190 (* names *)
   191 
   192 fun declare_type_names t =
   193   map_names (fold_types (fold_atyps Term.declare_typ_names) t) #>
   194   map_maxidx (fold_types Term.maxidx_typ t);
   195 
   196 fun declare_names t =
   197   declare_type_names t #>
   198   map_names (fold_aterms Term.declare_term_frees t) #>
   199   map_maxidx (Term.maxidx_term t);
   200 
   201 
   202 (* type occurrences *)
   203 
   204 fun decl_type_occsT T = fold_atyps (fn TFree (a, _) => Symtab.default (a, []) | _ => I) T;
   205 
   206 val decl_type_occs = fold_term_types
   207   (fn Free (x, _) => fold_atyps (fn TFree (a, _) => Symtab.insert_list (op =) (a, x) | _ => I)
   208     | _ => decl_type_occsT);
   209 
   210 val declare_type_occsT = map_type_occs o fold_types decl_type_occsT;
   211 val declare_type_occs = map_type_occs o decl_type_occs;
   212 
   213 
   214 (* constraints *)
   215 
   216 fun constrain_tvar (xi, S) =
   217   if S = dummyS then Vartab.delete_safe xi else Vartab.update (xi, S);
   218 
   219 fun declare_constraints t = map_constraints (fn (types, sorts) =>
   220   let
   221     val types' = fold_aterms
   222       (fn Free (x, T) => Vartab.update ((x, ~1), T)
   223         | Var v => Vartab.update v
   224         | _ => I) t types;
   225     val sorts' = (fold_types o fold_atyps)
   226       (fn TFree (x, S) => constrain_tvar ((x, ~1), S)
   227         | TVar v => constrain_tvar v
   228         | _ => I) t sorts;
   229   in (types', sorts') end)
   230   #> declare_type_occsT t
   231   #> declare_type_names t;
   232 
   233 
   234 (* common declarations *)
   235 
   236 fun declare_internal t =
   237   declare_names t #>
   238   declare_type_occs t #>
   239   map_sorts (Sorts.insert_term t);
   240 
   241 fun declare_term t =
   242   declare_internal t #>
   243   declare_constraints t;
   244 
   245 val declare_typ = declare_term o Logic.mk_type;
   246 
   247 val declare_prf = Proofterm.fold_proof_terms declare_internal (declare_internal o Logic.mk_type);
   248 
   249 val declare_thm = Thm.fold_terms declare_internal;
   250 fun global_thm_context th = declare_thm th (Proof_Context.init_global (Thm.theory_of_thm th));
   251 
   252 
   253 (* renaming term/type frees *)
   254 
   255 fun variant_frees ctxt ts frees =
   256   let
   257     val names = names_of (fold declare_names ts ctxt);
   258     val xs = fst (fold_map Name.variant (map #1 frees) names);
   259   in xs ~~ map snd frees end;
   260 
   261 
   262 
   263 (** term bindings **)
   264 
   265 fun bind_term (xi, NONE) = map_binds (Vartab.delete_safe xi)
   266   | bind_term ((x, i), SOME t) =
   267       let
   268         val u = Term.close_schematic_term t;
   269         val U = Term.fastype_of u;
   270       in declare_term u #> map_binds (Vartab.update ((x, i), (U, u))) end;
   271 
   272 fun expand_binds ctxt =
   273   let
   274     val binds = binds_of ctxt;
   275     val get = fn Var (xi, _) => Vartab.lookup binds xi | _ => NONE;
   276   in Envir.beta_norm o Envir.expand_term get end;
   277 
   278 
   279 
   280 (** consts **)
   281 
   282 val lookup_const = Symtab.lookup o #consts o rep_data;
   283 val is_const = is_some oo lookup_const;
   284 
   285 val declare_fixed = map_consts o Symtab.delete_safe;
   286 val declare_const = map_consts o Symtab.update;
   287 
   288 
   289 
   290 (** fixes **)
   291 
   292 (* specialized name space *)
   293 
   294 val is_fixed = Name_Space.defined_entry o fixes_space;
   295 fun newly_fixed inner outer = is_fixed inner andf (not o is_fixed outer);
   296 
   297 val fixed_ord = Name_Space.entry_ord o fixes_space;
   298 val intern_fixed = Name_Space.intern o fixes_space;
   299 
   300 fun lookup_fixed ctxt x =
   301   let val x' = intern_fixed ctxt x
   302   in if is_fixed ctxt x' then SOME x' else NONE end;
   303 
   304 fun revert_fixed ctxt x =
   305   (case Symtab.lookup (#2 (fixes_of ctxt)) x of
   306     SOME x' => if intern_fixed ctxt x' = x then x' else x
   307   | NONE => x);
   308 
   309 fun markup_fixed ctxt x =
   310   Name_Space.markup (fixes_space ctxt) x
   311   |> Markup.name (revert_fixed ctxt x);
   312 
   313 fun dest_fixes ctxt =
   314   let val (space, tab) = fixes_of ctxt
   315   in sort (Name_Space.entry_ord space o pairself #2) (map swap (Symtab.dest tab)) end;
   316 
   317 
   318 (* collect variables *)
   319 
   320 fun add_free_names ctxt =
   321   fold_aterms (fn Free (x, _) => not (is_fixed ctxt x) ? insert (op =) x | _ => I);
   322 
   323 fun add_frees ctxt =
   324   fold_aterms (fn Free (x, T) => not (is_fixed ctxt x) ? insert (op =) (x, T) | _ => I);
   325 
   326 fun add_fixed_names ctxt =
   327   fold_aterms (fn Free (x, _) => is_fixed ctxt x ? insert (op =) x | _ => I);
   328 
   329 fun add_fixed ctxt =
   330   fold_aterms (fn Free (x, T) => is_fixed ctxt x ? insert (op =) (x, T) | _ => I);
   331 
   332 
   333 (* declarations *)
   334 
   335 local
   336 
   337 fun err_dups dups =
   338   error ("Duplicate fixed variable(s): " ^ commas (map Binding.print dups));
   339 
   340 fun new_fixed ((x, x'), pos) ctxt =
   341   if is_some (lookup_fixed ctxt x') then err_dups [Binding.make (x, pos)]
   342   else
   343     let val context = Context.Proof ctxt |> Name_Space.map_naming (K Name_Space.default_naming) in
   344       ctxt
   345       |> map_fixes
   346         (Name_Space.define context true (Binding.make (x', pos), x) #> snd #>>
   347           Name_Space.alias Name_Space.default_naming (Binding.make (x, pos)) x')
   348       |> declare_fixed x
   349       |> declare_constraints (Syntax.free x')
   350   end;
   351 
   352 fun new_fixes names' xs xs' ps =
   353   map_names (K names') #>
   354   fold new_fixed ((xs ~~ xs') ~~ ps) #>
   355   pair xs';
   356 
   357 in
   358 
   359 fun add_fixes_binding bs ctxt =
   360   let
   361     val _ =
   362       (case filter (can Name.dest_skolem o Binding.name_of) bs of
   363         [] => ()
   364       | bads => error ("Illegal internal Skolem constant(s): " ^ commas (map Binding.print bads)));
   365     val _ =
   366       (case duplicates (op = o pairself Binding.name_of) bs of
   367         [] => ()
   368       | dups => err_dups dups);
   369 
   370     val xs = map check_name bs;
   371     val names = names_of ctxt;
   372     val (xs', names') =
   373       if is_body ctxt then fold_map Name.variant xs names |>> map Name.skolem
   374       else (xs, fold Name.declare xs names);
   375   in ctxt |> new_fixes names' xs xs' (map Binding.pos_of bs) end;
   376 
   377 fun variant_fixes raw_xs ctxt =
   378   let
   379     val names = names_of ctxt;
   380     val xs = map (fn x => Name.clean x |> can Name.dest_internal x ? Name.internal) raw_xs;
   381     val (xs', names') = fold_map Name.variant xs names |>> (is_body ctxt ? map Name.skolem);
   382   in ctxt |> new_fixes names' xs xs' (replicate (length xs) Position.none) end;
   383 
   384 end;
   385 
   386 val add_fixes = add_fixes_binding o map Binding.name;
   387 
   388 fun add_fixes_direct xs ctxt = ctxt
   389   |> set_body false
   390   |> (snd o add_fixes xs)
   391   |> restore_body ctxt;
   392 
   393 fun auto_fixes t ctxt = ctxt
   394   |> not (is_body ctxt) ? add_fixes_direct (rev (add_free_names ctxt t []))
   395   |> declare_term t;
   396 
   397 fun invent_types Ss ctxt =
   398   let
   399     val tfrees = Name.invent (names_of ctxt) Name.aT (length Ss) ~~ Ss;
   400     val ctxt' = fold (declare_constraints o Logic.mk_type o TFree) tfrees ctxt;
   401   in (tfrees, ctxt') end;
   402 
   403 
   404 
   405 (** export -- generalize type/term variables (beware of closure sizes) **)
   406 
   407 fun export_inst inner outer =
   408   let
   409     val declared_outer = is_declared outer;
   410     val still_fixed = not o newly_fixed inner outer;
   411 
   412     val gen_fixes =
   413       Symtab.fold (fn (y, _) => not (is_fixed outer y) ? cons y)
   414         (#2 (fixes_of inner)) [];
   415 
   416     val type_occs_inner = type_occs_of inner;
   417     fun gen_fixesT ts =
   418       Symtab.fold (fn (a, xs) =>
   419         if declared_outer a orelse exists still_fixed xs
   420         then I else cons a) (fold decl_type_occs ts type_occs_inner) [];
   421   in (gen_fixesT, gen_fixes) end;
   422 
   423 fun exportT_inst inner outer = #1 (export_inst inner outer);
   424 
   425 fun exportT_terms inner outer =
   426   let val mk_tfrees = exportT_inst inner outer in
   427     fn ts => ts |> map
   428       (Term_Subst.generalize (mk_tfrees ts, [])
   429         (fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1))
   430   end;
   431 
   432 fun export_terms inner outer =
   433   let val (mk_tfrees, tfrees) = export_inst inner outer in
   434     fn ts => ts |> map
   435       (Term_Subst.generalize (mk_tfrees ts, tfrees)
   436         (fold Term.maxidx_term ts ~1 + 1))
   437   end;
   438 
   439 fun export_prf inner outer prf =
   440   let
   441     val (mk_tfrees, frees) = export_inst (declare_prf prf inner) outer;
   442     val tfrees = mk_tfrees [];
   443     val idx = Proofterm.maxidx_proof prf ~1 + 1;
   444     val gen_term = Term_Subst.generalize_same (tfrees, frees) idx;
   445     val gen_typ = Term_Subst.generalizeT_same tfrees idx;
   446   in Same.commit (Proofterm.map_proof_terms_same gen_term gen_typ) prf end;
   447 
   448 
   449 fun gen_export (mk_tfrees, frees) ths =
   450   let
   451     val tfrees = mk_tfrees (map Thm.full_prop_of ths);
   452     val maxidx = fold Thm.maxidx_thm ths ~1;
   453   in map (Thm.generalize (tfrees, frees) (maxidx + 1)) ths end;
   454 
   455 fun exportT inner outer = gen_export (exportT_inst inner outer, []);
   456 fun export inner outer = gen_export (export_inst inner outer);
   457 
   458 fun export_morphism inner outer =
   459   let
   460     val fact = export inner outer;
   461     val term = singleton (export_terms inner outer);
   462     val typ = Logic.type_map term;
   463   in Morphism.morphism {binding = [], typ = [typ], term = [term], fact = [fact]} end;
   464 
   465 
   466 
   467 (** import -- fix schematic type/term variables **)
   468 
   469 fun importT_inst ts ctxt =
   470   let
   471     val tvars = rev (fold Term.add_tvars ts []);
   472     val (tfrees, ctxt') = invent_types (map #2 tvars) ctxt;
   473   in (tvars ~~ map TFree tfrees, ctxt') end;
   474 
   475 fun import_inst is_open ts ctxt =
   476   let
   477     val ren = Name.clean #> (if is_open then I else Name.internal);
   478     val (instT, ctxt') = importT_inst ts ctxt;
   479     val vars = map (apsnd (Term_Subst.instantiateT instT)) (rev (fold Term.add_vars ts []));
   480     val (xs, ctxt'') = variant_fixes (map (ren o #1 o #1) vars) ctxt';
   481     val inst = vars ~~ map Free (xs ~~ map #2 vars);
   482   in ((instT, inst), ctxt'') end;
   483 
   484 fun importT_terms ts ctxt =
   485   let val (instT, ctxt') = importT_inst ts ctxt
   486   in (map (Term_Subst.instantiate (instT, [])) ts, ctxt') end;
   487 
   488 fun import_terms is_open ts ctxt =
   489   let val (inst, ctxt') = import_inst is_open ts ctxt
   490   in (map (Term_Subst.instantiate inst) ts, ctxt') end;
   491 
   492 fun importT ths ctxt =
   493   let
   494     val thy = Proof_Context.theory_of ctxt;
   495     val (instT, ctxt') = importT_inst (map Thm.full_prop_of ths) ctxt;
   496     val insts' as (instT', _) = Thm.certify_inst thy (instT, []);
   497     val ths' = map (Thm.instantiate insts') ths;
   498   in ((instT', ths'), ctxt') end;
   499 
   500 fun import_prf is_open prf ctxt =
   501   let
   502     val ts = rev (Proofterm.fold_proof_terms cons (cons o Logic.mk_type) prf []);
   503     val (insts, ctxt') = import_inst is_open ts ctxt;
   504   in (Proofterm.instantiate insts prf, ctxt') end;
   505 
   506 fun import is_open ths ctxt =
   507   let
   508     val thy = Proof_Context.theory_of ctxt;
   509     val (insts, ctxt') = import_inst is_open (map Thm.full_prop_of ths) ctxt;
   510     val insts' = Thm.certify_inst thy insts;
   511     val ths' = map (Thm.instantiate insts') ths;
   512   in ((insts', ths'), ctxt') end;
   513 
   514 
   515 (* import/export *)
   516 
   517 fun gen_trade imp exp f ctxt ths =
   518   let val ((_, ths'), ctxt') = imp ths ctxt
   519   in exp ctxt' ctxt (f ctxt' ths') end;
   520 
   521 val tradeT = gen_trade importT exportT;
   522 val trade = gen_trade (import true) export;
   523 
   524 
   525 (* focus on outermost parameters: !!x y z. B *)
   526 
   527 fun focus_params t ctxt =
   528   let
   529     val (xs, Ts) =
   530       split_list (Term.variant_frees t (Term.strip_all_vars t));  (*as they are printed :-*)
   531     val (xs', ctxt') = variant_fixes xs ctxt;
   532     val ps = xs' ~~ Ts;
   533     val ctxt'' = ctxt' |> fold (declare_constraints o Free) ps;
   534   in ((xs, ps), ctxt'') end;
   535 
   536 fun focus t ctxt =
   537   let
   538     val ((xs, ps), ctxt') = focus_params t ctxt;
   539     val t' = Term.subst_bounds (rev (map Free ps), Term.strip_all_body t);
   540   in (((xs ~~ ps), t'), ctxt') end;
   541 
   542 fun forall_elim_prop t prop =
   543   Thm.beta_conversion false (Thm.apply (Thm.dest_arg prop) t)
   544   |> Thm.cprop_of |> Thm.dest_arg;
   545 
   546 fun focus_cterm goal ctxt =
   547   let
   548     val cert = Thm.cterm_of (Thm.theory_of_cterm goal);
   549     val ((xs, ps), ctxt') = focus_params (Thm.term_of goal) ctxt;
   550     val ps' = map (cert o Free) ps;
   551     val goal' = fold forall_elim_prop ps' goal;
   552   in ((xs ~~ ps', goal'), ctxt') end;
   553 
   554 fun focus_subgoal i st =
   555   let
   556     val all_vars = Thm.fold_terms Term.add_vars st [];
   557     val no_binds = map (fn (xi, _) => (xi, NONE)) all_vars;
   558   in
   559     fold bind_term no_binds #>
   560     fold (declare_constraints o Var) all_vars #>
   561     focus_cterm (Thm.cprem_of st i)
   562   end;
   563 
   564 
   565 
   566 (** implicit polymorphism **)
   567 
   568 (* warn_extra_tfrees *)
   569 
   570 fun warn_extra_tfrees ctxt1 ctxt2 =
   571   let
   572     fun occs_typ a = Term.exists_subtype (fn TFree (b, _) => a = b | _ => false);
   573     fun occs_free a x =
   574       (case def_type ctxt1 false (x, ~1) of
   575         SOME T => if occs_typ a T then I else cons (a, x)
   576       | NONE => cons (a, x));
   577 
   578     val occs1 = type_occs_of ctxt1;
   579     val occs2 = type_occs_of ctxt2;
   580     val extras = Symtab.fold (fn (a, xs) =>
   581       if Symtab.defined occs1 a then I else fold (occs_free a) xs) occs2 [];
   582     val tfrees = map #1 extras |> sort_distinct string_ord;
   583     val frees = map #2 extras |> sort_distinct string_ord;
   584   in
   585     if null extras orelse not (Context_Position.is_visible ctxt2) then ()
   586     else warning ("Introduced fixed type variable(s): " ^ commas tfrees ^ " in " ^
   587       space_implode " or " (map quote frees))
   588   end;
   589 
   590 
   591 (* polymorphic terms *)
   592 
   593 fun polymorphic_types ctxt ts =
   594   let
   595     val ctxt' = fold declare_term ts ctxt;
   596     val occs = type_occs_of ctxt;
   597     val occs' = type_occs_of ctxt';
   598     val types = Symtab.fold (fn (a, _) => if Symtab.defined occs a then I else cons a) occs' [];
   599     val idx = maxidx_of ctxt' + 1;
   600     val Ts' = (fold o fold_types o fold_atyps)
   601       (fn T as TFree _ =>
   602           (case Term_Subst.generalizeT types idx T of TVar v => insert (op =) v | _ => I)
   603         | _ => I) ts [];
   604     val ts' = map (Term_Subst.generalize (types, []) idx) ts;
   605   in (rev Ts', ts') end;
   606 
   607 fun polymorphic ctxt ts = snd (polymorphic_types ctxt ts);
   608 
   609 end;